lisp/timezone.el

   1 ;;; Timezone package for GNU Emacs
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993 Free Software Foundation, Inc.
   4
   5 ;;; Author: Masanobu Umeda
   6 ;;; Maintainer: umerin@mse.kyutech.ac.jp
   7 ;;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Code:
  26
  27 (provide 'timezone)
  28
  29 (defvar timezone-world-timezones
  30   '(("PST" .  -800)
  31     ("PDT" .  -700)
  32     ("MST" .  -700)
  33     ("MDT" .  -600)
  34     ("CST" .  -600)
  35     ("CDT" .  -500)
  36     ("EST" .  -500)
  37     ("EDT" .  -400)
  38     ("AST" .  -400)                     ;by <clamen@CS.CMU.EDU>
  39     ("NST" .  -330)                     ;by <clamen@CS.CMU.EDU>
  40     ("UT"  .  +000)
  41     ("GMT" .  +000)
  42     ("BST" .  +100)
  43     ("MET" .  +100)
  44     ("EET" .  +200)
  45     ("JST" .  +900)
  46     ("GMT+1"  .  +100) ("GMT+2"  .  +200) ("GMT+3"  .  +300)
  47     ("GMT+4"  .  +400) ("GMT+5"  .  +500) ("GMT+6"  .  +600)
  48     ("GMT+7"  .  +700) ("GMT+8"  .  +800) ("GMT+9"  .  +900)
  49     ("GMT+10" . +1000) ("GMT+11" . +1100) ("GMT+12" . +1200) ("GMT+13" . +1300)
  50     ("GMT-1"  .  -100) ("GMT-2"  .  -200) ("GMT-3"  .  -300)
  51     ("GMT-4"  .  -400) ("GMT-5"  .  -500) ("GMT-6"  .  -600)
  52     ("GMT-7"  .  -700) ("GMT-8"  .  -800) ("GMT-9"  .  -900)
  53     ("GMT-10" . -1000) ("GMT-11" . -1100) ("GMT-12" . -1200))
  54   "*Time differentials of timezone from GMT in +-HHMM form.
  55 This list is obsolescent, and is present only for backwards compatibility,
  56 because time zone names are ambiguous in practice.
  57 Use `current-time-zone' instead.")
  58
  59 (defvar timezone-months-assoc
  60   '(("JAN" .  1)("FEB" .  2)("MAR" .  3)
  61     ("APR" .  4)("MAY" .  5)("JUN" .  6)
  62     ("JUL" .  7)("AUG" .  8)("SEP" .  9)
  63     ("OCT" . 10)("NOV" . 11)("DEC" . 12))
  64   "Alist of first three letters of a month and its numerical representation.")
  65
  66 (defun timezone-make-date-arpa-standard (date &optional local timezone)
  67   "Convert DATE to an arpanet standard date.
  68 Optional 1st argument LOCAL specifies the default local timezone of the DATE;
  69 if nil, GMT is assumed.
  70 Optional 2nd argument TIMEZONE specifies a time zone to be represented in;
  71 if nil, the local time zone is assumed."
  72   (let ((new (timezone-fix-time date local timezone)))
  73     (timezone-make-arpa-date (aref new 0) (aref new 1) (aref new 2)
  74                              (timezone-make-time-string
  75                               (aref new 3) (aref new 4) (aref new 5))
  76                              (aref new 6))
  77     ))
  78
  79 (defun timezone-make-date-sortable (date &optional local timezone)
  80   "Convert DATE to a sortable date string.
  81 Optional 1st argument LOCAL specifies the default local timezone of the DATE;
  82 if nil, GMT is assumed.
  83 Optional 2nd argument TIMEZONE specifies a timezone to be represented in;
  84 if nil, the local time zone is assumed."
  85   (let ((new (timezone-fix-time date local timezone)))
  86     (timezone-make-sortable-date (aref new 0) (aref new 1) (aref new 2)
  87                                  (timezone-make-time-string
  88                                   (aref new 3) (aref new 4) (aref new 5)))
  89     ))
  90
  91 \f
  92 ;;
  93 ;; Parsers and Constructors of Date and Time
  94 ;;
  95
  96 (defun timezone-make-arpa-date (year month day time &optional timezone)
  97   "Make arpanet standard date string from YEAR, MONTH, DAY, and TIME.
  98 Optional argument TIMEZONE specifies a time zone."
  99   (let ((zone
 100          (if (listp timezone)
 101              (let* ((m (timezone-zone-to-minute timezone))
 102                     (absm (if (< m 0) (- m) m)))
 103                (format "%c%02d%02d"
 104                        (if (< m 0) ?- ?+) (/ absm 60) (% absm 60)))
 105            timezone)))
 106     (format "%02d %s %04d %s %s"
 107             day
 108             (capitalize (car (rassq month timezone-months-assoc)))
 109             year
 110             time
 111             zone)))
 112
 113 (defun timezone-make-sortable-date (year month day time)
 114   "Make sortable date string from YEAR, MONTH, DAY, and TIME."
 115   (format "%4d%02d%02d%s"
 116           year month day time))
 117
 118 (defun timezone-make-time-string (hour minute second)
 119   "Make time string from HOUR, MINUTE, and SECOND."
 120   (format "%02d:%02d:%02d" hour minute second))
 121
 122 (defun timezone-parse-date (date)
 123   "Parse DATE and return a vector [YEAR MONTH DAY TIME TIMEZONE].
 124 19 is prepended to year if necessary.  Timezone may be nil if nothing.
 125 Understands the following styles:
 126  (1) 14 Apr 89 03:20[:12] [GMT]
 127  (2) Fri, 17 Mar 89 4:01[:33] [GMT]
 128  (3) Mon Jan 16 16:12[:37] [GMT] 1989
 129  (4) 6 May 1992 1641-JST (Wednesday)
 130  (5) 22-AUG-1993 10:59:12.82
 131  (6) Thu, 11 Apr 16:17:12 91 [MET]
 132  (7) Mon, 6  Jul 16:47:20 T 1992 [MET]"
 133   (let ((date (or date ""))
 134         (year nil)
 135         (month nil)
 136         (day nil)
 137         (time nil)
 138         (zone nil))                     ;This may be nil.
 139     (cond ((string-match
 140             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\'" date)
 141            ;; Styles: (6) and (7) without timezone
 142            (setq year 6 month 3 day 2 time 4 zone nil))
 143           ((string-match
 144             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 145            ;; Styles: (6) and (7) with timezone and buggy timezone
 146            (setq year 6 month 3 day 2 time 4 zone 7))
 147           ((string-match
 148             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\'" date)
 149            ;; Styles: (1) and (2) without timezone
 150            (setq year 3 month 2 day 1 time 4 zone nil))
 151           ((string-match
 152             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 153            ;; Styles: (1) and (2) with timezone and buggy timezone
 154            (setq year 3 month 2 day 1 time 4 zone 5))
 155           ((string-match
 156             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([0-9]+\\)" date)
 157            ;; Styles: (3) without timezone
 158            (setq year 4 month 1 day 2 time 3 zone nil))
 159           ((string-match
 160             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([-+a-zA-Z0-9]+\\)[ \t]+\\([0-9]+\\)" date)
 161            ;; Styles: (3) with timezone
 162            (setq year 5 month 1 day 2 time 3 zone 4))
 163           ((string-match
 164             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 165            ;; Styles: (4) with timezone
 166            (setq year 3 month 2 day 1 time 4 zone 5))
 167           ((string-match
 168             "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\.[0-9]+" date)
 169            ;; Styles: (5) without timezone.
 170            (setq year 3 month 2 day 1 time 4 zone nil))
 171           )
 172     (if year
 173         (progn
 174           (setq year
 175                 (substring date (match-beginning year) (match-end year)))
 176           ;; It is now Dec 1992.  8 years before the end of the World.
 177           (if (< (length year) 4)
 178               (setq year (concat "19" (substring year -2 nil))))
 179           (setq month
 180                 (int-to-string
 181                  (cdr
 182                   (assoc
 183                    (upcase
 184                     ;; Don't use `match-end' in order to take 3
 185                     ;; letters from the beginning.
 186                     (substring date
 187                                (match-beginning month)
 188                                (+ (match-beginning month) 3)))
 189                    timezone-months-assoc))))
 190           (setq day
 191                 (substring date (match-beginning day) (match-end day)))
 192           (setq time
 193                 (substring date (match-beginning time) (match-end time)))))
 194     (if zone
 195         (setq zone
 196               (substring date (match-beginning zone) (match-end zone))))
 197     ;; Return a vector.
 198     (if year
 199         (vector year month day time zone)
 200       (vector "0" "0" "0" "0" nil))
 201     ))
 202
 203 (defun timezone-parse-time (time)
 204   "Parse TIME (HH:MM:SS) and return a vector [hour minute second].
 205 Recognize HH:MM:SS, HH:MM, HHMMSS, HHMM."
 206   (let ((time (or time ""))
 207         (hour nil)
 208         (minute nil)
 209         (second nil))
 210     (cond ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 211            ;; HH:MM:SS
 212            (setq hour 1 minute 2 second 3))
 213           ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 214            ;; HH:MM
 215            (setq hour 1 minute 2 second nil))
 216           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 217            ;; HHMMSS
 218            (setq hour 1 minute 2 second 3))
 219           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 220            ;; HHMM
 221            (setq hour 1 minute 2 second nil))
 222           )
 223     ;; Return [hour minute second]
 224     (vector
 225      (if hour
 226          (substring time (match-beginning hour) (match-end hour)) "0")
 227      (if minute
 228          (substring time (match-beginning minute) (match-end minute)) "0")
 229      (if second
 230          (substring time (match-beginning second) (match-end second)) "0"))
 231     ))
 232
 233 \f
 234 ;; Miscellaneous
 235
 236 (defun timezone-zone-to-minute (timezone)
 237   "Translate TIMEZONE to an integer minute offset from GMT.
 238 TIMEZONE can be a cons cell containing the output of current-time-zone,
 239 or an integer of the form +-HHMM, or a time zone name."
 240   (cond
 241      ((consp timezone)
 242       (/ (car timezone) 60))
 243      (timezone
 244       (progn
 245         (setq timezone
 246               (or (cdr (assoc (upcase timezone) timezone-world-timezones))
 247                   ;; +900
 248                   timezone))
 249         (if (stringp timezone)
 250             (setq timezone (string-to-int timezone)))
 251         ;; Taking account of minute in timezone.
 252         ;; HHMM -> MM
 253         (let* ((abszone (abs timezone))
 254                (minutes (+ (* 60 (/ abszone 100)) (% abszone 100))))
 255           (if (< timezone 0) (- minutes) minutes))))
 256      (t 0)))
 257
 258 (defun timezone-time-from-absolute (date seconds)
 259   "Compute the UTC time equivalent to DATE at time SECONDS after midnight.
 260 Return a list suitable as an argument to current-time-zone,
 261 or nil if the date cannot be thus represented.
 262 DATE is the number of days elapsed since the (imaginary)
 263 Gregorian date Sunday, December 31, 1 BC."
 264   (let* ((current-time-origin 719162)
 265             ;; (timezone-absolute-from-gregorian 1 1 1970)
 266          (days (- date current-time-origin))
 267          (seconds-per-day (float 86400))
 268          (seconds (+ seconds (* days seconds-per-day)))
 269          (current-time-arithmetic-base (float 65536))
 270          (hi (floor (/ seconds current-time-arithmetic-base)))
 271          (hibase (* hi current-time-arithmetic-base))
 272          (lo (floor (- seconds hibase))))
 273      (and (< (abs (- seconds (+ hibase lo))) 2) ;; Check for integer overflow.
 274           (cons hi lo))))
 275
 276 (defun timezone-time-zone-from-absolute (date seconds)
 277   "Compute the local time zone for DATE at time SECONDS after midnight.
 278 Return a list in the same format as current-time-zone's result,
 279 or nil if the local time zone could not be computed.
 280 DATE is the number of days elapsed since the (imaginary)
 281 Gregorian date Sunday, December 31, 1 BC."
 282    (and (fboundp 'current-time-zone)
 283         (let ((utc-time (timezone-time-from-absolute date seconds)))
 284           (and utc-time
 285                (let ((zone (current-time-zone utc-time)))
 286                  (and (car zone) zone))))))
 287
 288 (defun timezone-fix-time (date local timezone)
 289   "Convert DATE (default timezone LOCAL) to YYYY-MM-DD-HH-MM-SS-ZONE vector.
 290 If LOCAL is nil, it is assumed to be GMT.
 291 If TIMEZONE is nil, use the local time zone."
 292   (let* ((date   (timezone-parse-date date))
 293          (year   (string-to-int (aref date 0)))
 294          (year   (cond ((< year 50)
 295                         (+ year 2000))
 296                        ((< year 100)
 297                         (+ year 1900))
 298                        (t year)))
 299          (month  (string-to-int (aref date 1)))
 300          (day    (string-to-int (aref date 2)))
 301          (time   (timezone-parse-time (aref date 3)))
 302          (hour   (string-to-int (aref time 0)))
 303          (minute (string-to-int (aref time 1)))
 304          (second (string-to-int (aref time 2)))
 305          (local  (or (aref date 4) local)) ;Use original if defined
 306          (timezone
 307           (or timezone
 308               (timezone-time-zone-from-absolute
 309                (timezone-absolute-from-gregorian month day year)
 310                (+ second (* 60 (+ minute (* 60 hour)))))))
 311          (diff   (- (timezone-zone-to-minute timezone)
 312                     (timezone-zone-to-minute local)))
 313          (minute (+ minute diff))
 314          (hour-fix (floor minute 60)))
 315     (setq hour (+ hour hour-fix))
 316     (setq minute (- minute (* 60 hour-fix)))
 317     ;; HOUR may be larger than 24 or smaller than 0.
 318     (cond ((<= 24 hour)                 ;24 -> 00
 319            (setq hour (- hour 24))
 320            (setq day  (1+ day))
 321            (if (< (timezone-last-day-of-month month year) day)
 322                (progn
 323                  (setq month (1+ month))
 324                  (setq day 1)
 325                  (if (< 12 month)
 326                      (progn
 327                        (setq month 1)
 328                        (setq year (1+ year))
 329                        ))
 330                  )))
 331           ((> 0 hour)
 332            (setq hour (+ hour 24))
 333            (setq day  (1- day))
 334            (if (> 1 day)
 335                (progn
 336                  (setq month (1- month))
 337                  (if (> 1 month)
 338                      (progn
 339                        (setq month 12)
 340                        (setq year (1- year))
 341                        ))
 342                  (setq day (timezone-last-day-of-month month year))
 343                  )))
 344           )
 345     (vector year month day hour minute second timezone)))
 346
 347 ;; Partly copied from Calendar program by Edward M. Reingold.
 348 ;; Thanks a lot.
 349
 350 (defun timezone-last-day-of-month (month year)
 351   "The last day in MONTH during YEAR."
 352   (if (and (= month 2) (timezone-leap-year-p year))
 353       29
 354     (aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
 355
 356 (defun timezone-leap-year-p (year)
 357   "Returns t if YEAR is a Gregorian leap year."
 358   (or (and (zerop  (% year 4))
 359            (not (zerop (% year 100))))
 360       (zerop (% year 400))))
 361
 362 (defun timezone-day-number (month day year)
 363   "Return the day number within the year of the date month/day/year."
 364   (let ((day-of-year (+ day (* 31 (1- month)))))
 365     (if (> month 2)
 366         (progn
 367           (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 368           (if (timezone-leap-year-p year)
 369               (setq day-of-year (1+ day-of-year)))))
 370     day-of-year))
 371
 372 (defun timezone-absolute-from-gregorian (month day year)
 373   "The number of days between the Gregorian date 12/31/1 BC and month/day/year.
 374 The Gregorian date Sunday, December 31, 1 BC is imaginary."
 375   (+ (timezone-day-number month day year);; Days this year
 376      (* 365 (1- year));;        + Days in prior years
 377      (/ (1- year) 4);;          + Julian leap years
 378      (- (/ (1- year) 100));;    - century years
 379      (/ (1- year) 400)));;      + Gregorian leap years
 380
 381 ;;; timezone.el ends here