lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems
   2
   3 ;; Copyright (C) 1993, 1994, 1996, 1997, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar frame-creation-function-alist
  31   (list (cons nil
  32               (if (fboundp 'tty-create-frame-with-faces)
  33                   'tty-create-frame-with-faces
  34                 (lambda (parameters)
  35                   (error "Can't create multiple frames without a window system")))))
  36   "Alist of window-system dependent functions to call to create a new frame.
  37 The window system startup file should add its frame creation
  38 function to this list, which should take an alist of parameters
  39 as its argument.")
  40
  41 (defvar window-system-default-frame-alist nil
  42   "Alist of window-system dependent default frame parameters.
  43 You can set this in your `.emacs' file; for example,
  44
  45     ;; Disable menubar and toolbar on the console, but enable them under X.
  46     (setq window-system-default-frame-alist
  47           '((x (menu-bar-lines . 1) (tool-bar-lines . 1))
  48             (nil (menu-bar-lines . 0) (tool-bar-lines . 0))))
  49
  50 Parameters specified here supersede the values given in `default-frame-alist'.")
  51
  52 ;; The initial value given here used to ask for a minibuffer.
  53 ;; But that's not necessary, because the default is to have one.
  54 ;; By not specifying it here, we let an X resource specify it.
  55 (defcustom initial-frame-alist nil
  56   "*Alist of frame parameters for creating the initial X window frame.
  57 You can set this in your `.emacs' file; for example,
  58  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  59 Parameters specified here supersede the values given in `default-frame-alist'.
  60
  61 If the value calls for a frame without a minibuffer, and you have not created
  62 a minibuffer frame on your own, one is created according to
  63 `minibuffer-frame-alist'.
  64
  65 You can specify geometry-related options for just the initial frame
  66 by setting this variable in your `.emacs' file; however, they won't
  67 take effect until Emacs reads `.emacs', which happens after first creating
  68 the frame.  If you want the frame to have the proper geometry as soon
  69 as it appears, you need to use this three-step process:
  70 * Specify X resources to give the geometry you want.
  71 * Set `default-frame-alist' to override these options so that they
  72   don't affect subsequent frames.
  73 * Set `initial-frame-alist' in a way that matches the X resources,
  74   to override what you put in `default-frame-alist'."
  75   :type '(repeat (cons :format "%v"
  76                        (symbol :tag "Parameter")
  77                        (sexp :tag "Value")))
  78   :group 'frames)
  79
  80 (defcustom minibuffer-frame-alist '((width . 80) (height . 2))
  81   "*Alist of frame parameters for initially creating a minibuffer frame.
  82 You can set this in your `.emacs' file; for example,
  83  (setq minibuffer-frame-alist
  84    '((top . 1) (left . 1) (width . 80) (height . 2)))
  85 Parameters specified here supersede the values given in
  86 `default-frame-alist', for a minibuffer frame."
  87   :type '(repeat (cons :format "%v"
  88                        (symbol :tag "Parameter")
  89                        (sexp :tag "Value")))
  90   :group 'frames)
  91
  92 (defcustom pop-up-frame-alist nil
  93   "*Alist of frame parameters used when creating pop-up frames.
  94 Pop-up frames are used for completions, help, and the like.
  95 This variable can be set in your init file, like this:
  96   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  97 These supersede the values given in `default-frame-alist',
  98 for pop-up frames."
  99   :type '(repeat (cons :format "%v"
 100                        (symbol :tag "Parameter")
 101                        (sexp :tag "Value")))
 102   :group 'frames)
 103
 104 (setq pop-up-frame-function
 105       ;; Using `function' here caused some sort of problem.
 106       '(lambda ()
 107          (make-frame pop-up-frame-alist)))
 108
 109 (defcustom special-display-frame-alist
 110   '((height . 14) (width . 80) (unsplittable . t))
 111   "*Alist of frame parameters used when creating special frames.
 112 Special frames are used for buffers whose names are in
 113 `special-display-buffer-names' and for buffers whose names match
 114 one of the regular expressions in `special-display-regexps'.
 115 This variable can be set in your init file, like this:
 116   (setq special-display-frame-alist '((width . 80) (height . 20)))
 117 These supersede the values given in `default-frame-alist'."
 118   :type '(repeat (cons :format "%v"
 119                          (symbol :tag "Parameter")
 120                          (sexp :tag "Value")))
 121   :group 'frames)
 122
 123 (defun special-display-popup-frame (buffer &optional args)
 124   "Display BUFFER in its own frame, reusing an existing window if any.
 125 Return the window chosen.
 126 Currently we do not insist on selecting the window within its frame.
 127 If ARGS is an alist, use it as a list of frame parameter specs.
 128 If ARGS is a list whose car is a symbol,
 129 use (car ARGS) as a function to do the work.
 130 Pass it BUFFER as first arg, and (cdr ARGS) gives the rest of the args."
 131   (if (and args (symbolp (car args)))
 132       (apply (car args) buffer (cdr args))
 133     (let ((window (get-buffer-window buffer 0)))
 134       (or
 135        ;; If we have a window already, make it visible.
 136        (when window
 137          (let ((frame (window-frame window)))
 138            (make-frame-visible frame)
 139            (raise-frame frame)
 140            window))
 141        ;; Reuse the current window if the user requested it.
 142        (when (cdr (assq 'same-window args))
 143          (condition-case nil
 144              (progn (switch-to-buffer buffer) (selected-window))
 145            (error nil)))
 146        ;; Stay on the same frame if requested.
 147        (when (or (cdr (assq 'same-frame args)) (cdr (assq 'same-window args)))
 148          (let* ((pop-up-frames nil) (pop-up-windows t)
 149                 special-display-regexps special-display-buffer-names
 150                 (window (display-buffer buffer)))
 151            ;; Only do it if this is a new window:
 152            ;; (set-window-dedicated-p window t)
 153            window))
 154        ;; If no window yet, make one in a new frame.
 155        (let ((frame
 156               (with-current-buffer buffer
 157                 (make-frame (append args special-display-frame-alist)))))
 158          (set-window-buffer (frame-selected-window frame) buffer)
 159          (set-window-dedicated-p (frame-selected-window frame) t)
 160          (frame-selected-window frame))))))
 161
 162 (defun handle-delete-frame (event)
 163   "Handle delete-frame events from the X server."
 164   (interactive "e")
 165   (let ((frame (posn-window (event-start event)))
 166         (i 0)
 167         (tail (frame-list)))
 168     (while tail
 169       (and (frame-visible-p (car tail))
 170            (not (eq (car tail) frame))
 171           (setq i (1+ i)))
 172       (setq tail (cdr tail)))
 173     (if (> i 0)
 174         (delete-frame frame t)
 175       ;; Gildea@x.org says it is ok to ask questions before terminating.
 176       (save-buffers-kill-emacs))))
 177 \f
 178 ;;;; Arrangement of frames at startup
 179
 180 ;; 1) Load the window system startup file from the lisp library and read the
 181 ;; high-priority arguments (-q and the like).  The window system startup
 182 ;; file should create any frames specified in the window system defaults.
 183 ;;
 184 ;; 2) If no frames have been opened, we open an initial text frame.
 185 ;;
 186 ;; 3) Once the init file is done, we apply any newly set parameters
 187 ;; in initial-frame-alist to the frame.
 188
 189 ;; These are now called explicitly at the proper times,
 190 ;; since that is easier to understand.
 191 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
 192 ;; (add-hook 'before-init-hook 'frame-initialize)
 193 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
 194
 195 ;; If we create the initial frame, this is it.
 196 (defvar frame-initial-frame nil)
 197
 198 ;; Record the parameters used in frame-initialize to make the initial frame.
 199 (defvar frame-initial-frame-alist)
 200
 201 (defvar frame-initial-geometry-arguments nil)
 202
 203 ;; startup.el calls this function before loading the user's init
 204 ;; file - if there is no frame with a minibuffer open now, create
 205 ;; one to display messages while loading the init file.
 206 (defun frame-initialize ()
 207   "Create an initial frame if necessary."
 208   ;; Are we actually running under a window system at all?
 209   (if (and initial-window-system
 210            (not noninteractive)
 211            (not (eq initial-window-system 'pc)))
 212       (progn
 213         ;; Turn on special-display processing only if there's a window system.
 214         (setq special-display-function 'special-display-popup-frame)
 215
 216         ;; If there is no frame with a minibuffer besides the terminal
 217         ;; frame, then we need to create the opening frame.  Make sure
 218         ;; it has a minibuffer, but let initial-frame-alist omit the
 219         ;; minibuffer spec.
 220         (or (delq terminal-frame (minibuffer-frame-list))
 221             (progn
 222               (setq frame-initial-frame-alist
 223                     (append initial-frame-alist default-frame-alist nil))
 224               (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
 225                   (setq frame-initial-frame-alist
 226                         (cons '(horizontal-scroll-bars . t)
 227                               frame-initial-frame-alist)))
 228               (setq frame-initial-frame-alist
 229                     (cons (cons 'window-system initial-window-system)
 230                           frame-initial-frame-alist))
 231               (setq default-minibuffer-frame
 232                     (setq frame-initial-frame
 233                           (make-frame frame-initial-frame-alist)))
 234               ;; Delete any specifications for window geometry parameters
 235               ;; so that we won't reapply them in frame-notice-user-settings.
 236               ;; It would be wrong to reapply them then,
 237               ;; because that would override explicit user resizing.
 238               (setq initial-frame-alist
 239                     (frame-remove-geometry-params initial-frame-alist))))
 240         ;; Copy the environment of the Emacs process into the new frame.
 241         (set-frame-parameter frame-initial-frame 'environment
 242                              (frame-parameter terminal-frame 'environment))
 243         ;; At this point, we know that we have a frame open, so we
 244         ;; can delete the terminal frame.
 245         (delete-frame terminal-frame)
 246         (setq terminal-frame nil))))
 247
 248 (defvar frame-notice-user-settings t
 249   "Non-nil means function `frame-notice-user-settings' wasn't run yet.")
 250
 251 ;; startup.el calls this function after loading the user's init
 252 ;; file.  Now default-frame-alist and initial-frame-alist contain
 253 ;; information to which we must react; do what needs to be done.
 254 (defun frame-notice-user-settings ()
 255   "Act on user's init file settings of frame parameters.
 256 React to settings of `initial-frame-alist',
 257 `window-system-default-frame-alist' and `default-frame-alist'
 258 there (in decreasing order of priority)."
 259   ;; Make menu-bar-mode and default-frame-alist consistent.
 260   (when (boundp 'menu-bar-mode)
 261     (let ((default (assq 'menu-bar-lines default-frame-alist)))
 262       (if default
 263           (setq menu-bar-mode (not (eq (cdr default) 0)))
 264         (setq default-frame-alist
 265               (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
 266                     default-frame-alist)))))
 267
 268   ;; Make tool-bar-mode and default-frame-alist consistent.  Don't do
 269   ;; it in batch mode since that would leave a tool-bar-lines
 270   ;; parameter in default-frame-alist in a dumped Emacs, which is not
 271   ;; what we want.
 272   (when (and (boundp 'tool-bar-mode)
 273              (not noninteractive))
 274     (let ((default (assq 'tool-bar-lines default-frame-alist)))
 275       (if default
 276           (setq tool-bar-mode (not (eq (cdr default) 0)))
 277         ;; If Emacs was started on a tty, changing default-frame-alist
 278         ;; would disable the toolbar on X frames created later.  We
 279         ;; want to keep the default of showing a toolbar under X even
 280         ;; in this case.
 281         ;;
 282         ;; If the user explicitly called `tool-bar-mode' in .emacs,
 283         ;; then default-frame-alist is already changed anyway.
 284         (when initial-window-system
 285           (setq default-frame-alist
 286                 (cons (cons 'tool-bar-lines (if tool-bar-mode 1 0))
 287                       default-frame-alist))))))
 288
 289   ;; Creating and deleting frames may shift the selected frame around,
 290   ;; and thus the current buffer.  Protect against that.  We don't
 291   ;; want to use save-excursion here, because that may also try to set
 292   ;; the buffer of the selected window, which fails when the selected
 293   ;; window is the minibuffer.
 294   (let ((old-buffer (current-buffer))
 295         (window-system-frame-alist
 296          (cdr (assq initial-window-system
 297                     window-system-default-frame-alist))))
 298
 299     (when (and frame-notice-user-settings
 300                (null frame-initial-frame))
 301       ;; This case happens when we don't have a window system, and
 302       ;; also for MS-DOS frames.
 303       (let ((parms (frame-parameters frame-initial-frame)))
 304         ;; Don't change the frame names.
 305         (setq parms (delq (assq 'name parms) parms))
 306         ;; Can't modify the minibuffer parameter, so don't try.
 307         (setq parms (delq (assq 'minibuffer parms) parms))
 308         (modify-frame-parameters nil
 309                                  (if (null initial-window-system)
 310                                      (append initial-frame-alist
 311                                              window-system-frame-alist
 312                                              default-frame-alist
 313                                              parms
 314                                              nil)
 315                                    ;; initial-frame-alist and
 316                                    ;; default-frame-alist were already
 317                                    ;; applied in pc-win.el.
 318                                    parms))
 319         (if (null initial-window-system) ;; MS-DOS does this differently in pc-win.el
 320             (let ((newparms (frame-parameters))
 321                   (frame (selected-frame)))
 322               (tty-handle-reverse-video frame newparms)
 323               ;; If we changed the background color, we need to update
 324               ;; the background-mode parameter, and maybe some faces,
 325               ;; too.
 326               (when (assq 'background-color newparms)
 327                 (unless (or (assq 'background-mode initial-frame-alist)
 328                             (assq 'background-mode default-frame-alist))
 329                   (frame-set-background-mode frame))
 330                 (face-set-after-frame-default frame))))))
 331
 332     ;; If the initial frame is still around, apply initial-frame-alist
 333     ;; and default-frame-alist to it.
 334     (when (frame-live-p frame-initial-frame)
 335
 336       ;; When tool-bar has been switched off, correct the frame size
 337       ;; by the lines added in x-create-frame for the tool-bar and
 338       ;; switch `tool-bar-mode' off.
 339       (when (display-graphic-p)
 340         (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 341                                   (assq 'tool-bar-lines window-system-frame-alist)
 342                                   (assq 'tool-bar-lines default-frame-alist))))
 343           (when (and tool-bar-originally-present
 344                      (or (null tool-bar-lines)
 345                          (null (cdr tool-bar-lines))
 346                          (eq 0 (cdr tool-bar-lines))))
 347             (let* ((char-height (frame-char-height frame-initial-frame))
 348                    (image-height tool-bar-images-pixel-height)
 349                    (margin (cond ((and (consp tool-bar-button-margin)
 350                                        (integerp (cdr tool-bar-button-margin))
 351                                        (> tool-bar-button-margin 0))
 352                                   (cdr tool-bar-button-margin))
 353                                  ((and (integerp tool-bar-button-margin)
 354                                        (> tool-bar-button-margin 0))
 355                                   tool-bar-button-margin)
 356                                  (t 0)))
 357                    (relief (if (and (integerp tool-bar-button-relief)
 358                                     (> tool-bar-button-relief 0))
 359                                tool-bar-button-relief 3))
 360                    (lines (/ (+ image-height
 361                                 (* 2 margin)
 362                                 (* 2 relief)
 363                                 (1- char-height))
 364                              char-height))
 365                    (height (frame-parameter frame-initial-frame 'height))
 366                    (newparms (list (cons 'height (- height lines))))
 367                    (initial-top (cdr (assq 'top
 368                                            frame-initial-geometry-arguments)))
 369                    (top (frame-parameter frame-initial-frame 'top)))
 370               (when (and (consp initial-top) (eq '- (car initial-top)))
 371                 (let ((adjusted-top
 372                        (cond ((and (consp top)
 373                                    (eq '+ (car top)))
 374                               (list '+
 375                                     (+ (cadr top)
 376                                        (* lines char-height))))
 377                              ((and (consp top)
 378                                    (eq '- (car top)))
 379                               (list '-
 380                                     (- (cadr top)
 381                                        (* lines char-height))))
 382                              (t (+ top (* lines char-height))))))
 383                   (setq newparms
 384                         (append newparms
 385                                 `((top . ,adjusted-top))
 386                                 nil))))
 387               (modify-frame-parameters frame-initial-frame newparms)
 388               (tool-bar-mode -1)))))
 389
 390       ;; The initial frame we create above always has a minibuffer.
 391       ;; If the user wants to remove it, or make it a minibuffer-only
 392       ;; frame, then we'll have to delete the current frame and make a
 393       ;; new one; you can't remove or add a root window to/from an
 394       ;; existing frame.
 395       ;;
 396       ;; NOTE: default-frame-alist was nil when we created the
 397       ;; existing frame.  We need to explicitly include
 398       ;; default-frame-alist in the parameters of the screen we
 399       ;; create here, so that its new value, gleaned from the user's
 400       ;; .emacs file, will be applied to the existing screen.
 401       (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 402                             (assq 'minibuffer window-system-frame-alist)
 403                             (assq 'minibuffer default-frame-alist)
 404                             '(minibuffer . t)))
 405                    t))
 406           ;; Create the new frame.
 407           (let (parms new)
 408             ;; If the frame isn't visible yet, wait till it is.
 409             ;; If the user has to position the window,
 410             ;; Emacs doesn't know its real position until
 411             ;; the frame is seen to be visible.
 412             (while (not (cdr (assq 'visibility
 413                                    (frame-parameters frame-initial-frame))))
 414               (sleep-for 1))
 415             (setq parms (frame-parameters frame-initial-frame))
 416
 417             ;; Get rid of `name' unless it was specified explicitly before.
 418             (or (assq 'name frame-initial-frame-alist)
 419                 (setq parms (delq (assq 'name parms) parms)))
 420
 421             (setq parms (append initial-frame-alist
 422                                 window-system-frame-alist
 423                                 default-frame-alist
 424                                 parms
 425                                 nil))
 426
 427             ;; Get rid of `reverse', because that was handled
 428             ;; when we first made the frame.
 429             (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))
 430
 431             (if (assq 'height frame-initial-geometry-arguments)
 432                 (setq parms (assq-delete-all 'height parms)))
 433             (if (assq 'width frame-initial-geometry-arguments)
 434                 (setq parms (assq-delete-all 'width parms)))
 435             (if (assq 'left frame-initial-geometry-arguments)
 436                 (setq parms (assq-delete-all 'left parms)))
 437             (if (assq 'top frame-initial-geometry-arguments)
 438                 (setq parms (assq-delete-all 'top parms)))
 439             (setq new
 440                   (make-frame
 441                    ;; Use the geometry args that created the existing
 442                    ;; frame, rather than the parms we get for it.
 443                    (append frame-initial-geometry-arguments
 444                            '((user-size . t) (user-position . t))
 445                            parms)))
 446             ;; The initial frame, which we are about to delete, may be
 447             ;; the only frame with a minibuffer.  If it is, create a
 448             ;; new one.
 449             (or (delq frame-initial-frame (minibuffer-frame-list))
 450                 (make-initial-minibuffer-frame nil))
 451
 452             ;; If the initial frame is serving as a surrogate
 453             ;; minibuffer frame for any frames, we need to wean them
 454             ;; onto a new frame.  The default-minibuffer-frame
 455             ;; variable must be handled similarly.
 456             (let ((users-of-initial
 457                    (filtered-frame-list
 458                     (lambda (frame)
 459                       (and (not (eq frame frame-initial-frame))
 460                            (eq (window-frame
 461                                 (minibuffer-window frame))
 462                                frame-initial-frame))))))
 463               (if (or users-of-initial
 464                       (eq default-minibuffer-frame frame-initial-frame))
 465
 466                   ;; Choose an appropriate frame.  Prefer frames which
 467                   ;; are only minibuffers.
 468                   (let* ((new-surrogate
 469                           (car
 470                            (or (filtered-frame-list
 471                                 (lambda (frame)
 472                                   (eq (cdr (assq 'minibuffer
 473                                                  (frame-parameters frame)))
 474                                       'only)))
 475                                (minibuffer-frame-list))))
 476                          (new-minibuffer (minibuffer-window new-surrogate)))
 477
 478                     (if (eq default-minibuffer-frame frame-initial-frame)
 479                         (setq default-minibuffer-frame new-surrogate))
 480
 481                     ;; Wean the frames using frame-initial-frame as
 482                     ;; their minibuffer frame.
 483                     (dolist (frame users-of-initial)
 484                       (modify-frame-parameters
 485                        frame (list (cons 'minibuffer new-minibuffer)))))))
 486
 487             ;; Redirect events enqueued at this frame to the new frame.
 488             ;; Is this a good idea?
 489             (redirect-frame-focus frame-initial-frame new)
 490
 491             ;; Finally, get rid of the old frame.
 492             (delete-frame frame-initial-frame t))
 493
 494         ;; Otherwise, we don't need all that rigamarole; just apply
 495         ;; the new parameters.
 496         (let (newparms allparms tail)
 497           (setq allparms (append initial-frame-alist
 498                                  window-system-frame-alist
 499                                  default-frame-alist nil))
 500           (if (assq 'height frame-initial-geometry-arguments)
 501               (setq allparms (assq-delete-all 'height allparms)))
 502           (if (assq 'width frame-initial-geometry-arguments)
 503               (setq allparms (assq-delete-all 'width allparms)))
 504           (if (assq 'left frame-initial-geometry-arguments)
 505               (setq allparms (assq-delete-all 'left allparms)))
 506           (if (assq 'top frame-initial-geometry-arguments)
 507               (setq allparms (assq-delete-all 'top allparms)))
 508           (setq tail allparms)
 509           ;; Find just the parms that have changed since we first
 510           ;; made this frame.  Those are the ones actually set by
 511           ;; the init file.  For those parms whose values we already knew
 512           ;; (such as those spec'd by command line options)
 513           ;; it is undesirable to specify the parm again
 514           ;; once the user has seen the frame and been able to alter it
 515           ;; manually.
 516           (while tail
 517             (let (newval oldval)
 518               (setq oldval (assq (car (car tail))
 519                                  frame-initial-frame-alist))
 520               (setq newval (cdr (assq (car (car tail)) allparms)))
 521               (or (and oldval (eq (cdr oldval) newval))
 522                   (setq newparms
 523                         (cons (cons (car (car tail)) newval) newparms))))
 524             (setq tail (cdr tail)))
 525           (setq newparms (nreverse newparms))
 526           (modify-frame-parameters frame-initial-frame
 527                                    newparms)
 528           ;; If we changed the background color,
 529           ;; we need to update the background-mode parameter
 530           ;; and maybe some faces too.
 531           (when (assq 'background-color newparms)
 532             (unless (assq 'background-mode newparms)
 533               (frame-set-background-mode frame-initial-frame))
 534             (face-set-after-frame-default frame-initial-frame)))))
 535
 536     ;; Restore the original buffer.
 537     (set-buffer old-buffer)
 538
 539     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 540     ;; Make sure frame-notice-user-settings does nothing if called twice.
 541     (setq frame-notice-user-settings nil)
 542     (setq frame-initial-frame nil)))
 543
 544 (defun make-initial-minibuffer-frame (display)
 545   (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
 546     (if display
 547         (make-frame-on-display display parms)
 548       (make-frame parms))))
 549
 550 ;;;; Creation of additional frames, and other frame miscellanea
 551
 552 (defun modify-all-frames-parameters (alist)
 553   "Modify all current and future frames' parameters according to ALIST.
 554 This changes `default-frame-alist' and possibly `initial-frame-alist'.
 555 Furthermore, this function removes all parameters in ALIST from
 556 `window-system-default-frame-alist'.
 557 See help of `modify-frame-parameters' for more information."
 558   (dolist (frame (frame-list))
 559     (modify-frame-parameters frame alist))
 560
 561   (dolist (pair alist) ;; conses to add/replace
 562     ;; initial-frame-alist needs setting only when
 563     ;; frame-notice-user-settings is true.
 564     (and frame-notice-user-settings
 565          (setq initial-frame-alist
 566                (assq-delete-all (car pair) initial-frame-alist)))
 567     (setq default-frame-alist
 568           (assq-delete-all (car pair) default-frame-alist))
 569     ;; Remove any similar settings from the window-system specific
 570     ;; parameters---they would override default-frame-alist.
 571     (dolist (w window-system-default-frame-alist)
 572       (setcdr w (assq-delete-all (car pair) (cdr w)))))
 573
 574   (and frame-notice-user-settings
 575        (setq initial-frame-alist (append initial-frame-alist alist)))
 576   (setq default-frame-alist (append default-frame-alist alist)))
 577
 578 (defun get-other-frame ()
 579   "Return some frame other than the current frame.
 580 Create one if necessary.  Note that the minibuffer frame, if separate,
 581 is not considered (see `next-frame')."
 582   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 583                (make-frame)
 584              (next-frame (selected-frame)))))
 585     s))
 586
 587 (defun next-multiframe-window ()
 588   "Select the next window, regardless of which frame it is on."
 589   (interactive)
 590   (select-window (next-window (selected-window)
 591                               (> (minibuffer-depth) 0)
 592                               0))
 593   (select-frame-set-input-focus (selected-frame)))
 594
 595 (defun previous-multiframe-window ()
 596   "Select the previous window, regardless of which frame it is on."
 597   (interactive)
 598   (select-window (previous-window (selected-window)
 599                                   (> (minibuffer-depth) 0)
 600                                   0))
 601   (select-frame-set-input-focus (selected-frame)))
 602
 603 (declare-function x-initialize-window-system "term/x-win" ())
 604
 605 (defun make-frame-on-display (display &optional parameters)
 606   "Make a frame on X display DISPLAY.
 607 The optional second argument PARAMETERS specifies additional frame parameters."
 608   (interactive "sMake frame on display: ")
 609   (or (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
 610       (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
 611   (when (and (boundp 'x-initialized) (not x-initialized))
 612     (setq x-display-name display)
 613     (x-initialize-window-system))
 614   (make-frame `((window-system . x) (display . ,display) . ,parameters)))
 615
 616 (defun make-frame-on-tty (tty type &optional parameters)
 617   "Make a frame on terminal device TTY.
 618 TTY should be the file name of the tty device to use.  TYPE
 619 should be the terminal type string of TTY, for example \"xterm\"
 620 or \"vt100\".  The optional third argument PARAMETERS specifies
 621 additional frame parameters."
 622   (interactive "fOpen frame on tty device: \nsTerminal type of %s: ")
 623   (unless tty
 624     (error "Invalid terminal device"))
 625   (unless type
 626     (error "Invalid terminal type"))
 627   (make-frame `((window-system . nil) (tty . ,tty) (tty-type . ,type) . ,parameters)))
 628
 629 (defun close-display-connection (display)
 630   "Close the connection to a display, deleting all its associated frames.
 631 For DISPLAY, specify either a frame or a display name (a string).
 632 If DISPLAY is nil, that stands for the selected frame's display."
 633   (interactive
 634    (list
 635     (let* ((default (frame-parameter nil 'display))
 636            (display (completing-read
 637                      (format "Close display (default %s): " default)
 638                      (delete-dups
 639                       (mapcar (lambda (frame)
 640                                 (frame-parameter frame 'display))
 641                               (frame-list)))
 642                      nil t nil nil
 643                      default)))
 644       (if (zerop (length display)) default display))))
 645   (let ((frames (delq nil
 646                       (mapcar (lambda (frame)
 647                                 (if (equal display
 648                                            (frame-parameter frame 'display))
 649                                     frame))
 650                               (frame-list)))))
 651     (if (and (consp frames)
 652              (not (y-or-n-p (if (cdr frames)
 653                                 (format "Delete %s frames? " (length frames))
 654                               (format "Delete %s ? " (car frames))))))
 655         (error "Abort!")
 656       (mapc 'delete-frame frames)
 657       (x-close-connection display))))
 658
 659 (defun make-frame-command ()
 660   "Make a new frame, and select it if the terminal displays only one frame."
 661   (interactive)
 662   (if (and window-system (not (eq window-system 'pc)))
 663       (make-frame)
 664     (select-frame (make-frame))))
 665
 666 (defvar before-make-frame-hook nil
 667   "Functions to run before a frame is created.")
 668
 669 (defvar after-make-frame-functions nil
 670   "Functions to run after a frame is created.
 671 The functions are run with one arg, the newly created frame.")
 672
 673 (defvar after-setting-font-hook nil
 674   "Functions to run after a frame's font has been changed.")
 675
 676 ;; Alias, kept temporarily.
 677 (define-obsolete-function-alias 'new-frame 'make-frame "22.1")
 678
 679 (defvar frame-inherited-parameters '()
 680   ;; FIXME: Shouldn't we add `font' here as well?
 681   "Parameters `make-frame' copies from the `selected-frame' to the new frame.")
 682
 683 (defun make-frame (&optional parameters)
 684   "Return a newly created frame displaying the current buffer.
 685 Optional argument PARAMETERS is an alist of parameters for the new frame.
 686 Each element of PARAMETERS should have the form (NAME . VALUE), for example:
 687
 688  (name . STRING)        The frame should be named STRING.
 689
 690  (width . NUMBER)       The frame should be NUMBER characters in width.
 691  (height . NUMBER)      The frame should be NUMBER text lines high.
 692
 693 You cannot specify either `width' or `height', you must use neither or both.
 694
 695  (minibuffer . t)       The frame should have a minibuffer.
 696  (minibuffer . nil)     The frame should have no minibuffer.
 697  (minibuffer . only)    The frame should contain only a minibuffer.
 698  (minibuffer . WINDOW)  The frame should use WINDOW as its minibuffer window.
 699
 700  (window-system . nil)  The frame should be displayed on a terminal device.
 701  (window-system . x)    The frame should be displayed in an X window.
 702
 703  (terminal . ID)          The frame should use the terminal identified by ID.
 704
 705 Before the frame is created (via `frame-creation-function-alist'), functions on the
 706 hook `before-make-frame-hook' are run.  After the frame is created, functions
 707 on `after-make-frame-functions' are run with one arg, the newly created frame.
 708
 709 This function itself does not make the new frame the selected frame.
 710 The previously selected frame remains selected.  However, the
 711 window system may select the new frame for its own reasons, for
 712 instance if the frame appears under the mouse pointer and your
 713 setup is for focus to follow the pointer."
 714   (interactive)
 715   (let* ((w (cond
 716              ((assq 'terminal parameters)
 717               (let ((type (terminal-live-p (cdr (assq 'terminal parameters)))))
 718                 (cond
 719                  ((eq type t) nil)
 720                  ((eq type nil) (error "Terminal %s does not exist"
 721                                        (cdr (assq 'terminal parameters))))
 722                  (t type))))
 723              ((assq 'window-system parameters)
 724               (cdr (assq 'window-system parameters)))
 725              (t window-system)))
 726          (frame-creation-function (cdr (assq w frame-creation-function-alist)))
 727          (oldframe (selected-frame))
 728          frame)
 729     (unless frame-creation-function
 730       (error "Don't know how to create a frame on window system %s" w))
 731     (run-hooks 'before-make-frame-hook)
 732     (setq frame
 733           (funcall frame-creation-function
 734                    (append parameters
 735                            (cdr (assq w window-system-default-frame-alist)))))
 736     (normal-erase-is-backspace-setup-frame frame)
 737     ;; Inherit the original frame's parameters.
 738     (dolist (param frame-inherited-parameters)
 739       (unless (assq param parameters)   ;Overridden by explicit parameters.
 740         (let ((val (frame-parameter oldframe param)))
 741           (when val (set-frame-parameter frame param val)))))
 742     (run-hook-with-args 'after-make-frame-functions frame)
 743     frame))
 744
 745 (defun filtered-frame-list (predicate)
 746   "Return a list of all live frames which satisfy PREDICATE."
 747   (let* ((frames (frame-list))
 748          (list frames))
 749     (while (consp frames)
 750       (unless (funcall predicate (car frames))
 751         (setcar frames nil))
 752       (setq frames (cdr frames)))
 753     (delq nil list)))
 754
 755 (defun minibuffer-frame-list ()
 756   "Return a list of all frames with their own minibuffers."
 757   (filtered-frame-list
 758    (lambda (frame)
 759      (eq frame (window-frame (minibuffer-window frame))))))
 760
 761 ;; Used to be called `terminal-id' in termdev.el.
 762 (defun get-device-terminal (device)
 763   "Return the terminal corresponding to DEVICE.
 764 DEVICE can be a terminal, a frame, nil (meaning the selected frame's terminal),
 765 the name of an X display device (HOST.SERVER.SCREEN) or a tty device file."
 766   (cond
 767    ((or (null device) (framep device))
 768     (frame-terminal device))
 769    ((stringp device)
 770     (let ((f (car (filtered-frame-list
 771                    (lambda (frame)
 772                      (or (equal (frame-parameter frame 'display) device)
 773                          (equal (frame-parameter frame 'tty) device)))))))
 774       (or f (error "Display %s does not exist" device))
 775       (frame-terminal f)))
 776    ((terminal-live-p device) device)
 777    (t
 778     (error "Invalid argument %s in `get-device-terminal'" device))))
 779
 780 (defun frames-on-display-list (&optional device)
 781   "Return a list of all frames on DEVICE.
 782
 783 DEVICE should be a terminal, a frame,
 784 or a name of an X display or tty (a string of the form
 785 HOST:SERVER.SCREEN).
 786
 787 If DEVICE is omitted or nil, it defaults to the selected
 788 frame's terminal device."
 789   (let* ((terminal (get-device-terminal device))
 790          (func #'(lambda (frame)
 791                    (eq (frame-terminal frame) terminal))))
 792     (filtered-frame-list func)))
 793
 794 (defun framep-on-display (&optional terminal)
 795   "Return the type of frames on TERMINAL.
 796 TERMINAL may be a terminal id, a display name or a frame.  If it
 797 is a frame, its type is returned.  If TERMINAL is omitted or nil,
 798 it defaults to the selected frame's terminal device.  All frames
 799 on a given display are of the same type."
 800   (or (terminal-live-p terminal)
 801       (framep terminal)
 802       (framep (car (frames-on-display-list terminal)))))
 803
 804 (defun frame-remove-geometry-params (param-list)
 805   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 806 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 807 `height', `user-size' and `user-position' parameters.
 808 Emacs uses this to avoid overriding explicit moves and resizings from
 809 the user during startup."
 810   (setq param-list (cons nil param-list))
 811   (let ((tail param-list))
 812     (while (consp (cdr tail))
 813       (if (and (consp (car (cdr tail)))
 814                (memq (car (car (cdr tail)))
 815                      '(height width top left user-position user-size)))
 816           (progn
 817             (setq frame-initial-geometry-arguments
 818                   (cons (car (cdr tail)) frame-initial-geometry-arguments))
 819             (setcdr tail (cdr (cdr tail))))
 820         (setq tail (cdr tail)))))
 821   (setq frame-initial-geometry-arguments
 822         (nreverse frame-initial-geometry-arguments))
 823   (cdr param-list))
 824
 825 (defun select-frame-set-input-focus (frame)
 826   "Select FRAME, raise it, and set input focus, if possible."
 827     (select-frame frame)
 828     (raise-frame frame)
 829     ;; Ensure, if possible, that frame gets input focus.
 830     (when (memq (window-system frame) '(x mac w32))
 831       (x-focus-frame frame))
 832     (when focus-follows-mouse
 833       (set-mouse-position (selected-frame) (1- (frame-width)) 0)))
 834
 835 (defun other-frame (arg)
 836   "Select the ARGth different visible frame on current display, and raise it.
 837 All frames are arranged in a cyclic order.
 838 This command selects the frame ARG steps away in that order.
 839 A negative ARG moves in the opposite order.
 840
 841 To make this command work properly, you must tell Emacs
 842 how the system (or the window manager) generally handles
 843 focus-switching between windows.  If moving the mouse onto a window
 844 selects it (gives it focus), set `focus-follows-mouse' to t.
 845 Otherwise, that variable should be nil."
 846   (interactive "p")
 847   (let ((frame (selected-frame)))
 848     (while (> arg 0)
 849       (setq frame (next-frame frame))
 850       (while (not (eq (frame-visible-p frame) t))
 851         (setq frame (next-frame frame)))
 852       (setq arg (1- arg)))
 853     (while (< arg 0)
 854       (setq frame (previous-frame frame))
 855       (while (not (eq (frame-visible-p frame) t))
 856         (setq frame (previous-frame frame)))
 857       (setq arg (1+ arg)))
 858     (select-frame-set-input-focus frame)))
 859
 860 (defun iconify-or-deiconify-frame ()
 861   "Iconify the selected frame, or deiconify if it's currently an icon."
 862   (interactive)
 863   (if (eq (cdr (assq 'visibility (frame-parameters))) t)
 864       (iconify-frame)
 865     (make-frame-visible)))
 866
 867 (defun suspend-frame ()
 868   "Do whatever is right to suspend the current frame.
 869 Calls `suspend-emacs' if invoked from the controlling tty device,
 870 `suspend-tty' from a secondary tty device, and
 871 `iconify-or-deiconify-frame' from an X frame."
 872   (interactive)
 873   (let ((type (framep (selected-frame))))
 874     (cond
 875      ((memq type '(x w32)) (iconify-or-deiconify-frame))
 876      ((eq type t)
 877       (if (controlling-tty-p)
 878           (suspend-emacs)
 879         (suspend-tty)))
 880      (t (suspend-emacs)))))
 881
 882 (defun make-frame-names-alist ()
 883   (let* ((current-frame (selected-frame))
 884          (falist
 885           (cons
 886            (cons (frame-parameter current-frame 'name) current-frame) nil))
 887          (frame (next-frame nil t)))
 888     (while (not (eq frame current-frame))
 889       (progn
 890         (setq falist (cons (cons (frame-parameter frame 'name) frame) falist))
 891         (setq frame (next-frame frame t))))
 892     falist))
 893
 894 (defvar frame-name-history nil)
 895 (defun select-frame-by-name (name)
 896   "Select the frame on the current terminal whose name is NAME and raise it.
 897 If there is no frame by that name, signal an error."
 898   (interactive
 899    (let* ((frame-names-alist (make-frame-names-alist))
 900            (default (car (car frame-names-alist)))
 901            (input (completing-read
 902                    (format "Select Frame (default %s): " default)
 903                    frame-names-alist nil t nil 'frame-name-history)))
 904      (if (= (length input) 0)
 905          (list default)
 906        (list input))))
 907   (let* ((frame-names-alist (make-frame-names-alist))
 908          (frame (cdr (assoc name frame-names-alist))))
 909     (or frame
 910         (error "There is no frame named `%s'" name))
 911     (make-frame-visible frame)
 912     (raise-frame frame)
 913     (select-frame frame)
 914     ;; Ensure, if possible, that frame gets input focus.
 915     (cond ((memq (window-system frame) '(x w32))
 916            (x-focus-frame frame)))
 917     (when focus-follows-mouse
 918       (set-mouse-position frame (1- (frame-width frame)) 0))))
 919 \f
 920 ;;;; Frame configurations
 921
 922 (defun current-frame-configuration ()
 923   "Return a list describing the positions and states of all frames.
 924 Its car is `frame-configuration'.
 925 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 926 where
 927   FRAME is a frame object,
 928   ALIST is an association list specifying some of FRAME's parameters, and
 929   WINDOW-CONFIG is a window configuration object for FRAME."
 930   (cons 'frame-configuration
 931         (mapcar (lambda (frame)
 932                   (list frame
 933                         (frame-parameters frame)
 934                         (current-window-configuration frame)))
 935                 (frame-list))))
 936
 937 (defun set-frame-configuration (configuration &optional nodelete)
 938   "Restore the frames to the state described by CONFIGURATION.
 939 Each frame listed in CONFIGURATION has its position, size, window
 940 configuration, and other parameters set as specified in CONFIGURATION.
 941 However, this function does not restore deleted frames.
 942
 943 Ordinarily, this function deletes all existing frames not
 944 listed in CONFIGURATION.  But if optional second argument NODELETE
 945 is given and non-nil, the unwanted frames are iconified instead."
 946   (or (frame-configuration-p configuration)
 947       (signal 'wrong-type-argument
 948               (list 'frame-configuration-p configuration)))
 949   (let ((config-alist (cdr configuration))
 950         frames-to-delete)
 951     (dolist (frame (frame-list))
 952       (let ((parameters (assq frame config-alist)))
 953         (if parameters
 954             (progn
 955               (modify-frame-parameters
 956                frame
 957                ;; Since we can't set a frame's minibuffer status,
 958                ;; we might as well omit the parameter altogether.
 959                (let* ((parms (nth 1 parameters))
 960                       (mini (assq 'minibuffer parms))
 961                       (name (assq 'name parms))
 962                       (explicit-name (cdr (assq 'explicit-name parms))))
 963                  (when mini (setq parms (delq mini parms)))
 964                  ;; Leave name in iff it was set explicitly.
 965                  ;; This should fix the behavior reported in
 966                  ;; http://lists.gnu.org/archive/html/emacs-devel/2007-08/msg01632.html
 967                  (when (and name (not explicit-name))
 968                    (setq parms (delq name parms)))
 969                  parms))
 970               (set-window-configuration (nth 2 parameters)))
 971           (setq frames-to-delete (cons frame frames-to-delete)))))
 972     (mapc (if nodelete
 973               ;; Note: making frames invisible here was tried
 974               ;; but led to some strange behavior--each time the frame
 975               ;; was made visible again, the window manager asked afresh
 976               ;; for where to put it.
 977               'iconify-frame
 978             'delete-frame)
 979           frames-to-delete)))
 980 \f
 981 ;;;; Convenience functions for accessing and interactively changing
 982 ;;;; frame parameters.
 983
 984 (defun frame-height (&optional frame)
 985   "Return number of lines available for display on FRAME.
 986 If FRAME is omitted, describe the currently selected frame."
 987   (cdr (assq 'height (frame-parameters frame))))
 988
 989 (defun frame-width (&optional frame)
 990   "Return number of columns available for display on FRAME.
 991 If FRAME is omitted, describe the currently selected frame."
 992   (cdr (assq 'width (frame-parameters frame))))
 993
 994 (defalias 'set-default-font 'set-frame-font)
 995 (defun set-frame-font (font-name &optional keep-size)
 996   "Set the font of the selected frame to FONT-NAME.
 997 When called interactively, prompt for the name of the font to use.
 998 To get the frame's current default font, use `frame-parameters'.
 999
1000 The default behavior is to keep the numbers of lines and columns in
1001 the frame, thus may change its pixel size.  If optional KEEP-SIZE is
1002 non-nil (interactively, prefix argument) the current frame size (in
1003 pixels) is kept by adjusting the numbers of the lines and columns."
1004   (interactive
1005    (let* ((completion-ignore-case t)
1006           (font (completing-read "Font name: "
1007                                  ;; x-list-fonts will fail with an error
1008                                  ;; if this frame doesn't support fonts.
1009                                  (x-list-fonts "*" nil (selected-frame))
1010                                  nil nil nil nil
1011                                  (frame-parameter nil 'font))))
1012      (list font current-prefix-arg)))
1013   (let (fht fwd)
1014     (if keep-size
1015         (setq fht (* (frame-parameter nil 'height) (frame-char-height))
1016               fwd (* (frame-parameter nil 'width)  (frame-char-width))))
1017     (modify-frame-parameters (selected-frame)
1018                              (list (cons 'font font-name)))
1019     (if keep-size
1020         (modify-frame-parameters
1021          (selected-frame)
1022          (list (cons 'height (round fht (frame-char-height)))
1023                (cons 'width (round fwd (frame-char-width)))))))
1024   (run-hooks 'after-setting-font-hook 'after-setting-font-hooks))
1025
1026 (defun set-frame-parameter (frame parameter value)
1027   "Set frame parameter PARAMETER to VALUE on FRAME.
1028 If FRAME is nil, it defaults to the selected frame.
1029 See `modify-frame-parameters'."
1030   (modify-frame-parameters frame (list (cons parameter value))))
1031
1032 (defun set-background-color (color-name)
1033   "Set the background color of the selected frame to COLOR-NAME.
1034 When called interactively, prompt for the name of the color to use.
1035 To get the frame's current background color, use `frame-parameters'."
1036   (interactive (list (facemenu-read-color "Background color: ")))
1037   (modify-frame-parameters (selected-frame)
1038                            (list (cons 'background-color color-name)))
1039   (or window-system
1040       (face-set-after-frame-default (selected-frame))))
1041
1042 (defun set-foreground-color (color-name)
1043   "Set the foreground color of the selected frame to COLOR-NAME.
1044 When called interactively, prompt for the name of the color to use.
1045 To get the frame's current foreground color, use `frame-parameters'."
1046   (interactive (list (facemenu-read-color "Foreground color: ")))
1047   (modify-frame-parameters (selected-frame)
1048                            (list (cons 'foreground-color color-name)))
1049   (or window-system
1050       (face-set-after-frame-default (selected-frame))))
1051
1052 (defun set-cursor-color (color-name)
1053   "Set the text cursor color of the selected frame to COLOR-NAME.
1054 When called interactively, prompt for the name of the color to use.
1055 To get the frame's current cursor color, use `frame-parameters'."
1056   (interactive (list (facemenu-read-color "Cursor color: ")))
1057   (modify-frame-parameters (selected-frame)
1058                            (list (cons 'cursor-color color-name))))
1059
1060 (defun set-mouse-color (color-name)
1061   "Set the color of the mouse pointer of the selected frame to COLOR-NAME.
1062 When called interactively, prompt for the name of the color to use.
1063 To get the frame's current mouse color, use `frame-parameters'."
1064   (interactive (list (facemenu-read-color "Mouse color: ")))
1065   (modify-frame-parameters (selected-frame)
1066                            (list (cons 'mouse-color
1067                                        (or color-name
1068                                            (cdr (assq 'mouse-color
1069                                                       (frame-parameters))))))))
1070
1071 (defun set-border-color (color-name)
1072   "Set the color of the border of the selected frame to COLOR-NAME.
1073 When called interactively, prompt for the name of the color to use.
1074 To get the frame's current border color, use `frame-parameters'."
1075   (interactive (list (facemenu-read-color "Border color: ")))
1076   (modify-frame-parameters (selected-frame)
1077                            (list (cons 'border-color color-name))))
1078
1079 (defun auto-raise-mode (arg)
1080   "Toggle whether or not the selected frame should auto-raise.
1081 With arg, turn auto-raise mode on if and only if arg is positive.
1082 Note that this controls Emacs's own auto-raise feature.
1083 Some window managers allow you to enable auto-raise for certain windows.
1084 You can use that for Emacs windows if you wish, but if you do,
1085 that is beyond the control of Emacs and this command has no effect on it."
1086   (interactive "P")
1087   (if (null arg)
1088       (setq arg
1089             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
1090                 -1 1)))
1091   (if (> arg 0)
1092       (raise-frame (selected-frame)))
1093   (modify-frame-parameters (selected-frame)
1094                            (list (cons 'auto-raise (> arg 0)))))
1095
1096 (defun auto-lower-mode (arg)
1097   "Toggle whether or not the selected frame should auto-lower.
1098 With arg, turn auto-lower mode on if and only if arg is positive.
1099 Note that this controls Emacs's own auto-lower feature.
1100 Some window managers allow you to enable auto-lower for certain windows.
1101 You can use that for Emacs windows if you wish, but if you do,
1102 that is beyond the control of Emacs and this command has no effect on it."
1103   (interactive "P")
1104   (if (null arg)
1105       (setq arg
1106             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
1107                 -1 1)))
1108   (modify-frame-parameters (selected-frame)
1109                            (list (cons 'auto-lower (> arg 0)))))
1110 (defun set-frame-name (name)
1111   "Set the name of the selected frame to NAME.
1112 When called interactively, prompt for the name of the frame.
1113 The frame name is displayed on the modeline if the terminal displays only
1114 one frame, otherwise the name is displayed on the frame's caption bar."
1115   (interactive "sFrame name: ")
1116   (modify-frame-parameters (selected-frame)
1117                            (list (cons 'name name))))
1118
1119 (defun frame-current-scroll-bars (&optional frame)
1120   "Return the current scroll-bar settings in frame FRAME.
1121 Value is a cons (VERTICAL . HORIZ0NTAL) where VERTICAL specifies the
1122 current location of the vertical scroll-bars (left, right, or nil),
1123 and HORIZONTAL specifies the current location of the horizontal scroll
1124 bars (top, bottom, or nil)."
1125   (let ((vert (frame-parameter frame 'vertical-scroll-bars))
1126         (hor nil))
1127     (unless (memq vert '(left right nil))
1128       (setq vert default-frame-scroll-bars))
1129     (cons vert hor)))
1130 \f
1131 ;;;; Frame/display capabilities.
1132 (defun selected-terminal ()
1133   "Return the terminal that is now selected."
1134   (frame-terminal (selected-frame)))
1135
1136 (declare-function msdos-mouse-p "dosfns.c")
1137
1138 (defun display-mouse-p (&optional display)
1139   "Return non-nil if DISPLAY has a mouse available.
1140 DISPLAY can be a display name, a frame, or nil (meaning the selected
1141 frame's display)."
1142   (let ((frame-type (framep-on-display display)))
1143     (cond
1144      ((eq frame-type 'pc)
1145       (msdos-mouse-p))
1146      ((eq system-type 'windows-nt)
1147       (with-no-warnings
1148        (> w32-num-mouse-buttons 0)))
1149      ((memq frame-type '(x mac))
1150       t)    ;; We assume X and Mac *always* have a pointing device
1151      (t
1152       (or (and (featurep 'xt-mouse)
1153                xterm-mouse-mode)
1154           ;; t-mouse is distributed with the GPM package.  It doesn't have
1155           ;; a toggle.
1156           (featurep 't-mouse))))))
1157
1158 (defun display-popup-menus-p (&optional display)
1159   "Return non-nil if popup menus are supported on DISPLAY.
1160 DISPLAY can be a display name, a frame, or nil (meaning the selected
1161 frame's display).
1162 Support for popup menus requires that the mouse be available."
1163   (and
1164    (let ((frame-type (framep-on-display display)))
1165      (memq frame-type '(x w32 pc mac)))
1166    (display-mouse-p display)))
1167
1168 (defun display-graphic-p (&optional display)
1169   "Return non-nil if DISPLAY is a graphic display.
1170 Graphical displays are those which are capable of displaying several
1171 frames and several different fonts at once.  This is true for displays
1172 that use a window system such as X, and false for text-only terminals.
1173 DISPLAY can be a display name, a frame, or nil (meaning the selected
1174 frame's display)."
1175   (not (null (memq (framep-on-display display) '(x w32 mac)))))
1176
1177 (defun display-images-p (&optional display)
1178   "Return non-nil if DISPLAY can display images.
1179
1180 DISPLAY can be a display name, a frame, or nil (meaning the selected
1181 frame's display)."
1182   (and (display-graphic-p display)
1183        (fboundp 'image-mask-p)
1184        (fboundp 'image-size)))
1185
1186 (defalias 'display-multi-frame-p 'display-graphic-p)
1187 (defalias 'display-multi-font-p 'display-graphic-p)
1188
1189 (defun display-selections-p (&optional display)
1190   "Return non-nil if DISPLAY supports selections.
1191 A selection is a way to transfer text or other data between programs
1192 via special system buffers called `selection' or `cut buffer' or
1193 `clipboard'.
1194 DISPLAY can be a display name, a frame, or nil (meaning the selected
1195 frame's display)."
1196   (let ((frame-type (framep-on-display display)))
1197     (cond
1198      ((eq frame-type 'pc)
1199       ;; MS-DOG frames support selections when Emacs runs inside
1200       ;; the Windows' DOS Box.
1201       (with-no-warnings
1202        (not (null dos-windows-version))))
1203      ((memq frame-type '(x w32 mac))
1204       t)    ;; FIXME?
1205      (t
1206       nil))))
1207
1208 (defun display-screens (&optional display)
1209   "Return the number of screens associated with DISPLAY."
1210   (let ((frame-type (framep-on-display display)))
1211     (cond
1212      ((memq frame-type '(x w32 mac))
1213       (x-display-screens display))
1214      (t
1215       1))))
1216
1217 (defun display-pixel-height (&optional display)
1218   "Return the height of DISPLAY's screen in pixels.
1219 For character terminals, each character counts as a single pixel."
1220   (let ((frame-type (framep-on-display display)))
1221     (cond
1222      ((memq frame-type '(x w32 mac))
1223       (x-display-pixel-height display))
1224      (t
1225       (frame-height (if (framep display) display (selected-frame)))))))
1226
1227 (defun display-pixel-width (&optional display)
1228   "Return the width of DISPLAY's screen in pixels.
1229 For character terminals, each character counts as a single pixel."
1230   (let ((frame-type (framep-on-display display)))
1231     (cond
1232      ((memq frame-type '(x w32 mac))
1233       (x-display-pixel-width display))
1234      (t
1235       (frame-width (if (framep display) display (selected-frame)))))))
1236
1237 (defcustom display-mm-dimensions-alist nil
1238   "Alist for specifying screen dimensions in millimeters.
1239 The dimensions will be used for `display-mm-height' and
1240 `display-mm-width' if defined for the respective display.
1241
1242 Each element of the alist has the form (display . (width . height)),
1243 e.g. (\":0.0\" . (287 . 215)).
1244
1245 If `display' equals t, it specifies dimensions for all graphical
1246 displays not explicitely specified."
1247   :version "22.1"
1248   :type '(alist :key-type (choice (string :tag "Display name")
1249                                   (const :tag "Default" t))
1250                 :value-type (cons :tag "Dimensions"
1251                                   (integer :tag "Width")
1252                                   (integer :tag "Height")))
1253   :group 'frames)
1254
1255 (defun display-mm-height (&optional display)
1256   "Return the height of DISPLAY's screen in millimeters.
1257 System values can be overridden by `display-mm-dimensions-alist'.
1258 If the information is unavailable, value is nil."
1259   (and (memq (framep-on-display display) '(x w32 mac))
1260        (or (cddr (assoc (or display (frame-parameter nil 'display))
1261                         display-mm-dimensions-alist))
1262            (cddr (assoc t display-mm-dimensions-alist))
1263            (x-display-mm-height display))))
1264
1265 (defun display-mm-width (&optional display)
1266   "Return the width of DISPLAY's screen in millimeters.
1267 System values can be overridden by `display-mm-dimensions-alist'.
1268 If the information is unavailable, value is nil."
1269   (and (memq (framep-on-display display) '(x w32 mac))
1270        (or (cadr (assoc (or display (frame-parameter nil 'display))
1271                         display-mm-dimensions-alist))
1272            (cadr (assoc t display-mm-dimensions-alist))
1273            (x-display-mm-width display))))
1274
1275 (defun display-backing-store (&optional display)
1276   "Return the backing store capability of DISPLAY's screen.
1277 The value may be `always', `when-mapped', `not-useful', or nil if
1278 the question is inapplicable to a certain kind of display."
1279   (let ((frame-type (framep-on-display display)))
1280     (cond
1281      ((memq frame-type '(x w32 mac))
1282       (x-display-backing-store display))
1283      (t
1284       'not-useful))))
1285
1286 (defun display-save-under (&optional display)
1287   "Return non-nil if DISPLAY's screen supports the SaveUnder feature."
1288   (let ((frame-type (framep-on-display display)))
1289     (cond
1290      ((memq frame-type '(x w32 mac))
1291       (x-display-save-under display))
1292      (t
1293       'not-useful))))
1294
1295 (defun display-planes (&optional display)
1296   "Return the number of planes supported by DISPLAY."
1297   (let ((frame-type (framep-on-display display)))
1298     (cond
1299      ((memq frame-type '(x w32 mac))
1300       (x-display-planes display))
1301      ((eq frame-type 'pc)
1302       4)
1303      (t
1304       (truncate (log (length (tty-color-alist)) 2))))))
1305
1306 (defun display-color-cells (&optional display)
1307   "Return the number of color cells supported by DISPLAY."
1308   (let ((frame-type (framep-on-display display)))
1309     (cond
1310      ((memq frame-type '(x w32 mac))
1311       (x-display-color-cells display))
1312      ((eq frame-type 'pc)
1313       16)
1314      (t
1315       (tty-display-color-cells display)))))
1316
1317 (defun display-visual-class (&optional display)
1318   "Returns the visual class of DISPLAY.
1319 The value is one of the symbols `static-gray', `gray-scale',
1320 `static-color', `pseudo-color', `true-color', or `direct-color'."
1321   (let ((frame-type (framep-on-display display)))
1322     (cond
1323      ((memq frame-type '(x w32 mac))
1324       (x-display-visual-class display))
1325      ((and (memq frame-type '(pc t))
1326            (tty-display-color-p display))
1327       'static-color)
1328      (t
1329       'static-gray))))
1330
1331 \f
1332 ;;;; Frame geometry values
1333
1334 (defun frame-geom-value-cons (type value &optional frame)
1335   "Return equivalent geometry value for FRAME as a cons with car `+'.
1336 A geometry value equivalent to VALUE for FRAME is returned,
1337 where the value is a cons with car `+', not numeric.
1338 TYPE is the car of the original geometry spec (TYPE . VALUE).
1339    It is `top' or `left', depending on which edge VALUE is related to.
1340 VALUE is the cdr of a frame geometry spec: (left/top . VALUE).
1341 If VALUE is a number, then it is converted to a cons value, perhaps
1342    relative to the opposite frame edge from that in the original spec.
1343 FRAME defaults to the selected frame.
1344
1345 Examples (measures in pixels) -
1346  Assuming display height/width=1024, frame height/width=600:
1347  300 inside display edge:                   300  => (+  300)
1348                                         (+  300) => (+  300)
1349  300 inside opposite display edge:      (-  300) => (+  124)
1350                                            -300  => (+  124)
1351  300 beyond display edge
1352   (= 724 inside opposite display edge): (+ -300) => (+ -300)
1353  300 beyond display edge
1354   (= 724 inside opposite display edge): (- -300) => (+  724)
1355
1356 In the 3rd, 4th, and 6th examples, the returned value is relative to
1357 the opposite frame edge from the edge indicated in the input spec."
1358   (cond ((and (consp value) (eq '+ (car value))) ; e.g. (+ 300), (+ -300)
1359          value)
1360         ((natnump value) (list '+ value)) ; e.g. 300 => (+ 300)
1361         (t                              ; e.g. -300, (- 300), (- -300)
1362          (list '+ (- (if (eq 'left type) ; => (+ 124), (+ 124), (+ 724)
1363                          (x-display-pixel-width)
1364                        (x-display-pixel-height))
1365                      (if (integerp value) (- value) (cadr value))
1366                      (if (eq 'left type)
1367                          (frame-pixel-width frame)
1368                        (frame-pixel-height frame)))))))
1369
1370 (defun frame-geom-spec-cons (spec &optional frame)
1371   "Return equivalent geometry spec for FRAME as a cons with car `+'.
1372 A geometry specification equivalent to SPEC for FRAME is returned,
1373 where the value is a cons with car `+', not numeric.
1374 SPEC is a frame geometry spec: (left . VALUE) or (top . VALUE).
1375 If VALUE is a number, then it is converted to a cons value, perhaps
1376    relative to the opposite frame edge from that in the original spec.
1377 FRAME defaults to the selected frame.
1378
1379 Examples (measures in pixels) -
1380  Assuming display height=1024, frame height=600:
1381  top 300 below display top:               (top .  300) => (top +  300)
1382                                           (top +  300) => (top +  300)
1383  bottom 300 above display bottom:         (top -  300) => (top +  124)
1384                                           (top . -300) => (top +  124)
1385  top 300 above display top
1386   (= bottom 724 above display bottom):    (top + -300) => (top + -300)
1387  bottom 300 below display bottom
1388   (= top 724 below display top):          (top - -300) => (top +  724)
1389
1390 In the 3rd, 4th, and 6th examples, the returned value is relative to
1391 the opposite frame edge from the edge indicated in the input spec."
1392   (cons (car spec) (frame-geom-value-cons (car spec) (cdr spec))))
1393 \f
1394 ;;;; Aliases for backward compatibility with Emacs 18.
1395 (define-obsolete-function-alias 'screen-height 'frame-height) ;before 19.15
1396 (define-obsolete-function-alias 'screen-width 'frame-width) ;before 19.15
1397
1398 (defun set-screen-width (cols &optional pretend)
1399   "Change the size of the screen to COLS columns.
1400 Optional second arg non-nil means that redisplay should use COLS columns
1401 but that the idea of the actual width of the frame should not be changed.
1402 This function is provided only for compatibility with Emacs 18."
1403   (set-frame-width (selected-frame) cols pretend))
1404
1405 (defun set-screen-height (lines &optional pretend)
1406   "Change the height of the screen to LINES lines.
1407 Optional second arg non-nil means that redisplay should use LINES lines
1408 but that the idea of the actual height of the screen should not be changed.
1409 This function is provided only for compatibility with Emacs 18."
1410   (set-frame-height (selected-frame) lines pretend))
1411
1412 (defun delete-other-frames (&optional frame)
1413   "Delete all frames except FRAME.
1414 If FRAME uses another frame's minibuffer, the minibuffer frame is
1415 left untouched.  FRAME nil or omitted means use the selected frame."
1416   (interactive)
1417   (unless frame
1418     (setq frame (selected-frame)))
1419   (let* ((mini-frame (window-frame (minibuffer-window frame)))
1420          (frames (delq mini-frame (delq frame (frame-list)))))
1421     ;; Delete mon-minibuffer-only frames first, because `delete-frame'
1422     ;; signals an error when trying to delete a mini-frame that's
1423     ;; still in use by another frame.
1424     (dolist (frame frames)
1425       (unless (eq (frame-parameter frame 'minibuffer) 'only)
1426         (delete-frame frame)))
1427     ;; Delete minibuffer-only frames.
1428     (dolist (frame frames)
1429       (when (eq (frame-parameter frame 'minibuffer) 'only)
1430         (delete-frame frame)))))
1431
1432 (make-obsolete 'set-screen-width 'set-frame-width) ;before 19.15
1433 (make-obsolete 'set-screen-height 'set-frame-height) ;before 19.15
1434
1435 ;; miscellaneous obsolescence declarations
1436 (define-obsolete-variable-alias 'delete-frame-hook
1437     'delete-frame-functions "22.1")
1438
1439 \f
1440 ;; Highlighting trailing whitespace.
1441
1442 (make-variable-buffer-local 'show-trailing-whitespace)
1443
1444 (defcustom show-trailing-whitespace nil
1445   "*Non-nil means highlight trailing whitespace.
1446 This is done in the face `trailing-whitespace'."
1447   :type 'boolean
1448   :group 'whitespace-faces)
1449
1450
1451 \f
1452 ;; Scrolling
1453
1454 (defgroup scrolling nil
1455   "Scrolling windows."
1456   :version "21.1"
1457   :group 'frames)
1458
1459 (defcustom auto-hscroll-mode t
1460   "*Allow or disallow automatic scrolling windows horizontally.
1461 If non-nil, windows are automatically scrolled horizontally to make
1462 point visible."
1463   :version "21.1"
1464   :type 'boolean
1465   :group 'scrolling)
1466 (defvaralias 'automatic-hscrolling 'auto-hscroll-mode)
1467
1468 \f
1469 ;; Blinking cursor
1470
1471 (defgroup cursor nil
1472   "Displaying text cursors."
1473   :version "21.1"
1474   :group 'frames)
1475
1476 (defcustom blink-cursor-delay 0.5
1477   "*Seconds of idle time after which cursor starts to blink."
1478   :type 'number
1479   :group 'cursor)
1480
1481 (defcustom blink-cursor-interval 0.5
1482   "*Length of cursor blink interval in seconds."
1483   :type 'number
1484   :group 'cursor)
1485
1486 (defvar blink-cursor-idle-timer nil
1487   "Timer started after `blink-cursor-delay' seconds of Emacs idle time.
1488 The function `blink-cursor-start' is called when the timer fires.")
1489
1490 (defvar blink-cursor-timer nil
1491   "Timer started from `blink-cursor-start'.
1492 This timer calls `blink-cursor-timer-function' every
1493 `blink-cursor-interval' seconds.")
1494
1495 (defun blink-cursor-start ()
1496   "Timer function called from the timer `blink-cursor-idle-timer'.
1497 This starts the timer `blink-cursor-timer', which makes the cursor blink
1498 if appropriate.  It also arranges to cancel that timer when the next
1499 command starts, by installing a pre-command hook."
1500   (when (null blink-cursor-timer)
1501     ;; Set up the timer first, so that if this signals an error,
1502     ;; blink-cursor-end is not added to pre-command-hook.
1503     (setq blink-cursor-timer
1504           (run-with-timer blink-cursor-interval blink-cursor-interval
1505                           'blink-cursor-timer-function))
1506     (add-hook 'pre-command-hook 'blink-cursor-end)
1507     (internal-show-cursor nil nil)))
1508
1509 (defun blink-cursor-timer-function ()
1510   "Timer function of timer `blink-cursor-timer'."
1511   (internal-show-cursor nil (not (internal-show-cursor-p))))
1512
1513 (defun blink-cursor-end ()
1514   "Stop cursor blinking.
1515 This is installed as a pre-command hook by `blink-cursor-start'.
1516 When run, it cancels the timer `blink-cursor-timer' and removes
1517 itself as a pre-command hook."
1518   (remove-hook 'pre-command-hook 'blink-cursor-end)
1519   (internal-show-cursor nil t)
1520   (when blink-cursor-timer
1521     (cancel-timer blink-cursor-timer)
1522     (setq blink-cursor-timer nil)))
1523
1524 (define-minor-mode blink-cursor-mode
1525   "Toggle blinking cursor mode.
1526 With a numeric argument, turn blinking cursor mode on if ARG is positive,
1527 otherwise turn it off.  When blinking cursor mode is enabled, the
1528 cursor of the selected window blinks.
1529
1530 Note that this command is effective only when Emacs
1531 displays through a window system, because then Emacs does its own
1532 cursor display.  On a text-only terminal, this is not implemented."
1533   :init-value (not (or noninteractive
1534                        no-blinking-cursor
1535                        (eq system-type 'ms-dos)
1536                        (not (memq window-system '(x w32 mac)))))
1537   :initialize 'custom-initialize-safe-default
1538   :group 'cursor
1539   :global t
1540   (if blink-cursor-idle-timer (cancel-timer blink-cursor-idle-timer))
1541   (setq blink-cursor-idle-timer nil)
1542   (blink-cursor-end)
1543   (when blink-cursor-mode
1544     ;; Hide the cursor.
1545     ;;(internal-show-cursor nil nil)
1546     (setq blink-cursor-idle-timer
1547           (run-with-idle-timer blink-cursor-delay
1548                                blink-cursor-delay
1549                                'blink-cursor-start))))
1550
1551 (define-obsolete-variable-alias 'blink-cursor 'blink-cursor-mode "22.1")
1552 \f
1553 ;; Hourglass pointer
1554
1555 (defcustom display-hourglass t
1556   "*Non-nil means show an hourglass pointer, when Emacs is busy.
1557 This feature only works when on a window system that can change
1558 cursor shapes."
1559   :type 'boolean
1560   :group 'cursor)
1561
1562 (defcustom hourglass-delay 1
1563   "*Seconds to wait before displaying an hourglass pointer when Emacs is busy."
1564   :type 'number
1565   :group 'cursor)
1566
1567 \f
1568 (defcustom cursor-in-non-selected-windows t
1569   "*Non-nil means show a hollow box cursor in non-selected windows.
1570 If nil, don't show a cursor except in the selected window.
1571 If t, display a cursor related to the usual cursor type
1572  \(a solid box becomes hollow, a bar becomes a narrower bar).
1573 You can also specify the cursor type as in the `cursor-type' variable.
1574 Use Custom to set this variable to get the display updated."
1575   :tag "Cursor In Non-selected Windows"
1576   :type 'boolean
1577   :group 'cursor
1578   :set #'(lambda (symbol value)
1579            (set-default symbol value)
1580            (force-mode-line-update t)))
1581
1582 \f
1583 ;;;; Key bindings
1584
1585 (define-key ctl-x-5-map "2" 'make-frame-command)
1586 (define-key ctl-x-5-map "1" 'delete-other-frames)
1587 (define-key ctl-x-5-map "0" 'delete-frame)
1588 (define-key ctl-x-5-map "o" 'other-frame)
1589
1590 (provide 'frame)
1591
1592 ;; arch-tag: 82979c70-b8f2-4306-b2ad-ddbd6b328b56
1593 ;;; frame.el ends here