lisp/epa-file.el

   1 ;;; epa-file.el --- the EasyPG Assistant, transparent file encryption
   2 ;; Copyright (C) 2006, 2007, 2008 Free Software Foundation, Inc.
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: PGP, GnuPG
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Code:
  23
  24 (require 'epa)
  25 (require 'epa-hook)
  26
  27 (defcustom epa-file-cache-passphrase-for-symmetric-encryption nil
  28   "If non-nil, cache passphrase for symmetric encryption."
  29   :type 'boolean
  30   :group 'epa-file)
  31
  32 (defcustom epa-file-select-keys nil
  33   "If non-nil, always asks user to select recipients."
  34   :type 'boolean
  35   :group 'epa-file)
  36
  37 (defvar epa-file-passphrase-alist nil)
  38
  39 (eval-and-compile
  40   (if (fboundp 'encode-coding-string)
  41       (defalias 'epa-file--encode-coding-string 'encode-coding-string)
  42     (defalias 'epa-file--encode-coding-string 'identity)))
  43
  44 (eval-and-compile
  45   (if (fboundp 'decode-coding-string)
  46       (defalias 'epa-file--decode-coding-string 'decode-coding-string)
  47     (defalias 'epa-file--decode-coding-string 'identity)))
  48
  49 (defun epa-file-passphrase-callback-function (context key-id file)
  50   (if (and epa-file-cache-passphrase-for-symmetric-encryption
  51            (eq key-id 'SYM))
  52       (progn
  53         (setq file (file-truename file))
  54         (let ((entry (assoc file epa-file-passphrase-alist))
  55               passphrase)
  56           (or (copy-sequence (cdr entry))
  57               (progn
  58                 (unless entry
  59                   (setq entry (list file)
  60                         epa-file-passphrase-alist
  61                         (cons entry
  62                               epa-file-passphrase-alist)))
  63                 (setq passphrase (epa-passphrase-callback-function context
  64                                                                    key-id nil))
  65                 (setcdr entry (copy-sequence passphrase))
  66                 passphrase))))
  67     (epa-passphrase-callback-function context key-id nil)))
  68
  69 ;;;###autoload
  70 (defun epa-file-handler (operation &rest args)
  71   (save-match-data
  72     (let ((op (get operation 'epa-file)))
  73       (if op
  74           (apply op args)
  75         (epa-file-run-real-handler operation args)))))
  76
  77 (defun epa-file-run-real-handler (operation args)
  78   (let ((inhibit-file-name-handlers
  79          (cons 'epa-file-handler
  80                (and (eq inhibit-file-name-operation operation)
  81                     inhibit-file-name-handlers)))
  82         (inhibit-file-name-operation operation))
  83     (apply operation args)))
  84
  85 (defun epa-file-decode-and-insert (string file visit beg end replace)
  86   (if (fboundp 'decode-coding-inserted-region)
  87       (save-restriction
  88         (narrow-to-region (point) (point))
  89         (let ((multibyte enable-multibyte-characters))
  90           (set-buffer-multibyte nil)
  91           (insert string)
  92           (set-buffer-multibyte multibyte)
  93           (decode-coding-inserted-region
  94            (point-min) (point-max)
  95            (substring file 0 (string-match epa-file-name-regexp file))
  96            visit beg end replace)))
  97     (insert (epa-file--decode-coding-string string (or coding-system-for-read
  98                                                        'undecided)))))
  99
 100 (defvar last-coding-system-used)
 101 (defun epa-file-insert-file-contents (file &optional visit beg end replace)
 102   (barf-if-buffer-read-only)
 103   (if (and visit (or beg end))
 104       (error "Attempt to visit less than an entire file"))
 105   (setq file (expand-file-name file))
 106   (let* ((local-copy
 107           (condition-case inl
 108               (epa-file-run-real-handler #'file-local-copy (list file))
 109             (error)))
 110          (local-file (or local-copy file))
 111          (context (epg-make-context))
 112          string length entry)
 113     (if visit
 114         (setq buffer-file-name file))
 115     (epg-context-set-passphrase-callback
 116      context
 117      (cons #'epa-file-passphrase-callback-function
 118            local-file))
 119     (epg-context-set-progress-callback context
 120                                        #'epa-progress-callback-function)
 121     (unwind-protect
 122         (progn
 123           (if replace
 124               (goto-char (point-min)))
 125           (condition-case error
 126               (setq string (epg-decrypt-file context local-file nil))
 127             (error
 128              (if (setq entry (assoc file epa-file-passphrase-alist))
 129                  (setcdr entry nil))
 130              (signal 'file-error
 131                      (cons "Opening input file" (cdr error)))))
 132           (make-local-variable 'epa-file-encrypt-to)
 133           (setq epa-file-encrypt-to
 134                 (mapcar #'car (epg-context-result-for context 'encrypted-to)))
 135           (if (or beg end)
 136               (setq string (substring string (or beg 0) end)))
 137           (save-excursion
 138             (save-restriction
 139               (narrow-to-region (point) (point))
 140               (epa-file-decode-and-insert string file visit beg end replace)
 141               (setq length (- (point-max) (point-min))))
 142             (if replace
 143                 (delete-region (point) (point-max)))))
 144       (if (and local-copy
 145                (file-exists-p local-copy))
 146           (delete-file local-copy)))
 147     (list file length)))
 148 (put 'insert-file-contents 'epa-file 'epa-file-insert-file-contents)
 149
 150 (defun epa-file-write-region (start end file &optional append visit lockname
 151                                     mustbenew)
 152   (if append
 153       (error "Can't append to the file."))
 154   (setq file (expand-file-name file))
 155   (let* ((coding-system (or coding-system-for-write
 156                             (if (fboundp 'select-safe-coding-system)
 157                                 ;; This is needed since Emacs 22 has
 158                                 ;; no-conversion setting for *.gpg in
 159                                 ;; `auto-coding-alist'.
 160                                 (let ((buffer-file-name
 161                                        (file-name-sans-extension file)))
 162                                   (select-safe-coding-system
 163                                    (point-min) (point-max)))
 164                               buffer-file-coding-system)))
 165          (context (epg-make-context))
 166          (coding-system-for-write 'binary)
 167          string entry
 168          (recipients
 169           (cond
 170            ((listp epa-file-encrypt-to) epa-file-encrypt-to)
 171            ((stringp epa-file-encrypt-to) (list epa-file-encrypt-to)))))
 172     (epg-context-set-passphrase-callback
 173      context
 174      (cons #'epa-file-passphrase-callback-function
 175            file))
 176     (epg-context-set-progress-callback context
 177                                        #'epa-progress-callback-function)
 178     (epg-context-set-armor context epa-armor)
 179     (condition-case error
 180         (setq string
 181               (epg-encrypt-string
 182                context
 183                (if (stringp start)
 184                    (epa-file--encode-coding-string start coding-system)
 185                  (unless start
 186                    (setq start (point-min))
 187                    (setq end (point-max)))
 188                  (epa-file--encode-coding-string (buffer-substring start end)
 189                                                  coding-system))
 190                (if (or epa-file-select-keys
 191                        (not (local-variable-p 'epa-file-encrypt-to
 192                                               (current-buffer))))
 193                    (epa-select-keys
 194                     context
 195                     "Select recipents for encryption.
 196 If no one is selected, symmetric encryption will be performed.  "
 197                     recipients)
 198                  (if epa-file-encrypt-to
 199                      (epg-list-keys context recipients)))))
 200       (error
 201        (if (setq entry (assoc file epa-file-passphrase-alist))
 202            (setcdr entry nil))
 203        (signal 'file-error (cons "Opening output file" (cdr error)))))
 204     (epa-file-run-real-handler
 205      #'write-region
 206      (list string nil file append visit lockname mustbenew))
 207     (if (boundp 'last-coding-system-used)
 208         (setq last-coding-system-used coding-system))
 209     (if (eq visit t)
 210         (progn
 211           (setq buffer-file-name file)
 212           (set-visited-file-modtime))
 213       (if (stringp visit)
 214           (progn
 215             (set-visited-file-modtime)
 216             (setq buffer-file-name visit))))
 217     (if (or (eq visit t)
 218             (eq visit nil)
 219             (stringp visit))
 220         (message "Wrote %s" buffer-file-name))))
 221 (put 'write-region 'epa-file 'epa-file-write-region)
 222
 223 (defun epa-file-select-keys ()
 224   "Select recipients for encryption."
 225   (interactive)
 226   (make-local-variable 'epa-file-encrypt-to)
 227   (setq epa-file-encrypt-to
 228         (mapcar
 229          (lambda (key)
 230            (epg-sub-key-id (car (epg-key-sub-key-list key))))
 231         (epa-select-keys
 232          (epg-make-context)
 233          "Select recipents for encryption.
 234 If no one is selected, symmetric encryption will be performed.  "))))
 235
 236 ;;;###autoload
 237 (defun epa-file-enable ()
 238   (interactive)
 239   (if (memq epa-file-handler file-name-handler-alist)
 240       (message "`epa-file' already enabled")
 241     (setq file-name-handler-alist
 242           (cons epa-file-handler file-name-handler-alist))
 243     (add-hook 'find-file-hook 'epa-file-find-file-hook)
 244     (setq auto-mode-alist (cons epa-file-auto-mode-alist-entry auto-mode-alist))
 245     (message "`epa-file' enabled")))
 246
 247 ;;;###autoload
 248 (defun epa-file-disable ()
 249   (interactive)
 250   (if (memq epa-file-handler file-name-handler-alist)
 251       (progn
 252         (setq file-name-handler-alist
 253               (delq epa-file-handler file-name-handler-alist))
 254         (remove-hook 'find-file-hook 'epa-file-find-file-hook)
 255         (setq auto-mode-alist (delq epa-file-auto-mode-alist-entry
 256                                     auto-mode-alist))
 257         (message "`epa-file' disabled"))
 258     (message "`epa-file' already disabled")))
 259
 260 (provide 'epa-file)
 261
 262 ;; arch-tag: 5715152f-0eb1-4dbc-9008-07098775314d
 263 ;;; epa-file.el ends here