lisp/gnus/nnspool.el

   1 ;;; nnspool.el --- spool access for GNU Emacs
   2
   3 ;; Copyright (C) 1988, 1989, 1990, 1993, 1994, 1995, 1996, 1997, 1998,
   4 ;;   2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   5 ;;   Free Software Foundation, Inc.
   6
   7 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   9 ;; Keywords: news
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'nnheader)
  31 (require 'nntp)
  32 (require 'nnoo)
  33 (eval-when-compile (require 'cl))
  34
  35 (nnoo-declare nnspool)
  36
  37 (defvoo nnspool-inews-program news-inews-program
  38   "Program to post news.
  39 This is most commonly `inews' or `injnews'.")
  40
  41 (defvoo nnspool-inews-switches '("-h" "-S")
  42   "Switches for nnspool-request-post to pass to `inews' for posting news.
  43 If you are using Cnews, you probably should set this variable to nil.")
  44
  45 (defvoo nnspool-spool-directory
  46     (file-name-as-directory (if (boundp 'news-directory)
  47                                 (symbol-value 'news-directory)
  48                               news-path))
  49   "Local news spool directory.")
  50
  51 (defvoo nnspool-nov-directory (concat nnspool-spool-directory "over.view/")
  52   "Local news nov directory.")
  53
  54 (defvoo nnspool-lib-dir
  55     (if (file-exists-p "/usr/lib/news/active")
  56         "/usr/lib/news/"
  57       "/var/lib/news/")
  58   "Where the local news library files are stored.")
  59
  60 (defvoo nnspool-active-file (concat nnspool-lib-dir "active")
  61   "Local news active file.")
  62
  63 (defvoo nnspool-newsgroups-file (concat nnspool-lib-dir "newsgroups")
  64   "Local news newsgroups file.")
  65
  66 (defvoo nnspool-distributions-file (concat nnspool-lib-dir "distribs.pat")
  67   "Local news distributions file.")
  68
  69 (defvoo nnspool-history-file (concat nnspool-lib-dir "history")
  70   "Local news history file.")
  71
  72 (defvoo nnspool-active-times-file (concat nnspool-lib-dir "active.times")
  73   "Local news active date file.")
  74
  75 (defvoo nnspool-large-newsgroup 50
  76   "The number of articles which indicates a large newsgroup.
  77 If the number of articles is greater than the value, verbose
  78 messages will be shown to indicate the current status.")
  79
  80 (defvoo nnspool-nov-is-evil nil
  81   "Non-nil means that nnspool will never return NOV lines instead of headers.")
  82
  83 (defconst nnspool-sift-nov-with-sed nil
  84   "If non-nil, use sed to get the relevant portion from the overview file.
  85 If nil, nnspool will load the entire file into a buffer and process it
  86 there.")
  87
  88 (defvoo nnspool-rejected-article-hook nil
  89   "*A hook that will be run when an article has been rejected by the server.")
  90
  91 (defvoo nnspool-file-coding-system nnheader-file-coding-system
  92   "Coding system for nnspool.")
  93
  94 \f
  95
  96 (defconst nnspool-version "nnspool 2.0"
  97   "Version numbers of this version of NNSPOOL.")
  98
  99 (defvoo nnspool-current-directory nil
 100   "Current news group directory.")
 101
 102 (defvoo nnspool-current-group nil)
 103 (defvoo nnspool-status-string "")
 104
 105 \f
 106 ;;; Interface functions.
 107
 108 (nnoo-define-basics nnspool)
 109
 110 (deffoo nnspool-retrieve-headers (articles &optional group server fetch-old)
 111   "Retrieve the headers of ARTICLES."
 112   (with-current-buffer nntp-server-buffer
 113     (erase-buffer)
 114     (when (nnspool-possibly-change-directory group)
 115       (let* ((number (length articles))
 116              (count 0)
 117              (default-directory nnspool-current-directory)
 118              (do-message (and (numberp nnspool-large-newsgroup)
 119                               (> number nnspool-large-newsgroup)))
 120              (nnheader-file-coding-system nnspool-file-coding-system)
 121              file beg article ag)
 122         (if (and (numberp (car articles))
 123                  (nnspool-retrieve-headers-with-nov articles fetch-old))
 124             ;; We successfully retrieved the NOV headers.
 125             'nov
 126           ;; No NOV headers here, so we do it the hard way.
 127           (while (setq article (pop articles))
 128             (if (stringp article)
 129                 ;; This is a Message-ID.
 130                 (setq ag (nnspool-find-id article)
 131                       file (and ag (nnspool-article-pathname
 132                                     (car ag) (cdr ag)))
 133                       article (cdr ag))
 134               ;; This is an article in the current group.
 135               (setq file (int-to-string article)))
 136             ;; Insert the head of the article.
 137             (when (and file
 138                        (file-exists-p file))
 139               (insert "221 ")
 140               (princ article (current-buffer))
 141               (insert " Article retrieved.\n")
 142               (setq beg (point))
 143               (inline (nnheader-insert-head file))
 144               (goto-char beg)
 145               (if (search-forward "\n\n" nil t)
 146                   (progn
 147                     (forward-char -1)
 148                     (insert ".\n"))
 149                 (goto-char (point-max))
 150                 (if (bolp)
 151                     (insert ".\n")
 152                   (insert "\n.\n")))
 153               (delete-region (point) (point-max)))
 154
 155             (and do-message
 156                  (zerop (% (incf count) 20))
 157                  (nnheader-message 5 "nnspool: Receiving headers... %d%%"
 158                                    (/ (* count 100) number))))
 159
 160           (when do-message
 161             (nnheader-message 5 "nnspool: Receiving headers...done"))
 162
 163           ;; Fold continuation lines.
 164           (nnheader-fold-continuation-lines)
 165           'headers)))))
 166
 167 (deffoo nnspool-open-server (server &optional defs)
 168   (nnoo-change-server 'nnspool server defs)
 169   (cond
 170    ((not (file-exists-p nnspool-spool-directory))
 171     (nnspool-close-server)
 172     (nnheader-report 'nnspool "Spool directory doesn't exist: %s"
 173                      nnspool-spool-directory))
 174    ((not (file-directory-p
 175           (directory-file-name
 176            (file-truename nnspool-spool-directory))))
 177     (nnspool-close-server)
 178     (nnheader-report 'nnspool "Not a directory: %s" nnspool-spool-directory))
 179    ((not (file-exists-p nnspool-active-file))
 180     (nnheader-report 'nnspool "The active file doesn't exist: %s"
 181                      nnspool-active-file))
 182    (t
 183     (nnheader-report 'nnspool "Opened server %s using directory %s"
 184                      server nnspool-spool-directory)
 185     t)))
 186
 187 (deffoo nnspool-request-article (id &optional group server buffer)
 188   "Select article by message ID (or number)."
 189   (nnspool-possibly-change-directory group)
 190   (let ((nntp-server-buffer (or buffer nntp-server-buffer))
 191         file ag)
 192     (if (stringp id)
 193         ;; This is a Message-ID.
 194         (when (setq ag (nnspool-find-id id))
 195           (setq file (nnspool-article-pathname (car ag) (cdr ag))))
 196       (setq file (nnspool-article-pathname nnspool-current-group id)))
 197     (and file
 198          (file-exists-p file)
 199          (not (file-directory-p file))
 200          (save-excursion (nnspool-find-file file))
 201          ;; We return the article number and group name.
 202          (if (numberp id)
 203              (cons nnspool-current-group id)
 204            ag))))
 205
 206 (deffoo nnspool-request-body (id &optional group server)
 207   "Select article body by message ID (or number)."
 208   (nnspool-possibly-change-directory group)
 209   (let ((res (nnspool-request-article id)))
 210     (when res
 211       (with-current-buffer nntp-server-buffer
 212         (goto-char (point-min))
 213         (when (search-forward "\n\n" nil t)
 214           (delete-region (point-min) (point)))
 215         res))))
 216
 217 (deffoo nnspool-request-head (id &optional group server)
 218   "Select article head by message ID (or number)."
 219   (nnspool-possibly-change-directory group)
 220   (let ((res (nnspool-request-article id)))
 221     (when res
 222       (with-current-buffer nntp-server-buffer
 223         (goto-char (point-min))
 224         (when (search-forward "\n\n" nil t)
 225           (delete-region (1- (point)) (point-max)))
 226         (nnheader-fold-continuation-lines)))
 227     res))
 228
 229 (deffoo nnspool-request-group (group &optional server dont-check info)
 230   "Select news GROUP."
 231   (let ((pathname (nnspool-article-pathname group))
 232         dir)
 233     (if (not (file-directory-p pathname))
 234         (nnheader-report
 235          'nnspool "Invalid group name (no such directory): %s" group)
 236       (setq nnspool-current-directory pathname)
 237       (nnheader-report 'nnspool "Selected group %s" group)
 238       (if dont-check
 239           (progn
 240             (nnheader-report 'nnspool "Selected group %s" group)
 241             t)
 242         ;; Yes, completely empty spool directories *are* possible.
 243         ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>
 244         (when (setq dir (directory-files pathname nil "^[0-9]+$" t))
 245           (setq dir (sort (mapcar 'string-to-number dir) '<)))
 246         (if dir
 247             (nnheader-insert
 248              "211 %d %d %d %s\n" (length dir) (car dir)
 249              (car (last dir)) group)
 250           (nnheader-report 'nnspool "Empty group %s" group)
 251           (nnheader-insert "211 0 0 0 %s\n" group))))))
 252
 253 (deffoo nnspool-request-type (group &optional article)
 254   'news)
 255
 256 (deffoo nnspool-close-group (group &optional server)
 257   t)
 258
 259 (deffoo nnspool-request-list (&optional server)
 260   "List active newsgroups."
 261   (save-excursion
 262     (or (nnspool-find-file nnspool-active-file)
 263         (nnheader-report 'nnspool (nnheader-file-error nnspool-active-file)))))
 264
 265 (deffoo nnspool-request-list-newsgroups (&optional server)
 266   "List newsgroups (defined in NNTP2)."
 267   (save-excursion
 268     (or (nnspool-find-file nnspool-newsgroups-file)
 269         (nnheader-report 'nnspool (nnheader-file-error
 270                                    nnspool-newsgroups-file)))))
 271
 272 (deffoo nnspool-request-list-distributions (&optional server)
 273   "List distributions (defined in NNTP2)."
 274   (save-excursion
 275     (or (nnspool-find-file nnspool-distributions-file)
 276         (nnheader-report 'nnspool (nnheader-file-error
 277                                    nnspool-distributions-file)))))
 278
 279 ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 280 (deffoo nnspool-request-newgroups (date &optional server)
 281   "List groups created after DATE."
 282   (if (nnspool-find-file nnspool-active-times-file)
 283       (save-excursion
 284         ;; Find the last valid line.
 285         (goto-char (point-max))
 286         (while (and (not (looking-at
 287                           "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
 288                     (zerop (forward-line -1))))
 289         ;; We require nnheader which requires gnus-util.
 290         (let ((seconds (gnus-float-time (date-to-time date)))
 291               groups)
 292           ;; Go through lines and add the latest groups to a list.
 293           (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
 294                       (progn
 295                         ;; We insert a .0 to make the list reader
 296                         ;; interpret the number as a float.  It is far
 297                         ;; too big to be stored in a lisp integer.
 298                         (goto-char (1- (match-end 0)))
 299                         (insert ".0")
 300                         (> (progn
 301                              (goto-char (match-end 1))
 302                              (read (current-buffer)))
 303                            seconds))
 304                       (push (buffer-substring
 305                              (match-beginning 1) (match-end 1))
 306                             groups)
 307                       (zerop (forward-line -1))))
 308           (erase-buffer)
 309           (dolist (group groups)
 310             (insert group " 0 0 y\n")))
 311         t)
 312     nil))
 313
 314 (deffoo nnspool-request-post (&optional server)
 315   "Post a new news in current buffer."
 316   (save-excursion
 317     (let* ((process-connection-type nil) ; t bugs out on Solaris
 318            (inews-buffer (generate-new-buffer " *nnspool post*"))
 319            (proc
 320             (condition-case err
 321                 (apply 'start-process "*nnspool inews*" inews-buffer
 322                        nnspool-inews-program nnspool-inews-switches)
 323               (error
 324                (nnheader-report 'nnspool "inews error: %S" err)))))
 325       (if (not proc)
 326           ;; The inews program failed.
 327           ()
 328         (nnheader-report 'nnspool "")
 329         (set-process-sentinel proc 'nnspool-inews-sentinel)
 330         (mm-with-unibyte-current-buffer
 331           (process-send-region proc (point-min) (point-max)))
 332         ;; We slap a condition-case around this, because the process may
 333         ;; have exited already...
 334         (ignore-errors
 335           (process-send-eof proc))
 336         t))))
 337
 338
 339 \f
 340 ;;; Internal functions.
 341
 342 (defun nnspool-inews-sentinel (proc status)
 343   (with-current-buffer (process-buffer proc)
 344     (goto-char (point-min))
 345     (if (or (zerop (buffer-size))
 346             (search-forward "spooled" nil t))
 347         (kill-buffer (current-buffer))
 348       ;; Make status message by folding lines.
 349       (while (re-search-forward "[ \t\n]+" nil t)
 350         (replace-match " " t t))
 351       (nnheader-report 'nnspool "%s" (buffer-string))
 352       (nnheader-message 5 "nnspool: %s" nnspool-status-string)
 353       (ding)
 354       (run-hooks 'nnspool-rejected-article-hook))))
 355
 356 (defun nnspool-retrieve-headers-with-nov (articles &optional fetch-old)
 357   (if (or gnus-nov-is-evil nnspool-nov-is-evil)
 358       nil
 359     (let ((nov (nnheader-group-pathname
 360                 nnspool-current-group nnspool-nov-directory ".overview"))
 361           (arts articles)
 362           (nnheader-file-coding-system nnspool-file-coding-system)
 363           last)
 364       (if (not (file-exists-p nov))
 365           ()
 366         (with-current-buffer nntp-server-buffer
 367           (erase-buffer)
 368           (if nnspool-sift-nov-with-sed
 369               (nnspool-sift-nov-with-sed articles nov)
 370             (nnheader-insert-file-contents nov)
 371             (if (and fetch-old
 372                      (not (numberp fetch-old)))
 373                 t                       ; We want all the headers.
 374               (ignore-errors
 375                 ;; Delete unwanted NOV lines.
 376                 (nnheader-nov-delete-outside-range
 377                  (if fetch-old (max 1 (- (car articles) fetch-old))
 378                    (car articles))
 379                  (car (last articles)))
 380                 ;; If the buffer is empty, this wasn't very successful.
 381                 (unless (zerop (buffer-size))
 382                   ;; We check what the last article number was.
 383                   ;; The NOV file may be out of sync with the articles
 384                   ;; in the group.
 385                   (forward-line -1)
 386                   (setq last (read (current-buffer)))
 387                   (if (= last (car articles))
 388                       ;; Yup, it's all there.
 389                       t
 390                     ;; Perhaps not.  We try to find the missing articles.
 391                     (while (and arts
 392                                 (<= last (car arts)))
 393                       (pop arts))
 394                     ;; The articles in `arts' are missing from the buffer.
 395                     (mapc 'nnspool-insert-nov-head arts)
 396                     t))))))))))
 397
 398 (defun nnspool-insert-nov-head (article)
 399   "Read the head of ARTICLE, convert to NOV headers, and insert."
 400   (save-excursion
 401     (let ((cur (current-buffer))
 402           buf)
 403       (setq buf (nnheader-set-temp-buffer " *nnspool head*"))
 404       (when (nnheader-insert-head
 405              (nnspool-article-pathname nnspool-current-group article))
 406         (nnheader-insert-article-line article)
 407         (goto-char (point-min))
 408         (let ((headers (nnheader-parse-head)))
 409           (set-buffer cur)
 410           (goto-char (point-max))
 411           (nnheader-insert-nov headers)))
 412       (kill-buffer buf))))
 413
 414 (defun nnspool-sift-nov-with-sed (articles file)
 415   (let ((first (car articles))
 416         (last (car (last articles))))
 417     (call-process "awk" nil t nil
 418                   (format "BEGIN {firstmsg=%d; lastmsg=%d;}\n $1 >= firstmsg && $1 <= lastmsg {print;}"
 419                           (1- first) (1+ last))
 420                   file)))
 421
 422 ;; Fixed by fdc@cliwe.ping.de (Frank D. Cringle).
 423 ;; Find out what group an article identified by a Message-ID is in.
 424 (defun nnspool-find-id (id)
 425   (with-temp-buffer
 426     (ignore-errors
 427       (call-process "grep" nil t nil (regexp-quote id) nnspool-history-file))
 428     (goto-char (point-min))
 429     (when (looking-at "<[^>]+>[ \t]+[-0-9~]+[ \t]+\\([^ /\t\n]+\\)/\\([0-9]+\\)[ \t\n]")
 430       (cons (match-string 1) (string-to-number (match-string 2))))))
 431
 432 (defun nnspool-find-file (file)
 433   "Insert FILE in server buffer safely."
 434   (set-buffer nntp-server-buffer)
 435   (erase-buffer)
 436   (condition-case ()
 437       (let ((coding-system-for-read nnspool-file-coding-system))
 438         (mm-insert-file-contents file)
 439         t)
 440     (file-error nil)))
 441
 442 (defun nnspool-possibly-change-directory (group)
 443   (if (not group)
 444       t
 445     (let ((pathname (nnspool-article-pathname group)))
 446       (if (file-directory-p pathname)
 447           (setq nnspool-current-directory pathname
 448                 nnspool-current-group group)
 449         (nnheader-report 'nnspool "No such newsgroup: %s" group)))))
 450
 451 (defun nnspool-article-pathname (group &optional article)
 452   "Find the file name for GROUP."
 453   (nnheader-group-pathname group nnspool-spool-directory article))
 454
 455 (provide 'nnspool)
 456
 457 ;;; nnspool.el ends here