lisp/uniquify.el

   1 ;;; uniquify.el --- unique buffer names dependent on file name
   2
   3 ;; Copyright (C) 1989, 1995, 1996, 1997, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Dick King <king@reasoning.com>
   7 ;; Maintainer: FSF
   8 ;; Keywords: files
   9 ;; Created: 15 May 86
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; Emacs's standard method for making buffer names unique adds <2>, <3>,
  31 ;; etc.. to the end of (all but one of) the buffers.  This file replaces
  32 ;; that behavior, for buffers visiting files and dired buffers, with a
  33 ;; uniquification that adds parts of the file name until the buffer names
  34 ;; are unique.  For instance, buffers visiting /u/mernst/tmp/Makefile and
  35 ;; /usr/projects/zaphod/Makefile would be named Makefile|tmp and
  36 ;; Makefile|zaphod, respectively (instead of Makefile and Makefile<2>).
  37 ;; Other buffer name styles are also available.
  38
  39 ;; To use this file, do (require 'uniquify)
  40 ;; and set uniquify-buffer-name-style to one of its non-nil alternative values.
  41
  42 ;; For other options, see "User-visible variables", below.
  43
  44 ;; A version of uniquify.el that works under Emacs 18, Emacs 19, XEmacs,
  45 ;; and InfoDock is available from the maintainer.
  46
  47 ;;; Change Log:
  48
  49 ;; Originally by Dick King <king@reasoning.com> 15 May 86
  50 ;; Converted for Emacs 18 by Stephen Gildea <gildea@stop.mail-abuse.org>
  51 ;; Make uniquify-min-dir-content 0 truly non-invasive.  gildea 23 May 89
  52 ;; Some cleanup.  uniquify-min-dir-content default 0.  gildea 01 Jun 89
  53 ;; Don't rename to "".  Michael Ernst <mernst@theory.lcs.mit.edu> 15 Jun 94
  54 ;; Add kill-buffer-hook.  Kenneth Manheimer <ken.manheimer@nist.gov> 09 May 95
  55 ;; Add advice for rename-buffer and create-file-buffer, handle dired buffers,
  56 ;;  kill-buffer-rationalize-buffer-names-p, documentation.  mernst 24 May 95
  57 ;; Remove free variables, fix typos.  mernst 5 Jun 95
  58 ;; Efficiently support Emacs 19.27 & earlier.  ken.manheimer, mernst 10 Jun 95
  59 ;; Rename user options to "uniquify-...", add uniquify-reverse-dir-content-p,
  60 ;;  add uniquify-ask-about-buffer-names-p.  king, mernst 13 Jun 95
  61 ;; Prefix functions by "uniquify-..."; rename mnemonic-buffer-names to
  62 ;;  uniquify-buffer-name-style; add 'forward and 'post-forward-angle-brackets
  63 ;;  styles; remove uniquify-reverse-dir-content-p; add
  64 ;;  uniquify-trailing-separator-p.  mernst 4 Aug 95
  65 ;; Don't call expand-file-name on nil.  mernst 7 Jan 96
  66 ;; Check whether list-buffers-directory is bound.  mernst 11 Oct 96
  67 ;; Ignore non-file non-dired buffers. Colin Rafferty <craffert@ml.com> 3 Mar 97
  68 ;; Use last component, not "", for file name of directories.  mernst 27 Jun 97
  69 ;; Use directory-file-name; code cleanup.  mernst 6 Sep 97
  70 ;; Add uniquify-ignore-buffers-re.
  71 ;;  Andre Srinivasan <andre@visigenic.com> 9 Sep 97
  72 ;; Add uniquify-list-buffers-directory-modes
  73 ;;   Stefan Monnier <monnier@cs.yale.edu> 17 Nov 2000
  74 ;; Algorithm and data structure changed to reduce consing with lots of buffers
  75 ;;   Francesco Potortì <pot@gnu.org> (ideas by rms and monnier) 2001-07-18
  76
  77 ;; Valuable feedback was provided by
  78 ;; Paul Smith <psmith@baynetworks.com>,
  79 ;; Alastair Burt <burt@dfki.uni-kl.de>,
  80 ;; Bob Weiner <weiner@footloose.sps.mot.com>,
  81 ;; Albert L. Ting <alt@vlibs.com>,
  82 ;; gyro@reasoning.com,
  83 ;; Bryan O'Sullivan <bos@eng.sun.com>.
  84
  85
  86 ;;; Code:
  87
  88 (eval-when-compile (require 'cl))
  89
  90 ;;; User-visible variables
  91
  92 (defgroup uniquify nil
  93   "Unique buffer names dependent on file name."
  94   :group 'applications)
  95
  96
  97 (defcustom uniquify-buffer-name-style nil
  98   "If non-nil, buffer names are uniquified with parts of directory name.
  99 The value determines the buffer name style and is one of `forward',
 100 `reverse', `post-forward', or `post-forward-angle-brackets'.
 101 For example, files `/foo/bar/mumble/name' and `/baz/quux/mumble/name'
 102 would have the following buffer names in the various styles:
 103   forward        bar/mumble/name  quux/mumble/name
 104   reverse        name\\mumble\\bar  name\\mumble\\quux
 105   post-forward   name|bar/mumble  name|quux/mumble
 106   post-forward-angle-brackets   name<bar/mumble>  name<quux/mumble>
 107   nil            name  name<2>
 108 Of course, the \"mumble\" part may be stripped as well, depending on the setting
 109 of `uniquify-strip-common-suffix'."
 110   :type '(radio (const forward)
 111                 (const reverse)
 112                 (const post-forward)
 113                 (const post-forward-angle-brackets)
 114                 (const :tag "standard Emacs behavior (nil)" nil))
 115   :require 'uniquify
 116   :group 'uniquify)
 117
 118 (defcustom uniquify-after-kill-buffer-p t
 119   "If non-nil, rerationalize buffer names after a buffer has been killed."
 120   :type 'boolean
 121   :group 'uniquify)
 122
 123 (defcustom uniquify-ask-about-buffer-names-p nil
 124   "If non-nil, permit user to choose names for buffers with same base file.
 125 If the user chooses to name a buffer, uniquification is preempted and no
 126 other buffer names are changed."
 127   :type 'boolean
 128   :group 'uniquify)
 129
 130 ;; The default value matches certain Gnus buffers.
 131 (defcustom uniquify-ignore-buffers-re nil
 132   "Regular expression matching buffer names that should not be uniquified.
 133 For instance, set this to \"^draft-[0-9]+$\" to avoid having uniquify rename
 134 draft buffers even if `uniquify-after-kill-buffer-p' is non-nil and the
 135 visited file name isn't the same as that of the buffer."
 136   :type '(choice (const :tag "Uniquify all buffers" nil) regexp)
 137   :group 'uniquify)
 138
 139 (defcustom uniquify-min-dir-content 0
 140   "Minimum number of directory name components included in buffer name."
 141   :type 'integer
 142   :group 'uniquify)
 143
 144 (defcustom uniquify-separator nil
 145   "String separator for buffer name components.
 146 When `uniquify-buffer-name-style' is `post-forward', separates
 147 base file name from directory part in buffer names (default \"|\").
 148 When `uniquify-buffer-name-style' is `reverse', separates all
 149 file name components (default \"\\\")."
 150   :type '(choice (const nil) string)
 151   :group 'uniquify)
 152
 153 (defcustom uniquify-trailing-separator-p nil
 154   "If non-nil, add a file name separator to dired buffer names.
 155 If `uniquify-buffer-name-style' is `forward', add the separator at the end;
 156 if it is `reverse', add the separator at the beginning; otherwise, this
 157 variable is ignored."
 158   :type 'boolean
 159   :group 'uniquify)
 160
 161 (defcustom uniquify-strip-common-suffix
 162   ;; Using it when uniquify-min-dir-content>0 doesn't make much sense.
 163   (eq 0 uniquify-min-dir-content)
 164   "If non-nil, strip common directory suffixes of conflicting files.
 165 E.g. if you open /a1/b/c/d and /a2/b/c/d, the buffer names will say
 166 \"d|a1\" and \"d|a2\" instead of \"d|a1/b/c\" and \"d|a2/b/c\".
 167 This can be handy when you have deep parallel hierarchies."
 168   :type 'boolean
 169   :group 'uniquify)
 170
 171 (defvar uniquify-list-buffers-directory-modes '(dired-mode cvs-mode)
 172   "List of modes for which uniquify should obey `list-buffers-directory'.
 173 That means that when `buffer-file-name' is set to nil, `list-buffers-directory'
 174 contains the name of the directory which the buffer is visiting.")
 175
 176 ;;; Utilities
 177
 178 ;; uniquify-fix-list data structure
 179 (defstruct (uniquify-item
 180             (:constructor nil) (:copier nil)
 181             (:constructor uniquify-make-item
 182              (base dirname buffer &optional proposed)))
 183   base dirname buffer proposed)
 184
 185 ;; Internal variables used free
 186 (defvar uniquify-possibly-resolvable nil)
 187
 188 (defvar uniquify-managed nil
 189   "Non-nil if the name of this buffer is managed by uniquify.
 190 It actually holds the list of `uniquify-item's corresponding to the conflict.")
 191 (make-variable-buffer-local 'uniquify-managed)
 192 (put 'uniquify-managed 'permanent-local t)
 193
 194 ;;; Main entry point.
 195
 196 (defun uniquify-rationalize-file-buffer-names (base dirname newbuf)
 197   "Make file buffer names unique by adding segments from file name.
 198 If `uniquify-min-dir-content' > 0, always pulls that many
 199 file name elements.
 200 Arguments BASE, DIRNAME, and NEWBUF specify the new buffer that causes
 201 this rationalization."
 202   (interactive
 203    (list (if uniquify-managed
 204              (uniquify-item-base (car uniquify-managed)) (buffer-name))
 205          (uniquify-buffer-file-name (current-buffer))
 206          (current-buffer)))
 207   ;; Make sure we don't get confused by outdated uniquify-managed info in
 208   ;; this buffer.
 209   (with-current-buffer newbuf (setq uniquify-managed nil))
 210   (when dirname
 211     (setq dirname (expand-file-name (directory-file-name dirname)))
 212     (let ((fix-list (list (uniquify-make-item base dirname newbuf)))
 213           items)
 214       (dolist (buffer (buffer-list))
 215         (when (and (not (and uniquify-ignore-buffers-re
 216                              (string-match uniquify-ignore-buffers-re
 217                                            (buffer-name buffer))))
 218                    ;; Only try to rename buffers we actually manage.
 219                    (setq items (buffer-local-value 'uniquify-managed buffer))
 220                    (equal base (uniquify-item-base (car items)))
 221                    ;; Don't re-add stuff we already have.  Actually this
 222                    ;; whole `and' test should only match at most once.
 223                    (not (memq (car items) fix-list)))
 224           (unless (cdr items)
 225             ;; If there was no conflict, the buffer-name is equal to the
 226             ;; base-name and we may have missed a rename-buffer because
 227             ;; of code like in set-visited-file-name:
 228             ;; (or (string= new-name (buffer-name)) (rename-buffer new-name t))
 229             ;; So we need to refresh the dirname of the uniquify-item.
 230             (setf (uniquify-item-dirname (car items))
 231                   (uniquify-buffer-file-name
 232                    (uniquify-item-buffer (car items))))
 233             ;; This shouldn't happen, but maybe there's no dirname any more.
 234             (unless (uniquify-item-dirname (car items))
 235               (with-current-buffer (uniquify-item-buffer (car items))
 236                 (setq uniquify-managed nil))
 237               (setq items nil)))
 238           ;; In case we missed some calls to kill-buffer, there may be dead
 239           ;; buffers in uniquify-managed, so filter them out.
 240           (setq items
 241                 (delq nil (mapcar
 242                            (lambda (item)
 243                              (if (buffer-live-p (uniquify-item-buffer item))
 244                                  item))
 245                            items)))
 246           (setq fix-list (append fix-list items))))
 247       ;; selects buffers whose names may need changing, and others that
 248       ;; may conflict, then bring conflicting names together
 249       (uniquify-rationalize fix-list))))
 250
 251 ;; uniquify's version of buffer-file-name; result never contains trailing slash
 252 (defun uniquify-buffer-file-name (buffer)
 253   "Return name of directory, file BUFFER is visiting, or nil if none.
 254 Works on ordinary file-visiting buffers and buffers whose mode is mentioned
 255 in `uniquify-list-buffers-directory-modes', otherwise returns nil."
 256   (with-current-buffer buffer
 257     (let ((filename
 258            (or buffer-file-name
 259                (if (memq major-mode uniquify-list-buffers-directory-modes)
 260                    list-buffers-directory))))
 261       (when filename
 262         (directory-file-name
 263          (file-name-directory
 264           (expand-file-name
 265            (directory-file-name filename))))))))
 266
 267 (defun uniquify-rerationalize-w/o-cb (fix-list)
 268   "Re-rationalize the buffers in FIX-LIST, but ignoring `current-buffer'."
 269   (let ((new-fix-list nil))
 270     (dolist (item fix-list)
 271       (let ((buf (uniquify-item-buffer item)))
 272         (unless (or (eq buf (current-buffer)) (not (buffer-live-p buf)))
 273           (push item new-fix-list))))
 274     (when new-fix-list
 275       (uniquify-rationalize new-fix-list))))
 276
 277 (defun uniquify-rationalize (fix-list)
 278   ;; Set up uniquify to re-rationalize after killing/renaming
 279   ;; if there is a conflict.
 280   (dolist (item fix-list)
 281     (with-current-buffer (uniquify-item-buffer item)
 282       ;; Refresh the dirnames and proposed names.
 283       (setf (uniquify-item-proposed item)
 284             (uniquify-get-proposed-name (uniquify-item-base item)
 285                                         (uniquify-item-dirname item)))
 286       (setq uniquify-managed fix-list)))
 287   ;; Strip any shared last directory names of the dirname.
 288   (when (and (cdr fix-list) uniquify-strip-common-suffix)
 289     (let ((strip t))
 290       (while (let* ((base (file-name-nondirectory
 291                            (uniquify-item-dirname (car fix-list))))
 292                     (items fix-list))
 293                (when (> (length base) 0)
 294                  (while (and strip items)
 295                    (unless (equal base (file-name-nondirectory
 296                                         (uniquify-item-dirname (pop items))))
 297                      (setq strip nil)))
 298                  strip))
 299         ;; It's all the same => strip.
 300         (dolist (item (prog1 fix-list (setq fix-list nil)))
 301           ;; Create new items because the old ones are kept (with the true
 302           ;; `dirname') for later rerationalizing.
 303           (push (uniquify-make-item (uniquify-item-base item)
 304                                     (let ((f (file-name-directory
 305                                               (uniquify-item-dirname item))))
 306                                       (and f (directory-file-name f)))
 307                                     (uniquify-item-buffer item)
 308                                     (uniquify-item-proposed item))
 309                 fix-list)))))
 310   ;; If uniquify-min-dir-content is 0, this will end up just
 311   ;; passing fix-list to uniquify-rationalize-conflicting-sublist.
 312   (uniquify-rationalize-a-list fix-list))
 313
 314 (defun uniquify-item-greaterp (item1 item2)
 315   (string-lessp (uniquify-item-proposed item2)
 316                 (uniquify-item-proposed item1)))
 317
 318 (defun uniquify-rationalize-a-list (fix-list &optional depth)
 319   (unless depth (setq depth uniquify-min-dir-content))
 320   (let (conflicting-sublist     ; all elements have the same proposed name
 321         (old-proposed "")
 322         proposed)
 323     ;; Divide fix-list into items with same proposed names and pass them
 324     ;; to uniquify-rationalize-conflicting-sublist.
 325     (dolist (item (sort fix-list 'uniquify-item-greaterp))
 326       (setq proposed (uniquify-item-proposed item))
 327       (unless (equal proposed old-proposed)
 328         (uniquify-rationalize-conflicting-sublist conflicting-sublist
 329                                                   old-proposed depth)
 330         (setq conflicting-sublist nil))
 331       (push item conflicting-sublist)
 332       (setq old-proposed proposed))
 333     (uniquify-rationalize-conflicting-sublist conflicting-sublist
 334                                               old-proposed depth)))
 335
 336 (defun uniquify-get-proposed-name (base dirname &optional depth)
 337   (unless depth (setq depth uniquify-min-dir-content))
 338   (assert (equal (directory-file-name dirname) dirname))  ;No trailing slash.
 339
 340   ;; Distinguish directories by adding extra separator.
 341   (if (and uniquify-trailing-separator-p
 342            (file-directory-p (expand-file-name base dirname))
 343            (not (string-equal base "")))
 344       (cond ((eq uniquify-buffer-name-style 'forward)
 345              (setq base (file-name-as-directory base)))
 346             ;; (setq base (concat base "/")))
 347             ((eq uniquify-buffer-name-style 'reverse)
 348              (setq base (concat (or uniquify-separator "\\") base)))))
 349
 350   (let ((extra-string nil)
 351         (n depth))
 352     (while (and (> n 0) dirname)
 353       (let ((file (file-name-nondirectory dirname)))
 354         (when (setq dirname (file-name-directory dirname))
 355           (setq dirname (directory-file-name dirname)))
 356         (setq n (1- n))
 357         (push (if (zerop (length file)) ;nil or "".
 358                   (prog1 "" (setq dirname nil)) ;Could be `dirname' iso "".
 359                 file)
 360               extra-string)))
 361     (when (zerop n)
 362       (if (and dirname extra-string
 363                (equal dirname (file-name-directory dirname)))
 364           ;; We're just before the root.  Let's add the leading / already.
 365           ;; With "/a/b"+"/c/d/b" this leads to "/a/b" and "d/b" but with
 366           ;; "/a/b"+"/c/a/b" this leads to "/a/b" and "a/b".
 367           (push "" extra-string))
 368       (setq uniquify-possibly-resolvable t))
 369
 370     (cond
 371      ((null extra-string) base)
 372      ((string-equal base "") ;Happens for dired buffers on the root directory.
 373       (mapconcat 'identity extra-string "/"))
 374      ((eq uniquify-buffer-name-style 'reverse)
 375       (mapconcat 'identity
 376                  (cons base (nreverse extra-string))
 377                  (or uniquify-separator "\\")))
 378      ((eq uniquify-buffer-name-style 'forward)
 379       (mapconcat 'identity (nconc extra-string (list base))
 380                  "/"))
 381      ((eq uniquify-buffer-name-style 'post-forward)
 382       (concat base (or uniquify-separator "|")
 383               (mapconcat 'identity extra-string "/")))
 384      ((eq uniquify-buffer-name-style 'post-forward-angle-brackets)
 385       (concat base "<" (mapconcat 'identity extra-string "/")
 386               ">"))
 387      (t (error "Bad value for uniquify-buffer-name-style: %s"
 388                uniquify-buffer-name-style)))))
 389
 390
 391 ;; Deal with conflicting-sublist, all of whose elements have identical
 392 ;; "base" components.
 393 (defun uniquify-rationalize-conflicting-sublist (conf-list old-name depth)
 394   (when conf-list
 395     (if (or (cdr conf-list)
 396             ;; Check that the proposed name doesn't conflict with some
 397             ;; existing buffer.
 398             (let ((buf (get-buffer old-name)))
 399               (and buf (not (eq buf (uniquify-item-buffer (car conf-list)))))))
 400         (when uniquify-possibly-resolvable
 401           (setq uniquify-possibly-resolvable nil
 402                 depth (1+ depth))
 403           (dolist (item conf-list)
 404             (setf (uniquify-item-proposed item)
 405                   (uniquify-get-proposed-name
 406                    (uniquify-item-base item)
 407                    (uniquify-item-dirname item)
 408                    depth)))
 409           (uniquify-rationalize-a-list conf-list depth))
 410       (unless (string= old-name "")
 411         (uniquify-rename-buffer (car conf-list) old-name)))))
 412
 413
 414 (defun uniquify-rename-buffer (item newname)
 415   (let ((buffer (uniquify-item-buffer item)))
 416     (unless (equal newname (buffer-name buffer))
 417       (with-current-buffer buffer
 418         (let ((uniquify-buffer-name-style nil)) ;Avoid hooks on rename-buffer.
 419           ;; Pass the `unique' arg, so the advice doesn't mark it as unmanaged.
 420           (rename-buffer newname t))))))
 421
 422 ;;; Hooks from the rest of Emacs
 423
 424 ;; Buffer deletion
 425 ;; Rerationalize after a buffer is killed, to reduce coinciding buffer names.
 426 ;; This mechanism uses `kill-buffer-hook', which runs *before* deletion, so
 427 ;; it calls `uniquify-rerationalize-w/o-cb' to rerationalize the buffer list
 428 ;; ignoring the current buffer (which is going to be deleted anyway).
 429 (defun uniquify-maybe-rerationalize-w/o-cb ()
 430   "Re-rationalize buffer names, ignoring current buffer.
 431 For use on `kill-buffer-hook'."
 432   (if (and (cdr uniquify-managed)
 433            uniquify-buffer-name-style
 434            uniquify-after-kill-buffer-p)
 435       (uniquify-rerationalize-w/o-cb uniquify-managed)))
 436
 437 ;; Ideally we'd like to add it buffer-locally, but that doesn't work
 438 ;; because kill-buffer-hook is not permanent-local :-(
 439 (add-hook 'kill-buffer-hook 'uniquify-maybe-rerationalize-w/o-cb)
 440
 441 ;; The logical place to put all this code is in generate-new-buffer-name.
 442 ;; It's written in C, so we would add a generate-new-buffer-name-function
 443 ;; which, if non-nil, would be called instead of the C.  One problem with
 444 ;; that is that generate-new-buffer-name takes a potential buffer name as
 445 ;; its argument -- not other information, such as what file the buffer will
 446 ;; visit.
 447
 448 ;; The below solution works because generate-new-buffer-name is called
 449 ;; only by rename-buffer (which, as of 19.29, is never called from C) and
 450 ;; generate-new-buffer, which is called only by Lisp functions
 451 ;; create-file-buffer and rename-uniquely.  Rename-uniquely generally
 452 ;; isn't used for buffers visiting files, so it's sufficient to hook
 453 ;; rename-buffer and create-file-buffer.  (Setting find-file-hook isn't
 454 ;; sufficient.)
 455
 456 (defadvice rename-buffer (after rename-buffer-uniquify activate)
 457   "Uniquify buffer names with parts of directory name."
 458   (uniquify-maybe-rerationalize-w/o-cb)
 459   (if (null (ad-get-arg 1))             ; no UNIQUE argument.
 460       ;; Mark this buffer so it won't be renamed by uniquify.
 461       (setq uniquify-managed nil)
 462     (when uniquify-buffer-name-style
 463       ;; Rerationalize w.r.t the new name.
 464       (uniquify-rationalize-file-buffer-names
 465        (ad-get-arg 0)
 466        (uniquify-buffer-file-name (current-buffer))
 467        (current-buffer))
 468       (setq ad-return-value (buffer-name (current-buffer))))))
 469
 470 (defadvice create-file-buffer (after create-file-buffer-uniquify activate)
 471   "Uniquify buffer names with parts of directory name."
 472   (if uniquify-buffer-name-style
 473       (let ((filename (expand-file-name (directory-file-name (ad-get-arg 0)))))
 474         (uniquify-rationalize-file-buffer-names
 475          (file-name-nondirectory filename)
 476          (file-name-directory filename) ad-return-value))))
 477
 478 ;;; The End
 479
 480 (defun uniquify-unload-function ()
 481   "Unload the uniquify library."
 482   (save-current-buffer
 483     (let ((buffers nil))
 484       (dolist (buf (buffer-list))
 485         (set-buffer buf)
 486         (when uniquify-managed
 487           (push (cons buf (uniquify-item-base (car uniquify-managed))) buffers)))
 488       (dolist (fun '(rename-buffer create-file-buffer))
 489         (ad-remove-advice fun 'after (intern (concat (symbol-name fun) "-uniquify")))
 490         (ad-update fun))
 491       (dolist (buf buffers)
 492         (set-buffer (car buf))
 493         (rename-buffer (cdr buf) t))))
 494   ;; continue standard uploading
 495   nil)
 496
 497 (provide 'uniquify)
 498
 499 ;; arch-tag: e763faa3-56c9-4903-8eb8-26e1c45a0065
 500 ;;; uniquify.el ends here