lisp/emacs-lisp/lisp-mode.el

   1 ;;; lisp-mode.el --- Lisp mode, and its idiosyncratic commands.
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: lisp, languages
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Code:
  25
  26 ;;; Commentary:
  27
  28 ;; The base major mode for editing Lisp code (used also for Emacs Lisp).
  29 ;; This mode is documented in the Emacs manual
  30
  31 ;;; Code:
  32
  33 (defvar lisp-mode-syntax-table nil "")
  34 (defvar emacs-lisp-mode-syntax-table nil "")
  35 (defvar lisp-mode-abbrev-table nil "")
  36
  37 (if (not emacs-lisp-mode-syntax-table)
  38     (let ((i 0))
  39       (setq emacs-lisp-mode-syntax-table (make-syntax-table))
  40       (while (< i ?0)
  41         (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
  42         (setq i (1+ i)))
  43       (setq i (1+ ?9))
  44       (while (< i ?A)
  45         (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
  46         (setq i (1+ i)))
  47       (setq i (1+ ?Z))
  48       (while (< i ?a)
  49         (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
  50         (setq i (1+ i)))
  51       (setq i (1+ ?z))
  52       (while (< i 128)
  53         (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
  54         (setq i (1+ i)))
  55       (modify-syntax-entry ?  "    " emacs-lisp-mode-syntax-table)
  56       (modify-syntax-entry ?\t "    " emacs-lisp-mode-syntax-table)
  57       (modify-syntax-entry ?\n ">   " emacs-lisp-mode-syntax-table)
  58       (modify-syntax-entry ?\f ">   " emacs-lisp-mode-syntax-table)
  59       (modify-syntax-entry ?\; "<   " emacs-lisp-mode-syntax-table)
  60       (modify-syntax-entry ?` "'   " emacs-lisp-mode-syntax-table)
  61       (modify-syntax-entry ?' "'   " emacs-lisp-mode-syntax-table)
  62       (modify-syntax-entry ?, "'   " emacs-lisp-mode-syntax-table)
  63       ;; Used to be singlequote; changed for flonums.
  64       (modify-syntax-entry ?. "_   " emacs-lisp-mode-syntax-table)
  65       (modify-syntax-entry ?# "'   " emacs-lisp-mode-syntax-table)
  66       (modify-syntax-entry ?\" "\"    " emacs-lisp-mode-syntax-table)
  67       (modify-syntax-entry ?\\ "\\   " emacs-lisp-mode-syntax-table)
  68       (modify-syntax-entry ?\( "()  " emacs-lisp-mode-syntax-table)
  69       (modify-syntax-entry ?\) ")(  " emacs-lisp-mode-syntax-table)
  70       (modify-syntax-entry ?\[ "(]  " emacs-lisp-mode-syntax-table)
  71       (modify-syntax-entry ?\] ")[  " emacs-lisp-mode-syntax-table)))
  72
  73 (if (not lisp-mode-syntax-table)
  74     (progn (setq lisp-mode-syntax-table
  75                  (copy-syntax-table emacs-lisp-mode-syntax-table))
  76            (modify-syntax-entry ?\| "\"   " lisp-mode-syntax-table)
  77            (modify-syntax-entry ?\[ "_   " lisp-mode-syntax-table)
  78            (modify-syntax-entry ?\] "_   " lisp-mode-syntax-table)))
  79
  80 (define-abbrev-table 'lisp-mode-abbrev-table ())
  81
  82 (defun lisp-mode-variables (lisp-syntax)
  83   (cond (lisp-syntax
  84           (set-syntax-table lisp-mode-syntax-table)))
  85   (setq local-abbrev-table lisp-mode-abbrev-table)
  86   (make-local-variable 'paragraph-start)
  87   (setq paragraph-start (concat "^$\\|" page-delimiter))
  88   (make-local-variable 'paragraph-separate)
  89   (setq paragraph-separate paragraph-start)
  90   (make-local-variable 'paragraph-ignore-fill-prefix)
  91   (setq paragraph-ignore-fill-prefix t)
  92   (make-local-variable 'indent-line-function)
  93   (setq indent-line-function 'lisp-indent-line)
  94   (make-local-variable 'indent-region-function)
  95   (setq indent-region-function 'lisp-indent-region)
  96   (make-local-variable 'parse-sexp-ignore-comments)
  97   (setq parse-sexp-ignore-comments t)
  98   (make-local-variable 'comment-start)
  99   (setq comment-start ";")
 100   (make-local-variable 'comment-start-skip)
 101   (setq comment-start-skip ";+ *")
 102   (make-local-variable 'comment-column)
 103   (setq comment-column 40)
 104   (make-local-variable 'comment-indent-function)
 105   (setq comment-indent-function 'lisp-comment-indent))
 106 \f
 107 (defvar shared-lisp-mode-map ()
 108   "Keymap for commands shared by all sorts of Lisp modes.")
 109
 110 (if shared-lisp-mode-map
 111     ()
 112    (setq shared-lisp-mode-map (make-sparse-keymap))
 113    (define-key shared-lisp-mode-map "\e\C-q" 'indent-sexp)
 114    (define-key shared-lisp-mode-map "\M-q" 'lisp-fill-paragraph)
 115    (define-key shared-lisp-mode-map "\177" 'backward-delete-char-untabify)
 116    (define-key shared-lisp-mode-map "\t" 'lisp-indent-line))
 117
 118 (defvar emacs-lisp-mode-map ()
 119   "Keymap for Emacs Lisp mode.
 120 All commands in shared-lisp-mode-map are inherited by this map.")
 121
 122 (if emacs-lisp-mode-map
 123     ()
 124   (setq emacs-lisp-mode-map
 125         (nconc (make-sparse-keymap) shared-lisp-mode-map))
 126   (define-key emacs-lisp-mode-map "\e\t" 'lisp-complete-symbol)
 127   (define-key emacs-lisp-mode-map "\e\C-x" 'eval-defun))
 128
 129 (defun emacs-lisp-mode ()
 130   "Major mode for editing Lisp code to run in Emacs.
 131 Commands:
 132 Delete converts tabs to spaces as it moves back.
 133 Blank lines separate paragraphs.  Semicolons start comments.
 134 \\{emacs-lisp-mode-map}
 135 Entry to this mode calls the value of `emacs-lisp-mode-hook'
 136 if that value is non-nil."
 137   (interactive)
 138   (kill-all-local-variables)
 139   (use-local-map emacs-lisp-mode-map)
 140   (set-syntax-table emacs-lisp-mode-syntax-table)
 141   (setq major-mode 'emacs-lisp-mode)
 142   (setq mode-name "Emacs-Lisp")
 143   (lisp-mode-variables nil)
 144   (run-hooks 'emacs-lisp-mode-hook))
 145
 146 (defvar lisp-mode-map ()
 147   "Keymap for ordinary Lisp mode.
 148 All commands in `shared-lisp-mode-map' are inherited by this map.")
 149
 150 (if lisp-mode-map
 151     ()
 152   (setq lisp-mode-map
 153         (nconc (make-sparse-keymap) shared-lisp-mode-map))
 154   (define-key lisp-mode-map "\e\C-x" 'lisp-send-defun)
 155   (define-key lisp-mode-map "\C-c\C-l" 'run-lisp))
 156
 157 (defun lisp-mode ()
 158   "Major mode for editing Lisp code for Lisps other than GNU Emacs Lisp.
 159 Commands:
 160 Delete converts tabs to spaces as it moves back.
 161 Blank lines separate paragraphs.  Semicolons start comments.
 162 \\{lisp-mode-map}
 163 Note that `run-lisp' may be used either to start an inferior Lisp job
 164 or to switch back to an existing one.
 165
 166 Entry to this mode calls the value of `lisp-mode-hook'
 167 if that value is non-nil."
 168   (interactive)
 169   (kill-all-local-variables)
 170   (use-local-map lisp-mode-map)
 171   (setq major-mode 'lisp-mode)
 172   (setq mode-name "Lisp")
 173   (lisp-mode-variables t)
 174   (set-syntax-table lisp-mode-syntax-table)
 175   (run-hooks 'lisp-mode-hook))
 176
 177 ;; This will do unless shell.el is loaded.
 178 (defun lisp-send-defun nil
 179   "Send the current defun to the Lisp process made by \\[run-lisp]."
 180   (interactive)
 181   (error "Process lisp does not exist"))
 182
 183 (defvar lisp-interaction-mode-map ()
 184   "Keymap for Lisp Interaction moe.
 185 All commands in `shared-lisp-mode-map' are inherited by this map.")
 186
 187 (if lisp-interaction-mode-map
 188     ()
 189   (setq lisp-interaction-mode-map
 190         (nconc (make-sparse-keymap) shared-lisp-mode-map))
 191   (define-key lisp-interaction-mode-map "\e\C-x" 'eval-defun)
 192   (define-key lisp-interaction-mode-map "\e\t" 'lisp-complete-symbol)
 193   (define-key lisp-interaction-mode-map "\n" 'eval-print-last-sexp))
 194
 195 (defun lisp-interaction-mode ()
 196   "Major mode for typing and evaluating Lisp forms.
 197 Like Lisp mode except that \\[eval-print-last-sexp] evals the Lisp expression
 198 before point, and prints its value into the buffer, advancing point.
 199
 200 Commands:
 201 Delete converts tabs to spaces as it moves back.
 202 Paragraphs are separated only by blank lines.
 203 Semicolons start comments.
 204 \\{lisp-interaction-mode-map}
 205 Entry to this mode calls the value of `lisp-interaction-mode-hook'
 206 if that value is non-nil."
 207   (interactive)
 208   (kill-all-local-variables)
 209   (use-local-map lisp-interaction-mode-map)
 210   (setq major-mode 'lisp-interaction-mode)
 211   (setq mode-name "Lisp Interaction")
 212   (set-syntax-table emacs-lisp-mode-syntax-table)
 213   (lisp-mode-variables nil)
 214   (run-hooks 'lisp-interaction-mode-hook))
 215
 216 (defun eval-print-last-sexp ()
 217   "Evaluate sexp before point; print value into current buffer."
 218   (interactive)
 219   (let ((standard-output (current-buffer)))
 220     (terpri)
 221     (eval-last-sexp t)
 222     (terpri)))
 223 \f
 224 (defun eval-last-sexp (eval-last-sexp-arg-internal)
 225   "Evaluate sexp before point; print value in minibuffer.
 226 With argument, print output into current buffer."
 227   (interactive "P")
 228   (let ((standard-output (if eval-last-sexp-arg-internal (current-buffer) t))
 229         (opoint (point)))
 230     (prin1 (let ((stab (syntax-table)))
 231              (eval (unwind-protect
 232                        (save-excursion
 233                          (set-syntax-table emacs-lisp-mode-syntax-table)
 234                          (forward-sexp -1)
 235                          (save-restriction
 236                            (narrow-to-region (point-min) opoint)
 237                            (read (current-buffer))))
 238                      (set-syntax-table stab)))))))
 239
 240 (defun eval-defun (eval-defun-arg-internal)
 241   "Evaluate defun that point is in or before.
 242 Print value in minibuffer.
 243 With argument, insert value in current buffer after the defun."
 244   (interactive "P")
 245   (let ((standard-output (if eval-defun-arg-internal (current-buffer) t)))
 246     (prin1 (eval (save-excursion
 247                    (end-of-defun)
 248                    (beginning-of-defun)
 249                    (read (current-buffer)))))))
 250 \f
 251 (defun lisp-comment-indent ()
 252   (if (looking-at "\\s<\\s<\\s<")
 253       (current-column)
 254     (if (looking-at "\\s<\\s<")
 255         (let ((tem (calculate-lisp-indent)))
 256           (if (listp tem) (car tem) tem))
 257       (skip-chars-backward " \t")
 258       (max (if (bolp) 0 (1+ (current-column)))
 259            comment-column))))
 260
 261 (defconst lisp-indent-offset nil "")
 262 (defconst lisp-indent-function 'lisp-indent-function "")
 263
 264 (defun lisp-indent-line (&optional whole-exp)
 265   "Indent current line as Lisp code.
 266 With argument, indent any additional lines of the same expression
 267 rigidly along with this one."
 268   (interactive "P")
 269   (let ((indent (calculate-lisp-indent)) shift-amt beg end
 270         (pos (- (point-max) (point))))
 271     (beginning-of-line)
 272     (setq beg (point))
 273     (skip-chars-forward " \t")
 274     (if (looking-at "\\s<\\s<\\s<")
 275         ;; Don't alter indentation of a ;;; comment line.
 276         (goto-char (- (point-max) pos))
 277       (if (and (looking-at "\\s<") (not (looking-at "\\s<\\s<")))
 278           ;; Single-semicolon comment lines should be indented
 279           ;; as comment lines, not as code.
 280           (progn (indent-for-comment) (forward-char -1))
 281         (if (listp indent) (setq indent (car indent)))
 282         (setq shift-amt (- indent (current-column)))
 283         (if (zerop shift-amt)
 284             nil
 285           (delete-region beg (point))
 286           (indent-to indent)))
 287       ;; If initial point was within line's indentation,
 288       ;; position after the indentation.  Else stay at same point in text.
 289       (if (> (- (point-max) pos) (point))
 290           (goto-char (- (point-max) pos)))
 291       ;; If desired, shift remaining lines of expression the same amount.
 292       (and whole-exp (not (zerop shift-amt))
 293            (save-excursion
 294              (goto-char beg)
 295              (forward-sexp 1)
 296              (setq end (point))
 297              (goto-char beg)
 298              (forward-line 1)
 299              (setq beg (point))
 300              (> end beg))
 301            (indent-code-rigidly beg end shift-amt)))))
 302
 303 (defun calculate-lisp-indent (&optional parse-start)
 304   "Return appropriate indentation for current line as Lisp code.
 305 In usual case returns an integer: the column to indent to.
 306 Can instead return a list, whose car is the column to indent to.
 307 This means that following lines at the same level of indentation
 308 should not necessarily be indented the same way.
 309 The second element of the list is the buffer position
 310 of the start of the containing expression."
 311   (save-excursion
 312     (beginning-of-line)
 313     (let ((indent-point (point))
 314           state paren-depth
 315           ;; setting this to a number inhibits calling hook
 316           (desired-indent nil)
 317           (retry t)
 318           last-sexp containing-sexp)
 319       (if parse-start
 320           (goto-char parse-start)
 321           (beginning-of-defun))
 322       ;; Find outermost containing sexp
 323       (while (< (point) indent-point)
 324         (setq state (parse-partial-sexp (point) indent-point 0)))
 325       ;; Find innermost containing sexp
 326       (while (and retry
 327                   state
 328                   (> (setq paren-depth (elt state 0)) 0))
 329         (setq retry nil)
 330         (setq last-sexp (elt state 2))
 331         (setq containing-sexp (elt state 1))
 332         ;; Position following last unclosed open.
 333         (goto-char (1+ containing-sexp))
 334         ;; Is there a complete sexp since then?
 335         (if (and last-sexp (> last-sexp (point)))
 336             ;; Yes, but is there a containing sexp after that?
 337             (let ((peek (parse-partial-sexp last-sexp indent-point 0)))
 338               (if (setq retry (car (cdr peek))) (setq state peek)))))
 339       (if retry
 340           nil
 341         ;; Innermost containing sexp found
 342         (goto-char (1+ containing-sexp))
 343         (if (not last-sexp)
 344             ;; indent-point immediately follows open paren.
 345             ;; Don't call hook.
 346             (setq desired-indent (current-column))
 347           ;; Find the start of first element of containing sexp.
 348           (parse-partial-sexp (point) last-sexp 0 t)
 349           (cond ((looking-at "\\s(")
 350                  ;; First element of containing sexp is a list.
 351                  ;; Indent under that list.
 352                  )
 353                 ((> (save-excursion (forward-line 1) (point))
 354                     last-sexp)
 355                  ;; This is the first line to start within the containing sexp.
 356                  ;; It's almost certainly a function call.
 357                  (if (= (point) last-sexp)
 358                      ;; Containing sexp has nothing before this line
 359                      ;; except the first element.  Indent under that element.
 360                      nil
 361                    ;; Skip the first element, find start of second (the first
 362                    ;; argument of the function call) and indent under.
 363                    (progn (forward-sexp 1)
 364                           (parse-partial-sexp (point) last-sexp 0 t)))
 365                  (backward-prefix-chars))
 366                 (t
 367                  ;; Indent beneath first sexp on same line as last-sexp.
 368                  ;; Again, it's almost certainly a function call.
 369                  (goto-char last-sexp)
 370                  (beginning-of-line)
 371                  (parse-partial-sexp (point) last-sexp 0 t)
 372                  (backward-prefix-chars)))))
 373       ;; Point is at the point to indent under unless we are inside a string.
 374       ;; Call indentation hook except when overridden by lisp-indent-offset
 375       ;; or if the desired indentation has already been computed.
 376       (let ((normal-indent (current-column)))
 377         (cond ((elt state 3)
 378                ;; Inside a string, don't change indentation.
 379                (goto-char indent-point)
 380                (skip-chars-forward " \t")
 381                (current-column))
 382               ((and (integerp lisp-indent-offset) containing-sexp)
 383                ;; Indent by constant offset
 384                (goto-char containing-sexp)
 385                (+ (current-column) lisp-indent-offset))
 386               (desired-indent)
 387               ((and (boundp 'lisp-indent-function)
 388                     lisp-indent-function
 389                     (not retry))
 390                (or (funcall lisp-indent-function indent-point state)
 391                    normal-indent))
 392               (t
 393                normal-indent))))))
 394
 395 (defun lisp-indent-function (indent-point state)
 396   (let ((normal-indent (current-column)))
 397     (goto-char (1+ (elt state 1)))
 398     (parse-partial-sexp (point) last-sexp 0 t)
 399     (if (and (elt state 2)
 400              (not (looking-at "\\sw\\|\\s_")))
 401         ;; car of form doesn't seem to be a a symbol
 402         (progn
 403           (if (not (> (save-excursion (forward-line 1) (point))
 404                       last-sexp))
 405               (progn (goto-char last-sexp)
 406                      (beginning-of-line)
 407                      (parse-partial-sexp (point) last-sexp 0 t)))
 408           ;; Indent under the list or under the first sexp on the
 409           ;; same line as last-sexp.  Note that first thing on that
 410           ;; line has to be complete sexp since we are inside the
 411           ;; innermost containing sexp.
 412           (backward-prefix-chars)
 413           (current-column))
 414       (let ((function (buffer-substring (point)
 415                                         (progn (forward-sexp 1) (point))))
 416             method)
 417         (setq method (or (get (intern-soft function) 'lisp-indent-function)
 418                          (get (intern-soft function) 'lisp-indent-hook)))
 419         (cond ((or (eq method 'defun)
 420                    (and (null method)
 421                         (> (length function) 3)
 422                         (string-match "\\`def" function)))
 423                (lisp-indent-defform state indent-point))
 424               ((integerp method)
 425                (lisp-indent-specform method state
 426                                      indent-point normal-indent))
 427               (method
 428                 (funcall method state indent-point)))))))
 429
 430 (defconst lisp-body-indent 2
 431   "Number of columns to indent the second line of a `(def...)' form.")
 432
 433 (defun lisp-indent-specform (count state indent-point normal-indent)
 434   (let ((containing-form-start (elt state 1))
 435         (i count)
 436         body-indent containing-form-column)
 437     ;; Move to the start of containing form, calculate indentation
 438     ;; to use for non-distinguished forms (> count), and move past the
 439     ;; function symbol.  lisp-indent-function guarantees that there is at
 440     ;; least one word or symbol character following open paren of containing
 441     ;; form.
 442     (goto-char containing-form-start)
 443     (setq containing-form-column (current-column))
 444     (setq body-indent (+ lisp-body-indent containing-form-column))
 445     (forward-char 1)
 446     (forward-sexp 1)
 447     ;; Now find the start of the last form.
 448     (parse-partial-sexp (point) indent-point 1 t)
 449     (while (and (< (point) indent-point)
 450                 (condition-case ()
 451                     (progn
 452                       (setq count (1- count))
 453                       (forward-sexp 1)
 454                       (parse-partial-sexp (point) indent-point 1 t))
 455                   (error nil))))
 456     ;; Point is sitting on first character of last (or count) sexp.
 457     (if (> count 0)
 458         ;; A distinguished form.  If it is the first or second form use double
 459         ;; lisp-body-indent, else normal indent.  With lisp-body-indent bound
 460         ;; to 2 (the default), this just happens to work the same with if as
 461         ;; the older code, but it makes unwind-protect, condition-case,
 462         ;; with-output-to-temp-buffer, et. al. much more tasteful.  The older,
 463         ;; less hacked, behavior can be obtained by replacing below with
 464         ;; (list normal-indent containing-form-start).
 465         (if (<= (- i count) 1)
 466             (list (+ containing-form-column (* 2 lisp-body-indent))
 467                   containing-form-start)
 468             (list normal-indent containing-form-start))
 469       ;; A non-distinguished form.  Use body-indent if there are no
 470       ;; distinguished forms and this is the first undistinguished form,
 471       ;; or if this is the first undistinguished form and the preceding
 472       ;; distinguished form has indentation at least as great as body-indent.
 473       (if (or (and (= i 0) (= count 0))
 474               (and (= count 0) (<= body-indent normal-indent)))
 475           body-indent
 476           normal-indent))))
 477
 478 (defun lisp-indent-defform (state indent-point)
 479   (goto-char (car (cdr state)))
 480   (forward-line 1)
 481   (if (> (point) (car (cdr (cdr state))))
 482       (progn
 483         (goto-char (car (cdr state)))
 484         (+ lisp-body-indent (current-column)))))
 485
 486 \f
 487 ;; (put 'progn 'lisp-indent-function 0), say, causes progn to be indented
 488 ;; like defun if the first form is placed on the next line, otherwise
 489 ;; it is indented like any other form (i.e. forms line up under first).
 490
 491 (put 'lambda 'lisp-indent-function 'defun)
 492 (put 'autoload 'lisp-indent-function 'defun)
 493 (put 'progn 'lisp-indent-function 0)
 494 (put 'prog1 'lisp-indent-function 1)
 495 (put 'prog2 'lisp-indent-function 2)
 496 (put 'save-excursion 'lisp-indent-function 0)
 497 (put 'save-window-excursion 'lisp-indent-function 0)
 498 (put 'save-restriction 'lisp-indent-function 0)
 499 (put 'save-match-data 'lisp-indent-function 0)
 500 (put 'let 'lisp-indent-function 1)
 501 (put 'let* 'lisp-indent-function 1)
 502 (put 'while 'lisp-indent-function 1)
 503 (put 'if 'lisp-indent-function 2)
 504 (put 'catch 'lisp-indent-function 1)
 505 (put 'condition-case 'lisp-indent-function 2)
 506 (put 'unwind-protect 'lisp-indent-function 1)
 507 (put 'with-output-to-temp-buffer 'lisp-indent-function 1)
 508
 509 (defun indent-sexp (&optional endpos)
 510   "Indent each line of the list starting just after point.
 511 If optional arg ENDPOS is given, indent each line, stopping when
 512 ENDPOS is encountered."
 513   (interactive)
 514   (let ((indent-stack (list nil))
 515         (next-depth 0)
 516         (starting-point (point))
 517         (last-point (point))
 518         last-depth bol outer-loop-done inner-loop-done state this-indent)
 519     ;; Get error now if we don't have a complete sexp after point.
 520     (save-excursion (forward-sexp 1))
 521     (save-excursion
 522       (setq outer-loop-done nil)
 523       (while (if endpos (< (point) endpos)
 524                (not outer-loop-done))
 525         (setq last-depth next-depth
 526               inner-loop-done nil)
 527         ;; Parse this line so we can learn the state
 528         ;; to indent the next line.
 529         ;; This inner loop goes through only once
 530         ;; unless a line ends inside a string.
 531         (while (and (not inner-loop-done)
 532                     (not (setq outer-loop-done (eobp))))
 533           (setq state (parse-partial-sexp (point) (progn (end-of-line) (point))
 534                                           nil nil state))
 535           (setq next-depth (car state))
 536           ;; If the line contains a comment other than the sort
 537           ;; that is indented like code,
 538           ;; indent it now with indent-for-comment.
 539           ;; Comments indented like code are right already.
 540           ;; In any case clear the in-comment flag in the state
 541           ;; because parse-partial-sexp never sees the newlines.
 542           (if (car (nthcdr 4 state))
 543               (progn (indent-for-comment)
 544                      (end-of-line)
 545                      (setcar (nthcdr 4 state) nil)))
 546           ;; If this line ends inside a string,
 547           ;; go straight to next line, remaining within the inner loop,
 548           ;; and turn off the \-flag.
 549           (if (car (nthcdr 3 state))
 550               (progn
 551                 (forward-line 1)
 552                 (setcar (nthcdr 5 state) nil))
 553             (setq inner-loop-done t)))
 554         (and endpos
 555              (<= next-depth 0)
 556              (progn
 557                (setq indent-stack (append indent-stack
 558                                           (make-list (- next-depth) nil))
 559                      last-depth (- last-depth next-depth)
 560                      next-depth 0)))
 561         (or outer-loop-done
 562             (setq outer-loop-done (<= next-depth 0)))
 563         (if outer-loop-done
 564             (forward-line 1)
 565           (while (> last-depth next-depth)
 566             (setq indent-stack (cdr indent-stack)
 567                   last-depth (1- last-depth)))
 568           (while (< last-depth next-depth)
 569             (setq indent-stack (cons nil indent-stack)
 570                   last-depth (1+ last-depth)))
 571           ;; Now go to the next line and indent it according
 572           ;; to what we learned from parsing the previous one.
 573           (forward-line 1)
 574           (setq bol (point))
 575           (skip-chars-forward " \t")
 576           ;; But not if the line is blank, or just a comment
 577           ;; (except for double-semi comments; indent them as usual).
 578           (if (or (eobp) (looking-at "\\s<\\|\n"))
 579               nil
 580             (if (and (car indent-stack)
 581                      (>= (car indent-stack) 0))
 582                 (setq this-indent (car indent-stack))
 583               (let ((val (calculate-lisp-indent
 584                           (if (car indent-stack) (- (car indent-stack))
 585                             starting-point))))
 586                 (if (integerp val)
 587                     (setcar indent-stack
 588                             (setq this-indent val))
 589                   (setcar indent-stack (- (car (cdr val))))
 590                   (setq this-indent (car val)))))
 591             (if (/= (current-column) this-indent)
 592                 (progn (delete-region bol (point))
 593                        (indent-to this-indent)))))
 594         (or outer-loop-done
 595             (setq outer-loop-done (= (point) last-point))
 596             (setq last-point (point)))))))
 597
 598 ;; Indent every line whose first char is between START and END inclusive.
 599 (defun lisp-indent-region (start end)
 600   (save-excursion
 601     (goto-char start)
 602     (and (bolp) (not (eolp))
 603          (lisp-indent-line))
 604     (let ((endmark (copy-marker end)))
 605       (indent-sexp endmark)
 606       (set-marker endmark nil))))
 607 \f
 608 ;;;; Lisp paragraph filling commands.
 609
 610 (defun lisp-fill-paragraph (&optional justify)
 611   "Like \\[fill-paragraph], but handle Emacs Lisp comments.
 612 If any of the current line is a comment, fill the comment or the
 613 paragraph of it that point is in, preserving the comment's indentation
 614 and initial semicolons."
 615   (interactive "P")
 616   (let (
 617         ;; Non-nil if the current line contains a comment.
 618         has-comment
 619
 620         ;; If has-comment, the appropriate fill-prefix for the comment.
 621         comment-fill-prefix
 622         )
 623
 624     ;; Figure out what kind of comment we are looking at.
 625     (save-excursion
 626       (beginning-of-line)
 627       (cond
 628
 629        ;; A line with nothing but a comment on it?
 630        ((looking-at "[ \t]*;[; \t]*")
 631         (setq has-comment t
 632               comment-fill-prefix (buffer-substring (match-beginning 0)
 633                                                     (match-end 0))))
 634
 635        ;; A line with some code, followed by a comment?  Remember that the
 636        ;; semi which starts the comment shouldn't be part of a string or
 637        ;; character.
 638        ((progn
 639           (while (not (looking-at ";\\|$"))
 640             (skip-chars-forward "^;\n\"\\\\?")
 641             (cond
 642              ((eq (char-after (point)) ?\\) (forward-char 2))
 643              ((memq (char-after (point)) '(?\" ??)) (forward-sexp 1))))
 644           (looking-at ";+[\t ]*"))
 645         (setq has-comment t)
 646         (setq comment-fill-prefix
 647               (concat (make-string (current-column) ? )
 648                       (buffer-substring (match-beginning 0) (match-end 0)))))))
 649
 650     (if (not has-comment)
 651         (fill-paragraph justify)
 652
 653       ;; Narrow to include only the comment, and then fill the region.
 654       (save-restriction
 655         (narrow-to-region
 656          ;; Find the first line we should include in the region to fill.
 657          (save-excursion
 658            (while (and (zerop (forward-line -1))
 659                        (looking-at "^[ \t]*;")))
 660            ;; We may have gone to far.  Go forward again.
 661            (or (looking-at "^[ \t]*;")
 662                (forward-line 1))
 663            (point))
 664          ;; Find the beginning of the first line past the region to fill.
 665          (save-excursion
 666            (while (progn (forward-line 1)
 667                          (looking-at "^[ \t]*;")))
 668            (point)))
 669
 670         ;; Lines with only semicolons on them can be paragraph boundaries.
 671         (let ((paragraph-start (concat paragraph-start "\\|^[ \t;]*$"))
 672               (paragraph-separate (concat paragraph-start "\\|^[ \t;]*$"))
 673               (fill-prefix comment-fill-prefix))
 674           (fill-paragraph justify))))))
 675
 676 \f
 677 (defun indent-code-rigidly (start end arg &optional nochange-regexp)
 678   "Indent all lines of code, starting in the region, sideways by ARG columns.
 679 Does not affect lines starting inside comments or strings, assuming that
 680 the start of the region is not inside them.
 681
 682 Called from a program, takes args START, END, COLUMNS and NOCHANGE-REGEXP.
 683 The last is a regexp which, if matched at the beginning of a line,
 684 means don't indent that line."
 685   (interactive "r\np")
 686   (let (state)
 687     (save-excursion
 688       (goto-char end)
 689       (setq end (point-marker))
 690       (goto-char start)
 691       (or (bolp)
 692           (setq state (parse-partial-sexp (point)
 693                                           (progn
 694                                             (forward-line 1) (point))
 695                                           nil nil state)))
 696       (while (< (point) end)
 697         (or (car (nthcdr 3 state))
 698             (and nochange-regexp
 699                  (looking-at nochange-regexp))
 700             ;; If line does not start in string, indent it
 701             (let ((indent (current-indentation)))
 702               (delete-region (point) (progn (skip-chars-forward " \t") (point)))
 703               (or (eolp)
 704                   (indent-to (max 0 (+ indent arg)) 0))))
 705         (setq state (parse-partial-sexp (point)
 706                                         (progn
 707                                           (forward-line 1) (point))
 708                                         nil nil state))))))
 709
 710 (provide 'lisp-mode)
 711
 712 ;;; lisp-mode.el ends here