lisp/emacs-lisp/shadow.el

   1 ;;; shadow.el --- locate Emacs Lisp file shadowings
   2
   3 ;; Copyright (C) 1995, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
   4 ;;   2009, 2010, 2011  Free Software Foundation, Inc.
   5
   6 ;; Author: Terry Jones <terry@santafe.edu>
   7 ;; Keywords: lisp
   8 ;; Created: 15 December 1995
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; The functions in this file detect (`load-path-shadows-find')
  28 ;; and display (`list-load-path-shadows') potential load-path
  29 ;; problems that arise when Emacs Lisp files "shadow" each other.
  30 ;;
  31 ;; For example, a file XXX.el early in one's load-path will shadow
  32 ;; a file with the same name in a later load-path directory.  When
  33 ;; this is unintentional, it may result in problems that could have
  34 ;; been easily avoided.  This occurs often (to me) when installing a
  35 ;; new version of emacs and something in the site-lisp directory
  36 ;; has been updated and added to the emacs distribution.  The old
  37 ;; version, now outdated, shadows the new one. This is obviously
  38 ;; undesirable.
  39 ;;
  40 ;; The `list-load-path-shadows' function was run when you installed
  41 ;; this version of emacs. To run it by hand in emacs:
  42 ;;
  43 ;;     M-x list-load-path-shadows
  44 ;;
  45 ;; or run it non-interactively via:
  46 ;;
  47 ;;     emacs -batch -f list-load-path-shadows
  48 ;;
  49 ;; Thanks to Francesco Potorti` <pot@cnuce.cnr.it> for suggestions,
  50 ;; rewritings & speedups.
  51
  52 ;;; Code:
  53 \f
  54 (defgroup lisp-shadow nil
  55   "Locate Emacs Lisp file shadowings."
  56   :prefix "load-path-shadows-"
  57   :group 'lisp)
  58
  59 (define-obsolete-variable-alias 'shadows-compare-text-p
  60   'load-path-shadows-compare-text "23.3")
  61
  62 (defcustom load-path-shadows-compare-text nil
  63   "If non-nil, then shadowing files are reported only if their text differs.
  64 This is slower, but filters out some innocuous shadowing."
  65   :type 'boolean
  66   :group 'lisp-shadow)
  67
  68 (defun load-path-shadows-find (&optional path)
  69   "Return a list of Emacs Lisp files that create shadows.
  70 This function does the work for `list-load-path-shadows'.
  71
  72 We traverse PATH looking for shadows, and return a \(possibly empty\)
  73 even-length list of files.  A file in this list at position 2i shadows
  74 the file in position 2i+1.  Emacs Lisp file suffixes \(.el and .elc\)
  75 are stripped from the file names in the list.
  76
  77 See the documentation for `list-load-path-shadows' for further information."
  78   (let (true-names                      ; List of dirs considered.
  79         shadows                         ; List of shadowings, to be returned.
  80         files                           ; File names ever seen, with dirs.
  81         dir                             ; The dir being currently scanned.
  82         curr-files                      ; This dir's Emacs Lisp files.
  83         orig-dir                        ; Where the file was first seen.
  84         files-seen-this-dir             ; Files seen so far in this dir.
  85         file)                           ; The current file.
  86     (dolist (pp (or path load-path))
  87       (setq dir (directory-file-name (file-truename (or pp "."))))
  88       (if (member dir true-names)
  89           ;; We have already considered this PATH redundant directory.
  90           ;; Show the redundancy if we are interactive, unless the PATH
  91           ;; dir is nil or "." (these redundant directories are just a
  92           ;; result of the current working directory, and are therefore
  93           ;; not always redundant).
  94           (or noninteractive
  95               (and pp
  96                    (not (string= pp "."))
  97                    (message "Ignoring redundant directory %s" pp)))
  98
  99         (setq true-names (append true-names (list dir)))
 100         (setq dir (directory-file-name (or pp ".")))
 101         (setq curr-files (if (file-accessible-directory-p dir)
 102                              (directory-files dir nil ".\\.elc?\\(\\.gz\\)?$" t)))
 103         (and curr-files
 104              (not noninteractive)
 105              (message "Checking %d files in %s..." (length curr-files) dir))
 106
 107         (setq files-seen-this-dir nil)
 108
 109         (dolist (file curr-files)
 110
 111           (if (string-match "\\.gz$" file)
 112               (setq file (substring file 0 -3)))
 113           (setq file (substring
 114                       file 0 (if (string= (substring file -1) "c") -4 -3)))
 115
 116           ;; FILE now contains the current file name, with no suffix.
 117           (unless (or (member file files-seen-this-dir)
 118                       ;; Ignore these files.
 119                       (member file '("subdirs")))
 120             ;; File has not been seen yet in this directory.
 121             ;; This test prevents us declaring that XXX.el shadows
 122             ;; XXX.elc (or vice-versa) when they are in the same directory.
 123             (setq files-seen-this-dir (cons file files-seen-this-dir))
 124
 125             (if (setq orig-dir (assoc file files))
 126                 ;; This file was seen before, we have a shadowing.
 127                 ;; Report it unless the files are identical.
 128                 (let ((base1 (concat (cdr orig-dir) "/" file))
 129                       (base2 (concat dir "/" file)))
 130                   (if (not (and load-path-shadows-compare-text
 131                                 (load-path-shadows-same-file-or-nonexistent
 132                                  (concat base1 ".el") (concat base2 ".el"))
 133                                 ;; This is a bit strict, but safe.
 134                                 (load-path-shadows-same-file-or-nonexistent
 135                                  (concat base1 ".elc") (concat base2 ".elc"))))
 136                       (setq shadows
 137                             (append shadows (list base1 base2)))))
 138
 139               ;; Not seen before, add it to the list of seen files.
 140               (setq files (cons (cons file dir) files)))))))
 141     ;; Return the list of shadowings.
 142     shadows))
 143
 144 (define-obsolete-function-alias 'find-emacs-lisp-shadows
 145   'load-path-shadows-find "23.3")
 146
 147 ;; Return true if neither file exists, or if both exist and have identical
 148 ;; contents.
 149 (defun load-path-shadows-same-file-or-nonexistent (f1 f2)
 150   (let ((exists1 (file-exists-p f1))
 151         (exists2 (file-exists-p f2)))
 152     (or (and (not exists1) (not exists2))
 153         (and exists1 exists2
 154              (or (equal (file-truename f1) (file-truename f2))
 155                  ;; As a quick test, avoiding spawning a process, compare file
 156                  ;; sizes.
 157                  (and (= (nth 7 (file-attributes f1))
 158                          (nth 7 (file-attributes f2)))
 159                       (eq 0 (call-process "cmp" nil nil nil "-s" f1 f2))))))))
 160
 161 (defvar load-path-shadows-font-lock-keywords
 162   `((,(format "hides \\(%s.*\\)"
 163               (file-name-directory (locate-library "simple.el")))
 164      . (1 font-lock-warning-face)))
 165   "Keywords to highlight in `load-path-shadows-mode'.")
 166
 167 (define-derived-mode load-path-shadows-mode fundamental-mode "LP-Shadows"
 168   "Major mode for load-path shadows buffer."
 169   (set (make-local-variable 'font-lock-defaults)
 170        '((load-path-shadows-font-lock-keywords)))
 171   (setq buffer-undo-list t
 172         buffer-read-only t))
 173
 174 ;; TODO use text-properties instead, a la dired.
 175 (require 'button)
 176 (define-button-type 'load-path-shadows-find-file
 177   'follow-link t
 178 ;;  'face 'default
 179   'action (lambda (button)
 180             (let ((file (concat (button-get button 'shadow-file) ".el")))
 181               (or (file-exists-p file)
 182                   (setq file (concat file ".gz")))
 183               (if (file-readable-p file)
 184                   (pop-to-buffer (find-file-noselect file))
 185                 (error "Cannot read file"))))
 186   'help-echo "mouse-2, RET: find this file")
 187
 188 \f
 189 ;;;###autoload
 190 (defun list-load-path-shadows (&optional stringp)
 191   "Display a list of Emacs Lisp files that shadow other files.
 192
 193 If STRINGP is non-nil, returns any shadows as a string.
 194 Otherwise, if interactive shows any shadows in a `*Shadows*' buffer;
 195 else prints messages listing any shadows.
 196
 197 This function lists potential load path problems.  Directories in
 198 the `load-path' variable are searched, in order, for Emacs Lisp
 199 files.  When a previously encountered file name is found again, a
 200 message is displayed indicating that the later file is \"hidden\" by
 201 the earlier.
 202
 203 For example, suppose `load-path' is set to
 204
 205 \(\"/usr/gnu/emacs/site-lisp\" \"/usr/gnu/emacs/share/emacs/19.30/lisp\"\)
 206
 207 and that each of these directories contains a file called XXX.el.  Then
 208 XXX.el in the site-lisp directory is referred to by all of:
 209 \(require 'XXX\), \(autoload .... \"XXX\"\), \(load-library \"XXX\"\) etc.
 210
 211 The first XXX.el file prevents Emacs from seeing the second \(unless
 212 the second is loaded explicitly via `load-file'\).
 213
 214 When not intended, such shadowings can be the source of subtle
 215 problems.  For example, the above situation may have arisen because the
 216 XXX package was not distributed with versions of Emacs prior to
 217 19.30.  An Emacs maintainer downloaded XXX from elsewhere and installed
 218 it.  Later, XXX was updated and included in the Emacs distribution.
 219 Unless the Emacs maintainer checks for this, the new version of XXX
 220 will be hidden behind the old \(which may no longer work with the new
 221 Emacs version\).
 222
 223 This function performs these checks and flags all possible
 224 shadowings.  Because a .el file may exist without a corresponding .elc
 225 \(or vice-versa\), these suffixes are essentially ignored.  A file
 226 XXX.elc in an early directory \(that does not contain XXX.el\) is
 227 considered to shadow a later file XXX.el, and vice-versa.
 228
 229 Shadowings are located by calling the (non-interactive) companion
 230 function, `load-path-shadows-find'."
 231   (interactive)
 232   (let* ((path (copy-sequence load-path))
 233         (tem path)
 234         toplevs)
 235     ;; If we can find simple.el in two places,
 236     (dolist (tt tem)
 237       (if (or (file-exists-p (expand-file-name "simple.el" tt))
 238               (file-exists-p (expand-file-name "simple.el.gz" tt)))
 239           (setq toplevs (cons tt toplevs))))
 240     (if (> (length toplevs) 1)
 241         ;; Cut off our copy of load-path right before
 242         ;; the last directory which has simple.el in it.
 243         ;; This avoids loads of duplications between the source dir
 244         ;; and the dir where these files were copied by installation.
 245         (let ((break (car toplevs)))
 246           (setq tem path)
 247           (while tem
 248             (if (eq (nth 1 tem) break)
 249                 (progn
 250                   (setcdr tem nil)
 251                   (setq tem nil)))
 252             (setq tem (cdr tem)))))
 253
 254     (let* ((shadows (load-path-shadows-find path))
 255            (n (/ (length shadows) 2))
 256            (msg (format "%s Emacs Lisp load-path shadowing%s found"
 257                         (if (zerop n) "No" (concat "\n" (number-to-string n)))
 258                         (if (= n 1) " was" "s were"))))
 259       (with-temp-buffer
 260         (while shadows
 261           (insert (format "%s hides %s\n" (car shadows)
 262                           (car (cdr shadows))))
 263           (setq shadows (cdr (cdr shadows))))
 264         (if stringp
 265             (buffer-string)
 266           (if (called-interactively-p 'interactive)
 267               ;; We are interactive.
 268               ;; Create the *Shadows* buffer and display shadowings there.
 269               (let ((string (buffer-string)))
 270                 (with-current-buffer (get-buffer-create "*Shadows*")
 271                   (display-buffer (current-buffer))
 272                   (load-path-shadows-mode) ; run after-change-major-mode-hook
 273                   (let ((inhibit-read-only t))
 274                     (erase-buffer)
 275                     (insert string)
 276                     (insert msg "\n")
 277                     (while (re-search-backward "\\(^.*\\) hides \\(.*$\\)"
 278                                                nil t)
 279                       (dotimes (i 2)
 280                         (make-button (match-beginning (1+ i))
 281                                      (match-end (1+ i))
 282                                      'type 'load-path-shadows-find-file
 283                                      'shadow-file
 284                                      (match-string (1+ i)))))
 285                     (goto-char (point-max)))))
 286             ;; We are non-interactive, print shadows via message.
 287             (unless (zerop n)
 288               (message "This site has duplicate Lisp libraries with the same name.
 289 If a locally-installed Lisp library overrides a library in the Emacs release,
 290 that can cause trouble, and you should probably remove the locally-installed
 291 version unless you know what you are doing.\n")
 292               (goto-char (point-min))
 293               ;; Mimic the previous behavior of using lots of messages.
 294               ;; I think one single message would look better...
 295               (while (not (eobp))
 296                 (message "%s" (buffer-substring (line-beginning-position)
 297                                                 (line-end-position)))
 298                 (forward-line 1))
 299               (message "%s" msg))))))))
 300
 301 (provide 'shadow)
 302
 303 ;;; shadow.el ends here