lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer
   2
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Colin Walters <walters@verbum.org>
   7 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   8 ;; Created: 2 Dec 2001
   9 ;; Keywords: buffer, convenience
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This program is free software; you can redistribute it and/or
  14 ;; modify it under the terms of the GNU General Public License as
  15 ;; published by the Free Software Foundation; either version 3, or (at
  16 ;; your option) any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful, but
  19 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 ;; General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with this program ; see the file COPYING.  If not, write to
  25 ;; the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; These functions should be automatically loaded when called, but you
  31 ;; can explicity (require 'ibuf-ext) in your ~/.emacs to have them
  32 ;; preloaded.
  33
  34 ;;; Code:
  35
  36 (require 'ibuffer)
  37
  38 (eval-when-compile
  39   (require 'ibuf-macs)
  40   (require 'cl))
  41
  42 ;;; Utility functions
  43 (defun ibuffer-delete-alist (key alist)
  44   "Delete all entries in ALIST that have a key equal to KEY."
  45   (let (entry)
  46     (while (setq entry (assoc key alist))
  47       (setq alist (delete entry alist)))
  48     alist))
  49
  50 ;; borrowed from Gnus
  51 (defun ibuffer-remove-duplicates (list)
  52   "Return a copy of LIST with duplicate elements removed."
  53   (let ((new nil)
  54         (tail list))
  55     (while tail
  56       (or (member (car tail) new)
  57           (setq new (cons (car tail) new)))
  58       (setq tail (cdr tail)))
  59     (nreverse new)))
  60
  61 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  62   (let ((hip-crowd nil)
  63         (lamers nil))
  64     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  65       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  66           (push ibuffer-split-list-elt hip-crowd)
  67         (push ibuffer-split-list-elt lamers)))
  68     ;; Too bad Emacs Lisp doesn't have multiple values.
  69     (list (nreverse hip-crowd) (nreverse lamers))))
  70
  71 (defcustom ibuffer-never-show-predicates nil
  72   "A list of predicates (a regexp or function) for buffers not to display.
  73 If a regexp, then it will be matched against the buffer's name.
  74 If a function, it will be called with the buffer as an argument, and
  75 should return non-nil if this buffer should not be shown."
  76   :type '(repeat (choice regexp function))
  77   :require 'ibuf-ext
  78   :group 'ibuffer)
  79
  80 (defcustom ibuffer-always-show-predicates nil
  81   "A list of predicates (a regexp or function) for buffers to always display.
  82 If a regexp, then it will be matched against the buffer's name.
  83 If a function, it will be called with the buffer as an argument, and
  84 should return non-nil if this buffer should be shown.
  85 Note that buffers matching one of these predicates will be shown
  86 regardless of any active filters in this buffer."
  87   :type '(repeat (choice regexp function))
  88   :group 'ibuffer)
  89
  90 (defvar ibuffer-tmp-hide-regexps nil
  91   "A list of regexps which should match buffer names to not show.")
  92
  93 (defvar ibuffer-tmp-show-regexps nil
  94   "A list of regexps which should match buffer names to always show.")
  95
  96 (defvar ibuffer-auto-mode nil
  97   "If non-nil, Ibuffer auto-mode should be enabled for this buffer.
  98 Do not set this variable directly!  Use the function
  99 `ibuffer-auto-mode' instead.")
 100
 101 (defvar ibuffer-auto-buffers-changed nil)
 102
 103 (defcustom ibuffer-saved-filters '(("gnus"
 104                                     ((or (mode . message-mode)
 105                                          (mode . mail-mode)
 106                                          (mode . gnus-group-mode)
 107                                          (mode . gnus-summary-mode)
 108                                          (mode . gnus-article-mode))))
 109                                    ("programming"
 110                                     ((or (mode . emacs-lisp-mode)
 111                                          (mode . cperl-mode)
 112                                          (mode . c-mode)
 113                                          (mode . java-mode)
 114                                          (mode . idl-mode)
 115                                          (mode . lisp-mode)))))
 116
 117   "An alist of filter qualifiers to switch between.
 118
 119 This variable should look like ((\"STRING\" QUALIFIERS)
 120                                 (\"STRING\" QUALIFIERS) ...), where
 121 QUALIFIERS is a list of the same form as
 122 `ibuffer-filtering-qualifiers'.
 123 See also the variables `ibuffer-filtering-qualifiers',
 124 `ibuffer-filtering-alist', and the functions
 125 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 126   :type '(repeat sexp)
 127   :group 'ibuffer)
 128
 129 (defvar ibuffer-filtering-qualifiers nil
 130   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 131 See also `ibuffer-filtering-alist'.")
 132
 133 ;; This is now frobbed by `define-ibuffer-filter'.
 134 (defvar ibuffer-filtering-alist nil
 135   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 136
 137 You most likely do not want to modify this variable directly; see
 138 `define-ibuffer-filter'.
 139
 140 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 141 displaying information to the user.  FUNCTION is given a buffer and
 142 the value of the qualifier, and returns non-nil if and only if the
 143 buffer should be displayed.")
 144
 145 (defcustom ibuffer-filter-format-alist nil
 146   "An alist which has special formats used when a filter is active.
 147 The contents of this variable should look like:
 148  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 149
 150 For example, suppose that when you add a filter for buffers whose
 151 major mode is `emacs-lisp-mode', you only want to see the mark and the
 152 name of the buffer.  You could accomplish that by adding:
 153  (mode ((mark \" \" name)))
 154 to this variable."
 155   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 156                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 157   :group 'ibuffer)
 158
 159 (defvar ibuffer-cached-filter-formats nil)
 160 (defvar ibuffer-compiled-filter-formats nil)
 161
 162 (defvar ibuffer-filter-groups nil
 163   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 164 The SYMBOL should be one from `ibuffer-filtering-alist'.
 165 The QUALIFIER should be the same as QUALIFIER in
 166 `ibuffer-filtering-qualifiers'.")
 167
 168 (defcustom ibuffer-show-empty-filter-groups t
 169   "If non-nil, then show the names of filter groups which are empty."
 170   :type 'boolean
 171   :group 'ibuffer)
 172
 173 (defcustom ibuffer-saved-filter-groups nil
 174   "An alist of filtering groups to switch between.
 175
 176 This variable should look like ((\"STRING\" QUALIFIERS)
 177                                 (\"STRING\" QUALIFIERS) ...), where
 178 QUALIFIERS is a list of the same form as
 179 `ibuffer-filtering-qualifiers'.
 180
 181 See also the variables `ibuffer-filter-groups',
 182 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 183 functions `ibuffer-switch-to-saved-filter-groups',
 184 `ibuffer-save-filter-groups'."
 185   :type '(repeat sexp)
 186   :group 'ibuffer)
 187
 188 (defvar ibuffer-hidden-filter-groups nil
 189   "A list of filtering groups which are currently hidden.")
 190
 191 (defvar ibuffer-filter-group-kill-ring nil)
 192
 193 (defcustom ibuffer-old-time 72
 194   "The number of hours before a buffer is considered \"old\"."
 195   :type '(choice (const :tag "72 hours (3 days)" 72)
 196                  (const :tag "48 hours (2 days)" 48)
 197                  (const :tag "24 hours (1 day)" 24)
 198                  (integer :tag "hours"))
 199   :group 'ibuffer)
 200
 201 (defcustom ibuffer-save-with-custom t
 202   "If non-nil, then use Custom to save interactively changed variables.
 203 Currently, this only applies to `ibuffer-saved-filters' and
 204 `ibuffer-saved-filter-groups'."
 205   :type 'boolean
 206   :group 'ibuffer)
 207
 208 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 209   (or
 210    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 211    (and (not
 212          (or
 213           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 214           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 215         (or all
 216             (not
 217              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 218         (or ibuffer-view-ibuffer
 219             (and ibuffer-buf
 220                  (not (eq ibuffer-buf buf))))
 221         (or
 222          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 223          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 224
 225 (defun ibuffer-auto-update-changed ()
 226   (when (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed)
 227     (dolist (buf (buffer-list))
 228       (ignore-errors
 229         (with-current-buffer buf
 230           (when (and ibuffer-auto-mode
 231                      (derived-mode-p 'ibuffer-mode))
 232             (ibuffer-update nil t)))))))
 233
 234 ;;;###autoload
 235 (defun ibuffer-auto-mode (&optional arg)
 236   "Toggle use of Ibuffer's auto-update facility.
 237 With numeric ARG, enable auto-update if and only if ARG is positive."
 238   (interactive)
 239   (unless (derived-mode-p 'ibuffer-mode)
 240     (error "This buffer is not in Ibuffer mode"))
 241   (set (make-local-variable 'ibuffer-auto-mode)
 242        (if arg
 243            (plusp arg)
 244          (not ibuffer-auto-mode)))
 245   (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed) ; Initialize state vector
 246   (add-hook 'post-command-hook 'ibuffer-auto-update-changed))
 247
 248 ;;;###autoload
 249 (defun ibuffer-mouse-filter-by-mode (event)
 250   "Enable or disable filtering by the major mode chosen via mouse."
 251   (interactive "e")
 252   (ibuffer-interactive-filter-by-mode event))
 253
 254 ;;;###autoload
 255 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 256   "Enable or disable filtering by the major mode at point."
 257   (interactive "d")
 258   (if (eventp event-or-point)
 259       (posn-set-point (event-end event-or-point))
 260     (goto-char event-or-point))
 261   (let ((buf (ibuffer-current-buffer)))
 262     (if (assq 'mode ibuffer-filtering-qualifiers)
 263         (setq ibuffer-filtering-qualifiers
 264               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 265       (ibuffer-push-filter (cons 'mode
 266                                 (with-current-buffer buf
 267                                   major-mode)))))
 268   (ibuffer-update nil t))
 269
 270 ;;;###autoload
 271 (defun ibuffer-mouse-toggle-filter-group (event)
 272   "Toggle the display status of the filter group chosen with the mouse."
 273   (interactive "e")
 274   (ibuffer-toggle-filter-group-1 (save-excursion
 275                                    (mouse-set-point event)
 276                                    (point))))
 277
 278 ;;;###autoload
 279 (defun ibuffer-toggle-filter-group ()
 280   "Toggle the display status of the filter group on this line."
 281   (interactive)
 282   (ibuffer-toggle-filter-group-1 (point)))
 283
 284 (defun ibuffer-toggle-filter-group-1 (posn)
 285   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 286     (unless (stringp name)
 287       (error "No filtering group name present"))
 288     (if (member name ibuffer-hidden-filter-groups)
 289         (setq ibuffer-hidden-filter-groups
 290               (delete name ibuffer-hidden-filter-groups))
 291       (push name ibuffer-hidden-filter-groups))
 292     (ibuffer-update nil t)))
 293
 294 ;;;###autoload
 295 (defun ibuffer-forward-filter-group (&optional count)
 296   "Move point forwards by COUNT filtering groups."
 297   (interactive "P")
 298   (unless count
 299     (setq count 1))
 300   (when (> count 0)
 301     (when (get-text-property (point) 'ibuffer-filter-group-name)
 302       (goto-char (next-single-property-change
 303                   (point) 'ibuffer-filter-group-name
 304                   nil (point-max))))
 305     (goto-char (next-single-property-change
 306                 (point) 'ibuffer-filter-group-name
 307                 nil (point-max)))
 308     (ibuffer-forward-filter-group (1- count)))
 309   (ibuffer-forward-line 0))
 310
 311 ;;;###autoload
 312 (defun ibuffer-backward-filter-group (&optional count)
 313   "Move point backwards by COUNT filtering groups."
 314   (interactive "P")
 315   (unless count
 316     (setq count 1))
 317   (when (> count 0)
 318     (when (get-text-property (point) 'ibuffer-filter-group-name)
 319       (goto-char (previous-single-property-change
 320                   (point) 'ibuffer-filter-group-name
 321                   nil (point-min))))
 322     (goto-char (previous-single-property-change
 323                 (point) 'ibuffer-filter-group-name
 324                 nil (point-min)))
 325     (ibuffer-backward-filter-group (1- count)))
 326   (when (= (point) (point-min))
 327     (goto-char (point-max))
 328     (ibuffer-backward-filter-group 1))
 329   (ibuffer-forward-line 0))
 330
 331 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext")
 332 (define-ibuffer-op shell-command-pipe (command)
 333   "Pipe the contents of each marked buffer to shell command COMMAND."
 334   (:interactive "sPipe to shell command: "
 335    :opstring "Shell command executed on"
 336    :modifier-p nil)
 337   (shell-command-on-region
 338    (point-min) (point-max) command
 339    (get-buffer-create "* ibuffer-shell-output*")))
 340
 341 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext")
 342 (define-ibuffer-op shell-command-pipe-replace (command)
 343   "Replace the contents of marked buffers with output of pipe to COMMAND."
 344   (:interactive "sPipe to shell command (replace): "
 345    :opstring "Buffer contents replaced in"
 346    :active-opstring "replace buffer contents in"
 347    :dangerous t
 348    :modifier-p t)
 349   (with-current-buffer buf
 350     (shell-command-on-region (point-min) (point-max)
 351                              command nil t)))
 352
 353 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext")
 354 (define-ibuffer-op shell-command-file (command)
 355   "Run shell command COMMAND separately on files of marked buffers."
 356   (:interactive "sShell command on buffer's file: "
 357    :opstring "Shell command executed on"
 358    :modifier-p nil)
 359   (shell-command (concat command " "
 360                          (shell-quote-argument
 361                           (if buffer-file-name
 362                               buffer-file-name
 363                             (make-temp-file
 364                              (substring (buffer-name) 0 (min 10 (length (buffer-name))))))))))
 365
 366 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext")
 367 (define-ibuffer-op eval (form)
 368   "Evaluate FORM in each of the buffers.
 369 Does not display the buffer during evaluation. See
 370 `ibuffer-do-view-and-eval' for that."
 371   (:interactive
 372    (list
 373     (read-from-minibuffer
 374      "Eval in buffers (form): "
 375      nil read-expression-map t 'read-expression-history))
 376    :opstring "evaluated in"
 377    :modifier-p :maybe)
 378   (eval form))
 379
 380 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext")
 381 (define-ibuffer-op view-and-eval (form)
 382   "Evaluate FORM while displaying each of the marked buffers.
 383 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 384   (:interactive
 385    (list
 386     (read-from-minibuffer
 387      "Eval viewing in buffers (form): "
 388      nil read-expression-map t 'read-expression-history))
 389    :opstring "evaluated in"
 390    :complex t
 391    :modifier-p :maybe)
 392   (let ((ibuffer-buf (current-buffer)))
 393     (unwind-protect
 394         (progn
 395           (switch-to-buffer buf)
 396           (eval form))
 397       (switch-to-buffer ibuffer-buf))))
 398
 399 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext")
 400 (define-ibuffer-op rename-uniquely ()
 401   "Rename marked buffers as with `rename-uniquely'."
 402   (:opstring "renamed"
 403    :modifier-p t)
 404   (rename-uniquely))
 405
 406 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext")
 407 (define-ibuffer-op revert ()
 408   "Revert marked buffers as with `revert-buffer'."
 409   (:dangerous t
 410    :opstring "reverted"
 411    :active-opstring "revert"
 412    :modifier-p :maybe)
 413   (revert-buffer t t))
 414
 415 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext")
 416 (define-ibuffer-op replace-regexp (from-str to-str)
 417   "Perform a `replace-regexp' in marked buffers."
 418   (:interactive
 419    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 420           (to-str (read-from-minibuffer (concat "Replace " from-str
 421                                                 " with: "))))
 422      (list from-str to-str))
 423    :opstring "replaced in"
 424    :complex t
 425    :modifier-p :maybe)
 426   (save-window-excursion
 427     (switch-to-buffer buf)
 428     (save-excursion
 429       (goto-char (point-min))
 430       (let ((case-fold-search ibuffer-case-fold-search))
 431         (while (re-search-forward from-str nil t)
 432           (replace-match to-str))))
 433     t))
 434
 435 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext")
 436 (define-ibuffer-op query-replace (&rest args)
 437   "Perform a `query-replace' in marked buffers."
 438   (:interactive
 439    (query-replace-read-args "Query replace" t t)
 440    :opstring "replaced in"
 441    :complex t
 442    :modifier-p :maybe)
 443   (save-window-excursion
 444     (switch-to-buffer buf)
 445     (save-excursion
 446       (let ((case-fold-search ibuffer-case-fold-search))
 447         (goto-char (point-min))
 448         (apply #'query-replace args)))
 449     t))
 450
 451 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext")
 452 (define-ibuffer-op query-replace-regexp (&rest args)
 453   "Perform a `query-replace-regexp' in marked buffers."
 454   (:interactive
 455    (query-replace-read-args "Query replace regexp" t t)
 456    :opstring "replaced in"
 457    :complex t
 458    :modifier-p :maybe)
 459   (save-window-excursion
 460     (switch-to-buffer buf)
 461     (save-excursion
 462       (let ((case-fold-search ibuffer-case-fold-search))
 463         (goto-char (point-min))
 464         (apply #'query-replace-regexp args)))
 465     t))
 466
 467 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext")
 468 (define-ibuffer-op print ()
 469   "Print marked buffers as with `print-buffer'."
 470   (:opstring "printed"
 471    :modifier-p nil)
 472   (print-buffer))
 473
 474 ;;;###autoload
 475 (defun ibuffer-included-in-filters-p (buf filters)
 476   (not
 477    (memq nil ;; a filter will return nil if it failed
 478          (mapcar
 479           ;; filter should be like (TYPE . QUALIFIER), or
 480           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 481           #'(lambda (qual)
 482               (ibuffer-included-in-filter-p buf qual))
 483           filters))))
 484
 485 (defun ibuffer-included-in-filter-p (buf filter)
 486   (if (eq (car filter) 'not)
 487       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 488     (ibuffer-included-in-filter-p-1 buf filter)))
 489
 490 (defun ibuffer-included-in-filter-p-1 (buf filter)
 491   (not
 492    (not
 493     (case (car filter)
 494       (or
 495        (memq t (mapcar #'(lambda (x)
 496                            (ibuffer-included-in-filter-p buf x))
 497                        (cdr filter))))
 498       (saved
 499        (let ((data
 500               (assoc (cdr filter)
 501                      ibuffer-saved-filters)))
 502          (unless data
 503            (ibuffer-filter-disable)
 504            (error "Unknown saved filter %s" (cdr filter)))
 505          (ibuffer-included-in-filters-p buf (cadr data))))
 506       (t
 507        (let ((filterdat (assq (car filter)
 508                               ibuffer-filtering-alist)))
 509          ;; filterdat should be like (TYPE DESCRIPTION FUNC)
 510          ;; just a sanity check
 511         (unless filterdat
 512           (ibuffer-filter-disable)
 513           (error "Undefined filter %s" (car filter)))
 514         (not
 515          (not
 516           (funcall (caddr filterdat)
 517                    buf
 518                    (cdr filter))))))))))
 519
 520 (defun ibuffer-generate-filter-groups (bmarklist &optional noempty nodefault)
 521   (let ((filter-group-alist (if nodefault
 522                                 ibuffer-filter-groups
 523                               (append ibuffer-filter-groups
 524                                       (list (cons "Default" nil))))))
 525 ;;     (dolist (hidden ibuffer-hidden-filter-groups)
 526 ;;       (setq filter-group-alist (ibuffer-delete-alist
 527 ;;                                 hidden filter-group-alist)))
 528     (let ((vec (make-vector (length filter-group-alist) nil))
 529           (i 0))
 530       (dolist (filtergroup filter-group-alist)
 531         (let ((filterset (cdr filtergroup)))
 532           (multiple-value-bind (hip-crowd lamers)
 533               (ibuffer-split-list (lambda (bufmark)
 534                                     (ibuffer-included-in-filters-p (car bufmark)
 535                                                                    filterset))
 536                                   bmarklist)
 537             (aset vec i hip-crowd)
 538             (incf i)
 539             (setq bmarklist lamers))))
 540       (let (ret)
 541         (dotimes (j i ret)
 542           (let ((bufs (aref vec j)))
 543             (unless (and noempty (null bufs))
 544               (push (cons (car (nth j filter-group-alist))
 545                           bufs)
 546                     ret))))))))
 547
 548 ;;;###autoload
 549 (defun ibuffer-filters-to-filter-group (name)
 550   "Make the current filters into a filtering group."
 551   (interactive "sName for filtering group: ")
 552   (when (null ibuffer-filtering-qualifiers)
 553     (error "No filters in effect"))
 554   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 555   (ibuffer-filter-disable))
 556
 557 ;;;###autoload
 558 (defun ibuffer-set-filter-groups-by-mode ()
 559   "Set the current filter groups to filter by mode."
 560   (interactive)
 561   (setq ibuffer-filter-groups
 562         (mapcar (lambda (mode)
 563                   (cons (format "%s" mode) `((mode . ,mode))))
 564                 (let ((modes
 565                        (ibuffer-remove-duplicates
 566                         (mapcar (lambda (buf)
 567                                   (with-current-buffer buf major-mode))
 568                                 (buffer-list)))))
 569                   (if ibuffer-view-ibuffer
 570                       modes
 571                     (delq 'ibuffer-mode modes)))))
 572   (ibuffer-update nil t))
 573
 574 ;;;###autoload
 575 (defun ibuffer-pop-filter-group ()
 576   "Remove the first filter group."
 577   (interactive)
 578   (when (null ibuffer-filter-groups)
 579     (error "No filter groups active"))
 580   (setq ibuffer-hidden-filter-groups
 581         (delete (pop ibuffer-filter-groups)
 582                 ibuffer-hidden-filter-groups))
 583   (ibuffer-update nil t))
 584
 585 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 586   (when (and (not noerror) (null ibuffer-filter-groups))
 587     (error "No filter groups active"))
 588   ;; `ibuffer-generate-filter-groups' returns all non-hidden filter
 589   ;; groups, possibly excluding empty groups or Default.
 590   ;; We add `ibuffer-hidden-filter-groups' to the list, excluding
 591   ;; Default if necessary.
 592   (completing-read msg (nconc
 593                         (ibuffer-generate-filter-groups
 594                          (ibuffer-current-state-list)
 595                          (not ibuffer-show-empty-filter-groups)
 596                          nodefault)
 597                         (if nodefault
 598                             (remove "Default" ibuffer-hidden-filter-groups)
 599                           ibuffer-hidden-filter-groups))
 600                    nil t))
 601
 602 ;;;###autoload
 603 (defun ibuffer-decompose-filter-group (group)
 604   "Decompose the filter group GROUP into active filters."
 605   (interactive
 606    (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 607   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 608     (setq ibuffer-filter-groups (ibuffer-delete-alist
 609                                  group ibuffer-filter-groups)
 610           ibuffer-filtering-qualifiers data))
 611   (ibuffer-update nil t))
 612
 613 ;;;###autoload
 614 (defun ibuffer-clear-filter-groups ()
 615   "Remove all filter groups."
 616   (interactive)
 617   (setq ibuffer-filter-groups nil
 618         ibuffer-hidden-filter-groups nil)
 619   (ibuffer-update nil t))
 620
 621 (defun ibuffer-current-filter-groups-with-position ()
 622   (save-excursion
 623     (goto-char (point-min))
 624     (let ((pos nil)
 625           (result nil))
 626       (while (and (not (eobp))
 627                   (setq pos (next-single-property-change
 628                              (point) 'ibuffer-filter-group-name)))
 629         (goto-char pos)
 630         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 631                     pos)
 632               result)
 633         (goto-char (next-single-property-change
 634                     pos 'ibuffer-filter-group-name)))
 635       (nreverse result))))
 636
 637 ;;;###autoload
 638 (defun ibuffer-jump-to-filter-group (name)
 639   "Move point to the filter group whose name is NAME."
 640   (interactive
 641    (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 642   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 643       (goto-char (cdr it))
 644     (error "No filter group with name %s" name)))
 645
 646 ;;;###autoload
 647 (defun ibuffer-kill-filter-group (name)
 648   "Kill the filter group named NAME.
 649 The group will be added to `ibuffer-filter-group-kill-ring'."
 650   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 651   (when (equal name "Default")
 652     (error "Can't kill default filter group"))
 653   (ibuffer-aif (assoc name ibuffer-filter-groups)
 654       (progn
 655         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 656         (setq ibuffer-filter-groups (ibuffer-delete-alist
 657                                      name ibuffer-filter-groups))
 658         (setq ibuffer-hidden-filter-groups
 659               (delete name ibuffer-hidden-filter-groups)))
 660     (error "No filter group with name \"%s\"" name))
 661   (ibuffer-update nil t))
 662
 663 ;;;###autoload
 664 (defun ibuffer-kill-line (&optional arg interactive-p)
 665   "Kill the filter group at point.
 666 See also `ibuffer-kill-filter-group'."
 667   (interactive "P\np")
 668   (ibuffer-aif (save-excursion
 669                  (ibuffer-forward-line 0)
 670                  (get-text-property (point) 'ibuffer-filter-group-name))
 671       (progn
 672         (ibuffer-kill-filter-group it))
 673       (funcall (if interactive-p #'call-interactively #'funcall)
 674                #'kill-line arg)))
 675
 676 (defun ibuffer-insert-filter-group-before (newgroup group)
 677   (let* ((found nil)
 678          (pos (let ((groups (mapcar #'car ibuffer-filter-groups))
 679                     (res 0))
 680                 (while groups
 681                   (if (equal (car groups) group)
 682                       (setq found t
 683                             groups nil)
 684                     (incf res)
 685                     (setq groups (cdr groups))))
 686                 res)))
 687     (cond ((not found)
 688            (setq ibuffer-filter-groups
 689                  (nconc ibuffer-filter-groups (list newgroup))))
 690           ((zerop pos)
 691            (push newgroup ibuffer-filter-groups))
 692           (t
 693            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 694              (setf (cdr cell) (cons (car cell) (cdr cell)))
 695              (setf (car cell) newgroup))))))
 696
 697 ;;;###autoload
 698 (defun ibuffer-yank ()
 699   "Yank the last killed filter group before group at point."
 700   (interactive)
 701   (ibuffer-yank-filter-group
 702    (or (get-text-property (point) 'ibuffer-filter-group-name)
 703        (get-text-property (point) 'ibuffer-filter-group)
 704        (error "No filter group at point"))))
 705
 706 ;;;###autoload
 707 (defun ibuffer-yank-filter-group (name)
 708   "Yank the last killed filter group before group named NAME."
 709   (interactive (list (ibuffer-read-filter-group-name
 710                         "Yank filter group before group: ")))
 711   (unless ibuffer-filter-group-kill-ring
 712     (error "The Ibuffer filter group kill-ring is empty"))
 713   (save-excursion
 714     (ibuffer-forward-line 0)
 715     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 716                                         name))
 717   (ibuffer-update nil t))
 718
 719 ;;;###autoload
 720 (defun ibuffer-save-filter-groups (name groups)
 721   "Save all active filter groups GROUPS as NAME.
 722 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 723 prompt for NAME, and use the current filters."
 724   (interactive
 725    (if (null ibuffer-filter-groups)
 726        (error "No filter groups active")
 727      (list
 728       (read-from-minibuffer "Save current filter groups as: ")
 729       ibuffer-filter-groups)))
 730   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 731       (setcdr it groups)
 732     (push (cons name groups) ibuffer-saved-filter-groups))
 733   (ibuffer-maybe-save-stuff))
 734
 735 ;;;###autoload
 736 (defun ibuffer-delete-saved-filter-groups (name)
 737   "Delete saved filter groups with NAME.
 738 They are removed from `ibuffer-saved-filter-groups'."
 739   (interactive
 740    (list
 741     (if (null ibuffer-saved-filter-groups)
 742         (error "No saved filter groups")
 743       (completing-read "Delete saved filter group: "
 744                        ibuffer-saved-filter-groups nil t))))
 745   (setq ibuffer-saved-filter-groups
 746         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 747   (ibuffer-maybe-save-stuff)
 748   (ibuffer-update nil t))
 749
 750 ;;;###autoload
 751 (defun ibuffer-switch-to-saved-filter-groups (name)
 752   "Set this buffer's filter groups to saved version with NAME.
 753 The value from `ibuffer-saved-filter-groups' is used."
 754   (interactive
 755    (list
 756     (if (null ibuffer-saved-filter-groups)
 757         (error "No saved filters")
 758       (completing-read "Switch to saved filter group: "
 759                        ibuffer-saved-filter-groups nil t))))
 760   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 761         ibuffer-hidden-filter-groups nil)
 762   (ibuffer-update nil t))
 763
 764 ;;;###autoload
 765 (defun ibuffer-filter-disable ()
 766   "Disable all filters currently in effect in this buffer."
 767   (interactive)
 768   (setq ibuffer-filtering-qualifiers nil)
 769   (let ((buf (ibuffer-current-buffer)))
 770     (ibuffer-update nil t)
 771     (when buf
 772       (ibuffer-jump-to-buffer (buffer-name buf)))))
 773
 774 ;;;###autoload
 775 (defun ibuffer-pop-filter ()
 776   "Remove the top filter in this buffer."
 777   (interactive)
 778   (when (null ibuffer-filtering-qualifiers)
 779     (error "No filters in effect"))
 780   (pop ibuffer-filtering-qualifiers)
 781   (let ((buf (ibuffer-current-buffer)))
 782     (ibuffer-update nil t)
 783     (when buf
 784       (ibuffer-jump-to-buffer (buffer-name buf)))))
 785
 786 (defun ibuffer-push-filter (qualifier)
 787   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 788   (push qualifier ibuffer-filtering-qualifiers))
 789
 790 ;;;###autoload
 791 (defun ibuffer-decompose-filter ()
 792   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 793
 794 This means that the topmost filter on the filtering stack, which must
 795 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 796 turned into two separate filters [name: foo] and [mode: bar-mode]."
 797   (interactive)
 798   (when (null ibuffer-filtering-qualifiers)
 799     (error "No filters in effect"))
 800   (let ((lim (pop ibuffer-filtering-qualifiers)))
 801     (case (car lim)
 802       (or
 803        (setq ibuffer-filtering-qualifiers (append
 804                                           (cdr lim)
 805                                           ibuffer-filtering-qualifiers)))
 806       (saved
 807        (let ((data
 808               (assoc (cdr lim)
 809                      ibuffer-saved-filters)))
 810          (unless data
 811            (ibuffer-filter-disable)
 812            (error "Unknown saved filter %s" (cdr lim)))
 813          (setq ibuffer-filtering-qualifiers (append
 814                                             (cadr data)
 815                                             ibuffer-filtering-qualifiers))))
 816       (not
 817        (push (cdr lim)
 818              ibuffer-filtering-qualifiers))
 819       (t
 820        (error "Filter type %s is not compound" (car lim)))))
 821   (ibuffer-update nil t))
 822
 823 ;;;###autoload
 824 (defun ibuffer-exchange-filters ()
 825   "Exchange the top two filters on the stack in this buffer."
 826   (interactive)
 827   (when (< (length ibuffer-filtering-qualifiers)
 828            2)
 829     (error "Need two filters to exchange"))
 830   (let ((first (pop ibuffer-filtering-qualifiers))
 831         (second (pop ibuffer-filtering-qualifiers)))
 832     (push first ibuffer-filtering-qualifiers)
 833     (push second ibuffer-filtering-qualifiers))
 834   (ibuffer-update nil t))
 835
 836 ;;;###autoload
 837 (defun ibuffer-negate-filter ()
 838   "Negate the sense of the top filter in the current buffer."
 839   (interactive)
 840   (when (null ibuffer-filtering-qualifiers)
 841     (error "No filters in effect"))
 842   (let ((lim (pop ibuffer-filtering-qualifiers)))
 843     (push (if (eq (car lim) 'not)
 844               (cdr lim)
 845             (cons 'not lim))
 846           ibuffer-filtering-qualifiers))
 847   (ibuffer-update nil t))
 848
 849 ;;;###autoload
 850 (defun ibuffer-or-filter (&optional reverse)
 851   "Replace the top two filters in this buffer with their logical OR.
 852 If optional argument REVERSE is non-nil, instead break the top OR
 853 filter into parts."
 854   (interactive "P")
 855   (if reverse
 856       (progn
 857         (when (or (null ibuffer-filtering-qualifiers)
 858                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 859           (error "Top filter is not an OR"))
 860         (let ((lim (pop ibuffer-filtering-qualifiers)))
 861           (setq ibuffer-filtering-qualifiers
 862                 (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 863     (when (< (length ibuffer-filtering-qualifiers) 2)
 864       (error "Need two filters to OR"))
 865     ;; If the second filter is an OR, just add to it.
 866     (let ((first (pop ibuffer-filtering-qualifiers))
 867           (second (pop ibuffer-filtering-qualifiers)))
 868       (if (eq 'or (car second))
 869           (push (nconc (list 'or first) (cdr second))
 870                 ibuffer-filtering-qualifiers)
 871         (push (list 'or first second)
 872               ibuffer-filtering-qualifiers))))
 873   (ibuffer-update nil t))
 874
 875 (defun ibuffer-maybe-save-stuff ()
 876   (when ibuffer-save-with-custom
 877     (if (fboundp 'customize-save-variable)
 878         (progn
 879           (customize-save-variable 'ibuffer-saved-filters
 880                                    ibuffer-saved-filters)
 881           (customize-save-variable 'ibuffer-saved-filter-groups
 882                                    ibuffer-saved-filter-groups))
 883       (message "Not saved permanently: Customize not available"))))
 884
 885 ;;;###autoload
 886 (defun ibuffer-save-filters (name filters)
 887   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 888 Interactively, prompt for NAME, and use the current filters."
 889   (interactive
 890    (if (null ibuffer-filtering-qualifiers)
 891        (error "No filters currently in effect")
 892      (list
 893       (read-from-minibuffer "Save current filters as: ")
 894       ibuffer-filtering-qualifiers)))
 895   (ibuffer-aif (assoc name ibuffer-saved-filters)
 896       (setcdr it filters)
 897     (push (list name filters) ibuffer-saved-filters))
 898   (ibuffer-maybe-save-stuff))
 899
 900 ;;;###autoload
 901 (defun ibuffer-delete-saved-filters (name)
 902   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 903   (interactive
 904    (list
 905     (if (null ibuffer-saved-filters)
 906         (error "No saved filters")
 907       (completing-read "Delete saved filters: "
 908                        ibuffer-saved-filters nil t))))
 909   (setq ibuffer-saved-filters
 910         (ibuffer-delete-alist name ibuffer-saved-filters))
 911   (ibuffer-maybe-save-stuff)
 912   (ibuffer-update nil t))
 913
 914 ;;;###autoload
 915 (defun ibuffer-add-saved-filters (name)
 916   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 917   (interactive
 918    (list
 919     (if (null ibuffer-saved-filters)
 920         (error "No saved filters")
 921       (completing-read "Add saved filters: "
 922                        ibuffer-saved-filters nil t))))
 923   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 924   (ibuffer-update nil t))
 925
 926 ;;;###autoload
 927 (defun ibuffer-switch-to-saved-filters (name)
 928   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'."
 929   (interactive
 930    (list
 931     (if (null ibuffer-saved-filters)
 932         (error "No saved filters")
 933       (completing-read "Switch to saved filters: "
 934                        ibuffer-saved-filters nil t))))
 935   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 936   (ibuffer-update nil t))
 937
 938 (defun ibuffer-format-filter-group-data (filter)
 939   (if (equal filter "Default")
 940       ""
 941     (concat "Filter:" (mapconcat #'ibuffer-format-qualifier
 942                                  (cdr (assq filter ibuffer-filter-groups))
 943                                  " "))))
 944
 945 (defun ibuffer-format-qualifier (qualifier)
 946   (if (eq (car-safe qualifier) 'not)
 947       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 948     (ibuffer-format-qualifier-1 qualifier)))
 949
 950 (defun ibuffer-format-qualifier-1 (qualifier)
 951   (case (car qualifier)
 952     (saved
 953      (concat " [filter: " (cdr qualifier) "]"))
 954     (or
 955      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 956                                (cdr qualifier) "") "]"))
 957     (t
 958      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
 959        (unless qualifier
 960          (error "Ibuffer: bad qualifier %s" qualifier))
 961        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
 962
 963
 964 (defun ibuffer-list-buffer-modes ()
 965   "Create an alist of buffer modes currently in use.
 966 The list returned will be of the form (\"MODE-NAME\" . MODE-SYMBOL)."
 967   (let ((bufs (buffer-list))
 968         (modes)
 969         (this-mode))
 970     (while bufs
 971       (setq this-mode
 972             (with-current-buffer
 973                 (car bufs)
 974               major-mode)
 975             bufs (cdr bufs))
 976       (add-to-list
 977        'modes
 978        `(,(symbol-name this-mode) .
 979          ,this-mode)))
 980     modes))
 981
 982
 983 ;;; Extra operation definitions
 984
 985 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext")
 986 (define-ibuffer-filter mode
 987   "Toggle current view to buffers with major mode QUALIFIER."
 988   (:description "major mode"
 989    :reader
 990    (intern
 991     (completing-read "Filter by major mode: " obarray
 992                      #'(lambda (e)
 993                          (string-match "-mode$"
 994                                        (symbol-name e)))
 995                      t
 996                      (let ((buf (ibuffer-current-buffer)))
 997                        (if (and buf (buffer-live-p buf))
 998                            (with-current-buffer buf
 999                              (symbol-name major-mode))
1000                          "")))))
1001   (eq qualifier (with-current-buffer buf major-mode)))
1002
1003 ;;;###autoload (autoload 'ibuffer-filter-by-used-mode "ibuf-ext")
1004 (define-ibuffer-filter used-mode
1005   "Toggle current view to buffers with major mode QUALIFIER.
1006 Called interactively, this function allows selection of modes
1007 currently used by buffers."
1008   (:description "major mode in use"
1009                 :reader
1010                 (intern
1011                  (completing-read "Filter by major mode: "
1012                                   (ibuffer-list-buffer-modes)
1013                                   nil
1014                                   t
1015                                   (let ((buf (ibuffer-current-buffer)))
1016                                     (if (and buf (buffer-live-p buf))
1017                                         (with-current-buffer buf
1018                                           (symbol-name major-mode))
1019                                       "")))))
1020   (eq qualifier (with-current-buffer buf major-mode)))
1021
1022 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext")
1023 (define-ibuffer-filter name
1024   "Toggle current view to buffers with name matching QUALIFIER."
1025   (:description "buffer name"
1026    :reader (read-from-minibuffer "Filter by name (regexp): "))
1027   (string-match qualifier (buffer-name buf)))
1028
1029 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext")
1030 (define-ibuffer-filter filename
1031   "Toggle current view to buffers with filename matching QUALIFIER."
1032   (:description "filename"
1033    :reader (read-from-minibuffer "Filter by filename (regexp): "))
1034   (ibuffer-awhen (with-current-buffer buf
1035                    (or buffer-file-name
1036                        (and (boundp 'dired-directory)
1037                             (let ((dired-dir
1038                                    (if (stringp dired-directory)
1039                                        dired-directory
1040                                      (car dired-directory))))
1041                               (and dired-dir
1042                                    (expand-file-name dired-dir))))
1043                        (and (eq major-mode 'vc-dir-mode)
1044                             (bound-and-true-p default-directory))))
1045                  (string-match qualifier it)))
1046
1047 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext")
1048 (define-ibuffer-filter size-gt
1049   "Toggle current view to buffers with size greater than QUALIFIER."
1050   (:description "size greater than"
1051    :reader
1052    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
1053   (> (with-current-buffer buf (buffer-size))
1054      qualifier))
1055
1056 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext")
1057 (define-ibuffer-filter size-lt
1058    "Toggle current view to buffers with size less than QUALIFIER."
1059   (:description "size less than"
1060    :reader
1061    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
1062   (< (with-current-buffer buf (buffer-size))
1063      qualifier))
1064
1065 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext")
1066 (define-ibuffer-filter content
1067    "Toggle current view to buffers whose contents match QUALIFIER."
1068   (:description "content"
1069    :reader (read-from-minibuffer "Filter by content (regexp): "))
1070   (with-current-buffer buf
1071     (save-excursion
1072       (goto-char (point-min))
1073       (re-search-forward qualifier nil t))))
1074
1075 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext")
1076 (define-ibuffer-filter predicate
1077    "Toggle current view to buffers for which QUALIFIER returns non-nil."
1078   (:description "predicate"
1079    :reader (read-minibuffer "Filter by predicate (form): "))
1080   (with-current-buffer buf
1081     (eval qualifier)))
1082
1083 ;;; Sorting
1084
1085 ;;;###autoload
1086 (defun ibuffer-toggle-sorting-mode ()
1087   "Toggle the current sorting mode.
1088 Default sorting modes are:
1089  Recency - the last time the buffer was viewed
1090  Name - the name of the buffer
1091  Major Mode - the name of the major mode of the buffer
1092  Size - the size of the buffer"
1093   (interactive)
1094   (let ((modes (mapcar 'car ibuffer-sorting-functions-alist)))
1095     (add-to-list 'modes 'recency)
1096     (setq modes (sort modes 'string-lessp))
1097     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1098                     (car modes))))
1099       (setq ibuffer-sorting-mode next)
1100       (message "Sorting by %s" next)))
1101   (ibuffer-redisplay t))
1102
1103 ;;;###autoload
1104 (defun ibuffer-invert-sorting ()
1105   "Toggle whether or not sorting is in reverse order."
1106   (interactive)
1107   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1108   (message "Sorting order %s"
1109            (if ibuffer-sorting-reversep
1110                "reversed"
1111              "normal"))
1112   (ibuffer-redisplay t))
1113
1114 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext")
1115 (define-ibuffer-sorter major-mode
1116   "Sort the buffers by major modes.
1117 Ordering is lexicographic."
1118   (:description "major mode")
1119   (string-lessp (downcase
1120                  (symbol-name (with-current-buffer
1121                                   (car a)
1122                                 major-mode)))
1123                 (downcase
1124                  (symbol-name (with-current-buffer
1125                                   (car b)
1126                                 major-mode)))))
1127
1128 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext")
1129 (define-ibuffer-sorter mode-name
1130   "Sort the buffers by their mode name.
1131 Ordering is lexicographic."
1132   (:description "major mode name")
1133   (string-lessp (downcase
1134                   (with-current-buffer
1135                       (car a)
1136                     (format-mode-line mode-name)))
1137                 (downcase
1138                  (with-current-buffer
1139                      (car b)
1140                    (format-mode-line mode-name)))))
1141
1142 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext")
1143 (define-ibuffer-sorter alphabetic
1144   "Sort the buffers by their names.
1145 Ordering is lexicographic."
1146   (:description "buffer name")
1147   (string-lessp
1148    (buffer-name (car a))
1149    (buffer-name (car b))))
1150
1151 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext")
1152 (define-ibuffer-sorter size
1153  "Sort the buffers by their size."
1154   (:description "size")
1155   (< (with-current-buffer (car a)
1156        (buffer-size))
1157      (with-current-buffer (car b)
1158        (buffer-size))))
1159
1160 ;;;###autoload (autoload 'ibuffer-do-sort-by-filename/process "ibuf-ext")
1161 (define-ibuffer-sorter filename/process
1162  "Sort the buffers by their file name/process name."
1163   (:description "file name")
1164   (string-lessp
1165    ;; FIXME: For now just compare the file name and the process name
1166    ;; (if it exists).  Is there a better way to do this?
1167    (or (buffer-file-name (car a))
1168        (let ((pr-a (get-buffer-process (car a))))
1169          (and (processp pr-a) (process-name pr-a))))
1170    (or (buffer-file-name (car b))
1171        (let ((pr-b (get-buffer-process (car b))))
1172          (and (processp pr-b) (process-name pr-b))))))
1173
1174 ;;; Functions to emulate bs.el
1175
1176 ;;;###autoload
1177 (defun ibuffer-bs-show ()
1178   "Emulate `bs-show' from the bs.el package."
1179   (interactive)
1180   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1181   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1182
1183 (defun ibuffer-bs-toggle-all ()
1184   "Emulate `bs-toggle-show-all' from the bs.el package."
1185   (interactive)
1186   (if ibuffer-filtering-qualifiers
1187       (ibuffer-pop-filter)
1188     (progn (ibuffer-push-filter '(filename . ".*"))
1189            (ibuffer-update nil t))))
1190
1191 ;;; Handy functions
1192
1193 ;;;###autoload
1194 (defun ibuffer-add-to-tmp-hide (regexp)
1195   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1196 This means that buffers whose name matches REGEXP will not be shown
1197 for this Ibuffer session."
1198   (interactive
1199    (list
1200     (read-from-minibuffer "Never show buffers matching: "
1201                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1202   (push regexp ibuffer-tmp-hide-regexps))
1203
1204 ;;;###autoload
1205 (defun ibuffer-add-to-tmp-show (regexp)
1206   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1207 This means that buffers whose name matches REGEXP will always be shown
1208 for this Ibuffer session."
1209   (interactive
1210    (list
1211     (read-from-minibuffer "Always show buffers matching: "
1212                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1213   (push regexp ibuffer-tmp-show-regexps))
1214
1215 ;;;###autoload
1216 (defun ibuffer-forward-next-marked (&optional count mark direction)
1217   "Move forward by COUNT marked buffers (default 1).
1218
1219 If MARK is non-nil, it should be a character denoting the type of mark
1220 to move by.  The default is `ibuffer-marked-char'.
1221
1222 If DIRECTION is non-nil, it should be an integer; negative integers
1223 mean move backwards, non-negative integers mean move forwards."
1224   (interactive "P")
1225   (unless count
1226     (setq count 1))
1227   (unless mark
1228     (setq mark ibuffer-marked-char))
1229   (unless direction
1230     (setq direction 1))
1231   ;; Skip the title
1232   (ibuffer-forward-line 0)
1233   (let ((opos (point))
1234         curmark)
1235     (ibuffer-forward-line direction)
1236     (while (not (or (= (point) opos)
1237                     (eq (setq curmark (ibuffer-current-mark))
1238                         mark)))
1239       (ibuffer-forward-line direction))
1240     (when (and (= (point) opos)
1241                (not (eq (ibuffer-current-mark) mark)))
1242       (error "No buffers with mark %c" mark))))
1243
1244 ;;;###autoload
1245 (defun ibuffer-backwards-next-marked (&optional count mark)
1246    "Move backwards by COUNT marked buffers (default 1).
1247
1248 If MARK is non-nil, it should be a character denoting the type of mark
1249 to move by.  The default is `ibuffer-marked-char'."
1250    (interactive "P")
1251    (ibuffer-forward-next-marked count mark -1))
1252
1253 ;;;###autoload
1254 (defun ibuffer-do-kill-lines ()
1255   "Hide all of the currently marked lines."
1256   (interactive)
1257   (if (= (ibuffer-count-marked-lines) 0)
1258       (message "No buffers marked; use 'm' to mark a buffer")
1259     (let ((count
1260            (ibuffer-map-marked-lines
1261             #'(lambda (buf mark)
1262                 'kill))))
1263       (message "Killed %s lines" count))))
1264
1265 ;;;###autoload
1266 (defun ibuffer-jump-to-buffer (name)
1267   "Move point to the buffer whose name is NAME.
1268
1269 If called interactively, prompt for a buffer name and go to the
1270 corresponding line in the Ibuffer buffer.  If said buffer is in a
1271 hidden group filter, open it.
1272
1273 If `ibuffer-jump-offer-only-visible-buffers' is non-nil, only offer
1274 visible buffers in the completion list.  Calling the command with
1275 a prefix argument reverses the meaning of that variable."
1276   (interactive (list
1277                 (let ((only-visible ibuffer-jump-offer-only-visible-buffers))
1278                   (when current-prefix-arg
1279                     (setq only-visible (not only-visible)))
1280                   (if only-visible
1281                       (let ((table (mapcar #'(lambda (x)
1282                                                (buffer-name (car x)))
1283                                            (ibuffer-current-state-list))))
1284                         (when (null table)
1285                           (error "No buffers!"))
1286                         (completing-read "Jump to buffer: "
1287                                          table nil t))
1288                     (read-buffer "Jump to buffer: " nil t)))))
1289   (when (not (string= "" name))
1290     (let (buf-point)
1291       ;; Blindly search for our buffer: it is very likely that it is
1292       ;; not in a hidden filter group.
1293       (ibuffer-map-lines #'(lambda (buf marks)
1294                              (when (string= (buffer-name buf) name)
1295                                (setq buf-point (point))
1296                                nil))
1297                          t nil)
1298       (when (and
1299              (null buf-point)
1300              (not (null ibuffer-hidden-filter-groups)))
1301         ;; We did not find our buffer.  It must be in a hidden filter
1302         ;; group, so go through all hidden filter groups to find it.
1303         (catch 'found
1304           (dolist (group ibuffer-hidden-filter-groups)
1305             (ibuffer-jump-to-filter-group group)
1306             (ibuffer-toggle-filter-group)
1307             (ibuffer-map-lines #'(lambda (buf marks)
1308                                    (when (string= (buffer-name buf) name)
1309                                      (setq buf-point (point))
1310                                      nil))
1311                                t group)
1312             (if buf-point
1313                 (throw 'found nil)
1314               (ibuffer-toggle-filter-group)))))
1315       (if (null buf-point)
1316           ;; Still not found even though we expanded all hidden filter
1317           ;; groups: that must be because it's hidden by predicate:
1318           ;; we won't bother trying to display it.
1319           (error "No buffer with name %s" name)
1320         (goto-char buf-point)))))
1321
1322 ;;;###autoload
1323 (defun ibuffer-diff-with-file ()
1324   "View the differences between this buffer and its associated file.
1325 This requires the external program \"diff\" to be in your `exec-path'."
1326   (interactive)
1327   (let ((buf (ibuffer-current-buffer)))
1328     (unless (buffer-live-p buf)
1329       (error "Buffer %s has been killed" buf))
1330     (diff-buffer-with-file buf)))
1331
1332 ;;;###autoload
1333 (defun ibuffer-copy-filename-as-kill (&optional arg)
1334   "Copy filenames of marked buffers into the kill ring.
1335
1336 The names are separated by a space.
1337 If a buffer has no filename, it is ignored.
1338
1339 With no prefix arg, use the filename sans its directory of each marked file.
1340 With a zero prefix arg, use the complete filename of each marked file.
1341 With \\[universal-argument], use the filename of each marked file relative
1342 to `ibuffer-default-directory' if non-nil, otherwise `default-directory'.
1343
1344 You can then feed the file name(s) to other commands with \\[yank]."
1345   (interactive "p")
1346   (if (zerop (ibuffer-count-marked-lines))
1347       (message "No buffers marked; use 'm' to mark a buffer")
1348     (let ((ibuffer-copy-filename-as-kill-result "")
1349           (type (cond ((zerop arg)
1350                        'full)
1351                       ((= arg 4)
1352                        'relative)
1353                       (t
1354                        'name))))
1355       (ibuffer-map-marked-lines
1356        #'(lambda (buf mark)
1357            (setq ibuffer-copy-filename-as-kill-result
1358                  (concat ibuffer-copy-filename-as-kill-result
1359                          (let ((name (buffer-file-name buf)))
1360                            (if name
1361                                (case type
1362                                  (full
1363                                   name)
1364                                  (relative
1365                                   (file-relative-name
1366                                    name (or ibuffer-default-directory
1367                                             default-directory)))
1368                                  (t
1369                                   (file-name-nondirectory name)))
1370                              ""))
1371                          " "))))
1372       (kill-new ibuffer-copy-filename-as-kill-result))))
1373
1374 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1375   (let ((count
1376          (ibuffer-map-lines
1377           #'(lambda (buf mark)
1378               (when (funcall func buf)
1379                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1380                                         ibuffer-marked-char))
1381                 t))
1382           nil
1383           group)))
1384     (ibuffer-redisplay t)
1385     (message "Marked %s buffers" count)))
1386
1387 ;;;###autoload
1388 (defun ibuffer-mark-by-name-regexp (regexp)
1389   "Mark all buffers whose name matches REGEXP."
1390   (interactive "sMark by name (regexp): ")
1391   (ibuffer-mark-on-buffer
1392    #'(lambda (buf)
1393        (string-match regexp (buffer-name buf)))))
1394
1395 ;;;###autoload
1396 (defun ibuffer-mark-by-mode-regexp (regexp)
1397   "Mark all buffers whose major mode matches REGEXP."
1398   (interactive "sMark by major mode (regexp): ")
1399   (ibuffer-mark-on-buffer
1400    #'(lambda (buf)
1401        (with-current-buffer buf
1402          (string-match regexp (format-mode-line mode-name nil nil buf))))))
1403
1404 ;;;###autoload
1405 (defun ibuffer-mark-by-file-name-regexp (regexp)
1406   "Mark all buffers whose file name matches REGEXP."
1407   (interactive "sMark by file name (regexp): ")
1408   (ibuffer-mark-on-buffer
1409    #'(lambda (buf)
1410        (let ((name (or (buffer-file-name buf)
1411                        (with-current-buffer buf
1412                          (and
1413                           (boundp 'dired-directory)
1414                           (stringp dired-directory)
1415                           dired-directory)))))
1416          (when name
1417            (string-match regexp name))))))
1418
1419 ;;;###autoload
1420 (defun ibuffer-mark-by-mode (mode)
1421   "Mark all buffers whose major mode equals MODE."
1422   (interactive
1423    (list (intern (completing-read "Mark by major mode: " obarray
1424                                   #'(lambda (e)
1425                                       ;; kind of a hack...
1426                                       (and (fboundp e)
1427                                            (string-match "-mode$"
1428                                                          (symbol-name e))))
1429                                   t
1430                                   (let ((buf (ibuffer-current-buffer)))
1431                                     (if (and buf (buffer-live-p buf))
1432                                         (with-current-buffer buf
1433                                           (cons (symbol-name major-mode)
1434                                                 0))
1435                                       ""))))))
1436   (ibuffer-mark-on-buffer
1437    #'(lambda (buf)
1438        (with-current-buffer buf
1439          (eq major-mode mode)))))
1440
1441 ;;;###autoload
1442 (defun ibuffer-mark-modified-buffers ()
1443   "Mark all modified buffers."
1444   (interactive)
1445   (ibuffer-mark-on-buffer
1446    #'(lambda (buf) (buffer-modified-p buf))))
1447
1448 ;;;###autoload
1449 (defun ibuffer-mark-unsaved-buffers ()
1450   "Mark all modified buffers that have an associated file."
1451   (interactive)
1452   (ibuffer-mark-on-buffer
1453    #'(lambda (buf) (and (with-current-buffer buf buffer-file-name)
1454                         (buffer-modified-p buf)))))
1455
1456 ;;;###autoload
1457 (defun ibuffer-mark-dissociated-buffers ()
1458   "Mark all buffers whose associated file does not exist."
1459   (interactive)
1460   (ibuffer-mark-on-buffer
1461    #'(lambda (buf)
1462        (with-current-buffer buf
1463          (or
1464           (and buffer-file-name
1465                (not (file-exists-p buffer-file-name)))
1466           (and (eq major-mode 'dired-mode)
1467                (boundp 'dired-directory)
1468                (stringp dired-directory)
1469                (not (file-exists-p (file-name-directory dired-directory)))))))))
1470
1471 ;;;###autoload
1472 (defun ibuffer-mark-help-buffers ()
1473   "Mark buffers like *Help*, *Apropos*, *Info*."
1474   (interactive)
1475   (ibuffer-mark-on-buffer
1476    #'(lambda (buf)
1477        (with-current-buffer buf
1478          (memq major-mode ibuffer-help-buffer-modes)))))
1479
1480 ;;;###autoload
1481 (defun ibuffer-mark-compressed-file-buffers ()
1482   "Mark buffers whose associated file is compressed."
1483   (interactive)
1484   (ibuffer-mark-on-buffer
1485    #'(lambda (buf)
1486        (with-current-buffer buf
1487          (and buffer-file-name
1488               (string-match ibuffer-compressed-file-name-regexp
1489                            buffer-file-name))))))
1490
1491 ;;;###autoload
1492 (defun ibuffer-mark-old-buffers ()
1493   "Mark buffers which have not been viewed in `ibuffer-old-time' hours."
1494   (interactive)
1495   (ibuffer-mark-on-buffer
1496    #'(lambda (buf)
1497        (with-current-buffer buf
1498          ;; hacked from midnight.el
1499          (when buffer-display-time
1500            (let* ((tm (current-time))
1501                   (now (+ (* (float (ash 1 16)) (car tm))
1502                           (float (cadr tm)) (* 0.0000001 (caddr tm))))
1503                   (then (+ (* (float (ash 1 16))
1504                               (car buffer-display-time))
1505                            (float (cadr buffer-display-time))
1506                            (* 0.0000001 (caddr buffer-display-time)))))
1507              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1508
1509 ;;;###autoload
1510 (defun ibuffer-mark-special-buffers ()
1511   "Mark all buffers whose name begins and ends with '*'."
1512   (interactive)
1513   (ibuffer-mark-on-buffer
1514    #'(lambda (buf) (string-match "^\\*.+\\*$"
1515                                  (buffer-name buf)))))
1516
1517 ;;;###autoload
1518 (defun ibuffer-mark-read-only-buffers ()
1519   "Mark all read-only buffers."
1520   (interactive)
1521   (ibuffer-mark-on-buffer
1522    #'(lambda (buf)
1523        (with-current-buffer buf
1524          buffer-read-only))))
1525
1526 ;;;###autoload
1527 (defun ibuffer-mark-dired-buffers ()
1528   "Mark all `dired' buffers."
1529   (interactive)
1530   (ibuffer-mark-on-buffer
1531    #'(lambda (buf)
1532        (with-current-buffer buf
1533          (eq major-mode 'dired-mode)))))
1534
1535 ;;;###autoload
1536 (defun ibuffer-do-occur (regexp &optional nlines)
1537   "View lines which match REGEXP in all marked buffers.
1538 Optional argument NLINES says how many lines of context to display: it
1539 defaults to one."
1540   (interactive (occur-read-primary-args))
1541   (if (or (not (integerp nlines))
1542           (< nlines 0))
1543       (setq nlines 0))
1544   (when (zerop (ibuffer-count-marked-lines))
1545     (ibuffer-set-mark ibuffer-marked-char))
1546   (let ((ibuffer-do-occur-bufs nil))
1547     ;; Accumulate a list of marked buffers
1548     (ibuffer-map-marked-lines
1549      #'(lambda (buf mark)
1550          (push buf ibuffer-do-occur-bufs)))
1551     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1552
1553 (provide 'ibuf-ext)
1554
1555 ;; arch-tag: 9af21953-deda-4c30-b76d-f81d9128e76d
1556 ;;; ibuf-ext.el ends here