lisp/international/encoded-kb.el

   1 ;;; encoded-kb.el --- handler to input multibyte characters encoded somehow
   2
   3 ;; Copyright (C) 1995 Electrotechnical Laboratory, JAPAN.
   4 ;; Licensed to the Free Software Foundation.
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 ;; Usually this map is empty (even if Encoded-kbd mode is on), but if
  28 ;; the keyboard coding system is iso-2022-based, it defines dummy key
  29 ;; bindings for ESC $ ..., etc. so that those bindings in
  30 ;; key-translation-map take effect.
  31 (defconst encoded-kbd-mode-map (make-sparse-keymap)
  32   "Keymap for Encoded-kbd minor mode.")
  33
  34 ;; Subsidiary keymaps for handling ISO2022 escape sequences.
  35
  36 (defvar encoded-kbd-iso2022-esc-map
  37   (let ((map (make-sparse-keymap)))
  38     (define-key map "$" 'encoded-kbd-iso2022-esc-dollar-prefix)
  39     (define-key map "(" 'encoded-kbd-iso2022-designation-prefix)
  40     (define-key map ")" 'encoded-kbd-iso2022-designation-prefix)
  41     (define-key map "," 'encoded-kbd-iso2022-designation-prefix)
  42     (define-key map "-" 'encoded-kbd-iso2022-designation-prefix)
  43     map)
  44   "Keymap for handling ESC code in Encoded-kbd mode.")
  45 (fset 'encoded-kbd-iso2022-esc-prefix encoded-kbd-iso2022-esc-map)
  46
  47 (defvar encoded-kbd-iso2022-esc-dollar-map
  48   (let ((map (make-sparse-keymap)))
  49     (define-key map "(" 'encoded-kbd-iso2022-designation-prefix)
  50     (define-key map ")" 'encoded-kbd-iso2022-designation-prefix)
  51     (define-key map "," 'encoded-kbd-iso2022-designation-prefix)
  52     (define-key map "-" 'encoded-kbd-iso2022-designation-prefix)
  53     (define-key map "@" 'encoded-kbd-iso2022-designation)
  54     (define-key map "A" 'encoded-kbd-iso2022-designation)
  55     (define-key map "B" 'encoded-kbd-iso2022-designation)
  56     map)
  57   "Keymap for handling ESC $ sequence in Encoded-kbd mode.")
  58 (fset 'encoded-kbd-iso2022-esc-dollar-prefix
  59       encoded-kbd-iso2022-esc-dollar-map)
  60
  61 (defvar encoded-kbd-iso2022-designation-map
  62   (let ((map (make-sparse-keymap))
  63         (l charset-list)
  64         final-char)
  65     (while l
  66       (setq final-char (charset-iso-final-char (car l)))
  67       (if (> final-char 0)
  68           (define-key map (char-to-string final-char)
  69             'encoded-kbd-iso2022-designation))
  70       (setq l (cdr l)))
  71     map)
  72   "Keymap for handling ISO2022 designation sequence in Encoded-kbd mode.")
  73 (fset 'encoded-kbd-iso2022-designation-prefix
  74       encoded-kbd-iso2022-designation-map)
  75
  76 ;; Keep information of designation state of ISO2022 encoding.  When
  77 ;; Encoded-kbd mode is on, this is set to a vector of length 4, the
  78 ;; elements are character sets currently designated to graphic
  79 ;; registers 0 thru 3.
  80
  81 (defvar encoded-kbd-iso2022-designations nil)
  82 (put 'encoded-kbd-iso2022-designations 'permanent-local t)
  83
  84 ;; Keep information of invocation state of ISO2022 encoding.  When
  85 ;; Encoded-kbd mode is on, this is set to a vector of length 3,
  86 ;; graphic register numbers currently invoked to graphic plane 1 and
  87 ;; 2, and a single shifted graphic register number.
  88
  89 (defvar encoded-kbd-iso2022-invocations nil)
  90 (put 'encoded-kbd-iso2022-invocations 'permanent-local t)
  91
  92 (defsubst encoded-kbd-last-key ()
  93   (let ((keys (this-single-command-keys)))
  94     (aref keys (1- (length keys)))))
  95
  96 (defun encoded-kbd-iso2022-designation (ignore)
  97   "Do ISO2022 designation according to the current key in Encoded-kbd mode.
  98 The following key sequence may cause multilingual text insertion."
  99   (let ((key-seq (this-single-command-keys))
 100         (prev-g0-charset (aref encoded-kbd-iso2022-designations
 101                                (aref encoded-kbd-iso2022-invocations 0)))
 102         intermediate-char final-char
 103         reg dimension chars charset)
 104     (if (= (length key-seq) 4)
 105         ;; ESC $ <intermediate-char> <final-char>
 106         (setq intermediate-char (aref key-seq 2)
 107               dimension 2
 108               chars (if (< intermediate-char ?,) 94 96)
 109               final-char (aref key-seq 3)
 110               reg (mod intermediate-char 4))
 111       (if (= (aref key-seq 1) ?$)
 112           ;; ESC $ <final-char>
 113           (setq dimension 2
 114                 chars 94
 115                 final-char (aref key-seq 2)
 116                 reg 0)
 117         ;; ESC <intermediate-char> <final-char>
 118         (setq intermediate-char (aref key-seq 1)
 119               dimension 1
 120               chars (if (< intermediate-char ?,) 94 96)
 121               final-char (aref key-seq 2)
 122               reg (mod intermediate-char 4))))
 123     (aset encoded-kbd-iso2022-designations reg
 124           (iso-charset dimension chars final-char)))
 125   "")
 126
 127 (defun encoded-kbd-iso2022-single-shift (ignore)
 128   (let ((char (encoded-kbd-last-key)))
 129     (aset encoded-kbd-iso2022-invocations 2
 130           (aref encoded-kbd-iso2022-designations
 131                 (if (= char ?\216) 2 3))))
 132   "")
 133
 134 (defun encoded-kbd-self-insert-iso2022-7bit (ignore)
 135   (let ((char (encoded-kbd-last-key))
 136         (charset (aref encoded-kbd-iso2022-designations
 137                        (or (aref encoded-kbd-iso2022-invocations 2)
 138                            (aref encoded-kbd-iso2022-invocations 0)))))
 139     (aset encoded-kbd-iso2022-invocations 2 nil)
 140     (vector (if (= (charset-dimension charset) 1)
 141                 (make-char charset char)
 142               (make-char charset char (read-char-exclusive))))))
 143
 144 (defun encoded-kbd-self-insert-iso2022-8bit (ignore)
 145   (let ((char (encoded-kbd-last-key))
 146         (charset (aref encoded-kbd-iso2022-designations
 147                        (or (aref encoded-kbd-iso2022-invocations 2)
 148                            (aref encoded-kbd-iso2022-invocations 1)))))
 149     (aset encoded-kbd-iso2022-invocations 2 nil)
 150     (vector (if (= (charset-dimension charset) 1)
 151                 (make-char charset char)
 152               (make-char charset char (read-char-exclusive))))))
 153
 154 (defun encoded-kbd-self-insert-sjis (ignore)
 155   (let ((char (encoded-kbd-last-key)))
 156     (vector
 157      (if (or (< char ?\xA0) (>= char ?\xE0))
 158          (decode-sjis-char (+ (ash char 8) (read-char-exclusive)))
 159        (make-char 'katakana-jisx0201 char)))))
 160
 161 (defun encoded-kbd-self-insert-big5 (ignore)
 162   (let ((char (encoded-kbd-last-key)))
 163     (vector
 164      (decode-big5-char (+ (ash char 8) (read-char-exclusive))))))
 165
 166 (defun encoded-kbd-self-insert-ccl (ignore)
 167   (let ((str (char-to-string (encoded-kbd-last-key)))
 168         (ccl (car (aref (coding-system-spec (keyboard-coding-system)) 4)))
 169         (vec [nil nil nil nil nil nil nil nil nil])
 170         result)
 171     (while (= (length (setq result (ccl-execute-on-string ccl vec str t))) 0)
 172       (dotimes (i 9) (aset vec i nil))
 173       (setq str (format "%s%c" str (read-char-exclusive))))
 174     (vector (aref result 0))))
 175
 176 (defun encoded-kbd-setup-keymap (coding)
 177   ;; At first, reset the keymap.
 178   (define-key encoded-kbd-mode-map "\e" nil)
 179   ;; Then setup the keymap according to the keyboard coding system.
 180   (cond
 181    ((eq (coding-system-type coding) 1)  ; SJIS
 182     (let ((i 128))
 183       (while (< i 256)
 184         (define-key key-translation-map
 185           (vector i) 'encoded-kbd-self-insert-sjis)
 186         (setq i (1+ i))))
 187     8)
 188
 189    ((eq (coding-system-type coding) 3)  ; Big5
 190     (let ((i 161))
 191       (while (< i 255)
 192         (define-key key-translation-map
 193           (vector i) 'encoded-kbd-self-insert-big5)
 194         (setq i (1+ i))))
 195     8)
 196
 197    ((eq (coding-system-type coding) 2) ; ISO-2022
 198     (let ((flags (coding-system-flags coding))
 199           use-designation)
 200       (if (aref flags 8)
 201           nil                           ; Don't support locking-shift.
 202         (setq encoded-kbd-iso2022-designations (make-vector 4 nil)
 203               encoded-kbd-iso2022-invocations (make-vector 3 nil))
 204         (dotimes (i 4)
 205           (if (aref flags i)
 206               (if (charsetp (aref flags i))
 207                   (aset encoded-kbd-iso2022-designations
 208                         i (aref flags i))
 209                 (setq use-designation t)
 210                 (if (charsetp (car-safe (aref flags i)))
 211                     (aset encoded-kbd-iso2022-designations
 212                           i (car (aref flags i)))))))
 213         (aset encoded-kbd-iso2022-invocations 0 0)
 214         (if (aref encoded-kbd-iso2022-designations 1)
 215             (aset encoded-kbd-iso2022-invocations 1 1))
 216         (when use-designation
 217           (define-key encoded-kbd-mode-map "\e" 'encoded-kbd-iso2022-esc-prefix)
 218           (define-key key-translation-map "\e" 'encoded-kbd-iso2022-esc-prefix))
 219         (when (or (aref flags 2) (aref flags 3))
 220           (define-key key-translation-map
 221             [?\216] 'encoded-kbd-iso2022-single-shift)
 222           (define-key key-translation-map
 223             [?\217] 'encoded-kbd-iso2022-single-shift))
 224         (or (eq (aref flags 0) 'ascii)
 225             (dotimes (i 96)
 226               (define-key key-translation-map
 227                 (vector (+ 32 i)) 'encoded-kbd-self-insert-iso2022-7bit)))
 228         (if (aref flags 7)
 229             t
 230           (dotimes (i 96)
 231             (define-key key-translation-map
 232               (vector (+ 160 i)) 'encoded-kbd-self-insert-iso2022-8bit))
 233           8))))
 234
 235    ((eq (coding-system-type coding) 4)  ; CCL-base
 236     (let ((valid-codes (or (coding-system-get coding 'valid-codes)
 237                            '((128 . 255))))
 238           elt from to valid)
 239       (while valid-codes
 240         (setq elt (car valid-codes) valid-codes (cdr valid-codes))
 241         (if (consp elt)
 242             (setq from (car elt) to (cdr elt))
 243           (setq from (setq to elt)))
 244         (while (<= from to)
 245           (if (>= from 128)
 246               (define-key key-translation-map
 247                 (vector from) 'encoded-kbd-self-insert-ccl))
 248           (setq from (1+ from))))
 249       8))
 250
 251    (t
 252     nil)))
 253
 254 ;; key-translation-map at the time Encoded-kbd mode is turned on is
 255 ;; saved here.
 256 (defvar saved-key-translation-map nil)
 257
 258 ;; Input mode at the time Encoded-kbd mode is turned on is saved here.
 259 (defvar saved-input-mode nil)
 260
 261 (put 'encoded-kbd-mode 'permanent-local t)
 262 ;;;###autoload
 263 (define-minor-mode encoded-kbd-mode
 264   "Toggle Encoded-kbd minor mode.
 265 With arg, turn Encoded-kbd mode on if and only if arg is positive.
 266
 267 You should not turn this mode on manually, instead use the command
 268 \\[set-keyboard-coding-system] which turns on or off this mode
 269 automatically.
 270
 271 In Encoded-kbd mode, a text sent from keyboard is accepted
 272 as a multilingual text encoded in a coding system set by
 273 \\[set-keyboard-coding-system]."
 274   :global t
 275
 276   (if encoded-kbd-mode
 277       ;; We are turning on Encoded-kbd mode.
 278       (let ((coding (keyboard-coding-system))
 279             result)
 280         (or saved-key-translation-map
 281             (if (keymapp key-translation-map)
 282                 (setq saved-key-translation-map
 283                       (copy-keymap key-translation-map))
 284               (setq key-translation-map (make-sparse-keymap))))
 285         (or saved-input-mode
 286             (setq saved-input-mode
 287                   (current-input-mode)))
 288         (setq result (and coding (encoded-kbd-setup-keymap coding)))
 289         (if result
 290             (if (eq result 8)
 291                 (set-input-mode
 292                  (nth 0 saved-input-mode)
 293                  (nth 1 saved-input-mode)
 294                  'use-8th-bit
 295                  (nth 3 saved-input-mode)))
 296           (setq encoded-kbd-mode nil
 297                 saved-key-translation-map nil
 298                 saved-input-mode nil)
 299           (error "Unsupported coding system in Encoded-kbd mode: %S"
 300                  coding)))
 301
 302     ;; We are turning off Encoded-kbd mode.
 303     (setq key-translation-map saved-key-translation-map
 304           saved-key-translation-map nil)
 305     (apply 'set-input-mode saved-input-mode)
 306     (setq saved-input-mode nil)))
 307
 308 (provide 'encoded-kb)
 309
 310 ;;; arch-tag: 76f0f9b3-65e7-45c3-b692-59509a87ad44
 311 ;;; encoded-kb.el ends here