lisp/files.el

   1 ;;; files.el --- file input and output commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Code:
  24
  25 (defconst delete-auto-save-files t
  26   "*Non-nil means delete a buffer's auto-save file when the buffer is saved.")
  27
  28 (defconst directory-abbrev-alist
  29   nil
  30   "*Alist of abbreviations for file directories.
  31 A list of elements of the form (FROM . TO), each meaning to replace
  32 FROM with TO when it appears in a directory name.  This replacement is
  33 done when setting up the default directory of a newly visited file.
  34 *Every* FROM string should start with `^'.
  35
  36 Use this feature when you have directories which you normally refer to
  37 via absolute symbolic links.  Make TO the name of the link, and FROM
  38 the name it is linked to.")
  39
  40 ;;; Turn off backup files on VMS since it has version numbers.
  41 (defconst make-backup-files (not (eq system-type 'vax-vms))
  42   "*Create a backup of each file when it is saved for the first time.
  43 This can be done by renaming the file or by copying.
  44
  45 Renaming means that Emacs renames the existing file so that it is a
  46 backup file, then writes the buffer into a new file.  Any other names
  47 that the old file had will now refer to the backup file.  The new file
  48 is owned by you and its group is defaulted.
  49
  50 Copying means that Emacs copies the existing file into the backup
  51 file, then writes the buffer on top of the existing file.  Any other
  52 names that the old file had will now refer to the new (edited) file.
  53 The file's owner and group are unchanged.
  54
  55 The choice of renaming or copying is controlled by the variables
  56 `backup-by-copying', `backup-by-copying-when-linked' and
  57 `backup-by-copying-when-mismatch'.")
  58
  59 ;; Do this so that local variables based on the file name
  60 ;; are not overridden by the major mode.
  61 (defvar backup-inhibited nil
  62   "Non-nil means don't make a backup file for this buffer.")
  63 (put 'backup-inhibited 'permanent-local t)
  64
  65 (defconst backup-by-copying nil
  66  "*Non-nil means always use copying to create backup files.
  67 See documentation of variable `make-backup-files'.")
  68
  69 (defconst backup-by-copying-when-linked nil
  70  "*Non-nil means use copying to create backups for files with multiple names.
  71 This causes the alternate names to refer to the latest version as edited.
  72 This variable is relevant only if `backup-by-copying' is nil.")
  73
  74 (defconst backup-by-copying-when-mismatch nil
  75   "*Non-nil means create backups by copying if this preserves owner or group.
  76 Renaming may still be used (subject to control of other variables)
  77 when it would not result in changing the owner or group of the file;
  78 that is, for files which are owned by you and whose group matches
  79 the default for a new file created there by you.
  80 This variable is relevant only if `backup-by-copying' is nil.")
  81
  82 (defvar backup-enable-predicate
  83   '(lambda (name)
  84      (or (< (length name) 5)
  85          (not (string-equal "/tmp/" (substring name 0 5)))))
  86   "Predicate that looks at a file name and decides whether to make backups.
  87 Called with an absolute file name as argument, it returns t to enable backup.")
  88
  89 (defconst buffer-offer-save nil
  90   "*Non-nil in a buffer means offer to save the buffer on exit
  91 even if the buffer is not visiting a file.
  92 Automatically local in all buffers.")
  93 (make-variable-buffer-local 'buffer-offer-save)
  94
  95 (defconst find-file-existing-other-name nil
  96   "*Non-nil means find a file under alternative names, in existing buffers.
  97 This means if any existing buffer is visiting the file you want
  98 under another name, you get the existing buffer instead of a new buffer.")
  99
 100 (defconst find-file-visit-truename nil
 101   "*Non-nil means visit a file under its truename.
 102 The truename of a file is found by chasing all links
 103 both at the file level and at the levels of the containing directories.")
 104
 105 (defvar buffer-file-truename nil
 106   "The truename of the file visited in the current buffer.
 107 This variable is automatically local in all buffers, when non-nil.")
 108 (make-variable-buffer-local 'buffer-file-truename)
 109 (put 'buffer-file-truename 'permanent-local t)
 110
 111 (defvar buffer-file-number nil
 112   "The device number and file number of the file visited in the current buffer.
 113 The value is a list of the form (FILENUM DEVNUM).
 114 This pair of numbers uniquely identifies the file.
 115 If the buffer is visiting a new file, the value is nil.")
 116 (make-variable-buffer-local 'buffer-file-number)
 117 (put 'buffer-file-number 'permanent-local t)
 118
 119 (defconst file-precious-flag nil
 120   "*Non-nil means protect against I/O errors while saving files.
 121 Some modes set this non-nil in particular buffers.")
 122
 123 (defvar version-control nil
 124   "*Control use of version numbers for backup files.
 125 t means make numeric backup versions unconditionally.
 126 nil means make them for files that have some already.
 127 never means do not make them.")
 128
 129 (defvar dired-kept-versions 2
 130   "*When cleaning directory, number of versions to keep.")
 131
 132 (defvar trim-versions-without-asking nil
 133   "*If t, deletes excess backup versions silently.
 134 If nil, asks confirmation.  Any other value prevents any trimming.")
 135
 136 (defvar kept-old-versions 2
 137   "*Number of oldest versions to keep when a new numbered backup is made.")
 138
 139 (defvar kept-new-versions 2
 140   "*Number of newest versions to keep when a new numbered backup is made.
 141 Includes the new backup.  Must be > 0")
 142
 143 (defconst require-final-newline nil
 144   "*Value of t says silently ensure a file ends in a newline when it is saved.
 145 Non-nil but not t says ask user whether to add a newline when there isn't one.
 146 nil means don't add newlines.")
 147
 148 (defconst auto-save-default t
 149   "*Non-nil says by default do auto-saving of every file-visiting buffer.")
 150
 151 (defconst auto-save-visited-file-name nil
 152   "*Non-nil says auto-save a buffer in the file it is visiting, when practical.
 153 Normally auto-save files are written under other names.")
 154
 155 (defconst save-abbrevs nil
 156   "*Non-nil means save word abbrevs too when files are saved.
 157 Loading an abbrev file sets this to t.")
 158
 159 (defconst find-file-run-dired t
 160   "*Non-nil says run dired if find-file is given the name of a directory.")
 161
 162 (put 'find-file-not-found-hooks 'permanent-local t)
 163 (defvar find-file-not-found-hooks nil
 164   "List of functions to be called for `find-file' on nonexistent file.
 165 These functions are called as soon as the error is detected.
 166 `buffer-file-name' is already set up.
 167 The functions are called in the order given until one of them returns non-nil.")
 168
 169 (put 'find-file-hooks 'permanent-local t)
 170 (defvar find-file-hooks nil
 171   "List of functions to be called after a buffer is loaded from a file.
 172 The buffer's local variables (if any) will have been processed before the
 173 functions are called.")
 174
 175 (put 'write-file-hooks 'permanent-local t)
 176 (defvar write-file-hooks nil
 177   "List of functions to be called before writing out a buffer to a file.
 178 If one of them returns non-nil, the file is considered already written
 179 and the rest are not called.
 180 These hooks are considered to pertain to the visited file.
 181 So this list is cleared if you change the visited file name.
 182 See also `write-contents-hooks'.")
 183
 184 (defvar write-contents-hooks nil
 185   "List of functions to be called before writing out a buffer to a file.
 186 If one of them returns non-nil, the file is considered already written
 187 and the rest are not called.
 188 These hooks are considered to pertain to the buffer's contents,
 189 not to the particular visited file; thus, `set-visited-file-name' does
 190 not clear this variable, but changing the major mode does clear it.
 191 See also `write-file-hooks'.")
 192
 193 (defconst enable-local-variables t
 194   "*Control use of local-variables lists in files you visit.
 195 The value can be t, nil or something else.
 196 A value of t means local-variables lists are obeyed;
 197 nil means they are ignored; anything else means query.
 198
 199 The command \\[normal-mode] always obeys local-variables lists
 200 and ignores this variable.")
 201
 202 (defconst enable-local-eval 'maybe
 203   "*Control processing of the \"variable\" `eval' in a file's local variables.
 204 The value can be t, nil or something else.
 205 A value of t means obey `eval' variables;
 206 nil means ignore them; anything else means query.
 207
 208 The command \\[normal-mode] always obeys local-variables lists
 209 and ignores this variable.")
 210
 211 ;; Avoid losing in versions where CLASH_DETECTION is disabled.
 212 (or (fboundp 'lock-buffer)
 213     (fset 'lock-buffer 'ignore))
 214 (or (fboundp 'unlock-buffer)
 215     (fset 'unlock-buffer 'ignore))
 216 \f
 217 (defun pwd ()
 218   "Show the current default directory."
 219   (interactive nil)
 220   (message "Directory %s" default-directory))
 221
 222 (defun cd (dir)
 223   "Make DIR become the current buffer's default directory."
 224   (interactive "DChange default directory: ")
 225   (setq dir (expand-file-name dir))
 226   (if (not (eq system-type 'vax-vms))
 227       (setq dir (file-name-as-directory dir)))
 228   (if (not (file-directory-p dir))
 229       (error "%s is not a directory" dir)
 230     (if (file-executable-p dir)
 231         (setq default-directory dir)
 232       (error "Cannot cd to %s:  Permission denied" dir)))
 233   ;; We used to call pwd at this point.  That's not terribly helpful
 234   ;; when we're invoking cd interactively, and the new cmushell-based
 235   ;; shell has its own (better) facilities for this.
 236 )
 237
 238 (defun load-file (file)
 239   "Load the Lisp file named FILE."
 240   (interactive "fLoad file: ")
 241   (load (expand-file-name file) nil nil t))
 242
 243 (defun load-library (library)
 244   "Load the library named LIBRARY.
 245 This is an interface to the function `load'."
 246   (interactive "sLoad library: ")
 247   (load library))
 248
 249 ;; OTHER is the other file to be compared.
 250 (defun file-local-copy (file)
 251   "Copy the file FILE into a temporary file on this machine.
 252 Returns the name of the local copy, or nil, if FILE is directly
 253 accessible."
 254   (let (handler (handlers file-name-handler-alist))
 255     (save-match-data
 256      (while (and (consp handlers) (null handler))
 257        (if (and (consp (car handlers))
 258                 (stringp (car (car handlers)))
 259                 (string-match (car (car handlers)) file))
 260            (setq handler (cdr (car handlers))))
 261        (setq handlers (cdr handlers))))
 262     (if handler
 263         (funcall handler 'file-local-copy file)
 264       nil)))
 265
 266 (defun file-truename (filename)
 267   "Return the truename of FILENAME, which should be absolute.
 268 The truename of a file name is found by chasing symbolic links
 269 both at the level of the file and at the level of the directories
 270 containing it, until no links are left at any level."
 271   (if (string= filename "~")
 272       (setq filename (expand-file-name filename)))
 273   (let (handler (handlers file-name-handler-alist))
 274     (save-match-data
 275      (while (and (consp handlers) (null handler))
 276        (if (and (consp (car handlers))
 277                 (stringp (car (car handlers)))
 278                 (string-match (car (car handlers)) filename))
 279            (setq handler (cdr (car handlers))))
 280        (setq handlers (cdr handlers))))
 281     ;; For file name that has a special handler, call handler.
 282     ;; This is so that ange-ftp can save time by doing a no-op.
 283     (if handler
 284         (funcall handler 'file-truename filename)
 285       (let ((dir (file-name-directory filename))
 286             target dirfile)
 287         ;; Get the truename of the directory.
 288         (setq dirfile (directory-file-name dir))
 289         ;; If these are equal, we have the (or a) root directory.
 290         (or (string= dir dirfile)
 291             (setq dir (file-name-as-directory (file-truename dirfile))))
 292         ;; Put it back on the file name.
 293         (setq filename (concat dir (file-name-nondirectory filename)))
 294         ;; Is the file name the name of a link?
 295         (setq target (file-symlink-p filename))
 296         (if target
 297             ;; Yes => chase that link, then start all over
 298             ;; since the link may point to a directory name that uses links.
 299             (file-truename (expand-file-name target dir))
 300           ;; No, we are done!
 301           filename)))))
 302 \f
 303 (defun switch-to-buffer-other-window (buffer)
 304   "Select buffer BUFFER in another window."
 305   (interactive "BSwitch to buffer in other window: ")
 306   (let ((pop-up-windows t))
 307     (pop-to-buffer buffer t)))
 308
 309 (defun switch-to-buffer-other-frame (buffer)
 310   "Switch to buffer BUFFER in another frame."
 311   (interactive "BSwitch to buffer in other frame: ")
 312   (let ((pop-up-frames t))
 313     (pop-to-buffer buffer)))
 314
 315 (defun find-file (filename)
 316   "Edit file FILENAME.
 317 Switch to a buffer visiting file FILENAME,
 318 creating one if none already exists."
 319   (interactive "FFind file: ")
 320   (switch-to-buffer (find-file-noselect filename)))
 321
 322 (defun find-file-other-window (filename)
 323   "Edit file FILENAME, in another window.
 324 May create a new window, or reuse an existing one.
 325 See the function `display-buffer'."
 326   (interactive "FFind file in other window: ")
 327   (switch-to-buffer-other-window (find-file-noselect filename)))
 328
 329 (defun find-file-other-frame (filename)
 330   "Edit file FILENAME, in another frame.
 331 May create a new frame, or reuse an existing one.
 332 See the function `display-buffer'."
 333   (interactive "FFind file in other frame: ")
 334   (switch-to-buffer-other-frame (find-file-noselect filename)))
 335
 336 (defun find-file-read-only (filename)
 337   "Edit file FILENAME but don't allow changes.
 338 Like \\[find-file] but marks buffer as read-only.
 339 Use \\[toggle-read-only] to permit editing."
 340   (interactive "fFind file read-only: ")
 341   (find-file filename)
 342   (setq buffer-read-only t))
 343
 344 (defun find-file-read-only-other-window (filename)
 345   "Edit file FILENAME in another window but don't allow changes.
 346 Like \\[find-file-other-window] but marks buffer as read-only.
 347 Use \\[toggle-read-only] to permit editing."
 348   (interactive "fFind file read-only other window: ")
 349   (find-file filename)
 350   (setq buffer-read-only t))
 351
 352 (defun find-file-read-only-other-frame (filename)
 353   "Edit file FILENAME in another frame but don't allow changes.
 354 Like \\[find-file-other-frame] but marks buffer as read-only.
 355 Use \\[toggle-read-only] to permit editing."
 356   (interactive "fFind file read-only other frame: ")
 357   (find-file-other-frame filename)
 358   (setq buffer-read-only t))
 359
 360 (defun find-alternate-file (filename)
 361   "Find file FILENAME, select its buffer, kill previous buffer.
 362 If the current buffer now contains an empty file that you just visited
 363 \(presumably by mistake), use this command to visit the file you really want."
 364   (interactive
 365    (let ((file buffer-file-name)
 366          (file-name nil)
 367          (file-dir nil))
 368      (and file
 369           (setq file-name (file-name-nondirectory file)
 370                 file-dir (file-name-directory file)))
 371      (list (read-file-name
 372             "Find alternate file: " file-dir nil nil file-name))))
 373   (and (buffer-modified-p)
 374        ;; (not buffer-read-only)
 375        (not (yes-or-no-p (format "Buffer %s is modified; kill anyway? "
 376                                  (buffer-name))))
 377        (error "Aborted"))
 378   (let ((obuf (current-buffer))
 379         (ofile buffer-file-name)
 380         (oname (buffer-name)))
 381     (rename-buffer " **lose**")
 382     (setq buffer-file-name nil)
 383     (unwind-protect
 384         (progn
 385           (unlock-buffer)
 386           (find-file filename))
 387       (cond ((eq obuf (current-buffer))
 388              (setq buffer-file-name ofile)
 389              (lock-buffer)
 390              (rename-buffer oname))))
 391     (or (eq (current-buffer) obuf)
 392         (kill-buffer obuf))))
 393
 394 (defun create-file-buffer (filename)
 395   "Create a suitably named buffer for visiting FILENAME, and return it.
 396 FILENAME (sans directory) is used unchanged if that name is free;
 397 otherwise a string <2> or <3> or ... is appended to get an unused name."
 398   (let ((lastname (file-name-nondirectory filename)))
 399     (if (string= lastname "")
 400         (setq lastname filename))
 401     (generate-new-buffer lastname)))
 402
 403 (defun generate-new-buffer (name)
 404   "Create and return a buffer with a name based on NAME.
 405 Choose the buffer's name using `generate-new-buffer-name'."
 406   (get-buffer-create (generate-new-buffer-name name)))
 407
 408 (defconst automount-dir-prefix "^/tmp_mnt/"
 409   "Regexp to match the automounter prefix in a directory name.")
 410
 411 (defun abbreviate-file-name (filename)
 412   "Return a version of FILENAME shortened using `directory-abbrev-alist'.
 413 This also substitutes \"~\" for the user's home directory.
 414 Type \\[describe-variable] directory-abbrev-alist RET for more information."
 415   ;; Get rid of the prefixes added by the automounter.
 416   (if (and (string-match automount-dir-prefix filename)
 417            (file-exists-p (file-name-directory
 418                            (substring filename (1- (match-end 0))))))
 419       (setq filename (substring filename (1- (match-end 0)))))
 420   (let ((tail directory-abbrev-alist))
 421     (while tail
 422       (if (string-match (car (car tail)) filename)
 423           (setq filename
 424                 (concat (cdr (car tail)) (substring filename (match-end 0)))))
 425       (setq tail (cdr tail)))
 426     (if (string-match (concat "^" (expand-file-name "~")) filename)
 427         (setq filename
 428               (concat "~" (substring filename (match-end 0)))))
 429     filename))
 430
 431 (defun find-file-noselect (filename &optional nowarn)
 432   "Read file FILENAME into a buffer and return the buffer.
 433 If a buffer exists visiting FILENAME, return that one, but
 434 verify that the file has not changed since visited or saved.
 435 The buffer is not selected, just returned to the caller."
 436   (setq filename
 437         (abbreviate-file-name
 438          (expand-file-name filename)))
 439   (if (file-directory-p filename)
 440       (if find-file-run-dired
 441           (dired-noselect filename)
 442         (error "%s is a directory." filename))
 443     (let* ((buf (get-file-buffer filename))
 444            (truename (abbreviate-file-name (file-truename filename)))
 445            (number (nthcdr 10 (file-attributes truename)))
 446            ;; Find any buffer for a file which has same truename.
 447            (same-truename
 448             (or buf ; Shortcut
 449                 (let (found
 450                       (list (buffer-list)))
 451                   (while (and (not found) list)
 452                     (save-excursion
 453                       (set-buffer (car list))
 454                       (if (string= buffer-file-truename truename)
 455                         (setq found (car list))))
 456                     (setq list (cdr list)))
 457                   found)))
 458            (same-number
 459             (or buf ; Shortcut
 460                 (and number
 461                      (let (found
 462                            (list (buffer-list)))
 463                        (while (and (not found) list)
 464                          (save-excursion
 465                            (set-buffer (car list))
 466                            (if (equal buffer-file-number number)
 467                              (setq found (car list))))
 468                          (setq list (cdr list)))
 469                        found))))
 470            error)
 471       ;; Let user know if there is a buffer with the same truename.
 472       (if (and (not buf) same-truename (not nowarn))
 473           (message "%s and %s are the same file (%s)"
 474                    filename (buffer-file-name same-truename)
 475                    truename)
 476         (if (and (not buf) same-number (not nowarn))
 477           (message "%s and %s are the same file"
 478                    filename (buffer-file-name same-number))))
 479
 480       ;; Optionally also find that buffer.
 481       (if (or find-file-existing-other-name find-file-visit-truename)
 482           (setq buf (or same-truename same-number)))
 483       (if buf
 484           (or nowarn
 485               (verify-visited-file-modtime buf)
 486               (cond ((not (file-exists-p filename))
 487                      (error "File %s no longer exists!" filename))
 488                     ((yes-or-no-p
 489                       (format
 490                        (if (buffer-modified-p buf)
 491     "File %s changed on disk.  Discard your edits? "
 492     "File %s changed on disk.  Read the new version? ")
 493                        (file-name-nondirectory filename)))
 494                      (save-excursion
 495                        (set-buffer buf)
 496                        (revert-buffer t t)))))
 497         (save-excursion
 498 ;;; The truename stuff makes this obsolete.
 499 ;;;       (let* ((link-name (car (file-attributes filename)))
 500 ;;;              (linked-buf (and (stringp link-name)
 501 ;;;                               (get-file-buffer link-name))))
 502 ;;;         (if (bufferp linked-buf)
 503 ;;;             (message "Symbolic link to file in buffer %s"
 504 ;;;                      (buffer-name linked-buf))))
 505           (setq buf (create-file-buffer filename))
 506           (set-buffer buf)
 507           (erase-buffer)
 508           (condition-case ()
 509               (insert-file-contents filename t)
 510             (file-error
 511              (setq error t)
 512              ;; Run find-file-not-found-hooks until one returns non-nil.
 513              (let ((hooks find-file-not-found-hooks))
 514                (while (and hooks
 515                            (not (funcall (car hooks))))
 516                  (setq hooks (cdr hooks))))))
 517           ;; Find the file's truename, and maybe use that as visited name.
 518           (setq buffer-file-truename (abbreviate-file-name truename))
 519           (setq buffer-file-number number)
 520           (if find-file-visit-truename (setq filename buffer-file-truename))
 521           ;; Set buffer's default directory to that of the file.
 522           (setq default-directory (file-name-directory filename))
 523           ;; Turn off backup files for certain file names.  Since
 524           ;; this is a permanent local, the major mode won't eliminate it.
 525           (and (not (funcall backup-enable-predicate buffer-file-name))
 526                (progn
 527                  (make-local-variable 'backup-inhibited)
 528                  (setq backup-inhibited t)))
 529           (after-find-file error (not nowarn))))
 530       buf)))
 531 \f
 532 (defun after-find-file (&optional error warn noauto)
 533   "Called after finding a file and by the default revert function.
 534 Sets buffer mode, parses local variables.
 535 Optional args ERROR, WARN, and NOAUTO: ERROR non-nil means there was an
 536 error in reading the file.  WARN non-nil means warn if there
 537 exists an auto-save file more recent than the visited file.
 538 NOAUTO means don't mess with auto-save mode.
 539 Finishes by calling the functions in `find-file-hooks'."
 540   (setq buffer-read-only (not (file-writable-p buffer-file-name)))
 541   (if noninteractive
 542       nil
 543     (let* (not-serious
 544            (msg
 545             (cond ((and error (file-attributes buffer-file-name))
 546                    (setq buffer-read-only t)
 547                    "File exists, but is read-protected.")
 548                   ((not buffer-read-only)
 549                    (if (and warn
 550                             (file-newer-than-file-p (make-auto-save-file-name)
 551                                                     buffer-file-name))
 552                        "Auto save file is newer; consider M-x recover-file"
 553                      (setq not-serious t)
 554                      (if error "(New file)" nil)))
 555                   ((not error)
 556                    (setq not-serious t)
 557                    "Note: file is write protected")
 558                   ((file-attributes (directory-file-name default-directory))
 559                    "File not found and directory write-protected")
 560                   (t
 561                    ;; If the directory the buffer is in doesn't exist,
 562                    ;; offer to create it.  It's better to do this now
 563                    ;; than when we save the buffer, because we want
 564                    ;; autosaving to work.
 565                    (setq buffer-read-only nil)
 566                    (or (file-exists-p (file-name-directory buffer-file-name))
 567                        (if (yes-or-no-p
 568                             (format
 569                              "The directory containing %s does not exist.  Create? "
 570                              (abbreviate-file-name buffer-file-name)))
 571                            (make-directory-path
 572                             (file-name-directory buffer-file-name))))
 573                    nil))))
 574       (if msg
 575           (progn
 576             (message msg)
 577             (or not-serious (sit-for 1 nil t)))))
 578     (if (and auto-save-default (not noauto))
 579         (auto-save-mode t)))
 580   (normal-mode t)
 581   (mapcar 'funcall find-file-hooks))
 582
 583 (defun normal-mode (&optional find-file)
 584   "Choose the major mode for this buffer automatically.
 585 Also sets up any specified local variables of the file.
 586 Uses the visited file name, the -*- line, and the local variables spec.
 587
 588 This function is called automatically from `find-file'.  In that case,
 589 we may set up specified local variables depending on the value of
 590 `enable-local-variables': if it is t, we do; if it is nil, we don't;
 591 otherwise, we query.  `enable-local-variables' is ignored if you
 592 run `normal-mode' explicitly."
 593   (interactive)
 594   (or find-file (funcall (or default-major-mode 'fundamental-mode)))
 595   (condition-case err
 596       (set-auto-mode)
 597     (error (message "File mode specification error: %s"
 598                     (prin1-to-string err))))
 599   (condition-case err
 600       (let ((enable-local-variables (or (not find-file)
 601                                         enable-local-variables)))
 602         (hack-local-variables))
 603     (error (message "File local-variables error: %s"
 604                     (prin1-to-string err)))))
 605
 606 (defvar auto-mode-alist (mapcar 'purecopy
 607                                 '(("\\.text\\'" . text-mode)
 608                                   ("\\.c\\'" . c-mode)
 609                                   ("\\.h\\'" . c-mode)
 610                                   ("\\.tex\\'" . TeX-mode)
 611                                   ("\\.ltx\\'" . LaTeX-mode)
 612                                   ("\\.el\\'" . emacs-lisp-mode)
 613                                   ("\\.mm\\'" . nroff-mode)
 614                                   ("\\.me\\'" . nroff-mode)
 615                                   ("\\.scm\\'" . scheme-mode)
 616                                   ("\\.l\\'" . lisp-mode)
 617                                   ("\\.lisp\\'" . lisp-mode)
 618                                   ("\\.f\\'" . fortran-mode)
 619                                   ("\\.for\\'" . fortran-mode)
 620                                   ("\\.mss\\'" . scribe-mode)
 621                                   ("\\.pl\\'" . prolog-mode)
 622                                   ("\\.cc\\'" . c++-mode)
 623                                   ("\\.C\\'" . c++-mode)
 624 ;;; Less common extensions come here
 625 ;;; so more common ones above are found faster.
 626                                   ("\\.s\\'" . asm-mode)
 627                                   ("ChangeLog\\'" . change-log-mode)
 628                                   ("ChangeLog.[0-9]+\\'" . change-log-mode)
 629                                   ("\\$CHANGE_LOG\\$\\.TXT" . change-log-mode)
 630 ;; The following should come after the ChangeLog pattern
 631 ;; for the sake of ChangeLog.1, etc.
 632                                   ("\\.[12345678]\\'" . nroff-mode)
 633                                   ("\\.TeX\\'" . TeX-mode)
 634                                   ("\\.sty\\'" . LaTeX-mode)
 635                                   ("\\.bbl\\'" . LaTeX-mode)
 636                                   ("\\.bib\\'" . bibtex-mode)
 637                                   ("\\.article\\'" . text-mode)
 638                                   ("\\.letter\\'" . text-mode)
 639                                   ("\\.texinfo\\'" . texinfo-mode)
 640                                   ("\\.texi\\'" . texinfo-mode)
 641                                   ("\\.lsp\\'" . lisp-mode)
 642                                   ("\\.awk\\'" . awk-mode)
 643                                   ("\\.prolog\\'" . prolog-mode)
 644                                   ;; Mailer puts message to be edited in
 645                                   ;; /tmp/Re.... or Message
 646                                   ("^/tmp/Re" . text-mode)
 647                                   ("/Message[0-9]*\\'" . text-mode)
 648                                   ;; some news reader is reported to use this
 649                                   ("^/tmp/fol/" . text-mode)
 650                                   ("\\.y\\'" . c-mode)
 651                                   ("\\.oak\\'" . scheme-mode)
 652                                   ("\\.scm.[0-9]*\\'" . scheme-mode)
 653                                   ;; .emacs following a directory delimiter
 654                                   ;; in either Unix or VMS syntax.
 655                                   ("[]>:/]\\..*emacs\\'" . emacs-lisp-mode)
 656                                   ("\\.ml\\'" . lisp-mode)))
 657   "\
 658 Alist of filename patterns vs corresponding major mode functions.
 659 Each element looks like (REGEXP . FUNCTION).
 660 Visiting a file whose name matches REGEXP causes FUNCTION to be called.")
 661
 662 (defun set-auto-mode ()
 663   "Select major mode appropriate for current buffer.
 664 This checks for a -*- mode tag in the buffer's text, or
 665 compares the filename against the entries in auto-mode-alist.  It does
 666 not check for the \"mode:\" local variable in the Local Variables
 667 section of the file; for that, use `hack-local-variables'.
 668
 669 If `enable-local-variables' is nil, this function does not check for a
 670 -*- mode tag."
 671   ;; Look for -*-MODENAME-*- or -*- ... mode: MODENAME; ... -*-
 672   (let (beg end mode)
 673     (save-excursion
 674       (goto-char (point-min))
 675       (skip-chars-forward " \t\n")
 676       (if (and enable-local-variables
 677                (search-forward "-*-" (save-excursion (end-of-line) (point)) t)
 678                (progn
 679                  (skip-chars-forward " \t")
 680                  (setq beg (point))
 681                  (search-forward "-*-"
 682                                  (save-excursion (end-of-line) (point))
 683                                  t))
 684                (progn
 685                  (forward-char -3)
 686                  (skip-chars-backward " \t")
 687                  (setq end (point))
 688                  (goto-char beg)
 689                  (if (search-forward ":" end t)
 690                      (progn
 691                        (goto-char beg)
 692                        (if (let ((case-fold-search t))
 693                              (search-forward "mode:" end t))
 694                            (progn
 695                              (skip-chars-forward " \t")
 696                              (setq beg (point))
 697                              (if (search-forward ";" end t)
 698                                  (forward-char -1)
 699                                (goto-char end))
 700                              (skip-chars-backward " \t")
 701                              (setq mode (buffer-substring beg (point))))))
 702                    (setq mode (buffer-substring beg end)))))
 703           (setq mode (intern (concat (downcase mode) "-mode")))
 704         (let ((alist auto-mode-alist)
 705               (name buffer-file-name))
 706           (let ((case-fold-search (eq system-type 'vax-vms)))
 707             ;; Remove backup-suffixes from file name.
 708             (setq name (file-name-sans-versions name))
 709             ;; Find first matching alist entry.
 710             (while (and (not mode) alist)
 711               (if (string-match (car (car alist)) name)
 712                   (setq mode (cdr (car alist))))
 713               (setq alist (cdr alist)))))))
 714     (if mode (funcall mode))))
 715
 716 (defun hack-local-variables-prop-line ()
 717   ;; Set local variables specified in the -*- line.
 718   ;; Returns t if mode was set.
 719   (save-excursion
 720     (goto-char (point-min))
 721     (skip-chars-forward " \t\n\r")
 722     (let ((result '())
 723           (end (save-excursion (end-of-line) (point)))
 724           mode-p)
 725       ;; Parse the -*- line into the `result' alist.
 726       (cond ((not (search-forward "-*-" end t))
 727              ;; doesn't have one.
 728              nil)
 729             ((looking-at "[ \t]*\\([^ \t\n\r:;]+\\)\\([ \t]*-\\*-\\)")
 730              ;; Simple form: "-*- MODENAME -*-".
 731              (setq result
 732                (list (cons 'mode
 733                            (intern (buffer-substring
 734                                     (match-beginning 1)
 735                                     (match-end 1)))))))
 736             (t
 737              ;; Hairy form: '-*-' [ <variable> ':' <value> ';' ]* '-*-'
 738              ;; (last ";" is optional).
 739              (save-excursion
 740                (if (search-forward "-*-" end t)
 741                    (setq end (- (point) 3))
 742                  (error "-*- not terminated before end of line")))
 743              (while (< (point) end)
 744                (or (looking-at "[ \t]*\\([^ \t\n:]+\\)[ \t]*:[ \t]*")
 745                    (error "malformed -*- line"))
 746                (goto-char (match-end 0))
 747                (let ((key (intern (downcase (buffer-substring
 748                                              (match-beginning 1)
 749                                              (match-end 1)))))
 750                      (val (save-restriction
 751                             (narrow-to-region (point) end)
 752                             (read (current-buffer)))))
 753                  (setq result (cons (cons key val) result))
 754                  (skip-chars-forward " \t;")))
 755              (setq result (nreverse result))))
 756
 757       ;; Mode is magic.
 758       (let (mode)
 759         (while (setq mode (assq 'mode result))
 760           (setq mode-p t result (delq mode result))
 761           (funcall (intern (concat (downcase (symbol-name (cdr mode)))
 762                                    "-mode")))))
 763
 764       (if (and result
 765                (or (eq enable-local-variables t)
 766                    (and enable-local-variables
 767                         (save-window-excursion
 768                           (switch-to-buffer (current-buffer))
 769                           (y-or-n-p (format "Set local variables as specified in -*- line of %s? "
 770                                             (file-name-nondirectory buffer-file-name)))))))
 771           (while result
 772             (let ((key (car (car result)))
 773                   (val (cdr (car result))))
 774               ;; 'mode has already been removed from this list.
 775               (hack-one-local-variable key val))
 776             (setq result (cdr result))))
 777       mode-p)))
 778
 779 (defun hack-local-variables ()
 780   "Parse and put into effect this buffer's local variables spec."
 781   (hack-local-variables-prop-line)
 782   ;; Look for "Local variables:" line in last page.
 783   (save-excursion
 784     (goto-char (point-max))
 785     (search-backward "\n\^L" (max (- (point-max) 3000) (point-min)) 'move)
 786     (if (let ((case-fold-search t))
 787           (and (search-forward "Local Variables:" nil t)
 788                (or (eq enable-local-variables t)
 789                    (and enable-local-variables
 790                         (save-window-excursion
 791                           (switch-to-buffer (current-buffer))
 792                           (save-excursion
 793                             (beginning-of-line)
 794                             (set-window-start (selected-window) (point)))
 795                           (y-or-n-p (format "Set local variables as specified at end of %s? "
 796                                             (file-name-nondirectory buffer-file-name))))))))
 797         (let ((continue t)
 798               prefix prefixlen suffix beg
 799               (enable-local-eval enable-local-eval))
 800           ;; The prefix is what comes before "local variables:" in its line.
 801           ;; The suffix is what comes after "local variables:" in its line.
 802           (skip-chars-forward " \t")
 803           (or (eolp)
 804               (setq suffix (buffer-substring (point)
 805                                              (progn (end-of-line) (point)))))
 806           (goto-char (match-beginning 0))
 807           (or (bolp)
 808               (setq prefix
 809                     (buffer-substring (point)
 810                                       (progn (beginning-of-line) (point)))))
 811
 812           (if prefix (setq prefixlen (length prefix)
 813                            prefix (regexp-quote prefix)))
 814           (if suffix (setq suffix (concat (regexp-quote suffix) "$")))
 815           (while continue
 816             ;; Look at next local variable spec.
 817             (if selective-display (re-search-forward "[\n\C-m]")
 818               (forward-line 1))
 819             ;; Skip the prefix, if any.
 820             (if prefix
 821                 (if (looking-at prefix)
 822                     (forward-char prefixlen)
 823                   (error "Local variables entry is missing the prefix")))
 824             ;; Find the variable name; strip whitespace.
 825             (skip-chars-forward " \t")
 826             (setq beg (point))
 827             (skip-chars-forward "^:\n")
 828             (if (eolp) (error "Missing colon in local variables entry"))
 829             (skip-chars-backward " \t")
 830             (let* ((str (buffer-substring beg (point)))
 831                    (var (read str))
 832                   val)
 833               ;; Setting variable named "end" means end of list.
 834               (if (string-equal (downcase str) "end")
 835                   (setq continue nil)
 836                 ;; Otherwise read the variable value.
 837                 (skip-chars-forward "^:")
 838                 (forward-char 1)
 839                 (setq val (read (current-buffer)))
 840                 (skip-chars-backward "\n")
 841                 (skip-chars-forward " \t")
 842                 (or (if suffix (looking-at suffix) (eolp))
 843                     (error "Local variables entry is terminated incorrectly"))
 844                 ;; Set the variable.  "Variables" mode and eval are funny.
 845                 (hack-one-local-variable var val))))))))
 846
 847 (defconst ignored-local-variables
 848   '(enable-local-eval)
 849   "Variables to be ignored in a file's local variable spec.")
 850
 851 ;; "Set" one variable in a local variables spec.
 852 ;; A few variable names are treated specially.
 853 (defun hack-one-local-variable (var val)
 854   (cond ((eq var 'mode)
 855          (funcall (intern (concat (downcase (symbol-name val))
 856                                   "-mode"))))
 857         ((memq var ignored-local-variables)
 858          nil)
 859         ;; "Setting" eval means either eval it or do nothing.
 860         ((eq var 'eval)
 861          (if (and (not (string= (user-login-name) "root"))
 862                   (or (eq enable-local-eval t)
 863                       (and enable-local-eval
 864                            (save-window-excursion
 865                              (switch-to-buffer (current-buffer))
 866                              (save-excursion
 867                                (beginning-of-line)
 868                                (set-window-start (selected-window) (point)))
 869                              (setq enable-local-eval
 870                                    (y-or-n-p (format "Process `eval' local variable in file %s? "
 871                                                      (file-name-nondirectory buffer-file-name))))))))
 872              (save-excursion (eval val))
 873            (message "Ignoring `eval:' in file's local variables")))
 874         ;; Ordinary variable, really set it.
 875         (t (make-local-variable var)
 876            (set var val))))
 877
 878 \f
 879 (defun set-visited-file-name (filename)
 880   "Change name of file visited in current buffer to FILENAME.
 881 The next time the buffer is saved it will go in the newly specified file.
 882 nil or empty string as argument means make buffer not be visiting any file.
 883 Remember to delete the initial contents of the minibuffer
 884 if you wish to pass an empty string as the argument."
 885   (interactive "FSet visited file name: ")
 886   (if filename
 887       (setq filename
 888             (if (string-equal filename "")
 889                 nil
 890               (expand-file-name filename))))
 891   (or (equal filename buffer-file-name)
 892       (null filename)
 893       (progn
 894         (lock-buffer filename)
 895         (unlock-buffer)))
 896   (setq buffer-file-name filename)
 897   (if filename                          ; make buffer name reflect filename.
 898       (let ((new-name (file-name-nondirectory buffer-file-name)))
 899         (if (string= new-name "")
 900             (error "Empty file name"))
 901         (if (eq system-type 'vax-vms)
 902             (setq new-name (downcase new-name)))
 903         (setq default-directory (file-name-directory buffer-file-name))
 904         (rename-buffer new-name t)))
 905   (setq buffer-backed-up nil)
 906   (clear-visited-file-modtime)
 907   (if filename
 908       (progn
 909         (setq buffer-file-truename
 910               (abbreviate-file-name (file-truename buffer-file-name)))
 911         (if find-file-visit-truename
 912             (setq buffer-file-name buffer-file-truename))
 913         (setq buffer-file-number (nth 10 (file-attributes buffer-file-name))))
 914     (setq buffer-file-truename nil buffer-file-number nil))
 915   ;; write-file-hooks is normally used for things like ftp-find-file
 916   ;; that visit things that are not local files as if they were files.
 917   ;; Changing to visit an ordinary local file instead should flush the hook.
 918   (kill-local-variable 'write-file-hooks)
 919   (kill-local-variable 'revert-buffer-function)
 920   (kill-local-variable 'backup-inhibited)
 921   ;; Turn off backup files for certain file names.
 922   ;; Since this is a permanent local, the major mode won't eliminate it.
 923   (and (not (funcall backup-enable-predicate buffer-file-name))
 924        (progn
 925          (make-local-variable 'backup-inhibited)
 926          (setq backup-inhibited t)))
 927   ;; If auto-save was not already on, turn it on if appropriate.
 928   (if (not buffer-auto-save-file-name)
 929       (auto-save-mode (and buffer-file-name auto-save-default))
 930     ;; If auto save is on, start using a new name.
 931     ;; We deliberately don't rename or delete the old auto save
 932     ;; for the old visited file name.  This is because perhaps
 933     ;; the user wants to save the new state and then compare with the
 934     ;; previous state from the auto save file.
 935     (setq buffer-auto-save-file-name
 936           (make-auto-save-file-name)))
 937   (if buffer-file-name
 938       (set-buffer-modified-p t)))
 939
 940 (defun write-file (filename)
 941   "Write current buffer into file FILENAME.
 942 Makes buffer visit that file, and marks it not modified."
 943 ;;  (interactive "FWrite file: ")
 944   (interactive
 945    (list (if buffer-file-name
 946              (read-file-name "Write file: "
 947                                  nil nil nil nil)
 948            (read-file-name "Write file: "
 949                                (cdr (assq 'default-directory
 950                                           (buffer-local-variables)))
 951                                nil nil (buffer-name)))))
 952   (or (null filename) (string-equal filename "")
 953       (set-visited-file-name filename))
 954   (set-buffer-modified-p t)
 955   (save-buffer))
 956 \f
 957 (defun backup-buffer ()
 958   "Make a backup of the disk file visited by the current buffer, if appropriate.
 959 This is normally done before saving the buffer the first time.
 960 If the value is non-nil, it is the result of `file-modes' on the original
 961 file; this means that the caller, after saving the buffer, should change
 962 the modes of the new file to agree with the old modes."
 963   (if (and make-backup-files (not backup-inhibited)
 964            (not buffer-backed-up)
 965            (file-exists-p buffer-file-name)
 966            (memq (aref (elt (file-attributes buffer-file-name) 8) 0)
 967                  '(?- ?l)))
 968       (let ((real-file-name buffer-file-name)
 969             backup-info backupname targets setmodes)
 970         ;; If specified name is a symbolic link, chase it to the target.
 971         ;; Thus we make the backups in the directory where the real file is.
 972         (while (let ((tem (file-symlink-p real-file-name)))
 973                  (if tem
 974                      (setq real-file-name
 975                            (expand-file-name tem
 976                                              (file-name-directory real-file-name))))
 977                  tem))
 978         (setq backup-info (find-backup-file-name real-file-name)
 979               backupname (car backup-info)
 980               targets (cdr backup-info))
 981 ;;;     (if (file-directory-p buffer-file-name)
 982 ;;;         (error "Cannot save buffer in directory %s" buffer-file-name))
 983         (condition-case ()
 984             (let ((delete-old-versions
 985                    ;; If have old versions to maybe delete,
 986                    ;; ask the user to confirm now, before doing anything.
 987                    ;; But don't actually delete til later.
 988                    (and targets
 989                         (or (eq trim-versions-without-asking t) (eq trim-versions-without-asking nil))
 990                         (or trim-versions-without-asking
 991                             (y-or-n-p (format "Delete excess backup versions of %s? "
 992                                               real-file-name))))))
 993               ;; Actually write the back up file.
 994               (condition-case ()
 995                   (if (or file-precious-flag
 996 ;                         (file-symlink-p buffer-file-name)
 997                           backup-by-copying
 998                           (and backup-by-copying-when-linked
 999                                (> (file-nlinks real-file-name) 1))
1000                           (and backup-by-copying-when-mismatch
1001                                (let ((attr (file-attributes real-file-name)))
1002                                  (or (nth 9 attr)
1003                                      (/= (nth 2 attr) (user-uid))))))
1004                       (condition-case ()
1005                           (copy-file real-file-name backupname t t)
1006                         (file-error
1007                          ;; If copying fails because file BACKUPNAME
1008                          ;; is not writable, delete that file and try again.
1009                          (if (and (file-exists-p backupname)
1010                                   (not (file-writable-p backupname)))
1011                              (delete-file backupname))
1012                          (copy-file real-file-name backupname t t)))
1013                     ;; rename-file should delete old backup.
1014                     (rename-file real-file-name backupname t)
1015                     (setq setmodes (file-modes backupname)))
1016                 (file-error
1017                  ;; If trouble writing the backup, write it in ~.
1018                  (setq backupname (expand-file-name "~/%backup%~"))
1019                  (message "Cannot write backup file; backing up in ~/%%backup%%~")
1020                  (sleep-for 1)
1021                  (condition-case ()
1022                      (copy-file real-file-name backupname t t)
1023                    (file-error
1024                     ;; If copying fails because file BACKUPNAME
1025                     ;; is not writable, delete that file and try again.
1026                     (if (and (file-exists-p backupname)
1027                              (not (file-writable-p backupname)))
1028                         (delete-file backupname))
1029                     (copy-file real-file-name backupname t t)))))
1030               (setq buffer-backed-up t)
1031               ;; Now delete the old versions, if desired.
1032               (if delete-old-versions
1033                   (while targets
1034                     (condition-case ()
1035                         (delete-file (car targets))
1036                       (file-error nil))
1037                     (setq targets (cdr targets))))
1038               setmodes)
1039         (file-error nil)))))
1040
1041 (defun file-name-sans-versions (name &optional keep-backup-version)
1042   "Return FILENAME sans backup versions or strings.
1043 This is a separate procedure so your site-init or startup file can
1044 redefine it.
1045 If the optional argument KEEP-BACKUP-VERSION is non-nil,
1046 we do not remove backup version numbers, only true file version numbers."
1047   (let (handler (handlers file-name-handler-alist))
1048     (save-match-data
1049      (while (and (consp handlers) (null handler))
1050        (if (and (consp (car handlers))
1051                 (stringp (car (car handlers)))
1052                 (string-match (car (car handlers)) name))
1053            (setq handler (cdr (car handlers))))
1054        (setq handlers (cdr handlers))))
1055     (if handler
1056         (funcall handler 'file-name-sans-versions name keep-backup-version)
1057       (substring name 0
1058                  (if (eq system-type 'vax-vms)
1059                      ;; VMS version number is (a) semicolon, optional
1060                      ;; sign, zero or more digits or (b) period, option
1061                      ;; sign, zero or more digits, provided this is the
1062                      ;; second period encountered outside of the
1063                      ;; device/directory part of the file name.
1064                      (or (string-match ";[---+]?[0-9]*\\'" name)
1065                          (if (string-match "\\.[^]>:]*\\(\\.[---+]?[0-9]*\\)\\'"
1066                                            name)
1067                              (match-beginning 1))
1068                          (length name))
1069                    (if keep-backup-version
1070                        (length name)
1071                      (or (string-match "\\.~[0-9]+~\\'" name)
1072                          (string-match "~\\'" name)
1073                          (length name))))))))
1074
1075 (defun make-backup-file-name (file)
1076   "Create the non-numeric backup file name for FILE.
1077 This is a separate function so you can redefine it for customization."
1078   (concat file "~"))
1079
1080 (defun backup-file-name-p (file)
1081   "Return non-nil if FILE is a backup file name (numeric or not).
1082 This is a separate function so you can redefine it for customization.
1083 You may need to redefine `file-name-sans-versions' as well."
1084   (string-match "~$" file))
1085
1086 ;; This is used in various files.
1087 ;; The usage of bv-length is not very clean,
1088 ;; but I can't see a good alternative,
1089 ;; so as of now I am leaving it alone.
1090 (defun backup-extract-version (fn)
1091   "Given the name of a numeric backup file, return the backup number.
1092 Uses the free variable `bv-length', whose value should be
1093 the index in the name where the version number begins."
1094   (if (and (string-match "[0-9]+~$" fn bv-length)
1095            (= (match-beginning 0) bv-length))
1096       (string-to-int (substring fn bv-length -1))
1097       0))
1098
1099 ;; I believe there is no need to alter this behavior for VMS;
1100 ;; since backup files are not made on VMS, it should not get called.
1101 (defun find-backup-file-name (fn)
1102   "Find a file name for a backup file, and suggestions for deletions.
1103 Value is a list whose car is the name for the backup file
1104  and whose cdr is a list of old versions to consider deleting now."
1105   (if (eq version-control 'never)
1106       (list (make-backup-file-name fn))
1107     (let* ((base-versions (concat (file-name-nondirectory fn) ".~"))
1108            (bv-length (length base-versions))
1109            (possibilities (file-name-all-completions
1110                            base-versions
1111                            (file-name-directory fn)))
1112            (versions (sort (mapcar
1113                             (function backup-extract-version)
1114                             possibilities)
1115                            '<))
1116            (high-water-mark (apply 'max 0 versions))
1117            (deserve-versions-p
1118             (or version-control
1119                 (> high-water-mark 0)))
1120            (number-to-delete (- (length versions)
1121                                 kept-old-versions kept-new-versions -1)))
1122       (if (not deserve-versions-p)
1123           (list (make-backup-file-name fn))
1124         (cons (concat fn ".~" (int-to-string (1+ high-water-mark)) "~")
1125               (if (> number-to-delete 0)
1126                   (mapcar (function (lambda (n)
1127                                       (concat fn ".~" (int-to-string n) "~")))
1128                           (let ((v (nthcdr kept-old-versions versions)))
1129                             (rplacd (nthcdr (1- number-to-delete) v) ())
1130                             v))))))))
1131
1132 (defun file-nlinks (filename)
1133   "Return number of names file FILENAME has."
1134   (car (cdr (file-attributes filename))))
1135
1136 (defun file-relative-name-1 (directory)
1137   (cond ((string= directory "/")
1138          filename)
1139         ((string-match (concat "^" (regexp-quote directory))
1140                        filename)
1141          (substring filename (match-end 0)))
1142         (t
1143          (file-relative-name-1
1144           (file-name-directory (substring directory 0 -1))))))
1145
1146 (defun file-relative-name (filename &optional directory)
1147   "Convert FILENAME to be relative to DIRECTORY (default: default-directory)."
1148   (setq filename (expand-file-name filename)
1149         directory (file-name-as-directory (if directory
1150                                               (expand-file-name directory)
1151                                               default-directory)))
1152   (file-relative-name-1 directory))
1153 \f
1154 (defun save-buffer (&optional args)
1155   "Save current buffer in visited file if modified.  Versions described below.
1156 By default, makes the previous version into a backup file
1157  if previously requested or if this is the first save.
1158 With 1 or 3 \\[universal-argument]'s, marks this version
1159  to become a backup when the next save is done.
1160 With 2 or 3 \\[universal-argument]'s,
1161  unconditionally makes the previous version into a backup file.
1162 With argument of 0, never makes the previous version into a backup file.
1163
1164 If a file's name is FOO, the names of its numbered backup versions are
1165  FOO.~i~ for various integers i.  A non-numbered backup file is called FOO~.
1166 Numeric backups (rather than FOO~) will be made if value of
1167  `version-control' is not the atom `never' and either there are already
1168  numeric versions of the file being backed up, or `version-control' is
1169  non-nil.
1170 We don't want excessive versions piling up, so there are variables
1171  `kept-old-versions', which tells Emacs how many oldest versions to keep,
1172  and `kept-new-versions', which tells how many newest versions to keep.
1173  Defaults are 2 old versions and 2 new.
1174 `dired-kept-versions' controls dired's clean-directory (.) command.
1175 If `trim-versions-without-asking' is nil, system will query user
1176  before trimming versions.  Otherwise it does it silently."
1177   (interactive "p")
1178   (let ((modp (buffer-modified-p))
1179         (large (> (buffer-size) 50000))
1180         (make-backup-files (and make-backup-files (not (eq args 0)))))
1181     (and modp (memq args '(16 64)) (setq buffer-backed-up nil))
1182     (if (and modp large) (message "Saving file %s..." (buffer-file-name)))
1183     (basic-save-buffer)
1184     (and modp (memq args '(4 64)) (setq buffer-backed-up nil))))
1185
1186 (defun delete-auto-save-file-if-necessary (&optional force)
1187   "Delete auto-save file for current buffer if `delete-auto-save-files' is t.
1188 Normally delete only if the file was written by this Emacs since
1189 the last real save, but optional arg FORCE non-nil means delete anyway."
1190   (and buffer-auto-save-file-name delete-auto-save-files
1191        (not (string= buffer-file-name buffer-auto-save-file-name))
1192        (or force (recent-auto-save-p))
1193        (progn
1194          (condition-case ()
1195              (delete-file buffer-auto-save-file-name)
1196            (file-error nil))
1197          (set-buffer-auto-saved))))
1198
1199 (defun basic-save-buffer ()
1200   "Save the current buffer in its visited file, if it has been modified."
1201   (interactive)
1202   (if (buffer-modified-p)
1203       (let ((recent-save (recent-auto-save-p))
1204             setmodes tempsetmodes)
1205         ;; On VMS, rename file and buffer to get rid of version number.
1206         (if (and (eq system-type 'vax-vms)
1207                  (not (string= buffer-file-name
1208                                (file-name-sans-versions buffer-file-name))))
1209             (let (buffer-new-name)
1210               ;; Strip VMS version number before save.
1211               (setq buffer-file-name
1212                     (file-name-sans-versions buffer-file-name))
1213               ;; Construct a (unique) buffer name to correspond.
1214               (let ((buf (create-file-buffer (downcase buffer-file-name))))
1215                 (setq buffer-new-name (buffer-name buf))
1216                 (kill-buffer buf))
1217               (rename-buffer buffer-new-name)))
1218         ;; If buffer has no file name, ask user for one.
1219         (or buffer-file-name
1220             (progn
1221               (setq buffer-file-name
1222                     (expand-file-name (read-file-name "File to save in: ") nil)
1223                     default-directory (file-name-directory buffer-file-name))
1224               (auto-save-mode auto-save-default)))
1225         (or (verify-visited-file-modtime (current-buffer))
1226             (not (file-exists-p buffer-file-name))
1227             (yes-or-no-p
1228              (format "%s has changed since visited or saved.  Save anyway? "
1229                      (file-name-nondirectory buffer-file-name)))
1230             (error "Save not confirmed"))
1231         (save-restriction
1232           (widen)
1233           (and (> (point-max) 1)
1234                (/= (char-after (1- (point-max))) ?\n)
1235                (or (eq require-final-newline t)
1236                    (and require-final-newline
1237                         (y-or-n-p
1238                          (format "Buffer %s does not end in newline.  Add one? "
1239                                  (buffer-name)))))
1240                (save-excursion
1241                  (goto-char (point-max))
1242                  (insert ?\n)))
1243           (let ((hooks (append write-contents-hooks write-file-hooks))
1244                 (done nil))
1245             (while (and hooks
1246                         (not (setq done (funcall (car hooks)))))
1247               (setq hooks (cdr hooks)))
1248             ;; If a hook returned t, file is already "written".
1249             (cond ((not done)
1250                    (if (not (file-writable-p buffer-file-name))
1251                        (let ((dir (file-name-directory buffer-file-name)))
1252                          (if (not (file-directory-p dir))
1253                              (error "%s is not a directory" dir)
1254                            (if (not (file-exists-p buffer-file-name))
1255                                (error "Directory %s write-protected" dir)
1256                              (if (yes-or-no-p
1257                                   (format "File %s is write-protected; try to save anyway? "
1258                                           (file-name-nondirectory
1259                                            buffer-file-name)))
1260                                  (setq tempsetmodes t)
1261                                (error "Attempt to save to a file which you aren't allowed to write"))))))
1262                    (or buffer-backed-up
1263                        (setq setmodes (backup-buffer)))
1264                    (if file-precious-flag
1265                        ;; If file is precious, write temp name, then rename it.
1266                        (let ((dir (file-name-directory buffer-file-name))
1267                              (realname buffer-file-name)
1268                              tempname temp nogood i succeed)
1269                          (setq i 0)
1270                          (setq nogood t)
1271                          ;; Find the temporary name to write under.
1272                          (while nogood
1273                            (setq tempname (format "%s#tmp#%d" dir i))
1274                            (setq nogood (file-exists-p tempname))
1275                            (setq i (1+ i)))
1276                          (unwind-protect
1277                              (progn (clear-visited-file-modtime)
1278                                     (write-region (point-min) (point-max)
1279                                                   tempname nil realname)
1280                                     (setq succeed t))
1281                            ;; If writing the temp file fails,
1282                            ;; delete the temp file.
1283                            (or succeed (delete-file tempname)))
1284                          ;; We succeeded in writing the temp file,
1285                          ;; so rename it.
1286                          (rename-file tempname buffer-file-name t))
1287                      ;; If file not writable, see if we can make it writable
1288                      ;; temporarily while we write it.
1289                      ;; But no need to do so if we have just backed it up
1290                      ;; (setmodes is set) because that says we're superseding.
1291                      (cond ((and tempsetmodes (not setmodes))
1292                             ;; Change the mode back, after writing.
1293                             (setq setmodes (file-modes buffer-file-name))
1294                             (set-file-modes buffer-file-name 511)))
1295                      (write-region (point-min) (point-max)
1296                                    buffer-file-name nil t)))))
1297           (setq buffer-file-number (nth 10 (file-attributes buffer-file-name)))
1298           (if setmodes
1299               (condition-case ()
1300                   (set-file-modes buffer-file-name setmodes)
1301                 (error nil))))
1302         ;; If the auto-save file was recent before this command,
1303         ;; delete it now.
1304         (delete-auto-save-file-if-necessary recent-save)
1305         (run-hooks 'after-save-hooks))
1306     (message "(No changes need to be saved)")))
1307
1308 (defun save-some-buffers (&optional arg exiting)
1309   "Save some modified file-visiting buffers.  Asks user about each one.
1310 Optional argument (the prefix) non-nil means save all with no questions.
1311 Optional second argument EXITING means ask about certain non-file buffers
1312  as well as about file buffers."
1313   (interactive "P")
1314   (save-window-excursion
1315     (if (zerop (map-y-or-n-p
1316                 (function
1317                  (lambda (buffer)
1318                    (and (buffer-modified-p buffer)
1319                         (or
1320                          (buffer-file-name buffer)
1321                          (and exiting
1322                               (progn
1323                                 (set-buffer buffer)
1324                                 (and buffer-offer-save (> (buffer-size) 0)))))
1325                         (if arg
1326                             t
1327                           (if (buffer-file-name buffer)
1328                               (format "Save file %s? "
1329                                       (buffer-file-name buffer))
1330                             (format "Save buffer %s? "
1331                                     (buffer-name buffer)))))))
1332                 (function
1333                  (lambda (buffer)
1334                    (set-buffer buffer)
1335                    (save-buffer)))
1336                 (buffer-list)
1337                 '("buffer" "buffers" "save")
1338                 (list (list ?\C-r (lambda (buf)
1339                                     (view-buffer buf)
1340                                     (setq view-exit-action
1341                                           '(lambda (ignore)
1342                                              (exit-recursive-edit)))
1343                                     (recursive-edit)
1344                                     ;; Return nil to ask about BUF again.
1345                                     nil)
1346                             "display the current buffer"))
1347                 ))
1348         (message "(No files need saving)"))))
1349 \f
1350 (defun not-modified (&optional arg)
1351   "Mark current buffer as unmodified, not needing to be saved.
1352 With prefix arg, mark buffer as modified, so \\[save-buffer] will save."
1353   (interactive "P")
1354   (message (if arg "Modification-flag set"
1355                "Modification-flag cleared"))
1356   (set-buffer-modified-p arg))
1357
1358 (defun toggle-read-only (&optional arg)
1359   "Change whether this buffer is visiting its file read-only.
1360 With arg, set read-only iff arg is positive."
1361   (interactive "P")
1362   (setq buffer-read-only
1363         (if (null arg)
1364             (not buffer-read-only)
1365             (> (prefix-numeric-value arg) 0)))
1366   ;; Force mode-line redisplay
1367   (set-buffer-modified-p (buffer-modified-p)))
1368
1369 (defun insert-file (filename)
1370   "Insert contents of file FILENAME into buffer after point.
1371 Set mark after the inserted text.
1372
1373 This function is meant for the user to run interactively.
1374 Don't call it from programs!  Use `insert-file-contents' instead.
1375 \(Its calling sequence is different; see its documentation)."
1376   (interactive "fInsert file: ")
1377   (let ((tem (insert-file-contents filename)))
1378     (push-mark (+ (point) (car (cdr tem))))))
1379
1380 (defun append-to-file (start end filename)
1381   "Append the contents of the region to the end of file FILENAME.
1382 When called from a function, expects three arguments,
1383 START, END and FILENAME.  START and END are buffer positions
1384 saying what text to write."
1385   (interactive "r\nFAppend to file: ")
1386   (write-region start end filename t))
1387
1388 (defun file-newest-backup (filename)
1389   "Return most recent backup file for FILENAME or nil if no backups exist."
1390   (let* ((filename (expand-file-name filename))
1391          (file (file-name-nondirectory filename))
1392          (dir  (file-name-directory    filename))
1393          (comp (file-name-all-completions file dir))
1394          newest)
1395     (while comp
1396       (setq file (concat dir (car comp))
1397             comp (cdr comp))
1398       (if (and (backup-file-name-p file)
1399                (or (null newest) (file-newer-than-file-p file newest)))
1400           (setq newest file)))
1401     newest))
1402
1403 (defun rename-uniquely ()
1404   "Rename current buffer to a similar name not already taken.
1405 This function is useful for creating multiple shell process buffers
1406 or multiple mail buffers, etc."
1407   (interactive)
1408   (let* ((new-buf (generate-new-buffer (buffer-name)))
1409          (name (buffer-name new-buf)))
1410     (kill-buffer new-buf)
1411     (rename-buffer name)
1412     (set-buffer-modified-p (buffer-modified-p)))) ; force mode line update
1413
1414 (defun make-directory-path (path)
1415   "Create all the directories along path that don't exist yet."
1416   (interactive "Fdirectory path to create: ")
1417   (let ((path (directory-file-name (expand-file-name path)))
1418         create-list)
1419     (while (not (file-exists-p path))
1420       (setq create-list (cons path create-list)
1421             path (directory-file-name (file-name-directory path))))
1422     (while create-list
1423       (make-directory (car create-list))
1424       (setq create-list (cdr create-list)))))
1425
1426 \f
1427 (put 'revert-buffer-function 'permanent-local t)
1428 (defvar revert-buffer-function nil
1429   "Function to use to revert this buffer, or nil to do the default.")
1430
1431 (put 'revert-buffer-insert-file-contents-function 'permanent-local t)
1432 (defvar revert-buffer-insert-file-contents-function nil
1433   "Function to use to insert contents when reverting this buffer.
1434 Gets two args, first the nominal file name to use,
1435 and second, t if reading the auto-save file.")
1436
1437 (defun revert-buffer (&optional check-auto noconfirm)
1438   "Replace the buffer text with the text of the visited file on disk.
1439 This undoes all changes since the file was visited or saved.
1440 With a prefix argument, offer to revert from latest auto-save file, if
1441 that is more recent than the visited file.
1442 When called from lisp, this is the first argument, CHECK-AUTO; it is optional.
1443 Optional second argument NOCONFIRM means don't ask for confirmation at all.
1444
1445 If the value of `revert-buffer-function' is non-nil, it is called to
1446 do the work."
1447   (interactive "P")
1448   (if revert-buffer-function
1449       (funcall revert-buffer-function (not check-auto) noconfirm)
1450     (let* ((opoint (point))
1451            (auto-save-p (and check-auto (recent-auto-save-p)
1452                              buffer-auto-save-file-name
1453                              (file-readable-p buffer-auto-save-file-name)
1454                              (y-or-n-p
1455    "Buffer has been auto-saved recently.  Revert from auto-save file? ")))
1456            (file-name (if auto-save-p
1457                           buffer-auto-save-file-name
1458                         buffer-file-name)))
1459       (cond ((null file-name)
1460              (error "Buffer does not seem to be associated with any file"))
1461             ((or noconfirm
1462                  (yes-or-no-p (format "Revert buffer from file %s? "
1463                                       file-name)))
1464              ;; If file was backed up but has changed since,
1465              ;; we shd make another backup.
1466              (and (not auto-save-p)
1467                   (not (verify-visited-file-modtime (current-buffer)))
1468                   (setq buffer-backed-up nil))
1469              ;; Get rid of all undo records for this buffer.
1470              (or (eq buffer-undo-list t)
1471                  (setq buffer-undo-list nil))
1472              (let ((buffer-read-only nil)
1473                    ;; Don't make undo records for the reversion.
1474                    (buffer-undo-list t))
1475                (if revert-buffer-insert-file-contents-function
1476                    (funcall revert-buffer-insert-file-contents-function
1477                             file-name auto-save-p)
1478                  (if (not (file-exists-p file-name))
1479                      (error "File %s no longer exists!" file-name))
1480                  ;; Bind buffer-file-name to nil
1481                  ;; so that we don't try to lock the file.
1482                  (let ((buffer-file-name nil))
1483                    (or auto-save-p
1484                        (unlock-buffer))
1485                    (erase-buffer))
1486                  (insert-file-contents file-name (not auto-save-p))))
1487              (goto-char (min opoint (point-max)))
1488              (after-find-file nil nil t)
1489              t)))))
1490
1491 (defun recover-file (file)
1492   "Visit file FILE, but get contents from its last auto-save file."
1493   (interactive
1494    (let ((prompt-file buffer-file-name)
1495          (file-name nil)
1496          (file-dir nil))
1497      (and prompt-file
1498           (setq file-name (file-name-nondirectory prompt-file)
1499                 file-dir (file-name-directory prompt-file)))
1500      (list (read-file-name "Recover file: "
1501                                file-dir nil nil file-name))))
1502   (setq file (expand-file-name file))
1503   (if (auto-save-file-name-p file) (error "%s is an auto-save file" file))
1504   (let ((file-name (let ((buffer-file-name file))
1505                      (make-auto-save-file-name))))
1506     (cond ((not (file-newer-than-file-p file-name file))
1507            (error "Auto-save file %s not current" file-name))
1508           ((save-window-excursion
1509              (if (not (eq system-type 'vax-vms))
1510                  (with-output-to-temp-buffer "*Directory*"
1511                    (buffer-disable-undo standard-output)
1512                    (call-process "ls" nil standard-output nil
1513                                  (if (file-symlink-p file) "-lL" "-l")
1514                                  file file-name)))
1515              (yes-or-no-p (format "Recover auto save file %s? " file-name)))
1516            (switch-to-buffer (find-file-noselect file t))
1517            (let ((buffer-read-only nil))
1518              (erase-buffer)
1519              (insert-file-contents file-name nil))
1520            (after-find-file nil nil t))
1521           (t (error "Recover-file cancelled.")))))
1522
1523 (defun kill-some-buffers ()
1524   "For each buffer, ask whether to kill it."
1525   (interactive)
1526   (let ((list (buffer-list)))
1527     (while list
1528       (let* ((buffer (car list))
1529              (name (buffer-name buffer)))
1530         (and (not (string-equal name ""))
1531              (/= (aref name 0) ? )
1532              (yes-or-no-p
1533               (format "Buffer %s %s.  Kill? "
1534                       name
1535                       (if (buffer-modified-p buffer)
1536                           "HAS BEEN EDITED" "is unmodified")))
1537              (kill-buffer buffer)))
1538       (setq list (cdr list)))))
1539 \f
1540 (defun auto-save-mode (arg)
1541   "Toggle auto-saving of contents of current buffer.
1542 With prefix argument ARG, turn auto-saving on if positive, else off."
1543   (interactive "P")
1544   (setq buffer-auto-save-file-name
1545         (and (if (null arg)
1546                  (not buffer-auto-save-file-name)
1547                (or (eq arg t) (listp arg) (and (integerp arg) (> arg 0))))
1548              (if (and buffer-file-name auto-save-visited-file-name
1549                       (not buffer-read-only))
1550                  buffer-file-name
1551                (make-auto-save-file-name))))
1552   (if (interactive-p)
1553       (message "Auto-save %s (in this buffer)"
1554                (if buffer-auto-save-file-name "on" "off")))
1555   buffer-auto-save-file-name)
1556
1557 (defun rename-auto-save-file ()
1558   "Adjust current buffer's auto save file name for current conditions.
1559 Also rename any existing auto save file, if it was made in this session."
1560   (let ((osave buffer-auto-save-file-name))
1561     (setq buffer-auto-save-file-name
1562           (make-auto-save-file-name))
1563     (if (and osave buffer-auto-save-file-name
1564              (not (string= buffer-auto-save-file-name buffer-file-name))
1565              (not (string= buffer-auto-save-file-name osave))
1566              (file-exists-p osave)
1567              (recent-auto-save-p))
1568         (rename-file osave buffer-auto-save-file-name t))))
1569
1570 (defun make-auto-save-file-name ()
1571   "Return file name to use for auto-saves of current buffer.
1572 Does not consider `auto-save-visited-file-name' as that variable is checked
1573 before calling this function.  You can redefine this for customization.
1574 See also `auto-save-file-name-p'."
1575   (if buffer-file-name
1576       (concat (file-name-directory buffer-file-name)
1577               "#"
1578               (file-name-nondirectory buffer-file-name)
1579               "#")
1580     ;; For non-file bfr, use bfr name and Emacs pid.
1581     (expand-file-name (format "#%s#%s#" (buffer-name) (make-temp-name "")))))
1582
1583 (defun auto-save-file-name-p (filename)
1584   "Return non-nil if FILENAME can be yielded by `make-auto-save-file-name'.
1585 FILENAME should lack slashes.  You can redefine this for customization."
1586   (string-match "^#.*#$" filename))
1587 \f
1588 (defconst list-directory-brief-switches
1589   (if (eq system-type 'vax-vms) "" "-CF")
1590   "*Switches for list-directory to pass to `ls' for brief listing,")
1591
1592 (defconst list-directory-verbose-switches
1593   (if (eq system-type 'vax-vms)
1594       "/PROTECTION/SIZE/DATE/OWNER/WIDTH=(OWNER:10)"
1595     "-l")
1596   "*Switches for list-directory to pass to `ls' for verbose listing,")
1597
1598 (defun list-directory (dirname &optional verbose)
1599   "Display a list of files in or matching DIRNAME, a la `ls'.
1600 DIRNAME is globbed by the shell if necessary.
1601 Prefix arg (second arg if noninteractive) means supply -l switch to `ls'.
1602 Actions controlled by variables `list-directory-brief-switches'
1603 and `list-directory-verbose-switches'."
1604   (interactive (let ((pfx current-prefix-arg))
1605                  (list (read-file-name (if pfx "List directory (verbose): "
1606                                          "List directory (brief): ")
1607                                        nil default-directory nil)
1608                        pfx)))
1609   (let ((switches (if verbose list-directory-verbose-switches
1610                     list-directory-brief-switches)))
1611     (or dirname (setq dirname default-directory))
1612     (setq dirname (expand-file-name dirname))
1613     (with-output-to-temp-buffer "*Directory*"
1614       (buffer-disable-undo standard-output)
1615       (princ "Directory ")
1616       (princ dirname)
1617       (terpri)
1618       (save-excursion
1619         (set-buffer "*Directory*")
1620         (let ((wildcard (not (file-directory-p dirname))))
1621           (insert-directory dirname switches wildcard (not wildcard)))))))
1622
1623 (defvar insert-directory-program "ls"
1624   "Absolute or relative name of the `ls' program used by `insert-directory'.")
1625
1626 ;; insert-directory
1627 ;; - must insert _exactly_one_line_ describing FILE if WILDCARD and
1628 ;;   FULL-DIRECTORY-P is nil.
1629 ;;   The single line of output must display FILE's name as it was
1630 ;;   given, namely, an absolute path name.
1631 ;; - must insert exactly one line for each file if WILDCARD or
1632 ;;   FULL-DIRECTORY-P is t, plus one optional "total" line
1633 ;;   before the file lines, plus optional text after the file lines.
1634 ;;   Lines are delimited by "\n", so filenames containing "\n" are not
1635 ;;   allowed.
1636 ;;   File lines should display the basename.
1637 ;; - must be consistent with
1638 ;;   - functions dired-move-to-filename, (these two define what a file line is)
1639 ;;               dired-move-to-end-of-filename,
1640 ;;               dired-between-files, (shortcut for (not (dired-move-to-filename)))
1641 ;;               dired-insert-headerline
1642 ;;               dired-after-subdir-garbage (defines what a "total" line is)
1643 ;;   - variable dired-subdir-regexp
1644 (defun insert-directory (file switches &optional wildcard full-directory-p)
1645   "Insert directory listing for of FILE, formatted according to SWITCHES.
1646 Leaves point after the inserted text.
1647 Optional third arg WILDCARD means treat FILE as shell wildcard.
1648 Optional fourth arg FULL-DIRECTORY-P means file is a directory and
1649 switches do not contain `d', so that a full listing is expected.
1650
1651 This works by running a directory listing program
1652 whose name is in the variable `ls-program'.
1653 If WILDCARD, it also runs the shell specified by `shell-file-name'."
1654   (let (handler (handlers file-name-handler-alist))
1655     (save-match-data
1656      (while (and (consp handlers) (null handler))
1657        (if (and (consp (car handlers))
1658                 (stringp (car (car handlers)))
1659                 (string-match (car (car handlers)) file))
1660            (setq handler (cdr (car handlers))))
1661        (setq handlers (cdr handlers))))
1662     (if handler
1663         (funcall handler 'insert-directory file switches
1664                  wildcard full-directory-p)
1665       (if (eq system-type 'vax-vms)
1666           (vms-read-directory file switches (current-buffer))
1667         (if wildcard
1668             (let ((default-directory (file-name-directory file)))
1669               (call-process shell-file-name nil t nil
1670                             "-c" (concat insert-directory-program
1671                                          " -d " switches " "
1672                                          (file-name-nondirectory file))))
1673 ;;;       ;; Chase links till we reach a non-link.
1674 ;;;       (let (symlink)
1675 ;;;         (while (setq symlink (file-symlink-p file))
1676 ;;;           (setq file symlink)))
1677           (call-process insert-directory-program nil t nil switches file))))))
1678
1679 (defun save-buffers-kill-emacs (&optional arg)
1680   "Offer to save each buffer, then kill this Emacs process.
1681 With prefix arg, silently save all file-visiting buffers, then kill."
1682   (interactive "P")
1683   (save-some-buffers arg t)
1684   (and (or (not (memq t (mapcar (function
1685                                   (lambda (buf) (and (buffer-file-name buf)
1686                                                      (buffer-modified-p buf))))
1687                                 (buffer-list))))
1688            (yes-or-no-p "Modified buffers exist; exit anyway? "))
1689        (or (not (fboundp 'process-list))
1690            ;; process-list is not defined on VMS.
1691            (let ((processes (process-list))
1692                  active)
1693              (while processes
1694                (and (memq (process-status (car processes)) '(run stop open))
1695                     (let ((val (process-kill-without-query (car processes))))
1696                       (process-kill-without-query (car processes) val)
1697                       val)
1698                     (setq active t))
1699                (setq processes (cdr processes)))
1700              (or (not active)
1701                  (yes-or-no-p "Active processes exist; kill them and exit anyway? "))))
1702        (kill-emacs)))
1703 \f
1704 (define-key ctl-x-map "\C-f" 'find-file)
1705 (define-key ctl-x-map "\C-q" 'toggle-read-only)
1706 (define-key ctl-x-map "\C-r" 'find-file-read-only)
1707 (define-key ctl-x-map "\C-v" 'find-alternate-file)
1708 (define-key ctl-x-map "\C-s" 'save-buffer)
1709 (define-key ctl-x-map "s" 'save-some-buffers)
1710 (define-key ctl-x-map "\C-w" 'write-file)
1711 (define-key ctl-x-map "i" 'insert-file)
1712 (define-key esc-map "~" 'not-modified)
1713 (define-key ctl-x-map "\C-d" 'list-directory)
1714 (define-key ctl-x-map "\C-c" 'save-buffers-kill-emacs)
1715
1716 (define-key ctl-x-4-map "f" 'find-file-other-window)
1717 (define-key ctl-x-4-map "r" 'find-file-read-only-other-window)
1718 (define-key ctl-x-4-map "\C-f" 'find-file-other-window)
1719 (define-key ctl-x-4-map "b" 'switch-to-buffer-other-window)
1720 (define-key ctl-x-4-map "\C-o" 'display-buffer)
1721
1722 (define-key ctl-x-5-map "b" 'switch-to-buffer-other-frame)
1723 (define-key ctl-x-5-map "f" 'find-file-other-frame)
1724 (define-key ctl-x-5-map "\C-f" 'find-file-other-frame)
1725 (define-key ctl-x-5-map "r" 'find-file-read-only-other-frame)
1726
1727 ;;; files.el ends here