lisp/hexl.el

   1 ;;; hexl.el --- edit a file in a hex dump format using the hexl filter.
   2
   3 ;; Copyright (C) 1989 Free Software Foundation, Inc.
   4
   5 ;; Author: Keith Gabryelski <ag@wheaties.ai.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package implements a major mode for editing binary files.  It uses
  28 ;; a program called hexl, supplied with the GNU Emacs distribution, that
  29 ;; can filter a binary into an editable format or from the format back into
  30 ;; binary.  For full instructions, invoke `hexl-mode' on an empty buffer and
  31 ;; do `M-x describe-mode'.
  32 ;;
  33 ;; This may be useful in your .emacs:
  34 ;;
  35 ;;      (autoload 'hexl-find-file "hexl"
  36 ;;        "Edit file FILENAME in hexl-mode." t)
  37 ;;
  38 ;;      (define-key global-map "\C-c\C-h" 'hexl-find-file)
  39 ;;
  40 ;; NOTE: Remember to change HEXL-PROGRAM or HEXL-OPTIONS if needed.
  41 ;;
  42 ;; Currently hexl only supports big endian hex output with 16 bit
  43 ;; grouping.
  44 ;;
  45 ;; -iso in `hexl-options' will allow iso characters to display in the
  46 ;; ASCII region of the screen (if your emacs supports this) instead of
  47 ;; changing them to dots.
  48
  49 ;;; Code:
  50
  51 ;;
  52 ;; vars here
  53 ;;
  54
  55 (defvar hexl-program "hexl"
  56   "The program that will hexlify and de-hexlify its stdin.
  57 `hexl-program' will always be concatenated with `hexl-options'
  58 and \"-de\" when dehexlfying a buffer.")
  59
  60 (defvar hexl-iso ""
  61   "If your emacs can handle ISO characters, this should be set to
  62 \"-iso\" otherwise it should be \"\".")
  63
  64 (defvar hexl-options (format "-hex %s" hexl-iso)
  65   "Options to hexl-program that suit your needs.")
  66
  67 (defvar hexlify-command
  68   (format "%s%s %s" exec-directory hexl-program hexl-options)
  69   "The command to use to hexlify a buffer.")
  70
  71 (defvar dehexlify-command
  72   (format "%s%s -de %s" exec-directory hexl-program hexl-options)
  73   "The command to use to unhexlify a buffer.")
  74
  75 (defvar hexl-max-address 0
  76   "Maximum offset into hexl buffer.")
  77
  78 (defvar hexl-mode-map nil)
  79
  80 ;; routines
  81
  82 ;;;###autoload
  83 (defun hexl-mode (&optional arg)
  84   "\\<hexl-mode-map>
  85 A major mode for editing binary files in hex dump format.
  86
  87 This function automatically converts a buffer into the hexl format
  88 using the function `hexlify-buffer'.
  89
  90 Each line in the buffer has an \"address\" (displayed in hexadecimal)
  91 representing the offset into the file that the characters on this line
  92 are at and 16 characters from the file (displayed as hexadecimal
  93 values grouped every 16 bits) and as their ASCII values.
  94
  95 If any of the characters (displayed as ASCII characters) are
  96 unprintable (control or meta characters) they will be replaced as
  97 periods.
  98
  99 If `hexl-mode' is invoked with an argument the buffer is assumed to be
 100 in hexl format.
 101
 102 A sample format:
 103
 104   HEX ADDR: 0001 0203 0405 0607 0809 0a0b 0c0d 0e0f     ASCII-TEXT
 105   --------  ---- ---- ---- ---- ---- ---- ---- ----  ----------------
 106   00000000: 5468 6973 2069 7320 6865 786c 2d6d 6f64  This is hexl-mod
 107   00000010: 652e 2020 4561 6368 206c 696e 6520 7265  e.  Each line re
 108   00000020: 7072 6573 656e 7473 2031 3620 6279 7465  presents 16 byte
 109   00000030: 7320 6173 2068 6578 6164 6563 696d 616c  s as hexadecimal
 110   00000040: 2041 5343 4949 0a61 6e64 2070 7269 6e74   ASCII.and print
 111   00000050: 6162 6c65 2041 5343 4949 2063 6861 7261  able ASCII chara
 112   00000060: 6374 6572 732e 2020 416e 7920 636f 6e74  cters.  Any cont
 113   00000070: 726f 6c20 6f72 206e 6f6e 2d41 5343 4949  rol or non-ASCII
 114   00000080: 2063 6861 7261 6374 6572 730a 6172 6520   characters.are
 115   00000090: 6469 7370 6c61 7965 6420 6173 2070 6572  displayed as per
 116   000000a0: 696f 6473 2069 6e20 7468 6520 7072 696e  iods in the prin
 117   000000b0: 7461 626c 6520 6368 6172 6163 7465 7220  table character
 118   000000c0: 7265 6769 6f6e 2e0a                      region..
 119
 120 Movement is as simple as movement in a normal emacs text buffer.  Most
 121 cursor movement bindings are the same (ie. Use \\[hexl-backward-char], \\[hexl-forward-char], \\[hexl-next-line], and \\[hexl-previous-line]
 122 to move the cursor left, right, down, and up).
 123
 124 Advanced cursor movement commands (ala \\[hexl-beginning-of-line], \\[hexl-end-of-line], \\[hexl-beginning-of-buffer], and \\[hexl-end-of-buffer]) are
 125 also supported.
 126
 127 There are several ways to change text in hexl mode:
 128
 129 ASCII characters (character between space (0x20) and tilde (0x7E)) are
 130 bound to self-insert so you can simply type the character and it will
 131 insert itself (actually overstrike) into the buffer.
 132
 133 \\[hexl-quoted-insert] followed by another keystroke allows you to insert the key even if
 134 it isn't bound to self-insert.  An octal number can be supplied in place
 135 of another key to insert the octal number's ASCII representation.
 136
 137 \\[hexl-insert-hex-char] will insert a given hexadecimal value (if it is between 0 and 0xFF)
 138 into the buffer at the current point.
 139
 140 \\[hexl-insert-octal-char] will insert a given octal value (if it is between 0 and 0377)
 141 into the buffer at the current point.
 142
 143 \\[hexl-insert-decimal-char] will insert a given decimal value (if it is between 0 and 255)
 144 into the buffer at the current point.
 145
 146 \\[hexl-mode-exit] will exit hexl-mode.
 147
 148 Note: saving the file with any of the usual Emacs commands
 149 will actually convert it back to binary format while saving.
 150
 151 You can use \\[hexl-find-file] to visit a file in hexl-mode.
 152
 153 \\[describe-bindings] for advanced commands."
 154   (interactive "p")
 155   (if (eq major-mode 'hexl-mode)
 156       (error "You are already in hexl mode.")
 157     (kill-all-local-variables)
 158     (make-local-variable 'hexl-mode-old-local-map)
 159     (setq hexl-mode-old-local-map (current-local-map))
 160     (use-local-map hexl-mode-map)
 161
 162     (make-local-variable 'hexl-mode-old-mode-name)
 163     (setq hexl-mode-old-mode-name mode-name)
 164     (setq mode-name "Hexl")
 165
 166     (make-local-variable 'hexl-mode-old-major-mode)
 167     (setq hexl-mode-old-major-mode major-mode)
 168     (setq major-mode 'hexl-mode)
 169
 170     (make-local-variable 'write-contents-hooks)
 171     (add-hook 'write-contents-hooks 'hexl-save-buffer)
 172
 173     (let ((modified (buffer-modified-p))
 174           (read-only buffer-read-only)
 175           (original-point (1- (point))))
 176       (if (not (or (eq arg 1) (not arg)))
 177 ;; if no argument then we guess at hexl-max-address
 178           (setq hexl-max-address (+ (* (/ (1- (buffer-size)) 68) 16) 15))
 179         (setq buffer-read-only nil)
 180         (setq hexl-max-address (1- (buffer-size)))
 181         (hexlify-buffer)
 182         (set-buffer-modified-p modified)
 183         (setq buffer-read-only read-only)
 184         (hexl-goto-address original-point)))))
 185
 186 (defvar hexl-in-save-buffer nil)
 187
 188 (defun hexl-save-buffer ()
 189   "Save a hexl format buffer as binary in visited file if modified."
 190   (interactive)
 191   (if hexl-in-save-buffer nil
 192     (set-buffer-modified-p (if (buffer-modified-p)
 193                                (save-excursion
 194                                  (let ((buf (generate-new-buffer " hexl"))
 195                                        (name (buffer-name))
 196                                        (file-name (buffer-file-name))
 197                                        (start (point-min))
 198                                        (end (point-max))
 199                                        modified)
 200                                    (set-buffer buf)
 201                                    (insert-buffer-substring name start end)
 202                                    (set-buffer name)
 203                                    (dehexlify-buffer)
 204                                    ;; Prevent infinite recursion.
 205                                    (let ((hexl-in-save-buffer t))
 206                                      (save-buffer))
 207                                    (setq modified (buffer-modified-p))
 208                                    (delete-region (point-min) (point-max))
 209                                    (insert-buffer-substring buf start end)
 210                                    (kill-buffer buf)
 211                                    modified))
 212                              (message "(No changes need to be saved)")
 213                              nil))
 214     ;; Return t to indicate we have saved t
 215     t))
 216
 217 ;;;###autoload
 218 (defun hexl-find-file (filename)
 219   "Edit file FILENAME in hexl-mode.
 220 Switch to a buffer visiting file FILENAME, creating one in none exists."
 221   (interactive "fFilename: ")
 222   (find-file filename)
 223   (if (not (eq major-mode 'hexl-mode))
 224       (hexl-mode)))
 225
 226 (defun hexl-mode-exit (&optional arg)
 227   "Exit Hexl mode, returning to previous mode.
 228 With arg, don't unhexlify buffer."
 229   (interactive "p")
 230   (if (or (eq arg 1) (not arg))
 231       (let ((modified (buffer-modified-p))
 232             (read-only buffer-read-only)
 233             (original-point (1+ (hexl-current-address))))
 234         (setq buffer-read-only nil)
 235         (dehexlify-buffer)
 236         (remove-hook 'write-contents-hook 'hexl-save-buffer)
 237         (set-buffer-modified-p modified)
 238         (setq buffer-read-only read-only)
 239         (goto-char original-point)))
 240   (setq mode-name hexl-mode-old-mode-name)
 241   (use-local-map hexl-mode-old-local-map)
 242   (setq major-mode hexl-mode-old-major-mode)
 243 ;; Kludge to update mode-line
 244   (switch-to-buffer (current-buffer))
 245 )
 246
 247 (defun hexl-current-address ()
 248   "Return current hexl-address."
 249   (interactive)
 250   (let ((current-column (- (% (point) 68) 11))
 251         (hexl-address 0))
 252     (setq hexl-address (+ (* (/ (point) 68) 16)
 253                           (/ (- current-column  (/ current-column 5)) 2)))
 254     hexl-address))
 255
 256 (defun hexl-address-to-marker (address)
 257   "Return marker for ADDRESS."
 258   (interactive "nAddress: ")
 259   (+ (* (/ address 16) 68) 11 (/ (* (% address 16) 5) 2)))
 260
 261 (defun hexl-goto-address (address)
 262   "Goto hexl-mode (decimal) address ADDRESS.
 263
 264 Signal error if ADDRESS out of range."
 265   (interactive "nAddress: ")
 266   (if (or (< address 0) (> address hexl-max-address))
 267           (error "Out of hexl region."))
 268   (goto-char (hexl-address-to-marker address)))
 269
 270 (defun hexl-goto-hex-address (hex-address)
 271   "Go to hexl-mode address (hex string) HEX-ADDRESS.
 272
 273 Signal error if HEX-ADDRESS is out of range."
 274   (interactive "sHex Address: ")
 275   (hexl-goto-address (hexl-hex-string-to-integer hex-address)))
 276
 277 (defun hexl-hex-string-to-integer (hex-string)
 278   "Return decimal integer for HEX-STRING."
 279   (interactive "sHex number: ")
 280   (let ((hex-num 0))
 281     (while (not (equal hex-string ""))
 282       (setq hex-num (+ (* hex-num 16)
 283                        (hexl-hex-char-to-integer (string-to-char hex-string))))
 284       (setq hex-string (substring hex-string 1)))
 285     hex-num))
 286
 287 (defun hexl-octal-string-to-integer (octal-string)
 288   "Return decimal integer for OCTAL-STRING."
 289   (interactive "sOctal number: ")
 290   (let ((oct-num 0))
 291     (while (not (equal octal-string ""))
 292       (setq oct-num (+ (* oct-num 8)
 293                        (hexl-oct-char-to-integer
 294                         (string-to-char octal-string))))
 295       (setq octal-string (substring octal-string 1)))
 296     oct-num))
 297
 298 ;; move point functions
 299
 300 (defun hexl-backward-char (arg)
 301   "Move to left ARG bytes (right if ARG negative) in hexl-mode."
 302   (interactive "p")
 303   (hexl-goto-address (- (hexl-current-address) arg)))
 304
 305 (defun hexl-forward-char (arg)
 306   "Move right ARG bytes (left if ARG negative) in hexl-mode."
 307   (interactive "p")
 308   (hexl-goto-address (+ (hexl-current-address) arg)))
 309
 310 (defun hexl-backward-short (arg)
 311   "Move to left ARG shorts (right if ARG negative) in hexl-mode."
 312   (interactive "p")
 313   (hexl-goto-address (let ((address (hexl-current-address)))
 314                        (if (< arg 0)
 315                            (progn
 316                              (setq arg (- arg))
 317                              (while (> arg 0)
 318                                (if (not (equal address (logior address 3)))
 319                                    (if (> address hexl-max-address)
 320                                        (progn
 321                                          (message "End of buffer.")
 322                                          (setq address hexl-max-address))
 323                                      (setq address (logior address 3)))
 324                                  (if (> address hexl-max-address)
 325                                      (progn
 326                                        (message "End of buffer.")
 327                                        (setq address hexl-max-address))
 328                                    (setq address (+ address 4))))
 329                                (setq arg (1- arg)))
 330                              (if (> address hexl-max-address)
 331                                  (progn
 332                                    (message "End of buffer.")
 333                                    (setq address hexl-max-address))
 334                                (setq address (logior address 3))))
 335                          (while (> arg 0)
 336                            (if (not (equal address (logand address -4)))
 337                                (setq address (logand address -4))
 338                              (if (not (equal address 0))
 339                                  (setq address (- address 4))
 340                                (message "Beginning of buffer.")))
 341                            (setq arg (1- arg))))
 342                        address)))
 343
 344 (defun hexl-forward-short (arg)
 345   "Move right ARG shorts (left if ARG negative) in hexl-mode."
 346   (interactive "p")
 347   (hexl-backward-short (- arg)))
 348
 349 (defun hexl-backward-word (arg)
 350   "Move to left ARG words (right if ARG negative) in hexl-mode."
 351   (interactive "p")
 352   (hexl-goto-address (let ((address (hexl-current-address)))
 353                        (if (< arg 0)
 354                            (progn
 355                              (setq arg (- arg))
 356                              (while (> arg 0)
 357                                (if (not (equal address (logior address 7)))
 358                                    (if (> address hexl-max-address)
 359                                        (progn
 360                                          (message "End of buffer.")
 361                                          (setq address hexl-max-address))
 362                                      (setq address (logior address 7)))
 363                                  (if (> address hexl-max-address)
 364                                      (progn
 365                                        (message "End of buffer.")
 366                                        (setq address hexl-max-address))
 367                                    (setq address (+ address 8))))
 368                                (setq arg (1- arg)))
 369                              (if (> address hexl-max-address)
 370                                  (progn
 371                                    (message "End of buffer.")
 372                                    (setq address hexl-max-address))
 373                                (setq address (logior address 7))))
 374                          (while (> arg 0)
 375                            (if (not (equal address (logand address -8)))
 376                                (setq address (logand address -8))
 377                              (if (not (equal address 0))
 378                                  (setq address (- address 8))
 379                                (message "Beginning of buffer.")))
 380                            (setq arg (1- arg))))
 381                        address)))
 382
 383 (defun hexl-forward-word (arg)
 384   "Move right ARG words (left if ARG negative) in hexl-mode."
 385   (interactive "p")
 386   (hexl-backward-word (- arg)))
 387
 388 (defun hexl-previous-line (arg)
 389   "Move vertically up ARG lines [16 bytes] (down if ARG negative) in hexl-mode.
 390 If there is byte at the target address move to the last byte in that line."
 391   (interactive "p")
 392   (hexl-next-line (- arg)))
 393
 394 (defun hexl-next-line (arg)
 395   "Move vertically down ARG lines [16 bytes] (up if ARG negative) in hexl-mode.
 396 If there is no byte at the target address move to the last byte in that line."
 397   (interactive "p")
 398   (hexl-goto-address (let ((address (+ (hexl-current-address) (* arg 16))))
 399                        (if (and (< arg 0) (< address 0))
 400                                 (progn (message "Out of hexl region.")
 401                                        (setq address
 402                                              (% (hexl-current-address) 16)))
 403                          (if (and (> address hexl-max-address)
 404                                   (< (% hexl-max-address 16) (% address 16)))
 405                              (setq address hexl-max-address)
 406                            (if (> address hexl-max-address)
 407                                (progn (message "Out of hexl region.")
 408                                       (setq
 409                                        address
 410                                        (+ (logand hexl-max-address -16)
 411                                           (% (hexl-current-address) 16)))))))
 412                        address)))
 413
 414 (defun hexl-beginning-of-buffer (arg)
 415   "Move to the beginning of the hexl buffer.
 416 Leaves `hexl-mark' at previous position.
 417 With prefix arg N, puts point N bytes of the way from the true beginning."
 418   (interactive "p")
 419   (push-mark (point))
 420   (hexl-goto-address (+ 0 (1- arg))))
 421
 422 (defun hexl-end-of-buffer (arg)
 423   "Go to `hexl-max-address' minus ARG."
 424   (interactive "p")
 425   (push-mark (point))
 426   (hexl-goto-address (- hexl-max-address (1- arg))))
 427
 428 (defun hexl-beginning-of-line ()
 429   "Goto beginning of line in hexl mode."
 430   (interactive)
 431   (goto-char (+ (* (/ (point) 68) 68) 11)))
 432
 433 (defun hexl-end-of-line ()
 434   "Goto end of line in hexl mode."
 435   (interactive)
 436   (hexl-goto-address (let ((address (logior (hexl-current-address) 15)))
 437                        (if (> address hexl-max-address)
 438                            (setq address hexl-max-address))
 439                        address)))
 440
 441 (defun hexl-scroll-down (arg)
 442   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 443   (interactive "P")
 444   (if (null arg)
 445       (setq arg (1- (window-height)))
 446     (setq arg (prefix-numeric-value arg)))
 447   (hexl-scroll-up (- arg)))
 448
 449 (defun hexl-scroll-up (arg)
 450   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 451   (interactive "P")
 452   (if (null arg)
 453       (setq arg (1- (window-height)))
 454     (setq arg (prefix-numeric-value arg)))
 455   (let ((movement (* arg 16))
 456         (address (hexl-current-address)))
 457     (if (or (> (+ address movement) hexl-max-address)
 458             (< (+ address movement) 0))
 459         (message "Out of hexl region.")
 460       (hexl-goto-address (+ address movement))
 461       (recenter 0))))
 462
 463 (defun hexl-beginning-of-1k-page ()
 464   "Goto to beginning of 1k boundry."
 465   (interactive)
 466   (hexl-goto-address (logand (hexl-current-address) -1024)))
 467
 468 (defun hexl-end-of-1k-page ()
 469   "Goto to end of 1k boundry."
 470   (interactive)
 471   (hexl-goto-address (let ((address (logior (hexl-current-address) 1023)))
 472                        (if (> address hexl-max-address)
 473                            (setq address hexl-max-address))
 474                        address)))
 475
 476 (defun hexl-beginning-of-512b-page ()
 477   "Goto to beginning of 512 byte boundry."
 478   (interactive)
 479   (hexl-goto-address (logand (hexl-current-address) -512)))
 480
 481 (defun hexl-end-of-512b-page ()
 482   "Goto to end of 512 byte boundry."
 483   (interactive)
 484   (hexl-goto-address (let ((address (logior (hexl-current-address) 511)))
 485                        (if (> address hexl-max-address)
 486                            (setq address hexl-max-address))
 487                        address)))
 488
 489 (defun hexl-quoted-insert (arg)
 490   "Read next input character and insert it.
 491 Useful for inserting control characters.
 492 You may also type up to 3 octal digits, to insert a character with that code"
 493   (interactive "p")
 494   (hexl-insert-char (read-quoted-char) arg))
 495
 496 ;00000000: 0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789ABCDEF
 497
 498 ;;;###autoload
 499 (defun hexlify-buffer ()
 500   "Convert a binary buffer to hexl format"
 501   (interactive)
 502   (shell-command-on-region (point-min) (point-max) hexlify-command t))
 503
 504 (defun dehexlify-buffer ()
 505   "Convert a hexl format buffer to binary."
 506   (interactive)
 507   (shell-command-on-region (point-min) (point-max) dehexlify-command t))
 508
 509 (defun hexl-char-after-point ()
 510   "Return char for ASCII hex digits at point."
 511   (hexl-htoi (char-after (point))
 512              (char-after (1+ (point)))))
 513
 514 (defun hexl-htoi (lh rh)
 515   "Hex (char) LH (char) RH to integer."
 516     (+ (* (hexl-hex-char-to-integer lh) 16)
 517        (hexl-hex-char-to-integer rh)))
 518
 519 (defun hexl-hex-char-to-integer (character)
 520   "Take a char and return its value as if it was a hex digit."
 521   (if (and (>= character ?0) (<= character ?9))
 522       (- character ?0)
 523     (let ((ch (logior character 32)))
 524       (if (and (>= ch ?a) (<= ch ?f))
 525           (- ch (- ?a 10))
 526         (error (format "Invalid hex digit `%c'." ch))))))
 527
 528 (defun hexl-oct-char-to-integer (character)
 529   "Take a char and return its value as if it was a octal digit."
 530   (if (and (>= character ?0) (<= character ?7))
 531       (- character ?0)
 532     (error (format "Invalid octal digit `%c'." character))))
 533
 534 (defun hexl-printable-character (ch)
 535   "Return a displayable string for character CH."
 536   (format "%c" (if hexl-iso
 537                    (if (or (< ch 32) (and (>= ch 127) (< ch 160)))
 538                        46
 539                      ch)
 540                  (if (or (< ch 32) (>= ch 127))
 541                      46
 542                    ch))))
 543
 544 (defun hexl-self-insert-command (arg)
 545   "Insert this character."
 546   (interactive "p")
 547   (hexl-insert-char last-command-char arg))
 548
 549 (defun hexl-insert-char (ch num)
 550   "Insert a character in a hexl buffer."
 551   (let ((address (hexl-current-address)))
 552     (while (> num 0)
 553       (delete-char 2)
 554       (insert (format "%02x" ch))
 555       (goto-char
 556        (+ (* (/ address 16) 68) 52 (% address 16)))
 557       (delete-char 1)
 558       (insert (hexl-printable-character ch))
 559       (if (eq address hexl-max-address)
 560           (hexl-goto-address address)
 561         (hexl-goto-address (1+ address)))
 562       (setq num (1- num)))))
 563
 564 ;; hex conversion
 565
 566 (defun hexl-insert-hex-char (arg)
 567   "Insert a ASCII char ARG times at point for a given hexadecimal number."
 568   (interactive "p")
 569   (let ((num (hexl-hex-string-to-integer (read-string "Hex number: "))))
 570     (if (or (> num 255) (< num 0))
 571         (error "Hex number out of range.")
 572       (hexl-insert-char num arg))))
 573
 574 (defun hexl-insert-decimal-char (arg)
 575   "Insert a ASCII char ARG times at point for a given decimal number."
 576   (interactive "p")
 577   (let ((num (string-to-int (read-string "Decimal Number: "))))
 578     (if (or (> num 255) (< num 0))
 579         (error "Decimal number out of range.")
 580       (hexl-insert-char num arg))))
 581
 582 (defun hexl-insert-octal-char (arg)
 583   "Insert a ASCII char ARG times at point for a given octal number."
 584   (interactive "p")
 585   (let ((num (hexl-octal-string-to-integer (read-string "Octal Number: "))))
 586     (if (or (> num 255) (< num 0))
 587         (error "Decimal number out of range.")
 588       (hexl-insert-char num arg))))
 589
 590 ;; startup stuff.
 591
 592 (if hexl-mode-map
 593     nil
 594     (setq hexl-mode-map (make-sparse-keymap))
 595
 596     (define-key hexl-mode-map "\C-a" 'hexl-beginning-of-line)
 597     (define-key hexl-mode-map "\C-b" 'hexl-backward-char)
 598     (define-key hexl-mode-map "\C-d" 'undefined)
 599     (define-key hexl-mode-map "\C-e" 'hexl-end-of-line)
 600     (define-key hexl-mode-map "\C-f" 'hexl-forward-char)
 601
 602     (if (not (eq (key-binding (char-to-string help-char)) 'help-command))
 603         (define-key hexl-mode-map help-char 'undefined))
 604
 605     (define-key hexl-mode-map "\C-i" 'hexl-self-insert-command)
 606     (define-key hexl-mode-map "\C-j" 'hexl-self-insert-command)
 607     (define-key hexl-mode-map "\C-k" 'undefined)
 608     (define-key hexl-mode-map "\C-m" 'hexl-self-insert-command)
 609     (define-key hexl-mode-map "\C-n" 'hexl-next-line)
 610     (define-key hexl-mode-map "\C-o" 'undefined)
 611     (define-key hexl-mode-map "\C-p" 'hexl-previous-line)
 612     (define-key hexl-mode-map "\C-q" 'hexl-quoted-insert)
 613     (define-key hexl-mode-map "\C-t" 'undefined)
 614     (define-key hexl-mode-map "\C-v" 'hexl-scroll-up)
 615     (define-key hexl-mode-map "\C-w" 'undefined)
 616     (define-key hexl-mode-map "\C-y" 'undefined)
 617
 618     (let ((ch 32))
 619       (while (< ch 127)
 620         (define-key hexl-mode-map (format "%c" ch) 'hexl-self-insert-command)
 621         (setq ch (1+ ch))))
 622
 623     (define-key hexl-mode-map "\e\C-a" 'hexl-beginning-of-512b-page)
 624     (define-key hexl-mode-map "\e\C-b" 'hexl-backward-short)
 625     (define-key hexl-mode-map "\e\C-c" 'undefined)
 626     (define-key hexl-mode-map "\e\C-d" 'hexl-insert-decimal-char)
 627     (define-key hexl-mode-map "\e\C-e" 'hexl-end-of-512b-page)
 628     (define-key hexl-mode-map "\e\C-f" 'hexl-forward-short)
 629     (define-key hexl-mode-map "\e\C-g" 'undefined)
 630     (define-key hexl-mode-map "\e\C-h" 'undefined)
 631     (define-key hexl-mode-map "\e\C-i" 'undefined)
 632     (define-key hexl-mode-map "\e\C-j" 'undefined)
 633     (define-key hexl-mode-map "\e\C-k" 'undefined)
 634     (define-key hexl-mode-map "\e\C-l" 'undefined)
 635     (define-key hexl-mode-map "\e\C-m" 'undefined)
 636     (define-key hexl-mode-map "\e\C-n" 'undefined)
 637     (define-key hexl-mode-map "\e\C-o" 'hexl-insert-octal-char)
 638     (define-key hexl-mode-map "\e\C-p" 'undefined)
 639     (define-key hexl-mode-map "\e\C-q" 'undefined)
 640     (define-key hexl-mode-map "\e\C-r" 'undefined)
 641     (define-key hexl-mode-map "\e\C-s" 'undefined)
 642     (define-key hexl-mode-map "\e\C-t" 'undefined)
 643     (define-key hexl-mode-map "\e\C-u" 'undefined)
 644
 645     (define-key hexl-mode-map "\e\C-w" 'undefined)
 646     (define-key hexl-mode-map "\e\C-x" 'hexl-insert-hex-char)
 647     (define-key hexl-mode-map "\e\C-y" 'undefined)
 648
 649     (define-key hexl-mode-map "\ea" 'undefined)
 650     (define-key hexl-mode-map "\eb" 'hexl-backward-word)
 651     (define-key hexl-mode-map "\ec" 'undefined)
 652     (define-key hexl-mode-map "\ed" 'undefined)
 653     (define-key hexl-mode-map "\ee" 'undefined)
 654     (define-key hexl-mode-map "\ef" 'hexl-forward-word)
 655     (define-key hexl-mode-map "\eg" 'hexl-goto-hex-address)
 656     (define-key hexl-mode-map "\eh" 'undefined)
 657     (define-key hexl-mode-map "\ei" 'undefined)
 658     (define-key hexl-mode-map "\ej" 'hexl-goto-address)
 659     (define-key hexl-mode-map "\ek" 'undefined)
 660     (define-key hexl-mode-map "\el" 'undefined)
 661     (define-key hexl-mode-map "\em" 'undefined)
 662     (define-key hexl-mode-map "\en" 'undefined)
 663     (define-key hexl-mode-map "\eo" 'undefined)
 664     (define-key hexl-mode-map "\ep" 'undefined)
 665     (define-key hexl-mode-map "\eq" 'undefined)
 666     (define-key hexl-mode-map "\er" 'undefined)
 667     (define-key hexl-mode-map "\es" 'undefined)
 668     (define-key hexl-mode-map "\et" 'undefined)
 669     (define-key hexl-mode-map "\eu" 'undefined)
 670     (define-key hexl-mode-map "\ev" 'hexl-scroll-down)
 671     (define-key hexl-mode-map "\ey" 'undefined)
 672     (define-key hexl-mode-map "\ez" 'undefined)
 673     (define-key hexl-mode-map "\e<" 'hexl-beginning-of-buffer)
 674     (define-key hexl-mode-map "\e>" 'hexl-end-of-buffer)
 675
 676     (define-key hexl-mode-map "\C-c\C-c" 'hexl-mode-exit)
 677
 678     (define-key hexl-mode-map "\C-x[" 'hexl-beginning-of-1k-page)
 679     (define-key hexl-mode-map "\C-x]" 'hexl-end-of-1k-page)
 680     (define-key hexl-mode-map "\C-x\C-p" 'undefined)
 681     (define-key hexl-mode-map "\C-x\C-s" 'hexl-save-buffer)
 682     (define-key hexl-mode-map "\C-x\C-t" 'undefined))
 683
 684 ;;; hexl.el ends here