lisp/ediff.el

   1 ;;; ediff.el --- a comprehensive visual interface to diff & patch
   2
   3 ;; Copyright (C) 1994, 95, 96, 97, 98, 99, 2000, 01, 02, 03 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Kifer <kifer@cs.stonybrook.edu>
   6 ;; Created: February 2, 1994
   7 ;; Keywords: comparing, merging, patching, tools, unix
   8
   9 (defconst ediff-version "2.78" "The current version of Ediff")
  10 (defconst ediff-date "January 25, 2003" "Date of last update")
  11
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  28 ;; Boston, MA 02111-1307, USA.
  29
  30 ;;; Commentary:
  31
  32 ;; Never read that diff output again!
  33 ;; Apply patch interactively!
  34 ;; Merge with ease!
  35
  36 ;; This package provides a convenient way of simultaneous browsing through
  37 ;; the differences between a pair (or a triple) of files or buffers.  The
  38 ;; files being compared, file-A, file-B, and file-C (if applicable) are
  39 ;; shown in separate windows (side by side, one above the another, or in
  40 ;; separate frames), and the differences are highlighted as you step
  41 ;; through them.  You can also copy difference regions from one buffer to
  42 ;; another (and recover old differences if you change your mind).
  43
  44 ;; Ediff also supports merging operations on files and buffers, including
  45 ;; merging using ancestor versions.  Both comparison and merging operations can
  46 ;; be performed on directories, i.e., by pairwise comparison of files in those
  47 ;; directories.
  48
  49 ;; In addition, Ediff can apply a patch to a file and then let you step
  50 ;; though both files, the patched and the original one, simultaneously,
  51 ;; difference-by-difference.  You can even apply a patch right out of a
  52 ;; mail buffer, i.e., patches received by mail don't even have to be saved.
  53 ;; Since Ediff lets you copy differences between buffers, you can, in
  54 ;; effect, apply patches selectively (i.e., you can copy a difference
  55 ;; region from file_orig to file, thereby undoing any particular patch that
  56 ;; you don't like).
  57
  58 ;; Ediff is aware of version control, which lets the user compare
  59 ;; files with their older versions.  Ediff can also work with remote and
  60 ;; compressed files.  Details are given below.
  61
  62 ;; Finally, Ediff supports directory-level comparison, merging and patching.
  63 ;; See the on-line manual for details.
  64
  65 ;; This package builds upon the ideas borrowed from emerge.el and several
  66 ;; Ediff's functions are adaptations from emerge.el.  Much of the functionality
  67 ;; Ediff provides is also influenced by emerge.el.
  68
  69 ;; The present version of Ediff supersedes Emerge.  It provides a superior user
  70 ;; interface and has numerous major features not found in Emerge.  In
  71 ;; particular, it can do patching, and 2-way and 3-way file comparison,
  72 ;; merging, and directory operations.
  73
  74
  75
  76 ;;; Bugs:
  77
  78 ;;  1. The undo command doesn't restore deleted regions well.  That is, if
  79 ;;  you delete all characters in a difference region and then invoke
  80 ;;  `undo', the reinstated text will most likely be inserted outside of
  81 ;;  what Ediff thinks is the current difference region. (This problem
  82 ;;  doesn't seem to exist with XEmacs.)
  83 ;;
  84 ;;  If at any point you feel that difference regions are no longer correct,
  85 ;;  you can hit '!' to recompute the differences.
  86
  87 ;;  2. On a monochrome display, the repertoire of faces with which to
  88 ;;  highlight fine differences is limited.  By default, Ediff is using
  89 ;;  underlining.  However, if the region is already underlined by some other
  90 ;;  overlays, there is no simple way to temporarily remove that residual
  91 ;;  underlining.  This problem occurs when a buffer is highlighted with
  92 ;;  hilit19.el or font-lock.el packages.  If this residual highlighting gets
  93 ;;  in the way, you can do the following.  Both font-lock.el and hilit19.el
  94 ;;  provide commands for unhighlighting buffers.  You can either place these
  95 ;;  commands in `ediff-prepare-buffer-hook' (which will unhighlight every
  96 ;;  buffer used by Ediff) or you can execute them interactively, at any time
  97 ;;  and on any buffer.
  98
  99
 100 ;;; Acknowledgements:
 101
 102 ;; Ediff was inspired by Dale R. Worley's <drw@math.mit.edu> emerge.el.
 103 ;; Ediff would not have been possible without the help and encouragement of
 104 ;; its many users.  See Ediff on-line Info for the full list of those who
 105 ;; helped.  Improved defaults in Ediff file-name reading commands.
 106
 107 ;;; Code:
 108
 109 (provide 'ediff)
 110
 111 ;; Compiler pacifier
 112 (defvar cvs-cookie-handle)
 113 (defvar ediff-last-dir-patch)
 114 (defvar ediff-patch-default-directory)
 115
 116 (and noninteractive
 117      (eval-when-compile
 118          (load-library "dired")
 119          (load-library "info")
 120          (load "pcl-cvs" 'noerror)))
 121 (eval-when-compile
 122   (let ((load-path (cons (expand-file-name ".") load-path)))
 123     (or (featurep 'ediff-init)
 124         (load "ediff-init.el" nil nil 'nosuffix))
 125     (or (featurep 'ediff-mult)
 126         (load "ediff-mult.el" nil nil 'nosuffix))
 127     (or (featurep 'ediff-ptch)
 128         (load "ediff-ptch.el" nil nil 'nosuffix))
 129     (or (featurep 'ediff-vers)
 130         (load "ediff-vers.el" nil nil 'nosuffix))
 131     ))
 132 ;; end pacifier
 133
 134 (require 'ediff-init)
 135 (require 'ediff-mult)  ; required because of the registry stuff
 136
 137 (defgroup ediff nil
 138   "A comprehensive visual interface to diff & patch"
 139   :tag "Ediff"
 140   :group 'tools)
 141
 142
 143 (defcustom ediff-use-last-dir nil
 144   "*If t, Ediff will use previous directory as default when reading file name."
 145   :type 'boolean
 146   :group 'ediff)
 147
 148 ;; Last directory used by an Ediff command for file-A.
 149 (defvar ediff-last-dir-A nil)
 150 ;; Last directory used by an Ediff command for file-B.
 151 (defvar ediff-last-dir-B nil)
 152 ;; Last directory used by an Ediff command for file-C.
 153 (defvar ediff-last-dir-C nil)
 154 ;; Last directory used by an Ediff command for the ancestor file.
 155 (defvar ediff-last-dir-ancestor nil)
 156 ;; Last directory used by an Ediff command as the output directory for merge.
 157 (defvar ediff-last-merge-autostore-dir nil)
 158
 159
 160 ;; Used as a startup hook to set `_orig' patch file read-only.
 161 (defun ediff-set-read-only-in-buf-A ()
 162   (ediff-with-current-buffer ediff-buffer-A
 163     (toggle-read-only 1)))
 164
 165 ;; Return a plausible default for ediff's first file:
 166 ;; In dired, return the file number FILENO (or 0) in the list
 167 ;; (all-selected-files, filename under the cursor), where directories are
 168 ;; ignored. Otherwise, return DEFAULT file name, if non-nil. Else,
 169 ;; if the buffer is visiting a file, return that file name.
 170 (defun ediff-get-default-file-name (&optional default fileno)
 171   (cond ((eq major-mode 'dired-mode)
 172          (let ((current (dired-get-filename nil 'no-error))
 173                (marked (condition-case nil
 174                            (dired-get-marked-files 'no-dir)
 175                          (error nil)))
 176                aux-list choices result)
 177            (or (integerp fileno) (setq fileno 0))
 178            (if (stringp default)
 179                (setq aux-list (cons default aux-list)))
 180            (if (and (stringp current) (not (file-directory-p current)))
 181                (setq aux-list (cons current aux-list)))
 182            (setq choices (nconc  marked aux-list))
 183            (setq result (elt choices fileno))
 184            (or result
 185                default)))
 186         ((stringp default) default)
 187         ((buffer-file-name (current-buffer))
 188          (file-name-nondirectory (buffer-file-name (current-buffer))))
 189         ))
 190
 191 ;;; Compare files/buffers
 192
 193 ;;;###autoload
 194 (defun ediff-files (file-A file-B &optional startup-hooks)
 195   "Run Ediff on a pair of files, FILE-A and FILE-B."
 196   (interactive
 197    (let ((dir-A (if ediff-use-last-dir
 198                     ediff-last-dir-A
 199                   default-directory))
 200          dir-B f)
 201      (list (setq f (ediff-read-file-name
 202                     "File A to compare"
 203                     dir-A
 204                     (ediff-get-default-file-name)
 205                     'no-dirs))
 206            (ediff-read-file-name "File B to compare"
 207                                  (setq dir-B
 208                                        (if ediff-use-last-dir
 209                                            ediff-last-dir-B
 210                                          (file-name-directory f)))
 211                                  (progn
 212                                    (setq file-name-history
 213                                          (cons (ediff-abbreviate-file-name
 214                                                 (expand-file-name
 215                                                  (file-name-nondirectory f)
 216                                                  dir-B))
 217                                                file-name-history))
 218                                    (ediff-get-default-file-name f 1)))
 219            )))
 220   (ediff-files-internal file-A
 221                         (if (file-directory-p file-B)
 222                             (expand-file-name
 223                              (file-name-nondirectory file-A) file-B)
 224                           file-B)
 225                         nil ; file-C
 226                         startup-hooks
 227                         'ediff-files))
 228
 229 ;;;###autoload
 230 (defun ediff-files3 (file-A file-B file-C &optional startup-hooks)
 231   "Run Ediff on three files, FILE-A, FILE-B, and FILE-C."
 232   (interactive
 233    (let ((dir-A (if ediff-use-last-dir
 234                     ediff-last-dir-A
 235                   default-directory))
 236          dir-B dir-C f ff)
 237      (list (setq f (ediff-read-file-name
 238                     "File A to compare"
 239                     dir-A
 240                     (ediff-get-default-file-name)
 241                     'no-dirs))
 242            (setq ff (ediff-read-file-name "File B to compare"
 243                                           (setq dir-B
 244                                                 (if ediff-use-last-dir
 245                                                     ediff-last-dir-B
 246                                                   (file-name-directory f)))
 247                                           (progn
 248                                             (setq file-name-history
 249                                                   (cons
 250                                                    (ediff-abbreviate-file-name
 251                                                     (expand-file-name
 252                                                      (file-name-nondirectory f)
 253                                                      dir-B))
 254                                                    file-name-history))
 255                                             (ediff-get-default-file-name f 1))))
 256            (ediff-read-file-name "File C to compare"
 257                                  (setq dir-C (if ediff-use-last-dir
 258                                                  ediff-last-dir-C
 259                                                (file-name-directory ff)))
 260                                  (progn
 261                                    (setq file-name-history
 262                                          (cons (ediff-abbreviate-file-name
 263                                                 (expand-file-name
 264                                                  (file-name-nondirectory ff)
 265                                                  dir-C))
 266                                                file-name-history))
 267                                    (ediff-get-default-file-name ff 2)))
 268            )))
 269   (ediff-files-internal file-A
 270                         (if (file-directory-p file-B)
 271                             (expand-file-name
 272                              (file-name-nondirectory file-A) file-B)
 273                           file-B)
 274                         (if (file-directory-p file-C)
 275                             (expand-file-name
 276                              (file-name-nondirectory file-A) file-C)
 277                           file-C)
 278                         startup-hooks
 279                         'ediff-files3))
 280
 281 ;;;###autoload
 282 (defalias 'ediff3 'ediff-files3)
 283
 284
 285 ;; Visit FILE and arrange its buffer to Ediff's liking.
 286 ;; FILE is actually a variable symbol that must contain a true file name.
 287 ;; BUFFER-NAME is a variable symbol, which will get the buffer object into
 288 ;; which FILE is read.
 289 ;; LAST-DIR is the directory variable symbol where FILE's
 290 ;; directory name should be returned.  HOOKS-VAR is a variable symbol that will
 291 ;; be assigned the hook to be executed after `ediff-startup' is finished.
 292 ;; `ediff-find-file' arranges that the temp files it might create will be
 293 ;; deleted.
 294 (defun ediff-find-file (file-var buffer-name &optional last-dir hooks-var)
 295   (let* ((file (symbol-value file-var))
 296          (file-magic (ediff-filename-magic-p file))
 297          (temp-file-name-prefix (file-name-nondirectory file)))
 298     (cond ((not (file-readable-p file))
 299            (error "File `%s' does not exist or is not readable" file))
 300           ((file-directory-p file)
 301            (error "File `%s' is a directory" file)))
 302
 303     ;; some of the commands, below, require full file name
 304     (setq file (expand-file-name file))
 305
 306     ;; Record the directory of the file
 307     (if last-dir
 308         (set last-dir (expand-file-name (file-name-directory file))))
 309
 310     ;; Setup the buffer
 311     (set buffer-name (find-file-noselect file))
 312
 313     (ediff-with-current-buffer (symbol-value buffer-name)
 314       (widen) ; Make sure the entire file is seen
 315       (cond (file-magic  ;   file has a handler, such as jka-compr-handler or
 316                          ;;; ange-ftp-hook-function--arrange for temp file
 317              (ediff-verify-file-buffer 'magic)
 318              (setq file
 319                    (ediff-make-temp-file
 320                     (current-buffer) temp-file-name-prefix))
 321              (set hooks-var (cons `(lambda () (delete-file ,file))
 322                                   (symbol-value hooks-var))))
 323             ;; file processed via auto-mode-alist, a la uncompress.el
 324             ((not (equal (file-truename file)
 325                          (file-truename (buffer-file-name))))
 326              (setq file
 327                    (ediff-make-temp-file
 328                     (current-buffer) temp-file-name-prefix))
 329              (set hooks-var (cons `(lambda () (delete-file ,file))
 330                                   (symbol-value hooks-var))))
 331             (t ;; plain file---just check that the file matches the buffer
 332              (ediff-verify-file-buffer))))
 333     (set file-var file)))
 334
 335 ;; MERGE-BUFFER-FILE is the file to be associated with the merge buffer
 336 (defun ediff-files-internal (file-A file-B file-C startup-hooks job-name
 337                                     &optional merge-buffer-file)
 338   (let (buf-A buf-B buf-C)
 339     (if (string= file-A file-B)
 340         (error "Files A and B are the same"))
 341     (if (stringp file-C)
 342         (or (and (string= file-A file-C) (error "Files A and C are the same"))
 343             (and (string= file-B file-C) (error "Files B and C are the same"))))
 344     (message "Reading file %s ... " file-A)
 345     ;;(sit-for 0)
 346     (ediff-find-file 'file-A 'buf-A 'ediff-last-dir-A 'startup-hooks)
 347     (message "Reading file %s ... " file-B)
 348     ;;(sit-for 0)
 349     (ediff-find-file 'file-B 'buf-B 'ediff-last-dir-B 'startup-hooks)
 350     (if (stringp file-C)
 351         (progn
 352           (message "Reading file %s ... " file-C)
 353           ;;(sit-for 0)
 354           (ediff-find-file
 355            'file-C 'buf-C
 356            (if (eq job-name 'ediff-merge-files-with-ancestor)
 357                'ediff-last-dir-ancestor 'ediff-last-dir-C)
 358            'startup-hooks)))
 359     (ediff-setup buf-A file-A
 360                  buf-B file-B
 361                  buf-C file-C
 362                  startup-hooks
 363                  (list (cons 'ediff-job-name job-name))
 364                  merge-buffer-file)))
 365
 366
 367 ;;;###autoload
 368 (defalias 'ediff 'ediff-files)
 369
 370 ;;;###autoload
 371 (defun ediff-backup (file)
 372   "Run Ediff on FILE and its backup file.
 373 Uses the latest backup, if there are several numerical backups.
 374 If this file is a backup, `ediff' it with its original."
 375   (interactive (list (read-file-name "Ediff (file with backup): ")))
 376   ;; The code is taken from `diff-backup'.
 377   (require 'diff)
 378   (let (bak ori)
 379     (if (backup-file-name-p file)
 380         (setq bak file
 381               ori (file-name-sans-versions file))
 382       (setq bak (or (diff-latest-backup-file file)
 383                     (error "No backup found for %s" file))
 384             ori file))
 385     (ediff-files bak ori)))
 386
 387 ;;;###autoload
 388 (defun ediff-buffers (buffer-A buffer-B &optional startup-hooks job-name)
 389   "Run Ediff on a pair of buffers, BUFFER-A and BUFFER-B."
 390   (interactive
 391    (let (bf)
 392      (list (setq bf (read-buffer "Buffer A to compare: "
 393                                  (ediff-other-buffer "") t))
 394            (read-buffer "Buffer B to compare: "
 395                         (progn
 396                           ;; realign buffers so that two visible bufs will be
 397                           ;; at the top
 398                           (save-window-excursion (other-window 1))
 399                           (ediff-other-buffer bf))
 400                         t))))
 401   (or job-name (setq job-name 'ediff-buffers))
 402   (ediff-buffers-internal buffer-A buffer-B nil startup-hooks job-name))
 403
 404 ;;;###autoload
 405 (defalias 'ebuffers 'ediff-buffers)
 406
 407
 408 ;;;###autoload
 409 (defun ediff-buffers3 (buffer-A buffer-B buffer-C
 410                                  &optional startup-hooks job-name)
 411   "Run Ediff on three buffers, BUFFER-A, BUFFER-B, and BUFFER-C."
 412   (interactive
 413    (let (bf bff)
 414      (list (setq bf (read-buffer "Buffer A to compare: "
 415                                  (ediff-other-buffer "") t))
 416            (setq bff (read-buffer "Buffer B to compare: "
 417                                   (progn
 418                                     ;; realign buffers so that two visible
 419                                     ;; bufs will be at the top
 420                                     (save-window-excursion (other-window 1))
 421                                     (ediff-other-buffer bf))
 422                                   t))
 423            (read-buffer "Buffer C to compare: "
 424                                   (progn
 425                                     ;; realign buffers so that three visible
 426                                     ;; bufs will be at the top
 427                                     (save-window-excursion (other-window 1))
 428                                     (ediff-other-buffer (list bf bff)))
 429                                   t)
 430            )))
 431   (or job-name (setq job-name 'ediff-buffers3))
 432   (ediff-buffers-internal buffer-A buffer-B buffer-C startup-hooks job-name))
 433
 434 ;;;###autoload
 435 (defalias 'ebuffers3 'ediff-buffers3)
 436
 437
 438
 439 ;; MERGE-BUFFER-FILE is the file to be associated with the merge buffer
 440 (defun ediff-buffers-internal (buf-A buf-B buf-C startup-hooks job-name
 441                                      &optional merge-buffer-file)
 442   (let* ((buf-A-file-name (buffer-file-name (get-buffer buf-A)))
 443          (buf-B-file-name (buffer-file-name (get-buffer buf-B)))
 444          (buf-C-is-alive (ediff-buffer-live-p buf-C))
 445          (buf-C-file-name (if buf-C-is-alive
 446                               (buffer-file-name (get-buffer buf-B))))
 447          file-A file-B file-C)
 448     (if (not (ediff-buffer-live-p buf-A))
 449         (error "Buffer %S doesn't exist" buf-A))
 450     (if (not (ediff-buffer-live-p buf-B))
 451         (error "Buffer %S doesn't exist" buf-B))
 452     (let ((ediff-job-name job-name))
 453       (if (and ediff-3way-comparison-job
 454                (not buf-C-is-alive))
 455           (error "Buffer %S doesn't exist" buf-C)))
 456     (if (stringp buf-A-file-name)
 457         (setq buf-A-file-name (file-name-nondirectory buf-A-file-name)))
 458     (if (stringp buf-B-file-name)
 459         (setq buf-B-file-name (file-name-nondirectory buf-B-file-name)))
 460     (if (stringp buf-C-file-name)
 461         (setq buf-C-file-name (file-name-nondirectory buf-C-file-name)))
 462
 463     (setq file-A (ediff-make-temp-file buf-A buf-A-file-name)
 464           file-B (ediff-make-temp-file buf-B buf-B-file-name))
 465     (if buf-C-is-alive
 466         (setq file-C (ediff-make-temp-file buf-C buf-C-file-name)))
 467
 468     (ediff-setup (get-buffer buf-A) file-A
 469                  (get-buffer buf-B) file-B
 470                  (if buf-C-is-alive (get-buffer buf-C))
 471                  file-C
 472                  (cons `(lambda ()
 473                           (delete-file ,file-A)
 474                           (delete-file ,file-B)
 475                           (if (stringp ,file-C) (delete-file ,file-C)))
 476                        startup-hooks)
 477                  (list (cons 'ediff-job-name job-name))
 478                  merge-buffer-file)))
 479
 480
 481 ;;; Directory and file group operations
 482
 483 ;; Get appropriate default name for directory:
 484 ;; If ediff-use-last-dir, use ediff-last-dir-A.
 485 ;; In dired mode, use the directory that is under the point (if any);
 486 ;; otherwise, use default-directory
 487 (defun ediff-get-default-directory-name ()
 488   (cond (ediff-use-last-dir ediff-last-dir-A)
 489         ((eq major-mode 'dired-mode)
 490          (let ((f (dired-get-filename nil 'noerror)))
 491            (if (and (stringp f) (file-directory-p f))
 492                f
 493              default-directory)))
 494         (t default-directory)))
 495
 496
 497 ;;;###autoload
 498 (defun ediff-directories (dir1 dir2 regexp)
 499   "Run Ediff on a pair of directories, DIR1 and DIR2, comparing files that have
 500 the same name in both.  The third argument, REGEXP, is nil or a regular
 501 expression; only file names that match the regexp are considered."
 502   (interactive
 503    (let ((dir-A (ediff-get-default-directory-name))
 504          f)
 505      (list (setq f (ediff-read-file-name "Directory A to compare:" dir-A nil))
 506            (ediff-read-file-name "Directory B to compare:"
 507                                  (if ediff-use-last-dir
 508                                      ediff-last-dir-B
 509                                    (ediff-strip-last-dir f))
 510                                  nil)
 511            (read-string "Filter through regular expression: "
 512                         nil 'ediff-filtering-regexp-history)
 513            )))
 514   (ediff-directories-internal
 515    dir1 dir2 nil regexp 'ediff-files 'ediff-directories
 516    ))
 517
 518 ;;;###autoload
 519 (defalias 'edirs 'ediff-directories)
 520
 521
 522 ;;;###autoload
 523 (defun ediff-directory-revisions (dir1 regexp)
 524   "Run Ediff on a directory, DIR1, comparing its files with their revisions.
 525 The second argument, REGEXP, is a regular expression that filters the file
 526 names.  Only the files that are under revision control are taken into account."
 527   (interactive
 528    (let ((dir-A (ediff-get-default-directory-name)))
 529      (list (ediff-read-file-name
 530             "Directory to compare with revision:" dir-A nil)
 531            (read-string "Filter through regular expression: "
 532                         nil 'ediff-filtering-regexp-history)
 533            )))
 534   (ediff-directory-revisions-internal
 535    dir1 regexp 'ediff-revision 'ediff-directory-revisions
 536    ))
 537
 538 ;;;###autoload
 539 (defalias 'edir-revisions 'ediff-directory-revisions)
 540
 541
 542 ;;;###autoload
 543 (defun ediff-directories3 (dir1 dir2 dir3 regexp)
 544   "Run Ediff on three directories, DIR1, DIR2, and DIR3, comparing files that
 545 have the same name in all three.  The last argument, REGEXP, is nil or a
 546 regular expression; only file names that match the regexp are considered."
 547
 548   (interactive
 549    (let ((dir-A (ediff-get-default-directory-name))
 550          f)
 551      (list (setq f (ediff-read-file-name "Directory A to compare:" dir-A nil))
 552            (setq f (ediff-read-file-name "Directory B to compare:"
 553                                          (if ediff-use-last-dir
 554                                              ediff-last-dir-B
 555                                            (ediff-strip-last-dir f))
 556                                          nil))
 557            (ediff-read-file-name "Directory C to compare:"
 558                                  (if ediff-use-last-dir
 559                                      ediff-last-dir-C
 560                                    (ediff-strip-last-dir f))
 561                                  nil)
 562            (read-string "Filter through regular expression: "
 563                         nil 'ediff-filtering-regexp-history)
 564            )))
 565   (ediff-directories-internal
 566    dir1 dir2 dir3 regexp 'ediff-files3 'ediff-directories3
 567    ))
 568
 569 ;;;###autoload
 570 (defalias 'edirs3 'ediff-directories3)
 571
 572 ;;;###autoload
 573 (defun ediff-merge-directories (dir1 dir2 regexp &optional merge-autostore-dir)
 574   "Run Ediff on a pair of directories, DIR1 and DIR2, merging files that have
 575 the same name in both.  The third argument, REGEXP, is nil or a regular
 576 expression; only file names that match the regexp are considered."
 577   (interactive
 578    (let ((dir-A (ediff-get-default-directory-name))
 579          f)
 580      (list (setq f (ediff-read-file-name "Directory A to merge:" dir-A nil))
 581            (ediff-read-file-name "Directory B to merge:"
 582                                  (if ediff-use-last-dir
 583                                      ediff-last-dir-B
 584                                    (ediff-strip-last-dir f))
 585                                  nil)
 586            (read-string "Filter through regular expression: "
 587                         nil 'ediff-filtering-regexp-history)
 588            )))
 589   (ediff-directories-internal
 590    dir1 dir2 nil regexp 'ediff-merge-files 'ediff-merge-directories
 591    nil merge-autostore-dir
 592    ))
 593
 594 ;;;###autoload
 595 (defalias 'edirs-merge 'ediff-merge-directories)
 596
 597 ;;;###autoload
 598 (defun ediff-merge-directories-with-ancestor (dir1 dir2 ancestor-dir regexp
 599                                                    &optional
 600                                                    merge-autostore-dir)
 601   "Merge files in directories DIR1 and DIR2 using files in ANCESTOR-DIR as ancestors.
 602 Ediff merges files that have identical names in DIR1, DIR2.  If a pair of files
 603 in DIR1 and DIR2 doesn't have an ancestor in ANCESTOR-DIR, Ediff will merge
 604 without ancestor.  The fourth argument, REGEXP, is nil or a regular expression;
 605 only file names that match the regexp are considered."
 606   (interactive
 607    (let ((dir-A (ediff-get-default-directory-name))
 608          f)
 609      (list (setq f (ediff-read-file-name "Directory A to merge:" dir-A nil))
 610            (setq f (ediff-read-file-name "Directory B to merge:"
 611                                  (if ediff-use-last-dir
 612                                      ediff-last-dir-B
 613                                    (ediff-strip-last-dir f))
 614                                  nil))
 615            (ediff-read-file-name "Ancestor directory:"
 616                                  (if ediff-use-last-dir
 617                                      ediff-last-dir-C
 618                                    (ediff-strip-last-dir f))
 619                                  nil)
 620            (read-string "Filter through regular expression: "
 621                         nil 'ediff-filtering-regexp-history)
 622            )))
 623   (ediff-directories-internal
 624    dir1 dir2 ancestor-dir regexp
 625    'ediff-merge-files-with-ancestor 'ediff-merge-directories-with-ancestor
 626    nil merge-autostore-dir
 627    ))
 628
 629 ;;;###autoload
 630 (defun ediff-merge-directory-revisions (dir1 regexp
 631                                              &optional merge-autostore-dir)
 632   "Run Ediff on a directory, DIR1, merging its files with their revisions.
 633 The second argument, REGEXP, is a regular expression that filters the file
 634 names.  Only the files that are under revision control are taken into account."
 635   (interactive
 636    (let ((dir-A (ediff-get-default-directory-name)))
 637      (list (ediff-read-file-name
 638             "Directory to merge with revisions:" dir-A nil)
 639            (read-string "Filter through regular expression: "
 640                         nil 'ediff-filtering-regexp-history)
 641            )))
 642   (ediff-directory-revisions-internal
 643    dir1 regexp 'ediff-merge-revisions 'ediff-merge-directory-revisions
 644    nil merge-autostore-dir
 645    ))
 646
 647 ;;;###autoload
 648 (defalias 'edir-merge-revisions 'ediff-merge-directory-revisions)
 649
 650 ;;;###autoload
 651 (defun ediff-merge-directory-revisions-with-ancestor (dir1 regexp
 652                                                            &optional
 653                                                            merge-autostore-dir)
 654   "Run Ediff on a directory, DIR1, merging its files with their revisions and ancestors.
 655 The second argument, REGEXP, is a regular expression that filters the file
 656 names.  Only the files that are under revision control are taken into account."
 657   (interactive
 658    (let ((dir-A (ediff-get-default-directory-name)))
 659      (list (ediff-read-file-name
 660             "Directory to merge with revisions and ancestors:" dir-A nil)
 661            (read-string "Filter through regular expression: "
 662                         nil 'ediff-filtering-regexp-history)
 663            )))
 664   (ediff-directory-revisions-internal
 665    dir1 regexp 'ediff-merge-revisions-with-ancestor
 666    'ediff-merge-directory-revisions-with-ancestor
 667    nil merge-autostore-dir
 668    ))
 669
 670 ;;;###autoload
 671 (defalias
 672   'edir-merge-revisions-with-ancestor
 673   'ediff-merge-directory-revisions-with-ancestor)
 674
 675 ;;;###autoload
 676 (defalias 'edirs-merge-with-ancestor 'ediff-merge-directories-with-ancestor)
 677
 678 ;; Run ediff-action (ediff-files, ediff-merge, ediff-merge-with-ancestors)
 679 ;; on a pair of directories (three directories, in case of ancestor).
 680 ;; The third argument, REGEXP, is nil or a regular expression;
 681 ;; only file names that match the regexp are considered.
 682 ;; JOBNAME is the symbol indicating the meta-job to be performed.
 683 ;; MERGE-AUTOSTORE-DIR is the directory in which to store merged files.
 684 (defun ediff-directories-internal (dir1 dir2 dir3 regexp action jobname
 685                                         &optional startup-hooks
 686                                         merge-autostore-dir)
 687   ;; ediff-read-file-name is set to attach a previously entered file name if
 688   ;; the currently entered file is a directory.  This code takes care of that.
 689   (setq dir1 (if (file-directory-p dir1) dir1 (file-name-directory dir1))
 690         dir2 (if (file-directory-p dir2) dir2 (file-name-directory dir2)))
 691
 692   (if (stringp dir3)
 693       (setq dir3 (if (file-directory-p dir3) dir3 (file-name-directory dir3))))
 694
 695   (cond ((string= dir1 dir2)
 696          (error "Directories A and B are the same: %s" dir1))
 697         ((and (eq jobname 'ediff-directories3)
 698               (string= dir1 dir3))
 699          (error "Directories A and C are the same: %s" dir1))
 700         ((and (eq jobname 'ediff-directories3)
 701               (string= dir2 dir3))
 702          (error "Directories B and C are the same: %s" dir1)))
 703
 704   (if merge-autostore-dir
 705       (or (stringp merge-autostore-dir)
 706           (error "%s: Directory for storing merged files must be a string"
 707                  jobname)))
 708   (let (;; dir-diff-struct is of the form (common-list diff-list)
 709         ;; It is a structure where ediff-intersect-directories returns
 710         ;; commonalities and differences among directories
 711         dir-diff-struct
 712         meta-buf)
 713     (if (and ediff-autostore-merges
 714              (ediff-merge-metajob jobname)
 715              (not merge-autostore-dir))
 716         (setq merge-autostore-dir
 717               (read-file-name "Save merged files in directory: "
 718                               (if ediff-use-last-dir
 719                                         ediff-last-merge-autostore-dir
 720                                       (ediff-strip-last-dir dir1))
 721                               nil
 722                               'must-match)))
 723     ;; verify we are not merging into an orig directory
 724     (if merge-autostore-dir
 725         (cond ((and (stringp dir1) (string= merge-autostore-dir dir1))
 726                (or (y-or-n-p
 727                     "Directory for saving merged files = Directory A.  Sure? ")
 728                    (error "Directory merge aborted")))
 729               ((and (stringp dir2) (string= merge-autostore-dir dir2))
 730                (or (y-or-n-p
 731                     "Directory for saving merged files = Directory B.  Sure? ")
 732                    (error "Directory merge aborted")))
 733               ((and (stringp dir3) (string= merge-autostore-dir dir3))
 734                (or (y-or-n-p
 735                     "Directory for saving merged files = Ancestor Directory.  Sure? ")
 736                    (error "Directory merge aborted")))))
 737
 738     (setq dir-diff-struct (ediff-intersect-directories
 739                            jobname
 740                            regexp dir1 dir2 dir3 merge-autostore-dir))
 741     (setq startup-hooks
 742           ;; this sets various vars in the meta buffer inside
 743           ;; ediff-prepare-meta-buffer
 744           (cons `(lambda ()
 745                    ;; tell what to do if the user clicks on a session record
 746                    (setq ediff-session-action-function (quote ,action))
 747                    ;; set ediff-dir-difference-list
 748                    (setq ediff-dir-difference-list
 749                          (cdr (quote ,dir-diff-struct))))
 750                 startup-hooks))
 751     (setq meta-buf (ediff-prepare-meta-buffer
 752                     'ediff-filegroup-action
 753                     (car dir-diff-struct)
 754                     "*Ediff Session Group Panel"
 755                     'ediff-redraw-directory-group-buffer
 756                     jobname
 757                     startup-hooks))
 758     (ediff-show-meta-buffer meta-buf)
 759     ))
 760
 761 ;; MERGE-AUTOSTORE-DIR can be given to tell ediff where to store the merged
 762 ;; files
 763 (defun ediff-directory-revisions-internal (dir1 regexp action jobname
 764                                                 &optional startup-hooks
 765                                                 merge-autostore-dir)
 766   (setq dir1 (if (file-directory-p dir1) dir1 (file-name-directory dir1)))
 767
 768   (if merge-autostore-dir
 769       (or (stringp merge-autostore-dir)
 770           (error "%S: Directory for storing merged files must be a string"
 771                  jobname)))
 772   (let (file-list meta-buf)
 773     (if (and ediff-autostore-merges
 774              (ediff-merge-metajob jobname)
 775              (not merge-autostore-dir))
 776         (setq merge-autostore-dir
 777               (read-file-name "Save merged files in directory: "
 778                               (if ediff-use-last-dir
 779                                   ediff-last-merge-autostore-dir
 780                                 (ediff-strip-last-dir dir1))
 781                               nil
 782                               'must-match)))
 783     ;; verify merge-autostore-dir != dir1
 784     (if (and merge-autostore-dir
 785              (stringp dir1)
 786              (string= merge-autostore-dir dir1))
 787         (or (y-or-n-p
 788              "Directory for saving merged file = directory A.  Sure? ")
 789             (error "Merge of directory revisions aborted")))
 790
 791     (setq file-list
 792           (ediff-get-directory-files-under-revision
 793            jobname regexp dir1 merge-autostore-dir))
 794     (setq startup-hooks
 795           ;; this sets various vars in the meta buffer inside
 796           ;; ediff-prepare-meta-buffer
 797           (cons `(lambda ()
 798                    ;; tell what to do if the user clicks on a session record
 799                    (setq ediff-session-action-function (quote ,action)))
 800                 startup-hooks))
 801     (setq meta-buf (ediff-prepare-meta-buffer
 802                     'ediff-filegroup-action
 803                     file-list
 804                     "*Ediff Session Group Panel"
 805                     'ediff-redraw-directory-group-buffer
 806                     jobname
 807                     startup-hooks))
 808     (ediff-show-meta-buffer meta-buf)
 809     ))
 810
 811
 812 ;;; Compare regions and windows
 813
 814 ;;;###autoload
 815 (defun ediff-windows-wordwise (dumb-mode &optional wind-A wind-B startup-hooks)
 816   "Compare WIND-A and WIND-B, which are selected by clicking, wordwise.
 817 With prefix argument, DUMB-MODE, or on a non-windowing display, works as
 818 follows:
 819 If WIND-A is nil, use selected window.
 820 If WIND-B is nil, use window next to WIND-A."
 821   (interactive "P")
 822   (ediff-windows dumb-mode wind-A wind-B
 823                  startup-hooks 'ediff-windows-wordwise 'word-mode))
 824
 825 ;;;###autoload
 826 (defun ediff-windows-linewise (dumb-mode &optional wind-A wind-B startup-hooks)
 827   "Compare WIND-A and WIND-B, which are selected by clicking, linewise.
 828 With prefix argument, DUMB-MODE, or on a non-windowing display, works as
 829 follows:
 830 If WIND-A is nil, use selected window.
 831 If WIND-B is nil, use window next to WIND-A."
 832   (interactive "P")
 833   (ediff-windows dumb-mode wind-A wind-B
 834                  startup-hooks 'ediff-windows-linewise nil))
 835
 836 ;; Compare WIND-A and WIND-B, which are selected by clicking.
 837 ;; With prefix argument, DUMB-MODE, or on a non-windowing display,
 838 ;; works as follows:
 839 ;; If WIND-A is nil, use selected window.
 840 ;; If WIND-B is nil, use window next to WIND-A.
 841 (defun ediff-windows (dumb-mode wind-A wind-B startup-hooks job-name word-mode)
 842   (if (or dumb-mode (not (ediff-window-display-p)))
 843       (setq wind-A (ediff-get-next-window wind-A nil)
 844             wind-B (ediff-get-next-window wind-B wind-A))
 845     (setq wind-A (ediff-get-window-by-clicking wind-A nil 1)
 846           wind-B (ediff-get-window-by-clicking wind-B wind-A 2)))
 847
 848   (let ((buffer-A (window-buffer wind-A))
 849         (buffer-B (window-buffer wind-B))
 850         beg-A end-A beg-B end-B)
 851
 852     (save-excursion
 853       (save-window-excursion
 854         (sit-for 0) ; sync before using window-start/end -- a precaution
 855         (select-window wind-A)
 856         (setq beg-A (window-start)
 857               end-A (window-end))
 858         (select-window wind-B)
 859         (setq beg-B (window-start)
 860               end-B (window-end))))
 861     (setq buffer-A
 862           (ediff-clone-buffer-for-window-comparison
 863            buffer-A wind-A "-Window.A-")
 864           buffer-B
 865           (ediff-clone-buffer-for-window-comparison
 866            buffer-B wind-B "-Window.B-"))
 867     (ediff-regions-internal
 868      buffer-A beg-A end-A buffer-B beg-B end-B
 869      startup-hooks job-name word-mode nil)))
 870
 871
 872 ;;;###autoload
 873 (defun ediff-regions-wordwise (buffer-A buffer-B &optional startup-hooks)
 874   "Run Ediff on a pair of regions in specified buffers.
 875 Regions \(i.e., point and mark\) are assumed to be set in advance except
 876 for the second region in the case both regions are from the same buffer.
 877 In such a case the user is asked to interactively establish the second
 878 region.
 879 This function is effective only for relatively small regions, up to 200
 880 lines.  For large regions, use `ediff-regions-linewise'."
 881   (interactive
 882    (let (bf)
 883      (list (setq bf (read-buffer "Region's A buffer: "
 884                                  (ediff-other-buffer "") t))
 885            (read-buffer "Region's B buffer: "
 886                         (progn
 887                           ;; realign buffers so that two visible bufs will be
 888                           ;; at the top
 889                           (save-window-excursion (other-window 1))
 890                           (ediff-other-buffer bf))
 891                         t))))
 892   (if (not (ediff-buffer-live-p buffer-A))
 893       (error "Buffer %S doesn't exist" buffer-A))
 894   (if (not (ediff-buffer-live-p buffer-B))
 895       (error "Buffer %S doesn't exist" buffer-B))
 896
 897
 898   (let ((buffer-A
 899          (ediff-clone-buffer-for-region-comparison buffer-A "-Region.A-"))
 900         (buffer-B
 901          (ediff-clone-buffer-for-region-comparison buffer-B "-Region.B-"))
 902         reg-A-beg reg-A-end reg-B-beg reg-B-end)
 903     (save-excursion
 904       (set-buffer buffer-A)
 905       (setq reg-A-beg (region-beginning)
 906             reg-A-end (region-end))
 907       (set-buffer buffer-B)
 908       (setq reg-B-beg (region-beginning)
 909             reg-B-end (region-end)))
 910
 911     (ediff-regions-internal
 912      (get-buffer buffer-A) reg-A-beg reg-A-end
 913      (get-buffer buffer-B) reg-B-beg reg-B-end
 914      startup-hooks 'ediff-regions-wordwise 'word-mode nil)))
 915
 916 ;;;###autoload
 917 (defun ediff-regions-linewise (buffer-A buffer-B &optional startup-hooks)
 918   "Run Ediff on a pair of regions in specified buffers.
 919 Regions \(i.e., point and mark\) are assumed to be set in advance except
 920 for the second region in the case both regions are from the same buffer.
 921 In such a case the user is asked to interactively establish the second
 922 region.
 923 Each region is enlarged to contain full lines.
 924 This function is effective for large regions, over 100-200
 925 lines.  For small regions, use `ediff-regions-wordwise'."
 926   (interactive
 927    (let (bf)
 928      (list (setq bf (read-buffer "Region A's buffer: "
 929                                  (ediff-other-buffer "") t))
 930            (read-buffer "Region B's buffer: "
 931                         (progn
 932                           ;; realign buffers so that two visible bufs will be
 933                           ;; at the top
 934                           (save-window-excursion (other-window 1))
 935                           (ediff-other-buffer bf))
 936                         t))))
 937   (if (not (ediff-buffer-live-p buffer-A))
 938       (error "Buffer %S doesn't exist" buffer-A))
 939   (if (not (ediff-buffer-live-p buffer-B))
 940       (error "Buffer %S doesn't exist" buffer-B))
 941
 942   (let ((buffer-A
 943          (ediff-clone-buffer-for-region-comparison buffer-A "-Region.A-"))
 944         (buffer-B
 945          (ediff-clone-buffer-for-region-comparison buffer-B "-Region.B-"))
 946         reg-A-beg reg-A-end reg-B-beg reg-B-end)
 947     (save-excursion
 948       (set-buffer buffer-A)
 949       (setq reg-A-beg (region-beginning)
 950             reg-A-end (region-end))
 951       ;; enlarge the region to hold full lines
 952       (goto-char reg-A-beg)
 953       (beginning-of-line)
 954       (setq reg-A-beg (point))
 955       (goto-char reg-A-end)
 956       (end-of-line)
 957       (or (eobp) (forward-char)) ; include the newline char
 958       (setq reg-A-end (point))
 959
 960       (set-buffer buffer-B)
 961       (setq reg-B-beg (region-beginning)
 962             reg-B-end (region-end))
 963       ;; enlarge the region to hold full lines
 964       (goto-char reg-B-beg)
 965       (beginning-of-line)
 966       (setq reg-B-beg (point))
 967       (goto-char reg-B-end)
 968       (end-of-line)
 969       (or (eobp) (forward-char)) ; include the newline char
 970       (setq reg-B-end (point))
 971       ) ; save excursion
 972
 973     (ediff-regions-internal
 974      (get-buffer buffer-A) reg-A-beg reg-A-end
 975      (get-buffer buffer-B) reg-B-beg reg-B-end
 976      startup-hooks 'ediff-regions-linewise nil nil))) ; no word mode
 977
 978 ;; compare region beg-A to end-A of buffer-A
 979 ;; to regions beg-B -- end-B in buffer-B.
 980 (defun ediff-regions-internal (buffer-A beg-A end-A buffer-B beg-B end-B
 981                                         startup-hooks job-name word-mode
 982                                         setup-parameters)
 983   (let ((tmp-buffer (get-buffer-create ediff-tmp-buffer))
 984         overl-A overl-B
 985         file-A file-B)
 986
 987     ;; in case beg/end-A/B aren't markers--make them into markers
 988     (ediff-with-current-buffer buffer-A
 989       (setq beg-A (move-marker (make-marker) beg-A)
 990             end-A (move-marker (make-marker) end-A)))
 991     (ediff-with-current-buffer buffer-B
 992       (setq beg-B (move-marker (make-marker) beg-B)
 993             end-B (move-marker (make-marker) end-B)))
 994
 995     ;; make file-A
 996     (if word-mode
 997         (ediff-wordify beg-A end-A buffer-A tmp-buffer)
 998       (ediff-copy-to-buffer beg-A end-A buffer-A tmp-buffer))
 999     (setq file-A (ediff-make-temp-file tmp-buffer "regA"))
1000
1001     ;; make file-B
1002     (if word-mode
1003         (ediff-wordify beg-B end-B buffer-B tmp-buffer)
1004       (ediff-copy-to-buffer beg-B end-B buffer-B tmp-buffer))
1005     (setq file-B (ediff-make-temp-file tmp-buffer "regB"))
1006
1007     (setq overl-A (ediff-make-bullet-proof-overlay beg-A end-A buffer-A))
1008     (setq overl-B (ediff-make-bullet-proof-overlay beg-B end-B buffer-B))
1009     (ediff-setup buffer-A file-A
1010                  buffer-B file-B
1011                  nil nil            ; buffer & file C
1012                  (cons `(lambda ()
1013                             (delete-file ,file-A)
1014                             (delete-file ,file-B))
1015                        startup-hooks)
1016                  (append
1017                   (list (cons 'ediff-word-mode  word-mode)
1018                         (cons 'ediff-narrow-bounds (list overl-A overl-B))
1019                         (cons 'ediff-job-name job-name))
1020                   setup-parameters))
1021     ))
1022
1023
1024 ;;; Merge files and buffers
1025
1026 ;;;###autoload
1027 (defalias 'ediff-merge 'ediff-merge-files)
1028
1029 (defsubst ediff-merge-on-startup ()
1030   (ediff-do-merge 0)
1031   (ediff-with-current-buffer ediff-buffer-C
1032     (set-buffer-modified-p nil)))
1033
1034 ;;;###autoload
1035 (defun ediff-merge-files (file-A file-B
1036                                  ;; MERGE-BUFFER-FILE is the file to be
1037                                  ;; associated with the merge buffer
1038                                  &optional startup-hooks merge-buffer-file)
1039   "Merge two files without ancestor."
1040   (interactive
1041    (let ((dir-A (if ediff-use-last-dir
1042                     ediff-last-dir-A
1043                   default-directory))
1044          dir-B f)
1045      (list (setq f (ediff-read-file-name
1046                     "File A to merge"
1047                     dir-A
1048                     (ediff-get-default-file-name)
1049                     'no-dirs))
1050            (ediff-read-file-name "File B to merge"
1051                                  (setq dir-B
1052                                        (if ediff-use-last-dir
1053                                            ediff-last-dir-B
1054                                          (file-name-directory f)))
1055                                  (progn
1056                                    (setq file-name-history
1057                                          (cons (ediff-abbreviate-file-name
1058                                                 (expand-file-name
1059                                                  (file-name-nondirectory f)
1060                                                  dir-B))
1061                                                file-name-history))
1062                                    (ediff-get-default-file-name f 1)))
1063            )))
1064   (setq startup-hooks (cons 'ediff-merge-on-startup startup-hooks))
1065   (ediff-files-internal file-A
1066                         (if (file-directory-p file-B)
1067                             (expand-file-name
1068                              (file-name-nondirectory file-A) file-B)
1069                           file-B)
1070                           nil ; file-C
1071                           startup-hooks
1072                           'ediff-merge-files
1073                           merge-buffer-file))
1074
1075 ;;;###autoload
1076 (defun ediff-merge-files-with-ancestor (file-A file-B file-ancestor
1077                                                &optional
1078                                                startup-hooks
1079                                                ;; MERGE-BUFFER-FILE is the file
1080                                                ;; to be associated with the
1081                                                ;; merge buffer
1082                                                merge-buffer-file)
1083   "Merge two files with ancestor."
1084   (interactive
1085    (let ((dir-A (if ediff-use-last-dir
1086                     ediff-last-dir-A
1087                   default-directory))
1088          dir-B dir-ancestor f ff)
1089      (list (setq f (ediff-read-file-name
1090                     "File A to merge"
1091                     dir-A
1092                     (ediff-get-default-file-name)
1093                     'no-dirs))
1094            (setq ff (ediff-read-file-name "File B to merge"
1095                                           (setq dir-B
1096                                                 (if ediff-use-last-dir
1097                                                     ediff-last-dir-B
1098                                                   (file-name-directory f)))
1099                                           (progn
1100                                             (setq file-name-history
1101                                                   (cons
1102                                                    (ediff-abbreviate-file-name
1103                                                     (expand-file-name
1104                                                      (file-name-nondirectory f)
1105                                                      dir-B))
1106                                                    file-name-history))
1107                                             (ediff-get-default-file-name f 1))))
1108            (ediff-read-file-name "Ancestor file"
1109                                  (setq dir-ancestor
1110                                        (if ediff-use-last-dir
1111                                            ediff-last-dir-ancestor
1112                                          (file-name-directory ff)))
1113                                  (progn
1114                                    (setq file-name-history
1115                                          (cons (ediff-abbreviate-file-name
1116                                                 (expand-file-name
1117                                                  (file-name-nondirectory ff)
1118                                                  dir-ancestor))
1119                                                file-name-history))
1120                                    (ediff-get-default-file-name ff 2)))
1121            )))
1122   (setq startup-hooks (cons 'ediff-merge-on-startup startup-hooks))
1123   (ediff-files-internal file-A
1124                         (if (file-directory-p file-B)
1125                             (expand-file-name
1126                              (file-name-nondirectory file-A) file-B)
1127                           file-B)
1128                           file-ancestor
1129                           startup-hooks
1130                           'ediff-merge-files-with-ancestor
1131                           merge-buffer-file))
1132
1133 ;;;###autoload
1134 (defalias 'ediff-merge-with-ancestor 'ediff-merge-files-with-ancestor)
1135
1136 ;;;###autoload
1137 (defun ediff-merge-buffers (buffer-A buffer-B
1138                                      &optional
1139                                      ;; MERGE-BUFFER-FILE is the file to be
1140                                      ;; associated with the merge buffer
1141                                      startup-hooks job-name merge-buffer-file)
1142   "Merge buffers without ancestor."
1143   (interactive
1144    (let (bf)
1145      (list (setq bf (read-buffer "Buffer A to merge: "
1146                                  (ediff-other-buffer "") t))
1147            (read-buffer "Buffer B to merge: "
1148                         (progn
1149                           ;; realign buffers so that two visible bufs will be
1150                           ;; at the top
1151                           (save-window-excursion (other-window 1))
1152                           (ediff-other-buffer bf))
1153                         t))))
1154
1155   (setq startup-hooks (cons 'ediff-merge-on-startup startup-hooks))
1156   (or job-name (setq job-name 'ediff-merge-buffers))
1157   (ediff-buffers-internal
1158    buffer-A buffer-B nil startup-hooks job-name merge-buffer-file))
1159
1160 ;;;###autoload
1161 (defun ediff-merge-buffers-with-ancestor (buffer-A buffer-B buffer-ancestor
1162                                                    &optional
1163                                                    startup-hooks
1164                                                    job-name
1165                                                    ;; MERGE-BUFFER-FILE is the
1166                                                    ;; file to be associated
1167                                                    ;; with the merge buffer
1168                                                    merge-buffer-file)
1169   "Merge buffers with ancestor."
1170   (interactive
1171    (let (bf bff)
1172      (list (setq bf (read-buffer "Buffer A to merge: "
1173                                  (ediff-other-buffer "") t))
1174            (setq bff (read-buffer "Buffer B to merge: "
1175                                   (progn
1176                                     ;; realign buffers so that two visible
1177                                     ;; bufs will be at the top
1178                                     (save-window-excursion (other-window 1))
1179                                     (ediff-other-buffer bf))
1180                                   t))
1181            (read-buffer "Ancestor buffer: "
1182                                   (progn
1183                                     ;; realign buffers so that three visible
1184                                     ;; bufs will be at the top
1185                                     (save-window-excursion (other-window 1))
1186                                     (ediff-other-buffer (list bf bff)))
1187                                   t)
1188            )))
1189
1190   (setq startup-hooks (cons 'ediff-merge-on-startup startup-hooks))
1191   (or job-name (setq job-name 'ediff-merge-buffers-with-ancestor))
1192   (ediff-buffers-internal
1193    buffer-A buffer-B buffer-ancestor startup-hooks job-name merge-buffer-file))
1194
1195
1196 ;;;###autoload
1197 (defun ediff-merge-revisions (&optional file startup-hooks merge-buffer-file)
1198   ;; MERGE-BUFFER-FILE is the file to be associated with the merge buffer
1199   "Run Ediff by merging two revisions of a file.
1200 The file is the optional FILE argument or the file visited by the current
1201 buffer."
1202   (interactive)
1203   (if (stringp file) (find-file file))
1204   (let (rev1 rev2)
1205     (setq rev1
1206           (read-string
1207            (format
1208             "Version 1 to merge (default: %s's working version): "
1209             (if (stringp file)
1210                 (file-name-nondirectory file) "current buffer")))
1211           rev2
1212           (read-string
1213            (format
1214             "Version 2 to merge (default: %s): "
1215             (if (stringp file)
1216                 (file-name-nondirectory file) "current buffer"))))
1217     (ediff-load-version-control)
1218     ;; ancestor-revision=nil
1219     (funcall
1220      (intern (format "ediff-%S-merge-internal" ediff-version-control-package))
1221      rev1 rev2 nil startup-hooks merge-buffer-file)))
1222
1223
1224 ;;;###autoload
1225 (defun ediff-merge-revisions-with-ancestor (&optional
1226                                             file startup-hooks
1227                                             ;; MERGE-BUFFER-FILE is the file to
1228                                             ;; be associated with the merge
1229                                             ;; buffer
1230                                             merge-buffer-file)
1231   "Run Ediff by merging two revisions of a file with a common ancestor.
1232 The file is the optional FILE argument or the file visited by the current
1233 buffer."
1234   (interactive)
1235   (if (stringp file) (find-file file))
1236   (let (rev1 rev2 ancestor-rev)
1237     (setq rev1
1238           (read-string
1239            (format
1240             "Version 1 to merge (default: %s's working version): "
1241             (if (stringp file)
1242                 (file-name-nondirectory file) "current buffer")))
1243           rev2
1244           (read-string
1245            (format
1246             "Version 2 to merge (default: %s): "
1247             (if (stringp file)
1248                 (file-name-nondirectory file) "current buffer")))
1249           ancestor-rev
1250           (read-string
1251            (format
1252             "Ancestor version (default: %s's base revision): "
1253             (if (stringp file)
1254                 (file-name-nondirectory file) "current buffer"))))
1255     (ediff-load-version-control)
1256     (funcall
1257      (intern (format "ediff-%S-merge-internal" ediff-version-control-package))
1258      rev1 rev2 ancestor-rev startup-hooks merge-buffer-file)))
1259
1260 ;; MK: Check. This function doesn't seem to be used any more by pcvs or pcl-cvs
1261 ;;;###autoload
1262 (defun run-ediff-from-cvs-buffer (pos)
1263   "Run Ediff-merge on appropriate revisions of the selected file.
1264 First run after `M-x cvs-update'.  Then place the cursor on a line describing a
1265 file and then run `run-ediff-from-cvs-buffer'."
1266   (interactive "d")
1267   (ediff-load-version-control)
1268   (let ((tin (tin-locate cvs-cookie-handle pos)))
1269     (if tin
1270         (cvs-run-ediff-on-file-descriptor tin)
1271       (error "There is no file to merge"))))
1272
1273
1274 ;;; Apply patch
1275
1276 ;;;###autoload
1277 (defun ediff-patch-file (&optional arg patch-buf)
1278   "Run Ediff by patching SOURCE-FILENAME.
1279 If optional PATCH-BUF is given, use the patch in that buffer
1280 and don't ask the user.
1281 If prefix argument, then: if even argument, assume that the patch is in a
1282 buffer. If odd -- assume it is in a file."
1283   (interactive "P")
1284   (let (source-dir source-file)
1285     (require 'ediff-ptch)
1286     (setq patch-buf
1287           (ediff-get-patch-buffer
1288            (if arg (prefix-numeric-value arg)) patch-buf))
1289     (setq source-dir (cond (ediff-use-last-dir ediff-last-dir-patch)
1290                            ((and (not ediff-patch-default-directory)
1291                                  (buffer-file-name patch-buf))
1292                             (file-name-directory
1293                              (expand-file-name
1294                               (buffer-file-name patch-buf))))
1295                            (t default-directory)))
1296     (setq source-file
1297           (read-file-name
1298            "File to patch (directory, if multifile patch): "
1299            ;; use an explicit initial file
1300            source-dir nil nil (ediff-get-default-file-name)))
1301     (ediff-dispatch-file-patching-job patch-buf source-file)))
1302
1303 ;;;###autoload
1304 (defun ediff-patch-buffer (&optional arg patch-buf)
1305   "Run Ediff by patching BUFFER-NAME.
1306 Without prefix argument: asks if the patch is in some buffer and prompts for
1307 the buffer or a file, depending on the answer.
1308 With prefix arg=1: assumes the patch is in a file and prompts for the file.
1309 With prefix arg=2: assumes the patch is in a buffer and prompts for the buffer."
1310   (interactive "P")
1311   (require 'ediff-ptch)
1312   (setq patch-buf
1313         (ediff-get-patch-buffer
1314          (if arg (prefix-numeric-value arg)) patch-buf))
1315   (ediff-patch-buffer-internal
1316    patch-buf
1317    (read-buffer
1318     "Which buffer to patch? "
1319     (current-buffer))))
1320
1321
1322 ;;;###autoload
1323 (defalias 'epatch 'ediff-patch-file)
1324 ;;;###autoload
1325 (defalias 'epatch-buffer 'ediff-patch-buffer)
1326
1327
1328
1329 \f
1330 ;;; Versions Control functions
1331
1332 ;;;###autoload
1333 (defun ediff-revision (&optional file startup-hooks)
1334   "Run Ediff by comparing versions of a file.
1335 The file is an optional FILE argument or the file entered at the prompt.
1336 Default: the file visited by the current buffer.
1337 Uses `vc.el' or `rcs.el' depending on `ediff-version-control-package'."
1338   ;; if buffer is non-nil, use that buffer instead of the current buffer
1339   (interactive "P")
1340   (if (not (stringp file))
1341     (setq file
1342           (ediff-read-file-name "Compare revisions for file"
1343                                 (if ediff-use-last-dir
1344                                     ediff-last-dir-A
1345                                   default-directory)
1346                                 (ediff-get-default-file-name)
1347                                 'no-dirs)))
1348   (find-file file)
1349   (if (and (buffer-modified-p)
1350            (y-or-n-p (message "Buffer %s is modified. Save buffer? "
1351                               (buffer-name))))
1352       (save-buffer (current-buffer)))
1353   (let (rev1 rev2)
1354     (setq rev1
1355           (read-string
1356            (format "Revision 1 to compare (default: %s's latest revision): "
1357                    (file-name-nondirectory file)))
1358           rev2
1359           (read-string
1360            (format "Revision 2 to compare (default: %s's current state): "
1361                    (file-name-nondirectory file))))
1362     (ediff-load-version-control)
1363     (funcall
1364      (intern (format "ediff-%S-internal" ediff-version-control-package))
1365      rev1 rev2 startup-hooks)
1366     ))
1367
1368
1369 ;;;###autoload
1370 (defalias 'erevision 'ediff-revision)
1371
1372
1373 ;; Test if version control package is loaded and load if not
1374 ;; Is SILENT is non-nil, don't report error if package is not found.
1375 (defun ediff-load-version-control (&optional silent)
1376   (require 'ediff-vers)
1377   (or (featurep ediff-version-control-package)
1378       (if (locate-library (symbol-name ediff-version-control-package))
1379           (progn
1380             (message "") ; kill the message from `locate-library'
1381             (require ediff-version-control-package))
1382         (or silent
1383             (error "Version control package %S.el not found.  Use vc.el instead"
1384                    ediff-version-control-package)))))
1385
1386
1387 ;;;###autoload
1388 (defun ediff-version ()
1389   "Return string describing the version of Ediff.
1390 When called interactively, displays the version."
1391   (interactive)
1392   (if (interactive-p)
1393       (message (ediff-version))
1394     (format "Ediff %s of %s" ediff-version ediff-date)))
1395
1396
1397 ;;;###autoload
1398 (defun ediff-documentation (&optional node)
1399   "Display Ediff's manual.
1400 With optional NODE, goes to that node."
1401   (interactive)
1402   (let ((ctl-window ediff-control-window)
1403         (ctl-buf ediff-control-buffer))
1404
1405     (ediff-skip-unsuitable-frames)
1406     (condition-case nil
1407         (progn
1408           (pop-to-buffer (get-buffer-create "*info*"))
1409           (info (if ediff-xemacs-p "ediff.info" "ediff"))
1410           (if node
1411               (Info-goto-node node)
1412             (message "Type `i' to search for a specific topic"))
1413           (raise-frame (selected-frame)))
1414       (error (beep 1)
1415              (with-output-to-temp-buffer ediff-msg-buffer
1416                (ediff-with-current-buffer standard-output
1417                  (fundamental-mode))
1418                (princ ediff-BAD-INFO))
1419              (if (window-live-p ctl-window)
1420                  (progn
1421                    (select-window ctl-window)
1422                    (set-window-buffer ctl-window ctl-buf)))))))
1423
1424
1425
1426
1427 ;;; Local Variables:
1428 ;;; eval: (put 'ediff-defvar-local 'lisp-indent-hook 'defun)
1429 ;;; eval: (put 'ediff-with-current-buffer 'lisp-indent-hook 1)
1430 ;;; eval: (put 'ediff-with-current-buffer 'edebug-form-spec '(form body))
1431 ;;; End:
1432
1433 (require 'ediff-util)
1434
1435 (run-hooks 'ediff-load-hook)
1436
1437 ;;; ediff.el ends here