lisp/buff-menu.el

   1 ;;; buff-menu.el --- buffer menu main function and support functions.
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; Edit, delete, or change attributes of all currently active Emacs
  26 ;; buffers from a list summarizing their state.  A good way to browse
  27 ;; any special or scratch buffers you have loaded, since you can't find
  28 ;; them by filename.  The single entry point is `Buffer-menu-mode',
  29 ;; normally bound to C-x C-b.
  30
  31 ;;; Change Log:
  32
  33 ;; Merged by esr with recent mods to Emacs 19 buff-menu, 23 Mar 1993
  34 ;;
  35 ;; Modified by Bob Weiner, Motorola, Inc., 4/14/89
  36 ;;
  37 ;; Added optional backup argument to 'Buffer-menu-unmark' to make it undelete
  38 ;; current entry and then move to previous one.
  39 ;;
  40 ;; Based on FSF code dating back to 1985.
  41
  42 ;;; Code:
  43
  44 ;;;Not needed, now that q is now just quit and Buffer-menu-select is v.
  45 ;;;(defvar Buffer-menu-window-config nil
  46 ;;;  "Window configuration saved from entry to `buffer-menu'.")
  47
  48 ; Put buffer *Buffer List* into proper mode right away
  49 ; so that from now on even list-buffers is enough to get a buffer menu.
  50
  51 (defvar Buffer-menu-mode-map nil "")
  52
  53 (if Buffer-menu-mode-map
  54     ()
  55   (setq Buffer-menu-mode-map (make-keymap))
  56   (suppress-keymap Buffer-menu-mode-map t)
  57   (define-key Buffer-menu-mode-map "q" 'Buffer-menu-quit)
  58   (define-key Buffer-menu-mode-map "v" 'Buffer-menu-select)
  59   (define-key Buffer-menu-mode-map "2" 'Buffer-menu-2-window)
  60   (define-key Buffer-menu-mode-map "1" 'Buffer-menu-1-window)
  61   (define-key Buffer-menu-mode-map "f" 'Buffer-menu-this-window)
  62   (define-key Buffer-menu-mode-map "o" 'Buffer-menu-other-window)
  63   (define-key Buffer-menu-mode-map "\C-o" 'Buffer-menu-switch-other-window)
  64   (define-key Buffer-menu-mode-map "s" 'Buffer-menu-save)
  65   (define-key Buffer-menu-mode-map "d" 'Buffer-menu-delete)
  66   (define-key Buffer-menu-mode-map "k" 'Buffer-menu-delete)
  67   (define-key Buffer-menu-mode-map "\C-d" 'Buffer-menu-delete-backwards)
  68   (define-key Buffer-menu-mode-map "\C-k" 'Buffer-menu-delete)
  69   (define-key Buffer-menu-mode-map "x" 'Buffer-menu-execute)
  70   (define-key Buffer-menu-mode-map " " 'next-line)
  71   (define-key Buffer-menu-mode-map "n" 'next-line)
  72   (define-key Buffer-menu-mode-map "p" 'previous-line)
  73   (define-key Buffer-menu-mode-map "\177" 'Buffer-menu-backup-unmark)
  74   (define-key Buffer-menu-mode-map "~" 'Buffer-menu-not-modified)
  75   (define-key Buffer-menu-mode-map "?" 'describe-mode)
  76   (define-key Buffer-menu-mode-map "u" 'Buffer-menu-unmark)
  77   (define-key Buffer-menu-mode-map "m" 'Buffer-menu-mark)
  78   (define-key Buffer-menu-mode-map "t" 'Buffer-menu-visit-tags-table)
  79   (define-key Buffer-menu-mode-map "%" 'Buffer-menu-toggle-read-only)
  80   (define-key Buffer-menu-mode-map [mouse-2] 'Buffer-menu-mouse-select)
  81 )
  82
  83 ;; Buffer Menu mode is suitable only for specially formatted data.
  84 (put 'Buffer-menu-mode 'mode-class 'special)
  85
  86 (defun Buffer-menu-mode ()
  87   "Major mode for editing a list of buffers.
  88 Each line describes one of the buffers in Emacs.
  89 Letters do not insert themselves; instead, they are commands.
  90 \\<Buffer-menu-mode-map>
  91 \\[Buffer-menu-mouse-select] -- select buffer you click on, in place of the buffer menu.
  92 \\[Buffer-menu-this-window] -- select current line's buffer in place of the buffer menu.
  93 \\[Buffer-menu-other-window] -- select that buffer in another window,
  94   so the buffer menu buffer remains visible in its window.
  95 \\[Buffer-menu-switch-other-window] -- make another window display that buffer.
  96 \\[Buffer-menu-mark] -- mark current line's buffer to be displayed.
  97 \\[Buffer-menu-select] -- select current line's buffer.
  98   Also show buffers marked with m, in other windows.
  99 \\[Buffer-menu-1-window] -- select that buffer in full-frame window.
 100 \\[Buffer-menu-2-window] -- select that buffer in one window,
 101   together with buffer selected before this one in another window.
 102 \\[Buffer-menu-visit-tags-table] -- visit-tags-table this buffer.
 103 \\[Buffer-menu-not-modified] -- clear modified-flag on that buffer.
 104 \\[Buffer-menu-save] -- mark that buffer to be saved, and move down.
 105 \\[Buffer-menu-delete] -- mark that buffer to be deleted, and move down.
 106 \\[Buffer-menu-delete-backwards] -- mark that buffer to be deleted, and move up.
 107 \\[Buffer-menu-execute] -- delete or save marked buffers.
 108 \\[Buffer-menu-unmark] -- remove all kinds of marks from current line.
 109   With prefix argument, also move up one line.
 110 \\[Buffer-menu-backup-unmark] -- back up a line and remove marks.
 111 \\[Buffer-menu-toggle-read-only] -- toggle read-only status of buffer on this line."
 112   (kill-all-local-variables)
 113   (use-local-map Buffer-menu-mode-map)
 114   (setq major-mode 'Buffer-menu-mode)
 115   (setq mode-name "Buffer Menu")
 116   (save-excursion
 117     (goto-char (point-min))
 118     (forward-line 2)
 119     (while (not (eobp))
 120       (put-text-property (point) (save-excursion (end-of-line) (point))
 121                          'mouse-face 'highlight)
 122       (forward-line 1)))
 123   (setq truncate-lines t)
 124   (setq buffer-read-only t)
 125   (run-hooks 'buffer-menu-mode-hook))
 126 \f
 127 (defvar Buffer-menu-buffer-column nil)
 128
 129 (defvar Buffer-menu-size-column nil)
 130
 131 (defun Buffer-menu-buffer (error-if-non-existent-p)
 132   "Return buffer described by this line of buffer menu."
 133   (if (null Buffer-menu-buffer-column)
 134       (save-excursion
 135        (goto-char (point-min))
 136        (search-forward "Buffer")
 137        (backward-word 1)
 138        (setq Buffer-menu-buffer-column (current-column))
 139        (search-forward "Size")
 140        (backward-word 1)
 141        (setq Buffer-menu-size-column (current-column))))
 142   (save-excursion
 143     (beginning-of-line)
 144     (forward-char Buffer-menu-buffer-column)
 145     (let ((start (point))
 146           string)
 147       ;; End of buffer name marked by tab or two spaces.
 148       (re-search-forward "\t\\|  ")
 149       (skip-chars-backward " \t")
 150       (setq string (buffer-substring start (point)))
 151       (or (get-buffer string)
 152           (if error-if-non-existent-p
 153               (error "No buffer named \"%s\"" string)
 154             nil)))))
 155 \f
 156 (defun buffer-menu (&optional arg)
 157   "Make a menu of buffers so you can save, delete or select them.
 158 With argument, show only buffers that are visiting files.
 159 Type ? after invocation to get help on commands available.
 160 Type q immediately to make the buffer menu go away and to restore
 161 previous window configuration."
 162   (interactive "P")
 163 ;;;  (setq Buffer-menu-window-config (current-window-configuration))
 164   (list-buffers arg)
 165   (pop-to-buffer "*Buffer List*")
 166   (forward-line 2)
 167   (message
 168    "Commands: d, s, x, u; f, o, 1, 2, m, v; ~, %%; q to quit; ? for help."))
 169
 170 (defun Buffer-menu-quit ()
 171   "Quit the buffer menu."
 172   (interactive)
 173   (let ((buffer (current-buffer)))
 174     ;; Restore previous window configuration before displaying
 175     ;; selected buffers.
 176     (switch-to-buffer (other-buffer))
 177     (bury-buffer buffer)))
 178
 179 (defun Buffer-menu-mark ()
 180   "Mark buffer on this line for being displayed by \\<Buffer-menu-mode-map>\\[Buffer-menu-select] command."
 181   (interactive)
 182   (beginning-of-line)
 183   (if (looking-at " [-M]")
 184       (ding)
 185     (let ((buffer-read-only nil))
 186       (delete-char 1)
 187       (insert ?>)
 188       (forward-line 1))))
 189
 190 (defun Buffer-menu-unmark (&optional backup)
 191   "Cancel all requested operations on buffer on this line and move down.
 192 Optional ARG means move up."
 193   (interactive "P")
 194   (beginning-of-line)
 195   (if (looking-at " [-M]")
 196       (ding)
 197     (let* ((buf (Buffer-menu-buffer t))
 198            (mod (buffer-modified-p buf))
 199            (readonly (save-excursion (set-buffer buf) buffer-read-only))
 200            (buffer-read-only nil))
 201       (delete-char 3)
 202       (insert (if readonly (if mod " *%" "  %") (if mod " * " "   ")))))
 203   (forward-line (if backup -1 1)))
 204
 205 (defun Buffer-menu-backup-unmark ()
 206   "Move up and cancel all requested operations on buffer on line above."
 207   (interactive)
 208   (forward-line -1)
 209   (Buffer-menu-unmark)
 210   (forward-line -1))
 211
 212 (defun Buffer-menu-delete ()
 213   "Mark buffer on this line to be deleted by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command."
 214   (interactive)
 215   (beginning-of-line)
 216   (if (looking-at " [-M]")              ;header lines
 217       (ding)
 218     (let ((buffer-read-only nil))
 219       (delete-char 1)
 220       (insert ?D)
 221       (forward-line 1))))
 222
 223 (defun Buffer-menu-delete-backwards ()
 224   "Mark buffer on this line to be deleted by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command
 225 and then move up one line"
 226   (interactive)
 227   (Buffer-menu-delete)
 228   (forward-line -2)
 229   (if (looking-at " [-M]") (forward-line 1)))
 230
 231 (defun Buffer-menu-save ()
 232   "Mark buffer on this line to be saved by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command."
 233   (interactive)
 234   (beginning-of-line)
 235   (forward-char 1)
 236   (if (looking-at " [-M]")              ;header lines
 237       (ding)
 238     (let ((buffer-read-only nil))
 239       (delete-char 1)
 240       (insert ?S)
 241       (forward-line 1))))
 242
 243 (defun Buffer-menu-not-modified ()
 244   "Mark buffer on this line as unmodified (no changes to save)."
 245   (interactive)
 246   (save-excursion
 247     (set-buffer (Buffer-menu-buffer t))
 248     (set-buffer-modified-p nil))
 249   (save-excursion
 250    (beginning-of-line)
 251    (forward-char 1)
 252    (if (looking-at "\\*")
 253        (let ((buffer-read-only nil))
 254          (delete-char 1)
 255          (insert ? )))))
 256
 257 (defun Buffer-menu-execute ()
 258   "Save and/or delete buffers marked with \\<Buffer-menu-mode-map>\\[Buffer-menu-save] or \\<Buffer-menu-mode-map>\\[Buffer-menu-delete] commands."
 259   (interactive)
 260   (save-excursion
 261     (goto-char (point-min))
 262     (forward-line 1)
 263     (while (re-search-forward "^.S" nil t)
 264       (let ((modp nil))
 265         (save-excursion
 266           (set-buffer (Buffer-menu-buffer t))
 267           (save-buffer)
 268           (setq modp (buffer-modified-p)))
 269         (let ((buffer-read-only nil))
 270           (delete-char -1)
 271           (insert (if modp ?* ? ))))))
 272   (save-excursion
 273     (goto-char (point-min))
 274     (forward-line 1)
 275     (let ((buff-menu-buffer (current-buffer))
 276           (buffer-read-only nil))
 277       (while (search-forward "\nD" nil t)
 278         (forward-char -1)
 279         (let ((buf (Buffer-menu-buffer nil)))
 280           (or (eq buf nil)
 281               (eq buf buff-menu-buffer)
 282               (save-excursion (kill-buffer buf))))
 283         (if (Buffer-menu-buffer nil)
 284             (progn (delete-char 1)
 285                    (insert ? ))
 286           (delete-region (point) (progn (forward-line 1) (point)))
 287           (forward-char -1))))))
 288
 289 (defun Buffer-menu-select ()
 290   "Select this line's buffer; also display buffers marked with `>'.
 291 You can mark buffers with the \\<Buffer-menu-mode-map>\\[Buffer-menu-mark] command."
 292   (interactive)
 293   (let ((buff (Buffer-menu-buffer t))
 294         (menu (current-buffer))
 295         (others ())
 296         tem)
 297     (goto-char (point-min))
 298     (while (search-forward "\n>" nil t)
 299       (setq tem (Buffer-menu-buffer t))
 300       (let ((buffer-read-only nil))
 301         (delete-char -1)
 302         (insert ?\ ))
 303       (or (eq tem buff) (memq tem others) (setq others (cons tem others))))
 304     (setq others (nreverse others)
 305           tem (/ (1- (frame-height)) (1+ (length others))))
 306     (delete-other-windows)
 307     (switch-to-buffer buff)
 308     (or (eq menu buff)
 309         (bury-buffer menu))
 310     (if (equal (length others) 0)
 311         (progn
 312 ;;;       ;; Restore previous window configuration before displaying
 313 ;;;       ;; selected buffers.
 314 ;;;       (if Buffer-menu-window-config
 315 ;;;           (progn
 316 ;;;             (set-window-configuration Buffer-menu-window-config)
 317 ;;;             (setq Buffer-menu-window-config nil)))
 318           (switch-to-buffer buff))
 319       (while others
 320         (split-window nil tem)
 321         (other-window 1)
 322         (switch-to-buffer (car others))
 323         (setq others (cdr others)))
 324       (other-window 1)                          ;back to the beginning!
 325 )))
 326
 327 \f
 328 (defun Buffer-menu-visit-tags-table ()
 329   "Visit the tags table in the buffer on this line.  See `visit-tags-table'."
 330   (interactive)
 331   (let ((file (buffer-file-name (Buffer-menu-buffer t))))
 332     (if file
 333         (visit-tags-table file)
 334       (error "Specified buffer has no file"))))
 335
 336 (defun Buffer-menu-1-window ()
 337   "Select this line's buffer, alone, in full frame."
 338   (interactive)
 339   (switch-to-buffer (Buffer-menu-buffer t))
 340   (bury-buffer (other-buffer))
 341   (delete-other-windows))
 342
 343 (defun Buffer-menu-mouse-select (event)
 344   "Select the buffer whose line you click on."
 345   (interactive "e")
 346   (let (buffer)
 347     (save-excursion
 348       (set-buffer (window-buffer (posn-window (event-end event))))
 349       (save-excursion
 350         (goto-char (posn-point (event-end event)))
 351         (setq buffer (Buffer-menu-buffer t))))
 352     (select-window (posn-window (event-end event)))
 353     (switch-to-buffer buffer)))
 354
 355 (defun Buffer-menu-this-window ()
 356   "Select this line's buffer in this window."
 357   (interactive)
 358   (switch-to-buffer (Buffer-menu-buffer t)))
 359
 360 (defun Buffer-menu-other-window ()
 361   "Select this line's buffer in other window, leaving buffer menu visible."
 362   (interactive)
 363   (switch-to-buffer-other-window (Buffer-menu-buffer t)))
 364
 365 (defun Buffer-menu-switch-other-window ()
 366   "Make the other window select this line's buffer.
 367 The current window remains selected."
 368   (interactive)
 369   (display-buffer (Buffer-menu-buffer t)))
 370
 371 (defun Buffer-menu-2-window ()
 372   "Select this line's buffer, with previous buffer in second window."
 373   (interactive)
 374   (let ((buff (Buffer-menu-buffer t))
 375         (menu (current-buffer))
 376         (pop-up-windows t))
 377     (delete-other-windows)
 378     (switch-to-buffer (other-buffer))
 379     (pop-to-buffer buff)
 380     (bury-buffer menu)))
 381
 382 (defun Buffer-menu-toggle-read-only ()
 383   "Toggle read-only status of buffer on this line, perhaps via version control."
 384   (interactive)
 385   (let (char)
 386     (save-excursion
 387       (set-buffer (Buffer-menu-buffer t))
 388       (vc-toggle-read-only)
 389       (setq char (if buffer-read-only ?% ? )))
 390     (save-excursion
 391       (beginning-of-line)
 392       (forward-char 2)
 393       (if (/= (following-char) char)
 394           (let (buffer-read-only)
 395             (delete-char 1)
 396             (insert char))))))
 397
 398 ;;; buff-menu.el ends here