configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 dnl FIXME hesiod support may not be present, so it seems like an error
  95 dnl to define, or at least use, this unconditionally.
  96 if test "$with_hesiod" != no; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 101 if test "$with_mmdf" != no; then
 102    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 106 if test "$with_mail_unlink" != no; then
 107    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 108 fi
 109
 110 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 111     [string giving default POP mail host])],
 112     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 113
 114 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 115
 116 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 117 if test "$with_sync_input" = yes; then
 118    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 119 fi
 120
 121 dnl FIXME currently it is not the last.
 122 dnl This should be the last --with option, because --with-x is
 123 dnl added later on when we find the path of X, and it's best to
 124 dnl keep them together visually.
 125 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 126  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 127 [         case "${withval}" in
 128             y | ye | yes )      val=gtk ;;
 129             n | no )            val=no  ;;
 130             l | lu | luc | luci | lucid )       val=lucid ;;
 131             a | at | ath | athe | athen | athena )      val=athena ;;
 132             m | mo | mot | moti | motif )       val=motif ;;
 133             g | gt | gtk  )     val=gtk ;;
 134             * )
 135 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 136 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 137 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 138             ;;
 139           esac
 140           with_x_toolkit=$val
 141 ])
 142
 143 dnl _ON results in a '--without' option in the --help output, so
 144 dnl the help text should refer to "don't compile", etc.
 145 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 146 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 147 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 148 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 149 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 150 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 151
 152 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 153 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 154 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 155
 156 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 157 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 158 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 159 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 160
 161 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 162 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 163 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 164 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 165
 166 ## For the times when you want to build Emacs but don't have
 167 ## a suitable makeinfo, and can live without the manuals.
 168 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 169 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 170
 171 dnl Can remove these in Emacs 24.
 172 AC_ARG_WITH([gtk],,
 173   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 174 specify a toolkit.])],,)
 175
 176 AC_ARG_WITH([gcc],,
 177   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 178 variable to specify a compiler.])],,)
 179
 180 AC_ARG_WITH([pkg-config-prog],dnl
 181 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 182                   [path to pkg-config for finding GTK and librsvg])])
 183 if test "X${with_pkg_config_prog}" != X; then
 184    if test "${with_pkg_config_prog}" != yes; then
 185       PKG_CONFIG="${with_pkg_config_prog}"
 186    fi
 187 fi
 188
 189 CRT_DIR=
 190 AC_ARG_WITH([crt-dir],dnl
 191 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 192 This option is only used on x86-64 and s390x GNU/Linux architectures.])])
 193 CRT_DIR="${with_crt_dir}"
 194
 195 AC_ARG_WITH([gnustep-conf],dnl
 196 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 197 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 198   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 199 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 200      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 201
 202 AC_ARG_ENABLE(ns-self-contained,
 203 [AS_HELP_STRING([--disable-ns-self-contained],
 204                 [disable self contained build under NeXTstep])],
 205    EN_NS_SELF_CONTAINED=$enableval,
 206    EN_NS_SELF_CONTAINED=yes)
 207
 208 AC_ARG_ENABLE(asserts,
 209 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 210       USE_XASSERTS=$enableval,
 211       USE_XASSERTS=no)
 212
 213 AC_ARG_ENABLE(maintainer-mode,
 214 [AS_HELP_STRING([--enable-maintainer-mode],
 215                 [enable make rules and dependencies not useful (and sometimes
 216                  confusing) to the casual installer])],
 217       USE_MAINTAINER_MODE=$enableval,
 218       USE_MAINTAINER_MODE=no)
 219 if test $USE_MAINTAINER_MODE = yes; then
 220   MAINT=
 221 else
 222   MAINT=#
 223 fi
 224 AC_SUBST(MAINT)
 225
 226 AC_ARG_ENABLE(locallisppath,
 227 [AS_HELP_STRING([--enable-locallisppath=PATH],
 228                 [directories Emacs should search for lisp files specific
 229                  to this site])],
 230 if test "${enableval}" = "no"; then
 231   locallisppath=
 232 elif test "${enableval}" != "yes"; then
 233   locallisppath=${enableval}
 234 fi)
 235
 236 AC_ARG_ENABLE(checking,
 237 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 238                 [enable expensive run-time checks.  With LIST,
 239                  enable only specific categories of checks.
 240                  Categories are: all,yes,no.
 241                  Flags are: stringbytes, stringoverrun, stringfreelist,
 242                  xmallocoverrun, conslist])],
 243 [ac_checking_flags="${enableval}"],[])
 244 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 245 for check in $ac_checking_flags
 246 do
 247         case $check in
 248         # these set all the flags to specific states
 249         yes)            ac_enable_checking=1 ;;
 250         no)             ac_enable_checking= ;
 251                         ac_gc_check_stringbytes= ;
 252                         ac_gc_check_string_overrun= ;
 253                         ac_gc_check_string_free_list= ;
 254                         ac_xmalloc_overrun= ;
 255                         ac_gc_check_cons_list= ;;
 256         all)            ac_enable_checking=1 ;
 257                         ac_gc_check_stringbytes=1 ;
 258                         ac_gc_check_string_overrun=1 ;
 259                         ac_gc_check_string_free_list=1 ;
 260                         ac_xmalloc_overrun=1 ;
 261                         ac_gc_check_cons_list=1 ;;
 262         # these enable particular checks
 263         stringbytes)    ac_gc_check_stringbytes=1 ;;
 264         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 265         stringfreelist) ac_gc_check_string_free_list=1 ;;
 266         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 267         conslist)       ac_gc_check_cons_list=1 ;;
 268         *)      AC_MSG_ERROR(unknown check category $check) ;;
 269         esac
 270 done
 271 IFS="$ac_save_IFS"
 272
 273 if test x$ac_enable_checking != x ; then
 274   AC_DEFINE(ENABLE_CHECKING, 1,
 275 [Enable expensive run-time checking of data types?])
 276 fi
 277 if test x$ac_gc_check_stringbytes != x ; then
 278   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 279 [Define this temporarily to hunt a bug.  If defined, the size of
 280    strings is redundantly recorded in sdata structures so that it can
 281    be compared to the sizes recorded in Lisp strings.])
 282 fi
 283 if test x$ac_gc_check_stringoverrun != x ; then
 284   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 285 [Define this to check for short string overrun.])
 286 fi
 287 if test x$ac_gc_check_string_free_list != x ; then
 288   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 289 [Define this to check the string free list.])
 290 fi
 291 if test x$ac_xmalloc_overrun != x ; then
 292   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 293 [Define this to check for malloc buffer overrun.])
 294 fi
 295 if test x$ac_gc_check_cons_list != x ; then
 296   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 297 [Define this to check for errors in cons list.])
 298 fi
 299
 300 AC_ARG_ENABLE(profiling,
 301 [AS_HELP_STRING([--enable-profiling],
 302                 [build emacs with profiling support.
 303                  This might not work on all platforms])],
 304 [ac_enable_profiling="${enableval}"],[])
 305 if test x$ac_enable_profiling != x ; then
 306    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 307    PROFILING_LDFLAGS="-pg"
 308 else
 309    PROFILING_CFLAGS=
 310    PROFILING_LDFLAGS=
 311 fi
 312
 313 AC_ARG_ENABLE(autodepend,
 314 [AS_HELP_STRING([--enable-autodepend],
 315                 [automatically generate dependencies to .h-files.
 316                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 317                  found])],
 318 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 319
 320 #### Make srcdir absolute, if it isn't already.  It's important to
 321 #### avoid running the path through pwd unnecessarily, since pwd can
 322 #### give you automounter prefixes, which can go away.  We do all this
 323 #### so Emacs can find its files when run uninstalled.
 324 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 325 unset CDPATH
 326 case "${srcdir}" in
 327   /* ) ;;
 328   . )
 329     ## We may be able to use the $PWD environment variable to make this
 330     ## absolute.  But sometimes PWD is inaccurate.
 331     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 332     ## but that tested only for a well-formed and valid PWD,
 333     ## it did not object when PWD was well-formed and valid but just wrong.
 334     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 335     then
 336       srcdir="$PWD"
 337     else
 338       srcdir="`(cd ${srcdir}; pwd)`"
 339     fi
 340   ;;
 341   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 342 esac
 343
 344 #### Check if the source directory already has a configured system in it.
 345 if test `pwd` != `(cd ${srcdir} && pwd)` \
 346    && test -f "${srcdir}/src/config.h" ; then
 347   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 348    as a build directory right now; it has been configured in its own
 349    right.  To configure in another directory as well, you MUST
 350    use GNU make.  If you do not have GNU make, then you must
 351    now do `make distclean' in ${srcdir},
 352    and then run $0 again.]])
 353 fi
 354
 355 #### Given the configuration name, set machfile and opsysfile to the
 356 #### names of the m/*.h and s/*.h files we should use.
 357
 358 ### Canonicalize the configuration name.
 359
 360 AC_CANONICAL_HOST
 361 canonical=$host
 362 configuration=${host_alias-${build_alias-$host}}
 363
 364 dnl This used to use changequote, but, apart from `changequote is evil'
 365 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 366 dnl the great gob of text.  Thus it's not processed for possible expansion.
 367 dnl Just make sure the brackets remain balanced.
 368 dnl
 369 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 370 dnl indicated by comments.
 371 dnl quotation begins
 372 [
 373
 374 ### If you add support for a new configuration, add code to this
 375 ### switch statement to recognize your configuration name and select
 376 ### the appropriate operating system and machine description files.
 377
 378 ### You would hope that you could choose an m/*.h file pretty much
 379 ### based on the machine portion of the configuration name, and an s-
 380 ### file based on the operating system portion.  However, it turns out
 381 ### that each m/*.h file is pretty manufacturer-specific - for
 382 ### example mips.h is MIPS
 383 ### So we basically have to have a special case for each
 384 ### configuration name.
 385 ###
 386 ### As far as handling version numbers on operating systems is
 387 ### concerned, make sure things will fail in a fixable way.  If
 388 ### /etc/MACHINES doesn't say anything about version numbers, be
 389 ### prepared to handle anything reasonably.  If version numbers
 390 ### matter, be sure /etc/MACHINES says something about it.
 391 ###
 392 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 393 ### "System V Release 4"; he writes, "The old convention encouraged
 394 ### confusion between `system' and `release' levels'."
 395
 396 machine='' opsys='' unported=no
 397 case "${canonical}" in
 398
 399   ## FreeBSD ports
 400   *-*-freebsd* )
 401     opsys=freebsd
 402     case "${canonical}" in
 403       alpha*-*-freebsd*)        machine=alpha ;;
 404       arm*-*-freebsd*)          machine=arm ;;
 405       ia64-*-freebsd*)          machine=ia64 ;;
 406       sparc-*-freebsd*)         machine=sparc ;;
 407       sparc64-*-freebsd*)       machine=sparc ;;
 408       powerpc-*-freebsd*)       machine=macppc ;;
 409       i[3456]86-*-freebsd*)     machine=intel386 ;;
 410       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 411     esac
 412   ;;
 413
 414   ## FreeBSD kernel + glibc based userland
 415   *-*-kfreebsd*gnu* )
 416     opsys=gnu-kfreebsd
 417     case "${canonical}" in
 418       alpha*-*-kfreebsd*)       machine=alpha ;;
 419       ia64-*-kfreebsd*)         machine=ia64 ;;
 420       sparc-*-kfreebsd*)        machine=sparc ;;
 421       sparc64-*-kfreebsd*)      machine=sparc ;;
 422       powerpc-*-kfreebsd*)      machine=macppc ;;
 423       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 424       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 425     esac
 426   ;;
 427
 428   ## NetBSD ports
 429   *-*-netbsd* )
 430     opsys=netbsd
 431     if test -f /usr/lib/crti.o; then]
 432 dnl The close and open brackets here are because this section is quoted --
 433 dnl see the `changequote' comment above.
 434       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 435 [   fi
 436
 437     case "${canonical}" in
 438       alpha*-*-netbsd*) machine=alpha ;;
 439       i[3456]86-*-netbsd*) machine=intel386 ;;
 440       mips-*-netbsd*)   machine=mips ;;
 441       mipsel-*-netbsd*) machine=mips ;;
 442       mipseb-*-netbsd*) machine=mips ;;
 443       powerpc-*-netbsd*) machine=macppc ;;
 444       sparc*-*-netbsd*) machine=sparc ;;
 445       vax-*-netbsd*)    machine=vax ;;
 446       arm-*-netbsd*)    machine=arm ;;
 447       x86_64-*-netbsd*) machine=amdx86-64 ;;
 448       hppa-*-netbsd*)   machine=hp800 ;;
 449       m68k-*-netbsd*)   machine=m68k ;;
 450     esac
 451   ;;
 452
 453   ## OpenBSD ports
 454   *-*-openbsd* )
 455     opsys=openbsd
 456     case "${canonical}" in
 457       alpha*-*-openbsd*)        machine=alpha ;;
 458       arm-*-openbsd*)          machine=arm ;;
 459       i386-*-openbsd*)         machine=intel386 ;;
 460       powerpc-*-openbsd*)      machine=macppc ;;
 461       sparc*-*-openbsd*)       machine=sparc ;;
 462       vax-*-openbsd*)          machine=vax ;;
 463       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 464       hppa-*-openbsd*)         machine=hp800 ;;
 465     esac
 466   ;;
 467
 468   alpha*-*-linux-gnu* )
 469     machine=alpha opsys=gnu-linux
 470   ;;
 471
 472   arm*-*-linux-gnu* )
 473     machine=arm opsys=gnu-linux
 474   ;;
 475
 476   ## Apple Darwin / Mac OS X
 477   *-apple-darwin* )
 478     case "${canonical}" in
 479       i[3456]86-* )  machine=intel386 ;;
 480       powerpc-* )    machine=macppc ;;
 481       x86_64-* )     machine=amdx86-64 ;;
 482       * )            unported=yes ;;
 483     esac
 484     opsys=darwin
 485     # Define CPP as follows to make autoconf work correctly.
 486     CPP="${CC-cc} -E -no-cpp-precomp"
 487     # Use fink packages if available.
 488     if test -d /sw/include && test -d /sw/lib; then
 489       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 490       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 491       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 492     fi
 493   ;;
 494
 495   ## HP 9000 series 700 and 800, running HP/UX
 496   hppa*-hp-hpux10.2* )
 497     machine=hp800 opsys=hpux10-20
 498   ;;
 499   hppa*-hp-hpux1[1-9]* )
 500     machine=hp800 opsys=hpux11
 501     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 502   ;;
 503
 504   hppa*-*-linux-gnu* )
 505     machine=hp800 opsys=gnu-linux
 506   ;;
 507
 508   ## IBM machines
 509   s390-*-linux-gnu* )
 510     machine=ibms390 opsys=gnu-linux
 511   ;;
 512   s390x-*-linux-gnu* )
 513     machine=ibms390x opsys=gnu-linux
 514   ;;
 515   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 522     machine=ibmrs6000 opsys=aix4-2
 523   ;;
 524   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 525     machine=ibmrs6000 opsys=aix4-2
 526   ;;
 527
 528   ## Macintosh PowerPC
 529   powerpc*-*-linux-gnu* )
 530     machine=macppc opsys=gnu-linux
 531   ;;
 532
 533   ## Silicon Graphics machines
 534   ## Iris 4D
 535   mips-sgi-irix6.5 )
 536     machine=iris4d opsys=irix6-5
 537     # Without defining _LANGUAGE_C, things get masked out in the headers
 538     # so that, for instance, grepping for `free' in stdlib.h fails and
 539     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 540     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 541     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 542   ;;
 543
 544   ## Suns
 545   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 546     machine=sparc opsys=gnu-linux
 547   ;;
 548
 549   *-sun-solaris* \
 550     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 551     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 552     case "${canonical}" in
 553       i[3456]86-*-* )     machine=intel386 ;;
 554       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 555       sparc* )          machine=sparc ;;
 556       * )               unported=yes ;;
 557     esac
 558     case "${canonical}" in
 559       *-sunos5.6* | *-solaris2.6* )
 560                 opsys=sol2-6
 561                 NON_GNU_CPP=/usr/ccs/lib/cpp
 562                 RANLIB="ar -ts"
 563                 ;;
 564       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 565                 opsys=sol2-6
 566                 emacs_check_sunpro_c=yes
 567                 NON_GNU_CPP=/usr/ccs/lib/cpp
 568                 ;;
 569       *-sunos5* | *-solaris* )
 570                 opsys=sol2-10
 571                 emacs_check_sunpro_c=yes
 572                 NON_GNU_CPP=/usr/ccs/lib/cpp
 573                 ;;
 574     esac
 575     ## Watch out for a compiler that we know will not work.
 576     case "${canonical}" in
 577      *-solaris* | *-sunos5* )
 578                 if [ "x$CC" = x/usr/ucb/cc ]; then
 579                   ## /usr/ucb/cc doesn't work;
 580                   ## we should find some other compiler that does work.
 581                   unset CC
 582                 fi
 583                 ;;
 584       *) ;;
 585     esac
 586   ;;
 587
 588   ## IA-64
 589   ia64*-*-linux* )
 590     machine=ia64 opsys=gnu-linux
 591   ;;
 592
 593   ## Intel 386 machines where we don't care about the manufacturer
 594   i[3456]86-*-* )
 595     machine=intel386
 596     case "${canonical}" in
 597       *-cygwin )                opsys=cygwin ;;
 598       *-darwin* )               opsys=darwin
 599                                 CPP="${CC-cc} -E -no-cpp-precomp"
 600                                 ;;
 601       *-linux-gnu* )            opsys=gnu-linux ;;
 602       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 603       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 604       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 605       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 606     esac
 607   ;;
 608
 609   ## m68k Linux-based GNU system
 610   m68k-*-linux-gnu* )
 611     machine=m68k opsys=gnu-linux
 612   ;;
 613
 614   ## Mips Linux-based GNU system
 615   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 616     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 617     machine=mips opsys=gnu-linux
 618   ;;
 619
 620   ## AMD x86-64 Linux-based GNU system
 621   x86_64-*-linux-gnu* )
 622     machine=amdx86-64 opsys=gnu-linux
 623   ;;
 624
 625   ## Tensilica Xtensa Linux-based GNU system
 626   xtensa*-*-linux-gnu* )
 627     machine=xtensa opsys=gnu-linux
 628     ;;
 629
 630   ## SuperH Linux-based GNU system
 631   sh[34]*-*-linux-gnu* )
 632     machine=sh3 opsys=gnu-linux
 633   ;;
 634
 635   * )
 636     unported=yes
 637   ;;
 638 esac
 639
 640 ### If the code above didn't choose an operating system, just choose
 641 ### an operating system based on the configuration name.  You really
 642 ### only want to use this when you have no idea what the right
 643 ### operating system is; if you know what operating systems a machine
 644 ### runs, it's cleaner to make it explicit in the case statement
 645 ### above.
 646 if test x"${opsys}" = x; then
 647   case "${canonical}" in
 648     *-gnu* )                            opsys=gnu ;;
 649     * )
 650       unported=yes
 651     ;;
 652   esac
 653 fi
 654
 655 ]
 656 dnl quotation ends
 657
 658 if test $unported = yes; then
 659   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 660 Check `etc/MACHINES' for recognized configuration names.])
 661 fi
 662
 663 machfile="m/${machine}.h"
 664 opsysfile="s/${opsys}.h"
 665
 666
 667 #### Choose a compiler.
 668 test -n "$CC" && cc_specified=yes
 669
 670 # Save the value of CFLAGS that the user specified.
 671 SPECIFIED_CFLAGS="$CFLAGS"
 672
 673 dnl Sets GCC=yes if using gcc.
 674 AC_PROG_CC
 675
 676 # On Suns, sometimes $CPP names a directory.
 677 if test -n "$CPP" && test -d "$CPP"; then
 678   CPP=
 679 fi
 680
 681 ## If not using gcc, and on Solaris, and no CPP specified, see if
 682 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 683 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 684  test x"$CPP" = x; then
 685   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 686   AC_CACHE_VAL(emacs_cv_sunpro_c,
 687   [AC_TRY_LINK([],
 688 [#ifndef __SUNPRO_C
 689 fail;
 690 #endif
 691 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 692   AC_MSG_RESULT($emacs_cv_sunpro_c)
 693
 694   if test x"$emacs_cv_sunpro_c" = xyes; then
 695     NON_GNU_CPP="$CC -E -Xs"
 696   fi
 697 fi
 698
 699 #### Some systems specify a CPP to use unless we are using GCC.
 700 #### Now that we know whether we are using GCC, we can decide whether
 701 #### to use that one.
 702 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 703 then
 704   CPP="$NON_GNU_CPP"
 705 fi
 706
 707 #### Some systems specify a CC to use unless we are using GCC.
 708 #### Now that we know whether we are using GCC, we can decide whether
 709 #### to use that one.
 710 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 711   test x$cc_specified != xyes
 712 then
 713   CC="$NON_GNU_CC"
 714 fi
 715
 716 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 717 then
 718   CC="$CC $GCC_TEST_OPTIONS"
 719 fi
 720
 721 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 722 then
 723   CC="$CC $NON_GCC_TEST_OPTIONS"
 724 fi
 725
 726 dnl checks for Unix variants
 727 AC_USE_SYSTEM_EXTENSIONS
 728
 729 ### Use -Wno-pointer-sign if the compiler supports it
 730 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 731 SAVE_CFLAGS="$CFLAGS"
 732 CFLAGS="$CFLAGS -Wno-pointer-sign"
 733 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 734 if test $has_option = yes; then
 735    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 736 fi
 737 AC_MSG_RESULT($has_option)
 738 CFLAGS="$SAVE_CFLAGS"
 739 unset has_option
 740 unset SAVE_CFLAGS
 741
 742 ### Use -Wdeclaration-after-statement if the compiler supports it
 743 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 744 SAVE_CFLAGS="$CFLAGS"
 745 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 746 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 747 if test $has_option = yes; then
 748    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 749 fi
 750 AC_MSG_RESULT($has_option)
 751 CFLAGS="$SAVE_CFLAGS"
 752 unset has_option
 753 unset SAVE_CFLAGS
 754
 755 #### Some other nice autoconf tests.
 756
 757 dnl checks for programs
 758 AC_PROG_LN_S
 759 AC_PROG_CPP
 760 AC_PROG_INSTALL
 761 if test "x$RANLIB" = x; then
 762   AC_PROG_RANLIB
 763 fi
 764 AC_PATH_PROG(INSTALL_INFO, install-info)
 765 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 766 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 767 dnl Don't use GZIP, which is used by gzip for additional parameters.
 768 AC_PATH_PROG(GZIP_PROG, gzip)
 769
 770
 771 ## Need makeinfo >= 4.6 (?) to build the manuals.
 772 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 773 dnl By this stage, configure has already checked for egrep and set EGREP,
 774 dnl or exited with an error if no egrep was found.
 775 if test "$MAKEINFO" != "no" && \
 776   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 777    MAKEINFO=no
 778 fi
 779
 780 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 781 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 782 ## therefore in the category of "special tools" not normally required, which
 783 ## configure does not have to check for (eg autoconf itself).
 784 ## In a Bazaar checkout on the other hand, the manuals are not included.
 785 ## So makeinfo is a requirement to build from Bazaar, and configure
 786 ## should test for it as it does for any other build requirement.
 787 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 788 ## with pre-built manuals, from a Bazaar checkout.
 789 if test "$MAKEINFO" = "no"; then
 790   if test "x${with_makeinfo}" = "xno"; then
 791     MAKEINFO=off
 792   elif test ! -e $srcdir/info/emacs; then
 793     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 794 source tree does not seem to have pre-built manuals in the `info' directory.
 795 Either install a suitable version of makeinfo, or re-run configure
 796 with the `--without-makeinfo' option to build without the manuals.] )
 797   fi
 798 fi
 799
 800 dnl Add our options to ac_link now, after it is set up.
 801
 802 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 803 then
 804   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 805 fi
 806
 807 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 808 then
 809   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 810 fi
 811
 812 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 813 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 814 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 815 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 816 dnl if not built to support GNU ld.
 817
 818 late_LDFLAGS=$LDFLAGS
 819 if test "$GCC" = yes; then
 820   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 821 else
 822   LDFLAGS="$LDFLAGS -znocombreloc"
 823 fi
 824
 825 AC_MSG_CHECKING([for -znocombreloc])
 826 AC_LINK_IFELSE([main(){return 0;}],
 827   [AC_MSG_RESULT(yes)],
 828   LDFLAGS=$late_LDFLAGS
 829   [AC_MSG_RESULT(no)])
 830
 831 #### Extract some information from the operating system and machine files.
 832
 833 AC_CHECKING([the machine- and system-dependent files to find out
 834  - which libraries the lib-src programs will want, and
 835  - whether the GNU malloc routines are usable])
 836
 837 ### First figure out CFLAGS (which we use for running the compiler here)
 838 ### and REAL_CFLAGS (which we use for real compilation).
 839 ### The two are the same except on a few systems, where they are made
 840 ### different to work around various lossages.  For example,
 841 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 842 ### as implying static linking.
 843
 844 ### If the CFLAGS env var is specified, we use that value
 845 ### instead of the default.
 846
 847 ### It's not important that this name contain the PID; you can't run
 848 ### two configures in the same directory and have anything work
 849 ### anyway.
 850 tempcname="conftest.c"
 851
 852 echo '
 853 #include "'${srcdir}'/src/'${opsysfile}'"
 854 #include "'${srcdir}'/src/'${machfile}'"
 855 #ifndef LIBS_MACHINE
 856 #define LIBS_MACHINE
 857 #endif
 858 #ifndef LIBS_SYSTEM
 859 #define LIBS_SYSTEM
 860 #endif
 861 #ifndef C_SWITCH_SYSTEM
 862 #define C_SWITCH_SYSTEM
 863 #endif
 864 #ifndef C_SWITCH_MACHINE
 865 #define C_SWITCH_MACHINE
 866 #endif
 867 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 868 configure___ c_switch_system=C_SWITCH_SYSTEM
 869 configure___ c_switch_machine=C_SWITCH_MACHINE
 870
 871 #ifndef LIB_X11_LIB
 872 #define LIB_X11_LIB -lX11
 873 #endif
 874
 875 configure___ LIBX=LIB_X11_LIB
 876
 877 #ifdef UNEXEC
 878 configure___ unexec=UNEXEC
 879 #else
 880 configure___ unexec=unexec.o
 881 #endif
 882
 883 #ifdef SYSTEM_MALLOC
 884 configure___ system_malloc=yes
 885 #else
 886 configure___ system_malloc=no
 887 #endif
 888
 889 #ifdef USE_MMAP_FOR_BUFFERS
 890 configure___ use_mmap_for_buffers=yes
 891 #else
 892 configure___ use_mmap_for_buffers=no
 893 #endif
 894
 895 #ifndef C_OPTIMIZE_SWITCH
 896 #ifdef __GNUC__
 897 #define C_OPTIMIZE_SWITCH -O2
 898 #else
 899 #define C_OPTIMIZE_SWITCH -O
 900 #endif
 901 #endif
 902
 903 #ifndef C_WARNINGS_SWITCH
 904 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 905 #endif
 906
 907 #ifndef LD_SWITCH_MACHINE
 908 #define LD_SWITCH_MACHINE
 909 #endif
 910
 911 #ifndef LD_SWITCH_SYSTEM
 912 #define LD_SWITCH_SYSTEM
 913 #endif
 914
 915 #ifndef LD_SWITCH_X_SITE_AUX
 916 #define LD_SWITCH_X_SITE_AUX
 917 #endif
 918
 919 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 920 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 921
 922 #ifdef THIS_IS_CONFIGURE
 923
 924 /* Get the CFLAGS for tests in configure.  */
 925 #ifdef __GNUC__
 926 configure___ CFLAGS=-g C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 927 #else
 928 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 929 #endif
 930
 931 #else /* not THIS_IS_CONFIGURE */
 932
 933 /* Get the CFLAGS for real compilation.  */
 934 #ifdef __GNUC__
 935 configure___ REAL_CFLAGS=-g C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 936 #else
 937 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 938 #endif
 939
 940 #endif /* not THIS_IS_CONFIGURE */
 941 ' > ${tempcname}
 942
 943 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 944
 945 # The value of CPP is a quoted variable reference, so we need to do this
 946 # to get its actual value...
 947 CPP=`eval "echo $CPP"`
 948 [eval `${CPP} -Isrc ${tempcname} \
 949        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 950 if test "x$SPECIFIED_CFLAGS" = x; then
 951   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 952          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 953 else
 954   REAL_CFLAGS="$CFLAGS"
 955 fi]
 956 rm ${tempcname}
 957
 958 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 959
 960 ### Make sure subsequent tests use flags consistent with the build flags.
 961
 962 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 963   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 964 else
 965   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 966 fi
 967
 968 dnl For AC_FUNC_GETLOADAVG, at least:
 969 AC_CONFIG_LIBOBJ_DIR(src)
 970
 971 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 972 AC_SYS_LARGEFILE
 973
 974
 975 ## Note: at present CRT_DIR is only used for amdx86-64 and ibms390x.
 976 ## Other machine types hard-code the location in src/[ms]/*.h.
 977 case "${canonical}" in
 978   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 979
 980    ## On x86-64 and s390x GNU/Linux distributions, the standard library
 981    ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
 982    ## For anything else (eg /usr/lib32), it is up the user to specify
 983    ## the location (bug#5655).
 984    ## Test for crtn.o, not just the directory, because sometimes the
 985    ## directory exists but does not have the relevant files (bug#1287).
 986    ## If user specified a crt-dir, use that unconditionally.
 987    if test "X$CRT_DIR" = "X"; then
 988      CRT_DIR=/usr/lib
 989      test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
 990    fi
 991
 992    test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
 993      AC_MSG_ERROR([crt*.o not found.  Use --with-crt-dir to specify the location.])
 994    ;;
 995
 996 esac
 997 test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
 998 AC_SUBST(CRT_DIR)
 999
1000
1001 dnl This function defintion taken from Gnome 2.0
1002 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1003 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1004 dnl also defines GSTUFF_PKG_ERRORS on error
1005 AC_DEFUN([PKG_CHECK_MODULES], [
1006   succeeded=no
1007
1008   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1009
1010   if test "$PKG_CONFIG" = "no" ; then
1011      ifelse([$4], , [AC_MSG_ERROR([
1012       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1013   else
1014      PKG_CONFIG_MIN_VERSION=0.9.0
1015      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1016         AC_MSG_CHECKING(for $2)
1017
1018         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1019             AC_MSG_RESULT(yes)
1020             succeeded=yes
1021
1022             AC_MSG_CHECKING($1_CFLAGS)
1023             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1024             AC_MSG_RESULT($$1_CFLAGS)
1025
1026             AC_MSG_CHECKING($1_LIBS)
1027             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1028             AC_MSG_RESULT($$1_LIBS)
1029         else
1030             AC_MSG_RESULT(no)
1031             $1_CFLAGS=""
1032             $1_LIBS=""
1033             ## If we have a custom action on failure, don't print errors, but
1034             ## do set a variable so people can do so.
1035             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1036             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1037         fi
1038
1039         AC_SUBST($1_CFLAGS)
1040         AC_SUBST($1_LIBS)
1041      else
1042         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1043         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1044      fi
1045   fi
1046
1047   if test $succeeded = yes; then
1048      ifelse([$3], , :, [$3])
1049   else
1050      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1051   fi
1052 ])
1053
1054
1055 if test "${with_sound}" != "no"; then
1056   # Sound support for GNU/Linux and the free BSDs.
1057   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1058   # Emulation library used on NetBSD.
1059   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1060   AC_SUBST(LIBSOUND)
1061
1062   ALSA_REQUIRED=1.0.0
1063   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1064   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1065   if test $HAVE_ALSA = yes; then
1066     SAVE_CFLAGS="$CFLAGS"
1067     SAVE_LDFLAGS="$LDFLAGS"
1068     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1069     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1070     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1071                     emacs_alsa_normal=yes,
1072                     emacs_alsa_normal=no)
1073     if test "$emacs_alsa_normal" != yes; then
1074       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1075                      [snd_lib_error_set_handler (0);],
1076                      emacs_alsa_subdir=yes,
1077                      emacs_alsa_subdir=no)
1078       if test "$emacs_alsa_subdir" != yes; then
1079         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1080       fi
1081       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1082     fi
1083
1084     CFLAGS="$SAVE_CFLAGS"
1085     LDFLAGS="$SAVE_LDFLAGS"
1086     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1087     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1088     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1089   fi
1090   AC_SUBST(CFLAGS_SOUND)
1091 fi
1092
1093 dnl checks for header files
1094 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1095   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1096   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1097   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1098   sys/utsname.h pwd.h utmp.h)
1099
1100 AC_MSG_CHECKING(if personality LINUX32 can be set)
1101 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1102                emacs_cv_personality_linux32=yes,
1103                emacs_cv_personality_linux32=no)
1104 AC_MSG_RESULT($emacs_cv_personality_linux32)
1105
1106 if test $emacs_cv_personality_linux32 = yes; then
1107   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1108             [Define to 1 if personality LINUX32 can be set.])
1109 fi
1110
1111 dnl On Solaris 8 there's a compilation warning for term.h because
1112 dnl it doesn't define `bool'.
1113 AC_CHECK_HEADERS(term.h, , , -)
1114 AC_HEADER_STDC
1115 AC_HEADER_TIME
1116 AC_CHECK_DECLS([sys_siglist])
1117 if test $ac_cv_have_decl_sys_siglist != yes; then
1118   # For Tru64, at least:
1119   AC_CHECK_DECLS([__sys_siglist])
1120   if test $ac_cv_have_decl___sys_siglist = yes; then
1121     AC_DEFINE(sys_siglist, __sys_siglist,
1122               [Define to any substitute for sys_siglist.])
1123   fi
1124 fi
1125 AC_HEADER_SYS_WAIT
1126
1127 dnl Some systems have utime.h but don't declare the struct anyplace.
1128 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1129 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1130 #include <sys/time.h>
1131 #include <time.h>
1132 #else
1133 #ifdef HAVE_SYS_TIME_H
1134 #include <sys/time.h>
1135 #else
1136 #include <time.h>
1137 #endif
1138 #endif
1139 #ifdef HAVE_UTIME_H
1140 #include <utime.h>
1141 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1142   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1143 if test $emacs_cv_struct_utimbuf = yes; then
1144   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1145 fi
1146
1147 dnl checks for typedefs
1148 AC_TYPE_SIGNAL
1149
1150 dnl Check for speed_t typedef.
1151 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1152   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1153     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1154 if test $emacs_cv_speed_t = yes; then
1155   AC_DEFINE(HAVE_SPEED_T, 1,
1156            [Define to 1 if `speed_t' is declared by <termios.h>.])
1157 fi
1158
1159 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1160 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1161 #include <sys/time.h>
1162 #include <time.h>
1163 #else
1164 #ifdef HAVE_SYS_TIME_H
1165 #include <sys/time.h>
1166 #else
1167 #include <time.h>
1168 #endif
1169 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1170   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1171 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1172 if test $emacs_cv_struct_timeval = yes; then
1173   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1174 fi
1175
1176 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1177 AC_TRY_COMPILE([#include <math.h>],
1178 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1179   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1180 HAVE_EXCEPTION=$emacs_cv_struct_exception
1181 if test $emacs_cv_struct_exception != yes; then
1182   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1183 fi
1184
1185 AC_CHECK_HEADERS(sys/socket.h)
1186 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1187 #if HAVE_SYS_SOCKET_H
1188 #include <sys/socket.h>
1189 #endif])
1190
1191 dnl checks for structure members
1192 AC_STRUCT_TM
1193 AC_STRUCT_TIMEZONE
1194 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1195                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1196                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1197                 [#include <time.h>])
1198 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1199                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1200                   struct ifreq.ifr_addr], , ,
1201                  [AC_INCLUDES_DEFAULT
1202 #if HAVE_SYS_SOCKET_H
1203 #include <sys/socket.h>
1204 #endif
1205 #if HAVE_NET_IF_H
1206 #include <net/if.h>
1207 #endif])
1208
1209 dnl checks for compiler characteristics
1210
1211 dnl Testing __STDC__ to determine prototype support isn't good enough.
1212 dnl DEC C, for instance, doesn't define it with default options, and
1213 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1214 dnl and void *.
1215 AC_C_PROTOTYPES
1216 AC_C_VOLATILE
1217 AC_C_CONST
1218 dnl This isn't useful because we can't turn on use of `inline' unless
1219 dnl the compiler groks `extern inline'.
1220 dnl AC_C_INLINE
1221 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1222   [AC_TRY_COMPILE(, [void * foo;],
1223                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1224 if test $emacs_cv_void_star = yes; then
1225   AC_DEFINE(POINTER_TYPE, void)
1226 else
1227   AC_DEFINE(POINTER_TYPE, char)
1228 fi
1229 AH_TEMPLATE(POINTER_TYPE,
1230             [Define as `void' if your compiler accepts `void *'; otherwise
1231              define as `char'.])dnl
1232
1233
1234
1235 dnl This could be used for targets which can have both byte sexes.
1236 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1237 dnl AC_C_BIGENDIAN
1238
1239 dnl check for Make feature
1240 AC_PROG_MAKE_SET
1241
1242 dnl check for GNU Make if we have GCC and autodepend is on.
1243 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1244    AC_MSG_CHECKING([whether we are using GNU Make])
1245    HAVE_GNU_MAKE=no
1246    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1247    if test "x$testval" != x; then
1248       HAVE_GNU_MAKE=yes
1249    else
1250       ac_enable_autodepend=no
1251    fi
1252    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1253    if test $HAVE_GNU_MAKE = yes; then
1254       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1255       SAVE_CFLAGS="$CFLAGS"
1256       CFLAGS="$CFLAGS -MMD -MF deps.d"
1257       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1258       CFLAGS="$SAVE_CFLAGS"
1259       test -f deps.d || ac_enable_autodepend=no
1260       rm -rf deps.d
1261       AC_MSG_RESULT([$ac_enable_autodepend])
1262    fi
1263    if test $ac_enable_autodepend = yes; then
1264       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1265    fi
1266 fi
1267
1268 dnl checks for operating system services
1269 AC_SYS_LONG_FILE_NAMES
1270
1271 #### Choose a window system.
1272
1273 AC_PATH_X
1274 if test "$no_x" = yes; then
1275   window_system=none
1276 else
1277   window_system=x11
1278 fi
1279
1280 ## Workaround for bug in autoconf <= 2.62.
1281 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1282 ## No need to do anything special for these standard directories.
1283 ## This is an experiment, take it out if it causes problems.
1284 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1285
1286    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1287
1288 fi
1289
1290 if test "${x_libraries}" != NONE; then
1291   if test -n "${x_libraries}"; then
1292     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1293     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1294   fi
1295   x_default_search_path=""
1296   x_search_path=${x_libraries}
1297   if test -z "${x_search_path}"; then
1298     x_search_path=/usr/lib
1299   fi
1300   for x_library in `echo ${x_search_path}: | \
1301                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1302     x_search_path="\
1303 ${x_library}/X11/%L/%T/%N%C%S:\
1304 ${x_library}/X11/%l/%T/%N%C%S:\
1305 ${x_library}/X11/%T/%N%C%S:\
1306 ${x_library}/X11/%L/%T/%N%S:\
1307 ${x_library}/X11/%l/%T/%N%S:\
1308 ${x_library}/X11/%T/%N%S"
1309     if test x"${x_default_search_path}" = x; then
1310       x_default_search_path=${x_search_path}
1311     else
1312       x_default_search_path="${x_search_path}:${x_default_search_path}"
1313     fi
1314   done
1315 fi
1316 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1317   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1318 fi
1319
1320 if test x"${x_includes}" = x; then
1321   bitmapdir=/usr/include/X11/bitmaps
1322 else
1323   # accumulate include directories that have X11 bitmap subdirectories
1324   bmd_acc="dummyval"
1325   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1326     if test -d "${bmd}/X11/bitmaps"; then
1327       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1328     fi
1329     if test -d "${bmd}/bitmaps"; then
1330       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1331     fi
1332   done
1333   if test ${bmd_acc} != "dummyval"; then
1334     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1335   fi
1336 fi
1337
1338 HAVE_NS=no
1339 NS_IMPL_COCOA=no
1340 NS_IMPL_GNUSTEP=no
1341 tmp_CPPFLAGS="$CPPFLAGS"
1342 tmp_CFLAGS="$CFLAGS"
1343 CPPFLAGS="$CPPFLAGS -x objective-c"
1344 CFLAGS="$CFLAGS -x objective-c"
1345 if test "${with_ns}" != no; then
1346   if test "${opsys}" = darwin; then
1347      NS_IMPL_COCOA=yes
1348      ns_appdir=`pwd`/nextstep/Emacs.app
1349      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1350      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1351      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1352   elif test -f $GNUSTEP_CONFIG_FILE; then
1353      NS_IMPL_GNUSTEP=yes
1354      ns_appdir=`pwd`/nextstep/Emacs.app
1355      ns_appbindir=`pwd`/nextstep/Emacs.app
1356      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1357      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1358      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1359      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1360      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1361      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1362      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1363      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1364      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1365      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1366   fi
1367   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1368                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1369   files are missing or cannot be compiled.])])
1370   NS_HAVE_NSINTEGER=yes
1371   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1372                                      [NSInteger i;])],
1373                     ns_have_nsinteger=yes,
1374                     ns_have_nsinteger=no)
1375   if test $ns_have_nsinteger = no; then
1376     NS_HAVE_NSINTEGER=no
1377   fi
1378 fi
1379 if test "${HAVE_NS}" = yes; then
1380   window_system=nextstep
1381   with_xft=no
1382   # set up packaging dirs
1383   exec_prefix=${ns_appbindir}
1384   libexecdir=${ns_appbindir}/libexec
1385   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1386      prefix=${ns_appresdir}
1387   fi
1388 fi
1389 CFLAGS="$tmp_CFLAGS"
1390 CPPFLAGS="$tmp_CPPFLAGS"
1391
1392 case "${window_system}" in
1393   x11 )
1394     HAVE_X_WINDOWS=yes
1395     HAVE_X11=yes
1396     case "${with_x_toolkit}" in
1397       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1398       motif ) USE_X_TOOLKIT=MOTIF ;;
1399       gtk ) with_gtk=yes
1400 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1401 dnl USE_X_TOOLKIT is set.
1402             USE_X_TOOLKIT=none ;;
1403       no ) USE_X_TOOLKIT=none ;;
1404 dnl If user did not say whether to use a toolkit, make this decision later:
1405 dnl use the toolkit if we have gtk, or X11R5 or newer.
1406       * ) USE_X_TOOLKIT=maybe ;;
1407     esac
1408   ;;
1409   nextstep | none )
1410     HAVE_X_WINDOWS=no
1411     HAVE_X11=no
1412     USE_X_TOOLKIT=none
1413   ;;
1414 esac
1415
1416 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1417    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1418    if test "$HAVE_XSERVER" = true ||
1419       test -n "$DISPLAY" ||
1420       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1421         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1422 were found.  You should install the relevant development files for X
1423 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1424 sure you have development files for image handling, i.e.
1425 tiff, gif, jpeg, png and xpm.
1426 If you are sure you want Emacs compiled without X window support, pass
1427   --without-x
1428 to configure.])
1429    fi
1430 fi
1431
1432 ### If we're using X11, we should use the X menu package.
1433 HAVE_MENUS=no
1434 case ${HAVE_X11} in
1435   yes ) HAVE_MENUS=yes ;;
1436 esac
1437
1438 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1439 # Assume not, until told otherwise.
1440 GNU_MALLOC=yes
1441 doug_lea_malloc=yes
1442 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1443 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1444 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1445                emacs_cv_var___after_morecore_hook,
1446 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1447   emacs_cv_var___after_morecore_hook=yes,
1448   emacs_cv_var___after_morecore_hook=no)])
1449 if test $emacs_cv_var___after_morecore_hook = no; then
1450   doug_lea_malloc=no
1451 fi
1452 if test "${system_malloc}" = "yes"; then
1453   GNU_MALLOC=no
1454   GNU_MALLOC_reason="
1455     (The GNU allocators don't work with this system configuration.)"
1456 fi
1457 if test "$doug_lea_malloc" = "yes" ; then
1458   if test "$GNU_MALLOC" = yes ; then
1459     GNU_MALLOC_reason="
1460       (Using Doug Lea's new malloc from the GNU C Library.)"
1461   fi
1462   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1463             [Define to 1 if you are using the GNU C Library.])
1464 fi
1465
1466 if test x"${REL_ALLOC}" = x; then
1467   REL_ALLOC=${GNU_MALLOC}
1468 fi
1469
1470 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1471 dnl the system configuration file (s/*.h) to turn the use of mmap
1472 dnl in the relocating allocator on.
1473
1474 AC_FUNC_MMAP
1475 if test $use_mmap_for_buffers = yes; then
1476   REL_ALLOC=no
1477 fi
1478
1479 LIBS="$libsrc_libs $LIBS"
1480
1481 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1482 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1483 AC_CHECK_LIB(dnet, dnet_ntoa)
1484 dnl This causes -lresolv to get used in subsequent tests,
1485 dnl which causes failures on some systems such as HPUX 9.
1486 dnl AC_CHECK_LIB(resolv, gethostbyname)
1487
1488 dnl FIXME replace main with a function we actually want from this library.
1489 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1490
1491 AC_CHECK_LIB(pthreads, cma_open)
1492
1493 dnl Check for need for bigtoc support on IBM AIX
1494
1495 case ${host_os} in
1496 aix*)
1497   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1498     case $GCC in
1499     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1500     *) gdb_cv_bigtoc=-bbigtoc ;;
1501     esac
1502
1503     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1504     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1505   ])
1506   ;;
1507 esac
1508
1509 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1510 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1511 # REAL_CPPFLAGS later on.
1512
1513 REAL_CPPFLAGS="$CPPFLAGS"
1514
1515 if test "${HAVE_X11}" = "yes"; then
1516   DEFS="$C_SWITCH_X_SITE $DEFS"
1517   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1518   LIBS="$LIBX $LIBS"
1519   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1520   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1521
1522   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1523   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1524   # but it's more convenient here to set LD_RUN_PATH
1525   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1526   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1527     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1528     export LD_RUN_PATH
1529   fi
1530
1531   if test "${opsys}" = "gnu-linux"; then
1532     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1533     AC_TRY_LINK([],
1534      [XOpenDisplay ("foo");],
1535      [xlinux_first_failure=no],
1536      [xlinux_first_failure=yes])
1537     if test "${xlinux_first_failure}" = "yes"; then
1538       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1539       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1540       OLD_CPPFLAGS="$CPPFLAGS"
1541       OLD_LIBS="$LIBS"
1542       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1543       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1544       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1545       LIBS="$LIBS -b i486-linuxaout"
1546       AC_TRY_LINK([],
1547        [XOpenDisplay ("foo");],
1548        [xlinux_second_failure=no],
1549        [xlinux_second_failure=yes])
1550       if test "${xlinux_second_failure}" = "yes"; then
1551         # If we get the same failure with -b, there is no use adding -b.
1552         # So take it out.  This plays safe.
1553         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1554         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1555         CPPFLAGS="$OLD_CPPFLAGS"
1556         LIBS="$OLD_LIBS"
1557         AC_MSG_RESULT(no)
1558       else
1559         AC_MSG_RESULT(yes)
1560       fi
1561     else
1562       AC_MSG_RESULT(no)
1563     fi
1564   fi
1565
1566   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1567   # header files included from there.
1568   AC_MSG_CHECKING(for Xkb)
1569   AC_TRY_LINK([#include <X11/Xlib.h>
1570 #include <X11/XKBlib.h>],
1571         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1572         emacs_xkb=yes, emacs_xkb=no)
1573   AC_MSG_RESULT($emacs_xkb)
1574   if test $emacs_xkb = yes; then
1575     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1576   fi
1577
1578   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1579 XScreenNumberOfScreen XSetWMProtocols)
1580 fi
1581
1582 if test "${window_system}" = "x11"; then
1583   AC_MSG_CHECKING(X11 version 6)
1584   AC_CACHE_VAL(emacs_cv_x11_version_6,
1585   [AC_TRY_LINK([#include <X11/Xlib.h>],
1586 [#if XlibSpecificationRelease < 6
1587 fail;
1588 #endif
1589 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1590   if test $emacs_cv_x11_version_6 = yes; then
1591     AC_MSG_RESULT(6 or newer)
1592     AC_DEFINE(HAVE_X11R6, 1,
1593               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1594   else
1595     AC_MSG_RESULT(before 6)
1596   fi
1597 fi
1598
1599
1600 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1601 HAVE_RSVG=no
1602 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1603   if test "${with_rsvg}" != "no"; then
1604     RSVG_REQUIRED=2.11.0
1605     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1606
1607     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1608     AC_SUBST(RSVG_CFLAGS)
1609     AC_SUBST(RSVG_LIBS)
1610
1611     if test ".${RSVG_CFLAGS}" != "."; then
1612       HAVE_RSVG=yes
1613       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1614       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1615       LIBS="$RSVG_LIBS $LIBS"
1616     fi
1617   fi
1618 fi
1619
1620
1621 HAVE_GTK=no
1622 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1623   GLIB_REQUIRED=2.6
1624   GTK_REQUIRED=2.6
1625   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1626
1627   dnl Checks for libraries.
1628   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1629   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1630      AC_MSG_ERROR($GTK_PKG_ERRORS)
1631   fi
1632 fi
1633
1634
1635 GTK_OBJ=
1636 if test x"$pkg_check_gtk" = xyes; then
1637
1638   AC_SUBST(GTK_CFLAGS)
1639   AC_SUBST(GTK_LIBS)
1640   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1641   CFLAGS="$CFLAGS $GTK_CFLAGS"
1642   LIBS="$GTK_LIBS $LIBS"
1643   dnl Try to compile a simple GTK program.
1644   GTK_COMPILES=no
1645   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1646   if test "${GTK_COMPILES}" != "yes"; then
1647     if test "$USE_X_TOOLKIT" != "maybe"; then
1648       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1649     fi
1650   else
1651     HAVE_GTK=yes
1652     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1653     GTK_OBJ=gtkutil.o
1654     USE_X_TOOLKIT=none
1655     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1656       :
1657     else
1658       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1659        closing open displays.  This is no problem if you just use
1660        one display, but if you use more than one and close one of them
1661        Emacs may crash.]])
1662       sleep 3
1663     fi
1664   fi
1665
1666 fi
1667 AC_SUBST(GTK_OBJ)
1668
1669
1670 if test "${HAVE_GTK}" = "yes"; then
1671
1672   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1673   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1674   if test "$with_toolkit_scroll_bars" != no; then
1675     with_toolkit_scroll_bars=yes
1676   fi
1677
1678   dnl  Check if we can use multiple displays with this GTK version.
1679   dnl  If gdk_display_open exists, assume all others are there also.
1680   HAVE_GTK_MULTIDISPLAY=no
1681   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1682   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1683     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1684               [Define to 1 if GTK can handle more than one display.])
1685   fi
1686
1687   dnl  Check if we have the old file selection dialog declared and
1688   dnl  in the link library.  In 2.x it may be in the library,
1689   dnl  but not declared if deprecated featured has been selected out.
1690   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1691   HAVE_GTK_FILE_SELECTION=no
1692   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1693                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1694 #include <gtk/gtk.h>])
1695   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1696     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1697                    HAVE_GTK_FILE_SELECTION=no)
1698   fi
1699
1700   dnl  Check if we have the new file chooser dialog
1701   HAVE_GTK_FILE_CHOOSER=no
1702   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1703                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1704 #include <gtk/gtk.h>])
1705   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1706     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1707                    HAVE_GTK_FILE_CHOOSER=no)
1708   fi
1709
1710   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1711      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1712     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1713               [Define to 1 if GTK has both file selection and chooser dialog.])
1714   fi
1715
1716   dnl Check if pthreads are available.  Emacs only needs this when using
1717   dnl gtk_file_chooser under Gnome.
1718   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1719     HAVE_GTK_AND_PTHREAD=no
1720     AC_CHECK_HEADERS(pthread.h)
1721     if test "$ac_cv_header_pthread_h"; then
1722       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1723     fi
1724     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1725       case "${canonical}" in
1726         *-hpux*) ;;
1727         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1728       esac
1729       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1730                [Define to 1 if you have GTK and pthread (-lpthread).])
1731     fi
1732   fi
1733 fi
1734
1735 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1736 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1737 dnl also not configured.
1738 HAVE_DBUS=no
1739 DBUS_OBJ=
1740 if test "${with_dbus}" = "yes"; then
1741    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1742    if test "$HAVE_DBUS" = yes; then
1743      LIBS="$LIBS $DBUS_LIBS"
1744      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1745      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1746      DBUS_OBJ=dbusbind.o
1747    fi
1748 fi
1749 AC_SUBST(DBUS_OBJ)
1750
1751 dnl GConf has been tested under GNU/Linux only.
1752 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1753 HAVE_GCONF=no
1754 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1755    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1756    if test "$HAVE_GCONF" = yes; then
1757       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1758    fi
1759 fi
1760
1761 dnl SELinux is available for GNU/Linux only.
1762 HAVE_LIBSELINUX=no
1763 LIBSELINUX_LIBS=
1764 if test "${with_selinux}" = "yes"; then
1765    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1766    if test "$HAVE_LIBSELINUX" = yes; then
1767       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1768       LIBSELINUX_LIBS=-lselinux
1769    fi
1770 fi
1771 AC_SUBST(LIBSELINUX_LIBS)
1772
1773 dnl Do not put whitespace before the #include statements below.
1774 dnl Older compilers (eg sunos4 cc) choke on it.
1775 HAVE_XAW3D=no
1776 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1777   if test "$with_xaw3d" != no; then
1778     AC_MSG_CHECKING(for xaw3d)
1779     AC_CACHE_VAL(emacs_cv_xaw3d,
1780     [AC_TRY_LINK([
1781 #include <X11/Intrinsic.h>
1782 #include <X11/Xaw3d/Simple.h>],
1783       [],
1784       emacs_cv_xaw3d=yes,
1785       emacs_cv_xaw3d=no)])
1786   else
1787     emacs_cv_xaw3d=no
1788   fi
1789   if test $emacs_cv_xaw3d = yes; then
1790     AC_MSG_RESULT([yes; using Lucid toolkit])
1791     USE_X_TOOLKIT=LUCID
1792     HAVE_XAW3D=yes
1793     AC_DEFINE(HAVE_XAW3D, 1,
1794               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1795   else
1796     AC_MSG_RESULT(no)
1797     AC_MSG_CHECKING(for libXaw)
1798     AC_CACHE_VAL(emacs_cv_xaw,
1799     [AC_TRY_LINK([
1800 #include <X11/Intrinsic.h>
1801 #include <X11/Xaw/Simple.h>],
1802       [],
1803       emacs_cv_xaw=yes,
1804       emacs_cv_xaw=no)])
1805     if test $emacs_cv_xaw = yes; then
1806       AC_MSG_RESULT([yes; using Lucid toolkit])
1807       USE_X_TOOLKIT=LUCID
1808     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1809       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1810     else
1811       AC_MSG_RESULT([no; do not use toolkit by default])
1812       USE_X_TOOLKIT=none
1813     fi
1814   fi
1815 fi
1816
1817 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1818
1819 if test "${USE_X_TOOLKIT}" != "none"; then
1820   AC_MSG_CHECKING(X11 toolkit version)
1821   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1822   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1823 [#if XtSpecificationRelease < 6
1824 fail;
1825 #endif
1826 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1827   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1828   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1829     AC_MSG_RESULT(6 or newer)
1830     AC_DEFINE(HAVE_X11XTR6, 1,
1831               [Define to 1 if you have the X11R6 or newer version of Xt.])
1832   else
1833     AC_MSG_RESULT(before 6)
1834   fi
1835
1836 dnl If using toolkit, check whether libXmu.a exists.
1837 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1838   OLDLIBS="$LIBS"
1839   if test x$HAVE_X11XTR6 = xyes; then
1840     LIBS="-lXt -lSM -lICE $LIBS"
1841   else
1842     LIBS="-lXt $LIBS"
1843   fi
1844   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1845   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1846 fi
1847
1848 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1849 if test "${HAVE_X11}" = "yes"; then
1850   if test "${USE_X_TOOLKIT}" != "none"; then
1851     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1852   fi
1853 fi
1854
1855 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1856   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1857   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1858     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1859 int x = 5;
1860 #else
1861 Motif version prior to 2.1.
1862 #endif],
1863     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1864   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1865   if test $emacs_cv_motif_version_2_1 = yes; then
1866     HAVE_LIBXP=no
1867     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1868               [Define to 1 if you have Motif 2.1 or newer.])
1869     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1870     if test ${HAVE_LIBXP} = yes; then
1871       AC_DEFINE(HAVE_LIBXP, 1,
1872                 [Define to 1 if you have the Xp library (-lXp).])
1873     fi
1874   else
1875     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1876     # We put this in CFLAGS temporarily to precede other -I options
1877     # that might be in CFLAGS temporarily.
1878     # We put this in CPPFLAGS where it precedes the other -I options.
1879     OLD_CPPFLAGS=$CPPFLAGS
1880     OLD_CFLAGS=$CFLAGS
1881     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1882     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1883     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1884       [int x = 5;],
1885       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1886     if test $emacs_cv_lesstif = yes; then
1887       # Make sure this -I option remains in CPPFLAGS after it is set
1888       # back to REAL_CPPFLAGS.
1889       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1890       # have those other -I options anyway.  Ultimately, having this
1891       # directory ultimately in CPPFLAGS will be enough.
1892       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1893       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1894     else
1895       CFLAGS=$OLD_CFLAGS
1896       CPPFLAGS=$OLD_CPPFLAGS
1897     fi
1898   fi
1899 fi
1900
1901 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1902 dnl using Motif or Xaw3d is available, and unless
1903 dnl --with-toolkit-scroll-bars=no was specified.
1904
1905 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1906             [Define to 1 if we should use toolkit scroll bars.])dnl
1907 USE_TOOLKIT_SCROLL_BARS=no
1908 if test "${with_toolkit_scroll_bars}" != "no"; then
1909   if test "${USE_X_TOOLKIT}" != "none"; then
1910     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1911       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1912       HAVE_XAW3D=no
1913       USE_TOOLKIT_SCROLL_BARS=yes
1914     elif test "${HAVE_XAW3D}" = "yes"; then
1915       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1916       USE_TOOLKIT_SCROLL_BARS=yes
1917     fi
1918   elif test "${HAVE_GTK}" = "yes"; then
1919     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1920     USE_TOOLKIT_SCROLL_BARS=yes
1921   elif test "${HAVE_NS}" = "yes"; then
1922     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1923     USE_TOOLKIT_SCROLL_BARS=yes
1924   fi
1925 fi
1926
1927 dnl See if XIM is available.
1928 AC_TRY_COMPILE([
1929           #include <X11/Xlib.h>
1930           #include <X11/Xresource.h>],
1931          [XIMProc  callback;],
1932          [HAVE_XIM=yes
1933          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1934          HAVE_XIM=no)
1935
1936 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1937
1938 if test "${with_xim}" != "no"; then
1939   AC_DEFINE(USE_XIM, 1,
1940             [Define to 1 if we should use XIM, if it is available.])
1941 fi
1942
1943
1944 if test "${HAVE_XIM}" != "no"; then
1945   late_CFLAGS=$CFLAGS
1946   if test "$GCC" = yes; then
1947     CFLAGS="$CFLAGS --pedantic-errors"
1948   fi
1949   AC_TRY_COMPILE([
1950 #include <X11/Xlib.h>
1951 #include <X11/Xresource.h>],
1952 [Display *display;
1953 XrmDatabase db;
1954 char *res_name;
1955 char *res_class;
1956 XIMProc  callback;
1957 XPointer *client_data;
1958 #ifndef __GNUC__
1959 /* If we're not using GCC, it's probably not XFree86, and this is
1960    probably right, but we can't use something like --pedantic-errors.  */
1961 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1962                                            char*, XIMProc, XPointer*);
1963 #endif
1964 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1965    client_data);],
1966     [emacs_cv_arg6_star=yes])
1967   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1968          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1969 either XPointer or XPointer*.])dnl
1970   if test "$emacs_cv_arg6_star" = yes; then
1971     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1972   else
1973     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1974   fi
1975   CFLAGS=$late_CFLAGS
1976 fi
1977
1978 ### Start of font-backend (under any platform) section.
1979 # (nothing here yet -- this is a placeholder)
1980 ### End of font-backend (under any platform) section.
1981
1982 ### Start of font-backend (under X11) section.
1983 if test "${HAVE_X11}" = "yes"; then
1984    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1985
1986    ## Use -lXft if available, unless `--with-xft=no'.
1987    HAVE_XFT=maybe
1988     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
1989       with_xft="no";
1990     fi
1991     if test "x${with_xft}" != "xno"; then
1992
1993       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1994       ## Because xftfont.c uses XRenderQueryExtension, we also
1995       ## need to link to -lXrender.
1996       HAVE_XRENDER=no
1997       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
1998       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
1999         OLD_CPPFLAGS="$CPPFLAGS"
2000         OLD_CFLAGS="$CFLAGS"
2001         OLD_LIBS="$LIBS"
2002         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2003         CFLAGS="$CFLAGS $XFT_CFLAGS"
2004         XFT_LIBS="-lXrender $XFT_LIBS"
2005         LIBS="$XFT_LIBS $LIBS"
2006         AC_CHECK_HEADER(X11/Xft/Xft.h,
2007           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2008
2009         if test "${HAVE_XFT}" = "yes"; then
2010           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2011             AC_SUBST(XFT_LIBS)
2012           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2013         else
2014           CPPFLAGS="$OLD_CPPFLAGS"
2015           CFLAGS="$OLD_CFLAGS"
2016           LIBS="$OLD_LIBS"
2017         fi                        # "${HAVE_XFT}" = "yes"
2018       fi                          # "$HAVE_XFT" != no
2019     fi                            # "x${with_xft}" != "xno"
2020
2021     dnl For the "Does Emacs use" message at the end.
2022     if test "$HAVE_XFT" != "yes"; then
2023        HAVE_XFT=no
2024     fi
2025
2026
2027     HAVE_FREETYPE=no
2028     ## We used to allow building with FreeType and without Xft.
2029     ## However, the ftx font backend driver is not in good shape.
2030     if test "${HAVE_XFT}" = "yes"; then
2031       dnl As we use Xft, we anyway use freetype.
2032       dnl There's no need for additional CFLAGS and LIBS.
2033       HAVE_FREETYPE=yes
2034       FONTCONFIG_CFLAGS=
2035       FONTCONFIG_LIBS=
2036     fi
2037
2038     HAVE_LIBOTF=no
2039     if test "${HAVE_FREETYPE}" = "yes"; then
2040       AC_DEFINE(HAVE_FREETYPE, 1,
2041                 [Define to 1 if using the freetype and fontconfig libraries.])
2042       if test "${with_libotf}" != "no"; then
2043         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2044                           HAVE_LIBOTF=no)
2045         if test "$HAVE_LIBOTF" = "yes"; then
2046           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2047           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2048                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2049                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2050           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2051             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2052                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2053           fi
2054         fi
2055       fi
2056     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2057     dnl Does the new font backend require it, or can it work without it?
2058     fi
2059
2060     HAVE_M17N_FLT=no
2061     if test "${HAVE_LIBOTF}" = yes; then
2062       if test "${with_m17n_flt}" != "no"; then
2063         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2064         if test "$HAVE_M17N_FLT" = "yes"; then
2065           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2066         fi
2067       fi
2068     fi
2069 else
2070     HAVE_XFT=no
2071     HAVE_FREETYPE=no
2072     HAVE_LIBOTF=no
2073     HAVE_M17N_FLT=no
2074 fi
2075 ### End of font-backend (under X11) section.
2076
2077 AC_SUBST(FREETYPE_CFLAGS)
2078 AC_SUBST(FREETYPE_LIBS)
2079 AC_SUBST(FONTCONFIG_CFLAGS)
2080 AC_SUBST(FONTCONFIG_LIBS)
2081 AC_SUBST(LIBOTF_CFLAGS)
2082 AC_SUBST(LIBOTF_LIBS)
2083 AC_SUBST(M17N_FLT_CFLAGS)
2084 AC_SUBST(M17N_FLT_LIBS)
2085
2086 ### Use -lXpm if available, unless `--with-xpm=no'.
2087 HAVE_XPM=no
2088 LIBXPM=
2089 if test "${HAVE_X11}" = "yes"; then
2090   if test "${with_xpm}" != "no"; then
2091     AC_CHECK_HEADER(X11/xpm.h,
2092       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2093     if test "${HAVE_XPM}" = "yes"; then
2094       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2095       AC_EGREP_CPP(no_return_alloc_pixels,
2096       [#include "X11/xpm.h"
2097 #ifndef XpmReturnAllocPixels
2098 no_return_alloc_pixels
2099 #endif
2100       ], HAVE_XPM=no, HAVE_XPM=yes)
2101
2102       if test "${HAVE_XPM}" = "yes"; then
2103         AC_MSG_RESULT(yes)
2104       else
2105         AC_MSG_RESULT(no)
2106       fi
2107     fi
2108   fi
2109
2110   if test "${HAVE_XPM}" = "yes"; then
2111     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2112     LIBXPM=-lXpm
2113   fi
2114 fi
2115 AC_SUBST(LIBXPM)
2116
2117 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2118 HAVE_JPEG=no
2119 LIBJPEG=
2120 if test "${HAVE_X11}" = "yes"; then
2121   if test "${with_jpeg}" != "no"; then
2122     dnl Checking for jpeglib.h can lose because of a redefinition of
2123     dnl  HAVE_STDLIB_H.
2124     AC_CHECK_HEADER(jerror.h,
2125       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2126   fi
2127
2128   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2129   if test "${HAVE_JPEG}" = "yes"; then
2130     AC_DEFINE(HAVE_JPEG)
2131     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2132         [#include <jpeglib.h>
2133          version=JPEG_LIB_VERSION
2134 ],
2135         [AC_DEFINE(HAVE_JPEG)],
2136         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2137         HAVE_JPEG=no])
2138   fi
2139   if test "${HAVE_JPEG}" = "yes"; then
2140     LIBJPEG=-ljpeg
2141   fi
2142 fi
2143 AC_SUBST(LIBJPEG)
2144
2145 ### Use -lpng if available, unless `--with-png=no'.
2146 HAVE_PNG=no
2147 LIBPNG=
2148 if test "${HAVE_X11}" = "yes"; then
2149   if test "${with_png}" != "no"; then
2150     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2151     # in /usr/include/libpng.
2152     AC_CHECK_HEADERS(png.h libpng/png.h)
2153     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2154       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2155     fi
2156   fi
2157
2158   if test "${HAVE_PNG}" = "yes"; then
2159     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2160     LIBPNG="-lpng -lz -lm"
2161   fi
2162 fi
2163 AC_SUBST(LIBPNG)
2164
2165 ### Use -ltiff if available, unless `--with-tiff=no'.
2166 HAVE_TIFF=no
2167 LIBTIFF=
2168 if test "${HAVE_X11}" = "yes"; then
2169   if test "${with_tiff}" != "no"; then
2170     AC_CHECK_HEADER(tiffio.h,
2171       [tifflibs="-lz -lm"
2172       # At least one tiff package requires the jpeg library.
2173       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2174       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2175   fi
2176
2177   if test "${HAVE_TIFF}" = "yes"; then
2178     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2179     dnl FIXME -lz -lm, as per libpng?
2180     LIBTIFF=-ltiff
2181   fi
2182 fi
2183 AC_SUBST(LIBTIFF)
2184
2185 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2186 HAVE_GIF=no
2187 LIBGIF=
2188 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2189   AC_CHECK_HEADER(gif_lib.h,
2190 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2191 # Earlier versions can crash Emacs.
2192     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2193
2194   if test "$HAVE_GIF" = yes; then
2195     LIBGIF=-lgif
2196   elif test "$HAVE_GIF" = maybe; then
2197 # If gif_lib.h but no libgif, try libungif.
2198     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2199     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2200   fi
2201
2202   if test "${HAVE_GIF}" = "yes"; then
2203     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2204   fi
2205 fi
2206 AC_SUBST(LIBGIF)
2207
2208 dnl Check for required libraries.
2209 if test "${HAVE_X11}" = "yes"; then
2210   MISSING=""
2211   WITH_NO=""
2212   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2213     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2214   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2215     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2216   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2217     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2218   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2219     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2220   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2221     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2222
2223   if test "X${MISSING}" != X; then
2224     AC_MSG_ERROR([The following required libraries were not found:
2225     $MISSING
2226 Maybe some development libraries/packages are missing?
2227 If you don't want to link with them give
2228     $WITH_NO
2229 as options to configure])
2230   fi
2231 fi
2232
2233 ### Use -lgpm if available, unless `--with-gpm=no'.
2234 HAVE_GPM=no
2235 LIBGPM=
2236 if test "${with_gpm}" != "no"; then
2237   AC_CHECK_HEADER(gpm.h,
2238     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2239
2240   if test "${HAVE_GPM}" = "yes"; then
2241     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2242     LIBGPM=-lgpm
2243   fi
2244 fi
2245 AC_SUBST(LIBGPM)
2246
2247 dnl Check for malloc/malloc.h on darwin
2248 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2249
2250 ### Use NeXTstep API to implement GUI.
2251 if test "${HAVE_NS}" = "yes"; then
2252   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2253   if test "${NS_IMPL_COCOA}" = "yes"; then
2254     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2255     GNU_OBJC_CFLAGS=
2256   fi
2257   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2258     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2259     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2260   fi
2261   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2262     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2263   fi
2264   # We also have mouse menus.
2265   HAVE_MENUS=yes
2266   OTHER_FILES=ns-app
2267 fi
2268
2269
2270 ### Use session management (-lSM -lICE) if available
2271 HAVE_X_SM=no
2272 LIBXSM=
2273 if test "${HAVE_X11}" = "yes"; then
2274   AC_CHECK_HEADER(X11/SM/SMlib.h,
2275     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2276
2277   if test "${HAVE_X_SM}" = "yes"; then
2278     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2279     LIBXSM="-lSM -lICE"
2280     case "$LIBS" in
2281       *-lSM*) ;;
2282       *)      LIBS="$LIBXSM $LIBS" ;;
2283     esac
2284   fi
2285 fi
2286 AC_SUBST(LIBXSM)
2287
2288 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2289 AC_CACHE_CHECK(whether netdb declares h_errno,
2290                emacs_cv_netdb_declares_h_errno,
2291 [AC_TRY_LINK([#include <netdb.h>],
2292   [return h_errno;],
2293   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2294 if test $emacs_cv_netdb_declares_h_errno = yes; then
2295   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2296 fi
2297
2298 AC_FUNC_ALLOCA
2299
2300 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2301 dnl FIXME is there an autoconf test that does the right thing, without
2302 dnl needing to call A_M_E afterwards?
2303 if test x"$ac_cv_func_alloca_works" != xyes; then
2304    AC_MSG_ERROR( [a system implementation of alloca is required] )
2305 fi
2306
2307 # fmod, logb, and frexp are found in -lm on most systems.
2308 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2309 AC_CHECK_LIB(m, sqrt)
2310
2311 # Check for mail-locking functions in a "mail" library.  Probably this should
2312 # have the same check as for liblockfile below.
2313 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2314 if test $have_mail = yes; then
2315   LIBS_MAIL=-lmail
2316   LIBS="$LIBS_MAIL $LIBS"
2317   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2318 else
2319   LIBS_MAIL=
2320 fi
2321 dnl Debian, at least:
2322 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2323 if test $have_lockfile = yes; then
2324    LIBS_MAIL=-llockfile
2325    LIBS="$LIBS_MAIL $LIBS"
2326    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2327 else
2328 # If we have the shared liblockfile, assume we must use it for mail
2329 # locking (e.g. Debian).  If we couldn't link against liblockfile
2330 # (no liblockfile.a installed), ensure that we don't need to.
2331   dnl This works for files generally, not just executables.
2332   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2333   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2334                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2335   if test $ac_cv_prog_liblockfile = yes; then
2336     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2337 This probably means that movemail could lose mail.
2338 There may be a `development' package to install containing liblockfile.])
2339   fi
2340 fi
2341 AC_CHECK_FUNCS(touchlock)
2342 AC_CHECK_HEADERS(maillock.h)
2343 AC_SUBST(LIBS_MAIL)
2344
2345 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2346 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2347 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2348 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2349 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2350 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2351 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2352 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2353 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2354 cfmakeraw cfsetspeed)
2355
2356 AC_CHECK_HEADERS(sys/un.h)
2357
2358 AC_FUNC_MKTIME
2359 if test "$ac_cv_func_working_mktime" = no; then
2360   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2361 fi
2362
2363 AC_FUNC_GETLOADAVG
2364
2365 AC_FUNC_FSEEKO
2366
2367 # Configure getopt.
2368 m4_include([m4/getopt.m4])
2369 gl_GETOPT_IFELSE([
2370   gl_GETOPT_SUBSTITUTE_HEADER
2371   gl_PREREQ_GETOPT
2372   GETOPTOBJS='getopt.o getopt1.o'
2373 ])
2374 AC_SUBST(GETOPTOBJS)
2375
2376 AC_FUNC_GETPGRP
2377
2378 AC_FUNC_STRFTIME
2379
2380 # UNIX98 PTYs.
2381 AC_CHECK_FUNCS(grantpt)
2382
2383 # PTY-related GNU extensions.
2384 AC_CHECK_FUNCS(getpt)
2385
2386 # Check this now, so that we will NOT find the above functions in ncurses.
2387 # That is because we have not set up to link ncurses in lib-src.
2388 # It's better to believe a function is not available
2389 # than to expect to find it in ncurses.
2390 # Also we need tputs and frieds to be able to build at all.
2391 have_tputs_et_al=true
2392 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2393 if test "$have_tputs_et_al" != true; then
2394   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2395 Maybe some development libraries/packages are missing?  Try installing
2396 libncurses-dev(el), libterminfo-dev(el) or similar.])
2397 fi
2398 # Must define this when any termcap library is found.
2399 AC_DEFINE(HAVE_LIBNCURSES, 1,
2400           [Define to 1 if you have the `ncurses' library (-lncurses).])
2401
2402 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2403
2404 resolv=no
2405 AC_TRY_LINK([#include <netinet/in.h>
2406 #include <arpa/nameser.h>
2407 #include <resolv.h>],
2408     [return res_init();],
2409     have_res_init=yes, have_res_init=no)
2410 if test "$have_res_init" = no; then
2411   OLIBS="$LIBS"
2412   LIBS="$LIBS -lresolv"
2413   AC_MSG_CHECKING(for res_init with -lresolv)
2414   AC_TRY_LINK([#include <netinet/in.h>
2415 #include <arpa/nameser.h>
2416 #include <resolv.h>],
2417     [return res_init();],
2418     have_res_init=yes, have_res_init=no)
2419   AC_MSG_RESULT($have_res_init)
2420   if test "$have_res_init" = yes ; then
2421     resolv=yes
2422   fi
2423   LIBS="$OLIBS"
2424 fi
2425
2426 if test "$have_res_init" = yes; then
2427   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2428 fi
2429
2430 # Do we need the Hesiod library to provide the support routines?
2431 LIBHESIOD=
2432 if test "$with_hesiod" != no ; then
2433   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2434   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2435      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2436                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2437   if test "$resolv" = yes ; then
2438     RESOLVLIB=-lresolv
2439   else
2440     RESOLVLIB=
2441   fi
2442   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2443         hesiod=yes, :, $RESOLVLIB)])
2444
2445   if test x"$hesiod" = xyes; then
2446     AC_DEFINE(HAVE_LIBHESIOD, 1,
2447               [Define to 1 if you have the hesiod library (-lhesiod).])
2448     LIBHESIOD=-lhesiod
2449   fi
2450 fi
2451 AC_SUBST(LIBHESIOD)
2452
2453 # Do we need libresolv (due to res_init or Hesiod)?
2454 if test "$resolv" = yes ; then
2455   AC_DEFINE(HAVE_LIBRESOLV, 1,
2456             [Define to 1 if you have the resolv library (-lresolv).])
2457   LIBRESOLV=-lresolv
2458 else
2459   LIBRESOLV=
2460 fi
2461 AC_SUBST(LIBRESOLV)
2462
2463 # These tell us which Kerberos-related libraries to use.
2464 COM_ERRLIB=
2465 CRYPTOLIB=
2466 KRB5LIB=
2467 DESLIB=
2468 KRB4LIB=
2469
2470 if test "${with_kerberos}" != no; then
2471   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2472   if test $have_com_err = yes; then
2473     COM_ERRLIB=-lcom_err
2474     LIBS="$COM_ERRLIB $LIBS"
2475     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2476   fi
2477   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2478   if test $have_crypto = yes; then
2479     CRYPTOLIB=-lcrypto
2480     LIBS="$CRYPTOLIB $LIBS"
2481     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2482   fi
2483   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2484   if test $have_k5crypto = yes; then
2485     CRYPTOLIB=-lk5crypto
2486     LIBS="$CRYPTOLIB $LIBS"
2487     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2488   fi
2489   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2490   if test $have_krb5=yes; then
2491     KRB5LIB=-lkrb5
2492     LIBS="$KRB5LIB $LIBS"
2493     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2494   fi
2495   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2496   if test "${with_kerberos5}" = no; then
2497     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2498     if test $have_des425 = yes; then
2499       DESLIB=-ldes425
2500       LIBS="$DESLIB $LIBS"
2501       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2502     else
2503       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2504       if test $have_des = yes; then
2505         DESLIB=-ldes
2506         LIBS="$DESLIB $LIBS"
2507         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2508       fi
2509     fi
2510     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2511     if test $have_krb4 = yes; then
2512       KRB4LIB=-lkrb4
2513       LIBS="$KRB4LIB $LIBS"
2514       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2515     else
2516       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2517       if test $have_krb = yes; then
2518         KRB4LIB=-lkrb
2519         LIBS="$KRB4LIB $LIBS"
2520         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2521       fi
2522     fi
2523   fi
2524
2525   if test "${with_kerberos5}" != no; then
2526     AC_CHECK_HEADERS(krb5.h,
2527       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2528                         [#include <krb5.h>])])
2529   else
2530     AC_CHECK_HEADERS(des.h,,
2531                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2532                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2533     AC_CHECK_HEADERS(krb.h,,
2534                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2535                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2536   fi
2537   AC_CHECK_HEADERS(com_err.h)
2538 fi
2539
2540 AC_SUBST(COM_ERRLIB)
2541 AC_SUBST(CRYPTOLIB)
2542 AC_SUBST(KRB5LIB)
2543 AC_SUBST(DESLIB)
2544 AC_SUBST(KRB4LIB)
2545
2546 # Solaris requires -lintl if you want strerror (which calls dgettext)
2547 # to return localized messages.
2548 AC_CHECK_LIB(intl, dgettext)
2549
2550 AC_MSG_CHECKING(whether localtime caches TZ)
2551 AC_CACHE_VAL(emacs_cv_localtime_cache,
2552 [if test x$ac_cv_func_tzset = xyes; then
2553 AC_TRY_RUN([#include <time.h>
2554 extern char **environ;
2555 unset_TZ ()
2556 {
2557   char **from, **to;
2558   for (to = from = environ; (*to = *from); from++)
2559     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2560       to++;
2561 }
2562 char TZ_GMT0[] = "TZ=GMT0";
2563 char TZ_PST8[] = "TZ=PST8";
2564 main()
2565 {
2566   time_t now = time ((time_t *) 0);
2567   int hour_GMT0, hour_unset;
2568   if (putenv (TZ_GMT0) != 0)
2569     exit (1);
2570   hour_GMT0 = localtime (&now)->tm_hour;
2571   unset_TZ ();
2572   hour_unset = localtime (&now)->tm_hour;
2573   if (putenv (TZ_PST8) != 0)
2574     exit (1);
2575   if (localtime (&now)->tm_hour == hour_GMT0)
2576     exit (1);
2577   unset_TZ ();
2578   if (localtime (&now)->tm_hour != hour_unset)
2579     exit (1);
2580   exit (0);
2581 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2582 [# If we have tzset, assume the worst when cross-compiling.
2583 emacs_cv_localtime_cache=yes])
2584 else
2585         # If we lack tzset, report that localtime does not cache TZ,
2586         # since we can't invalidate the cache if we don't have tzset.
2587         emacs_cv_localtime_cache=no
2588 fi])dnl
2589 AC_MSG_RESULT($emacs_cv_localtime_cache)
2590 if test $emacs_cv_localtime_cache = yes; then
2591   AC_DEFINE(LOCALTIME_CACHE, 1,
2592             [Define to 1 if localtime caches TZ.])
2593 fi
2594
2595 if test "x$HAVE_TIMEVAL" = xyes; then
2596   AC_CHECK_FUNCS(gettimeofday)
2597   if test $ac_cv_func_gettimeofday = yes; then
2598     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2599                    emacs_cv_gettimeofday_two_arguments,
2600     [AC_TRY_COMPILE([
2601 #ifdef TIME_WITH_SYS_TIME
2602 #include <sys/time.h>
2603 #include <time.h>
2604 #else
2605 #ifdef HAVE_SYS_TIME_H
2606 #include <sys/time.h>
2607 #else
2608 #include <time.h>
2609 #endif
2610 #endif],
2611       [struct timeval time;
2612        gettimeofday (&time, 0);],
2613       emacs_cv_gettimeofday_two_arguments=yes,
2614       emacs_cv_gettimeofday_two_arguments=no)])
2615     if test $emacs_cv_gettimeofday_two_arguments = no; then
2616       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2617                 [Define to 1 if gettimeofday accepts only one argument.])
2618     fi
2619   fi
2620 fi
2621
2622 ok_so_far=yes
2623 AC_CHECK_FUNC(socket, , ok_so_far=no)
2624 if test $ok_so_far = yes; then
2625   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2626 fi
2627 if test $ok_so_far = yes; then
2628   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2629 fi
2630 if test $ok_so_far = yes; then
2631 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2632   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2633             [Define to 1 if you have inet sockets.])
2634 fi
2635
2636 AC_CHECK_HEADERS(sys/ioctl.h)
2637
2638 if test -f /usr/lpp/X11/bin/smt.exp; then
2639   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2640             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2641 fi
2642
2643 AC_MSG_CHECKING(whether system supports dynamic ptys)
2644 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2645   AC_MSG_RESULT(yes)
2646   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2647 else
2648   AC_MSG_RESULT(no)
2649 fi
2650
2651 AC_FUNC_FORK
2652
2653 dnl Adapted from Haible's version.
2654 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2655   [AC_TRY_LINK([#include <langinfo.h>],
2656     [char* cs = nl_langinfo(CODESET);],
2657     emacs_cv_langinfo_codeset=yes,
2658     emacs_cv_langinfo_codeset=no)
2659   ])
2660 if test $emacs_cv_langinfo_codeset = yes; then
2661   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2662     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2663 fi
2664
2665 AC_CHECK_TYPES(size_t)
2666
2667 AC_TYPE_MBSTATE_T
2668
2669 dnl Restrict could probably be used effectively other than in regex.c.
2670 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2671   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2672                   emacs_cv_c_restrict=yes,
2673                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2674                                   emacs_cv_c_restrict=__restrict,
2675                                   emacs_cv_c_restrict=no)])])
2676 case "$emacs_cv_c_restrict" in
2677   yes) emacs_restrict=restrict;;
2678   no) emacs_restrict="";;
2679   *) emacs_restrict="$emacs_cv_c_restrict";;
2680 esac
2681 if test "$emacs_restrict" != __restrict; then
2682   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2683     [Define to compiler's equivalent of C99 restrict keyword.
2684      Don't define if equivalent is `__restrict'.])
2685 fi
2686
2687 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2688   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2689                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2690 if test "$emacs_cv_c_restrict_arr" = yes; then
2691   AC_DEFINE(__restrict_arr, __restrict,
2692     [Define to compiler's equivalent of C99 restrict keyword in array
2693      declarations.  Define as empty for no equivalent.])
2694 fi
2695
2696 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2697 dnl how the tty code is related to POSIX and/or other versions of termios.
2698 dnl The following looks like a useful start.
2699 dnl
2700 dnl AC_SYS_POSIX_TERMIOS
2701 dnl if test $ac_cv_sys_posix_termios = yes; then
2702 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2703 dnl                                and macros for terminal control.])
2704 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2705 dnl fi
2706
2707 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2708
2709 # Set up the CFLAGS for real compilation, so we can substitute it.
2710 CFLAGS="$REAL_CFLAGS"
2711 CPPFLAGS="$REAL_CPPFLAGS"
2712
2713 #### Find out which version of Emacs this is.
2714 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2715          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2716 if test x"${version}" = x; then
2717   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2718 fi
2719 if test x"${version}" != x"$PACKAGE_VERSION"; then
2720   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
2721 fi
2722
2723 ### Specify what sort of things we'll be editing into Makefile and config.h.
2724 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2725 AC_SUBST(version)
2726 AC_SUBST(configuration)
2727 AC_SUBST(canonical)
2728 AC_SUBST(srcdir)
2729 AC_SUBST(prefix)
2730 AC_SUBST(exec_prefix)
2731 AC_SUBST(bindir)
2732 AC_SUBST(datadir)
2733 AC_SUBST(sharedstatedir)
2734 AC_SUBST(libexecdir)
2735 AC_SUBST(mandir)
2736 AC_SUBST(infodir)
2737 AC_SUBST(lispdir)
2738 AC_SUBST(locallisppath)
2739 AC_SUBST(lisppath)
2740 AC_SUBST(x_default_search_path)
2741 AC_SUBST(etcdir)
2742 AC_SUBST(archlibdir)
2743 AC_SUBST(docdir)
2744 AC_SUBST(bitmapdir)
2745 AC_SUBST(gamedir)
2746 AC_SUBST(gameuser)
2747 AC_SUBST(c_switch_system)
2748 AC_SUBST(c_switch_machine)
2749 AC_SUBST(LD_SWITCH_X_SITE)
2750 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2751 AC_SUBST(C_SWITCH_X_SITE)
2752 AC_SUBST(CFLAGS)
2753 AC_SUBST(X_TOOLKIT_TYPE)
2754 AC_SUBST(machfile)
2755 AC_SUBST(opsysfile)
2756 AC_SUBST(GETLOADAVG_LIBS)
2757 AC_SUBST(ns_appdir)
2758 AC_SUBST(ns_appbindir)
2759 AC_SUBST(ns_appresdir)
2760 AC_SUBST(ns_appsrc)
2761 AC_SUBST(GNUSTEP_MAKEFILES)
2762 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2763 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2764 AC_SUBST(GNU_OBJC_CFLAGS)
2765 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2766 AC_SUBST(OTHER_FILES)
2767
2768 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2769                    [Define to the canonical Emacs configuration name.])
2770 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2771                    [Define to the options passed to configure.])
2772 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2773                    [Define to the used machine dependent file.])
2774 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2775                    [Define to the used os dependent file.])
2776 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2777 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2778  may need to deal with X Windows.  For instance, if you've defined
2779  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2780  your loader can find on its own, you might want to add "-L/..." or
2781  something similar.])
2782 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2783                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2784                     in case it's needed (for Solaris, for example).])
2785 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2786 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2787  may need to deal with X Windows.  For instance, if you've defined
2788  HAVE_X_WINDOWS above and your X include files aren't in a place
2789  that your compiler can find on its own, you might want to add
2790  "-I/..." or something similar.])
2791 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2792                    [Define to the unexec source file name.])
2793
2794 XMENU_OBJ=
2795 XOBJ=
2796 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2797   AC_DEFINE(HAVE_X_WINDOWS, 1,
2798             [Define to 1 if you want to use the X window system.])
2799   XMENU_OBJ=xmenu.o
2800   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
2801 fi
2802 AC_SUBST(XMENU_OBJ)
2803 AC_SUBST(XOBJ)
2804
2805 if test "${USE_X_TOOLKIT}" != "none" ; then
2806   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2807   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2808     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2809   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2810     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2811   fi
2812 fi
2813 if test "${HAVE_X11}" = "yes" ; then
2814   AC_DEFINE(HAVE_X11, 1,
2815             [Define to 1 if you want to use version 11 of X windows.
2816              Otherwise, Emacs expects to use version 10.])
2817 fi
2818 if test "${HAVE_MENUS}" = "yes" ; then
2819   AC_DEFINE(HAVE_MENUS, 1,
2820             [Define to 1 if you have mouse menus.
2821              (This is automatic if you use X, but the option to specify it remains.)
2822              It is also defined with other window systems that support xmenu.c.])
2823 fi
2824 if test "${GNU_MALLOC}" = "yes" ; then
2825   AC_DEFINE(GNU_MALLOC, 1,
2826             [Define to 1 if you want to use the GNU memory allocator.])
2827 fi
2828 if test "${REL_ALLOC}" = "yes" ; then
2829   AC_DEFINE(REL_ALLOC, 1,
2830             [Define REL_ALLOC if you want to use the relocating allocator for
2831              buffer space.])
2832 fi
2833
2834
2835 AH_TOP([/* GNU Emacs site configuration template file.
2836    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2837      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
2838
2839 This file is part of GNU Emacs.
2840
2841 GNU Emacs is free software: you can redistribute it and/or modify
2842 it under the terms of the GNU General Public License as published by
2843 the Free Software Foundation, either version 3 of the License, or
2844 (at your option) any later version.
2845
2846 GNU Emacs is distributed in the hope that it will be useful,
2847 but WITHOUT ANY WARRANTY; without even the implied warranty of
2848 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2849 GNU General Public License for more details.
2850
2851 You should have received a copy of the GNU General Public License
2852 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2853
2854
2855 /* No code in Emacs #includes config.h twice, but some bits of code
2856    intended to work with other packages as well (like gmalloc.c)
2857    think they can include it as many times as they like.  */
2858 #ifndef EMACS_CONFIG_H
2859 #define EMACS_CONFIG_H
2860 ])dnl
2861
2862 AH_BOTTOM([
2863 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2864 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2865 #define HAVE_WINDOW_SYSTEM
2866 #define HAVE_MOUSE
2867 #endif
2868
2869 /* Define AMPERSAND_FULL_NAME if you use the convention
2870    that & in the full name stands for the login id.  */
2871 /* Turned on June 1996 supposing nobody will mind it.  */
2872 #define AMPERSAND_FULL_NAME
2873
2874 /* Define HAVE_SOUND if we have sound support.  We know it works
2875    and compiles only on the specified platforms.   For others,
2876    it probably doesn't make sense to try.  */
2877
2878 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2879 #ifdef HAVE_MACHINE_SOUNDCARD_H
2880 #define HAVE_SOUND 1
2881 #endif
2882 #ifdef HAVE_SYS_SOUNDCARD_H
2883 #define HAVE_SOUND 1
2884 #endif
2885 #ifdef HAVE_SOUNDCARD_H
2886 #define HAVE_SOUND 1
2887 #endif
2888 #ifdef HAVE_ALSA
2889 #define HAVE_SOUND 1
2890 #endif
2891 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2892
2893 /* If using GNU, then support inline function declarations. */
2894 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2895    generally, because even if non-gcc compilers accept `inline', they
2896    may reject `extern inline'.  */
2897 #if defined (__GNUC__) && defined (OPTIMIZE)
2898 #define INLINE __inline__
2899 #else
2900 #define INLINE
2901 #endif
2902
2903 /* `subprocesses' should be defined if you want to
2904    have code for asynchronous subprocesses
2905    (as used in M-x compile and M-x shell).
2906    Only MSDOS does not support this (it overrides
2907    this in its config_opsysfile below).  */
2908
2909 #define subprocesses
2910
2911 /* Include the os and machine dependent files.  */
2912 #include config_opsysfile
2913 #include config_machfile
2914
2915 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2916   (There is probably a better place to do this, but right now the Cocoa
2917    side does this in s/darwin.h and we cannot
2918    parallel this exactly since GNUstep is multi-OS. */
2919 #ifdef HAVE_NS
2920 # ifdef NS_IMPL_GNUSTEP
2921 /* See also .m.o rule in Makefile.in */
2922 /* FIXME: are all these flags really needed?  Document here why.  */
2923 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2924 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2925 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2926 #  define SYSTEM_PURESIZE_EXTRA 30000
2927 # endif /* NS_IMPL_GNUSTEP */
2928 #endif /* HAVE_NS */
2929
2930 /* SIGTYPE is the macro we actually use.  */
2931 #ifndef SIGTYPE
2932 #define SIGTYPE RETSIGTYPE
2933 #endif
2934
2935 #ifdef emacs /* Don't do this for lib-src.  */
2936 /* Tell regex.c to use a type compatible with Emacs.  */
2937 #define RE_TRANSLATE_TYPE Lisp_Object
2938 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2939 #ifdef make_number
2940 /* If make_number is a macro, use it.  */
2941 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2942 #else
2943 /* If make_number is a function, avoid it.  */
2944 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2945 #endif
2946 #endif
2947
2948 /* Avoid link-time collision with system mktime if we will use our own.  */
2949 #if ! HAVE_MKTIME || BROKEN_MKTIME
2950 #define mktime emacs_mktime
2951 #endif
2952
2953 #define my_strftime nstrftime   /* for strftime.c */
2954
2955 /* The rest of the code currently tests the CPP symbol BSTRING.
2956    Override any claims made by the system-description files.
2957    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2958 #undef BSTRING
2959 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2960 #define BSTRING
2961 #endif
2962
2963 /* Some of the files of Emacs which are intended for use with other
2964    programs assume that if you have a config.h file, you must declare
2965    the type of getenv.
2966
2967    This declaration shouldn't appear when alloca.s or Makefile.in
2968    includes config.h.  */
2969 #ifndef NOT_C_CODE
2970 extern char *getenv ();
2971 #endif
2972
2973 /* These default definitions are good for almost all machines.
2974    The exceptions override them in m/MACHINE.h.  */
2975
2976 #ifndef BITS_PER_CHAR
2977 #define BITS_PER_CHAR 8
2978 #endif
2979
2980 #ifndef BITS_PER_SHORT
2981 #define BITS_PER_SHORT 16
2982 #endif
2983
2984 /* Note that lisp.h uses this in a preprocessor conditional, so it
2985    would not work to use sizeof.  That being so, we do all of them
2986    without sizeof, for uniformity's sake.  */
2987 #ifndef BITS_PER_INT
2988 #define BITS_PER_INT 32
2989 #endif
2990
2991 #ifndef BITS_PER_LONG
2992 #ifdef _LP64
2993 #define BITS_PER_LONG 64
2994 #else
2995 #define BITS_PER_LONG 32
2996 #endif
2997 #endif
2998
2999 /* Define if the compiler supports function prototypes.  It may do so
3000    but not define __STDC__ (e.g. DEC C by default) or may define it as
3001    zero.  */
3002 #undef PROTOTYPES
3003 /* For mktime.c:  */
3004 #ifndef __P
3005 # if defined PROTOTYPES
3006 #  define __P(args) args
3007 # else
3008 #  define __P(args) ()
3009 # endif  /* GCC.  */
3010 #endif /* __P */
3011
3012 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
3013 #ifndef NOT_C_CODE
3014 #ifdef HAVE_STRING_H
3015 #include "string.h"
3016 #endif
3017 #ifdef HAVE_STRINGS_H
3018 #include "strings.h"  /* May be needed for bcopy & al. */
3019 #endif
3020 #ifdef HAVE_STDLIB_H
3021 #include <stdlib.h>
3022 #endif
3023 #ifndef __GNUC__
3024 # ifdef HAVE_ALLOCA_H
3025 #  include <alloca.h>
3026 # else /* AIX files deal with #pragma.  */
3027 #  ifndef alloca /* predefined by HP cc +Olibcalls */
3028 char *alloca ();
3029 #  endif
3030 # endif /* HAVE_ALLOCA_H */
3031 #endif /* __GNUC__ */
3032 #ifndef HAVE_SIZE_T
3033 typedef unsigned size_t;
3034 #endif
3035 #endif /* NOT_C_CODE */
3036
3037 /* Define HAVE_X_I18N if we have usable i18n support.  */
3038
3039 #ifdef HAVE_X11R6
3040 #define HAVE_X_I18N
3041 #elif !defined X11R5_INHIBIT_I18N
3042 #define HAVE_X_I18N
3043 #endif
3044
3045 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3046
3047 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3048 #define HAVE_X11R6_XIM
3049 #endif
3050
3051 #if defined __GNUC__ && (__GNUC__ > 2 \
3052                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3053 #define NO_RETURN       __attribute__ ((__noreturn__))
3054 #else
3055 #define NO_RETURN       /* nothing */
3056 #endif
3057
3058 /* These won't be used automatically yet.  We also need to know, at least,
3059    that the stack is continuous.  */
3060 #ifdef __GNUC__
3061 #  ifndef GC_SETJMP_WORKS
3062   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3063      see NON_SAVING_SETJMP in the target descriptions.  */
3064   /* Exceptions (see NON_SAVING_SETJMP in target description) are
3065      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3066      Fixme: Deal with SVR3.  */
3067 #    define GC_SETJMP_WORKS 1
3068 #  endif
3069 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3070 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3071 #  endif
3072 #endif
3073
3074 #ifndef HAVE_BCOPY
3075 #define bcopy(a,b,s) memcpy (b,a,s)
3076 #endif
3077 #ifndef HAVE_BZERO
3078 #define bzero(a,s) memset (a,0,s)
3079 #endif
3080 #ifndef HAVE_BCMP
3081 #define BCMP memcmp
3082 #endif
3083
3084 #endif /* EMACS_CONFIG_H */
3085
3086 /*
3087 Local Variables:
3088 mode: c
3089 End:
3090 */
3091 ])dnl
3092
3093 #### Report on what we decided to do.
3094 #### Report GTK as a toolkit, even if it doesn't use Xt.
3095 #### It makes printing result more understandable as using GTK sets
3096 #### toolkit_scroll_bars to yes by default.
3097 if test "${HAVE_GTK}" = "yes"; then
3098   USE_X_TOOLKIT=GTK
3099 fi
3100
3101 echo "
3102 Configured for \`${canonical}'.
3103
3104   Where should the build process find the source code?    ${srcdir}
3105   What operating system and machine description files should Emacs use?
3106         \`${opsysfile}' and \`${machfile}'
3107   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3108   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3109   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3110   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3111   What window system should Emacs use?                    ${window_system}
3112   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3113
3114 if test -n "${x_includes}"; then
3115 echo "  Where do we find X Windows header files?                ${x_includes}"
3116 else
3117 echo "  Where do we find X Windows header files?                Standard dirs"
3118 fi
3119 if test -n "${x_libraries}"; then
3120 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3121 else
3122 echo "  Where do we find X Windows libraries?                   Standard dirs"
3123 fi
3124
3125 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3126 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3127 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3128 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3129 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3130 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3131 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3132 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3133 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3134 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3135 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3136
3137 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3138 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3139 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3140 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3141
3142 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3143 echo
3144
3145 if test $USE_XASSERTS = yes; then
3146    echo "  Compiling with asserts turned on."
3147    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3148 fi
3149
3150 echo
3151
3152 if test "$HAVE_NS" = "yes"; then
3153    echo
3154    echo "You must run \"make install\" in order to test the built application.
3155 The installed application will go to nextstep/Emacs.app and can be
3156 run or moved from there."
3157    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3158       echo "The application will be fully self-contained."
3159     else
3160       echo "The lisp resources for the application will be installed under ${prefix}.
3161 You may need to run \"make install\" with sudo.  The application will fail
3162 to run if these resources are not installed."
3163    fi
3164    echo
3165 fi
3166
3167 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3168   echo "D-Bus integration has been tested for GNU/Linux only."
3169   echo
3170 fi
3171
3172
3173 # Remove any trailing slashes in these variables.
3174 [test "${prefix}" != NONE &&
3175   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3176 test "${exec_prefix}" != NONE &&
3177   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3178
3179 # Now get this: Some word that is part of the ${srcdir} directory name
3180 # or the ${configuration} value might, just might, happen to be an
3181 # identifier like `sun4' or `i386' or something, and be predefined by
3182 # the C preprocessor to some helpful value like 1, or maybe the empty
3183 # string.  Needless to say consequent macro substitutions are less
3184 # than conducive to the makefile finding the correct directory.
3185 [cpp_undefs="`echo $srcdir $configuration $canonical unix |
3186   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3187   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3188
3189 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3190 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3191 ## from Makefile.c can correctly provide the arg `-traditional' to the
3192 ## C preprocessor.
3193
3194 AC_EGREP_CPP(yes..yes,
3195         [yes..yes],
3196         CPP_NEED_TRADITIONAL=no,
3197         CPP_NEED_TRADITIONAL=yes)
3198
3199 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3200         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3201         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3202         lwlib/Makefile lisp/Makefile leim/Makefile, [
3203
3204 ### Make the necessary directories, if they don't exist.
3205 for dir in etc lisp ; do
3206   test -d ${dir} || mkdir ${dir}
3207 done
3208
3209 # Build src/Makefile from ${srcdir}/src/Makefile.c
3210 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3211 # This must be done after src/config.h is built, since we rely on that file.
3212
3213 echo creating src/epaths.h
3214 ${MAKE-make} epaths-force
3215
3216 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3217 # `..' to `. .'  unless invoked with -traditional
3218
3219 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3220   CPPFLAGS="$CPPFLAGS -traditional"
3221 fi
3222
3223 echo creating lib-src/Makefile
3224 ( cd lib-src
3225   rm -f junk.c junk1.c junk2.c
3226   sed -e '/start of cpp stuff/q' \
3227       < Makefile.c > junk1.c
3228   sed -e '1,/start of cpp stuff/d'\
3229       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3230       < Makefile.c > junk.c
3231   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3232       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3233   cat junk1.c junk2.c > Makefile.new
3234   rm -f junk.c junk1.c junk2.c
3235   chmod 444 Makefile.new
3236   mv -f Makefile.new Makefile
3237 )
3238
3239 echo creating src/Makefile
3240 ( cd src
3241   rm -f junk.c junk1.c junk2.c
3242   sed -e '/start of cpp stuff/q' \
3243       < Makefile.c > junk1.c
3244   sed -e '1,/start of cpp stuff/d'\
3245       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3246       < Makefile.c > junk.c
3247   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3248       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3249   cat junk1.c junk2.c > Makefile.new
3250   rm -f junk.c junk1.c junk2.c
3251   chmod 444 Makefile.new
3252   mv -f Makefile.new Makefile
3253 )
3254
3255 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3256   echo creating src/.gdbinit
3257   echo source $srcdir/src/.gdbinit > src/.gdbinit
3258 fi
3259
3260 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3261
3262 m4_if(dnl       Do not change this comment
3263    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3264 )dnl