lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This file contains a VC backend for the git version control
  26 ;; system.
  27 ;;
  28
  29 ;;; Installation:
  30
  31 ;; To install: put this file on the load-path and add Git to the list
  32 ;; of supported backends in `vc-handled-backends'; the following line,
  33 ;; placed in your ~/.emacs, will accomplish this:
  34 ;;
  35 ;;     (add-to-list 'vc-handled-backends 'Git)
  36
  37 ;;; Todo:
  38 ;;  - check if more functions could use vc-git-command instead
  39 ;;     of start-process.
  40 ;;  - changelog generation
  41
  42 ;; Implement the rest of the vc interface. See the comment at the
  43 ;; beginning of vc.el. The current status is:
  44 ;; ("??" means: "figure out what to do about it")
  45 ;;
  46 ;; FUNCTION NAME                                   STATUS
  47 ;; BACKEND PROPERTIES
  48 ;; * revision-granularity                          OK
  49 ;; STATE-QUERYING FUNCTIONS
  50 ;; * registered (file)                             OK
  51 ;; * state (file)                                  OK
  52 ;; - state-heuristic (file)                        NOT NEEDED
  53 ;; * working-revision (file)                       OK
  54 ;; - latest-on-branch-p (file)                     NOT NEEDED
  55 ;; * checkout-model (files)                        OK
  56 ;; - workfile-unchanged-p (file)                   OK
  57 ;; - mode-line-string (file)                       OK
  58 ;; STATE-CHANGING FUNCTIONS
  59 ;; * create-repo ()                                OK
  60 ;; * register (files &optional rev comment)        OK
  61 ;; - init-revision (file)                          NOT NEEDED
  62 ;; - responsible-p (file)                          OK
  63 ;; - could-register (file)                         NOT NEEDED, DEFAULT IS GOOD
  64 ;; - receive-file (file rev)                       NOT NEEDED
  65 ;; - unregister (file)                             OK
  66 ;; * checkin (files rev comment)                   OK
  67 ;; * find-revision (file rev buffer)               OK
  68 ;; * checkout (file &optional editable rev)        OK
  69 ;; * revert (file &optional contents-done)         OK
  70 ;; - rollback (files)                              COULD BE SUPPORTED
  71 ;; - merge (file rev1 rev2)                   It would be possible to merge
  72 ;;                                          changes into a single file, but when
  73 ;;                                          committing they wouldn't
  74 ;;                                          be identified as a merge
  75 ;;                                          by git, so it's probably
  76 ;;                                          not a good idea.
  77 ;; - merge-news (file)                     see `merge'
  78 ;; - steal-lock (file &optional revision)          NOT NEEDED
  79 ;; HISTORY FUNCTIONS
  80 ;; * print-log (files &optional buffer shortlog)   OK
  81 ;; - log-view-mode ()                              OK
  82 ;; - show-log-entry (revision)                     OK
  83 ;; - comment-history (file)                        ??
  84 ;; - update-changelog (files)                      COULD BE SUPPORTED
  85 ;; * diff (file &optional rev1 rev2 buffer)        OK
  86 ;; - revision-completion-table (files)             OK
  87 ;; - annotate-command (file buf &optional rev)     OK
  88 ;; - annotate-time ()                              OK
  89 ;; - annotate-current-time ()                      NOT NEEDED
  90 ;; - annotate-extract-revision-at-line ()          OK
  91 ;; TAG SYSTEM
  92 ;; - create-tag (dir name branchp)                 OK
  93 ;; - retrieve-tag (dir name update)                OK
  94 ;; MISCELLANEOUS
  95 ;; - make-version-backups-p (file)                 NOT NEEDED
  96 ;; - repository-hostname (dirname)                 NOT NEEDED
  97 ;; - previous-revision (file rev)                  OK
  98 ;; - next-revision (file rev)                      OK
  99 ;; - check-headers ()                              COULD BE SUPPORTED
 100 ;; - clear-headers ()                              NOT NEEDED
 101 ;; - delete-file (file)                            OK
 102 ;; - rename-file (old new)                         OK
 103 ;; - find-file-hook ()                             NOT NEEDED
 104
 105 (eval-when-compile
 106   (require 'cl)
 107   (require 'vc)
 108   (require 'vc-dir)
 109   (require 'grep))
 110
 111 (defcustom vc-git-diff-switches t
 112   "String or list of strings specifying switches for Git diff under VC.
 113 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
 114   :type '(choice (const :tag "Unspecified" nil)
 115                  (const :tag "None" t)
 116                  (string :tag "Argument String")
 117                  (repeat :tag "Argument List" :value ("") string))
 118   :version "23.1"
 119   :group 'vc)
 120
 121 (defcustom vc-git-add-signoff nil
 122   "Add a Signed-off-by line when committing."
 123   :type 'boolean
 124   :version "23.2"
 125   :group 'vc)
 126
 127
 128 (defvar git-commits-coding-system 'utf-8
 129   "Default coding system for git commits.")
 130
 131 ;;; BACKEND PROPERTIES
 132
 133 (defun vc-git-revision-granularity () 'repository)
 134 (defun vc-git-checkout-model (files) 'implicit)
 135
 136 ;;; STATE-QUERYING FUNCTIONS
 137
 138 ;;;###autoload (defun vc-git-registered (file)
 139 ;;;###autoload   "Return non-nil if FILE is registered with git."
 140 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 141 ;;;###autoload       (progn
 142 ;;;###autoload         (load "vc-git")
 143 ;;;###autoload         (vc-git-registered file))))
 144
 145 (defun vc-git-registered (file)
 146   "Check whether FILE is registered with git."
 147   (when (vc-git-root file)
 148     (with-temp-buffer
 149       (let* (process-file-side-effects
 150              (dir (file-name-directory file))
 151              (name (file-relative-name file dir))
 152              (str (ignore-errors
 153                     (when dir (cd dir))
 154                     (vc-git--out-ok "ls-files" "-c" "-z" "--" name)
 155                     ;; if result is empty, use ls-tree to check for deleted file
 156                     (when (eq (point-min) (point-max))
 157                       (vc-git--out-ok "ls-tree" "--name-only" "-z" "HEAD" "--" name))
 158                     (buffer-string))))
 159         (and str
 160              (> (length str) (length name))
 161              (string= (substring str 0 (1+ (length name)))
 162                       (concat name "\0")))))))
 163
 164 (defun vc-git--state-code (code)
 165   "Convert from a string to a added/deleted/modified state."
 166   (case (string-to-char code)
 167     (?M 'edited)
 168     (?A 'added)
 169     (?D 'removed)
 170     (?U 'edited)     ;; FIXME
 171     (?T 'edited)))   ;; FIXME
 172
 173 (defun vc-git-state (file)
 174   "Git-specific version of `vc-state'."
 175   ;; FIXME: This can't set 'ignored yet
 176   (if (not (vc-git-registered file))
 177       'unregistered
 178     (vc-git--call nil "add" "--refresh" "--" (file-relative-name file))
 179     (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 180       (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\([ADMUT]\\)\0[^\0]+\0"
 181                                   diff))
 182           (vc-git--state-code (match-string 1 diff))
 183         (if (vc-git--empty-db-p) 'added 'up-to-date)))))
 184
 185 (defun vc-git-working-revision (file)
 186   "Git-specific version of `vc-working-revision'."
 187   (let* (process-file-side-effects
 188          (str (with-output-to-string
 189                 (with-current-buffer standard-output
 190                   (vc-git--out-ok "symbolic-ref" "HEAD")))))
 191     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 192         (match-string 2 str)
 193       str)))
 194
 195 (defun vc-git-workfile-unchanged-p (file)
 196   (eq 'up-to-date (vc-git-state file)))
 197
 198 (defun vc-git-mode-line-string (file)
 199   "Return string for placement into the modeline for FILE."
 200   (let* ((branch (vc-git-working-revision file))
 201          (def-ml (vc-default-mode-line-string 'Git file))
 202          (help-echo (get-text-property 0 'help-echo def-ml)))
 203     (if (zerop (length branch))
 204         (propertize
 205          (concat def-ml "!")
 206          'help-echo (concat help-echo "\nNo current branch (detached HEAD)"))
 207       (propertize def-ml
 208                   'help-echo (concat help-echo "\nCurrent branch: " branch)))))
 209
 210 (defstruct (vc-git-extra-fileinfo
 211             (:copier nil)
 212             (:constructor vc-git-create-extra-fileinfo (old-perm new-perm &optional rename-state orig-name))
 213             (:conc-name vc-git-extra-fileinfo->))
 214   old-perm new-perm   ;; permission flags
 215   rename-state        ;; rename or copy state
 216   orig-name)          ;; original name for renames or copies
 217
 218 (defun vc-git-escape-file-name (name)
 219   "Escape a file name if necessary."
 220   (if (string-match "[\n\t\"\\]" name)
 221       (concat "\""
 222               (mapconcat (lambda (c)
 223                    (case c
 224                      (?\n "\\n")
 225                      (?\t "\\t")
 226                      (?\\ "\\\\")
 227                      (?\" "\\\"")
 228                      (t (char-to-string c))))
 229                  name "")
 230               "\"")
 231     name))
 232
 233 (defun vc-git-file-type-as-string (old-perm new-perm)
 234   "Return a string describing the file type based on its permissions."
 235   (let* ((old-type (lsh (or old-perm 0) -9))
 236          (new-type (lsh (or new-perm 0) -9))
 237          (str (case new-type
 238                 (?\100  ;; file
 239                  (case old-type
 240                    (?\100 nil)
 241                    (?\120 "   (type change symlink -> file)")
 242                    (?\160 "   (type change subproject -> file)")))
 243                  (?\120  ;; symlink
 244                   (case old-type
 245                     (?\100 "   (type change file -> symlink)")
 246                     (?\160 "   (type change subproject -> symlink)")
 247                     (t "   (symlink)")))
 248                   (?\160  ;; subproject
 249                    (case old-type
 250                      (?\100 "   (type change file -> subproject)")
 251                      (?\120 "   (type change symlink -> subproject)")
 252                      (t "   (subproject)")))
 253                   (?\110 nil)  ;; directory (internal, not a real git state)
 254                   (?\000  ;; deleted or unknown
 255                    (case old-type
 256                      (?\120 "   (symlink)")
 257                      (?\160 "   (subproject)")))
 258                   (t (format "   (unknown type %o)" new-type)))))
 259     (cond (str (propertize str 'face 'font-lock-comment-face))
 260           ((eq new-type ?\110) "/")
 261           (t ""))))
 262
 263 (defun vc-git-rename-as-string (state extra)
 264   "Return a string describing the copy or rename associated with INFO, or an empty string if none."
 265   (let ((rename-state (when extra
 266                         (vc-git-extra-fileinfo->rename-state extra))))
 267     (if rename-state
 268         (propertize
 269          (concat "   ("
 270                  (if (eq rename-state 'copy) "copied from "
 271                    (if (eq state 'added) "renamed from "
 272                      "renamed to "))
 273                  (vc-git-escape-file-name (vc-git-extra-fileinfo->orig-name extra))
 274                  ")") 'face 'font-lock-comment-face)
 275       "")))
 276
 277 (defun vc-git-permissions-as-string (old-perm new-perm)
 278   "Format a permission change as string."
 279   (propertize
 280    (if (or (not old-perm)
 281            (not new-perm)
 282            (eq 0 (logand ?\111 (logxor old-perm new-perm))))
 283        "  "
 284      (if (eq 0 (logand ?\111 old-perm)) "+x" "-x"))
 285   'face 'font-lock-type-face))
 286
 287 (defun vc-git-dir-printer (info)
 288   "Pretty-printer for the vc-dir-fileinfo structure."
 289   (let* ((isdir (vc-dir-fileinfo->directory info))
 290          (state (if isdir "" (vc-dir-fileinfo->state info)))
 291          (extra (vc-dir-fileinfo->extra info))
 292          (old-perm (when extra (vc-git-extra-fileinfo->old-perm extra)))
 293          (new-perm (when extra (vc-git-extra-fileinfo->new-perm extra))))
 294     (insert
 295      "  "
 296      (propertize (format "%c" (if (vc-dir-fileinfo->marked info) ?* ? ))
 297                  'face 'font-lock-type-face)
 298      "  "
 299      (propertize
 300       (format "%-12s" state)
 301       'face (cond ((eq state 'up-to-date) 'font-lock-builtin-face)
 302                   ((eq state 'missing) 'font-lock-warning-face)
 303                   (t 'font-lock-variable-name-face))
 304       'mouse-face 'highlight)
 305      "  " (vc-git-permissions-as-string old-perm new-perm)
 306      "    "
 307      (propertize (vc-git-escape-file-name (vc-dir-fileinfo->name info))
 308                  'face (if isdir 'font-lock-comment-delimiter-face 'font-lock-function-name-face)
 309                  'help-echo
 310                  (if isdir
 311                      "Directory\nVC operations can be applied to it\nmouse-3: Pop-up menu"
 312                    "File\nmouse-3: Pop-up menu")
 313                  'keymap vc-dir-filename-mouse-map
 314                  'mouse-face 'highlight)
 315      (vc-git-file-type-as-string old-perm new-perm)
 316      (vc-git-rename-as-string state extra))))
 317
 318 (defun vc-git-after-dir-status-stage (stage files update-function)
 319   "Process sentinel for the various dir-status stages."
 320   (let (remaining next-stage result)
 321     (goto-char (point-min))
 322     (case stage
 323       ('update-index
 324        (setq next-stage (if (vc-git--empty-db-p) 'ls-files-added
 325                           (if files 'ls-files-up-to-date 'diff-index))))
 326       ('ls-files-added
 327        (setq next-stage 'ls-files-unknown)
 328        (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 329          (let ((new-perm (string-to-number (match-string 1) 8))
 330                (name (match-string 2)))
 331            (push (list name 'added (vc-git-create-extra-fileinfo 0 new-perm)) result))))
 332       ('ls-files-up-to-date
 333        (setq next-stage 'diff-index)
 334        (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 335          (let ((perm (string-to-number (match-string 1) 8))
 336                (name (match-string 2)))
 337            (push (list name 'up-to-date (vc-git-create-extra-fileinfo perm perm)) result))))
 338       ('ls-files-unknown
 339        (when files (setq next-stage 'ls-files-ignored))
 340        (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 341          (push (list (match-string 1) 'unregistered (vc-git-create-extra-fileinfo 0 0)) result)))
 342       ('ls-files-ignored
 343        (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 344          (push (list (match-string 1) 'ignored (vc-git-create-extra-fileinfo 0 0)) result)))
 345       ('diff-index
 346        (setq next-stage 'ls-files-unknown)
 347        (while (re-search-forward
 348                ":\\([0-7]\\{6\\}\\) \\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\(\\([ADMUT]\\)\0\\([^\0]+\\)\\|\\([CR]\\)[0-9]*\0\\([^\0]+\\)\0\\([^\0]+\\)\\)\0"
 349                nil t 1)
 350          (let ((old-perm (string-to-number (match-string 1) 8))
 351                (new-perm (string-to-number (match-string 2) 8))
 352                (state (or (match-string 4) (match-string 6)))
 353                (name (or (match-string 5) (match-string 7)))
 354                (new-name (match-string 8)))
 355            (if new-name  ; copy or rename
 356                (if (eq ?C (string-to-char state))
 357                    (push (list new-name 'added (vc-git-create-extra-fileinfo old-perm new-perm 'copy name)) result)
 358                  (push (list name 'removed (vc-git-create-extra-fileinfo 0 0 'rename new-name)) result)
 359                  (push (list new-name 'added (vc-git-create-extra-fileinfo old-perm new-perm 'rename name)) result))
 360              (push (list name (vc-git--state-code state) (vc-git-create-extra-fileinfo old-perm new-perm)) result))))))
 361     (when result
 362       (setq result (nreverse result))
 363       (when files
 364         (dolist (entry result) (setq files (delete (car entry) files)))
 365         (unless files (setq next-stage nil))))
 366     (when (or result (not next-stage)) (funcall update-function result next-stage))
 367     (when next-stage (vc-git-dir-status-goto-stage next-stage files update-function))))
 368
 369 (defun vc-git-dir-status-goto-stage (stage files update-function)
 370   (erase-buffer)
 371   (case stage
 372     ('update-index
 373      (if files
 374          (vc-git-command (current-buffer) 'async files "add" "--refresh" "--")
 375        (vc-git-command (current-buffer) 'async nil "update-index" "--refresh")))
 376     ('ls-files-added
 377      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-c" "-s" "--"))
 378     ('ls-files-up-to-date
 379      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-c" "-s" "--"))
 380     ('ls-files-unknown
 381      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-o"
 382                      "--directory" "--no-empty-directory" "--exclude-standard" "--"))
 383     ('ls-files-ignored
 384      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-o" "-i"
 385                      "--directory" "--no-empty-directory" "--exclude-standard" "--"))
 386     ('diff-index
 387      (vc-git-command (current-buffer) 'async files "diff-index" "-z" "-M" "HEAD" "--")))
 388   (vc-exec-after
 389    `(vc-git-after-dir-status-stage (quote ,stage) (quote ,files) (quote ,update-function))))
 390
 391 (defun vc-git-dir-status (dir update-function)
 392   "Return a list of (FILE STATE EXTRA) entries for DIR."
 393   ;; Further things that would have to be fixed later:
 394   ;; - how to handle unregistered directories
 395   ;; - how to support vc-dir on a subdir of the project tree
 396   (vc-git-dir-status-goto-stage 'update-index nil update-function))
 397
 398 (defun vc-git-dir-status-files (dir files default-state update-function)
 399   "Return a list of (FILE STATE EXTRA) entries for FILES in DIR."
 400   (vc-git-dir-status-goto-stage 'update-index files update-function))
 401
 402 (defun vc-git-dir-extra-headers (dir)
 403   (let ((str (with-output-to-string
 404                (with-current-buffer standard-output
 405                  (vc-git--out-ok "symbolic-ref" "HEAD"))))
 406         (stash (vc-git-stash-list)))
 407     ;; FIXME: maybe use a different face when nothing is stashed.
 408     (when (string= stash "") (setq stash "Nothing stashed"))
 409     (concat
 410      (propertize "Branch     : " 'face 'font-lock-type-face)
 411      (propertize
 412       (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 413           (match-string 2 str)
 414         "not (detached HEAD)")
 415        'face 'font-lock-variable-name-face)
 416      "\n"
 417      (propertize "Stash      : " 'face 'font-lock-type-face)
 418      (propertize
 419       stash
 420        'face 'font-lock-variable-name-face))))
 421
 422 ;;; STATE-CHANGING FUNCTIONS
 423
 424 (defun vc-git-create-repo ()
 425   "Create a new Git repository."
 426   (vc-git-command nil 0 nil "init"))
 427
 428 (defun vc-git-register (files &optional rev comment)
 429   "Register FILES into the git version-control system."
 430   (let (flist dlist)
 431     (dolist (crt files)
 432       (if (file-directory-p crt)
 433           (push crt dlist)
 434         (push crt flist)))
 435     (when flist
 436       (vc-git-command nil 0 flist "update-index" "--add" "--"))
 437     (when dlist
 438       (vc-git-command nil 0 dlist "add"))))
 439
 440 (defalias 'vc-git-responsible-p 'vc-git-root)
 441
 442 (defun vc-git-unregister (file)
 443   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 444
 445
 446 (defun vc-git-checkin (files rev comment)
 447   (let ((coding-system-for-write git-commits-coding-system))
 448     (vc-git-command nil 0 files "commit"
 449                     (if vc-git-add-signoff "-s") "-m" comment "--only" "--")))
 450
 451 (defun vc-git-find-revision (file rev buffer)
 452   (let* (process-file-side-effects
 453          (coding-system-for-read 'binary)
 454          (coding-system-for-write 'binary)
 455          (fullname (substring
 456                     (vc-git--run-command-string
 457                      file "ls-files" "-z" "--full-name" "--")
 458                     0 -1)))
 459     (vc-git-command
 460      buffer 0
 461      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 462
 463 (defun vc-git-checkout (file &optional editable rev)
 464   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 465
 466 (defun vc-git-revert (file &optional contents-done)
 467   "Revert FILE to the version stored in the git repository."
 468   (if contents-done
 469       (vc-git-command nil 0 file "update-index" "--")
 470     (vc-git-command nil 0 file "checkout" "HEAD")))
 471
 472 ;;; HISTORY FUNCTIONS
 473
 474 (defun vc-git-print-log (files &optional buffer)
 475   "Get change log associated with FILES."
 476   (let ((coding-system-for-read git-commits-coding-system)
 477         ;; Support both the old print-log interface that passes a
 478         ;; single file, and the new one that passes a file list.
 479         (flist (if (listp files) files (list files))))
 480     ;; `vc-do-command' creates the buffer, but we need it before running
 481     ;; the command.
 482     (vc-setup-buffer buffer)
 483     ;; If the buffer exists from a previous invocation it might be
 484     ;; read-only.
 485     (let ((inhibit-read-only t))
 486       (with-current-buffer
 487           buffer
 488         (vc-git-command buffer 'async files
 489                         "rev-list" "--pretty" "HEAD" "--")))))
 490
 491 (defvar log-view-message-re)
 492 (defvar log-view-file-re)
 493 (defvar log-view-font-lock-keywords)
 494 (defvar log-view-per-file-logs)
 495
 496 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 497   (require 'add-log) ;; we need the faces add-log
 498   ;; Don't have file markers, so use impossible regexp.
 499   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 500   (set (make-local-variable 'log-view-per-file-logs) nil)
 501   (set (make-local-variable 'log-view-message-re)
 502        "^commit *\\([0-9a-z]+\\)")
 503   (set (make-local-variable 'log-view-font-lock-keywords)
 504        (append
 505         `((,log-view-message-re  (1 'change-log-acknowledgement)))
 506         ;; Handle the case:
 507         ;; user: foo@bar
 508         '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 509            (1 'change-log-email))
 510           ;; Handle the case:
 511           ;; user: FirstName LastName <foo@bar>
 512           ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 513            (1 'change-log-name)
 514            (2 'change-log-email))
 515           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 516            (1 'change-log-name))
 517           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 518            (1 'change-log-name)
 519            (2 'change-log-email))
 520           ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
 521            (1 'change-log-acknowledgement)
 522            (2 'change-log-acknowledgement))
 523           ("^Date:   \\(.+\\)" (1 'change-log-date))
 524           ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 525
 526 (defun vc-git-show-log-entry (revision)
 527   "Move to the log entry for REVISION.
 528 REVISION may have the form BRANCH, BRANCH~N,
 529 or BRANCH^ (where \"^\" can be repeated)."
 530   (goto-char (point-min))
 531   (when revision
 532     (search-forward (format "\ncommit %s" revision) nil t
 533                     (cond ((string-match "~\\([0-9]\\)$" revision)
 534                            (1+ (string-to-number (match-string 1 revision))))
 535                           ((string-match "\\^+$" revision)
 536                            (1+ (length (match-string 0 revision))))
 537                           (t nil))))
 538   (beginning-of-line))
 539
 540 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 541   "Get a difference report using Git between two revisions of FILES."
 542   (let (process-file-side-effects)
 543     (apply #'vc-git-command (or buffer "*vc-diff*") 1 files
 544            (if (and rev1 rev2) "diff-tree" "diff-index")
 545            "--exit-code"
 546            (append (vc-switches 'git 'diff)
 547                    (list "-p" (or rev1 "HEAD") rev2 "--")))))
 548
 549 (defun vc-git-revision-table (files)
 550   ;; What about `files'?!?  --Stef
 551   (let (process-file-side-effects
 552         (table (list "HEAD")))
 553     (with-temp-buffer
 554       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
 555       (goto-char (point-min))
 556       (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
 557         (push (match-string 2) table)))
 558     table))
 559
 560 (defun vc-git-revision-completion-table (files)
 561   (lexical-let ((files files)
 562                 table)
 563     (setq table (lazy-completion-table
 564                  table (lambda () (vc-git-revision-table files))))
 565     table))
 566
 567 (defun vc-git-annotate-command (file buf &optional rev)
 568   (let ((name (file-relative-name file)))
 569     (vc-git-command buf 'async name "blame" "--date=iso" rev "--")))
 570
 571 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 572
 573 (defun vc-git-annotate-time ()
 574   (and (re-search-forward "[0-9a-f]+[^()]+(.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+) " nil t)
 575        (vc-annotate-convert-time
 576         (apply #'encode-time (mapcar (lambda (match)
 577                                        (string-to-number (match-string match)))
 578                                      '(6 5 4 3 2 1 7))))))
 579
 580 (defun vc-git-annotate-extract-revision-at-line ()
 581   (save-excursion
 582     (move-beginning-of-line 1)
 583     (and (looking-at "[0-9a-f^][0-9a-f]+")
 584          (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
 585
 586 ;;; TAG SYSTEM
 587
 588 (defun vc-git-create-tag (dir name branchp)
 589   (let ((default-directory dir))
 590     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 591          (if branchp
 592              (vc-git-command nil 0 nil "checkout" "-b" name)
 593            (vc-git-command nil 0 nil "tag" name)))))
 594
 595 (defun vc-git-retrieve-tag (dir name update)
 596   (let ((default-directory dir))
 597     (vc-git-command nil 0 nil "checkout" name)
 598     ;; FIXME: update buffers if `update' is true
 599     ))
 600
 601
 602 ;;; MISCELLANEOUS
 603
 604 (defun vc-git-previous-revision (file rev)
 605   "Git-specific version of `vc-previous-revision'."
 606   (if file
 607       (let* ((default-directory (file-name-directory (expand-file-name file)))
 608              (file (file-name-nondirectory file))
 609              (prev-rev (with-temp-buffer
 610                          (and
 611                           (vc-git--out-ok "rev-list" "-2" rev "--" file)
 612                           (goto-char (point-max))
 613                           (bolp)
 614                           (zerop (forward-line -1))
 615                           (not (bobp))
 616                           (buffer-substring-no-properties
 617                            (point)
 618                            (1- (point-max)))))))
 619         (or (vc-git-symbolic-commit prev-rev) prev-rev))
 620     (with-temp-buffer
 621       (and
 622        (vc-git--out-ok "rev-parse" (concat rev "^"))
 623        (buffer-substring-no-properties (point-min) (+ (point-min) 40))))))
 624
 625 (defun vc-git-next-revision (file rev)
 626   "Git-specific version of `vc-next-revision'."
 627   (let* ((default-directory (file-name-directory
 628                              (expand-file-name file)))
 629          (file (file-name-nondirectory file))
 630          (current-rev
 631           (with-temp-buffer
 632             (and
 633              (vc-git--out-ok "rev-list" "-1" rev "--" file)
 634              (goto-char (point-max))
 635              (bolp)
 636              (zerop (forward-line -1))
 637              (bobp)
 638              (buffer-substring-no-properties
 639               (point)
 640               (1- (point-max))))))
 641          (next-rev
 642           (and current-rev
 643                (with-temp-buffer
 644                  (and
 645                   (vc-git--out-ok "rev-list" "HEAD" "--" file)
 646                   (goto-char (point-min))
 647                   (search-forward current-rev nil t)
 648                   (zerop (forward-line -1))
 649                   (buffer-substring-no-properties
 650                    (point)
 651                    (progn (forward-line 1) (1- (point)))))))))
 652     (or (vc-git-symbolic-commit next-rev) next-rev)))
 653
 654 (defun vc-git-delete-file (file)
 655   (vc-git-command nil 0 file "rm" "-f" "--"))
 656
 657 (defun vc-git-rename-file (old new)
 658   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 659
 660 (defvar vc-git-extra-menu-map
 661   (let ((map (make-sparse-keymap)))
 662     (define-key map [git-grep]
 663       '(menu-item "Git grep..." vc-git-grep
 664                   :help "Run the `git grep' command"))
 665     (define-key map [git-st]
 666       '(menu-item "Stash..." vc-git-stash
 667                   :help "Stash away changes"))
 668     (define-key map [git-ss]
 669       '(menu-item "Show Stash..." vc-git-stash-show
 670                   :help "Show stash contents"))
 671     (define-key map [git-sig]
 672       '(menu-item "Add Signed-off-by on commit" vc-git-toggle-signoff
 673               :help "Add Add Signed-off-by when commiting (i.e. add the -s flag)"
 674               :button (:toggle . vc-git-add-signoff)))
 675     map))
 676
 677 (defun vc-git-extra-menu () vc-git-extra-menu-map)
 678
 679 (defun vc-git-extra-status-menu () vc-git-extra-menu-map)
 680
 681 (defun vc-git-toggle-signoff ()
 682   (interactive)
 683   (setq vc-git-add-signoff (not vc-git-add-signoff)))
 684
 685 ;; Derived from `lgrep'.
 686 (defun vc-git-grep (regexp &optional files dir)
 687   "Run git grep, searching for REGEXP in FILES in directory DIR.
 688 The search is limited to file names matching shell pattern FILES.
 689 FILES may use abbreviations defined in `grep-files-aliases', e.g.
 690 entering `ch' is equivalent to `*.[ch]'.
 691
 692 With \\[universal-argument] prefix, you can edit the constructed shell command line
 693 before it is executed.
 694 With two \\[universal-argument] prefixes, directly edit and run `grep-command'.
 695
 696 Collect output in a buffer.  While git grep runs asynchronously, you
 697 can use \\[next-error] (M-x next-error), or \\<grep-mode-map>\\[compile-goto-error] \
 698 in the grep output buffer,
 699 to go to the lines where grep found matches.
 700
 701 This command shares argument histories with \\[rgrep] and \\[grep]."
 702   (interactive
 703    (progn
 704      (grep-compute-defaults)
 705      (cond
 706       ((equal current-prefix-arg '(16))
 707        (list (read-from-minibuffer "Run: " "git grep"
 708                                    nil nil 'grep-history)
 709              nil))
 710       (t (let* ((regexp (grep-read-regexp))
 711                 (files (grep-read-files regexp))
 712                 (dir (read-directory-name "In directory: "
 713                                           nil default-directory t)))
 714            (list regexp files dir))))))
 715   (require 'grep)
 716   (when (and (stringp regexp) (> (length regexp) 0))
 717     (let ((command regexp))
 718       (if (null files)
 719           (if (string= command "git grep")
 720               (setq command nil))
 721         (setq dir (file-name-as-directory (expand-file-name dir)))
 722         (setq command
 723               (grep-expand-template "git grep -n -e <R> -- <F>" regexp files))
 724         (when command
 725           (if (equal current-prefix-arg '(4))
 726               (setq command
 727                     (read-from-minibuffer "Confirm: "
 728                                           command nil nil 'grep-history))
 729             (add-to-history 'grep-history command))))
 730       (when command
 731         (let ((default-directory dir)
 732               (compilation-environment '("PAGER=")))
 733           ;; Setting process-setup-function makes exit-message-function work
 734           ;; even when async processes aren't supported.
 735           (compilation-start command 'grep-mode))
 736         (if (eq next-error-last-buffer (current-buffer))
 737             (setq default-directory dir))))))
 738
 739 (defun vc-git-stash (name)
 740   "Create a stash."
 741   (interactive "sStash name: ")
 742   (let ((root (vc-git-root default-directory)))
 743     (when root
 744       (vc-git--call nil "stash" "save" name)
 745       (vc-resynch-buffer root t t))))
 746
 747 (defun vc-git-stash-show (name)
 748   "Show the contents of stash NAME."
 749   (interactive "sStash name: ")
 750   (vc-setup-buffer "*vc-git-stash*")
 751   (vc-git-command "*vc-git-stash*" 'async nil "stash" "show" "-p" name)
 752   (set-buffer "*vc-git-stash*")
 753   (diff-mode)
 754   (setq buffer-read-only t)
 755   (pop-to-buffer (current-buffer)))
 756
 757 (defun vc-git-stash-list ()
 758   (replace-regexp-in-string
 759    "\n" "\n             "
 760    (replace-regexp-in-string
 761     "^stash@" "" (vc-git--run-command-string nil "stash" "list"))))
 762
 763 \f
 764 ;;; Internal commands
 765
 766 (defun vc-git-root (file)
 767   (vc-find-root file ".git"))
 768
 769 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 770   "A wrapper around `vc-do-command' for use in vc-git.el.
 771 The difference to vc-do-command is that this function always invokes `git'."
 772   (apply 'vc-do-command (or buffer "*vc*") okstatus "git" file-or-list flags))
 773
 774 (defun vc-git--empty-db-p ()
 775   "Check if the git db is empty (no commit done yet)."
 776   (let (process-file-side-effects)
 777     (not (eq 0 (vc-git--call nil "rev-parse" "--verify" "HEAD")))))
 778
 779 (defun vc-git--call (buffer command &rest args)
 780   ;; We don't need to care the arguments.  If there is a file name, it
 781   ;; is always a relative one.  This works also for remote
 782   ;; directories.
 783   (apply 'process-file "git" nil buffer nil command args))
 784
 785 (defun vc-git--out-ok (command &rest args)
 786   (zerop (apply 'vc-git--call '(t nil) command args)))
 787
 788 (defun vc-git--run-command-string (file &rest args)
 789   "Run a git command on FILE and return its output as string.
 790 FILE can be nil."
 791   (let* ((ok t)
 792          (str (with-output-to-string
 793                 (with-current-buffer standard-output
 794                   (unless (apply 'vc-git--out-ok
 795                                  (if file
 796                                      (append args (list (file-relative-name
 797                                                          file)))
 798                                    args))
 799                     (setq ok nil))))))
 800     (and ok str)))
 801
 802 (defun vc-git-symbolic-commit (commit)
 803   "Translate COMMIT string into symbolic form.
 804 Returns nil if not possible."
 805   (and commit
 806        (let ((name (with-temp-buffer
 807                      (and
 808                       (vc-git--out-ok "name-rev" "--name-only" commit)
 809                       (goto-char (point-min))
 810                       (= (forward-line 2) 1)
 811                       (bolp)
 812                       (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 813          (and name (not (string= name "undefined")) name))))
 814
 815 (provide 'vc-git)
 816
 817 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 818 ;;; vc-git.el ends here