configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 dnl FIXME hesiod support may not be present, so it seems like an error
  95 dnl to define, or at least use, this unconditionally.
  96 if test "$with_hesiod" != no; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 101 if test "$with_mmdf" != no; then
 102    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 106 if test "$with_mail_unlink" != no; then
 107    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 108 fi
 109
 110 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 111     [string giving default POP mail host])],
 112     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 113
 114 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 115
 116 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 117 if test "$with_sync_input" = yes; then
 118    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 119 fi
 120
 121 dnl FIXME currently it is not the last.
 122 dnl This should be the last --with option, because --with-x is
 123 dnl added later on when we find the path of X, and it's best to
 124 dnl keep them together visually.
 125 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 126  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 127 [         case "${withval}" in
 128             y | ye | yes )      val=gtk ;;
 129             n | no )            val=no  ;;
 130             l | lu | luc | luci | lucid )       val=lucid ;;
 131             a | at | ath | athe | athen | athena )      val=athena ;;
 132             m | mo | mot | moti | motif )       val=motif ;;
 133             g | gt | gtk  )     val=gtk ;;
 134             * )
 135 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 136 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 137 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 138             ;;
 139           esac
 140           with_x_toolkit=$val
 141 ])
 142
 143 dnl _ON results in a '--without' option in the --help output, so
 144 dnl the help text should refer to "don't compile", etc.
 145 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 146 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 147 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 148 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 149 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 150 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 151
 152 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 153 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 154 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 155
 156 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 157 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 158 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 159 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 160
 161 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 162 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 163 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 164
 165 ## For the times when you want to build Emacs but don't have
 166 ## a suitable makeinfo, and can live without the manuals.
 167 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 168 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 169
 170 dnl Can remove these in Emacs 24.
 171 AC_ARG_WITH([gtk],,
 172   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 173 specify a toolkit.])],,)
 174
 175 AC_ARG_WITH([gcc],,
 176   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 177 variable to specify a compiler.])],,)
 178
 179 AC_ARG_WITH([pkg-config-prog],dnl
 180 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 181                   [path to pkg-config for finding GTK and librsvg])])
 182 if test "X${with_pkg_config_prog}" != X; then
 183    if test "${with_pkg_config_prog}" != yes; then
 184       PKG_CONFIG="${with_pkg_config_prog}"
 185    fi
 186 fi
 187
 188 AC_ARG_WITH([gnustep-conf],dnl
 189 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 190 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 191   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 192 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 193      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 194
 195 AC_ARG_ENABLE(ns-self-contained,
 196 [AS_HELP_STRING([--disable-ns-self-contained],
 197                 [disable self contained build under NeXTstep])],
 198    EN_NS_SELF_CONTAINED=$enableval,
 199    EN_NS_SELF_CONTAINED=yes)
 200
 201 AC_ARG_ENABLE(asserts,
 202 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 203       USE_XASSERTS=$enableval,
 204       USE_XASSERTS=no)
 205
 206 AC_ARG_ENABLE(maintainer-mode,
 207 [AS_HELP_STRING([--enable-maintainer-mode],
 208                 [enable make rules and dependencies not useful (and sometimes
 209                  confusing) to the casual installer])],
 210       USE_MAINTAINER_MODE=$enableval,
 211       USE_MAINTAINER_MODE=no)
 212 if test $USE_MAINTAINER_MODE = yes; then
 213   MAINT=
 214 else
 215   MAINT=#
 216 fi
 217 AC_SUBST(MAINT)
 218
 219 AC_ARG_ENABLE(locallisppath,
 220 [AS_HELP_STRING([--enable-locallisppath=PATH],
 221                 [directories Emacs should search for lisp files specific
 222                  to this site])],
 223 if test "${enableval}" = "no"; then
 224   locallisppath=
 225 elif test "${enableval}" != "yes"; then
 226   locallisppath=${enableval}
 227 fi)
 228
 229 AC_ARG_ENABLE(checking,
 230 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 231                 [enable expensive run-time checks.  With LIST,
 232                  enable only specific categories of checks.
 233                  Categories are: all,yes,no.
 234                  Flags are: stringbytes, stringoverrun, stringfreelist,
 235                  xmallocoverrun, conslist])],
 236 [ac_checking_flags="${enableval}"],[])
 237 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 238 for check in $ac_checking_flags
 239 do
 240         case $check in
 241         # these set all the flags to specific states
 242         yes)            ac_enable_checking=1 ;;
 243         no)             ac_enable_checking= ;
 244                         ac_gc_check_stringbytes= ;
 245                         ac_gc_check_string_overrun= ;
 246                         ac_gc_check_string_free_list= ;
 247                         ac_xmalloc_overrun= ;
 248                         ac_gc_check_cons_list= ;;
 249         all)            ac_enable_checking=1 ;
 250                         ac_gc_check_stringbytes=1 ;
 251                         ac_gc_check_string_overrun=1 ;
 252                         ac_gc_check_string_free_list=1 ;
 253                         ac_xmalloc_overrun=1 ;
 254                         ac_gc_check_cons_list=1 ;;
 255         # these enable particular checks
 256         stringbytes)    ac_gc_check_stringbytes=1 ;;
 257         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 258         stringfreelist) ac_gc_check_string_free_list=1 ;;
 259         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 260         conslist)       ac_gc_check_cons_list=1 ;;
 261         *)      AC_MSG_ERROR(unknown check category $check) ;;
 262         esac
 263 done
 264 IFS="$ac_save_IFS"
 265
 266 if test x$ac_enable_checking != x ; then
 267   AC_DEFINE(ENABLE_CHECKING, 1,
 268 [Enable expensive run-time checking of data types?])
 269 fi
 270 if test x$ac_gc_check_stringbytes != x ; then
 271   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 272 [Define this temporarily to hunt a bug.  If defined, the size of
 273    strings is redundantly recorded in sdata structures so that it can
 274    be compared to the sizes recorded in Lisp strings.])
 275 fi
 276 if test x$ac_gc_check_stringoverrun != x ; then
 277   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 278 [Define this to check for short string overrun.])
 279 fi
 280 if test x$ac_gc_check_string_free_list != x ; then
 281   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 282 [Define this to check the string free list.])
 283 fi
 284 if test x$ac_xmalloc_overrun != x ; then
 285   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 286 [Define this to check for malloc buffer overrun.])
 287 fi
 288 if test x$ac_gc_check_cons_list != x ; then
 289   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 290 [Define this to check for errors in cons list.])
 291 fi
 292
 293 AC_ARG_ENABLE(profiling,
 294 [AS_HELP_STRING([--enable-profiling],
 295                 [build emacs with profiling support.
 296                  This might not work on all platforms])],
 297 [ac_enable_profiling="${enableval}"],[])
 298 if test x$ac_enable_profiling != x ; then
 299    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 300    PROFILING_LDFLAGS="-pg"
 301 else
 302    PROFILING_CFLAGS=
 303    PROFILING_LDFLAGS=
 304 fi
 305
 306 AC_ARG_ENABLE(autodepend,
 307 [AS_HELP_STRING([--enable-autodepend],
 308                 [automatically generate dependencies to .h-files.
 309                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 310                  found])],
 311 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 312
 313 #### Make srcdir absolute, if it isn't already.  It's important to
 314 #### avoid running the path through pwd unnecessarily, since pwd can
 315 #### give you automounter prefixes, which can go away.  We do all this
 316 #### so Emacs can find its files when run uninstalled.
 317 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 318 unset CDPATH
 319 case "${srcdir}" in
 320   /* ) ;;
 321   . )
 322     ## We may be able to use the $PWD environment variable to make this
 323     ## absolute.  But sometimes PWD is inaccurate.
 324     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 325     ## but that tested only for a well-formed and valid PWD,
 326     ## it did not object when PWD was well-formed and valid but just wrong.
 327     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 328     then
 329       srcdir="$PWD"
 330     else
 331       srcdir="`(cd ${srcdir}; pwd)`"
 332     fi
 333   ;;
 334   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 335 esac
 336
 337 #### Check if the source directory already has a configured system in it.
 338 if test `pwd` != `(cd ${srcdir} && pwd)` \
 339    && test -f "${srcdir}/src/config.h" ; then
 340   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 341    as a build directory right now; it has been configured in its own
 342    right.  To configure in another directory as well, you MUST
 343    use GNU make.  If you do not have GNU make, then you must
 344    now do `make distclean' in ${srcdir},
 345    and then run $0 again.]])
 346 fi
 347
 348 #### Given the configuration name, set machfile and opsysfile to the
 349 #### names of the m/*.h and s/*.h files we should use.
 350
 351 ### Canonicalize the configuration name.
 352
 353 AC_CANONICAL_HOST
 354 canonical=$host
 355 configuration=${host_alias-${build_alias-$host}}
 356
 357 dnl This used to use changequote, but, apart from `changequote is evil'
 358 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 359 dnl the great gob of text.  Thus it's not processed for possible expansion.
 360 dnl Just make sure the brackets remain balanced.
 361 dnl
 362 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 363 dnl indicated by comments.
 364 dnl quotation begins
 365 [
 366
 367 ### If you add support for a new configuration, add code to this
 368 ### switch statement to recognize your configuration name and select
 369 ### the appropriate operating system and machine description files.
 370
 371 ### You would hope that you could choose an m/*.h file pretty much
 372 ### based on the machine portion of the configuration name, and an s-
 373 ### file based on the operating system portion.  However, it turns out
 374 ### that each m/*.h file is pretty manufacturer-specific - for
 375 ### example mips.h is MIPS
 376 ### So we basically have to have a special case for each
 377 ### configuration name.
 378 ###
 379 ### As far as handling version numbers on operating systems is
 380 ### concerned, make sure things will fail in a fixable way.  If
 381 ### /etc/MACHINES doesn't say anything about version numbers, be
 382 ### prepared to handle anything reasonably.  If version numbers
 383 ### matter, be sure /etc/MACHINES says something about it.
 384 ###
 385 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 386 ### "System V Release 4"; he writes, "The old convention encouraged
 387 ### confusion between `system' and `release' levels'."
 388
 389 machine='' opsys='' unported=no
 390 case "${canonical}" in
 391
 392   ## FreeBSD ports
 393   *-*-freebsd* )
 394     opsys=freebsd
 395     case "${canonical}" in
 396       alpha*-*-freebsd*)        machine=alpha ;;
 397       arm*-*-freebsd*)          machine=arm ;;
 398       ia64-*-freebsd*)          machine=ia64 ;;
 399       sparc-*-freebsd*)         machine=sparc ;;
 400       sparc64-*-freebsd*)       machine=sparc ;;
 401       powerpc-*-freebsd*)       machine=macppc ;;
 402       i[3456]86-*-freebsd*)     machine=intel386 ;;
 403       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 404     esac
 405   ;;
 406
 407   ## FreeBSD kernel + glibc based userland
 408   *-*-kfreebsd*gnu* )
 409     opsys=gnu-kfreebsd
 410     case "${canonical}" in
 411       alpha*-*-kfreebsd*)       machine=alpha ;;
 412       ia64-*-kfreebsd*)         machine=ia64 ;;
 413       sparc-*-kfreebsd*)        machine=sparc ;;
 414       sparc64-*-kfreebsd*)      machine=sparc ;;
 415       powerpc-*-kfreebsd*)      machine=macppc ;;
 416       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 417       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 418     esac
 419   ;;
 420
 421   ## NetBSD ports
 422   *-*-netbsd* )
 423     opsys=netbsd
 424     if test -f /usr/lib/crti.o; then]
 425 dnl The close and open brackets here are because this section is quoted --
 426 dnl see the `changequote' comment above.
 427       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 428 [   fi
 429
 430     case "${canonical}" in
 431       alpha*-*-netbsd*) machine=alpha ;;
 432       i[3456]86-*-netbsd*) machine=intel386 ;;
 433       mips-*-netbsd*)   machine=mips ;;
 434       mipsel-*-netbsd*) machine=mips ;;
 435       mipseb-*-netbsd*) machine=mips ;;
 436       powerpc-*-netbsd*) machine=macppc ;;
 437       sparc*-*-netbsd*) machine=sparc ;;
 438       vax-*-netbsd*)    machine=vax ;;
 439       arm-*-netbsd*)    machine=arm ;;
 440       x86_64-*-netbsd*) machine=amdx86-64 ;;
 441       hppa-*-netbsd*)   machine=hp800 ;;
 442       m68k-*-netbsd*)   machine=m68k ;;
 443     esac
 444   ;;
 445
 446   ## OpenBSD ports
 447   *-*-openbsd* )
 448     opsys=openbsd
 449     case "${canonical}" in
 450       alpha*-*-openbsd*)        machine=alpha ;;
 451       arm-*-openbsd*)          machine=arm ;;
 452       i386-*-openbsd*)         machine=intel386 ;;
 453       powerpc-*-openbsd*)      machine=macppc ;;
 454       sparc*-*-openbsd*)       machine=sparc ;;
 455       vax-*-openbsd*)          machine=vax ;;
 456       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 457       hppa-*-openbsd*)         machine=hp800 ;;
 458     esac
 459   ;;
 460
 461   alpha*-*-linux-gnu* )
 462     machine=alpha opsys=gnu-linux
 463   ;;
 464
 465   arm*-*-linux-gnu* )
 466     machine=arm opsys=gnu-linux
 467   ;;
 468
 469   ## Apple Darwin / Mac OS X
 470   *-apple-darwin* )
 471     case "${canonical}" in
 472       i[3456]86-* )  machine=intel386 ;;
 473       powerpc-* )    machine=macppc ;;
 474       x86_64-* )     machine=amdx86-64 ;;
 475       * )            unported=yes ;;
 476     esac
 477     opsys=darwin
 478     # Define CPP as follows to make autoconf work correctly.
 479     CPP="${CC-cc} -E -no-cpp-precomp"
 480     # Use fink packages if available.
 481     if test -d /sw/include && test -d /sw/lib; then
 482       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 483       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 484       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 485     fi
 486   ;;
 487
 488   ## HP 9000 series 700 and 800, running HP/UX
 489   hppa*-hp-hpux10.2* )
 490     machine=hp800 opsys=hpux10-20
 491   ;;
 492   hppa*-hp-hpux1[1-9]* )
 493     machine=hp800 opsys=hpux11
 494     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 495   ;;
 496
 497   hppa*-*-linux-gnu* )
 498     machine=hp800 opsys=gnu-linux
 499   ;;
 500
 501   ## IBM machines
 502   s390-*-linux-gnu* )
 503     machine=ibms390 opsys=gnu-linux
 504   ;;
 505   s390x-*-linux-gnu* )
 506     machine=ibms390x opsys=gnu-linux
 507   ;;
 508   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 509     machine=ibmrs6000 opsys=aix4-2
 510   ;;
 511   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 512     machine=ibmrs6000 opsys=aix4-2
 513   ;;
 514   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 515     machine=ibmrs6000 opsys=aix4-2
 516   ;;
 517   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 518     machine=ibmrs6000 opsys=aix4-2
 519   ;;
 520
 521   ## Macintosh PowerPC
 522   powerpc*-*-linux-gnu* )
 523     machine=macppc opsys=gnu-linux
 524   ;;
 525
 526   ## Silicon Graphics machines
 527   ## Iris 4D
 528   mips-sgi-irix6.5 )
 529     machine=iris4d opsys=irix6-5
 530     # Without defining _LANGUAGE_C, things get masked out in the headers
 531     # so that, for instance, grepping for `free' in stdlib.h fails and
 532     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 533     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 534     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 535   ;;
 536
 537   ## Suns
 538   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 539     machine=sparc opsys=gnu-linux
 540   ;;
 541
 542   *-sun-solaris* \
 543     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 544     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 545     case "${canonical}" in
 546       i[3456]86-*-* )     machine=intel386 ;;
 547       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 548       sparc* )          machine=sparc ;;
 549       * )               unported=yes ;;
 550     esac
 551     case "${canonical}" in
 552       *-sunos5.6* | *-solaris2.6* )
 553                 opsys=sol2-6
 554                 NON_GNU_CPP=/usr/ccs/lib/cpp
 555                 RANLIB="ar -ts"
 556                 ;;
 557       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 558                 opsys=sol2-6
 559                 emacs_check_sunpro_c=yes
 560                 NON_GNU_CPP=/usr/ccs/lib/cpp
 561                 ;;
 562       *-sunos5* | *-solaris* )
 563                 opsys=sol2-10
 564                 emacs_check_sunpro_c=yes
 565                 NON_GNU_CPP=/usr/ccs/lib/cpp
 566                 ;;
 567     esac
 568     ## Watch out for a compiler that we know will not work.
 569     case "${canonical}" in
 570      *-solaris* | *-sunos5* )
 571                 if [ "x$CC" = x/usr/ucb/cc ]; then
 572                   ## /usr/ucb/cc doesn't work;
 573                   ## we should find some other compiler that does work.
 574                   unset CC
 575                 fi
 576                 ;;
 577       *) ;;
 578     esac
 579   ;;
 580
 581   ## IA-64
 582   ia64*-*-linux* )
 583     machine=ia64 opsys=gnu-linux
 584   ;;
 585
 586   ## Intel 386 machines where we don't care about the manufacturer
 587   i[3456]86-*-* )
 588     machine=intel386
 589     case "${canonical}" in
 590       *-cygwin )                opsys=cygwin ;;
 591       *-darwin* )               opsys=darwin
 592                                 CPP="${CC-cc} -E -no-cpp-precomp"
 593                                 ;;
 594       *-linux-gnu* )            opsys=gnu-linux ;;
 595       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 596       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 597       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 598       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 599     esac
 600   ;;
 601
 602   ## m68k Linux-based GNU system
 603   m68k-*-linux-gnu* )
 604     machine=m68k opsys=gnu-linux
 605   ;;
 606
 607   ## Mips Linux-based GNU system
 608   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 609     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 610     machine=mips opsys=gnu-linux
 611   ;;
 612
 613   ## AMD x86-64 Linux-based GNU system
 614   x86_64-*-linux-gnu* )
 615     machine=amdx86-64 opsys=gnu-linux
 616   ;;
 617
 618   ## Tensilica Xtensa Linux-based GNU system
 619   xtensa*-*-linux-gnu* )
 620     machine=xtensa opsys=gnu-linux
 621     ;;
 622
 623   ## SuperH Linux-based GNU system
 624   sh[34]*-*-linux-gnu* )
 625     machine=sh3 opsys=gnu-linux
 626   ;;
 627
 628   * )
 629     unported=yes
 630   ;;
 631 esac
 632
 633 ### If the code above didn't choose an operating system, just choose
 634 ### an operating system based on the configuration name.  You really
 635 ### only want to use this when you have no idea what the right
 636 ### operating system is; if you know what operating systems a machine
 637 ### runs, it's cleaner to make it explicit in the case statement
 638 ### above.
 639 if test x"${opsys}" = x; then
 640   case "${canonical}" in
 641     *-gnu* )                            opsys=gnu ;;
 642     * )
 643       unported=yes
 644     ;;
 645   esac
 646 fi
 647
 648 ]
 649 dnl quotation ends
 650
 651 if test $unported = yes; then
 652   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 653 Check `etc/MACHINES' for recognized configuration names.])
 654 fi
 655
 656 machfile="m/${machine}.h"
 657 opsysfile="s/${opsys}.h"
 658
 659
 660 #### Choose a compiler.
 661 test -n "$CC" && cc_specified=yes
 662
 663 # Save the value of CFLAGS that the user specified.
 664 SPECIFIED_CFLAGS="$CFLAGS"
 665
 666 dnl Sets GCC=yes if using gcc.
 667 AC_PROG_CC
 668
 669 # On Suns, sometimes $CPP names a directory.
 670 if test -n "$CPP" && test -d "$CPP"; then
 671   CPP=
 672 fi
 673
 674 ## If not using gcc, and on Solaris, and no CPP specified, see if
 675 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 676 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 677  test x"$CPP" = x; then
 678   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 679   AC_CACHE_VAL(emacs_cv_sunpro_c,
 680   [AC_TRY_LINK([],
 681 [#ifndef __SUNPRO_C
 682 fail;
 683 #endif
 684 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 685   AC_MSG_RESULT($emacs_cv_sunpro_c)
 686
 687   if test x"$emacs_cv_sunpro_c" = xyes; then
 688     NON_GNU_CPP="$CC -E -Xs"
 689   fi
 690 fi
 691
 692 #### Some systems specify a CPP to use unless we are using GCC.
 693 #### Now that we know whether we are using GCC, we can decide whether
 694 #### to use that one.
 695 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 696 then
 697   CPP="$NON_GNU_CPP"
 698 fi
 699
 700 #### Some systems specify a CC to use unless we are using GCC.
 701 #### Now that we know whether we are using GCC, we can decide whether
 702 #### to use that one.
 703 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 704   test x$cc_specified != xyes
 705 then
 706   CC="$NON_GNU_CC"
 707 fi
 708
 709 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 710 then
 711   CC="$CC $GCC_TEST_OPTIONS"
 712 fi
 713
 714 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 715 then
 716   CC="$CC $NON_GCC_TEST_OPTIONS"
 717 fi
 718
 719 dnl checks for Unix variants
 720 AC_USE_SYSTEM_EXTENSIONS
 721
 722 ### Use -Wno-pointer-sign if the compiler supports it
 723 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 724 SAVE_CFLAGS="$CFLAGS"
 725 CFLAGS="$CFLAGS -Wno-pointer-sign"
 726 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 727 if test $has_option = yes; then
 728    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 729 fi
 730 AC_MSG_RESULT($has_option)
 731 CFLAGS="$SAVE_CFLAGS"
 732 unset has_option
 733 unset SAVE_CFLAGS
 734
 735 ### Use -Wdeclaration-after-statement if the compiler supports it
 736 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 737 SAVE_CFLAGS="$CFLAGS"
 738 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 739 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 740 if test $has_option = yes; then
 741    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 742 fi
 743 AC_MSG_RESULT($has_option)
 744 CFLAGS="$SAVE_CFLAGS"
 745 unset has_option
 746 unset SAVE_CFLAGS
 747
 748 #### Some other nice autoconf tests.
 749
 750 dnl checks for programs
 751 AC_PROG_LN_S
 752 AC_PROG_CPP
 753 AC_PROG_INSTALL
 754 if test "x$RANLIB" = x; then
 755   AC_PROG_RANLIB
 756 fi
 757 AC_PATH_PROG(INSTALL_INFO, install-info)
 758 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 759 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 760 dnl Don't use GZIP, which is used by gzip for additional parameters.
 761 AC_PATH_PROG(GZIP_PROG, gzip)
 762
 763
 764 ## Need makeinfo >= 4.6 (?) to build the manuals.
 765 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 766 dnl By this stage, configure has already checked for egrep and set EGREP,
 767 dnl or exited with an error if no egrep was found.
 768 if test "$MAKEINFO" != "no" && \
 769   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 770    MAKEINFO=no
 771 fi
 772
 773 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 774 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 775 ## therefore in the category of "special tools" not normally required, which
 776 ## configure does not have to check for (eg autoconf itself).
 777 ## In a Bazaar checkout on the other hand, the manuals are not included.
 778 ## So makeinfo is a requirement to build from Bazaar, and configure
 779 ## should test for it as it does for any other build requirement.
 780 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 781 ## with pre-built manuals, from a Bazaar checkout.
 782 if test "$MAKEINFO" = "no"; then
 783   if test "x${with_makeinfo}" = "xno"; then
 784     MAKEINFO=off
 785   elif ! test -e $srcdir/info/emacs; then
 786     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 787 source tree does not seem to have pre-built manuals in the `info' directory.
 788 Either install a suitable version of makeinfo, or re-run configure
 789 with the `--without-makeinfo' option to build without the manuals.] )
 790   fi
 791 fi
 792
 793 dnl Add our options to ac_link now, after it is set up.
 794
 795 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 796 then
 797   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 798 fi
 799
 800 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 801 then
 802   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 803 fi
 804
 805 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 806 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 807 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 808 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 809 dnl if not built to support GNU ld.
 810
 811 late_LDFLAGS=$LDFLAGS
 812 if test "$GCC" = yes; then
 813   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 814 else
 815   LDFLAGS="$LDFLAGS -znocombreloc"
 816 fi
 817
 818 AC_MSG_CHECKING([for -znocombreloc])
 819 AC_LINK_IFELSE([main(){return 0;}],
 820   [AC_MSG_RESULT(yes)],
 821   LDFLAGS=$late_LDFLAGS
 822   [AC_MSG_RESULT(no)])
 823
 824 #### Extract some information from the operating system and machine files.
 825
 826 AC_CHECKING([the machine- and system-dependent files to find out
 827  - which libraries the lib-src programs will want, and
 828  - whether the GNU malloc routines are usable])
 829
 830 ### First figure out CFLAGS (which we use for running the compiler here)
 831 ### and REAL_CFLAGS (which we use for real compilation).
 832 ### The two are the same except on a few systems, where they are made
 833 ### different to work around various lossages.  For example,
 834 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 835 ### as implying static linking.
 836
 837 ### If the CFLAGS env var is specified, we use that value
 838 ### instead of the default.
 839
 840 ### It's not important that this name contain the PID; you can't run
 841 ### two configures in the same directory and have anything work
 842 ### anyway.
 843 tempcname="conftest.c"
 844
 845 echo '
 846 #include "'${srcdir}'/src/'${opsysfile}'"
 847 #include "'${srcdir}'/src/'${machfile}'"
 848 #ifndef LIBS_MACHINE
 849 #define LIBS_MACHINE
 850 #endif
 851 #ifndef LIBS_SYSTEM
 852 #define LIBS_SYSTEM
 853 #endif
 854 #ifndef C_SWITCH_SYSTEM
 855 #define C_SWITCH_SYSTEM
 856 #endif
 857 #ifndef C_SWITCH_MACHINE
 858 #define C_SWITCH_MACHINE
 859 #endif
 860 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 861 configure___ c_switch_system=C_SWITCH_SYSTEM
 862 configure___ c_switch_machine=C_SWITCH_MACHINE
 863
 864 #ifndef LIB_X11_LIB
 865 #define LIB_X11_LIB -lX11
 866 #endif
 867
 868 configure___ LIBX=LIB_X11_LIB
 869
 870 #ifdef UNEXEC
 871 configure___ unexec=UNEXEC
 872 #else
 873 configure___ unexec=unexec.o
 874 #endif
 875
 876 #ifdef SYSTEM_MALLOC
 877 configure___ system_malloc=yes
 878 #else
 879 configure___ system_malloc=no
 880 #endif
 881
 882 #ifdef USE_MMAP_FOR_BUFFERS
 883 configure___ use_mmap_for_buffers=yes
 884 #else
 885 configure___ use_mmap_for_buffers=no
 886 #endif
 887
 888 #ifndef C_OPTIMIZE_SWITCH
 889 #ifdef __GNUC__
 890 #define C_OPTIMIZE_SWITCH -O2
 891 #else
 892 #define C_OPTIMIZE_SWITCH -O
 893 #endif
 894 #endif
 895
 896 #ifndef C_WARNINGS_SWITCH
 897 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 898 #endif
 899
 900 #ifndef LD_SWITCH_MACHINE
 901 #define LD_SWITCH_MACHINE
 902 #endif
 903
 904 #ifndef LD_SWITCH_SYSTEM
 905 #define LD_SWITCH_SYSTEM
 906 #endif
 907
 908 #ifndef LD_SWITCH_X_SITE_AUX
 909 #define LD_SWITCH_X_SITE_AUX
 910 #endif
 911
 912 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 913 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 914
 915 #ifdef THIS_IS_CONFIGURE
 916
 917 /* Get the CFLAGS for tests in configure.  */
 918 #ifdef __GNUC__
 919 configure___ CFLAGS=C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 920 #else
 921 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 922 #endif
 923
 924 #else /* not THIS_IS_CONFIGURE */
 925
 926 /* Get the CFLAGS for real compilation.  */
 927 #ifdef __GNUC__
 928 configure___ REAL_CFLAGS=C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 929 #else
 930 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 931 #endif
 932
 933 #endif /* not THIS_IS_CONFIGURE */
 934 ' > ${tempcname}
 935
 936 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 937
 938 # The value of CPP is a quoted variable reference, so we need to do this
 939 # to get its actual value...
 940 CPP=`eval "echo $CPP"`
 941 [eval `${CPP} -Isrc ${tempcname} \
 942        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 943 if test "x$SPECIFIED_CFLAGS" = x; then
 944   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 945          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 946 else
 947   REAL_CFLAGS="$CFLAGS"
 948 fi]
 949 rm ${tempcname}
 950
 951 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 952
 953 ### Make sure subsequent tests use flags consistent with the build flags.
 954
 955 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 956   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 957 else
 958   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 959 fi
 960
 961 dnl For AC_FUNC_GETLOADAVG, at least:
 962 AC_CONFIG_LIBOBJ_DIR(src)
 963
 964 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 965 AC_SYS_LARGEFILE
 966
 967
 968 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 969 ### be located in either /usr/lib64 or /usr/lib.
 970 ### In some rare cases, /usr/lib64 exists but does not contain the
 971 ### relevant files (bug#1287).  Hence test for crtn.o.
 972 case "${canonical}" in
 973   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 974     if test -e /usr/lib64/crtn.o; then
 975       AC_DEFINE(HAVE_LIB64_DIR, 1,
 976         [Define to 1 if the directory /usr/lib64 exists.])
 977 fi
 978 esac
 979
 980 dnl This function defintion taken from Gnome 2.0
 981 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 982 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 983 dnl also defines GSTUFF_PKG_ERRORS on error
 984 AC_DEFUN([PKG_CHECK_MODULES], [
 985   succeeded=no
 986
 987   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 988
 989   if test "$PKG_CONFIG" = "no" ; then
 990      ifelse([$4], , [AC_MSG_ERROR([
 991       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
 992   else
 993      PKG_CONFIG_MIN_VERSION=0.9.0
 994      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 995         AC_MSG_CHECKING(for $2)
 996
 997         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
 998             AC_MSG_RESULT(yes)
 999             succeeded=yes
1000
1001             AC_MSG_CHECKING($1_CFLAGS)
1002             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1003             AC_MSG_RESULT($$1_CFLAGS)
1004
1005             AC_MSG_CHECKING($1_LIBS)
1006             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1007             AC_MSG_RESULT($$1_LIBS)
1008         else
1009             AC_MSG_RESULT(no)
1010             $1_CFLAGS=""
1011             $1_LIBS=""
1012             ## If we have a custom action on failure, don't print errors, but
1013             ## do set a variable so people can do so.
1014             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1015             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1016         fi
1017
1018         AC_SUBST($1_CFLAGS)
1019         AC_SUBST($1_LIBS)
1020      else
1021         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1022         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1023      fi
1024   fi
1025
1026   if test $succeeded = yes; then
1027      ifelse([$3], , :, [$3])
1028   else
1029      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1030   fi
1031 ])
1032
1033
1034 if test "${with_sound}" != "no"; then
1035   # Sound support for GNU/Linux and the free BSDs.
1036   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1037   # Emulation library used on NetBSD.
1038   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1039   AC_SUBST(LIBSOUND)
1040
1041   ALSA_REQUIRED=1.0.0
1042   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1043   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1044   if test $HAVE_ALSA = yes; then
1045     SAVE_CFLAGS="$CFLAGS"
1046     SAVE_LDFLAGS="$LDFLAGS"
1047     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1048     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1049     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1050                     emacs_alsa_normal=yes,
1051                     emacs_alsa_normal=no)
1052     if test "$emacs_alsa_normal" != yes; then
1053       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1054                      [snd_lib_error_set_handler (0);],
1055                      emacs_alsa_subdir=yes,
1056                      emacs_alsa_subdir=no)
1057       if test "$emacs_alsa_subdir" != yes; then
1058         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1059       fi
1060       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1061     fi
1062
1063     CFLAGS="$SAVE_CFLAGS"
1064     LDFLAGS="$SAVE_LDFLAGS"
1065     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1066     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1067     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1068   fi
1069   AC_SUBST(CFLAGS_SOUND)
1070 fi
1071
1072 dnl checks for header files
1073 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1074   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1075   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1076   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1077   sys/utsname.h pwd.h utmp.h)
1078
1079 AC_MSG_CHECKING(if personality LINUX32 can be set)
1080 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1081                emacs_cv_personality_linux32=yes,
1082                emacs_cv_personality_linux32=no)
1083 AC_MSG_RESULT($emacs_cv_personality_linux32)
1084
1085 if test $emacs_cv_personality_linux32 = yes; then
1086   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1087             [Define to 1 if personality LINUX32 can be set.])
1088 fi
1089
1090 dnl On Solaris 8 there's a compilation warning for term.h because
1091 dnl it doesn't define `bool'.
1092 AC_CHECK_HEADERS(term.h, , , -)
1093 AC_HEADER_STDC
1094 AC_HEADER_TIME
1095 AC_CHECK_DECLS([sys_siglist])
1096 if test $ac_cv_have_decl_sys_siglist != yes; then
1097   # For Tru64, at least:
1098   AC_CHECK_DECLS([__sys_siglist])
1099   if test $ac_cv_have_decl___sys_siglist = yes; then
1100     AC_DEFINE(sys_siglist, __sys_siglist,
1101               [Define to any substitute for sys_siglist.])
1102   fi
1103 fi
1104 AC_HEADER_SYS_WAIT
1105
1106 dnl Some systems have utime.h but don't declare the struct anyplace.
1107 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1108 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1109 #include <sys/time.h>
1110 #include <time.h>
1111 #else
1112 #ifdef HAVE_SYS_TIME_H
1113 #include <sys/time.h>
1114 #else
1115 #include <time.h>
1116 #endif
1117 #endif
1118 #ifdef HAVE_UTIME_H
1119 #include <utime.h>
1120 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1121   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1122 if test $emacs_cv_struct_utimbuf = yes; then
1123   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1124 fi
1125
1126 dnl checks for typedefs
1127 AC_TYPE_SIGNAL
1128
1129 dnl Check for speed_t typedef.
1130 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1131   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1132     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1133 if test $emacs_cv_speed_t = yes; then
1134   AC_DEFINE(HAVE_SPEED_T, 1,
1135            [Define to 1 if `speed_t' is declared by <termios.h>.])
1136 fi
1137
1138 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1139 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1140 #include <sys/time.h>
1141 #include <time.h>
1142 #else
1143 #ifdef HAVE_SYS_TIME_H
1144 #include <sys/time.h>
1145 #else
1146 #include <time.h>
1147 #endif
1148 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1149   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1150 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1151 if test $emacs_cv_struct_timeval = yes; then
1152   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1153 fi
1154
1155 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1156 AC_TRY_COMPILE([#include <math.h>],
1157 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1158   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1159 HAVE_EXCEPTION=$emacs_cv_struct_exception
1160 if test $emacs_cv_struct_exception != yes; then
1161   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1162 fi
1163
1164 AC_CHECK_HEADERS(sys/socket.h)
1165 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1166 #if HAVE_SYS_SOCKET_H
1167 #include <sys/socket.h>
1168 #endif])
1169
1170 dnl checks for structure members
1171 AC_STRUCT_TM
1172 AC_STRUCT_TIMEZONE
1173 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1174                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1175                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1176                 [#include <time.h>])
1177 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1178                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1179                   struct ifreq.ifr_addr], , ,
1180                  [AC_INCLUDES_DEFAULT
1181 #if HAVE_SYS_SOCKET_H
1182 #include <sys/socket.h>
1183 #endif
1184 #if HAVE_NET_IF_H
1185 #include <net/if.h>
1186 #endif])
1187
1188 dnl checks for compiler characteristics
1189
1190 dnl Testing __STDC__ to determine prototype support isn't good enough.
1191 dnl DEC C, for instance, doesn't define it with default options, and
1192 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1193 dnl and void *.
1194 AC_C_PROTOTYPES
1195 AC_C_VOLATILE
1196 AC_C_CONST
1197 dnl This isn't useful because we can't turn on use of `inline' unless
1198 dnl the compiler groks `extern inline'.
1199 dnl AC_C_INLINE
1200 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1201   [AC_TRY_COMPILE(, [void * foo;],
1202                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1203 if test $emacs_cv_void_star = yes; then
1204   AC_DEFINE(POINTER_TYPE, void)
1205 else
1206   AC_DEFINE(POINTER_TYPE, char)
1207 fi
1208 AH_TEMPLATE(POINTER_TYPE,
1209             [Define as `void' if your compiler accepts `void *'; otherwise
1210              define as `char'.])dnl
1211
1212
1213
1214 dnl This could be used for targets which can have both byte sexes.
1215 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1216 dnl AC_C_BIGENDIAN
1217
1218 dnl check for Make feature
1219 AC_PROG_MAKE_SET
1220
1221 dnl check for GNU Make if we have GCC and autodepend is on.
1222 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1223    AC_MSG_CHECKING([whether we are using GNU Make])
1224    HAVE_GNU_MAKE=no
1225    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1226    if test "x$testval" != x; then
1227       HAVE_GNU_MAKE=yes
1228    else
1229       ac_enable_autodepend=no
1230    fi
1231    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1232    if test $HAVE_GNU_MAKE = yes; then
1233       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1234       SAVE_CFLAGS="$CFLAGS"
1235       CFLAGS="$CFLAGS -MMD -MF deps.d"
1236       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1237       CFLAGS="$SAVE_CFLAGS"
1238       test -f deps.d || ac_enable_autodepend=no
1239       rm -rf deps.d
1240       AC_MSG_RESULT([$ac_enable_autodepend])
1241    fi
1242    if test $ac_enable_autodepend = yes; then
1243       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1244    fi
1245 fi
1246
1247 dnl checks for operating system services
1248 AC_SYS_LONG_FILE_NAMES
1249
1250 #### Choose a window system.
1251
1252 AC_PATH_X
1253 if test "$no_x" = yes; then
1254   window_system=none
1255 else
1256   window_system=x11
1257 fi
1258
1259 ## Workaround for bug in autoconf <= 2.62.
1260 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1261 ## No need to do anything special for these standard directories.
1262 ## This is an experiment, take it out if it causes problems.
1263 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1264
1265    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1266
1267 fi
1268
1269 if test "${x_libraries}" != NONE; then
1270   if test -n "${x_libraries}"; then
1271     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1272     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1273   fi
1274   x_default_search_path=""
1275   x_search_path=${x_libraries}
1276   if test -z "${x_search_path}"; then
1277     x_search_path=/usr/lib
1278   fi
1279   for x_library in `echo ${x_search_path}: | \
1280                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1281     x_search_path="\
1282 ${x_library}/X11/%L/%T/%N%C%S:\
1283 ${x_library}/X11/%l/%T/%N%C%S:\
1284 ${x_library}/X11/%T/%N%C%S:\
1285 ${x_library}/X11/%L/%T/%N%S:\
1286 ${x_library}/X11/%l/%T/%N%S:\
1287 ${x_library}/X11/%T/%N%S"
1288     if test x"${x_default_search_path}" = x; then
1289       x_default_search_path=${x_search_path}
1290     else
1291       x_default_search_path="${x_search_path}:${x_default_search_path}"
1292     fi
1293   done
1294 fi
1295 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1296   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1297 fi
1298
1299 if test x"${x_includes}" = x; then
1300   bitmapdir=/usr/include/X11/bitmaps
1301 else
1302   # accumulate include directories that have X11 bitmap subdirectories
1303   bmd_acc="dummyval"
1304   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1305     if test -d "${bmd}/X11/bitmaps"; then
1306       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1307     fi
1308     if test -d "${bmd}/bitmaps"; then
1309       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1310     fi
1311   done
1312   if test ${bmd_acc} != "dummyval"; then
1313     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1314   fi
1315 fi
1316
1317 HAVE_NS=no
1318 NS_IMPL_COCOA=no
1319 NS_IMPL_GNUSTEP=no
1320 tmp_CPPFLAGS="$CPPFLAGS"
1321 tmp_CFLAGS="$CFLAGS"
1322 CPPFLAGS="$CPPFLAGS -x objective-c"
1323 CFLAGS="$CFLAGS -x objective-c"
1324 if test "${with_ns}" != no; then
1325   if test "${opsys}" = darwin; then
1326      NS_IMPL_COCOA=yes
1327      ns_appdir=`pwd`/nextstep/Emacs.app
1328      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1329      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1330      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1331   elif test -f $GNUSTEP_CONFIG_FILE; then
1332      NS_IMPL_GNUSTEP=yes
1333      ns_appdir=`pwd`/nextstep/Emacs.app
1334      ns_appbindir=`pwd`/nextstep/Emacs.app
1335      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1336      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1337      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1338      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1339      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1340      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1341      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1342      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1343      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1344      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1345   fi
1346   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1347                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1348   files are missing or cannot be compiled.])])
1349   NS_HAVE_NSINTEGER=yes
1350   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1351                                      [NSInteger i;])],
1352                     ns_have_nsinteger=yes,
1353                     ns_have_nsinteger=no)
1354   if test $ns_have_nsinteger = no; then
1355     NS_HAVE_NSINTEGER=no
1356   fi
1357 fi
1358 if test "${HAVE_NS}" = yes; then
1359   window_system=nextstep
1360   with_xft=no
1361   # set up packaging dirs
1362   exec_prefix=${ns_appbindir}
1363   libexecdir=${ns_appbindir}/libexec
1364   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1365      prefix=${ns_appresdir}
1366   fi
1367 fi
1368 CFLAGS="$tmp_CFLAGS"
1369 CPPFLAGS="$tmp_CPPFLAGS"
1370
1371 case "${window_system}" in
1372   x11 )
1373     HAVE_X_WINDOWS=yes
1374     HAVE_X11=yes
1375     case "${with_x_toolkit}" in
1376       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1377       motif ) USE_X_TOOLKIT=MOTIF ;;
1378       gtk ) with_gtk=yes
1379 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1380 dnl USE_X_TOOLKIT is set.
1381             USE_X_TOOLKIT=none ;;
1382       no ) USE_X_TOOLKIT=none ;;
1383 dnl If user did not say whether to use a toolkit, make this decision later:
1384 dnl use the toolkit if we have gtk, or X11R5 or newer.
1385       * ) USE_X_TOOLKIT=maybe ;;
1386     esac
1387   ;;
1388   nextstep | none )
1389     HAVE_X_WINDOWS=no
1390     HAVE_X11=no
1391     USE_X_TOOLKIT=none
1392   ;;
1393 esac
1394
1395 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1396    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1397    if test "$HAVE_XSERVER" = true ||
1398       test -n "$DISPLAY" ||
1399       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1400         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1401 were found.  You should install the relevant development files for X
1402 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1403 sure you have development files for image handling, i.e.
1404 tiff, gif, jpeg, png and xpm.
1405 If you are sure you want Emacs compiled without X window support, pass
1406   --without-x
1407 to configure.])
1408    fi
1409 fi
1410
1411 ### If we're using X11, we should use the X menu package.
1412 HAVE_MENUS=no
1413 case ${HAVE_X11} in
1414   yes ) HAVE_MENUS=yes ;;
1415 esac
1416
1417 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1418 # Assume not, until told otherwise.
1419 GNU_MALLOC=yes
1420 doug_lea_malloc=yes
1421 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1422 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1423 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1424                emacs_cv_var___after_morecore_hook,
1425 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1426   emacs_cv_var___after_morecore_hook=yes,
1427   emacs_cv_var___after_morecore_hook=no)])
1428 if test $emacs_cv_var___after_morecore_hook = no; then
1429   doug_lea_malloc=no
1430 fi
1431 if test "${system_malloc}" = "yes"; then
1432   GNU_MALLOC=no
1433   GNU_MALLOC_reason="
1434     (The GNU allocators don't work with this system configuration.)"
1435 fi
1436 if test "$doug_lea_malloc" = "yes" ; then
1437   if test "$GNU_MALLOC" = yes ; then
1438     GNU_MALLOC_reason="
1439       (Using Doug Lea's new malloc from the GNU C Library.)"
1440   fi
1441   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1442             [Define to 1 if you are using the GNU C Library.])
1443 fi
1444
1445 if test x"${REL_ALLOC}" = x; then
1446   REL_ALLOC=${GNU_MALLOC}
1447 fi
1448
1449 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1450 dnl the system configuration file (s/*.h) to turn the use of mmap
1451 dnl in the relocating allocator on.
1452
1453 AC_FUNC_MMAP
1454 if test $use_mmap_for_buffers = yes; then
1455   REL_ALLOC=no
1456 fi
1457
1458 LIBS="$libsrc_libs $LIBS"
1459
1460 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1461 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1462 AC_CHECK_LIB(dnet, dnet_ntoa)
1463 dnl This causes -lresolv to get used in subsequent tests,
1464 dnl which causes failures on some systems such as HPUX 9.
1465 dnl AC_CHECK_LIB(resolv, gethostbyname)
1466
1467 dnl FIXME replace main with a function we actually want from this library.
1468 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1469
1470 AC_CHECK_LIB(pthreads, cma_open)
1471
1472 dnl Check for need for bigtoc support on IBM AIX
1473
1474 case ${host_os} in
1475 aix*)
1476   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1477     case $GCC in
1478     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1479     *) gdb_cv_bigtoc=-bbigtoc ;;
1480     esac
1481
1482     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1483     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1484   ])
1485   ;;
1486 esac
1487
1488 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1489 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1490 # REAL_CPPFLAGS later on.
1491
1492 REAL_CPPFLAGS="$CPPFLAGS"
1493
1494 if test "${HAVE_X11}" = "yes"; then
1495   DEFS="$C_SWITCH_X_SITE $DEFS"
1496   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1497   LIBS="$LIBX $LIBS"
1498   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1499   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1500
1501   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1502   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1503   # but it's more convenient here to set LD_RUN_PATH
1504   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1505   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1506     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1507     export LD_RUN_PATH
1508   fi
1509
1510   if test "${opsys}" = "gnu-linux"; then
1511     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1512     AC_TRY_LINK([],
1513      [XOpenDisplay ("foo");],
1514      [xlinux_first_failure=no],
1515      [xlinux_first_failure=yes])
1516     if test "${xlinux_first_failure}" = "yes"; then
1517       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1518       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1519       OLD_CPPFLAGS="$CPPFLAGS"
1520       OLD_LIBS="$LIBS"
1521       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1522       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1523       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1524       LIBS="$LIBS -b i486-linuxaout"
1525       AC_TRY_LINK([],
1526        [XOpenDisplay ("foo");],
1527        [xlinux_second_failure=no],
1528        [xlinux_second_failure=yes])
1529       if test "${xlinux_second_failure}" = "yes"; then
1530         # If we get the same failure with -b, there is no use adding -b.
1531         # So take it out.  This plays safe.
1532         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1533         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1534         CPPFLAGS="$OLD_CPPFLAGS"
1535         LIBS="$OLD_LIBS"
1536         AC_MSG_RESULT(no)
1537       else
1538         AC_MSG_RESULT(yes)
1539       fi
1540     else
1541       AC_MSG_RESULT(no)
1542     fi
1543   fi
1544
1545   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1546   # header files included from there.
1547   AC_MSG_CHECKING(for Xkb)
1548   AC_TRY_LINK([#include <X11/Xlib.h>
1549 #include <X11/XKBlib.h>],
1550         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1551         emacs_xkb=yes, emacs_xkb=no)
1552   AC_MSG_RESULT($emacs_xkb)
1553   if test $emacs_xkb = yes; then
1554     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1555   fi
1556
1557   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1558 XScreenNumberOfScreen XSetWMProtocols)
1559 fi
1560
1561 if test "${window_system}" = "x11"; then
1562   AC_MSG_CHECKING(X11 version 6)
1563   AC_CACHE_VAL(emacs_cv_x11_version_6,
1564   [AC_TRY_LINK([#include <X11/Xlib.h>],
1565 [#if XlibSpecificationRelease < 6
1566 fail;
1567 #endif
1568 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1569   if test $emacs_cv_x11_version_6 = yes; then
1570     AC_MSG_RESULT(6 or newer)
1571     AC_DEFINE(HAVE_X11R6, 1,
1572               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1573   else
1574     AC_MSG_RESULT(before 6)
1575   fi
1576 fi
1577
1578
1579 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1580 HAVE_RSVG=no
1581 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1582   if test "${with_rsvg}" != "no"; then
1583     RSVG_REQUIRED=2.11.0
1584     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1585
1586     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1587     AC_SUBST(RSVG_CFLAGS)
1588     AC_SUBST(RSVG_LIBS)
1589
1590     if test ".${RSVG_CFLAGS}" != "."; then
1591       HAVE_RSVG=yes
1592       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1593       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1594       LIBS="$RSVG_LIBS $LIBS"
1595     fi
1596   fi
1597 fi
1598
1599
1600 HAVE_GTK=no
1601 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1602   GLIB_REQUIRED=2.6
1603   GTK_REQUIRED=2.6
1604   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1605
1606   dnl Checks for libraries.
1607   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1608   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1609      AC_MSG_ERROR($GTK_PKG_ERRORS)
1610   fi
1611 fi
1612
1613
1614 if test x"$pkg_check_gtk" = xyes; then
1615
1616   AC_SUBST(GTK_CFLAGS)
1617   AC_SUBST(GTK_LIBS)
1618   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1619   CFLAGS="$CFLAGS $GTK_CFLAGS"
1620   LIBS="$GTK_LIBS $LIBS"
1621   dnl Try to compile a simple GTK program.
1622   GTK_COMPILES=no
1623   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1624   if test "${GTK_COMPILES}" != "yes"; then
1625     if test "$USE_X_TOOLKIT" != "maybe"; then
1626       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1627     fi
1628   else
1629     HAVE_GTK=yes
1630     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1631     USE_X_TOOLKIT=none
1632     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1633       :
1634     else
1635       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1636        closing open displays.  This is no problem if you just use
1637        one display, but if you use more than one and close one of them
1638        Emacs may crash.]])
1639       sleep 3
1640     fi
1641   fi
1642
1643 fi
1644
1645
1646 if test "${HAVE_GTK}" = "yes"; then
1647
1648   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1649   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1650   if test "$with_toolkit_scroll_bars" != no; then
1651     with_toolkit_scroll_bars=yes
1652   fi
1653
1654   dnl  Check if we can use multiple displays with this GTK version.
1655   dnl  If gdk_display_open exists, assume all others are there also.
1656   HAVE_GTK_MULTIDISPLAY=no
1657   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1658   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1659     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1660               [Define to 1 if GTK can handle more than one display.])
1661   fi
1662
1663   dnl  Check if we have the old file selection dialog declared and
1664   dnl  in the link library.  In 2.x it may be in the library,
1665   dnl  but not declared if deprecated featured has been selected out.
1666   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1667   HAVE_GTK_FILE_SELECTION=no
1668   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1669                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1670 #include <gtk/gtk.h>])
1671   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1672     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1673                    HAVE_GTK_FILE_SELECTION=no)
1674   fi
1675
1676   dnl  Check if we have the new file chooser dialog
1677   HAVE_GTK_FILE_CHOOSER=no
1678   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1679                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1680 #include <gtk/gtk.h>])
1681   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1682     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1683                    HAVE_GTK_FILE_CHOOSER=no)
1684   fi
1685
1686   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1687      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1688     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1689               [Define to 1 if GTK has both file selection and chooser dialog.])
1690   fi
1691
1692   dnl Check if pthreads are available.  Emacs only needs this when using
1693   dnl gtk_file_chooser under Gnome.
1694   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1695     HAVE_GTK_AND_PTHREAD=no
1696     AC_CHECK_HEADERS(pthread.h)
1697     if test "$ac_cv_header_pthread_h"; then
1698       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1699     fi
1700     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1701       case "${canonical}" in
1702         *-hpux*) ;;
1703         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1704       esac
1705       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1706                [Define to 1 if you have GTK and pthread (-lpthread).])
1707     fi
1708   fi
1709 fi
1710
1711 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1712 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1713 dnl also not configured.
1714 HAVE_DBUS=no
1715 if test "${with_dbus}" = "yes"; then
1716    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1717    if test "$HAVE_DBUS" = yes; then
1718      LIBS="$LIBS $DBUS_LIBS"
1719      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1720      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1721    fi
1722 fi
1723
1724 dnl GConf has been tested under GNU/Linux only.
1725 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1726 HAVE_GCONF=no
1727 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1728    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1729    if test "$HAVE_GCONF" = yes; then
1730       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1731    fi
1732 fi
1733
1734 dnl Do not put whitespace before the #include statements below.
1735 dnl Older compilers (eg sunos4 cc) choke on it.
1736 HAVE_XAW3D=no
1737 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1738   if test "$with_xaw3d" != no; then
1739     AC_MSG_CHECKING(for xaw3d)
1740     AC_CACHE_VAL(emacs_cv_xaw3d,
1741     [AC_TRY_LINK([
1742 #include <X11/Intrinsic.h>
1743 #include <X11/Xaw3d/Simple.h>],
1744       [],
1745       emacs_cv_xaw3d=yes,
1746       emacs_cv_xaw3d=no)])
1747   else
1748     emacs_cv_xaw3d=no
1749   fi
1750   if test $emacs_cv_xaw3d = yes; then
1751     AC_MSG_RESULT([yes; using Lucid toolkit])
1752     USE_X_TOOLKIT=LUCID
1753     HAVE_XAW3D=yes
1754     AC_DEFINE(HAVE_XAW3D, 1,
1755               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1756   else
1757     AC_MSG_RESULT(no)
1758     AC_MSG_CHECKING(for libXaw)
1759     AC_CACHE_VAL(emacs_cv_xaw,
1760     [AC_TRY_LINK([
1761 #include <X11/Intrinsic.h>
1762 #include <X11/Xaw/Simple.h>],
1763       [],
1764       emacs_cv_xaw=yes,
1765       emacs_cv_xaw=no)])
1766     if test $emacs_cv_xaw = yes; then
1767       AC_MSG_RESULT([yes; using Lucid toolkit])
1768       USE_X_TOOLKIT=LUCID
1769     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1770       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1771     else
1772       AC_MSG_RESULT([no; do not use toolkit by default])
1773       USE_X_TOOLKIT=none
1774     fi
1775   fi
1776 fi
1777
1778 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1779
1780 if test "${USE_X_TOOLKIT}" != "none"; then
1781   AC_MSG_CHECKING(X11 toolkit version)
1782   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1783   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1784 [#if XtSpecificationRelease < 6
1785 fail;
1786 #endif
1787 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1788   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1789   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1790     AC_MSG_RESULT(6 or newer)
1791     AC_DEFINE(HAVE_X11XTR6, 1,
1792               [Define to 1 if you have the X11R6 or newer version of Xt.])
1793   else
1794     AC_MSG_RESULT(before 6)
1795   fi
1796
1797 dnl If using toolkit, check whether libXmu.a exists.
1798 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1799   OLDLIBS="$LIBS"
1800   if test x$HAVE_X11XTR6 = xyes; then
1801     LIBS="-lXt -lSM -lICE $LIBS"
1802   else
1803     LIBS="-lXt $LIBS"
1804   fi
1805   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1806   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1807 fi
1808
1809 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1810 if test "${HAVE_X11}" = "yes"; then
1811   if test "${USE_X_TOOLKIT}" != "none"; then
1812     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1813   fi
1814 fi
1815
1816 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1817   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1818   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1819     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1820 int x = 5;
1821 #else
1822 Motif version prior to 2.1.
1823 #endif],
1824     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1825   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1826   if test $emacs_cv_motif_version_2_1 = yes; then
1827     HAVE_LIBXP=no
1828     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1829               [Define to 1 if you have Motif 2.1 or newer.])
1830     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1831     if test ${HAVE_LIBXP} = yes; then
1832       AC_DEFINE(HAVE_LIBXP, 1,
1833                 [Define to 1 if you have the Xp library (-lXp).])
1834     fi
1835   else
1836     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1837     # We put this in CFLAGS temporarily to precede other -I options
1838     # that might be in CFLAGS temporarily.
1839     # We put this in CPPFLAGS where it precedes the other -I options.
1840     OLD_CPPFLAGS=$CPPFLAGS
1841     OLD_CFLAGS=$CFLAGS
1842     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1843     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1844     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1845       [int x = 5;],
1846       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1847     if test $emacs_cv_lesstif = yes; then
1848       # Make sure this -I option remains in CPPFLAGS after it is set
1849       # back to REAL_CPPFLAGS.
1850       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1851       # have those other -I options anyway.  Ultimately, having this
1852       # directory ultimately in CPPFLAGS will be enough.
1853       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1854       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1855     else
1856       CFLAGS=$OLD_CFLAGS
1857       CPPFLAGS=$OLD_CPPFLAGS
1858     fi
1859   fi
1860 fi
1861
1862 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1863 dnl using Motif or Xaw3d is available, and unless
1864 dnl --with-toolkit-scroll-bars=no was specified.
1865
1866 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1867             [Define to 1 if we should use toolkit scroll bars.])dnl
1868 USE_TOOLKIT_SCROLL_BARS=no
1869 if test "${with_toolkit_scroll_bars}" != "no"; then
1870   if test "${USE_X_TOOLKIT}" != "none"; then
1871     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1872       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1873       HAVE_XAW3D=no
1874       USE_TOOLKIT_SCROLL_BARS=yes
1875     elif test "${HAVE_XAW3D}" = "yes"; then
1876       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1877       USE_TOOLKIT_SCROLL_BARS=yes
1878     fi
1879   elif test "${HAVE_GTK}" = "yes"; then
1880     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1881     USE_TOOLKIT_SCROLL_BARS=yes
1882   elif test "${HAVE_NS}" = "yes"; then
1883     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1884     USE_TOOLKIT_SCROLL_BARS=yes
1885   fi
1886 fi
1887
1888 dnl See if XIM is available.
1889 AC_TRY_COMPILE([
1890           #include <X11/Xlib.h>
1891           #include <X11/Xresource.h>],
1892          [XIMProc  callback;],
1893          [HAVE_XIM=yes
1894          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1895          HAVE_XIM=no)
1896
1897 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1898
1899 if test "${with_xim}" != "no"; then
1900   AC_DEFINE(USE_XIM, 1,
1901             [Define to 1 if we should use XIM, if it is available.])
1902 fi
1903
1904
1905 if test "${HAVE_XIM}" != "no"; then
1906   late_CFLAGS=$CFLAGS
1907   if test "$GCC" = yes; then
1908     CFLAGS="$CFLAGS --pedantic-errors"
1909   fi
1910   AC_TRY_COMPILE([
1911 #include <X11/Xlib.h>
1912 #include <X11/Xresource.h>],
1913 [Display *display;
1914 XrmDatabase db;
1915 char *res_name;
1916 char *res_class;
1917 XIMProc  callback;
1918 XPointer *client_data;
1919 #ifndef __GNUC__
1920 /* If we're not using GCC, it's probably not XFree86, and this is
1921    probably right, but we can't use something like --pedantic-errors.  */
1922 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1923                                            char*, XIMProc, XPointer*);
1924 #endif
1925 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1926    client_data);],
1927     [emacs_cv_arg6_star=yes])
1928   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1929          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1930 either XPointer or XPointer*.])dnl
1931   if test "$emacs_cv_arg6_star" = yes; then
1932     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1933   else
1934     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1935   fi
1936   CFLAGS=$late_CFLAGS
1937 fi
1938
1939 ### Start of font-backend (under any platform) section.
1940 # (nothing here yet -- this is a placeholder)
1941 ### End of font-backend (under any platform) section.
1942
1943 ### Start of font-backend (under X11) section.
1944 if test "${HAVE_X11}" = "yes"; then
1945    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1946
1947    ## Use -lXft if available, unless `--with-xft=no'.
1948    HAVE_XFT=maybe
1949     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
1950       with_xft="no";
1951     fi
1952     if test "x${with_xft}" != "xno"; then
1953
1954       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1955       ## Because xftfont.c uses XRenderQueryExtension, we also
1956       ## need to link to -lXrender.
1957       HAVE_XRENDER=no
1958       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
1959       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
1960         OLD_CPPFLAGS="$CPPFLAGS"
1961         OLD_CFLAGS="$CFLAGS"
1962         OLD_LIBS="$LIBS"
1963         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1964         CFLAGS="$CFLAGS $XFT_CFLAGS"
1965         XFT_LIBS="-lXrender $XFT_LIBS"
1966         LIBS="$XFT_LIBS $LIBS"
1967         AC_CHECK_HEADER(X11/Xft/Xft.h,
1968           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1969
1970         if test "${HAVE_XFT}" = "yes"; then
1971           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1972             AC_SUBST(XFT_LIBS)
1973           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1974         else
1975           CPPFLAGS="$OLD_CPPFLAGS"
1976           CFLAGS="$OLD_CFLAGS"
1977           LIBS="$OLD_LIBS"
1978         fi                        # "${HAVE_XFT}" = "yes"
1979       fi                          # "$HAVE_XFT" != no
1980     fi                            # "x${with_xft}" != "xno"
1981
1982     dnl For the "Does Emacs use" message at the end.
1983     if test "$HAVE_XFT" != "yes"; then
1984        HAVE_XFT=no
1985     fi
1986
1987
1988     HAVE_FREETYPE=no
1989     ## We used to allow building with FreeType and without Xft.
1990     ## However, the ftx font backend driver is not in good shape.
1991     if test "${HAVE_XFT}" = "yes"; then
1992       dnl As we use Xft, we anyway use freetype.
1993       dnl There's no need for additional CFLAGS and LIBS.
1994       HAVE_FREETYPE=yes
1995       FONTCONFIG_CFLAGS=
1996       FONTCONFIG_LIBS=
1997     fi
1998
1999     HAVE_LIBOTF=no
2000     if test "${HAVE_FREETYPE}" = "yes"; then
2001       AC_DEFINE(HAVE_FREETYPE, 1,
2002                 [Define to 1 if using the freetype and fontconfig libraries.])
2003       if test "${with_libotf}" != "no"; then
2004         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2005                           HAVE_LIBOTF=no)
2006         if test "$HAVE_LIBOTF" = "yes"; then
2007           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2008           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2009                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2010                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2011           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2012             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2013                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2014           fi
2015         fi
2016       fi
2017     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2018     dnl Does the new font backend require it, or can it work without it?
2019     fi
2020
2021     HAVE_M17N_FLT=no
2022     if test "${HAVE_LIBOTF}" = yes; then
2023       if test "${with_m17n_flt}" != "no"; then
2024         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2025         if test "$HAVE_M17N_FLT" = "yes"; then
2026           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2027         fi
2028       fi
2029     fi
2030 else
2031     HAVE_XFT=no
2032     HAVE_FREETYPE=no
2033     HAVE_LIBOTF=no
2034     HAVE_M17N_FLT=no
2035 fi
2036 ### End of font-backend (under X11) section.
2037
2038 AC_SUBST(FREETYPE_CFLAGS)
2039 AC_SUBST(FREETYPE_LIBS)
2040 AC_SUBST(FONTCONFIG_CFLAGS)
2041 AC_SUBST(FONTCONFIG_LIBS)
2042 AC_SUBST(LIBOTF_CFLAGS)
2043 AC_SUBST(LIBOTF_LIBS)
2044 AC_SUBST(M17N_FLT_CFLAGS)
2045 AC_SUBST(M17N_FLT_LIBS)
2046
2047 ### Use -lXpm if available, unless `--with-xpm=no'.
2048 HAVE_XPM=no
2049 LIBXPM=
2050 if test "${HAVE_X11}" = "yes"; then
2051   if test "${with_xpm}" != "no"; then
2052     AC_CHECK_HEADER(X11/xpm.h,
2053       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2054     if test "${HAVE_XPM}" = "yes"; then
2055       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2056       AC_EGREP_CPP(no_return_alloc_pixels,
2057       [#include "X11/xpm.h"
2058 #ifndef XpmReturnAllocPixels
2059 no_return_alloc_pixels
2060 #endif
2061       ], HAVE_XPM=no, HAVE_XPM=yes)
2062
2063       if test "${HAVE_XPM}" = "yes"; then
2064         AC_MSG_RESULT(yes)
2065       else
2066         AC_MSG_RESULT(no)
2067       fi
2068     fi
2069   fi
2070
2071   if test "${HAVE_XPM}" = "yes"; then
2072     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2073     LIBXPM=-lXpm
2074   fi
2075 fi
2076 AC_SUBST(LIBXPM)
2077
2078 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2079 HAVE_JPEG=no
2080 LIBJPEG=
2081 if test "${HAVE_X11}" = "yes"; then
2082   if test "${with_jpeg}" != "no"; then
2083     dnl Checking for jpeglib.h can lose because of a redefinition of
2084     dnl  HAVE_STDLIB_H.
2085     AC_CHECK_HEADER(jerror.h,
2086       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2087   fi
2088
2089   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2090   if test "${HAVE_JPEG}" = "yes"; then
2091     AC_DEFINE(HAVE_JPEG)
2092     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2093         [#include <jpeglib.h>
2094          version=JPEG_LIB_VERSION
2095 ],
2096         [AC_DEFINE(HAVE_JPEG)],
2097         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2098         HAVE_JPEG=no])
2099   fi
2100   if test "${HAVE_JPEG}" = "yes"; then
2101     LIBJPEG=-ljpeg
2102   fi
2103 fi
2104 AC_SUBST(LIBJPEG)
2105
2106 ### Use -lpng if available, unless `--with-png=no'.
2107 HAVE_PNG=no
2108 LIBPNG=
2109 if test "${HAVE_X11}" = "yes"; then
2110   if test "${with_png}" != "no"; then
2111     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2112     # in /usr/include/libpng.
2113     AC_CHECK_HEADERS(png.h libpng/png.h)
2114     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2115       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2116     fi
2117   fi
2118
2119   if test "${HAVE_PNG}" = "yes"; then
2120     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2121     LIBPNG="-lpng -lz -lm"
2122   fi
2123 fi
2124 AC_SUBST(LIBPNG)
2125
2126 ### Use -ltiff if available, unless `--with-tiff=no'.
2127 HAVE_TIFF=no
2128 LIBTIFF=
2129 if test "${HAVE_X11}" = "yes"; then
2130   if test "${with_tiff}" != "no"; then
2131     AC_CHECK_HEADER(tiffio.h,
2132       [tifflibs="-lz -lm"
2133       # At least one tiff package requires the jpeg library.
2134       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2135       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2136   fi
2137
2138   if test "${HAVE_TIFF}" = "yes"; then
2139     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2140     dnl FIXME -lz -lm, as per libpng?
2141     LIBTIFF=-ltiff
2142   fi
2143 fi
2144 AC_SUBST(LIBTIFF)
2145
2146 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2147 HAVE_GIF=no
2148 LIBGIF=
2149 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2150   AC_CHECK_HEADER(gif_lib.h,
2151 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2152 # Earlier versions can crash Emacs.
2153     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2154
2155   if test "$HAVE_GIF" = yes; then
2156     LIBGIF=-lgif
2157   elif test "$HAVE_GIF" = maybe; then
2158 # If gif_lib.h but no libgif, try libungif.
2159     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2160     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2161   fi
2162
2163   if test "${HAVE_GIF}" = "yes"; then
2164     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2165   fi
2166 fi
2167 AC_SUBST(LIBGIF)
2168
2169 dnl Check for required libraries.
2170 if test "${HAVE_X11}" = "yes"; then
2171   MISSING=""
2172   WITH_NO=""
2173   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2174     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2175   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2176     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2177   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2178     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2179   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2180     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2181   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2182     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2183
2184   if test "X${MISSING}" != X; then
2185     AC_MSG_ERROR([The following required libraries were not found:
2186     $MISSING
2187 Maybe some development libraries/packages are missing?
2188 If you don't want to link with them give
2189     $WITH_NO
2190 as options to configure])
2191   fi
2192 fi
2193
2194 ### Use -lgpm if available, unless `--with-gpm=no'.
2195 HAVE_GPM=no
2196 LIBGPM=
2197 if test "${with_gpm}" != "no"; then
2198   AC_CHECK_HEADER(gpm.h,
2199     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2200
2201   if test "${HAVE_GPM}" = "yes"; then
2202     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2203     LIBGPM=-lgpm
2204   fi
2205 fi
2206 AC_SUBST(LIBGPM)
2207
2208 dnl Check for malloc/malloc.h on darwin
2209 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2210
2211 ### Use NeXTstep API to implement GUI.
2212 if test "${HAVE_NS}" = "yes"; then
2213   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2214   if test "${NS_IMPL_COCOA}" = "yes"; then
2215     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2216     GNU_OBJC_CFLAGS=
2217   fi
2218   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2219     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2220     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2221   fi
2222   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2223     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2224   fi
2225   # We also have mouse menus.
2226   HAVE_MENUS=yes
2227   OTHER_FILES=ns-app
2228 fi
2229
2230
2231 ### Use session management (-lSM -lICE) if available
2232 HAVE_X_SM=no
2233 if test "${HAVE_X11}" = "yes"; then
2234   AC_CHECK_HEADER(X11/SM/SMlib.h,
2235     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2236
2237   if test "${HAVE_X_SM}" = "yes"; then
2238     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2239     case "$LIBS" in
2240       *-lSM*) ;;
2241       *)      LIBS="-lSM -lICE $LIBS" ;;
2242     esac
2243   fi
2244 fi
2245
2246 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2247 AC_CACHE_CHECK(whether netdb declares h_errno,
2248                emacs_cv_netdb_declares_h_errno,
2249 [AC_TRY_LINK([#include <netdb.h>],
2250   [return h_errno;],
2251   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2252 if test $emacs_cv_netdb_declares_h_errno = yes; then
2253   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2254 fi
2255
2256 AC_FUNC_ALLOCA
2257
2258 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2259 dnl FIXME is there an autoconf test that does the right thing, without
2260 dnl needing to call A_M_E afterwards?
2261 if test x"$ac_cv_func_alloca_works" != xyes; then
2262    AC_MSG_ERROR( [a system implementation of alloca is required] )
2263 fi
2264
2265 # fmod, logb, and frexp are found in -lm on most systems.
2266 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2267 AC_CHECK_LIB(m, sqrt)
2268
2269 # Check for mail-locking functions in a "mail" library.  Probably this should
2270 # have the same check as for liblockfile below.
2271 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2272 if test $have_mail = yes; then
2273   LIBS_MAIL=-lmail
2274   LIBS="$LIBS_MAIL $LIBS"
2275   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2276 else
2277   LIBS_MAIL=
2278 fi
2279 dnl Debian, at least:
2280 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2281 if test $have_lockfile = yes; then
2282    LIBS_MAIL=-llockfile
2283    LIBS="$LIBS_MAIL $LIBS"
2284    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2285 else
2286 # If we have the shared liblockfile, assume we must use it for mail
2287 # locking (e.g. Debian).  If we couldn't link against liblockfile
2288 # (no liblockfile.a installed), ensure that we don't need to.
2289   dnl This works for files generally, not just executables.
2290   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2291   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2292                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2293   if test $ac_cv_prog_liblockfile = yes; then
2294     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2295 This probably means that movemail could lose mail.
2296 There may be a `development' package to install containing liblockfile.])
2297   fi
2298 fi
2299 AC_CHECK_FUNCS(touchlock)
2300 AC_CHECK_HEADERS(maillock.h)
2301 AC_SUBST(LIBS_MAIL)
2302
2303 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2304 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2305 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2306 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2307 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2308 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2309 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2310 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2311 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2312 cfmakeraw cfsetspeed)
2313
2314 AC_CHECK_HEADERS(sys/un.h)
2315
2316 AC_FUNC_MKTIME
2317 if test "$ac_cv_func_working_mktime" = no; then
2318   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2319 fi
2320
2321 AC_FUNC_GETLOADAVG
2322
2323 AC_FUNC_FSEEKO
2324
2325 # Configure getopt.
2326 m4_include([m4/getopt.m4])
2327 gl_GETOPT_IFELSE([
2328   gl_GETOPT_SUBSTITUTE_HEADER
2329   gl_PREREQ_GETOPT
2330   GETOPTOBJS='getopt.o getopt1.o'
2331 ])
2332 AC_SUBST(GETOPTOBJS)
2333
2334 AC_FUNC_GETPGRP
2335
2336 AC_FUNC_STRFTIME
2337
2338 # UNIX98 PTYs.
2339 AC_CHECK_FUNCS(grantpt)
2340
2341 # PTY-related GNU extensions.
2342 AC_CHECK_FUNCS(getpt)
2343
2344 # Check this now, so that we will NOT find the above functions in ncurses.
2345 # That is because we have not set up to link ncurses in lib-src.
2346 # It's better to believe a function is not available
2347 # than to expect to find it in ncurses.
2348 # Also we need tputs and frieds to be able to build at all.
2349 have_tputs_et_al=true
2350 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2351 if test "$have_tputs_et_al" != true; then
2352   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2353 Maybe some development libraries/packages are missing?  Try installing
2354 libncurses-dev(el), libterminfo-dev(el) or similar.])
2355 fi
2356 # Must define this when any termcap library is found.
2357 AC_DEFINE(HAVE_LIBNCURSES, 1,
2358           [Define to 1 if you have the `ncurses' library (-lncurses).])
2359
2360 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2361
2362 resolv=no
2363 AC_TRY_LINK([#include <netinet/in.h>
2364 #include <arpa/nameser.h>
2365 #include <resolv.h>],
2366     [return res_init();],
2367     have_res_init=yes, have_res_init=no)
2368 if test "$have_res_init" = no; then
2369   OLIBS="$LIBS"
2370   LIBS="$LIBS -lresolv"
2371   AC_MSG_CHECKING(for res_init with -lresolv)
2372   AC_TRY_LINK([#include <netinet/in.h>
2373 #include <arpa/nameser.h>
2374 #include <resolv.h>],
2375     [return res_init();],
2376     have_res_init=yes, have_res_init=no)
2377   AC_MSG_RESULT($have_res_init)
2378   if test "$have_res_init" = yes ; then
2379     resolv=yes
2380   fi
2381   LIBS="$OLIBS"
2382 fi
2383
2384 if test "$have_res_init" = yes; then
2385   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2386 fi
2387
2388 # Do we need the Hesiod library to provide the support routines?
2389 LIBHESIOD=
2390 if test "$with_hesiod" != no ; then
2391   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2392   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2393      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2394                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2395   if test "$resolv" = yes ; then
2396     RESOLVLIB=-lresolv
2397   else
2398     RESOLVLIB=
2399   fi
2400   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2401         hesiod=yes, :, $RESOLVLIB)])
2402
2403   if test x"$hesiod" = xyes; then
2404     AC_DEFINE(HAVE_LIBHESIOD, 1,
2405               [Define to 1 if you have the hesiod library (-lhesiod).])
2406     LIBHESIOD=-lhesiod
2407   fi
2408 fi
2409 AC_SUBST(LIBHESIOD)
2410
2411 # Do we need libresolv (due to res_init or Hesiod)?
2412 if test "$resolv" = yes ; then
2413   AC_DEFINE(HAVE_LIBRESOLV, 1,
2414             [Define to 1 if you have the resolv library (-lresolv).])
2415   LIBRESOLV=-lresolv
2416 else
2417   LIBRESOLV=
2418 fi
2419 AC_SUBST(LIBRESOLV)
2420
2421 # These tell us which Kerberos-related libraries to use.
2422 COM_ERRLIB=
2423 CRYPTOLIB=
2424 KRB5LIB=
2425 DESLIB=
2426 KRB4LIB=
2427
2428 if test "${with_kerberos}" != no; then
2429   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2430   if test $have_com_err = yes; then
2431     COM_ERRLIB=-lcom_err
2432     LIBS="$COM_ERRLIB $LIBS"
2433     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2434   fi
2435   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2436   if test $have_crypto = yes; then
2437     CRYPTOLIB=-lcrypto
2438     LIBS="$CRYPTOLIB $LIBS"
2439     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2440   fi
2441   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2442   if test $have_k5crypto = yes; then
2443     CRYPTOLIB=-lk5crypto
2444     LIBS="$CRYPTOLIB $LIBS"
2445     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2446   fi
2447   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2448   if test $have_krb5=yes; then
2449     KRB5LIB=-lkrb5
2450     LIBS="$KRB5LIB $LIBS"
2451     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2452   fi
2453   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2454   if test "${with_kerberos5}" = no; then
2455     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2456     if test $have_des425 = yes; then
2457       DESLIB=-ldes425
2458       LIBS="$DESLIB $LIBS"
2459       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2460     else
2461       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2462       if test $have_des = yes; then
2463         DESLIB=-ldes
2464         LIBS="$DESLIB $LIBS"
2465         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2466       fi
2467     fi
2468     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2469     if test $have_krb4 = yes; then
2470       KRB4LIB=-lkrb4
2471       LIBS="$KRB4LIB $LIBS"
2472       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2473     else
2474       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2475       if test $have_krb = yes; then
2476         KRB4LIB=-lkrb
2477         LIBS="$KRB4LIB $LIBS"
2478         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2479       fi
2480     fi
2481   fi
2482
2483   if test "${with_kerberos5}" != no; then
2484     AC_CHECK_HEADERS(krb5.h,
2485       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2486                         [#include <krb5.h>])])
2487   else
2488     AC_CHECK_HEADERS(des.h,,
2489                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2490                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2491     AC_CHECK_HEADERS(krb.h,,
2492                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2493                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2494   fi
2495   AC_CHECK_HEADERS(com_err.h)
2496 fi
2497
2498 AC_SUBST(COM_ERRLIB)
2499 AC_SUBST(CRYPTOLIB)
2500 AC_SUBST(KRB5LIB)
2501 AC_SUBST(DESLIB)
2502 AC_SUBST(KRB4LIB)
2503
2504 # Solaris requires -lintl if you want strerror (which calls dgettext)
2505 # to return localized messages.
2506 AC_CHECK_LIB(intl, dgettext)
2507
2508 AC_MSG_CHECKING(whether localtime caches TZ)
2509 AC_CACHE_VAL(emacs_cv_localtime_cache,
2510 [if test x$ac_cv_func_tzset = xyes; then
2511 AC_TRY_RUN([#include <time.h>
2512 extern char **environ;
2513 unset_TZ ()
2514 {
2515   char **from, **to;
2516   for (to = from = environ; (*to = *from); from++)
2517     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2518       to++;
2519 }
2520 char TZ_GMT0[] = "TZ=GMT0";
2521 char TZ_PST8[] = "TZ=PST8";
2522 main()
2523 {
2524   time_t now = time ((time_t *) 0);
2525   int hour_GMT0, hour_unset;
2526   if (putenv (TZ_GMT0) != 0)
2527     exit (1);
2528   hour_GMT0 = localtime (&now)->tm_hour;
2529   unset_TZ ();
2530   hour_unset = localtime (&now)->tm_hour;
2531   if (putenv (TZ_PST8) != 0)
2532     exit (1);
2533   if (localtime (&now)->tm_hour == hour_GMT0)
2534     exit (1);
2535   unset_TZ ();
2536   if (localtime (&now)->tm_hour != hour_unset)
2537     exit (1);
2538   exit (0);
2539 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2540 [# If we have tzset, assume the worst when cross-compiling.
2541 emacs_cv_localtime_cache=yes])
2542 else
2543         # If we lack tzset, report that localtime does not cache TZ,
2544         # since we can't invalidate the cache if we don't have tzset.
2545         emacs_cv_localtime_cache=no
2546 fi])dnl
2547 AC_MSG_RESULT($emacs_cv_localtime_cache)
2548 if test $emacs_cv_localtime_cache = yes; then
2549   AC_DEFINE(LOCALTIME_CACHE, 1,
2550             [Define to 1 if localtime caches TZ.])
2551 fi
2552
2553 if test "x$HAVE_TIMEVAL" = xyes; then
2554   AC_CHECK_FUNCS(gettimeofday)
2555   if test $ac_cv_func_gettimeofday = yes; then
2556     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2557                    emacs_cv_gettimeofday_two_arguments,
2558     [AC_TRY_COMPILE([
2559 #ifdef TIME_WITH_SYS_TIME
2560 #include <sys/time.h>
2561 #include <time.h>
2562 #else
2563 #ifdef HAVE_SYS_TIME_H
2564 #include <sys/time.h>
2565 #else
2566 #include <time.h>
2567 #endif
2568 #endif],
2569       [struct timeval time;
2570        gettimeofday (&time, 0);],
2571       emacs_cv_gettimeofday_two_arguments=yes,
2572       emacs_cv_gettimeofday_two_arguments=no)])
2573     if test $emacs_cv_gettimeofday_two_arguments = no; then
2574       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2575                 [Define to 1 if gettimeofday accepts only one argument.])
2576     fi
2577   fi
2578 fi
2579
2580 ok_so_far=yes
2581 AC_CHECK_FUNC(socket, , ok_so_far=no)
2582 if test $ok_so_far = yes; then
2583   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2584 fi
2585 if test $ok_so_far = yes; then
2586   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2587 fi
2588 if test $ok_so_far = yes; then
2589 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2590   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2591             [Define to 1 if you have inet sockets.])
2592 fi
2593
2594 AC_CHECK_HEADERS(sys/ioctl.h)
2595
2596 if test -f /usr/lpp/X11/bin/smt.exp; then
2597   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2598             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2599 fi
2600
2601 AC_MSG_CHECKING(whether system supports dynamic ptys)
2602 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2603   AC_MSG_RESULT(yes)
2604   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2605 else
2606   AC_MSG_RESULT(no)
2607 fi
2608
2609 AC_FUNC_FORK
2610
2611 dnl Adapted from Haible's version.
2612 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2613   [AC_TRY_LINK([#include <langinfo.h>],
2614     [char* cs = nl_langinfo(CODESET);],
2615     emacs_cv_langinfo_codeset=yes,
2616     emacs_cv_langinfo_codeset=no)
2617   ])
2618 if test $emacs_cv_langinfo_codeset = yes; then
2619   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2620     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2621 fi
2622
2623 AC_CHECK_TYPES(size_t)
2624
2625 AC_TYPE_MBSTATE_T
2626
2627 dnl Restrict could probably be used effectively other than in regex.c.
2628 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2629   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2630                   emacs_cv_c_restrict=yes,
2631                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2632                                   emacs_cv_c_restrict=__restrict,
2633                                   emacs_cv_c_restrict=no)])])
2634 case "$emacs_cv_c_restrict" in
2635   yes) emacs_restrict=restrict;;
2636   no) emacs_restrict="";;
2637   *) emacs_restrict="$emacs_cv_c_restrict";;
2638 esac
2639 if test "$emacs_restrict" != __restrict; then
2640   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2641     [Define to compiler's equivalent of C99 restrict keyword.
2642      Don't define if equivalent is `__restrict'.])
2643 fi
2644
2645 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2646   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2647                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2648 if test "$emacs_cv_c_restrict_arr" = yes; then
2649   AC_DEFINE(__restrict_arr, __restrict,
2650     [Define to compiler's equivalent of C99 restrict keyword in array
2651      declarations.  Define as empty for no equivalent.])
2652 fi
2653
2654 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2655 dnl how the tty code is related to POSIX and/or other versions of termios.
2656 dnl The following looks like a useful start.
2657 dnl
2658 dnl AC_SYS_POSIX_TERMIOS
2659 dnl if test $ac_cv_sys_posix_termios = yes; then
2660 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2661 dnl                                and macros for terminal control.])
2662 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2663 dnl fi
2664
2665 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2666
2667 # Set up the CFLAGS for real compilation, so we can substitute it.
2668 CFLAGS="$REAL_CFLAGS"
2669 CPPFLAGS="$REAL_CPPFLAGS"
2670
2671 #### Find out which version of Emacs this is.
2672 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2673          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2674 if test x"${version}" = x; then
2675   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2676 fi
2677 if test x"${version}" != x"$PACKAGE_VERSION"; then
2678   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
2679 fi
2680
2681 ### Specify what sort of things we'll be editing into Makefile and config.h.
2682 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2683 AC_SUBST(version)
2684 AC_SUBST(configuration)
2685 AC_SUBST(canonical)
2686 AC_SUBST(srcdir)
2687 AC_SUBST(prefix)
2688 AC_SUBST(exec_prefix)
2689 AC_SUBST(bindir)
2690 AC_SUBST(datadir)
2691 AC_SUBST(sharedstatedir)
2692 AC_SUBST(libexecdir)
2693 AC_SUBST(mandir)
2694 AC_SUBST(infodir)
2695 AC_SUBST(lispdir)
2696 AC_SUBST(locallisppath)
2697 AC_SUBST(lisppath)
2698 AC_SUBST(x_default_search_path)
2699 AC_SUBST(etcdir)
2700 AC_SUBST(archlibdir)
2701 AC_SUBST(docdir)
2702 AC_SUBST(bitmapdir)
2703 AC_SUBST(gamedir)
2704 AC_SUBST(gameuser)
2705 AC_SUBST(c_switch_system)
2706 AC_SUBST(c_switch_machine)
2707 AC_SUBST(LD_SWITCH_X_SITE)
2708 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2709 AC_SUBST(C_SWITCH_X_SITE)
2710 AC_SUBST(CFLAGS)
2711 AC_SUBST(X_TOOLKIT_TYPE)
2712 AC_SUBST(machfile)
2713 AC_SUBST(opsysfile)
2714 AC_SUBST(GETLOADAVG_LIBS)
2715 AC_SUBST(ns_appdir)
2716 AC_SUBST(ns_appbindir)
2717 AC_SUBST(ns_appresdir)
2718 AC_SUBST(ns_appsrc)
2719 AC_SUBST(GNUSTEP_MAKEFILES)
2720 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2721 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2722 AC_SUBST(GNU_OBJC_CFLAGS)
2723 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2724 AC_SUBST(OTHER_FILES)
2725
2726 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2727                    [Define to the canonical Emacs configuration name.])
2728 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2729                    [Define to the options passed to configure.])
2730 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2731                    [Define to the used machine dependent file.])
2732 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2733                    [Define to the used os dependent file.])
2734 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2735 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2736  may need to deal with X Windows.  For instance, if you've defined
2737  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2738  your loader can find on its own, you might want to add "-L/..." or
2739  something similar.])
2740 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2741                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2742                     in case it's needed (for Solaris, for example).])
2743 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2744 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2745  may need to deal with X Windows.  For instance, if you've defined
2746  HAVE_X_WINDOWS above and your X include files aren't in a place
2747  that your compiler can find on its own, you might want to add
2748  "-I/..." or something similar.])
2749 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2750                    [Define to the unexec source file name.])
2751
2752 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2753   AC_DEFINE(HAVE_X_WINDOWS, 1,
2754             [Define to 1 if you want to use the X window system.])
2755 fi
2756 if test "${USE_X_TOOLKIT}" != "none" ; then
2757   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2758   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2759     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2760   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2761     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2762   fi
2763 fi
2764 if test "${HAVE_X11}" = "yes" ; then
2765   AC_DEFINE(HAVE_X11, 1,
2766             [Define to 1 if you want to use version 11 of X windows.
2767              Otherwise, Emacs expects to use version 10.])
2768 fi
2769 if test "${HAVE_MENUS}" = "yes" ; then
2770   AC_DEFINE(HAVE_MENUS, 1,
2771             [Define to 1 if you have mouse menus.
2772              (This is automatic if you use X, but the option to specify it remains.)
2773              It is also defined with other window systems that support xmenu.c.])
2774 fi
2775 if test "${GNU_MALLOC}" = "yes" ; then
2776   AC_DEFINE(GNU_MALLOC, 1,
2777             [Define to 1 if you want to use the GNU memory allocator.])
2778 fi
2779 if test "${REL_ALLOC}" = "yes" ; then
2780   AC_DEFINE(REL_ALLOC, 1,
2781             [Define REL_ALLOC if you want to use the relocating allocator for
2782              buffer space.])
2783 fi
2784
2785
2786 AH_TOP([/* GNU Emacs site configuration template file.
2787    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2788      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
2789
2790 This file is part of GNU Emacs.
2791
2792 GNU Emacs is free software: you can redistribute it and/or modify
2793 it under the terms of the GNU General Public License as published by
2794 the Free Software Foundation, either version 3 of the License, or
2795 (at your option) any later version.
2796
2797 GNU Emacs is distributed in the hope that it will be useful,
2798 but WITHOUT ANY WARRANTY; without even the implied warranty of
2799 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2800 GNU General Public License for more details.
2801
2802 You should have received a copy of the GNU General Public License
2803 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2804
2805
2806 /* No code in Emacs #includes config.h twice, but some bits of code
2807    intended to work with other packages as well (like gmalloc.c)
2808    think they can include it as many times as they like.  */
2809 #ifndef EMACS_CONFIG_H
2810 #define EMACS_CONFIG_H
2811 ])dnl
2812
2813 AH_BOTTOM([
2814 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2815 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2816 #define HAVE_WINDOW_SYSTEM
2817 #define HAVE_MOUSE
2818 #endif
2819
2820 /* Define AMPERSAND_FULL_NAME if you use the convention
2821    that & in the full name stands for the login id.  */
2822 /* Turned on June 1996 supposing nobody will mind it.  */
2823 #define AMPERSAND_FULL_NAME
2824
2825 /* Define HAVE_SOUND if we have sound support.  We know it works
2826    and compiles only on the specified platforms.   For others,
2827    it probably doesn't make sense to try.  */
2828
2829 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2830 #ifdef HAVE_MACHINE_SOUNDCARD_H
2831 #define HAVE_SOUND 1
2832 #endif
2833 #ifdef HAVE_SYS_SOUNDCARD_H
2834 #define HAVE_SOUND 1
2835 #endif
2836 #ifdef HAVE_SOUNDCARD_H
2837 #define HAVE_SOUND 1
2838 #endif
2839 #ifdef HAVE_ALSA
2840 #define HAVE_SOUND 1
2841 #endif
2842 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2843
2844 /* If using GNU, then support inline function declarations. */
2845 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2846    generally, because even if non-gcc compilers accept `inline', they
2847    may reject `extern inline'.  */
2848 #if defined (__GNUC__) && defined (OPTIMIZE)
2849 #define INLINE __inline__
2850 #else
2851 #define INLINE
2852 #endif
2853
2854 /* `subprocesses' should be defined if you want to
2855    have code for asynchronous subprocesses
2856    (as used in M-x compile and M-x shell).
2857    Only MSDOS does not support this (it overrides
2858    this in its config_opsysfile below).  */
2859
2860 #define subprocesses
2861
2862 /* Include the os and machine dependent files.  */
2863 #include config_opsysfile
2864 #include config_machfile
2865
2866 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2867   (There is probably a better place to do this, but right now the Cocoa
2868    side does this in s/darwin.h and we cannot
2869    parallel this exactly since GNUstep is multi-OS. */
2870 #ifdef HAVE_NS
2871 # ifdef NS_IMPL_GNUSTEP
2872 /* See also .m.o rule in Makefile.in */
2873 /* FIXME: are all these flags really needed?  Document here why.  */
2874 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2875 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2876 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2877 #  define SYSTEM_PURESIZE_EXTRA 30000
2878 # endif /* NS_IMPL_GNUSTEP */
2879 #endif /* HAVE_NS */
2880
2881 /* SIGTYPE is the macro we actually use.  */
2882 #ifndef SIGTYPE
2883 #define SIGTYPE RETSIGTYPE
2884 #endif
2885
2886 #ifdef emacs /* Don't do this for lib-src.  */
2887 /* Tell regex.c to use a type compatible with Emacs.  */
2888 #define RE_TRANSLATE_TYPE Lisp_Object
2889 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2890 #ifdef make_number
2891 /* If make_number is a macro, use it.  */
2892 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2893 #else
2894 /* If make_number is a function, avoid it.  */
2895 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2896 #endif
2897 #endif
2898
2899 /* Avoid link-time collision with system mktime if we will use our own.  */
2900 #if ! HAVE_MKTIME || BROKEN_MKTIME
2901 #define mktime emacs_mktime
2902 #endif
2903
2904 #define my_strftime nstrftime   /* for strftime.c */
2905
2906 /* The rest of the code currently tests the CPP symbol BSTRING.
2907    Override any claims made by the system-description files.
2908    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2909 #undef BSTRING
2910 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2911 #define BSTRING
2912 #endif
2913
2914 /* Some of the files of Emacs which are intended for use with other
2915    programs assume that if you have a config.h file, you must declare
2916    the type of getenv.
2917
2918    This declaration shouldn't appear when alloca.s or Makefile.in
2919    includes config.h.  */
2920 #ifndef NOT_C_CODE
2921 extern char *getenv ();
2922 #endif
2923
2924 /* These default definitions are good for almost all machines.
2925    The exceptions override them in m/MACHINE.h.  */
2926
2927 #ifndef BITS_PER_CHAR
2928 #define BITS_PER_CHAR 8
2929 #endif
2930
2931 #ifndef BITS_PER_SHORT
2932 #define BITS_PER_SHORT 16
2933 #endif
2934
2935 /* Note that lisp.h uses this in a preprocessor conditional, so it
2936    would not work to use sizeof.  That being so, we do all of them
2937    without sizeof, for uniformity's sake.  */
2938 #ifndef BITS_PER_INT
2939 #define BITS_PER_INT 32
2940 #endif
2941
2942 #ifndef BITS_PER_LONG
2943 #ifdef _LP64
2944 #define BITS_PER_LONG 64
2945 #else
2946 #define BITS_PER_LONG 32
2947 #endif
2948 #endif
2949
2950 /* Define if the compiler supports function prototypes.  It may do so
2951    but not define __STDC__ (e.g. DEC C by default) or may define it as
2952    zero.  */
2953 #undef PROTOTYPES
2954 /* For mktime.c:  */
2955 #ifndef __P
2956 # if defined PROTOTYPES
2957 #  define __P(args) args
2958 # else
2959 #  define __P(args) ()
2960 # endif  /* GCC.  */
2961 #endif /* __P */
2962
2963 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2964 #ifndef NOT_C_CODE
2965 #ifdef HAVE_STRING_H
2966 #include "string.h"
2967 #endif
2968 #ifdef HAVE_STRINGS_H
2969 #include "strings.h"  /* May be needed for bcopy & al. */
2970 #endif
2971 #ifdef HAVE_STDLIB_H
2972 #include <stdlib.h>
2973 #endif
2974 #ifndef __GNUC__
2975 # ifdef HAVE_ALLOCA_H
2976 #  include <alloca.h>
2977 # else /* AIX files deal with #pragma.  */
2978 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2979 char *alloca ();
2980 #  endif
2981 # endif /* HAVE_ALLOCA_H */
2982 #endif /* __GNUC__ */
2983 #ifndef HAVE_SIZE_T
2984 typedef unsigned size_t;
2985 #endif
2986 #endif /* NOT_C_CODE */
2987
2988 /* Define HAVE_X_I18N if we have usable i18n support.  */
2989
2990 #ifdef HAVE_X11R6
2991 #define HAVE_X_I18N
2992 #elif !defined X11R5_INHIBIT_I18N
2993 #define HAVE_X_I18N
2994 #endif
2995
2996 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2997
2998 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2999 #define HAVE_X11R6_XIM
3000 #endif
3001
3002 #if defined __GNUC__ && (__GNUC__ > 2 \
3003                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3004 #define NO_RETURN       __attribute__ ((__noreturn__))
3005 #else
3006 #define NO_RETURN       /* nothing */
3007 #endif
3008
3009 /* These won't be used automatically yet.  We also need to know, at least,
3010    that the stack is continuous.  */
3011 #ifdef __GNUC__
3012 #  ifndef GC_SETJMP_WORKS
3013   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3014      see NON_SAVING_SETJMP in the target descriptions.  */
3015   /* Exceptions (see NON_SAVING_SETJMP in target description) are
3016      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3017      Fixme: Deal with SVR3.  */
3018 #    define GC_SETJMP_WORKS 1
3019 #  endif
3020 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3021 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3022 #  endif
3023 #endif
3024
3025 #ifndef HAVE_BCOPY
3026 #define bcopy(a,b,s) memcpy (b,a,s)
3027 #endif
3028 #ifndef HAVE_BZERO
3029 #define bzero(a,s) memset (a,0,s)
3030 #endif
3031 #ifndef HAVE_BCMP
3032 #define BCMP memcmp
3033 #endif
3034
3035 #endif /* EMACS_CONFIG_H */
3036
3037 /*
3038 Local Variables:
3039 mode: c
3040 End:
3041 */
3042 ])dnl
3043
3044 #### Report on what we decided to do.
3045 #### Report GTK as a toolkit, even if it doesn't use Xt.
3046 #### It makes printing result more understandable as using GTK sets
3047 #### toolkit_scroll_bars to yes by default.
3048 if test "${HAVE_GTK}" = "yes"; then
3049   USE_X_TOOLKIT=GTK
3050 fi
3051
3052 echo "
3053 Configured for \`${canonical}'.
3054
3055   Where should the build process find the source code?    ${srcdir}
3056   What operating system and machine description files should Emacs use?
3057         \`${opsysfile}' and \`${machfile}'
3058   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3059   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3060   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3061   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3062   What window system should Emacs use?                    ${window_system}
3063   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3064
3065 if test -n "${x_includes}"; then
3066 echo "  Where do we find X Windows header files?                ${x_includes}"
3067 else
3068 echo "  Where do we find X Windows header files?                Standard dirs"
3069 fi
3070 if test -n "${x_libraries}"; then
3071 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3072 else
3073 echo "  Where do we find X Windows libraries?                   Standard dirs"
3074 fi
3075
3076 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3077 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3078 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3079 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3080 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3081 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3082 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3083 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3084 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3085 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3086
3087 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3088 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3089 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3090 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3091
3092 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3093 echo
3094
3095 if test $USE_XASSERTS = yes; then
3096    echo "  Compiling with asserts turned on."
3097    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3098 fi
3099
3100 echo
3101
3102 if test "$HAVE_NS" = "yes"; then
3103    echo
3104    echo "You must run \"make install\" in order to test the built application.
3105 The installed application will go to nextstep/Emacs.app and can be
3106 run or moved from there."
3107    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3108       echo "The application will be fully self-contained."
3109     else
3110       echo "The lisp resources for the application will be installed under ${prefix}.
3111 You may need to run \"make install\" with sudo.  The application will fail
3112 to run if these resources are not installed."
3113    fi
3114    echo
3115 fi
3116
3117 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3118   echo "D-Bus integration has been tested for GNU/Linux only."
3119   echo
3120 fi
3121
3122
3123 # Remove any trailing slashes in these variables.
3124 [test "${prefix}" != NONE &&
3125   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3126 test "${exec_prefix}" != NONE &&
3127   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3128
3129 # Now get this: Some word that is part of the ${srcdir} directory name
3130 # or the ${configuration} value might, just might, happen to be an
3131 # identifier like `sun4' or `i386' or something, and be predefined by
3132 # the C preprocessor to some helpful value like 1, or maybe the empty
3133 # string.  Needless to say consequent macro substitutions are less
3134 # than conducive to the makefile finding the correct directory.
3135 [cpp_undefs="`echo $srcdir $configuration $canonical |
3136   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3137   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3138
3139 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3140 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3141 ## from Makefile.c can correctly provide the arg `-traditional' to the
3142 ## C preprocessor.
3143
3144 AC_EGREP_CPP(yes..yes,
3145         [yes..yes],
3146         CPP_NEED_TRADITIONAL=no,
3147         CPP_NEED_TRADITIONAL=yes)
3148
3149 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3150         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3151         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3152         lwlib/Makefile lisp/Makefile leim/Makefile, [
3153
3154 ### Make the necessary directories, if they don't exist.
3155 for dir in etc lisp ; do
3156   test -d ${dir} || mkdir ${dir}
3157 done
3158
3159 # Build src/Makefile from ${srcdir}/src/Makefile.c
3160 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3161 # This must be done after src/config.h is built, since we rely on that file.
3162
3163 echo creating src/epaths.h
3164 ${MAKE-make} epaths-force
3165
3166 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3167 # `..' to `. .'  unless invoked with -traditional
3168
3169 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3170   CPPFLAGS="$CPPFLAGS -traditional"
3171 fi
3172
3173 echo creating lib-src/Makefile
3174 ( cd lib-src
3175   rm -f junk.c junk1.c junk2.c
3176   sed -e '/start of cpp stuff/q' \
3177       < Makefile.c > junk1.c
3178   sed -e '1,/start of cpp stuff/d'\
3179       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3180       < Makefile.c > junk.c
3181   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3182       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3183   cat junk1.c junk2.c > Makefile.new
3184   rm -f junk.c junk1.c junk2.c
3185   chmod 444 Makefile.new
3186   mv -f Makefile.new Makefile
3187 )
3188
3189 echo creating src/Makefile
3190 ( cd src
3191   rm -f junk.c junk1.c junk2.c
3192   sed -e '/start of cpp stuff/q' \
3193       < Makefile.c > junk1.c
3194   sed -e '1,/start of cpp stuff/d'\
3195       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3196       < Makefile.c > junk.c
3197   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3198       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3199   cat junk1.c junk2.c > Makefile.new
3200   rm -f junk.c junk1.c junk2.c
3201   chmod 444 Makefile.new
3202   mv -f Makefile.new Makefile
3203 )
3204
3205 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3206   echo creating src/.gdbinit
3207   echo source $srcdir/src/.gdbinit > src/.gdbinit
3208 fi
3209
3210 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3211
3212 m4_if(dnl       Do not change this comment
3213    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3214 )dnl