lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems
   2
   3 ;; Copyright (C) 1993, 1994, 1996, 1997, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (defvar frame-creation-function-alist
  29   (list (cons nil
  30               (if (fboundp 'tty-create-frame-with-faces)
  31                   'tty-create-frame-with-faces
  32                 (lambda (parameters)
  33                   (error "Can't create multiple frames without a window system")))))
  34   "Alist of window-system dependent functions to call to create a new frame.
  35 The window system startup file should add its frame creation
  36 function to this list, which should take an alist of parameters
  37 as its argument.")
  38
  39 (defvar window-system-default-frame-alist nil
  40   "Alist of window-system dependent default frame parameters.
  41 You can set this in your `.emacs' file; for example,
  42
  43     ;; Disable menubar and toolbar on the console, but enable them under X.
  44     (setq window-system-default-frame-alist
  45           '((x (menu-bar-lines . 1) (tool-bar-lines . 1))
  46             (nil (menu-bar-lines . 0) (tool-bar-lines . 0))))
  47
  48 Parameters specified here supersede the values given in `default-frame-alist'.")
  49
  50 ;; The initial value given here used to ask for a minibuffer.
  51 ;; But that's not necessary, because the default is to have one.
  52 ;; By not specifying it here, we let an X resource specify it.
  53 (defcustom initial-frame-alist nil
  54   "*Alist of frame parameters for creating the initial X window frame.
  55 You can set this in your `.emacs' file; for example,
  56  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  57 Parameters specified here supersede the values given in `default-frame-alist'.
  58
  59 If the value calls for a frame without a minibuffer, and you have not created
  60 a minibuffer frame on your own, one is created according to
  61 `minibuffer-frame-alist'.
  62
  63 You can specify geometry-related options for just the initial frame
  64 by setting this variable in your `.emacs' file; however, they won't
  65 take effect until Emacs reads `.emacs', which happens after first creating
  66 the frame.  If you want the frame to have the proper geometry as soon
  67 as it appears, you need to use this three-step process:
  68 * Specify X resources to give the geometry you want.
  69 * Set `default-frame-alist' to override these options so that they
  70   don't affect subsequent frames.
  71 * Set `initial-frame-alist' in a way that matches the X resources,
  72   to override what you put in `default-frame-alist'."
  73   :type '(repeat (cons :format "%v"
  74                        (symbol :tag "Parameter")
  75                        (sexp :tag "Value")))
  76   :group 'frames)
  77
  78 (defcustom minibuffer-frame-alist '((width . 80) (height . 2))
  79   "*Alist of frame parameters for initially creating a minibuffer frame.
  80 You can set this in your `.emacs' file; for example,
  81  (setq minibuffer-frame-alist
  82    '((top . 1) (left . 1) (width . 80) (height . 2)))
  83 Parameters specified here supersede the values given in
  84 `default-frame-alist', for a minibuffer frame."
  85   :type '(repeat (cons :format "%v"
  86                        (symbol :tag "Parameter")
  87                        (sexp :tag "Value")))
  88   :group 'frames)
  89
  90 (defcustom pop-up-frame-alist nil
  91   "*Alist of frame parameters used when creating pop-up frames.
  92 Pop-up frames are used for completions, help, and the like.
  93 This variable can be set in your init file, like this:
  94   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  95 These supersede the values given in `default-frame-alist',
  96 for pop-up frames."
  97   :type '(repeat (cons :format "%v"
  98                        (symbol :tag "Parameter")
  99                        (sexp :tag "Value")))
 100   :group 'frames)
 101
 102 (setq pop-up-frame-function
 103       ;; Using `function' here caused some sort of problem.
 104       '(lambda ()
 105          (make-frame pop-up-frame-alist)))
 106
 107 (defcustom special-display-frame-alist
 108   '((height . 14) (width . 80) (unsplittable . t))
 109   "*Alist of frame parameters used when creating special frames.
 110 Special frames are used for buffers whose names are in
 111 `special-display-buffer-names' and for buffers whose names match
 112 one of the regular expressions in `special-display-regexps'.
 113 This variable can be set in your init file, like this:
 114   (setq special-display-frame-alist '((width . 80) (height . 20)))
 115 These supersede the values given in `default-frame-alist'."
 116   :type '(repeat (cons :format "%v"
 117                          (symbol :tag "Parameter")
 118                          (sexp :tag "Value")))
 119   :group 'frames)
 120
 121 (defun special-display-popup-frame (buffer &optional args)
 122   "Display BUFFER in its own frame, reusing an existing window if any.
 123 Return the window chosen.
 124 Currently we do not insist on selecting the window within its frame.
 125 If ARGS is an alist, use it as a list of frame parameter specs.
 126 If ARGS is a list whose car is a symbol,
 127 use (car ARGS) as a function to do the work.
 128 Pass it BUFFER as first arg, and (cdr ARGS) gives the rest of the args."
 129   (if (and args (symbolp (car args)))
 130       (apply (car args) buffer (cdr args))
 131     (let ((window (get-buffer-window buffer 0)))
 132       (or
 133        ;; If we have a window already, make it visible.
 134        (when window
 135          (let ((frame (window-frame window)))
 136            (make-frame-visible frame)
 137            (raise-frame frame)
 138            window))
 139        ;; Reuse the current window if the user requested it.
 140        (when (cdr (assq 'same-window args))
 141          (condition-case nil
 142              (progn (switch-to-buffer buffer) (selected-window))
 143            (error nil)))
 144        ;; Stay on the same frame if requested.
 145        (when (or (cdr (assq 'same-frame args)) (cdr (assq 'same-window args)))
 146          (let* ((pop-up-frames nil) (pop-up-windows t)
 147                 special-display-regexps special-display-buffer-names
 148                 (window (display-buffer buffer)))
 149            ;; Only do it if this is a new window:
 150            ;; (set-window-dedicated-p window t)
 151            window))
 152        ;; If no window yet, make one in a new frame.
 153        (let ((frame
 154               (with-current-buffer buffer
 155                 (make-frame (append args special-display-frame-alist)))))
 156          (set-window-buffer (frame-selected-window frame) buffer)
 157          (set-window-dedicated-p (frame-selected-window frame) t)
 158          (frame-selected-window frame))))))
 159
 160 (defun handle-delete-frame (event)
 161   "Handle delete-frame events from the X server."
 162   (interactive "e")
 163   (let ((frame (posn-window (event-start event)))
 164         (i 0)
 165         (tail (frame-list)))
 166     (while tail
 167       (and (frame-visible-p (car tail))
 168            (not (eq (car tail) frame))
 169           (setq i (1+ i)))
 170       (setq tail (cdr tail)))
 171     (if (> i 0)
 172         (delete-frame frame t)
 173       ;; Gildea@x.org says it is ok to ask questions before terminating.
 174       (save-buffers-kill-emacs))))
 175 \f
 176 ;;;; Arrangement of frames at startup
 177
 178 ;; 1) Load the window system startup file from the lisp library and read the
 179 ;; high-priority arguments (-q and the like).  The window system startup
 180 ;; file should create any frames specified in the window system defaults.
 181 ;;
 182 ;; 2) If no frames have been opened, we open an initial text frame.
 183 ;;
 184 ;; 3) Once the init file is done, we apply any newly set parameters
 185 ;; in initial-frame-alist to the frame.
 186
 187 ;; These are now called explicitly at the proper times,
 188 ;; since that is easier to understand.
 189 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
 190 ;; (add-hook 'before-init-hook 'frame-initialize)
 191 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
 192
 193 ;; If we create the initial frame, this is it.
 194 (defvar frame-initial-frame nil)
 195
 196 ;; Record the parameters used in frame-initialize to make the initial frame.
 197 (defvar frame-initial-frame-alist)
 198
 199 (defvar frame-initial-geometry-arguments nil)
 200
 201 ;; startup.el calls this function before loading the user's init
 202 ;; file - if there is no frame with a minibuffer open now, create
 203 ;; one to display messages while loading the init file.
 204 (defun frame-initialize ()
 205   "Create an initial frame if necessary."
 206   ;; Are we actually running under a window system at all?
 207   (if (and initial-window-system
 208            (not noninteractive)
 209            (not (eq initial-window-system 'pc)))
 210       (progn
 211         ;; Turn on special-display processing only if there's a window system.
 212         (setq special-display-function 'special-display-popup-frame)
 213
 214         ;; If there is no frame with a minibuffer besides the terminal
 215         ;; frame, then we need to create the opening frame.  Make sure
 216         ;; it has a minibuffer, but let initial-frame-alist omit the
 217         ;; minibuffer spec.
 218         (or (delq terminal-frame (minibuffer-frame-list))
 219             (progn
 220               (setq frame-initial-frame-alist
 221                     (append initial-frame-alist default-frame-alist nil))
 222               (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
 223                   (setq frame-initial-frame-alist
 224                         (cons '(horizontal-scroll-bars . t)
 225                               frame-initial-frame-alist)))
 226               (setq frame-initial-frame-alist
 227                     (cons (cons 'window-system initial-window-system)
 228                           frame-initial-frame-alist))
 229               (setq default-minibuffer-frame
 230                     (setq frame-initial-frame
 231                           (make-frame frame-initial-frame-alist)))
 232               ;; Delete any specifications for window geometry parameters
 233               ;; so that we won't reapply them in frame-notice-user-settings.
 234               ;; It would be wrong to reapply them then,
 235               ;; because that would override explicit user resizing.
 236               (setq initial-frame-alist
 237                     (frame-remove-geometry-params initial-frame-alist))))
 238         ;; Copy the environment of the Emacs process into the new frame.
 239         (set-frame-parameter frame-initial-frame 'environment
 240                              (frame-parameter terminal-frame 'environment))
 241         ;; At this point, we know that we have a frame open, so we
 242         ;; can delete the terminal frame.
 243         (delete-frame terminal-frame)
 244         (setq terminal-frame nil))))
 245
 246 (defvar frame-notice-user-settings t
 247   "Non-nil means function `frame-notice-user-settings' wasn't run yet.")
 248
 249 (declare-function tool-bar-mode "tool-bar" (&optional arg))
 250
 251 ;; startup.el calls this function after loading the user's init
 252 ;; file.  Now default-frame-alist and initial-frame-alist contain
 253 ;; information to which we must react; do what needs to be done.
 254 (defun frame-notice-user-settings ()
 255   "Act on user's init file settings of frame parameters.
 256 React to settings of `initial-frame-alist',
 257 `window-system-default-frame-alist' and `default-frame-alist'
 258 there (in decreasing order of priority)."
 259   ;; Make menu-bar-mode and default-frame-alist consistent.
 260   (when (boundp 'menu-bar-mode)
 261     (let ((default (assq 'menu-bar-lines default-frame-alist)))
 262       (if default
 263           (setq menu-bar-mode (not (eq (cdr default) 0)))
 264         (setq default-frame-alist
 265               (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
 266                     default-frame-alist)))))
 267
 268   ;; Make tool-bar-mode and default-frame-alist consistent.  Don't do
 269   ;; it in batch mode since that would leave a tool-bar-lines
 270   ;; parameter in default-frame-alist in a dumped Emacs, which is not
 271   ;; what we want.
 272   (when (and (boundp 'tool-bar-mode)
 273              (not noninteractive))
 274     (let ((default (assq 'tool-bar-lines default-frame-alist)))
 275       (if default
 276           (setq tool-bar-mode (not (eq (cdr default) 0)))
 277         ;; If Emacs was started on a tty, changing default-frame-alist
 278         ;; would disable the toolbar on X frames created later.  We
 279         ;; want to keep the default of showing a toolbar under X even
 280         ;; in this case.
 281         ;;
 282         ;; If the user explicitly called `tool-bar-mode' in .emacs,
 283         ;; then default-frame-alist is already changed anyway.
 284         (when initial-window-system
 285           (setq default-frame-alist
 286                 (cons (cons 'tool-bar-lines (if tool-bar-mode 1 0))
 287                       default-frame-alist))))))
 288
 289   ;; Creating and deleting frames may shift the selected frame around,
 290   ;; and thus the current buffer.  Protect against that.  We don't
 291   ;; want to use save-excursion here, because that may also try to set
 292   ;; the buffer of the selected window, which fails when the selected
 293   ;; window is the minibuffer.
 294   (let ((old-buffer (current-buffer))
 295         (window-system-frame-alist
 296          (cdr (assq initial-window-system
 297                     window-system-default-frame-alist))))
 298
 299     (when (and frame-notice-user-settings
 300                (null frame-initial-frame))
 301       ;; This case happens when we don't have a window system, and
 302       ;; also for MS-DOS frames.
 303       (let ((parms (frame-parameters frame-initial-frame)))
 304         ;; Don't change the frame names.
 305         (setq parms (delq (assq 'name parms) parms))
 306         ;; Can't modify the minibuffer parameter, so don't try.
 307         (setq parms (delq (assq 'minibuffer parms) parms))
 308         (modify-frame-parameters nil
 309                                  (if (null initial-window-system)
 310                                      (append initial-frame-alist
 311                                              window-system-frame-alist
 312                                              default-frame-alist
 313                                              parms
 314                                              nil)
 315                                    ;; initial-frame-alist and
 316                                    ;; default-frame-alist were already
 317                                    ;; applied in pc-win.el.
 318                                    parms))
 319         (if (null initial-window-system) ;; MS-DOS does this differently in pc-win.el
 320             (let ((newparms (frame-parameters))
 321                   (frame (selected-frame)))
 322               (tty-handle-reverse-video frame newparms)
 323               ;; If we changed the background color, we need to update
 324               ;; the background-mode parameter, and maybe some faces,
 325               ;; too.
 326               (when (assq 'background-color newparms)
 327                 (unless (or (assq 'background-mode initial-frame-alist)
 328                             (assq 'background-mode default-frame-alist))
 329                   (frame-set-background-mode frame))
 330                 (face-set-after-frame-default frame))))))
 331
 332     ;; If the initial frame is still around, apply initial-frame-alist
 333     ;; and default-frame-alist to it.
 334     (when (frame-live-p frame-initial-frame)
 335
 336       ;; When tool-bar has been switched off, correct the frame size
 337       ;; by the lines added in x-create-frame for the tool-bar and
 338       ;; switch `tool-bar-mode' off.
 339       (when (display-graphic-p)
 340         (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 341                                   (assq 'tool-bar-lines window-system-frame-alist)
 342                                   (assq 'tool-bar-lines default-frame-alist))))
 343           (when (and tool-bar-originally-present
 344                      (or (null tool-bar-lines)
 345                          (null (cdr tool-bar-lines))
 346                          (eq 0 (cdr tool-bar-lines))))
 347             (let* ((char-height (frame-char-height frame-initial-frame))
 348                    (image-height tool-bar-images-pixel-height)
 349                    (margin (cond ((and (consp tool-bar-button-margin)
 350                                        (integerp (cdr tool-bar-button-margin))
 351                                        (> tool-bar-button-margin 0))
 352                                   (cdr tool-bar-button-margin))
 353                                  ((and (integerp tool-bar-button-margin)
 354                                        (> tool-bar-button-margin 0))
 355                                   tool-bar-button-margin)
 356                                  (t 0)))
 357                    (relief (if (and (integerp tool-bar-button-relief)
 358                                     (> tool-bar-button-relief 0))
 359                                tool-bar-button-relief 3))
 360                    (lines (/ (+ image-height
 361                                 (* 2 margin)
 362                                 (* 2 relief)
 363                                 (1- char-height))
 364                              char-height))
 365                    (height (frame-parameter frame-initial-frame 'height))
 366                    (newparms (list (cons 'height (- height lines))))
 367                    (initial-top (cdr (assq 'top
 368                                            frame-initial-geometry-arguments)))
 369                    (top (frame-parameter frame-initial-frame 'top)))
 370               (when (and (consp initial-top) (eq '- (car initial-top)))
 371                 (let ((adjusted-top
 372                        (cond ((and (consp top)
 373                                    (eq '+ (car top)))
 374                               (list '+
 375                                     (+ (cadr top)
 376                                        (* lines char-height))))
 377                              ((and (consp top)
 378                                    (eq '- (car top)))
 379                               (list '-
 380                                     (- (cadr top)
 381                                        (* lines char-height))))
 382                              (t (+ top (* lines char-height))))))
 383                   (setq newparms
 384                         (append newparms
 385                                 `((top . ,adjusted-top))
 386                                 nil))))
 387               (modify-frame-parameters frame-initial-frame newparms)
 388               (tool-bar-mode -1)))))
 389
 390       ;; The initial frame we create above always has a minibuffer.
 391       ;; If the user wants to remove it, or make it a minibuffer-only
 392       ;; frame, then we'll have to delete the current frame and make a
 393       ;; new one; you can't remove or add a root window to/from an
 394       ;; existing frame.
 395       ;;
 396       ;; NOTE: default-frame-alist was nil when we created the
 397       ;; existing frame.  We need to explicitly include
 398       ;; default-frame-alist in the parameters of the screen we
 399       ;; create here, so that its new value, gleaned from the user's
 400       ;; .emacs file, will be applied to the existing screen.
 401       (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 402                             (assq 'minibuffer window-system-frame-alist)
 403                             (assq 'minibuffer default-frame-alist)
 404                             '(minibuffer . t)))
 405                    t))
 406           ;; Create the new frame.
 407           (let (parms new)
 408             ;; If the frame isn't visible yet, wait till it is.
 409             ;; If the user has to position the window,
 410             ;; Emacs doesn't know its real position until
 411             ;; the frame is seen to be visible.
 412             (while (not (cdr (assq 'visibility
 413                                    (frame-parameters frame-initial-frame))))
 414               (sleep-for 1))
 415             (setq parms (frame-parameters frame-initial-frame))
 416
 417             ;; Get rid of `name' unless it was specified explicitly before.
 418             (or (assq 'name frame-initial-frame-alist)
 419                 (setq parms (delq (assq 'name parms) parms)))
 420             ;; An explicit parent-id is a request to XEmbed the frame.
 421             (or (assq 'parent-id frame-initial-frame-alist)
 422                 (setq parms (delq (assq 'parent-id parms) parms)))
 423
 424             (setq parms (append initial-frame-alist
 425                                 window-system-frame-alist
 426                                 default-frame-alist
 427                                 parms
 428                                 nil))
 429
 430             ;; Get rid of `reverse', because that was handled
 431             ;; when we first made the frame.
 432             (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))
 433
 434             (if (assq 'height frame-initial-geometry-arguments)
 435                 (setq parms (assq-delete-all 'height parms)))
 436             (if (assq 'width frame-initial-geometry-arguments)
 437                 (setq parms (assq-delete-all 'width parms)))
 438             (if (assq 'left frame-initial-geometry-arguments)
 439                 (setq parms (assq-delete-all 'left parms)))
 440             (if (assq 'top frame-initial-geometry-arguments)
 441                 (setq parms (assq-delete-all 'top parms)))
 442             (setq new
 443                   (make-frame
 444                    ;; Use the geometry args that created the existing
 445                    ;; frame, rather than the parms we get for it.
 446                    (append frame-initial-geometry-arguments
 447                            '((user-size . t) (user-position . t))
 448                            parms)))
 449             ;; The initial frame, which we are about to delete, may be
 450             ;; the only frame with a minibuffer.  If it is, create a
 451             ;; new one.
 452             (or (delq frame-initial-frame (minibuffer-frame-list))
 453                 (make-initial-minibuffer-frame nil))
 454
 455             ;; If the initial frame is serving as a surrogate
 456             ;; minibuffer frame for any frames, we need to wean them
 457             ;; onto a new frame.  The default-minibuffer-frame
 458             ;; variable must be handled similarly.
 459             (let ((users-of-initial
 460                    (filtered-frame-list
 461                     (lambda (frame)
 462                       (and (not (eq frame frame-initial-frame))
 463                            (eq (window-frame
 464                                 (minibuffer-window frame))
 465                                frame-initial-frame))))))
 466               (if (or users-of-initial
 467                       (eq default-minibuffer-frame frame-initial-frame))
 468
 469                   ;; Choose an appropriate frame.  Prefer frames which
 470                   ;; are only minibuffers.
 471                   (let* ((new-surrogate
 472                           (car
 473                            (or (filtered-frame-list
 474                                 (lambda (frame)
 475                                   (eq (cdr (assq 'minibuffer
 476                                                  (frame-parameters frame)))
 477                                       'only)))
 478                                (minibuffer-frame-list))))
 479                          (new-minibuffer (minibuffer-window new-surrogate)))
 480
 481                     (if (eq default-minibuffer-frame frame-initial-frame)
 482                         (setq default-minibuffer-frame new-surrogate))
 483
 484                     ;; Wean the frames using frame-initial-frame as
 485                     ;; their minibuffer frame.
 486                     (dolist (frame users-of-initial)
 487                       (modify-frame-parameters
 488                        frame (list (cons 'minibuffer new-minibuffer)))))))
 489
 490             ;; Redirect events enqueued at this frame to the new frame.
 491             ;; Is this a good idea?
 492             (redirect-frame-focus frame-initial-frame new)
 493
 494             ;; Finally, get rid of the old frame.
 495             (delete-frame frame-initial-frame t))
 496
 497         ;; Otherwise, we don't need all that rigamarole; just apply
 498         ;; the new parameters.
 499         (let (newparms allparms tail)
 500           (setq allparms (append initial-frame-alist
 501                                  window-system-frame-alist
 502                                  default-frame-alist nil))
 503           (if (assq 'height frame-initial-geometry-arguments)
 504               (setq allparms (assq-delete-all 'height allparms)))
 505           (if (assq 'width frame-initial-geometry-arguments)
 506               (setq allparms (assq-delete-all 'width allparms)))
 507           (if (assq 'left frame-initial-geometry-arguments)
 508               (setq allparms (assq-delete-all 'left allparms)))
 509           (if (assq 'top frame-initial-geometry-arguments)
 510               (setq allparms (assq-delete-all 'top allparms)))
 511           (setq tail allparms)
 512           ;; Find just the parms that have changed since we first
 513           ;; made this frame.  Those are the ones actually set by
 514           ;; the init file.  For those parms whose values we already knew
 515           ;; (such as those spec'd by command line options)
 516           ;; it is undesirable to specify the parm again
 517           ;; once the user has seen the frame and been able to alter it
 518           ;; manually.
 519           (while tail
 520             (let (newval oldval)
 521               (setq oldval (assq (car (car tail))
 522                                  frame-initial-frame-alist))
 523               (setq newval (cdr (assq (car (car tail)) allparms)))
 524               (or (and oldval (eq (cdr oldval) newval))
 525                   (setq newparms
 526                         (cons (cons (car (car tail)) newval) newparms))))
 527             (setq tail (cdr tail)))
 528           (setq newparms (nreverse newparms))
 529           (modify-frame-parameters frame-initial-frame
 530                                    newparms)
 531           ;; If we changed the background color,
 532           ;; we need to update the background-mode parameter
 533           ;; and maybe some faces too.
 534           (when (assq 'background-color newparms)
 535             (unless (assq 'background-mode newparms)
 536               (frame-set-background-mode frame-initial-frame))
 537             (face-set-after-frame-default frame-initial-frame)))))
 538
 539     ;; Restore the original buffer.
 540     (set-buffer old-buffer)
 541
 542     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 543     ;; Make sure frame-notice-user-settings does nothing if called twice.
 544     (setq frame-notice-user-settings nil)
 545     (setq frame-initial-frame nil)))
 546
 547 (defun make-initial-minibuffer-frame (display)
 548   (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
 549     (if display
 550         (make-frame-on-display display parms)
 551       (make-frame parms))))
 552
 553 ;;;; Creation of additional frames, and other frame miscellanea
 554
 555 (defun modify-all-frames-parameters (alist)
 556   "Modify all current and future frames' parameters according to ALIST.
 557 This changes `default-frame-alist' and possibly `initial-frame-alist'.
 558 Furthermore, this function removes all parameters in ALIST from
 559 `window-system-default-frame-alist'.
 560 See help of `modify-frame-parameters' for more information."
 561   (dolist (frame (frame-list))
 562     (modify-frame-parameters frame alist))
 563
 564   (dolist (pair alist) ;; conses to add/replace
 565     ;; initial-frame-alist needs setting only when
 566     ;; frame-notice-user-settings is true.
 567     (and frame-notice-user-settings
 568          (setq initial-frame-alist
 569                (assq-delete-all (car pair) initial-frame-alist)))
 570     (setq default-frame-alist
 571           (assq-delete-all (car pair) default-frame-alist))
 572     ;; Remove any similar settings from the window-system specific
 573     ;; parameters---they would override default-frame-alist.
 574     (dolist (w window-system-default-frame-alist)
 575       (setcdr w (assq-delete-all (car pair) (cdr w)))))
 576
 577   (and frame-notice-user-settings
 578        (setq initial-frame-alist (append initial-frame-alist alist)))
 579   (setq default-frame-alist (append default-frame-alist alist)))
 580
 581 (defun get-other-frame ()
 582   "Return some frame other than the current frame.
 583 Create one if necessary.  Note that the minibuffer frame, if separate,
 584 is not considered (see `next-frame')."
 585   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 586                (make-frame)
 587              (next-frame (selected-frame)))))
 588     s))
 589
 590 (defun next-multiframe-window ()
 591   "Select the next window, regardless of which frame it is on."
 592   (interactive)
 593   (select-window (next-window (selected-window)
 594                               (> (minibuffer-depth) 0)
 595                               0))
 596   (select-frame-set-input-focus (selected-frame)))
 597
 598 (defun previous-multiframe-window ()
 599   "Select the previous window, regardless of which frame it is on."
 600   (interactive)
 601   (select-window (previous-window (selected-window)
 602                                   (> (minibuffer-depth) 0)
 603                                   0))
 604   (select-frame-set-input-focus (selected-frame)))
 605
 606 (declare-function x-initialize-window-system "term/x-win" ())
 607 (declare-function ns-initialize-window-system "term/ns-win" ())
 608 (defvar x-display-name)                 ; term/x-win
 609
 610 (defun make-frame-on-display (display &optional parameters)
 611   "Make a frame on X display DISPLAY.
 612 The optional second argument PARAMETERS specifies additional frame parameters."
 613   (interactive "sMake frame on display: ")
 614   (if (featurep 'ns)
 615       (progn
 616         (when (and (boundp 'ns-initialized) (not ns-initialized))
 617           (setq x-display-name display)
 618           (ns-initialize-window-system))
 619         (make-frame `((window-system . ns) (display . ,display) . ,parameters)))
 620     (progn
 621       (unless (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
 622         (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
 623       (when (and (boundp 'x-initialized) (not x-initialized))
 624         (setq x-display-name display)
 625         (x-initialize-window-system))
 626       (make-frame `((window-system . x) (display . ,display) . ,parameters)))))
 627
 628 (defun make-frame-on-tty (tty type &optional parameters)
 629   "Make a frame on terminal device TTY.
 630 TTY should be the file name of the tty device to use.  TYPE
 631 should be the terminal type string of TTY, for example \"xterm\"
 632 or \"vt100\".  The optional third argument PARAMETERS specifies
 633 additional frame parameters."
 634   (interactive "fOpen frame on tty device: \nsTerminal type of %s: ")
 635   (unless tty
 636     (error "Invalid terminal device"))
 637   (unless type
 638     (error "Invalid terminal type"))
 639   (make-frame `((window-system . nil) (tty . ,tty) (tty-type . ,type) . ,parameters)))
 640
 641 (declare-function x-close-connection "xfns.c" (terminal))
 642
 643 (defun close-display-connection (display)
 644   "Close the connection to a display, deleting all its associated frames.
 645 For DISPLAY, specify either a frame or a display name (a string).
 646 If DISPLAY is nil, that stands for the selected frame's display."
 647   (interactive
 648    (list
 649     (let* ((default (frame-parameter nil 'display))
 650            (display (completing-read
 651                      (format "Close display (default %s): " default)
 652                      (delete-dups
 653                       (mapcar (lambda (frame)
 654                                 (frame-parameter frame 'display))
 655                               (frame-list)))
 656                      nil t nil nil
 657                      default)))
 658       (if (zerop (length display)) default display))))
 659   (let ((frames (delq nil
 660                       (mapcar (lambda (frame)
 661                                 (if (equal display
 662                                            (frame-parameter frame 'display))
 663                                     frame))
 664                               (frame-list)))))
 665     (if (and (consp frames)
 666              (not (y-or-n-p (if (cdr frames)
 667                                 (format "Delete %s frames? " (length frames))
 668                               (format "Delete %s ? " (car frames))))))
 669         (error "Abort!")
 670       (mapc 'delete-frame frames)
 671       (x-close-connection display))))
 672
 673 (defun make-frame-command ()
 674   "Make a new frame, and select it if the terminal displays only one frame."
 675   (interactive)
 676   (if (and window-system (not (eq window-system 'pc)))
 677       (make-frame)
 678     (select-frame (make-frame))))
 679
 680 (defvar before-make-frame-hook nil
 681   "Functions to run before a frame is created.")
 682
 683 (defvar after-make-frame-functions nil
 684   "Functions to run after a frame is created.
 685 The functions are run with one arg, the newly created frame.")
 686
 687 (defvar after-setting-font-hook nil
 688   "Functions to run after a frame's font has been changed.")
 689
 690 ;; Alias, kept temporarily.
 691 (define-obsolete-function-alias 'new-frame 'make-frame "22.1")
 692
 693 (defvar frame-inherited-parameters '()
 694   ;; FIXME: Shouldn't we add `font' here as well?
 695   "Parameters `make-frame' copies from the `selected-frame' to the new frame.")
 696
 697 (defun make-frame (&optional parameters)
 698   "Return a newly created frame displaying the current buffer.
 699 Optional argument PARAMETERS is an alist of parameters for the new frame.
 700 Each element of PARAMETERS should have the form (NAME . VALUE), for example:
 701
 702  (name . STRING)        The frame should be named STRING.
 703
 704  (width . NUMBER)       The frame should be NUMBER characters in width.
 705  (height . NUMBER)      The frame should be NUMBER text lines high.
 706
 707 You cannot specify either `width' or `height', you must use neither or both.
 708
 709  (minibuffer . t)       The frame should have a minibuffer.
 710  (minibuffer . nil)     The frame should have no minibuffer.
 711  (minibuffer . only)    The frame should contain only a minibuffer.
 712  (minibuffer . WINDOW)  The frame should use WINDOW as its minibuffer window.
 713
 714  (window-system . nil)  The frame should be displayed on a terminal device.
 715  (window-system . x)    The frame should be displayed in an X window.
 716
 717  (terminal . ID)          The frame should use the terminal identified by ID.
 718
 719 Before the frame is created (via `frame-creation-function-alist'), functions on the
 720 hook `before-make-frame-hook' are run.  After the frame is created, functions
 721 on `after-make-frame-functions' are run with one arg, the newly created frame.
 722
 723 This function itself does not make the new frame the selected frame.
 724 The previously selected frame remains selected.  However, the
 725 window system may select the new frame for its own reasons, for
 726 instance if the frame appears under the mouse pointer and your
 727 setup is for focus to follow the pointer."
 728   (interactive)
 729   (let* ((w (cond
 730              ((assq 'terminal parameters)
 731               (let ((type (terminal-live-p (cdr (assq 'terminal parameters)))))
 732                 (cond
 733                  ((eq type t) nil)
 734                  ((eq type nil) (error "Terminal %s does not exist"
 735                                        (cdr (assq 'terminal parameters))))
 736                  (t type))))
 737              ((assq 'window-system parameters)
 738               (cdr (assq 'window-system parameters)))
 739              (t window-system)))
 740          (frame-creation-function (cdr (assq w frame-creation-function-alist)))
 741          (oldframe (selected-frame))
 742          frame)
 743     (unless frame-creation-function
 744       (error "Don't know how to create a frame on window system %s" w))
 745     (run-hooks 'before-make-frame-hook)
 746     (setq frame
 747           (funcall frame-creation-function
 748                    (append parameters
 749                            (cdr (assq w window-system-default-frame-alist)))))
 750     (normal-erase-is-backspace-setup-frame frame)
 751     ;; Inherit the original frame's parameters.
 752     (dolist (param frame-inherited-parameters)
 753       (unless (assq param parameters)   ;Overridden by explicit parameters.
 754         (let ((val (frame-parameter oldframe param)))
 755           (when val (set-frame-parameter frame param val)))))
 756     (run-hook-with-args 'after-make-frame-functions frame)
 757     frame))
 758
 759 (defun filtered-frame-list (predicate)
 760   "Return a list of all live frames which satisfy PREDICATE."
 761   (let* ((frames (frame-list))
 762          (list frames))
 763     (while (consp frames)
 764       (unless (funcall predicate (car frames))
 765         (setcar frames nil))
 766       (setq frames (cdr frames)))
 767     (delq nil list)))
 768
 769 (defun minibuffer-frame-list ()
 770   "Return a list of all frames with their own minibuffers."
 771   (filtered-frame-list
 772    (lambda (frame)
 773      (eq frame (window-frame (minibuffer-window frame))))))
 774
 775 ;; Used to be called `terminal-id' in termdev.el.
 776 (defun get-device-terminal (device)
 777   "Return the terminal corresponding to DEVICE.
 778 DEVICE can be a terminal, a frame, nil (meaning the selected frame's terminal),
 779 the name of an X display device (HOST.SERVER.SCREEN) or a tty device file."
 780   (cond
 781    ((or (null device) (framep device))
 782     (frame-terminal device))
 783    ((stringp device)
 784     (let ((f (car (filtered-frame-list
 785                    (lambda (frame)
 786                      (or (equal (frame-parameter frame 'display) device)
 787                          (equal (frame-parameter frame 'tty) device)))))))
 788       (or f (error "Display %s does not exist" device))
 789       (frame-terminal f)))
 790    ((terminal-live-p device) device)
 791    (t
 792     (error "Invalid argument %s in `get-device-terminal'" device))))
 793
 794 (defun frames-on-display-list (&optional device)
 795   "Return a list of all frames on DEVICE.
 796
 797 DEVICE should be a terminal, a frame,
 798 or a name of an X display or tty (a string of the form
 799 HOST:SERVER.SCREEN).
 800
 801 If DEVICE is omitted or nil, it defaults to the selected
 802 frame's terminal device."
 803   (let* ((terminal (get-device-terminal device))
 804          (func #'(lambda (frame)
 805                    (eq (frame-terminal frame) terminal))))
 806     (filtered-frame-list func)))
 807
 808 (defun framep-on-display (&optional terminal)
 809   "Return the type of frames on TERMINAL.
 810 TERMINAL may be a terminal id, a display name or a frame.  If it
 811 is a frame, its type is returned.  If TERMINAL is omitted or nil,
 812 it defaults to the selected frame's terminal device.  All frames
 813 on a given display are of the same type."
 814   (or (terminal-live-p terminal)
 815       (framep terminal)
 816       (framep (car (frames-on-display-list terminal)))))
 817
 818 (defun frame-remove-geometry-params (param-list)
 819   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 820 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 821 `height', `user-size' and `user-position' parameters.
 822 Emacs uses this to avoid overriding explicit moves and resizings from
 823 the user during startup."
 824   (setq param-list (cons nil param-list))
 825   (let ((tail param-list))
 826     (while (consp (cdr tail))
 827       (if (and (consp (car (cdr tail)))
 828                (memq (car (car (cdr tail)))
 829                      '(height width top left user-position user-size)))
 830           (progn
 831             (setq frame-initial-geometry-arguments
 832                   (cons (car (cdr tail)) frame-initial-geometry-arguments))
 833             (setcdr tail (cdr (cdr tail))))
 834         (setq tail (cdr tail)))))
 835   (setq frame-initial-geometry-arguments
 836         (nreverse frame-initial-geometry-arguments))
 837   (cdr param-list))
 838
 839 (declare-function x-focus-frame "xfns.c" (frame))
 840
 841 (defun select-frame-set-input-focus (frame)
 842   "Select FRAME, raise it, and set input focus, if possible."
 843     (select-frame frame)
 844     (raise-frame frame)
 845     ;; Ensure, if possible, that frame gets input focus.
 846     (when (memq (window-system frame) '(x mac w32 ns))
 847       (x-focus-frame frame))
 848     (when focus-follows-mouse
 849       (set-mouse-position (selected-frame) (1- (frame-width)) 0)))
 850
 851 (defun other-frame (arg)
 852   "Select the ARGth different visible frame on current display, and raise it.
 853 All frames are arranged in a cyclic order.
 854 This command selects the frame ARG steps away in that order.
 855 A negative ARG moves in the opposite order.
 856
 857 To make this command work properly, you must tell Emacs
 858 how the system (or the window manager) generally handles
 859 focus-switching between windows.  If moving the mouse onto a window
 860 selects it (gives it focus), set `focus-follows-mouse' to t.
 861 Otherwise, that variable should be nil."
 862   (interactive "p")
 863   (let ((frame (selected-frame)))
 864     (while (> arg 0)
 865       (setq frame (next-frame frame))
 866       (while (not (eq (frame-visible-p frame) t))
 867         (setq frame (next-frame frame)))
 868       (setq arg (1- arg)))
 869     (while (< arg 0)
 870       (setq frame (previous-frame frame))
 871       (while (not (eq (frame-visible-p frame) t))
 872         (setq frame (previous-frame frame)))
 873       (setq arg (1+ arg)))
 874     (select-frame-set-input-focus frame)))
 875
 876 (defun iconify-or-deiconify-frame ()
 877   "Iconify the selected frame, or deiconify if it's currently an icon."
 878   (interactive)
 879   (if (eq (cdr (assq 'visibility (frame-parameters))) t)
 880       (iconify-frame)
 881     (make-frame-visible)))
 882
 883 (defun suspend-frame ()
 884   "Do whatever is right to suspend the current frame.
 885 Calls `suspend-emacs' if invoked from the controlling tty device,
 886 `suspend-tty' from a secondary tty device, and
 887 `iconify-or-deiconify-frame' from an X frame."
 888   (interactive)
 889   (let ((type (framep (selected-frame))))
 890     (cond
 891      ((memq type '(x ns w32)) (iconify-or-deiconify-frame))
 892      ((eq type t)
 893       (if (controlling-tty-p)
 894           (suspend-emacs)
 895         (suspend-tty)))
 896      (t (suspend-emacs)))))
 897
 898 (defun make-frame-names-alist ()
 899   (let* ((current-frame (selected-frame))
 900          (falist
 901           (cons
 902            (cons (frame-parameter current-frame 'name) current-frame) nil))
 903          (frame (next-frame nil t)))
 904     (while (not (eq frame current-frame))
 905       (progn
 906         (setq falist (cons (cons (frame-parameter frame 'name) frame) falist))
 907         (setq frame (next-frame frame t))))
 908     falist))
 909
 910 (defvar frame-name-history nil)
 911 (defun select-frame-by-name (name)
 912   "Select the frame on the current terminal whose name is NAME and raise it.
 913 If there is no frame by that name, signal an error."
 914   (interactive
 915    (let* ((frame-names-alist (make-frame-names-alist))
 916            (default (car (car frame-names-alist)))
 917            (input (completing-read
 918                    (format "Select Frame (default %s): " default)
 919                    frame-names-alist nil t nil 'frame-name-history)))
 920      (if (= (length input) 0)
 921          (list default)
 922        (list input))))
 923   (let* ((frame-names-alist (make-frame-names-alist))
 924          (frame (cdr (assoc name frame-names-alist))))
 925     (or frame
 926         (error "There is no frame named `%s'" name))
 927     (make-frame-visible frame)
 928     (raise-frame frame)
 929     (select-frame frame)
 930     ;; Ensure, if possible, that frame gets input focus.
 931     (cond ((memq (window-system frame) '(x w32 ns))
 932            (x-focus-frame frame)))
 933     (when focus-follows-mouse
 934       (set-mouse-position frame (1- (frame-width frame)) 0))))
 935 \f
 936 ;;;; Frame configurations
 937
 938 (defun current-frame-configuration ()
 939   "Return a list describing the positions and states of all frames.
 940 Its car is `frame-configuration'.
 941 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 942 where
 943   FRAME is a frame object,
 944   ALIST is an association list specifying some of FRAME's parameters, and
 945   WINDOW-CONFIG is a window configuration object for FRAME."
 946   (cons 'frame-configuration
 947         (mapcar (lambda (frame)
 948                   (list frame
 949                         (frame-parameters frame)
 950                         (current-window-configuration frame)))
 951                 (frame-list))))
 952
 953 (defun set-frame-configuration (configuration &optional nodelete)
 954   "Restore the frames to the state described by CONFIGURATION.
 955 Each frame listed in CONFIGURATION has its position, size, window
 956 configuration, and other parameters set as specified in CONFIGURATION.
 957 However, this function does not restore deleted frames.
 958
 959 Ordinarily, this function deletes all existing frames not
 960 listed in CONFIGURATION.  But if optional second argument NODELETE
 961 is given and non-nil, the unwanted frames are iconified instead."
 962   (or (frame-configuration-p configuration)
 963       (signal 'wrong-type-argument
 964               (list 'frame-configuration-p configuration)))
 965   (let ((config-alist (cdr configuration))
 966         frames-to-delete)
 967     (dolist (frame (frame-list))
 968       (let ((parameters (assq frame config-alist)))
 969         (if parameters
 970             (progn
 971               (modify-frame-parameters
 972                frame
 973                ;; Since we can't set a frame's minibuffer status,
 974                ;; we might as well omit the parameter altogether.
 975                (let* ((parms (nth 1 parameters))
 976                       (mini (assq 'minibuffer parms))
 977                       (name (assq 'name parms))
 978                       (explicit-name (cdr (assq 'explicit-name parms))))
 979                  (when mini (setq parms (delq mini parms)))
 980                  ;; Leave name in iff it was set explicitly.
 981                  ;; This should fix the behavior reported in
 982                  ;; http://lists.gnu.org/archive/html/emacs-devel/2007-08/msg01632.html
 983                  (when (and name (not explicit-name))
 984                    (setq parms (delq name parms)))
 985                  parms))
 986               (set-window-configuration (nth 2 parameters)))
 987           (setq frames-to-delete (cons frame frames-to-delete)))))
 988     (mapc (if nodelete
 989               ;; Note: making frames invisible here was tried
 990               ;; but led to some strange behavior--each time the frame
 991               ;; was made visible again, the window manager asked afresh
 992               ;; for where to put it.
 993               'iconify-frame
 994             'delete-frame)
 995           frames-to-delete)))
 996 \f
 997 ;;;; Convenience functions for accessing and interactively changing
 998 ;;;; frame parameters.
 999
1000 (defun frame-height (&optional frame)
1001   "Return number of lines available for display on FRAME.
1002 If FRAME is omitted, describe the currently selected frame."
1003   (cdr (assq 'height (frame-parameters frame))))
1004
1005 (defun frame-width (&optional frame)
1006   "Return number of columns available for display on FRAME.
1007 If FRAME is omitted, describe the currently selected frame."
1008   (cdr (assq 'width (frame-parameters frame))))
1009
1010 (declare-function x-list-fonts "xfaces.c"
1011                   (pattern &optional face frame maximum width))
1012
1013 (defalias 'set-default-font 'set-frame-font)
1014 (defun set-frame-font (font-name &optional keep-size)
1015   "Set the font of the selected frame to FONT-NAME.
1016 When called interactively, prompt for the name of the font to use.
1017 To get the frame's current default font, use `frame-parameters'.
1018
1019 The default behavior is to keep the numbers of lines and columns in
1020 the frame, thus may change its pixel size.  If optional KEEP-SIZE is
1021 non-nil (interactively, prefix argument) the current frame size (in
1022 pixels) is kept by adjusting the numbers of the lines and columns."
1023   (interactive
1024    (let* ((completion-ignore-case t)
1025           (font (completing-read "Font name: "
1026                                  ;; x-list-fonts will fail with an error
1027                                  ;; if this frame doesn't support fonts.
1028                                  (x-list-fonts "*" nil (selected-frame))
1029                                  nil nil nil nil
1030                                  (frame-parameter nil 'font))))
1031      (list font current-prefix-arg)))
1032   (let (fht fwd)
1033     (if keep-size
1034         (setq fht (* (frame-parameter nil 'height) (frame-char-height))
1035               fwd (* (frame-parameter nil 'width)  (frame-char-width))))
1036     (modify-frame-parameters (selected-frame)
1037                              (list (cons 'font font-name)))
1038     (if keep-size
1039         (modify-frame-parameters
1040          (selected-frame)
1041          (list (cons 'height (round fht (frame-char-height)))
1042                (cons 'width (round fwd (frame-char-width)))))))
1043   (run-hooks 'after-setting-font-hook 'after-setting-font-hooks))
1044
1045 (defun set-frame-parameter (frame parameter value)
1046   "Set frame parameter PARAMETER to VALUE on FRAME.
1047 If FRAME is nil, it defaults to the selected frame.
1048 See `modify-frame-parameters'."
1049   (modify-frame-parameters frame (list (cons parameter value))))
1050
1051 (defun set-background-color (color-name)
1052   "Set the background color of the selected frame to COLOR-NAME.
1053 When called interactively, prompt for the name of the color to use.
1054 To get the frame's current background color, use `frame-parameters'."
1055   (interactive (list (facemenu-read-color "Background color: ")))
1056   (modify-frame-parameters (selected-frame)
1057                            (list (cons 'background-color color-name)))
1058   (or window-system
1059       (face-set-after-frame-default (selected-frame))))
1060
1061 (defun set-foreground-color (color-name)
1062   "Set the foreground color of the selected frame to COLOR-NAME.
1063 When called interactively, prompt for the name of the color to use.
1064 To get the frame's current foreground color, use `frame-parameters'."
1065   (interactive (list (facemenu-read-color "Foreground color: ")))
1066   (modify-frame-parameters (selected-frame)
1067                            (list (cons 'foreground-color color-name)))
1068   (or window-system
1069       (face-set-after-frame-default (selected-frame))))
1070
1071 (defun set-cursor-color (color-name)
1072   "Set the text cursor color of the selected frame to COLOR-NAME.
1073 When called interactively, prompt for the name of the color to use.
1074 To get the frame's current cursor color, use `frame-parameters'."
1075   (interactive (list (facemenu-read-color "Cursor color: ")))
1076   (modify-frame-parameters (selected-frame)
1077                            (list (cons 'cursor-color color-name))))
1078
1079 (defun set-mouse-color (color-name)
1080   "Set the color of the mouse pointer of the selected frame to COLOR-NAME.
1081 When called interactively, prompt for the name of the color to use.
1082 To get the frame's current mouse color, use `frame-parameters'."
1083   (interactive (list (facemenu-read-color "Mouse color: ")))
1084   (modify-frame-parameters (selected-frame)
1085                            (list (cons 'mouse-color
1086                                        (or color-name
1087                                            (cdr (assq 'mouse-color
1088                                                       (frame-parameters))))))))
1089
1090 (defun set-border-color (color-name)
1091   "Set the color of the border of the selected frame to COLOR-NAME.
1092 When called interactively, prompt for the name of the color to use.
1093 To get the frame's current border color, use `frame-parameters'."
1094   (interactive (list (facemenu-read-color "Border color: ")))
1095   (modify-frame-parameters (selected-frame)
1096                            (list (cons 'border-color color-name))))
1097
1098 (defun auto-raise-mode (arg)
1099   "Toggle whether or not the selected frame should auto-raise.
1100 With arg, turn auto-raise mode on if and only if arg is positive.
1101 Note that this controls Emacs's own auto-raise feature.
1102 Some window managers allow you to enable auto-raise for certain windows.
1103 You can use that for Emacs windows if you wish, but if you do,
1104 that is beyond the control of Emacs and this command has no effect on it."
1105   (interactive "P")
1106   (if (null arg)
1107       (setq arg
1108             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
1109                 -1 1)))
1110   (if (> arg 0)
1111       (raise-frame (selected-frame)))
1112   (modify-frame-parameters (selected-frame)
1113                            (list (cons 'auto-raise (> arg 0)))))
1114
1115 (defun auto-lower-mode (arg)
1116   "Toggle whether or not the selected frame should auto-lower.
1117 With arg, turn auto-lower mode on if and only if arg is positive.
1118 Note that this controls Emacs's own auto-lower feature.
1119 Some window managers allow you to enable auto-lower for certain windows.
1120 You can use that for Emacs windows if you wish, but if you do,
1121 that is beyond the control of Emacs and this command has no effect on it."
1122   (interactive "P")
1123   (if (null arg)
1124       (setq arg
1125             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
1126                 -1 1)))
1127   (modify-frame-parameters (selected-frame)
1128                            (list (cons 'auto-lower (> arg 0)))))
1129 (defun set-frame-name (name)
1130   "Set the name of the selected frame to NAME.
1131 When called interactively, prompt for the name of the frame.
1132 The frame name is displayed on the modeline if the terminal displays only
1133 one frame, otherwise the name is displayed on the frame's caption bar."
1134   (interactive "sFrame name: ")
1135   (modify-frame-parameters (selected-frame)
1136                            (list (cons 'name name))))
1137
1138 (defun frame-current-scroll-bars (&optional frame)
1139   "Return the current scroll-bar settings in frame FRAME.
1140 Value is a cons (VERTICAL . HORIZ0NTAL) where VERTICAL specifies the
1141 current location of the vertical scroll-bars (left, right, or nil),
1142 and HORIZONTAL specifies the current location of the horizontal scroll
1143 bars (top, bottom, or nil)."
1144   (let ((vert (frame-parameter frame 'vertical-scroll-bars))
1145         (hor nil))
1146     (unless (memq vert '(left right nil))
1147       (setq vert default-frame-scroll-bars))
1148     (cons vert hor)))
1149 \f
1150 ;;;; Frame/display capabilities.
1151 (defun selected-terminal ()
1152   "Return the terminal that is now selected."
1153   (frame-terminal (selected-frame)))
1154
1155 (declare-function msdos-mouse-p "dosfns.c")
1156
1157 (defun display-mouse-p (&optional display)
1158   "Return non-nil if DISPLAY has a mouse available.
1159 DISPLAY can be a display name, a frame, or nil (meaning the selected
1160 frame's display)."
1161   (let ((frame-type (framep-on-display display)))
1162     (cond
1163      ((eq frame-type 'pc)
1164       (msdos-mouse-p))
1165      ((eq system-type 'windows-nt)
1166       (with-no-warnings
1167        (> w32-num-mouse-buttons 0)))
1168      ((memq frame-type '(x mac ns))
1169       t)    ;; We assume X, Mac, NeXTstep *always* have a pointing device
1170      (t
1171       (or (and (featurep 'xt-mouse)
1172                xterm-mouse-mode)
1173           ;; t-mouse is distributed with the GPM package.  It doesn't have
1174           ;; a toggle.
1175           (featurep 't-mouse))))))
1176
1177 (defun display-popup-menus-p (&optional display)
1178   "Return non-nil if popup menus are supported on DISPLAY.
1179 DISPLAY can be a display name, a frame, or nil (meaning the selected
1180 frame's display).
1181 Support for popup menus requires that the mouse be available."
1182   (and
1183    (let ((frame-type (framep-on-display display)))
1184      (memq frame-type '(x w32 pc mac ns)))
1185    (display-mouse-p display)))
1186
1187 (defun display-graphic-p (&optional display)
1188   "Return non-nil if DISPLAY is a graphic display.
1189 Graphical displays are those which are capable of displaying several
1190 frames and several different fonts at once.  This is true for displays
1191 that use a window system such as X, and false for text-only terminals.
1192 DISPLAY can be a display name, a frame, or nil (meaning the selected
1193 frame's display)."
1194   (not (null (memq (framep-on-display display) '(x w32 mac ns)))))
1195
1196 (defun display-images-p (&optional display)
1197   "Return non-nil if DISPLAY can display images.
1198
1199 DISPLAY can be a display name, a frame, or nil (meaning the selected
1200 frame's display)."
1201   (and (display-graphic-p display)
1202        (fboundp 'image-mask-p)
1203        (fboundp 'image-size)))
1204
1205 (defalias 'display-multi-frame-p 'display-graphic-p)
1206 (defalias 'display-multi-font-p 'display-graphic-p)
1207
1208 (defun display-selections-p (&optional display)
1209   "Return non-nil if DISPLAY supports selections.
1210 A selection is a way to transfer text or other data between programs
1211 via special system buffers called `selection' or `cut buffer' or
1212 `clipboard'.
1213 DISPLAY can be a display name, a frame, or nil (meaning the selected
1214 frame's display)."
1215   (let ((frame-type (framep-on-display display)))
1216     (cond
1217      ((eq frame-type 'pc)
1218       ;; MS-DOG frames support selections when Emacs runs inside
1219       ;; the Windows' DOS Box.
1220       (with-no-warnings
1221        (not (null dos-windows-version))))
1222      ((memq frame-type '(x w32 mac ns))
1223       t)    ;; FIXME?
1224      (t
1225       nil))))
1226
1227 (declare-function x-display-screens "xfns.c" (&optional terminal))
1228
1229 (defun display-screens (&optional display)
1230   "Return the number of screens associated with DISPLAY."
1231   (let ((frame-type (framep-on-display display)))
1232     (cond
1233      ((memq frame-type '(x w32 mac ns))
1234       (x-display-screens display))
1235      (t
1236       1))))
1237
1238 (declare-function x-display-pixel-height "xfns.c" (&optional terminal))
1239
1240 (defun display-pixel-height (&optional display)
1241   "Return the height of DISPLAY's screen in pixels.
1242 For character terminals, each character counts as a single pixel."
1243   (let ((frame-type (framep-on-display display)))
1244     (cond
1245      ((memq frame-type '(x w32 mac ns))
1246       (x-display-pixel-height display))
1247      (t
1248       (frame-height (if (framep display) display (selected-frame)))))))
1249
1250 (declare-function x-display-pixel-width "xfns.c" (&optional terminal))
1251
1252 (defun display-pixel-width (&optional display)
1253   "Return the width of DISPLAY's screen in pixels.
1254 For character terminals, each character counts as a single pixel."
1255   (let ((frame-type (framep-on-display display)))
1256     (cond
1257      ((memq frame-type '(x w32 mac ns))
1258       (x-display-pixel-width display))
1259      (t
1260       (frame-width (if (framep display) display (selected-frame)))))))
1261
1262 (defcustom display-mm-dimensions-alist nil
1263   "Alist for specifying screen dimensions in millimeters.
1264 The dimensions will be used for `display-mm-height' and
1265 `display-mm-width' if defined for the respective display.
1266
1267 Each element of the alist has the form (display . (width . height)),
1268 e.g. (\":0.0\" . (287 . 215)).
1269
1270 If `display' equals t, it specifies dimensions for all graphical
1271 displays not explicitely specified."
1272   :version "22.1"
1273   :type '(alist :key-type (choice (string :tag "Display name")
1274                                   (const :tag "Default" t))
1275                 :value-type (cons :tag "Dimensions"
1276                                   (integer :tag "Width")
1277                                   (integer :tag "Height")))
1278   :group 'frames)
1279
1280 (declare-function x-display-mm-height "xfns.c" (&optional terminal))
1281
1282 (defun display-mm-height (&optional display)
1283   "Return the height of DISPLAY's screen in millimeters.
1284 System values can be overridden by `display-mm-dimensions-alist'.
1285 If the information is unavailable, value is nil."
1286   (and (memq (framep-on-display display) '(x w32 mac ns))
1287        (or (cddr (assoc (or display (frame-parameter nil 'display))
1288                         display-mm-dimensions-alist))
1289            (cddr (assoc t display-mm-dimensions-alist))
1290            (x-display-mm-height display))))
1291
1292 (declare-function x-display-mm-width "xfns.c" (&optional terminal))
1293
1294 (defun display-mm-width (&optional display)
1295   "Return the width of DISPLAY's screen in millimeters.
1296 System values can be overridden by `display-mm-dimensions-alist'.
1297 If the information is unavailable, value is nil."
1298   (and (memq (framep-on-display display) '(x w32 mac ns))
1299        (or (cadr (assoc (or display (frame-parameter nil 'display))
1300                         display-mm-dimensions-alist))
1301            (cadr (assoc t display-mm-dimensions-alist))
1302            (x-display-mm-width display))))
1303
1304 (declare-function x-display-backing-store "xfns.c" (&optional terminal))
1305
1306 (defun display-backing-store (&optional display)
1307   "Return the backing store capability of DISPLAY's screen.
1308 The value may be `always', `when-mapped', `not-useful', or nil if
1309 the question is inapplicable to a certain kind of display."
1310   (let ((frame-type (framep-on-display display)))
1311     (cond
1312      ((memq frame-type '(x w32 mac ns))
1313       (x-display-backing-store display))
1314      (t
1315       'not-useful))))
1316
1317 (declare-function x-display-save-under "xfns.c" (&optional terminal))
1318
1319 (defun display-save-under (&optional display)
1320   "Return non-nil if DISPLAY's screen supports the SaveUnder feature."
1321   (let ((frame-type (framep-on-display display)))
1322     (cond
1323      ((memq frame-type '(x w32 mac ns))
1324       (x-display-save-under display))
1325      (t
1326       'not-useful))))
1327
1328 (declare-function x-display-planes "xfns.c" (&optional terminal))
1329
1330 (defun display-planes (&optional display)
1331   "Return the number of planes supported by DISPLAY."
1332   (let ((frame-type (framep-on-display display)))
1333     (cond
1334      ((memq frame-type '(x w32 mac ns))
1335       (x-display-planes display))
1336      ((eq frame-type 'pc)
1337       4)
1338      (t
1339       (truncate (log (length (tty-color-alist)) 2))))))
1340
1341 (declare-function x-display-color-cells "xfns.c" (&optional terminal))
1342
1343 (defun display-color-cells (&optional display)
1344   "Return the number of color cells supported by DISPLAY."
1345   (let ((frame-type (framep-on-display display)))
1346     (cond
1347      ((memq frame-type '(x w32 mac ns))
1348       (x-display-color-cells display))
1349      ((eq frame-type 'pc)
1350       16)
1351      (t
1352       (tty-display-color-cells display)))))
1353
1354 (declare-function x-display-visual-class "xfns.c" (&optional terminal))
1355
1356 (defun display-visual-class (&optional display)
1357   "Returns the visual class of DISPLAY.
1358 The value is one of the symbols `static-gray', `gray-scale',
1359 `static-color', `pseudo-color', `true-color', or `direct-color'."
1360   (let ((frame-type (framep-on-display display)))
1361     (cond
1362      ((memq frame-type '(x w32 mac ns))
1363       (x-display-visual-class display))
1364      ((and (memq frame-type '(pc t))
1365            (tty-display-color-p display))
1366       'static-color)
1367      (t
1368       'static-gray))))
1369
1370 \f
1371 ;;;; Frame geometry values
1372
1373 (defun frame-geom-value-cons (type value &optional frame)
1374   "Return equivalent geometry value for FRAME as a cons with car `+'.
1375 A geometry value equivalent to VALUE for FRAME is returned,
1376 where the value is a cons with car `+', not numeric.
1377 TYPE is the car of the original geometry spec (TYPE . VALUE).
1378    It is `top' or `left', depending on which edge VALUE is related to.
1379 VALUE is the cdr of a frame geometry spec: (left/top . VALUE).
1380 If VALUE is a number, then it is converted to a cons value, perhaps
1381    relative to the opposite frame edge from that in the original spec.
1382 FRAME defaults to the selected frame.
1383
1384 Examples (measures in pixels) -
1385  Assuming display height/width=1024, frame height/width=600:
1386  300 inside display edge:                   300  => (+  300)
1387                                         (+  300) => (+  300)
1388  300 inside opposite display edge:      (-  300) => (+  124)
1389                                            -300  => (+  124)
1390  300 beyond display edge
1391   (= 724 inside opposite display edge): (+ -300) => (+ -300)
1392  300 beyond display edge
1393   (= 724 inside opposite display edge): (- -300) => (+  724)
1394
1395 In the 3rd, 4th, and 6th examples, the returned value is relative to
1396 the opposite frame edge from the edge indicated in the input spec."
1397   (cond ((and (consp value) (eq '+ (car value))) ; e.g. (+ 300), (+ -300)
1398          value)
1399         ((natnump value) (list '+ value)) ; e.g. 300 => (+ 300)
1400         (t                              ; e.g. -300, (- 300), (- -300)
1401          (list '+ (- (if (eq 'left type) ; => (+ 124), (+ 124), (+ 724)
1402                          (x-display-pixel-width)
1403                        (x-display-pixel-height))
1404                      (if (integerp value) (- value) (cadr value))
1405                      (if (eq 'left type)
1406                          (frame-pixel-width frame)
1407                        (frame-pixel-height frame)))))))
1408
1409 (defun frame-geom-spec-cons (spec &optional frame)
1410   "Return equivalent geometry spec for FRAME as a cons with car `+'.
1411 A geometry specification equivalent to SPEC for FRAME is returned,
1412 where the value is a cons with car `+', not numeric.
1413 SPEC is a frame geometry spec: (left . VALUE) or (top . VALUE).
1414 If VALUE is a number, then it is converted to a cons value, perhaps
1415    relative to the opposite frame edge from that in the original spec.
1416 FRAME defaults to the selected frame.
1417
1418 Examples (measures in pixels) -
1419  Assuming display height=1024, frame height=600:
1420  top 300 below display top:               (top .  300) => (top +  300)
1421                                           (top +  300) => (top +  300)
1422  bottom 300 above display bottom:         (top -  300) => (top +  124)
1423                                           (top . -300) => (top +  124)
1424  top 300 above display top
1425   (= bottom 724 above display bottom):    (top + -300) => (top + -300)
1426  bottom 300 below display bottom
1427   (= top 724 below display top):          (top - -300) => (top +  724)
1428
1429 In the 3rd, 4th, and 6th examples, the returned value is relative to
1430 the opposite frame edge from the edge indicated in the input spec."
1431   (cons (car spec) (frame-geom-value-cons (car spec) (cdr spec))))
1432 \f
1433 ;;;; Aliases for backward compatibility with Emacs 18.
1434 (define-obsolete-function-alias 'screen-height 'frame-height "19.7")
1435 (define-obsolete-function-alias 'screen-width 'frame-width "19.7")
1436
1437 (defun set-screen-width (cols &optional pretend)
1438   "Change the size of the screen to COLS columns.
1439 Optional second arg non-nil means that redisplay should use COLS columns
1440 but that the idea of the actual width of the frame should not be changed.
1441 This function is provided only for compatibility with Emacs 18."
1442   (set-frame-width (selected-frame) cols pretend))
1443
1444 (defun set-screen-height (lines &optional pretend)
1445   "Change the height of the screen to LINES lines.
1446 Optional second arg non-nil means that redisplay should use LINES lines
1447 but that the idea of the actual height of the screen should not be changed.
1448 This function is provided only for compatibility with Emacs 18."
1449   (set-frame-height (selected-frame) lines pretend))
1450
1451 (defun delete-other-frames (&optional frame)
1452   "Delete all frames except FRAME.
1453 If FRAME uses another frame's minibuffer, the minibuffer frame is
1454 left untouched.  FRAME nil or omitted means use the selected frame."
1455   (interactive)
1456   (unless frame
1457     (setq frame (selected-frame)))
1458   (let* ((mini-frame (window-frame (minibuffer-window frame)))
1459          (frames (delq mini-frame (delq frame (frame-list)))))
1460     ;; Delete mon-minibuffer-only frames first, because `delete-frame'
1461     ;; signals an error when trying to delete a mini-frame that's
1462     ;; still in use by another frame.
1463     (dolist (frame frames)
1464       (unless (eq (frame-parameter frame 'minibuffer) 'only)
1465         (delete-frame frame)))
1466     ;; Delete minibuffer-only frames.
1467     (dolist (frame frames)
1468       (when (eq (frame-parameter frame 'minibuffer) 'only)
1469         (delete-frame frame)))))
1470
1471 (make-obsolete 'set-screen-width 'set-frame-width "19.7")
1472 (make-obsolete 'set-screen-height 'set-frame-height "19.7")
1473
1474 ;; miscellaneous obsolescence declarations
1475 (define-obsolete-variable-alias 'delete-frame-hook
1476     'delete-frame-functions "22.1")
1477
1478 \f
1479 ;; Highlighting trailing whitespace.
1480
1481 (make-variable-buffer-local 'show-trailing-whitespace)
1482
1483 (defcustom show-trailing-whitespace nil
1484   "*Non-nil means highlight trailing whitespace.
1485 This is done in the face `trailing-whitespace'."
1486   :type 'boolean
1487   :group 'whitespace-faces)
1488
1489
1490 \f
1491 ;; Scrolling
1492
1493 (defgroup scrolling nil
1494   "Scrolling windows."
1495   :version "21.1"
1496   :group 'frames)
1497
1498 (defcustom auto-hscroll-mode t
1499   "*Allow or disallow automatic scrolling windows horizontally.
1500 If non-nil, windows are automatically scrolled horizontally to make
1501 point visible."
1502   :version "21.1"
1503   :type 'boolean
1504   :group 'scrolling)
1505 (defvaralias 'automatic-hscrolling 'auto-hscroll-mode)
1506
1507 \f
1508 ;; Blinking cursor
1509
1510 (defgroup cursor nil
1511   "Displaying text cursors."
1512   :version "21.1"
1513   :group 'frames)
1514
1515 (defcustom blink-cursor-delay 0.5
1516   "*Seconds of idle time after which cursor starts to blink."
1517   :type 'number
1518   :group 'cursor)
1519
1520 (defcustom blink-cursor-interval 0.5
1521   "*Length of cursor blink interval in seconds."
1522   :type 'number
1523   :group 'cursor)
1524
1525 (defvar blink-cursor-idle-timer nil
1526   "Timer started after `blink-cursor-delay' seconds of Emacs idle time.
1527 The function `blink-cursor-start' is called when the timer fires.")
1528
1529 (defvar blink-cursor-timer nil
1530   "Timer started from `blink-cursor-start'.
1531 This timer calls `blink-cursor-timer-function' every
1532 `blink-cursor-interval' seconds.")
1533
1534 (defun blink-cursor-start ()
1535   "Timer function called from the timer `blink-cursor-idle-timer'.
1536 This starts the timer `blink-cursor-timer', which makes the cursor blink
1537 if appropriate.  It also arranges to cancel that timer when the next
1538 command starts, by installing a pre-command hook."
1539   (when (null blink-cursor-timer)
1540     ;; Set up the timer first, so that if this signals an error,
1541     ;; blink-cursor-end is not added to pre-command-hook.
1542     (setq blink-cursor-timer
1543           (run-with-timer blink-cursor-interval blink-cursor-interval
1544                           'blink-cursor-timer-function))
1545     (add-hook 'pre-command-hook 'blink-cursor-end)
1546     (internal-show-cursor nil nil)))
1547
1548 (defun blink-cursor-timer-function ()
1549   "Timer function of timer `blink-cursor-timer'."
1550   (internal-show-cursor nil (not (internal-show-cursor-p))))
1551
1552 (defun blink-cursor-end ()
1553   "Stop cursor blinking.
1554 This is installed as a pre-command hook by `blink-cursor-start'.
1555 When run, it cancels the timer `blink-cursor-timer' and removes
1556 itself as a pre-command hook."
1557   (remove-hook 'pre-command-hook 'blink-cursor-end)
1558   (internal-show-cursor nil t)
1559   (when blink-cursor-timer
1560     (cancel-timer blink-cursor-timer)
1561     (setq blink-cursor-timer nil)))
1562
1563 (define-minor-mode blink-cursor-mode
1564   "Toggle blinking cursor mode.
1565 With a numeric argument, turn blinking cursor mode on if ARG is positive,
1566 otherwise turn it off.  When blinking cursor mode is enabled, the
1567 cursor of the selected window blinks.
1568
1569 Note that this command is effective only when Emacs
1570 displays through a window system, because then Emacs does its own
1571 cursor display.  On a text-only terminal, this is not implemented."
1572   :init-value (not (or noninteractive
1573                        no-blinking-cursor
1574                        (eq system-type 'ms-dos)
1575                        (not (memq window-system '(x w32 mac)))))
1576   :initialize 'custom-initialize-safe-default
1577   :group 'cursor
1578   :global t
1579   (if blink-cursor-idle-timer (cancel-timer blink-cursor-idle-timer))
1580   (setq blink-cursor-idle-timer nil)
1581   (blink-cursor-end)
1582   (when blink-cursor-mode
1583     ;; Hide the cursor.
1584     ;;(internal-show-cursor nil nil)
1585     (setq blink-cursor-idle-timer
1586           (run-with-idle-timer blink-cursor-delay
1587                                blink-cursor-delay
1588                                'blink-cursor-start))))
1589
1590 (define-obsolete-variable-alias 'blink-cursor 'blink-cursor-mode "22.1")
1591 \f
1592 ;; Hourglass pointer
1593
1594 (defcustom display-hourglass t
1595   "*Non-nil means show an hourglass pointer, when Emacs is busy.
1596 This feature only works when on a window system that can change
1597 cursor shapes."
1598   :type 'boolean
1599   :group 'cursor)
1600
1601 (defcustom hourglass-delay 1
1602   "*Seconds to wait before displaying an hourglass pointer when Emacs is busy."
1603   :type 'number
1604   :group 'cursor)
1605
1606 \f
1607 (defcustom cursor-in-non-selected-windows t
1608   "*Non-nil means show a hollow box cursor in non-selected windows.
1609 If nil, don't show a cursor except in the selected window.
1610 If t, display a cursor related to the usual cursor type
1611  \(a solid box becomes hollow, a bar becomes a narrower bar).
1612 You can also specify the cursor type as in the `cursor-type' variable.
1613 Use Custom to set this variable to get the display updated."
1614   :tag "Cursor In Non-selected Windows"
1615   :type 'boolean
1616   :group 'cursor
1617   :set #'(lambda (symbol value)
1618            (set-default symbol value)
1619            (force-mode-line-update t)))
1620
1621 \f
1622 ;;;; Key bindings
1623
1624 (define-key ctl-x-5-map "2" 'make-frame-command)
1625 (define-key ctl-x-5-map "1" 'delete-other-frames)
1626 (define-key ctl-x-5-map "0" 'delete-frame)
1627 (define-key ctl-x-5-map "o" 'other-frame)
1628
1629 (provide 'frame)
1630
1631 ;; arch-tag: 82979c70-b8f2-4306-b2ad-ddbd6b328b56
1632 ;;; frame.el ends here