lisp/international/kkc.el

   1 ;;; kkc.el --- Kana Kanji converter
   2
   3 ;; Copyright (C) 1995 Electrotechnical Laboratory, JAPAN.
   4 ;; Licensed to the Free Software Foundation.
   5
   6 ;; Keywords: mule, multilingual, Japanese, SKK
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; These routines provide a simple and easy-to-use converter from
  28 ;; Kana-string to Kana-Kanji-mixed-string.  This converter (here after
  29 ;; KKC) uses a SKK dictionary to get information how to convert
  30 ;; Kana-string.  Since KKC can't be fully automated, we need an
  31 ;; interaction with a user to decide the correct conversion.   For
  32 ;; that, we provide KKC major mode.
  33
  34 ;;; Code:
  35
  36 (require 'skkdic-utl)
  37
  38 (defvar kkc-input-method-title "\e$B4A\e(B"
  39   "String denoting KKC input method.
  40 This string is shown at mode line when users are in KKC mode.")
  41
  42 (defvar kkc-init-file-name "~/.kkcrc"
  43   "Name of a file which contains user's initial setup code for KKC.")
  44
  45 ;; A flag to control a file specified by `kkc-init-file-name'.
  46 ;; The value nil means the file is not yet consulted.
  47 ;; The value t means the file has already been consulted but there's
  48 ;; no need of updating it yet.
  49 ;; Any other value means that we must update the file before exiting Emacs.
  50 (defvar kkc-init-file-flag nil)
  51
  52 ;; Cash data for `kkc-lookup-key'.  This may be initialized by loading
  53 ;; a file specified by `kkc-init-file-name'.  If any elements are
  54 ;; modified, the data is written out to the file when exiting Emacs.
  55 (defvar kkc-lookup-cache nil)
  56
  57 ;; Tag symbol of `kkc-lookup-cache'.
  58 (defconst kkc-lookup-cache-tag 'kkc-lookup-cache-2)
  59
  60 (defun kkc-save-init-file ()
  61   "Save initial setup code for KKC to a file specified by `kkc-init-file-name'"
  62   (if (and kkc-init-file-flag
  63            (not (eq kkc-init-file-flag t)))
  64       (let ((coding-system-for-write 'iso-2022-7bit))
  65         (write-region (format "(setq kkc-lookup-cache '%S)\n" kkc-lookup-cache)
  66                       nil
  67                       kkc-init-file-name))))
  68
  69 ;; Sequence of characters to be used for indexes for shown list.  The
  70 ;; Nth character is for the Nth conversion in the list currently shown.
  71 (defvar kkc-show-conversion-list-index-chars
  72   "1234567890")
  73
  74 (defun kkc-help ()
  75   "Show key bindings available while converting by KKC."
  76   (interactive)
  77   (with-output-to-temp-buffer "*Help*"
  78     (princ (substitute-command-keys "\\{kkc-keymap}"))))
  79
  80 (defvar kkc-keymap
  81   (let ((map (make-sparse-keymap))
  82         (len (length kkc-show-conversion-list-index-chars))
  83         (i 0))
  84     (while (< i len)
  85       (define-key map
  86         (char-to-string (aref kkc-show-conversion-list-index-chars i))
  87         'kkc-select-from-list)
  88       (setq i (1+ i)))
  89     (define-key map " " 'kkc-next)
  90     (define-key map "\r" 'kkc-terminate)
  91     (define-key map "\C-@" 'kkc-first-char-only)
  92     (define-key map "\C-n" 'kkc-next)
  93     (define-key map "\C-p" 'kkc-prev)
  94     (define-key map "\C-i" 'kkc-shorter)
  95     (define-key map "\C-o" 'kkc-longer)
  96     (define-key map "I" 'kkc-shorter-conversion)
  97     (define-key map "O" 'kkc-longer-phrase)
  98     (define-key map "\C-c" 'kkc-cancel)
  99     (define-key map "\C-?" 'kkc-cancel)
 100     (define-key map "\C-f" 'kkc-next-phrase)
 101     (define-key map "K" 'kkc-katakana)
 102     (define-key map "H" 'kkc-hiragana)
 103     (define-key map "l" 'kkc-show-conversion-list-or-next-group)
 104     (define-key map "L" 'kkc-show-conversion-list-or-prev-group)
 105     (define-key map [?\C- ] 'kkc-first-char-only)
 106     (define-key map [delete] 'kkc-cancel)
 107     (define-key map [return] 'kkc-terminate)
 108     (define-key map "\C-h" 'kkc-help)
 109     map)
 110   "Keymap for KKC (Kana Kanji Converter).")
 111
 112 ;;; Internal variables used in KKC.
 113
 114 ;; The current Kana string to be converted.
 115 (defvar kkc-original-kana nil)
 116
 117 ;; The current key sequence (vector of Kana characters) generated from
 118 ;; `kkc-original-kana'.
 119 (defvar kkc-current-key nil)
 120
 121 ;; List of the current conversions for `kkc-current-key'.
 122 (defvar kkc-current-conversions nil)
 123
 124 ;; Vector of the same length as `kkc-current-conversion'.  The first
 125 ;; element is a vector of:
 126 ;;      o index number of the first conversion shown previously,
 127 ;;      o index number of a conversion next of the last one shown previously,
 128 ;;      o the shown string itself.
 129 ;; The remaining elements are widths (including columns for index
 130 ;; numbers) of conversions stored in the same order as in
 131 ;; `kkc-current-conversion'.
 132 (defvar kkc-current-conversions-width nil)
 133
 134 (defvar kkc-show-conversion-list-count 4
 135   "Count of successive `kkc-next' or `kkc-prev' to show conversion list.")
 136
 137 ;; Provided that `kkc-current-key' is [A B C D E F G H I], the current
 138 ;; conversion target is [A B C D E F], and the sequence of which
 139 ;; conversion is found is [A B C D]:
 140 ;;
 141 ;;                                A B C D E F G H I
 142 ;; kkc-overlay-head (black):     |<--------->|
 143 ;; kkc-overlay-tail (underline):         |<------->|
 144 ;; kkc-length-head:              |<--------->|
 145 ;; kkc-length-converted:         |<----->|
 146 ;;
 147 (defvar kkc-overlay-head nil)
 148 (defvar kkc-overlay-tail nil)
 149 (defvar kkc-length-head nil)
 150 (defvar kkc-length-converted nil)
 151
 152 ;; Cursor type (`box' or `bar') of the current frame.
 153 (defvar kkc-cursor-type nil)
 154
 155 ;; Lookup SKK dictionary to set list of conversions in
 156 ;; kkc-current-conversions for key sequence kkc-current-key of length
 157 ;; LEN.  If no conversion is found in the dictionary, don't change
 158 ;; kkc-current-conversions and return nil.
 159 ;; Postfixes are handled only if POSTFIX is non-nil.
 160 (defun kkc-lookup-key (len &optional postfix prefer-noun)
 161   ;; At first, prepare cache data if any.
 162   (unless kkc-init-file-flag
 163     (setq kkc-init-file-flag t
 164           kkc-lookup-cache nil)
 165     (add-hook 'kill-emacs-hook 'kkc-save-init-file)
 166     (if (file-readable-p kkc-init-file-name)
 167         (condition-case nil
 168             (load-file kkc-init-file-name)
 169           (kkc-error "Invalid data in %s" kkc-init-file-name))))
 170   (or (and (nested-alist-p kkc-lookup-cache)
 171            (eq (car kkc-lookup-cache) kkc-lookup-cache-tag))
 172       (setq kkc-lookup-cache (list kkc-lookup-cache-tag)
 173             kkc-init-file-flag 'kkc-lookup-cache))
 174   (let ((entry (lookup-nested-alist kkc-current-key kkc-lookup-cache len 0 t)))
 175     (if (consp (car entry))
 176         (setq kkc-length-converted len
 177               kkc-current-conversions-width nil
 178               kkc-current-conversions (car entry))
 179       (setq entry (skkdic-lookup-key kkc-current-key len postfix prefer-noun))
 180       (if entry
 181           (progn
 182             (setq kkc-length-converted len
 183                   kkc-current-conversions-width nil
 184                   kkc-current-conversions (cons 1 entry))
 185             (if postfix
 186                 ;; Store this conversions in the cache.
 187                 (progn
 188                   (set-nested-alist kkc-current-key kkc-current-conversions
 189                                     kkc-lookup-cache kkc-length-converted)
 190                   (setq kkc-init-file-flag 'kkc-lookup-cache)))
 191             t)
 192         (if (= len 1)
 193             (setq kkc-length-converted 1
 194                   kkc-current-conversions-width nil
 195                   kkc-current-conversions (cons 0 nil)))))))
 196
 197 (put 'kkc-error 'error-conditions '(kkc-error error))
 198 (defun kkc-error (&rest args)
 199   (signal 'kkc-error (apply 'format args)))
 200
 201 (defvar kkc-converting nil)
 202
 203 ;;;###autoload
 204 (defun kkc-region (from to)
 205   "Convert Kana string in the current region to Kanji-Kana mixed string.
 206 Users can select a desirable conversion interactively.
 207 When called from a program, expects two arguments,
 208 positions FROM and TO (integers or markers) specifying the target region.
 209 When it returns, the point is at the tail of the selected conversion,
 210 and the return value is the length of the conversion."
 211   (interactive "r")
 212   (setq kkc-original-kana (buffer-substring from to))
 213   (goto-char from)
 214
 215   ;; Setup overlays.
 216   (if (overlayp kkc-overlay-head)
 217       (move-overlay kkc-overlay-head from to)
 218     (setq kkc-overlay-head (make-overlay from to nil nil t))
 219     (overlay-put kkc-overlay-head 'face 'highlight))
 220   (if (overlayp kkc-overlay-tail)
 221       (move-overlay kkc-overlay-tail to to)
 222     (setq kkc-overlay-tail (make-overlay to to nil nil t))
 223     (overlay-put kkc-overlay-tail 'face 'underline))
 224
 225   (setq kkc-current-key (string-to-vector kkc-original-kana))
 226   (setq kkc-length-head (length kkc-current-key))
 227   (setq kkc-length-converted 0)
 228
 229   (unwind-protect
 230       ;; At first convert the region to the first candidate.
 231       (let ((current-input-method-title kkc-input-method-title)
 232             (input-method-function nil)
 233             (first t))
 234         (while (not (kkc-lookup-key kkc-length-head nil first))
 235           (setq kkc-length-head (1- kkc-length-head)
 236                 first nil))
 237         (goto-char to)
 238         (kkc-update-conversion 'all)
 239
 240         ;; Then, ask users to select a desirable conversion.
 241         (force-mode-line-update)
 242         (setq kkc-converting t)
 243         (while kkc-converting
 244           (let* ((overriding-terminal-local-map kkc-keymap)
 245                  (help-char nil)
 246                  (keyseq (read-key-sequence nil))
 247                  (cmd (lookup-key kkc-keymap keyseq)))
 248             (if (commandp cmd)
 249                 (condition-case err
 250                     (call-interactively cmd)
 251                   (kkc-error (message "%s" (cdr err)) (beep)))
 252               ;; KEYSEQ is not defined in KKC keymap.
 253               ;; Let's put the event back.
 254               (setq unread-input-method-events
 255                     (append (string-to-list keyseq)
 256                             unread-input-method-events))
 257               (kkc-terminate))))
 258
 259         (force-mode-line-update)
 260         (goto-char (overlay-end kkc-overlay-tail))
 261         (- (overlay-start kkc-overlay-head) from))
 262     (delete-overlay kkc-overlay-head)
 263     (delete-overlay kkc-overlay-tail)))
 264
 265 (defun kkc-terminate ()
 266   "Exit from KKC mode by fixing the current conversion."
 267   (interactive)
 268   (goto-char (overlay-end kkc-overlay-tail))
 269   (move-overlay kkc-overlay-head (point) (point))
 270   (setq kkc-converting nil))
 271
 272 (defun kkc-cancel ()
 273   "Exit from KKC mode by canceling any conversions."
 274   (interactive)
 275   (goto-char (overlay-start kkc-overlay-head))
 276   (delete-region (overlay-start kkc-overlay-head)
 277                  (overlay-end kkc-overlay-tail))
 278   (insert kkc-original-kana)
 279   (setq kkc-converting nil))
 280
 281 (defun kkc-first-char-only ()
 282   "Select only the first character currently converted."
 283   (interactive)
 284   (goto-char (overlay-start kkc-overlay-head))
 285   (forward-char 1)
 286   (delete-region (point) (overlay-end kkc-overlay-tail))
 287   (kkc-terminate))
 288
 289 ;; Count of successive invocations of `kkc-next'.
 290 (defvar kkc-next-count nil)
 291
 292 (defun kkc-next ()
 293   "Select the next candidate of conversion."
 294   (interactive)
 295   (if (eq this-command last-command)
 296       (setq kkc-next-count (1+ kkc-next-count))
 297     (setq kkc-next-count 1))
 298   (let ((idx (1+ (car kkc-current-conversions))))
 299     (if (< idx 0)
 300         (setq idx 1))
 301     (if (>= idx (length kkc-current-conversions))
 302         (setq idx 0))
 303     (setcar kkc-current-conversions idx)
 304     (if (> idx 1)
 305         (progn
 306           (set-nested-alist kkc-current-key kkc-current-conversions
 307                             kkc-lookup-cache kkc-length-converted)
 308           (setq kkc-init-file-flag 'kkc-lookup-cache)))
 309     (if (or kkc-current-conversions-width
 310             (>= kkc-next-count kkc-show-conversion-list-count))
 311         (kkc-show-conversion-list-update))
 312     (kkc-update-conversion)))
 313
 314 ;; Count of successive invocations of `kkc-next'.
 315 (defvar kkc-prev-count nil)
 316
 317 (defun kkc-prev ()
 318   "Select the previous candidate of conversion."
 319   (interactive)
 320   (if (eq this-command last-command)
 321       (setq kkc-prev-count (1+ kkc-prev-count))
 322     (setq kkc-prev-count 1))
 323   (let ((idx (1- (car kkc-current-conversions))))
 324     (if (< idx 0)
 325         (setq idx (1- (length kkc-current-conversions))))
 326     (setcar kkc-current-conversions idx)
 327     (if (> idx 1)
 328         (progn
 329           (set-nested-alist kkc-current-key kkc-current-conversions
 330                             kkc-lookup-cache kkc-length-converted)
 331           (setq kkc-init-file-flag 'kkc-lookup-cache)))
 332     (if (or kkc-current-conversions-width
 333             (>= kkc-prev-count kkc-show-conversion-list-count))
 334         (kkc-show-conversion-list-update))
 335     (kkc-update-conversion)))
 336
 337 (defun kkc-select-from-list ()
 338   "Select one candidate from the list currently shown in echo area."
 339   (interactive)
 340   (let (idx)
 341     (if kkc-current-conversions-width
 342         (let ((len (length kkc-show-conversion-list-index-chars))
 343               (maxlen (- (aref (aref kkc-current-conversions-width 0) 1)
 344                          (aref (aref kkc-current-conversions-width 0) 0)))
 345               (i 0))
 346           (if (> len maxlen)
 347               (setq len maxlen))
 348           (while (< i len)
 349             (if (= (aref kkc-show-conversion-list-index-chars i)
 350                    last-input-event)
 351                 (setq idx i i len)
 352               (setq i (1+ i))))))
 353     (if idx
 354         (progn
 355           (setcar kkc-current-conversions
 356                   (+ (aref (aref kkc-current-conversions-width 0) 0) idx))
 357           (kkc-show-conversion-list-update)
 358           (kkc-update-conversion))
 359       (setq unread-input-method-events
 360             (cons last-input-event unread-input-method-events))
 361       (kkc-terminate))))
 362
 363 (defun kkc-katakana ()
 364   "Convert to Katakana."
 365   (interactive)
 366   (setcar kkc-current-conversions -1)
 367   (kkc-update-conversion 'all))
 368
 369 (defun kkc-hiragana ()
 370   "Convert to hiragana."
 371   (interactive)
 372   (setcar kkc-current-conversions 0)
 373   (kkc-update-conversion))
 374
 375 (defun kkc-shorter ()
 376   "Make the Kana string to be converted shorter."
 377   (interactive)
 378   (if (<= kkc-length-head 1)
 379       (kkc-error "Can't be shorter"))
 380   (setq kkc-length-head (1- kkc-length-head))
 381   (if (> kkc-length-converted kkc-length-head)
 382       (let ((len kkc-length-head))
 383         (setq kkc-length-converted 0)
 384         (while (not (kkc-lookup-key len))
 385           (setq len (1- len)))))
 386   (kkc-update-conversion 'all))
 387
 388 (defun kkc-longer ()
 389   "Make the Kana string to be converted longer."
 390   (interactive)
 391   (if (>= kkc-length-head (length kkc-current-key))
 392       (kkc-error "Can't be longer"))
 393   (setq kkc-length-head (1+ kkc-length-head))
 394   ;; This time, try also entries with postfixes.
 395   (kkc-lookup-key kkc-length-head 'postfix)
 396   (kkc-update-conversion 'all))
 397
 398 (defun kkc-shorter-conversion ()
 399   "Make the Kana string to be converted shorter."
 400   (interactive)
 401   (if (<= kkc-length-converted 1)
 402       (kkc-error "Can't be shorter"))
 403   (let ((len (1- kkc-length-converted)))
 404     (setq kkc-length-converted 0)
 405     (while (not (kkc-lookup-key len))
 406       (setq len (1- len))))
 407   (kkc-update-conversion 'all))
 408
 409 (defun kkc-longer-phrase ()
 410   "Make the current phrase (BUNSETSU) longer without looking up dictionary."
 411   (interactive)
 412   (if (>= kkc-length-head (length kkc-current-key))
 413       (kkc-error "Can't be longer"))
 414   (setq kkc-length-head (1+ kkc-length-head))
 415   (kkc-update-conversion 'all))
 416
 417 (defun kkc-next-phrase ()
 418   "Fix the currently converted string and try to convert the remaining string."
 419   (interactive)
 420   (if (>= kkc-length-head (length kkc-current-key))
 421       (kkc-terminate)
 422     (setq kkc-length-head (- (length kkc-current-key) kkc-length-head))
 423     (goto-char (overlay-end kkc-overlay-head))
 424     (while (and (< (point) (overlay-end kkc-overlay-tail))
 425                 (looking-at "\\CH"))
 426       (goto-char (match-end 0))
 427       (setq kkc-length-head (1- kkc-length-head)))
 428     (if (= kkc-length-head 0)
 429         (kkc-terminate)
 430       (let ((newkey (make-vector kkc-length-head 0))
 431             (idx (- (length kkc-current-key) kkc-length-head))
 432             (len kkc-length-head)
 433             (i 0))
 434         ;; For the moment, (setq kkc-original-kana (concat newkey))
 435         ;; doesn't work.
 436         (setq kkc-original-kana "")
 437         (while (< i kkc-length-head)
 438           (aset newkey i (aref kkc-current-key (+ idx i)))
 439           (setq kkc-original-kana
 440                 (concat kkc-original-kana (char-to-string (aref newkey i))))
 441           (setq i (1+ i)))
 442         (setq kkc-current-key newkey)
 443         (setq kkc-length-converted 0)
 444         (while (and (not (kkc-lookup-key kkc-length-head nil
 445                                          (< kkc-length-head len)))
 446                     (> kkc-length-head 1))
 447           (setq kkc-length-head (1- kkc-length-head)))
 448         (let ((pos (point))
 449               (tail (overlay-end kkc-overlay-tail)))
 450           (move-overlay kkc-overlay-head pos tail)
 451           (move-overlay kkc-overlay-tail tail tail))
 452         (kkc-update-conversion 'all)))))
 453
 454 ;; We'll show users a list of available conversions in echo area with
 455 ;; index numbers so that users can select one conversion with the
 456 ;; number.
 457
 458 ;; Set `kkc-current-conversions-width'.
 459 (defun kkc-setup-current-conversions-width ()
 460   (let ((convs (cdr kkc-current-conversions))
 461         (len (length kkc-current-conversions))
 462         (idx 1))
 463     (setq kkc-current-conversions-width (make-vector len nil))
 464     ;; To tell `kkc-show-conversion-list-update' to generate
 465     ;; message from scratch.
 466     (aset kkc-current-conversions-width 0 (vector len -2 nil))
 467     ;; Fill the remaining slots.
 468     (while convs
 469       (aset kkc-current-conversions-width idx
 470             (+ (string-width (car convs)) 4))
 471       (setq convs (cdr convs)
 472             idx (1+ idx)))))
 473
 474 (defun kkc-show-conversion-list-or-next-group ()
 475   "Show list of available conversions in echo area with index numbers.
 476 If the list is already shown, show the next group of conversions,
 477 and change the current conversion to the first one in the group."
 478   (interactive)
 479   (if (< (length kkc-current-conversions) 3)
 480       (kkc-error "No alternative"))
 481   (if kkc-current-conversions-width
 482       (let ((next-idx (aref (aref kkc-current-conversions-width 0) 1)))
 483         (if (< next-idx (length kkc-current-conversions-width))
 484             (setcar kkc-current-conversions next-idx)
 485           (setcar kkc-current-conversions 1))
 486         (kkc-show-conversion-list-update)
 487         (kkc-update-conversion))
 488     (kkc-setup-current-conversions-width)
 489     (kkc-show-conversion-list-update)))
 490
 491 (defun kkc-show-conversion-list-or-prev-group ()
 492   "Show list of available conversions in echo area with index numbers.
 493 If the list is already shown, show the previous group of conversions,
 494 and change the current conversion to the last one in the group."
 495   (interactive)
 496   (if (< (length kkc-current-conversions) 3)
 497       (kkc-error "No alternative"))
 498   (if kkc-current-conversions-width
 499       (let ((this-idx (aref (aref kkc-current-conversions-width 0) 0)))
 500         (if (> this-idx 1)
 501             (setcar kkc-current-conversions (1- this-idx))
 502           (setcar kkc-current-conversions
 503                   (1- (length kkc-current-conversions-width))))
 504         (kkc-show-conversion-list-update)
 505         (kkc-update-conversion))
 506     (kkc-setup-current-conversions-width)
 507     (kkc-show-conversion-list-update)))
 508
 509 ;; Update the conversion list shown in echo area.
 510 (defun kkc-show-conversion-list-update ()
 511   (or kkc-current-conversions-width
 512       (kkc-setup-current-conversions-width))
 513   (let* ((current-idx (car kkc-current-conversions))
 514          (first-slot (aref kkc-current-conversions-width 0))
 515          (this-idx (aref first-slot 0))
 516          (next-idx (aref first-slot 1))
 517          (msg (aref first-slot 2)))
 518     (if (< current-idx this-idx)
 519         ;; The currently selected conversion is before the list shown
 520         ;; previously.  We must start calculation of message width
 521         ;; from the start again.
 522         (setq this-idx 1 msg nil)
 523       (if (>= current-idx next-idx)
 524           ;; The currently selected conversion is after the list shown
 525           ;; previously.  We start calculation of message width from
 526           ;; the conversion next of TO.
 527           (setq this-idx next-idx msg nil)
 528         ;; The current conversion is in MSG.  Just clear brackets
 529         ;; around index number.
 530         (if (string-match "<.>" msg)
 531             (progn
 532               (aset msg (match-beginning 0) ?\ )
 533               (aset msg (1- (match-end 0)) ?\ )))))
 534     (if (not msg)
 535         (let ((len (length kkc-current-conversions))
 536               (max-width (window-width (minibuffer-window)))
 537               (width-table kkc-current-conversions-width)
 538               (width 0)
 539               (idx this-idx)
 540               (max-items (length kkc-show-conversion-list-index-chars))
 541               l)
 542           (while (< idx current-idx)
 543             (if (and (<= (+ width (aref width-table idx)) max-width)
 544                      (< (- idx this-idx) max-items))
 545                 (setq width (+ width (aref width-table idx)))
 546               (setq this-idx idx width (aref width-table idx)))
 547             (setq idx (1+ idx)
 548                   l (cdr l)))
 549           (aset first-slot 0 this-idx)
 550           (while (and (< idx len)
 551                       (<= (+ width (aref width-table idx)) max-width)
 552                       (< (- idx this-idx) max-items))
 553             (setq width (+ width (aref width-table idx))
 554                   idx (1+ idx)
 555                   l (cdr l)))
 556           (aset first-slot 1 (setq next-idx idx))
 557           (setq l (nthcdr this-idx kkc-current-conversions))
 558           (setq msg "")
 559           (setq idx this-idx)
 560           (while (< idx next-idx)
 561             (setq msg (format "%s %c %s "
 562                               msg
 563                               (aref kkc-show-conversion-list-index-chars
 564                                     (- idx this-idx))
 565                               (car l)))
 566             (setq idx (1+ idx)
 567                   l (cdr l)))
 568           (aset first-slot 2 msg)))
 569     (if (> current-idx 0)
 570         (progn
 571           ;; Highlight the current conversion by brackets.
 572           (string-match (format " \\(%c\\) "
 573                                 (aref kkc-show-conversion-list-index-chars
 574                                       (- current-idx this-idx)))
 575                         msg)
 576           (aset msg (match-beginning 0) ?<)
 577           (aset msg (1- (match-end 0)) ?>)))
 578     (message "%s" msg)))
 579
 580 ;; Update the conversion area with the latest conversion selected.
 581 ;; ALL if non nil means to update the whole area, else update only
 582 ;; inside quail-overlay-head.
 583
 584 (defun kkc-update-conversion (&optional all)
 585   (goto-char (overlay-start kkc-overlay-head))
 586   (cond ((= (car kkc-current-conversions) 0) ; Hiragana
 587          (let ((i 0))
 588            (while (< i kkc-length-converted)
 589              (insert (aref kkc-current-key i))
 590              (setq i (1+ i)))))
 591         ((= (car kkc-current-conversions) -1) ; Katakana
 592          (let ((i 0))
 593            (while (< i kkc-length-converted)
 594              (insert (japanese-katakana (aref kkc-current-key i)))
 595              (setq i (1+ i)))))
 596         (t
 597          (insert (nth (car kkc-current-conversions) kkc-current-conversions))))
 598   (delete-region (point) (overlay-start kkc-overlay-tail))
 599   (if all
 600       (let ((len (length kkc-current-key))
 601             (i kkc-length-converted))
 602         (delete-region (overlay-start kkc-overlay-tail)
 603                        (overlay-end kkc-overlay-head))
 604         (while (< i kkc-length-head)
 605           (if (= (car kkc-current-conversions) -1)
 606               (insert (japanese-katakana (aref kkc-current-key i)))
 607             (insert (aref kkc-current-key i)))
 608           (setq i (1+ i)))
 609         (let ((pos (point)))
 610           (while (< i len)
 611             (insert (aref kkc-current-key i))
 612             (setq i (1+ i)))
 613           (move-overlay kkc-overlay-head
 614                         (overlay-start kkc-overlay-head) pos)
 615           (delete-region (point) (overlay-end kkc-overlay-tail)))))
 616   (goto-char (overlay-end kkc-overlay-tail)))
 617
 618 ;;
 619 (provide 'kkc)
 620
 621 ;; kkc.el ends here