configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.61)
  25 AC_INIT(emacs, 23.0.60)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 137 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 138 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 139 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 140
 141 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 142 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 143 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 144 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 145
 146 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 147 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 148
 149 ## For the times when you want to build Emacs but don't have
 150 ## a suitable makeinfo, and can live without the manuals.
 151 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 152 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 153
 154 dnl Can remove these in Emacs 24.
 155 AC_ARG_WITH([gtk],,
 156   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 157 specify a toolkit.])],,)
 158
 159 AC_ARG_WITH([gcc],,
 160   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 161 variable to specify a compiler.])],,)
 162
 163 AC_ARG_WITH([pkg-config-prog],dnl
 164 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 165                   [path to pkg-config for finding GTK and librsvg])])
 166 if test "X${with_pkg_config_prog}" != X; then
 167    if test "${with_pkg_config_prog}" != yes; then
 168       PKG_CONFIG="${with_pkg_config_prog}"
 169    fi
 170 fi
 171
 172 AC_ARG_WITH([gnustep-conf],dnl
 173 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 174 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 175   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 176 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 177      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 178
 179 AC_ARG_ENABLE(cocoa-experimental-ctrl-g,
 180 [AS_HELP_STRING([--enable-cocoa-experimental-ctrl-g],
 181                 [enable experimental improved ctrl-g recognition])],
 182    EN_COCOA_EXPERIMENTAL_CTRL_G=$enableval,
 183    EN_COCOA_EXPERIMENTAL_CTRL_G=no)
 184
 185 AC_ARG_ENABLE(ns-self-contained,
 186 [AS_HELP_STRING([--disable-ns-self-contained],
 187                 [disable self contained build under NeXTstep])],
 188    EN_NS_SELF_CONTAINED=$enableval,
 189    EN_NS_SELF_CONTAINED=yes)
 190
 191 AC_ARG_ENABLE(asserts,
 192 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 193       USE_XASSERTS=$enableval,
 194       USE_XASSERTS=no)
 195
 196 AC_ARG_ENABLE(maintainer-mode,
 197 [AS_HELP_STRING([--enable-maintainer-mode],
 198                 [enable make rules and dependencies not useful (and sometimes
 199                  confusing) to the casual installer])],
 200       USE_MAINTAINER_MODE=$enableval,
 201       USE_MAINTAINER_MODE=no)
 202 if test $USE_MAINTAINER_MODE = yes; then
 203   MAINT=
 204 else
 205   MAINT=#
 206 fi
 207 AC_SUBST(MAINT)
 208
 209 AC_ARG_ENABLE(locallisppath,
 210 [AS_HELP_STRING([--enable-locallisppath=PATH],
 211                 [directories Emacs should search for lisp files specific
 212                  to this site])],
 213 if test "${enableval}" = "no"; then
 214   locallisppath=
 215 elif test "${enableval}" != "yes"; then
 216   locallisppath=${enableval}
 217 fi)
 218
 219 #### Make srcdir absolute, if it isn't already.  It's important to
 220 #### avoid running the path through pwd unnecessarily, since pwd can
 221 #### give you automounter prefixes, which can go away.  We do all this
 222 #### so Emacs can find its files when run uninstalled.
 223 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 224 unset CDPATH
 225 case "${srcdir}" in
 226   /* ) ;;
 227   . )
 228     ## We may be able to use the $PWD environment variable to make this
 229     ## absolute.  But sometimes PWD is inaccurate.
 230     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 231     ## but that tested only for a well-formed and valid PWD,
 232     ## it did not object when PWD was well-formed and valid but just wrong.
 233     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 234     then
 235       srcdir="$PWD"
 236     else
 237       srcdir="`(cd ${srcdir}; pwd)`"
 238     fi
 239   ;;
 240   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 241 esac
 242
 243 #### Check if the source directory already has a configured system in it.
 244 if test `pwd` != `(cd ${srcdir} && pwd)` \
 245    && test -f "${srcdir}/src/config.h" ; then
 246   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 247    as a build directory right now; it has been configured in its own
 248    right.  To configure in another directory as well, you MUST
 249    use GNU make.  If you do not have GNU make, then you must
 250    now do `make distclean' in ${srcdir},
 251    and then run $0 again.]])
 252 fi
 253
 254 #### Given the configuration name, set machfile and opsysfile to the
 255 #### names of the m/*.h and s/*.h files we should use.
 256
 257 ### Canonicalize the configuration name.
 258
 259 AC_CANONICAL_HOST
 260 canonical=$host
 261 configuration=${host_alias-${build_alias-$host}}
 262
 263 dnl This used to use changequote, but, apart from `changequote is evil'
 264 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 265 dnl the great gob of text.  Thus it's not processed for possible expansion.
 266 dnl Just make sure the brackets remain balanced.
 267 dnl
 268 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 269 dnl indicated by comments.
 270 dnl quotation begins
 271 [
 272
 273 ### If you add support for a new configuration, add code to this
 274 ### switch statement to recognize your configuration name and select
 275 ### the appropriate operating system and machine description files.
 276
 277 ### You would hope that you could choose an m/*.h file pretty much
 278 ### based on the machine portion of the configuration name, and an s-
 279 ### file based on the operating system portion.  However, it turns out
 280 ### that each m/*.h file is pretty manufacturer-specific - for
 281 ### example mips.h is MIPS
 282 ### So we basically have to have a special case for each
 283 ### configuration name.
 284 ###
 285 ### As far as handling version numbers on operating systems is
 286 ### concerned, make sure things will fail in a fixable way.  If
 287 ### /etc/MACHINES doesn't say anything about version numbers, be
 288 ### prepared to handle anything reasonably.  If version numbers
 289 ### matter, be sure /etc/MACHINES says something about it.
 290 ###
 291 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 292 ### "System V Release 4"; he writes, "The old convention encouraged
 293 ### confusion between `system' and `release' levels'."
 294
 295 machine='' opsys='' unported=no
 296 case "${canonical}" in
 297
 298   ## FreeBSD ports
 299   *-*-freebsd* )
 300     opsys=freebsd
 301     case "${canonical}" in
 302       alpha*-*-freebsd*)        machine=alpha ;;
 303       arm*-*-freebsd*)          machine=arm ;;
 304       ia64-*-freebsd*)          machine=ia64 ;;
 305       sparc-*-freebsd*)         machine=sparc ;;
 306       sparc64-*-freebsd*)       machine=sparc ;;
 307       powerpc-*-freebsd*)       machine=macppc ;;
 308       i[3456]86-*-freebsd*)     machine=intel386 ;;
 309       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 310     esac
 311   ;;
 312
 313   ## FreeBSD kernel + glibc based userland
 314   *-*-kfreebsd*gnu* )
 315     opsys=gnu-kfreebsd
 316     case "${canonical}" in
 317       alpha*-*-kfreebsd*)       machine=alpha ;;
 318       ia64-*-kfreebsd*)         machine=ia64 ;;
 319       sparc-*-kfreebsd*)        machine=sparc ;;
 320       sparc64-*-kfreebsd*)      machine=sparc ;;
 321       powerpc-*-kfreebsd*)      machine=macppc ;;
 322       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 323       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 324     esac
 325   ;;
 326
 327   ## NetBSD ports
 328   *-*-netbsd* )
 329     opsys=netbsd
 330     if test -f /usr/lib/crti.o; then]
 331 dnl The close and open brackets here are because this section is quoted --
 332 dnl see the `changequote' comment above.
 333       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 334 [   fi
 335
 336     case "${canonical}" in
 337       alpha*-*-netbsd*) machine=alpha ;;
 338       i[3456]86-*-netbsd*) machine=intel386 ;;
 339       powerpc-*-netbsd*) machine=macppc ;;
 340       sparc*-*-netbsd*) machine=sparc ;;
 341       vax-*-netbsd*)    machine=vax ;;
 342       arm-*-netbsd*)    machine=arm ;;
 343       x86_64-*-netbsd*) machine=amdx86-64 ;;
 344       hppa-*-netbsd*)   machine=hp800 ;;
 345     esac
 346   ;;
 347
 348   ## OpenBSD ports
 349   *-*-openbsd* )
 350     opsys=openbsd
 351     case "${canonical}" in
 352       alpha*-*-openbsd*)        machine=alpha ;;
 353       arm-*-openbsd*)          machine=arm ;;
 354       i386-*-openbsd*)         machine=intel386 ;;
 355       powerpc-*-openbsd*)      machine=macppc ;;
 356       sparc*-*-openbsd*)       machine=sparc ;;
 357       vax-*-openbsd*)          machine=vax ;;
 358       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 359     esac
 360   ;;
 361
 362   ## LynxOS ports
 363   *-*-lynxos* )
 364     opsys=lynxos
 365     case "${canonical}" in
 366       i[3456]86-*-lynxos*) machine=intel386 ;;
 367       powerpc-*-lynxos*) machine=powerpc ;;
 368     esac
 369   ;;
 370
 371   alpha*-*-linux-gnu* )
 372     machine=alpha opsys=gnu-linux
 373   ;;
 374
 375   arm*-*-linux-gnu* )
 376     machine=arm opsys=gnu-linux
 377   ;;
 378
 379   ## Apple Darwin / Mac OS X
 380   *-apple-darwin* )
 381     case "${canonical}" in
 382       i[3456]86-* )  machine=intel386 ;;
 383       powerpc-* )    machine=macppc ;;
 384       * )            unported=yes ;;
 385     esac
 386     opsys=darwin
 387     # Define CPP as follows to make autoconf work correctly.
 388     CPP="${CC-cc} -E -no-cpp-precomp"
 389     # Use fink packages if available.
 390     if test -d /sw/include && test -d /sw/lib; then
 391       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 392       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 393       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 394     fi
 395   ;;
 396
 397   ## HP 9000 series 700 and 800, running HP/UX
 398   hppa*-hp-hpux10.2* )
 399     machine=hp800 opsys=hpux10-20
 400   ;;
 401   hppa*-hp-hpux1[1-9]* )
 402     machine=hp800 opsys=hpux11
 403     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 404   ;;
 405
 406   hppa*-*-linux-gnu* )
 407     machine=hp800 opsys=gnu-linux
 408   ;;
 409
 410   ## IBM machines
 411   s390-*-linux-gnu* )
 412     machine=ibms390 opsys=gnu-linux
 413   ;;
 414   s390x-*-linux-gnu* )
 415     machine=ibms390x opsys=gnu-linux
 416   ;;
 417   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 418     machine=ibmrs6000 opsys=aix4-2
 419   ;;
 420   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 421     machine=ibmrs6000 opsys=aix4-2
 422   ;;
 423   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 424     machine=ibmrs6000 opsys=aix4-2
 425   ;;
 426   rs6000-ibm-aix5* | powerpc-ibm-aix6*  )
 427     machine=ibmrs6000 opsys=aix4-2
 428   ;;
 429
 430   ## Macintosh PowerPC
 431   powerpc*-*-linux-gnu* )
 432     machine=macppc opsys=gnu-linux
 433   ;;
 434
 435   ## Silicon Graphics machines
 436   ## Iris 4D
 437   mips-sgi-irix6.5 )
 438     machine=iris4d opsys=irix6-5
 439     # Without defining _LANGUAGE_C, things get masked out in the headers
 440     # so that, for instance, grepping for `free' in stdlib.h fails and
 441     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 442     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 443     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 444   ;;
 445
 446   ## Suns
 447   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 448     machine=sparc opsys=gnu-linux
 449   ;;
 450
 451   *-sun-solaris* \
 452     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 453     | rs6000-*-solaris2*)
 454     case "${canonical}" in
 455       i[3456]86-*-* )     machine=intel386 ;;
 456       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 457       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 458       sparc* )          machine=sparc ;;
 459       * )               unported=yes ;;
 460     esac
 461     case "${canonical}" in
 462       *-sunos5.3* | *-solaris2.3* )
 463                 opsys=sol2-3
 464                 NON_GNU_CPP=/usr/ccs/lib/cpp
 465                 ;;
 466       *-sunos5.4* | *-solaris2.4* )
 467                 opsys=sol2-4
 468                 NON_GNU_CPP=/usr/ccs/lib/cpp
 469                 RANLIB="ar -ts"
 470                 ;;
 471       *-sunos5.5* | *-solaris2.5* )
 472                 opsys=sol2-5
 473                 NON_GNU_CPP=/usr/ccs/lib/cpp
 474                 RANLIB="ar -ts"
 475                 ;;
 476       *-sunos5.6* | *-solaris2.6* )
 477                 opsys=sol2-6
 478                 NON_GNU_CPP=/usr/ccs/lib/cpp
 479                 RANLIB="ar -ts"
 480                 ;;
 481       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 482                 opsys=sol2-6
 483                 emacs_check_sunpro_c=yes
 484                 NON_GNU_CPP=/usr/ccs/lib/cpp
 485                 ;;
 486       *-sunos5* | *-solaris* )
 487                 opsys=sol2-10
 488                 emacs_check_sunpro_c=yes
 489                 NON_GNU_CPP=/usr/ccs/lib/cpp
 490                 ;;
 491     esac
 492     ## Watch out for a compiler that we know will not work.
 493     case "${canonical}" in
 494      *-solaris* | *-sunos5* )
 495                 if [ "x$CC" = x/usr/ucb/cc ]; then
 496                   ## /usr/ucb/cc doesn't work;
 497                   ## we should find some other compiler that does work.
 498                   unset CC
 499                 fi
 500                 ;;
 501       *) ;;
 502     esac
 503   ;;
 504
 505   ## Vaxen.
 506   vax-dec-* )
 507     machine=vax
 508     case "${canonical}" in
 509       *-vms* )                                          opsys=vms ;;
 510       * )                                               unported=yes
 511     esac
 512   ;;
 513
 514   ## IA-64
 515   ia64*-*-linux* )
 516     machine=ia64 opsys=gnu-linux
 517   ;;
 518
 519   ## Intel 386 machines where we don't care about the manufacturer
 520   i[3456]86-*-* )
 521     machine=intel386
 522     case "${canonical}" in
 523       *-cygwin )                opsys=cygwin ;;
 524       *-darwin* )               opsys=darwin
 525                                 CPP="${CC-cc} -E -no-cpp-precomp"
 526                                 ;;
 527       *-linux-gnu* )            opsys=gnu-linux ;;
 528       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 529       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 530       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 531       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 532     esac
 533   ;;
 534
 535   ## m68k Linux-based GNU system
 536   m68k-*-linux-gnu* )
 537     machine=m68k opsys=gnu-linux
 538   ;;
 539
 540   ## Mips Linux-based GNU system
 541   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 542     machine=mips opsys=gnu-linux
 543   ;;
 544
 545   ## AMD x86-64 Linux-based GNU system
 546   x86_64-*-linux-gnu* )
 547     machine=amdx86-64 opsys=gnu-linux
 548   ;;
 549
 550   ## Tensilica Xtensa Linux-based GNU system
 551   xtensa*-*-linux-gnu* )
 552     machine=xtensa opsys=gnu-linux
 553     ;;
 554
 555   ## SuperH Linux-based GNU system
 556   sh[34]*-*-linux-gnu* )
 557     machine=sh3 opsys=gnu-linux
 558   ;;
 559
 560   * )
 561     unported=yes
 562   ;;
 563 esac
 564
 565 ### If the code above didn't choose an operating system, just choose
 566 ### an operating system based on the configuration name.  You really
 567 ### only want to use this when you have no idea what the right
 568 ### operating system is; if you know what operating systems a machine
 569 ### runs, it's cleaner to make it explicit in the case statement
 570 ### above.
 571 if test x"${opsys}" = x; then
 572   case "${canonical}" in
 573     *-gnu* )                            opsys=gnu ;;
 574     *-sysv4.2uw* )                      opsys=unixware ;;
 575     *-sysv5uw* )                        opsys=unixware ;;
 576     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 577     *-sysv4.1* | *-sysvr4.1* )
 578         NON_GNU_CPP=/usr/lib/cpp
 579         opsys=usg5-4 ;;
 580     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 581         if [ x$NON_GNU_CPP = x ]; then
 582           if [ -f /usr/ccs/lib/cpp ]; then
 583             NON_GNU_CPP=/usr/ccs/lib/cpp
 584           else
 585             NON_GNU_CPP=/lib/cpp
 586           fi
 587         fi
 588         opsys=usg5-4-2 ;;
 589     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 590     * )
 591       unported=yes
 592     ;;
 593   esac
 594 fi
 595
 596 ]
 597 dnl quotation ends
 598
 599 if test $unported = yes; then
 600   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 601 Check `etc/MACHINES' for recognized configuration names.])
 602 fi
 603
 604 machfile="m/${machine}.h"
 605 opsysfile="s/${opsys}.h"
 606
 607
 608 #### Choose a compiler.
 609 test -n "$CC" && cc_specified=yes
 610
 611 # Save the value of CFLAGS that the user specified.
 612 SPECIFIED_CFLAGS="$CFLAGS"
 613
 614 dnl Sets GCC=yes if using gcc.
 615 AC_PROG_CC
 616
 617 # On Suns, sometimes $CPP names a directory.
 618 if test -n "$CPP" && test -d "$CPP"; then
 619   CPP=
 620 fi
 621
 622 ## If not using gcc, and on Solaris, and no CPP specified, see if
 623 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 624 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 625  test x"$CPP" = x; then
 626   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 627   AC_CACHE_VAL(emacs_cv_sunpro_c,
 628   [AC_TRY_LINK([],
 629 [#ifndef __SUNPRO_C
 630 fail;
 631 #endif
 632 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 633   AC_MSG_RESULT($emacs_cv_sunpro_c)
 634
 635   if test x"$emacs_cv_sunpro_c" = xyes; then
 636     NON_GNU_CPP="$CC -E -Xs"
 637   fi
 638 fi
 639
 640 #### Some systems specify a CPP to use unless we are using GCC.
 641 #### Now that we know whether we are using GCC, we can decide whether
 642 #### to use that one.
 643 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 644 then
 645   CPP="$NON_GNU_CPP"
 646 fi
 647
 648 #### Some systems specify a CC to use unless we are using GCC.
 649 #### Now that we know whether we are using GCC, we can decide whether
 650 #### to use that one.
 651 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 652   test x$cc_specified != xyes
 653 then
 654   CC="$NON_GNU_CC"
 655 fi
 656
 657 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 658 then
 659   CC="$CC $GCC_TEST_OPTIONS"
 660 fi
 661
 662 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 663 then
 664   CC="$CC $NON_GCC_TEST_OPTIONS"
 665 fi
 666
 667 dnl checks for Unix variants
 668 AC_USE_SYSTEM_EXTENSIONS
 669
 670 ### Use -Wno-pointer-sign if the compiler supports it
 671 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 672 SAVE_CFLAGS="$CFLAGS"
 673 CFLAGS="$CFLAGS -Wno-pointer-sign"
 674 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 675 if test $has_option = yes; then
 676    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 677 fi
 678 AC_MSG_RESULT($has_option)
 679 CFLAGS="$SAVE_CFLAGS"
 680 unset has_option
 681 unset SAVE_CFLAGS
 682
 683 #### Some other nice autoconf tests.
 684
 685 dnl checks for programs
 686 AC_PROG_LN_S
 687 AC_PROG_CPP
 688 AC_PROG_INSTALL
 689 if test "x$RANLIB" = x; then
 690   AC_PROG_RANLIB
 691 fi
 692 AC_PATH_PROG(INSTALL_INFO, install-info)
 693 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 694 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 695 dnl Don't use GZIP, which is used by gzip for additional parameters.
 696 AC_PATH_PROG(GZIP_PROG, gzip)
 697
 698
 699 ## Need makeinfo >= 4.6 (?) to build the manuals.
 700 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 701 dnl By this stage, configure has already checked for egrep and set EGREP,
 702 dnl or exited with an error if no egrep was found.
 703 if test "$MAKEINFO" != "no" && \
 704   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 705    MAKEINFO=no
 706 fi
 707
 708 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 709 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 710 ## therefore in the category of "special tools" not normally required, which
 711 ## configure does not have to check for (eg autoconf itself).
 712 ## In a CVS checkout on the other hand, the manuals are not included.
 713 ## So makeinfo is a requirement to build from CVS, and configure
 714 ## should test for it as it does for any other build requirement.
 715 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 716 ## with pre-built manuals, from a CVS checkout.
 717 if test "$MAKEINFO" = "no"; then
 718   if test "x${with_makeinfo}" = "xno"; then
 719     MAKEINFO=off
 720   elif ! test -e $srcdir/info/emacs; then
 721     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 722 source tree does not seem to have pre-built manuals in the `info' directory.
 723 Either install a suitable version of makeinfo, or re-run configure
 724 with the `--without-makeinfo' option to build without the manuals.] )
 725   fi
 726 fi
 727
 728 dnl Add our options to ac_link now, after it is set up.
 729
 730 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 731 then
 732   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 733 fi
 734
 735 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 736 then
 737   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 738 fi
 739
 740 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 741 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 742 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 743 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 744 dnl if not built to support GNU ld.
 745
 746 late_LDFLAGS=$LDFLAGS
 747 if test "$GCC" = yes; then
 748   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 749 else
 750   LDFLAGS="$LDFLAGS -znocombreloc"
 751 fi
 752
 753 AC_MSG_CHECKING([for -znocombreloc])
 754 AC_LINK_IFELSE([main(){return 0;}],
 755   [AC_MSG_RESULT(yes)],
 756   LDFLAGS=$late_LDFLAGS
 757   [AC_MSG_RESULT(no)])
 758
 759 #### Extract some information from the operating system and machine files.
 760
 761 AC_CHECKING([the machine- and system-dependent files to find out
 762  - which libraries the lib-src programs will want, and
 763  - whether the GNU malloc routines are usable])
 764
 765 ### First figure out CFLAGS (which we use for running the compiler here)
 766 ### and REAL_CFLAGS (which we use for real compilation).
 767 ### The two are the same except on a few systems, where they are made
 768 ### different to work around various lossages.  For example,
 769 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 770 ### as implying static linking.
 771
 772 ### If the CFLAGS env var is specified, we use that value
 773 ### instead of the default.
 774
 775 ### It's not important that this name contain the PID; you can't run
 776 ### two configures in the same directory and have anything work
 777 ### anyway.
 778 tempcname="conftest.c"
 779
 780 echo '
 781 #include "'${srcdir}'/src/'${opsysfile}'"
 782 #include "'${srcdir}'/src/'${machfile}'"
 783 #ifndef LIBS_MACHINE
 784 #define LIBS_MACHINE
 785 #endif
 786 #ifndef LIBS_SYSTEM
 787 #define LIBS_SYSTEM
 788 #endif
 789 #ifndef C_SWITCH_SYSTEM
 790 #define C_SWITCH_SYSTEM
 791 #endif
 792 #ifndef C_SWITCH_MACHINE
 793 #define C_SWITCH_MACHINE
 794 #endif
 795 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 796 configure___ c_switch_system=C_SWITCH_SYSTEM
 797 configure___ c_switch_machine=C_SWITCH_MACHINE
 798
 799 #ifndef LIB_X11_LIB
 800 #define LIB_X11_LIB -lX11
 801 #endif
 802
 803 #ifndef LIBX11_SYSTEM
 804 #define LIBX11_SYSTEM
 805 #endif
 806 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 807
 808 #ifdef UNEXEC
 809 configure___ unexec=UNEXEC
 810 #else
 811 configure___ unexec=unexec.o
 812 #endif
 813
 814 #ifdef SYSTEM_MALLOC
 815 configure___ system_malloc=yes
 816 #else
 817 configure___ system_malloc=no
 818 #endif
 819
 820 #ifdef USE_MMAP_FOR_BUFFERS
 821 configure___ use_mmap_for_buffers=yes
 822 #else
 823 configure___ use_mmap_for_buffers=no
 824 #endif
 825
 826 #ifndef C_DEBUG_SWITCH
 827 #define C_DEBUG_SWITCH -g
 828 #endif
 829
 830 #ifndef C_OPTIMIZE_SWITCH
 831 #ifdef __GNUC__
 832 #define C_OPTIMIZE_SWITCH -O2
 833 #else
 834 #define C_OPTIMIZE_SWITCH -O
 835 #endif
 836 #endif
 837
 838 #ifndef C_WARNINGS_SWITCH
 839 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 840 #endif
 841
 842 #ifndef LD_SWITCH_MACHINE
 843 #define LD_SWITCH_MACHINE
 844 #endif
 845
 846 #ifndef LD_SWITCH_SYSTEM
 847 #define LD_SWITCH_SYSTEM
 848 #endif
 849
 850 #ifndef LD_SWITCH_X_SITE_AUX
 851 #define LD_SWITCH_X_SITE_AUX
 852 #endif
 853
 854 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 855 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 856
 857 #ifdef THIS_IS_CONFIGURE
 858
 859 /* Get the CFLAGS for tests in configure.  */
 860 #ifdef __GNUC__
 861 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 862 #else
 863 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 864 #endif
 865
 866 #else /* not THIS_IS_CONFIGURE */
 867
 868 /* Get the CFLAGS for real compilation.  */
 869 #ifdef __GNUC__
 870 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
 871 #else
 872 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 873 #endif
 874
 875 #endif /* not THIS_IS_CONFIGURE */
 876 ' > ${tempcname}
 877
 878 # The value of CPP is a quoted variable reference, so we need to do this
 879 # to get its actual value...
 880 CPP=`eval "echo $CPP"`
 881 [eval `${CPP} -Isrc ${tempcname} \
 882        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 883 if test "x$SPECIFIED_CFLAGS" = x; then
 884   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 885          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 886 else
 887   REAL_CFLAGS="$CFLAGS"
 888 fi]
 889 rm ${tempcname}
 890
 891 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 892
 893 ### Make sure subsequent tests use flags consistent with the build flags.
 894
 895 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 896   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 897 else
 898   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 899 fi
 900
 901 dnl For AC_FUNC_GETLOADAVG, at least:
 902 AC_CONFIG_LIBOBJ_DIR(src)
 903
 904 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 905 AC_SYS_LARGEFILE
 906
 907
 908 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 909 ### be located in either /usr/lib64 or /usr/lib.
 910 ### In some rare cases, /usr/lib64 exists but does not contain the
 911 ### relevant files (bug#1287).  Hence test for crtn.o.
 912 case "${canonical}" in
 913   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 914     if test -e /usr/lib64/crtn.o; then
 915       AC_DEFINE(HAVE_LIB64_DIR, 1,
 916         [Define to 1 if the directory /usr/lib64 exists.])
 917 fi
 918 esac
 919
 920 dnl This function defintion taken from Gnome 2.0
 921 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 922 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 923 dnl also defines GSTUFF_PKG_ERRORS on error
 924 AC_DEFUN([PKG_CHECK_MODULES], [
 925   succeeded=no
 926
 927   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 928
 929   if test "$PKG_CONFIG" = "no" ; then
 930      ifelse([$4], , [AC_MSG_ERROR([
 931       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
 932   else
 933      PKG_CONFIG_MIN_VERSION=0.9.0
 934      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 935         AC_MSG_CHECKING(for $2)
 936
 937         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
 938             AC_MSG_RESULT(yes)
 939             succeeded=yes
 940
 941             AC_MSG_CHECKING($1_CFLAGS)
 942             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
 943             AC_MSG_RESULT($$1_CFLAGS)
 944
 945             AC_MSG_CHECKING($1_LIBS)
 946             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
 947             AC_MSG_RESULT($$1_LIBS)
 948         else
 949             AC_MSG_RESULT(no)
 950             $1_CFLAGS=""
 951             $1_LIBS=""
 952             ## If we have a custom action on failure, don't print errors, but
 953             ## do set a variable so people can do so.
 954             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
 955             ifelse([$4], ,echo $$1_PKG_ERRORS,)
 956         fi
 957
 958         AC_SUBST($1_CFLAGS)
 959         AC_SUBST($1_LIBS)
 960      else
 961         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
 962         echo "*** See http://www.freedesktop.org/software/pkgconfig"
 963      fi
 964   fi
 965
 966   if test $succeeded = yes; then
 967      ifelse([$3], , :, [$3])
 968   else
 969      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
 970   fi
 971 ])
 972
 973
 974 if test "${with_sound}" != "no"; then
 975   # Sound support for GNU/Linux and the free BSDs.
 976   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
 977   # Emulation library used on NetBSD.
 978   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
 979   AC_SUBST(LIBSOUND)
 980
 981   ALSA_REQUIRED=1.0.0
 982   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
 983   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
 984   if test $HAVE_ALSA = yes; then
 985     SAVE_CFLAGS="$CFLAGS"
 986     SAVE_LDFLAGS="$LDFLAGS"
 987     CFLAGS="$ALSA_CFLAGS $CFLAGS"
 988     LDFLAGS="$ALSA_LIBS $LDFLAGS"
 989     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
 990                     emacs_alsa_normal=yes,
 991                     emacs_alsa_normal=no)
 992     if test "$emacs_alsa_normal" != yes; then
 993       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
 994                      [snd_lib_error_set_handler (0);],
 995                      emacs_alsa_subdir=yes,
 996                      emacs_alsa_subdir=no)
 997       if test "$emacs_alsa_subdir" != yes; then
 998         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
 999       fi
1000       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1001     fi
1002
1003     CFLAGS="$SAVE_CFLAGS"
1004     LDFLAGS="$SAVE_LDFLAGS"
1005     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1006     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1007     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1008   fi
1009   AC_SUBST(CFLAGS_SOUND)
1010 fi
1011
1012 dnl checks for header files
1013 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1014   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1015   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1016   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1017   sys/utsname.h pwd.h)
1018
1019 AC_MSG_CHECKING(if personality LINUX32 can be set)
1020 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1021                emacs_cv_personality_linux32=yes,
1022                emacs_cv_personality_linux32=no)
1023 AC_MSG_RESULT($emacs_cv_personality_linux32)
1024
1025 if test $emacs_cv_personality_linux32 = yes; then
1026   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1027             [Define to 1 if personality LINUX32 can be set.])
1028 fi
1029
1030 dnl On Solaris 8 there's a compilation warning for term.h because
1031 dnl it doesn't define `bool'.
1032 AC_CHECK_HEADERS(term.h, , , -)
1033 AC_HEADER_STDC
1034 AC_HEADER_TIME
1035 AC_CHECK_DECLS([sys_siglist])
1036 if test $ac_cv_have_decl_sys_siglist != yes; then
1037   # For Tru64, at least:
1038   AC_CHECK_DECLS([__sys_siglist])
1039   if test $ac_cv_have_decl___sys_siglist = yes; then
1040     AC_DEFINE(sys_siglist, __sys_siglist,
1041               [Define to any substitute for sys_siglist.])
1042   fi
1043 fi
1044 AC_HEADER_SYS_WAIT
1045
1046 dnl Some systems have utime.h but don't declare the struct anyplace.
1047 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1048 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1049 #include <sys/time.h>
1050 #include <time.h>
1051 #else
1052 #ifdef HAVE_SYS_TIME_H
1053 #include <sys/time.h>
1054 #else
1055 #include <time.h>
1056 #endif
1057 #endif
1058 #ifdef HAVE_UTIME_H
1059 #include <utime.h>
1060 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1061   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1062 if test $emacs_cv_struct_utimbuf = yes; then
1063   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1064 fi
1065
1066 dnl checks for typedefs
1067 AC_TYPE_SIGNAL
1068
1069 dnl Check for speed_t typedef.
1070 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1071   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1072     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1073 if test $emacs_cv_speed_t = yes; then
1074   AC_DEFINE(HAVE_SPEED_T, 1,
1075            [Define to 1 if `speed_t' is declared by <termios.h>.])
1076 fi
1077
1078 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1079 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1080 #include <sys/time.h>
1081 #include <time.h>
1082 #else
1083 #ifdef HAVE_SYS_TIME_H
1084 #include <sys/time.h>
1085 #else
1086 #include <time.h>
1087 #endif
1088 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1089   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1090 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1091 if test $emacs_cv_struct_timeval = yes; then
1092   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1093 fi
1094
1095 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1096 AC_TRY_COMPILE([#include <math.h>],
1097 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1098   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1099 HAVE_EXCEPTION=$emacs_cv_struct_exception
1100 if test $emacs_cv_struct_exception != yes; then
1101   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1102 fi
1103
1104 AC_CHECK_HEADERS(sys/socket.h)
1105 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1106 #if HAVE_SYS_SOCKET_H
1107 #include <sys/socket.h>
1108 #endif])
1109
1110 dnl checks for structure members
1111 AC_STRUCT_TM
1112 AC_STRUCT_TIMEZONE
1113 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1114                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1115                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1116                 [#include <time.h>])
1117 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1118                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1119                   struct ifreq.ifr_addr], , ,
1120                  [AC_INCLUDES_DEFAULT
1121 #if HAVE_SYS_SOCKET_H
1122 #include <sys/socket.h>
1123 #endif
1124 #if HAVE_NET_IF_H
1125 #include <net/if.h>
1126 #endif])
1127
1128 dnl checks for compiler characteristics
1129
1130 dnl Testing __STDC__ to determine prototype support isn't good enough.
1131 dnl DEC C, for instance, doesn't define it with default options, and
1132 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1133 dnl and void *.
1134 AC_C_PROTOTYPES
1135 AC_C_VOLATILE
1136 AC_C_CONST
1137 dnl This isn't useful because we can't turn on use of `inline' unless
1138 dnl the compiler groks `extern inline'.
1139 dnl AC_C_INLINE
1140 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1141   [AC_TRY_COMPILE(, [void * foo;],
1142                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1143 if test $emacs_cv_void_star = yes; then
1144   AC_DEFINE(POINTER_TYPE, void)
1145 else
1146   AC_DEFINE(POINTER_TYPE, char)
1147 fi
1148 AH_TEMPLATE(POINTER_TYPE,
1149             [Define as `void' if your compiler accepts `void *'; otherwise
1150              define as `char'.])dnl
1151
1152
1153
1154 dnl This could be used for targets which can have both byte sexes.
1155 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1156 dnl AC_C_BIGENDIAN
1157
1158 dnl check for Make feature
1159 AC_PROG_MAKE_SET
1160
1161 dnl checks for operating system services
1162 AC_SYS_LONG_FILE_NAMES
1163
1164 #### Choose a window system.
1165
1166 AC_PATH_X
1167 if test "$no_x" = yes; then
1168   window_system=none
1169 else
1170   window_system=x11
1171 fi
1172
1173 ## Workaround for bug in autoconf <= 2.62.
1174 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1175 ## No need to do anything special for these standard directories.
1176 ## This is an experiment, take it out if it causes problems.
1177 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1178
1179    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1180
1181 fi
1182
1183 if test "${x_libraries}" != NONE; then
1184   if test -n "${x_libraries}"; then
1185     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1186     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1187   fi
1188   x_default_search_path=""
1189   x_search_path=${x_libraries}
1190   if test -z "${x_search_path}"; then
1191     x_search_path=/usr/lib
1192   fi
1193   for x_library in `echo ${x_search_path}: | \
1194                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1195     x_search_path="\
1196 ${x_library}/X11/%L/%T/%N%C%S:\
1197 ${x_library}/X11/%l/%T/%N%C%S:\
1198 ${x_library}/X11/%T/%N%C%S:\
1199 ${x_library}/X11/%L/%T/%N%S:\
1200 ${x_library}/X11/%l/%T/%N%S:\
1201 ${x_library}/X11/%T/%N%S"
1202     if test x"${x_default_search_path}" = x; then
1203       x_default_search_path=${x_search_path}
1204     else
1205       x_default_search_path="${x_search_path}:${x_default_search_path}"
1206     fi
1207   done
1208 fi
1209 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1210   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1211 fi
1212
1213 if test x"${x_includes}" = x; then
1214   bitmapdir=/usr/include/X11/bitmaps
1215 else
1216   # accumulate include directories that have X11 bitmap subdirectories
1217   bmd_acc="dummyval"
1218   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1219     if test -d "${bmd}/X11/bitmaps"; then
1220       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1221     fi
1222     if test -d "${bmd}/bitmaps"; then
1223       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1224     fi
1225   done
1226   if test ${bmd_acc} != "dummyval"; then
1227     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1228   fi
1229 fi
1230
1231 HAVE_NS=no
1232 NS_IMPL_COCOA=no
1233 NS_IMPL_GNUSTEP=no
1234 tmp_CPPFLAGS="$CPPFLAGS"
1235 tmp_CFLAGS="$CFLAGS"
1236 CPPFLAGS="$CPPFLAGS -x objective-c"
1237 CFLAGS="$CFLAGS -x objective-c"
1238 if test "${with_ns}" != no; then
1239   if test "${opsys}" = darwin; then
1240      NS_IMPL_COCOA=yes
1241      ns_appdir=`pwd`/nextstep/Emacs.app
1242      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1243      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1244      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1245   elif test -f $GNUSTEP_CONFIG_FILE; then
1246      NS_IMPL_GNUSTEP=yes
1247      ns_appdir=`pwd`/nextstep/Emacs.app
1248      ns_appbindir=`pwd`/nextstep/Emacs.app
1249      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1250      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1251      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1252      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1253      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1254      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1255      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1256      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1257      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1258      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1259   fi
1260   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1261                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1262   files are missing or cannot be compiled.])])
1263   NS_HAVE_NSINTEGER=yes
1264   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1265                                      [NSInteger i;])],
1266                     ns_have_nsinteger=yes,
1267                     ns_have_nsinteger=no)
1268   if test $ns_have_nsinteger = no; then
1269     NS_HAVE_NSINTEGER=no
1270   fi
1271 fi
1272 if test "${HAVE_NS}" = yes; then
1273   window_system=nextstep
1274   with_xft=no
1275   with_freetype=no
1276   # set up packaging dirs
1277   exec_prefix=${ns_appbindir}
1278   libexecdir=${ns_appbindir}/libexec
1279   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1280      prefix=${ns_appresdir}
1281   fi
1282 fi
1283 CFLAGS="$tmp_CFLAGS"
1284 CPPFLAGS="$tmp_CPPFLAGS"
1285
1286 case "${window_system}" in
1287   x11 )
1288     HAVE_X_WINDOWS=yes
1289     HAVE_X11=yes
1290     case "${with_x_toolkit}" in
1291       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1292       motif ) USE_X_TOOLKIT=MOTIF ;;
1293       gtk ) with_gtk=yes
1294 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1295 dnl USE_X_TOOLKIT is set.
1296             USE_X_TOOLKIT=none ;;
1297       no ) USE_X_TOOLKIT=none ;;
1298 dnl If user did not say whether to use a toolkit, make this decision later:
1299 dnl use the toolkit if we have gtk, or X11R5 or newer.
1300       * ) USE_X_TOOLKIT=maybe ;;
1301     esac
1302   ;;
1303   nextstep | none )
1304     HAVE_X_WINDOWS=no
1305     HAVE_X11=no
1306     USE_X_TOOLKIT=none
1307   ;;
1308 esac
1309
1310 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1311    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1312    if test "$HAVE_XSERVER" = true ||
1313       test -n "$DISPLAY" ||
1314       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1315         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1316 were found.  You should install the relevant development files for X
1317 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1318 sure you have development files for image handling, i.e.
1319 tiff, gif, jpeg, png and xpm.
1320 If you are sure you want Emacs compiled without X window support, pass
1321   --without-x
1322 to configure.])
1323    fi
1324 fi
1325
1326 ### If we're using X11, we should use the X menu package.
1327 HAVE_MENUS=no
1328 case ${HAVE_X11} in
1329   yes ) HAVE_MENUS=yes ;;
1330 esac
1331
1332 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1333 # Assume not, until told otherwise.
1334 GNU_MALLOC=yes
1335 doug_lea_malloc=yes
1336 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1337 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1338 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1339                emacs_cv_var___after_morecore_hook,
1340 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1341   emacs_cv_var___after_morecore_hook=yes,
1342   emacs_cv_var___after_morecore_hook=no)])
1343 if test $emacs_cv_var___after_morecore_hook = no; then
1344   doug_lea_malloc=no
1345 fi
1346 if test "${system_malloc}" = "yes"; then
1347   GNU_MALLOC=no
1348   GNU_MALLOC_reason="
1349     (The GNU allocators don't work with this system configuration.)"
1350 fi
1351 if test "$doug_lea_malloc" = "yes" ; then
1352   if test "$GNU_MALLOC" = yes ; then
1353     GNU_MALLOC_reason="
1354       (Using Doug Lea's new malloc from the GNU C Library.)"
1355   fi
1356   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1357             [Define to 1 if you are using the GNU C Library.])
1358 fi
1359
1360 if test x"${REL_ALLOC}" = x; then
1361   REL_ALLOC=${GNU_MALLOC}
1362 fi
1363
1364 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1365 dnl the system configuration file (s/*.h) to turn the use of mmap
1366 dnl in the relocating allocator on.
1367
1368 AC_FUNC_MMAP
1369 if test $use_mmap_for_buffers = yes; then
1370   REL_ALLOC=no
1371 fi
1372
1373 LIBS="$libsrc_libs $LIBS"
1374
1375 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1376 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1377 AC_CHECK_LIB(dnet, dnet_ntoa)
1378 dnl This causes -lresolv to get used in subsequent tests,
1379 dnl which causes failures on some systems such as HPUX 9.
1380 dnl AC_CHECK_LIB(resolv, gethostbyname)
1381
1382 dnl FIXME replace main with a function we actually want from this library.
1383 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1384
1385 AC_CHECK_LIB(pthreads, cma_open)
1386
1387 dnl Check for need for bigtoc support on IBM AIX
1388
1389 case ${host_os} in
1390 aix*)
1391   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1392     case $GCC in
1393     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1394     *) gdb_cv_bigtoc=-bbigtoc ;;
1395     esac
1396
1397     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1398     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1399   ])
1400   ;;
1401 esac
1402
1403 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1404 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1405 # REAL_CPPFLAGS later on.
1406
1407 REAL_CPPFLAGS="$CPPFLAGS"
1408
1409 if test "${HAVE_X11}" = "yes"; then
1410   DEFS="$C_SWITCH_X_SITE $DEFS"
1411   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1412   LIBS="$LIBX $LIBS"
1413   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1414   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1415
1416   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1417   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1418   # but it's more convenient here to set LD_RUN_PATH
1419   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1420   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1421     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1422     export LD_RUN_PATH
1423   fi
1424
1425   if test "${opsys}" = "gnu-linux"; then
1426     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1427     AC_TRY_LINK([],
1428      [XOpenDisplay ("foo");],
1429      [xlinux_first_failure=no],
1430      [xlinux_first_failure=yes])
1431     if test "${xlinux_first_failure}" = "yes"; then
1432       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1433       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1434       OLD_CPPFLAGS="$CPPFLAGS"
1435       OLD_LIBS="$LIBS"
1436       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1437       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1438       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1439       LIBS="$LIBS -b i486-linuxaout"
1440       AC_TRY_LINK([],
1441        [XOpenDisplay ("foo");],
1442        [xlinux_second_failure=no],
1443        [xlinux_second_failure=yes])
1444       if test "${xlinux_second_failure}" = "yes"; then
1445         # If we get the same failure with -b, there is no use adding -b.
1446         # So take it out.  This plays safe.
1447         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1448         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1449         CPPFLAGS="$OLD_CPPFLAGS"
1450         LIBS="$OLD_LIBS"
1451         AC_MSG_RESULT(no)
1452       else
1453         AC_MSG_RESULT(yes)
1454       fi
1455     else
1456       AC_MSG_RESULT(no)
1457     fi
1458   fi
1459
1460   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1461   # header files included from there.
1462   AC_MSG_CHECKING(for Xkb)
1463   AC_TRY_LINK([#include <X11/Xlib.h>
1464 #include <X11/XKBlib.h>],
1465         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1466         emacs_xkb=yes, emacs_xkb=no)
1467   AC_MSG_RESULT($emacs_xkb)
1468   if test $emacs_xkb = yes; then
1469     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1470   fi
1471
1472   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1473 XScreenNumberOfScreen XSetWMProtocols)
1474 fi
1475
1476 if test "${window_system}" = "x11"; then
1477   AC_MSG_CHECKING(X11 version 6)
1478   AC_CACHE_VAL(emacs_cv_x11_version_6,
1479   [AC_TRY_LINK([#include <X11/Xlib.h>],
1480 [#if XlibSpecificationRelease < 6
1481 fail;
1482 #endif
1483 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1484   if test $emacs_cv_x11_version_6 = yes; then
1485     AC_MSG_RESULT(6 or newer)
1486     AC_DEFINE(HAVE_X11R6, 1,
1487               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1488   else
1489     AC_MSG_RESULT(before 6)
1490   fi
1491 fi
1492
1493
1494 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1495 HAVE_RSVG=no
1496 if test "${HAVE_X11}" = "yes"; then
1497   if test "${with_rsvg}" != "no"; then
1498     RSVG_REQUIRED=2.0.0
1499     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1500
1501     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1502     AC_SUBST(RSVG_CFLAGS)
1503     AC_SUBST(RSVG_LIBS)
1504
1505     if test ".${RSVG_CFLAGS}" != "."; then
1506       HAVE_RSVG=yes
1507       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1508       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1509       LIBS="$RSVG_LIBS $LIBS"
1510     fi
1511   fi
1512 fi
1513
1514
1515 HAVE_GTK=no
1516 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1517   GLIB_REQUIRED=2.6
1518   GTK_REQUIRED=2.6
1519   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1520
1521   dnl Checks for libraries.
1522   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1523   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1524      AC_MSG_ERROR($GTK_PKG_ERRORS)
1525   fi
1526 fi
1527
1528
1529 if test x"$pkg_check_gtk" = xyes; then
1530
1531   AC_SUBST(GTK_CFLAGS)
1532   AC_SUBST(GTK_LIBS)
1533   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1534   CFLAGS="$CFLAGS $GTK_CFLAGS"
1535   LIBS="$GTK_LIBS $LIBS"
1536   dnl Try to compile a simple GTK program.
1537   GTK_COMPILES=no
1538   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1539   if test "${GTK_COMPILES}" != "yes"; then
1540     if test "$USE_X_TOOLKIT" != "maybe"; then
1541       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1542     fi
1543   else
1544     HAVE_GTK=yes
1545     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1546     USE_X_TOOLKIT=none
1547     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1548       :
1549     else
1550       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1551        closing open displays.  This is no problem if you just use
1552        one display, but if you use more than one and close one of them
1553        Emacs may crash.]])
1554       sleep 3
1555     fi
1556   fi
1557
1558 fi
1559
1560
1561 if test "${HAVE_GTK}" = "yes"; then
1562
1563   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1564   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1565   if test "$with_toolkit_scroll_bars" != no; then
1566     with_toolkit_scroll_bars=yes
1567   fi
1568
1569   dnl  Check if we can use multiple displays with this GTK version.
1570   dnl  If gdk_display_open exists, assume all others are there also.
1571   HAVE_GTK_MULTIDISPLAY=no
1572   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1573   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1574     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1575               [Define to 1 if GTK can handle more than one display.])
1576   fi
1577
1578   dnl  Check if we have the old file selection dialog.
1579   dnl  If gdk_display_open exists, assume all others are there also.
1580   HAVE_GTK_FILE_SELECTION=no
1581   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1582
1583   dnl  Check if we have the new file chooser dialog
1584   dnl  If gdk_display_open exists, assume all others are there also.
1585   HAVE_GTK_FILE_CHOOSER=no
1586   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1587
1588   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1589      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1590     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1591               [Define to 1 if GTK has both file selection and chooser dialog.])
1592   fi
1593
1594   dnl Check if pthreads are available.  Emacs only needs this when using
1595   dnl gtk_file_chooser under Gnome.
1596   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1597     HAVE_GTK_AND_PTHREAD=no
1598     AC_CHECK_HEADERS(pthread.h)
1599     if test "$ac_cv_header_pthread_h"; then
1600       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1601     fi
1602     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1603       case "${canonical}" in
1604         *-hpux*) ;;
1605         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1606       esac
1607       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1608                [Define to 1 if you have GTK and pthread (-lpthread).])
1609     fi
1610   fi
1611 fi
1612
1613 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1614 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1615 dnl also not configured.
1616 HAVE_DBUS=no
1617 if test "${with_dbus}" = "yes"; then
1618    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1619    if test "$HAVE_DBUS" = yes; then
1620       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1621    fi
1622 fi
1623
1624 dnl Do not put whitespace before the #include statements below.
1625 dnl Older compilers (eg sunos4 cc) choke on it.
1626 HAVE_XAW3D=no
1627 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1628   if test "$with_xaw3d" != no; then
1629     AC_MSG_CHECKING(for xaw3d)
1630     AC_CACHE_VAL(emacs_cv_xaw3d,
1631     [AC_TRY_LINK([
1632 #include <X11/Intrinsic.h>
1633 #include <X11/Xaw3d/Simple.h>],
1634       [],
1635       emacs_cv_xaw3d=yes,
1636       emacs_cv_xaw3d=no)])
1637   else
1638     emacs_cv_xaw3d=no
1639   fi
1640   if test $emacs_cv_xaw3d = yes; then
1641     AC_MSG_RESULT([yes; using Lucid toolkit])
1642     USE_X_TOOLKIT=LUCID
1643     HAVE_XAW3D=yes
1644     AC_DEFINE(HAVE_XAW3D, 1,
1645               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1646   else
1647     AC_MSG_RESULT(no)
1648     AC_MSG_CHECKING(for libXaw)
1649     AC_CACHE_VAL(emacs_cv_xaw,
1650     [AC_TRY_LINK([
1651 #include <X11/Intrinsic.h>
1652 #include <X11/Xaw/Simple.h>],
1653       [],
1654       emacs_cv_xaw=yes,
1655       emacs_cv_xaw=no)])
1656     if test $emacs_cv_xaw = yes; then
1657       AC_MSG_RESULT([yes; using Lucid toolkit])
1658       USE_X_TOOLKIT=LUCID
1659     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1660       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1661     else
1662       AC_MSG_RESULT([no; do not use toolkit by default])
1663       USE_X_TOOLKIT=none
1664     fi
1665   fi
1666 fi
1667
1668 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1669
1670 if test "${USE_X_TOOLKIT}" != "none"; then
1671   AC_MSG_CHECKING(X11 toolkit version)
1672   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1673   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1674 [#if XtSpecificationRelease < 6
1675 fail;
1676 #endif
1677 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1678   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1679   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1680     AC_MSG_RESULT(6 or newer)
1681     AC_DEFINE(HAVE_X11XTR6, 1,
1682               [Define to 1 if you have the X11R6 or newer version of Xt.])
1683   else
1684     AC_MSG_RESULT(before 6)
1685   fi
1686
1687 dnl If using toolkit, check whether libXmu.a exists.
1688 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1689   OLDLIBS="$LIBS"
1690   if test x$HAVE_X11XTR6 = xyes; then
1691     LIBS="-lXt -lSM -lICE $LIBS"
1692   else
1693     LIBS="-lXt $LIBS"
1694   fi
1695   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1696   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1697 fi
1698
1699 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1700 if test "${HAVE_X11}" = "yes"; then
1701   if test "${USE_X_TOOLKIT}" != "none"; then
1702     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1703   fi
1704 fi
1705
1706 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1707   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1708   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1709     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1710 int x = 5;
1711 #else
1712 Motif version prior to 2.1.
1713 #endif],
1714     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1715   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1716   if test $emacs_cv_motif_version_2_1 = yes; then
1717     HAVE_LIBXP=no
1718     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1719               [Define to 1 if you have Motif 2.1 or newer.])
1720     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1721     if test ${HAVE_LIBXP} = yes; then
1722       AC_DEFINE(HAVE_LIBXP, 1,
1723                 [Define to 1 if you have the Xp library (-lXp).])
1724     fi
1725   else
1726     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1727     # We put this in CFLAGS temporarily to precede other -I options
1728     # that might be in CFLAGS temporarily.
1729     # We put this in CPPFLAGS where it precedes the other -I options.
1730     OLD_CPPFLAGS=$CPPFLAGS
1731     OLD_CFLAGS=$CFLAGS
1732     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1733     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1734     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1735       [int x = 5;],
1736       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1737     if test $emacs_cv_lesstif = yes; then
1738       # Make sure this -I option remains in CPPFLAGS after it is set
1739       # back to REAL_CPPFLAGS.
1740       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1741       # have those other -I options anyway.  Ultimately, having this
1742       # directory ultimately in CPPFLAGS will be enough.
1743       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1744       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1745     else
1746       CFLAGS=$OLD_CFLAGS
1747       CPPFLAGS=$OLD_CPPFLAGS
1748     fi
1749   fi
1750 fi
1751
1752 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1753 dnl using Motif or Xaw3d is available, and unless
1754 dnl --with-toolkit-scroll-bars=no was specified.
1755
1756 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1757             [Define to 1 if we should use toolkit scroll bars.])dnl
1758 USE_TOOLKIT_SCROLL_BARS=no
1759 if test "${with_toolkit_scroll_bars}" != "no"; then
1760   if test "${USE_X_TOOLKIT}" != "none"; then
1761     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1762       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1763       HAVE_XAW3D=no
1764       USE_TOOLKIT_SCROLL_BARS=yes
1765     elif test "${HAVE_XAW3D}" = "yes"; then
1766       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1767       USE_TOOLKIT_SCROLL_BARS=yes
1768     fi
1769   elif test "${HAVE_GTK}" = "yes"; then
1770     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1771     USE_TOOLKIT_SCROLL_BARS=yes
1772   elif test "${HAVE_NS}" = "yes"; then
1773     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1774     USE_TOOLKIT_SCROLL_BARS=yes
1775   fi
1776 fi
1777
1778 dnl See if XIM is available.
1779 AC_TRY_COMPILE([
1780           #include <X11/Xlib.h>
1781           #include <X11/Xresource.h>],
1782          [XIMProc  callback;],
1783          [HAVE_XIM=yes
1784          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1785          HAVE_XIM=no)
1786
1787 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1788
1789 if test "${with_xim}" != "no"; then
1790   AC_DEFINE(USE_XIM, 1,
1791             [Define to 1 if we should use XIM, if it is available.])
1792 fi
1793
1794
1795 if test "${HAVE_XIM}" != "no"; then
1796   late_CFLAGS=$CFLAGS
1797   if test "$GCC" = yes; then
1798     CFLAGS="$CFLAGS --pedantic-errors"
1799   fi
1800   AC_TRY_COMPILE([
1801 #include <X11/Xlib.h>
1802 #include <X11/Xresource.h>],
1803 [Display *display;
1804 XrmDatabase db;
1805 char *res_name;
1806 char *res_class;
1807 XIMProc  callback;
1808 XPointer *client_data;
1809 #ifndef __GNUC__
1810 /* If we're not using GCC, it's probably not XFree86, and this is
1811    probably right, but we can't use something like --pedantic-errors.  */
1812 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1813                                            char*, XIMProc, XPointer*);
1814 #endif
1815 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1816    client_data);],
1817     [emacs_cv_arg6_star=yes])
1818   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1819          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1820 either XPointer or XPointer*.])dnl
1821   if test "$emacs_cv_arg6_star" = yes; then
1822     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1823   else
1824     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1825   fi
1826   CFLAGS=$late_CFLAGS
1827 fi
1828
1829 ### Start of font-backend section.
1830 PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1831 test "${HAVE_FC}" = "no" && with_freetype=no
1832
1833 ## Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1834 HAVE_XFT=maybe
1835 if test "x${with_freetype}" = "xno" || test "x${with_x}" = "xno"; then
1836   with_xft="no";
1837 fi
1838 if test "x${with_xft}" != "xno"; then
1839
1840   PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1841   if test "$HAVE_XFT" != no; then
1842     OLD_CPPFLAGS="$CPPFLAGS"
1843     OLD_CFLAGS="$CFLAGS"
1844     OLD_LIBS="$LIBS"
1845     CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1846     CFLAGS="$CFLAGS $XFT_CFLAGS"
1847     LIBS="$XFT_LIBS $LIBS"
1848     AC_CHECK_HEADER(X11/Xft/Xft.h,
1849       AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1850
1851     if test "${HAVE_XFT}" = "yes"; then
1852       AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1853         AC_SUBST(XFT_LIBS)
1854       C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1855     else
1856       CPPFLAGS="$OLD_CPPFLAGS"
1857       CFLAGS="$OLD_CFLAGS"
1858       LIBS="$OLD_LIBS"
1859     fi                        # "${HAVE_XFT}" = "yes"
1860   fi                          # "$HAVE_XFT" != no
1861 fi                            # "x${with_xft}" != "xno"
1862
1863 dnl For the "Does Emacs use" message at the end.
1864 if test "$HAVE_XFT" != "yes"; then
1865    HAVE_XFT=no
1866 fi
1867
1868
1869 HAVE_FREETYPE=no
1870 ### Use -lfreetype if available, unless `--with-freetype=no'.
1871 if test "${HAVE_XFT}" = "yes"; then
1872   dnl As we use Xft, we anyway use freetype.
1873   dnl In this case, there's no need of additional CFLAGS and LIBS.
1874   HAVE_FREETYPE=yes
1875   FONTCONFIG_CFLAGS=
1876   FONTCONFIG_LIBS=
1877 elif test "x${with_freetype}" != "xno" && test "x${with_x}" != "xno"; then
1878
1879   PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
1880 fi
1881
1882 HAVE_LIBOTF=no
1883 if test "${HAVE_FREETYPE}" = "yes"; then
1884   AC_DEFINE(HAVE_FREETYPE, 1,
1885             [Define to 1 if using the freetype and fontconfig libraries.])
1886   if test "${with_libotf}" != "no"; then
1887     PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
1888                       HAVE_LIBOTF=no)
1889     if test "$HAVE_LIBOTF" = "yes"; then
1890       AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
1891     fi
1892   fi
1893 dnl FIXME should there be an error if HAVE_FREETYPE != yes?
1894 dnl Does the new font backend require it, or can it work without it?
1895 fi
1896
1897 HAVE_M17N_FLT=no
1898 if test "${HAVE_LIBOTF}" = yes; then
1899   if test "${with_m17n_flt}" != "no"; then
1900     PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
1901     if test "$HAVE_M17N_FLT" = "yes"; then
1902       AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
1903     fi
1904   fi
1905 fi
1906
1907 AC_SUBST(FREETYPE_CFLAGS)
1908 AC_SUBST(FREETYPE_LIBS)
1909 AC_SUBST(FONTCONFIG_CFLAGS)
1910 AC_SUBST(FONTCONFIG_LIBS)
1911 AC_SUBST(LIBOTF_CFLAGS)
1912 AC_SUBST(LIBOTF_LIBS)
1913 AC_SUBST(M17N_FLT_CFLAGS)
1914 AC_SUBST(M17N_FLT_LIBS)
1915
1916 ### End of font-backend section.
1917
1918 ### Use -lXpm if available, unless `--with-xpm=no'.
1919 HAVE_XPM=no
1920 if test "${HAVE_X11}" = "yes"; then
1921   if test "${with_xpm}" != "no"; then
1922     AC_CHECK_HEADER(X11/xpm.h,
1923       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
1924     if test "${HAVE_XPM}" = "yes"; then
1925       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1926       AC_EGREP_CPP(no_return_alloc_pixels,
1927       [#include "X11/xpm.h"
1928 #ifndef XpmReturnAllocPixels
1929 no_return_alloc_pixels
1930 #endif
1931       ], HAVE_XPM=no, HAVE_XPM=yes)
1932
1933       if test "${HAVE_XPM}" = "yes"; then
1934         AC_MSG_RESULT(yes)
1935       else
1936         AC_MSG_RESULT(no)
1937       fi
1938     fi
1939   fi
1940
1941   if test "${HAVE_XPM}" = "yes"; then
1942     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
1943   fi
1944 fi
1945
1946 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1947 HAVE_JPEG=no
1948 if test "${HAVE_X11}" = "yes"; then
1949   if test "${with_jpeg}" != "no"; then
1950     dnl Checking for jpeglib.h can lose because of a redefinition of
1951     dnl  HAVE_STDLIB_H.
1952     AC_CHECK_HEADER(jerror.h,
1953       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
1954   fi
1955
1956   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
1957   if test "${HAVE_JPEG}" = "yes"; then
1958     AC_DEFINE(HAVE_JPEG)
1959     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
1960         [#include <jpeglib.h>
1961          version=JPEG_LIB_VERSION
1962 ],
1963         [AC_DEFINE(HAVE_JPEG)],
1964         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1965         HAVE_JPEG=no])
1966   fi
1967 fi
1968
1969 ### Use -lpng if available, unless `--with-png=no'.
1970 HAVE_PNG=no
1971 if test "${HAVE_X11}" = "yes"; then
1972   if test "${with_png}" != "no"; then
1973     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
1974     # in /usr/include/libpng.
1975     AC_CHECK_HEADERS(png.h libpng/png.h)
1976     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
1977       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
1978     fi
1979   fi
1980
1981   if test "${HAVE_PNG}" = "yes"; then
1982     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
1983   fi
1984 fi
1985
1986 ### Use -ltiff if available, unless `--with-tiff=no'.
1987 HAVE_TIFF=no
1988 if test "${HAVE_X11}" = "yes"; then
1989   if test "${with_tiff}" != "no"; then
1990     AC_CHECK_HEADER(tiffio.h,
1991       [tifflibs="-lz -lm"
1992       # At least one tiff package requires the jpeg library.
1993       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1994       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
1995   fi
1996
1997   if test "${HAVE_TIFF}" = "yes"; then
1998     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
1999   fi
2000 fi
2001
2002 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2003 HAVE_GIF=no
2004 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2005   AC_CHECK_HEADER(gif_lib.h,
2006 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2007 # Earlier versions can crash Emacs.
2008     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2009
2010   if test "$HAVE_GIF" = yes; then
2011       ac_gif_lib_name="-lgif"
2012   fi
2013
2014 # If gif_lib.h but no libgif, try libungif.
2015   if test x"$try_libungif" = xyes; then
2016     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2017
2018     if test "$HAVE_GIF" = yes; then
2019       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2020       ac_gif_lib_name="-lungif"
2021     fi
2022   fi
2023
2024   if test "${HAVE_GIF}" = "yes"; then
2025     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2026   fi
2027 fi
2028
2029 dnl Check for required libraries.
2030 if test "${HAVE_X11}" = "yes"; then
2031   MISSING=""
2032   WITH_NO=""
2033   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2034     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2035   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2036     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2037   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2038     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2039   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2040     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2041   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2042     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2043
2044   if test "X${MISSING}" != X; then
2045     AC_MSG_ERROR([The following required libraries were not found:
2046     $MISSING
2047 Maybe some development libraries/packages are missing?
2048 If you don't want to link with them give
2049     $WITH_NO
2050 as options to configure])
2051   fi
2052 fi
2053
2054 ### Use -lgpm if available, unless `--with-gpm=no'.
2055 HAVE_GPM=no
2056 if test "${with_gpm}" != "no"; then
2057   AC_CHECK_HEADER(gpm.h,
2058     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2059 fi
2060
2061 if test "${HAVE_GPM}" = "yes"; then
2062   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2063 fi
2064
2065 dnl Check for malloc/malloc.h on darwin
2066 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2067
2068 ### Use NeXTstep API to implement GUI.
2069 if test "${HAVE_NS}" = "yes"; then
2070   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2071   if test "${NS_IMPL_COCOA}" = "yes"; then
2072     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2073     GNU_OBJC_CFLAGS=
2074     LIB_SRC_EXTRA_INSTALLABLES=mac-fix-env
2075   fi
2076   if test "${EN_COCOA_EXPERIMENTAL_CTRL_G}" = "yes"; then
2077     AC_DEFINE(COCOA_EXPERIMENTAL_CTRL_G, 1, [Define to 1 if you are trying experimental enhanced Ctrl-g support using NS windowing under MacOS X.])
2078   fi
2079   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2080     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2081     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2082   fi
2083   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2084     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2085   fi
2086   # We also have mouse menus.
2087   HAVE_MENUS=yes
2088 fi
2089
2090
2091 ### Use session management (-lSM -lICE) if available
2092 HAVE_X_SM=no
2093 if test "${HAVE_X11}" = "yes"; then
2094   AC_CHECK_HEADER(X11/SM/SMlib.h,
2095     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2096
2097   if test "${HAVE_X_SM}" = "yes"; then
2098     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2099     case "$LIBS" in
2100       *-lSM*) ;;
2101       *)      LIBS="-lSM -lICE $LIBS" ;;
2102     esac
2103   fi
2104 fi
2105
2106 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2107 AC_CACHE_CHECK(whether netdb declares h_errno,
2108                emacs_cv_netdb_declares_h_errno,
2109 [AC_TRY_LINK([#include <netdb.h>],
2110   [return h_errno;],
2111   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2112 if test $emacs_cv_netdb_declares_h_errno = yes; then
2113   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2114 fi
2115
2116 AC_FUNC_ALLOCA
2117
2118 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2119 dnl FIXME is there an autoconf test that does the right thing, without
2120 dnl needing to call A_M_E afterwards?
2121 if test x"$ac_cv_func_alloca_works" != xyes; then
2122    AC_MSG_ERROR( [a system implementation of alloca is required] )
2123 fi
2124
2125 # fmod, logb, and frexp are found in -lm on most systems.
2126 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2127 AC_CHECK_LIB(m, sqrt)
2128
2129 # Check for mail-locking functions in a "mail" library.  Probably this should
2130 # have the same check as for liblockfile below.
2131 AC_CHECK_LIB(mail, maillock)
2132 dnl Debian, at least:
2133 AC_CHECK_LIB(lockfile, maillock)
2134 # If we have the shared liblockfile, assume we must use it for mail
2135 # locking (e.g. Debian).  If we couldn't link against liblockfile
2136 # (no liblockfile.a installed), ensure that we don't need to.
2137 if test "$ac_cv_lib_lockfile_maillock" = no; then
2138   dnl This works for files generally, not just executables.
2139   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2140   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2141                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2142   if test $ac_cv_prog_liblockfile = yes; then
2143     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2144 This probably means that movemail could lose mail.
2145 There may be a `development' package to install containing liblockfile.])
2146   else :
2147   fi
2148 fi
2149 AC_CHECK_FUNCS(touchlock)
2150 AC_CHECK_HEADERS(maillock.h)
2151
2152 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2153 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2154 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2155 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2156 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2157 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2158 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2159 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2160 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2161 cfmakeraw cfsetspeed)
2162
2163 AC_CHECK_HEADERS(sys/un.h)
2164
2165 AC_FUNC_MKTIME
2166 if test "$ac_cv_func_working_mktime" = no; then
2167   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2168 fi
2169
2170 AC_FUNC_GETLOADAVG
2171
2172 AC_FUNC_FSEEKO
2173
2174 # Configure getopt.
2175 m4_include([m4/getopt.m4])
2176 gl_GETOPT_IFELSE([
2177   gl_GETOPT_SUBSTITUTE_HEADER
2178   gl_PREREQ_GETOPT
2179   GETOPTOBJS='getopt.o getopt1.o'
2180 ])
2181 AC_SUBST(GETOPTOBJS)
2182
2183 AC_FUNC_GETPGRP
2184
2185 AC_FUNC_STRFTIME
2186
2187 # UNIX98 PTYs.
2188 AC_CHECK_FUNCS(grantpt)
2189
2190 # PTY-related GNU extensions.
2191 AC_CHECK_FUNCS(getpt)
2192
2193 # Check this now, so that we will NOT find the above functions in ncurses.
2194 # That is because we have not set up to link ncurses in lib-src.
2195 # It's better to believe a function is not available
2196 # than to expect to find it in ncurses.
2197 AC_CHECK_LIB(ncurses, tparm)
2198
2199 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2200
2201 resolv=no
2202 AC_TRY_LINK([#include <netinet/in.h>
2203 #include <arpa/nameser.h>
2204 #include <resolv.h>],
2205     [return res_init();],
2206     have_res_init=yes, have_res_init=no)
2207 if test "$have_res_init" = no; then
2208   OLIBS="$LIBS"
2209   LIBS="$LIBS -lresolv"
2210   AC_MSG_CHECKING(for res_init with -lresolv)
2211   AC_TRY_LINK([#include <netinet/in.h>
2212 #include <arpa/nameser.h>
2213 #include <resolv.h>],
2214     [return res_init();],
2215     have_res_init=yes, have_res_init=no)
2216   AC_MSG_RESULT($have_res_init)
2217   if test "$have_res_init" = yes ; then
2218     resolv=yes
2219   fi
2220   LIBS="$OLIBS"
2221 fi
2222
2223 if test "$have_res_init" = yes; then
2224   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2225 fi
2226
2227 # Do we need the Hesiod library to provide the support routines?
2228 if test "$with_hesiod" != no ; then
2229   # Don't set $LIBS here -- see comments above.
2230   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2231      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2232                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2233   if test "$resolv" = yes ; then
2234     RESOLVLIB=-lresolv
2235   else
2236     RESOLVLIB=
2237   fi
2238   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2239         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2240                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2241         :, $RESOLVLIB)])
2242 fi
2243
2244 # Do we need libresolv (due to res_init or Hesiod)?
2245 if test "$resolv" = yes ; then
2246   AC_DEFINE(HAVE_LIBRESOLV, 1,
2247             [Define to 1 if you have the resolv library (-lresolv).])
2248 fi
2249
2250 # These tell us which Kerberos-related libraries to use.
2251 if test "${with_kerberos}" != no; then
2252   AC_CHECK_LIB(com_err, com_err)
2253   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2254   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2255   AC_CHECK_LIB(krb5, krb5_init_context)
2256   if test "${with_kerberos5}" = no; then
2257     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2258                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2259     AC_CHECK_LIB(krb4, krb_get_cred,,
2260                  [AC_CHECK_LIB(krb, krb_get_cred)])
2261   fi
2262
2263   if test "${with_kerberos5}" != no; then
2264     AC_CHECK_HEADERS(krb5.h,
2265       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2266                         [#include <krb5.h>])])
2267   else
2268     AC_CHECK_HEADERS(des.h,,
2269                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2270                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2271     AC_CHECK_HEADERS(krb.h,,
2272                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2273                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2274   fi
2275   AC_CHECK_HEADERS(com_err.h)
2276 fi
2277
2278 # Solaris requires -lintl if you want strerror (which calls dgettext)
2279 # to return localized messages.
2280 AC_CHECK_LIB(intl, dgettext)
2281
2282 AC_MSG_CHECKING(whether localtime caches TZ)
2283 AC_CACHE_VAL(emacs_cv_localtime_cache,
2284 [if test x$ac_cv_func_tzset = xyes; then
2285 AC_TRY_RUN([#include <time.h>
2286 extern char **environ;
2287 unset_TZ ()
2288 {
2289   char **from, **to;
2290   for (to = from = environ; (*to = *from); from++)
2291     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2292       to++;
2293 }
2294 char TZ_GMT0[] = "TZ=GMT0";
2295 char TZ_PST8[] = "TZ=PST8";
2296 main()
2297 {
2298   time_t now = time ((time_t *) 0);
2299   int hour_GMT0, hour_unset;
2300   if (putenv (TZ_GMT0) != 0)
2301     exit (1);
2302   hour_GMT0 = localtime (&now)->tm_hour;
2303   unset_TZ ();
2304   hour_unset = localtime (&now)->tm_hour;
2305   if (putenv (TZ_PST8) != 0)
2306     exit (1);
2307   if (localtime (&now)->tm_hour == hour_GMT0)
2308     exit (1);
2309   unset_TZ ();
2310   if (localtime (&now)->tm_hour != hour_unset)
2311     exit (1);
2312   exit (0);
2313 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2314 [# If we have tzset, assume the worst when cross-compiling.
2315 emacs_cv_localtime_cache=yes])
2316 else
2317         # If we lack tzset, report that localtime does not cache TZ,
2318         # since we can't invalidate the cache if we don't have tzset.
2319         emacs_cv_localtime_cache=no
2320 fi])dnl
2321 AC_MSG_RESULT($emacs_cv_localtime_cache)
2322 if test $emacs_cv_localtime_cache = yes; then
2323   AC_DEFINE(LOCALTIME_CACHE, 1,
2324             [Define to 1 if localtime caches TZ.])
2325 fi
2326
2327 if test "x$HAVE_TIMEVAL" = xyes; then
2328   AC_CHECK_FUNCS(gettimeofday)
2329   if test $ac_cv_func_gettimeofday = yes; then
2330     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2331                    emacs_cv_gettimeofday_two_arguments,
2332     [AC_TRY_COMPILE([
2333 #ifdef TIME_WITH_SYS_TIME
2334 #include <sys/time.h>
2335 #include <time.h>
2336 #else
2337 #ifdef HAVE_SYS_TIME_H
2338 #include <sys/time.h>
2339 #else
2340 #include <time.h>
2341 #endif
2342 #endif],
2343       [struct timeval time;
2344        gettimeofday (&time, 0);],
2345       emacs_cv_gettimeofday_two_arguments=yes,
2346       emacs_cv_gettimeofday_two_arguments=no)])
2347     if test $emacs_cv_gettimeofday_two_arguments = no; then
2348       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2349                 [Define to 1 if gettimeofday accepts only one argument.])
2350     fi
2351   fi
2352 fi
2353
2354 ok_so_far=yes
2355 AC_CHECK_FUNC(socket, , ok_so_far=no)
2356 if test $ok_so_far = yes; then
2357   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2358 fi
2359 if test $ok_so_far = yes; then
2360   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2361 fi
2362 if test $ok_so_far = yes; then
2363 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2364   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2365             [Define to 1 if you have inet sockets.])
2366 fi
2367
2368 AC_CHECK_HEADERS(sys/ioctl.h)
2369
2370 if test -f /usr/lpp/X11/bin/smt.exp; then
2371   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2372             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2373 fi
2374
2375 AC_MSG_CHECKING(whether system supports dynamic ptys)
2376 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2377   AC_MSG_RESULT(yes)
2378   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2379 else
2380   AC_MSG_RESULT(no)
2381 fi
2382
2383 AC_FUNC_FORK
2384
2385 dnl Adapted from Haible's version.
2386 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2387   [AC_TRY_LINK([#include <langinfo.h>],
2388     [char* cs = nl_langinfo(CODESET);],
2389     emacs_cv_langinfo_codeset=yes,
2390     emacs_cv_langinfo_codeset=no)
2391   ])
2392 if test $emacs_cv_langinfo_codeset = yes; then
2393   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2394     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2395 fi
2396
2397 AC_CHECK_TYPES(size_t)
2398
2399 AC_TYPE_MBSTATE_T
2400
2401 dnl Restrict could probably be used effectively other than in regex.c.
2402 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2403   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2404                   emacs_cv_c_restrict=yes,
2405                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2406                                   emacs_cv_c_restrict=__restrict,
2407                                   emacs_cv_c_restrict=no)])])
2408 case "$emacs_cv_c_restrict" in
2409   yes) emacs_restrict=restrict;;
2410   no) emacs_restrict="";;
2411   *) emacs_restrict="$emacs_cv_c_restrict";;
2412 esac
2413 if test "$emacs_restrict" != __restrict; then
2414   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2415     [Define to compiler's equivalent of C99 restrict keyword.
2416      Don't define if equivalent is `__restrict'.])
2417 fi
2418
2419 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2420   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2421                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2422 if test "$emacs_cv_c_restrict_arr" = yes; then
2423   AC_DEFINE(__restrict_arr, __restrict,
2424     [Define to compiler's equivalent of C99 restrict keyword in array
2425      declarations.  Define as empty for no equivalent.])
2426 fi
2427
2428 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2429 dnl how the tty code is related to POSIX and/or other versions of termios.
2430 dnl The following looks like a useful start.
2431 dnl
2432 dnl AC_SYS_POSIX_TERMIOS
2433 dnl if test $ac_cv_sys_posix_termios = yes; then
2434 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2435 dnl                                and macros for terminal control.])
2436 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2437 dnl fi
2438
2439 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2440
2441 # Set up the CFLAGS for real compilation, so we can substitute it.
2442 CFLAGS="$REAL_CFLAGS"
2443 CPPFLAGS="$REAL_CPPFLAGS"
2444
2445 #### Find out which version of Emacs this is.
2446 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2447          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2448 if test x"${version}" = x; then
2449   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2450 fi
2451
2452 ### Specify what sort of things we'll be editing into Makefile and config.h.
2453 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2454 AC_SUBST(version)
2455 AC_SUBST(configuration)
2456 AC_SUBST(canonical)
2457 AC_SUBST(srcdir)
2458 AC_SUBST(prefix)
2459 AC_SUBST(exec_prefix)
2460 AC_SUBST(bindir)
2461 AC_SUBST(datadir)
2462 AC_SUBST(sharedstatedir)
2463 AC_SUBST(libexecdir)
2464 AC_SUBST(mandir)
2465 AC_SUBST(infodir)
2466 AC_SUBST(lispdir)
2467 AC_SUBST(locallisppath)
2468 AC_SUBST(lisppath)
2469 AC_SUBST(x_default_search_path)
2470 AC_SUBST(etcdir)
2471 AC_SUBST(archlibdir)
2472 AC_SUBST(docdir)
2473 AC_SUBST(bitmapdir)
2474 AC_SUBST(gamedir)
2475 AC_SUBST(gameuser)
2476 AC_SUBST(c_switch_system)
2477 AC_SUBST(c_switch_machine)
2478 AC_SUBST(LD_SWITCH_X_SITE)
2479 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2480 AC_SUBST(C_SWITCH_X_SITE)
2481 AC_SUBST(CFLAGS)
2482 AC_SUBST(X_TOOLKIT_TYPE)
2483 AC_SUBST(machfile)
2484 AC_SUBST(opsysfile)
2485 AC_SUBST(GETLOADAVG_LIBS)
2486 AC_SUBST(ns_appdir)
2487 AC_SUBST(ns_appbindir)
2488 AC_SUBST(ns_appresdir)
2489 AC_SUBST(ns_appsrc)
2490 AC_SUBST(GNUSTEP_MAKEFILES)
2491 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2492 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2493 AC_SUBST(GNU_OBJC_CFLAGS)
2494 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2495
2496 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2497                    [Define to the canonical Emacs configuration name.])
2498 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2499                    [Define to the options passed to configure.])
2500 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2501                    [Define to the used machine dependent file.])
2502 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2503                    [Define to the used os dependent file.])
2504 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2505 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2506  may need to deal with X Windows.  For instance, if you've defined
2507  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2508  your loader can find on its own, you might want to add "-L/..." or
2509  something similar.])
2510 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2511                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2512                     in case it's needed (for Solaris, for example).])
2513 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2514 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2515  may need to deal with X Windows.  For instance, if you've defined
2516  HAVE_X_WINDOWS above and your X include files aren't in a place
2517  that your compiler can find on its own, you might want to add
2518  "-I/..." or something similar.])
2519 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2520                    [Define to the unexec source file name.])
2521
2522 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2523   AC_DEFINE(HAVE_X_WINDOWS, 1,
2524             [Define to 1 if you want to use the X window system.])
2525 fi
2526 if test "${USE_X_TOOLKIT}" != "none" ; then
2527   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2528   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2529     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2530   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2531     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2532   fi
2533 fi
2534 if test "${HAVE_X11}" = "yes" ; then
2535   AC_DEFINE(HAVE_X11, 1,
2536             [Define to 1 if you want to use version 11 of X windows.
2537              Otherwise, Emacs expects to use version 10.])
2538 fi
2539 if test "${HAVE_MENUS}" = "yes" ; then
2540   AC_DEFINE(HAVE_MENUS, 1,
2541             [Define to 1 if you have mouse menus.
2542              (This is automatic if you use X, but the option to specify it remains.)
2543              It is also defined with other window systems that support xmenu.c.])
2544 fi
2545 if test "${GNU_MALLOC}" = "yes" ; then
2546   AC_DEFINE(GNU_MALLOC, 1,
2547             [Define to 1 if you want to use the GNU memory allocator.])
2548 fi
2549 if test "${REL_ALLOC}" = "yes" ; then
2550   AC_DEFINE(REL_ALLOC, 1,
2551             [Define REL_ALLOC if you want to use the relocating allocator for
2552              buffer space.])
2553 fi
2554
2555
2556 AH_TOP([/* GNU Emacs site configuration template file.
2557    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2558      2006, 2007, 2008  Free Software Foundation, Inc.
2559
2560 This file is part of GNU Emacs.
2561
2562 GNU Emacs is free software: you can redistribute it and/or modify
2563 it under the terms of the GNU General Public License as published by
2564 the Free Software Foundation, either version 3 of the License, or
2565 (at your option) any later version.
2566
2567 GNU Emacs is distributed in the hope that it will be useful,
2568 but WITHOUT ANY WARRANTY; without even the implied warranty of
2569 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2570 GNU General Public License for more details.
2571
2572 You should have received a copy of the GNU General Public License
2573 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2574
2575
2576 /* No code in Emacs #includes config.h twice, but some bits of code
2577    intended to work with other packages as well (like gmalloc.c)
2578    think they can include it as many times as they like.  */
2579 #ifndef EMACS_CONFIG_H
2580 #define EMACS_CONFIG_H
2581 ])dnl
2582
2583 AH_BOTTOM([
2584 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2585 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2586 #define HAVE_WINDOW_SYSTEM
2587 #define HAVE_MOUSE
2588 #endif
2589
2590 /* Sadly for now, GNUstep dump does not work.  */
2591 #ifdef NS_IMPL_GNUSTEP
2592 #define CANNOT_DUMP
2593 #endif
2594
2595 /* Define AMPERSAND_FULL_NAME if you use the convention
2596    that & in the full name stands for the login id.  */
2597 /* Turned on June 1996 supposing nobody will mind it.  */
2598 #define AMPERSAND_FULL_NAME
2599
2600 /* Define HAVE_SOUND if we have sound support.  We know it works
2601    and compiles only on the specified platforms.   For others,
2602    it probably doesn't make sense to try.  */
2603
2604 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2605 #ifdef HAVE_MACHINE_SOUNDCARD_H
2606 #define HAVE_SOUND 1
2607 #endif
2608 #ifdef HAVE_SYS_SOUNDCARD_H
2609 #define HAVE_SOUND 1
2610 #endif
2611 #ifdef HAVE_SOUNDCARD_H
2612 #define HAVE_SOUND 1
2613 #endif
2614 #ifdef HAVE_ALSA
2615 #define HAVE_SOUND 1
2616 #endif
2617 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2618
2619 /* If using GNU, then support inline function declarations. */
2620 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2621    generally, because even if non-gcc compilers accept `inline', they
2622    may reject `extern inline'.  */
2623 #if defined (__GNUC__) && defined (OPTIMIZE)
2624 #define INLINE __inline__
2625 #else
2626 #define INLINE
2627 #endif
2628
2629 /* `subprocesses' should be defined if you want to
2630    have code for asynchronous subprocesses
2631    (as used in M-x compile and M-x shell).
2632    Only MSDOS does not support this (it overrides
2633    this in its config_opsysfile below).  */
2634
2635 #define subprocesses
2636
2637 /* Include the os and machine dependent files.  */
2638 #include config_opsysfile
2639 #include config_machfile
2640
2641 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2642   (There is probably a better place to do this, but right now the Cocoa
2643    side does this in s/darwin.h and we cannot
2644    parallel this exactly since GNUstep is multi-OS. */
2645 #ifdef HAVE_NS
2646 #define OTHER_FILES ns-app
2647 # ifdef NS_IMPL_GNUSTEP
2648 /* See also .m.o rule in Makefile.in */
2649 /* FIXME: are all these flags really needed?  Document here why.  */
2650 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2651 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2652 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2653 #  define SYSTEM_PURESIZE_EXTRA 30000
2654 # endif /* NS_IMPL_GNUSTEP */
2655 #endif /* HAVE_NS */
2656
2657 /* SIGTYPE is the macro we actually use.  */
2658 #ifndef SIGTYPE
2659 #define SIGTYPE RETSIGTYPE
2660 #endif
2661
2662 #ifdef emacs /* Don't do this for lib-src.  */
2663 /* Tell regex.c to use a type compatible with Emacs.  */
2664 #define RE_TRANSLATE_TYPE Lisp_Object
2665 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2666 #ifdef make_number
2667 /* If make_number is a macro, use it.  */
2668 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2669 #else
2670 /* If make_number is a function, avoid it.  */
2671 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2672 #endif
2673 #endif
2674
2675 /* Avoid link-time collision with system mktime if we will use our own.  */
2676 #if ! HAVE_MKTIME || BROKEN_MKTIME
2677 #define mktime emacs_mktime
2678 #endif
2679
2680 #define my_strftime nstrftime   /* for strftime.c */
2681
2682 /* The rest of the code currently tests the CPP symbol BSTRING.
2683    Override any claims made by the system-description files.
2684    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2685 #undef BSTRING
2686 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2687 #define BSTRING
2688 #endif
2689
2690 /* Some of the files of Emacs which are intended for use with other
2691    programs assume that if you have a config.h file, you must declare
2692    the type of getenv.
2693
2694    This declaration shouldn't appear when alloca.s or Makefile.in
2695    includes config.h.  */
2696 #ifndef NOT_C_CODE
2697 extern char *getenv ();
2698 #endif
2699
2700 /* These default definitions are good for almost all machines.
2701    The exceptions override them in m/MACHINE.h.  */
2702
2703 #ifndef BITS_PER_CHAR
2704 #define BITS_PER_CHAR 8
2705 #endif
2706
2707 #ifndef BITS_PER_SHORT
2708 #define BITS_PER_SHORT 16
2709 #endif
2710
2711 /* Note that lisp.h uses this in a preprocessor conditional, so it
2712    would not work to use sizeof.  That being so, we do all of them
2713    without sizeof, for uniformity's sake.  */
2714 #ifndef BITS_PER_INT
2715 #define BITS_PER_INT 32
2716 #endif
2717
2718 #ifndef BITS_PER_LONG
2719 #ifdef _LP64
2720 #define BITS_PER_LONG 64
2721 #else
2722 #define BITS_PER_LONG 32
2723 #endif
2724 #endif
2725
2726 /* Define if the compiler supports function prototypes.  It may do so
2727    but not define __STDC__ (e.g. DEC C by default) or may define it as
2728    zero.  */
2729 #undef PROTOTYPES
2730 /* For mktime.c:  */
2731 #ifndef __P
2732 # if defined PROTOTYPES
2733 #  define __P(args) args
2734 # else
2735 #  define __P(args) ()
2736 # endif  /* GCC.  */
2737 #endif /* __P */
2738
2739 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2740 #ifndef NOT_C_CODE
2741 #ifdef HAVE_STRING_H
2742 #include "string.h"
2743 #endif
2744 #ifdef HAVE_STRINGS_H
2745 #include "strings.h"  /* May be needed for bcopy & al. */
2746 #endif
2747 #ifdef HAVE_STDLIB_H
2748 #include <stdlib.h>
2749 #endif
2750 #ifndef __GNUC__
2751 # ifdef HAVE_ALLOCA_H
2752 #  include <alloca.h>
2753 # else /* AIX files deal with #pragma.  */
2754 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2755 char *alloca ();
2756 #  endif
2757 # endif /* HAVE_ALLOCA_H */
2758 #endif /* __GNUC__ */
2759 #ifndef HAVE_SIZE_T
2760 typedef unsigned size_t;
2761 #endif
2762 #endif /* NOT_C_CODE */
2763
2764 /* Define HAVE_X_I18N if we have usable i18n support.  */
2765
2766 #ifdef HAVE_X11R6
2767 #define HAVE_X_I18N
2768 #elif !defined X11R5_INHIBIT_I18N
2769 #define HAVE_X_I18N
2770 #endif
2771
2772 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2773
2774 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2775 #define HAVE_X11R6_XIM
2776 #endif
2777
2778 /* Should we enable expensive run-time checking of data types?  */
2779 #undef ENABLE_CHECKING
2780
2781 #if defined __GNUC__ && (__GNUC__ > 2 \
2782                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2783 #define NO_RETURN       __attribute__ ((__noreturn__))
2784 #else
2785 #define NO_RETURN       /* nothing */
2786 #endif
2787
2788 /* These won't be used automatically yet.  We also need to know, at least,
2789    that the stack is continuous.  */
2790 #ifdef __GNUC__
2791 #  ifndef GC_SETJMP_WORKS
2792   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2793      see NON_SAVING_SETJMP in the target descriptions.  */
2794   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2795      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2796      Fixme: Deal with SVR3.  */
2797 #    define GC_SETJMP_WORKS 1
2798 #  endif
2799 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2800 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2801 #  endif
2802 #endif
2803
2804 #ifndef HAVE_BCOPY
2805 #define bcopy(a,b,s) memcpy (b,a,s)
2806 #endif
2807 #ifndef HAVE_BZERO
2808 #define bzero(a,s) memset (a,0,s)
2809 #endif
2810 #ifndef HAVE_BCMP
2811 #define BCMP memcmp
2812 #endif
2813
2814 #endif /* EMACS_CONFIG_H */
2815
2816 /*
2817 Local Variables:
2818 mode: c
2819 End:
2820 */
2821 ])dnl
2822
2823 #### Report on what we decided to do.
2824 #### Report GTK as a toolkit, even if it doesn't use Xt.
2825 #### It makes printing result more understandable as using GTK sets
2826 #### toolkit_scroll_bars to yes by default.
2827 if test "${HAVE_GTK}" = "yes"; then
2828   USE_X_TOOLKIT=GTK
2829 fi
2830
2831 echo "
2832 Configured for \`${canonical}'.
2833
2834   Where should the build process find the source code?    ${srcdir}
2835   What operating system and machine description files should Emacs use?
2836         \`${opsysfile}' and \`${machfile}'
2837   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2838   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2839   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2840   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2841   What window system should Emacs use?                    ${window_system}
2842   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2843
2844 if test -n "${x_includes}"; then
2845 echo "  Where do we find X Windows header files?                ${x_includes}"
2846 else
2847 echo "  Where do we find X Windows header files?                Standard dirs"
2848 fi
2849 if test -n "${x_libraries}"; then
2850 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2851 else
2852 echo "  Where do we find X Windows libraries?                   Standard dirs"
2853 fi
2854
2855 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2856 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2857 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2858 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2859 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2860 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2861 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2862 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2863 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2864
2865 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2866 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2867 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2868 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2869
2870 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
2871 echo
2872
2873 if test $USE_XASSERTS = yes; then
2874    echo "  Compiling with asserts turned on."
2875    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2876 fi
2877
2878 echo
2879
2880 if test "$USE_X_TOOLKIT" = GTK; then
2881   case "$canonical" in
2882   *cygwin*)
2883     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2884   will probably get a crash on startup.  If this happens, please use another
2885   toolkit for Emacs.  See etc/PROBLEMS for more information."
2886   ;;
2887   esac
2888 fi
2889
2890 if test "$HAVE_NS" = "yes"; then
2891    echo
2892    echo "You must run \"make install\" in order to test the built application.
2893 The installed application will go to nextstep/Emacs.app and can be
2894 run or moved from there."
2895    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
2896       echo "The application will be fully self-contained."
2897     else
2898       echo "The lisp resources for the application will be installed under ${prefix}.
2899 You may need to run \"make install\" with sudo.  The application will fail
2900 to run if these resources are not installed."
2901    fi
2902    echo
2903 fi
2904
2905 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
2906   echo "D-Bus integration has been tested for GNU/Linux only."
2907   echo
2908 fi
2909
2910
2911 # Remove any trailing slashes in these variables.
2912 [test "${prefix}" != NONE &&
2913   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2914 test "${exec_prefix}" != NONE &&
2915   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
2916
2917 # Now get this: Some word that is part of the ${srcdir} directory name
2918 # or the ${configuration} value might, just might, happen to be an
2919 # identifier like `sun4' or `i386' or something, and be predefined by
2920 # the C preprocessor to some helpful value like 1, or maybe the empty
2921 # string.  Needless to say consequent macro substitutions are less
2922 # than conducive to the makefile finding the correct directory.
2923 [cpp_undefs="`echo $srcdir $configuration $canonical |
2924   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
2925   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
2926
2927 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
2928 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2929 ## from Makefile.c can correctly provide the arg `-traditional' to the
2930 ## C preprocessor.
2931
2932 AC_EGREP_CPP(yes..yes,
2933         [yes..yes],
2934         CPP_NEED_TRADITIONAL=no,
2935         CPP_NEED_TRADITIONAL=yes)
2936
2937 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2938         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
2939         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
2940         lwlib/Makefile lisp/Makefile leim/Makefile, [
2941
2942 ### Make the necessary directories, if they don't exist.
2943 for dir in etc lisp ; do
2944   test -d ${dir} || mkdir ${dir}
2945 done
2946
2947 # Build src/Makefile from ${srcdir}/src/Makefile.c
2948 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2949 # This must be done after src/config.h is built, since we rely on that file.
2950
2951 echo creating src/epaths.h
2952 ${MAKE-make} epaths-force
2953
2954 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2955 # `..' to `. .'  unless invoked with -traditional
2956
2957 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2958   CPPFLAGS="$CPPFLAGS -traditional"
2959 fi
2960
2961 echo creating lib-src/Makefile
2962 ( cd lib-src
2963   rm -f junk.c junk1.c junk2.c
2964   sed -e '/start of cpp stuff/q' \
2965       < Makefile.c > junk1.c
2966   sed -e '1,/start of cpp stuff/d'\
2967       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2968       < Makefile.c > junk.c
2969   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2970       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2971   cat junk1.c junk2.c > Makefile.new
2972   rm -f junk.c junk1.c junk2.c
2973   chmod 444 Makefile.new
2974   mv -f Makefile.new Makefile
2975 )
2976
2977 echo creating src/Makefile
2978 ( cd src
2979   rm -f junk.c junk1.c junk2.c
2980   sed -e '/start of cpp stuff/q' \
2981       < Makefile.c > junk1.c
2982   sed -e '1,/start of cpp stuff/d'\
2983       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2984       < Makefile.c > junk.c
2985   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2986       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2987   cat junk1.c junk2.c > Makefile.new
2988   rm -f junk.c junk1.c junk2.c
2989   chmod 444 Makefile.new
2990   mv -f Makefile.new Makefile
2991 )
2992
2993 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
2994   echo creating src/.gdbinit
2995   echo source $srcdir/src/.gdbinit > src/.gdbinit
2996 fi
2997
2998 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
2999
3000 m4_if(dnl       Do not change this comment
3001    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3002 )dnl