lisp/startup.el

   1 ;;; startup.el --- process Emacs shell arguments
   2
   3 ;; Copyright (C) 1985, 86, 92, 94, 95, 96, 97, 1998, 1999 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file parses the command line and gets Emacs running.  Options on
  28 ;; the command line are handled in precedence order.  The order is the
  29 ;; one in the list below; first described means first handled.  Options
  30 ;; within each category (delimited by a bar) are handled in the order
  31 ;; encountered on the command line.
  32
  33 ;; -------------------------
  34 ;; -version                  Print Emacs version to stderr, then exit
  35 ;; --version                 successfully right away.
  36 ;;                           This option is handled by emacs.c
  37 ;; -------------------------
  38 ;; -help                     Print a short usage description and exit
  39 ;; --help                    successfully right away.
  40 ;;                           This option is handled by emacs.c
  41 ;; -------------------------
  42 ;; -nl                       Do not use shared memory (for systems that
  43 ;; -no-shared-memory         support this) for the dumped Emacs data.
  44 ;;                           This option is handled by emacs.c
  45 ;;
  46 ;; -map                      For VMS.
  47 ;; --map-data                This option is handled by emacs.c
  48 ;; -------------------------
  49 ;; -t FILE                   Use FILE as the name of the terminal.
  50 ;; --terminal FILE           Using this implies "-nw" also.
  51 ;;                           This option is handled by emacs.c
  52 ;; -------------------------
  53 ;; -d DISPNAME               Use DISPNAME as the name of the X
  54 ;; -display DISPNAME         display for the initial frame.
  55 ;; --display DISPNAME        This option is handled by emacs.c
  56 ;; -------------------------
  57 ;; -nw                       Do not use a windows system (but use the
  58 ;; --no-windows              terminal instead.)
  59 ;;                           This option is handled by emacs.c
  60 ;; -------------------------
  61 ;; -batch                    Execute noninteractively (messages go to stdout,
  62 ;; --batch                   variable noninteractive set to t)
  63 ;;                           This option is handled by emacs.c
  64 ;; -------------------------
  65 ;; -q                        Do not load user's init file and do not load
  66 ;; -no-init-file             "default.el".  Regardless of this switch,
  67 ;; --no-init-file            "site-start" is still loaded.
  68 ;; -------------------------
  69 ;; -no-site-file             Do not load "site-start.el".  (This is the ONLY
  70 ;; --no-site-file            way to prevent loading that file.)
  71 ;; -------------------------
  72 ;; -u USER                   Load USER's init file instead of the init
  73 ;; -user USER                file belonging to the user starting Emacs.
  74 ;; --user USER
  75 ;; -------------------------
  76 ;; -debug-init               Don't catch errors in init files; let the
  77 ;; --debug-init              debugger run.
  78 ;; -------------------------
  79 ;; -i ICONTYPE               Set type of icon using when Emacs is
  80 ;; -itype ICONTYPE           iconified under X.
  81 ;; --icon-type ICONTYPE      This option is passed on to term/x-win.el
  82 ;;
  83 ;; -iconic                   Start Emacs iconified.
  84 ;; --iconic                  This option is passed on to term/x-win.el
  85 ;; -------------------------
  86 ;; Various X options for colors/fonts/geometry/title etc.
  87 ;; These options are passed on to term/x-win.el which see.  Certain
  88 ;; of these are also found in term/pc-win.el
  89 ;; -------------------------
  90 ;; FILE                      Visit FILE.
  91 ;; -visit FILE
  92 ;; --visit FILE
  93 ;; -file FILE
  94 ;; --file FILE
  95 ;;
  96 ;; -L DIRNAME                Add DIRNAME to load-path
  97 ;; -directory DIRNAME
  98 ;; --directory DIRNAME
  99 ;;
 100 ;; -l FILE                   Load and execute the Emacs lisp code
 101 ;; -load FILE                in FILE.
 102 ;; --load FILE
 103 ;;
 104 ;; -f FUNC                   Execute Emacs lisp function FUNC with
 105 ;; -funcall FUNC             no arguments.  The "-e" form is outdated
 106 ;; --funcall FUNC            and should not be used.  (It's a typo
 107 ;; -e FUNC                   promoted to a feature.)
 108 ;;
 109 ;; -eval FORM                Execute Emacs lisp form FORM.
 110 ;; --eval FORM
 111 ;; -execute EXPR
 112 ;; --execute EXPR
 113 ;;
 114 ;; -insert FILE              Insert the contents of FILE into buffer.
 115 ;; --insert FILE
 116 ;; -------------------------
 117 ;; -kill                     Kill (exit) Emacs right away.
 118 ;; --kill
 119 ;; -------------------------
 120
 121 ;;; Code:
 122
 123 (setq top-level '(normal-top-level))
 124
 125 (defvar command-line-processed nil
 126   "Non-nil once command line has been processed")
 127
 128 (defgroup initialization nil
 129   "Emacs start-up procedure"
 130   :group 'internal)
 131
 132 (defcustom inhibit-startup-message nil
 133   "*Non-nil inhibits the initial startup message.
 134 This is for use in your personal init file, once you are familiar
 135 with the contents of the startup message."
 136   :type 'boolean
 137   :group 'initialization)
 138
 139 (defcustom inhibit-startup-echo-area-message nil
 140   "*Non-nil inhibits the initial startup echo area message.
 141 Setting this variable takes effect
 142 only if you do it with the customization buffer
 143 or if your `.emacs' file contains a line of this form:
 144  (setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\")
 145 If your `.emacs' file is byte-compiled, use the following form instead:
 146  (eval '(setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\"))
 147 Thus, someone else using a copy of your `.emacs' file will see
 148 the startup message unless he personally acts to inhibit it."
 149   :type '(choice (const :tag "Don't inhibit")
 150                  (string :tag "Enter your user name, to inhibit"))
 151   :group 'initialization)
 152
 153 (defcustom inhibit-default-init nil
 154   "*Non-nil inhibits loading the `default' library."
 155   :type 'boolean
 156   :group 'initialization)
 157
 158 (defvar command-switch-alist nil
 159   "Alist of command-line switches.
 160 Elements look like (SWITCH-STRING . HANDLER-FUNCTION).
 161 HANDLER-FUNCTION receives switch name as sole arg;
 162 remaining command-line args are in the variable `command-line-args-left'.")
 163
 164 (defvar command-line-args-left nil
 165   "List of command-line args not yet processed.")
 166
 167 (defvar command-line-functions nil    ;; lrs 7/31/89
 168   "List of functions to process unrecognized command-line arguments.
 169 Each function should access the dynamically bound variables
 170 `argi' (the current argument) and `command-line-args-left' (the remaining
 171 arguments).  The function should return non-nil only if it recognizes and
 172 processes `argi'.  If it does so, it may consume successive arguments by
 173 altering `command-line-args-left' to remove them.")
 174
 175 (defvar command-line-default-directory nil
 176   "Default directory to use for command line arguments.
 177 This is normally copied from `default-directory' when Emacs starts.")
 178
 179 ;;; This is here, rather than in x-win.el, so that we can ignore these
 180 ;;; options when we are not using X.
 181 (defconst command-line-x-option-alist
 182   '(("-bw" 1 x-handle-numeric-switch border-width)
 183     ("-d" 1 x-handle-display)
 184     ("-display" 1 x-handle-display)
 185     ("-name" 1 x-handle-name-switch)
 186     ("-title" 1 x-handle-switch title)
 187     ("-T" 1 x-handle-switch title)
 188     ("-r" 0 x-handle-switch reverse t)
 189     ("-rv" 0 x-handle-switch reverse t)
 190     ("-reverse" 0 x-handle-switch reverse t)
 191     ("-reverse-video" 0 x-handle-switch reverse t)
 192     ("-fn" 1 x-handle-switch font)
 193     ("-font" 1 x-handle-switch font)
 194     ("-ib" 1 x-handle-numeric-switch internal-border-width)
 195     ("-g" 1 x-handle-geometry)
 196     ("-lsp" 1 x-handle-numeric-switch line-spacing)
 197     ("-geometry" 1 x-handle-geometry)
 198     ("-fg" 1 x-handle-switch foreground-color)
 199     ("-foreground" 1 x-handle-switch foreground-color)
 200     ("-bg" 1 x-handle-switch background-color)
 201     ("-background" 1 x-handle-switch background-color)
 202     ("-ms" 1 x-handle-switch mouse-color)
 203     ("-itype" 0 x-handle-switch icon-type t)
 204     ("-i" 0 x-handle-switch icon-type t)
 205     ("-iconic" 0 x-handle-iconic)
 206     ("-xrm" 1 x-handle-xrm-switch)
 207     ("-cr" 1 x-handle-switch cursor-color)
 208     ("-vb" 0 x-handle-switch vertical-scroll-bars t)
 209     ("-hb" 0 x-handle-switch horizontal-scroll-bars t)
 210     ("-bd" 1 x-handle-switch)
 211     ("--border-width" 1 x-handle-numeric-switch border-width)
 212     ("--display" 1 x-handle-display)
 213     ("--name" 1 x-handle-name-switch)
 214     ("--title" 1 x-handle-switch title)
 215     ("--reverse-video" 0 x-handle-switch reverse t)
 216     ("--font" 1 x-handle-switch font)
 217     ("--internal-border" 1 x-handle-numeric-switch internal-border-width)
 218     ("--geometry" 1 x-handle-geometry)
 219     ("--foreground-color" 1 x-handle-switch foreground-color)
 220     ("--background-color" 1 x-handle-switch background-color)
 221     ("--mouse-color" 1 x-handle-switch mouse-color)
 222     ("--icon-type" 0 x-handle-switch icon-type t)
 223     ("--iconic" 0 x-handle-iconic)
 224     ("--xrm" 1 x-handle-xrm-switch)
 225     ("--cursor-color" 1 x-handle-switch cursor-color)
 226     ("--vertical-scroll-bars" 0 x-handle-switch vertical-scroll-bars t)
 227     ("--line-spacing" 1 x-handle-numeric-switch line-spacing)
 228     ("--border-color" 1 x-handle-switch border-width))
 229   "Alist of X Windows options.
 230 Each element has the form
 231   (NAME NUMARGS HANDLER FRAME-PARAM VALUE)
 232 where NAME is the option name string, NUMARGS is the number of arguments
 233 that the option accepts, HANDLER is a function to call to handle the option.
 234 FRAME-PARAM (optional) is the frame parameter this option specifies,
 235 and VALUE is the value which is given to that frame parameter
 236 \(most options use the argument for this, so VALUE is not present).")
 237
 238 (defvar before-init-hook nil
 239   "Normal hook run after handling urgent options but before loading init files.")
 240
 241 (defvar after-init-hook nil
 242   "Normal hook run after loading the init files, `~/.emacs' and `default.el'.
 243 There is no `condition-case' around the running of these functions;
 244 therefore, if you set `debug-on-error' non-nil in `.emacs',
 245 an error in one of these functions will invoke the debugger.")
 246
 247 (defvar emacs-startup-hook nil
 248   "Normal hook run after loading init files and handling the command line.")
 249
 250 (defvar term-setup-hook nil
 251   "Normal hook run after loading terminal-specific Lisp code.
 252 It also follows `emacs-startup-hook'.  This hook exists for users to set,
 253 so as to override the definitions made by the terminal-specific file.
 254 Emacs never sets this variable itself.")
 255
 256 (defvar keyboard-type nil
 257   "The brand of keyboard you are using.
 258 This variable is used to define
 259 the proper function and keypad keys for use under X.  It is used in a
 260 fashion analogous to the environment variable TERM.")
 261
 262 (defvar window-setup-hook nil
 263   "Normal hook run to initialize window system display.
 264 Emacs runs this hook after processing the command line arguments and loading
 265 the user's init file.")
 266
 267 (defcustom initial-major-mode 'lisp-interaction-mode
 268   "Major mode command symbol to use for the initial *scratch* buffer."
 269   :type 'function
 270   :group 'initialization)
 271
 272 (defcustom init-file-user nil
 273   "Identity of user whose `.emacs' file is or was read.
 274 The value is nil if `-q' or `--no-init-file' was specified,
 275 meaning do not load any init file.
 276
 277 Otherwise, the value may be the null string, meaning use the init file
 278 for the user that originally logged in, or it may be a
 279 string containing a user's name meaning use that person's init file.
 280
 281 In either of the latter cases, `(concat \"~\" init-file-user \"/\")'
 282 evaluates to the name of the directory where the `.emacs' file was
 283 looked for.
 284
 285 Setting `init-file-user' does not prevent Emacs from loading
 286 `site-start.el'.  The only way to do that is to use `--no-site-file'."
 287   :type '(choice (const :tag "none" nil) string)
 288   :group 'initialization)
 289
 290 (defcustom site-run-file "site-start"
 291   "File containing site-wide run-time initializations.
 292 This file is loaded at run-time before `~/.emacs'.  It contains inits
 293 that need to be in place for the entire site, but which, due to their
 294 higher incidence of change, don't make sense to load into emacs'
 295 dumped image.  Thus, the run-time load order is: 1. file described in
 296 this variable, if non-nil; 2. `~/.emacs'; 3. `default.el'.
 297
 298 Don't use the `site-start.el' file for things some users may not like.
 299 Put them in `default.el' instead, so that users can more easily
 300 override them.  Users can prevent loading `default.el' with the `-q'
 301 option or by setting `inhibit-default-init' in their own init files,
 302 but inhibiting `site-start.el' requires `--no-site-file', which
 303 is less convenient."
 304   :type '(choice (const :tag "none" nil) string)
 305   :group 'initialization)
 306
 307 (defcustom mail-host-address nil
 308   "*Name of this machine, for purposes of naming users."
 309   :type '(choice (const nil) string)
 310   :group 'mail)
 311
 312 (defcustom user-mail-address nil
 313   "*Full mailing address of this user.
 314 This is initialized based on `mail-host-address',
 315 after your init file is read, in case it sets `mail-host-address'."
 316   :type 'string
 317   :group 'mail)
 318
 319 (defcustom auto-save-list-file-prefix
 320   (cond ((eq system-type 'ms-dos)
 321          ;; MS-DOS cannot have initial dot, and allows only 8.3 names
 322          "~/_emacs.d/auto-save.list/_s")
 323         (t
 324          "~/.emacs.d/auto-save-list/.saves-"))
 325   "Prefix for generating `auto-save-list-file-name'.
 326 This is used after reading your `.emacs' file to initialize
 327 `auto-save-list-file-name', by appending Emacs's pid and the system name,
 328 if you have not already set `auto-save-list-file-name' yourself.
 329 Directories in the prefix will be created if necessary.
 330 Set this to nil if you want to prevent `auto-save-list-file-name'
 331 from being initialized."
 332   :type '(choice (const :tag "Don't record a session's auto save list" nil)
 333                  string)
 334   :group 'auto-save)
 335
 336 (defvar init-file-debug nil)
 337
 338 (defvar init-file-had-error nil)
 339
 340 (defvar normal-top-level-add-subdirs-inode-list nil)
 341
 342 (defun normal-top-level-add-subdirs-to-load-path ()
 343   "Add all subdirectories of current directory to `load-path'.
 344 More precisely, this uses only the subdirectories whose names
 345 start with letters or digits; it excludes any subdirectory named `RCS'
 346 or `CVS', and any subdirectory that contains a file named `.nosearch'."
 347   (let (dirs
 348         attrs
 349         (pending (list default-directory)))
 350     ;; This loop does a breadth-first tree walk on DIR's subtree,
 351     ;; putting each subdir into DIRS as its contents are examined.
 352     (while pending
 353       (setq dirs (cons (car pending) dirs))
 354       (setq pending (cdr pending))
 355       (setq attrs (nthcdr 10 (file-attributes (car dirs))))
 356       (let ((contents (directory-files (car dirs)))
 357             (default-directory (car dirs)))
 358         (unless (member attrs normal-top-level-add-subdirs-inode-list)
 359           (setq normal-top-level-add-subdirs-inode-list
 360                 (cons attrs normal-top-level-add-subdirs-inode-list))
 361           (while contents
 362             (unless (member (car contents) '("." ".." "RCS" "CVS"))
 363               (when (and (string-match "\\`[a-zA-Z0-9]" (car contents))
 364                          ;; Avoid doing a `stat' when it isn't necessary
 365                          ;; because that can cause trouble when an NFS server
 366                          ;; is down.
 367                          (not (string-match "\\.elc?\\'" (car contents)))
 368                          (file-directory-p (car contents)))
 369                 (let ((expanded (expand-file-name (car contents))))
 370                   (unless (file-exists-p (expand-file-name ".nosearch"
 371                                                            expanded))
 372                     (setq pending (nconc pending (list expanded)))))))
 373             (setq contents (cdr contents))))))
 374     (normal-top-level-add-to-load-path (cdr (nreverse dirs)))))
 375
 376 ;; This function is called from a subdirs.el file.
 377 ;; It assumes that default-directory is the directory
 378 ;; in which the subdirs.el file exists,
 379 ;; and it adds to load-path the subdirs of that directory
 380 ;; as specified in DIRS.  Normally the elements of DIRS are relative.
 381 (defun normal-top-level-add-to-load-path (dirs)
 382   (let ((tail load-path)
 383         (thisdir (directory-file-name default-directory)))
 384     (while (and tail
 385                 ;;Don't go all the way to the nil terminator.
 386                 (cdr tail)
 387                 (not (equal thisdir (car tail)))
 388                 (not (and (memq system-type '(ms-dos windows-nt))
 389                           (equal (downcase thisdir) (downcase (car tail))))))
 390       (setq tail (cdr tail)))
 391     ;;Splice the new section in.
 392     (when tail
 393       (setcdr tail (append (mapcar 'expand-file-name dirs) (cdr tail))))))
 394
 395 (defun normal-top-level ()
 396   (if command-line-processed
 397       (message "Back to top level.")
 398     (setq command-line-processed t)
 399     ;; Give *Messages* the same default-directory as *scratch*,
 400     ;; just to keep things predictable.
 401     (let ((dir default-directory))
 402       (save-excursion
 403         (set-buffer (get-buffer "*Messages*"))
 404         (setq default-directory dir)))
 405     ;; For root, preserve owner and group when editing files.
 406     (if (equal (user-uid) 0)
 407         (setq backup-by-copying-when-mismatch t))
 408     ;; Look in each dir in load-path for a subdirs.el file.
 409     ;; If we find one, load it, which will add the appropriate subdirs
 410     ;; of that dir into load-path,
 411     (let ((tail load-path)
 412           new)
 413       (while tail
 414         (setq new (cons (car tail) new))
 415         (condition-case nil
 416             (let ((default-directory (car tail)))
 417               (load (expand-file-name "subdirs.el" (car tail)) t t t)))
 418         (setq tail (cdr tail))))
 419     (if (not (eq system-type 'vax-vms))
 420         (progn
 421           ;; If the PWD environment variable isn't accurate, delete it.
 422           (let ((pwd (getenv "PWD")))
 423             (and (stringp pwd)
 424                  ;; Use FOO/., so that if FOO is a symlink, file-attributes
 425                  ;; describes the directory linked to, not FOO itself.
 426                  (or (equal (file-attributes
 427                              (concat (file-name-as-directory pwd) "."))
 428                             (file-attributes
 429                              (concat (file-name-as-directory default-directory)
 430                                      ".")))
 431                      (setq process-environment
 432                            (delete (concat "PWD=" pwd)
 433                                    process-environment)))))))
 434     (setq default-directory (abbreviate-file-name default-directory))
 435     (let ((menubar-bindings-done nil))
 436       (unwind-protect
 437           (command-line)
 438         ;; Do this again, in case .emacs defined more abbreviations.
 439         (setq default-directory (abbreviate-file-name default-directory))
 440         ;; Specify the file for recording all the auto save files of this session.
 441         ;; This is used by recover-session.
 442         (or auto-save-list-file-name
 443             (and auto-save-list-file-prefix
 444                  (setq auto-save-list-file-name
 445                        ;; Under MS-DOS our PID is almost always reused between
 446                        ;; Emacs invocations.  We need something more unique.
 447                        (cond ((eq system-type 'ms-dos)
 448                               ;; We are going to access the auto-save
 449                               ;; directory, so make sure it exists.
 450                               (make-directory
 451                                (file-name-directory auto-save-list-file-prefix)
 452                                t)
 453                               (concat
 454                                (make-temp-name
 455                                 (expand-file-name
 456                                  auto-save-list-file-prefix))
 457                                "~"))
 458                              (t
 459                               (expand-file-name
 460                                (format "%s%d-%s~"
 461                                        auto-save-list-file-prefix
 462                                        (emacs-pid)
 463                                        (system-name))))))))
 464         (run-hooks 'emacs-startup-hook)
 465         (and term-setup-hook
 466              (run-hooks 'term-setup-hook))
 467         ;; Modify the initial frame based on what .emacs puts into
 468         ;; ...-frame-alist.
 469         (if (fboundp 'frame-notice-user-settings)
 470             (frame-notice-user-settings))
 471         ;; Now we know the user's default font, so add it to the menu.
 472         (if (fboundp 'font-menu-add-default)
 473             (font-menu-add-default))
 474         (and window-setup-hook
 475              (run-hooks 'window-setup-hook))
 476         (or menubar-bindings-done
 477             (if (memq window-system '(x w32))
 478                 (precompute-menubar-bindings)))))))
 479
 480 ;; Precompute the keyboard equivalents in the menu bar items.
 481 (defun precompute-menubar-bindings ()
 482   (let ((submap (lookup-key global-map [menu-bar])))
 483     (while submap
 484       (and (consp (car submap))
 485            (symbolp (car (car submap)))
 486            (stringp (car-safe (cdr (car submap))))
 487            (keymapp (cdr (cdr (car submap))))
 488            (progn
 489              (x-popup-menu nil (cdr (cdr (car submap))))
 490              (if purify-flag
 491                  (garbage-collect))))
 492       (setq submap (cdr submap))))
 493   (setq define-key-rebound-commands t))
 494
 495 (defun command-line ()
 496   (setq command-line-default-directory default-directory)
 497
 498   ;; Choose a reasonable location for temporary files.
 499   (setq temporary-file-directory
 500         (file-name-as-directory
 501          (cond ((memq system-type '(ms-dos windows-nt))
 502                 (or (getenv "TEMP") (getenv "TMPDIR") (getenv "TMP") "c:/temp"))
 503                ((memq system-type '(vax-vms axp-vms))
 504                 (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "SYS$SCRATCH:"))
 505                (t
 506                 (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "/tmp")))))
 507   (setq small-temporary-file-directory
 508         (if (eq system-type 'ms-dos)
 509             (getenv "TMPDIR")))
 510
 511   ;; See if we should import version-control from the environment variable.
 512   (let ((vc (getenv "VERSION_CONTROL")))
 513     (cond ((eq vc nil))                 ;don't do anything if not set
 514           ((or (string= vc "t")
 515                (string= vc "numbered"))
 516            (setq version-control t))
 517           ((or (string= vc "nil")
 518                (string= vc "existing"))
 519            (setq version-control nil))
 520           ((or (string= vc "never")
 521                (string= vc "simple"))
 522            (setq version-control 'never))))
 523
 524   (set-locale-environment nil)
 525
 526   ;;! This has been commented out; I currently find the behavior when
 527   ;;! split-window-keep-point is nil disturbing, but if I can get used
 528   ;;! to it, then it would be better to eliminate the option.
 529   ;;! ;; Choose a good default value for split-window-keep-point.
 530   ;;! (setq split-window-keep-point (> baud-rate 2400))
 531
 532   ;; Set the default strings to display in mode line for
 533   ;; end-of-line formats that aren't native to this platform.
 534   (cond
 535    ((memq system-type '(ms-dos windows-nt emx))
 536     (setq eol-mnemonic-unix "(Unix)")
 537     (setq eol-mnemonic-mac  "(Mac)"))
 538    ;; Mac-specific settings should come here, once there's a
 539    ;; system-type symbol specific to MacOS.
 540    (t   ; this is for Unix/GNU/Linux systems
 541     (setq eol-mnemonic-dos  "(DOS)")
 542     (setq eol-mnemonic-mac  "(Mac)")))
 543
 544   ;; Read window system's init file if using a window system.
 545   (condition-case error
 546       (if (and window-system (not noninteractive))
 547           (load (concat term-file-prefix
 548                         (symbol-name window-system)
 549                         "-win")
 550                 ;; Every window system should have a startup file;
 551                 ;; barf if we can't find it.
 552                 nil t))
 553     ;; If we can't read it, print the error message and exit.
 554     (error
 555      (princ
 556       (if (eq (car error) 'error)
 557           (apply 'concat (cdr error))
 558         (if (memq 'file-error (get (car error) 'error-conditions))
 559             (format "%s: %s"
 560                      (nth 1 error)
 561                      (mapconcat '(lambda (obj) (prin1-to-string obj t))
 562                                 (cdr (cdr error)) ", "))
 563           (format "%s: %s"
 564                    (get (car error) 'error-message)
 565                    (mapconcat '(lambda (obj) (prin1-to-string obj t))
 566                               (cdr error) ", "))))
 567       'external-debugging-output)
 568      (setq window-system nil)
 569      (kill-emacs)))
 570
 571   (let ((done nil)
 572         (args (cdr command-line-args)))
 573
 574     ;; Figure out which user's init file to load,
 575     ;; either from the environment or from the options.
 576     (setq init-file-user (if noninteractive nil (user-login-name)))
 577     ;; If user has not done su, use current $HOME to find .emacs.
 578     (and init-file-user (string= init-file-user (user-real-login-name))
 579          (setq init-file-user ""))
 580
 581     ;; Process the command-line args, and delete the arguments
 582     ;; processed.  This is consistent with the way main in emacs.c
 583     ;; does things.
 584     (while (and (not done) args)
 585       (let ((longopts '(("--no-init-file") ("--no-site-file") ("--user")
 586                         ("--debug-init") ("--iconic") ("--icon-type")))
 587             (argi (car args))
 588             (argval nil))
 589         ;; Handle --OPTION=VALUE format.
 590         (if (and (string-match "\\`--" argi)
 591                  (string-match "=" argi))
 592             (setq argval (substring argi (match-end 0))
 593                   argi (substring argi 0 (match-beginning 0))))
 594         (or (equal argi "--")
 595             (let ((completion (try-completion argi longopts)))
 596               (if (eq completion t)
 597                   (setq argi (substring argi 1))
 598                 (if (stringp completion)
 599                     (let ((elt (assoc completion longopts)))
 600                       (or elt
 601                           (error "Option `%s' is ambiguous" argi))
 602                       (setq argi (substring (car elt) 1)))
 603                   (setq argval nil)))))
 604         (cond
 605          ((or (string-equal argi "-q")
 606               (string-equal argi "-no-init-file"))
 607           (setq init-file-user nil
 608                 args (cdr args)))
 609          ((or (string-equal argi "-u")
 610               (string-equal argi "-user"))
 611           (or argval
 612               (setq args (cdr args)
 613                     argval (car args)))
 614           (setq init-file-user argval
 615                 argval nil
 616                 args (cdr args)))
 617          ((string-equal argi "-no-site-file")
 618           (setq site-run-file nil
 619                 args (cdr args)))
 620          ((string-equal argi "-debug-init")
 621           (setq init-file-debug t
 622                 args (cdr args)))
 623          ((string-equal argi "-iconic")
 624           (setq initial-frame-alist
 625                 (cons '(visibility . icon) initial-frame-alist))
 626           (setq args (cdr args)))
 627          ((or (string-equal argi "-icon-type")
 628               (string-equal argi "-i")
 629               (string-equal argi "-itype"))
 630           (setq default-frame-alist
 631                 (cons '(icon-type . t) default-frame-alist))
 632           (setq args (cdr args)))
 633          (t (setq done t)))
 634         ;; Was argval set but not used?
 635         (and argval
 636              (error "Option `%s' doesn't allow an argument" argi))))
 637
 638     ;; Re-attach the program name to the front of the arg list.
 639     (and command-line-args (setcdr command-line-args args)))
 640
 641   ;; Under X Windows, this creates the X frame and deletes the terminal frame.
 642   (if (fboundp 'frame-initialize)
 643       (frame-initialize))
 644   ;; If frame was created with a menu bar, set menu-bar-mode on.
 645   (if (or (not (memq window-system '(x w32)))
 646           (> (cdr (assq 'menu-bar-lines (frame-parameters))) 0))
 647       (menu-bar-mode t))
 648
 649   (run-hooks 'before-init-hook)
 650
 651   ;; Run the site-start library if it exists.  The point of this file is
 652   ;; that it is run before .emacs.  There is no point in doing this after
 653   ;; .emacs; that is useless.
 654   (if site-run-file
 655       (load site-run-file t t))
 656
 657   ;; Register available input methods by loading LEIM list file.
 658   (load "leim-list.el" 'noerror 'nomessage 'nosuffix)
 659
 660   ;; Sites should not disable this.  Only individuals should disable
 661   ;; the startup message.
 662   (setq inhibit-startup-message nil)
 663
 664   ;; Load that user's init file, or the default one, or none.
 665   (let (debug-on-error-from-init-file
 666         debug-on-error-should-be-set
 667         (debug-on-error-initial
 668          (if (eq init-file-debug t) 'startup init-file-debug))
 669         (orig-enable-multibyte default-enable-multibyte-characters))
 670     (let ((debug-on-error debug-on-error-initial)
 671           ;; This function actually reads the init files.
 672           (inner
 673            (function
 674             (lambda ()
 675               (if init-file-user
 676                   (let ((user-init-file-1
 677                           (cond
 678                            ((eq system-type 'ms-dos)
 679                             (concat "~" init-file-user "/_emacs"))
 680                            ((eq system-type 'windows-nt)
 681                             (if (directory-files "~" nil "^\\.emacs\\(\\.elc?\\)?$")
 682                                 "~/.emacs"
 683                               "~/_emacs"))
 684                            ((eq system-type 'vax-vms)
 685                             "sys$login:.emacs")
 686                            (t
 687                             (concat "~" init-file-user "/.emacs")))))
 688                     ;; This tells `load' to store the file name found
 689                     ;; into user-init-file.
 690                     (setq user-init-file t)
 691                     (load user-init-file-1 t t)
 692                     ;; If we did not find the user's init file,
 693                     ;; set user-init-file conclusively to nil;
 694                     ;; don't let it be set from default.el.
 695                     (if (eq user-init-file t)
 696                         (setq user-init-file nil))
 697                     ;; If we loaded a compiled file, set
 698                     ;; `user-init-file' to the source version if that
 699                     ;; exists.
 700                     (if (and user-init-file
 701                              (equal (file-name-extension user-init-file)
 702                                     "elc"))
 703                         (let ((el (concat (file-name-sans-extension
 704                                            user-init-file)
 705                                           ".el")))
 706                           (if (file-exists-p el)
 707                               (setq user-init-file el))))
 708                     (or inhibit-default-init
 709                         (let ((inhibit-startup-message nil))
 710                           ;; Users are supposed to be told their rights.
 711                           ;; (Plus how to get help and how to undo.)
 712                           ;; Don't you dare turn this off for anyone
 713                           ;; except yourself.
 714                           (load "default" t t)))))))))
 715       (if init-file-debug
 716           ;; Do this without a condition-case if the user wants to debug.
 717           (funcall inner)
 718         (condition-case error
 719             (progn
 720               (funcall inner)
 721               (setq init-file-had-error nil))
 722           (error (message "Error in init file: %s%s%s"
 723                           (get (car error) 'error-message)
 724                           (if (cdr error) ": " "")
 725                           (mapconcat 'prin1-to-string (cdr error) ", "))
 726                  (setq init-file-had-error t))))
 727       ;; If we can tell that the init file altered debug-on-error,
 728       ;; arrange to preserve the value that it set up.
 729       (or (eq debug-on-error debug-on-error-initial)
 730           (setq debug-on-error-should-be-set t
 731                 debug-on-error-from-init-file debug-on-error)))
 732     (if debug-on-error-should-be-set
 733         (setq debug-on-error debug-on-error-from-init-file))
 734     (unless (or default-enable-multibyte-characters
 735                 (eq orig-enable-multibyte default-enable-multibyte-characters))
 736       ;; Init file changed to unibyte.  Reset existing multibyte
 737       ;; buffers (probably *scratch*, *Messages*, *Minibuff-0*).
 738       ;; Arguably this should only be done if they're free of
 739       ;; multibyte characters.
 740       (mapcar (lambda (buffer)
 741                 (with-current-buffer buffer
 742                   (if enable-multibyte-characters
 743                       (set-buffer-multibyte nil))))
 744               (buffer-list))
 745       ;; Also re-set the language environment in case it was
 746       ;; originally done before unibyte was set and is sensitive to
 747       ;; unibyte (display table, terminal coding system &c).
 748       (set-language-environment current-language-environment)))
 749
 750   ;; Do this here in case the init file sets mail-host-address.
 751   (or user-mail-address
 752       (setq user-mail-address (concat (user-login-name) "@"
 753                                       (or mail-host-address
 754                                           (system-name)))))
 755
 756   (run-hooks 'after-init-hook)
 757
 758   ;; If *scratch* exists and init file didn't change its mode, initialize it.
 759   (if (get-buffer "*scratch*")
 760       (save-excursion
 761         (set-buffer "*scratch*")
 762         (if (eq major-mode 'fundamental-mode)
 763             (funcall initial-major-mode))))
 764
 765   ;; Register default TTY colors for the case the terminal hasn't a
 766   ;; terminal init file.
 767   (or (memq window-system '(x w32))
 768       (not (tty-display-color-p))
 769       (let* ((colors (cond ((eq window-system 'pc)
 770                             msdos-color-values)
 771                            ((eq system-type 'windows-nt)
 772                             w32-tty-standard-colors)
 773                            (t tty-standard-colors)))
 774              (color (car colors)))
 775         (while colors
 776           (tty-color-define (car color) (cadr color) (cddr color))
 777           (setq colors (cdr colors) color (car colors)))))
 778
 779   ;; Load library for our terminal type.
 780   ;; User init file can set term-file-prefix to nil to prevent this.
 781   (and term-file-prefix (not noninteractive) (not window-system)
 782        (let ((term (getenv "TERM"))
 783              hyphend)
 784          (while (and term
 785                      (not (load (concat term-file-prefix term) t t)))
 786            ;; Strip off last hyphen and what follows, then try again
 787            (if (setq hyphend (string-match "[-_][^-_]+$" term))
 788                (setq term (substring term 0 hyphend))
 789              (setq term nil)))))
 790
 791   ;; Process the remaining args.
 792   (command-line-1 (cdr command-line-args))
 793
 794   ;; If -batch, terminate after processing the command options.
 795   (if noninteractive (kill-emacs t)))
 796
 797 (defcustom initial-scratch-message (purecopy "\
 798 ;; This buffer is for notes you don't want to save, and for Lisp evaluation.
 799 ;; If you want to create a file, visit that file with C-x C-f,
 800 ;; then enter the text in that file's own buffer.
 801
 802 ")
 803   "Initial message displayed in *scratch* buffer at startup.
 804 If this is nil, no message will be displayed."
 805   :type 'string)
 806
 807 (defun command-line-1 (command-line-args-left)
 808   (or noninteractive (input-pending-p) init-file-had-error
 809       (and inhibit-startup-echo-area-message
 810            user-init-file
 811            (or (and (get 'inhibit-startup-echo-area-message 'saved-value)
 812                     (equal inhibit-startup-echo-area-message
 813                            (if (string= init-file-user "")
 814                                (user-login-name)
 815                              init-file-user)))
 816                ;; Wasn't set with custom; see if .emacs has a setq.
 817                (let ((buffer (get-buffer-create " *temp*")))
 818                  (prog1
 819                      (condition-case nil
 820                          (save-excursion
 821                            (set-buffer buffer)
 822                            (insert-file-contents user-init-file)
 823                            (re-search-forward
 824                             (concat
 825                              "([ \t\n]*setq[ \t\n]+"
 826                              "inhibit-startup-echo-area-message[ \t\n]+"
 827                              (regexp-quote
 828                               (prin1-to-string
 829                                (if (string= init-file-user "")
 830                                    (user-login-name)
 831                                  init-file-user)))
 832                              "[ \t\n]*)")
 833                             nil t))
 834                        (error nil))
 835                    (kill-buffer buffer)))))
 836       (message (if (eq (key-binding "\C-h\C-p") 'describe-project)
 837                    "For information about the GNU Project and its goals, type C-h C-p."
 838                  (substitute-command-keys
 839                   "For information about the GNU Project and its goals, type \\[describe-project]."))))
 840   (if (null command-line-args-left)
 841       (cond ((and (not inhibit-startup-message) (not noninteractive)
 842                   ;; Don't clobber a non-scratch buffer if init file
 843                   ;; has selected it.
 844                   (string= (buffer-name) "*scratch*"))
 845              ;; If there are no switches to process, we might as well
 846              ;; run this hook now, and there may be some need to do it
 847              ;; before doing any output.
 848              (and term-setup-hook
 849                   (run-hooks 'term-setup-hook))
 850              ;; Don't let the hook be run twice.
 851              (setq term-setup-hook nil)
 852
 853              ;; It's important to notice the user settings before we
 854              ;; display the startup message; otherwise, the settings
 855              ;; won't take effect until the user gives the first
 856              ;; keystroke, and that's distracting.
 857              (if (fboundp 'frame-notice-user-settings)
 858                  (frame-notice-user-settings))
 859
 860              (and window-setup-hook
 861                   (run-hooks 'window-setup-hook))
 862              (setq window-setup-hook nil)
 863              ;; Do this now to avoid an annoying delay if the user
 864              ;; clicks the menu bar during the sit-for.
 865              (when (memq window-system '(x w32))
 866                (precompute-menubar-bindings))
 867              (setq menubar-bindings-done t)
 868              (when (= (buffer-size) 0)
 869                (let ((buffer-undo-list t))
 870                  (unwind-protect
 871                      (when (not (input-pending-p))
 872                        (goto-char (point-max))
 873                        ;; The convention for this piece of code is that
 874                        ;; each piece of output starts with one or two newlines
 875                        ;; and does not end with any newlines.
 876                        (insert "Welcome to GNU Emacs")
 877                        (if (eq system-type 'gnu/linux)
 878                            (insert ", one component of a Linux-based GNU system."))
 879                        (insert "\n")
 880                        (if (assq 'display (frame-parameters))
 881                            (progn
 882                              (insert "\
 883 The menu bar and scroll bar are sufficient for basic editing with the mouse.
 884
 885 Useful Files menu items:
 886 Exit Emacs              (or type Control-x followed by Control-c)
 887 Recover Session         recover files you were editing before a crash
 888
 889 Important Help menu items:
 890 Emacs Tutorial          Learn-by-doing tutorial for using Emacs efficiently.
 891 \(Non)Warranty          GNU Emacs comes with ABSOLUTELY NO WARRANTY
 892 Copying Conditions      Conditions for redistributing and changing Emacs.
 893 Getting New Versions    How to obtain the latest version of Emacs.
 894 ")
 895                              (insert "\n\n" (emacs-version)
 896                                      "
 897 Copyright (C) 1999 Free Software Foundation, Inc."))
 898                          ;; If keys have their default meanings,
 899                          ;; use precomputed string to save lots of time.
 900                          (if (and (eq (key-binding "\C-h") 'help-command)
 901                                   (eq (key-binding "\C-xu") 'advertised-undo)
 902                                   (eq (key-binding "\C-x\C-c") 'save-buffers-kill-emacs)
 903                                   (eq (key-binding "\C-ht") 'help-with-tutorial)
 904                                   (eq (key-binding "\C-hi") 'info)
 905                                   (eq (key-binding "\C-h\C-n") 'view-emacs-news))
 906                              (insert "
 907 Get help           C-h  (Hold down CTRL and press h)
 908 Undo changes       C-x u       Exit Emacs               C-x C-c
 909 Get a tutorial     C-h t       Use Info to read docs    C-h i")
 910                            (insert (substitute-command-keys
 911                                     (format "\n
 912 Get help           %s
 913 Undo changes       \\[advertised-undo]
 914 Exit Emacs         \\[save-buffers-kill-emacs]
 915 Get a tutorial     \\[help-with-tutorial]
 916 Use Info to read docs   \\[info]"
 917                                             (let ((where (where-is-internal
 918                                                           'help-command nil t)))
 919                                               (if where
 920                                                   (key-description where)
 921                                                 "M-x help"))))))
 922                          ;; Say how to use the menu bar
 923                          ;; if that is not with the mouse.
 924                          (if (and (eq (key-binding "\M-`") 'tmm-menubar)
 925                                   (eq (key-binding [f10]) 'tmm-menubar))
 926                              (insert "
 927 Activate menubar   F10  or  ESC `  or   M-`")
 928                            (insert (substitute-command-keys "
 929 Activate menubar     \\[tmm-menubar]")))
 930
 931                        ;; Windows and MSDOS (currently) do not count as
 932                        ;; window systems, but do have mouse support.
 933                          (if window-system
 934                              (insert "
 935 Mode-specific menu   C-mouse-3 (third button, with CTRL)"))
 936                          ;; Many users seem to have problems with these.
 937                          (insert "
 938 \(`C-' means use the CTRL key.  `M-' means use the Meta (or Alt) key.
 939 If you have no Meta key, you may instead type ESC followed by the character.)")
 940                          (and auto-save-list-file-prefix
 941                               (directory-files
 942                                (file-name-directory auto-save-list-file-prefix)
 943                                nil
 944                                (concat "\\`"
 945                                        (regexp-quote (file-name-nondirectory
 946                                                       auto-save-list-file-prefix)))
 947                                t)
 948                               (insert "\n\nIf an Emacs session crashed recently, "
 949                                       "type M-x recover-session RET\nto recover"
 950                                       " the files you were editing."))
 951
 952                          (insert "\n\n" (emacs-version)
 953                                  "
 954 Copyright (C) 1999 Free Software Foundation, Inc.")
 955                          (if (and (eq (key-binding "\C-h\C-c") 'describe-copying)
 956                                   (eq (key-binding "\C-h\C-d") 'describe-distribution)
 957                                   (eq (key-binding "\C-h\C-w") 'describe-no-warranty))
 958                              (insert
 959                               "\n
 960 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type C-h C-w for full details.
 961 Emacs is Free Software--Free as in Freedom--so you can redistribute copies
 962 of Emacs and modify it; type C-h C-c to see the conditions.
 963 Type C-h C-d for information on getting the latest version.")
 964                            (insert (substitute-command-keys
 965                                     "\n
 966 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type \\[describe-no-warranty] for full details.
 967 Emacs is Free Software--Free as in Freedom--so you can redistribute copies
 968 of Emacs and modify it; type \\[describe-copying] to see the conditions.
 969 Type \\[describe-distribution] for information on getting the latest version."))))
 970                        (goto-char (point-min))
 971
 972                        (set-buffer-modified-p nil)
 973                        (sit-for 120))
 974                    (with-current-buffer (get-buffer "*scratch*")
 975                      (erase-buffer)
 976                      (and initial-scratch-message
 977                           (insert initial-scratch-message))
 978                      (set-buffer-modified-p nil)))))))
 979     ;; Delay 2 seconds after the init file error message
 980     ;; was displayed, so user can read it.
 981     (if init-file-had-error
 982         (sit-for 2))
 983     (let ((dir command-line-default-directory)
 984           (file-count 0)
 985           first-file-buffer
 986           tem
 987           just-files  ;; t if this follows the magic -- option.
 988           ;; This includes our standard options' long versions
 989           ;; and long versions of what's on command-switch-alist.
 990           (longopts
 991            (append '(("--funcall") ("--load") ("--insert") ("--kill")
 992                      ("--directory") ("--eval") ("--execute")
 993                      ("--find-file") ("--visit") ("--file"))
 994                    (mapcar '(lambda (elt)
 995                               (list (concat "-" (car elt))))
 996                            command-switch-alist)))
 997           (line 0))
 998
 999       ;; Add the long X options to longopts.
1000       (setq tem command-line-x-option-alist)
1001       (while tem
1002         (if (string-match "^--" (car (car tem)))
1003             (setq longopts (cons (list (car (car tem))) longopts)))
1004         (setq tem (cdr tem)))
1005
1006       ;; Loop, processing options.
1007       (while (and command-line-args-left)
1008         (let* ((argi (car command-line-args-left))
1009                (orig-argi argi)
1010                argval completion
1011                ;; List of directories specified in -L/--directory,
1012                ;; in reverse of the order specified.
1013                extra-load-path
1014                (initial-load-path load-path))
1015           (setq command-line-args-left (cdr command-line-args-left))
1016
1017           ;; Do preliminary decoding of the option.
1018           (if just-files
1019               ;; After --, don't look for options; treat all args as files.
1020               (setq argi "")
1021             ;; Convert long options to ordinary options
1022             ;; and separate out an attached option argument into argval.
1023             (if (string-match "^--[^=]*=" argi)
1024                 (setq argval (substring argi (match-end 0))
1025                       argi (substring argi 0 (1- (match-end 0)))))
1026             (if (equal argi "--")
1027                 (setq completion nil)
1028               (setq completion (try-completion argi longopts)))
1029             (if (eq completion t)
1030                 (setq argi (substring argi 1))
1031               (if (stringp completion)
1032                   (let ((elt (assoc completion longopts)))
1033                     (or elt
1034                         (error "Option `%s' is ambiguous" argi))
1035                     (setq argi (substring (car elt) 1)))
1036                 (setq argval nil argi orig-argi))))
1037
1038           ;; Execute the option.
1039           (cond ((setq tem (assoc argi command-switch-alist))
1040                  (if argval
1041                      (let ((command-line-args-left
1042                             (cons argval command-line-args-left)))
1043                        (funcall (cdr tem) argi))
1044                    (funcall (cdr tem) argi)))
1045
1046                 ((or (string-equal argi "-f")  ;what the manual claims
1047                      (string-equal argi "-funcall")
1048                      (string-equal argi "-e")) ; what the source used to say
1049                  (if argval
1050                      (setq tem (intern argval))
1051                    (setq tem (intern (car command-line-args-left)))
1052                    (setq command-line-args-left (cdr command-line-args-left)))
1053                  (if (arrayp (symbol-function tem))
1054                      (command-execute tem)
1055                    (funcall tem)))
1056
1057                 ((or (string-equal argi "-eval")
1058                      (string-equal argi "-execute"))
1059                  (if argval
1060                      (setq tem argval)
1061                    (setq tem (car command-line-args-left))
1062                    (setq command-line-args-left (cdr command-line-args-left)))
1063                  (eval (read tem)))
1064                 ;; Set the default directory as specified in -L.
1065
1066                 ((or (string-equal argi "-L")
1067                      (string-equal argi "-directory"))
1068                  (if argval
1069                      (setq tem argval)
1070                    (setq tem (car command-line-args-left)
1071                          command-line-args-left (cdr command-line-args-left)))
1072                  (setq tem (command-line-normalize-file-name tem))
1073                  (setq extra-load-path
1074                        (cons (expand-file-name tem) extra-load-path))
1075                  (setq load-path (append (nreverse extra-load-path)
1076                                          initial-load-path)))
1077
1078                 ((or (string-equal argi "-l")
1079                      (string-equal argi "-load"))
1080                  (if argval
1081                      (setq tem argval)
1082                    (setq tem (car command-line-args-left)
1083                          command-line-args-left (cdr command-line-args-left)))
1084                  (let ((file (command-line-normalize-file-name tem)))
1085                    ;; Take file from default dir if it exists there;
1086                    ;; otherwise let `load' search for it.
1087                    (if (file-exists-p (expand-file-name file))
1088                        (setq file (expand-file-name file)))
1089                    (load file nil t)))
1090
1091                 ((string-equal argi "-insert")
1092                  (if argval
1093                      (setq tem argval)
1094                    (setq tem (car command-line-args-left)
1095                          command-line-args-left (cdr command-line-args-left)))
1096                  (or (stringp tem)
1097                      (error "File name omitted from `-insert' option"))
1098                  (insert-file-contents (command-line-normalize-file-name tem)))
1099
1100                 ((string-equal argi "-kill")
1101                  (kill-emacs t))
1102
1103                 ((string-match "^\\+[0-9]+\\'" argi)
1104                  (setq line (string-to-int argi)))
1105
1106                 ((setq tem (assoc argi command-line-x-option-alist))
1107                  ;; Ignore X-windows options and their args if not using X.
1108                  (setq command-line-args-left
1109                        (nthcdr (nth 1 tem) command-line-args-left)))
1110
1111                 ((or (string-equal argi "-find-file")
1112                      (string-equal argi "-file")
1113                      (string-equal argi "-visit"))
1114                  ;; An explicit option to specify visiting a file.
1115                  (if argval
1116                      (setq tem argval)
1117                    (setq tem (car command-line-args-left)
1118                          command-line-args-left (cdr command-line-args-left)))
1119                  (unless (stringp tem)
1120                    (error "File name omitted from `%s' option" argi))
1121                  (setq file-count (1+ file-count))
1122                  (let ((file (expand-file-name
1123                               (command-line-normalize-file-name tem) dir)))
1124                    (if (= file-count 1)
1125                        (setq first-file-buffer (find-file file))
1126                      (find-file-other-window file)))
1127                  (or (zerop line)
1128                      (goto-line line))
1129                  (setq line 0))
1130
1131                 ((equal argi "--")
1132                  (setq just-files t))
1133                 (t
1134                  ;; We have almost exhausted our options. See if the
1135                  ;; user has made any other command-line options available
1136                  (let ((hooks command-line-functions);; lrs 7/31/89
1137                        (did-hook nil))
1138                    (while (and hooks
1139                                (not (setq did-hook (funcall (car hooks)))))
1140                      (setq hooks (cdr hooks)))
1141                    (if (not did-hook)
1142                        ;; Ok, presume that the argument is a file name
1143                        (progn
1144                          (if (string-match "\\`-" argi)
1145                              (error "Unknown option `%s'" argi))
1146                          (setq file-count (1+ file-count))
1147                          (let ((file
1148                                 (expand-file-name
1149                                  (command-line-normalize-file-name orig-argi)
1150                                  dir)))
1151                            (if (= file-count 1)
1152                                (setq first-file-buffer (find-file file))
1153                              (find-file-other-window file)))
1154                          (or (zerop line)
1155                              (goto-line line))
1156                          (setq line 0))))))))
1157       ;; If 3 or more files visited, and not all visible,
1158       ;; show user what they all are.
1159       (and (> file-count 2)
1160            (not noninteractive)
1161            (or (get-buffer-window first-file-buffer)
1162                (progn (other-window 1)
1163                       (buffer-menu)))))))
1164
1165 (defun command-line-normalize-file-name (file)
1166   "Collapse multiple slashes to one, to handle non-Emacs file names."
1167   (save-match-data
1168     ;; Use arg 1 so that we don't collapse // at the start of the file name.
1169     ;; That is significant on some systems.
1170     ;; However, /// at the beginning is supposed to mean just /, not //.
1171     (if (string-match "^///+" file)
1172         (setq file (replace-match "/" t t file)))
1173     (while (string-match "//+" file 1)
1174       (setq file (replace-match "/" t t file)))
1175     file))
1176
1177 ;;; startup.el ends here