lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992,1993,1994,1995,1996,1998,1999,2000,2001,2002,2004
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile
  31   (require 'cl)
  32   ;; Warning suppression -- can't require x-win in batch:
  33   (autoload 'xw-defined-colors "x-win"))
  34
  35 \f
  36 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  37 ;;; Font selection.
  38 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  39
  40 (defgroup font-selection nil
  41   "Influencing face font selection."
  42   :group 'faces)
  43
  44
  45 (defcustom face-font-selection-order
  46   '(:width :height :weight :slant)
  47   "*A list specifying how face font selection chooses fonts.
  48 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  49 must appear once in the list, and the list must not contain any other
  50 elements.  Font selection tries to find a best matching font for
  51 those face attributes first that appear first in the list.  For
  52 example, if `:slant' appears before `:height', font selection first
  53 tries to find a font with a suitable slant, even if this results in
  54 a font height that isn't optimal."
  55   :tag "Font selection order"
  56   :type '(list symbol symbol symbol symbol)
  57   :group 'font-selection
  58   :set #'(lambda (symbol value)
  59            (set-default symbol value)
  60            (internal-set-font-selection-order value)))
  61
  62
  63 ;; This is defined originally in xfaces.c.
  64 (defcustom face-font-family-alternatives
  65   '(("courier" "fixed")
  66     ("helv" "helvetica" "arial" "fixed"))
  67   "*Alist of alternative font family names.
  68 Each element has the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  69 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  70 ALTERNATIVE2 etc."
  71   :tag "Alternative font families to try"
  72   :type '(repeat (repeat string))
  73   :group 'font-selection
  74   :set #'(lambda (symbol value)
  75            (set-default symbol value)
  76            (internal-set-alternative-font-family-alist value)))
  77
  78
  79 ;; This is defined originally in xfaces.c.
  80 (defcustom face-font-registry-alternatives
  81   (if (eq system-type 'windows-nt)
  82       '(("iso8859-1" "ms-oemlatin")
  83         ("gb2312.1980" "gb2312")
  84         ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  85         ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  86         ("muletibetan-2" "muletibetan-0"))
  87     '(("gb2312.1980" "gb2312.80&gb8565.88" "gbk*")
  88       ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  89       ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  90       ("muletibetan-2" "muletibetan-0")))
  91   "*Alist of alternative font registry names.
  92 Each element has the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
  93 If fonts of registry REGISTRY can be loaded, font selection
  94 tries to find a best matching font among all fonts of registry
  95 REGISTRY, ALTERNATIVE1, ALTERNATIVE2, and etc."
  96   :tag "Alternative font registries to try"
  97   :type '(repeat (repeat string))
  98   :version "21.1"
  99   :group 'font-selection
 100   :set #'(lambda (symbol value)
 101            (set-default symbol value)
 102            (internal-set-alternative-font-registry-alist value)))
 103
 104
 105 \f
 106 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 107 ;;; Creation, copying.
 108 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 109
 110
 111 (defun face-list ()
 112   "Return a list of all defined face names."
 113   (mapcar #'car face-new-frame-defaults))
 114
 115
 116 ;;; ### If not frame-local initialize by what X resources?
 117
 118 (defun make-face (face &optional no-init-from-resources)
 119   "Define a new face with name FACE, a symbol.
 120 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
 121 variants of FACE from X resources.  (X resources recognized are found
 122 in the global variable `face-x-resources'.)  If FACE is already known
 123 as a face, leave it unmodified.  Value is FACE."
 124   (interactive "SMake face: ")
 125   (unless (facep face)
 126     ;; Make frame-local faces (this also makes the global one).
 127     (dolist (frame (frame-list))
 128       (internal-make-lisp-face face frame))
 129     ;; Add the face to the face menu.
 130     (when (fboundp 'facemenu-add-new-face)
 131       (facemenu-add-new-face face))
 132     ;; Define frame-local faces for all frames from X resources.
 133     (unless no-init-from-resources
 134       (make-face-x-resource-internal face)))
 135   face)
 136
 137
 138 (defun make-empty-face (face)
 139   "Define a new, empty face with name FACE.
 140 If the face already exists, it is left unmodified.  Value is FACE."
 141   (interactive "SMake empty face: ")
 142   (make-face face 'no-init-from-resources))
 143
 144
 145 (defun copy-face (old-face new-face &optional frame new-frame)
 146   "Define a face just like OLD-FACE, with name NEW-FACE.
 147
 148 If NEW-FACE already exists as a face, it is modified to be like
 149 OLD-FACE.  If it doesn't already exist, it is created.
 150
 151 If the optional argument FRAME is given as a frame, NEW-FACE is
 152 changed on FRAME only.
 153 If FRAME is t, the frame-independent default specification for OLD-FACE
 154 is copied to NEW-FACE.
 155 If FRAME is nil, copying is done for the frame-independent defaults
 156 and for each existing frame.
 157
 158 If the optional fourth argument NEW-FRAME is given,
 159 copy the information from face OLD-FACE on frame FRAME
 160 to NEW-FACE on frame NEW-FRAME."
 161   (let ((inhibit-quit t))
 162     (if (null frame)
 163         (progn
 164           (dolist (frame (frame-list))
 165             (copy-face old-face new-face frame))
 166           (copy-face old-face new-face t))
 167       (internal-copy-lisp-face old-face new-face frame new-frame))
 168     new-face))
 169
 170
 171 \f
 172 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 173 ;;; Obsolete functions
 174 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 175
 176 ;; The functions in this section are defined because Lisp packages use
 177 ;; them, despite the prefix `internal-' suggesting that they are
 178 ;; private to the face implementation.
 179
 180 (defun internal-find-face (name &optional frame)
 181   "Retrieve the face named NAME.
 182 Return nil if there is no such face.
 183 If the optional argument FRAME is given, this gets the face NAME for
 184 that frame; otherwise, it uses the selected frame.
 185 If FRAME is the symbol t, then the global, non-frame face is returned.
 186 If NAME is already a face, it is simply returned.
 187
 188 This function is defined for compatibility with Emacs 20.2.  It
 189 should not be used anymore."
 190   (facep name))
 191 (make-obsolete 'internal-find-face 'facep "21.1")
 192
 193
 194 (defun internal-get-face (name &optional frame)
 195   "Retrieve the face named NAME; error if there is none.
 196 If the optional argument FRAME is given, this gets the face NAME for
 197 that frame; otherwise, it uses the selected frame.
 198 If FRAME is the symbol t, then the global, non-frame face is returned.
 199 If NAME is already a face, it is simply returned."
 200   (or (facep name)
 201       (check-face name)))
 202 (make-obsolete 'internal-get-face "see `facep' and `check-face'." "21.1")
 203
 204 \f
 205 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 206 ;;; Predicates, type checks.
 207 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 208
 209 (defun facep (face)
 210   "Return non-nil if FACE is a face name."
 211   (internal-lisp-face-p face))
 212
 213
 214 (defun check-face (face)
 215   "Signal an error if FACE doesn't name a face.
 216 Value is FACE."
 217   (unless (facep face)
 218     (error "Not a face: %s" face))
 219   face)
 220
 221
 222 ;; The ID returned is not to be confused with the internally used IDs
 223 ;; of realized faces.  The ID assigned to Lisp faces is used to
 224 ;; support faces in display table entries.
 225
 226 (defun face-id (face &optional frame)
 227   "Return the internal ID of face with name FACE.
 228 If optional argument FRAME is nil or omitted, use the selected frame."
 229   (check-face face)
 230   (get face 'face))
 231
 232
 233 (defun face-equal (face1 face2 &optional frame)
 234   "Non-nil if faces FACE1 and FACE2 are equal.
 235 Faces are considered equal if all their attributes are equal.
 236 If the optional argument FRAME is given, report on face FACE in that frame.
 237 If FRAME is t, report on the defaults for face FACE (for new frames).
 238 If FRAME is omitted or nil, use the selected frame."
 239   (internal-lisp-face-equal-p face1 face2 frame))
 240
 241
 242 (defun face-differs-from-default-p (face &optional frame)
 243   "Non-nil if FACE displays differently from the default face.
 244 If the optional argument FRAME is given, report on face FACE in that frame.
 245 If FRAME is t, report on the defaults for face FACE (for new frames).
 246 If FRAME is omitted or nil, use the selected frame.
 247 A face is considered to be ``the same'' as the default face if it is
 248 actually specified in the same way (equal attributes) or if it is
 249 fully-unspecified, and thus inherits the attributes of any face it
 250 is displayed on top of."
 251   (cond ((eq frame t) (setq frame nil))
 252         ((null frame) (setq frame (selected-frame))))
 253   (let* ((v1 (internal-lisp-face-p face frame))
 254          (n (if v1 (length v1) 0))
 255          (v2 (internal-lisp-face-p 'default frame))
 256          (i 1))
 257     (unless v1
 258       (error "Not a face: %S" face))
 259     (while (and (< i n)
 260                 (or (eq 'unspecified (aref v1 i))
 261                     (equal (aref v1 i) (aref v2 i))))
 262       (setq i (1+ i)))
 263     (< i n)))
 264
 265
 266 (defun face-nontrivial-p (face &optional frame)
 267   "True if face FACE has some non-nil attribute.
 268 If the optional argument FRAME is given, report on face FACE in that frame.
 269 If FRAME is t, report on the defaults for face FACE (for new frames).
 270 If FRAME is omitted or nil, use the selected frame."
 271   (not (internal-lisp-face-empty-p face frame)))
 272
 273
 274 \f
 275 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 276 ;;; Setting face attributes from X resources.
 277 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 278
 279 (defcustom face-x-resources
 280   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 281     (:width (".attributeWidth" . "Face.AttributeWidth"))
 282     (:height (".attributeHeight" . "Face.AttributeHeight"))
 283     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 284     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 285     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 286     (:background (".attributeBackground" . "Face.AttributeBackground"))
 287     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 288     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 289     (:box (".attributeBox" . "Face.AttributeBox"))
 290     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 291     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 292     (:stipple
 293      (".attributeStipple" . "Face.AttributeStipple")
 294      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 295     (:bold (".attributeBold" . "Face.AttributeBold"))
 296     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 297     (:font (".attributeFont" . "Face.AttributeFont"))
 298     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 299   "*List of X resources and classes for face attributes.
 300 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 301 the name of a face attribute, and each ENTRY is a cons of the form
 302 \(RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 303 X resource class for the attribute."
 304   :type '(repeat (cons symbol (repeat (cons string string))))
 305   :group 'faces)
 306
 307
 308 (defun set-face-attribute-from-resource (face attribute resource class frame)
 309   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 310 Value is the attribute value specified by the resource, or nil
 311 if not present.  This function displays a message if the resource
 312 specifies an invalid attribute."
 313   (let* ((face-name (face-name face))
 314          (value (internal-face-x-get-resource (concat face-name resource)
 315                                               class frame)))
 316     (when value
 317       (condition-case ()
 318           (internal-set-lisp-face-attribute-from-resource
 319            face attribute (downcase value) frame)
 320         (error
 321          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 322                   face-name frame attribute value))))
 323     value))
 324
 325
 326 (defun set-face-attributes-from-resources (face frame)
 327   "Set attributes of FACE from X resources for FRAME."
 328   (when (memq (framep frame) '(x w32 mac))
 329     (dolist (definition face-x-resources)
 330       (let ((attribute (car definition)))
 331         (dolist (entry (cdr definition))
 332           (set-face-attribute-from-resource face attribute (car entry)
 333                                             (cdr entry) frame))))))
 334
 335
 336 (defun make-face-x-resource-internal (face &optional frame)
 337   "Fill frame-local FACE on FRAME from X resources.
 338 FRAME nil or not specified means do it for all frames."
 339   (if (null frame)
 340       (dolist (frame (frame-list))
 341         (set-face-attributes-from-resources face frame))
 342     (set-face-attributes-from-resources face frame)))
 343
 344
 345 \f
 346 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 347 ;;; Retrieving face attributes.
 348 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 349
 350 (defun face-name (face)
 351   "Return the name of face FACE."
 352   (symbol-name (check-face face)))
 353
 354
 355 (defun face-attribute (face attribute &optional frame inherit)
 356   "Return the value of FACE's ATTRIBUTE on FRAME.
 357 If the optional argument FRAME is given, report on face FACE in that frame.
 358 If FRAME is t, report on the defaults for face FACE (for new frames).
 359 If FRAME is omitted or nil, use the selected frame.
 360
 361 If INHERIT is nil, only attributes directly defined by FACE are considered,
 362   so the return value may be `unspecified', or a relative value.
 363 If INHERIT is non-nil, FACE's definition of ATTRIBUTE is merged with the
 364   faces specified by its `:inherit' attribute; however the return value
 365   may still be `unspecified' or relative.
 366 If INHERIT is a face or a list of faces, then the result is further merged
 367   with that face (or faces), until it becomes specified and absolute.
 368
 369 To ensure that the return value is always specified and absolute, use a
 370 value of `default' for INHERIT; this will resolve any unspecified or
 371 relative values by merging with the `default' face (which is always
 372 completely specified)."
 373   (let ((value (internal-get-lisp-face-attribute face attribute frame)))
 374     (when (and inherit (face-attribute-relative-p attribute value))
 375       ;; VALUE is relative, so merge with inherited faces
 376       (let ((inh-from (face-attribute face :inherit frame)))
 377         (unless (or (null inh-from) (eq inh-from 'unspecified))
 378           (setq value
 379                 (face-attribute-merged-with attribute value inh-from frame)))))
 380     (when (and inherit
 381                (not (eq inherit t))
 382                (face-attribute-relative-p attribute value))
 383       ;; We should merge with INHERIT as well
 384       (setq value (face-attribute-merged-with attribute value inherit frame)))
 385     value))
 386
 387 (defun face-attribute-merged-with (attribute value faces &optional frame)
 388   "Merges ATTRIBUTE, initially VALUE, with faces from FACES until absolute.
 389 FACES may be either a single face or a list of faces.
 390 \[This is an internal function]"
 391   (cond ((not (face-attribute-relative-p attribute value))
 392          value)
 393         ((null faces)
 394          value)
 395         ((consp faces)
 396          (face-attribute-merged-with
 397           attribute
 398           (face-attribute-merged-with attribute value (car faces) frame)
 399           (cdr faces)
 400           frame))
 401         (t
 402          (merge-face-attribute attribute
 403                                value
 404                                (face-attribute faces attribute frame t)))))
 405
 406
 407 (defmacro face-attribute-specified-or (value &rest body)
 408   "Return VALUE, unless it's `unspecified', in which case evaluate BODY and return the result."
 409   (let ((temp (make-symbol "value")))
 410     `(let ((,temp ,value))
 411        (if (not (eq ,temp 'unspecified))
 412            ,temp
 413          ,@body))))
 414
 415 (defun face-foreground (face &optional frame inherit)
 416   "Return the foreground color name of FACE, or nil if unspecified.
 417 If the optional argument FRAME is given, report on face FACE in that frame.
 418 If FRAME is t, report on the defaults for face FACE (for new frames).
 419 If FRAME is omitted or nil, use the selected frame.
 420
 421 If INHERIT is nil, only a foreground color directly defined by FACE is
 422   considered, so the return value may be nil.
 423 If INHERIT is t, and FACE doesn't define a foreground color, then any
 424   foreground color that FACE inherits through its `:inherit' attribute
 425   is considered as well; however the return value may still be nil.
 426 If INHERIT is a face or a list of faces, then it is used to try to
 427   resolve an unspecified foreground color.
 428
 429 To ensure that a valid color is always returned, use a value of
 430 `default' for INHERIT; this will resolve any unspecified values by
 431 merging with the `default' face (which is always completely specified)."
 432   (face-attribute-specified-or (face-attribute face :foreground frame inherit)
 433                                nil))
 434
 435 (defun face-background (face &optional frame inherit)
 436   "Return the background color name of FACE, or nil if unspecified.
 437 If the optional argument FRAME is given, report on face FACE in that frame.
 438 If FRAME is t, report on the defaults for face FACE (for new frames).
 439 If FRAME is omitted or nil, use the selected frame.
 440
 441 If INHERIT is nil, only a background color directly defined by FACE is
 442   considered, so the return value may be nil.
 443 If INHERIT is t, and FACE doesn't define a background color, then any
 444   background color that FACE inherits through its `:inherit' attribute
 445   is considered as well; however the return value may still be nil.
 446 If INHERIT is a face or a list of faces, then it is used to try to
 447   resolve an unspecified background color.
 448
 449 To ensure that a valid color is always returned, use a value of
 450 `default' for INHERIT; this will resolve any unspecified values by
 451 merging with the `default' face (which is always completely specified)."
 452   (face-attribute-specified-or (face-attribute face :background frame inherit)
 453                                nil))
 454
 455 (defun face-stipple (face &optional frame inherit)
 456  "Return the stipple pixmap name of FACE, or nil if unspecified.
 457 If the optional argument FRAME is given, report on face FACE in that frame.
 458 If FRAME is t, report on the defaults for face FACE (for new frames).
 459 If FRAME is omitted or nil, use the selected frame.
 460
 461 If INHERIT is nil, only a stipple directly defined by FACE is
 462   considered, so the return value may be nil.
 463 If INHERIT is t, and FACE doesn't define a stipple, then any stipple
 464   that FACE inherits through its `:inherit' attribute is considered as
 465   well; however the return value may still be nil.
 466 If INHERIT is a face or a list of faces, then it is used to try to
 467   resolve an unspecified stipple.
 468
 469 To ensure that a valid stipple or nil is always returned, use a value of
 470 `default' for INHERIT; this will resolve any unspecified values by merging
 471 with the `default' face (which is always completely specified)."
 472   (face-attribute-specified-or (face-attribute face :stipple frame inherit)
 473                                nil))
 474
 475
 476 (defalias 'face-background-pixmap 'face-stipple)
 477
 478
 479 (defun face-underline-p (face &optional frame)
 480  "Return non-nil if FACE is underlined.
 481 If the optional argument FRAME is given, report on face FACE in that frame.
 482 If FRAME is t, report on the defaults for face FACE (for new frames).
 483 If FRAME is omitted or nil, use the selected frame."
 484  (eq (face-attribute face :underline frame) t))
 485
 486
 487 (defun face-inverse-video-p (face &optional frame)
 488  "Return non-nil if FACE is in inverse video on FRAME.
 489 If the optional argument FRAME is given, report on face FACE in that frame.
 490 If FRAME is t, report on the defaults for face FACE (for new frames).
 491 If FRAME is omitted or nil, use the selected frame."
 492  (eq (face-attribute face :inverse-video frame) t))
 493
 494
 495 (defun face-bold-p (face &optional frame)
 496   "Return non-nil if the font of FACE is bold on FRAME.
 497 If the optional argument FRAME is given, report on face FACE in that frame.
 498 If FRAME is t, report on the defaults for face FACE (for new frames).
 499 If FRAME is omitted or nil, use the selected frame.
 500 Use `face-attribute' for finer control."
 501   (let ((bold (face-attribute face :weight frame)))
 502     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 503
 504
 505 (defun face-italic-p (face &optional frame)
 506   "Return non-nil if the font of FACE is italic on FRAME.
 507 If the optional argument FRAME is given, report on face FACE in that frame.
 508 If FRAME is t, report on the defaults for face FACE (for new frames).
 509 If FRAME is omitted or nil, use the selected frame.
 510 Use `face-attribute' for finer control."
 511   (let ((italic (face-attribute face :slant frame)))
 512     (memq italic '(italic oblique))))
 513
 514
 515 \f
 516 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 517 ;;; Face documentation.
 518 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 519
 520 (defun face-documentation (face)
 521   "Get the documentation string for FACE."
 522   (get face 'face-documentation))
 523
 524
 525 (defun set-face-documentation (face string)
 526   "Set the documentation string for FACE to STRING."
 527   ;; Perhaps the text should go in DOC.
 528   (put face 'face-documentation (purecopy string)))
 529
 530
 531 (defalias 'face-doc-string 'face-documentation)
 532 (defalias 'set-face-doc-string 'set-face-documentation)
 533
 534
 535 \f
 536 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 537 ;; Setting face attributes.
 538 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 539
 540
 541 (defun set-face-attribute (face frame &rest args)
 542   "Set attributes of FACE on FRAME from ARGS.
 543
 544 FRAME nil means change attributes on all frames.  FRAME t means change
 545 the default for new frames (this is done automatically each time an
 546 attribute is changed on all frames).
 547
 548 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 549 face attribute name.  All attributes can be set to `unspecified';
 550 this fact is not further mentioned below.
 551
 552 The following attributes are recognized:
 553
 554 `:family'
 555
 556 VALUE must be a string specifying the font family, e.g. ``courier'',
 557 or a fontset alias name.  If a font family is specified, wild-cards `*'
 558 and `?' are allowed.
 559
 560 `:width'
 561
 562 VALUE specifies the relative proportionate width of the font to use.
 563 It must be one of the symbols `ultra-condensed', `extra-condensed',
 564 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 565 `extra-expanded', or `ultra-expanded'.
 566
 567 `:height'
 568
 569 VALUE must be either an integer specifying the height of the font to use
 570 in 1/10 pt, a floating point number specifying the amount by which to
 571 scale any underlying face, or a function, which is called with the old
 572 height (from the underlying face), and should return the new height.
 573
 574 `:weight'
 575
 576 VALUE specifies the weight of the font to use.  It must be one of the
 577 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 578 `semi-light', `light', `extra-light', `ultra-light'.
 579
 580 `:slant'
 581
 582 VALUE specifies the slant of the font to use.  It must be one of the
 583 symbols `italic', `oblique', `normal', `reverse-italic', or
 584 `reverse-oblique'.
 585
 586 `:foreground', `:background'
 587
 588 VALUE must be a color name, a string.
 589
 590 `:underline'
 591
 592 VALUE specifies whether characters in FACE should be underlined.  If
 593 VALUE is t, underline with foreground color of the face.  If VALUE is
 594 a string, underline with that color.  If VALUE is nil, explicitly
 595 don't underline.
 596
 597 `:overline'
 598
 599 VALUE specifies whether characters in FACE should be overlined.  If
 600 VALUE is t, overline with foreground color of the face.  If VALUE is a
 601 string, overline with that color.  If VALUE is nil, explicitly don't
 602 overline.
 603
 604 `:strike-through'
 605
 606 VALUE specifies whether characters in FACE should be drawn with a line
 607 striking through them.  If VALUE is t, use the foreground color of the
 608 face.  If VALUE is a string, strike-through with that color.  If VALUE
 609 is nil, explicitly don't strike through.
 610
 611 `:box'
 612
 613 VALUE specifies whether characters in FACE should have a box drawn
 614 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 615 VALUE is t, draw a box with lines of width 1 in the foreground color
 616 of the face.  If VALUE is a string, the string must be a color name,
 617 and the box is drawn in that color with a line width of 1.  Otherwise,
 618 VALUE must be a property list of the form `(:line-width WIDTH
 619 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 620 the property list, a default value will be used for the value, as
 621 specified below.  WIDTH specifies the width of the lines to draw; it
 622 defaults to 1.  If WIDTH is negative, the absolute value is the width
 623 of the lines, and draw top/bottom lines inside the characters area,
 624 not around it.  COLOR is the name of the color to draw in, default is
 625 the foreground color of the face for simple boxes, and the background
 626 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 627 should be draw.  If STYLE is `released-button', draw a box looking
 628 like a released 3D button.  If STYLE is `pressed-button' draw a box
 629 that appears like a pressed button.  If STYLE is nil, the default if
 630 the property list doesn't contain a style specification, draw a 2D
 631 box.
 632
 633 `:inverse-video'
 634
 635 VALUE specifies whether characters in FACE should be displayed in
 636 inverse video.  VALUE must be one of t or nil.
 637
 638 `:stipple'
 639
 640 If VALUE is a string, it must be the name of a file of pixmap data.
 641 The directories listed in the `x-bitmap-file-path' variable are
 642 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 643 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 644 is a string containing the raw bits of the bitmap.  VALUE nil means
 645 explicitly don't use a stipple pattern.
 646
 647 For convenience, attributes `:family', `:width', `:height', `:weight',
 648 and `:slant' may also be set in one step from an X font name:
 649
 650 `:font'
 651
 652 Set font-related face attributes from VALUE.  VALUE must be a valid
 653 XLFD font name.  If it is a font name pattern, the first matching font
 654 will be used.
 655
 656 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 657 be used to specify that a bold or italic font should be used.  VALUE
 658 must be t or nil in that case.  A value of `unspecified' is not allowed.
 659
 660 `:inherit'
 661
 662 VALUE is the name of a face from which to inherit attributes, or a list
 663 of face names.  Attributes from inherited faces are merged into the face
 664 like an underlying face would be, with higher priority than underlying faces."
 665   (let ((where (if (null frame) 0 frame)))
 666     (setq args (purecopy args))
 667     ;; If we set the new-frame defaults, this face is modified outside Custom.
 668     (if (memq where '(0 t))
 669         (put face 'face-modified t))
 670     (while args
 671       (internal-set-lisp-face-attribute face (car args)
 672                                         (purecopy (cadr args))
 673                                         where)
 674       (setq args (cdr (cdr args))))))
 675
 676
 677 (defun make-face-bold (face &optional frame noerror)
 678   "Make the font of FACE be bold, if possible.
 679 FRAME nil or not specified means change face on all frames.
 680 Argument NOERROR is ignored and retained for compatibility.
 681 Use `set-face-attribute' for finer control of the font weight."
 682   (interactive (list (read-face-name "Make which face bold")))
 683   (set-face-attribute face frame :weight 'bold))
 684
 685
 686 (defun make-face-unbold (face &optional frame noerror)
 687   "Make the font of FACE be non-bold, if possible.
 688 FRAME nil or not specified means change face on all frames.
 689 Argument NOERROR is ignored and retained for compatibility."
 690   (interactive (list (read-face-name "Make which face non-bold")))
 691   (set-face-attribute face frame :weight 'normal))
 692
 693
 694 (defun make-face-italic (face &optional frame noerror)
 695   "Make the font of FACE be italic, if possible.
 696 FRAME nil or not specified means change face on all frames.
 697 Argument NOERROR is ignored and retained for compatibility.
 698 Use `set-face-attribute' for finer control of the font slant."
 699   (interactive (list (read-face-name "Make which face italic")))
 700   (set-face-attribute face frame :slant 'italic))
 701
 702
 703 (defun make-face-unitalic (face &optional frame noerror)
 704   "Make the font of FACE be non-italic, if possible.
 705 FRAME nil or not specified means change face on all frames.
 706 Argument NOERROR is ignored and retained for compatibility."
 707   (interactive (list (read-face-name "Make which face non-italic")))
 708   (set-face-attribute face frame :slant 'normal))
 709
 710
 711 (defun make-face-bold-italic (face &optional frame noerror)
 712   "Make the font of FACE be bold and italic, if possible.
 713 FRAME nil or not specified means change face on all frames.
 714 Argument NOERROR is ignored and retained for compatibility.
 715 Use `set-face-attribute' for finer control of font weight and slant."
 716   (interactive (list (read-face-name "Make which face bold-italic")))
 717   (set-face-attribute face frame :weight 'bold :slant 'italic))
 718
 719
 720 (defun set-face-font (face font &optional frame)
 721   "Change font-related attributes of FACE to those of FONT (a string).
 722 FRAME nil or not specified means change face on all frames.
 723 This sets the attributes `:family', `:width', `:height', `:weight',
 724 and `:slant'.  When called interactively, prompt for the face and font."
 725   (interactive (read-face-and-attribute :font))
 726   (set-face-attribute face frame :font font))
 727
 728
 729 ;; Implementation note: Emulating gray background colors with a
 730 ;; stipple pattern is now part of the face realization process, and is
 731 ;; done in C depending on the frame on which the face is realized.
 732
 733 (defun set-face-background (face color &optional frame)
 734   "Change the background color of face FACE to COLOR (a string).
 735 FRAME nil or not specified means change face on all frames.
 736 When called interactively, prompt for the face and color."
 737   (interactive (read-face-and-attribute :background))
 738   (set-face-attribute face frame :background (or color 'unspecified)))
 739
 740
 741 (defun set-face-foreground (face color &optional frame)
 742   "Change the foreground color of face FACE to COLOR (a string).
 743 FRAME nil or not specified means change face on all frames.
 744 When called interactively, prompt for the face and color."
 745   (interactive (read-face-and-attribute :foreground))
 746   (set-face-attribute face frame :foreground (or color 'unspecified)))
 747
 748
 749 (defun set-face-stipple (face stipple &optional frame)
 750   "Change the stipple pixmap of face FACE to STIPPLE.
 751 FRAME nil or not specified means change face on all frames.
 752 STIPPLE should be a string, the name of a file of pixmap data.
 753 The directories listed in the `x-bitmap-file-path' variable are searched.
 754
 755 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 756 where WIDTH and HEIGHT are the size in pixels,
 757 and DATA is a string, containing the raw bits of the bitmap."
 758   (interactive (read-face-and-attribute :stipple))
 759   (set-face-attribute face frame :stipple (or stipple 'unspecified)))
 760
 761
 762 (defun set-face-underline (face underline &optional frame)
 763   "Specify whether face FACE is underlined.
 764 UNDERLINE nil means FACE explicitly doesn't underline.
 765 UNDERLINE non-nil means FACE explicitly does underlining
 766 with the same of the foreground color.
 767 If UNDERLINE is a string, underline with the color named UNDERLINE.
 768 FRAME nil or not specified means change face on all frames.
 769 Use `set-face-attribute' to ``unspecify'' underlining."
 770   (interactive
 771    (let ((list (read-face-and-attribute :underline)))
 772      (list (car list) (eq (car (cdr list)) t))))
 773   (set-face-attribute face frame :underline underline))
 774
 775
 776 (defun set-face-underline-p (face underline-p &optional frame)
 777   "Specify whether face FACE is underlined.
 778 UNDERLINE-P nil means FACE explicitly doesn't underline.
 779 UNDERLINE-P non-nil means FACE explicitly does underlining.
 780 FRAME nil or not specified means change face on all frames.
 781 Use `set-face-attribute' to ``unspecify'' underlining."
 782   (interactive
 783    (let ((list (read-face-and-attribute :underline)))
 784      (list (car list) (eq (car (cdr list)) t))))
 785   (set-face-attribute face frame :underline underline-p))
 786
 787
 788 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 789   "Specify whether face FACE is in inverse video.
 790 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 791 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 792 FRAME nil or not specified means change face on all frames.
 793 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 794   (interactive
 795    (let ((list (read-face-and-attribute :inverse-video)))
 796      (list (car list) (eq (car (cdr list)) t))))
 797   (set-face-attribute face frame :inverse-video inverse-video-p))
 798
 799
 800 (defun set-face-bold-p (face bold-p &optional frame)
 801   "Specify whether face FACE is bold.
 802 BOLD-P non-nil means FACE should explicitly display bold.
 803 BOLD-P nil means FACE should explicitly display non-bold.
 804 FRAME nil or not specified means change face on all frames.
 805 Use `set-face-attribute' or `modify-face' for finer control."
 806   (if (null bold-p)
 807       (make-face-unbold face frame)
 808     (make-face-bold face frame)))
 809
 810
 811 (defun set-face-italic-p (face italic-p &optional frame)
 812   "Specify whether face FACE is italic.
 813 ITALIC-P non-nil means FACE should explicitly display italic.
 814 ITALIC-P nil means FACE should explicitly display non-italic.
 815 FRAME nil or not specified means change face on all frames.
 816 Use `set-face-attribute' or `modify-face' for finer control."
 817   (if (null italic-p)
 818       (make-face-unitalic face frame)
 819     (make-face-italic face frame)))
 820
 821
 822 (defalias 'set-face-background-pixmap 'set-face-stipple)
 823
 824
 825 (defun invert-face (face &optional frame)
 826   "Swap the foreground and background colors of FACE.
 827 If FRAME is omitted or nil, it means change face on all frames.
 828 If FACE specifies neither foreground nor background color,
 829 set its foreground and background to the background and foreground
 830 of the default face.  Value is FACE."
 831   (interactive (list (read-face-name "Invert face")))
 832   (let ((fg (face-attribute face :foreground frame))
 833         (bg (face-attribute face :background frame)))
 834     (if (not (and (eq fg 'unspecified) (eq bg 'unspecified)))
 835         (set-face-attribute face frame :foreground bg :background fg)
 836       (set-face-attribute face frame
 837                           :foreground
 838                           (face-attribute 'default :background frame)
 839                           :background
 840                           (face-attribute 'default :foreground frame))))
 841   face)
 842
 843 \f
 844 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 845 ;;; Interactively modifying faces.
 846 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 847
 848 (defun read-face-name (prompt &optional string-describing-default multiple)
 849   "Read a face, defaulting to the face or faces on the char after point.
 850 If it has a `read-face-name' property, that overrides the `face' property.
 851 PROMPT describes what you will do with the face (don't end in a space).
 852 STRING-DESCRIBING-DEFAULT describes what default you will use
 853 if this function returns nil.
 854 If MULTIPLE is non-nil, return a list of faces (possibly only one).
 855 Otherwise, return a single face."
 856   (let ((faceprop (or (get-char-property (point) 'read-face-name)
 857                       (get-char-property (point) 'face)))
 858         faces)
 859     ;; Make a list of the named faces that the `face' property uses.
 860     (if (listp faceprop)
 861         (dolist (f faceprop)
 862           (if (symbolp f)
 863               (push f faces)))
 864       (if (symbolp faceprop)
 865           (setq faces (list faceprop))))
 866     ;; If there are none, try to get a face name from the buffer.
 867     (if (and (null faces)
 868              (memq (intern-soft (thing-at-point 'symbol)) (face-list)))
 869         (setq faces (list (intern-soft (thing-at-point 'symbol)))))
 870
 871     ;; If we only want one, and the default is more than one,
 872     ;; discard the unwanted ones now.
 873     (unless multiple
 874       (if faces
 875           (setq faces (list (car faces)))))
 876     (let* ((input
 877             ;; Read the input.
 878             (completing-read
 879              (if (or faces string-describing-default)
 880                  (format "%s (default %s): " prompt
 881                          (if faces (mapconcat 'symbol-name faces ", ")
 882                            string-describing-default))
 883                (format "%s: " prompt))
 884              obarray 'custom-facep t))
 885            ;; Canonicalize the output.
 886            (output
 887             (if (equal input "")
 888                 faces
 889               (if (stringp input)
 890                   (list (intern input))
 891                 input))))
 892       ;; Return either a list of faces or just one face.
 893       (if multiple
 894           output
 895         (car output)))))
 896
 897
 898 (defun face-valid-attribute-values (attribute &optional frame)
 899   "Return valid values for face attribute ATTRIBUTE.
 900 The optional argument FRAME is used to determine available fonts
 901 and colors.  If it is nil or not specified, the selected frame is
 902 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 903 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 904 an integer value."
 905   (let ((valid
 906          (case attribute
 907            (:family
 908             (if window-system
 909                 (mapcar #'(lambda (x) (cons (car x) (car x)))
 910                         (x-font-family-list))
 911               ;; Only one font on TTYs.
 912               (list (cons "default" "default"))))
 913            ((:width :weight :slant :inverse-video)
 914             (mapcar #'(lambda (x) (cons (symbol-name x) x))
 915                     (internal-lisp-face-attribute-values attribute)))
 916            ((:underline :overline :strike-through :box)
 917             (if window-system
 918                 (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 919                                (internal-lisp-face-attribute-values attribute))
 920                        (mapcar #'(lambda (c) (cons c c))
 921                                (x-defined-colors frame)))
 922               (mapcar #'(lambda (x) (cons (symbol-name x) x))
 923                       (internal-lisp-face-attribute-values attribute))))
 924            ((:foreground :background)
 925             (mapcar #'(lambda (c) (cons c c))
 926                     (defined-colors frame)))
 927            ((:height)
 928             'integerp)
 929            (:stipple
 930             (and (memq window-system '(x w32 mac))
 931                  (mapcar #'list
 932                          (apply #'nconc
 933                                 (mapcar (lambda (dir)
 934                                           (and (file-readable-p dir)
 935                                                (file-directory-p dir)
 936                                                (directory-files dir)))
 937                                         x-bitmap-file-path)))))
 938            (:inherit
 939             (cons '("none" . nil)
 940                   (mapcar #'(lambda (c) (cons (symbol-name c) c))
 941                           (face-list))))
 942            (t
 943             (error "Internal error")))))
 944     (if (and (listp valid) (not (memq attribute '(:inherit))))
 945         (nconc (list (cons "unspecified" 'unspecified)) valid)
 946       valid)))
 947
 948
 949 (defvar face-attribute-name-alist
 950   '((:family . "font family")
 951     (:width . "character set width")
 952     (:height . "height in 1/10 pt")
 953     (:weight . "weight")
 954     (:slant . "slant")
 955     (:underline . "underline")
 956     (:overline . "overline")
 957     (:strike-through . "strike-through")
 958     (:box . "box")
 959     (:inverse-video . "inverse-video display")
 960     (:foreground . "foreground color")
 961     (:background . "background color")
 962     (:stipple . "background stipple")
 963     (:inherit . "inheritance"))
 964   "An alist of descriptive names for face attributes.
 965 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 966 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 967 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 968
 969
 970 (defun face-descriptive-attribute-name (attribute)
 971   "Return a descriptive name for ATTRIBUTE."
 972   (cdr (assq attribute face-attribute-name-alist)))
 973
 974
 975 (defun face-read-string (face default name &optional completion-alist)
 976   "Interactively read a face attribute string value.
 977 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
 978 default string to return if no new value is entered.  NAME is a
 979 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
 980 alist of valid values, if non-nil.
 981
 982 Entering nothing accepts the default string DEFAULT.
 983 Value is the new attribute value."
 984   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
 985   ;; each word in a string separately).
 986   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
 987   (let* ((completion-ignore-case t)
 988          (value (completing-read
 989                  (if default
 990                      (format "%s for face `%s' (default %s): "
 991                              name face default)
 992                    (format "%s for face `%s': " name face))
 993                  completion-alist)))
 994     (if (equal value "") default value)))
 995
 996
 997 (defun face-read-integer (face default name)
 998   "Interactively read an integer face attribute value.
 999 FACE is the face whose attribute is read.  DEFAULT is the default
1000 value to return if no new value is entered.  NAME is a descriptive
1001 name of the attribute for prompting.  Value is the new attribute value."
1002   (let ((new-value
1003          (face-read-string face
1004                            (format "%s" default)
1005                            name
1006                            (list (cons "unspecified" 'unspecified)))))
1007     (cond ((equal new-value "unspecified")
1008            'unspecified)
1009           ((member new-value '("unspecified-fg" "unspecified-bg"))
1010            new-value)
1011           (t
1012            (string-to-int new-value)))))
1013
1014
1015 (defun read-face-attribute (face attribute &optional frame)
1016   "Interactively read a new value for FACE's ATTRIBUTE.
1017 Optional argument FRAME nil or unspecified means read an attribute value
1018 of a global face.  Value is the new attribute value."
1019   (let* ((old-value (face-attribute face attribute frame))
1020          (attribute-name (face-descriptive-attribute-name attribute))
1021          (valid (face-valid-attribute-values attribute frame))
1022          new-value)
1023     ;; Represent complex attribute values as strings by printing them
1024     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
1025     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
1026     ;; SHADOW)'.
1027     (when (and (or (eq attribute :stipple)
1028                    (eq attribute :box))
1029                (or (consp old-value)
1030                    (vectorp old-value)))
1031       (setq old-value (prin1-to-string old-value)))
1032     (cond ((listp valid)
1033            (let ((default
1034                    (or (car (rassoc old-value valid))
1035                        (format "%s" old-value))))
1036              (setq new-value
1037                    (face-read-string face default attribute-name valid))
1038              (if (equal new-value default)
1039                  ;; Nothing changed, so don't bother with all the stuff
1040                  ;; below.  In particular, this avoids a non-tty color
1041                  ;; from being canonicalized for a tty when the user
1042                  ;; just uses the default.
1043                  (setq new-value old-value)
1044                ;; Terminal frames can support colors that don't appear
1045                ;; explicitly in VALID, using color approximation code
1046                ;; in tty-colors.el.
1047                (when (and (memq attribute '(:foreground :background))
1048                           (not (memq window-system '(x w32 mac)))
1049                           (not (member new-value
1050                                        '("unspecified"
1051                                          "unspecified-fg" "unspecified-bg"))))
1052                  (setq new-value (car (tty-color-desc new-value frame))))
1053                (when (assoc new-value valid)
1054                  (setq new-value (cdr (assoc new-value valid)))))))
1055           ((eq valid 'integerp)
1056            (setq new-value (face-read-integer face old-value attribute-name)))
1057           (t (error "Internal error")))
1058     ;; Convert stipple and box value text we read back to a list or
1059     ;; vector if it looks like one.  This makes the assumption that a
1060     ;; pixmap file name won't start with an open-paren.
1061     (when (and (or (eq attribute :stipple)
1062                    (eq attribute :box))
1063                (stringp new-value)
1064                (string-match "^[[(]" new-value))
1065       (setq new-value (read new-value)))
1066     new-value))
1067
1068
1069 (defun read-face-font (face &optional frame)
1070   "Read the name of a font for FACE on FRAME.
1071 If optional argument FRAME Is nil or omitted, use the selected frame."
1072   (let ((completion-ignore-case t))
1073     (completing-read (format "Set font attributes of face `%s' from font: " face)
1074                      (append (fontset-list) (x-list-fonts "*" nil frame)))))
1075
1076
1077 (defun read-all-face-attributes (face &optional frame)
1078   "Interactively read all attributes for FACE.
1079 If optional argument FRAME Is nil or omitted, use the selected frame.
1080 Value is a property list of attribute names and new values."
1081   (let (result)
1082     (dolist (attribute face-attribute-name-alist result)
1083       (setq result (cons (car attribute)
1084                          (cons (read-face-attribute face (car attribute) frame)
1085                                result))))))
1086
1087 (defun modify-face (&optional face foreground background stipple
1088                               bold-p italic-p underline-p inverse-p frame)
1089   "Modify attributes of faces interactively.
1090 If optional argument FRAME is nil or omitted, modify the face used
1091 for newly created frame, i.e. the global face.
1092 For non-interactive use, `set-face-attribute' is preferred.
1093 When called from elisp, if FACE is nil, all arguments but FRAME are ignored
1094 and the face and its settings are obtained by querying the user."
1095   (interactive)
1096   (if face
1097       (set-face-attribute face frame
1098                           :foreground (or foreground 'unspecified)
1099                           :background (or background 'unspecified)
1100                           :stipple stipple
1101                           :bold bold-p
1102                           :italic italic-p
1103                           :underline underline-p
1104                           :inverse-video inverse-p)
1105     (setq face (read-face-name "Modify face"))
1106     (apply #'set-face-attribute face frame
1107            (read-all-face-attributes face frame))))
1108
1109 (defun read-face-and-attribute (attribute &optional frame)
1110   "Read face name and face attribute value.
1111 ATTRIBUTE is the attribute whose new value is read.
1112 FRAME nil or unspecified means read attribute value of global face.
1113 Value is a list (FACE NEW-VALUE) where FACE is the face read
1114 \(a symbol), and NEW-VALUE is value read."
1115   (cond ((eq attribute :font)
1116          (let* ((prompt "Set font-related attributes of face")
1117                 (face (read-face-name prompt))
1118                 (font (read-face-font face frame)))
1119            (list face font)))
1120         (t
1121          (let* ((attribute-name (face-descriptive-attribute-name attribute))
1122                 (prompt (format "Set %s of face" attribute-name))
1123                 (face (read-face-name prompt))
1124                 (new-value (read-face-attribute face attribute frame)))
1125            (list face new-value)))))
1126
1127
1128 \f
1129 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1130 ;;; Listing faces.
1131 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1132
1133 (defvar list-faces-sample-text
1134   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1135   "*Text string to display as the sample text for `list-faces-display'.")
1136
1137
1138 ;; The name list-faces would be more consistent, but let's avoid a
1139 ;; conflict with Lucid, which uses that name differently.
1140
1141 (defvar help-xref-stack)
1142 (defun list-faces-display ()
1143   "List all faces, using the same sample text in each.
1144 The sample text is a string that comes from the variable
1145 `list-faces-sample-text'."
1146   (interactive)
1147   (let ((faces (sort (face-list) #'string-lessp))
1148         (face nil)
1149         (frame (selected-frame))
1150         disp-frame window face-name)
1151     (with-output-to-temp-buffer "*Faces*"
1152       (save-excursion
1153         (set-buffer standard-output)
1154         (setq truncate-lines t)
1155         (insert
1156          (substitute-command-keys
1157           (concat
1158            "Use "
1159            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1160            "\\[help-follow] on a face name to customize it\n"
1161            "or on its sample text for a description of the face.\n\n")))
1162         (setq help-xref-stack nil)
1163         (while faces
1164           (setq face (car faces))
1165           (setq faces (cdr faces))
1166           (setq face-name (symbol-name face))
1167           (insert (format "%25s " face-name))
1168           ;; Hyperlink to a customization buffer for the face.  Using
1169           ;; the help xref mechanism may not be the best way.
1170           (save-excursion
1171             (save-match-data
1172               (search-backward face-name)
1173               (help-xref-button 0 'help-customize-face face)))
1174           (let ((beg (point))
1175                 (line-beg (line-beginning-position)))
1176             (insert list-faces-sample-text)
1177             ;; Hyperlink to a help buffer for the face.
1178             (save-excursion
1179               (save-match-data
1180                 (search-backward list-faces-sample-text)
1181                 (help-xref-button 0 'help-face face)))
1182             (insert "\n")
1183             (put-text-property beg (1- (point)) 'face face)
1184             ;; Make all face commands default to the proper face
1185             ;; anywhere in the line.
1186             (put-text-property line-beg (1- (point)) 'read-face-name face)
1187             ;; If the sample text has multiple lines, line up all of them.
1188             (goto-char beg)
1189             (forward-line 1)
1190             (while (not (eobp))
1191               (insert "                          ")
1192               (forward-line 1))))
1193         (goto-char (point-min)))
1194       (print-help-return-message))
1195     ;; If the *Faces* buffer appears in a different frame,
1196     ;; copy all the face definitions from FRAME,
1197     ;; so that the display will reflect the frame that was selected.
1198     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1199     (setq disp-frame (if window (window-frame window)
1200                        (car (frame-list))))
1201     (or (eq frame disp-frame)
1202         (let ((faces (face-list)))
1203           (while faces
1204             (copy-face (car faces) (car faces) frame disp-frame)
1205             (setq faces (cdr faces)))))))
1206
1207 (defun describe-face (face &optional frame)
1208   "Display the properties of face FACE on FRAME.
1209 Interactively, FACE defaults to the faces of the character after point
1210 and FRAME defaults to the selected frame.
1211
1212 If the optional argument FRAME is given, report on face FACE in that frame.
1213 If FRAME is t, report on the defaults for face FACE (for new frames).
1214 If FRAME is omitted or nil, use the selected frame."
1215   (interactive (list (read-face-name "Describe face" "= `default' face" t)))
1216   (let* ((attrs '((:family . "Family")
1217                   (:width . "Width")
1218                   (:height . "Height")
1219                   (:weight . "Weight")
1220                   (:slant . "Slant")
1221                   (:foreground . "Foreground")
1222                   (:background . "Background")
1223                   (:underline . "Underline")
1224                   (:overline . "Overline")
1225                   (:strike-through . "Strike-through")
1226                   (:box . "Box")
1227                   (:inverse-video . "Inverse")
1228                   (:stipple . "Stipple")
1229                   (:font . "Font")
1230                   (:fontset . "Fontset")
1231                   (:inherit . "Inherit")))
1232         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1233                                         attrs))))
1234     (help-setup-xref (list #'describe-face face) (interactive-p))
1235     (unless face
1236       (setq face 'default))
1237     (if (not (listp face))
1238         (setq face (list face)))
1239     (with-output-to-temp-buffer (help-buffer)
1240       (save-excursion
1241         (set-buffer standard-output)
1242         (dolist (f face)
1243           (insert "Face: " (symbol-name f))
1244           (if (not (facep f))
1245               (insert "   undefined face.\n")
1246             (let ((customize-label "customize this face"))
1247               (princ (concat " (" customize-label ")\n"))
1248               (insert "Documentation: "
1249                       (or (face-documentation f)
1250                           "Not documented as a face.")
1251                       "\n\n")
1252               (with-current-buffer standard-output
1253                 (save-excursion
1254                   (re-search-backward
1255                    (concat "\\(" customize-label "\\)") nil t)
1256                   (help-xref-button 1 'help-customize-face f)))
1257               (dolist (a attrs)
1258                 (let ((attr (face-attribute f (car a) frame)))
1259                   (insert (make-string (- max-width (length (cdr a))) ?\ )
1260                           (cdr a) ": " (format "%s" attr) "\n")))))
1261           (terpri)))
1262       (print-help-return-message))))
1263
1264 \f
1265 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1266 ;;; Face specifications (defface).
1267 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1268
1269 ;; Parameter FRAME Is kept for call compatibility to with previous
1270 ;; face implementation.
1271
1272 (defun face-attr-construct (face &optional frame)
1273   "Return a defface-style attribute list for FACE on FRAME.
1274 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1275 face attributes of FACE where ATTRIBUTE is the attribute name and
1276 VALUE is the specified value of that attribute."
1277   (let (result)
1278     (dolist (entry face-attribute-name-alist result)
1279       (let* ((attribute (car entry))
1280              (value (face-attribute face attribute)))
1281         (unless (eq value 'unspecified)
1282           (setq result (nconc (list attribute value) result)))))))
1283
1284
1285 (defun face-spec-set-match-display (display frame)
1286   "Non-nil if DISPLAY matches FRAME.
1287 DISPLAY is part of a spec such as can be used in `defface'.
1288 If FRAME is nil, the current FRAME is used."
1289   (let* ((conjuncts display)
1290          conjunct req options
1291          ;; t means we have succeeded against all the conjuncts in
1292          ;; DISPLAY that have been tested so far.
1293          (match t))
1294     (if (eq conjuncts t)
1295         (setq conjuncts nil))
1296     (while (and conjuncts match)
1297       (setq conjunct (car conjuncts)
1298             conjuncts (cdr conjuncts)
1299             req (car conjunct)
1300             options (cdr conjunct)
1301             match (cond ((eq req 'type)
1302                          (or (memq window-system options)
1303                              ;; FIXME: This should be revisited to use
1304                              ;; display-graphic-p, provided that the
1305                              ;; color selection depends on the number
1306                              ;; of supported colors, and all defface's
1307                              ;; are changed to look at number of colors
1308                              ;; instead of (type graphic) etc.
1309                              (and (null window-system)
1310                                   (memq 'tty options))
1311                              (and (memq 'motif options)
1312                                   (featurep 'motif))
1313                              (and (memq 'lucid options)
1314                                   (featurep 'x-toolkit)
1315                                   (not (featurep 'motif)))
1316                              (and (memq 'x-toolkit options)
1317                                   (featurep 'x-toolkit))))
1318                         ((eq req 'min-colors)
1319                          (>= (display-color-cells frame) (car options)))
1320                         ((eq req 'class)
1321                          (memq (frame-parameter frame 'display-type) options))
1322                         ((eq req 'background)
1323                          (memq (frame-parameter frame 'background-mode)
1324                                options))
1325                         ((eq req 'supports)
1326                          (display-supports-face-attributes-p options frame))
1327                         (t (error "Unknown req `%S' with options `%S'"
1328                                   req options)))))
1329     match))
1330
1331
1332 (defun face-spec-choose (spec &optional frame)
1333   "Choose the proper attributes for FRAME, out of SPEC.
1334 If SPEC is nil, return nil."
1335   (unless frame
1336     (setq frame (selected-frame)))
1337   (let ((tail spec)
1338         result all)
1339     (while tail
1340       (let* ((entry (pop tail))
1341              (display (car entry))
1342              (attrs (cdr entry)))
1343         (when (face-spec-set-match-display display frame)
1344           (setq result (if (null (cdr attrs)) ;; was (listp (car attrs))
1345                            ;; Old-style entry, the attribute list is the
1346                            ;; first element.
1347                            (car attrs)
1348                          attrs))
1349           (if (eq display t)
1350               (setq all result result nil)
1351             (setq tail nil)))))
1352     (if all (append result all) result)))
1353
1354
1355 (defun face-spec-reset-face (face &optional frame)
1356   "Reset all attributes of FACE on FRAME to unspecified."
1357   (let ((attrs face-attribute-name-alist))
1358     (while attrs
1359       (let ((attr-and-name (car attrs)))
1360         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1361       (setq attrs (cdr attrs)))))
1362
1363
1364 (defun face-spec-set (face spec &optional frame)
1365   "Set FACE's attributes according to the first matching entry in SPEC.
1366 FRAME is the frame whose frame-local face is set.  FRAME nil means
1367 do it on all frames.  See `defface' for information about SPEC.
1368 If SPEC is nil, do nothing."
1369   (let ((attrs (face-spec-choose spec frame)))
1370     (when attrs
1371       (face-spec-reset-face face frame))
1372     (while attrs
1373       (let ((attribute (car attrs))
1374             (value (car (cdr attrs))))
1375         ;; Support some old-style attribute names and values.
1376         (case attribute
1377           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1378           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1379           ((:foreground :background)
1380            ;; Compatibility with 20.x.  Some bogus face specs seem to
1381            ;; exist containing things like `:foreground nil'.
1382            (if (null value) (setq value 'unspecified)))
1383           (t (unless (assq attribute face-x-resources)
1384                (setq attribute nil))))
1385         (when attribute
1386           (set-face-attribute face frame attribute value)))
1387       (setq attrs (cdr (cdr attrs)))))
1388   ;; When we reset the face based on its spec, then it is unmodified
1389   ;; as far as Custom is concerned.
1390   (if (null frame)
1391       (put face 'face-modified nil)))
1392
1393
1394 (defun face-attr-match-p (face attrs &optional frame)
1395   "Return t if attributes of FACE match values in plist ATTRS.
1396 Optional parameter FRAME is the frame whose definition of FACE
1397 is used.  If nil or omitted, use the selected frame."
1398   (unless frame
1399     (setq frame (selected-frame)))
1400   (let ((list face-attribute-name-alist)
1401         (match t))
1402     (while (and match (not (null list)))
1403       (let* ((attr (car (car list)))
1404              (specified-value
1405               (if (plist-member attrs attr)
1406                   (plist-get attrs attr)
1407                 'unspecified))
1408              (value-now (face-attribute face attr frame)))
1409         (setq match (equal specified-value value-now))
1410         (setq list (cdr list))))
1411     match))
1412
1413 (defun face-spec-match-p (face spec &optional frame)
1414   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1415   (face-attr-match-p face (face-spec-choose spec frame) frame))
1416
1417 (defsubst face-default-spec (face)
1418   "Return the default face-spec for FACE, ignoring any user customization.
1419 If there is no default for FACE, return nil."
1420   (get face 'face-defface-spec))
1421
1422 (defsubst face-user-default-spec (face)
1423   "Return the user's customized face-spec for FACE, or the default if none.
1424 If there is neither a user setting nor a default for FACE, return nil."
1425   (or (get face 'saved-face)
1426       (face-default-spec face)))
1427
1428 \f
1429 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1430 ;;; Frame-type independent color support.
1431 ;;; We keep the old x-* names as aliases for back-compatibility.
1432 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1433
1434 (defun defined-colors (&optional frame)
1435   "Return a list of colors supported for a particular frame.
1436 The argument FRAME specifies which frame to try.
1437 The value may be different for frames on different display types.
1438 If FRAME doesn't support colors, the value is nil."
1439   (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1440       (xw-defined-colors frame)
1441     (mapcar 'car (tty-color-alist frame))))
1442 (defalias 'x-defined-colors 'defined-colors)
1443
1444 (defun color-defined-p (color &optional frame)
1445   "Return non-nil if color COLOR is supported on frame FRAME.
1446 If FRAME is omitted or nil, use the selected frame.
1447 If COLOR is the symbol `unspecified' or one of the strings
1448 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1449   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1450       nil
1451     (if (member (framep (or frame (selected-frame))) '(x w32 mac))
1452         (xw-color-defined-p color frame)
1453       (numberp (tty-color-translate color frame)))))
1454 (defalias 'x-color-defined-p 'color-defined-p)
1455
1456 (defun color-values (color &optional frame)
1457   "Return a description of the color named COLOR on frame FRAME.
1458 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1459 These values appear to range from 0 65535; white is \(65535 65535 65535\).
1460 If FRAME is omitted or nil, use the selected frame.
1461 If FRAME cannot display COLOR, the value is nil.
1462 If COLOR is the symbol `unspecified' or one of the strings
1463 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1464   (if (member color '(unspecified "unspecified-fg" "unspecified-bg"))
1465       nil
1466     (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1467         (xw-color-values color frame)
1468       (tty-color-values color frame))))
1469 (defalias 'x-color-values 'color-values)
1470
1471 (defun display-color-p (&optional display)
1472   "Return t if DISPLAY supports color.
1473 The optional argument DISPLAY specifies which display to ask about.
1474 DISPLAY should be either a frame or a display name (a string).
1475 If omitted or nil, that stands for the selected frame's display."
1476   (if (memq (framep-on-display display) '(x w32 mac))
1477       (xw-display-color-p display)
1478     (tty-display-color-p display)))
1479 (defalias 'x-display-color-p 'display-color-p)
1480
1481 (defun display-grayscale-p (&optional display)
1482   "Return non-nil if frames on DISPLAY can display shades of gray."
1483   (let ((frame-type (framep-on-display display)))
1484     (cond
1485      ((memq frame-type '(x w32 mac))
1486       (x-display-grayscale-p display))
1487      (t
1488       (> (tty-color-gray-shades display) 2)))))
1489
1490 (defun display-supports-face-attributes-p (attributes &optional display)
1491   "Return non-nil if all the face attributes in ATTRIBUTES are supported.
1492 The optional argument DISPLAY can be a display name, a frame, or
1493 nil (meaning the selected frame's display)
1494
1495 The definition of `supported' is somewhat heuristic, but basically means
1496 that a face containing all the attributes in ATTRIBUTES, when merged
1497 with the default face for display, can be represented in a way that's
1498
1499  (1) different in appearance than the default face, and
1500  (2) `close in spirit' to what the attributes specify, if not exact.
1501
1502 Point (2) implies that a `:weight black' attribute will be satisfied by
1503 any display that can display bold, and a `:foreground \"yellow\"' as long
1504 as it can display a yellowish color, but `:slant italic' will _not_ be
1505 satisfied by the tty display code's automatic substitution of a `dim'
1506 face for italic."
1507   (let ((frame
1508          (if (framep display)
1509              display
1510            (car (frames-on-display-list display)))))
1511     ;; For now, we assume that non-tty displays can support everything.
1512     ;; Later, we should add the ability to query about specific fonts,
1513     ;; colors, etc.
1514     (or (memq (framep frame) '(x w32 mac))
1515         (tty-supports-face-attributes-p attributes frame))))
1516
1517 \f
1518 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1519 ;;; Background mode.
1520 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1521
1522 (defcustom frame-background-mode nil
1523   "*The brightness of the background.
1524 Set this to the symbol `dark' if your background color is dark, `light' if
1525 your background is light, or nil (default) if you want Emacs to
1526 examine the brightness for you.  Don't set this variable with `setq';
1527 this won't have the expected effect."
1528   :group 'faces
1529   :set #'(lambda (var value)
1530            (set-default var value)
1531            (mapc 'frame-set-background-mode (frame-list)))
1532   :initialize 'custom-initialize-changed
1533   :type '(choice (choice-item dark)
1534                  (choice-item light)
1535                  (choice-item :tag "default" nil)))
1536
1537
1538 (defun frame-set-background-mode (frame)
1539   "Set up display-dependent faces on FRAME.
1540 Display-dependent faces are those which have different definitions
1541 according to the `background-mode' and `display-type' frame parameters."
1542   (let* ((bg-resource
1543           (and window-system
1544                (x-get-resource "backgroundMode" "BackgroundMode")))
1545          (bg-color (frame-parameter frame 'background-color))
1546          (bg-mode
1547           (cond (frame-background-mode)
1548                 (bg-resource
1549                  (intern (downcase bg-resource)))
1550                 ((and (null window-system) (null bg-color))
1551                  ;; No way to determine this automatically (?).
1552                  'dark)
1553                 ;; Unspecified frame background color can only happen
1554                 ;; on tty's.
1555                 ((member bg-color '(unspecified "unspecified-bg"))
1556                  'dark)
1557                 ((equal bg-color "unspecified-fg") ; inverted colors
1558                  'light)
1559                 ((>= (apply '+ (x-color-values bg-color frame))
1560                     ;; Just looking at the screen, colors whose
1561                     ;; values add up to .6 of the white total
1562                     ;; still look dark to me.
1563                     (* (apply '+ (x-color-values "white" frame)) .6))
1564                  'light)
1565                 (t 'dark)))
1566          (display-type
1567           (cond ((null window-system)
1568                  (if (tty-display-color-p frame) 'color 'mono))
1569                 ((x-display-color-p frame)
1570                  'color)
1571                 ((x-display-grayscale-p frame)
1572                  'grayscale)
1573                 (t 'mono)))
1574          (old-bg-mode
1575           (frame-parameter frame 'background-mode))
1576          (old-display-type
1577           (frame-parameter frame 'display-type)))
1578
1579     (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
1580       (let ((locally-modified-faces nil))
1581         ;; Before modifying the frame parameters, we collect a list of
1582         ;; faces that don't match what their face-spec says they should
1583         ;; look like; we then avoid changing these faces below.  A
1584         ;; negative list is used on the assumption that most faces will
1585         ;; be unmodified, so we can avoid consing in the common case.
1586         (dolist (face (face-list))
1587           (when (not (face-spec-match-p face
1588                                         (face-user-default-spec face)
1589                                         (selected-frame)))
1590             (push face locally-modified-faces)))
1591         ;; Now change to the new frame parameters
1592         (modify-frame-parameters frame
1593                                  (list (cons 'background-mode bg-mode)
1594                                        (cons 'display-type display-type)))
1595         ;; For all named faces, choose face specs matching the new frame
1596         ;; parameters, unless they have been locally modified.
1597         (dolist (face (face-list))
1598           (unless (memq face locally-modified-faces)
1599             (face-spec-set face (face-user-default-spec face) frame)))))))
1600
1601 \f
1602 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1603 ;;; Frame creation.
1604 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1605
1606 (defun x-handle-named-frame-geometry (parameters)
1607   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1608 Value is the new parameter list."
1609   (let* ((name (or (cdr (assq 'name parameters))
1610                    (cdr (assq 'name default-frame-alist))))
1611          (x-resource-name name)
1612          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1613     (when res-geometry
1614       (let ((parsed (x-parse-geometry res-geometry)))
1615         ;; If the resource specifies a position, call the position
1616         ;; and size "user-specified".
1617         (when (or (assq 'top parsed)
1618                   (assq 'left parsed))
1619           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1620         ;; Put the geometry parameters at the end.  Copy
1621         ;; default-frame-alist so that they go after it.
1622         (setq parameters (append parameters default-frame-alist parsed))))
1623     parameters))
1624
1625
1626 (defun x-handle-reverse-video (frame parameters)
1627   "Handle the reverse-video frame parameter and X resource.
1628 `x-create-frame' does not handle this one."
1629   (when (cdr (or (assq 'reverse parameters)
1630                  (assq 'reverse default-frame-alist)
1631                  (let ((resource (x-get-resource "reverseVideo"
1632                                                  "ReverseVideo")))
1633                    (if resource
1634                        (cons nil (member (downcase resource)
1635                                          '("on" "true")))))))
1636       (let* ((params (frame-parameters frame))
1637              (bg (cdr (assq 'foreground-color params)))
1638              (fg (cdr (assq 'background-color params))))
1639         (modify-frame-parameters frame
1640                                  (list (cons 'foreground-color fg)
1641                                        (cons 'background-color bg)))
1642         (if (equal bg (cdr (assq 'border-color params)))
1643             (modify-frame-parameters frame
1644                                      (list (cons 'border-color fg))))
1645         (if (equal bg (cdr (assq 'mouse-color params)))
1646             (modify-frame-parameters frame
1647                                      (list (cons 'mouse-color fg))))
1648         (if (equal bg (cdr (assq 'cursor-color params)))
1649             (modify-frame-parameters frame
1650                                      (list (cons 'cursor-color fg)))))))
1651
1652
1653 (defun x-create-frame-with-faces (&optional parameters)
1654   "Create a frame from optional frame parameters PARAMETERS.
1655 Parameters not specified by PARAMETERS are taken from
1656 `default-frame-alist'.  If PARAMETERS specify a frame name,
1657 handle X geometry resources for that name.  If either PARAMETERS
1658 or `default-frame-alist' contains a `reverse' parameter, or
1659 the X resource ``reverseVideo'' is present, handle that.
1660 Value is the new frame created."
1661   (setq parameters (x-handle-named-frame-geometry parameters))
1662   (let ((visibility-spec (assq 'visibility parameters))
1663         (frame-list (frame-list))
1664         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1665         success)
1666     (unwind-protect
1667         (progn
1668           (x-handle-reverse-video frame parameters)
1669           (frame-set-background-mode frame)
1670           (face-set-after-frame-default frame)
1671           (if (or (null frame-list) (null visibility-spec))
1672               (make-frame-visible frame)
1673             (modify-frame-parameters frame (list visibility-spec)))
1674           (setq success t))
1675       (unless success
1676         (delete-frame frame)))
1677     frame))
1678
1679
1680 (defun face-set-after-frame-default (frame)
1681   "Set frame-local faces of FRAME from face specs and resources.
1682 Initialize colors of certain faces from frame parameters."
1683   (if (face-attribute 'default :font t)
1684       (set-face-attribute 'default frame :font
1685                           (face-attribute 'default :font t))
1686     (set-face-attribute 'default frame :family
1687                         (face-attribute 'default :family t))
1688     (set-face-attribute 'default frame :height
1689                         (face-attribute 'default :height t))
1690     (set-face-attribute 'default frame :slant
1691                         (face-attribute 'default :slant t))
1692     (set-face-attribute 'default frame :weight
1693                         (face-attribute 'default :weight t))
1694     (set-face-attribute 'default frame :width
1695                         (face-attribute 'default :width t)))
1696   (dolist (face (face-list))
1697     ;; Don't let frame creation fail because of an invalid face spec.
1698     (condition-case ()
1699         (when (not (equal face 'default))
1700           (face-spec-set face (face-user-default-spec face) frame)
1701           (internal-merge-in-global-face face frame)
1702           (when (and (memq window-system '(x w32 mac))
1703                      (or (not (boundp 'inhibit-default-face-x-resources))
1704                          (not (eq face 'default))))
1705             (make-face-x-resource-internal face frame)))
1706       (error nil)))
1707   ;; Initialize attributes from frame parameters.
1708   (let ((params '((foreground-color default :foreground)
1709                   (background-color default :background)
1710                   (border-color border :background)
1711                   (cursor-color cursor :background)
1712                   (scroll-bar-foreground scroll-bar :foreground)
1713                   (scroll-bar-background scroll-bar :background)
1714                   (mouse-color mouse :background))))
1715     (dolist (param params)
1716       (let ((frame-param (frame-parameter frame (nth 0 param)))
1717             (face (nth 1 param))
1718             (attr (nth 2 param)))
1719         (when (and frame-param
1720                    ;; Don't override face attributes explicitly
1721                    ;; specified for new frames.
1722                    (eq (face-attribute face attr t) 'unspecified))
1723           (set-face-attribute face frame attr frame-param))))))
1724
1725
1726 (defun tty-handle-reverse-video (frame parameters)
1727   "Handle the reverse-video frame parameter for terminal frames."
1728   (when (cdr (or (assq 'reverse parameters)
1729                  (assq 'reverse default-frame-alist)))
1730     (let* ((params (frame-parameters frame))
1731            (bg (cdr (assq 'foreground-color params)))
1732            (fg (cdr (assq 'background-color params))))
1733       (modify-frame-parameters frame
1734                                (list (cons 'foreground-color fg)
1735                                      (cons 'background-color bg)))
1736       (if (equal bg (cdr (assq 'mouse-color params)))
1737           (modify-frame-parameters frame
1738                                    (list (cons 'mouse-color fg))))
1739       (if (equal bg (cdr (assq 'cursor-color params)))
1740           (modify-frame-parameters frame
1741                                    (list (cons 'cursor-color fg)))))))
1742
1743
1744 (defun tty-create-frame-with-faces (&optional parameters)
1745   "Create a frame from optional frame parameters PARAMETERS.
1746 Parameters not specified by PARAMETERS are taken from
1747 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1748 contains a `reverse' parameter, handle that.  Value is the new frame
1749 created."
1750   (let ((frame (make-terminal-frame parameters))
1751         success)
1752     (unwind-protect
1753         (progn
1754           (tty-handle-reverse-video frame (frame-parameters frame))
1755           (frame-set-background-mode frame)
1756           (face-set-after-frame-default frame)
1757           (setq success t))
1758       (unless success
1759         (delete-frame frame)))
1760     frame))
1761
1762
1763 ;; Called from C function init_display to initialize faces of the
1764 ;; dumped terminal frame on startup.
1765
1766 (defun tty-set-up-initial-frame-faces ()
1767   (let ((frame (selected-frame)))
1768     (frame-set-background-mode frame)
1769     (face-set-after-frame-default frame)))
1770
1771
1772
1773 \f
1774 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1775 ;;; Compatiblity with 20.2
1776 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1777
1778 ;; Update a frame's faces when we change its default font.
1779
1780 (defalias 'frame-update-faces 'ignore)
1781 (make-obsolete 'frame-update-faces "no longer necessary." "21.1")
1782
1783 ;; Update the colors of FACE, after FRAME's own colors have been
1784 ;; changed.
1785
1786 (defalias 'frame-update-face-colors 'frame-set-background-mode)
1787 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode "21.1")
1788
1789 \f
1790 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1791 ;;; Standard faces.
1792 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1793
1794 (defgroup basic-faces nil
1795   "The standard faces of Emacs."
1796   :group 'faces)
1797
1798
1799 (defface default
1800   '((t nil))
1801   "Basic default face."
1802   :group 'basic-faces)
1803
1804
1805 (defface mode-line
1806   '((((type x w32 mac) (class color))
1807      :box (:line-width -1 :style released-button)
1808      :background "grey75" :foreground "black")
1809     (t
1810      :inverse-video t))
1811   "Basic mode line face for selected window."
1812   :version "21.1"
1813   :group 'modeline
1814   :group 'basic-faces)
1815
1816 (defface mode-line-inactive
1817   '((t
1818      :inherit mode-line)
1819     (((type x w32 mac) (background light) (class color))
1820      :weight light
1821      :box (:line-width -1 :color "grey75" :style nil)
1822      :foreground "grey20" :background "grey90")
1823     (((type x w32 mac) (background dark) (class color))
1824      :weight light
1825      :box (:line-width -1 :color "grey40" :style nil)
1826      :foreground "grey80" :background "grey30"))
1827   "Basic mode line face for non-selected windows."
1828   :version "21.4"
1829   :group 'modeline
1830   :group 'basic-faces)
1831
1832 ;; Make `modeline' an alias for `mode-line', for compatibility.
1833 (put 'modeline 'face-alias 'mode-line)
1834 (put 'modeline-inactive 'face-alias 'mode-line-inactive)
1835
1836 (defface header-line
1837   '((t
1838      :inherit mode-line)
1839     (((type tty))
1840      ;; This used to be `:inverse-video t', but that doesn't look very
1841      ;; good when combined with inverse-video mode-lines and multiple
1842      ;; windows.  Underlining looks better, and is more consistent with
1843      ;; the window-system face variants, which deemphasize the
1844      ;; header-line in relation to the mode-line face.  If a terminal
1845      ;; can't underline, then the header-line will end up without any
1846      ;; highlighting; this may be too confusing in general, although it
1847      ;; happens to look good with the only current use of header-lines,
1848      ;; the info browser. XXX
1849      :inverse-video nil        ;Override the value inherited from mode-line.
1850      :underline t)
1851     (((class color grayscale) (background light))
1852      :background "grey90" :foreground "grey20"
1853      :box nil)
1854     (((class color grayscale) (background dark))
1855      :background "grey20" :foreground "grey90"
1856      :box nil)
1857     (((class mono) (background light))
1858      :background "white" :foreground "black"
1859      :inverse-video nil
1860      :box nil
1861      :underline t)
1862     (((class mono) (background dark))
1863      :background "black" :foreground "white"
1864      :inverse-video nil
1865      :box nil
1866      :underline t))
1867   "Basic header-line face."
1868   :version "21.1"
1869   :group 'basic-faces)
1870
1871
1872 (defface tool-bar
1873   '((t
1874      :box (:line-width 1 :style released-button)
1875      :foreground "black")
1876     (((type x w32 mac) (class color))
1877      :background "grey75")
1878     (((type x) (class mono))
1879      :background "grey"))
1880   "Basic tool-bar face."
1881   :version "21.1"
1882   :group 'basic-faces)
1883
1884
1885 (defface minibuffer-prompt '((((background dark)) :foreground "cyan")
1886                              (((type pc)) :foreground "magenta")
1887                              (t :foreground "dark blue"))
1888   "Face for minibuffer prompts."
1889   :version "21.4"
1890   :group 'basic-faces)
1891
1892 (setq minibuffer-prompt-properties
1893       (append minibuffer-prompt-properties (list 'face 'minibuffer-prompt)))
1894
1895 (defface region
1896   '((((class color) (min-colors 88) (background dark))
1897      :background "blue3")
1898     (((class color) (min-colors 88) (background light))
1899      :background "lightgoldenrod2")
1900     (((class color) (min-colors 16) (background dark))
1901      :background "blue3")
1902     (((class color) (min-colors 16) (background light))
1903      :background "lightgoldenrod2")
1904     (((class color) (min-colors 8))
1905      :background "blue" :foreground "white")
1906     (((type tty) (class mono))
1907      :inverse-video t)
1908     (t :background "gray"))
1909   "Basic face for highlighting the region."
1910   :version "21.1"
1911   :group 'basic-faces)
1912
1913
1914 (defface fringe
1915   '((((class color) (background light))
1916      :background "grey95")
1917     (((class color) (background dark))
1918      :background "grey10")
1919     (t
1920      :background "gray"))
1921   "Basic face for the fringes to the left and right of windows under X."
1922   :version "21.1"
1923   :group 'frames
1924   :group 'basic-faces)
1925
1926
1927 (defface scroll-bar '()
1928   "Basic face for the scroll bar colors under X."
1929   :version "21.1"
1930   :group 'frames
1931   :group 'basic-faces)
1932
1933
1934 (defface menu
1935   '((((type tty))
1936      :inverse-video t)
1937     (((type x-toolkit))
1938      )
1939     (t
1940      :inverse-video t))
1941   "Basic face for the font and colors of the menu bar and popup menus."
1942   :version "21.1"
1943   :group 'menu
1944   :group 'basic-faces)
1945
1946
1947 (defface border '()
1948   "Basic face for the frame border under X."
1949   :version "21.1"
1950   :group 'frames
1951   :group 'basic-faces)
1952
1953
1954 (defface cursor '()
1955   "Basic face for the cursor color under X."
1956   :version "21.1"
1957   :group 'cursor
1958   :group 'basic-faces)
1959
1960
1961 (defface mouse '()
1962   "Basic face for the mouse color under X."
1963   :version "21.1"
1964   :group 'mouse
1965   :group 'basic-faces)
1966
1967
1968 (defface bold '((t :weight bold))
1969   "Basic bold face."
1970   :group 'basic-faces)
1971
1972
1973 (defface italic
1974   '((((supports :slant italic))
1975      :slant italic)
1976     (((supports :underline t))
1977      :underline t)
1978     (t
1979      ;; default to italic, even it doesn't appear to be supported,
1980      ;; because in some cases the display engine will do it's own
1981      ;; workaround (to `dim' on ttys)
1982      :slant italic))
1983   "Basic italic font."
1984   :group 'basic-faces)
1985
1986
1987 (defface bold-italic '((t :weight bold :slant italic))
1988   "Basic bold-italic face."
1989   :group 'basic-faces)
1990
1991
1992 (defface underline '((t :underline t))
1993   "Basic underlined face."
1994   :group 'basic-faces)
1995
1996
1997 (defface highlight
1998   '((((class color) (min-colors 88) (background light))
1999      :background "darkseagreen2")
2000     (((class color) (min-colors 88) (background dark))
2001      :background "darkolivegreen")
2002     (((class color) (min-colors 16) (background light))
2003      :background "darkseagreen2")
2004     (((class color) (min-colors 16) (background dark))
2005      :background "darkolivegreen")
2006     (((class color) (min-colors 8))
2007      :background "green" :foreground "black")
2008     (t :inverse-video t))
2009   "Basic face for highlighting."
2010   :group 'basic-faces)
2011
2012
2013 (defface secondary-selection
2014   '((((class color) (min-colors 88) (background light))
2015      :background "yellow")
2016     (((class color) (min-colors 88) (background dark))
2017      :background "SkyBlue4")
2018     (((class color) (min-colors 16) (background light))
2019      :background "yellow")
2020     (((class color) (min-colors 16) (background dark))
2021      :background "SkyBlue4")
2022     (((class color) (min-colors 8))
2023      :background "cyan" :foreground "black")
2024     (t :inverse-video t))
2025   "Basic face for displaying the secondary selection."
2026   :group 'basic-faces)
2027
2028
2029 (defface fixed-pitch '((t :family "courier"))
2030   "The basic fixed-pitch face."
2031   :group 'basic-faces)
2032
2033
2034 (defface variable-pitch '((t :family "helv"))
2035   "The basic variable-pitch face."
2036   :group 'basic-faces)
2037
2038
2039 (defface trailing-whitespace
2040   '((((class color) (background light))
2041      :background "red")
2042     (((class color) (background dark))
2043      :background "red")
2044     (t :inverse-video t))
2045   "Basic face for highlighting trailing whitespace."
2046   :version "21.1"
2047   :group 'font-lock                     ; like `show-trailing-whitespace'
2048   :group 'basic-faces)
2049
2050
2051 \f
2052 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2053 ;;; Manipulating font names.
2054 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2055
2056 ;; This is here for compatibilty with Emacs 20.2.  For example,
2057 ;; international/fontset.el uses x-resolve-font-name.  The following
2058 ;; functions are not used in the face implementation itself.
2059
2060 (defvar x-font-regexp nil)
2061 (defvar x-font-regexp-head nil)
2062 (defvar x-font-regexp-weight nil)
2063 (defvar x-font-regexp-slant nil)
2064
2065 (defconst x-font-regexp-weight-subnum 1)
2066 (defconst x-font-regexp-slant-subnum 2)
2067 (defconst x-font-regexp-swidth-subnum 3)
2068 (defconst x-font-regexp-adstyle-subnum 4)
2069
2070 ;;; Regexps matching font names in "Host Portable Character Representation."
2071 ;;;
2072 (let ((-                "[-?]")
2073       (foundry          "[^-]+")
2074       (family           "[^-]+")
2075       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
2076 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
2077       (weight\?         "\\([^-]*\\)")                                  ; 1
2078       (slant            "\\([ior]\\)")                                  ; 2
2079 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
2080       (slant\?          "\\([^-]?\\)")                                  ; 2
2081 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
2082       (swidth           "\\([^-]*\\)")                                  ; 3
2083 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
2084       (adstyle          "\\([^-]*\\)")                                  ; 4
2085       (pixelsize        "[0-9]+")
2086       (pointsize        "[0-9][0-9]+")
2087       (resx             "[0-9][0-9]+")
2088       (resy             "[0-9][0-9]+")
2089       (spacing          "[cmp?*]")
2090       (avgwidth         "[0-9]+")
2091       (registry         "[^-]+")
2092       (encoding         "[^-]+")
2093       )
2094   (setq x-font-regexp
2095         (concat "\\`\\*?[-?*]"
2096                 foundry - family - weight\? - slant\? - swidth - adstyle -
2097                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
2098                 registry - encoding "\\*?\\'"
2099                 ))
2100   (setq x-font-regexp-head
2101         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
2102                 "\\([-*?]\\|\\'\\)"))
2103   (setq x-font-regexp-slant (concat - slant -))
2104   (setq x-font-regexp-weight (concat - weight -))
2105   nil)
2106
2107
2108 (defun x-resolve-font-name (pattern &optional face frame)
2109   "Return a font name matching PATTERN.
2110 All wildcards in PATTERN are instantiated.
2111 If PATTERN is nil, return the name of the frame's base font, which never
2112 contains wildcards.
2113 Given optional arguments FACE and FRAME, return a font which is
2114 also the same size as FACE on FRAME, or fail."
2115   (or (symbolp face)
2116       (setq face (face-name face)))
2117   (and (eq frame t)
2118        (setq frame nil))
2119   (if pattern
2120       ;; Note that x-list-fonts has code to handle a face with nil as its font.
2121       (let ((fonts (x-list-fonts pattern face frame 1)))
2122         (or fonts
2123             (if face
2124                 (if (string-match "\\*" pattern)
2125                     (if (null (face-font face))
2126                         (error "No matching fonts are the same height as the frame default font")
2127                       (error "No matching fonts are the same height as face `%s'" face))
2128                   (if (null (face-font face))
2129                       (error "Height of font `%s' doesn't match the frame default font"
2130                              pattern)
2131                     (error "Height of font `%s' doesn't match face `%s'"
2132                            pattern face)))
2133               (error "No fonts match `%s'" pattern)))
2134         (car fonts))
2135     (cdr (assq 'font (frame-parameters (selected-frame))))))
2136
2137
2138 (defun x-frob-font-weight (font which)
2139   (let ((case-fold-search t))
2140     (cond ((string-match x-font-regexp font)
2141            (concat (substring font 0
2142                               (match-beginning x-font-regexp-weight-subnum))
2143                    which
2144                    (substring font (match-end x-font-regexp-weight-subnum)
2145                               (match-beginning x-font-regexp-adstyle-subnum))
2146                    ;; Replace the ADD_STYLE_NAME field with *
2147                    ;; because the info in it may not be the same
2148                    ;; for related fonts.
2149                    "*"
2150                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2151           ((string-match x-font-regexp-head font)
2152            (concat (substring font 0 (match-beginning 1)) which
2153                    (substring font (match-end 1))))
2154           ((string-match x-font-regexp-weight font)
2155            (concat (substring font 0 (match-beginning 1)) which
2156                    (substring font (match-end 1)))))))
2157 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
2158
2159 (defun x-frob-font-slant (font which)
2160   (let ((case-fold-search t))
2161     (cond ((string-match x-font-regexp font)
2162            (concat (substring font 0
2163                               (match-beginning x-font-regexp-slant-subnum))
2164                    which
2165                    (substring font (match-end x-font-regexp-slant-subnum)
2166                               (match-beginning x-font-regexp-adstyle-subnum))
2167                    ;; Replace the ADD_STYLE_NAME field with *
2168                    ;; because the info in it may not be the same
2169                    ;; for related fonts.
2170                    "*"
2171                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2172           ((string-match x-font-regexp-head font)
2173            (concat (substring font 0 (match-beginning 2)) which
2174                    (substring font (match-end 2))))
2175           ((string-match x-font-regexp-slant font)
2176            (concat (substring font 0 (match-beginning 1)) which
2177                    (substring font (match-end 1)))))))
2178 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
2179
2180 ;; These aliases are here so that we don't get warnings about obsolete
2181 ;; functions from the byte compiler.
2182 (defalias 'internal-frob-font-weight 'x-frob-font-weight)
2183 (defalias 'internal-frob-font-slant 'x-frob-font-slant)
2184
2185 (defun x-make-font-bold (font)
2186   "Given an X font specification, make a bold version of it.
2187 If that can't be done, return nil."
2188   (internal-frob-font-weight font "bold"))
2189 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
2190
2191 (defun x-make-font-demibold (font)
2192   "Given an X font specification, make a demibold version of it.
2193 If that can't be done, return nil."
2194   (internal-frob-font-weight font "demibold"))
2195 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
2196
2197 (defun x-make-font-unbold (font)
2198   "Given an X font specification, make a non-bold version of it.
2199 If that can't be done, return nil."
2200   (internal-frob-font-weight font "medium"))
2201 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
2202
2203 (defun x-make-font-italic (font)
2204   "Given an X font specification, make an italic version of it.
2205 If that can't be done, return nil."
2206   (internal-frob-font-slant font "i"))
2207 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
2208
2209 (defun x-make-font-oblique (font) ; you say tomayto...
2210   "Given an X font specification, make an oblique version of it.
2211 If that can't be done, return nil."
2212   (internal-frob-font-slant font "o"))
2213 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
2214
2215 (defun x-make-font-unitalic (font)
2216   "Given an X font specification, make a non-italic version of it.
2217 If that can't be done, return nil."
2218   (internal-frob-font-slant font "r"))
2219 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
2220
2221 (defun x-make-font-bold-italic (font)
2222   "Given an X font specification, make a bold and italic version of it.
2223 If that can't be done, return nil."
2224   (and (setq font (internal-frob-font-weight font "bold"))
2225        (internal-frob-font-slant font "i")))
2226 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
2227
2228 (provide 'faces)
2229
2230 ;;; arch-tag: 19a4759f-2963-445f-b004-425b9aadd7d6
2231 ;;; faces.el ends here