lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001,
   4 ;;   2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file contains those help commands which are complicated, and
  29 ;; which may not be used in every session.  For example
  30 ;; `describe-function' will probably be heavily used when doing elisp
  31 ;; programming, but not if just editing C files.  Simpler help commands
  32 ;; are in help.el
  33
  34 ;;; Code:
  35
  36 (require 'help-mode)
  37
  38 ;; Functions
  39
  40 ;;;###autoload
  41 (defun describe-function (function)
  42   "Display the full documentation of FUNCTION (a symbol)."
  43   (interactive
  44    (let ((fn (function-called-at-point))
  45          (enable-recursive-minibuffers t)
  46          val)
  47      (setq val (completing-read (if fn
  48                                     (format "Describe function (default %s): " fn)
  49                                   "Describe function: ")
  50                                 obarray 'fboundp t nil nil
  51                                 (and fn (symbol-name fn))))
  52      (list (if (equal val "")
  53                fn (intern val)))))
  54   (if (null function)
  55       (message "You didn't specify a function")
  56     (help-setup-xref (list #'describe-function function) (interactive-p))
  57     (save-excursion
  58       (with-output-to-temp-buffer (help-buffer)
  59         (prin1 function)
  60         ;; Use " is " instead of a colon so that
  61         ;; it is easier to get out the function name using forward-sexp.
  62         (princ " is ")
  63         (describe-function-1 function)
  64         (print-help-return-message)
  65         (with-current-buffer standard-output
  66           ;; Return the text we displayed.
  67           (buffer-string))))))
  68
  69 (defun help-split-fundoc (docstring def)
  70   "Split a function DOCSTRING into the actual doc and the usage info.
  71 Return (USAGE . DOC) or nil if there's no usage info.
  72 DEF is the function whose usage we're looking for in DOCSTRING."
  73   ;; Functions can get the calling sequence at the end of the doc string.
  74   ;; In cases where `function' has been fset to a subr we can't search for
  75   ;; function's name in the doc string so we use `fn' as the anonymous
  76   ;; function name instead.
  77   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  78     (cons (format "(%s%s"
  79                   ;; Replace `fn' with the actual function name.
  80                   (if (consp def) "anonymous" def)
  81                   (match-string 1 docstring))
  82           (substring docstring 0 (match-beginning 0)))))
  83
  84 (defun help-add-fundoc-usage (docstring arglist)
  85   "Add the usage info to DOCSTRING.
  86 If DOCSTRING already has a usage info, then just return it unchanged.
  87 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  88 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  89   (unless (stringp docstring) (setq docstring "Not documented"))
  90   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
  91       docstring
  92     (concat docstring
  93             (if (string-match "\n?\n\\'" docstring)
  94                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  95               "\n\n")
  96             (if (and (stringp arglist)
  97                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
  98                 (concat "(fn" (match-string 1 arglist) ")")
  99               (format "%S" (help-make-usage 'fn arglist))))))
 100
 101 (defun help-function-arglist (def)
 102   ;; Handle symbols aliased to other symbols.
 103   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 104   ;; If definition is a macro, find the function inside it.
 105   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 106   (cond
 107    ((byte-code-function-p def) (aref def 0))
 108    ((eq (car-safe def) 'lambda) (nth 1 def))
 109    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 110     "[Arg list not available until function definition is loaded.]")
 111    (t t)))
 112
 113 (defun help-make-usage (function arglist)
 114   (cons (if (symbolp function) function 'anonymous)
 115         (mapcar (lambda (arg)
 116                   (if (not (symbolp arg))
 117                       (if (and (consp arg) (symbolp (car arg)))
 118                           ;; CL style default values for optional args.
 119                           (cons (intern (upcase (symbol-name (car arg))))
 120                                 (cdr arg))
 121                         arg)
 122                     (let ((name (symbol-name arg)))
 123                       (if (string-match "\\`&" name) arg
 124                         (intern (upcase name))))))
 125                 arglist)))
 126
 127 ;; Could be this, if we make symbol-file do the work below.
 128 ;; (defun help-C-file-name (subr-or-var kind)
 129 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 130 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 131 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 132 ;;               (subr-name subr-or-var))
 133 ;;             (if (eq kind 'var) 'defvar 'defun)))
 134 ;;;###autoload
 135 (defun help-C-file-name (subr-or-var kind)
 136   "Return the name of the C file where SUBR-OR-VAR is defined.
 137 KIND should be `var' for a variable or `subr' for a subroutine."
 138   (let ((docbuf (get-buffer-create " *DOC*"))
 139         (name (if (eq 'var kind)
 140                   (concat "V" (symbol-name subr-or-var))
 141                 (concat "F" (subr-name subr-or-var)))))
 142     (with-current-buffer docbuf
 143       (goto-char (point-min))
 144       (if (eobp)
 145           (insert-file-contents-literally
 146            (expand-file-name internal-doc-file-name doc-directory)))
 147       (let ((file (catch 'loop
 148                     (while t
 149                       (let ((pnt (search-forward (concat "\1f" name "\n"))))
 150                         (re-search-backward "\1fS\\(.*\\)")
 151                         (let ((file (match-string 1)))
 152                           (if (member file build-files)
 153                               (throw 'loop file)
 154                             (goto-char pnt))))))))
 155         (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 156             (setq file (replace-match ".c" t t file)))
 157         (if (string-match "\\.c\\'" file)
 158             (concat "src/" file)
 159           file)))))
 160
 161 (defface help-argument-name '((((supports :slant italic)) :inherit italic))
 162   "Face to highlight argument names in *Help* buffers."
 163   :group 'help)
 164
 165 (defun help-default-arg-highlight (arg)
 166   "Default function to highlight arguments in *Help* buffers.
 167 It returns ARG in face `help-argument-name'; ARG is also
 168 downcased if it displays differently than the default
 169 face (according to `face-differs-from-default-p')."
 170   (propertize (if (face-differs-from-default-p 'help-argument-name)
 171                   (downcase arg)
 172                 arg)
 173               'face 'help-argument-name))
 174
 175 (defun help-do-arg-highlight (doc args)
 176   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 177     (modify-syntax-entry ?\- "w")
 178     (dolist (arg args doc)
 179       (setq doc (replace-regexp-in-string
 180                  ;; This is heuristic, but covers all common cases
 181                  ;; except ARG1-ARG2
 182                  (concat "\\<"                   ; beginning of word
 183                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 184                          "\\("
 185                          (regexp-quote arg)
 186                          "\\)"
 187                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 188                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 189                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 190                          "\\>")                  ; end of word
 191                  (help-default-arg-highlight arg)
 192                  doc t t 1)))))
 193
 194 (defun help-highlight-arguments (usage doc &rest args)
 195   (when usage
 196     (with-temp-buffer
 197       (insert usage)
 198       (goto-char (point-min))
 199       (let ((case-fold-search nil)
 200             (next (not (or args (looking-at "\\["))))
 201             (opt nil))
 202         ;; Make a list of all arguments
 203         (skip-chars-forward "^ ")
 204         (while next
 205           (or opt (not (looking-at " &")) (setq opt t))
 206           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 207               (setq next nil)
 208             (setq args (cons (match-string 2) args))
 209             (when (and opt (string= (match-string 1) "("))
 210               ;; A pesky CL-style optional argument with default value,
 211               ;; so let's skip over it
 212               (search-backward "(")
 213               (goto-char (scan-sexps (point) 1)))))
 214         ;; Highlight aguments in the USAGE string
 215         (setq usage (help-do-arg-highlight (buffer-string) args))
 216         ;; Highlight arguments in the DOC string
 217         (setq doc (and doc (help-do-arg-highlight doc args))))))
 218   ;; Return value is like the one from help-split-fundoc, but highlighted
 219   (cons usage doc))
 220
 221 ;;;###autoload
 222 (defun describe-simplify-lib-file-name (file)
 223   "Simplify a library name FILE to a relative name, and make it a source file."
 224   (if file
 225       ;; Try converting the absolute file name to a library name.
 226       (let ((libname (file-name-nondirectory file)))
 227         ;; Now convert that back to a file name and see if we get
 228         ;; the original one.  If so, they are equivalent.
 229         (if (equal file (locate-file libname load-path '("")))
 230             (if (string-match "[.]elc\\'" libname)
 231                 (substring libname 0 -1)
 232               libname)
 233           file))))
 234
 235 (defun find-source-lisp-file (file-name)
 236   (let* ((elc-file (locate-file (concat file-name
 237                                  (if (string-match "\\.el" file-name)
 238                                      "c"
 239                                    ".elc"))
 240                                  load-path))
 241          (str (if (and elc-file (file-readable-p elc-file))
 242                   (with-temp-buffer
 243                     (insert-file-contents-literally elc-file nil 0 256)
 244                     (buffer-string))))
 245          (src-file (and str
 246                         (string-match ";;; from file \\(.*\\.el\\)" str)
 247                         (match-string 1 str))))
 248     (if (and src-file (file-readable-p src-file))
 249         src-file
 250       file-name)))
 251
 252 ;;;###autoload
 253 (defun describe-function-1 (function)
 254   (let* ((def (if (symbolp function)
 255                   (symbol-function function)
 256                 function))
 257          file-name string
 258          (beg (if (commandp def) "an interactive " "a ")))
 259     (setq string
 260           (cond ((or (stringp def)
 261                      (vectorp def))
 262                  "a keyboard macro")
 263                 ((subrp def)
 264                  (if (eq 'unevalled (cdr (subr-arity def)))
 265                      (concat beg "special form")
 266                    (concat beg "built-in function")))
 267                 ((byte-code-function-p def)
 268                  (concat beg "compiled Lisp function"))
 269                 ((symbolp def)
 270                  (while (symbolp (symbol-function def))
 271                    (setq def (symbol-function def)))
 272                  (format "an alias for `%s'" def))
 273                 ((eq (car-safe def) 'lambda)
 274                  (concat beg "Lisp function"))
 275                 ((eq (car-safe def) 'macro)
 276                  "a Lisp macro")
 277                 ((eq (car-safe def) 'autoload)
 278                  (setq file-name (nth 1 def))
 279                  (format "%s autoloaded %s"
 280                          (if (commandp def) "an interactive" "an")
 281                          (if (eq (nth 4 def) 'keymap) "keymap"
 282                            (if (nth 4 def) "Lisp macro" "Lisp function"))
 283                          ))
 284                 ((keymapp def)
 285                  (let ((is-full nil)
 286                        (elts (cdr-safe def)))
 287                    (while elts
 288                      (if (char-table-p (car-safe elts))
 289                          (setq is-full t
 290                                elts nil))
 291                      (setq elts (cdr-safe elts)))
 292                    (if is-full
 293                        "a full keymap"
 294                      "a sparse keymap")))
 295                 (t "")))
 296     (princ string)
 297     (with-current-buffer standard-output
 298       (save-excursion
 299         (save-match-data
 300           (if (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 301               (help-xref-button 1 'help-function def)))))
 302     (or file-name
 303         (setq file-name (symbol-file function 'defun)))
 304     (setq file-name (describe-simplify-lib-file-name file-name))
 305     (when (equal file-name "loaddefs.el")
 306       ;; Find the real def site of the preloaded function.
 307       ;; This is necessary only for defaliases.
 308       (let ((location
 309              (condition-case nil
 310                  (find-function-search-for-symbol function nil "loaddefs.el")
 311                (error nil))))
 312         (when location
 313           (with-current-buffer (car location)
 314             (goto-char (cdr location))
 315             (when (re-search-backward
 316                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 317               (setq file-name (match-string 1)))))))
 318     (when (and (null file-name) (subrp def))
 319       ;; Find the C source file name.
 320       (setq file-name (if (get-buffer " *DOC*")
 321                           (help-C-file-name def 'subr)
 322                         'C-source)))
 323     (when file-name
 324       (princ " in `")
 325       ;; We used to add .el to the file name,
 326       ;; but that's completely wrong when the user used load-file.
 327       (princ (if (eq file-name 'C-source) "C source code" file-name))
 328       (princ "'")
 329       ;; See if lisp files are present where they where installed from.
 330       (if (not (eq file-name 'C-source))
 331           (setq file-name (find-source-lisp-file file-name)))
 332
 333       ;; Make a hyperlink to the library.
 334       (with-current-buffer standard-output
 335         (save-excursion
 336           (re-search-backward "`\\([^`']+\\)'" nil t)
 337           (help-xref-button 1 'help-function-def function file-name))))
 338     (princ ".")
 339     (terpri)
 340     (when (commandp function)
 341       (if (and (eq function 'self-insert-command)
 342                (eq (key-binding "a") 'self-insert-command)
 343                (eq (key-binding "b") 'self-insert-command)
 344                (eq (key-binding "c") 'self-insert-command))
 345           (princ "It is bound to many ordinary text characters.\n")
 346         (let* ((remapped (command-remapping function))
 347                (keys (where-is-internal
 348                       (or remapped function) overriding-local-map nil nil))
 349                non-modified-keys)
 350           ;; Which non-control non-meta keys run this command?
 351           (dolist (key keys)
 352             (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 353                 (push key non-modified-keys)))
 354           (when remapped
 355             (princ "It is remapped to `")
 356             (princ (symbol-name remapped))
 357             (princ "'"))
 358
 359           (when keys
 360             (princ (if remapped " which is bound to " "It is bound to "))
 361             ;; If lots of ordinary text characters run this command,
 362             ;; don't mention them one by one.
 363             (if (< (length non-modified-keys) 10)
 364                 (princ (mapconcat 'key-description keys ", "))
 365               (dolist (key non-modified-keys)
 366                 (setq keys (delq key keys)))
 367               (if keys
 368                   (progn
 369                     (princ (mapconcat 'key-description keys ", "))
 370                     (princ ", and many ordinary text characters"))
 371                 (princ "many ordinary text characters"))))
 372           (when (or remapped keys non-modified-keys)
 373             (princ ".")
 374             (terpri)))))
 375     (let* ((arglist (help-function-arglist def))
 376            (doc (documentation function))
 377            (usage (help-split-fundoc doc function)))
 378       (with-current-buffer standard-output
 379         ;; If definition is a keymap, skip arglist note.
 380         (unless (keymapp def)
 381           (let* ((use (cond
 382                         (usage (setq doc (cdr usage)) (car usage))
 383                         ((listp arglist)
 384                          (format "%S" (help-make-usage function arglist)))
 385                         ((stringp arglist) arglist)
 386                         ;; Maybe the arglist is in the docstring of the alias.
 387                         ((let ((fun function))
 388                            (while (and (symbolp fun)
 389                                        (setq fun (symbol-function fun))
 390                                        (not (setq usage (help-split-fundoc
 391                                                          (documentation fun)
 392                                                          function)))))
 393                            usage)
 394                          (car usage))
 395                         ((or (stringp def)
 396                              (vectorp def))
 397                          (format "\nMacro: %s" (format-kbd-macro def)))
 398                         (t "[Missing arglist.  Please make a bug report.]")))
 399                  (high (help-highlight-arguments use doc)))
 400             (let ((fill-begin (point)))
 401               (insert (car high) "\n")
 402               (fill-region fill-begin (point)))
 403             (setq doc (cdr high))))
 404         (let ((obsolete (and
 405                          ;; function might be a lambda construct.
 406                          (symbolp function)
 407                          (get function 'byte-obsolete-info))))
 408           (when obsolete
 409             (princ "\nThis function is obsolete")
 410             (when (nth 2 obsolete)
 411               (insert (format " since %s" (nth 2 obsolete))))
 412             (insert ";\n"
 413                     (if (stringp (car obsolete)) (car obsolete)
 414                       (format "use `%s' instead." (car obsolete)))
 415                     "\n"))
 416           (insert "\n"
 417                   (or doc "Not documented.")))))))
 418
 419 \f
 420 ;; Variables
 421
 422 ;;;###autoload
 423 (defun variable-at-point (&optional any-symbol)
 424   "Return the bound variable symbol found at or before point.
 425 Return 0 if there is no such symbol.
 426 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 427   (or (condition-case ()
 428           (with-syntax-table emacs-lisp-mode-syntax-table
 429             (save-excursion
 430               (or (not (zerop (skip-syntax-backward "_w")))
 431                   (eq (char-syntax (following-char)) ?w)
 432                   (eq (char-syntax (following-char)) ?_)
 433                   (forward-sexp -1))
 434               (skip-chars-forward "'")
 435               (let ((obj (read (current-buffer))))
 436                 (and (symbolp obj) (boundp obj) obj))))
 437         (error nil))
 438       (let* ((str (find-tag-default))
 439              (sym (if str (intern-soft str))))
 440         (if (and sym (or any-symbol (boundp sym)))
 441             sym
 442           (save-match-data
 443             (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 444               (setq sym (intern-soft (match-string 1 str)))
 445               (and (or any-symbol (boundp sym)) sym)))))
 446       0))
 447
 448 ;;;###autoload
 449 (defun describe-variable (variable &optional buffer)
 450   "Display the full documentation of VARIABLE (a symbol).
 451 Returns the documentation as a string, also.
 452 If VARIABLE has a buffer-local value in BUFFER (default to the current buffer),
 453 it is displayed along with the global value."
 454   (interactive
 455    (let ((v (variable-at-point))
 456          (enable-recursive-minibuffers t)
 457          val)
 458      (setq val (completing-read (if (symbolp v)
 459                                     (format
 460                                      "Describe variable (default %s): " v)
 461                                   "Describe variable: ")
 462                                 obarray
 463                                 '(lambda (vv)
 464                                    (or (boundp vv)
 465                                        (get vv 'variable-documentation)))
 466                                 t nil nil
 467                                 (if (symbolp v) (symbol-name v))))
 468      (list (if (equal val "")
 469                v (intern val)))))
 470   (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 471   (if (not (symbolp variable))
 472       (message "You did not specify a variable")
 473     (save-excursion
 474       (let* ((valvoid (not (with-current-buffer buffer (boundp variable))))
 475              ;; Extract the value before setting up the output buffer,
 476              ;; in case `buffer' *is* the output buffer.
 477              (val (unless valvoid (buffer-local-value variable buffer)))
 478              val-start-pos)
 479         (help-setup-xref (list #'describe-variable variable buffer)
 480                          (interactive-p))
 481         (with-output-to-temp-buffer (help-buffer)
 482           (with-current-buffer buffer
 483             (prin1 variable)
 484             ;; Make a hyperlink to the library if appropriate.  (Don't
 485             ;; change the format of the buffer's initial line in case
 486             ;; anything expects the current format.)
 487             (let ((file-name (symbol-file variable 'defvar)))
 488               (setq file-name (describe-simplify-lib-file-name file-name))
 489               (when (equal file-name "loaddefs.el")
 490                 ;; Find the real def site of the preloaded variable.
 491                 (let ((location
 492                        (condition-case nil
 493                            (find-variable-noselect variable file-name)
 494                          (error nil))))
 495                   (when location
 496                     (with-current-buffer (car location)
 497                       (when (cdr location)
 498                         (goto-char (cdr location)))
 499                       (when (re-search-backward
 500                              "^;;; Generated autoloads from \\(.*\\)" nil t)
 501                         (setq file-name (match-string 1)))))))
 502               (when (and (null file-name)
 503                          (integerp (get variable 'variable-documentation)))
 504                 ;; It's a variable not defined in Elisp but in C.
 505                 (setq file-name
 506                       (if (get-buffer " *DOC*")
 507                           (help-C-file-name variable 'var)
 508                         'C-source)))
 509               (if file-name
 510                   (progn
 511                     (princ " is a variable defined in `")
 512                     (princ (if (eq file-name 'C-source) "C source code" file-name))
 513                     (princ "'.\n")
 514                     (with-current-buffer standard-output
 515                       (save-excursion
 516                         (re-search-backward "`\\([^`']+\\)'" nil t)
 517                         (help-xref-button 1 'help-variable-def
 518                                           variable file-name)))
 519                     (if valvoid
 520                         (princ "It is void as a variable.")
 521                       (princ "Its ")))
 522                 (if valvoid
 523                     (princ " is void as a variable.")
 524                   (princ "'s "))))
 525             (if valvoid
 526                 nil
 527               (with-current-buffer standard-output
 528                 (setq val-start-pos (point))
 529                 (princ "value is ")
 530                 (terpri)
 531                 (let ((from (point)))
 532                   (pp val)
 533                   ;; Hyperlinks in variable's value are quite frequently
 534                   ;; inappropriate e.g C-h v <RET> features <RET>
 535                   ;; (help-xref-on-pp from (point))
 536                   (if (< (point) (+ from 20))
 537                       (delete-region (1- from) from)))))
 538             (terpri)
 539
 540             (when (local-variable-p variable)
 541               (princ (format "%socal in buffer %s; "
 542                              (if (get variable 'permanent-local)
 543                                  "Permanently l" "L")
 544                              (buffer-name)))
 545               (if (not (default-boundp variable))
 546                   (princ "globally void")
 547                 (let ((val (default-value variable)))
 548                   (with-current-buffer standard-output
 549                     (princ "global value is ")
 550                     (terpri)
 551                     ;; Fixme: pp can take an age if you happen to
 552                     ;; ask for a very large expression.  We should
 553                     ;; probably print it raw once and check it's a
 554                     ;; sensible size before prettyprinting.  -- fx
 555                     (let ((from (point)))
 556                       (pp val)
 557                       ;; See previous comment for this function.
 558                       ;; (help-xref-on-pp from (point))
 559                       (if (< (point) (+ from 20))
 560                           (delete-region (1- from) from)))))))
 561             ;; Add a note for variables that have been make-var-buffer-local.
 562             (when (and (local-variable-if-set-p variable)
 563                        (or (not (local-variable-p variable))
 564                            (with-temp-buffer
 565                              (local-variable-if-set-p variable))))
 566               (princ "\nAutomatically becomes buffer-local when set in any fashion.\n"))
 567             (terpri)
 568
 569             ;; If the value is large, move it to the end.
 570             (with-current-buffer standard-output
 571               (when (> (count-lines (point-min) (point-max)) 10)
 572                 ;; Note that setting the syntax table like below
 573                 ;; makes forward-sexp move over a `'s' at the end
 574                 ;; of a symbol.
 575                 (set-syntax-table emacs-lisp-mode-syntax-table)
 576                 (goto-char val-start-pos)
 577                 ;; The line below previously read as
 578                 ;; (delete-region (point) (progn (end-of-line) (point)))
 579                 ;; which suppressed display of the buffer local value for
 580                 ;; large values.
 581                 (when (looking-at "value is") (replace-match ""))
 582                 (save-excursion
 583                   (insert "\n\nValue:")
 584                   (set (make-local-variable 'help-button-cache)
 585                        (point-marker)))
 586                 (insert "value is shown ")
 587                 (insert-button "below"
 588                                'action help-button-cache
 589                                'follow-link t
 590                                'help-echo "mouse-2, RET: show value")
 591                 (insert ".\n")))
 592
 593             ;; Mention if it's an alias
 594             (let* ((alias (condition-case nil
 595                              (indirect-variable variable)
 596                            (error variable)))
 597                    (obsolete (get variable 'byte-obsolete-variable))
 598                    (safe-var (get variable 'safe-local-variable))
 599                    (doc (or (documentation-property variable 'variable-documentation)
 600                             (documentation-property alias 'variable-documentation))))
 601               (unless (eq alias variable)
 602                 (princ (format "\nThis variable is an alias for `%s'.\n" alias)))
 603               (if (or obsolete safe-var)
 604                   (terpri))
 605
 606               (when obsolete
 607                 (princ "This variable is obsolete")
 608                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 609                 (princ ";") (terpri)
 610                 (princ (if (stringp (car obsolete)) (car obsolete)
 611                          (format "use `%s' instead." (car obsolete))))
 612                 (terpri))
 613               (when safe-var
 614                 (princ "This variable is safe as a file local variable ")
 615                 (princ "if its value\nsatisfies the predicate ")
 616                 (princ (if (byte-code-function-p safe-var)
 617                            "which is byte-compiled expression.\n"
 618                          (format "`%s'.\n" safe-var))))
 619               (princ "\nDocumentation:\n")
 620               (princ (or doc "Not documented as a variable.")))
 621             ;; Make a link to customize if this variable can be customized.
 622             (if (custom-variable-p variable)
 623                 (let ((customize-label "customize"))
 624                   (terpri)
 625                   (terpri)
 626                   (princ (concat "You can " customize-label " this variable."))
 627                   (with-current-buffer standard-output
 628                     (save-excursion
 629                       (re-search-backward
 630                        (concat "\\(" customize-label "\\)") nil t)
 631                       (help-xref-button 1 'help-customize-variable variable)))))
 632             (print-help-return-message)
 633             (save-excursion
 634               (set-buffer standard-output)
 635               ;; Return the text we displayed.
 636               (buffer-string))))))))
 637
 638
 639 ;;;###autoload
 640 (defun describe-syntax (&optional buffer)
 641   "Describe the syntax specifications in the syntax table of BUFFER.
 642 The descriptions are inserted in a help buffer, which is then displayed.
 643 BUFFER defaults to the current buffer."
 644   (interactive)
 645   (setq buffer (or buffer (current-buffer)))
 646   (help-setup-xref (list #'describe-syntax buffer) (interactive-p))
 647   (with-output-to-temp-buffer (help-buffer)
 648     (let ((table (with-current-buffer buffer (syntax-table))))
 649       (with-current-buffer standard-output
 650         (describe-vector table 'internal-describe-syntax-value)
 651         (while (setq table (char-table-parent table))
 652           (insert "\nThe parent syntax table is:")
 653           (describe-vector table 'internal-describe-syntax-value))))))
 654
 655 (defun help-describe-category-set (value)
 656   (insert (cond
 657            ((null value) "default")
 658            ((char-table-p value) "deeper char-table ...")
 659            (t (condition-case err
 660                   (category-set-mnemonics value)
 661                 (error "invalid"))))))
 662
 663 ;;;###autoload
 664 (defun describe-categories (&optional buffer)
 665   "Describe the category specifications in the current category table.
 666 The descriptions are inserted in a buffer, which is then displayed.
 667 If BUFFER is non-nil, then describe BUFFER's category table instead.
 668 BUFFER should be a buffer or a buffer name."
 669   (interactive)
 670   (setq buffer (or buffer (current-buffer)))
 671   (help-setup-xref (list #'describe-categories buffer) (interactive-p))
 672   (with-output-to-temp-buffer (help-buffer)
 673     (let ((table (with-current-buffer buffer (category-table))))
 674       (with-current-buffer standard-output
 675         (describe-vector table 'help-describe-category-set)
 676         (let ((docs (char-table-extra-slot table 0)))
 677           (if (or (not (vectorp docs)) (/= (length docs) 95))
 678               (insert "Invalid first extra slot in this char table\n")
 679             (insert "Meanings of mnemonic characters are:\n")
 680             (dotimes (i 95)
 681               (let ((elt (aref docs i)))
 682                 (when elt
 683                   (insert (+ i ?\s) ": " elt "\n"))))
 684             (while (setq table (char-table-parent table))
 685               (insert "\nThe parent category table is:")
 686               (describe-vector table 'help-describe-category-set))))))))
 687
 688 (provide 'help-fns)
 689
 690 ;; arch-tag: 9e10331c-ae81-4d13-965d-c4819aaab0b3
 691 ;;; help-fns.el ends here