lisp/server.el

   1 ;; Lisp code for GNU Emacs running as server process.
   2 ;; Copyright (C) 1986, 1987 Free Software Foundation, Inc.
   3 ;; Author William Sommerfeld, wesommer@athena.mit.edu.
   4 ;; Changes by peck@sun.com and by rms.
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 1, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  20 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  21
  22
  23 ;;; This Lisp code is run in Emacs when it is to operate as
  24 ;;; a server for other processes.
  25
  26 ;;; Load this library and do M-x server-edit to enable Emacs as a server.
  27 ;;; Emacs runs the program ../etc/emacsserver as a subprocess
  28 ;;; for communication with clients.  If there are no client buffers to edit,
  29 ;;; server-edit acts like (switch-to-buffer (other-buffer))
  30
  31 ;;; When some other program runs "the editor" to edit a file,
  32 ;;; "the editor" can be the Emacs client program ../etc/emacsclient.
  33 ;;; This program transmits the file names to Emacs through
  34 ;;; the server subprocess, and Emacs visits them and lets you edit them.
  35
  36 ;;; Note that any number of clients may dispatch files to emacs to be edited.
  37
  38 ;;; When you finish editing a Server buffer, again call server-edit
  39 ;;; to mark that buffer as done for the client and switch to the next
  40 ;;; Server buffer.  When all the buffers for a client have been edited
  41 ;;; and exited with server-edit, the client "editor" will return
  42 ;;; to the program that invoked it.
  43
  44 ;;; Your editing commands and Emacs's display output go to and from
  45 ;;; the terminal in the usual way.  Thus, server operation is possible
  46 ;;; only when Emacs can talk to the terminal at the time you invoke
  47 ;;; the client.  This is possible in four cases:
  48
  49 ;;; 1. On a window system, where Emacs runs in one window and the
  50 ;;; program that wants to use "the editor" runs in another.
  51
  52 ;;; 2. On a multi-terminal system, where Emacs runs on one terminal and the
  53 ;;; program that wants to use "the editor" runs on another.
  54
  55 ;;; 3. When the program that wants to use "the editor" is running
  56 ;;; as a subprocess of Emacs.
  57
  58 ;;; 4. On a system with job control, when Emacs is suspended, the program
  59 ;;; that wants to use "the editor" will stop and display
  60 ;;; "Waiting for Emacs...".  It can then be suspended, and Emacs can be
  61 ;;; brought into the foreground for editing.  When done editing, Emacs is
  62 ;;; suspended again, and the client program is brought into the foreground.
  63
  64 ;;; The buffer local variable "server-buffer-clients" lists
  65 ;;; the clients who are waiting for this buffer to be edited.
  66 ;;; The global variable "server-clients" lists all the waiting clients,
  67 ;;; and which files are yet to be edited for each.
  68 \f
  69 (defvar server-program "emacsserver"
  70   "*The program to use as the edit server")
  71
  72 (defvar server-visit-hook nil
  73   "*List of hooks to call when switching to a buffer for the Emacs server.")
  74
  75 (defvar server-process nil
  76   "the current server process")
  77
  78 (defvar server-previous-string "")
  79
  80 (defvar server-clients nil
  81   "List of current server clients.
  82 Each element is (CLIENTID FILES...) where CLIENTID is a string
  83 that can be given to the server process to identify a client.
  84 When a buffer is marked as \"done\", it is removed from this list.")
  85
  86 (defvar server-buffer-clients nil
  87   "List of clientids for clients requesting editing of current buffer.")
  88 ;; Changing major modes should not erase this local.
  89 (put 'server-buffer-clients 'permanent-local t)
  90
  91 (defvar server-temp-file-regexp "^/tmp/Re\\|/draft$"
  92   "*Regexp which should match filenames of temporary files
  93 which are deleted and reused after each edit
  94 by the programs that invoke the emacs server.")
  95
  96 (make-variable-buffer-local 'server-buffer-clients)
  97 (setq-default server-buffer-clients nil)
  98 (or (assq 'server-buffer-clients minor-mode-alist)
  99     (setq minor-mode-alist (cons '(server-buffer-clients " Server") minor-mode-alist)))
 100
 101 ;; If a *server* buffer exists,
 102 ;; write STRING to it for logging purposes.
 103 (defun server-log (string)
 104   (if (get-buffer "*server*")
 105       (save-excursion
 106         (set-buffer "*server*")
 107         (goto-char (point-max))
 108         (insert string)
 109         (or (bobp) (newline)))))
 110
 111 (defun server-sentinel (proc msg)
 112   (cond ((eq (process-status proc) 'exit)
 113          (server-log (message "Server subprocess exited")))
 114         ((eq (process-status proc) 'signal)
 115          (server-log (message "Server subprocess killed")))))
 116
 117 ;;;###autoload
 118 (defun server-start (&optional leave-dead)
 119   "Allow this Emacs process to be a server for client processes.
 120 This starts a server communications subprocess through which
 121 client \"editors\" can send your editing commands to this Emacs job.
 122 To use the server, set up the program `etc/emacsclient' in the
 123 Emacs distribution as your standard \"editor\".
 124
 125 Prefix arg means just kill any existing server communications subprocess."
 126   (interactive "P")
 127   ;; kill it dead!
 128   (if server-process
 129       (progn
 130         (set-process-sentinel server-process nil)
 131         (condition-case () (delete-process server-process) (error nil))))
 132   (condition-case () (delete-file "~/.emacs_server") (error nil))
 133   ;; If we already had a server, clear out associated status.
 134   (while server-clients
 135     (let ((buffer (nth 1 (car server-clients))))
 136       (server-buffer-done buffer)))
 137   (if leave-dead
 138       nil
 139     (if server-process
 140         (server-log (message "Restarting server")))
 141     (setq server-process (start-process "server" nil server-program))
 142     (set-process-sentinel server-process 'server-sentinel)
 143     (set-process-filter server-process 'server-process-filter)
 144     (process-kill-without-query server-process)))
 145 \f
 146 ;Process a request from the server to edit some files.
 147 ;Format of STRING is "Client: CLIENTID PATH PATH PATH... \n"
 148 (defun server-process-filter (proc string)
 149   (server-log string)
 150   (setq string (concat server-previous-string string))
 151   (if (not (and (eq ?\n (aref string (1- (length string))))
 152                 (eq 0 (string-match "Client: " string))))
 153       ;; If input is not complete, save it for later.
 154       (setq server-previous-string string)
 155     ;; If it is complete, process it now, and discard what was saved.
 156     (setq string (substring string (match-end 0)))
 157     (setq server-previous-string "")
 158     (let ((client (list (substring string 0 (string-match " " string))))
 159           (files nil)
 160           (lineno 1))
 161       (setq string (substring string (match-end 0)))
 162       (while (string-match "[^ ]+ " string)
 163         (let ((arg
 164                (substring string (match-beginning 0) (1- (match-end 0)))))
 165           (setq string (substring string (match-end 0)))
 166           (if (string-match "\\`\\+[0-9]+\\'" arg)
 167               (setq lineno (read (substring arg 1)))
 168             (setq files
 169                   (cons (list arg lineno)
 170                         files))
 171             (setq lineno 1))))
 172       (server-visit-files files client)
 173       ;; CLIENT is now a list (CLIENTNUM BUFFERS...)
 174       (setq server-clients (cons client server-clients))
 175       (switch-to-buffer (nth 1 client))
 176       (message (substitute-command-keys
 177                 "When done with a buffer, type \\[server-edit].")))))
 178
 179 (defun server-visit-files (files client)
 180   "Finds FILES and returns the list CLIENT with the buffers nconc'd.
 181 FILES is an alist whose elements are (FILENAME LINENUMBER)."
 182   (let (client-record)
 183     (while files
 184       (save-excursion
 185         ;; If there is an existing buffer modified or the file is modified,
 186         ;; revert it.
 187         ;; If there is an existing buffer with deleted file, offer to write it.
 188         (let* ((filen (car (car files)))
 189                (obuf (get-file-buffer filen)))
 190           (if (and obuf (set-buffer obuf))
 191               (if (file-exists-p filen)
 192                   (if (or (not (verify-visited-file-modtime obuf))
 193                           (buffer-modified-p obuf))
 194                       (revert-buffer t nil))
 195                 (if (y-or-n-p
 196                      (concat "File no longer exists: "
 197                              filen
 198                              ", write buffer to file? "))
 199                     (write-file filen)))
 200             (set-buffer (find-file-noselect filen))
 201             (run-hooks 'server-visit-hook)))
 202         (goto-line (nth 1 (car files)))
 203         (setq server-buffer-clients (cons (car client) server-buffer-clients))
 204         (setq client-record (cons (current-buffer) client-record)))
 205         (setq files (cdr files)))
 206     (nconc client client-record)))
 207 \f
 208 (defun server-buffer-done (buffer)
 209   "Mark BUFFER as \"done\" for its client(s).
 210 Buries the buffer, and returns another server buffer
 211 as a suggestion for what to select next."
 212   (let ((running (eq (process-status server-process) 'run))
 213         (next-buffer nil)
 214         (old-clients server-clients))
 215     (while old-clients
 216       (let ((client (car old-clients)))
 217         (or next-buffer
 218             (setq next-buffer (nth 1 (memq buffer client))))
 219         (delq buffer client)
 220         ;; If client now has no pending buffers,
 221         ;; tell it that it is done, and forget it entirely.
 222         (if (cdr client) nil
 223           (if running
 224               (progn
 225                 (send-string server-process
 226                              (format "Close: %s Done\n" (car client)))
 227                 (server-log (format "Close: %s Done\n" (car client)))))
 228           (setq server-clients (delq client server-clients))))
 229       (setq old-clients (cdr old-clients)))
 230     (if (buffer-name buffer)
 231         (save-excursion
 232           (set-buffer buffer)
 233           (setq server-buffer-clients nil)))
 234     (bury-buffer buffer)
 235     next-buffer))
 236
 237 (defun server-temp-file-p (buffer)
 238   "Return non-nil if BUFFER contains a file considered temporary.
 239 These are files whose names suggest they are repeatedly
 240 reused to pass information to another program.
 241
 242 The variable `server-temp-file-regexp' controls which filenames
 243 are considered temporary."
 244   (and (buffer-file-name buffer)
 245        (string-match server-temp-file-regexp (buffer-file-name buffer))))
 246
 247 (defun server-done ()
 248   "Offer to save current buffer, mark it as \"done\" for clients,
 249 bury it, and return a suggested buffer to select next."
 250   (let ((buffer (current-buffer)))
 251     (if server-buffer-clients
 252         (progn
 253           (if (server-temp-file-p buffer)
 254               (progn (save-buffer)
 255                      (write-region (point-min) (point-max)
 256                                    (concat buffer-file-name "~"))
 257                      (kill-buffer buffer))
 258             (if (and (buffer-modified-p)
 259                      (y-or-n-p (concat "Save file " buffer-file-name "? ")))
 260                 (save-buffer buffer)))
 261           (server-buffer-done buffer)))))
 262 \f
 263 (defun server-edit (&optional arg)
 264   "Switch to next server editing buffer; say \"Done\" for current buffer.
 265 If a server buffer is current, it is marked \"done\" and optionally saved.
 266 When all of a client's buffers are marked as \"done\", the client is notified.
 267
 268 Temporary files such as MH <draft> files are always saved and backed up,
 269 no questions asked.  The variable `server-temp-file-regexp' controls
 270 which filenames are considered temporary.
 271
 272 If invoked with a prefix argument, or if there is no server process running,
 273 starts server process and that is all.  Invoked by \\[server-edit]."
 274
 275   (interactive "P")
 276   (if (or arg
 277           (not server-process)
 278           (memq (process-status server-process) '(signal exit)))
 279       (server-start nil)
 280     (server-switch-buffer (server-done))))
 281
 282 (defun server-switch-buffer (next-buffer)
 283   "Switch to another buffer, preferably one that has a client.
 284 Arg NEXT-BUFFER is a suggestion; if it is a live buffer, use it."
 285   (if next-buffer
 286       (if (and (bufferp next-buffer)
 287                (buffer-name next-buffer))
 288           (switch-to-buffer next-buffer)
 289         ;; If NEXT-BUFFER is a dead buffer,
 290         ;; remove the server records for it
 291         ;; and try the next surviving server buffer.
 292         (server-switch-buffer
 293          (server-buffer-done next-buffer)))
 294     (if server-clients
 295         (server-switch-buffer (nth 1 (car server-clients)))
 296       (switch-to-buffer (other-buffer)))))
 297
 298 (global-set-key "\C-x#" 'server-edit)