lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems.
   2
   3 ;;;; Copyright (C) 1993 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;;; This file is part of GNU Emacs.
   9 ;;;
  10 ;;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 2, or (at your option)
  13 ;;; any later version.
  14 ;;;
  15 ;;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Code:
  25
  26 (defvar frame-creation-function nil
  27   "Window-system dependent function to call to create a new frame.
  28 The window system startup file should set this to its frame creation
  29 function, which should take an alist of parameters as its argument.")
  30
  31 ;;; The initial value given here for this must ask for a minibuffer.
  32 ;;; There must always exist a frame with a minibuffer, and after we
  33 ;;; delete the terminal frame, this will be the only frame.
  34 (defvar initial-frame-alist '((minibuffer . t))
  35   "Alist of frame parameters for creating the initial X window frame.
  36 You can set this in your `.emacs' file; for example,
  37  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  38 If the value calls for a frame without a minibuffer, and you do not create a
  39 minibuffer frame on your own, one is created according to
  40 `minibuffer-frame-alist'.
  41 Parameters specified here supersede the values given in
  42 `default-frame-alist'.")
  43
  44 (defvar minibuffer-frame-alist '((width . 80) (height . 2))
  45   "Alist of frame parameters for initially creating a minibuffer frame.
  46 You can set this in your `.emacs' file; for example,
  47  (setq minibuffer-frame-alist
  48    '((top . 1) (left . 1) (width . 80) (height . 2)))
  49 Parameters specified here supersede the values given in
  50 `default-frame-alist'.")
  51
  52 (defvar pop-up-frame-alist nil
  53   "Alist of frame parameters used when creating pop-up frames.
  54 Pop-up frames are used for completions, help, and the like.
  55 This variable can be set in your init file, like this:
  56   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  57 These supersede the values given in `default-frame-alist'.")
  58
  59 (setq pop-up-frame-function
  60       (function (lambda ()
  61                   (new-frame pop-up-frame-alist))))
  62
  63 \f
  64 ;;;; Arrangement of frames at startup
  65
  66 ;;; 1) Load the window system startup file from the lisp library and read the
  67 ;;; high-priority arguments (-q and the like).  The window system startup
  68 ;;; file should create any frames specified in the window system defaults.
  69 ;;;
  70 ;;; 2) If no frames have been opened, we open an initial text frame.
  71 ;;;
  72 ;;; 3) Once the init file is done, we apply any newly set parameters
  73 ;;; in initial-frame-alist to the frame.
  74
  75 ;; These are now called explicitly at the proper times,
  76 ;; since that is easier to understand.
  77 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
  78 ;; (add-hook 'before-init-hook 'frame-initialize)
  79 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
  80
  81 ;;; If we create the initial frame, this is it.
  82 (defvar frame-initial-frame nil)
  83
  84 ;; Record the parameters used in frame-initialize to make the initial frame.
  85 (defvar frame-initial-frame-alist)
  86
  87 ;;; startup.el calls this function before loading the user's init
  88 ;;; file - if there is no frame with a minibuffer open now, create
  89 ;;; one to display messages while loading the init file.
  90 (defun frame-initialize ()
  91
  92   ;; Are we actually running under a window system at all?
  93   (if (and window-system (not noninteractive))
  94       (progn
  95         ;; If there is no frame with a minibuffer besides the terminal
  96         ;; frame, then we need to create the opening frame.  Make sure
  97         ;; it has a minibuffer, but let initial-frame-alist omit the
  98         ;; minibuffer spec.
  99         (or (delq terminal-frame (minibuffer-frame-list))
 100             (progn
 101               (setq frame-initial-frame-alist
 102                     (append initial-frame-alist default-frame-alist))
 103               (setq default-minibuffer-frame
 104                     (setq frame-initial-frame
 105                           (new-frame initial-frame-alist)))
 106               ;; Delete any specifications for window geometry parameters
 107               ;; so that we won't reapply them in frame-notice-user-settings.
 108               ;; It would be wrong to reapply them then,
 109               ;; because that would override explicit user resizing.
 110               (setq initial-frame-alist
 111                     (frame-remove-geometry-params initial-frame-alist))
 112               ;; Handle `reverse' as a parameter.
 113               (if (cdr (or (assq 'reverse initial-frame-alist)
 114                            (assq 'reverse default-frame-alist)))
 115                   (let ((params (frame-parameters frame-initial-frame)))
 116                     (modify-frame-parameters
 117                      frame-initial-frame
 118                      ;; Must set cursor-color after background color.
 119                      ;; So put it first.
 120                      (list (cons 'cursor-color
 121                                  (cdr (assq 'background-color params)))
 122                            (cons 'foreground-color
 123                                  (cdr (assq 'background-color params)))
 124                            (cons 'background-color
 125                                  (cdr (assq 'foreground-color params)))
 126                            (cons 'mouse-color
 127                                  (cdr (assq 'background-color params)))
 128                            (cons 'border-color
 129                                  (cdr (assq 'background-color params)))))))))
 130
 131         ;; At this point, we know that we have a frame open, so we
 132         ;; can delete the terminal frame.
 133         (delete-frame terminal-frame)
 134         (setq terminal-frame nil))
 135
 136     ;; No, we're not running a window system.  Arrange to cause errors.
 137     (setq frame-creation-function
 138           (function
 139            (lambda (parameters)
 140              (error
 141               "Can't create multiple frames without a window system"))))))
 142
 143 ;;; startup.el calls this function after loading the user's init
 144 ;;; file.  Now default-frame-alist and initial-frame-alist contain
 145 ;;; information to which we must react; do what needs to be done.
 146 (defun frame-notice-user-settings ()
 147
 148   ;; Creating and deleting frames may shift the selected frame around,
 149   ;; and thus the current buffer.  Protect against that.  We don't
 150   ;; want to use save-excursion here, because that may also try to set
 151   ;; the buffer of the selected window, which fails when the selected
 152   ;; window is the minibuffer.
 153   (let ((old-buffer (current-buffer)))
 154
 155     ;; If the initial frame is still around, apply initial-frame-alist
 156     ;; and default-frame-alist to it.
 157     (if (frame-live-p frame-initial-frame)
 158
 159         ;; The initial frame we create above always has a minibuffer.
 160         ;; If the user wants to remove it, or make it a minibuffer-only
 161         ;; frame, then we'll have to delete the current frame and make a
 162         ;; new one; you can't remove or add a root window to/from an
 163         ;; existing frame.
 164         ;;
 165         ;; NOTE: default-frame-alist was nil when we created the
 166         ;; existing frame.  We need to explicitly include
 167         ;; default-frame-alist in the parameters of the screen we
 168         ;; create here, so that its new value, gleaned from the user's
 169         ;; .emacs file, will be applied to the existing screen.
 170         (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 171                               (assq 'minibuffer default-frame-alist)
 172                               '(minibuffer . t)))
 173                      t))
 174             ;; Create the new frame.
 175             (let ((new
 176                    (new-frame
 177                     (append initial-frame-alist
 178                             default-frame-alist
 179                             (frame-parameters frame-initial-frame)))))
 180
 181               ;; The initial frame, which we are about to delete, may be
 182               ;; the only frame with a minibuffer.  If it is, create a
 183               ;; new one.
 184               (or (delq frame-initial-frame (minibuffer-frame-list))
 185                   (new-frame (append minibuffer-frame-alist
 186                                      '((minibuffer . only)))))
 187
 188               ;; If the initial frame is serving as a surrogate
 189               ;; minibuffer frame for any frames, we need to wean them
 190               ;; onto a new frame.  The default-minibuffer-frame
 191               ;; variable must be handled similarly.
 192               (let ((users-of-initial
 193                      (filtered-frame-list
 194                       (function (lambda (frame)
 195                                   (and (not (eq frame frame-initial-frame))
 196                                        (eq (window-frame
 197                                             (minibuffer-window frame))
 198                                            frame-initial-frame)))))))
 199                 (if (or users-of-initial
 200                         (eq default-minibuffer-frame frame-initial-frame))
 201
 202                     ;; Choose an appropriate frame.  Prefer frames which
 203                     ;; are only minibuffers.
 204                     (let* ((new-surrogate
 205                             (car
 206                              (or (filtered-frame-list
 207                                   (function
 208                                    (lambda (frame)
 209                                      (eq (cdr (assq 'minibuffer
 210                                                     (frame-parameters frame)))
 211                                          'only))))
 212                                  (minibuffer-frame-list))))
 213                            (new-minibuffer (minibuffer-window new-surrogate)))
 214
 215                       (if (eq default-minibuffer-frame frame-initial-frame)
 216                           (setq default-minibuffer-frame new-surrogate))
 217
 218                       ;; Wean the frames using frame-initial-frame as
 219                       ;; their minibuffer frame.
 220                       (mapcar
 221                        (function
 222                         (lambda (frame)
 223                           (modify-frame-parameters
 224                            frame (list (cons 'minibuffer new-minibuffer)))))
 225                        users-of-initial))))
 226
 227               ;; Redirect events enqueued at this frame to the new frame.
 228               ;; Is this a good idea?
 229               (redirect-frame-focus frame-initial-frame new)
 230
 231               ;; Finally, get rid of the old frame.
 232               (delete-frame frame-initial-frame t))
 233
 234           ;; Otherwise, we don't need all that rigamarole; just apply
 235           ;; the new parameters.
 236           (let (newparms allparms tail)
 237             (setq allparms (append initial-frame-alist
 238                                    default-frame-alist))
 239             (setq tail allparms)
 240             ;; Find just the parms that have changed since we first
 241             ;; made this frame.  Those are the ones actually set by
 242             ;; the init file.  For those parms whose values we already knew
 243             ;; (such as those spec'd by command line options)
 244             ;; it is undesirable to specify the parm again
 245             ;; once the user has seen the frame and been able to alter it
 246             ;; manually.
 247             (while tail
 248               (let (newval oldval)
 249                 (setq oldval (cdr (assq (car (car tail))
 250                                         frame-initial-frame-alist)))
 251                 (setq newval (cdr (assq (car (car tail)) allparms)))
 252                 (or (eq oldval newval)
 253                     (setq newparms
 254                           (cons (cons (car (car tail)) newval) newparms))))
 255               (setq tail (cdr tail)))
 256             (modify-frame-parameters frame-initial-frame
 257                                      (nreverse newparms)))))
 258
 259     ;; Restore the original buffer.
 260     (set-buffer old-buffer)
 261
 262     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 263     ;; Make sure frame-notice-user-settings does nothing if called twice.
 264     (setq frame-initial-frame nil)))
 265
 266 \f
 267 ;;;; Creation of additional frames, and other frame miscellanea
 268
 269 ;;; Return some frame other than the current frame, creating one if
 270 ;;; necessary.  Note that the minibuffer frame, if separate, is not
 271 ;;; considered (see next-frame).
 272 (defun get-other-frame ()
 273   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 274                (new-frame)
 275              (next-frame (selected-frame)))))
 276     s))
 277
 278 (defun next-multiframe-window ()
 279   "Select the next window, regardless of which frame it is on."
 280   (interactive)
 281   (select-window (next-window (selected-window)
 282                               (> (minibuffer-depth) 0)
 283                               t)))
 284
 285 (defun previous-multiframe-window ()
 286   "Select the previous window, regardless of which frame it is on."
 287   (interactive)
 288   (select-window (previous-window (selected-window)
 289                                   (> (minibuffer-depth) 0)
 290                                   t)))
 291
 292 ;; Alias, kept temporarily.
 293 (defalias 'new-frame 'make-frame)
 294 (defun make-frame (&optional parameters)
 295   "Create a new frame, displaying the current buffer.
 296
 297 Optional argument PARAMETERS is an alist of parameters for the new
 298 frame.  Specifically, PARAMETERS is a list of pairs, each having one
 299 of the following forms:
 300
 301 \(name . STRING)        - The frame should be named STRING.
 302
 303 \(height . NUMBER) - The frame should be NUMBER text lines high.  If
 304         this parameter is present, the width parameter must also be
 305         given.
 306
 307 \(width . NUMBER) - The frame should be NUMBER characters in width.
 308         If this parameter is present, the height parameter must also
 309         be given.
 310
 311 \(minibuffer . t) - the frame should have a minibuffer
 312 \(minibuffer . nil) - the frame should have no minibuffer
 313 \(minibuffer . only) - the frame should contain only a minibuffer
 314 \(minibuffer . WINDOW) - the frame should use WINDOW as its minibuffer window.
 315
 316 The documentation for the function `x-create-frame' describes
 317 additional frame parameters that Emacs recognizes for X window frames."
 318   (interactive)
 319   (funcall frame-creation-function parameters))
 320
 321 (defun filtered-frame-list (predicate)
 322   "Return a list of all live frames which satisfy PREDICATE."
 323   (let ((frames (frame-list))
 324         good-frames)
 325     (while (consp frames)
 326       (if (funcall predicate (car frames))
 327           (setq good-frames (cons (car frames) good-frames)))
 328       (setq frames (cdr frames)))
 329     good-frames))
 330
 331 (defun minibuffer-frame-list ()
 332   "Return a list of all frames with their own minibuffers."
 333   (filtered-frame-list
 334    (function (lambda (frame)
 335                (eq frame (window-frame (minibuffer-window frame)))))))
 336
 337 (defun frame-remove-geometry-params (param-list)
 338   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 339 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 340 and `height' parameters.
 341 Emacs uses this to avoid overriding explicit moves and resizings from
 342 the user during startup."
 343   (setq param-list (cons nil param-list))
 344   (let ((tail param-list))
 345     (while (consp (cdr tail))
 346       (if (and (consp (car (cdr tail)))
 347                (memq (car (car (cdr tail))) '(height width top left)))
 348           (setcdr tail (cdr (cdr tail)))
 349         (setq tail (cdr tail)))))
 350   (cdr param-list))
 351
 352
 353 (defun other-frame (arg)
 354   "Select the ARG'th different visible frame, and raise it.
 355 All frames are arranged in a cyclic order.
 356 This command selects the frame ARG steps away in that order.
 357 A negative ARG moves in the opposite order."
 358   (interactive "p")
 359   (let ((frame (selected-frame)))
 360     (while (> arg 0)
 361       (setq frame (next-frame frame))
 362       (while (not (eq (frame-visible-p frame) t))
 363         (setq frame (next-frame frame)))
 364       (setq arg (1- arg)))
 365     (while (< arg 0)
 366       (setq frame (previous-frame frame))
 367       (while (not (eq (frame-visible-p frame) t))
 368         (setq frame (previous-frame frame)))
 369       (setq arg (1+ arg)))
 370     (raise-frame frame)
 371     (select-frame frame)))
 372 \f
 373 ;;;; Frame configurations
 374
 375 (defun current-frame-configuration ()
 376   "Return a list describing the positions and states of all frames.
 377 Its car is `frame-configuration'.
 378 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 379 where
 380   FRAME is a frame object,
 381   ALIST is an association list specifying some of FRAME's parameters, and
 382   WINDOW-CONFIG is a window configuration object for FRAME."
 383   (cons 'frame-configuration
 384         (mapcar (function
 385                  (lambda (frame)
 386                    (list frame
 387                          (frame-parameters frame)
 388                          (current-window-configuration frame))))
 389                 (frame-list))))
 390
 391 (defun set-frame-configuration (configuration)
 392   "Restore the frames to the state described by CONFIGURATION.
 393 Each frame listed in CONFIGURATION has its position, size, window
 394 configuration, and other parameters set as specified in CONFIGURATION."
 395   (or (frame-configuration-p configuration)
 396       (signal 'wrong-type-argument
 397               (list 'frame-configuration-p configuration)))
 398   (let ((config-alist (cdr configuration))
 399         frames-to-delete)
 400     (mapcar (function
 401              (lambda (frame)
 402                (let ((parameters (assq frame config-alist)))
 403                  (if parameters
 404                      (progn
 405                        (modify-frame-parameters
 406                         frame
 407                         ;; Since we can't set a frame's minibuffer status,
 408                         ;; we might as well omit the parameter altogether.
 409                         (let* ((parms (nth 1 parameters))
 410                                (mini (assq 'minibuffer parms)))
 411                           (if mini (setq parms (delq mini parms)))
 412                           parms))
 413                        (set-window-configuration (nth 2 parameters)))
 414                    (setq frames-to-delete (cons frame frames-to-delete))))))
 415             (frame-list))
 416     (mapcar 'delete-frame frames-to-delete)))
 417
 418 (defun frame-configuration-p (object)
 419   "Return non-nil if OBJECT seems to be a frame configuration.
 420 Any list whose car is `frame-configuration' is assumed to be a frame
 421 configuration."
 422   (and (consp object)
 423        (eq (car object) 'frame-configuration)))
 424
 425 \f
 426 ;;;; Convenience functions for accessing and interactively changing
 427 ;;;; frame parameters.
 428
 429 (defun frame-height (&optional frame)
 430   "Return number of lines available for display on FRAME.
 431 If FRAME is omitted, describe the currently selected frame."
 432   (cdr (assq 'height (frame-parameters frame))))
 433
 434 (defun frame-width (&optional frame)
 435   "Return number of columns available for display on FRAME.
 436 If FRAME is omitted, describe the currently selected frame."
 437   (cdr (assq 'width (frame-parameters frame))))
 438
 439 (defun set-default-font (font-name)
 440   "Set the font of the selected frame to FONT.
 441 When called interactively, prompt for the name of the font to use."
 442   (interactive "sFont name: ")
 443   (modify-frame-parameters (selected-frame)
 444                            (list (cons 'font font-name))))
 445
 446 (defun set-background-color (color-name)
 447   "Set the background color of the selected frame to COLOR.
 448 When called interactively, prompt for the name of the color to use."
 449   (interactive "sColor: ")
 450   (modify-frame-parameters (selected-frame)
 451                            (list (cons 'background-color color-name))))
 452
 453 (defun set-foreground-color (color-name)
 454   "Set the foreground color of the selected frame to COLOR.
 455 When called interactively, prompt for the name of the color to use."
 456   (interactive "sColor: ")
 457   (modify-frame-parameters (selected-frame)
 458                            (list (cons 'foreground-color color-name))))
 459
 460 (defun set-cursor-color (color-name)
 461   "Set the text cursor color of the selected frame to COLOR.
 462 When called interactively, prompt for the name of the color to use."
 463   (interactive "sColor: ")
 464   (modify-frame-parameters (selected-frame)
 465                            (list (cons 'cursor-color color-name))))
 466
 467 (defun set-mouse-color (color-name)
 468   "Set the color of the mouse pointer of the selected frame to COLOR.
 469 When called interactively, prompt for the name of the color to use."
 470   (interactive "sColor: ")
 471   (modify-frame-parameters (selected-frame)
 472                            (list (cons 'mouse-color color-name))))
 473
 474 (defun set-border-color (color-name)
 475   "Set the color of the border of the selected frame to COLOR.
 476 When called interactively, prompt for the name of the color to use."
 477   (interactive "sColor: ")
 478   (modify-frame-parameters (selected-frame)
 479                            (list (cons 'border-color color-name))))
 480
 481 (defun auto-raise-mode (arg)
 482   "Toggle whether or not the selected frame should auto-raise.
 483 With arg, turn auto-raise mode on if and only if arg is positive."
 484   (interactive "P")
 485   (if (null arg)
 486       (setq arg
 487             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
 488                 -1 1)))
 489   (modify-frame-parameters (selected-frame)
 490                            (list (cons 'auto-raise (> arg 0)))))
 491
 492 (defun auto-lower-mode (arg)
 493   "Toggle whether or not the selected frame should auto-lower.
 494 With arg, turn auto-lower mode on if and only if arg is positive."
 495   (interactive "P")
 496   (if (null arg)
 497       (setq arg
 498             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
 499                 -1 1)))
 500   (modify-frame-parameters (selected-frame)
 501                            (list (cons 'auto-lower (> arg 0)))))
 502
 503 (defun toggle-scroll-bar (arg)
 504   "Toggle whether or not the selected frame has vertical scroll bars.
 505 With arg, turn vertical scroll bars on if and only if arg is positive."
 506   (interactive "P")
 507   (if (null arg)
 508       (setq arg
 509             (if (cdr (assq 'vertical-scroll-bars
 510                            (frame-parameters (selected-frame))))
 511                 -1 1)))
 512   (modify-frame-parameters (selected-frame)
 513                            (list (cons 'vertical-scroll-bars (> arg 0)))))
 514
 515 (defun toggle-horizontal-scroll-bar (arg)
 516   "Toggle whether or not the selected frame has horizontal scroll bars.
 517 With arg, turn horizontal scroll bars on if and only if arg is positive.
 518 Horizontal scroll bars aren't implemented yet."
 519   (interactive "P")
 520   (error "Horizontal scroll bars aren't implemented yet"))
 521
 522 \f
 523 ;;;; Aliases for backward compatibility with Emacs 18.
 524 (defalias 'screen-height 'frame-height)
 525 (defalias 'screen-width 'frame-width)
 526
 527 (defun set-screen-width (cols &optional pretend)
 528   "Obsolete function to change the size of the screen to COLS columns.\n\
 529 Optional second arg non-nil means that redisplay should use COLS columns\n\
 530 but that the idea of the actual width of the frame should not be changed.\n\
 531 This function is provided only for compatibility with Emacs 18; new code\n\
 532 should use `set-frame-width instead'."
 533   (set-frame-width (selected-frame) cols pretend))
 534
 535 (defun set-screen-height (lines &optional pretend)
 536   "Obsolete function to change the height of the screen to LINES lines.\n\
 537 Optional second arg non-nil means that redisplay should use LINES lines\n\
 538 but that the idea of the actual height of the screen should not be changed.\n\
 539 This function is provided only for compatibility with Emacs 18; new code\n\
 540 should use `set-frame-width' instead."
 541   (set-frame-height (selected-frame) lines pretend))
 542
 543 (make-obsolete 'screen-height 'frame-height)
 544 (make-obsolete 'screen-width  'frame-width)
 545 (make-obsolete 'set-screen-width 'set-frame-width)
 546 (make-obsolete 'set-screen-height 'set-frame-height)
 547
 548 \f
 549 ;;;; Key bindings
 550 (defvar ctl-x-5-map (make-sparse-keymap)
 551   "Keymap for frame commands.")
 552 (defalias 'ctl-x-5-prefix ctl-x-5-map)
 553 (define-key ctl-x-map "5" 'ctl-x-5-prefix)
 554
 555 (define-key ctl-x-5-map "2" 'new-frame)
 556 (define-key ctl-x-5-map "0" 'delete-frame)
 557 (define-key ctl-x-5-map "o" 'other-frame)
 558
 559 (provide 'frame)
 560
 561 ;;; frame.el ends here