lisp/eshell/em-cmpl.el

   1 ;;; em-cmpl.el --- completion using the TAB key
   2
   3 ;; Copyright (C) 1999, 2000 Free Software Foundation
   4
   5 ;; Author: John Wiegley <johnw@gnu.org>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 (provide 'em-cmpl)
  25
  26 (eval-when-compile (require 'esh-maint))
  27 (require 'esh-util)
  28
  29 (defgroup eshell-cmpl nil
  30   "This module provides a programmable completion function bound to
  31 the TAB key, which allows for completing command names, file names,
  32 variable names, arguments, etc."
  33   :tag "Argument completion"
  34   :group 'eshell-module)
  35
  36 ;;; Commentary:
  37
  38 ;; Eshell, by using the pcomplete package, provides a full
  39 ;; programmable completion facility that is comparable to shells like
  40 ;; tcsh or zsh.
  41 ;;
  42 ;; Completions are context-sensitive, which means that pressing <TAB>
  43 ;; after the command 'rmdir' will result in a list of directories,
  44 ;; while doing so after 'rm' will result in a list of all file
  45 ;; entries.
  46 ;;
  47 ;; Many builtin completion rules are provided, for commands such as
  48 ;; `cvs', or RedHat's `rpm' utility.  Adding new completion rules is
  49 ;; no more difficult than writing a plain Lisp functions, and they can
  50 ;; be debugged, profiled, and compiled using exactly the same
  51 ;; facilities (since in fact, they *are* just Lisp functions).  See
  52 ;; the definition of the function `pcomplete/make' for an example of
  53 ;; how to write a completion function.
  54 ;;
  55 ;; The completion facility is very easy to use.  Just press TAB.  If
  56 ;; there are a large number of possible completions, a buffer will
  57 ;; appear showing a list of them.  Completions may be selected from
  58 ;; that buffer using the mouse.  If no completion is selected, and the
  59 ;; user starts doing something else, the display buffer will
  60 ;; automatically disappear.
  61 ;;
  62 ;; If the list of possible completions is very small, Eshell will
  63 ;; "cycle" through them, selecting a different entry each time <TAB>
  64 ;; is pressed.  <S-TAB> may be used to cycle in the opposite
  65 ;; direction.
  66 ;;
  67 ;; Glob patterns can also be cycled.  For example, entering 'echo
  68 ;; x*<tab>' will cycle through all the filenames beginning with 'x'.
  69 ;; This is done because the glob list is treated as though it were a
  70 ;; list of possible completions.  Pressing <C-c SPC> will insert all
  71 ;; of the matching glob patterns at point.
  72 ;;
  73 ;; If a Lisp form is being entered, <TAB> will complete the Lisp
  74 ;; symbol name, in exactly the same way that <M-TAB> does in Emacs
  75 ;; Lisp mode.
  76 ;;
  77 ;; The list of possible completions can be viewed at any point by
  78 ;; pressing <M-?>.
  79 ;;
  80 ;; Finally, context-related help can be accessed by pressing <C-c i>.
  81 ;; This only works well if the completion function has provided Eshell
  82 ;; with sufficient pointers to locate the relevant help text.
  83
  84 ;;; User Variables:
  85
  86 (defcustom eshell-cmpl-load-hook '(eshell-cmpl-initialize)
  87   "*A list of functions to run when `eshell-cmpl' is loaded."
  88   :type 'hook
  89   :group 'eshell-cmpl)
  90
  91 (defcustom eshell-show-lisp-completions nil
  92   "*If non-nil, include Lisp functions in the command completion list.
  93 If this variable is nil, Lisp completion can still be done in command
  94 position by using M-TAB instead of TAB."
  95   :type 'boolean
  96   :group 'eshell-cmpl)
  97
  98 (defcustom eshell-show-lisp-alternatives t
  99   "*If non-nil, and no other completions found, show Lisp functions.
 100 Setting this variable means nothing if `eshell-show-lisp-completions'
 101 is non-nil."
 102   :type 'boolean
 103   :group 'eshell-cmpl)
 104
 105 (defcustom eshell-no-completion-during-jobs t
 106   "*If non-nil, don't allow completion while a process is running."
 107   :type 'boolean
 108   :group 'eshell-cmpl)
 109
 110 (defcustom eshell-command-completions-alist
 111   '(("acroread" . "\\.pdf\\'")
 112     ("xpdf"     . "\\.pdf\\'")
 113     ("ar"       . "\\.[ao]\\'")
 114     ("gcc"      . "\\.[Cc]\\([Cc]\\|[Pp][Pp]\\)?\\'")
 115     ("g++"      . "\\.[Cc]\\([Cc]\\|[Pp][Pp]\\)?\\'")
 116     ("cc"       . "\\.[Cc]\\([Cc]\\|[Pp][Pp]\\)?\\'")
 117     ("CC"       . "\\.[Cc]\\([Cc]\\|[Pp][Pp]\\)?\\'")
 118     ("acc"      . "\\.[Cc]\\([Cc]\\|[Pp][Pp]\\)?\\'")
 119     ("bcc"      . "\\.[Cc]\\([Cc]\\|[Pp][Pp]\\)?\\'")
 120     ("readelf"  . "\\(\\`[^.]*\\|\\.\\([ao]\\|so\\)\\)\\'")
 121     ("objdump"  . "\\(\\`[^.]*\\|\\.\\([ao]\\|so\\)\\)\\'")
 122     ("nm"       . "\\(\\`[^.]*\\|\\.\\([ao]\\|so\\)\\)\\'")
 123     ("gdb"      . "\\`\\([^.]*\\|a\\.out\\)\\'")
 124     ("dbx"      . "\\`\\([^.]*\\|a\\.out\\)\\'")
 125     ("sdb"      . "\\`\\([^.]*\\|a\\.out\\)\\'")
 126     ("adb"      . "\\`\\([^.]*\\|a\\.out\\)\\'"))
 127   "*An alist that defines simple argument type correlations.
 128 This is provided for common commands, as a simplistic alternative
 129 to writing a completion function."
 130   :type '(repeat (cons string regexp))
 131   :group 'eshell-cmpl)
 132
 133 (defcustom eshell-cmpl-file-ignore "~\\'"
 134   (documentation-property 'pcomplete-file-ignore
 135                           'variable-documentation)
 136   :type (get 'pcomplete-file-ignore 'custom-type)
 137   :group 'eshell-cmpl)
 138
 139 (defcustom eshell-cmpl-dir-ignore
 140   (format "\\`\\(\\.\\.?\\|CVS\\)%c\\'" directory-sep-char)
 141   (documentation-property 'pcomplete-dir-ignore
 142                           'variable-documentation)
 143   :type (get 'pcomplete-dir-ignore 'custom-type)
 144   :group 'eshell-cmpl)
 145
 146 (defcustom eshell-cmpl-ignore-case (eshell-under-windows-p)
 147   (documentation-property 'pcomplete-ignore-case
 148                           'variable-documentation)
 149   :type (get 'pcomplete-ignore-case 'custom-type)
 150   :group 'eshell-cmpl)
 151
 152 (defcustom eshell-cmpl-autolist nil
 153   (documentation-property 'pcomplete-autolist
 154                           'variable-documentation)
 155   :type (get 'pcomplete-autolist 'custom-type)
 156   :group 'eshell-cmpl)
 157
 158 (defcustom eshell-cmpl-suffix-list (list directory-sep-char ?:)
 159   (documentation-property 'pcomplete-suffix-list
 160                           'variable-documentation)
 161   :type (get 'pcomplete-suffix-list 'custom-type)
 162   :group 'pcomplete)
 163
 164 (defcustom eshell-cmpl-recexact nil
 165   (documentation-property 'pcomplete-recexact
 166                           'variable-documentation)
 167   :type (get 'pcomplete-recexact 'custom-type)
 168   :group 'eshell-cmpl)
 169
 170 (defcustom eshell-cmpl-man-function 'man
 171   (documentation-property 'pcomplete-man-function
 172                           'variable-documentation)
 173   :type (get 'pcomplete-man-function 'custom-type)
 174   :group 'eshell-cmpl)
 175
 176 (defcustom eshell-cmpl-compare-entry-function 'file-newer-than-file-p
 177   (documentation-property 'pcomplete-compare-entry-function
 178                           'variable-documentation)
 179   :type (get 'pcomplete-compare-entry-function 'custom-type)
 180   :group 'eshell-cmpl)
 181
 182 (defcustom eshell-cmpl-expand-before-complete nil
 183   (documentation-property 'pcomplete-expand-before-complete
 184                           'variable-documentation)
 185   :type (get 'pcomplete-expand-before-complete 'custom-type)
 186   :group 'eshell-cmpl)
 187
 188 (defcustom eshell-cmpl-cycle-completions t
 189   (documentation-property 'pcomplete-cycle-completions
 190                           'variable-documentation)
 191   :type (get 'pcomplete-cycle-completions 'custom-type)
 192   :group 'eshell-cmpl)
 193
 194 (defcustom eshell-cmpl-cycle-cutoff-length 5
 195   (documentation-property 'pcomplete-cycle-cutoff-length
 196                           'variable-documentation)
 197   :type (get 'pcomplete-cycle-cutoff-length 'custom-type)
 198   :group 'eshell-cmpl)
 199
 200 (defcustom eshell-cmpl-restore-window-delay 1
 201   (documentation-property 'pcomplete-restore-window-delay
 202                           'variable-documentation)
 203   :type (get 'pcomplete-restore-window-delay 'custom-type)
 204   :group 'eshell-cmpl)
 205
 206 (defcustom eshell-command-completion-function
 207   (function
 208    (lambda ()
 209      (pcomplete-here (eshell-complete-commands-list))))
 210   (documentation-property 'pcomplete-command-completion-function
 211                           'variable-documentation)
 212   :type (get 'pcomplete-command-completion-function 'custom-type)
 213   :group 'eshell-cmpl)
 214
 215 (defcustom eshell-cmpl-command-name-function
 216   'eshell-completion-command-name
 217   (documentation-property 'pcomplete-command-name-function
 218                           'variable-documentation)
 219   :type (get 'pcomplete-command-name-function 'custom-type)
 220   :group 'eshell-cmpl)
 221
 222 (defcustom eshell-default-completion-function
 223   (function
 224    (lambda ()
 225      (while (pcomplete-here
 226              (pcomplete-dirs-or-entries
 227               (cdr (assoc (funcall eshell-cmpl-command-name-function)
 228                           eshell-command-completions-alist)))))))
 229   (documentation-property 'pcomplete-default-completion-function
 230                           'variable-documentation)
 231   :type (get 'pcomplete-default-completion-function 'custom-type)
 232   :group 'eshell-cmpl)
 233
 234 (defcustom eshell-cmpl-use-paring t
 235   (documentation-property 'pcomplete-use-paring 'variable-documentation)
 236   :type (get 'pcomplete-use-paring 'custom-type)
 237   :group 'eshell-cmpl)
 238
 239 ;;; Functions:
 240
 241 (defun eshell-cmpl-initialize ()
 242   "Initialize the completions module."
 243   (unless (fboundp 'pcomplete)
 244     (load "pcmpl-auto" t t))
 245   (set (make-local-variable 'pcomplete-command-completion-function)
 246        eshell-command-completion-function)
 247   (set (make-local-variable 'pcomplete-command-name-function)
 248        eshell-cmpl-command-name-function)
 249   (set (make-local-variable 'pcomplete-default-completion-function)
 250        eshell-default-completion-function)
 251   (set (make-local-variable 'pcomplete-parse-arguments-function)
 252        'eshell-complete-parse-arguments)
 253   (set (make-local-variable 'pcomplete-file-ignore)
 254        eshell-cmpl-file-ignore)
 255   (set (make-local-variable 'pcomplete-dir-ignore)
 256        eshell-cmpl-dir-ignore)
 257   (set (make-local-variable 'pcomplete-ignore-case)
 258        eshell-cmpl-ignore-case)
 259   (set (make-local-variable 'pcomplete-autolist)
 260        eshell-cmpl-autolist)
 261   (set (make-local-variable 'pcomplete-suffix-list)
 262        eshell-cmpl-suffix-list)
 263   (set (make-local-variable 'pcomplete-recexact)
 264        eshell-cmpl-recexact)
 265   (set (make-local-variable 'pcomplete-man-function)
 266        eshell-cmpl-man-function)
 267   (set (make-local-variable 'pcomplete-compare-entry-function)
 268        eshell-cmpl-compare-entry-function)
 269   (set (make-local-variable 'pcomplete-expand-before-complete)
 270        eshell-cmpl-expand-before-complete)
 271   (set (make-local-variable 'pcomplete-cycle-completions)
 272        eshell-cmpl-cycle-completions)
 273   (set (make-local-variable 'pcomplete-cycle-cutoff-length)
 274        eshell-cmpl-cycle-cutoff-length)
 275   (set (make-local-variable 'pcomplete-restore-window-delay)
 276        eshell-cmpl-restore-window-delay)
 277   (set (make-local-variable 'pcomplete-use-paring)
 278        eshell-cmpl-use-paring)
 279   ;; `pcomplete-arg-quote-list' should only be set after all the
 280   ;; load-hooks for any other extension modules have been run, which
 281   ;; is true at the time `eshell-mode-hook' is run
 282   (add-hook 'eshell-mode-hook
 283             (function
 284              (lambda ()
 285                (set (make-local-variable 'pcomplete-arg-quote-list)
 286                     eshell-special-chars-outside-quoting))) nil t)
 287   (add-hook 'pcomplete-quote-arg-hook 'eshell-quote-backslash nil t)
 288   (define-key eshell-mode-map [(meta tab)] 'lisp-complete-symbol)
 289   (define-key eshell-mode-map [(meta control ?i)] 'lisp-complete-symbol)
 290   (define-key eshell-command-map [(meta ?h)] 'eshell-completion-help)
 291   (define-key eshell-command-map [tab] 'pcomplete-expand-and-complete)
 292   (define-key eshell-command-map [(control ?i)]
 293     'pcomplete-expand-and-complete)
 294   (define-key eshell-command-map [space] 'pcomplete-expand)
 295   (define-key eshell-command-map [? ] 'pcomplete-expand)
 296   (define-key eshell-mode-map [tab] 'pcomplete)
 297   (define-key eshell-mode-map [(control ?i)] 'pcomplete)
 298   ;; jww (1999-10-19): Will this work on anything but X?
 299   (if (eshell-under-xemacs-p)
 300       (define-key eshell-mode-map [iso-left-tab] 'pcomplete-reverse)
 301     (define-key eshell-mode-map [(shift iso-lefttab)] 'pcomplete-reverse)
 302     (define-key eshell-mode-map [(shift control ?i)] 'pcomplete-reverse))
 303   (define-key eshell-mode-map [(meta ??)] 'pcomplete-list))
 304
 305 (defun eshell-completion-command-name ()
 306   "Return the command name, possibly sans globbing."
 307   (let ((cmd (file-name-nondirectory (pcomplete-arg 'first))))
 308     (setq cmd (if (and (> (length cmd) 0)
 309                        (eq (aref cmd 0) eshell-explicit-command-char))
 310                   (substring cmd 1)
 311                 cmd))
 312     (if (eshell-under-windows-p)
 313         (file-name-sans-extension cmd)
 314       cmd)))
 315
 316 (defun eshell-completion-help ()
 317   (interactive)
 318   (if (= (point) eshell-last-output-end)
 319       (describe-prefix-bindings)
 320     (call-interactively 'pcomplete-help)))
 321
 322 (defun eshell-complete-parse-arguments ()
 323   "Parse the command line arguments for `pcomplete-argument'."
 324   (when (and eshell-no-completion-during-jobs
 325              (eshell-interactive-process))
 326     (insert-and-inherit "\t")
 327     (throw 'pcompleted t))
 328   (let ((end (point-marker))
 329         (begin (save-excursion (eshell-bol) (point)))
 330         (posns (list t))
 331         args delim)
 332     (when (memq this-command '(pcomplete-expand
 333                                pcomplete-expand-and-complete))
 334       (run-hook-with-args 'eshell-expand-input-functions begin end)
 335       (if (= begin end)
 336           (end-of-line))
 337       (setq end (point-marker)))
 338     (if (setq delim
 339               (catch 'eshell-incomplete
 340                 (ignore
 341                  (setq args (eshell-parse-arguments begin end)))))
 342         (cond ((memq (car delim) '(?\{ ?\<))
 343                (setq begin (1+ (cadr delim))
 344                      args (eshell-parse-arguments begin end)))
 345               ((eq (car delim) ?\()
 346                (lisp-complete-symbol)
 347                (throw 'pcompleted t))
 348               (t
 349                (insert-and-inherit "\t")
 350                (throw 'pcompleted t))))
 351     (when (get-text-property (1- end) 'comment)
 352       (insert-and-inherit "\t")
 353       (throw 'pcompleted t))
 354     (let ((pos begin))
 355       (while (< pos end)
 356         (if (get-text-property pos 'arg-begin)
 357             (nconc posns (list pos)))
 358         (setq pos (1+ pos))))
 359     (setq posns (cdr posns))
 360     (assert (= (length args) (length posns)))
 361     (let ((a args)
 362           (i 0)
 363           l final)
 364       (while a
 365         (if (and (consp (car a))
 366                  (eq (caar a) 'eshell-operator))
 367             (setq l i))
 368         (setq a (cdr a) i (1+ i)))
 369       (and l
 370            (setq args (nthcdr (1+ l) args)
 371                  posns (nthcdr (1+ l) posns))))
 372     (assert (= (length args) (length posns)))
 373     (when (and args (eq (char-syntax (char-before end)) ? ))
 374       (nconc args (list ""))
 375       (nconc posns (list (point))))
 376     (cons (mapcar
 377            (function
 378             (lambda (arg)
 379               (let ((val
 380                      (if (listp arg)
 381                          (let ((result
 382                                 (eshell-do-eval
 383                                  (list 'eshell-commands arg) t)))
 384                            (assert (eq (car result) 'quote))
 385                            (cadr result))
 386                        arg)))
 387                 (if (numberp val)
 388                     (setq val (number-to-string val)))
 389                 (or val ""))))
 390            args)
 391           posns)))
 392
 393 (defun eshell-complete-commands-list ()
 394   "Generate list of applicable, visible commands."
 395   (let ((filename (pcomplete-arg)) glob-name)
 396     (if (file-name-directory filename)
 397         (pcomplete-executables)
 398       (if (and (> (length filename) 0)
 399                (eq (aref filename 0) eshell-explicit-command-char))
 400           (setq filename (substring filename 1)
 401                 pcomplete-stub filename
 402                 glob-name t))
 403       (let* ((paths (split-string (getenv "PATH") path-separator))
 404              (cwd (file-name-as-directory
 405                    (expand-file-name default-directory)))
 406              (path "") (comps-in-path ())
 407              (file "") (filepath "") (completions ()))
 408         ;; Go thru each path in the search path, finding completions.
 409         (while paths
 410           (setq path (file-name-as-directory
 411                       (expand-file-name (or (car paths) ".")))
 412                 comps-in-path
 413                 (and (file-accessible-directory-p path)
 414                      (file-name-all-completions filename path)))
 415           ;; Go thru each completion found, to see whether it should
 416           ;; be used.
 417           (while comps-in-path
 418             (setq file (car comps-in-path)
 419                   filepath (concat path file))
 420             (if (and (not (member file completions)) ;
 421                      (or (string-equal path cwd)
 422                          (not (file-directory-p filepath)))
 423                      (file-executable-p filepath))
 424                 (setq completions (cons file completions)))
 425             (setq comps-in-path (cdr comps-in-path)))
 426           (setq paths (cdr paths)))
 427         ;; Add aliases which are currently visible, and Lisp functions.
 428         (pcomplete-uniqify-list
 429          (if glob-name
 430              completions
 431            (setq completions
 432                  (append (and (eshell-using-module 'eshell-alias)
 433                               (funcall (symbol-function 'eshell-alias-completions)
 434                                        filename))
 435                          (eshell-winnow-list
 436                           (mapcar
 437                            (function
 438                             (lambda (name)
 439                               (substring name 7)))
 440                            (all-completions (concat "eshell/" filename)
 441                                             obarray 'functionp))
 442                           nil '(eshell-find-alias-function))
 443                          completions))
 444            (append (and (or eshell-show-lisp-completions
 445                             (and eshell-show-lisp-alternatives
 446                                  (null completions)))
 447                         (all-completions filename obarray 'functionp))
 448                    completions)))))))
 449
 450 ;;; Code:
 451
 452 ;;; arch-tag: 0e914699-673a-45f8-8cbf-82e1dbc571bc
 453 ;;; em-cmpl.el ends here