configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation; either version 3, or (at your option)
  14 dnl  any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  23 dnl  Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 dnl  Boston, MA 02110-1301, USA.
  25
  26 AC_PREREQ(2.61)dnl
  27 AC_INIT(emacs, 23.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 lispdir='${datadir}/emacs/${version}/lisp'
  36 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  37 '${datadir}/emacs/site-lisp'
  38 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  39 etcdir='${datadir}/emacs/${version}/etc'
  40 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  41 docdir='${datadir}/emacs/${version}/etc'
  42 gamedir='${localstatedir}/games/emacs'
  43
  44 gameuser=games
  45
  46 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  47 dnl Create a new --with option that defaults to being disabled.
  48 dnl NAME is the base name of the option.  The shell variable with_NAME
  49 dnl   will be set to either the user's value (if the option is
  50 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  51 dnl   option is not specified).  Note that the shell variable name is
  52 dnl   constructed as autoconf does, by replacing non-alphanumeric
  53 dnl   characters with "_".
  54 dnl HELP-STRING is the help text for the option.
  55 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  56   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  57     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  58 ])dnl
  59
  60 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  61 dnl Create a new --with option that defaults to being enabled.  NAME
  62 dnl   is the base name of the option.  The shell variable with_NAME
  63 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  64 dnl   'yes' (if the option is not specified).  Note that the shell
  65 dnl   variable name is constructed as autoconf does, by replacing
  66 dnl   non-alphanumeric characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  70    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  71 ])dnl
  72
  73 dnl By default, neither off nor on.
  74 AC_ARG_WITH([gcc],
  75 [AS_HELP_STRING([--without-gcc],
  76     [don't use GCC to compile Emacs even if GCC is found])])
  77
  78 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  79 if test "$with_pop" = yes; then
  80    AC_DEFINE(MAIL_USE_POP)
  81 fi
  82 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  85 if test "$with_kerberos" = yes; then
  86    AC_DEFINE(KERBEROS)
  87 fi
  88 AH_TEMPLATE(KERBEROS,
  89             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  90
  91 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  92 if test "${with_kerberos5}" = yes; then
  93   if test "${with_kerberos}" != yes; then
  94     with_kerberos=yes
  95     AC_DEFINE(KERBEROS)
  96   fi
  97   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  98 fi
  99
 100 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 101 if test "$with_hesiod" = yes; then
 102   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 103 fi
 104
 105 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 106
 107 dnl FIXME currently it is not the last.
 108 dnl This should be the last --with option, because --with-x is
 109 dnl added later on when we find the path of X, and it's best to
 110 dnl keep them together visually.
 111 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 112  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 113 [         case "${withval}" in
 114             y | ye | yes )      val=gtk ;;
 115             n | no )            val=no  ;;
 116             l | lu | luc | luci | lucid )       val=lucid ;;
 117             a | at | ath | athe | athen | athena )      val=athena ;;
 118             m | mo | mot | moti | motif )       val=motif ;;
 119             g | gt | gtk  )     val=gtk ;;
 120             * )
 121 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 122 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 123 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 124             ;;
 125           esac
 126           with_x_toolkit=$val
 127 ])
 128
 129 dnl _ON results in a '--without' option in the --help output, so
 130 dnl the help text should refer to "don't compile", etc.
 131 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 132 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 133 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 134 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 135 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 136 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 137
 138 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 139 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 140 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 141 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 142
 143 OPTION_DEFAULT_OFF([gtk],[use GTK toolkit])
 144 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 145 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 146 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 147 OPTION_DEFAULT_OFF([carbon],[use Carbon GUI on Mac OS X.  This is unsupported!])
 148
 149 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 150 OPTION_DEFAULT_OFF([dbus],[compile with D-Bus support])
 151
 152 AC_ARG_WITH([pkg-config-prog],dnl
 153 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 154                   [Path to pkg-config for finding GTK and librsvg])])
 155 if test "X${with_pkg_config_prog}" != X; then
 156    if test "${with_pkg_config_prog}" != yes; then
 157       PKG_CONFIG="${with_pkg_config_prog}"
 158    fi
 159 fi
 160
 161 AC_ARG_ENABLE(carbon-app,
 162 [AS_HELP_STRING([--enable-carbon-app@<:@=DIR@:>@],
 163                 [specify install directory for Emacs.app on Mac OS X
 164                  [DIR=/Application]])],
 165 [ carbon_appdir_x=${enableval}])
 166
 167 AC_ARG_ENABLE(font-backend,
 168 [  --enable-font-backend   compile code of font-backend support],
 169       USE_FONT_BACKEND=$enableval,
 170       USE_FONT_BACKEND=no)
 171
 172 AC_ARG_ENABLE(asserts,
 173 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 174       USE_XASSERTS=$enableval,
 175       USE_XASSERTS=no)
 176
 177 AC_ARG_ENABLE(maintainer-mode,
 178 [AS_HELP_STRING([--enable-maintainer-mode],
 179                 [enable make rules and dependencies not useful (and sometimes
 180                  confusing) to the casual installer])],
 181       USE_MAINTAINER_MODE=$enableval,
 182       USE_MAINTAINER_MODE=no)
 183 if test $USE_MAINTAINER_MODE = yes; then
 184   MAINT=
 185 else
 186   MAINT=#
 187 fi
 188 AC_SUBST(MAINT)
 189
 190 AC_ARG_ENABLE(locallisppath,
 191 [AS_HELP_STRING([--enable-locallisppath=PATH],
 192                 [directories Emacs should search for lisp files specific
 193                  to this site])],
 194 if test "${enableval}" = "no"; then
 195   locallisppath=
 196 elif test "${enableval}" != "yes"; then
 197   locallisppath=${enableval}
 198 fi)
 199
 200 #### Make srcdir absolute, if it isn't already.  It's important to
 201 #### avoid running the path through pwd unnecessarily, since pwd can
 202 #### give you automounter prefixes, which can go away.  We do all this
 203 #### so Emacs can find its files when run uninstalled.
 204 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 205 unset CDPATH
 206 case "${srcdir}" in
 207   /* ) ;;
 208   . )
 209     ## We may be able to use the $PWD environment variable to make this
 210     ## absolute.  But sometimes PWD is inaccurate.
 211     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 212     ## but that tested only for a well-formed and valid PWD,
 213     ## it did not object when PWD was well-formed and valid but just wrong.
 214     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 215     then
 216       srcdir="$PWD"
 217     else
 218       srcdir="`(cd ${srcdir}; pwd)`"
 219     fi
 220   ;;
 221   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 222 esac
 223
 224 #### Check if the source directory already has a configured system in it.
 225 if test `pwd` != `(cd ${srcdir} && pwd)` \
 226    && test -f "${srcdir}/src/config.h" ; then
 227   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 228    as a build directory right now; it has been configured in its own
 229    right.  To configure in another directory as well, you MUST
 230    use GNU make.  If you do not have GNU make, then you must
 231    now do `make distclean' in ${srcdir},
 232    and then run $0 again.]])
 233 fi
 234
 235 #### Given the configuration name, set machfile and opsysfile to the
 236 #### names of the m/*.h and s/*.h files we should use.
 237
 238 ### Canonicalize the configuration name.
 239
 240 AC_CANONICAL_HOST
 241 canonical=$host
 242 configuration=${host_alias-${build_alias-$host}}
 243
 244 dnl This used to use changequote, but, apart from `changequote is evil'
 245 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 246 dnl the great gob of text.  Thus it's not processed for possible expansion.
 247 dnl Just make sure the brackets remain balanced.
 248 dnl
 249 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 250 dnl indicated by comments.
 251 dnl quotation begins
 252 [
 253
 254 ### If you add support for a new configuration, add code to this
 255 ### switch statement to recognize your configuration name and select
 256 ### the appropriate operating system and machine description files.
 257
 258 ### You would hope that you could choose an m/*.h file pretty much
 259 ### based on the machine portion of the configuration name, and an s-
 260 ### file based on the operating system portion.  However, it turns out
 261 ### that each m/*.h file is pretty manufacturer-specific - for
 262 ### example hp9000s300.h is a 68000 machine;
 263 ### mips.h, pmax.h are all MIPS
 264 ### machines.  So we basically have to have a special case for each
 265 ### configuration name.
 266 ###
 267 ### As far as handling version numbers on operating systems is
 268 ### concerned, make sure things will fail in a fixable way.  If
 269 ### /etc/MACHINES doesn't say anything about version numbers, be
 270 ### prepared to handle anything reasonably.  If version numbers
 271 ### matter, be sure /etc/MACHINES says something about it.
 272 ###
 273 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 274 ### "System V Release 4"; he writes, "The old convention encouraged
 275 ### confusion between `system' and `release' levels'."
 276
 277 machine='' opsys='' unported=no
 278 case "${canonical}" in
 279
 280   ## FreeBSD ports
 281   *-*-freebsd* )
 282     opsys=freebsd
 283     case "${canonical}" in
 284       alpha*-*-freebsd*)        machine=alpha ;;
 285       ia64-*-freebsd*)          machine=ia64 ;;
 286       sparc64-*-freebsd*)       machine=sparc ;;
 287       powerpc-*-freebsd*)       machine=macppc ;;
 288       i[3456]86-*-freebsd*)     machine=intel386 ;;
 289       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 290     esac
 291   ;;
 292
 293   ## FreeBSD kernel + glibc based userland
 294   *-*-kfreebsd*gnu* )
 295     opsys=gnu-kfreebsd
 296     case "${canonical}" in
 297       alpha*-*-kfreebsd*)       machine=alpha ;;
 298       ia64-*-kfreebsd*)         machine=ia64 ;;
 299       sparc64-*-kfreebsd*)      machine=sparc ;;
 300       powerpc-*-kfreebsd*)      machine=macppc ;;
 301       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 302       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 303     esac
 304   ;;
 305
 306   ## NetBSD ports
 307   *-*-netbsd* )
 308     opsys=netbsd
 309     if test -f /usr/lib/crti.o; then]
 310 dnl The close and open brackets here are because this section is quoted --
 311 dnl see the `changequote' comment above.
 312       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 313 [   fi
 314
 315     case "${canonical}" in
 316       alpha*-*-netbsd*) machine=alpha ;;
 317       i[3456]86-*-netbsd*) machine=intel386 ;;
 318       m68k-*-netbsd*)
 319                         # This is somewhat bogus.
 320                         machine=hp9000s300 ;;
 321       mips-*-netbsd*)   machine=pmax ;;
 322       mipsel-*-netbsd*) machine=pmax ;;
 323       mipseb-*-netbsd*) machine=pmax ;;
 324       powerpc-*-netbsd*) machine=macppc ;;
 325       sparc*-*-netbsd*) machine=sparc ;;
 326       vax-*-netbsd*)    machine=vax ;;
 327       arm-*-netbsd*)    machine=arm ;;
 328       x86_64-*-netbsd*) machine=amdx86-64 ;;
 329       hppa-*-netbsd*)   machine=hp800 ;;
 330     esac
 331   ;;
 332
 333   ## OpenBSD ports
 334   *-*-openbsd* )
 335     opsys=openbsd
 336     case "${canonical}" in
 337       alpha*-*-openbsd*)        machine=alpha ;;
 338       arm-*-openbsd*)          machine=arm ;;
 339       hppa-*-openbsd*)         machine=hp9000s300 ;;
 340       i386-*-openbsd*)         machine=intel386 ;;
 341       m68k-*-openbsd*)         machine=hp9000s300 ;;
 342       mips64-*-openbsd*)       machine=mips64 ;;
 343       powerpc-*-openbsd*)      machine=macppc ;;
 344       sparc*-*-openbsd*)       machine=sparc ;;
 345       vax-*-openbsd*)          machine=vax ;;
 346       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 347     esac
 348   ;;
 349
 350   ## LynxOS ports
 351   *-*-lynxos* )
 352     opsys=lynxos
 353     case "${canonical}" in
 354       i[3456]86-*-lynxos*) machine=intel386 ;;
 355       powerpc-*-lynxos*) machine=powerpc ;;
 356     esac
 357   ;;
 358
 359   ## BSDI ports
 360   *-*-bsdi* )
 361     opsys=bsdi
 362     case "${canonical}" in
 363       i[345]86-*-bsdi*) machine=intel386 ;;
 364       sparc-*-bsdi*)  machine=sparc ;;
 365       powerpc-*-bsdi*)  machine=macppc ;;
 366     esac
 367     case "${canonical}" in
 368       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 369       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 370       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 371       *-*-bsdi3* )              opsys=bsdos3 ;;
 372       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 373     esac
 374   ;;
 375
 376   ## Alpha (DEC) machines.
 377   alpha*-dec-osf* )
 378     machine=alpha opsys=osf1
 379     # This is needed to find X11R6.1 libraries for certain tests.
 380     NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 381     GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 382     # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
 383     # due to non-traditional preprocessing with the current compiler
 384     # defaults.  OSF 4 can also have that compiler version, and there
 385     # seems always to have been a usable /usr/bin/cpp.
 386     NON_GNU_CPP=/usr/bin/cpp
 387     case "${canonical}" in
 388     alpha*-dec-osf[5-9]*)
 389       opsys=osf5-0 ;;
 390     esac
 391   ;;
 392
 393   alpha*-*-linux-gnu* )
 394     machine=alpha opsys=gnu-linux
 395   ;;
 396
 397   arm*-*-linux-gnu* )
 398     machine=arm opsys=gnu-linux
 399   ;;
 400
 401   ## Apple Darwin / Mac OS X
 402   *-apple-darwin* )
 403     case "${canonical}" in
 404       i[3456]86-* )  machine=intel386 ;;
 405       powerpc-* )    machine=powermac ;;
 406       * )            unported=yes ;;
 407     esac
 408     opsys=darwin
 409     # Define CPP as follows to make autoconf work correctly.
 410     CPP="${CC-cc} -E -no-cpp-precomp"
 411     # Use fink packages if available.
 412     if test -d /sw/include && test -d /sw/lib; then
 413       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 414       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 415       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 416     fi
 417   ;;
 418
 419   ## Compaq Nonstop
 420   mips-compaq-nonstopux* )
 421     machine=nonstopux opsys=nonstopux
 422     ;;
 423
 424   ## Cubix QBx/386
 425   i[3456]86-cubix-sysv* )
 426     machine=intel386 opsys=usg5-3
 427   ;;
 428
 429   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 430     machine=pmax opsys=bsd4-2
 431   ;;
 432   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 433     machine=pmax opsys=bsd4-3
 434   ;;
 435   mips-dec-ultrix* )
 436     machine=pmax opsys=ultrix4-3
 437   ;;
 438   mips-dec-osf* )
 439     machine=pmax opsys=osf1
 440   ;;
 441   mips-dec-mach_bsd4.3* )
 442     machine=pmax opsys=mach-bsd4-3
 443   ;;
 444
 445   ## HP 9000 series 200 or 300
 446   m68*-hp-bsd* )
 447     machine=hp9000s300 opsys=bsd4-3
 448   ;;
 449   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 450   m68*-hp-hpux* )
 451     case "`uname -r`" in
 452       ## Someone's system reports A.B8.05 for this.
 453       ## I wonder what other possibilities there are.
 454       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 455       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 456       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 457       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 458       *) machine=hp9000s300 opsys=hpux ;;
 459     esac
 460   ;;
 461
 462   ## HP 9000 series 700 and 800, running HP/UX
 463   hppa*-hp-hpux7* )
 464     machine=hp800 opsys=hpux
 465   ;;
 466   hppa*-hp-hpux8* )
 467     machine=hp800 opsys=hpux8
 468   ;;
 469   hppa*-hp-hpux9shr* )
 470     machine=hp800 opsys=hpux9shr
 471   ;;
 472   hppa*-hp-hpux9* )
 473     machine=hp800 opsys=hpux9
 474   ;;
 475   hppa*-hp-hpux10.2* )
 476     machine=hp800 opsys=hpux10-20
 477   ;;
 478   hppa*-hp-hpux10* )
 479     machine=hp800 opsys=hpux10
 480   ;;
 481   hppa*-hp-hpux1[1-9]* )
 482     machine=hp800 opsys=hpux11
 483     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 484   ;;
 485
 486   hppa*-*-linux-gnu* )
 487     machine=hp800 opsys=gnu-linux
 488   ;;
 489
 490   ## HP 9000 series 700 and 800, running HP/UX
 491   hppa*-hp-hpux* )
 492     ## Cross-compilation?  Nah!
 493     case "`uname -r`" in
 494       ## Someone's system reports A.B8.05 for this.
 495       ## I wonder what other possibilities there are.
 496       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 497       *.08.* ) machine=hp800 opsys=hpux8 ;;
 498       *.09.* ) machine=hp800 opsys=hpux9 ;;
 499       *) machine=hp800 opsys=hpux10 ;;
 500     esac
 501   ;;
 502   hppa*-*-nextstep* )
 503     machine=hp800 opsys=nextstep
 504   ;;
 505
 506   ## IBM machines
 507   i370-ibm-aix*)
 508     machine=ibm370aix opsys=usg5-3
 509   ;;
 510   s390-*-linux-gnu* )
 511     machine=ibms390 opsys=gnu-linux
 512   ;;
 513   s390x-*-linux-gnu* )
 514     machine=ibms390x opsys=gnu-linux
 515   ;;
 516   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 517     machine=ibmrs6000 opsys=aix3-1
 518   ;;
 519   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 520     machine=ibmrs6000 opsys=aix3-2-5
 521   ;;
 522   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 523     machine=ibmrs6000 opsys=aix4-1
 524   ;;
 525   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 526     machine=ibmrs6000 opsys=aix4-2
 527   ;;
 528   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 529     machine=ibmrs6000 opsys=aix4-2
 530   ;;
 531   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 532     machine=ibmrs6000 opsys=aix4-2
 533   ;;
 534   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 535     machine=ibmrs6000 opsys=aix4
 536   ;;
 537   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 538     machine=ibmrs6000 opsys=aix4-1
 539   ;;
 540   rs6000-ibm-aix* | powerpc-ibm-aix* )
 541     machine=ibmrs6000 opsys=aix3-2
 542   ;;
 543
 544   ## Prime EXL
 545   i[3456]86-prime-sysv* )
 546     machine=i386 opsys=usg5-3
 547   ;;
 548
 549   ## ncr machine running svr4.3.
 550   i[3456]86-ncr-sysv4.3 )
 551     machine=ncr386 opsys=usg5-4-3
 552   ;;
 553
 554   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 555   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 556   i[3456]86-ncr-sysv* )
 557     machine=ncr386 opsys=usg5-4-2
 558   ;;
 559
 560   ## Macintosh PowerPC
 561   powerpc*-*-linux-gnu* )
 562     machine=macppc opsys=gnu-linux
 563   ;;
 564
 565   ## Workstations sold by MIPS
 566   ## This is not necessarily all workstations using the MIPS processor -
 567   ## Irises are produced by SGI, and DECstations by DEC.
 568
 569   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 570   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 571   ## it gives for choosing between the alternatives seems to be "Use
 572   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 573   ## the BSD world."  I'll assume that these are instructions for
 574   ## handling two odd situations, and that every other situation
 575   ## should use mips.h and usg5-2-2, they being listed first.
 576   mips-mips-usg* )
 577     machine=mips4
 578     ## Fall through to the general code at the bottom to decide on the OS.
 579   ;;
 580   mips-mips-riscos4* )
 581     machine=mips4 opsys=bsd4-3
 582     NON_GNU_CC="cc -systype bsd43"
 583     NON_GNU_CPP="cc -systype bsd43 -E"
 584   ;;
 585   mips-mips-riscos5* )
 586     machine=mips4 opsys=riscos5
 587     NON_GNU_CC="cc -systype bsd43"
 588     NON_GNU_CPP="cc -systype bsd43 -E"
 589   ;;
 590   mips-mips-bsd* )
 591     machine=mips opsys=bsd4-3
 592   ;;
 593   mips-mips-* )
 594     machine=mips opsys=usg5-2-2
 595   ;;
 596
 597   ## NeXT
 598   m68*-next-* | m68k-*-nextstep* )
 599     machine=m68k opsys=nextstep
 600   ;;
 601
 602   ## NEC EWS4800
 603   mips-nec-sysv4*)
 604   machine=ews4800 opsys=ux4800
 605   ;;
 606
 607   ## Siemens Nixdorf
 608   mips-siemens-sysv* | mips-sni-sysv*)
 609     machine=mips-siemens opsys=usg5-4
 610     NON_GNU_CC=/usr/ccs/bin/cc
 611     NON_GNU_CPP=/usr/ccs/lib/cpp
 612   ;;
 613
 614   ## Silicon Graphics machines
 615   ## Iris 4D
 616   mips-sgi-irix6.5 )
 617     machine=iris4d opsys=irix6-5
 618     # Without defining _LANGUAGE_C, things get masked out in the headers
 619     # so that, for instance, grepping for `free' in stdlib.h fails and
 620     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 621     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 622     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 623   ;;
 624   mips-sgi-irix6* )
 625     machine=iris4d opsys=irix6-0
 626     # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
 627     # but presumably it does no harm.
 628     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 629     # -32 probably isn't necessary in later v.6s -- anyone know which?
 630     NON_GCC_TEST_OPTIONS=-32
 631   ;;
 632   mips-sgi-irix5.[01]* )
 633     machine=iris4d opsys=irix5-0
 634   ;;
 635   mips-sgi-irix5* | mips-sgi-irix* )
 636     machine=iris4d opsys=irix5-2
 637   ;;
 638
 639   ## Suns
 640   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 641     machine=sparc opsys=gnu-linux
 642   ;;
 643
 644   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 645     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 646     | rs6000-*-solaris2*)
 647     case "${canonical}" in
 648       i[3456]86-*-* )     machine=intel386 ;;
 649       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 650       powerpcle* )      machine=powerpcle ;;
 651       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 652       sparc* )          machine=sparc ;;
 653       * )               unported=yes ;;
 654     esac
 655     case "${canonical}" in
 656       *-sunos5.3* | *-solaris2.3* )
 657                 opsys=sol2-3
 658                 NON_GNU_CPP=/usr/ccs/lib/cpp
 659                 ;;
 660       *-sunos5.4* | *-solaris2.4* )
 661                 opsys=sol2-4
 662                 NON_GNU_CPP=/usr/ccs/lib/cpp
 663                 RANLIB="ar -ts"
 664                 ;;
 665       *-sunos5.5* | *-solaris2.5* )
 666                 opsys=sol2-5
 667                 NON_GNU_CPP=/usr/ccs/lib/cpp
 668                 RANLIB="ar -ts"
 669                 ;;
 670       *-sunos5.6* | *-solaris2.6* )
 671                 opsys=sol2-6
 672                 NON_GNU_CPP=/usr/ccs/lib/cpp
 673                 RANLIB="ar -ts"
 674                 ;;
 675       *-sunos5* | *-solaris* )
 676                 opsys=sol2-6
 677                 emacs_check_sunpro_c=yes
 678                 NON_GNU_CPP=/usr/ccs/lib/cpp
 679                 ;;
 680       *                   ) opsys=bsd4-2   ;;
 681     esac
 682     ## Watch out for a compiler that we know will not work.
 683     case "${canonical}" in
 684      *-solaris* | *-sunos5* )
 685                 if [ "x$CC" = x/usr/ucb/cc ]; then
 686                   ## /usr/ucb/cc doesn't work;
 687                   ## we should find some other compiler that does work.
 688                   unset CC
 689                 fi
 690                 ;;
 691       *) ;;
 692     esac
 693   ;;
 694   sparc-*-nextstep* )
 695     machine=sparc opsys=nextstep
 696   ;;
 697
 698   ## Tandem Integrity S2
 699   mips-tandem-sysv* )
 700     machine=tandem-s2 opsys=usg5-3
 701   ;;
 702
 703   ## Vaxen.
 704   vax-dec-* )
 705     machine=vax
 706     case "${canonical}" in
 707       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 708       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 709       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 710       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 711       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 712       *-vms* )                                          opsys=vms ;;
 713       * )                                               unported=yes
 714     esac
 715   ;;
 716
 717   ## IA-64
 718   ia64*-*-linux* )
 719     machine=ia64 opsys=gnu-linux
 720   ;;
 721
 722   ## Intel 386 machines where we don't care about the manufacturer
 723   i[3456]86-*-* )
 724     machine=intel386
 725     case "${canonical}" in
 726       *-cygwin )                opsys=cygwin ;;
 727       *-darwin* )               opsys=darwin
 728                                 CPP="${CC-cc} -E -no-cpp-precomp"
 729                                 ;;
 730       *-xenix* )                opsys=xenix ;;
 731       *-linux-gnu* )            opsys=gnu-linux ;;
 732       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 733       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 734       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 735       *-386bsd* )               opsys=386bsd ;;
 736       *-nextstep* )             opsys=nextstep ;;
 737       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 738     esac
 739   ;;
 740
 741   ## m68k Linux-based GNU system
 742   m68k-*-linux-gnu* )
 743     machine=m68k opsys=gnu-linux
 744   ;;
 745
 746   ## Mips Linux-based GNU system
 747   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 748     machine=mips opsys=gnu-linux
 749   ;;
 750
 751   ## UXP/DS
 752   sparc-fujitsu-sysv4* )
 753     machine=sparc opsys=uxpds
 754     NON_GNU_CPP=/usr/ccs/lib/cpp
 755     RANLIB="ar -ts"
 756   ;;
 757
 758   ## AMD x86-64 Linux-based GNU system
 759   x86_64-*-linux-gnu* )
 760     machine=amdx86-64 opsys=gnu-linux
 761   ;;
 762
 763   ## Tensilica Xtensa Linux-based GNU system
 764   xtensa*-*-linux-gnu* )
 765     machine=xtensa opsys=gnu-linux
 766     ;;
 767
 768   * )
 769     unported=yes
 770   ;;
 771 esac
 772
 773 ### If the code above didn't choose an operating system, just choose
 774 ### an operating system based on the configuration name.  You really
 775 ### only want to use this when you have no idea what the right
 776 ### operating system is; if you know what operating systems a machine
 777 ### runs, it's cleaner to make it explicit in the case statement
 778 ### above.
 779 if test x"${opsys}" = x; then
 780   case "${canonical}" in
 781     *-gnu* )                            opsys=gnu ;;
 782     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 783     *-bsd4.2 )                          opsys=bsd4-2 ;;
 784     *-bsd4.3 )                          opsys=bsd4-3 ;;
 785     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 786     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 787     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 788     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 789     *-sysv4.2uw* )                      opsys=unixware ;;
 790     *-sysv5uw* )                        opsys=unixware ;;
 791     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 792     *-sysv4.1* | *-sysvr4.1* )
 793         NON_GNU_CPP=/usr/lib/cpp
 794         opsys=usg5-4 ;;
 795     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 796         if [ x$NON_GNU_CPP = x ]; then
 797           if [ -f /usr/ccs/lib/cpp ]; then
 798             NON_GNU_CPP=/usr/ccs/lib/cpp
 799           else
 800             NON_GNU_CPP=/lib/cpp
 801           fi
 802         fi
 803         opsys=usg5-4-2 ;;
 804     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 805     * )
 806       unported=yes
 807     ;;
 808   esac
 809 fi
 810
 811 ]
 812 dnl quotation ends
 813
 814 if test $unported = yes; then
 815   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 816 Check `etc/MACHINES' for recognized configuration names.])
 817 fi
 818
 819 machfile="m/${machine}.h"
 820 opsysfile="s/${opsys}.h"
 821
 822
 823 #### Choose a compiler.
 824 test -n "$CC" && cc_specified=yes
 825
 826 # Save the value of CFLAGS that the user specified.
 827 SPECIFIED_CFLAGS="$CFLAGS"
 828
 829 case ${with_gcc} in
 830   "yes" ) CC="gcc" GCC=yes ;;
 831   "no"  ) : ${CC=cc} ;;
 832   * )
 833 esac
 834 AC_PROG_CC
 835
 836 # On Suns, sometimes $CPP names a directory.
 837 if test -n "$CPP" && test -d "$CPP"; then
 838   CPP=
 839 fi
 840
 841 ## If not using gcc, and on Solaris, and no CPP specified, see if
 842 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 843 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 844  test x"$CPP" = x; then
 845   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 846   AC_CACHE_VAL(emacs_cv_sunpro_c,
 847   [AC_TRY_LINK([],
 848 [#ifndef __SUNPRO_C
 849 fail;
 850 #endif
 851 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 852   AC_MSG_RESULT($emacs_cv_sunpro_c)
 853
 854   if test x"$emacs_cv_sunpro_c" = xyes; then
 855     NON_GNU_CPP="$CC -E -Xs"
 856   fi
 857 fi
 858
 859 #### Some systems specify a CPP to use unless we are using GCC.
 860 #### Now that we know whether we are using GCC, we can decide whether
 861 #### to use that one.
 862 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 863 then
 864   CPP="$NON_GNU_CPP"
 865 fi
 866
 867 #### Some systems specify a CC to use unless we are using GCC.
 868 #### Now that we know whether we are using GCC, we can decide whether
 869 #### to use that one.
 870 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 871   test x$cc_specified != xyes
 872 then
 873   CC="$NON_GNU_CC"
 874 fi
 875
 876 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 877 then
 878   CC="$CC $GCC_TEST_OPTIONS"
 879 fi
 880
 881 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 882 then
 883   CC="$CC $NON_GCC_TEST_OPTIONS"
 884 fi
 885
 886 dnl checks for Unix variants
 887 AC_AIX
 888 AC_GNU_SOURCE
 889
 890 ### Use -Wno-pointer-sign if the compiler supports it
 891 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 892 SAVE_CFLAGS="$CFLAGS"
 893 CFLAGS="$CFLAGS -Wno-pointer-sign"
 894 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 895 if test $has_option = yes; then
 896    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 897 fi
 898 AC_MSG_RESULT($has_option)
 899 CFLAGS="$SAVE_CFLAGS"
 900 unset has_option
 901 unset SAVE_CFLAGS
 902
 903 #### Some other nice autoconf tests.
 904
 905 dnl checks for programs
 906 AC_PROG_LN_S
 907 AC_PROG_CPP
 908 AC_PROG_INSTALL
 909 if test "x$RANLIB" = x; then
 910   AC_PROG_RANLIB
 911 fi
 912 AC_PATH_PROG(INSTALL_INFO, install-info)
 913 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 914 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 915 dnl Don't use GZIP, which is used by gzip for additional parameters.
 916 AC_PATH_PROG(GZIP_PROG, gzip)
 917
 918
 919 ## Need makeinfo >= 4.6 (?) to build the manuals.
 920 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 921 dnl By this stage, configure has already checked for egrep and set EGREP,
 922 dnl or exited with an error if no egrep was found.
 923 if test "$MAKEINFO" != "no" && \
 924   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 925    MAKEINFO=no
 926 fi
 927
 928 if test "$MAKEINFO" = "no"; then
 929   AC_MSG_ERROR( [makeinfo >= 4.6 is required] )
 930 fi
 931
 932
 933 dnl Add our options to ac_link now, after it is set up.
 934
 935 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 936 then
 937   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 938 fi
 939
 940 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 941 then
 942   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 943 fi
 944
 945 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 946 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 947 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 948 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 949 dnl if not built to support GNU ld.
 950
 951 late_LDFLAGS=$LDFLAGS
 952 if test "$GCC" = yes; then
 953   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 954 else
 955   LDFLAGS="$LDFLAGS -znocombreloc"
 956 fi
 957
 958 AC_MSG_CHECKING([for -znocombreloc])
 959 AC_LINK_IFELSE([main(){return 0;}],
 960   [AC_MSG_RESULT(yes)],
 961   LDFLAGS=$late_LDFLAGS
 962   [AC_MSG_RESULT(no)])
 963
 964 #### Extract some information from the operating system and machine files.
 965
 966 AC_CHECKING([the machine- and system-dependent files to find out
 967  - which libraries the lib-src programs will want, and
 968  - whether the GNU malloc routines are usable])
 969
 970 ### First figure out CFLAGS (which we use for running the compiler here)
 971 ### and REAL_CFLAGS (which we use for real compilation).
 972 ### The two are the same except on a few systems, where they are made
 973 ### different to work around various lossages.  For example,
 974 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 975 ### as implying static linking.
 976
 977 ### If the CFLAGS env var is specified, we use that value
 978 ### instead of the default.
 979
 980 ### It's not important that this name contain the PID; you can't run
 981 ### two configures in the same directory and have anything work
 982 ### anyway.
 983 tempcname="conftest.c"
 984
 985 echo '
 986 #include "'${srcdir}'/src/'${opsysfile}'"
 987 #include "'${srcdir}'/src/'${machfile}'"
 988 #ifndef LIBS_MACHINE
 989 #define LIBS_MACHINE
 990 #endif
 991 #ifndef LIBS_SYSTEM
 992 #define LIBS_SYSTEM
 993 #endif
 994 #ifndef C_SWITCH_SYSTEM
 995 #define C_SWITCH_SYSTEM
 996 #endif
 997 #ifndef C_SWITCH_MACHINE
 998 #define C_SWITCH_MACHINE
 999 #endif
1000 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1001 configure___ c_switch_system=C_SWITCH_SYSTEM
1002 configure___ c_switch_machine=C_SWITCH_MACHINE
1003
1004 #ifndef LIB_X11_LIB
1005 #define LIB_X11_LIB -lX11
1006 #endif
1007
1008 #ifndef LIBX11_MACHINE
1009 #define LIBX11_MACHINE
1010 #endif
1011
1012 #ifndef LIBX11_SYSTEM
1013 #define LIBX11_SYSTEM
1014 #endif
1015 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1016
1017 #ifdef UNEXEC
1018 configure___ unexec=UNEXEC
1019 #else
1020 configure___ unexec=unexec.o
1021 #endif
1022
1023 #ifdef SYSTEM_MALLOC
1024 configure___ system_malloc=yes
1025 #else
1026 configure___ system_malloc=no
1027 #endif
1028
1029 #ifdef USE_MMAP_FOR_BUFFERS
1030 configure___ use_mmap_for_buffers=yes
1031 #else
1032 configure___ use_mmap_for_buffers=no
1033 #endif
1034
1035 #ifndef C_DEBUG_SWITCH
1036 #define C_DEBUG_SWITCH -g
1037 #endif
1038
1039 #ifndef C_OPTIMIZE_SWITCH
1040 #ifdef __GNUC__
1041 #define C_OPTIMIZE_SWITCH -O2
1042 #else
1043 #define C_OPTIMIZE_SWITCH -O
1044 #endif
1045 #endif
1046
1047 #ifndef C_WARNINGS_SWITCH
1048 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
1049 #endif
1050
1051 #ifndef LD_SWITCH_MACHINE
1052 #define LD_SWITCH_MACHINE
1053 #endif
1054
1055 #ifndef LD_SWITCH_SYSTEM
1056 #define LD_SWITCH_SYSTEM
1057 #endif
1058
1059 #ifndef LD_SWITCH_X_SITE_AUX
1060 #define LD_SWITCH_X_SITE_AUX
1061 #endif
1062
1063 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1064 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1065
1066 #ifdef THIS_IS_CONFIGURE
1067
1068 /* Get the CFLAGS for tests in configure.  */
1069 #ifdef __GNUC__
1070 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1071 #else
1072 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1073 #endif
1074
1075 #else /* not THIS_IS_CONFIGURE */
1076
1077 /* Get the CFLAGS for real compilation.  */
1078 #ifdef __GNUC__
1079 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
1080 #else
1081 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1082 #endif
1083
1084 #endif /* not THIS_IS_CONFIGURE */
1085 ' > ${tempcname}
1086
1087 # The value of CPP is a quoted variable reference, so we need to do this
1088 # to get its actual value...
1089 CPP=`eval "echo $CPP"`
1090 [eval `${CPP} -Isrc ${tempcname} \
1091        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1092 if test "x$SPECIFIED_CFLAGS" = x; then
1093   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1094          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1095 else
1096   REAL_CFLAGS="$CFLAGS"
1097 fi]
1098 rm ${tempcname}
1099
1100 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1101
1102 ### Make sure subsequent tests use flags consistent with the build flags.
1103
1104 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1105   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1106 else
1107   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1108 fi
1109
1110 dnl For AC_FUNC_GETLOADAVG, at least:
1111 AC_CONFIG_LIBOBJ_DIR(src)
1112
1113 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1114 AC_SYS_LARGEFILE
1115
1116
1117 ### The standard library on x86-64 and s390x GNU/Linux distributions can
1118 ### be located in either /usr/lib64 or /usr/lib.
1119 case "${canonical}" in
1120   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1121     if test -d /usr/lib64; then
1122       AC_DEFINE(HAVE_LIB64_DIR, 1,
1123         [Define to 1 if the directory /usr/lib64 exists.])
1124 fi
1125 esac
1126
1127 dnl This function defintion taken from Gnome 2.0
1128 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1129 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1130 dnl also defines GSTUFF_PKG_ERRORS on error
1131 AC_DEFUN([PKG_CHECK_MODULES], [
1132   succeeded=no
1133
1134   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1135
1136   if test "$PKG_CONFIG" = "no" ; then
1137      ifelse([$4], , [AC_MSG_ERROR([
1138       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1139   else
1140      PKG_CONFIG_MIN_VERSION=0.9.0
1141      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1142         AC_MSG_CHECKING(for $2)
1143
1144         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1145             AC_MSG_RESULT(yes)
1146             succeeded=yes
1147
1148             AC_MSG_CHECKING($1_CFLAGS)
1149             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1150             AC_MSG_RESULT($$1_CFLAGS)
1151
1152             AC_MSG_CHECKING($1_LIBS)
1153             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1154             AC_MSG_RESULT($$1_LIBS)
1155         else
1156             AC_MSG_RESULT(no)
1157             $1_CFLAGS=""
1158             $1_LIBS=""
1159             ## If we have a custom action on failure, don't print errors, but
1160             ## do set a variable so people can do so.
1161             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1162             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1163         fi
1164
1165         AC_SUBST($1_CFLAGS)
1166         AC_SUBST($1_LIBS)
1167      else
1168         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1169         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1170      fi
1171   fi
1172
1173   if test $succeeded = yes; then
1174      ifelse([$3], , :, [$3])
1175   else
1176      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1177   fi
1178 ])
1179
1180
1181 if test "${with_sound}" != "no"; then
1182   # Sound support for GNU/Linux and the free BSDs.
1183   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1184   # Emulation library used on NetBSD.
1185   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1186   AC_SUBST(LIBSOUND)
1187
1188   ALSA_REQUIRED=1.0.0
1189   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1190   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1191   if test $HAVE_ALSA = yes; then
1192     SAVE_CFLAGS="$CFLAGS"
1193     SAVE_LDFLAGS="$LDFLAGS"
1194     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1195     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1196     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1197                     emacs_alsa_normal=yes,
1198                     emacs_alsa_normal=no)
1199     if test "$emacs_alsa_normal" != yes; then
1200       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1201                      [snd_lib_error_set_handler (0);],
1202                      emacs_alsa_subdir=yes,
1203                      emacs_alsa_subdir=no)
1204       if test "$emacs_alsa_subdir" != yes; then
1205         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1206       fi
1207       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1208     fi
1209
1210     CFLAGS="$SAVE_CFLAGS"
1211     LDFLAGS="$SAVE_LDFLAGS"
1212     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1213     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1214     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1215   fi
1216   AC_SUBST(CFLAGS_SOUND)
1217 fi
1218
1219 dnl checks for header files
1220 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1221   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1222   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1223   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1224   sys/utsname.h pwd.h)
1225
1226 AC_MSG_CHECKING(if personality LINUX32 can be set)
1227 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1228                emacs_cv_personality_linux32=yes,
1229                emacs_cv_personality_linux32=no)
1230 AC_MSG_RESULT($emacs_cv_personality_linux32)
1231
1232 if test $emacs_cv_personality_linux32 = yes; then
1233   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1234             [Define to 1 if personality LINUX32 can be set.])
1235 fi
1236
1237 dnl On Solaris 8 there's a compilation warning for term.h because
1238 dnl it doesn't define `bool'.
1239 AC_CHECK_HEADERS(term.h, , , -)
1240 AC_HEADER_STDC
1241 AC_HEADER_TIME
1242 AC_CHECK_DECLS([sys_siglist])
1243 if test $ac_cv_have_decl_sys_siglist != yes; then
1244   # For Tru64, at least:
1245   AC_CHECK_DECLS([__sys_siglist])
1246   if test $ac_cv_have_decl___sys_siglist = yes; then
1247     AC_DEFINE(sys_siglist, __sys_siglist,
1248               [Define to any substitute for sys_siglist.])
1249   fi
1250 fi
1251 AC_HEADER_SYS_WAIT
1252
1253 dnl Some systems have utime.h but don't declare the struct anyplace.
1254 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1255 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1256 #include <sys/time.h>
1257 #include <time.h>
1258 #else
1259 #ifdef HAVE_SYS_TIME_H
1260 #include <sys/time.h>
1261 #else
1262 #include <time.h>
1263 #endif
1264 #endif
1265 #ifdef HAVE_UTIME_H
1266 #include <utime.h>
1267 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1268   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1269 if test $emacs_cv_struct_utimbuf = yes; then
1270   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1271 fi
1272
1273 dnl checks for typedefs
1274 AC_TYPE_SIGNAL
1275
1276 dnl Check for speed_t typedef.
1277 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1278   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1279     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1280 if test $emacs_cv_speed_t = yes; then
1281   AC_DEFINE(HAVE_SPEED_T, 1,
1282            [Define to 1 if `speed_t' is declared by <termios.h>.])
1283 fi
1284
1285 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1286 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1287 #include <sys/time.h>
1288 #include <time.h>
1289 #else
1290 #ifdef HAVE_SYS_TIME_H
1291 #include <sys/time.h>
1292 #else
1293 #include <time.h>
1294 #endif
1295 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1296   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1297 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1298 if test $emacs_cv_struct_timeval = yes; then
1299   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1300 fi
1301
1302 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1303 AC_TRY_COMPILE([#include <math.h>],
1304 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1305   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1306 HAVE_EXCEPTION=$emacs_cv_struct_exception
1307 if test $emacs_cv_struct_exception != yes; then
1308   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1309 fi
1310
1311 AC_CHECK_HEADERS(sys/socket.h)
1312 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1313 #if HAVE_SYS_SOCKET_H
1314 #include <sys/socket.h>
1315 #endif])
1316
1317 dnl checks for structure members
1318 AC_STRUCT_TM
1319 AC_STRUCT_TIMEZONE
1320 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1321                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1322                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1323                 [#include <time.h>])
1324 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1325                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1326                   struct ifreq.ifr_addr], , ,
1327                  [AC_INCLUDES_DEFAULT
1328 #if HAVE_SYS_SOCKET_H
1329 #include <sys/socket.h>
1330 #endif
1331 #if HAVE_NET_IF_H
1332 #include <net/if.h>
1333 #endif])
1334
1335 dnl checks for compiler characteristics
1336
1337 dnl Testing __STDC__ to determine prototype support isn't good enough.
1338 dnl DEC C, for instance, doesn't define it with default options, and
1339 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1340 dnl and void *.
1341 AC_C_PROTOTYPES
1342 AC_C_VOLATILE
1343 AC_C_CONST
1344 dnl This isn't useful because we can't turn on use of `inline' unless
1345 dnl the compiler groks `extern inline'.
1346 dnl AC_C_INLINE
1347 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1348   [AC_TRY_COMPILE(, [void * foo;],
1349                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1350 if test $emacs_cv_void_star = yes; then
1351   AC_DEFINE(POINTER_TYPE, void)
1352 else
1353   AC_DEFINE(POINTER_TYPE, char)
1354 fi
1355 AH_TEMPLATE(POINTER_TYPE,
1356             [Define as `void' if your compiler accepts `void *'; otherwise
1357              define as `char'.])dnl
1358
1359
1360
1361 dnl This could be used for targets which can have both byte sexes.
1362 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1363 dnl AC_C_BIGENDIAN
1364
1365 dnl check for Make feature
1366 AC_PROG_MAKE_SET
1367
1368 dnl checks for operating system services
1369 AC_SYS_LONG_FILE_NAMES
1370
1371 #### Choose a window system.
1372
1373 AC_PATH_X
1374 if test "$no_x" = yes; then
1375   window_system=none
1376 else
1377   window_system=x11
1378 fi
1379
1380 if test "${x_libraries}" != NONE; then
1381   if test -n "${x_libraries}"; then
1382     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1383     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1384   fi
1385   x_default_search_path=""
1386   x_search_path=${x_libraries}
1387   if test -z "${x_search_path}"; then
1388     x_search_path=/usr/lib
1389   fi
1390   for x_library in `echo ${x_search_path}: | \
1391                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1392     x_search_path="\
1393 ${x_library}/X11/%L/%T/%N%C%S:\
1394 ${x_library}/X11/%l/%T/%N%C%S:\
1395 ${x_library}/X11/%T/%N%C%S:\
1396 ${x_library}/X11/%L/%T/%N%S:\
1397 ${x_library}/X11/%l/%T/%N%S:\
1398 ${x_library}/X11/%T/%N%S"
1399     if test x"${x_default_search_path}" = x; then
1400       x_default_search_path=${x_search_path}
1401     else
1402       x_default_search_path="${x_search_path}:${x_default_search_path}"
1403     fi
1404   done
1405 fi
1406 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1407   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1408 fi
1409
1410 if test x"${x_includes}" = x; then
1411   bitmapdir=/usr/include/X11/bitmaps
1412 else
1413   # accumulate include directories that have X11 bitmap subdirectories
1414   bmd_acc="dummyval"
1415   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1416     if test -d "${bmd}/X11/bitmaps"; then
1417       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1418     fi
1419     if test -d "${bmd}/bitmaps"; then
1420       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1421     fi
1422   done
1423   if test ${bmd_acc} != "dummyval"; then
1424     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1425   fi
1426 fi
1427
1428 HAVE_CARBON=no
1429 if test "${with_carbon}" != no; then
1430   AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1431 fi
1432 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1433   if test "${with_carbon+set}" != set \
1434      && test "${carbon_appdir_x+set}" != set; then
1435     for var in with_x with_x_toolkit with_gtk with_xim \
1436                with_xpm with_jpeg with_tiff with_gif with_png; do
1437       if eval test \"\${$var+set}\" = set; then
1438         HAVE_CARBON=no
1439         break
1440       fi
1441     done
1442   fi
1443 fi
1444 if test "${HAVE_CARBON}" = yes; then
1445   window_system=mac
1446 fi
1447
1448 case "${window_system}" in
1449   x11 )
1450     HAVE_X_WINDOWS=yes
1451     HAVE_X11=yes
1452     case "${with_x_toolkit}" in
1453       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1454       motif ) USE_X_TOOLKIT=MOTIF ;;
1455       gtk ) with_gtk=yes
1456 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1457 dnl USE_X_TOOLKIT is set.
1458             USE_X_TOOLKIT=none ;;
1459       no ) USE_X_TOOLKIT=none ;;
1460 dnl If user did not say whether to use a toolkit, make this decision later:
1461 dnl use the toolkit if we have gtk, or X11R5 or newer.
1462       * )
1463           if test x"$with_gtk" = xyes; then
1464              USE_X_TOOLKIT=none
1465           else
1466              USE_X_TOOLKIT=maybe
1467           fi
1468           ;;
1469     esac
1470   ;;
1471   mac | none )
1472     HAVE_X_WINDOWS=no
1473     HAVE_X11=no
1474     USE_X_TOOLKIT=none
1475   ;;
1476 esac
1477
1478 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1479    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1480    if test "$HAVE_XSERVER" = true ||
1481       test -n "$DISPLAY" ||
1482       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1483         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1484 were found.  You should install the relevant development files for X
1485 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1486 sure you have development files for image handling, i.e.
1487 tiff, gif, jpeg, png and xpm.
1488 If you are sure you want Emacs compiled without X window support, pass
1489   --without-x
1490 to configure.])
1491    fi
1492 fi
1493
1494 ### If we're using X11, we should use the X menu package.
1495 HAVE_MENUS=no
1496 case ${HAVE_X11} in
1497   yes ) HAVE_MENUS=yes ;;
1498 esac
1499
1500 ### Compute the unexec source name from the object name.
1501 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1502
1503 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1504 # Assume not, until told otherwise.
1505 GNU_MALLOC=yes
1506 doug_lea_malloc=yes
1507 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1508 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1509 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1510                emacs_cv_var___after_morecore_hook,
1511 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1512   emacs_cv_var___after_morecore_hook=yes,
1513   emacs_cv_var___after_morecore_hook=no)])
1514 if test $emacs_cv_var___after_morecore_hook = no; then
1515   doug_lea_malloc=no
1516 fi
1517 if test "${system_malloc}" = "yes"; then
1518   GNU_MALLOC=no
1519   GNU_MALLOC_reason="
1520     (The GNU allocators don't work with this system configuration.)"
1521 fi
1522 if test "$doug_lea_malloc" = "yes" ; then
1523   if test "$GNU_MALLOC" = yes ; then
1524     GNU_MALLOC_reason="
1525       (Using Doug Lea's new malloc from the GNU C Library.)"
1526   fi
1527   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1528             [Define to 1 if you are using the GNU C Library.])
1529 fi
1530
1531 if test x"${REL_ALLOC}" = x; then
1532   REL_ALLOC=${GNU_MALLOC}
1533 fi
1534
1535 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1536 dnl the system configuration file (s/*.h) to turn the use of mmap
1537 dnl in the relocating allocator on.
1538
1539 AC_FUNC_MMAP
1540 if test $use_mmap_for_buffers = yes; then
1541   REL_ALLOC=no
1542 fi
1543
1544 LIBS="$libsrc_libs $LIBS"
1545
1546 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1547 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1548 AC_CHECK_LIB(dnet, dnet_ntoa)
1549 dnl This causes -lresolv to get used in subsequent tests,
1550 dnl which causes failures on some systems such as HPUX 9.
1551 dnl AC_CHECK_LIB(resolv, gethostbyname)
1552
1553 dnl FIXME replace main with a function we actually want from this library.
1554 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1555
1556 AC_CHECK_LIB(pthreads, cma_open)
1557
1558 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1559 if test -d /usr/X386/include; then
1560   HAVE_XFREE386=yes
1561   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1562 else
1563   HAVE_XFREE386=no
1564 fi
1565 AC_MSG_RESULT($HAVE_XFREE386)
1566
1567 dnl Check for need for bigtoc support on IBM AIX
1568
1569 case ${host_os} in
1570 aix*)
1571   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1572     case $GCC in
1573     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1574     *) gdb_cv_bigtoc=-bbigtoc ;;
1575     esac
1576
1577     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1578     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1579   ])
1580   ;;
1581 esac
1582
1583 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1584 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1585 # REAL_CPPFLAGS later on.
1586
1587 REAL_CPPFLAGS="$CPPFLAGS"
1588
1589 if test "${HAVE_X11}" = "yes"; then
1590   DEFS="$C_SWITCH_X_SITE $DEFS"
1591   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1592   LIBS="$LIBX $LIBS"
1593   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1594   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1595
1596   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1597   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1598   # but it's more convenient here to set LD_RUN_PATH
1599   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1600   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1601     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1602     export LD_RUN_PATH
1603   fi
1604
1605   if test "${opsys}" = "gnu-linux"; then
1606     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1607     AC_TRY_LINK([],
1608      [XOpenDisplay ("foo");],
1609      [xlinux_first_failure=no],
1610      [xlinux_first_failure=yes])
1611     if test "${xlinux_first_failure}" = "yes"; then
1612       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1613       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1614       OLD_CPPFLAGS="$CPPFLAGS"
1615       OLD_LIBS="$LIBS"
1616       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1617       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1618       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1619       LIBS="$LIBS -b i486-linuxaout"
1620       AC_TRY_LINK([],
1621        [XOpenDisplay ("foo");],
1622        [xlinux_second_failure=no],
1623        [xlinux_second_failure=yes])
1624       if test "${xlinux_second_failure}" = "yes"; then
1625         # If we get the same failure with -b, there is no use adding -b.
1626         # So take it out.  This plays safe.
1627         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1628         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1629         CPPFLAGS="$OLD_CPPFLAGS"
1630         LIBS="$OLD_LIBS"
1631         AC_MSG_RESULT(no)
1632       else
1633         AC_MSG_RESULT(yes)
1634       fi
1635     else
1636       AC_MSG_RESULT(no)
1637     fi
1638   fi
1639
1640   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1641   # header files included from there.
1642   AC_MSG_CHECKING(for Xkb)
1643   AC_TRY_LINK([#include <X11/Xlib.h>
1644 #include <X11/XKBlib.h>],
1645         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1646         emacs_xkb=yes, emacs_xkb=no)
1647   AC_MSG_RESULT($emacs_xkb)
1648   if test $emacs_xkb = yes; then
1649     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1650   fi
1651
1652   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1653 XScreenNumberOfScreen XSetWMProtocols)
1654 fi
1655
1656 if test "${window_system}" = "x11"; then
1657   AC_MSG_CHECKING(X11 version 6)
1658   AC_CACHE_VAL(emacs_cv_x11_version_6,
1659   [AC_TRY_LINK([#include <X11/Xlib.h>],
1660 [#if XlibSpecificationRelease < 6
1661 fail;
1662 #endif
1663 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1664   if test $emacs_cv_x11_version_6 = yes; then
1665     AC_MSG_RESULT(6 or newer)
1666     AC_DEFINE(HAVE_X11R6, 1,
1667               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1668   else
1669     AC_MSG_RESULT(before 6)
1670   fi
1671 fi
1672
1673
1674 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1675 HAVE_RSVG=no
1676 if test "${HAVE_X11}" = "yes" || test "${HAVE_CARBON}" = "yes"; then
1677   if test "${with_rsvg}" != "no"; then
1678     RSVG_REQUIRED=2.0.0
1679     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1680
1681     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1682     AC_SUBST(RSVG_CFLAGS)
1683     AC_SUBST(RSVG_LIBS)
1684
1685     if test ".${RSVG_CFLAGS}" != "."; then
1686       HAVE_RSVG=yes
1687       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1688       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1689       LIBS="$RSVG_LIBS $LIBS"
1690     fi
1691   fi
1692 fi
1693
1694
1695 HAVE_GTK=no
1696 if test "${with_gtk}" = "yes" && test "$USE_X_TOOLKIT" = "gtk"; then
1697   USE_X_TOOLKIT=none
1698 fi
1699 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "gtk" || \
1700  test "$USE_X_TOOLKIT" = "maybe"; then
1701   if test "$USE_X_TOOLKIT" != "none" && test "$USE_X_TOOLKIT" != "maybe"; then
1702     AC_MSG_ERROR([Conflicting options, --with-gtk is incompatible with --with-x-toolkit=${with_x_toolkit}]);
1703   fi
1704   GLIB_REQUIRED=2.6
1705   GTK_REQUIRED=2.6
1706   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1707
1708   dnl Checks for libraries.
1709   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1710   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1711      AC_MSG_ERROR($GTK_PKG_ERRORS)
1712   fi
1713 fi
1714
1715
1716 if test x"$pkg_check_gtk" = xyes; then
1717
1718   AC_SUBST(GTK_CFLAGS)
1719   AC_SUBST(GTK_LIBS)
1720   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1721   CFLAGS="$CFLAGS $GTK_CFLAGS"
1722   LIBS="$GTK_LIBS $LIBS"
1723   dnl Try to compile a simple GTK program.
1724   GTK_COMPILES=no
1725   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1726   if test "${GTK_COMPILES}" != "yes"; then
1727     if test "$USE_X_TOOLKIT" != "maybe"; then
1728       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1729     fi
1730   else
1731     HAVE_GTK=yes
1732     AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
1733     USE_X_TOOLKIT=none
1734   fi
1735
1736 fi
1737
1738
1739 if test "${HAVE_GTK}" = "yes"; then
1740
1741   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1742   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1743   if test "$with_toolkit_scroll_bars" != no; then
1744     with_toolkit_scroll_bars=yes
1745   fi
1746
1747   dnl  Check if we can use multiple displays with this GTK version.
1748   dnl  If gdk_display_open exists, assume all others are there also.
1749   HAVE_GTK_MULTIDISPLAY=no
1750   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1751   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1752     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1753               [Define to 1 if GTK can handle more than one display.])
1754   fi
1755
1756   dnl  Check if we have the old file selection dialog.
1757   dnl  If gdk_display_open exists, assume all others are there also.
1758   HAVE_GTK_FILE_SELECTION=no
1759   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1760
1761   dnl  Check if we have the new file chooser dialog
1762   dnl  If gdk_display_open exists, assume all others are there also.
1763   HAVE_GTK_FILE_CHOOSER=no
1764   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1765
1766   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1767      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1768     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1769               [Define to 1 if GTK has both file selection and chooser dialog.])
1770   fi
1771
1772   dnl Check if pthreads are available.  Emacs only needs this when using
1773   dnl gtk_file_chooser under Gnome.
1774   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1775     HAVE_GTK_AND_PTHREAD=no
1776     AC_CHECK_HEADERS(pthread.h)
1777     if test "$ac_cv_header_pthread_h"; then
1778       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1779     fi
1780     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1781       case "${canonical}" in
1782         *-hpux*) ;;
1783         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1784       esac
1785       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1786                [Define to 1 if you have GTK and pthread (-lpthread).])
1787     fi
1788   fi
1789 fi
1790
1791 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1792 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1793 dnl also not configured.
1794 HAVE_DBUS=no
1795 if test "${with_dbus}" = "yes"; then
1796    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1797    if test "$HAVE_DBUS" = yes; then
1798       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1799    fi
1800 fi
1801
1802 dnl Do not put whitespace before the #include statements below.
1803 dnl Older compilers (eg sunos4 cc) choke on it.
1804 HAVE_XAW3D=no
1805 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1806   if test "$with_xaw3d" != no; then
1807     AC_MSG_CHECKING(for xaw3d)
1808     AC_CACHE_VAL(emacs_cv_xaw3d,
1809     [AC_TRY_LINK([
1810 #include <X11/Intrinsic.h>
1811 #include <X11/Xaw3d/Simple.h>],
1812       [],
1813       emacs_cv_xaw3d=yes,
1814       emacs_cv_xaw3d=no)])
1815   else
1816     emacs_cv_xaw3d=no
1817   fi
1818   if test $emacs_cv_xaw3d = yes; then
1819     AC_MSG_RESULT([yes; using Lucid toolkit])
1820     USE_X_TOOLKIT=LUCID
1821     HAVE_XAW3D=yes
1822     AC_DEFINE(HAVE_XAW3D, 1,
1823               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1824   else
1825     AC_MSG_RESULT(no)
1826     AC_MSG_CHECKING(for libXaw)
1827     AC_CACHE_VAL(emacs_cv_xaw,
1828     [AC_TRY_LINK([
1829 #include <X11/Intrinsic.h>
1830 #include <X11/Xaw/Simple.h>],
1831       [],
1832       emacs_cv_xaw=yes,
1833       emacs_cv_xaw=no)])
1834     if test $emacs_cv_xaw = yes; then
1835       AC_MSG_RESULT([yes; using Lucid toolkit])
1836       USE_X_TOOLKIT=LUCID
1837     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1838       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1839     else
1840       AC_MSG_RESULT([no; do not use toolkit by default])
1841       USE_X_TOOLKIT=none
1842     fi
1843   fi
1844 fi
1845
1846 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1847
1848 if test "${USE_X_TOOLKIT}" != "none"; then
1849   AC_MSG_CHECKING(X11 toolkit version)
1850   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1851   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1852 [#if XtSpecificationRelease < 6
1853 fail;
1854 #endif
1855 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1856   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1857   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1858     AC_MSG_RESULT(6 or newer)
1859     AC_DEFINE(HAVE_X11XTR6, 1,
1860               [Define to 1 if you have the X11R6 or newer version of Xt.])
1861   else
1862     AC_MSG_RESULT(before 6)
1863   fi
1864
1865 dnl If using toolkit, check whether libXmu.a exists.
1866 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1867   OLDLIBS="$LIBS"
1868   if test x$HAVE_X11XTR6 = xyes; then
1869     LIBS="-lXt -lSM -lICE $LIBS"
1870   else
1871     LIBS="-lXt $LIBS"
1872   fi
1873   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1874   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1875 fi
1876
1877 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1878 if test "${HAVE_X11}" = "yes"; then
1879   if test "${USE_X_TOOLKIT}" != "none"; then
1880     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1881   fi
1882 fi
1883
1884 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1885   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1886   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1887     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1888 int x = 5;
1889 #else
1890 Motif version prior to 2.1.
1891 #endif],
1892     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1893   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1894   if test $emacs_cv_motif_version_2_1 = yes; then
1895     HAVE_LIBXP=no
1896     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1897               [Define to 1 if you have Motif 2.1 or newer.])
1898     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1899     if test ${HAVE_LIBXP} = yes; then
1900       AC_DEFINE(HAVE_LIBXP, 1,
1901                 [Define to 1 if you have the Xp library (-lXp).])
1902     fi
1903   else
1904     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1905     # We put this in CFLAGS temporarily to precede other -I options
1906     # that might be in CFLAGS temporarily.
1907     # We put this in CPPFLAGS where it precedes the other -I options.
1908     OLD_CPPFLAGS=$CPPFLAGS
1909     OLD_CFLAGS=$CFLAGS
1910     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1911     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1912     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1913       [int x = 5;],
1914       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1915     if test $emacs_cv_lesstif = yes; then
1916       # Make sure this -I option remains in CPPFLAGS after it is set
1917       # back to REAL_CPPFLAGS.
1918       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1919       # have those other -I options anyway.  Ultimately, having this
1920       # directory ultimately in CPPFLAGS will be enough.
1921       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1922       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1923     else
1924       CFLAGS=$OLD_CFLAGS
1925       CPPFLAGS=$OLD_CPPFLAGS
1926     fi
1927   fi
1928 fi
1929
1930 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1931 dnl using Motif or Xaw3d is available, and unless
1932 dnl --with-toolkit-scroll-bars=no was specified.
1933
1934 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1935             [Define to 1 if we should use toolkit scroll bars.])dnl
1936 USE_TOOLKIT_SCROLL_BARS=no
1937 if test "${with_toolkit_scroll_bars}" != "no"; then
1938   if test "${USE_X_TOOLKIT}" != "none"; then
1939     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1940       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1941       HAVE_XAW3D=no
1942       USE_TOOLKIT_SCROLL_BARS=yes
1943     elif test "${HAVE_XAW3D}" = "yes"; then
1944       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1945       USE_TOOLKIT_SCROLL_BARS=yes
1946     fi
1947   elif test "${HAVE_GTK}" = "yes"; then
1948     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1949     USE_TOOLKIT_SCROLL_BARS=yes
1950   elif test "${HAVE_CARBON}" = "yes"; then
1951     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1952     USE_TOOLKIT_SCROLL_BARS=yes
1953   fi
1954 fi
1955
1956 dnl See if XIM is available.
1957 AC_TRY_COMPILE([
1958           #include <X11/Xlib.h>
1959           #include <X11/Xresource.h>],
1960          [XIMProc  callback;],
1961          [HAVE_XIM=yes
1962          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1963          HAVE_XIM=no)
1964
1965 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1966
1967 if test "${with_xim}" != "no"; then
1968   AC_DEFINE(USE_XIM, 1,
1969             [Define to 1 if we should use XIM, if it is available.])
1970 fi
1971
1972
1973 if test "${HAVE_XIM}" != "no"; then
1974   late_CFLAGS=$CFLAGS
1975   if test "$GCC" = yes; then
1976     CFLAGS="$CFLAGS --pedantic-errors"
1977   fi
1978   AC_TRY_COMPILE([
1979 #include <X11/Xlib.h>
1980 #include <X11/Xresource.h>],
1981 [Display *display;
1982 XrmDatabase db;
1983 char *res_name;
1984 char *res_class;
1985 XIMProc  callback;
1986 XPointer *client_data;
1987 #ifndef __GNUC__
1988 /* If we're not using GCC, it's probably not XFree86, and this is
1989    probably right, but we can't use something like --pedantic-errors.  */
1990 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1991                                            char*, XIMProc, XPointer*);
1992 #endif
1993 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1994    client_data);],
1995     [emacs_cv_arg6_star=yes])
1996   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1997          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1998 either XPointer or XPointer*.])dnl
1999   if test "$emacs_cv_arg6_star" = yes; then
2000     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2001   else
2002     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2003   fi
2004   CFLAGS=$late_CFLAGS
2005 fi
2006
2007 #### For font-backend
2008 if test "${USE_FONT_BACKEND}" = "yes"; then
2009
2010 AC_DEFINE(USE_FONT_BACKEND, 1,
2011           [Define to 1 if we should use font-backend.])
2012
2013 ### Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
2014 HAVE_XFT=maybe
2015 if test "${HAVE_X11}" = "yes"; then
2016   if test "x${with_freetype}" = "xno"; then
2017     with_xft="no";
2018   fi
2019   if test "x${with_xft}" != "xno"; then
2020
2021     dnl Check if --with-pkg-config-prog has been given.
2022     if test "X${with_pkg_config_prog}" != X; then
2023       PKG_CONFIG="${with_pkg_config_prog}"
2024     fi
2025
2026     PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2027     if test "$HAVE_XFT" != no; then
2028       OLD_CPPFLAGS="$CPPFLAGS"
2029       OLD_CFLAGS="$CFLAGS"
2030       OLD_LIBS="$LIBS"
2031       CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2032       CFLAGS="$CFLAGS $XFT_CFLAGS"
2033       LIBS="$XFT_LIBS $LIBS"
2034       AC_CHECK_HEADER(X11/Xft/Xft.h,
2035         AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2036
2037       if test "${HAVE_XFT}" = "yes"; then
2038         AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2039         AC_SUBST(XFT_LIBS)
2040         C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2041       else
2042         CPPFLAGS="$OLD_CPPFLAGS"
2043         CFLAGS="$OLD_CFLAGS"
2044         LIBS="$OLD_LIBS"
2045       fi
2046     fi
2047   fi
2048 fi
2049
2050 HAVE_FREETYPE=no
2051 ### Use -lfreetype if available, unless `--with-freetype=no'.
2052 if test "${HAVE_XFT}" = "yes"; then
2053   dnl As we use Xft, we anyway use freetype.
2054   dnl In this case, there's no need of additional CFLAGS and LIBS.
2055   HAVE_FREETYPE=yes
2056 elif test "x${with_freetype}" != "xno"; then
2057   dnl Check if --with-pkg-config-prog has been given.
2058   if test "X${with_pkg_config_prog}" != X; then
2059     PKG_CONFIG="${with_pkg_config_prog}"
2060   fi
2061
2062   PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
2063   if test "${HAVE_FREETYPE}" = "yes"; then
2064     PKG_CHECK_MODULES(FONTCONFIG, fontconfig, HAVE_FC=yes, HAVE_FC=no)
2065     if test "${HAVE_FC}" = "no"; then
2066       dnl Witout fontconfig, we can't use freetype at the moment.
2067       HAVE_FREETYPE=no
2068     fi
2069   fi
2070 fi
2071
2072 HAVE_LIBOTF=no
2073 if test "${HAVE_FREETYPE}" = "yes"; then
2074   AC_DEFINE(HAVE_FREETYPE, 1,
2075             [Define to 1 if you have freetype and fontconfig libraries.])
2076   if test "${with_libotf}" != "no"; then
2077     dnl Check if --with-pkg-config-prog has been given.
2078     if test "X${with_pkg_config_prog}" != X; then
2079       PKG_CONFIG="${with_pkg_config_prog}"
2080     fi
2081     PKG_CHECK_MODULES(LIBOTF, libotf, pkg_check_libotf=yes,
2082                       pkg_check_libotf=no)
2083     if test "$pkg_check_libotf" = "yes"; then
2084       AC_DEFINE(HAVE_LIBOTF, 1,
2085                 [Define to 1 if you have libotf library.])
2086     fi
2087   fi
2088 fi
2089
2090 HAVE_M17N_FLT=no
2091 if test "${with_m17n_flt}" != "no"; then
2092   dnl Check if --with-pkg-config-prog has been given.
2093   if test "X${with_pkg_config_prog}" != X; then
2094     PKG_CONFIG="${with_pkg_config_prog}"
2095   fi
2096   dnl Checks for libraries.
2097   PKG_CHECK_MODULES(M17N_FLT, m17n-flt, pkg_check_m17n_flt=yes,
2098                     pkg_check_m17n_flt=no)
2099   if test "$pkg_check_m17n_flt" = "yes"; then
2100     AC_DEFINE(HAVE_M17N_FLT, 1,
2101               [Define to 1 if you have m17n-flt library.])
2102   fi
2103 fi
2104
2105 AC_SUBST(FREETYPE_CFLAGS)
2106 AC_SUBST(FREETYPE_LIBS)
2107 AC_SUBST(FONTCONFIG_CFLAGS)
2108 AC_SUBST(FONTCONFIG_LIBS)
2109 AC_SUBST(LIBOTF_CFLAGS)
2110 AC_SUBST(LIBOTF_LIBS)
2111 AC_SUBST(M17N_FLT_CFLAGS)
2112 AC_SUBST(M17N_FLT_LIBS)
2113
2114 fi
2115 #### End for font-backend
2116
2117 ### Use -lXpm if available, unless `--with-xpm=no'.
2118 HAVE_XPM=no
2119 if test "${HAVE_X11}" = "yes"; then
2120   if test "${with_xpm}" != "no"; then
2121     AC_CHECK_HEADER(X11/xpm.h,
2122       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2123     if test "${HAVE_XPM}" = "yes"; then
2124       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2125       AC_EGREP_CPP(no_return_alloc_pixels,
2126       [#include "X11/xpm.h"
2127 #ifndef XpmReturnAllocPixels
2128 no_return_alloc_pixels
2129 #endif
2130       ], HAVE_XPM=no, HAVE_XPM=yes)
2131
2132       if test "${HAVE_XPM}" = "yes"; then
2133         AC_MSG_RESULT(yes)
2134       else
2135         AC_MSG_RESULT(no)
2136       fi
2137     fi
2138   fi
2139
2140   if test "${HAVE_XPM}" = "yes"; then
2141     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2142   fi
2143 fi
2144
2145 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2146 HAVE_JPEG=no
2147 if test "${HAVE_X11}" = "yes"; then
2148   if test "${with_jpeg}" != "no"; then
2149     dnl Checking for jpeglib.h can lose because of a redefinition of
2150     dnl  HAVE_STDLIB_H.
2151     AC_CHECK_HEADER(jerror.h,
2152       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2153   fi
2154
2155   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2156   if test "${HAVE_JPEG}" = "yes"; then
2157     AC_DEFINE(HAVE_JPEG)
2158     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2159         [#include <jpeglib.h>
2160          version=JPEG_LIB_VERSION
2161 ],
2162         [AC_DEFINE(HAVE_JPEG)],
2163         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2164         HAVE_JPEG=no])
2165   fi
2166 fi
2167
2168 ### Use -lpng if available, unless `--with-png=no'.
2169 HAVE_PNG=no
2170 if test "${HAVE_X11}" = "yes"; then
2171   if test "${with_png}" != "no"; then
2172     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2173     # in /usr/include/libpng.
2174     AC_CHECK_HEADERS(png.h libpng/png.h)
2175     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2176       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2177     fi
2178   fi
2179
2180   if test "${HAVE_PNG}" = "yes"; then
2181     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2182   fi
2183 fi
2184
2185 ### Use -ltiff if available, unless `--with-tiff=no'.
2186 HAVE_TIFF=no
2187 if test "${HAVE_X11}" = "yes"; then
2188   if test "${with_tiff}" != "no"; then
2189     AC_CHECK_HEADER(tiffio.h,
2190       [tifflibs="-lz -lm"
2191       # At least one tiff package requires the jpeg library.
2192       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2193       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2194   fi
2195
2196   if test "${HAVE_TIFF}" = "yes"; then
2197     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2198   fi
2199 fi
2200
2201 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2202 HAVE_GIF=no
2203 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2204   AC_CHECK_HEADER(gif_lib.h,
2205 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2206 # Earlier versions can crash Emacs.
2207     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2208
2209   if test "$HAVE_GIF" = yes; then
2210       ac_gif_lib_name="-lgif"
2211   fi
2212
2213 # If gif_lib.h but no libgif, try libungif.
2214   if test x"$try_libungif" = xyes; then
2215     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2216
2217     if test "$HAVE_GIF" = yes; then
2218       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2219       ac_gif_lib_name="-lungif"
2220     fi
2221   fi
2222
2223   if test "${HAVE_GIF}" = "yes"; then
2224     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2225   fi
2226 fi
2227
2228 dnl Check for required libraries.
2229 if test "${HAVE_X11}" = "yes"; then
2230   MISSING=""
2231   WITH_NO=""
2232   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2233     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2234   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2235     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2236   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2237     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2238   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2239     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2240   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2241     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2242
2243   if test "X${MISSING}" != X; then
2244     AC_MSG_ERROR([The following required libraries were not found:
2245     $MISSING
2246 Maybe some development libraries/packages are missing?
2247 If you don't want to link with them give
2248     $WITH_NO
2249 as options to configure])
2250   fi
2251 fi
2252
2253 ### Use -lgpm if available, unless `--with-gpm=no'.
2254 HAVE_GPM=no
2255 if test "${with_gpm}" != "no"; then
2256   AC_CHECK_HEADER(gpm.h,
2257     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2258 fi
2259
2260 if test "${HAVE_GPM}" = "yes"; then
2261   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2262 fi
2263
2264 dnl Check for malloc/malloc.h on darwin
2265 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2266
2267 ### Use Mac OS X Carbon API to implement GUI.
2268 if test "${HAVE_CARBON}" = "yes"; then
2269   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2270   ## Specify the install directory
2271   carbon_appdir=
2272   if test "${carbon_appdir_x}" != ""; then
2273     case ${carbon_appdir_x} in
2274       y | ye | yes)  carbon_appdir=/Applications ;;
2275       * ) carbon_appdir=${carbon_appdir_x} ;;
2276     esac
2277   fi
2278   # We also have mouse menus.
2279   HAVE_MENUS=yes
2280 fi
2281
2282 ### Use session management (-lSM -lICE) if available
2283 HAVE_X_SM=no
2284 if test "${HAVE_X11}" = "yes"; then
2285   AC_CHECK_HEADER(X11/SM/SMlib.h,
2286     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2287
2288   if test "${HAVE_X_SM}" = "yes"; then
2289     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2290     case "$LIBS" in
2291       *-lSM*) ;;
2292       *)      LIBS="-lSM -lICE $LIBS" ;;
2293     esac
2294   fi
2295 fi
2296
2297 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2298 AC_CACHE_CHECK(whether netdb declares h_errno,
2299                emacs_cv_netdb_declares_h_errno,
2300 [AC_TRY_LINK([#include <netdb.h>],
2301   [return h_errno;],
2302   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2303 if test $emacs_cv_netdb_declares_h_errno = yes; then
2304   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2305 fi
2306
2307 AC_FUNC_ALLOCA
2308
2309 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2310 dnl FIXME is there an autoconf test that does the right thing, without
2311 dnl needing to call A_M_E afterwards?
2312 if test x"$ac_cv_func_alloca_works" != xyes; then
2313    AC_MSG_ERROR( [a system implementation of alloca is required] )
2314 fi
2315
2316 # fmod, logb, and frexp are found in -lm on most systems.
2317 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2318 AC_CHECK_LIB(m, sqrt)
2319
2320 # Check for mail-locking functions in a "mail" library.  Probably this should
2321 # have the same check as for liblockfile below.
2322 AC_CHECK_LIB(mail, maillock)
2323 dnl Debian, at least:
2324 AC_CHECK_LIB(lockfile, maillock)
2325 # If we have the shared liblockfile, assume we must use it for mail
2326 # locking (e.g. Debian).  If we couldn't link against liblockfile
2327 # (no liblockfile.a installed), ensure that we don't need to.
2328 if test "$ac_cv_lib_lockfile_maillock" = no; then
2329   dnl This works for files generally, not just executables.
2330   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2331   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2332                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2333   if test $ac_cv_prog_liblockfile = yes; then
2334     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2335 This probably means that movemail could lose mail.
2336 There may be a `development' package to install containing liblockfile.])
2337   else :
2338   fi
2339 fi
2340 AC_CHECK_FUNCS(touchlock)
2341 AC_CHECK_HEADERS(maillock.h)
2342
2343 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2344 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2345 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2346 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2347 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2348 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2349 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2350 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2351 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2352
2353 AC_CHECK_HEADERS(sys/un.h)
2354
2355 AC_FUNC_MKTIME
2356 if test "$ac_cv_func_working_mktime" = no; then
2357   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2358 fi
2359
2360 AC_FUNC_GETLOADAVG
2361
2362 AC_FUNC_FSEEKO
2363
2364 # Configure getopt.
2365 m4_include([m4/getopt.m4])
2366 gl_GETOPT_IFELSE([
2367   gl_GETOPT_SUBSTITUTE_HEADER
2368   gl_PREREQ_GETOPT
2369   GETOPTOBJS='getopt.o getopt1.o'
2370 ])
2371 AC_SUBST(GETOPTOBJS)
2372
2373 AC_FUNC_GETPGRP
2374
2375 AC_FUNC_STRFTIME
2376
2377 # UNIX98 PTYs.
2378 AC_CHECK_FUNCS(grantpt)
2379
2380 # PTY-related GNU extensions.
2381 AC_CHECK_FUNCS(getpt)
2382
2383 # Check this now, so that we will NOT find the above functions in ncurses.
2384 # That is because we have not set up to link ncurses in lib-src.
2385 # It's better to believe a function is not available
2386 # than to expect to find it in ncurses.
2387 AC_CHECK_LIB(ncurses, tparm)
2388
2389 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2390
2391 resolv=no
2392 AC_TRY_LINK([#include <netinet/in.h>
2393 #include <arpa/nameser.h>
2394 #include <resolv.h>],
2395     [return res_init();],
2396     have_res_init=yes, have_res_init=no)
2397 if test "$have_res_init" = no; then
2398   OLIBS="$LIBS"
2399   LIBS="$LIBS -lresolv"
2400   AC_MSG_CHECKING(for res_init with -lresolv)
2401   AC_TRY_LINK([#include <netinet/in.h>
2402 #include <arpa/nameser.h>
2403 #include <resolv.h>],
2404     [return res_init();],
2405     have_res_init=yes, have_res_init=no)
2406   AC_MSG_RESULT($have_res_init)
2407   if test "$have_res_init" = yes ; then
2408     resolv=yes
2409   fi
2410   LIBS="$OLIBS"
2411 fi
2412
2413 if test "$have_res_init" = yes; then
2414   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2415 fi
2416
2417 # Do we need the Hesiod library to provide the support routines?
2418 if test "$with_hesiod" = yes ; then
2419   # Don't set $LIBS here -- see comments above.
2420   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2421      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2422                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2423   if test "$resolv" = yes ; then
2424     RESOLVLIB=-lresolv
2425   else
2426     RESOLVLIB=
2427   fi
2428   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2429         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2430                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2431         :, $RESOLVLIB)])
2432 fi
2433
2434 # Do we need libresolv (due to res_init or Hesiod)?
2435 if test "$resolv" = yes ; then
2436   AC_DEFINE(HAVE_LIBRESOLV, 1,
2437             [Define to 1 if you have the resolv library (-lresolv).])
2438 fi
2439
2440 # These tell us which Kerberos-related libraries to use.
2441 if test "${with_kerberos+set}" = set; then
2442   AC_CHECK_LIB(com_err, com_err)
2443   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2444   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2445   AC_CHECK_LIB(krb5, krb5_init_context)
2446   if test "${with_kerberos5+set}" != set; then
2447     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2448                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2449     AC_CHECK_LIB(krb4, krb_get_cred,,
2450                  [AC_CHECK_LIB(krb, krb_get_cred)])
2451   fi
2452
2453   if test "${with_kerberos5+set}" = set; then
2454     AC_CHECK_HEADERS(krb5.h)
2455   else
2456     AC_CHECK_HEADERS(des.h,,
2457                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2458                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2459     AC_CHECK_HEADERS(krb.h,,
2460                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2461                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2462   fi
2463   AC_CHECK_HEADERS(com_err.h)
2464 fi
2465
2466 # Solaris requires -lintl if you want strerror (which calls dgettext)
2467 # to return localized messages.
2468 AC_CHECK_LIB(intl, dgettext)
2469
2470 AC_MSG_CHECKING(whether localtime caches TZ)
2471 AC_CACHE_VAL(emacs_cv_localtime_cache,
2472 [if test x$ac_cv_func_tzset = xyes; then
2473 AC_TRY_RUN([#include <time.h>
2474 extern char **environ;
2475 unset_TZ ()
2476 {
2477   char **from, **to;
2478   for (to = from = environ; (*to = *from); from++)
2479     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2480       to++;
2481 }
2482 char TZ_GMT0[] = "TZ=GMT0";
2483 char TZ_PST8[] = "TZ=PST8";
2484 main()
2485 {
2486   time_t now = time ((time_t *) 0);
2487   int hour_GMT0, hour_unset;
2488   if (putenv (TZ_GMT0) != 0)
2489     exit (1);
2490   hour_GMT0 = localtime (&now)->tm_hour;
2491   unset_TZ ();
2492   hour_unset = localtime (&now)->tm_hour;
2493   if (putenv (TZ_PST8) != 0)
2494     exit (1);
2495   if (localtime (&now)->tm_hour == hour_GMT0)
2496     exit (1);
2497   unset_TZ ();
2498   if (localtime (&now)->tm_hour != hour_unset)
2499     exit (1);
2500   exit (0);
2501 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2502 [# If we have tzset, assume the worst when cross-compiling.
2503 emacs_cv_localtime_cache=yes])
2504 else
2505         # If we lack tzset, report that localtime does not cache TZ,
2506         # since we can't invalidate the cache if we don't have tzset.
2507         emacs_cv_localtime_cache=no
2508 fi])dnl
2509 AC_MSG_RESULT($emacs_cv_localtime_cache)
2510 if test $emacs_cv_localtime_cache = yes; then
2511   AC_DEFINE(LOCALTIME_CACHE, 1,
2512             [Define to 1 if localtime caches TZ.])
2513 fi
2514
2515 if test "x$HAVE_TIMEVAL" = xyes; then
2516   AC_CHECK_FUNCS(gettimeofday)
2517   if test $ac_cv_func_gettimeofday = yes; then
2518     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2519                    emacs_cv_gettimeofday_two_arguments,
2520     [AC_TRY_COMPILE([
2521 #ifdef TIME_WITH_SYS_TIME
2522 #include <sys/time.h>
2523 #include <time.h>
2524 #else
2525 #ifdef HAVE_SYS_TIME_H
2526 #include <sys/time.h>
2527 #else
2528 #include <time.h>
2529 #endif
2530 #endif],
2531       [struct timeval time;
2532        gettimeofday (&time, 0);],
2533       emacs_cv_gettimeofday_two_arguments=yes,
2534       emacs_cv_gettimeofday_two_arguments=no)])
2535     if test $emacs_cv_gettimeofday_two_arguments = no; then
2536       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2537                 [Define to 1 if gettimeofday accepts only one argument.])
2538     fi
2539   fi
2540 fi
2541
2542 ok_so_far=yes
2543 AC_CHECK_FUNC(socket, , ok_so_far=no)
2544 if test $ok_so_far = yes; then
2545   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2546 fi
2547 if test $ok_so_far = yes; then
2548   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2549 fi
2550 if test $ok_so_far = yes; then
2551 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2552   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2553             [Define to 1 if you have inet sockets.])
2554 fi
2555
2556 AC_CHECK_HEADERS(sys/ioctl.h)
2557
2558 if test -f /usr/lpp/X11/bin/smt.exp; then
2559   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2560             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2561 fi
2562
2563 AC_MSG_CHECKING(whether system supports dynamic ptys)
2564 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2565   AC_MSG_RESULT(yes)
2566   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2567 else
2568   AC_MSG_RESULT(no)
2569 fi
2570
2571 AC_FUNC_FORK
2572
2573 dnl Adapted from Haible's version.
2574 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2575   [AC_TRY_LINK([#include <langinfo.h>],
2576     [char* cs = nl_langinfo(CODESET);],
2577     emacs_cv_langinfo_codeset=yes,
2578     emacs_cv_langinfo_codeset=no)
2579   ])
2580 if test $emacs_cv_langinfo_codeset = yes; then
2581   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2582     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2583 fi
2584
2585 AC_CHECK_TYPES(size_t)
2586
2587 AC_TYPE_MBSTATE_T
2588
2589 dnl Restrict could probably be used effectively other than in regex.c.
2590 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2591   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2592                   emacs_cv_c_restrict=yes,
2593                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2594                                   emacs_cv_c_restrict=__restrict,
2595                                   emacs_cv_c_restrict=no)])])
2596 case "$emacs_cv_c_restrict" in
2597   yes) emacs_restrict=restrict;;
2598   no) emacs_restrict="";;
2599   *) emacs_restrict="$emacs_cv_c_restrict";;
2600 esac
2601 if test "$emacs_restrict" != __restrict; then
2602   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2603     [Define to compiler's equivalent of C99 restrict keyword.
2604      Don't define if equivalent is `__restrict'.])
2605 fi
2606
2607 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2608   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2609                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2610 if test "$emacs_cv_c_restrict_arr" = yes; then
2611   AC_DEFINE(__restrict_arr, __restrict,
2612     [Define to compiler's equivalent of C99 restrict keyword in array
2613      declarations.  Define as empty for no equivalent.])
2614 fi
2615
2616 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2617 dnl how the tty code is related to POSIX and/or other versions of termios.
2618 dnl The following looks like a useful start.
2619 dnl
2620 dnl AC_SYS_POSIX_TERMIOS
2621 dnl if test $ac_cv_sys_posix_termios = yes; then
2622 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2623 dnl                                and macros for terminal control.])
2624 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2625 dnl fi
2626
2627 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2628
2629 # Set up the CFLAGS for real compilation, so we can substitute it.
2630 CFLAGS="$REAL_CFLAGS"
2631 CPPFLAGS="$REAL_CPPFLAGS"
2632
2633 #### Find out which version of Emacs this is.
2634 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2635          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2636 if test x"${version}" = x; then
2637   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2638 fi
2639
2640 ### Specify what sort of things we'll be editing into Makefile and config.h.
2641 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2642 AC_SUBST(version)
2643 AC_SUBST(configuration)
2644 AC_SUBST(canonical)
2645 AC_SUBST(srcdir)
2646 AC_SUBST(prefix)
2647 AC_SUBST(exec_prefix)
2648 AC_SUBST(bindir)
2649 AC_SUBST(datadir)
2650 AC_SUBST(sharedstatedir)
2651 AC_SUBST(libexecdir)
2652 AC_SUBST(mandir)
2653 AC_SUBST(infodir)
2654 AC_SUBST(lispdir)
2655 AC_SUBST(locallisppath)
2656 AC_SUBST(lisppath)
2657 AC_SUBST(x_default_search_path)
2658 AC_SUBST(etcdir)
2659 AC_SUBST(archlibdir)
2660 AC_SUBST(docdir)
2661 AC_SUBST(bitmapdir)
2662 AC_SUBST(gamedir)
2663 AC_SUBST(gameuser)
2664 AC_SUBST(c_switch_system)
2665 AC_SUBST(c_switch_machine)
2666 AC_SUBST(LD_SWITCH_X_SITE)
2667 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2668 AC_SUBST(C_SWITCH_X_SITE)
2669 AC_SUBST(CFLAGS)
2670 AC_SUBST(X_TOOLKIT_TYPE)
2671 AC_SUBST(machfile)
2672 AC_SUBST(opsysfile)
2673 AC_SUBST(GETLOADAVG_LIBS)
2674 AC_SUBST(carbon_appdir)
2675
2676 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2677                    [Define to the canonical Emacs configuration name.])
2678 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2679                    [Define to the options passed to configure.])
2680 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2681                    [Define to the used machine dependent file.])
2682 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2683                    [Define to the used os dependent file.])
2684 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2685 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2686  may need to deal with X Windows.  For instance, if you've defined
2687  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2688  your loader can find on its own, you might want to add "-L/..." or
2689  something similar.])
2690 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2691                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2692                     in case it's needed (for Solaris, for example).])
2693 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2694 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2695  may need to deal with X Windows.  For instance, if you've defined
2696  HAVE_X_WINDOWS above and your X include files aren't in a place
2697  that your compiler can find on its own, you might want to add
2698  "-I/..." or something similar.])
2699 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2700                    [Define to the unexec source file name.])
2701
2702 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2703   AC_DEFINE(HAVE_X_WINDOWS, 1,
2704             [Define to 1 if you want to use the X window system.])
2705 fi
2706 if test "${USE_X_TOOLKIT}" != "none" ; then
2707   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2708 fi
2709 if test "${HAVE_X11}" = "yes" ; then
2710   AC_DEFINE(HAVE_X11, 1,
2711             [Define to 1 if you want to use version 11 of X windows.
2712              Otherwise, Emacs expects to use version 10.])
2713 fi
2714 if test "${HAVE_XFREE386}" = "yes" ; then
2715   AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2716 fi
2717 if test "${HAVE_MENUS}" = "yes" ; then
2718   AC_DEFINE(HAVE_MENUS, 1,
2719             [Define to 1 if you have mouse menus.
2720              (This is automatic if you use X, but the option to specify it remains.)
2721              It is also defined with other window systems that support xmenu.c.])
2722 fi
2723 if test "${GNU_MALLOC}" = "yes" ; then
2724   AC_DEFINE(GNU_MALLOC, 1,
2725             [Define to 1 if you want to use the GNU memory allocator.])
2726 fi
2727 if test "${REL_ALLOC}" = "yes" ; then
2728   AC_DEFINE(REL_ALLOC, 1,
2729             [Define REL_ALLOC if you want to use the relocating allocator for
2730              buffer space.])
2731 fi
2732
2733
2734 AH_TOP([/* GNU Emacs site configuration template file.
2735    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2736      2006, 2007, 2008  Free Software Foundation, Inc.
2737
2738 This file is part of GNU Emacs.
2739
2740 GNU Emacs is free software; you can redistribute it and/or modify
2741 it under the terms of the GNU General Public License as published by
2742 the Free Software Foundation; either version 3, or (at your option)
2743 any later version.
2744
2745 GNU Emacs is distributed in the hope that it will be useful,
2746 but WITHOUT ANY WARRANTY; without even the implied warranty of
2747 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2748 GNU General Public License for more details.
2749
2750 You should have received a copy of the GNU General Public License
2751 along with GNU Emacs; see the file COPYING.  If not, write to the
2752 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
2753 Boston, MA 02110-1301, USA.  */
2754
2755
2756 /* No code in Emacs #includes config.h twice, but some bits of code
2757    intended to work with other packages as well (like gmalloc.c)
2758    think they can include it as many times as they like.  */
2759 #ifndef EMACS_CONFIG_H
2760 #define EMACS_CONFIG_H
2761 ])dnl
2762
2763 AH_BOTTOM([
2764 /* If we're using any sort of window system, define some consequences.  */
2765 #ifdef HAVE_X_WINDOWS
2766 #define HAVE_WINDOW_SYSTEM
2767 #define MULTI_KBOARD
2768 #define HAVE_MOUSE
2769 #endif
2770
2771 /* Multi-tty support relies on MULTI_KBOARD.  It seems safe to turn it
2772    on unconditionally. */
2773 #ifndef MULTI_KBOARD
2774 #define MULTI_KBOARD
2775 #endif
2776
2777 /* If we're using the Carbon API on Mac OS X, define a few more
2778    variables as well.  */
2779 #ifdef HAVE_CARBON
2780 #define HAVE_WINDOW_SYSTEM
2781 #define HAVE_MOUSE
2782 #endif
2783
2784 /* Define USER_FULL_NAME to return a string
2785    that is the user's full name.
2786    It can assume that the variable `pw'
2787    points to the password file entry for this user.
2788
2789    At some sites, the pw_gecos field contains
2790    the user's full name.  If neither this nor any other
2791    field contains the right thing, use pw_name,
2792    giving the user's login name, since that is better than nothing.  */
2793 #define USER_FULL_NAME pw->pw_gecos
2794
2795 /* Define AMPERSAND_FULL_NAME if you use the convention
2796    that & in the full name stands for the login id.  */
2797 /* Turned on June 1996 supposing nobody will mind it.  */
2798 #define AMPERSAND_FULL_NAME
2799
2800 /* We have blockinput.h.  */
2801 #define DO_BLOCK_INPUT
2802
2803 /* Define HAVE_SOUND if we have sound support.  We know it works
2804    and compiles only on the specified platforms.   For others,
2805    it probably doesn't make sense to try.  */
2806
2807 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2808 #ifdef HAVE_MACHINE_SOUNDCARD_H
2809 #define HAVE_SOUND 1
2810 #endif
2811 #ifdef HAVE_SYS_SOUNDCARD_H
2812 #define HAVE_SOUND 1
2813 #endif
2814 #ifdef HAVE_SOUNDCARD_H
2815 #define HAVE_SOUND 1
2816 #endif
2817 #ifdef HAVE_ALSA
2818 #define HAVE_SOUND 1
2819 #endif
2820 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2821
2822 /* If using GNU, then support inline function declarations. */
2823 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2824    generally, because even if non-gcc compilers accept `inline', they
2825    may reject `extern inline'.  */
2826 #if defined (__GNUC__) && defined (OPTIMIZE)
2827 #define INLINE __inline__
2828 #else
2829 #define INLINE
2830 #endif
2831
2832 /* Include the os and machine dependent files.  */
2833 #include config_opsysfile
2834 #include config_machfile
2835
2836 /* Load in the conversion definitions if this system
2837    needs them and the source file being compiled has not
2838    said to inhibit this.  There should be no need for you
2839    to alter these lines.  */
2840
2841 #ifdef SHORTNAMES
2842 #ifndef NO_SHORTNAMES
2843 #include "../shortnames/remap.h"
2844 #endif /* not NO_SHORTNAMES */
2845 #endif /* SHORTNAMES */
2846
2847 /* If no remapping takes place, static variables cannot be dumped as
2848    pure, so don't worry about the `static' keyword. */
2849 #ifdef NO_REMAP
2850 #undef static
2851 #endif
2852
2853 /* Define `subprocesses' should be defined if you want to
2854    have code for asynchronous subprocesses
2855    (as used in M-x compile and M-x shell).
2856    These do not work for some USG systems yet;
2857    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
2858
2859 #ifndef VMS
2860 #ifndef USG
2861 /* #define subprocesses */
2862 #endif
2863 #endif
2864
2865 /* SIGTYPE is the macro we actually use.  */
2866 #ifndef SIGTYPE
2867 #define SIGTYPE RETSIGTYPE
2868 #endif
2869
2870 #ifdef emacs /* Don't do this for lib-src.  */
2871 /* Tell regex.c to use a type compatible with Emacs.  */
2872 #define RE_TRANSLATE_TYPE Lisp_Object
2873 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2874 #ifdef make_number
2875 /* If make_number is a macro, use it.  */
2876 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2877 #else
2878 /* If make_number is a function, avoid it.  */
2879 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2880 #endif
2881 #endif
2882
2883 /* Avoid link-time collision with system mktime if we will use our own.  */
2884 #if ! HAVE_MKTIME || BROKEN_MKTIME
2885 #define mktime emacs_mktime
2886 #endif
2887
2888 #define my_strftime nstrftime   /* for strftime.c */
2889
2890 /* The rest of the code currently tests the CPP symbol BSTRING.
2891    Override any claims made by the system-description files.
2892    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2893 #undef BSTRING
2894 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2895 #define BSTRING
2896 #endif
2897
2898 /* Some of the files of Emacs which are intended for use with other
2899    programs assume that if you have a config.h file, you must declare
2900    the type of getenv.
2901
2902    This declaration shouldn't appear when alloca.s or Makefile.in
2903    includes config.h.  */
2904 #ifndef NOT_C_CODE
2905 extern char *getenv ();
2906 #endif
2907
2908 /* These default definitions are good for almost all machines.
2909    The exceptions override them in m/MACHINE.h.  */
2910
2911 #ifndef BITS_PER_CHAR
2912 #define BITS_PER_CHAR 8
2913 #endif
2914
2915 #ifndef BITS_PER_SHORT
2916 #define BITS_PER_SHORT 16
2917 #endif
2918
2919 /* Note that lisp.h uses this in a preprocessor conditional, so it
2920    would not work to use sizeof.  That being so, we do all of them
2921    without sizeof, for uniformity's sake.  */
2922 #ifndef BITS_PER_INT
2923 #define BITS_PER_INT 32
2924 #endif
2925
2926 #ifndef BITS_PER_LONG
2927 #ifdef _LP64
2928 #define BITS_PER_LONG 64
2929 #else
2930 #define BITS_PER_LONG 32
2931 #endif
2932 #endif
2933
2934 /* Define if the compiler supports function prototypes.  It may do so
2935    but not define __STDC__ (e.g. DEC C by default) or may define it as
2936    zero.  */
2937 #undef PROTOTYPES
2938 /* For mktime.c:  */
2939 #ifndef __P
2940 # if defined PROTOTYPES
2941 #  define __P(args) args
2942 # else
2943 #  define __P(args) ()
2944 # endif  /* GCC.  */
2945 #endif /* __P */
2946
2947 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2948 #ifndef NOT_C_CODE
2949 #ifdef HAVE_STRING_H
2950 #include "string.h"
2951 #endif
2952 #ifdef HAVE_STRINGS_H
2953 #include "strings.h"  /* May be needed for bcopy & al. */
2954 #endif
2955 #ifdef HAVE_STDLIB_H
2956 #include <stdlib.h>
2957 #endif
2958 #ifndef __GNUC__
2959 # ifdef HAVE_ALLOCA_H
2960 #  include <alloca.h>
2961 # else /* AIX files deal with #pragma.  */
2962 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2963 char *alloca ();
2964 #  endif
2965 # endif /* HAVE_ALLOCA_H */
2966 #endif /* __GNUC__ */
2967 #ifndef HAVE_SIZE_T
2968 typedef unsigned size_t;
2969 #endif
2970 #endif /* NOT_C_CODE */
2971
2972 /* Define HAVE_X_I18N if we have usable i18n support.  */
2973
2974 #ifdef HAVE_X11R6
2975 #define HAVE_X_I18N
2976 #elif !defined X11R5_INHIBIT_I18N
2977 #define HAVE_X_I18N
2978 #endif
2979
2980 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2981
2982 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2983 #define HAVE_X11R6_XIM
2984 #endif
2985
2986 /* Should we enable expensive run-time checking of data types?  */
2987 #undef ENABLE_CHECKING
2988
2989 #if defined __GNUC__ && (__GNUC__ > 2 \
2990                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2991 #define NO_RETURN       __attribute__ ((__noreturn__))
2992 #else
2993 #define NO_RETURN       /* nothing */
2994 #endif
2995
2996 /* These won't be used automatically yet.  We also need to know, at least,
2997    that the stack is continuous.  */
2998 #ifdef __GNUC__
2999 #  ifndef GC_SETJMP_WORKS
3000   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3001      see NON_SAVING_SETJMP in the target descriptions.  */
3002   /* Exceptions (see NON_SAVING_SETJMP in target description) are
3003      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3004      Fixme: Deal with SVR3.  */
3005 #    define GC_SETJMP_WORKS 1
3006 #  endif
3007 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3008 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3009 #  endif
3010 #endif
3011
3012 #ifndef HAVE_BCOPY
3013 #define bcopy(a,b,s) memcpy (b,a,s)
3014 #endif
3015 #ifndef HAVE_BZERO
3016 #define bzero(a,s) memset (a,0,s)
3017 #endif
3018 #ifndef HAVE_BCMP
3019 #define BCMP memcmp
3020 #endif
3021
3022 #endif /* EMACS_CONFIG_H */
3023
3024 /*
3025 Local Variables:
3026 mode: c
3027 End:
3028 */
3029 ])dnl
3030
3031 #### Report on what we decided to do.
3032 #### Report GTK as a toolkit, even if it doesn't use Xt.
3033 #### It makes printing result more understandable as using GTK sets
3034 #### toolkit_scroll_bars to yes by default.
3035 if test "${HAVE_GTK}" = "yes"; then
3036   USE_X_TOOLKIT=GTK
3037 fi
3038
3039 echo "
3040 Configured for \`${canonical}'.
3041
3042   Where should the build process find the source code?    ${srcdir}
3043   What operating system and machine description files should Emacs use?
3044         \`${opsysfile}' and \`${machfile}'
3045   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3046   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3047   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3048   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3049   What window system should Emacs use?                    ${window_system}
3050   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3051
3052 if test -n "${x_includes}"; then
3053 echo "  Where do we find X Windows header files?                ${x_includes}"
3054 else
3055 echo "  Where do we find X Windows header files?                Standard dirs"
3056 fi
3057 if test -n "${x_libraries}"; then
3058 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3059 else
3060 echo "  Where do we find X Windows libraries?                   Standard dirs"
3061 fi
3062
3063 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3064 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3065 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3066 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3067 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
3068 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3069 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3070 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3071 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3072 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
3073 echo
3074
3075 if test $USE_XASSERTS = yes; then
3076    echo "  Compiling with asserts turned on."
3077    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3078    echo
3079 fi
3080
3081 if test "$USE_X_TOOLKIT" = GTK; then
3082   case "$canonical" in
3083   *cygwin*)
3084     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
3085   will probably get a crash on startup.  If this happens, please use another
3086   toolkit for Emacs.  See etc/PROBLEMS for more information."
3087   ;;
3088   esac
3089 fi
3090
3091
3092 if test "$HAVE_CARBON" = "yes"; then
3093    echo
3094    echo "Warning: The Mac Carbon port is currently unsupported and has
3095 known problems.  It is not recommended for use by non-developers.
3096 Read the emacs-devel archives for more information."
3097    echo
3098 fi
3099
3100 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3101   echo "D-Bus integration has been tested for GNU/Linux only."
3102   echo
3103 fi
3104
3105
3106 # Remove any trailing slashes in these variables.
3107 [test "${prefix}" != NONE &&
3108   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3109 test "${exec_prefix}" != NONE &&
3110   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3111
3112 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3113 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3114 ## from Makefile.c can correctly provide the arg `-traditional' to the
3115 ## C preprocessor.
3116
3117 AC_EGREP_CPP(yes..yes,
3118         [yes..yes],
3119         CPP_NEED_TRADITIONAL=no,
3120         CPP_NEED_TRADITIONAL=yes)
3121
3122 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3123         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3124         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3125         lwlib/Makefile lisp/Makefile leim/Makefile, [
3126
3127 ### Make the necessary directories, if they don't exist.
3128 for dir in etc lisp ; do
3129   test -d ${dir} || mkdir ${dir}
3130 done
3131
3132 # Build src/Makefile from ${srcdir}/src/Makefile.c
3133 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3134 # This must be done after src/config.h is built, since we rely on that file.
3135
3136 # Now get this: Some word that is part of the ${srcdir} directory name
3137 # or the ${configuration} value might, just might, happen to be an
3138 # identifier like `sun4' or `i386' or something, and be predefined by
3139 # the C preprocessor to some helpful value like 1, or maybe the empty
3140 # string.  Needless to say consequent macro substitutions are less
3141 # than conducive to the makefile finding the correct directory.
3142 [undefs="`echo $top_srcdir $configuration $canonical |
3143 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3144     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3145 `"]
3146
3147 echo creating src/epaths.h
3148 ${MAKE-make} epaths-force
3149
3150 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3151 # `..' to `. .'  unless invoked with -traditional
3152
3153 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3154   CPPFLAGS="$CPPFLAGS -traditional"
3155 fi
3156
3157 echo creating lib-src/Makefile
3158 ( cd lib-src
3159   rm -f junk.c junk1.c junk2.c
3160   sed -e '/start of cpp stuff/q' \
3161       < Makefile.c > junk1.c
3162   sed -e '1,/start of cpp stuff/d'\
3163       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3164       < Makefile.c > junk.c
3165   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3166       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3167   cat junk1.c junk2.c > Makefile.new
3168   rm -f junk.c junk1.c junk2.c
3169   chmod 444 Makefile.new
3170   mv -f Makefile.new Makefile
3171 )
3172
3173 echo creating src/Makefile
3174 ( cd src
3175   rm -f junk.c junk1.c junk2.c
3176   sed -e '/start of cpp stuff/q' \
3177       < Makefile.c > junk1.c
3178   sed -e '1,/start of cpp stuff/d'\
3179       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3180       < Makefile.c > junk.c
3181   if test -f ${srcdir}/admin/unidata/UnicodeData.txt; then
3182     CPPFLAGS="$CPPFLAGS -DHAVE_UNIDATA"
3183   fi
3184   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3185       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3186   cat junk1.c junk2.c > Makefile.new
3187   rm -f junk.c junk1.c junk2.c
3188   chmod 444 Makefile.new
3189   mv -f Makefile.new Makefile
3190 )
3191
3192 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3193   echo creating src/.gdbinit
3194   echo source $srcdir/src/.gdbinit > src/.gdbinit
3195 fi
3196
3197 # This is how we know whether to re-run configure in certain cases.
3198 touch src/config.stamp
3199
3200 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3201
3202 m4_if(dnl       Do not change this comment
3203    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3204 )dnl