lisp/hexl.el

   1 ;;; hexl.el --- edit a file in a hex dump format using the hexl filter.
   2
   3 ;; Copyright (C) 1989 Free Software Foundation, Inc.
   4
   5 ;; Author: Keith Gabryelski <ag@wheaties.ai.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package implements a major mode for editing binary files.  It uses
  28 ;; a program called hexl, supplied with the GNU Emacs distribution, that
  29 ;; can filter a binary into an editable format or from the format back into
  30 ;; binary.  For full instructions, invoke `hexl-mode' on an empty buffer and
  31 ;; do `M-x describe-mode'.
  32 ;;
  33 ;; This may be useful in your .emacs:
  34 ;;
  35 ;;      (autoload 'hexl-find-file "hexl"
  36 ;;        "Edit file FILENAME in hexl-mode." t)
  37 ;;
  38 ;;      (define-key global-map "\C-c\C-h" 'hexl-find-file)
  39 ;;
  40 ;; NOTE: Remember to change HEXL-PROGRAM or HEXL-OPTIONS if needed.
  41 ;;
  42 ;; Currently hexl only supports big endian hex output with 16 bit
  43 ;; grouping.
  44 ;;
  45 ;; -iso in `hexl-options' will allow iso characters to display in the
  46 ;; ASCII region of the screen (if your emacs supports this) instead of
  47 ;; changing them to dots.
  48
  49 ;;; Code:
  50
  51 ;;
  52 ;; vars here
  53 ;;
  54
  55 (defvar hexl-program "hexl"
  56   "The program that will hexlify and de-hexlify its stdin.
  57 `hexl-program' will always be concatenated with `hexl-options'
  58 and \"-de\" when dehexlfying a buffer.")
  59
  60 (defvar hexl-iso ""
  61   "If your emacs can handle ISO characters, this should be set to
  62 \"-iso\" otherwise it should be \"\".")
  63
  64 (defvar hexl-options (format "-hex %s" hexl-iso)
  65   "Options to hexl-program that suit your needs.")
  66
  67 (defvar hexlify-command
  68   (format "%s%s %s" exec-directory hexl-program hexl-options)
  69   "The command to use to hexlify a buffer.")
  70
  71 (defvar dehexlify-command
  72   (format "%s%s -de %s" exec-directory hexl-program hexl-options)
  73   "The command to use to unhexlify a buffer.")
  74
  75 (defvar hexl-max-address 0
  76   "Maximum offset into hexl buffer.")
  77
  78 (defvar hexl-mode-map nil)
  79
  80 ;; routines
  81
  82 ;;;###autoload
  83 (defun hexl-mode (&optional arg)
  84   "\\<hexl-mode-map>
  85 A major mode for editing binary files in hex dump format.
  86
  87 This function automatically converts a buffer into the hexl format
  88 using the function `hexlify-buffer'.
  89
  90 Each line in the buffer has an \"address\" (displayed in hexadecimal)
  91 representing the offset into the file that the characters on this line
  92 are at and 16 characters from the file (displayed as hexadecimal
  93 values grouped every 16 bits) and as their ASCII values.
  94
  95 If any of the characters (displayed as ASCII characters) are
  96 unprintable (control or meta characters) they will be replaced as
  97 periods.
  98
  99 If `hexl-mode' is invoked with an argument the buffer is assumed to be
 100 in hexl format.
 101
 102 A sample format:
 103
 104   HEX ADDR: 0001 0203 0405 0607 0809 0a0b 0c0d 0e0f     ASCII-TEXT
 105   --------  ---- ---- ---- ---- ---- ---- ---- ----  ----------------
 106   00000000: 5468 6973 2069 7320 6865 786c 2d6d 6f64  This is hexl-mod
 107   00000010: 652e 2020 4561 6368 206c 696e 6520 7265  e.  Each line re
 108   00000020: 7072 6573 656e 7473 2031 3620 6279 7465  presents 16 byte
 109   00000030: 7320 6173 2068 6578 6164 6563 696d 616c  s as hexadecimal
 110   00000040: 2041 5343 4949 0a61 6e64 2070 7269 6e74   ASCII.and print
 111   00000050: 6162 6c65 2041 5343 4949 2063 6861 7261  able ASCII chara
 112   00000060: 6374 6572 732e 2020 416e 7920 636f 6e74  cters.  Any cont
 113   00000070: 726f 6c20 6f72 206e 6f6e 2d41 5343 4949  rol or non-ASCII
 114   00000080: 2063 6861 7261 6374 6572 730a 6172 6520   characters.are
 115   00000090: 6469 7370 6c61 7965 6420 6173 2070 6572  displayed as per
 116   000000a0: 696f 6473 2069 6e20 7468 6520 7072 696e  iods in the prin
 117   000000b0: 7461 626c 6520 6368 6172 6163 7465 7220  table character
 118   000000c0: 7265 6769 6f6e 2e0a                      region..
 119
 120 Movement is as simple as movement in a normal emacs text buffer.  Most
 121 cursor movement bindings are the same (ie. Use \\[hexl-backward-char], \\[hexl-forward-char], \\[hexl-next-line], and \\[hexl-previous-line]
 122 to move the cursor left, right, down, and up).
 123
 124 Advanced cursor movement commands (ala \\[hexl-beginning-of-line], \\[hexl-end-of-line], \\[hexl-beginning-of-buffer], and \\[hexl-end-of-buffer]) are
 125 also supported.
 126
 127 There are several ways to change text in hexl mode:
 128
 129 ASCII characters (character between space (0x20) and tilde (0x7E)) are
 130 bound to self-insert so you can simply type the character and it will
 131 insert itself (actually overstrike) into the buffer.
 132
 133 \\[hexl-quoted-insert] followed by another keystroke allows you to insert the key even if
 134 it isn't bound to self-insert.  An octal number can be supplied in place
 135 of another key to insert the octal number's ASCII representation.
 136
 137 \\[hexl-insert-hex-char] will insert a given hexadecimal value (if it is between 0 and 0xFF)
 138 into the buffer at the current point.
 139
 140 \\[hexl-insert-octal-char] will insert a given octal value (if it is between 0 and 0377)
 141 into the buffer at the current point.
 142
 143 \\[hexl-insert-decimal-char] will insert a given decimal value (if it is between 0 and 255)
 144 into the buffer at the current point.
 145
 146 \\[hexl-mode-exit] will exit hexl-mode.
 147
 148 Note: saving the file with any of the usual Emacs commands
 149 will actually convert it back to binary format while saving.
 150
 151 You can use \\[hexl-find-file] to visit a file in hexl-mode.
 152
 153 \\[describe-bindings] for advanced commands."
 154   (interactive "p")
 155   (if (eq major-mode 'hexl-mode)
 156       (error "You are already in hexl mode.")
 157     (kill-all-local-variables)
 158     (make-local-variable 'hexl-mode-old-local-map)
 159     (setq hexl-mode-old-local-map (current-local-map))
 160     (use-local-map hexl-mode-map)
 161
 162     (make-local-variable 'hexl-mode-old-mode-name)
 163     (setq hexl-mode-old-mode-name mode-name)
 164     (setq mode-name "Hexl")
 165
 166     (make-local-variable 'hexl-mode-old-major-mode)
 167     (setq hexl-mode-old-major-mode major-mode)
 168     (setq major-mode 'hexl-mode)
 169
 170     (make-local-variable 'write-contents-hooks)
 171     (add-hook 'write-contents-hooks 'hexl-save-buffer)
 172
 173     (let ((modified (buffer-modified-p))
 174           (inhibit-read-only t)
 175           (original-point (1- (point))))
 176       (if (not (or (eq arg 1) (not arg)))
 177           ;; if no argument then we guess at hexl-max-address
 178           (setq hexl-max-address (+ (* (/ (1- (buffer-size)) 68) 16) 15))
 179         (setq hexl-max-address (1- (buffer-size)))
 180         (hexlify-buffer)
 181         (set-buffer-modified-p modified)
 182         (hexl-goto-address original-point)))))
 183
 184 (defvar hexl-in-save-buffer nil)
 185
 186 (defun hexl-save-buffer ()
 187   "Save a hexl format buffer as binary in visited file if modified."
 188   (interactive)
 189   (if hexl-in-save-buffer nil
 190     (set-buffer-modified-p (if (buffer-modified-p)
 191                                (save-excursion
 192                                  (let ((buf (generate-new-buffer " hexl"))
 193                                        (name (buffer-name))
 194                                        (file-name (buffer-file-name))
 195                                        (start (point-min))
 196                                        (end (point-max))
 197                                        modified)
 198                                    (set-buffer buf)
 199                                    (insert-buffer-substring name start end)
 200                                    (set-buffer name)
 201                                    (dehexlify-buffer)
 202                                    ;; Prevent infinite recursion.
 203                                    (let ((hexl-in-save-buffer t))
 204                                      (save-buffer))
 205                                    (setq modified (buffer-modified-p))
 206                                    (delete-region (point-min) (point-max))
 207                                    (insert-buffer-substring buf start end)
 208                                    (kill-buffer buf)
 209                                    modified))
 210                              (message "(No changes need to be saved)")
 211                              nil))
 212     ;; Return t to indicate we have saved t
 213     t))
 214
 215 ;;;###autoload
 216 (defun hexl-find-file (filename)
 217   "Edit file FILENAME in hexl-mode.
 218 Switch to a buffer visiting file FILENAME, creating one in none exists."
 219   (interactive "fFilename: ")
 220   (if (eq system-type 'ms-dos)
 221       (find-file-binary filename)
 222     (find-file filename))
 223   (if (not (eq major-mode 'hexl-mode))
 224       (hexl-mode)))
 225
 226 (defun hexl-mode-exit (&optional arg)
 227   "Exit Hexl mode, returning to previous mode.
 228 With arg, don't unhexlify buffer."
 229   (interactive "p")
 230   (if (or (eq arg 1) (not arg))
 231       (let ((modified (buffer-modified-p))
 232             (inhibit-read-only t)
 233             (original-point (1+ (hexl-current-address))))
 234         (dehexlify-buffer)
 235         (remove-hook 'write-contents-hook 'hexl-save-buffer)
 236         (set-buffer-modified-p modified)
 237         (goto-char original-point)))
 238   (setq mode-name hexl-mode-old-mode-name)
 239   (use-local-map hexl-mode-old-local-map)
 240   (setq major-mode hexl-mode-old-major-mode)
 241 ;; Kludge to update mode-line
 242   (switch-to-buffer (current-buffer))
 243 )
 244
 245 (defun hexl-current-address ()
 246   "Return current hexl-address."
 247   (interactive)
 248   (let ((current-column (- (% (point) 68) 11))
 249         (hexl-address 0))
 250     (setq hexl-address (+ (* (/ (point) 68) 16)
 251                           (/ (- current-column  (/ current-column 5)) 2)))
 252     hexl-address))
 253
 254 (defun hexl-address-to-marker (address)
 255   "Return marker for ADDRESS."
 256   (interactive "nAddress: ")
 257   (+ (* (/ address 16) 68) 11 (/ (* (% address 16) 5) 2)))
 258
 259 (defun hexl-goto-address (address)
 260   "Goto hexl-mode (decimal) address ADDRESS.
 261
 262 Signal error if ADDRESS out of range."
 263   (interactive "nAddress: ")
 264   (if (or (< address 0) (> address hexl-max-address))
 265           (error "Out of hexl region."))
 266   (goto-char (hexl-address-to-marker address)))
 267
 268 (defun hexl-goto-hex-address (hex-address)
 269   "Go to hexl-mode address (hex string) HEX-ADDRESS.
 270
 271 Signal error if HEX-ADDRESS is out of range."
 272   (interactive "sHex Address: ")
 273   (hexl-goto-address (hexl-hex-string-to-integer hex-address)))
 274
 275 (defun hexl-hex-string-to-integer (hex-string)
 276   "Return decimal integer for HEX-STRING."
 277   (interactive "sHex number: ")
 278   (let ((hex-num 0))
 279     (while (not (equal hex-string ""))
 280       (setq hex-num (+ (* hex-num 16)
 281                        (hexl-hex-char-to-integer (string-to-char hex-string))))
 282       (setq hex-string (substring hex-string 1)))
 283     hex-num))
 284
 285 (defun hexl-octal-string-to-integer (octal-string)
 286   "Return decimal integer for OCTAL-STRING."
 287   (interactive "sOctal number: ")
 288   (let ((oct-num 0))
 289     (while (not (equal octal-string ""))
 290       (setq oct-num (+ (* oct-num 8)
 291                        (hexl-oct-char-to-integer
 292                         (string-to-char octal-string))))
 293       (setq octal-string (substring octal-string 1)))
 294     oct-num))
 295
 296 ;; move point functions
 297
 298 (defun hexl-backward-char (arg)
 299   "Move to left ARG bytes (right if ARG negative) in hexl-mode."
 300   (interactive "p")
 301   (hexl-goto-address (- (hexl-current-address) arg)))
 302
 303 (defun hexl-forward-char (arg)
 304   "Move right ARG bytes (left if ARG negative) in hexl-mode."
 305   (interactive "p")
 306   (hexl-goto-address (+ (hexl-current-address) arg)))
 307
 308 (defun hexl-backward-short (arg)
 309   "Move to left ARG shorts (right if ARG negative) in hexl-mode."
 310   (interactive "p")
 311   (hexl-goto-address (let ((address (hexl-current-address)))
 312                        (if (< arg 0)
 313                            (progn
 314                              (setq arg (- arg))
 315                              (while (> arg 0)
 316                                (if (not (equal address (logior address 3)))
 317                                    (if (> address hexl-max-address)
 318                                        (progn
 319                                          (message "End of buffer.")
 320                                          (setq address hexl-max-address))
 321                                      (setq address (logior address 3)))
 322                                  (if (> address hexl-max-address)
 323                                      (progn
 324                                        (message "End of buffer.")
 325                                        (setq address hexl-max-address))
 326                                    (setq address (+ address 4))))
 327                                (setq arg (1- arg)))
 328                              (if (> address hexl-max-address)
 329                                  (progn
 330                                    (message "End of buffer.")
 331                                    (setq address hexl-max-address))
 332                                (setq address (logior address 3))))
 333                          (while (> arg 0)
 334                            (if (not (equal address (logand address -4)))
 335                                (setq address (logand address -4))
 336                              (if (not (equal address 0))
 337                                  (setq address (- address 4))
 338                                (message "Beginning of buffer.")))
 339                            (setq arg (1- arg))))
 340                        address)))
 341
 342 (defun hexl-forward-short (arg)
 343   "Move right ARG shorts (left if ARG negative) in hexl-mode."
 344   (interactive "p")
 345   (hexl-backward-short (- arg)))
 346
 347 (defun hexl-backward-word (arg)
 348   "Move to left ARG words (right if ARG negative) in hexl-mode."
 349   (interactive "p")
 350   (hexl-goto-address (let ((address (hexl-current-address)))
 351                        (if (< arg 0)
 352                            (progn
 353                              (setq arg (- arg))
 354                              (while (> arg 0)
 355                                (if (not (equal address (logior address 7)))
 356                                    (if (> address hexl-max-address)
 357                                        (progn
 358                                          (message "End of buffer.")
 359                                          (setq address hexl-max-address))
 360                                      (setq address (logior address 7)))
 361                                  (if (> address hexl-max-address)
 362                                      (progn
 363                                        (message "End of buffer.")
 364                                        (setq address hexl-max-address))
 365                                    (setq address (+ address 8))))
 366                                (setq arg (1- arg)))
 367                              (if (> address hexl-max-address)
 368                                  (progn
 369                                    (message "End of buffer.")
 370                                    (setq address hexl-max-address))
 371                                (setq address (logior address 7))))
 372                          (while (> arg 0)
 373                            (if (not (equal address (logand address -8)))
 374                                (setq address (logand address -8))
 375                              (if (not (equal address 0))
 376                                  (setq address (- address 8))
 377                                (message "Beginning of buffer.")))
 378                            (setq arg (1- arg))))
 379                        address)))
 380
 381 (defun hexl-forward-word (arg)
 382   "Move right ARG words (left if ARG negative) in hexl-mode."
 383   (interactive "p")
 384   (hexl-backward-word (- arg)))
 385
 386 (defun hexl-previous-line (arg)
 387   "Move vertically up ARG lines [16 bytes] (down if ARG negative) in hexl-mode.
 388 If there is byte at the target address move to the last byte in that line."
 389   (interactive "p")
 390   (hexl-next-line (- arg)))
 391
 392 (defun hexl-next-line (arg)
 393   "Move vertically down ARG lines [16 bytes] (up if ARG negative) in hexl-mode.
 394 If there is no byte at the target address move to the last byte in that line."
 395   (interactive "p")
 396   (hexl-goto-address (let ((address (+ (hexl-current-address) (* arg 16))))
 397                        (if (and (< arg 0) (< address 0))
 398                                 (progn (message "Out of hexl region.")
 399                                        (setq address
 400                                              (% (hexl-current-address) 16)))
 401                          (if (and (> address hexl-max-address)
 402                                   (< (% hexl-max-address 16) (% address 16)))
 403                              (setq address hexl-max-address)
 404                            (if (> address hexl-max-address)
 405                                (progn (message "Out of hexl region.")
 406                                       (setq
 407                                        address
 408                                        (+ (logand hexl-max-address -16)
 409                                           (% (hexl-current-address) 16)))))))
 410                        address)))
 411
 412 (defun hexl-beginning-of-buffer (arg)
 413   "Move to the beginning of the hexl buffer.
 414 Leaves `hexl-mark' at previous position.
 415 With prefix arg N, puts point N bytes of the way from the true beginning."
 416   (interactive "p")
 417   (push-mark (point))
 418   (hexl-goto-address (+ 0 (1- arg))))
 419
 420 (defun hexl-end-of-buffer (arg)
 421   "Go to `hexl-max-address' minus ARG."
 422   (interactive "p")
 423   (push-mark (point))
 424   (hexl-goto-address (- hexl-max-address (1- arg))))
 425
 426 (defun hexl-beginning-of-line ()
 427   "Goto beginning of line in hexl mode."
 428   (interactive)
 429   (goto-char (+ (* (/ (point) 68) 68) 11)))
 430
 431 (defun hexl-end-of-line ()
 432   "Goto end of line in hexl mode."
 433   (interactive)
 434   (hexl-goto-address (let ((address (logior (hexl-current-address) 15)))
 435                        (if (> address hexl-max-address)
 436                            (setq address hexl-max-address))
 437                        address)))
 438
 439 (defun hexl-scroll-down (arg)
 440   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 441   (interactive "P")
 442   (if (null arg)
 443       (setq arg (1- (window-height)))
 444     (setq arg (prefix-numeric-value arg)))
 445   (hexl-scroll-up (- arg)))
 446
 447 (defun hexl-scroll-up (arg)
 448   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 449   (interactive "P")
 450   (if (null arg)
 451       (setq arg (1- (window-height)))
 452     (setq arg (prefix-numeric-value arg)))
 453   (let ((movement (* arg 16))
 454         (address (hexl-current-address)))
 455     (if (or (> (+ address movement) hexl-max-address)
 456             (< (+ address movement) 0))
 457         (message "Out of hexl region.")
 458       (hexl-goto-address (+ address movement))
 459       (recenter 0))))
 460
 461 (defun hexl-beginning-of-1k-page ()
 462   "Goto to beginning of 1k boundry."
 463   (interactive)
 464   (hexl-goto-address (logand (hexl-current-address) -1024)))
 465
 466 (defun hexl-end-of-1k-page ()
 467   "Goto to end of 1k boundry."
 468   (interactive)
 469   (hexl-goto-address (let ((address (logior (hexl-current-address) 1023)))
 470                        (if (> address hexl-max-address)
 471                            (setq address hexl-max-address))
 472                        address)))
 473
 474 (defun hexl-beginning-of-512b-page ()
 475   "Goto to beginning of 512 byte boundry."
 476   (interactive)
 477   (hexl-goto-address (logand (hexl-current-address) -512)))
 478
 479 (defun hexl-end-of-512b-page ()
 480   "Goto to end of 512 byte boundry."
 481   (interactive)
 482   (hexl-goto-address (let ((address (logior (hexl-current-address) 511)))
 483                        (if (> address hexl-max-address)
 484                            (setq address hexl-max-address))
 485                        address)))
 486
 487 (defun hexl-quoted-insert (arg)
 488   "Read next input character and insert it.
 489 Useful for inserting control characters.
 490 You may also type up to 3 octal digits, to insert a character with that code"
 491   (interactive "p")
 492   (hexl-insert-char (read-quoted-char) arg))
 493
 494 ;00000000: 0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789ABCDEF
 495
 496 ;;;###autoload
 497 (defun hexlify-buffer ()
 498   "Convert a binary buffer to hexl format"
 499   (interactive)
 500   (shell-command-on-region (point-min) (point-max) hexlify-command t))
 501
 502 (defun dehexlify-buffer ()
 503   "Convert a hexl format buffer to binary."
 504   (interactive)
 505   (let ((binary-process t)) ; for Ms-Dos
 506     (shell-command-on-region (point-min) (point-max) dehexlify-command t)))
 507
 508 (defun hexl-char-after-point ()
 509   "Return char for ASCII hex digits at point."
 510   (hexl-htoi (char-after (point))
 511              (char-after (1+ (point)))))
 512
 513 (defun hexl-htoi (lh rh)
 514   "Hex (char) LH (char) RH to integer."
 515     (+ (* (hexl-hex-char-to-integer lh) 16)
 516        (hexl-hex-char-to-integer rh)))
 517
 518 (defun hexl-hex-char-to-integer (character)
 519   "Take a char and return its value as if it was a hex digit."
 520   (if (and (>= character ?0) (<= character ?9))
 521       (- character ?0)
 522     (let ((ch (logior character 32)))
 523       (if (and (>= ch ?a) (<= ch ?f))
 524           (- ch (- ?a 10))
 525         (error (format "Invalid hex digit `%c'." ch))))))
 526
 527 (defun hexl-oct-char-to-integer (character)
 528   "Take a char and return its value as if it was a octal digit."
 529   (if (and (>= character ?0) (<= character ?7))
 530       (- character ?0)
 531     (error (format "Invalid octal digit `%c'." character))))
 532
 533 (defun hexl-printable-character (ch)
 534   "Return a displayable string for character CH."
 535   (format "%c" (if hexl-iso
 536                    (if (or (< ch 32) (and (>= ch 127) (< ch 160)))
 537                        46
 538                      ch)
 539                  (if (or (< ch 32) (>= ch 127))
 540                      46
 541                    ch))))
 542
 543 (defun hexl-self-insert-command (arg)
 544   "Insert this character."
 545   (interactive "p")
 546   (hexl-insert-char last-command-char arg))
 547
 548 (defun hexl-insert-char (ch num)
 549   "Insert a character in a hexl buffer."
 550   (let ((address (hexl-current-address)))
 551     (while (> num 0)
 552       (delete-char 2)
 553       (insert (format "%02x" ch))
 554       (goto-char
 555        (+ (* (/ address 16) 68) 52 (% address 16)))
 556       (delete-char 1)
 557       (insert (hexl-printable-character ch))
 558       (if (eq address hexl-max-address)
 559           (hexl-goto-address address)
 560         (hexl-goto-address (1+ address)))
 561       (setq num (1- num)))))
 562
 563 ;; hex conversion
 564
 565 (defun hexl-insert-hex-char (arg)
 566   "Insert a ASCII char ARG times at point for a given hexadecimal number."
 567   (interactive "p")
 568   (let ((num (hexl-hex-string-to-integer (read-string "Hex number: "))))
 569     (if (or (> num 255) (< num 0))
 570         (error "Hex number out of range.")
 571       (hexl-insert-char num arg))))
 572
 573 (defun hexl-insert-decimal-char (arg)
 574   "Insert a ASCII char ARG times at point for a given decimal number."
 575   (interactive "p")
 576   (let ((num (string-to-int (read-string "Decimal Number: "))))
 577     (if (or (> num 255) (< num 0))
 578         (error "Decimal number out of range.")
 579       (hexl-insert-char num arg))))
 580
 581 (defun hexl-insert-octal-char (arg)
 582   "Insert a ASCII char ARG times at point for a given octal number."
 583   (interactive "p")
 584   (let ((num (hexl-octal-string-to-integer (read-string "Octal Number: "))))
 585     (if (or (> num 255) (< num 0))
 586         (error "Decimal number out of range.")
 587       (hexl-insert-char num arg))))
 588
 589 ;; startup stuff.
 590
 591 (if hexl-mode-map
 592     nil
 593     (setq hexl-mode-map (make-sparse-keymap))
 594
 595     (define-key hexl-mode-map "\C-a" 'hexl-beginning-of-line)
 596     (define-key hexl-mode-map "\C-b" 'hexl-backward-char)
 597     (define-key hexl-mode-map "\C-d" 'undefined)
 598     (define-key hexl-mode-map "\C-e" 'hexl-end-of-line)
 599     (define-key hexl-mode-map "\C-f" 'hexl-forward-char)
 600
 601     (if (not (eq (key-binding (char-to-string help-char)) 'help-command))
 602         (define-key hexl-mode-map help-char 'undefined))
 603
 604     (define-key hexl-mode-map "\C-i" 'hexl-self-insert-command)
 605     (define-key hexl-mode-map "\C-j" 'hexl-self-insert-command)
 606     (define-key hexl-mode-map "\C-k" 'undefined)
 607     (define-key hexl-mode-map "\C-m" 'hexl-self-insert-command)
 608     (define-key hexl-mode-map "\C-n" 'hexl-next-line)
 609     (define-key hexl-mode-map "\C-o" 'undefined)
 610     (define-key hexl-mode-map "\C-p" 'hexl-previous-line)
 611     (define-key hexl-mode-map "\C-q" 'hexl-quoted-insert)
 612     (define-key hexl-mode-map "\C-t" 'undefined)
 613     (define-key hexl-mode-map "\C-v" 'hexl-scroll-up)
 614     (define-key hexl-mode-map "\C-w" 'undefined)
 615     (define-key hexl-mode-map "\C-y" 'undefined)
 616
 617     (let ((ch 32))
 618       (while (< ch 127)
 619         (define-key hexl-mode-map (format "%c" ch) 'hexl-self-insert-command)
 620         (setq ch (1+ ch))))
 621
 622     (define-key hexl-mode-map "\e\C-a" 'hexl-beginning-of-512b-page)
 623     (define-key hexl-mode-map "\e\C-b" 'hexl-backward-short)
 624     (define-key hexl-mode-map "\e\C-c" 'undefined)
 625     (define-key hexl-mode-map "\e\C-d" 'hexl-insert-decimal-char)
 626     (define-key hexl-mode-map "\e\C-e" 'hexl-end-of-512b-page)
 627     (define-key hexl-mode-map "\e\C-f" 'hexl-forward-short)
 628     (define-key hexl-mode-map "\e\C-g" 'undefined)
 629     (define-key hexl-mode-map "\e\C-h" 'undefined)
 630     (define-key hexl-mode-map "\e\C-i" 'undefined)
 631     (define-key hexl-mode-map "\e\C-j" 'undefined)
 632     (define-key hexl-mode-map "\e\C-k" 'undefined)
 633     (define-key hexl-mode-map "\e\C-l" 'undefined)
 634     (define-key hexl-mode-map "\e\C-m" 'undefined)
 635     (define-key hexl-mode-map "\e\C-n" 'undefined)
 636     (define-key hexl-mode-map "\e\C-o" 'hexl-insert-octal-char)
 637     (define-key hexl-mode-map "\e\C-p" 'undefined)
 638     (define-key hexl-mode-map "\e\C-q" 'undefined)
 639     (define-key hexl-mode-map "\e\C-r" 'undefined)
 640     (define-key hexl-mode-map "\e\C-s" 'undefined)
 641     (define-key hexl-mode-map "\e\C-t" 'undefined)
 642     (define-key hexl-mode-map "\e\C-u" 'undefined)
 643
 644     (define-key hexl-mode-map "\e\C-w" 'undefined)
 645     (define-key hexl-mode-map "\e\C-x" 'hexl-insert-hex-char)
 646     (define-key hexl-mode-map "\e\C-y" 'undefined)
 647
 648     (define-key hexl-mode-map "\ea" 'undefined)
 649     (define-key hexl-mode-map "\eb" 'hexl-backward-word)
 650     (define-key hexl-mode-map "\ec" 'undefined)
 651     (define-key hexl-mode-map "\ed" 'undefined)
 652     (define-key hexl-mode-map "\ee" 'undefined)
 653     (define-key hexl-mode-map "\ef" 'hexl-forward-word)
 654     (define-key hexl-mode-map "\eg" 'hexl-goto-hex-address)
 655     (define-key hexl-mode-map "\eh" 'undefined)
 656     (define-key hexl-mode-map "\ei" 'undefined)
 657     (define-key hexl-mode-map "\ej" 'hexl-goto-address)
 658     (define-key hexl-mode-map "\ek" 'undefined)
 659     (define-key hexl-mode-map "\el" 'undefined)
 660     (define-key hexl-mode-map "\em" 'undefined)
 661     (define-key hexl-mode-map "\en" 'undefined)
 662     (define-key hexl-mode-map "\eo" 'undefined)
 663     (define-key hexl-mode-map "\ep" 'undefined)
 664     (define-key hexl-mode-map "\eq" 'undefined)
 665     (define-key hexl-mode-map "\er" 'undefined)
 666     (define-key hexl-mode-map "\es" 'undefined)
 667     (define-key hexl-mode-map "\et" 'undefined)
 668     (define-key hexl-mode-map "\eu" 'undefined)
 669     (define-key hexl-mode-map "\ev" 'hexl-scroll-down)
 670     (define-key hexl-mode-map "\ey" 'undefined)
 671     (define-key hexl-mode-map "\ez" 'undefined)
 672     (define-key hexl-mode-map "\e<" 'hexl-beginning-of-buffer)
 673     (define-key hexl-mode-map "\e>" 'hexl-end-of-buffer)
 674
 675     (define-key hexl-mode-map "\C-c\C-c" 'hexl-mode-exit)
 676
 677     (define-key hexl-mode-map "\C-x[" 'hexl-beginning-of-1k-page)
 678     (define-key hexl-mode-map "\C-x]" 'hexl-end-of-1k-page)
 679     (define-key hexl-mode-map "\C-x\C-p" 'undefined)
 680     (define-key hexl-mode-map "\C-x\C-s" 'hexl-save-buffer)
 681     (define-key hexl-mode-map "\C-x\C-t" 'undefined))
 682
 683 ;;; hexl.el ends here