configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2014 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.3.50)
  26
  27 dnl We get MINGW64 with MSYS2
  28 if test "x$MSYSTEM" = "xMINGW32" -o "x$MSYSTEM" = "xMINGW64"
  29 then
  30   . $srcdir/nt/mingw-cfg.site
  31
  32   case $srcdir in
  33     /* | ?:*)
  34       # srcdir is an absolute path.  In this case, force the format
  35       # "/c/foo/bar", to simplify later conversions to native Windows
  36       # format ("c:/foo/bar")
  37       srcdir=`cd "${srcdir}" && pwd -W`
  38       srcdir="/${srcdir:0:1}${srcdir:2}"
  39       ;;
  40   esac
  41 fi
  42
  43 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  44 dnl and then quoted again for a C string.  Separate options with spaces.
  45 dnl Add some environment variables, if they were passed via the environment
  46 dnl rather than on the command-line.
  47 emacs_config_options=
  48 optsep=
  49 dnl This is the documented way to record the args passed to configure,
  50 dnl rather than $ac_configure_args.
  51 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  52   case $opt in
  53     -n | --no-create | --no-recursion)
  54       continue ;;
  55     CFLAGS | CPPFLAGS | LDFLAGS)
  56       eval 'test "${'$opt'+set}" = set' || continue
  57       case " $*" in
  58         *" $opt="*) continue ;;
  59       esac
  60       eval opt=$opt=\$$opt ;;
  61   esac
  62
  63   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  64   case $opt in
  65     *[["$emacs_shell_specials"]]*)
  66       case $opt in
  67         *\'*)
  68           emacs_quote_apostrophes="s/'/'\\\\''/g"
  69           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  70       esac
  71       opt="'$opt'"
  72       case $opt in
  73         *[['"\\']]*)
  74           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  75           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  76       esac ;;
  77   esac
  78   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  79   optsep=' '
  80 done
  81
  82 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  83 AC_CONFIG_SRCDIR(src/lisp.h)
  84 AC_CONFIG_AUX_DIR(build-aux)
  85
  86 xcsdkdir=
  87 AC_CHECK_PROGS(XCRUN, [xcrun])
  88 if test -n "$XCRUN"; then
  89   if test -z "$MAKE"; then
  90     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  91     dnl SET_MAKE and with the usual MAKE variable that 'make' itself uses.
  92     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  93     if test -z "$MAKE_PROG"; then
  94       MAKE="$XCRUN MAKE"
  95       export MAKE
  96       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  97     fi
  98   fi
  99 fi
 100
 101 dnl Fairly arbitrary, older versions might work too.
 102 AM_INIT_AUTOMAKE(1.11)
 103
 104 dnl Support for --program-prefix, --program-suffix and
 105 dnl --program-transform-name options
 106 AC_ARG_PROGRAM
 107
 108 dnl It is important that variables on the RHS not be expanded here,
 109 dnl hence the single quotes.  This is per the GNU coding standards, see
 110 dnl (autoconf) Installation Directory Variables
 111 dnl See also epaths.h below.
 112 lispdir='${datadir}/emacs/${version}/lisp'
 113 standardlisppath='${lispdir}'
 114 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 115 '${datadir}/emacs/site-lisp'
 116 lisppath='${locallisppath}:${standardlisppath}'
 117 etcdir='${datadir}/emacs/${version}/etc'
 118 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 119 etcdocdir='${datadir}/emacs/${version}/etc'
 120 gamedir='${localstatedir}/games/emacs'
 121
 122 dnl Special option to disable the most of other options.
 123 AC_ARG_WITH(all,
 124 [AS_HELP_STRING([--without-all],
 125                 [omit almost all features and build
 126                 small executable with minimal dependencies])],
 127   [with_features=$withval],
 128   [with_features=yes])
 129
 130 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 131 dnl Create a new --with option that defaults to being disabled.
 132 dnl NAME is the base name of the option.  The shell variable with_NAME
 133 dnl   will be set to either the user's value (if the option is
 134 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 135 dnl   option is not specified).  Note that the shell variable name is
 136 dnl   constructed as autoconf does, by replacing non-alphanumeric
 137 dnl   characters with "_".
 138 dnl HELP-STRING is the help text for the option.
 139 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 140   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 141     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 142 ])dnl
 143
 144 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 145 dnl Create a new --with option that defaults to $with_features.
 146 dnl NAME is the base name of the option.  The shell variable with_NAME
 147 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 148 dnl   'yes' (if the option is not specified).  Note that the shell
 149 dnl   variable name is constructed as autoconf does, by replacing
 150 dnl   non-alphanumeric characters with "_".
 151 dnl HELP-STRING is the help text for the option.
 152 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 153   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 154    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 155 ])dnl
 156
 157 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 158 if test "$with_pop" = yes; then
 159    AC_DEFINE(MAIL_USE_POP)
 160 fi
 161 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 162
 163 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 164 if test "$with_kerberos" != no; then
 165    AC_DEFINE(KERBEROS)
 166 fi
 167 AH_TEMPLATE(KERBEROS,
 168             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 169
 170 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 171 if test "${with_kerberos5}" != no; then
 172   if test "${with_kerberos}" = no; then
 173     with_kerberos=yes
 174     AC_DEFINE(KERBEROS)
 175   fi
 176   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 177 fi
 178
 179 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 180 dnl FIXME hesiod support may not be present, so it seems like an error
 181 dnl to define, or at least use, this unconditionally.
 182 if test "$with_hesiod" != no; then
 183   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 184 fi
 185
 186 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 187 if test "$with_mmdf" != no; then
 188    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 189 fi
 190
 191 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 192 if test "$with_mail_unlink" != no; then
 193    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 194 fi
 195
 196 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 197     [string giving default POP mail host])],
 198     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 199
 200 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 201   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 202 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW.])],
 203   [ case "${withval}" in
 204       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 205       *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
 206 this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
 207       ;;
 208     esac
 209     with_sound=$val
 210   ],
 211   [with_sound=$with_features])
 212
 213 dnl FIXME currently it is not the last.
 214 dnl This should be the last --with option, because --with-x is
 215 dnl added later on when we find the file name of X, and it's best to
 216 dnl keep them together visually.
 217 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 218  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 219 [         case "${withval}" in
 220             y | ye | yes )      val=gtk ;;
 221             n | no )            val=no  ;;
 222             l | lu | luc | luci | lucid )       val=lucid ;;
 223             a | at | ath | athe | athen | athena )      val=athena ;;
 224             m | mo | mot | moti | motif )       val=motif ;;
 225             g | gt | gtk  )     val=gtk ;;
 226             gtk2  )     val=gtk2 ;;
 227             gtk3  )     val=gtk3 ;;
 228             * )
 229 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 230 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 231 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 232 `athena' and `lucid' are synonyms.])
 233             ;;
 234           esac
 235           with_x_toolkit=$val
 236 ])
 237
 238 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 239 if test "$with_wide_int" = yes; then
 240   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 241 fi
 242
 243 dnl _ON results in a '--without' option in the --help output, so
 244 dnl the help text should refer to "don't compile", etc.
 245 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 246 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 247 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 248 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 249 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 250 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 251 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 252 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 253
 254 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 255 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 256 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 257
 258 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 259 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 260 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 261 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 262 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 263
 264 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 265 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 266 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 267 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 268 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 269 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 270 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 271
 272 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 273  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 274  [ case "${withval}" in
 275     y | ye | yes )      val=yes ;;
 276     n | no )            val=no  ;;
 277     g | gf | gfi | gfil | gfile )       val=gfile ;;
 278     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 279     w | w3 | w32 )      val=w32 ;;
 280     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 281 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 282 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
 283 otherwise for the first of `gfile' or `inotify' that is usable.])
 284     ;;
 285    esac
 286    with_file_notification=$val
 287  ],
 288  [with_file_notification=$with_features])
 289
 290 ## For the times when you want to build Emacs but don't have
 291 ## a suitable makeinfo, and can live without the manuals.
 292 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 293 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 294
 295 ## Makefile.in needs the cache file name.
 296 AC_SUBST(cache_file)
 297
 298 ## This is an option because I do not know if all info/man support
 299 ## compressed files, nor how to test if they do so.
 300 OPTION_DEFAULT_ON([compress-install],
 301   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 302 make GZIP_PROG= install])
 303
 304 AC_ARG_WITH([pkg-config-prog],dnl
 305 [AS_HELP_STRING([--with-pkg-config-prog=FILENAME],
 306                   [file name of pkg-config for finding GTK and librsvg])])
 307 if test "X${with_pkg_config_prog}" != X; then
 308    if test "${with_pkg_config_prog}" != yes; then
 309       PKG_CONFIG="${with_pkg_config_prog}"
 310    fi
 311 fi
 312
 313 AC_ARG_WITH(gameuser,dnl
 314 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 315 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 316   && gameuser="${with_gameuser}"
 317 test "X$gameuser" = X && gameuser=games
 318
 319 AC_ARG_WITH([gnustep-conf],dnl
 320 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 321    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 322 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 323   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 324 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 325      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 326
 327 AC_ARG_ENABLE(ns-self-contained,
 328 [AS_HELP_STRING([--disable-ns-self-contained],
 329                 [disable self contained build under NeXTstep])],
 330    EN_NS_SELF_CONTAINED=$enableval,
 331    EN_NS_SELF_CONTAINED=yes)
 332
 333 AC_ARG_ENABLE(locallisppath,
 334 [AS_HELP_STRING([--enable-locallisppath=PATH],
 335                 [directories Emacs should search for lisp files specific
 336                  to this site])],
 337 if test "${enableval}" = "no"; then
 338   locallisppath=
 339 elif test "${enableval}" != "yes"; then
 340   locallisppath=${enableval}
 341 fi)
 342
 343 AC_ARG_ENABLE(checking,
 344 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 345                 [enable expensive run-time checks.  With LIST,
 346                  enable only specific categories of checks.
 347                  Categories are: all,yes,no.
 348                  Flags are: stringbytes, stringoverrun, stringfreelist,
 349                  xmallocoverrun, conslist, glyphs])],
 350 [ac_checking_flags="${enableval}"],[])
 351 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 352 for check in $ac_checking_flags
 353 do
 354         case $check in
 355         # these set all the flags to specific states
 356         yes)            ac_enable_checking=1 ;;
 357         no)             ac_enable_checking= ;
 358                         ac_gc_check_stringbytes= ;
 359                         ac_gc_check_string_overrun= ;
 360                         ac_gc_check_string_free_list= ;
 361                         ac_xmalloc_overrun= ;
 362                         ac_gc_check_cons_list= ;
 363                         ac_glyphs_debug= ;;
 364         all)            ac_enable_checking=1 ;
 365                         ac_gc_check_stringbytes=1 ;
 366                         ac_gc_check_string_overrun=1 ;
 367                         ac_gc_check_string_free_list=1 ;
 368                         ac_xmalloc_overrun=1 ;
 369                         ac_gc_check_cons_list=1 ;
 370                         ac_glyphs_debug=1 ;;
 371         # these enable particular checks
 372         stringbytes)    ac_gc_check_stringbytes=1 ;;
 373         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 374         stringfreelist) ac_gc_check_string_free_list=1 ;;
 375         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 376         conslist)       ac_gc_check_cons_list=1 ;;
 377         glyphs)         ac_glyphs_debug=1 ;;
 378         *)      AC_MSG_ERROR(unknown check category $check) ;;
 379         esac
 380 done
 381 IFS="$ac_save_IFS"
 382
 383 if test x$ac_enable_checking != x ; then
 384   AC_DEFINE(ENABLE_CHECKING, 1,
 385 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 386 fi
 387 if test x$ac_gc_check_stringbytes != x ; then
 388   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 389 [Define this temporarily to hunt a bug.  If defined, the size of
 390    strings is redundantly recorded in sdata structures so that it can
 391    be compared to the sizes recorded in Lisp strings.])
 392 fi
 393 if test x$ac_gc_check_string_overrun != x ; then
 394   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 395 [Define this to check for short string overrun.])
 396 fi
 397 if test x$ac_gc_check_string_free_list != x ; then
 398   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 399 [Define this to check the string free list.])
 400 fi
 401 if test x$ac_xmalloc_overrun != x ; then
 402   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 403 [Define this to check for malloc buffer overrun.])
 404 fi
 405 if test x$ac_gc_check_cons_list != x ; then
 406   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 407 [Define this to check for errors in cons list.])
 408 fi
 409 if test x$ac_glyphs_debug != x ; then
 410   AC_DEFINE(GLYPH_DEBUG, 1,
 411 [Define this to enable glyphs debugging code.])
 412 fi
 413
 414 AC_ARG_ENABLE(check-lisp-object-type,
 415 [AS_HELP_STRING([--enable-check-lisp-object-type],
 416                 [enable compile time checks for the Lisp_Object data type.
 417                 This is useful for development for catching certain types of bugs.])],
 418 if test "${enableval}" != "no"; then
 419    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 420    [Define this to enable compile time checks for the Lisp_Object data type.])
 421 fi)
 422
 423
 424 dnl The name of this option is unfortunate.  It predates, and has no
 425 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 426 dnl Actually, it stops it working.
 427 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 428 AC_ARG_ENABLE(profiling,
 429 [AS_HELP_STRING([--enable-profiling],
 430                 [build emacs with low-level, gprof profiling support.
 431                 Mainly useful for debugging Emacs itself.  May not work on
 432                 all platforms.  Stops profiler.el working.])],
 433 [ac_enable_profiling="${enableval}"],[])
 434 if test x$ac_enable_profiling != x ; then
 435    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 436 else
 437    PROFILING_CFLAGS=
 438 fi
 439 AC_SUBST(PROFILING_CFLAGS)
 440
 441 AC_ARG_ENABLE(autodepend,
 442 [AS_HELP_STRING([--enable-autodepend],
 443                 [automatically generate dependencies to .h-files.
 444                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 445                  found])],
 446 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 447
 448 AC_ARG_ENABLE(gtk-deprecation-warnings,
 449 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 450                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 451 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 452
 453 ### Canonicalize the configuration name.
 454
 455 AC_CANONICAL_HOST
 456 canonical=$host
 457 configuration=${host_alias-${build_alias-$host}}
 458
 459 dnl This used to use changequote, but, apart from `changequote is evil'
 460 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 461 dnl the great gob of text.  Thus it's not processed for possible expansion.
 462 dnl Just make sure the brackets remain balanced.
 463 dnl
 464 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 465 dnl indicated by comments.
 466 dnl quotation begins
 467 [
 468
 469 ### If you add support for a new configuration, add code to this
 470 ### switch statement to recognize your configuration name and select
 471 ### the appropriate operating system file.
 472
 473 ### You would hope that you could choose an s/*.h
 474 ### file based on the operating system portion.  However, it turns out
 475 ### that each s/*.h file is pretty manufacturer-specific.
 476 ### So we basically have to have a special case for each
 477 ### configuration name.
 478 ###
 479 ### As far as handling version numbers on operating systems is
 480 ### concerned, make sure things will fail in a fixable way.  If
 481 ### /etc/MACHINES doesn't say anything about version numbers, be
 482 ### prepared to handle anything reasonably.  If version numbers
 483 ### matter, be sure /etc/MACHINES says something about it.
 484
 485 opsys='' unported=no
 486 case "${canonical}" in
 487
 488   ## GNU/Linux and similar ports
 489   *-*-linux* )
 490     opsys=gnu-linux
 491   ;;
 492
 493   ## FreeBSD ports
 494   *-*-freebsd* )
 495     opsys=freebsd
 496   ;;
 497
 498   ## DragonFly ports
 499   *-*-dragonfly* )
 500     opsys=dragonfly
 501   ;;
 502
 503   ## FreeBSD kernel + glibc based userland
 504   *-*-kfreebsd*gnu* )
 505     opsys=gnu-kfreebsd
 506   ;;
 507
 508   ## NetBSD ports
 509   *-*-netbsd* )
 510     opsys=netbsd
 511   ;;
 512
 513   ## OpenBSD ports
 514   *-*-openbsd* )
 515     opsys=openbsd
 516   ;;
 517
 518   ## Apple Darwin / Mac OS X
 519   *-apple-darwin* )
 520     case "${canonical}" in
 521       i[3456]86-* )  ;;
 522       powerpc-* )    ;;
 523       x86_64-* )     ;;
 524       * )            unported=yes ;;
 525     esac
 526     opsys=darwin
 527     ## Use fink packages if available.
 528     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 529 ##    if test -d /sw/include && test -d /sw/lib; then
 530 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 531 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 532 ##    fi
 533   ;;
 534
 535   ## Cygwin ports
 536   *-*-cygwin )
 537     opsys=cygwin
 538   ;;
 539
 540   ## HP 9000 series 700 and 800, running HP/UX
 541   hppa*-hp-hpux10.2* )
 542     opsys=hpux10-20
 543   ;;
 544   hppa*-hp-hpux1[1-9]* )
 545     opsys=hpux11
 546     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 547   ;;
 548
 549   ## IBM machines
 550   rs6000-ibm-aix4.[23]* )
 551     opsys=aix4-2
 552   ;;
 553   powerpc-ibm-aix4.[23]*  )
 554     opsys=aix4-2
 555   ;;
 556   rs6000-ibm-aix[56]* )
 557     opsys=aix4-2
 558   ;;
 559   powerpc-ibm-aix[56]*  )
 560     opsys=aix4-2
 561   ;;
 562
 563   ## Silicon Graphics machines
 564   ## Iris 4D
 565   mips-sgi-irix6.5 )
 566     opsys=irix6-5
 567     # Without defining _LANGUAGE_C, things get masked out in the headers
 568     # so that, for instance, grepping for `free' in stdlib.h fails and
 569     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 570     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 571   ;;
 572
 573   ## Suns
 574   *-sun-solaris* \
 575     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 576     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 577     case "${canonical}" in
 578       i[3456]86-*-* )   ;;
 579       amd64-*-*|x86_64-*-*) ;;
 580       sparc* )          ;;
 581       * )               unported=yes ;;
 582     esac
 583     case "${canonical}" in
 584       *-sunos5.6* | *-solaris2.6* )
 585                 opsys=sol2-6
 586                 RANLIB="ar -ts"
 587                 ;;
 588       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 589                 opsys=sol2-6
 590                 emacs_check_sunpro_c=yes
 591                 ;;
 592       *-sunos5* | *-solaris* )
 593                 opsys=sol2-10
 594                 emacs_check_sunpro_c=yes
 595                 ;;
 596     esac
 597     ## Watch out for a compiler that we know will not work.
 598     case "${canonical}" in
 599      *-solaris* | *-sunos5* )
 600                 if [ "x$CC" = x/usr/ucb/cc ]; then
 601                   ## /usr/ucb/cc doesn't work;
 602                   ## we should find some other compiler that does work.
 603                   unset CC
 604                 fi
 605                 ;;
 606       *) ;;
 607     esac
 608   ;;
 609
 610   ## Intel 386 machines where we don't care about the manufacturer.
 611   i[3456]86-*-* )
 612     case "${canonical}" in
 613       *-darwin* )               opsys=darwin ;;
 614       *-mingw32 )
 615                 opsys=mingw32
 616                 # MinGW overrides and adds some system headers in nt/inc.
 617                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 618                 ;;
 619       *-sysv4.2uw* )            opsys=unixware ;;
 620       *-sysv5uw* )              opsys=unixware ;;
 621       *-sysv5OpenUNIX* )        opsys=unixware ;;
 622       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 623     esac
 624   ;;
 625
 626   # MinGW64
 627   x86_64-*-* )
 628     case "${canonical}" in
 629       *-mingw32 )
 630                 opsys=mingw32
 631                 # MinGW overrides and adds some system headers in nt/inc.
 632                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 633                 ;;
 634       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 635     esac
 636   ;;
 637
 638   * )
 639     unported=yes
 640   ;;
 641 esac
 642
 643 ### If the code above didn't choose an operating system, just choose
 644 ### an operating system based on the configuration name.  You really
 645 ### only want to use this when you have no idea what the right
 646 ### operating system is; if you know what operating systems a machine
 647 ### runs, it's cleaner to make it explicit in the case statement
 648 ### above.
 649 if test x"${opsys}" = x; then
 650   case "${canonical}" in
 651     *-gnu* )                            opsys=gnu ;;
 652     * )
 653       unported=yes
 654     ;;
 655   esac
 656 fi
 657
 658 ]
 659 dnl quotation ends
 660
 661 if test $unported = yes; then
 662   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 663 Check `etc/MACHINES' for recognized configuration names.])
 664 fi
 665
 666
 667 #### Choose a compiler.
 668
 669 dnl Sets GCC=yes if using gcc.
 670 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 671 if test -n "$XCRUN"; then
 672   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 673   test -n "$AR" && export AR
 674 fi
 675
 676 AM_PROG_CC_C_O
 677
 678 if test x$GCC = xyes; then
 679   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 680 else
 681   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 682 fi
 683
 684 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 685 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 686 dnl that clash with MinGW.
 687 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 688
 689 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 690 AC_DEFUN([gl_CRYPTO_CHECK])
 691 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 692 # as we don't use them.
 693 AC_DEFUN([gl_FCNTL_O_FLAGS])
 694 # Avoid gnulib's threadlib module, as we do threads our own way.
 695 AC_DEFUN([gl_THREADLIB])
 696
 697 # Initialize gnulib right after choosing the compiler.
 698 dnl Amongst other things, this sets AR and ARFLAGS.
 699 gl_EARLY
 700
 701 if test "$ac_test_CFLAGS" != set; then
 702   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 703   # if -g3 works and the user does not specify CFLAGS.
 704   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 705   case $CFLAGS in
 706     '-g')
 707       emacs_g3_CFLAGS='-g3';;
 708     '-g -O2')
 709       emacs_g3_CFLAGS='-g3 -O2';;
 710     *)
 711       emacs_g3_CFLAGS='';;
 712   esac
 713   if test -n "$emacs_g3_CFLAGS"; then
 714     emacs_save_CFLAGS=$CFLAGS
 715     CFLAGS=$emacs_g3_CFLAGS
 716     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 717       [emacs_cv_prog_cc_g3],
 718       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 719          [emacs_cv_prog_cc_g3=yes],
 720          [emacs_cv_prog_cc_g3=no])])
 721     if test $emacs_cv_prog_cc_g3 != yes; then
 722       CFLAGS=$emacs_save_CFLAGS
 723     fi
 724     if test $opsys = mingw32; then
 725       CFLAGS="$CFLAGS -gdwarf-2"
 726     fi
 727   fi
 728
 729   case $CFLAGS in
 730     *-O*) ;;
 731     *)
 732       # No optimization flag was inferred for this non-GCC compiler.
 733       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 734       emacs_save_CFLAGS=$CFLAGS
 735       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 736       CFLAGS=${CFLAGS}-O
 737       AC_CACHE_CHECK([whether $CC accepts -O],
 738         [emacs_cv_prog_cc_o],
 739         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 740            [emacs_cv_prog_cc_o=yes],
 741            [emacs_cv_prog_cc_o=no])])
 742       if test $emacs_cv_prog_cc_o != yes; then
 743         CFLAGS=$emacs_save_CFLAGS
 744       fi ;;
 745   esac
 746 fi
 747
 748 AC_ARG_ENABLE([gcc-warnings],
 749   [AS_HELP_STRING([--enable-gcc-warnings],
 750                   [turn on lots of GCC warnings/errors. This is intended for
 751                    developers, and may generate false alarms when used
 752                    with older or non-GNU development tools.])],
 753   [case $enableval in
 754      yes|no) ;;
 755      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 756    esac
 757    gl_gcc_warnings=$enableval],
 758   [gl_gcc_warnings=no]
 759 )
 760
 761 AC_ARG_ENABLE(link-time-optimization,
 762 [AS_HELP_STRING([--enable-link-time-optimization],
 763                 [build emacs with link-time optimization.
 764                  This is supported only for GCC since 4.5.0.])],
 765 if test "${enableval}" != "no"; then
 766    AC_MSG_CHECKING([whether link-time optimization is supported])
 767    ac_lto_supported=no
 768    if test x$GCC = xyes; then
 769       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 770       if test x$CPUS != x; then
 771          LTO="-flto=$CPUS"
 772       else
 773          LTO="-flto"
 774       fi
 775       old_CFLAGS=$CFLAGS
 776       CFLAGS="$CFLAGS $LTO"
 777       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 778         [ac_lto_supported=yes], [ac_lto_supported=no])
 779       CFLAGS="$old_CFLAGS"
 780    fi
 781    AC_MSG_RESULT([$ac_lto_supported])
 782    if test "$ac_lto_supported" = "yes"; then
 783       CFLAGS="$CFLAGS $LTO"
 784    fi
 785 fi)
 786
 787 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 788 # ------------------------------------------------
 789 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 790 # Otherwise, run RUN-IF-NOT-FOUND.
 791 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 792   [AC_PREPROC_IFELSE(
 793     [AC_LANG_PROGRAM(
 794       [[
 795 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 796 /* ok */
 797 #else
 798 # error "your version of gcc is older than $1.$2"
 799 #endif
 800       ]]),
 801     ], [$3], [$4])
 802   ]
 803 )
 804
 805 # clang is unduly picky about some things.
 806 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 807   [AC_COMPILE_IFELSE(
 808      [AC_LANG_PROGRAM([[
 809           #ifndef __clang__
 810             #error "not clang"
 811           #endif
 812         ]])],
 813      [emacs_cv_clang=yes],
 814      [emacs_cv_clang=no])])
 815
 816 # When compiling with GCC, prefer -isystem to -I when including system
 817 # include files, to avoid generating useless diagnostics for the files.
 818 if test "$gl_gcc_warnings" != yes; then
 819   isystem='-I'
 820   if test "$emacs_cv_clang" = yes
 821   then
 822      # Turn off some warnings if supported.
 823      gl_WARN_ADD([-Wno-switch])
 824      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 825      gl_WARN_ADD([-Wno-pointer-sign])
 826   fi
 827 else
 828   isystem='-isystem '
 829
 830   # This, $nw, is the list of warnings we disable.
 831   nw=
 832
 833   case $with_x_toolkit in
 834     lucid | athena | motif)
 835        # Old toolkits mishandle 'const'.
 836        nw="$nw -Wwrite-strings"
 837        ;;
 838     *)
 839        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 840        ;;
 841   esac
 842   AC_SUBST([WERROR_CFLAGS])
 843
 844   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 845   nw="$nw -Woverlength-strings"     # Not a problem these days
 846   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 847   nw="$nw -Wformat-nonliteral"      # we do this a lot
 848   nw="$nw -Wvla"                    # warnings in gettext.h
 849   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 850   nw="$nw -Wswitch-default"         # Too many warnings for now
 851   nw="$nw -Winline"                 # OK to ignore 'inline'
 852   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 853   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 854                                     # signed overflow has undefined behavior
 855   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 856   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 857   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 858
 859   # Emacs doesn't care about shadowing; see
 860   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 861   nw="$nw -Wshadow"
 862
 863   # Emacs's use of alloca inhibits protecting the stack.
 864   nw="$nw -Wstack-protector"
 865
 866   # The following line should be removable at some point.
 867   nw="$nw -Wsuggest-attribute=pure"
 868
 869   # This part is merely for shortening the command line,
 870   # since -Wno-FOO needs to be added below regardless.
 871   nw="$nw -Wmissing-field-initializers"
 872   nw="$nw -Wswitch"
 873   nw="$nw -Wtype-limits"
 874   nw="$nw -Wunused-parameter"
 875
 876   if test $emacs_cv_clang = yes; then
 877     nw="$nw -Wcast-align"
 878   fi
 879
 880   gl_MANYWARN_ALL_GCC([ws])
 881   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 882   for w in $ws; do
 883     gl_WARN_ADD([$w])
 884   done
 885   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 886   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 887   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 888   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 889   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 890   gl_WARN_ADD([-Wno-format-nonliteral])
 891
 892   # In spite of excluding -Wlogical-op above, it is enabled, as of
 893   # gcc 4.5.0 20090517.
 894   gl_WARN_ADD([-Wno-logical-op])
 895
 896   # More things that clang is unduly picky about.
 897   if test $emacs_cv_clang = yes; then
 898     gl_WARN_ADD([-Wno-format-extra-args])
 899     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 900     gl_WARN_ADD([-Wno-unused-command-line-argument])
 901     gl_WARN_ADD([-Wno-unused-value])
 902   fi
 903
 904   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 905   AH_VERBATIM([FORTIFY_SOURCE],
 906   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 907       without upsetting glibc 2.15+. */
 908    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 909    # define _FORTIFY_SOURCE 2
 910    #endif
 911   ])
 912   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 913
 914   # We use a slightly smaller set of warning options for lib/.
 915   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 916   nw=
 917   nw="$nw -Wunused-macros"
 918
 919   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 920   AC_SUBST([GNULIB_WARN_CFLAGS])
 921 fi
 922
 923
 924
 925 dnl Some other nice autoconf tests.
 926 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 927 dnl AC_PROG_INSTALL
 928 dnl AC_PROG_MKDIR_P
 929 dnl if test "x$RANLIB" = x; then
 930 dnl   AC_PROG_RANLIB
 931 dnl fi
 932
 933
 934 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
 935 dnl can be made to directories.  This is not relevant for our usage, and
 936 dnl excludes some cases that work fine for us.  Eg MS Windows or files
 937 dnl hosted on AFS, both examples where simple links work, but links to
 938 dnl directories fail.  We use a cut-down version instead.
 939 dnl AC_PROG_LN_S
 940
 941 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
 942 rm -f conf$$ conf$$.file
 943
 944 LN_S_FILEONLY='cp -p'
 945
 946 if (echo >conf$$.file) 2>/dev/null; then
 947   if ln -s conf$$.file conf$$ 2>/dev/null; then
 948     LN_S_FILEONLY='ln -s'
 949   elif ln conf$$.file conf$$ 2>/dev/null; then
 950     LN_S_FILEONLY=ln
 951   fi
 952 fi
 953
 954 rm -f conf$$ conf$$.file
 955
 956 if test "$LN_S_FILEONLY" = "ln -s"; then
 957    AC_MSG_RESULT([yes])
 958 else
 959    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
 960 fi
 961
 962 AC_SUBST(LN_S_FILEONLY)
 963
 964
 965 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
 966 dnl doesn't support links to directories, as in "ln file dir".  But that
 967 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
 968 dnl executables at "make install" time.
 969 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
 970 dnl for more details.
 971 if test "$opsys" = "mingw32"; then
 972   LN_S="ln"
 973 fi
 974
 975 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 976   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 977 dnl Don't use GZIP, which is used by gzip for additional parameters.
 978 AC_PATH_PROG(GZIP_PROG, gzip)
 979
 980 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
 981    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
 982
 983 if test $opsys = gnu-linux; then
 984   AC_PATH_PROG(PAXCTL, paxctl,,
 985     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 986   if test "X$PAXCTL" != X; then
 987     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 988     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 989       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 990       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 991   fi
 992
 993   if test "${SETFATTR+set}" != set; then
 994     AC_CACHE_CHECK([for setfattr],
 995       [emacs_cv_prog_setfattr],
 996       [touch conftest.tmp
 997        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
 998          emacs_cv_prog_setfattr=yes
 999        else
1000          emacs_cv_prog_setfattr=no
1001        fi])
1002     if test "$emacs_cv_prog_setfattr" = yes; then
1003       SETFATTR=setfattr
1004     else
1005       SETFATTR=
1006     fi
1007     rm -f conftest.tmp
1008     AC_SUBST([SETFATTR])
1009   fi
1010 fi
1011
1012 ## Need makeinfo >= 4.7 (?) to build the manuals.
1013 AC_PATH_PROG(MAKEINFO, makeinfo, no)
1014 dnl By this stage, configure has already checked for egrep and set EGREP,
1015 dnl or exited with an error if no egrep was found.
1016 if test "$MAKEINFO" != "no"; then
1017   case `
1018     $MAKEINFO --version 2> /dev/null |
1019     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
1020   ` in
1021     '') MAKEINFO=no;;
1022   esac
1023 fi
1024
1025 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1026 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1027 ## therefore in the category of "special tools" not normally required, which
1028 ## configure does not have to check for (eg autoconf itself).
1029 ## In a repository checkout on the other hand, the manuals are not included.
1030 ## So makeinfo is a requirement to build from the repository, and configure
1031 ## should test for it as it does for any other build requirement.
1032 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1033 ## with pre-built manuals, from a repository checkout.
1034 HAVE_MAKEINFO=yes
1035
1036 if test "$MAKEINFO" = "no"; then
1037   MAKEINFO=makeinfo
1038   if test "x${with_makeinfo}" = "xno"; then
1039     HAVE_MAKEINFO=no
1040   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1041     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1042 source tree does not seem to have pre-built manuals in the `info' directory.
1043 Either install a suitable version of makeinfo, or re-run configure
1044 with the `--without-makeinfo' option to build without the manuals.] )
1045   fi
1046 fi
1047 AC_SUBST(HAVE_MAKEINFO)
1048
1049 dnl Just so that there is only a single place we need to edit.
1050 INFO_EXT=.info
1051 INFO_OPTS=--no-split
1052 AC_SUBST(INFO_EXT)
1053 AC_SUBST(INFO_OPTS)
1054
1055 if test $opsys = mingw32; then
1056    DOCMISC_W32=efaq-w32
1057 else
1058    DOCMISC_W32=
1059 fi
1060 AC_SUBST(DOCMISC_W32)
1061
1062 dnl Add our options to ac_link now, after it is set up.
1063
1064 if test x$GCC = xyes; then
1065   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1066     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1067 else
1068   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1069     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1070 fi
1071
1072 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1073 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1074 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1075 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1076 dnl if not built to support GNU ld.
1077
1078 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1079 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1080 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1081 dnl   Eg "make LDFLAGS=... all" could run into problems,
1082 dnl   http://bugs.debian.org/684788
1083 dnl * unnecessary, since temacs is the only thing that actually needs it.
1084 dnl   Indeed this is where it was originally, prior to:
1085 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1086 late_LDFLAGS="$LDFLAGS"
1087 if test x$GCC = xyes; then
1088   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1089 else
1090   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1091 fi
1092
1093 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1094
1095 AC_MSG_CHECKING([for -znocombreloc])
1096 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1097   [AC_MSG_RESULT(yes)],
1098   LDFLAGS_NOCOMBRELOC=
1099   [AC_MSG_RESULT(no)])
1100
1101 LDFLAGS="$late_LDFLAGS"
1102
1103 AC_CACHE_CHECK([whether addresses are sanitized],
1104   [emacs_cv_sanitize_address],
1105   [AC_COMPILE_IFELSE(
1106      [AC_LANG_PROGRAM(
1107         [[#ifndef __has_feature
1108           #define __has_feature(f) 0
1109           #endif
1110           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1111           #else
1112            #error "Addresses are not sanitized."
1113           #endif
1114         ]])],
1115      [emacs_cv_sanitize_address=yes],
1116      [emacs_cv_sanitize_address=no])])
1117
1118 dnl The function dump-emacs will not be defined and temacs will do
1119 dnl (load "loadup") automatically unless told otherwise.
1120 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1121 case "$opsys" in
1122   your-opsys-here) CANNOT_DUMP=yes ;;
1123 esac
1124
1125 if test "$CANNOT_DUMP" = "yes"; then
1126   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1127 elif test "$emacs_cv_sanitize_address" = yes; then
1128   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1129 fi
1130
1131 AC_SUBST(CANNOT_DUMP)
1132
1133
1134 UNEXEC_OBJ=unexelf.o
1135 case "$opsys" in
1136   # MSDOS uses unexcoff.o
1137   aix4-2)
1138    UNEXEC_OBJ=unexaix.o
1139    ;;
1140   cygwin)
1141    UNEXEC_OBJ=unexcw.o
1142    ;;
1143   darwin)
1144    UNEXEC_OBJ=unexmacosx.o
1145    ;;
1146   hpux10-20 | hpux11)
1147    UNEXEC_OBJ=unexhp9k800.o
1148    ;;
1149   mingw32)
1150    UNEXEC_OBJ=unexw32.o
1151    ;;
1152   sol2-10)
1153    # Use the Solaris dldump() function, called from unexsol.c, to dump
1154    # emacs, instead of the generic ELF dump code found in unexelf.c.
1155    # The resulting binary has a complete symbol table, and is better
1156    # for debugging and other observability tools (debuggers, pstack, etc).
1157    #
1158    # If you encounter a problem using dldump(), please consider sending
1159    # a message to the OpenSolaris tools-linking mailing list:
1160    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1161    #
1162    # It is likely that dldump() works with older Solaris too, but this has
1163    # not been tested, so for now this change is for Solaris 10 or newer.
1164    UNEXEC_OBJ=unexsol.o
1165    ;;
1166 esac
1167
1168 LD_SWITCH_SYSTEM=
1169 case "$opsys" in
1170   freebsd|dragonfly)
1171    ## Let `ld' find image libs and similar things in /usr/local/lib.
1172    ## The system compiler, GCC, has apparently been modified to not
1173    ## look there, contrary to what a stock GCC would do.
1174 ### It's not our place to do this.  See bug#10313#17.
1175 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1176       :
1177    ;;
1178
1179   gnu-linux)
1180    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1181    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1182    ;;
1183
1184   netbsd)
1185 ### It's not our place to do this.  See bug#10313#17.
1186 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1187       :
1188    ;;
1189
1190   openbsd)
1191    ## Han Boetes <han@boetes.org> says this is necessary,
1192    ## otherwise Emacs dumps core on elf systems.
1193    LD_SWITCH_SYSTEM="-Z"
1194    ;;
1195 esac
1196 AC_SUBST(LD_SWITCH_SYSTEM)
1197
1198 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1199
1200 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1201 ## which has not been defined yet.  When this was handled with cpp,
1202 ## it was expanded to null when configure sourced the s/*.h file.
1203 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1204 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1205 ## (or somesuch), but because it is supposed to go at the _front_
1206 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1207 ## Compare with the gnu-linux case below, which added to the end
1208 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1209 ## LD_SWITCH_SYSTEM_TEMACS.
1210 case "$opsys" in
1211   netbsd|openbsd)
1212    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1213 esac
1214
1215
1216 C_SWITCH_MACHINE=
1217 case $canonical in
1218  alpha*)
1219   AC_CHECK_DECL([__ELF__])
1220   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1221     ## With ELF, make sure that all common symbols get allocated to in the
1222     ## data section.  Otherwise, the dump of temacs may miss variables in
1223     ## the shared library that have been initialized.  For example, with
1224     ## GNU libc, __malloc_initialized would normally be resolved to the
1225     ## shared library's .bss section, which is fatal.
1226     if test "x$GCC" = "xyes"; then
1227       C_SWITCH_MACHINE="-fno-common"
1228     else
1229       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1230     fi
1231   else
1232       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1233       dnl albeit under the mistaken assumption that said file
1234       dnl was no longer used.
1235       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1236   fi
1237   ;;
1238 esac
1239 AC_SUBST(C_SWITCH_MACHINE)
1240
1241 AC_SUBST(UNEXEC_OBJ)
1242
1243 C_SWITCH_SYSTEM=
1244 ## Some programs in src produce warnings saying certain subprograms
1245 ## are too complex and need a MAXMEM value greater than 2000 for
1246 ## additional optimization.  --nils@exp-math.uni-essen.de
1247 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1248   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1249 if test "$opsys" = "mingw32"; then
1250   case "$canonical" in
1251     x86_64-*-mingw32) C_SWITCH_SYSTEM="-mtune=generic" ;;
1252     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1253   esac
1254 fi
1255 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1256 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1257 AC_SUBST(C_SWITCH_SYSTEM)
1258
1259
1260 LIBS_SYSTEM=
1261 case "$opsys" in
1262   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1263   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1264
1265   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1266
1267   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1268
1269   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1270
1271   ## Motif needs -lgen.
1272   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1273 esac
1274
1275 AC_SUBST(LIBS_SYSTEM)
1276
1277 ### Make sure subsequent tests use flags consistent with the build flags.
1278
1279 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1280   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1281 else
1282   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1283 fi
1284
1285 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1286 AC_DEFUN([AC_TYPE_SIZE_T])
1287 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1288 AC_DEFUN([AC_TYPE_UID_T])
1289
1290
1291 LIB_MATH=-lm
1292 dnl Current possibilities handled by sed (aix4-2 -> aix,
1293 dnl gnu-linux -> gnu/linux, etc.):
1294 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1295 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1296 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1297
1298 case $opsys in
1299   cygwin )
1300     LIB_MATH=
1301     ;;
1302   darwin )
1303     ## Adding -lm confuses the dynamic linker, so omit it.
1304     LIB_MATH=
1305     ;;
1306   freebsd | dragonfly )
1307     SYSTEM_TYPE=berkeley-unix
1308     ;;
1309   gnu-linux | gnu-kfreebsd )
1310     ;;
1311   hpux10-20 | hpux11 )
1312     ;;
1313   mingw32 )
1314     LIB_MATH=
1315     SYSTEM_TYPE=windows-nt
1316     ;;
1317   dnl NB this may be adjusted below.
1318   netbsd | openbsd )
1319     SYSTEM_TYPE=berkeley-unix
1320     ;;
1321
1322   sol2* | unixware )
1323     SYSTEM_TYPE=usg-unix-v
1324     ;;
1325
1326 esac
1327
1328 AC_SUBST(LIB_MATH)
1329 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1330   [The type of system you are compiling for; sets `system-type'.])
1331
1332
1333 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1334 pre_PKG_CONFIG_LIBS=$LIBS
1335
1336 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1337
1338 dnl This function definition taken from Gnome 2.0
1339 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1340 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1341 dnl also defines GSTUFF_PKG_ERRORS on error
1342 AC_DEFUN([PKG_CHECK_MODULES], [
1343   succeeded=no
1344
1345   if test "$PKG_CONFIG" = "no" ; then
1346      ifelse([$4], , [AC_MSG_ERROR([
1347       *** The pkg-config script could not be found. Make sure it is in your path, or give the full name of pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1348   else
1349      PKG_CONFIG_MIN_VERSION=0.9.0
1350      if "$PKG_CONFIG" --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1351         AC_MSG_CHECKING(for $2)
1352
1353         if "$PKG_CONFIG" --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1354            $1_CFLAGS=`"$PKG_CONFIG" --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1355            $1_LIBS=`"$PKG_CONFIG" --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1356             edit_cflags="
1357               s,///*,/,g
1358               s/^/ /
1359               s/ -I/ $isystem/g
1360               s/^ //
1361             "
1362             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1363             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1364             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1365             succeeded=yes
1366         else
1367             AC_MSG_RESULT(no)
1368             $1_CFLAGS=""
1369             $1_LIBS=""
1370             ## If we have a custom action on failure, don't print errors, but
1371             ## do set a variable so people can do so.  Do it in a subshell
1372             ## to capture any diagnostics in invoking pkg-config.
1373             $1_PKG_ERRORS=`("$PKG_CONFIG" --print-errors "$2") 2>&1`
1374             ifelse([$4], ,echo "$$1_PKG_ERRORS",)
1375         fi
1376
1377         AC_SUBST($1_CFLAGS)
1378         AC_SUBST($1_LIBS)
1379      else
1380         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1381         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1382      fi
1383   fi
1384
1385   if test $succeeded = yes; then
1386      ifelse([$3], , :, [$3])
1387   else
1388      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1389   fi
1390 ])
1391
1392 HAVE_SOUND=no
1393 if test "${with_sound}" != "no"; then
1394   # Sound support for GNU/Linux, the free BSDs, and MinGW.
1395   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h],
1396     have_sound_header=yes, [], [
1397     #ifdef __MINGW32__
1398     #define WIN32_LEAN_AND_MEAN
1399     #include <windows.h>
1400     #endif
1401     ])
1402   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1403     AC_MSG_ERROR([OSS sound support requested but not found.])
1404
1405   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1406     # Emulation library used on NetBSD.
1407     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1408     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1409       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1410     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1411     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1412   fi
1413   AC_SUBST(LIBSOUND)
1414
1415   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1416     ALSA_REQUIRED=1.0.0
1417     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1418     PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1419     if test $HAVE_ALSA = yes; then
1420       SAVE_CFLAGS="$CFLAGS"
1421       SAVE_LIBS="$LIBS"
1422       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1423       LIBS="$ALSA_LIBS $LIBS"
1424       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1425                       emacs_alsa_normal=yes,
1426                     emacs_alsa_normal=no)
1427       if test "$emacs_alsa_normal" != yes; then
1428         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1429                        [[snd_lib_error_set_handler (0);]])],
1430                        emacs_alsa_subdir=yes,
1431                      emacs_alsa_subdir=no)
1432         if test "$emacs_alsa_subdir" != yes; then
1433           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1434         fi
1435         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1436       fi
1437
1438       CFLAGS="$SAVE_CFLAGS"
1439       LIBS="$SAVE_LIBS"
1440       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1441       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1442       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1443     elif test "${with_sound}" = "alsa"; then
1444       AC_MSG_ERROR([ALSA sound support requested but not found.])
1445     fi
1446   fi                            dnl with_sound = alsa|yes
1447
1448   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1449   dnl compiles only on the specified platforms.  For others, it
1450   dnl probably doesn't make sense to try.
1451   dnl FIXME So surely we should bypass this whole section if not using
1452   dnl one of these platforms?
1453   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1454      case "$opsys" in
1455        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1456        dnl Adjust the --with-sound help text if you change this.
1457        gnu-linux|freebsd|netbsd|mingw32)
1458          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1459          HAVE_SOUND=yes
1460          ;;
1461      esac
1462   fi
1463
1464   AC_SUBST(CFLAGS_SOUND)
1465 fi
1466
1467 dnl checks for header files
1468 AC_CHECK_HEADERS_ONCE(
1469   sys/systeminfo.h
1470   coff.h pty.h
1471   sys/resource.h
1472   sys/utsname.h pwd.h utmp.h util.h)
1473
1474 AC_MSG_CHECKING(if personality LINUX32 can be set)
1475 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1476                emacs_cv_personality_linux32=yes,
1477                emacs_cv_personality_linux32=no)
1478 AC_MSG_RESULT($emacs_cv_personality_linux32)
1479
1480 if test $emacs_cv_personality_linux32 = yes; then
1481   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1482             [Define to 1 if personality LINUX32 can be set.])
1483 fi
1484
1485 dnl On Solaris 8 there's a compilation warning for term.h because
1486 dnl it doesn't define `bool'.
1487 AC_CHECK_HEADERS(term.h, , , -)
1488 AC_HEADER_TIME
1489 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1490                                       ]])
1491 if test $ac_cv_have_decl_sys_siglist != yes; then
1492   # For Tru64, at least:
1493   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1494                                           ]])
1495 fi
1496 AC_HEADER_SYS_WAIT
1497
1498 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1499 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1500 #if HAVE_SYS_SOCKET_H
1501 #include <sys/socket.h>
1502 #endif])
1503 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1504 #if HAVE_SYS_SOCKET_H
1505 #include <sys/socket.h>
1506 #endif])
1507 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1508 #if HAVE_SYS_SOCKET_H
1509 #include <sys/socket.h>
1510 #endif])
1511
1512 dnl checks for structure members
1513 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1514                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1515                   struct ifreq.ifr_addr,
1516                   struct ifreq.ifr_addr.sa_len], , ,
1517                  [AC_INCLUDES_DEFAULT
1518 #if HAVE_SYS_SOCKET_H
1519 #include <sys/socket.h>
1520 #endif
1521 #if HAVE_NET_IF_H
1522 #include <net/if.h>
1523 #endif])
1524
1525 dnl Check for endianness.
1526 dnl AC_C_BIGENDIAN is done by gnulib.
1527
1528 dnl check for Make feature
1529 dnl AC_PROG_MAKE_SET is done by Automake.
1530
1531 DEPFLAGS=
1532 MKDEPDIR=":"
1533 deps_frag=deps.mk
1534 dnl check for GNU Make if we have GCC and autodepend is on.
1535 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1536    AC_MSG_CHECKING([whether we are using GNU Make])
1537    HAVE_GNU_MAKE=no
1538    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1539    if test "x$testval" != x; then
1540       HAVE_GNU_MAKE=yes
1541    else
1542       ac_enable_autodepend=no
1543    fi
1544    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1545    if test $HAVE_GNU_MAKE = yes; then
1546       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1547       SAVE_CFLAGS="$CFLAGS"
1548       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1549       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1550       CFLAGS="$SAVE_CFLAGS"
1551       test -f deps.d || ac_enable_autodepend=no
1552       rm -rf deps.d
1553       AC_MSG_RESULT([$ac_enable_autodepend])
1554    fi
1555    if test $ac_enable_autodepend = yes; then
1556       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1557       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1558       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1559       deps_frag=autodeps.mk
1560    fi
1561 fi
1562 deps_frag=$srcdir/src/$deps_frag
1563 AC_SUBST(MKDEPDIR)
1564 AC_SUBST(DEPFLAGS)
1565 AC_SUBST_FILE(deps_frag)
1566
1567
1568 lisp_frag=$srcdir/src/lisp.mk
1569 AC_SUBST_FILE(lisp_frag)
1570
1571
1572 dnl checks for operating system services
1573 AC_SYS_LONG_FILE_NAMES
1574
1575 #### Choose a window system.
1576
1577 ## We leave window_system equal to none if
1578 ## we end up building without one.  Any new window system should
1579 ## set window_system to an appropriate value and add objects to
1580 ## window-system-specific substs.
1581
1582 window_system=none
1583 AC_PATH_X
1584 if test "$no_x" != yes; then
1585   window_system=x11
1586 fi
1587
1588 LD_SWITCH_X_SITE_RPATH=
1589 if test "${x_libraries}" != NONE; then
1590   if test -n "${x_libraries}"; then
1591     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1592     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1593   fi
1594   x_default_search_path=""
1595   x_search_path=${x_libraries}
1596   if test -z "${x_search_path}"; then
1597     x_search_path=/usr/lib
1598   fi
1599   for x_library in `echo ${x_search_path}: | \
1600                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1601     x_search_path="\
1602 ${x_library}/X11/%L/%T/%N%C%S:\
1603 ${x_library}/X11/%l/%T/%N%C%S:\
1604 ${x_library}/X11/%T/%N%C%S:\
1605 ${x_library}/X11/%L/%T/%N%S:\
1606 ${x_library}/X11/%l/%T/%N%S:\
1607 ${x_library}/X11/%T/%N%S"
1608     if test x"${x_default_search_path}" = x; then
1609       x_default_search_path=${x_search_path}
1610     else
1611       x_default_search_path="${x_search_path}:${x_default_search_path}"
1612     fi
1613   done
1614 fi
1615 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1616
1617 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1618   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1619 fi
1620
1621 if test x"${x_includes}" = x; then
1622   bitmapdir=/usr/include/X11/bitmaps
1623 else
1624   # accumulate include directories that have X11 bitmap subdirectories
1625   bmd_acc="dummyval"
1626   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1627     if test -d "${bmd}/X11/bitmaps"; then
1628       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1629     fi
1630     if test -d "${bmd}/bitmaps"; then
1631       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1632     fi
1633   done
1634   if test ${bmd_acc} != "dummyval"; then
1635     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1636   fi
1637 fi
1638
1639 HAVE_NS=no
1640 NS_IMPL_COCOA=no
1641 NS_IMPL_GNUSTEP=no
1642 tmp_CPPFLAGS="$CPPFLAGS"
1643 tmp_CFLAGS="$CFLAGS"
1644 CPPFLAGS="$CPPFLAGS -x objective-c"
1645 CFLAGS="$CFLAGS -x objective-c"
1646 GNU_OBJC_CFLAGS=
1647 LIBS_GNUSTEP=
1648 if test "${with_ns}" != no; then
1649   if test "${opsys}" = darwin; then
1650      NS_IMPL_COCOA=yes
1651      ns_appdir=`pwd`/nextstep/Emacs.app
1652      ns_appbindir=${ns_appdir}/Contents/MacOS
1653      ns_appresdir=${ns_appdir}/Contents/Resources
1654      ns_appsrc=Cocoa/Emacs.base
1655   elif test -f $GNUSTEP_CONFIG_FILE; then
1656      NS_IMPL_GNUSTEP=yes
1657      ns_appdir=`pwd`/nextstep/Emacs.app
1658      ns_appbindir=${ns_appdir}
1659      ns_appresdir=${ns_appdir}/Resources
1660      ns_appsrc=GNUstep/Emacs.base
1661      dnl FIXME sourcing this several times in subshells seems inefficient.
1662      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1663      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1664      dnl I seemed to need these as well with GNUstep-startup 0.25.
1665      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1666      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1667      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1668        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1669      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1670        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1671      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1672      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1673      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1674      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1675      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1676      dnl If they had chosen to either define it or not, we could have
1677      dnl just used AC_CHECK_DECL here.
1678      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1679        emacs_cv_objc_exceptions,
1680 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1681 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1682 1;
1683 #else
1684 fail;
1685 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1686      if test $emacs_cv_objc_exceptions = yes; then
1687        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1688        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1689          [Define if GNUstep uses ObjC exceptions.])
1690        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1691      fi
1692   fi
1693
1694   dnl This is only used while we test the NS headers, it gets reset below.
1695   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1696
1697   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1698                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1699   files are missing or cannot be compiled.])])
1700
1701   macfont_file=""
1702   if test "${NS_IMPL_COCOA}" = "yes"; then
1703     AC_MSG_CHECKING([for OSX 10.4 or newer])
1704     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1705                                      [
1706 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1707 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1708  ; /* OK */
1709 #else
1710 #error "OSX 10.4 or newer required"
1711 #endif
1712 #endif
1713                     ])],
1714                     ns_osx_have_104=yes,
1715                     ns_osx_have_104=no)
1716     AC_MSG_RESULT([$ns_osx_have_104])
1717
1718     if test $ns_osx_have_104 = no; then
1719        AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1720     fi
1721     AC_MSG_CHECKING([for OSX 10.5 or newer])
1722     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1723                                      [
1724 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1725 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1050
1726  ; /* OK */
1727 #else
1728 #error "OSX 10.5 not found"
1729 #endif
1730 #endif
1731                     ])],
1732                     ns_osx_have_105=yes,
1733                     ns_osx_have_105=no)
1734     AC_MSG_RESULT([$ns_osx_have_105])
1735     if test $ns_osx_have_105 = yes; then
1736       macfont_file="macfont.o"
1737     fi
1738   fi
1739   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1740                                      [NSInteger i;])],
1741                     ns_have_nsinteger=yes,
1742                     ns_have_nsinteger=no)
1743   if test $ns_have_nsinteger = yes; then
1744     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1745   fi
1746 fi
1747
1748 AC_SUBST(LIBS_GNUSTEP)
1749
1750 INSTALL_ARCH_INDEP_EXTRA=install-etc
1751 ns_self_contained=no
1752 NS_OBJ=
1753 NS_OBJC_OBJ=
1754 if test "${HAVE_NS}" = yes; then
1755   if test "$with_toolkit_scroll_bars" = "no"; then
1756     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1757   fi
1758
1759   window_system=nextstep
1760   # set up packaging dirs
1761   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1762      ns_self_contained=yes
1763      prefix=${ns_appresdir}
1764      exec_prefix=${ns_appbindir}
1765      dnl This one isn't really used, only archlibdir is.
1766      libexecdir="\${ns_appbindir}/libexec"
1767      archlibdir="\${ns_appbindir}/libexec"
1768      etcdocdir="\${ns_appresdir}/etc"
1769      etcdir="\${ns_appresdir}/etc"
1770      dnl FIXME maybe set datarootdir instead.
1771      dnl That would also get applications, icons, man.
1772      infodir="\${ns_appresdir}/info"
1773      mandir="\${ns_appresdir}/man"
1774      lispdir="\${ns_appresdir}/lisp"
1775      INSTALL_ARCH_INDEP_EXTRA=
1776   fi
1777
1778   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o $macfont_file"
1779 fi
1780 CFLAGS="$tmp_CFLAGS"
1781 CPPFLAGS="$tmp_CPPFLAGS"
1782 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1783 AC_SUBST(ns_self_contained)
1784 AC_SUBST(NS_OBJ)
1785 AC_SUBST(NS_OBJC_OBJ)
1786
1787 HAVE_W32=no
1788 W32_OBJ=
1789 W32_LIBS=
1790 EMACSRES=
1791 CLIENTRES=
1792 CLIENTW=
1793 W32_RES_LINK=
1794 EMACS_MANIFEST=
1795 UPDATE_MANIFEST=
1796 if test "${with_w32}" != no; then
1797   case "${opsys}" in
1798     cygwin)
1799       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1800              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1801                    cannot be found.])])
1802     ;;
1803     mingw32)
1804     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1805     ;;
1806     *)
1807       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1808     ;;
1809   esac
1810 fi
1811
1812 if test "${opsys}" = "mingw32"; then
1813   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1814   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1815      #include <windows.h>
1816      #include <usp10.h>]],
1817    [[PIMAGE_NT_HEADERS pHeader;
1818      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1819    [emacs_cv_w32api=yes
1820     HAVE_W32=yes],
1821    emacs_cv_w32api=no)
1822   AC_MSG_RESULT($emacs_cv_w32api)
1823   if test "${emacs_cv_w32api}" = "no"; then
1824     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1825   fi
1826 fi
1827
1828 FIRSTFILE_OBJ=
1829 NTDIR=
1830 LIBS_ECLIENT=
1831 LIB_WSOCK32=
1832 NTLIB=
1833 CM_OBJ="cm.o"
1834 XARGS_LIMIT=
1835 if test "${HAVE_W32}" = "yes"; then
1836   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1837   AC_CHECK_TOOL(WINDRES, [windres],
1838                 [AC_MSG_ERROR([No resource compiler found.])])
1839   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1840   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1841   EMACSRES="emacs.res"
1842   case "$canonical" in
1843     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1844     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1845   esac
1846   UPDATE_MANIFEST=update-game-score.exe.manifest
1847   if test "${opsys}" = "cygwin"; then
1848     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1849     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1850     # Tell the linker that emacs.res is an object (which we compile from
1851     # the rc file), not a linker script.
1852     W32_RES_LINK="-Wl,emacs.res"
1853   else
1854     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1855     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1856     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1857     W32_RES_LINK="\$(EMACSRES)"
1858     CLIENTRES="emacsclient.res"
1859     CLIENTW="emacsclientw\$(EXEEXT)"
1860     FIRSTFILE_OBJ=firstfile.o
1861     NTDIR=nt
1862     CM_OBJ=
1863     LIBS_ECLIENT="-lcomctl32"
1864     LIB_WSOCK32="-lwsock32"
1865     NTLIB="ntlib.$ac_objext"
1866     XARGS_LIMIT="-s 10000"
1867   fi
1868 fi
1869 AC_SUBST(W32_OBJ)
1870 AC_SUBST(W32_LIBS)
1871 AC_SUBST(EMACSRES)
1872 AC_SUBST(EMACS_MANIFEST)
1873 AC_SUBST(UPDATE_MANIFEST)
1874 AC_SUBST(CLIENTRES)
1875 AC_SUBST(CLIENTW)
1876 AC_SUBST(W32_RES_LINK)
1877 AC_SUBST(FIRSTFILE_OBJ)
1878 AC_SUBST(NTDIR)
1879 AC_SUBST(CM_OBJ)
1880 AC_SUBST(LIBS_ECLIENT)
1881 AC_SUBST(LIB_WSOCK32)
1882 AC_SUBST(NTLIB)
1883 AC_SUBST(XARGS_LIMIT)
1884
1885 if test "${HAVE_W32}" = "yes"; then
1886   window_system=w32
1887   with_xft=no
1888 fi
1889
1890 ## $window_system is now set to the window system we will
1891 ## ultimately use.
1892
1893 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
1894    # Too many warnings for now.
1895    nw=
1896    nw="$nw -Wsuggest-attribute=const"
1897    nw="$nw -Wsuggest-attribute=noreturn"
1898    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1899
1900    gl_WARN_ADD([-Wno-unused-variable])
1901    gl_WARN_ADD([-Wno-unused-but-set-variable])
1902    gl_WARN_ADD([-Wno-unused-but-set-parameter])
1903 fi
1904
1905 term_header=
1906 HAVE_X_WINDOWS=no
1907 HAVE_X11=no
1908 USE_X_TOOLKIT=none
1909
1910 case "${window_system}" in
1911   x11 )
1912     HAVE_X_WINDOWS=yes
1913     HAVE_X11=yes
1914     term_header=xterm.h
1915     case "${with_x_toolkit}" in
1916       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1917       motif ) USE_X_TOOLKIT=MOTIF ;;
1918       gtk ) with_gtk=yes
1919             term_header=gtkutil.h
1920 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1921 dnl USE_X_TOOLKIT is set.
1922             USE_X_TOOLKIT=none ;;
1923       gtk2 ) with_gtk2=yes
1924              term_header=gtkutil.h
1925              USE_X_TOOLKIT=none ;;
1926       gtk3 ) with_gtk3=yes
1927              term_header=gtkutil.h
1928              USE_X_TOOLKIT=none ;;
1929       no ) USE_X_TOOLKIT=none ;;
1930 dnl If user did not say whether to use a toolkit, make this decision later:
1931 dnl use the toolkit if we have gtk, or X11R5 or newer.
1932       * ) USE_X_TOOLKIT=maybe ;;
1933     esac
1934   ;;
1935   nextstep )
1936     term_header=nsterm.h
1937   ;;
1938   w32 )
1939     term_header=w32term.h
1940   ;;
1941 esac
1942
1943 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1944    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1945    if test "$HAVE_XSERVER" = true ||
1946       test -n "$DISPLAY" ||
1947       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1948         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1949 were found.  You should install the relevant development files for X
1950 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1951 sure you have development files for image handling, i.e.
1952 tiff, gif, jpeg, png and xpm.
1953 If you are sure you want Emacs compiled without X window support, pass
1954   --without-x
1955 to configure.])
1956    fi
1957 fi
1958
1959 # Does the opsystem file prohibit the use of the GNU malloc?
1960 # Assume not, until told otherwise.
1961 GNU_MALLOC=yes
1962
1963 AC_CACHE_CHECK(
1964   [whether malloc is Doug Lea style],
1965   [emacs_cv_var_doug_lea_malloc],
1966   [emacs_cv_var_doug_lea_malloc=no
1967    dnl Hooks do not work with address sanitization.
1968    if test "$emacs_cv_sanitize_address" != yes; then
1969      AC_LINK_IFELSE(
1970        [AC_LANG_PROGRAM(
1971           [[#include <malloc.h>
1972             static void hook (void) {}]],
1973           [[malloc_set_state (malloc_get_state ());
1974             __after_morecore_hook = hook;
1975             __malloc_initialize_hook = hook;]])],
1976        [emacs_cv_var_doug_lea_malloc=yes])])
1977    fi
1978 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1979
1980 system_malloc=$emacs_cv_sanitize_address
1981 case "$opsys" in
1982   ## darwin ld insists on the use of malloc routines in the System framework.
1983   darwin|sol2-10) system_malloc=yes ;;
1984 esac
1985
1986 GMALLOC_OBJ=
1987 if test "${system_malloc}" = "yes"; then
1988   AC_DEFINE([SYSTEM_MALLOC], 1,
1989     [Define to 1 to use the system memory allocator, even if it is not
1990      Doug Lea style.])
1991   GNU_MALLOC=no
1992   GNU_MALLOC_reason="
1993     (The GNU allocators don't work with this system configuration.)"
1994   VMLIMIT_OBJ=
1995 else
1996   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1997   VMLIMIT_OBJ=vm-limit.o
1998
1999   AC_CHECK_HEADERS([sys/vlimit.h])
2000   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2001     [AC_LINK_IFELSE(
2002        [AC_LANG_PROGRAM(
2003          [[extern char data_start[]; char ch;]],
2004          [[return data_start < &ch;]])],
2005        [emacs_cv_data_start=yes],
2006        [emacs_cv_data_start=no])])
2007   if test $emacs_cv_data_start = yes; then
2008     AC_DEFINE([HAVE_DATA_START], 1,
2009       [Define to 1 if data_start is the address of the start
2010        of the main data segment.])
2011   fi
2012 fi
2013 AC_SUBST(GMALLOC_OBJ)
2014 AC_SUBST(VMLIMIT_OBJ)
2015
2016 if test "$doug_lea_malloc" = "yes" ; then
2017   if test "$GNU_MALLOC" = yes ; then
2018     GNU_MALLOC_reason="
2019       (Using Doug Lea's new malloc from the GNU C Library.)"
2020   fi
2021   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2022     [Define to 1 if the system memory allocator is Doug Lea style,
2023      with malloc hooks and malloc_set_state.])
2024
2025   ## Use mmap directly for allocating larger buffers.
2026   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2027   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2028   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2029   case "$opsys" in
2030     gnu*) REL_ALLOC=no ;;
2031   esac
2032 fi
2033
2034 if test x"${REL_ALLOC}" = x; then
2035   REL_ALLOC=${GNU_MALLOC}
2036 fi
2037
2038 use_mmap_for_buffers=no
2039 case "$opsys" in
2040   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2041 esac
2042
2043 AC_FUNC_MMAP
2044 if test $use_mmap_for_buffers = yes; then
2045   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2046   REL_ALLOC=no
2047 fi
2048
2049 LIBS="$LIBS_SYSTEM $LIBS"
2050
2051 dnl If found, this adds -ldnet to LIBS, which Autoconf uses for checks.
2052 AC_CHECK_LIB(dnet, dnet_ntoa)
2053 dnl This causes -lresolv to get used in subsequent tests,
2054 dnl which causes failures on some systems such as HPUX 9.
2055 dnl AC_CHECK_LIB(resolv, gethostbyname)
2056
2057 dnl FIXME replace main with a function we actually want from this library.
2058 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2059
2060 dnl Check if pthreads is available.
2061 LIB_PTHREAD=
2062 AC_CHECK_HEADERS_ONCE(pthread.h)
2063 if test "$ac_cv_header_pthread_h"; then
2064   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
2065   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
2066   dnl testing for pthread_self if Emacs uses gmalloc.c.
2067   if test "$GMALLOC_OBJ" = gmalloc.o; then
2068     emacs_pthread_function=pthread_atfork
2069   else
2070     emacs_pthread_function=pthread_self
2071   fi
2072   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
2073 fi
2074 if test "$HAVE_PTHREAD" = yes; then
2075   case "${canonical}" in
2076     *-hpux*) ;;
2077     *) LIB_PTHREAD="-lpthread"
2078        LIBS="$LIB_PTHREAD $LIBS" ;;
2079   esac
2080   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
2081 fi
2082 AC_SUBST([LIB_PTHREAD])
2083
2084 AC_CHECK_LIB(pthreads, cma_open)
2085
2086 ## Note: when using cpp in s/aix4.2.h, this definition depended on
2087 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
2088 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
2089 ## added to LIBS in configure would never contain the pthreads part,
2090 ## but the value used in Makefiles might.  FIXME?
2091 ##
2092 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
2093 ## be harmless on older versions of X where it happens to exist.
2094 test "$opsys" = "aix4-2" && \
2095   test $ac_cv_lib_pthreads_cma_open = yes && \
2096   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
2097
2098 dnl Check for need for bigtoc support on IBM AIX
2099
2100 case ${host_os} in
2101 aix*)
2102   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2103     case $GCC in
2104     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2105     *) gdb_cv_bigtoc=-bbigtoc ;;
2106     esac
2107
2108     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2109     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2110   ])
2111   ;;
2112 esac
2113
2114 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
2115 # used for the tests that follow.  We set them back to REAL_CFLAGS and
2116 # REAL_CPPFLAGS later on.
2117
2118 REAL_CFLAGS="$CFLAGS"
2119 REAL_CPPFLAGS="$CPPFLAGS"
2120
2121 if test "${HAVE_X11}" = "yes"; then
2122   DEFS="$C_SWITCH_X_SITE $DEFS"
2123   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2124   LIBS="-lX11 $LIBS"
2125   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2126   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2127
2128   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2129   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2130   # but it's more convenient here to set LD_RUN_PATH since this
2131   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2132   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2133     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2134     export LD_RUN_PATH
2135   fi
2136
2137   if test "${opsys}" = "gnu-linux"; then
2138     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2139     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2140      [[XOpenDisplay ("foo");]])],
2141      [xgnu_linux_first_failure=no],
2142      [xgnu_linux_first_failure=yes])
2143     if test "${xgnu_linux_first_failure}" = "yes"; then
2144       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
2145       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
2146       OLD_CPPFLAGS="$CPPFLAGS"
2147       OLD_LIBS="$LIBS"
2148       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2149       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2150       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2151       LIBS="$LIBS -b i486-linuxaout"
2152       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2153        [[XOpenDisplay ("foo");]])],
2154        [xgnu_linux_second_failure=no],
2155        [xgnu_linux_second_failure=yes])
2156       if test "${xgnu_linux_second_failure}" = "yes"; then
2157         # If we get the same failure with -b, there is no use adding -b.
2158         # So take it out.  This plays safe.
2159         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
2160         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
2161         CPPFLAGS="$OLD_CPPFLAGS"
2162         LIBS="$OLD_LIBS"
2163         AC_MSG_RESULT(no)
2164       else
2165         AC_MSG_RESULT(yes)
2166       fi
2167     else
2168       AC_MSG_RESULT(no)
2169     fi
2170   fi
2171
2172   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2173   # header files included from there.
2174   AC_MSG_CHECKING(for Xkb)
2175   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2176 #include <X11/XKBlib.h>]],
2177         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2178         emacs_xkb=yes, emacs_xkb=no)
2179   AC_MSG_RESULT($emacs_xkb)
2180   if test $emacs_xkb = yes; then
2181     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2182   fi
2183
2184   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2185 XScreenNumberOfScreen)
2186 fi
2187
2188 if test "${window_system}" = "x11"; then
2189   AC_MSG_CHECKING(X11 version 6)
2190   AC_CACHE_VAL(emacs_cv_x11_version_6,
2191   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2192 [[#if XlibSpecificationRelease < 6
2193 fail;
2194 #endif
2195 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2196   if test $emacs_cv_x11_version_6 = yes; then
2197     AC_MSG_RESULT(6 or newer)
2198     AC_DEFINE(HAVE_X11R6, 1,
2199               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2200     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2201     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2202     ## XIM support.
2203     case "$opsys" in
2204       sol2-*) : ;;
2205       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2206            [Define if you have usable X11R6-style XIM support.])
2207          ;;
2208     esac
2209   else
2210     AC_MSG_RESULT(before 6)
2211   fi
2212 fi
2213
2214
2215 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2216 HAVE_RSVG=no
2217 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2218   if test "${with_rsvg}" != "no"; then
2219     RSVG_REQUIRED=2.11.0
2220     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2221
2222     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
2223     AC_SUBST(RSVG_CFLAGS)
2224     AC_SUBST(RSVG_LIBS)
2225
2226     if test $HAVE_RSVG = yes; then
2227       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2228       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2229       # Windows loads librsvg dynamically
2230       if test "${opsys}" = "mingw32"; then
2231         RSVG_LIBS=
2232       fi
2233       LIBS="$RSVG_LIBS $LIBS"
2234     fi
2235   fi
2236 fi
2237
2238 HAVE_IMAGEMAGICK=no
2239 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
2240   if test "${with_imagemagick}" != "no"; then
2241     ## 6.2.8 is the earliest version known to work, but earlier versions
2242     ## might work - let us know if you find one.
2243     ## 6.0.7 does not work.  See bug#7955.
2244     ## 6.8.2 makes Emacs crash; see Bug#13867.
2245     IMAGEMAGICK_MODULE="Wand >= 6.2.8 Wand != 6.8.2"
2246     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
2247     AC_SUBST(IMAGEMAGICK_CFLAGS)
2248     AC_SUBST(IMAGEMAGICK_LIBS)
2249
2250     if test $HAVE_IMAGEMAGICK = yes; then
2251       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2252       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2253       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2254       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2255     fi
2256   fi
2257 fi
2258
2259
2260 HAVE_GTK=no
2261 GTK_OBJ=
2262 gtk_term_header=$term_header
2263 check_gtk2=no
2264 gtk3_pkg_errors=
2265 if test "${opsys}" != "mingw32"; then
2266   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2267     GLIB_REQUIRED=2.28
2268     GTK_REQUIRED=3.0
2269     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2270
2271     dnl Checks for libraries.
2272     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2273     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2274        AC_MSG_ERROR($GTK_PKG_ERRORS)
2275     fi
2276     if test "$pkg_check_gtk" = "yes"; then
2277        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2278        GTK_OBJ=emacsgtkfixed.o
2279        gtk_term_header=gtkutil.h
2280        USE_GTK_TOOLKIT="GTK3"
2281        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2282          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2283            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2284          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2285            [Define to 1 to disable Glib deprecation warnings.])
2286        fi
2287     else
2288        check_gtk2=yes
2289        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2290     fi
2291   fi
2292
2293   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2294     GLIB_REQUIRED=2.10
2295     GTK_REQUIRED=2.10
2296     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2297
2298     dnl Checks for libraries.
2299     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2300     if test "$pkg_check_gtk" = "no" &&
2301        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2302     then
2303       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2304     fi
2305     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2306   fi
2307 fi
2308
2309 if test x"$pkg_check_gtk" = xyes; then
2310
2311   AC_SUBST(GTK_LIBS)
2312   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2313   CFLAGS="$CFLAGS $GTK_CFLAGS"
2314   LIBS="$GTK_LIBS $LIBS"
2315   dnl Try to compile a simple GTK program.
2316   AC_MSG_CHECKING([whether GTK compiles])
2317   GTK_COMPILES=no
2318   AC_LINK_IFELSE(
2319     [AC_LANG_PROGRAM(
2320        [[/* Check the Gtk and Glib APIs.  */
2321          #include <gtk/gtk.h>
2322          #include <glib-object.h>
2323          static void
2324          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2325          {}
2326        ]],
2327        [[
2328          GtkSettings *gs = 0;
2329          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2330             strict C prohibits this.  Use gtk_main_iteration to test that the
2331             libraries are there.  */
2332          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2333                                     0, 0, 0, G_CALLBACK (callback), 0))
2334            gtk_main_iteration ();
2335        ]])],
2336     [GTK_COMPILES=yes])
2337   AC_MSG_RESULT([$GTK_COMPILES])
2338   if test "${GTK_COMPILES}" != "yes"; then
2339     GTK_OBJ=
2340     if test "$USE_X_TOOLKIT" != "maybe"; then
2341       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2342     fi
2343   else
2344     HAVE_GTK=yes
2345     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2346     GTK_OBJ="gtkutil.o $GTK_OBJ"
2347     term_header=$gtk_term_header
2348     USE_X_TOOLKIT=none
2349     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2350       :
2351     else
2352       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2353        closing open displays.  This is no problem if you just use
2354        one display, but if you use more than one and close one of them
2355        Emacs may crash.]])
2356       sleep 3
2357     fi
2358   fi
2359
2360 fi
2361 AC_SUBST(GTK_OBJ)
2362
2363
2364 if test "${HAVE_GTK}" = "yes"; then
2365
2366   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2367   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2368   if test "$with_toolkit_scroll_bars" != no; then
2369     with_toolkit_scroll_bars=yes
2370   fi
2371
2372   dnl  Check if we have the old file selection dialog declared and
2373   dnl  in the link library.  In 2.x it may be in the library,
2374   dnl  but not declared if deprecated featured has been selected out.
2375   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2376   HAVE_GTK_FILE_SELECTION=no
2377   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2378                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2379 #include <gtk/gtk.h>])
2380   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2381     AC_CHECK_FUNCS(gtk_file_selection_new)
2382   fi
2383
2384   dnl Same as above for gtk_handle_box.
2385   HAVE_GTK_HANDLE_BOX=no
2386   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2387                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2388 #include <gtk/gtk.h>])
2389   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2390     AC_CHECK_FUNCS(gtk_handle_box_new)
2391   fi
2392
2393   dnl Same as above for gtk_tearoff_menu_item.
2394   HAVE_GTK_TEAROFF_MENU_ITEM=no
2395   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2396                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2397 #include <gtk/gtk.h>])
2398   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2399     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2400   fi
2401
2402   dnl Check for functions introduced in 2.14 and later.
2403   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2404                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2405                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2406                  gtk_orientable_set_orientation \
2407                  gtk_window_set_has_resize_grip)
2408
2409  term_header=gtkutil.h
2410 fi
2411
2412 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2413 dnl other platforms.
2414 HAVE_DBUS=no
2415 DBUS_OBJ=
2416 if test "${with_dbus}" = "yes"; then
2417    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2418    if test "$HAVE_DBUS" = yes; then
2419      LIBS="$LIBS $DBUS_LIBS"
2420      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2421      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2422      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2423      dnl D-Bus 1.5.12.
2424      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2425                     dbus_type_is_valid \
2426                     dbus_validate_bus_name \
2427                     dbus_validate_path \
2428                     dbus_validate_interface \
2429                     dbus_validate_member)
2430      DBUS_OBJ=dbusbind.o
2431    fi
2432 fi
2433 AC_SUBST(DBUS_OBJ)
2434
2435 dnl GSettings has been tested under GNU/Linux only.
2436 HAVE_GSETTINGS=no
2437 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2438    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2439    if test "$HAVE_GSETTINGS" = "yes"; then
2440       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2441       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2442       SETTINGS_LIBS="$GSETTINGS_LIBS"
2443    fi
2444 fi
2445
2446 dnl GConf has been tested under GNU/Linux only.
2447 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2448 HAVE_GCONF=no
2449 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2450    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2451    if test "$HAVE_GCONF" = yes; then
2452       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2453       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2454       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2455       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2456    fi
2457 fi
2458
2459 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2460     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2461     if test "$HAVE_GOBJECT" = "yes"; then
2462        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2463        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2464     fi
2465     SAVE_CFLAGS="$CFLAGS"
2466     SAVE_LIBS="$LIBS"
2467     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2468     LIBS="$SETTINGS_LIBS $LIBS"
2469     CFLAGS="$SAVE_CFLAGS"
2470     LIBS="$SAVE_LIBS"
2471 fi
2472 AC_SUBST(SETTINGS_CFLAGS)
2473 AC_SUBST(SETTINGS_LIBS)
2474
2475
2476 dnl SELinux is available for GNU/Linux only.
2477 HAVE_LIBSELINUX=no
2478 LIBSELINUX_LIBS=
2479 if test "${with_selinux}" = "yes"; then
2480    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2481    if test "$HAVE_LIBSELINUX" = yes; then
2482       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2483       LIBSELINUX_LIBS=-lselinux
2484    fi
2485 fi
2486 AC_SUBST(LIBSELINUX_LIBS)
2487
2488 HAVE_GNUTLS=no
2489 HAVE_GNUTLS3=no
2490 if test "${with_gnutls}" = "yes" ; then
2491   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.0.0], HAVE_GNUTLS3=yes, HAVE_GNUTLS3=no)
2492   if test "${HAVE_GNUTLS3}" = "yes"; then
2493     AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])
2494     HAVE_GNUTLS="yes"
2495   else
2496     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2497   fi
2498   if test "${HAVE_GNUTLS}" = "yes"; then
2499     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2500   fi
2501
2502   # Windows loads GnuTLS dynamically
2503   if test "${opsys}" = "mingw32"; then
2504     LIBGNUTLS_LIBS=
2505   else
2506     CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2507     LIBS="$LIBGNUTLS_LIBS $LIBS"
2508   fi
2509 fi
2510
2511 AC_SUBST(LIBGNUTLS_LIBS)
2512 AC_SUBST(LIBGNUTLS_CFLAGS)
2513
2514 NOTIFY_OBJ=
2515 NOTIFY_SUMMARY=no
2516
2517 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2518 dnl a particular library.  This doesn't make much sense?
2519 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2520   with_file_notification=no
2521 fi
2522
2523 dnl MS Windows native file monitor is available for mingw32 only.
2524 case $with_file_notification,$opsys in
2525   w32,* | yes,mingw32)
2526     AC_CHECK_HEADER(windows.h)
2527     if test "$ac_cv_header_windows_h" = yes ; then
2528        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2529        NOTIFY_OBJ=w32notify.o
2530        NOTIFY_SUMMARY="yes (w32)"
2531     fi ;;
2532 esac
2533
2534 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2535 dnl has been added in glib 2.24.  It has been tested under
2536 dnl GNU/Linux only.  We take precedence over inotify, but this makes
2537 dnl only sense when glib has been compiled with inotify support.  How
2538 dnl to check?
2539 case $with_file_notification,$NOTIFY_OBJ in
2540   gfile, | yes,)
2541     PKG_CHECK_MODULES(GFILENOTIFY, gio-2.0 >= 2.24, HAVE_GFILENOTIFY=yes, HAVE_GFILENOTIFY=no)
2542     if test "$HAVE_GFILENOTIFY" = "yes"; then
2543        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2544        NOTIFY_OBJ=gfilenotify.o
2545        NOTIFY_SUMMARY="yes -lgio (gfile)"
2546     fi ;;
2547 esac
2548
2549 dnl inotify is only available on GNU/Linux.
2550 case $with_file_notification,$NOTIFY_OBJ in
2551   inotify, | yes,)
2552     AC_CHECK_HEADER(sys/inotify.h)
2553     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2554         AC_CHECK_FUNC(inotify_init1)
2555         if test "$ac_cv_func_inotify_init1" = yes; then
2556           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2557           NOTIFY_OBJ=inotify.o
2558           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2559        fi
2560     fi ;;
2561 esac
2562
2563 case $with_file_notification,$NOTIFY_OBJ in
2564   yes,* | no,* | *,?*) ;;
2565   *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;;
2566 esac
2567
2568 if test -n "$NOTIFY_OBJ"; then
2569    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2570 fi
2571 AC_SUBST(NOTIFY_OBJ)
2572 AC_SUBST(GFILENOTIFY_CFLAGS)
2573 AC_SUBST(GFILENOTIFY_LIBS)
2574
2575 dnl Do not put whitespace before the #include statements below.
2576 dnl Older compilers (eg sunos4 cc) choke on it.
2577 HAVE_XAW3D=no
2578 LUCID_LIBW=
2579 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2580   if test "$with_xaw3d" != no; then
2581     AC_CACHE_VAL(emacs_cv_xaw3d,
2582     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2583 #include <X11/Intrinsic.h>
2584 #include <X11/Xaw3d/Simple.h>]],
2585       [[]])],
2586       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2587                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2588       emacs_cv_xaw3d=no)])
2589   else
2590     emacs_cv_xaw3d=no
2591   fi
2592   if test $emacs_cv_xaw3d = yes; then
2593     AC_MSG_CHECKING(for xaw3d)
2594     AC_MSG_RESULT([yes; using Lucid toolkit])
2595     USE_X_TOOLKIT=LUCID
2596     HAVE_XAW3D=yes
2597     LUCID_LIBW=-lXaw3d
2598     AC_DEFINE(HAVE_XAW3D, 1,
2599               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2600   else
2601     AC_MSG_CHECKING(for xaw3d)
2602     AC_MSG_RESULT(no)
2603     AC_MSG_CHECKING(for libXaw)
2604     AC_CACHE_VAL(emacs_cv_xaw,
2605     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2606 #include <X11/Intrinsic.h>
2607 #include <X11/Xaw/Simple.h>]],
2608       [[]])],
2609       emacs_cv_xaw=yes,
2610       emacs_cv_xaw=no)])
2611     if test $emacs_cv_xaw = yes; then
2612       AC_MSG_RESULT([yes; using Lucid toolkit])
2613       USE_X_TOOLKIT=LUCID
2614       LUCID_LIBW=-lXaw
2615     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2616       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2617     else
2618       AC_MSG_ERROR([No X toolkit could be found.
2619 If you are sure you want Emacs compiled without an X toolkit, pass
2620   --with-x-toolkit=no
2621 to configure.  Otherwise, install the development libraries for the toolkit
2622 that you want to use (e.g. Gtk+) and re-run configure.])
2623     fi
2624   fi
2625 fi
2626
2627 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2628
2629 LIBXTR6=
2630 if test "${USE_X_TOOLKIT}" != "none"; then
2631   AC_MSG_CHECKING(X11 toolkit version)
2632   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2633   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2634 [[#if XtSpecificationRelease < 6
2635 fail;
2636 #endif
2637 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2638   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2639   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2640     AC_MSG_RESULT(6 or newer)
2641     AC_DEFINE(HAVE_X11XTR6, 1,
2642               [Define to 1 if you have the X11R6 or newer version of Xt.])
2643     LIBXTR6="-lSM -lICE"
2644     case "$opsys" in
2645       ## Use libw.a along with X11R6 Xt.
2646       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2647     esac
2648   else
2649     AC_MSG_RESULT(before 6)
2650   fi
2651
2652 dnl If using toolkit, check whether libXmu.a exists.
2653 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2654   OLDLIBS="$LIBS"
2655   if test x$HAVE_X11XTR6 = xyes; then
2656     LIBS="-lXt -lSM -lICE $LIBS"
2657   else
2658     LIBS="-lXt $LIBS"
2659   fi
2660   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2661   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2662   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2663 fi
2664 AC_SUBST(LIBXTR6)
2665
2666 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2667 dnl Why not just test for libxmu in the normal way?
2668 LIBXMU=-lXmu
2669 case $opsys in
2670   ## These systems don't supply Xmu.
2671   hpux* | aix4-2 )
2672     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2673     ;;
2674   mingw32 )
2675     LIBXMU=
2676     ;;
2677 esac
2678 AC_SUBST(LIBXMU)
2679
2680 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2681 if test "${HAVE_X11}" = "yes"; then
2682   if test "${USE_X_TOOLKIT}" != "none"; then
2683     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2684   fi
2685 fi
2686
2687 LIBXP=
2688 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2689   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2690   if test -d /usr/include/openmotif; then
2691     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2692     emacs_cv_openmotif=yes
2693     case "$canonical" in
2694       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2695       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2696       ;;
2697       *)
2698       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2699     esac
2700   else
2701     emacs_cv_openmotif=no
2702   fi
2703   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2704   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2705     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2706 int x = 5;
2707 #else
2708 Motif version prior to 2.1.
2709 #endif]])],
2710     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2711   if test $emacs_cv_motif_version_2_1 = yes; then
2712     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2713     if test x$emacs_cv_openmotif = xyes; then
2714       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2715     fi
2716   else
2717     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2718     # We put this in CFLAGS temporarily to precede other -I options
2719     # that might be in CFLAGS temporarily.
2720     # We put this in CPPFLAGS where it precedes the other -I options.
2721     OLD_CPPFLAGS=$CPPFLAGS
2722     OLD_CFLAGS=$CFLAGS
2723     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2724     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2725     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2726       [[int x = 5;]])],
2727       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2728     if test $emacs_cv_lesstif = yes; then
2729       # Make sure this -I option remains in CPPFLAGS after it is set
2730       # back to REAL_CPPFLAGS.
2731       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2732       # have those other -I options anyway.  Ultimately, having this
2733       # directory ultimately in CPPFLAGS will be enough.
2734       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2735       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2736     else
2737       CFLAGS=$OLD_CFLAGS
2738       CPPFLAGS=$OLD_CPPFLAGS
2739     fi
2740   fi
2741   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2742     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2743 fi
2744
2745 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2746 dnl using Motif or Xaw3d is available, and unless
2747 dnl --with-toolkit-scroll-bars=no was specified.
2748
2749 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2750             [Define to 1 if we should use toolkit scroll bars.])dnl
2751 USE_TOOLKIT_SCROLL_BARS=no
2752 if test "${with_toolkit_scroll_bars}" != "no"; then
2753   if test "${USE_X_TOOLKIT}" != "none"; then
2754     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2755       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2756       HAVE_XAW3D=no
2757       USE_TOOLKIT_SCROLL_BARS=yes
2758     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2759       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2760       USE_TOOLKIT_SCROLL_BARS=yes
2761     fi
2762   elif test "${HAVE_GTK}" = "yes"; then
2763     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2764     USE_TOOLKIT_SCROLL_BARS=yes
2765   elif test "${HAVE_NS}" = "yes"; then
2766     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2767     USE_TOOLKIT_SCROLL_BARS=yes
2768   elif test "${HAVE_W32}" = "yes"; then
2769     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2770     USE_TOOLKIT_SCROLL_BARS=yes
2771   fi
2772 fi
2773
2774 dnl See if XIM is available.
2775 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2776           #include <X11/Xlib.h>
2777           #include <X11/Xresource.h>]],
2778          [[XIMProc  callback;]])],
2779          [HAVE_XIM=yes
2780          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2781          HAVE_XIM=no)
2782
2783 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2784
2785 if test "${with_xim}" != "no"; then
2786   AC_DEFINE(USE_XIM, 1,
2787             [Define to 1 if we should use XIM, if it is available.])
2788 fi
2789
2790
2791 if test "${HAVE_XIM}" != "no"; then
2792   late_CFLAGS=$CFLAGS
2793   if test "$GCC" = yes; then
2794     CFLAGS="$CFLAGS --pedantic-errors"
2795   fi
2796   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2797 #include <X11/Xlib.h>
2798 #include <X11/Xresource.h>]],
2799 [[Display *display;
2800 XrmDatabase db;
2801 char *res_name;
2802 char *res_class;
2803 XIMProc  callback;
2804 XPointer *client_data;
2805 #ifndef __GNUC__
2806 /* If we're not using GCC, it's probably not XFree86, and this is
2807    probably right, but we can't use something like --pedantic-errors.  */
2808 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2809                                            char*, XIMProc, XPointer*);
2810 #endif
2811 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2812    client_data);]])],
2813     [emacs_cv_arg6_star=yes])
2814   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2815          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2816 either XPointer or XPointer*.])dnl
2817   if test "$emacs_cv_arg6_star" = yes; then
2818     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2819   else
2820     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2821   fi
2822   CFLAGS=$late_CFLAGS
2823 fi
2824
2825 ### Start of font-backend (under any platform) section.
2826 # (nothing here yet -- this is a placeholder)
2827 ### End of font-backend (under any platform) section.
2828
2829 ### Start of font-backend (under X11) section.
2830 if test "${HAVE_X11}" = "yes"; then
2831    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2832
2833    ## Use -lXft if available, unless `--with-xft=no'.
2834    HAVE_XFT=maybe
2835     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2836       with_xft="no";
2837     fi
2838     if test "x${with_xft}" != "xno"; then
2839
2840       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2841       ## Because xftfont.c uses XRenderQueryExtension, we also
2842       ## need to link to -lXrender.
2843       HAVE_XRENDER=no
2844       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2845       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2846         OLD_CPPFLAGS="$CPPFLAGS"
2847         OLD_CFLAGS="$CFLAGS"
2848         OLD_LIBS="$LIBS"
2849         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2850         CFLAGS="$CFLAGS $XFT_CFLAGS"
2851         XFT_LIBS="-lXrender $XFT_LIBS"
2852         LIBS="$XFT_LIBS $LIBS"
2853         AC_CHECK_HEADER(X11/Xft/Xft.h,
2854           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2855           [[#include <X11/X.h>]])
2856
2857         if test "${HAVE_XFT}" = "yes"; then
2858           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2859             AC_SUBST(XFT_LIBS)
2860           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2861         else
2862           CPPFLAGS="$OLD_CPPFLAGS"
2863           CFLAGS="$OLD_CFLAGS"
2864           LIBS="$OLD_LIBS"
2865         fi                        # "${HAVE_XFT}" = "yes"
2866       fi                          # "$HAVE_XFT" != no
2867     fi                            # "x${with_xft}" != "xno"
2868
2869     ## We used to allow building with FreeType and without Xft.
2870     ## However, the ftx font backend driver is not in good shape.
2871     if test "$HAVE_XFT" != "yes"; then
2872        dnl For the "Does Emacs use" message at the end.
2873        HAVE_XFT=no
2874        HAVE_FREETYPE=no
2875     else
2876        dnl Strict linkers fail with
2877        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2878        dnl if -lfreetype is not specified.
2879        dnl The following is needed to set FREETYPE_LIBS.
2880        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2881                          HAVE_FREETYPE=no)
2882
2883        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2884     fi
2885
2886     HAVE_LIBOTF=no
2887     if test "${HAVE_FREETYPE}" = "yes"; then
2888       AC_DEFINE(HAVE_FREETYPE, 1,
2889                 [Define to 1 if using the freetype and fontconfig libraries.])
2890       if test "${with_libotf}" != "no"; then
2891         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2892                           HAVE_LIBOTF=no)
2893         if test "$HAVE_LIBOTF" = "yes"; then
2894           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2895           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2896                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2897                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2898           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2899             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2900                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2901           fi
2902         fi
2903       fi
2904     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2905     dnl Does the new font backend require it, or can it work without it?
2906     fi
2907
2908     HAVE_M17N_FLT=no
2909     if test "${HAVE_LIBOTF}" = yes; then
2910       if test "${with_m17n_flt}" != "no"; then
2911         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2912         if test "$HAVE_M17N_FLT" = "yes"; then
2913           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2914         fi
2915       fi
2916     fi
2917 else
2918     HAVE_XFT=no
2919     HAVE_FREETYPE=no
2920     HAVE_LIBOTF=no
2921     HAVE_M17N_FLT=no
2922 fi
2923
2924 ### End of font-backend (under X11) section.
2925
2926 AC_SUBST(FREETYPE_CFLAGS)
2927 AC_SUBST(FREETYPE_LIBS)
2928 AC_SUBST(FONTCONFIG_CFLAGS)
2929 AC_SUBST(FONTCONFIG_LIBS)
2930 AC_SUBST(LIBOTF_CFLAGS)
2931 AC_SUBST(LIBOTF_LIBS)
2932 AC_SUBST(M17N_FLT_CFLAGS)
2933 AC_SUBST(M17N_FLT_LIBS)
2934
2935 ### Use -lXpm if available, unless `--with-xpm=no'.
2936 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
2937 HAVE_XPM=no
2938 LIBXPM=
2939 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
2940   if test "${with_xpm}" != "no"; then
2941     SAVE_CPPFLAGS="$CPPFLAGS"
2942     SAVE_LDFLAGS="$LDFLAGS"
2943     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2944     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2945     AC_CHECK_HEADER(X11/xpm.h,
2946       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2947     if test "${HAVE_XPM}" = "yes"; then
2948       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2949       AC_EGREP_CPP(no_return_alloc_pixels,
2950       [#include "X11/xpm.h"
2951 #ifndef XpmReturnAllocPixels
2952 no_return_alloc_pixels
2953 #endif
2954       ], HAVE_XPM=no, HAVE_XPM=yes)
2955
2956       if test "${HAVE_XPM}" = "yes"; then
2957         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2958         AC_MSG_RESULT(yes)
2959       else
2960         AC_MSG_RESULT(no)
2961         CPPFLAGS="$SAVE_CPPFLAGS"
2962         LDFLAGS="$SAVE_LDFLAGS"
2963       fi
2964     fi
2965   fi
2966
2967   if test "${HAVE_XPM}" = "yes"; then
2968     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2969     LIBXPM=-lXpm
2970   fi
2971 fi
2972
2973 if test "${HAVE_X11}" = "yes"; then
2974   if test "${with_xpm}" != "no"; then
2975     AC_CHECK_HEADER(X11/xpm.h,
2976       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2977     if test "${HAVE_XPM}" = "yes"; then
2978       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2979       AC_EGREP_CPP(no_return_alloc_pixels,
2980       [#include "X11/xpm.h"
2981 #ifndef XpmReturnAllocPixels
2982 no_return_alloc_pixels
2983 #endif
2984       ], HAVE_XPM=no, HAVE_XPM=yes)
2985
2986       if test "${HAVE_XPM}" = "yes"; then
2987         AC_MSG_RESULT(yes)
2988       else
2989         AC_MSG_RESULT(no)
2990       fi
2991     fi
2992   fi
2993
2994   if test "${HAVE_XPM}" = "yes"; then
2995     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2996     LIBXPM=-lXpm
2997   fi
2998 fi
2999
3000 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3001 ### slightly different requirements wrt image libraries (it doesn't
3002 ### use -lXpm because it loads the xpm shared library dynamically at
3003 ### run time).
3004 if test "${opsys}" = "mingw32"; then
3005   if test "${with_xpm}" != "no"; then
3006     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3007 #define FOR_MSW 1])
3008   fi
3009
3010   if test "${HAVE_XPM}" = "yes"; then
3011     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3012   fi
3013 fi
3014
3015 AC_SUBST(LIBXPM)
3016
3017 ### Use -ljpeg if available, unless `--with-jpeg=no'.
3018 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
3019 HAVE_JPEG=no
3020 LIBJPEG=
3021 if test "${opsys}" = "mingw32"; then
3022   if test "${with_jpeg}" != "no"; then
3023     dnl Checking for jpeglib.h can lose because of a redefinition of
3024     dnl HAVE_STDLIB_H.
3025     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
3026   fi
3027   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3028   if test "${HAVE_JPEG}" = "yes"; then
3029     AC_DEFINE(HAVE_JPEG)
3030     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3031         [#include <jpeglib.h>
3032          version=JPEG_LIB_VERSION
3033 ],
3034         [AC_DEFINE(HAVE_JPEG)],
3035         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3036         HAVE_JPEG=no])
3037   fi
3038 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3039   if test "${with_jpeg}" != "no"; then
3040     dnl Checking for jpeglib.h can lose because of a redefinition of
3041     dnl  HAVE_STDLIB_H.
3042     AC_CHECK_HEADER(jerror.h,
3043       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
3044   fi
3045
3046   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3047   if test "${HAVE_JPEG}" = "yes"; then
3048     AC_DEFINE(HAVE_JPEG)
3049     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3050         [#include <jpeglib.h>
3051          version=JPEG_LIB_VERSION
3052 ],
3053         [AC_DEFINE(HAVE_JPEG)],
3054         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3055         HAVE_JPEG=no])
3056   fi
3057   if test "${HAVE_JPEG}" = "yes"; then
3058     LIBJPEG=-ljpeg
3059   fi
3060 fi
3061 AC_SUBST(LIBJPEG)
3062
3063 ### Use -lpng if available, unless `--with-png=no'.
3064 ### mingw32 doesn't use -lpng, since it loads the library dynamically.
3065 HAVE_PNG=no
3066 LIBPNG=
3067 if test "${opsys}" = "mingw32"; then
3068   if test "${with_png}" != "no"; then
3069     AC_CHECK_HEADER(png.h, HAVE_PNG=yes, HAVE_PNG=no)
3070   fi
3071   if test "${HAVE_PNG}" = "yes"; then
3072     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
3073
3074     AC_CHECK_DECL(png_longjmp,
3075       [],
3076       [AC_DEFINE(PNG_DEPSTRUCT, [],
3077          [Define to empty to suppress deprecation warnings when building
3078           with --enable-gcc-warnings and with libpng versions before 1.5,
3079           which lack png_longjmp.])],
3080       [[#ifdef HAVE_LIBPNG_PNG_H
3081         # include <libpng/png.h>
3082         #else
3083         # include <png.h>
3084         #endif
3085       ]])
3086   fi
3087 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3088   if test "${with_png}" != "no"; then
3089     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3090     # in /usr/include/libpng.
3091     AC_CHECK_HEADERS(png.h libpng/png.h, break)
3092     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
3093       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
3094     fi
3095   fi
3096
3097   if test "${HAVE_PNG}" = "yes"; then
3098     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
3099     LIBPNG="-lpng -lz -lm"
3100
3101     AC_CHECK_DECL(png_longjmp,
3102       [],
3103       [AC_DEFINE(PNG_DEPSTRUCT, [],
3104          [Define to empty to suppress deprecation warnings when building
3105           with --enable-gcc-warnings and with libpng versions before 1.5,
3106           which lack png_longjmp.])],
3107       [[#ifdef HAVE_LIBPNG_PNG_H
3108         # include <libpng/png.h>
3109         #else
3110         # include <png.h>
3111         #endif
3112       ]])
3113   fi
3114 fi
3115 AC_SUBST(LIBPNG)
3116
3117 HAVE_ZLIB=no
3118 LIBZ=
3119 if test "${with_zlib}" != "no"; then
3120   OLIBS=$LIBS
3121   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3122   LIBS=$OLIBS
3123   case $ac_cv_search_inflateEnd in
3124     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3125   esac
3126 fi
3127 if test "${HAVE_ZLIB}" = "yes"; then
3128   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3129   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3130   if test "${opsys}" = "mingw32"; then
3131      LIBZ=
3132   fi
3133 fi
3134 AC_SUBST(LIBZ)
3135
3136
3137 ### Use -ltiff if available, unless `--with-tiff=no'.
3138 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3139 HAVE_TIFF=no
3140 LIBTIFF=
3141 if test "${opsys}" = "mingw32"; then
3142   if test "${with_tiff}" != "no"; then
3143     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3144   fi
3145   if test "${HAVE_TIFF}" = "yes"; then
3146     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3147   fi
3148 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3149   if test "${with_tiff}" != "no"; then
3150     AC_CHECK_HEADER(tiffio.h,
3151       [tifflibs="-lz -lm"
3152       # At least one tiff package requires the jpeg library.
3153       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3154       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3155   fi
3156
3157   if test "${HAVE_TIFF}" = "yes"; then
3158     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3159     dnl FIXME -lz -lm, as per libpng?
3160     LIBTIFF=-ltiff
3161   fi
3162 fi
3163 AC_SUBST(LIBTIFF)
3164
3165 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
3166 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3167 HAVE_GIF=no
3168 LIBGIF=
3169 if test "${opsys}" = "mingw32"; then
3170   if test "${with_gif}" != "no"; then
3171     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3172   fi
3173   if test "${HAVE_GIF}" = "yes"; then
3174     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3175   fi
3176 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3177         || test "${HAVE_W32}" = "yes"; then
3178   AC_CHECK_HEADER(gif_lib.h,
3179 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3180 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3181     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3182         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3183
3184   if test "$HAVE_GIF" = yes; then
3185     LIBGIF=-lgif
3186   elif test "$HAVE_GIF" = maybe; then
3187 # If gif_lib.h but no libgif, try libungif.
3188     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3189     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3190   fi
3191
3192   if test "${HAVE_GIF}" = "yes"; then
3193     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3194   fi
3195 fi
3196 AC_SUBST(LIBGIF)
3197
3198 dnl Check for required libraries.
3199 if test "${HAVE_X11}" = "yes"; then
3200   MISSING=""
3201   WITH_NO=""
3202   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3203     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3204   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3205     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3206   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3207     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3208   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3209     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3210   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3211     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3212
3213   if test "X${MISSING}" != X; then
3214     AC_MSG_ERROR([The following required libraries were not found:
3215     $MISSING
3216 Maybe some development libraries/packages are missing?
3217 If you don't want to link with them give
3218     $WITH_NO
3219 as options to configure])
3220   fi
3221 fi
3222
3223 ### Use -lgpm if available, unless `--with-gpm=no'.
3224 HAVE_GPM=no
3225 LIBGPM=
3226 if test "${with_gpm}" != "no"; then
3227   AC_CHECK_HEADER(gpm.h,
3228     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3229
3230   if test "${HAVE_GPM}" = "yes"; then
3231     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3232     LIBGPM=-lgpm
3233   fi
3234 fi
3235 AC_SUBST(LIBGPM)
3236
3237 dnl Check for malloc/malloc.h on darwin
3238 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3239
3240 GNUSTEP_CFLAGS=
3241 ### Use NeXTstep API to implement GUI.
3242 if test "${HAVE_NS}" = "yes"; then
3243   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3244   if test "${NS_IMPL_COCOA}" = "yes"; then
3245     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3246   fi
3247   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3248     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3249     # See also .m.o rule in Makefile.in */
3250     # FIXME: are all these flags really needed?  Document here why.  */
3251     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3252     ## Extra CFLAGS applied to src/*.m files.
3253     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3254   fi
3255   OTHER_FILES=ns-app
3256 fi
3257
3258 ### Use session management (-lSM -lICE) if available
3259 HAVE_X_SM=no
3260 LIBXSM=
3261 if test "${HAVE_X11}" = "yes"; then
3262   AC_CHECK_HEADER(X11/SM/SMlib.h,
3263     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3264
3265   if test "${HAVE_X_SM}" = "yes"; then
3266     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3267     LIBXSM="-lSM -lICE"
3268     case "$LIBS" in
3269       *-lSM*) ;;
3270       *)      LIBS="$LIBXSM $LIBS" ;;
3271     esac
3272   fi
3273 fi
3274 AC_SUBST(LIBXSM)
3275
3276 ### Use XRandr (-lXrandr) if available
3277 HAVE_XRANDR=no
3278 if test "${HAVE_X11}" = "yes"; then
3279   XRANDR_REQUIRED=1.2.2
3280   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3281   PKG_CHECK_MODULES(XRANDR, $XRANDR_MODULES, HAVE_XRANDR=yes, HAVE_XRANDR=no)
3282   if test $HAVE_XRANDR = no; then
3283     # Test old way in case pkg-config doesn't have it (older machines).
3284     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3285       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)])
3286     if test $HAVE_XRANDR = yes; then
3287       XRANDR_LIBS=-lXrandr
3288       AC_SUBST(XRANDR_LIBS)
3289     fi
3290   fi
3291   if test $HAVE_XRANDR = yes; then
3292     SAVE_CFLAGS="$CFLAGS"
3293     SAVE_LIBS="$LIBS"
3294     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3295     LIBS="$XRANDR_LIBS $LIBS"
3296     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3297     CFLAGS="$SAVE_CFLAGS"
3298     LIBS="$SAVE_LIBS"
3299
3300     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3301   fi
3302 fi
3303
3304 ### Use Xinerama (-lXinerama) if available
3305 HAVE_XINERAMA=no
3306 if test "${HAVE_X11}" = "yes"; then
3307   XINERAMA_REQUIRED=1.0.2
3308   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3309   PKG_CHECK_MODULES(XINERAMA, $XINERAMA_MODULES, HAVE_XINERAMA=yes,
3310                     HAVE_XINERAMA=no)
3311   if test $HAVE_XINERAMA = no; then
3312     # Test old way in case pkg-config doesn't have it (older machines).
3313     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3314       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3315     if test $HAVE_XINERAMA = yes; then
3316       XINERAMA_LIBS=-lXinerama
3317       AC_SUBST(XINERAMA_LIBS)
3318     fi
3319   fi
3320   if test $HAVE_XINERAMA = yes; then
3321     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3322   fi
3323 fi
3324
3325
3326 ### Use libxml (-lxml2) if available
3327 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3328 HAVE_LIBXML2=no
3329 if test "${with_xml2}" != "no"; then
3330   ### I'm not sure what the version number should be, so I just guessed.
3331   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3332   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3333   if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3334     SAVE_CPPFLAGS="$CPPFLAGS"
3335     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3336     AC_CHECK_HEADER(libxml/HTMLparser.h,
3337       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3338                      [#include <libxml/HTMLparser.h>])])
3339     CPPFLAGS="$SAVE_CPPFLAGS"
3340     if test "${HAVE_LIBXML2}" = "yes"; then
3341       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3342       LIBXML2_LIBS="-lxml2"
3343     fi
3344   fi
3345   if test "${HAVE_LIBXML2}" = "yes"; then
3346     if test "${opsys}" != "mingw32"; then
3347       LIBS="$LIBXML2_LIBS $LIBS"
3348       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3349     else
3350       LIBXML2_LIBS=""
3351     fi
3352     if test "${HAVE_LIBXML2}" = "yes"; then
3353       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3354     else
3355       LIBXML2_LIBS=""
3356       LIBXML2_CFLAGS=""
3357     fi
3358   fi
3359 fi
3360 AC_SUBST(LIBXML2_LIBS)
3361 AC_SUBST(LIBXML2_CFLAGS)
3362
3363 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3364 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3365 if test "${opsys}" = "mingw32"; then
3366   emacs_cv_netdb_declares_h_errno=yes
3367 fi
3368 AC_CACHE_CHECK(whether netdb declares h_errno,
3369                emacs_cv_netdb_declares_h_errno,
3370 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3371   [[return h_errno;]])],
3372   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3373 if test $emacs_cv_netdb_declares_h_errno = yes; then
3374   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3375 fi
3376
3377 # sqrt and other floating-point functions such as fmod and frexp
3378 # are found in -lm on most systems, but mingw32 doesn't use -lm.
3379 if test "${opsys}" != "mingw32"; then
3380   AC_CHECK_LIB(m, sqrt)
3381 fi
3382
3383 # Check for mail-locking functions in a "mail" library.  Probably this should
3384 # have the same check as for liblockfile below.
3385 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3386 if test $have_mail = yes; then
3387   LIBS_MAIL=-lmail
3388   LIBS="$LIBS_MAIL $LIBS"
3389   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3390 else
3391   LIBS_MAIL=
3392 fi
3393 dnl Debian, at least:
3394 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3395 if test $have_lockfile = yes; then
3396    LIBS_MAIL=-llockfile
3397    LIBS="$LIBS_MAIL $LIBS"
3398    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3399 else
3400 # If we have the shared liblockfile, assume we must use it for mail
3401 # locking (e.g. Debian).  If we couldn't link against liblockfile
3402 # (no liblockfile.a installed), ensure that we don't need to.
3403   dnl This works for files generally, not just executables.
3404   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3405   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3406                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3407   if test $ac_cv_prog_liblockfile = yes; then
3408     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3409 This probably means that movemail could lose mail.
3410 There may be a `development' package to install containing liblockfile.])
3411   fi
3412 fi
3413 AC_CHECK_HEADERS_ONCE(maillock.h)
3414 AC_SUBST(LIBS_MAIL)
3415
3416 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3417 ## interlock access to the mail spool.  The alternative is a lock file named
3418 ## /usr/spool/mail/$USER.lock.
3419 mail_lock=no
3420 case "$opsys" in
3421   aix4-2) mail_lock="lockf" ;;
3422
3423   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3424
3425   ## On GNU/Linux systems, both methods are used by various mail programs.
3426   ## I assume most people are using newer mailers that have heard of flock.
3427   ## Change this if you need to.
3428   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3429   ## configure gets the right answers, and that means *NOT* using flock.
3430   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3431   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3432   ## Debian maintainer hasn't provided a clean fix for Emacs.
3433   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3434   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3435   ## correct logic.  -- fx
3436   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3437   ## liblockfile is a Free Software replacement for libmail, used on
3438   ## Debian systems and elsewhere. -rfr.
3439   gnu-*)
3440     mail_lock="flock"
3441     if test $have_mail = yes || test $have_lockfile = yes; then
3442       test $ac_cv_header_maillock_h = yes && mail_lock=no
3443     fi
3444     ;;
3445
3446   mingw32)
3447     mail_lock="none-needed" ;;
3448 esac
3449
3450 BLESSMAIL_TARGET=
3451 case "$mail_lock" in
3452   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3453
3454   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3455
3456   none-needed) ;;
3457
3458   *) BLESSMAIL_TARGET="need-blessmail" ;;
3459 esac
3460 AC_SUBST(BLESSMAIL_TARGET)
3461
3462
3463 AC_CHECK_FUNCS(accept4 gethostname \
3464 getrusage get_current_dir_name \
3465 lrand48 \
3466 select getpagesize setlocale \
3467 getrlimit setrlimit shutdown getaddrinfo \
3468 strsignal setitimer \
3469 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3470 gai_strerror getline getdelim sync \
3471 difftime \
3472 getpwent endpwent getgrent endgrent \
3473 touchlock \
3474 cfmakeraw cfsetspeed copysign __executable_start log2)
3475
3476 dnl No need to check for aligned_alloc and posix_memalign if using
3477 dnl gmalloc.o, as it supplies them.  Don't use these functions on
3478 dnl Darwin as they are incompatible with unexmacosx.c.
3479 if test -z "$GMALLOC_OBJ" && test "$opsys" != darwin; then
3480   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3481 fi
3482
3483 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
3484 ## has a broken `rint' in some library versions including math library
3485 ## version number A.09.05.
3486 ## You can fix the math library by installing patch number PHSS_4630.
3487 ## But we can fix it more reliably for Emacs by just not using rint.
3488 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
3489 case $opsys in
3490    hpux*) : ;;
3491    *) AC_CHECK_FUNCS(random rint) ;;
3492 esac
3493
3494 dnl Cannot use AC_CHECK_FUNCS
3495 AC_CACHE_CHECK([for __builtin_unwind_init],
3496                emacs_cv_func___builtin_unwind_init,
3497 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3498                 emacs_cv_func___builtin_unwind_init=yes,
3499                 emacs_cv_func___builtin_unwind_init=no)])
3500 if test $emacs_cv_func___builtin_unwind_init = yes; then
3501   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3502             [Define to 1 if you have the `__builtin_unwind_init' function.])
3503 fi
3504
3505 AC_CHECK_HEADERS_ONCE(sys/un.h)
3506
3507 AC_FUNC_FSEEKO
3508
3509 # UNIX98 PTYs.
3510 AC_CHECK_FUNCS(grantpt)
3511
3512 # PTY-related GNU extensions.
3513 AC_CHECK_FUNCS(getpt posix_openpt)
3514
3515 # Check this now, so that we will NOT find the above functions in ncurses.
3516 # That is because we have not set up to link ncurses in lib-src.
3517 # It's better to believe a function is not available
3518 # than to expect to find it in ncurses.
3519 # Also we need tputs and friends to be able to build at all.
3520 AC_MSG_CHECKING([for library containing tputs])
3521 # Run a test program that contains a call to tputs, a call that is
3522 # never executed.  This tests whether a pre-'main' dynamic linker
3523 # works with the library.  It's too much trouble to actually call
3524 # tputs in the test program, due to portability hassles.  When
3525 # cross-compiling, assume the test program will run if it links.
3526 AC_DEFUN([tputs_link_source], [
3527   AC_LANG_SOURCE(
3528      [[extern void tputs (const char *, int, int (*)(int));
3529        int main (int argc, char **argv)
3530        {
3531           if (argc == 10000)
3532             tputs (argv[0], 0, 0);
3533           return 0;
3534        }]])
3535 ])
3536 if test "${opsys}" = "mingw32"; then
3537   msg='none required'
3538 else
3539   # Maybe curses should be tried earlier?
3540   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3541   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3542     OLIBS=$LIBS
3543     if test -z "$tputs_library"; then
3544       LIBS_TERMCAP=
3545       msg='none required'
3546     else
3547       LIBS_TERMCAP=-l$tputs_library
3548       msg=$LIBS_TERMCAP
3549       LIBS="$LIBS_TERMCAP $LIBS"
3550     fi
3551     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3552       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3553     LIBS=$OLIBS
3554     if test "X$msg" != Xno; then
3555       break
3556     fi
3557   done
3558 fi
3559 AC_MSG_RESULT([$msg])
3560 if test "X$msg" = Xno; then
3561   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3562 The following libraries were tried (in order):
3563   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3564 Please try installing whichever of these libraries is most appropriate
3565 for your system, together with its header files.
3566 For example, a libncurses-dev(el) or similar package.])
3567 fi
3568
3569 ## Use termcap instead of terminfo?
3570 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3571 TERMINFO=yes
3572 ## FIXME?  In the cases below where we unconditionally set
3573 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3574 ## if that was found above to have tputs.
3575 ## Should we use the gnu* logic everywhere?
3576 case "$opsys" in
3577   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3578   ##  The ncurses library has been moved out of the System framework in
3579   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3580   ##  option to use it.
3581   darwin) LIBS_TERMCAP="-lncurses" ;;
3582
3583   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3584
3585   freebsd)
3586     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3587     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3588     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3589 [[#if __FreeBSD_version < 400000
3590 fail;
3591 #endif
3592 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3593
3594     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3595
3596     if test $emacs_cv_freebsd_terminfo = yes; then
3597       LIBS_TERMCAP="-lncurses"
3598     else
3599       TERMINFO=no
3600       LIBS_TERMCAP="-ltermcap"
3601     fi
3602     ;;
3603
3604   mingw32)
3605     TERMINFO=no
3606     LIBS_TERMCAP=
3607     ;;
3608
3609   netbsd)
3610     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3611       TERMINFO=no
3612       LIBS_TERMCAP="-ltermcap"
3613     fi
3614     ;;
3615
3616   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3617
3618   ## hpux: Make sure we get select from libc rather than from libcurses
3619   ##  because libcurses on HPUX 10.10 has a broken version of select.
3620   ##  We used to use -lc -lcurses, but this may be cleaner.
3621   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3622   # set that way, now it uses the default).  Isn't this a contradiction?
3623   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3624
3625 esac
3626
3627 TERMCAP_OBJ=tparam.o
3628 if test $TERMINFO = yes; then
3629   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3630   TERMCAP_OBJ=terminfo.o
3631 fi
3632 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3633   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3634 fi
3635 AC_SUBST(LIBS_TERMCAP)
3636 AC_SUBST(TERMCAP_OBJ)
3637
3638
3639 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3640 # On Darwin, res_init appears not to be useful: see bug#562 and
3641 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3642 resolv=no
3643
3644 if test $opsys != darwin; then
3645
3646   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3647 #include <arpa/nameser.h>
3648 #include <resolv.h>]],
3649     [[return res_init();]])],
3650     have_res_init=yes, have_res_init=no)
3651   if test "$have_res_init" = no; then
3652     OLIBS="$LIBS"
3653     LIBS="$LIBS -lresolv"
3654     AC_MSG_CHECKING(for res_init with -lresolv)
3655     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3656 #include <arpa/nameser.h>
3657 #include <resolv.h>]],
3658       [[return res_init();]])],
3659       have_res_init=yes, have_res_init=no)
3660     AC_MSG_RESULT($have_res_init)
3661     if test "$have_res_init" = yes ; then
3662       resolv=yes
3663     fi
3664     LIBS="$OLIBS"
3665   fi
3666
3667   if test "$have_res_init" = yes; then
3668     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3669   fi
3670 fi                              dnl !darwin
3671
3672 # Do we need the Hesiod library to provide the support routines?
3673 dnl FIXME?  Should we be skipping this on Darwin too?
3674 LIBHESIOD=
3675 if test "$with_hesiod" != no ; then
3676   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3677   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3678      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3679                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3680   if test "$resolv" = yes ; then
3681     RESOLVLIB=-lresolv
3682   else
3683     RESOLVLIB=
3684   fi
3685   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3686         hesiod=yes, :, $RESOLVLIB)])
3687
3688   if test x"$hesiod" = xyes; then
3689     LIBHESIOD=-lhesiod
3690   fi
3691 fi
3692 AC_SUBST(LIBHESIOD)
3693
3694 # Do we need libresolv (due to res_init or Hesiod)?
3695 if test "$resolv" = yes && test $opsys != darwin; then
3696   LIBRESOLV=-lresolv
3697 else
3698   LIBRESOLV=
3699 fi
3700 AC_SUBST(LIBRESOLV)
3701
3702 # These tell us which Kerberos-related libraries to use.
3703 COM_ERRLIB=
3704 CRYPTOLIB=
3705 KRB5LIB=
3706 DESLIB=
3707 KRB4LIB=
3708
3709 if test "${with_kerberos}" != no; then
3710   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3711   if test $have_com_err = yes; then
3712     COM_ERRLIB=-lcom_err
3713     LIBS="$COM_ERRLIB $LIBS"
3714   fi
3715   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3716   if test $have_crypto = yes; then
3717     CRYPTOLIB=-lcrypto
3718     LIBS="$CRYPTOLIB $LIBS"
3719   fi
3720   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3721   if test $have_k5crypto = yes; then
3722     CRYPTOLIB=-lk5crypto
3723     LIBS="$CRYPTOLIB $LIBS"
3724   fi
3725   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3726   if test $have_krb5=yes; then
3727     KRB5LIB=-lkrb5
3728     LIBS="$KRB5LIB $LIBS"
3729   fi
3730   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3731   if test "${with_kerberos5}" = no; then
3732     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3733     if test $have_des425 = yes; then
3734       DESLIB=-ldes425
3735       LIBS="$DESLIB $LIBS"
3736     else
3737       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3738       if test $have_des = yes; then
3739         DESLIB=-ldes
3740         LIBS="$DESLIB $LIBS"
3741       fi
3742     fi
3743     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3744     if test $have_krb4 = yes; then
3745       KRB4LIB=-lkrb4
3746       LIBS="$KRB4LIB $LIBS"
3747     else
3748       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3749       if test $have_krb = yes; then
3750         KRB4LIB=-lkrb
3751         LIBS="$KRB4LIB $LIBS"
3752       fi
3753     fi
3754   fi
3755
3756   if test "${with_kerberos5}" != no; then
3757     AC_CHECK_HEADERS(krb5.h,
3758       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3759                         [#include <krb5.h>])])
3760   else
3761     AC_CHECK_HEADERS(krb.h,,
3762                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3763                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3764   fi
3765   AC_CHECK_HEADERS(com_err.h)
3766 fi
3767
3768 AC_SUBST(COM_ERRLIB)
3769 AC_SUBST(CRYPTOLIB)
3770 AC_SUBST(KRB5LIB)
3771 AC_SUBST(DESLIB)
3772 AC_SUBST(KRB4LIB)
3773
3774 AC_CHECK_HEADERS(valgrind/valgrind.h)
3775
3776 AC_CHECK_FUNCS_ONCE(tzset)
3777 AC_MSG_CHECKING(whether localtime caches TZ)
3778 AC_CACHE_VAL(emacs_cv_localtime_cache,
3779 [if test x$ac_cv_func_tzset = xyes; then
3780 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3781 char TZ_GMT0[] = "TZ=GMT0";
3782 char TZ_PST8[] = "TZ=PST8";
3783 main()
3784 {
3785   time_t now = time ((time_t *) 0);
3786   int hour_GMT0, hour_unset;
3787   if (putenv (TZ_GMT0) != 0)
3788     exit (1);
3789   hour_GMT0 = localtime (&now)->tm_hour;
3790   unsetenv("TZ");
3791   hour_unset = localtime (&now)->tm_hour;
3792   if (putenv (TZ_PST8) != 0)
3793     exit (1);
3794   if (localtime (&now)->tm_hour == hour_GMT0)
3795     exit (1);
3796   unsetenv("TZ");
3797   if (localtime (&now)->tm_hour != hour_unset)
3798     exit (1);
3799   exit (0);
3800 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3801 [# If we have tzset, assume the worst when cross-compiling.
3802 emacs_cv_localtime_cache=yes])
3803 else
3804         # If we lack tzset, report that localtime does not cache TZ,
3805         # since we can't invalidate the cache if we don't have tzset.
3806         emacs_cv_localtime_cache=no
3807 fi])dnl
3808 AC_MSG_RESULT($emacs_cv_localtime_cache)
3809 if test $emacs_cv_localtime_cache = yes; then
3810   AC_DEFINE(LOCALTIME_CACHE, 1,
3811             [Define to 1 if localtime caches TZ.])
3812 fi
3813
3814 ok_so_far=yes
3815 AC_CHECK_FUNC(socket, , ok_so_far=no)
3816 if test $ok_so_far = yes; then
3817   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3818 fi
3819 if test $ok_so_far = yes; then
3820   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3821 fi
3822 if test $ok_so_far = yes; then
3823 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3824   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3825             [Define to 1 if you have inet sockets.])
3826 fi
3827
3828 dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69).
3829 dnl This can be removed once we assume Autoconf 2.70.
3830 case $canonical in
3831   *-solaris2.4 | *-solaris2.4.*)
3832     dnl Disable the Autoconf-generated vfork test.
3833     : ${ac_cv_func_vfork_works=no};;
3834 esac
3835
3836 AC_FUNC_FORK
3837
3838 AC_CHECK_FUNCS(snprintf)
3839
3840 dnl Check this late.  It depends on what other libraries (lrsvg, Gtk+ etc)
3841 dnl Emacs uses.
3842 XGSELOBJ=
3843 AC_MSG_CHECKING([whether GLib is linked in])
3844 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3845         [[#include <glib.h>
3846         ]],
3847         [[g_print ("Hello world");]])],
3848      [links_glib=yes],
3849      [links_glib=no])
3850 AC_MSG_RESULT([$links_glib])
3851 if test "${links_glib}" = "yes"; then
3852   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
3853   if test "$HAVE_NS" = no;then
3854     XGSELOBJ=xgselect.o
3855   fi
3856 fi
3857 AC_SUBST(XGSELOBJ)
3858
3859 dnl Adapted from Haible's version.
3860 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3861   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3862     [[char* cs = nl_langinfo(CODESET);]])],
3863     emacs_cv_langinfo_codeset=yes,
3864     emacs_cv_langinfo_codeset=no)
3865   ])
3866 if test $emacs_cv_langinfo_codeset = yes; then
3867   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3868     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3869 fi
3870
3871 AC_TYPE_MBSTATE_T
3872
3873 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3874   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3875                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3876 if test "$emacs_cv_c_restrict_arr" = yes; then
3877   AC_DEFINE(__restrict_arr, __restrict,
3878     [Define to compiler's equivalent of C99 restrict keyword in array
3879      declarations.  Define as empty for no equivalent.])
3880 fi
3881
3882 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3883 dnl how the tty code is related to POSIX and/or other versions of termios.
3884 dnl The following looks like a useful start.
3885 dnl
3886 dnl AC_SYS_POSIX_TERMIOS
3887 dnl if test $ac_cv_sys_posix_termios = yes; then
3888 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3889 dnl                                and macros for terminal control.])
3890 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3891 dnl fi
3892
3893 dnl Turned on June 1996 supposing nobody will mind it.
3894 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
3895 if test "${opsys}" != "mingw32"; then
3896    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3897      in the full name stands for the login id.])
3898 fi
3899
3900 dnl Every platform that uses configure supports this.
3901 dnl There is a create-lockfiles option you can
3902 dnl customize if you do not want the lock files to be written.
3903 dnl So it is not clear that this #define still needs to exist.
3904 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3905   so that Emacs can tell instantly when you try to modify a file that
3906   someone else has modified in his/her Emacs.])
3907
3908 dnl Everybody supports this, except MS.
3909 dnl Seems like the kind of thing we should be testing for, though.
3910 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3911 if test "${opsys}" != "mingw32"; then
3912   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3913 fi
3914
3915 dnl Everybody supports this, except MS-DOS.
3916 dnl Seems like the kind of thing we should be testing for, though.
3917 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3918 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3919   4.2-compatible sockets.])
3920
3921 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3922
3923 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
3924   a null file, or a data sink.])
3925 if test "${opsys}" = "mingw32"; then
3926   AC_DEFINE(NULL_DEVICE, ["NUL:"])
3927 else
3928   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
3929 fi
3930
3931 if test "${opsys}" = "mingw32"; then
3932   SEPCHAR=';'
3933 else
3934   SEPCHAR=':'
3935 fi
3936 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
3937 dnl This is for MinGW, and is used in test/automated/Makefile.in.
3938 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
3939 dnl decides that a command-line argument to be passed to a MinGW program
3940 dnl is a PATH-style list of directories.  But that heuristics plays it
3941 dnl safe, and only does the replacement when it is _absolutely_ sure it
3942 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
3943 dnl which breaks in-tree builds.  So we do this manually instead.
3944 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
3945 dnl be computed as ':' in MSYS Bash.
3946 AC_SUBST(SEPCHAR)
3947
3948 dnl Everybody supports this, except MS-DOS.
3949 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3950
3951 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3952
3953
3954 AC_DEFINE(DIRECTORY_SEP, ['/'],
3955   [Character that separates directories in a file name.])
3956
3957 if test "${opsys}" = "mingw32"; then
3958   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
3959     [Returns true if character is a device separator.])
3960
3961   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
3962     [Returns true if character is a directory separator.])
3963
3964   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
3965     [Returns true if character is any form of separator.])
3966 else
3967   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3968     [Returns true if character is a device separator.])
3969
3970   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3971     [Returns true if character is a directory separator.])
3972
3973   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3974     [Returns true if character is any form of separator.])
3975 fi
3976
3977 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3978
3979 case $opsys in
3980   aix4-2)
3981     dnl Unfortunately without libXmu we cannot support EditRes.
3982     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3983       AC_DEFINE(NO_EDITRES, 1)
3984     fi
3985     ;;
3986
3987   hpux*)
3988     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3989     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3990     AC_DEFINE(NO_EDITRES, 1)
3991     ;;
3992 esac
3993
3994
3995 case $opsys in
3996   irix6-5 | sol2* | unixware )
3997     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3998     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3999     dnl need the constant to dimension an array.  So wire in the appropriate
4000     dnl value here.
4001     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4002     ;;
4003 esac
4004
4005 emacs_broken_SIGIO=no
4006
4007 case $opsys in
4008   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4009   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4010   hpux* | irix6-5 | openbsd | sol2* | unixware )
4011     emacs_broken_SIGIO=yes
4012     ;;
4013
4014   aix4-2)
4015     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4016     dnl the way this system works, libc functions that return malloced
4017     dnl memory use the libc malloc implementation. Calling xfree or
4018     dnl xrealloc on the results of such functions results in a crash.
4019     dnl
4020     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4021     dnl but that does not currently work on this system.
4022     dnl
4023     dnl It is possible to completely override the malloc implementation on
4024     dnl AIX, but that involves putting the malloc functions in a shared
4025     dnl library and setting the MALLOCTYPE environment variable to point to
4026     dnl that shared library.
4027     dnl
4028     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4029     dnl to avoid a crash just use the Emacs implementation for that function.
4030     dnl
4031     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4032     dnl of this file, so that we do not check for get_current_dir_name
4033     dnl on AIX.  But that might be fragile if something else ends
4034     dnl up testing for get_current_dir_name as a dependency.
4035     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4036       get_current_dir_name should not be used.])
4037     ;;
4038
4039   freebsd)
4040     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4041     dnl writes/reads on a PTY, read(2) returns bogus data:
4042     dnl
4043     dnl write(2)  1022 bytes
4044     dnl write(2)   954 bytes, get EAGAIN
4045     dnl read(2)   1024 bytes in process_read_output
4046     dnl read(2)     11 bytes in process_read_output
4047     dnl
4048     dnl That is, read(2) returns more bytes than have ever been written
4049     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4050     dnl successfully after processing (for example with CRs added if the
4051     dnl terminal is set up that way which it is here).  The same bytes will
4052     dnl be seen again in a later read(2), without the CRs.
4053     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4054       work around an issue when reading from a PTY.])
4055     ;;
4056 esac
4057
4058 case $opsys in
4059   gnu-* | sol2-10 )
4060     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4061     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4062   ;;
4063 esac
4064
4065 case $opsys in
4066   darwin | dragonfly | freebsd | netbsd | openbsd )
4067     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4068       close a pty to make it a controlling terminal (it is already a
4069       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4070   ;;
4071 esac
4072
4073 dnl FIXME Surely we can test for this rather than hard-code it.
4074 case $opsys in
4075   netbsd | openbsd) sound_device="/dev/audio" ;;
4076   *) sound_device="/dev/dsp" ;;
4077 esac
4078
4079 dnl Used in sound.c
4080 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4081   [Name of the default sound device.])
4082
4083
4084 dnl Emacs can read input using SIGIO and buffering characters itself,
4085 dnl or using CBREAK mode and making C-g cause SIGINT.
4086 dnl The choice is controlled by the variable interrupt_input.
4087 dnl
4088 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4089 dnl
4090 dnl Emacs uses the presence of the USABLE_SIGIO macro
4091 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4092 dnl INTERRUPT_INPUT to decide whether to use it by default.
4093 dnl
4094 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4095 dnl CBREAK mode has two disadvantages
4096 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4097 dnl I hear that in system V this problem does not exist.
4098 dnl 2) Control-G causes output to be discarded.
4099 dnl I do not know whether this can be fixed in system V.
4100 dnl
4101 dnl Another method of doing input is planned but not implemented.
4102 dnl It would have Emacs fork off a separate process
4103 dnl to read the input and send it to the true Emacs process
4104 dnl through a pipe.
4105 case $opsys in
4106   darwin | gnu-linux | gnu-kfreebsd )
4107     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4108   ;;
4109 esac
4110
4111
4112 dnl If the system's imake configuration file defines `NeedWidePrototypes'
4113 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
4114 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
4115 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4116 dnl taking float or double parameters.
4117 case $opsys in
4118   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4119     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4120       file defines `NeedWidePrototypes' as `NO'.])
4121   ;;
4122 esac
4123
4124
4125 dnl Used in process.c, this must be a loop, even if it only runs once.
4126 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4127 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4128 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4129 dnl trying suffixes 0-16.
4130 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4131   first PTY, if PTYs are supported.])
4132 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4133 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4134   end of a PTY, if non-standard.])
4135 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4136   end of a PTY, if non-standard.])
4137
4138 case $opsys in
4139   aix4-2 )
4140     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4141     dnl You allocate a pty by opening /dev/ptc to get the master side.
4142     dnl To get the name of the slave side, you just ttyname() the master side.
4143     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4144     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4145     ;;
4146
4147   cygwin )
4148     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4149     dnl multi-line AC_DEFINEs are hard. :(
4150     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4151     AC_DEFINE(PTY_NAME_SPRINTF, [])
4152     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4153     ;;
4154
4155   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4156   darwin )
4157     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4158     dnl Not used, because PTY_ITERATION is defined.
4159     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4160     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4161     dnl But we don't have to block SIGCHLD because it is blocked in the
4162     dnl implementation of grantpt.
4163     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4164     AC_DEFINE(PTY_NAME_SPRINTF, [])
4165     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4166     ;;
4167
4168   gnu | openbsd )
4169     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4170     ;;
4171
4172   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
4173     dnl if HAVE_GRANTPT
4174     if test "x$ac_cv_func_grantpt" = xyes; then
4175       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4176       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4177       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4178       dnl to prevent sigchld_handler from intercepting the child's death.
4179       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4180       dnl if HAVE_POSIX_OPENPT
4181       if test "x$ac_cv_func_posix_openpt" = xyes; then
4182         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4183         AC_DEFINE(PTY_NAME_SPRINTF, [])
4184       dnl if HAVE_GETPT
4185       elif test "x$ac_cv_func_getpt" = xyes; then
4186         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4187         AC_DEFINE(PTY_NAME_SPRINTF, [])
4188       else
4189         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4190       fi
4191     else
4192       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4193     fi
4194     ;;
4195
4196   hpux*)
4197     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4198     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4199     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4200     ;;
4201
4202   irix6-5 )
4203     dnl It looks like this cannot be right, because it is not a loop.
4204     dnl However, process.c actually does this:
4205     dnl # ifndef __sgi
4206     dnl   continue;
4207     dnl # else
4208     dnl   return -1;
4209     dnl # endif
4210     dnl which presumably makes it OK, since irix == sgi (?).
4211     dnl FIXME it seems like this special treatment is unnecessary?
4212     dnl Why can't irix use a single-trip loop like eg cygwin?
4213     AC_DEFINE(PTY_ITERATION, [])
4214     dnl Not used, because PTY_ITERATION is defined.
4215     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4216     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4217     dnl No need to get the pty name at all.
4218     AC_DEFINE(PTY_NAME_SPRINTF, [])
4219     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4220     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4221     ;;
4222
4223   sol2* )
4224     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4225     dnl from intercepting that death.  If any child but grantpt's should die
4226     dnl within, it should be caught after sigrelse(2).
4227     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4228     ;;
4229
4230   unixware )
4231     dnl Comments are as per sol2*.
4232     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4233     ;;
4234 esac
4235
4236
4237 case $opsys in
4238   sol2* | unixware )
4239     dnl This change means that we don't loop through allocate_pty too
4240     dnl many times in the (rare) event of a failure.
4241     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4242     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4243     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4244     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4245     ;;
4246 esac
4247
4248
4249 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4250 "typing" a signal character on the pty.])
4251
4252 case $opsys in
4253   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4254   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4255   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4256     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4257     ;;
4258
4259   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4260   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4261   gnu-linux | gnu-kfreebsd )
4262
4263     AC_MSG_CHECKING([for signals via characters])
4264     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4265 #include <linux/version.h>
4266 #if LINUX_VERSION_CODE < 0x20400
4267 # error "Linux version too old"
4268 #endif
4269       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4270
4271     AC_MSG_RESULT([$emacs_signals_via_chars])
4272     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4273     ;;
4274 esac
4275
4276
4277 dnl Used in lisp.h, emacs.c, vm-limit.c
4278 dnl NEWS.18 describes this as "a number which contains
4279 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
4280 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
4281 stored in a Lisp_Object.])
4282 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
4283
4284 case $opsys in
4285   aix*)
4286     dnl This works with 32-bit executables; Emacs doesn't support 64-bit.
4287     AC_DEFINE(DATA_SEG_BITS, [0x20000000])
4288     ;;
4289   hpux*)
4290     dnl The data segment on this machine always starts at address 0x40000000.
4291     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
4292     ;;
4293   irix6-5)
4294     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
4295     ;;
4296 esac
4297
4298
4299 AH_TEMPLATE(TAB3, [Undocumented.])
4300
4301 case $opsys in
4302   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4303
4304   gnu | dragonfly | freebsd | netbsd | openbsd )
4305     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4306     AC_DEFINE(TAB3, OXTABS)
4307     ;;
4308
4309   gnu-linux | gnu-kfreebsd )
4310     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4311 #ifndef __ia64__
4312 # error "not ia64"
4313 #endif
4314       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4315         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4316         [Mark a secondary stack, like the register stack on the ia64.]), [])
4317     ;;
4318
4319   hpux*)
4320     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4321       run_time_remap; for HPUX.])
4322     ;;
4323 esac
4324
4325
4326 dnl This won't be used automatically yet.  We also need to know, at least,
4327 dnl that the stack is continuous.
4328 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4329   registers relevant for conservative garbage collection in the jmp_buf.])
4330
4331
4332 case $opsys in
4333   dnl Not all the architectures are tested, but there are Debian packages
4334   dnl for SCM and/or Guile on them, so the technique must work.  See also
4335   dnl comments in alloc.c concerning setjmp and gcc.
4336   dnl Fixme: it's probably safe to just use the GCC conditional below.
4337   gnu-linux | gnu-kfreebsd )
4338     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4339 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4340   || defined __alpha__ || defined __mips__ || defined __s390__ \
4341   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4342   || defined __ia64__ || defined __sh__
4343 /* ok */
4344 #else
4345 # error "setjmp not known to work on this arch"
4346 #endif
4347     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4348     ;;
4349 esac
4350
4351
4352 if test x$GCC = xyes; then
4353    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4354    AC_DEFINE(GC_SETJMP_WORKS, 1)
4355 else
4356   case $opsys in
4357     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4358     dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4359       AC_DEFINE(GC_SETJMP_WORKS, 1)
4360       ;;
4361   esac
4362 fi                              dnl GCC?
4363
4364 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4365 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4366   [AC_LINK_IFELSE(
4367      [AC_LANG_PROGRAM(
4368        [[#include <setjmp.h>
4369          #ifdef __MINGW32__
4370          # define _longjmp longjmp
4371          #endif
4372        ]],
4373        [[jmp_buf j;
4374          if (! _setjmp (j))
4375            _longjmp (j, 1);]])],
4376      [emacs_cv_func__setjmp=yes],
4377      [emacs_cv_func__setjmp=no])])
4378 if test $emacs_cv_func__setjmp = yes; then
4379   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4380 else
4381   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4382     [AC_LINK_IFELSE(
4383        [AC_LANG_PROGRAM(
4384          [[#include <setjmp.h>
4385          ]],
4386          [[sigjmp_buf j;
4387            if (! sigsetjmp (j, 1))
4388              siglongjmp (j, 1);]])],
4389        [emacs_cv_func_sigsetjmp=yes],
4390        [emacs_cv_func_sigsetjmp=no])])
4391   if test $emacs_cv_func_sigsetjmp = yes; then
4392     AC_DEFINE([HAVE_SIGSETJMP], 1,
4393       [Define to 1 if sigsetjmp and siglongjmp work.
4394        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
4395   fi
4396 fi
4397
4398 case $opsys in
4399   sol2* | unixware )
4400     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4401     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4402     dnl and this is all we need.
4403     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4404     ;;
4405 esac
4406
4407
4408 case $opsys in
4409   hpux* | sol2* )
4410     dnl Used in xfaces.c.
4411     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4412       some systems, where it requires time.h.])
4413     ;;
4414 esac
4415
4416
4417 dnl Define symbols to identify the version of Unix this is.
4418 dnl Define all the symbols that apply correctly.
4419 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4420 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4421 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4422 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4423
4424 case $opsys in
4425   aix4-2)
4426     AC_DEFINE(USG, [])
4427     dnl This symbol should be defined on AIX Version 3  ???????
4428     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4429 #ifndef _AIX
4430 # error "_AIX not defined"
4431 #endif
4432     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4433     ;;
4434
4435   cygwin)
4436     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4437     ;;
4438
4439   darwin)
4440     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4441     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4442     dnl distinguish OS X from pure Darwin.
4443     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4444     ;;
4445
4446   gnu-linux | gnu-kfreebsd )
4447     AC_DEFINE(USG, [])
4448     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4449     ;;
4450
4451   hpux*)
4452     AC_DEFINE(USG, [])
4453     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4454     ;;
4455
4456   irix6-5)
4457     AC_DEFINE(USG, [])
4458     AC_DEFINE(USG5_4, [])
4459     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4460     ;;
4461
4462   mingw32)
4463     AC_DEFINE(DOS_NT, [])
4464     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4465     if test "x$ac_enable_checking" != "x" ; then
4466       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4467     fi
4468     ;;
4469
4470   sol2*)
4471     AC_DEFINE(USG, [])
4472     AC_DEFINE(USG5_4, [])
4473     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4474     ;;
4475
4476   unixware)
4477     AC_DEFINE(USG, [])
4478     AC_DEFINE(USG5_4, [])
4479     ;;
4480 esac
4481
4482 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4483   [case $opsys in
4484      aix4-2)
4485        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4486        emacs_cv_usable_FIONREAD=no
4487        ;;
4488
4489      mingw32)
4490        emacs_cv_usable_FIONREAD=yes
4491        ;;
4492
4493      *)
4494        AC_COMPILE_IFELSE(
4495          [AC_LANG_PROGRAM([[#include <sys/types.h>
4496                             #include <sys/ioctl.h>
4497                             #ifdef USG5_4
4498                             # include <sys/filio.h>
4499                             #endif
4500                           ]],
4501                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4502          [emacs_cv_usable_FIONREAD=yes],
4503          [emacs_cv_usable_FIONREAD=no])
4504        ;;
4505    esac])
4506 if test $emacs_cv_usable_FIONREAD = yes; then
4507   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4508
4509   if test $emacs_broken_SIGIO = no; then
4510     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4511       [AC_COMPILE_IFELSE(
4512          [AC_LANG_PROGRAM([[#include <fcntl.h>
4513                             #include <signal.h>
4514                           ]],
4515                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4516          [emacs_cv_usable_SIGIO=yes],
4517          [emacs_cv_usable_SIGIO=no])],
4518       [emacs_cv_usable_SIGIO=yes],
4519       [emacs_cv_usable_SIGIO=no])
4520     if test $emacs_cv_usable_SIGIO = yes; then
4521       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4522     fi
4523   fi
4524 fi
4525
4526
4527 case $opsys in
4528   dnl Emacs supplies its own malloc, but glib calls posix_memalign,
4529   dnl and on Cygwin prior to version 1.7.24 that becomes the
4530   dnl Cygwin-supplied posix_memalign.  As malloc is not the Cygwin
4531   dnl malloc, the Cygwin posix_memalign always returns ENOSYS.  A
4532   dnl workaround is to set G_SLICE=always-malloc.  This is no longer
4533   dnl needed starting with cygwin-1.7.24, and it is no longer
4534   dnl effective starting with glib-2.36. */
4535   cygwin)
4536     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
4537       G_SLICE environment variable to "always-malloc" at startup.])
4538     ;;
4539
4540   hpux11)
4541     dnl It works to open the pty's tty in the parent (Emacs), then
4542     dnl close and reopen it in the child.
4543     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4544       works to open a pty's tty in the parent process, then close and
4545       reopen it in the child.])
4546     ;;
4547
4548   irix6-5)
4549     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4550       use VSUSP instead of VSWTCH.])
4551     ;;
4552
4553   sol2-10)
4554     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4555       on Solaris.])
4556     ;;
4557 esac
4558
4559 # Set up the CFLAGS for real compilation, so we can substitute it.
4560 CFLAGS="$REAL_CFLAGS"
4561 CPPFLAGS="$REAL_CPPFLAGS"
4562
4563 ## Hack to detect a buggy GCC version.
4564 if test "x$GCC" = xyes \
4565    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4566    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4567    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4568    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4569 fi
4570
4571 version=$PACKAGE_VERSION
4572
4573 copyright="Copyright (C) 2014 Free Software Foundation, Inc."
4574 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4575   [Short copyright string for this version of Emacs.])
4576 AC_SUBST(copyright)
4577
4578 ### Specify what sort of things we'll be editing into Makefile and config.h.
4579 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4580 AC_SUBST(version)
4581 AC_SUBST(configuration)
4582 ## Unused?
4583 AC_SUBST(canonical)
4584 AC_SUBST(srcdir)
4585 AC_SUBST(prefix)
4586 AC_SUBST(exec_prefix)
4587 AC_SUBST(bindir)
4588 AC_SUBST(datadir)
4589 AC_SUBST(sharedstatedir)
4590 AC_SUBST(libexecdir)
4591 AC_SUBST(mandir)
4592 AC_SUBST(infodir)
4593 AC_SUBST(lispdir)
4594 AC_SUBST(standardlisppath)
4595 AC_SUBST(locallisppath)
4596 AC_SUBST(lisppath)
4597 AC_SUBST(x_default_search_path)
4598 AC_SUBST(etcdir)
4599 AC_SUBST(archlibdir)
4600 AC_SUBST(etcdocdir)
4601 AC_SUBST(bitmapdir)
4602 AC_SUBST(gamedir)
4603 AC_SUBST(gameuser)
4604 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4605 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4606 ## end of LIBX_BASE, but nothing ever set it.
4607 AC_SUBST(LD_SWITCH_X_SITE)
4608 AC_SUBST(C_SWITCH_X_SITE)
4609 AC_SUBST(GNUSTEP_CFLAGS)
4610 AC_SUBST(CFLAGS)
4611 ## Used in lwlib/Makefile.in.
4612 AC_SUBST(X_TOOLKIT_TYPE)
4613 AC_SUBST(ns_appdir)
4614 AC_SUBST(ns_appbindir)
4615 AC_SUBST(ns_appresdir)
4616 AC_SUBST(ns_appsrc)
4617 AC_SUBST(GNU_OBJC_CFLAGS)
4618 AC_SUBST(OTHER_FILES)
4619
4620 if test -n "${term_header}"; then
4621     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4622         [Define to the header for the built-in window system.])
4623 fi
4624
4625 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4626                    [Define to the canonical Emacs configuration name.])
4627 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4628                    [Define to the options passed to configure.])
4629 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4630   define this to include extra configuration information.])
4631
4632 case $opsys in
4633   mingw32)
4634     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4635     ;;
4636 esac
4637
4638 XMENU_OBJ=
4639 XOBJ=
4640 FONT_OBJ=
4641 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4642   AC_DEFINE(HAVE_X_WINDOWS, 1,
4643             [Define to 1 if you want to use the X window system.])
4644   XMENU_OBJ=xmenu.o
4645   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4646   FONT_OBJ=xfont.o
4647   if test "$HAVE_XFT" = "yes"; then
4648     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4649   elif test "$HAVE_FREETYPE" = "yes"; then
4650     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4651   fi
4652   AC_SUBST(FONT_OBJ)
4653 fi
4654 AC_SUBST(XMENU_OBJ)
4655 AC_SUBST(XOBJ)
4656 AC_SUBST(FONT_OBJ)
4657
4658 WIDGET_OBJ=
4659 MOTIF_LIBW=
4660 if test "${USE_X_TOOLKIT}" != "none" ; then
4661   WIDGET_OBJ=widget.o
4662   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4663   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4664     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4665   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4666     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4667     MOTIF_LIBW=-lXm
4668     case "$opsys" in
4669       gnu-linux)
4670         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4671         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4672         ;;
4673
4674       unixware)
4675         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4676         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4677         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4678         ;;
4679
4680       aix4-2)
4681         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4682         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4683         ;;
4684     esac
4685     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4686   fi
4687 fi
4688 AC_SUBST(WIDGET_OBJ)
4689
4690 TOOLKIT_LIBW=
4691 case "$USE_X_TOOLKIT" in
4692   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4693   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4694   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4695 esac
4696 AC_SUBST(TOOLKIT_LIBW)
4697
4698 if test "${opsys}" != "mingw32"; then
4699   if test "$USE_X_TOOLKIT" = "none"; then
4700     LIBXT_OTHER="\$(LIBXSM)"
4701   else
4702     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4703   fi
4704 fi
4705 AC_SUBST(LIBXT_OTHER)
4706
4707 if test "${HAVE_X11}" = "yes" ; then
4708   AC_DEFINE(HAVE_X11, 1,
4709             [Define to 1 if you want to use version 11 of X windows.])
4710   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4711 else
4712   LIBX_OTHER=
4713 fi
4714 AC_SUBST(LIBX_OTHER)
4715
4716 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4717   LIBXMENU=
4718 elif test "$USE_X_TOOLKIT" = none; then
4719   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4720 else
4721   LIBXMENU='$(lwlibdir)/liblw.a'
4722 fi
4723 AC_SUBST(LIBXMENU)
4724
4725 if test "${GNU_MALLOC}" = "yes" ; then
4726   AC_DEFINE(GNU_MALLOC, 1,
4727             [Define to 1 if you want to use the GNU memory allocator.])
4728 fi
4729
4730 RALLOC_OBJ=
4731 if test "${REL_ALLOC}" = "yes" ; then
4732   AC_DEFINE(REL_ALLOC, 1,
4733             [Define REL_ALLOC if you want to use the relocating allocator for
4734              buffer space.])
4735
4736   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4737 fi
4738 AC_SUBST(RALLOC_OBJ)
4739
4740 if test "$opsys" = "cygwin"; then
4741   CYGWIN_OBJ="sheap.o cygw32.o"
4742   ## Cygwin differs because of its unexec().
4743   PRE_ALLOC_OBJ=
4744   POST_ALLOC_OBJ=lastfile.o
4745 elif test "$opsys" = "mingw32"; then
4746   CYGWIN_OBJ=
4747   PRE_ALLOC_OBJ=
4748   POST_ALLOC_OBJ=lastfile.o
4749 else
4750   CYGWIN_OBJ=
4751   PRE_ALLOC_OBJ=lastfile.o
4752   POST_ALLOC_OBJ=
4753 fi
4754 AC_SUBST(CYGWIN_OBJ)
4755 AC_SUBST(PRE_ALLOC_OBJ)
4756 AC_SUBST(POST_ALLOC_OBJ)
4757
4758 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4759 dnl verbatim defined above.  The tricky name is apropos, as this hack
4760 dnl makes Fortify go sour!
4761 AH_VERBATIM([FORTIFY_SOUR],
4762 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4763    The workaround disables some useful run-time checking, so it
4764    should be conditional to the platforms with the performance bug.
4765    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4766 #if defined __APPLE__ && defined __GNUC__
4767 # ifndef _DONT_USE_CTYPE_INLINE_
4768 #  define _DONT_USE_CTYPE_INLINE_
4769 # endif
4770 # ifndef _FORTIFY_SOURCE
4771 #  define _FORTIFY_SOURCE 0
4772 # endif
4773 #endif
4774 ])
4775
4776 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4777 # it temporarily reverts them to their pre-pkg-config values,
4778 # because gnulib needs to work with both src (which uses the
4779 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4780 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4781 # and it therefore needs to run in an environment where LIBS does not
4782 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4783 # for some package unrelated to lib-src.
4784 SAVE_CFLAGS=$CFLAGS
4785 SAVE_LIBS=$LIBS
4786 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4787 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4788 gl_ASSERT_NO_GNULIB_POSIXCHECK
4789 gl_ASSERT_NO_GNULIB_TESTS
4790 gl_INIT
4791 CFLAGS=$SAVE_CFLAGS
4792 LIBS=$SAVE_LIBS
4793
4794 if test "${opsys}" = "mingw32"; then
4795   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4796   # Remove unneeded switches from the value of CC that goes to Makefiles
4797   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4798 fi
4799
4800 case "$opsys" in
4801   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4802
4803   darwin)
4804    ## The -headerpad option tells ld (see man page) to leave room at the
4805    ## end of the header for adding load commands.  Needed for dumping.
4806    ## 0x690 is the total size of 30 segment load commands (at 56
4807    ## each); under Cocoa 31 commands are required.
4808    if test "$HAVE_NS" = "yes"; then
4809      libs_nsgui="-framework AppKit"
4810      if test "$NS_IMPL_COCOA" = "yes"; then
4811         libs_nsgui="$libs_nsgui -framework IOKit"
4812      fi
4813      headerpad_extra=6C8
4814    else
4815      libs_nsgui=
4816      headerpad_extra=690
4817    fi
4818    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4819
4820    ## This is here because src/Makefile.in did some extra fiddling around
4821    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
4822    ## LD_SWITCH_SYSTEM_TEMACS instead,
4823    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4824      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4825    ;;
4826
4827   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4828   ## find X at run-time.
4829   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4830   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4831   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4832   ## had different values in configure (in ac_link) and src/Makefile.in.
4833   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4834   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4835
4836   mingw32)
4837    ## MinGW64 does not prepend an underscore to symbols, so we must
4838    ## pass a different -entry switch to linker.  FIXME: It is better
4839    ## to make the entry points the same by changing unexw32.c.
4840    case "$canonical" in
4841      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4842      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4843    esac
4844    ;;
4845
4846   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4847
4848   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4849 esac
4850
4851 if test x$ac_enable_profiling != x ; then
4852   case $opsys in
4853     *freebsd | gnu-linux) ;;
4854     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4855   esac
4856 fi
4857
4858 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
4859
4860 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4861
4862 ## MinGW-specific post-link processing of temacs.
4863 TEMACS_POST_LINK=":"
4864 ADDSECTION=
4865 EMACS_HEAPSIZE=
4866 if test "${opsys}" = "mingw32"; then
4867   TEMACS_POST_LINK="\$(MINGW_TEMACS_POST_LINK)"
4868   ADDSECTION="../nt/addsection\$(EXEEXT)"
4869   ## Preload heap size of temacs.exe in MB.
4870   case "$canonical" in
4871     x86_64-*-*) EMACS_HEAPSIZE=42 ;;
4872     *) EMACS_HEAPSIZE=27 ;;
4873   esac
4874 fi
4875
4876 AC_SUBST(ADDSECTION)
4877 AC_SUBST(TEMACS_POST_LINK)
4878 AC_SUBST(EMACS_HEAPSIZE)
4879
4880 ## Common for all window systems
4881 if test "$window_system" != "none"; then
4882   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4883   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4884 fi
4885
4886 AC_SUBST(WINDOW_SYSTEM_OBJ)
4887
4888 AH_TOP([/* GNU Emacs site configuration template file.
4889
4890 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2014
4891   Free Software Foundation, Inc.
4892
4893 This file is part of GNU Emacs.
4894
4895 GNU Emacs is free software: you can redistribute it and/or modify
4896 it under the terms of the GNU General Public License as published by
4897 the Free Software Foundation, either version 3 of the License, or
4898 (at your option) any later version.
4899
4900 GNU Emacs is distributed in the hope that it will be useful,
4901 but WITHOUT ANY WARRANTY; without even the implied warranty of
4902 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4903 GNU General Public License for more details.
4904
4905 You should have received a copy of the GNU General Public License
4906 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4907
4908
4909 /* No code in Emacs #includes config.h twice, but some bits of code
4910    intended to work with other packages as well (like gmalloc.c)
4911    think they can include it as many times as they like.  */
4912 #ifndef EMACS_CONFIG_H
4913 #define EMACS_CONFIG_H
4914 ])dnl
4915
4916 AH_BOTTOM([#include <conf_post.h>
4917
4918 #endif /* EMACS_CONFIG_H */
4919
4920 /*
4921 Local Variables:
4922 mode: c
4923 End:
4924 */
4925 ])dnl
4926
4927 #### Report on what we decided to do.
4928 #### Report GTK as a toolkit, even if it doesn't use Xt.
4929 #### It makes printing result more understandable as using GTK sets
4930 #### toolkit_scroll_bars to yes by default.
4931 if test "${HAVE_GTK}" = "yes"; then
4932   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4933 fi
4934
4935 if test $USE_ACL -ne 0; then
4936   acl_summary="yes $LIB_ACL"
4937 else
4938   acl_summary=no
4939 fi
4940
4941 echo "
4942 Configured for \`${canonical}'.
4943
4944   Where should the build process find the source code?    ${srcdir}
4945   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4946   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4947   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4948   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4949   What window system should Emacs use?                    ${window_system}
4950   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4951
4952 if test -n "${x_includes}"; then
4953 echo "  Where do we find X Windows header files?                ${x_includes}"
4954 else
4955 echo "  Where do we find X Windows header files?                Standard dirs"
4956 fi
4957 if test -n "${x_libraries}"; then
4958 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4959 else
4960 echo "  Where do we find X Windows libraries?                   Standard dirs"
4961 fi
4962
4963 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4964 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4965 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4966 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4967 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4968 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4969 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4970 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4971
4972 echo "  Does Emacs support sound?                               ${HAVE_SOUND}"
4973
4974 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4975 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4976 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4977 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4978 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
4979 echo "  Does Emacs use access control lists?                    ${acl_summary}"
4980 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4981 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4982 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4983
4984 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4985 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4986 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4987 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4988 echo "  Does Emacs directly use zlib?                           ${HAVE_ZLIB}"
4989
4990 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4991 echo
4992
4993 if test -n "${EMACSDATA}"; then
4994    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4995 fi
4996 if test -n "${EMACSDOC}"; then
4997    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4998 fi
4999
5000 echo
5001
5002 if test "$HAVE_NS" = "yes"; then
5003    echo
5004    echo "You must run \"${MAKE-make} install\" in order to test the built application.
5005 The installed application will go to nextstep/Emacs.app and can be
5006 run or moved from there."
5007    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5008       echo "The application will be fully self-contained."
5009     else
5010       echo "The lisp resources for the application will be installed under ${prefix}.
5011 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5012 to run if these resources are not installed."
5013    fi
5014    echo
5015 fi
5016
5017 if test "${opsys}" = "cygwin"; then
5018   case `uname -r` in
5019     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5020            echo
5021            ;;
5022   esac
5023 fi
5024
5025 # Remove any trailing slashes in these variables.
5026 [test "${prefix}" != NONE &&
5027   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
5028 test "${exec_prefix}" != NONE &&
5029   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
5030
5031 if test "$HAVE_NS" = "yes"; then
5032   if test "$NS_IMPL_GNUSTEP" = yes; then
5033     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5034       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5035     ns_check_file=Resources/Info-gnustep.plist
5036   else
5037     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5038       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5039     ns_check_file=Contents/Info.plist
5040   fi
5041   AC_SUBST(ns_check_file)
5042 fi
5043
5044 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5045 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5046 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5047 dnl (else you get "no `Makefile.am' found for any configure output").
5048 dnl This will work, but you get a config.status that is not quite right
5049 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5050 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5051 dnl it seems better to just live with the duplication.
5052 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5053
5054 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5055        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5056        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5057        leim/Makefile nextstep/Makefile nt/Makefile])
5058
5059 dnl test/ is not present in release tarfiles.
5060 opt_makefile=test/automated/Makefile
5061
5062 if test -f "$srcdir/$opt_makefile.in"; then
5063   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5064   dnl Again, it's best not to use a variable.  Though you can add
5065   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5066   AC_CONFIG_FILES([test/automated/Makefile])
5067 fi
5068
5069
5070 dnl The admin/ directory used to be excluded from tarfiles.
5071 if test -d $srcdir/admin; then
5072   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/unidata/Makefile admin/grammars/Makefile"
5073   AC_CONFIG_FILES([admin/unidata/Makefile])
5074   AC_CONFIG_FILES([admin/grammars/Makefile])
5075 fi                              dnl -d admin
5076
5077
5078 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5079
5080 AC_SUBST(SUBDIR_MAKEFILES_IN)
5081
5082 dnl You might wonder (I did) why epaths.h is generated by running make,
5083 dnl rather than just letting configure generate it from epaths.in.
5084 dnl One reason is that the various paths are not fully expanded (see above);
5085 dnl eg gamedir=${prefix}/var/games/emacs.
5086 dnl Secondly, the GNU Coding standards require that one should be able
5087 dnl to run `make prefix=/some/where/else' and override the values set
5088 dnl by configure.  This also explains the `move-if-change' test and
5089 dnl the use of force in the `epaths-force' rule in Makefile.in.
5090 AC_CONFIG_COMMANDS([src/epaths.h], [
5091 if test "${opsys}" = "mingw32"; then
5092   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5093 else
5094   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5095 fi
5096 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5097
5098 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5099 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5100 dnl or a symlink?
5101 AC_CONFIG_COMMANDS([src/.gdbinit], [
5102 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5103   echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit
5104 fi
5105 ])
5106
5107 AC_OUTPUT