lisp/replace.el

   1 ;;; replace.el --- replace commands for Emacs.
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992, 1994, 1996 Free Software Foundation, Inc.
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;; This package supplies the string and regular-expression replace functions
  25 ;; documented in the Emacs user's manual.
  26
  27 ;;; Code:
  28
  29 (defvar case-replace t "\
  30 *Non-nil means query-replace should preserve case in replacements.")
  31
  32 (defvar query-replace-history nil)
  33
  34 (defvar query-replace-interactive nil
  35   "Non-nil means `query-replace' uses the last search string.
  36 That becomes the \"string to replace\".")
  37
  38 (defun query-replace-read-args (string regexp-flag)
  39   (let (from to)
  40     (if query-replace-interactive
  41         (setq from (car (if regexp-flag regexp-search-ring search-ring)))
  42       (setq from (read-from-minibuffer (format "%s: " string)
  43                                        nil nil nil
  44                                        'query-replace-history)))
  45     (setq to (read-from-minibuffer (format "%s %s with: " string from)
  46                                    nil nil nil
  47                                    'query-replace-history))
  48     (list from to current-prefix-arg)))
  49
  50 (defun query-replace (from-string to-string &optional arg)
  51   "Replace some occurrences of FROM-STRING with TO-STRING.
  52 As each match is found, the user must type a character saying
  53 what to do with it.  For directions, type \\[help-command] at that time.
  54
  55 If `query-replace-interactive' is non-nil, the last incremental search
  56 string is used as FROM-STRING--you don't have to specify it with the
  57 minibuffer.
  58
  59 Preserves case in each replacement if `case-replace' and `case-fold-search'
  60 are non-nil and FROM-STRING has no uppercase letters.
  61 \(Preserving case means that if the string matched is all caps, or capitalized,
  62 then its replacement is upcased or capitalized.)
  63
  64 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
  65 only matches surrounded by word boundaries.
  66
  67 To customize possible responses, change the \"bindings\" in `query-replace-map'."
  68   (interactive (query-replace-read-args "Query replace" nil))
  69   (perform-replace from-string to-string t nil arg))
  70 (define-key esc-map "%" 'query-replace)
  71
  72 (defun query-replace-regexp (regexp to-string &optional arg)
  73   "Replace some things after point matching REGEXP with TO-STRING.
  74 As each match is found, the user must type a character saying
  75 what to do with it.  For directions, type \\[help-command] at that time.
  76
  77 If `query-replace-interactive' is non-nil, the last incremental search
  78 regexp is used as REGEXP--you don't have to specify it with the
  79 minibuffer.
  80
  81 Preserves case in each replacement if `case-replace' and `case-fold-search'
  82 are non-nil and REGEXP has no uppercase letters.
  83 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
  84 only matches surrounded by word boundaries.
  85 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
  86 and `\\=\\N' (where N is a digit) stands for
  87  whatever what matched the Nth `\\(...\\)' in REGEXP."
  88   (interactive (query-replace-read-args "Query replace regexp" t))
  89   (perform-replace regexp to-string t t arg))
  90
  91 (defun map-query-replace-regexp (regexp to-strings &optional arg)
  92   "Replace some matches for REGEXP with various strings, in rotation.
  93 The second argument TO-STRINGS contains the replacement strings, separated
  94 by spaces.  This command works like `query-replace-regexp' except
  95 that each successive replacement uses the next successive replacement string,
  96 wrapping around from the last such string to the first.
  97
  98 Non-interactively, TO-STRINGS may be a list of replacement strings.
  99
 100 If `query-replace-interactive' is non-nil, the last incremental search
 101 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 102
 103 A prefix argument N says to use each replacement string N times
 104 before rotating to the next."
 105   (interactive
 106    (let (from to)
 107      (setq from (if query-replace-interactive
 108                     (car regexp-search-ring)
 109                   (read-from-minibuffer "Map query replace (regexp): "
 110                                         nil nil nil
 111                                         'query-replace-history)))
 112      (setq to (read-from-minibuffer
 113                (format "Query replace %s with (space-separated strings): "
 114                        from)
 115                nil nil nil
 116                'query-replace-history))
 117      (list from to current-prefix-arg)))
 118   (let (replacements)
 119     (if (listp to-strings)
 120         (setq replacements to-strings)
 121       (while (/= (length to-strings) 0)
 122         (if (string-match " " to-strings)
 123             (setq replacements
 124                   (append replacements
 125                           (list (substring to-strings 0
 126                                            (string-match " " to-strings))))
 127                   to-strings (substring to-strings
 128                                        (1+ (string-match " " to-strings))))
 129           (setq replacements (append replacements (list to-strings))
 130                 to-strings ""))))
 131     (perform-replace regexp replacements t t nil arg)))
 132
 133 (defun replace-string (from-string to-string &optional delimited)
 134   "Replace occurrences of FROM-STRING with TO-STRING.
 135 Preserve case in each match if `case-replace' and `case-fold-search'
 136 are non-nil and FROM-STRING has no uppercase letters.
 137 \(Preserving case means that if the string matched is all caps, or capitalized,
 138 then its replacement is upcased or capitalized.)
 139
 140 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 141 only matches surrounded by word boundaries.
 142
 143 If `query-replace-interactive' is non-nil, the last incremental search
 144 string is used as FROM-STRING--you don't have to specify it with the
 145 minibuffer.
 146
 147 This function is usually the wrong thing to use in a Lisp program.
 148 What you probably want is a loop like this:
 149   (while (search-forward FROM-STRING nil t)
 150     (replace-match TO-STRING nil t))
 151 which will run faster and will not set the mark or print anything."
 152   (interactive (query-replace-read-args "Replace string" nil))
 153   (perform-replace from-string to-string nil nil delimited))
 154
 155 (defun replace-regexp (regexp to-string &optional delimited)
 156   "Replace things after point matching REGEXP with TO-STRING.
 157 Preserve case in each match if `case-replace' and `case-fold-search'
 158 are non-nil and REGEXP has no uppercase letters.
 159 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 160 only matches surrounded by word boundaries.
 161 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 162 and `\\=\\N' (where N is a digit) stands for
 163  whatever what matched the Nth `\\(...\\)' in REGEXP.
 164
 165 If `query-replace-interactive' is non-nil, the last incremental search
 166 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 167
 168 This function is usually the wrong thing to use in a Lisp program.
 169 What you probably want is a loop like this:
 170   (while (re-search-forward REGEXP nil t)
 171     (replace-match TO-STRING nil nil))
 172 which will run faster and will not set the mark or print anything."
 173   (interactive (query-replace-read-args "Replace regexp" t))
 174   (perform-replace regexp to-string nil t delimited))
 175 \f
 176 (defvar regexp-history nil
 177   "History list for some commands that read regular expressions.")
 178
 179 (defalias 'delete-non-matching-lines 'keep-lines)
 180 (defun keep-lines (regexp)
 181   "Delete all lines except those containing matches for REGEXP.
 182 A match split across lines preserves all the lines it lies in.
 183 Applies to all lines after point."
 184   (interactive (list (read-from-minibuffer
 185                       "Keep lines (containing match for regexp): "
 186                       nil nil nil 'regexp-history)))
 187   (save-excursion
 188     (or (bolp) (forward-line 1))
 189     (let ((start (point)))
 190       (while (not (eobp))
 191         ;; Start is first char not preserved by previous match.
 192         (if (not (re-search-forward regexp nil 'move))
 193             (delete-region start (point-max))
 194           (let ((end (save-excursion (goto-char (match-beginning 0))
 195                                      (beginning-of-line)
 196                                      (point))))
 197             ;; Now end is first char preserved by the new match.
 198             (if (< start end)
 199                 (delete-region start end))))
 200         (setq start (save-excursion (forward-line 1)
 201                                     (point)))
 202         ;; If the match was empty, avoid matching again at same place.
 203         (and (not (eobp)) (= (match-beginning 0) (match-end 0))
 204              (forward-char 1))))))
 205
 206 (defalias 'delete-matching-lines 'flush-lines)
 207 (defun flush-lines (regexp)
 208   "Delete lines containing matches for REGEXP.
 209 If a match is split across lines, all the lines it lies in are deleted.
 210 Applies to lines after point."
 211   (interactive (list (read-from-minibuffer
 212                       "Flush lines (containing match for regexp): "
 213                       nil nil nil 'regexp-history)))
 214   (save-excursion
 215     (while (and (not (eobp))
 216                 (re-search-forward regexp nil t))
 217       (delete-region (save-excursion (goto-char (match-beginning 0))
 218                                      (beginning-of-line)
 219                                      (point))
 220                      (progn (forward-line 1) (point))))))
 221
 222 (defalias 'count-matches 'how-many)
 223 (defun how-many (regexp)
 224   "Print number of matches for REGEXP following point."
 225   (interactive (list (read-from-minibuffer
 226                       "How many matches for (regexp): "
 227                       nil nil nil 'regexp-history)))
 228   (let ((count 0) opoint)
 229     (save-excursion
 230      (while (and (not (eobp))
 231                  (progn (setq opoint (point))
 232                         (re-search-forward regexp nil t)))
 233        (if (= opoint (point))
 234            (forward-char 1)
 235          (setq count (1+ count))))
 236      (message "%d occurrences" count))))
 237 \f
 238 (defvar occur-mode-map ())
 239 (if occur-mode-map
 240     ()
 241   (setq occur-mode-map (make-sparse-keymap))
 242   (define-key occur-mode-map [mouse-2] 'occur-mode-mouse-goto)
 243   (define-key occur-mode-map "\C-c\C-c" 'occur-mode-goto-occurrence)
 244   (define-key occur-mode-map "\C-m" 'occur-mode-goto-occurrence))
 245
 246 (defvar occur-buffer nil)
 247 (defvar occur-nlines nil)
 248 (defvar occur-pos-list nil)
 249
 250 (defun occur-mode ()
 251   "Major mode for output from \\[occur].
 252 \\<occur-mode-map>Move point to one of the items in this buffer, then use
 253 \\[occur-mode-goto-occurrence] to go to the occurrence that the item refers to.
 254 Alternatively, click \\[occur-mode-mouse-goto] on an item to go to it.
 255
 256 \\{occur-mode-map}"
 257   (kill-all-local-variables)
 258   (use-local-map occur-mode-map)
 259   (setq major-mode 'occur-mode)
 260   (setq mode-name "Occur")
 261   (make-local-variable 'occur-buffer)
 262   (make-local-variable 'occur-nlines)
 263   (make-local-variable 'occur-pos-list)
 264   (run-hooks 'occur-mode-hook))
 265
 266 (defun occur-mode-mouse-goto (event)
 267   "In Occur mode, go to the occurrence whose line you click on."
 268   (interactive "e")
 269   (let (buffer pos)
 270     (save-excursion
 271       (set-buffer (window-buffer (posn-window (event-end event))))
 272       (save-excursion
 273         (goto-char (posn-point (event-end event)))
 274         (setq pos (occur-mode-find-occurrence))
 275         (setq buffer occur-buffer)))
 276     (pop-to-buffer buffer)
 277     (goto-char (marker-position pos))))
 278
 279 (defun occur-mode-find-occurrence ()
 280   (if (or (null occur-buffer)
 281           (null (buffer-name occur-buffer)))
 282       (progn
 283         (setq occur-buffer nil
 284               occur-pos-list nil)
 285         (error "Buffer in which occurrences were found is deleted")))
 286   (let* ((line-count
 287           (count-lines (point-min)
 288                        (save-excursion
 289                          (beginning-of-line)
 290                          (point))))
 291          (occur-number (save-excursion
 292                          (beginning-of-line)
 293                          (/ (1- line-count)
 294                             (cond ((< occur-nlines 0)
 295                                    (- 2 occur-nlines))
 296                                   ((> occur-nlines 0)
 297                                    (+ 2 (* 2 occur-nlines)))
 298                                   (t 1)))))
 299          (pos (nth occur-number occur-pos-list)))
 300     (if (< line-count 1)
 301         (error "No occurrence on this line"))
 302     (or pos
 303         (error "No occurrence on this line"))
 304     pos))
 305
 306 (defun occur-mode-goto-occurrence ()
 307   "Go to the occurrence the current line describes."
 308   (interactive)
 309   (let ((pos (occur-mode-find-occurrence)))
 310     (pop-to-buffer occur-buffer)
 311     (goto-char (marker-position pos))))
 312 \f
 313 (defvar list-matching-lines-default-context-lines 0
 314   "*Default number of context lines to include around a `list-matching-lines'
 315 match.  A negative number means to include that many lines before the match.
 316 A positive number means to include that many lines both before and after.")
 317
 318 (defalias 'list-matching-lines 'occur)
 319
 320 (defun occur (regexp &optional nlines)
 321   "Show all lines in the current buffer containing a match for REGEXP.
 322
 323 If a match spreads across multiple lines, all those lines are shown.
 324
 325 Each line is displayed with NLINES lines before and after, or -NLINES
 326 before if NLINES is negative.
 327 NLINES defaults to `list-matching-lines-default-context-lines'.
 328 Interactively it is the prefix arg.
 329
 330 The lines are shown in a buffer named `*Occur*'.
 331 It serves as a menu to find any of the occurrences in this buffer.
 332 \\[describe-mode] in that buffer will explain how."
 333   (interactive
 334    (list (let* ((default (car regexp-history))
 335                 (input
 336                  (read-from-minibuffer
 337                   (if default
 338                       (format "List lines matching regexp (default `%s'): "
 339                               default)
 340                     "List lines matching regexp: ")
 341                   nil nil nil 'regexp-history)))
 342            (if (string-equal input "")
 343                default
 344              (set-text-properties 0 (length input) nil input)
 345              input))
 346          current-prefix-arg))
 347   (let ((nlines (if nlines
 348                     (prefix-numeric-value nlines)
 349                   list-matching-lines-default-context-lines))
 350         (first t)
 351         (buffer (current-buffer))
 352         (dir default-directory)
 353         (linenum 1)
 354         (prevpos (point-min))
 355         (final-context-start (make-marker)))
 356 ;;;     (save-excursion
 357 ;;;       (beginning-of-line)
 358 ;;;       (setq linenum (1+ (count-lines (point-min) (point))))
 359 ;;;       (setq prevpos (point)))
 360     (save-excursion
 361       (goto-char (point-min))
 362       ;; Check first whether there are any matches at all.
 363       (if (not (re-search-forward regexp nil t))
 364           (message "No matches for `%s'" regexp)
 365         ;; Back up, so the search loop below will find the first match.
 366         (goto-char (match-beginning 0))
 367         (with-output-to-temp-buffer "*Occur*"
 368           (save-excursion
 369             (set-buffer standard-output)
 370             (setq default-directory dir)
 371             ;; We will insert the number of lines, and "lines", later.
 372             (insert " matching ")
 373             (let ((print-escape-newlines t))
 374               (prin1 regexp))
 375             (insert " in buffer " (buffer-name buffer) ?. ?\n)
 376             (occur-mode)
 377             (setq occur-buffer buffer)
 378             (setq occur-nlines nlines)
 379             (setq occur-pos-list ()))
 380           (if (eq buffer standard-output)
 381               (goto-char (point-max)))
 382           (save-excursion
 383             ;; Find next match, but give up if prev match was at end of buffer.
 384             (while (and (not (= prevpos (point-max)))
 385                         (re-search-forward regexp nil t))
 386               (goto-char (match-beginning 0))
 387               (beginning-of-line)
 388               (save-match-data
 389                 (setq linenum (+ linenum (count-lines prevpos (point)))))
 390               (setq prevpos (point))
 391               (goto-char (match-end 0))
 392               (let* ((start (save-excursion
 393                               (goto-char (match-beginning 0))
 394                               (forward-line (if (< nlines 0) nlines (- nlines)))
 395                               (point)))
 396                      (end (save-excursion
 397                             (goto-char (match-end 0))
 398                             (if (> nlines 0)
 399                                 (forward-line (1+ nlines))
 400                                 (forward-line 1))
 401                             (point)))
 402                      (tag (format "%5d" linenum))
 403                      (empty (make-string (length tag) ?\ ))
 404                      tem)
 405                 (save-excursion
 406                   (setq tem (make-marker))
 407                   (set-marker tem (point))
 408                   (set-buffer standard-output)
 409                   (setq occur-pos-list (cons tem occur-pos-list))
 410                   (or first (zerop nlines)
 411                       (insert "--------\n"))
 412                   (setq first nil)
 413                   (insert-buffer-substring buffer start end)
 414                   (set-marker final-context-start
 415                               (- (point) (- end (match-end 0))))
 416                   (backward-char (- end start))
 417                   (setq tem nlines)
 418                   (while (> tem 0)
 419                     (insert empty ?:)
 420                     (forward-line 1)
 421                     (setq tem (1- tem)))
 422                   (let ((this-linenum linenum))
 423                     (while (< (point) final-context-start)
 424                       (if (null tag)
 425                           (setq tag (format "%5d" this-linenum)))
 426                       (insert tag ?:)
 427                       (put-text-property (save-excursion
 428                                            (beginning-of-line)
 429                                            (point))
 430                                          (save-excursion
 431                                            (end-of-line)
 432                                            (point))
 433                                          'mouse-face 'highlight)
 434                       (forward-line 1)
 435                       (setq tag nil)
 436                       (setq this-linenum (1+ this-linenum)))
 437                     (while (<= (point) final-context-start)
 438                       (insert empty ?:)
 439                       (forward-line 1)
 440                       (setq this-linenum (1+ this-linenum))))
 441                   (while (< tem nlines)
 442                     (insert empty ?:)
 443                     (forward-line 1)
 444                     (setq tem (1+ tem)))
 445                   (goto-char (point-max)))
 446                 (forward-line 1)))
 447             (set-buffer standard-output)
 448             ;; Put positions in increasing order to go with buffer.
 449             (setq occur-pos-list (nreverse occur-pos-list))
 450             (goto-char (point-min))
 451             (let ((message-string
 452                    (if (= (length occur-pos-list) 1)
 453                        "1 line"
 454                      (format "%d lines" (length occur-pos-list)))))
 455               (insert message-string)
 456               (if (interactive-p)
 457                   (message "%s matched" message-string)))))))))
 458 \f
 459 ;; It would be nice to use \\[...], but there is no reasonable way
 460 ;; to make that display both SPC and Y.
 461 (defconst query-replace-help
 462   "Type Space or `y' to replace one match, Delete or `n' to skip to next,
 463 RET or `q' to exit, Period to replace one match and exit,
 464 Comma to replace but not move point immediately,
 465 C-r to enter recursive edit (\\[exit-recursive-edit] to get out again),
 466 C-w to delete match and recursive edit,
 467 C-l to clear the screen, redisplay, and offer same replacement again,
 468 ! to replace all remaining matches with no more questions,
 469 ^ to move point back to previous match."
 470   "Help message while in query-replace")
 471
 472 (defvar query-replace-map (make-sparse-keymap)
 473   "Keymap that defines the responses to questions in `query-replace'.
 474 The \"bindings\" in this map are not commands; they are answers.
 475 The valid answers include `act', `skip', `act-and-show',
 476 `exit', `act-and-exit', `edit', `delete-and-edit', `recenter',
 477 `automatic', `backup', `exit-prefix', and `help'.")
 478
 479 (define-key query-replace-map " " 'act)
 480 (define-key query-replace-map "\d" 'skip)
 481 (define-key query-replace-map [delete] 'skip)
 482 (define-key query-replace-map [backspace] 'skip)
 483 (define-key query-replace-map "y" 'act)
 484 (define-key query-replace-map "n" 'skip)
 485 (define-key query-replace-map "Y" 'act)
 486 (define-key query-replace-map "N" 'skip)
 487 (define-key query-replace-map "," 'act-and-show)
 488 (define-key query-replace-map "q" 'exit)
 489 (define-key query-replace-map "\r" 'exit)
 490 (define-key query-replace-map [return] 'exit)
 491 (define-key query-replace-map "." 'act-and-exit)
 492 (define-key query-replace-map "\C-r" 'edit)
 493 (define-key query-replace-map "\C-w" 'delete-and-edit)
 494 (define-key query-replace-map "\C-l" 'recenter)
 495 (define-key query-replace-map "!" 'automatic)
 496 (define-key query-replace-map "^" 'backup)
 497 (define-key query-replace-map "\C-h" 'help)
 498 (define-key query-replace-map [f1] 'help)
 499 (define-key query-replace-map [help] 'help)
 500 (define-key query-replace-map "?" 'help)
 501 (define-key query-replace-map "\C-g" 'quit)
 502 (define-key query-replace-map "\C-]" 'quit)
 503 (define-key query-replace-map "\e" 'exit-prefix)
 504 (define-key query-replace-map [escape] 'exit-prefix)
 505
 506 (defun perform-replace (from-string replacements
 507                         query-flag regexp-flag delimited-flag
 508                         &optional repeat-count map)
 509   "Subroutine of `query-replace'.  Its complexity handles interactive queries.
 510 Don't use this in your own program unless you want to query and set the mark
 511 just as `query-replace' does.  Instead, write a simple loop like this:
 512   (while (re-search-forward \"foo[ \t]+bar\" nil t)
 513     (replace-match \"foobar\" nil nil))
 514 which will run faster and probably do exactly what you want."
 515   (or map (setq map query-replace-map))
 516   (and query-flag minibuffer-auto-raise
 517        (raise-frame (window-frame (minibuffer-window))))
 518   (let ((nocasify (not (and case-fold-search case-replace
 519                             (string-equal from-string
 520                                           (downcase from-string)))))
 521         (literal (not regexp-flag))
 522         (search-function (if regexp-flag 're-search-forward 'search-forward))
 523         (search-string from-string)
 524         (real-match-data nil)           ; the match data for the current match
 525         (next-replacement nil)
 526         (replacement-index 0)
 527         (keep-going t)
 528         (stack nil)
 529         (next-rotate-count 0)
 530         (replace-count 0)
 531         (lastrepl nil)                  ;Position after last match considered.
 532         (match-again t)
 533         (message
 534          (if query-flag
 535              (substitute-command-keys
 536               "Query replacing %s with %s: (\\<query-replace-map>\\[help] for help) "))))
 537     (if (stringp replacements)
 538         (setq next-replacement replacements)
 539       (or repeat-count (setq repeat-count 1)))
 540     (if delimited-flag
 541         (setq search-function 're-search-forward
 542               search-string (concat "\\b"
 543                                     (if regexp-flag from-string
 544                                       (regexp-quote from-string))
 545                                     "\\b")))
 546     (push-mark)
 547     (undo-boundary)
 548     (unwind-protect
 549         ;; Loop finding occurrences that perhaps should be replaced.
 550         (while (and keep-going
 551                     (not (eobp))
 552                     (funcall search-function search-string nil t)
 553                     ;; If the search string matches immediately after
 554                     ;; the previous match, but it did not match there
 555                     ;; before the replacement was done, ignore the match.
 556                     (if (or (eq lastrepl (point))
 557                             (and regexp-flag
 558                                  (eq lastrepl (match-beginning 0))
 559                                  (not match-again)))
 560                         (if (eobp)
 561                             nil
 562                           ;; Don't replace the null string
 563                           ;; right after end of previous replacement.
 564                           (forward-char 1)
 565                           (funcall search-function search-string nil t))
 566                       t))
 567
 568           ;; Save the data associated with the real match.
 569           ;; For speed, use only integers and reuse the list used last time.
 570           (setq real-match-data (match-data t real-match-data))
 571
 572           ;; Before we make the replacement, decide whether the search string
 573           ;; can match again just after this match.
 574           (if regexp-flag
 575               (setq match-again (looking-at search-string)))
 576           ;; If time for a change, advance to next replacement string.
 577           (if (and (listp replacements)
 578                    (= next-rotate-count replace-count))
 579               (progn
 580                 (setq next-rotate-count
 581                       (+ next-rotate-count repeat-count))
 582                 (setq next-replacement (nth replacement-index replacements))
 583                 (setq replacement-index (% (1+ replacement-index) (length replacements)))))
 584           (if (not query-flag)
 585               (progn
 586                 (store-match-data real-match-data)
 587                 (replace-match next-replacement nocasify literal)
 588                 (setq replace-count (1+ replace-count)))
 589             (undo-boundary)
 590             (let (done replaced key def)
 591               ;; Loop reading commands until one of them sets done,
 592               ;; which means it has finished handling this occurrence.
 593               (while (not done)
 594                 (store-match-data real-match-data)
 595                 (replace-highlight (match-beginning 0) (match-end 0))
 596                 ;; Bind message-log-max so we don't fill up the message log
 597                 ;; with a bunch of identical messages.
 598                 (let ((message-log-max nil))
 599                   (message message from-string next-replacement))
 600                 (setq key (read-event))
 601                 (setq key (vector key))
 602                 (setq def (lookup-key map key))
 603                 ;; Restore the match data while we process the command.
 604                 (cond ((eq def 'help)
 605                        (with-output-to-temp-buffer "*Help*"
 606                          (princ
 607                           (concat "Query replacing "
 608                                   (if regexp-flag "regexp " "")
 609                                   from-string " with "
 610                                   next-replacement ".\n\n"
 611                                   (substitute-command-keys
 612                                    query-replace-help)))
 613                          (save-excursion
 614                            (set-buffer standard-output)
 615                            (help-mode))))
 616                       ((eq def 'exit)
 617                        (setq keep-going nil)
 618                        (setq done t))
 619                       ((eq def 'backup)
 620                        (if stack
 621                            (let ((elt (car stack)))
 622                              (goto-char (car elt))
 623                              (setq replaced (eq t (cdr elt)))
 624                              (or replaced
 625                                  (store-match-data (cdr elt)))
 626                              (setq stack (cdr stack)))
 627                          (message "No previous match")
 628                          (ding 'no-terminate)
 629                          (sit-for 1)))
 630                       ((eq def 'act)
 631                        (or replaced
 632                            (progn
 633                              (replace-match next-replacement nocasify literal)
 634                              (setq replace-count (1+ replace-count))))
 635                        (setq done t replaced t))
 636                       ((eq def 'act-and-exit)
 637                        (or replaced
 638                            (progn
 639                              (replace-match next-replacement nocasify literal)
 640                              (setq replace-count (1+ replace-count))))
 641                        (setq keep-going nil)
 642                        (setq done t replaced t))
 643                       ((eq def 'act-and-show)
 644                        (if (not replaced)
 645                            (progn
 646                              (replace-match next-replacement nocasify literal)
 647                              (setq replace-count (1+ replace-count))
 648                              (setq replaced t))))
 649                       ((eq def 'automatic)
 650                        (or replaced
 651                            (progn
 652                              (replace-match next-replacement nocasify literal)
 653                              (setq replace-count (1+ replace-count))))
 654                        (setq done t query-flag nil replaced t))
 655                       ((eq def 'skip)
 656                        (setq done t))
 657                       ((eq def 'recenter)
 658                        (recenter nil))
 659                       ((eq def 'edit)
 660                        (store-match-data
 661                         (prog1 (match-data)
 662                           (save-excursion (recursive-edit))))
 663                        ;; Before we make the replacement,
 664                        ;; decide whether the search string
 665                        ;; can match again just after this match.
 666                        (if regexp-flag
 667                            (setq match-again (looking-at search-string))))
 668                       ((eq def 'delete-and-edit)
 669                        (delete-region (match-beginning 0) (match-end 0))
 670                        (store-match-data
 671                         (prog1 (match-data)
 672                           (save-excursion (recursive-edit))))
 673                        (setq replaced t))
 674                       ;; Note: we do not need to treat `exit-prefix'
 675                       ;; specially here, since we reread
 676                       ;; any unrecognized character.
 677                       (t
 678                        (setq this-command 'mode-exited)
 679                        (setq keep-going nil)
 680                        (setq unread-command-events
 681                              (append (listify-key-sequence key)
 682                                      unread-command-events))
 683                        (setq done t))))
 684               ;; Record previous position for ^ when we move on.
 685               ;; Change markers to numbers in the match data
 686               ;; since lots of markers slow down editing.
 687               (setq stack
 688                     (cons (cons (point)
 689                                 (or replaced (match-data t)))
 690                           stack))))
 691           (setq lastrepl (point)))
 692       (replace-dehighlight))
 693     (or unread-command-events
 694         (message "Replaced %d occurrence%s"
 695                  replace-count
 696                  (if (= replace-count 1) "" "s")))
 697     (and keep-going stack)))
 698
 699 (defvar query-replace-highlight nil
 700   "*Non-nil means to highlight words during query replacement.")
 701
 702 (defvar replace-overlay nil)
 703
 704 (defun replace-dehighlight ()
 705   (and replace-overlay
 706        (progn
 707          (delete-overlay replace-overlay)
 708          (setq replace-overlay nil))))
 709
 710 (defun replace-highlight (start end)
 711   (and query-replace-highlight
 712        (progn
 713          (or replace-overlay
 714              (progn
 715                (setq replace-overlay (make-overlay start end))
 716                (overlay-put replace-overlay 'face
 717                             (if (internal-find-face 'query-replace)
 718                                 'query-replace 'region))))
 719          (move-overlay replace-overlay start end (current-buffer)))))
 720
 721 ;;; replace.el ends here