lisp/uniquify.el

   1 ;;; uniquify.el --- unique buffer names dependent on file name
   2
   3 ;; Copyright (C) 1989, 1995, 1996, 1997, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Dick King <king@reasoning.com>
   7 ;; Maintainer: FSF
   8 ;; Keywords: files
   9 ;; Created: 15 May 86
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; Emacs's standard method for making buffer names unique adds <2>, <3>,
  31 ;; etc.. to the end of (all but one of) the buffers.  This file replaces
  32 ;; that behavior, for buffers visiting files and dired buffers, with a
  33 ;; uniquification that adds parts of the file name until the buffer names
  34 ;; are unique.  For instance, buffers visiting /u/mernst/tmp/Makefile and
  35 ;; /usr/projects/zaphod/Makefile would be named Makefile|tmp and
  36 ;; Makefile|zaphod, respectively (instead of Makefile and Makefile<2>).
  37 ;; Other buffer name styles are also available.
  38
  39 ;; To use this file, do (require 'uniquify)
  40 ;; and set uniquify-buffer-name-style to one of its non-nil alternative values.
  41
  42 ;; For other options, see "User-visible variables", below.
  43
  44 ;; A version of uniquify.el that works under Emacs 18, Emacs 19, XEmacs,
  45 ;; and InfoDock is available from the maintainer.
  46
  47 ;;; Change Log:
  48
  49 ;; Originally by Dick King <king@reasoning.com> 15 May 86
  50 ;; Converted for Emacs 18 by Stephen Gildea <gildea@stop.mail-abuse.org>
  51 ;; Make uniquify-min-dir-content 0 truly non-invasive.  gildea 23 May 89
  52 ;; Some cleanup.  uniquify-min-dir-content default 0.  gildea 01 Jun 89
  53 ;; Don't rename to "".  Michael Ernst <mernst@theory.lcs.mit.edu> 15 Jun 94
  54 ;; Add kill-buffer-hook.  Kenneth Manheimer <ken.manheimer@nist.gov> 09 May 95
  55 ;; Add advice for rename-buffer and create-file-buffer, handle dired buffers,
  56 ;;  kill-buffer-rationalize-buffer-names-p, documentation.  mernst 24 May 95
  57 ;; Remove free variables, fix typos.  mernst 5 Jun 95
  58 ;; Efficiently support Emacs 19.27 & earlier.  ken.manheimer, mernst 10 Jun 95
  59 ;; Rename user options to "uniquify-...", add uniquify-reverse-dir-content-p,
  60 ;;  add uniquify-ask-about-buffer-names-p.  king, mernst 13 Jun 95
  61 ;; Prefix functions by "uniquify-..."; rename mnemonic-buffer-names to
  62 ;;  uniquify-buffer-name-style; add 'forward and 'post-forward-angle-brackets
  63 ;;  styles; remove uniquify-reverse-dir-content-p; add
  64 ;;  uniquify-trailing-separator-p.  mernst 4 Aug 95
  65 ;; Don't call expand-file-name on nil.  mernst 7 Jan 96
  66 ;; Check whether list-buffers-directory is bound.  mernst 11 Oct 96
  67 ;; Ignore non-file non-dired buffers. Colin Rafferty <craffert@ml.com> 3 Mar 97
  68 ;; Use last component, not "", for file name of directories.  mernst 27 Jun 97
  69 ;; Use directory-file-name; code cleanup.  mernst 6 Sep 97
  70 ;; Add uniquify-ignore-buffers-re.
  71 ;;  Andre Srinivasan <andre@visigenic.com> 9 Sep 97
  72 ;; Add uniquify-list-buffers-directory-modes
  73 ;;   Stefan Monnier <monnier@cs.yale.edu> 17 Nov 2000
  74 ;; Algorithm and data structure changed to reduce consing with lots of buffers
  75 ;;   Francesco Potortì <pot@gnu.org> (ideas by rms and monnier) 2001-07-18
  76
  77 ;; Valuable feedback was provided by
  78 ;; Paul Smith <psmith@baynetworks.com>,
  79 ;; Alastair Burt <burt@dfki.uni-kl.de>,
  80 ;; Bob Weiner <weiner@footloose.sps.mot.com>,
  81 ;; Albert L. Ting <alt@vlibs.com>,
  82 ;; gyro@reasoning.com,
  83 ;; Bryan O'Sullivan <bos@eng.sun.com>.
  84
  85
  86 ;;; Code:
  87
  88 (eval-when-compile (require 'cl))
  89
  90 ;;; User-visible variables
  91
  92 (defgroup uniquify nil
  93   "Unique buffer names dependent on file name."
  94   :group 'applications)
  95
  96
  97 (defcustom uniquify-buffer-name-style nil
  98   "If non-nil, buffer names are uniquified with parts of directory name.
  99 The value determines the buffer name style and is one of `forward',
 100 `reverse', `post-forward', or `post-forward-angle-brackets'.
 101 For example, files `/foo/bar/mumble/name' and `/baz/quux/mumble/name'
 102 would have the following buffer names in the various styles:
 103   forward        bar/mumble/name  quux/mumble/name
 104   reverse        name\\mumble\\bar  name\\mumble\\quux
 105   post-forward   name|bar/mumble  name|quux/mumble
 106   post-forward-angle-brackets   name<bar/mumble>  name<quux/mumble>
 107   nil            name  name<2>
 108 Of course, the \"mumble\" part may be stripped as well, depending on the setting
 109 of `uniquify-strip-common-suffix'."
 110   :type '(radio (const forward)
 111                 (const reverse)
 112                 (const post-forward)
 113                 (const post-forward-angle-brackets)
 114                 (const :tag "standard Emacs behavior (nil)" nil))
 115   :require 'uniquify
 116   :group 'uniquify)
 117
 118 (defcustom uniquify-after-kill-buffer-p t
 119   "If non-nil, rerationalize buffer names after a buffer has been killed."
 120   :type 'boolean
 121   :group 'uniquify)
 122
 123 (defcustom uniquify-ask-about-buffer-names-p nil
 124   "If non-nil, permit user to choose names for buffers with same base file.
 125 If the user chooses to name a buffer, uniquification is preempted and no
 126 other buffer names are changed."
 127   :type 'boolean
 128   :group 'uniquify)
 129
 130 ;; The default value matches certain Gnus buffers.
 131 (defcustom uniquify-ignore-buffers-re nil
 132   "Regular expression matching buffer names that should not be uniquified.
 133 For instance, set this to \"^draft-[0-9]+$\" to avoid having uniquify rename
 134 draft buffers even if `uniquify-after-kill-buffer-p' is non-nil and the
 135 visited file name isn't the same as that of the buffer."
 136   :type '(choice (const :tag "Uniquify all buffers" nil) regexp)
 137   :group 'uniquify)
 138
 139 (defcustom uniquify-min-dir-content 0
 140   "Minimum number of directory name components included in buffer name."
 141   :type 'integer
 142   :group 'uniquify)
 143
 144 (defcustom uniquify-separator nil
 145   "String separator for buffer name components.
 146 When `uniquify-buffer-name-style' is `post-forward', separates
 147 base file name from directory part in buffer names (default \"|\").
 148 When `uniquify-buffer-name-style' is `reverse', separates all
 149 file name components (default \"\\\")."
 150   :type '(choice (const nil) string)
 151   :group 'uniquify)
 152
 153 (defcustom uniquify-trailing-separator-p nil
 154   "If non-nil, add a file name separator to dired buffer names.
 155 If `uniquify-buffer-name-style' is `forward', add the separator at the end;
 156 if it is `reverse', add the separator at the beginning; otherwise, this
 157 variable is ignored."
 158   :type 'boolean
 159   :group 'uniquify)
 160
 161 (defcustom uniquify-strip-common-suffix
 162   ;; Using it when uniquify-min-dir-content>0 doesn't make much sense.
 163   (eq 0 uniquify-min-dir-content)
 164   "If non-nil, strip common directory suffixes of conflicting files.
 165 E.g. if you open /a1/b/c/d and /a2/b/c/d, the buffer names will say
 166 \"d|a1\" and \"d|a2\" instead of \"d|a1/b/c\" and \"d|a2/b/c\".
 167 This can be handy when you have deep parallel hierarchies."
 168   :type 'boolean
 169   :group 'uniquify)
 170
 171 (defvar uniquify-list-buffers-directory-modes '(dired-mode cvs-mode)
 172   "List of modes for which uniquify should obey `list-buffers-directory'.
 173 That means that when `buffer-file-name' is set to nil, `list-buffers-directory'
 174 contains the name of the directory which the buffer is visiting.")
 175
 176 ;;; Utilities
 177
 178 ;; uniquify-fix-list data structure
 179 (defstruct (uniquify-item
 180             (:constructor nil) (:copier nil)
 181             (:constructor uniquify-make-item
 182              (base dirname buffer &optional proposed)))
 183   base dirname buffer proposed)
 184
 185 ;; Internal variables used free
 186 (defvar uniquify-possibly-resolvable nil)
 187
 188 (defvar uniquify-managed nil
 189   "Non-nil if the name of this buffer is managed by uniquify.
 190 It actually holds the list of `uniquify-item's corresponding to the conflict.")
 191 (make-variable-buffer-local 'uniquify-managed)
 192 (put 'uniquify-managed 'permanent-local t)
 193
 194 ;;; Main entry point.
 195
 196 (defun uniquify-rationalize-file-buffer-names (base dirname newbuf)
 197   "Make file buffer names unique by adding segments from file name.
 198 If `uniquify-min-dir-content' > 0, always pulls that many
 199 file name elements.
 200 Arguments BASE, DIRNAME, and NEWBUF specify the new buffer that causes
 201 this rationalization."
 202   (interactive
 203    (list (if uniquify-managed
 204              (uniquify-item-base (car uniquify-managed)) (buffer-name))
 205          (uniquify-buffer-file-name (current-buffer))
 206          (current-buffer)))
 207   ;; Make sure we don't get confused by outdated uniquify-managed info in
 208   ;; this buffer.
 209   (with-current-buffer newbuf (setq uniquify-managed nil))
 210   (when dirname
 211     (setq dirname (expand-file-name (directory-file-name dirname)))
 212     (let ((fix-list (list (uniquify-make-item base dirname newbuf)))
 213           items)
 214       (dolist (buffer (buffer-list))
 215         (when (and (not (and uniquify-ignore-buffers-re
 216                              (string-match uniquify-ignore-buffers-re
 217                                            (buffer-name buffer))))
 218                    ;; Only try to rename buffers we actually manage.
 219                    (setq items (buffer-local-value 'uniquify-managed buffer))
 220                    (equal base (uniquify-item-base (car items)))
 221                    ;; Don't re-add stuff we already have.  Actually this
 222                    ;; whole `and' test should only match at most once.
 223                    (not (memq (car items) fix-list)))
 224           (unless (cdr items)
 225             ;; If there was no conflict, the buffer-name is equal to the
 226             ;; base-name and we may have missed a rename-buffer because
 227             ;; of code like in set-visited-file-name:
 228             ;; (or (string= new-name (buffer-name)) (rename-buffer new-name t))
 229             ;; So we need to refresh the dirname of the uniquify-item.
 230             (setf (uniquify-item-dirname (car items))
 231                   (uniquify-buffer-file-name
 232                    (uniquify-item-buffer (car items))))
 233             ;; This shouldn't happen, but maybe there's no dirname any more.
 234             (unless (uniquify-item-dirname (car items))
 235               (with-current-buffer (uniquify-item-buffer (car items))
 236                 (setq uniquify-managed nil))
 237               (setq items nil)))
 238           (setq fix-list (append fix-list items))))
 239       ;; selects buffers whose names may need changing, and others that
 240       ;; may conflict, then bring conflicting names together
 241       (uniquify-rationalize fix-list))))
 242
 243 ;; uniquify's version of buffer-file-name; result never contains trailing slash
 244 (defun uniquify-buffer-file-name (buffer)
 245   "Return name of directory, file BUFFER is visiting, or nil if none.
 246 Works on ordinary file-visiting buffers and buffers whose mode is mentioned
 247 in `uniquify-list-buffers-directory-modes', otherwise returns nil."
 248   (with-current-buffer buffer
 249     (let ((filename
 250            (or buffer-file-name
 251                (if (memq major-mode uniquify-list-buffers-directory-modes)
 252                    list-buffers-directory))))
 253       (when filename
 254         (directory-file-name
 255          (file-name-directory
 256           (expand-file-name
 257            (directory-file-name filename))))))))
 258
 259 (defun uniquify-rerationalize-w/o-cb (fix-list)
 260   "Re-rationalize the buffers in FIX-LIST, but ignoring `current-buffer'."
 261   (let ((new-fix-list nil))
 262     (dolist (item fix-list)
 263       (let ((buf (uniquify-item-buffer item)))
 264         (unless (or (eq buf (current-buffer)) (not (buffer-live-p buf)))
 265           (push item new-fix-list))))
 266     (when new-fix-list
 267       (uniquify-rationalize new-fix-list))))
 268
 269 (defun uniquify-rationalize (fix-list)
 270   ;; Set up uniquify to re-rationalize after killing/renaming
 271   ;; if there is a conflict.
 272   (dolist (item fix-list)
 273     (with-current-buffer (uniquify-item-buffer item)
 274       ;; Refresh the dirnames and proposed names.
 275       (setf (uniquify-item-proposed item)
 276             (uniquify-get-proposed-name (uniquify-item-base item)
 277                                         (uniquify-item-dirname item)))
 278       (setq uniquify-managed fix-list)))
 279   ;; Strip any shared last directory names of the dirname.
 280   (when (and (cdr fix-list) uniquify-strip-common-suffix)
 281     (let ((strip t))
 282       (while (let* ((base (file-name-nondirectory
 283                            (uniquify-item-dirname (car fix-list))))
 284                     (items fix-list))
 285                (when (> (length base) 0)
 286                  (while (and strip items)
 287                    (unless (equal base (file-name-nondirectory
 288                                         (uniquify-item-dirname (pop items))))
 289                      (setq strip nil)))
 290                  strip))
 291         ;; It's all the same => strip.
 292         (dolist (item (prog1 fix-list (setq fix-list nil)))
 293           ;; Create new items because the old ones are kept (with the true
 294           ;; `dirname') for later rerationalizing.
 295           (push (uniquify-make-item (uniquify-item-base item)
 296                                     (let ((f (file-name-directory
 297                                               (uniquify-item-dirname item))))
 298                                       (and f (directory-file-name f)))
 299                                     (uniquify-item-buffer item)
 300                                     (uniquify-item-proposed item))
 301                 fix-list)))))
 302   ;; If uniquify-min-dir-content is 0, this will end up just
 303   ;; passing fix-list to uniquify-rationalize-conflicting-sublist.
 304   (uniquify-rationalize-a-list fix-list))
 305
 306 (defun uniquify-item-greaterp (item1 item2)
 307   (string-lessp (uniquify-item-proposed item2)
 308                 (uniquify-item-proposed item1)))
 309
 310 (defun uniquify-rationalize-a-list (fix-list &optional depth)
 311   (unless depth (setq depth uniquify-min-dir-content))
 312   (let (conflicting-sublist     ; all elements have the same proposed name
 313         (old-proposed "")
 314         proposed)
 315     ;; Divide fix-list into items with same proposed names and pass them
 316     ;; to uniquify-rationalize-conflicting-sublist.
 317     (dolist (item (sort fix-list 'uniquify-item-greaterp))
 318       (setq proposed (uniquify-item-proposed item))
 319       (unless (equal proposed old-proposed)
 320         (uniquify-rationalize-conflicting-sublist conflicting-sublist
 321                                                   old-proposed depth)
 322         (setq conflicting-sublist nil))
 323       (push item conflicting-sublist)
 324       (setq old-proposed proposed))
 325     (uniquify-rationalize-conflicting-sublist conflicting-sublist
 326                                               old-proposed depth)))
 327
 328 (defun uniquify-get-proposed-name (base dirname &optional depth)
 329   (unless depth (setq depth uniquify-min-dir-content))
 330   (assert (equal (directory-file-name dirname) dirname))  ;No trailing slash.
 331
 332   ;; Distinguish directories by adding extra separator.
 333   (if (and uniquify-trailing-separator-p
 334            (file-directory-p (expand-file-name base dirname))
 335            (not (string-equal base "")))
 336       (cond ((eq uniquify-buffer-name-style 'forward)
 337              (setq base (file-name-as-directory base)))
 338             ;; (setq base (concat base "/")))
 339             ((eq uniquify-buffer-name-style 'reverse)
 340              (setq base (concat (or uniquify-separator "\\") base)))))
 341
 342   (let ((extra-string nil)
 343         (n depth))
 344     (while (and (> n 0) dirname)
 345       (let ((file (file-name-nondirectory dirname)))
 346         (when (setq dirname (file-name-directory dirname))
 347           (setq dirname (directory-file-name dirname)))
 348         (setq n (1- n))
 349         (push (if (zerop (length file)) ;nil or "".
 350                   (prog1 "" (setq dirname nil)) ;Could be `dirname' iso "".
 351                 file)
 352               extra-string)))
 353     (when (zerop n)
 354       (if (and dirname extra-string
 355                (equal dirname (file-name-directory dirname)))
 356           ;; We're just before the root.  Let's add the leading / already.
 357           ;; With "/a/b"+"/c/d/b" this leads to "/a/b" and "d/b" but with
 358           ;; "/a/b"+"/c/a/b" this leads to "/a/b" and "a/b".
 359           (push "" extra-string))
 360       (setq uniquify-possibly-resolvable t))
 361
 362     (cond
 363      ((null extra-string) base)
 364      ((string-equal base "") ;Happens for dired buffers on the root directory.
 365       (mapconcat 'identity extra-string "/"))
 366      ((eq uniquify-buffer-name-style 'reverse)
 367       (mapconcat 'identity
 368                  (cons base (nreverse extra-string))
 369                  (or uniquify-separator "\\")))
 370      ((eq uniquify-buffer-name-style 'forward)
 371       (mapconcat 'identity (nconc extra-string (list base))
 372                  "/"))
 373      ((eq uniquify-buffer-name-style 'post-forward)
 374       (concat base (or uniquify-separator "|")
 375               (mapconcat 'identity extra-string "/")))
 376      ((eq uniquify-buffer-name-style 'post-forward-angle-brackets)
 377       (concat base "<" (mapconcat 'identity extra-string "/")
 378               ">"))
 379      (t (error "Bad value for uniquify-buffer-name-style: %s"
 380                uniquify-buffer-name-style)))))
 381
 382
 383 ;; Deal with conflicting-sublist, all of whose elements have identical
 384 ;; "base" components.
 385 (defun uniquify-rationalize-conflicting-sublist (conf-list old-name depth)
 386   (when conf-list
 387     (if (or (cdr conf-list)
 388             ;; Check that the proposed name doesn't conflict with some
 389             ;; existing buffer.
 390             (let ((buf (get-buffer old-name)))
 391               (and buf (not (eq buf (uniquify-item-buffer (car conf-list)))))))
 392         (when uniquify-possibly-resolvable
 393           (setq uniquify-possibly-resolvable nil
 394                 depth (1+ depth))
 395           (dolist (item conf-list)
 396             (setf (uniquify-item-proposed item)
 397                   (uniquify-get-proposed-name
 398                    (uniquify-item-base item)
 399                    (uniquify-item-dirname item)
 400                    depth)))
 401           (uniquify-rationalize-a-list conf-list depth))
 402       (unless (string= old-name "")
 403         (uniquify-rename-buffer (car conf-list) old-name)))))
 404
 405
 406 (defun uniquify-rename-buffer (item newname)
 407   (let ((buffer (uniquify-item-buffer item)))
 408     (unless (equal newname (buffer-name buffer))
 409       (with-current-buffer buffer
 410         (let ((uniquify-buffer-name-style nil)) ;Avoid hooks on rename-buffer.
 411           ;; Pass the `unique' arg, so the advice doesn't mark it as unmanaged.
 412           (rename-buffer newname t))))))
 413
 414 ;;; Hooks from the rest of Emacs
 415
 416 ;; The logical place to put all this code is in generate-new-buffer-name.
 417 ;; It's written in C, so we would add a generate-new-buffer-name-function
 418 ;; which, if non-nil, would be called instead of the C.  One problem with
 419 ;; that is that generate-new-buffer-name takes a potential buffer name as
 420 ;; its argument -- not other information, such as what file the buffer will
 421 ;; visit.
 422
 423 ;; The below solution works because generate-new-buffer-name is called
 424 ;; only by rename-buffer (which, as of 19.29, is never called from C) and
 425 ;; generate-new-buffer, which is called only by Lisp functions
 426 ;; create-file-buffer and rename-uniquely.  Rename-uniquely generally
 427 ;; isn't used for buffers visiting files, so it's sufficient to hook
 428 ;; rename-buffer and create-file-buffer.  (Setting find-file-hook isn't
 429 ;; sufficient.)
 430
 431 (defadvice rename-buffer (after rename-buffer-uniquify activate)
 432   "Uniquify buffer names with parts of directory name."
 433   (uniquify-maybe-rerationalize-w/o-cb)
 434   (if (null (ad-get-arg 1))             ; no UNIQUE argument.
 435       ;; Mark this buffer so it won't be renamed by uniquify.
 436       (setq uniquify-managed nil)
 437     (when uniquify-buffer-name-style
 438       ;; Rerationalize w.r.t the new name.
 439       (uniquify-rationalize-file-buffer-names
 440        (ad-get-arg 0)
 441        (uniquify-buffer-file-name (current-buffer))
 442        (current-buffer))
 443       (setq ad-return-value (buffer-name (current-buffer))))))
 444
 445 (defadvice create-file-buffer (after create-file-buffer-uniquify activate)
 446   "Uniquify buffer names with parts of directory name."
 447   (if uniquify-buffer-name-style
 448       (let ((filename (expand-file-name (directory-file-name (ad-get-arg 0)))))
 449         (uniquify-rationalize-file-buffer-names
 450          (file-name-nondirectory filename)
 451          (file-name-directory filename) ad-return-value))))
 452
 453 ;; Buffer deletion
 454 ;; Rerationalize after a buffer is killed, to reduce coinciding buffer names.
 455 ;; This mechanism uses `kill-buffer-hook', which runs *before* deletion.
 456 ;; That means that the kill-buffer-hook function cannot just delete the
 457 ;; buffer -- it has to set something to do the rationalization *later*.
 458 ;; It actually puts another function on `post-command-hook'.  This other
 459 ;; function runs the rationalization and then removes itself from the hook.
 460 ;; Is there a better way to accomplish this?
 461 ;; (This ought to set some global variables so the work is done only for
 462 ;; buffers with names similar to the deleted buffer.  -MDE)
 463
 464 (defun uniquify-maybe-rerationalize-w/o-cb ()
 465   "Re-rationalize buffer names, ignoring current buffer.
 466 For use on `kill-buffer-hook'."
 467   (if (and (cdr uniquify-managed)
 468            uniquify-buffer-name-style
 469            uniquify-after-kill-buffer-p)
 470       (uniquify-rerationalize-w/o-cb uniquify-managed)))
 471
 472 ;; Ideally we'd like to add it buffer-locally, but that doesn't work
 473 ;; because kill-buffer-hook is not permanent-local :-(
 474 (add-hook 'kill-buffer-hook 'uniquify-maybe-rerationalize-w/o-cb)
 475
 476 (provide 'uniquify)
 477
 478 ;; arch-tag: e763faa3-56c9-4903-8eb8-26e1c45a0065
 479 ;;; uniquify.el ends here