lisp/timezone.el

   1 ;;; Timezone package for GNU Emacs
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993 Free Software Foundation, Inc.
   4
   5 ;;; Author: Masanobu Umeda
   6 ;;; Maintainer: umerin@mse.kyutech.ac.jp
   7 ;;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Code:
  26
  27 (provide 'timezone)
  28
  29 (defvar timezone-world-timezones
  30   '(("PST" .  -800)
  31     ("PDT" .  -700)
  32     ("MST" .  -700)
  33     ("MDT" .  -600)
  34     ("CST" .  -600)
  35     ("CDT" .  -500)
  36     ("EST" .  -500)
  37     ("EDT" .  -400)
  38     ("AST" .  -400)                     ;by <clamen@CS.CMU.EDU>
  39     ("NST" .  -330)                     ;by <clamen@CS.CMU.EDU>
  40     ("GMT" .  +000)
  41     ("BST" .  +100)
  42     ("MET" .  +100)
  43     ("EET" .  +200)
  44     ("JST" .  +900)
  45     ("GMT+1"  .  +100) ("GMT+2"  .  +200) ("GMT+3"  .  +300)
  46     ("GMT+4"  .  +400) ("GMT+5"  .  +500) ("GMT+6"  .  +600)
  47     ("GMT+7"  .  +700) ("GMT+8"  .  +800) ("GMT+9"  .  +900)
  48     ("GMT+10" . +1000) ("GMT+11" . +1100) ("GMT+12" . +1200) ("GMT+13" . +1300)
  49     ("GMT-1"  .  -100) ("GMT-2"  .  -200) ("GMT-3"  .  -300)
  50     ("GMT-4"  .  -400) ("GMT-5"  .  -500) ("GMT-6"  .  -600)
  51     ("GMT-7"  .  -700) ("GMT-8"  .  -800) ("GMT-9"  .  -900)
  52     ("GMT-10" . -1000) ("GMT-11" . -1100) ("GMT-12" . -1200))
  53   "*Time differentials of timezone from GMT in +-HHMM form.
  54 This list is obsolescent, and is present only for backwards compatibility,
  55 because time zone names are ambiguous in practice.
  56 Use `current-time-zone' instead.")
  57
  58 (defvar timezone-months-assoc
  59   '(("JAN" .  1)("FEB" .  2)("MAR" .  3)
  60     ("APR" .  4)("MAY" .  5)("JUN" .  6)
  61     ("JUL" .  7)("AUG" .  8)("SEP" .  9)
  62     ("OCT" . 10)("NOV" . 11)("DEC" . 12))
  63   "Alist of first three letters of a month and its numerical representation.")
  64
  65 (defun timezone-make-date-arpa-standard (date &optional local timezone)
  66   "Convert DATE to an arpanet standard date.
  67 Optional 1st argument LOCAL specifies the default local timezone of the DATE;
  68 if nil, GMT is assumed.
  69 Optional 2nd argument TIMEZONE specifies a time zone to be represented in;
  70 if nil, the local time zone is assumed."
  71   (let ((new (timezone-fix-time date local timezone)))
  72     (timezone-make-arpa-date (aref new 0) (aref new 1) (aref new 2)
  73                              (timezone-make-time-string
  74                               (aref new 3) (aref new 4) (aref new 5))
  75                              (aref new 6))
  76     ))
  77
  78 (defun timezone-make-date-sortable (date &optional local timezone)
  79   "Convert DATE to a sortable date string.
  80 Optional 1st argument LOCAL specifies the default local timezone of the DATE;
  81 if nil, GMT is assumed.
  82 Optional 2nd argument TIMEZONE specifies a timezone to be represented in;
  83 if nil, the local time zone is assumed."
  84   (let ((new (timezone-fix-time date local timezone)))
  85     (timezone-make-sortable-date (aref new 0) (aref new 1) (aref new 2)
  86                                  (timezone-make-time-string
  87                                   (aref new 3) (aref new 4) (aref new 5)))
  88     ))
  89
  90 \f
  91 ;;
  92 ;; Parsers and Constructors of Date and Time
  93 ;;
  94
  95 (defun timezone-make-arpa-date (year month day time &optional timezone)
  96   "Make arpanet standard date string from YEAR, MONTH, DAY, and TIME.
  97 Optional argument TIMEZONE specifies a time zone."
  98   (let ((zone
  99          (if (listp timezone)
 100              (let* ((m (timezone-zone-to-minute timezone))
 101                     (absm (if (< m 0) (- m) m)))
 102                (format "%c%02d%02d"
 103                        (if (< m 0) ?- ?+) (/ absm 60) (% absm 60)))
 104            timezone)))
 105     (format "%02d %s %04d %s %s"
 106             day
 107             (capitalize (car (rassq month timezone-months-assoc)))
 108             year
 109             time
 110             zone)))
 111
 112 (defun timezone-make-sortable-date (year month day time)
 113   "Make sortable date string from YEAR, MONTH, DAY, and TIME."
 114   (format "%4d%02d%02d%s"
 115           year month day time))
 116
 117 (defun timezone-make-time-string (hour minute second)
 118   "Make time string from HOUR, MINUTE, and SECOND."
 119   (format "%02d:%02d:%02d" hour minute second))
 120
 121 (defun timezone-parse-date (date)
 122   "Parse DATE and return a vector [YEAR MONTH DAY TIME TIMEZONE].
 123 19 is prepended to year if necessary.  Timezone may be nil if nothing.
 124 Understands the following styles:
 125  (1) 14 Apr 89 03:20[:12] [GMT]
 126  (2) Fri, 17 Mar 89 4:01[:33] [GMT]
 127  (3) Mon Jan 16 16:12[:37] [GMT] 1989
 128  (4) 6 May 1992 1641-JST (Wednesday)
 129  (5) 22-AUG-1993 10:59:12.82"
 130   (let ((date (or date ""))
 131         (year nil)
 132         (month nil)
 133         (day nil)
 134         (time nil)
 135         (zone nil))                     ;This may be nil.
 136     (cond ((string-match
 137             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\'" date)
 138            ;; Styles: (1) and (2) without timezone
 139            (setq year 3 month 2 day 1 time 4 zone nil))
 140           ((string-match
 141             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 142            ;; Styles: (1) and (2) with timezone and buggy timezone
 143            (setq year 3 month 2 day 1 time 4 zone 5))
 144           ((string-match
 145             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([0-9]+\\)" date)
 146            ;; Styles: (3) without timezone
 147            (setq year 4 month 1 day 2 time 3 zone nil))
 148           ((string-match
 149             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([-+a-zA-Z0-9]+\\)[ \t]+\\([0-9]+\\)" date)
 150            ;; Styles: (3) with timezone
 151            (setq year 5 month 1 day 2 time 3 zone 4))
 152           ((string-match
 153             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 154            ;; Styles: (4) with timezone
 155            (setq year 3 month 2 day 1 time 4 zone 5))
 156           ((string-match
 157             "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\.[0-9]+" date)
 158            ;; Styles: (5) without timezone.
 159            (setq year 3 month 2 day 1 time 4 zone nil))
 160           )
 161     (if year
 162         (progn
 163           (setq year
 164                 (substring date (match-beginning year) (match-end year)))
 165           ;; It is now Dec 1992.  8 years before the end of the World.
 166           (if (< (length year) 4)
 167               (setq year (concat "19" (substring year -2 nil))))
 168           (setq month
 169                 (int-to-string
 170                  (cdr
 171                   (assoc
 172                    (upcase
 173                     ;; Don't use `match-end' in order to take 3
 174                     ;; letters from the beginning.
 175                     (substring date
 176                                (match-beginning month)
 177                                (+ (match-beginning month) 3)))
 178                    timezone-months-assoc))))
 179           (setq day
 180                 (substring date (match-beginning day) (match-end day)))
 181           (setq time
 182                 (substring date (match-beginning time) (match-end time)))))
 183     (if zone
 184         (setq zone
 185               (substring date (match-beginning zone) (match-end zone))))
 186     ;; Return a vector.
 187     (if year
 188         (vector year month day time zone)
 189       (vector "0" "0" "0" "0" nil))
 190     ))
 191
 192 (defun timezone-parse-time (time)
 193   "Parse TIME (HH:MM:SS) and return a vector [hour minute second].
 194 Recognize HH:MM:SS, HH:MM, HHMMSS, HHMM."
 195   (let ((time (or time ""))
 196         (hour nil)
 197         (minute nil)
 198         (second nil))
 199     (cond ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 200            ;; HH:MM:SS
 201            (setq hour 1 minute 2 second 3))
 202           ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 203            ;; HH:MM
 204            (setq hour 1 minute 2 second nil))
 205           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 206            ;; HHMMSS
 207            (setq hour 1 minute 2 second 3))
 208           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 209            ;; HHMM
 210            (setq hour 1 minute 2 second nil))
 211           )
 212     ;; Return [hour minute second]
 213     (vector
 214      (if hour
 215          (substring time (match-beginning hour) (match-end hour)) "0")
 216      (if minute
 217          (substring time (match-beginning minute) (match-end minute)) "0")
 218      (if second
 219          (substring time (match-beginning second) (match-end second)) "0"))
 220     ))
 221
 222 \f
 223 ;; Miscellaneous
 224
 225 (defun timezone-zone-to-minute (timezone)
 226   "Translate TIMEZONE to an integer minute offset from GMT.
 227 TIMEZONE can be a cons cell containing the output of current-time-zone,
 228 or an integer of the form +-HHMM, or a time zone name."
 229   (cond
 230      ((consp timezone)
 231       (/ (car timezone) 60))
 232      (timezone
 233       (progn
 234         (setq timezone
 235               (or (cdr (assoc (upcase timezone) timezone-world-timezones))
 236                   ;; +900
 237                   timezone))
 238         (if (stringp timezone)
 239             (setq timezone (string-to-int timezone)))
 240         ;; Taking account of minute in timezone.
 241         ;; HHMM -> MM
 242         (let* ((abszone (abs timezone))
 243                (minutes (+ (* 60 (/ abszone 100)) (% abszone 100))))
 244           (if (< timezone 0) (- minutes) minutes))))
 245      (t 0)))
 246
 247 (defun timezone-time-from-absolute (date seconds)
 248   "Compute the UTC time equivalent to DATE at time SECONDS after midnight.
 249 Return a list suitable as an argument to current-time-zone,
 250 or nil if the date cannot be thus represented.
 251 DATE is the number of days elapsed since the (imaginary)
 252 Gregorian date Sunday, December 31, 1 BC."
 253   (let* ((current-time-origin 719162)
 254             ;; (timezone-absolute-from-gregorian 1 1 1970)
 255          (days (- date current-time-origin))
 256          (seconds-per-day (float 86400))
 257          (seconds (+ seconds (* days seconds-per-day)))
 258          (current-time-arithmetic-base (float 65536))
 259          (hi (floor (/ seconds current-time-arithmetic-base)))
 260          (hibase (* hi current-time-arithmetic-base))
 261          (lo (floor (- seconds hibase))))
 262      (and (< (abs (- seconds (+ hibase lo))) 2) ;; Check for integer overflow.
 263           (cons hi lo))))
 264
 265 (defun timezone-time-zone-from-absolute (date seconds)
 266   "Compute the local time zone for DATE at time SECONDS after midnight.
 267 Return a list in the same format as current-time-zone's result,
 268 or nil if the local time zone could not be computed.
 269 DATE is the number of days elapsed since the (imaginary)
 270 Gregorian date Sunday, December 31, 1 BC."
 271    (and (fboundp 'current-time-zone)
 272         (let ((utc-time (timezone-time-from-absolute date seconds)))
 273           (and utc-time
 274                (let ((zone (current-time-zone utc-time)))
 275                  (and (car zone) zone))))))
 276
 277 (defun timezone-fix-time (date local timezone)
 278   "Convert DATE (default timezone LOCAL) to YYYY-MM-DD-HH-MM-SS-ZONE vector.
 279 If LOCAL is nil, it is assumed to be GMT.
 280 If TIMEZONE is nil, use the local time zone."
 281   (let* ((date   (timezone-parse-date date))
 282          (year   (string-to-int (aref date 0)))
 283          (year   (if (< year 100) (+ year 1900) year))
 284          (month  (string-to-int (aref date 1)))
 285          (day    (string-to-int (aref date 2)))
 286          (time   (timezone-parse-time (aref date 3)))
 287          (hour   (string-to-int (aref time 0)))
 288          (minute (string-to-int (aref time 1)))
 289          (second (string-to-int (aref time 2)))
 290          (local  (or (aref date 4) local)) ;Use original if defined
 291          (timezone
 292           (or timezone
 293               (timezone-time-zone-from-absolute
 294                (timezone-absolute-from-gregorian month day year)
 295                (+ second (* 60 (+ minute (* 60 hour)))))))
 296          (diff   (- (timezone-zone-to-minute timezone)
 297                     (timezone-zone-to-minute local)))
 298          (minute (+ minute diff))
 299          (hour-fix (floor minute 60)))
 300     (setq hour (+ hour hour-fix))
 301     (setq minute (- minute (* 60 hour-fix)))
 302     ;; HOUR may be larger than 24 or smaller than 0.
 303     (cond ((<= 24 hour)                 ;24 -> 00
 304            (setq hour (- hour 24))
 305            (setq day  (1+ day))
 306            (if (< (timezone-last-day-of-month month year) day)
 307                (progn
 308                  (setq month (1+ month))
 309                  (setq day 1)
 310                  (if (< 12 month)
 311                      (progn
 312                        (setq month 1)
 313                        (setq year (1+ year))
 314                        ))
 315                  )))
 316           ((> 0 hour)
 317            (setq hour (+ hour 24))
 318            (setq day  (1- day))
 319            (if (> 1 day)
 320                (progn
 321                  (setq month (1- month))
 322                  (if (> 1 month)
 323                      (progn
 324                        (setq month 12)
 325                        (setq year (1- year))
 326                        ))
 327                  (setq day (timezone-last-day-of-month month year))
 328                  )))
 329           )
 330     (vector year month day hour minute second timezone)))
 331
 332 ;; Partly copied from Calendar program by Edward M. Reingold.
 333 ;; Thanks a lot.
 334
 335 (defun timezone-last-day-of-month (month year)
 336   "The last day in MONTH during YEAR."
 337   (if (and (= month 2) (timezone-leap-year-p year))
 338       29
 339     (aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
 340
 341 (defun timezone-leap-year-p (year)
 342   "Returns t if YEAR is a Gregorian leap year."
 343   (or (and (zerop  (% year 4))
 344            (not (zerop (% year 100))))
 345       (zerop (% year 400))))
 346
 347 (defun timezone-day-number (month day year)
 348   "Return the day number within the year of the date month/day/year."
 349   (let ((day-of-year (+ day (* 31 (1- month)))))
 350     (if (> month 2)
 351         (progn
 352           (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 353           (if (timezone-leap-year-p year)
 354               (setq day-of-year (1+ day-of-year)))))
 355     day-of-year))
 356
 357 (defun timezone-absolute-from-gregorian (month day year)
 358   "The number of days between the Gregorian date 12/31/1 BC and month/day/year.
 359 The Gregorian date Sunday, December 31, 1 BC is imaginary."
 360   (+ (timezone-day-number month day year);; Days this year
 361      (* 365 (1- year));;        + Days in prior years
 362      (/ (1- year) 4);;          + Julian leap years
 363      (- (/ (1- year) 100));;    - century years
 364      (/ (1- year) 400)));;      + Gregorian leap years
 365
 366 ;;; timezone.el ends here