lisp/diff-mode.el

   1 ;;; diff-mode.el --- a mode for viewing/editing context diffs
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001  Free Software Foundation, Inc.
   4
   5 ;; Author: Stefan Monnier <monnier@cs.yale.edu>
   6 ;; Keywords: convenience patch diff
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Provides support for font-lock, outline, navigation
  28 ;; commands, editing and various conversions as well as jumping
  29 ;; to the corresponding source file.
  30
  31 ;; Inspired by Pavel Machek's patch-mode.el (<pavel@atrey.karlin.mff.cuni.cz>)
  32 ;; Some efforts were spent to have it somewhat compatible with XEmacs'
  33 ;; diff-mode as well as with compilation-minor-mode
  34
  35 ;; Bugs:
  36
  37 ;; - Reverse doesn't work with normal diffs.
  38
  39 ;; Todo:
  40
  41 ;; - Improve narrowed-view support.
  42 ;; - re-enable (conditionally) the `compile' support after improving it to use
  43 ;;   the same code as diff-goto-source.
  44 ;; - Support for # comments in context->unified.
  45 ;; - Allow diff.el to use diff-mode.
  46 ;;   This mostly means ability to jump from half-hunk to half-hunk
  47 ;;   in context (and normal) diffs and to jump to the corresponding
  48 ;;   (i.e. new or old) file.
  49 ;; - Handle `diff -b' output in context->unified.
  50
  51 ;; Low priority:
  52 ;; - Spice up the minor-mode with font-lock support.
  53 ;; - Recognize pcl-cvs' special string for `cvs-execute-single'.
  54
  55 ;;; Code:
  56
  57 (eval-when-compile (require 'cl))
  58
  59
  60 (defgroup diff-mode ()
  61   "Major mode for viewing/editing diffs"
  62   :version "21.1"
  63   :group 'tools
  64   :group 'diff)
  65
  66 (defcustom diff-default-read-only t
  67   "If non-nil, `diff-mode' buffers default to being read-only."
  68   :type 'boolean
  69   :group 'diff-mode)
  70
  71 (defcustom diff-jump-to-old-file nil
  72   "*Non-nil means `diff-goto-source' jumps to the old file.
  73 Else, it jumps to the new file."
  74   :type '(boolean))
  75
  76 (defcustom diff-update-on-the-fly t
  77   "*Non-nil means hunk headers are kept up-to-date on-the-fly.
  78 When editing a diff file, the line numbers in the hunk headers
  79 need to be kept consistent with the actual diff.  This can
  80 either be done on the fly (but this sometimes interacts poorly with the
  81 undo mechanism) or whenever the file is written (can be slow
  82 when editing big diffs)."
  83   :type '(boolean))
  84
  85 (defcustom diff-advance-after-apply-hunk t
  86   "*Non-nil means `diff-apply-hunk' will move to the next hunk after applying."
  87   :type 'boolean)
  88
  89
  90 (defvar diff-mode-hook nil
  91   "Run after setting up the `diff-mode' major mode.")
  92
  93 (defvar diff-outline-regexp
  94   "\\([*+][*+][*+] [^0-9]\\|@@ ...\\|\\*\\*\\* [0-9].\\|--- [0-9]..\\)")
  95
  96 ;;;;
  97 ;;;; keymap, menu, ...
  98 ;;;;
  99
 100 (easy-mmode-defmap diff-mode-shared-map
 101   '(;; From Pavel Machek's patch-mode.
 102     ("n" . diff-hunk-next)
 103     ("N" . diff-file-next)
 104     ("p" . diff-hunk-prev)
 105     ("P" . diff-file-prev)
 106     ("k" . diff-hunk-kill)
 107     ("K" . diff-file-kill)
 108     ;; From compilation-minor-mode.
 109     ("}" . diff-file-next)
 110     ("{" . diff-file-prev)
 111     ("\C-m" . diff-goto-source)
 112     ([mouse-2] . diff-mouse-goto-source)
 113     ;; From XEmacs' diff-mode.
 114     ("W" . widen)
 115     ;;("." . diff-goto-source)          ;display-buffer
 116     ;;("f" . diff-goto-source)          ;find-file
 117     ("o" . diff-goto-source)            ;other-window
 118     ;;("w" . diff-goto-source)          ;other-frame
 119     ;;("N" . diff-narrow)
 120     ;;("h" . diff-show-header)
 121     ;;("j" . diff-show-difference)      ;jump to Nth diff
 122     ;;("q" . diff-quit)
 123     (" " . scroll-up)
 124     ("\177" . scroll-down)
 125     ;; Our very own bindings.
 126     ("A" . diff-ediff-patch)
 127     ("r" . diff-restrict-view)
 128     ("R" . diff-reverse-direction)
 129     ("U" . diff-context->unified)
 130     ("C" . diff-unified->context))
 131   "Basic keymap for `diff-mode', bound to various prefix keys.")
 132
 133 (easy-mmode-defmap diff-mode-map
 134   `(("\e" . ,diff-mode-shared-map)
 135     ;; From compilation-minor-mode.
 136     ("\C-c\C-c" . diff-goto-source)
 137     ;; Misc operations.
 138     ("\C-c\C-s" . diff-split-hunk)
 139     ("\C-c\C-a" . diff-apply-hunk)
 140     ("\C-c\C-t" . diff-test-hunk))
 141   "Keymap for `diff-mode'.  See also `diff-mode-shared-map'.")
 142
 143 (easy-menu-define diff-mode-menu diff-mode-map
 144   "Menu for `diff-mode'."
 145   '("Diff"
 146     ["Jump to Source"           diff-goto-source        t]
 147     ["Apply hunk"               diff-apply-hunk         t]
 148     ["Apply diff with Ediff"    diff-ediff-patch        t]
 149     ["-----" nil nil]
 150     ["Reverse direction"        diff-reverse-direction  t]
 151     ["Context -> Unified"       diff-context->unified   t]
 152     ["Unified -> Context"       diff-unified->context   t]
 153     ;;["Fixup Headers"          diff-fixup-modifs       (not buffer-read-only)]
 154     ))
 155
 156 (defcustom diff-minor-mode-prefix "\C-c="
 157   "Prefix key for `diff-minor-mode' commands."
 158   :type '(choice (string "\e") (string "C-c=") string))
 159
 160 (easy-mmode-defmap diff-minor-mode-map
 161   `((,diff-minor-mode-prefix . ,diff-mode-shared-map))
 162   "Keymap for `diff-minor-mode'.  See also `diff-mode-shared-map'.")
 163
 164
 165 ;;;;
 166 ;;;; font-lock support
 167 ;;;;
 168
 169 (defface diff-header-face
 170   '((((type tty pc) (class color) (background light))
 171      (:foreground "blue1" :weight bold))
 172     (((type tty pc) (class color) (background dark))
 173      (:foreground "green" :weight bold))
 174     (((class color) (background light))
 175      (:background "grey85"))
 176     (((class color) (background dark))
 177      (:background "grey45"))
 178     (t (:weight bold)))
 179   "`diff-mode' face inherited by hunk and index header faces.")
 180 (defvar diff-header-face 'diff-header-face)
 181
 182 (defface diff-file-header-face
 183   '((((type tty pc) (class color) (background light))
 184      (:foreground "yellow" :weight bold))
 185     (((type tty pc) (class color) (background dark))
 186      (:foreground "cyan" :weight bold))
 187     (((class color) (background light))
 188      (:background "grey70" :weight bold))
 189     (((class color) (background dark))
 190      (:background "grey60" :weight bold))
 191     (t (:weight bold)))                 ; :height 1.3
 192   "`diff-mode' face used to highlight file header lines.")
 193 (defvar diff-file-header-face 'diff-file-header-face)
 194
 195 (defface diff-index-face
 196   '((t (:inherit diff-file-header-face)))
 197   "`diff-mode' face used to highlight index header lines.")
 198 (defvar diff-index-face 'diff-index-face)
 199
 200 (defface diff-hunk-header-face
 201   '((t (:inherit diff-header-face)))
 202   "`diff-mode' face used to highlight hunk header lines.")
 203 (defvar diff-hunk-header-face 'diff-hunk-header-face)
 204
 205 (defface diff-removed-face
 206   '((t (:inherit diff-changed-face)))
 207   "`diff-mode' face used to highlight removed lines.")
 208 (defvar diff-removed-face 'diff-removed-face)
 209
 210 (defface diff-added-face
 211   '((t (:inherit diff-changed-face)))
 212   "`diff-mode' face used to highlight added lines.")
 213 (defvar diff-added-face 'diff-added-face)
 214
 215 (defface diff-changed-face
 216   '((((type tty pc) (class color) (background light))
 217      (:foreground "magenta" :weight bold :slant italic))
 218     (((type tty pc) (class color) (background dark))
 219      (:foreground "yellow" :weight bold :slant italic))
 220     (t ()))
 221   "`diff-mode' face used to highlight changed lines.")
 222 (defvar diff-changed-face 'diff-changed-face)
 223
 224 (defface diff-function-face
 225   '((t (:inherit diff-context-face)))
 226   "`diff-mode' face used to highlight function names produced by \"diff -p\".")
 227 (defvar diff-function-face 'diff-function-face)
 228
 229 (defface diff-context-face
 230   '((((class color) (background light))
 231      (:foreground "grey50"))
 232     (((class color) (background dark))
 233      (:foreground "grey70"))
 234     (t ))
 235   "`diff-mode' face used to highlight context and other side-information.")
 236 (defvar diff-context-face 'diff-context-face)
 237
 238 (defface diff-nonexistent-face
 239   '((t (:inherit diff-file-header-face)))
 240   "`diff-mode' face used to highlight nonexistent files in recursive diffs.")
 241 (defvar diff-nonexistent-face 'diff-nonexistent-face)
 242
 243 (defvar diff-font-lock-keywords
 244   '(("^\\(@@ -[0-9,]+ \\+[0-9,]+ @@\\)\\(.*\\)$" ;unified
 245      (1 diff-hunk-header-face)
 246      (2 diff-function-face))
 247     ("^--- .+ ----$" . diff-hunk-header-face) ;context
 248     ("^\\(\\*\\{15\\}\\)\\(.*\\)$"      ;context
 249      (1 diff-hunk-header-face)
 250      (2 diff-function-face))
 251     ("^\\*\\*\\* .+ \\*\\*\\*\\*". diff-hunk-header-face) ;context
 252     ("^\\(---\\|\\+\\+\\+\\|\\*\\*\\*\\) \\(\\S-+\\)\\(.*[^*-]\\)?\n"
 253      (0 diff-header-face) (2 diff-file-header-face prepend))
 254     ("^[0-9,]+[acd][0-9,]+$" . diff-hunk-header-face)
 255     ("^!.*\n" . diff-changed-face)      ;context
 256     ("^[+>].*\n" . diff-added-face)
 257     ("^[-<].*\n" . diff-removed-face)
 258     ("^Index: \\(.+\\).*\n" (0 diff-header-face) (1 diff-index-face prepend))
 259     ("^Only in .*\n" . diff-nonexistent-face)
 260     ("^#.*" . font-lock-string-face)
 261     ("^[^-=+*!<>].*\n" . diff-context-face)))
 262
 263 (defconst diff-font-lock-defaults
 264   '(diff-font-lock-keywords t nil nil nil (font-lock-multiline . nil)))
 265
 266 (defvar diff-imenu-generic-expression
 267   ;; Prefer second name as first is most likely to be a backup or
 268   ;; version-control name.  The [\t\n] at the end of the unidiff pattern
 269   ;; catches Debian source diff files (which lack the trailing date).
 270   '((nil "\\+\\+\\+\\ \\([^\t\n]+\\)[\t\n]" 1) ; unidiffs
 271     (nil "^--- \\([^\t\n]+\\)\t.*\n\\*" 1))) ; context diffs
 272
 273 ;;;;
 274 ;;;; Compile support
 275 ;;;;
 276
 277 (defvar diff-file-regexp-alist
 278   '(("Index: \\(.+\\)" 1)))
 279
 280 (defvar diff-error-regexp-alist
 281   '(("@@ -\\([0-9]+\\),[0-9]+ \\+\\([0-9]+\\),[0-9]+ @@" nil 2)
 282     ("--- \\([0-9]+\\),[0-9]+ ----" nil 1)
 283     ("\\([0-9]+\\)\\(,[0-9]+\\)?[adc]\\([0-9]+\\)" nil 3)))
 284
 285 ;;;;
 286 ;;;; Movement
 287 ;;;;
 288
 289 (defconst diff-hunk-header-re "^\\(@@ -[0-9,]+ \\+[0-9,]+ @@.*\\|\\*\\{15\\}.*\n\\*\\*\\* .+ \\*\\*\\*\\*\\|[0-9]+\\(,[0-9]+\\)?[acd][0-9]+\\(,[0-9]+\\)?\\)$")
 290 (defconst diff-file-header-re (concat "^\\(--- .+\n\\+\\+\\+\\|\\*\\*\\* .+\n---\\|[^-+!<>0-9@* ]\\).+\n" (substring diff-hunk-header-re 1)))
 291 (defvar diff-narrowed-to nil)
 292
 293 (defun diff-end-of-hunk (&optional style)
 294   (if (looking-at diff-hunk-header-re) (goto-char (match-end 0)))
 295   (let ((end (and (re-search-forward (case style
 296                                        ;; A `unified' header is ambiguous.
 297                                        (unified (concat "^[^-+# \\]\\|"
 298                                                         diff-file-header-re))
 299                                        (context "^[^-+#! \\]")
 300                                        (normal "^[^<>#\\]")
 301                                        (t "^[^-+#!<> \\]"))
 302                                      nil t)
 303                   (match-beginning 0))))
 304     ;; The return value is used by easy-mmode-define-navigation.
 305     (goto-char (or end (point-max)))))
 306
 307 (defun diff-beginning-of-hunk ()
 308   (beginning-of-line)
 309   (unless (looking-at diff-hunk-header-re)
 310     (forward-line 1)
 311     (condition-case ()
 312         (re-search-backward diff-hunk-header-re)
 313       (error (error "Can't find the beginning of the hunk")))))
 314
 315 (defun diff-beginning-of-file ()
 316   (beginning-of-line)
 317   (unless (looking-at diff-file-header-re)
 318     (forward-line 2)
 319     (condition-case ()
 320         (re-search-backward diff-file-header-re)
 321       (error (error "Can't find the beginning of the file")))))
 322
 323 (defun diff-end-of-file ()
 324   (re-search-forward "^[-+#!<>0-9@* \\]" nil t)
 325   (re-search-forward "^[^-+#!<>0-9@* \\]" nil 'move)
 326   (beginning-of-line))
 327
 328 ;; Define diff-{hunk,file}-{prev,next}
 329 (easy-mmode-define-navigation
 330  diff-hunk diff-hunk-header-re "hunk" diff-end-of-hunk)
 331 (easy-mmode-define-navigation
 332  diff-file diff-file-header-re "file" diff-end-of-hunk)
 333
 334 (defun diff-restrict-view (&optional arg)
 335   "Restrict the view to the current hunk.
 336 If the prefix ARG is given, restrict the view to the current file instead."
 337   (interactive "P")
 338   (save-excursion
 339     (if arg (diff-beginning-of-file) (diff-beginning-of-hunk))
 340     (narrow-to-region (point)
 341                       (progn (if arg (diff-end-of-file) (diff-end-of-hunk))
 342                              (point)))
 343     (set (make-local-variable 'diff-narrowed-to) (if arg 'file 'hunk))))
 344
 345
 346 (defun diff-hunk-kill ()
 347   "Kill current hunk."
 348   (interactive)
 349   (diff-beginning-of-hunk)
 350   (let* ((start (point))
 351          (nexthunk (ignore-errors (diff-hunk-next) (point)))
 352          (firsthunk (ignore-errors
 353                       (goto-char start)
 354                       (diff-beginning-of-file) (diff-hunk-next) (point)))
 355          (nextfile (ignore-errors (diff-file-next) (point))))
 356     (goto-char start)
 357     (if (and firsthunk (= firsthunk start)
 358              (or (null nexthunk)
 359                  (and nextfile (> nexthunk nextfile))))
 360         ;; It's the only hunk for this file, so kill the file.
 361         (diff-file-kill)
 362       (diff-end-of-hunk)
 363       (kill-region start (point)))))
 364
 365 (defun diff-file-kill ()
 366   "Kill current file's hunks."
 367   (interactive)
 368   (diff-beginning-of-file)
 369   (let* ((start (point))
 370          (prevhunk (save-excursion
 371                      (ignore-errors
 372                        (diff-hunk-prev) (point))))
 373          (index (save-excursion
 374                   (re-search-backward "^Index: " prevhunk t))))
 375     (when index (setq start index))
 376     (diff-end-of-file)
 377     (kill-region start (point))))
 378
 379 (defun diff-kill-junk ()
 380   "Kill spurious empty diffs."
 381   (interactive)
 382   (save-excursion
 383     (let ((inhibit-read-only t))
 384       (goto-char (point-min))
 385       (while (re-search-forward (concat "^\\(Index: .*\n\\)"
 386                                         "\\([^-+!* <>].*\n\\)*?"
 387                                         "\\(\\(Index:\\) \\|"
 388                                         diff-file-header-re "\\)")
 389                                 nil t)
 390         (delete-region (if (match-end 4) (match-beginning 0) (match-end 1))
 391                        (match-beginning 3))
 392         (beginning-of-line)))))
 393
 394 (defun diff-count-matches (re start end)
 395   (save-excursion
 396     (let ((n 0))
 397       (goto-char start)
 398       (while (re-search-forward re end t) (incf n))
 399       n)))
 400
 401 (defun diff-split-hunk ()
 402   "Split the current (unified diff) hunk at point into two hunks."
 403   (interactive)
 404   (beginning-of-line)
 405   (let ((pos (point))
 406         (start (progn (diff-beginning-of-hunk) (point))))
 407     (unless (looking-at "@@ -\\([0-9]+\\),[0-9]+ \\+\\([0-9]+\\),[0-9]+ @@")
 408       (error "diff-split-hunk only works on unified context diffs"))
 409     (forward-line 1)
 410     (let* ((start1 (string-to-number (match-string 1)))
 411            (start2 (string-to-number (match-string 2)))
 412            (newstart1 (+ start1 (diff-count-matches "^[- \t]" (point) pos)))
 413            (newstart2 (+ start2 (diff-count-matches "^[+ \t]" (point) pos))))
 414       (goto-char pos)
 415       ;; Hopefully the after-change-function will not screw us over.
 416       (insert "@@ -" (number-to-string newstart1) ",1 +"
 417               (number-to-string newstart2) ",1 @@\n")
 418       ;; Fix the original hunk-header.
 419       (diff-fixup-modifs start pos))))
 420
 421
 422 ;;;;
 423 ;;;; jump to other buffers
 424 ;;;;
 425
 426 (defvar diff-remembered-files-alist nil)
 427
 428 (defun diff-filename-drop-dir (file)
 429   (when (string-match "/" file) (substring file (match-end 0))))
 430
 431 (defun diff-merge-strings (ancestor from to)
 432   "Merge the diff between ANCESTOR and FROM into TO.
 433 Returns the merged string if successful or nil otherwise.
 434 The strings are assumed not to contain any \"\\n\" (i.e. end of line).
 435 If ANCESTOR = FROM, returns TO.
 436 If ANCESTOR = TO, returns FROM.
 437 The heuristic is simplistic and only really works for cases
 438 like \(diff-merge-strings \"b/foo\" \"b/bar\" \"/a/c/foo\")."
 439   ;; Ideally, we want:
 440   ;;   AMB ANB CMD -> CND
 441   ;; but that's ambiguous if `foo' or `bar' is empty:
 442   ;; a/foo a/foo1 b/foo.c -> b/foo1.c but not 1b/foo.c or b/foo.c1
 443   (let ((str (concat ancestor "\n" from "\n" to)))
 444     (when (and (string-match (concat
 445                               "\\`\\(.*?\\)\\(.*\\)\\(.*\\)\n"
 446                               "\\1\\(.*\\)\\3\n"
 447                               "\\(.*\\(\\2\\).*\\)\\'") str)
 448                (equal to (match-string 5 str)))
 449       (concat (substring str (match-beginning 5) (match-beginning 6))
 450               (match-string 4 str)
 451               (substring str (match-end 6) (match-end 5))))))
 452
 453 (defun diff-find-file-name (&optional old)
 454   "Return the file corresponding to the current patch.
 455 Non-nil OLD means that we want the old file."
 456   (save-excursion
 457     (unless (looking-at diff-file-header-re)
 458       (or (ignore-errors (diff-beginning-of-file))
 459           (re-search-forward diff-file-header-re nil t)))
 460     (let* ((limit (save-excursion
 461                    (condition-case ()
 462                        (progn (diff-hunk-prev) (point))
 463                      (error (point-min)))))
 464            (header-files
 465             (if (looking-at "[-*][-*][-*] \\(\\S-+\\)\\(\\s-.*\\)?\n[-+][-+][-+] \\(\\S-+\\)")
 466                 (list (if old (match-string 1) (match-string 3))
 467                       (if old (match-string 3) (match-string 1)))
 468               (forward-line 1) nil))
 469            (fs (append
 470                 (when (save-excursion
 471                         (re-search-backward "^Index: \\(.+\\)" limit t))
 472                   (list (match-string 1)))
 473                 header-files
 474                 (when (re-search-backward "^diff \\(-\\S-+ +\\)*\\(\\S-+\\)\\( +\\(\\S-+\\)\\)?" nil t)
 475                   (list (if old (match-string 2) (match-string 4))
 476                         (if old (match-string 4) (match-string 2))))))
 477            (fs (delq nil fs)))
 478       (or
 479        ;; use any previously used preference
 480        (cdr (assoc fs diff-remembered-files-alist))
 481        ;; try to be clever and use previous choices as an inspiration
 482        (dolist (rf diff-remembered-files-alist)
 483          (let ((newfile (diff-merge-strings (caar rf) (car fs) (cdr rf))))
 484            (if (and newfile (file-exists-p newfile)) (return newfile))))
 485        ;; look for each file in turn.  If none found, try again but
 486        ;; ignoring the first level of directory, ...
 487        (do* ((files fs (delq nil (mapcar 'diff-filename-drop-dir files)))
 488              (file nil nil))
 489            ((or (null files)
 490                 (setq file (do* ((files files (cdr files))
 491                                  (file (car files) (car files)))
 492                                ((or (null file) (file-exists-p file))
 493                                 file))))
 494             file))
 495        ;; <foo>.rej patches implicitly apply to <foo>
 496        (and (string-match "\\.rej\\'" (or buffer-file-name ""))
 497             (let ((file (substring buffer-file-name 0 (match-beginning 0))))
 498               (when (file-exists-p file) file)))
 499        ;; if all else fails, ask the user
 500        (let ((file (read-file-name (format "Use file %s: " (or (first fs) ""))
 501                                    nil (first fs) t (first fs))))
 502          (set (make-local-variable 'diff-remembered-files-alist)
 503               (cons (cons fs file) diff-remembered-files-alist))
 504          file)))))
 505
 506
 507 (defun diff-mouse-goto-source (event)
 508   "Run `diff-goto-source' for the diff at a mouse click."
 509   (interactive "e")
 510   (save-excursion
 511     (mouse-set-point event)
 512     (diff-goto-source)))
 513
 514
 515 (defun diff-ediff-patch ()
 516   "Call `ediff-patch-file' on the current buffer."
 517   (interactive)
 518   (condition-case err
 519       (ediff-patch-file nil (current-buffer))
 520     (wrong-number-of-arguments (ediff-patch-file))))
 521
 522 ;;;;
 523 ;;;; Conversion functions
 524 ;;;;
 525
 526 ;;(defvar diff-inhibit-after-change nil
 527 ;;  "Non-nil means inhibit `diff-mode's after-change functions.")
 528
 529 (defun diff-unified->context (start end)
 530   "Convert unified diffs to context diffs.
 531 START and END are either taken from the region (if a prefix arg is given) or
 532 else cover the whole bufer."
 533   (interactive (if current-prefix-arg
 534                    (list (mark) (point))
 535                  (list (point-min) (point-max))))
 536   (unless (markerp end) (setq end (copy-marker end)))
 537   (let (;;(diff-inhibit-after-change t)
 538         (inhibit-read-only t))
 539     (save-excursion
 540       (goto-char start)
 541       (while (and (re-search-forward "^\\(\\(---\\) .+\n\\(\\+\\+\\+\\) .+\\|@@ -\\([0-9]+\\),\\([0-9]+\\) \\+\\([0-9]+\\),\\([0-9]+\\) @@.*\\)$" nil t)
 542                   (< (point) end))
 543         (combine-after-change-calls
 544           (if (match-beginning 2)
 545               ;; we matched a file header
 546               (progn
 547                 ;; use reverse order to make sure the indices are kept valid
 548                 (replace-match "---" t t nil 3)
 549                 (replace-match "***" t t nil 2))
 550             ;; we matched a hunk header
 551             (let ((line1 (match-string 4))
 552                   (lines1 (match-string 5))
 553                   (line2 (match-string 6))
 554                   (lines2 (match-string 7)))
 555               (replace-match
 556                (concat "***************\n*** " line1 ","
 557                        (number-to-string (+ (string-to-number line1)
 558                                             (string-to-number lines1)
 559                                             -1)) " ****"))
 560               (forward-line 1)
 561               (save-restriction
 562                 (narrow-to-region (point)
 563                                   (progn (diff-end-of-hunk 'unified) (point)))
 564                 (let ((hunk (buffer-string)))
 565                   (goto-char (point-min))
 566                   (if (not (save-excursion (re-search-forward "^-" nil t)))
 567                       (delete-region (point) (point-max))
 568                     (goto-char (point-max))
 569                     (let ((modif nil) last-pt)
 570                       (while (progn (setq last-pt (point))
 571                                     (= (forward-line -1) 0))
 572                         (case (char-after)
 573                           (?  (insert " ") (setq modif nil) (backward-char 1))
 574                           (?+ (delete-region (point) last-pt) (setq modif t))
 575                           (?- (if (not modif)
 576                                   (progn (forward-char 1)
 577                                          (insert " "))
 578                                 (delete-char 1)
 579                                 (insert "! "))
 580                               (backward-char 2))
 581                           (?\\ (when (save-excursion (forward-line -1)
 582                                                      (= (char-after) ?+))
 583                                  (delete-region (point) last-pt) (setq modif t)))
 584                           (t (setq modif nil))))))
 585                   (goto-char (point-max))
 586                   (save-excursion
 587                     (insert "--- " line2 ","
 588                             (number-to-string (+ (string-to-number line2)
 589                                                  (string-to-number lines2)
 590                                                  -1)) " ----\n" hunk))
 591                   ;;(goto-char (point-min))
 592                   (forward-line 1)
 593                   (if (not (save-excursion (re-search-forward "^+" nil t)))
 594                       (delete-region (point) (point-max))
 595                     (let ((modif nil) (delete nil))
 596                       (while (not (eobp))
 597                         (case (char-after)
 598                           (?  (insert " ") (setq modif nil) (backward-char 1))
 599                           (?- (setq delete t) (setq modif t))
 600                           (?+ (if (not modif)
 601                                   (progn (forward-char 1)
 602                                          (insert " "))
 603                                 (delete-char 1)
 604                                 (insert "! "))
 605                               (backward-char 2))
 606                           (?\\ (when (save-excursion (forward-line 1)
 607                                                      (not (eobp)))
 608                                  (setq delete t) (setq modif t)))
 609                           (t (setq modif nil)))
 610                         (let ((last-pt (point)))
 611                           (forward-line 1)
 612                           (when delete
 613                             (delete-region last-pt (point))
 614                             (setq delete nil)))))))))))))))
 615
 616 (defun diff-context->unified (start end)
 617   "Convert context diffs to unified diffs.
 618 START and END are either taken from the region (if a prefix arg is given) or
 619 else cover the whole bufer."
 620   (interactive (if current-prefix-arg
 621                    (list (mark) (point))
 622                  (list (point-min) (point-max))))
 623   (unless (markerp end) (setq end (copy-marker end)))
 624   (let (;;(diff-inhibit-after-change t)
 625         (inhibit-read-only t))
 626     (save-excursion
 627       (goto-char start)
 628       (while (and (re-search-forward "^\\(\\(\\*\\*\\*\\) .+\n\\(---\\) .+\\|\\*\\{15\\}.*\n\\*\\*\\* \\([0-9]+\\),\\(-?[0-9]+\\) \\*\\*\\*\\*\\)$" nil t)
 629                   (< (point) end))
 630         (combine-after-change-calls
 631           (if (match-beginning 2)
 632               ;; we matched a file header
 633               (progn
 634                 ;; use reverse order to make sure the indices are kept valid
 635                 (replace-match "+++" t t nil 3)
 636                 (replace-match "---" t t nil 2))
 637             ;; we matched a hunk header
 638             (let ((line1s (match-string 4))
 639                   (line1e (match-string 5))
 640                   (pt1 (match-beginning 0)))
 641               (replace-match "")
 642               (unless (re-search-forward
 643                        "^--- \\([0-9]+\\),\\(-?[0-9]+\\) ----$" nil t)
 644                 (error "Can't find matching `--- n1,n2 ----' line"))
 645               (let ((line2s (match-string 1))
 646                     (line2e (match-string 2))
 647                     (pt2 (progn
 648                            (delete-region (progn (beginning-of-line) (point))
 649                                           (progn (forward-line 1) (point)))
 650                            (point-marker))))
 651                 (goto-char pt1)
 652                 (forward-line 1)
 653                 (while (< (point) pt2)
 654                   (case (char-after)
 655                     ((?! ?-) (delete-char 2) (insert "-") (forward-line 1))
 656                     (?\                 ;merge with the other half of the chunk
 657                      (let* ((endline2
 658                              (save-excursion
 659                                (goto-char pt2) (forward-line 1) (point)))
 660                             (c (char-after pt2)))
 661                        (case c
 662                          ((?! ?+)
 663                           (insert "+"
 664                                   (prog1 (buffer-substring (+ pt2 2) endline2)
 665                                     (delete-region pt2 endline2))))
 666                          (?\            ;FIXME: check consistency
 667                           (delete-region pt2 endline2)
 668                           (delete-char 1)
 669                           (forward-line 1))
 670                          (?\\ (forward-line 1))
 671                          (t (delete-char 1) (forward-line 1)))))
 672                     (t (forward-line 1))))
 673                 (while (looking-at "[+! ] ")
 674                   (if (/= (char-after) ?!) (forward-char 1)
 675                     (delete-char 1) (insert "+"))
 676                   (delete-char 1) (forward-line 1))
 677                 (save-excursion
 678                   (goto-char pt1)
 679                   (insert "@@ -" line1s ","
 680                           (number-to-string (- (string-to-number line1e)
 681                                                (string-to-number line1s)
 682                                                -1))
 683                           " +" line2s ","
 684                           (number-to-string (- (string-to-number line2e)
 685                                                (string-to-number line2s)
 686                                                -1)) " @@"))))))))))
 687
 688 (defun diff-reverse-direction (start end)
 689   "Reverse the direction of the diffs.
 690 START and END are either taken from the region (if a prefix arg is given) or
 691 else cover the whole bufer."
 692   (interactive (if current-prefix-arg
 693                    (list (mark) (point))
 694                  (list (point-min) (point-max))))
 695   (unless (markerp end) (setq end (copy-marker end)))
 696   (let (;;(diff-inhibit-after-change t)
 697         (inhibit-read-only t))
 698     (save-excursion
 699       (goto-char start)
 700       (while (and (re-search-forward "^\\(\\([-*][-*][-*] \\)\\(.+\\)\n\\([-+][-+][-+] \\)\\(.+\\)\\|\\*\\{15\\}.*\n\\*\\*\\* \\(.+\\) \\*\\*\\*\\*\\|@@ -\\([0-9,]+\\) \\+\\([0-9,]+\\) @@.*\\)$" nil t)
 701                   (< (point) end))
 702         (combine-after-change-calls
 703           (cond
 704            ;; a file header
 705            ((match-beginning 2) (replace-match "\\2\\5\n\\4\\3" nil))
 706            ;; a context-diff hunk header
 707            ((match-beginning 6)
 708             (let ((pt-lines1 (match-beginning 6))
 709                   (lines1 (match-string 6)))
 710               (replace-match "" nil nil nil 6)
 711               (forward-line 1)
 712               (let ((half1s (point)))
 713                 (while (looking-at "[-! \\][ \t]\\|#")
 714                   (when (= (char-after) ?-) (delete-char 1) (insert "+"))
 715                   (forward-line 1))
 716                 (let ((half1 (delete-and-extract-region half1s (point))))
 717                   (unless (looking-at "^--- \\([0-9]+,-?[0-9]+\\) ----$")
 718                     (insert half1)
 719                     (error "Can't find matching `--- n1,n2 ----' line"))
 720                   (let ((str1 (match-string 1)))
 721                     (replace-match lines1 nil nil nil 1)
 722                     (forward-line 1)
 723                     (let ((half2s (point)))
 724                       (while (looking-at "[!+ \\][ \t]\\|#")
 725                         (when (= (char-after) ?+) (delete-char 1) (insert "-"))
 726                         (forward-line 1))
 727                       (let ((half2 (delete-and-extract-region half2s (point))))
 728                         (insert (or half1 ""))
 729                         (goto-char half1s)
 730                         (insert (or half2 ""))))
 731                     (goto-char pt-lines1)
 732                     (insert str1))))))
 733            ;; a unified-diff hunk header
 734            ((match-beginning 7)
 735             (replace-match "@@ -\\8 +\\7 @@" nil)
 736             (forward-line 1)
 737             (let ((c (char-after)) first last)
 738               (while (case (setq c (char-after))
 739                        (?- (setq first (or first (point)))
 740                            (delete-char 1) (insert "+") t)
 741                        (?+ (setq last (or last (point)))
 742                            (delete-char 1) (insert "-") t)
 743                        ((?\\ ?#) t)
 744                        (t (when (and first last (< first last))
 745                             (let ((str
 746                                    (save-excursion
 747                                      (delete-and-extract-region first last))))
 748                               (insert str)))
 749                           (setq first nil last nil)
 750                           (equal ?\  c)))
 751                 (forward-line 1))))))))))
 752
 753 (defun diff-fixup-modifs (start end)
 754   "Fixup the hunk headers (in case the buffer was modified).
 755 START and END are either taken from the region (if a prefix arg is given) or
 756 else cover the whole bufer."
 757   (interactive (if current-prefix-arg
 758                    (list (mark) (point))
 759                  (list (point-min) (point-max))))
 760   (let ((inhibit-read-only t))
 761     (save-excursion
 762       (goto-char end) (diff-end-of-hunk)
 763       (let ((plus 0) (minus 0) (space 0) (bang 0))
 764         (while (and (= (forward-line -1) 0) (<= start (point)))
 765           (if (not (looking-at "\\(@@ -[0-9,]+ \\+[0-9,]+ @@.*\\|[-*][-*][-*] .+ [-*][-*][-*][-*]\\)$"))
 766               (case (char-after)
 767                 (?\  (incf space))
 768                 (?+ (incf plus))
 769                 (?- (incf minus))
 770                 (?! (incf bang))
 771                 ((?\\ ?#) nil)
 772                 (t  (setq space 0 plus 0 minus 0 bang 0)))
 773             (cond
 774              ((looking-at "@@ -[0-9]+,\\([0-9]*\\) \\+[0-9]+,\\([0-9]*\\) @@.*$")
 775               (let* ((old1 (match-string 1))
 776                      (old2 (match-string 2))
 777                      (new1 (number-to-string (+ space minus)))
 778                      (new2 (number-to-string (+ space plus))))
 779                 (unless (string= new2 old2) (replace-match new2 t t nil 2))
 780                 (unless (string= new1 old1) (replace-match new1 t t nil 1))))
 781              ((looking-at "--- \\([0-9]+\\),\\([0-9]*\\) ----$")
 782               (when (> (+ space bang plus) 0)
 783                 (let* ((old1 (match-string 1))
 784                        (old2 (match-string 2))
 785                        (new (number-to-string
 786                              (+ space bang plus -1 (string-to-number old1)))))
 787                   (unless (string= new old2) (replace-match new t t nil 2)))))
 788              ((looking-at "\\*\\*\\* \\([0-9]+\\),\\(-?[0-9]*\\) \\*\\*\\*\\*$")
 789               (when (> (+ space bang minus) 0)
 790                 (let* ((old (match-string 1))
 791                        (new (format
 792                              (concat "%0" (number-to-string (length old)) "d")
 793                              (+ space bang minus -1 (string-to-number old)))))
 794                   (unless (string= new old) (replace-match new t t nil 2))))))
 795             (setq space 0 plus 0 minus 0 bang 0)))))))
 796
 797 ;;;;
 798 ;;;; Hooks
 799 ;;;;
 800
 801 (defun diff-write-contents-hooks ()
 802   "Fixup hunk headers if necessary."
 803   (if (buffer-modified-p) (diff-fixup-modifs (point-min) (point-max)))
 804   nil)
 805
 806 ;; It turns out that making changes in the buffer from within an
 807 ;; *-change-function is asking for trouble, whereas making them
 808 ;; from a post-command-hook doesn't pose much problems
 809 (defvar diff-unhandled-changes nil)
 810 (defun diff-after-change-function (beg end len)
 811   "Remember to fixup the hunk header.
 812 See `after-change-functions' for the meaning of BEG, END and LEN."
 813   ;; Ignoring changes when inhibit-read-only is set is strictly speaking
 814   ;; incorrect, but it turns out that inhibit-read-only is normally not set
 815   ;; inside editing commands, while it tends to be set when the buffer gets
 816   ;; updated by an async process or by a conversion function, both of which
 817   ;; would rather not be uselessly slowed down by this hook.
 818   (when (and (not undo-in-progress) (not inhibit-read-only))
 819     (if diff-unhandled-changes
 820         (setq diff-unhandled-changes
 821               (cons (min beg (car diff-unhandled-changes))
 822                     (max beg (cdr diff-unhandled-changes))))
 823       (setq diff-unhandled-changes (cons beg end)))))
 824
 825 (defun diff-post-command-hook ()
 826   "Fixup hunk headers if necessary."
 827   (when (consp diff-unhandled-changes)
 828     (ignore-errors
 829       (save-excursion
 830         (goto-char (car diff-unhandled-changes))
 831         ;; We used to fixup modifs on all the changes, but it turns out
 832         ;; that it's safer not to do it on big changes, for example
 833         ;; when yanking a big diff, since we might then screw up perfectly
 834         ;; correct values.  -stef
 835         ;; (unless (ignore-errors
 836         ;;        (diff-beginning-of-hunk)
 837         ;;        (save-excursion
 838         ;;          (diff-end-of-hunk)
 839         ;;          (> (point) (car diff-unhandled-changes))))
 840         ;;   (goto-char (car diff-unhandled-changes))
 841         ;; (re-search-forward diff-hunk-header-re (cdr diff-unhandled-changes))
 842         ;;   (diff-beginning-of-hunk))
 843         ;; (diff-fixup-modifs (point) (cdr diff-unhandled-changes))
 844         (diff-beginning-of-hunk)
 845         (when (save-excursion
 846                 (diff-end-of-hunk)
 847                 (> (point) (cdr diff-unhandled-changes)))
 848           (diff-fixup-modifs (point) (cdr diff-unhandled-changes)))))
 849     (setq diff-unhandled-changes nil)))
 850
 851 ;;;;
 852 ;;;; The main function
 853 ;;;;
 854
 855 ;;;###autoload
 856 (define-derived-mode diff-mode fundamental-mode "Diff"
 857   "Major mode for viewing/editing context diffs.
 858 Supports unified and context diffs as well as (to a lesser extent)
 859 normal diffs.
 860 When the buffer is read-only, the ESC prefix is not necessary."
 861   (set (make-local-variable 'font-lock-defaults) diff-font-lock-defaults)
 862   (set (make-local-variable 'outline-regexp) diff-outline-regexp)
 863   (set (make-local-variable 'imenu-generic-expression)
 864        diff-imenu-generic-expression)
 865   ;; These are not perfect.  They would be better done separately for
 866   ;; context diffs and unidiffs.
 867   ;; (set (make-local-variable 'paragraph-start)
 868   ;;        (concat "@@ "                       ; unidiff hunk
 869   ;;           "\\|\\*\\*\\* "          ; context diff hunk or file start
 870   ;;           "\\|--- [^\t]+\t"))      ; context or unidiff file
 871   ;;                                    ; start (first or second line)
 872   ;;   (set (make-local-variable 'paragraph-separate) paragraph-start)
 873   ;;   (set (make-local-variable 'page-delimiter) "--- [^\t]+\t")
 874   ;; compile support
 875
 876   ;;;; compile support is not good enough yet.  Also it can be annoying
 877   ;; and should thus only be enabled conditionally.
 878   ;; (set (make-local-variable 'compilation-file-regexp-alist)
 879   ;;      diff-file-regexp-alist)
 880   ;; (set (make-local-variable 'compilation-error-regexp-alist)
 881   ;;      diff-error-regexp-alist)
 882   ;; (when (string-match "\\.rej\\'" (or buffer-file-name ""))
 883   ;;   (set (make-local-variable 'compilation-current-file)
 884   ;;     (substring buffer-file-name 0 (match-beginning 0))))
 885   ;; (compilation-shell-minor-mode 1)
 886
 887   (when (and (> (point-max) (point-min)) diff-default-read-only)
 888     (toggle-read-only t))
 889   ;; setup change hooks
 890   (if (not diff-update-on-the-fly)
 891       (add-hook 'write-contents-hooks 'diff-write-contents-hooks)
 892     (make-local-variable 'diff-unhandled-changes)
 893     (add-hook 'after-change-functions 'diff-after-change-function nil t)
 894     (add-hook 'post-command-hook 'diff-post-command-hook nil t))
 895   ;; Neat trick from Dave Love to add more bindings in read-only mode:
 896   (add-to-list (make-local-variable 'minor-mode-overriding-map-alist)
 897                (cons 'buffer-read-only diff-mode-shared-map))
 898   ;; add-log support
 899   (set (make-local-variable 'add-log-current-defun-function)
 900        'diff-current-defun)
 901   (set (make-local-variable 'add-log-buffer-file-name-function)
 902        'diff-find-file-name))
 903
 904 ;;;###autoload
 905 (define-minor-mode diff-minor-mode
 906   "Minor mode for viewing/editing context diffs.
 907 \\{diff-minor-mode-map}"
 908   nil " Diff" nil
 909   ;; FIXME: setup font-lock
 910   ;; setup change hooks
 911   (if (not diff-update-on-the-fly)
 912       (add-hook 'write-contents-hooks 'diff-write-contents-hooks)
 913     (make-local-variable 'diff-unhandled-changes)
 914     (add-hook 'after-change-functions 'diff-after-change-function nil t)
 915     (add-hook 'post-command-hook 'diff-post-command-hook nil t)))
 916
 917
 918 ;;;
 919 ;;; Misc operations that have proved useful at some point.
 920 ;;;
 921
 922 (defun diff-next-complex-hunk ()
 923   "Jump to the next \"complex\" hunk.
 924 \"Complex\" is approximated by \"the hunk changes the number of lines\".
 925 Only works for unified diffs."
 926   (interactive)
 927   (while
 928       (and (re-search-forward "^@@ [-0-9]+,\\([0-9]+\\) [+0-9]+,\\([0-9]+\\) @@"
 929                               nil t)
 930            (equal (match-string 1) (match-string 2)))))
 931
 932 (defun diff-hunk-text (hunk destp char-offset)
 933   "Return the literal source text from HUNK as (TEXT . OFFSET).
 934 if DESTP is nil TEXT is the source, otherwise the destination text.
 935 CHAR-OFFSET is a char-offset in HUNK, and OFFSET is the corresponding
 936 char-offset in TEXT."
 937   (with-temp-buffer
 938     (insert hunk)
 939     (goto-char (point-min))
 940     (let ((src-pos nil)
 941           (dst-pos nil)
 942           (divider-pos nil)
 943           (num-pfx-chars 2))
 944       ;; Set the following variables:
 945       ;;  SRC-POS     buffer pos of the source part of the hunk or nil if none
 946       ;;  DST-POS     buffer pos of the destination part of the hunk or nil
 947       ;;  DIVIDER-POS buffer pos of any divider line separating the src & dst
 948       ;;  NUM-PFX-CHARS  number of line-prefix characters used by this format"
 949       (cond ((looking-at "^@@")
 950              ;; unified diff
 951              (setq num-pfx-chars 1)
 952              (forward-line 1)
 953              (setq src-pos (point) dst-pos (point)))
 954             ((looking-at "^\\*\\*")
 955              ;; context diff
 956              (forward-line 2)
 957              (setq src-pos (point))
 958              (re-search-forward "^--- " nil t)
 959              (forward-line 0)
 960              (setq divider-pos (point))
 961              (forward-line 1)
 962              (setq dst-pos (point)))
 963             ((looking-at "^[0-9]+a[0-9,]+$")
 964              ;; normal diff, insert
 965              (forward-line 1)
 966              (setq dst-pos (point)))
 967             ((looking-at "^[0-9,]+d[0-9]+$")
 968              ;; normal diff, delete
 969              (forward-line 1)
 970              (setq src-pos (point)))
 971             ((looking-at "^[0-9,]+c[0-9,]+$")
 972              ;; normal diff, change
 973              (forward-line 1)
 974              (setq src-pos (point))
 975              (re-search-forward "^---$" nil t)
 976              (forward-line 0)
 977              (setq divider-pos (point))
 978              (forward-line 1)
 979              (setq dst-pos (point)))
 980             (t
 981              (error "Unknown diff hunk type")))
 982
 983       (if (if destp (null dst-pos) (null src-pos))
 984           ;; Implied empty text
 985           (if char-offset '("" . 0) "")
 986
 987         ;; For context diffs, either side can be empty, (if there's only
 988         ;; added or only removed text).  We should then use the other side.
 989         (cond ((equal src-pos divider-pos) (setq src-pos dst-pos))
 990               ((equal dst-pos (point-max)) (setq dst-pos src-pos)))
 991
 992         (when char-offset (goto-char (+ (point-min) char-offset)))
 993
 994         ;; Get rid of anything except the desired text.
 995         (save-excursion
 996           ;; Delete unused text region
 997           (let ((keep (if destp dst-pos src-pos)))
 998             (when (and divider-pos (> divider-pos keep))
 999               (delete-region divider-pos (point-max)))
1000             (delete-region (point-min) keep))
1001           ;; Remove line-prefix characters, and unneeded lines (unified diffs).
1002           (let ((kill-char (if destp ?- ?+)))
1003             (goto-char (point-min))
1004             (while (not (eobp))
1005               (if (eq (char-after) kill-char)
1006                   (delete-region (point) (progn (forward-line 1) (point)))
1007                 (delete-char num-pfx-chars)
1008                 (forward-line 1)))))
1009
1010         (let ((text (buffer-substring-no-properties (point-min) (point-max))))
1011           (if char-offset (cons text (- (point) (point-min))) text))))))
1012
1013
1014 (defun diff-find-text (text)
1015   "Return the buffer position (BEG . END) of the nearest occurrence of TEXT.
1016 If TEXT isn't found, nil is returned."
1017   (let* ((orig (point))
1018          (forw (and (search-forward text nil t)
1019                     (cons (match-beginning 0) (match-end 0))))
1020          (back (and (goto-char (+ orig (length text)))
1021                     (search-backward text nil t)
1022                     (cons (match-beginning 0) (match-end 0)))))
1023     ;; Choose the closest match.
1024     (if (and forw back)
1025         (if (> (- (car forw) orig) (- orig (car back))) back forw)
1026       (or back forw))))
1027
1028 (defun diff-find-approx-text (text)
1029   "Return the buffer position (BEG . END) of the nearest occurrence of TEXT.
1030 Whitespace differences are ignored."
1031   (let* ((orig (point))
1032          (re (concat "^[ \t\n\f]*"
1033                      (mapconcat 'regexp-quote (split-string text) "[ \t\n\f]+")
1034                      "[ \t\n\f]*\n"))
1035          (forw (and (re-search-forward re nil t)
1036                     (cons (match-beginning 0) (match-end 0))))
1037          (back (and (goto-char (+ orig (length text)))
1038                     (re-search-backward re nil t)
1039                     (cons (match-beginning 0) (match-end 0)))))
1040     ;; Choose the closest match.
1041     (if (and forw back)
1042         (if (> (- (car forw) orig) (- orig (car back))) back forw)
1043       (or back forw))))
1044
1045 (defsubst diff-xor (a b) (if a (not b) b))
1046
1047 (defun diff-find-source-location (&optional other-file reverse)
1048   "Find out (BUF LINE-OFFSET POS SRC DST SWITCHED).
1049 BUF is the buffer corresponding to the source file.
1050 LINE-OFFSET is the offset between the expected and actual positions
1051   of the text of the hunk or nil if the text was not found.
1052 POS is a pair (BEG . END) indicating the position of the text in the buffer.
1053 SRC and DST are the two variants of text as returned by `diff-hunk-text'.
1054   SRC is the variant that was found in the buffer.
1055 SWITCHED is non-nil if the patch is already applied."
1056   (save-excursion
1057     (let* ((other (diff-xor other-file diff-jump-to-old-file))
1058            (char-offset (- (point) (progn (diff-beginning-of-hunk) (point))))
1059            (hunk (buffer-substring (point)
1060                                    (save-excursion (diff-end-of-hunk) (point))))
1061            (old (diff-hunk-text hunk reverse char-offset))
1062            (new (diff-hunk-text hunk (not reverse) char-offset))
1063            ;; Find the location specification.
1064            (line (if (not (looking-at "\\(?:\\*\\{15\\}.*\n\\)?[-@* ]*\\([0-9,]+\\)\\([ acd+]+\\([0-9,]+\\)\\)?"))
1065                      (error "Can't find the hunk header")
1066                    (if other (match-string 1)
1067                      (if (match-end 3) (match-string 3)
1068                        (unless (re-search-forward "^--- \\([0-9,]+\\)" nil t)
1069                          (error "Can't find the hunk separator"))
1070                        (match-string 1)))))
1071            (file (or (diff-find-file-name other) (error "Can't find the file")))
1072            (buf (find-file-noselect file)))
1073       ;; Update the user preference if he so wished.
1074       (when (> (prefix-numeric-value other-file) 8)
1075         (setq diff-jump-to-old-file other))
1076       (with-current-buffer buf
1077         (goto-line (string-to-number line))
1078         (let* ((orig-pos (point))
1079                (switched nil)
1080                (pos (or (diff-find-text (car old))
1081                         (progn (setq switched t) (diff-find-text (car new)))
1082                         (progn (setq switched nil)
1083                                (diff-find-approx-text (car old)))
1084                         (progn (setq switched t)
1085                                (diff-find-approx-text (car new)))
1086                         (progn (setq switched nil) nil))))
1087           (nconc
1088            (list buf)
1089            (if pos
1090                (list (count-lines orig-pos (car pos)) pos)
1091              (list nil (cons orig-pos (+ orig-pos (length (car old))))))
1092            (if switched (list new old t) (list old new))))))))
1093
1094
1095 (defun diff-hunk-status-msg (line-offset reversed dry-run)
1096   (let ((msg (if dry-run
1097                  (if reversed "already applied" "not yet applied")
1098                (if reversed "undone" "applied"))))
1099     (message (cond ((null line-offset) "Hunk text not found")
1100                    ((= line-offset 0) "Hunk %s")
1101                    ((= line-offset 1) "Hunk %s at offset %d line")
1102                    (t "Hunk %s at offset %d lines"))
1103              msg line-offset)))
1104
1105
1106 (defun diff-apply-hunk (&optional reverse)
1107   "Apply the current hunk to the source file and go to the next.
1108 By default, the new source file is patched, but if the variable
1109 `diff-jump-to-old-file' is non-nil, then the old source file is
1110 patched instead (some commands, such as `diff-goto-source' can change
1111 the value of this variable when given an appropriate prefix argument).
1112
1113 With a prefix argument, REVERSE the hunk."
1114   (interactive "P")
1115   (destructuring-bind (buf line-offset pos old new &optional switched)
1116       (diff-find-source-location nil reverse)
1117     (cond
1118      ((null line-offset)
1119       (error "Can't find the text to patch"))
1120      ((and switched
1121            ;; A reversed patch was detected, perhaps apply it in reverse.
1122            (not (save-window-excursion
1123                   (pop-to-buffer buf)
1124                   (goto-char (+ (car pos) (cdr old)))
1125                   (y-or-n-p
1126                    (if reverse
1127                        "Hunk hasn't been applied yet; apply it now? "
1128                      "Hunk has already been applied; undo it? ")))))
1129       (message "(Nothing done)"))
1130      (t
1131       ;; Apply the hunk
1132       (with-current-buffer buf
1133         (goto-char (car pos))
1134         (delete-region (car pos) (cdr pos))
1135         (insert (car new)))
1136       ;; Display BUF in a window
1137       (set-window-point (display-buffer buf) (+ (car pos) (cdr new)))
1138       (diff-hunk-status-msg line-offset (diff-xor switched reverse) nil)
1139       (when diff-advance-after-apply-hunk
1140         (diff-hunk-next))))))
1141
1142
1143 (defun diff-test-hunk (&optional reverse)
1144   "See whether it's possible to apply the current hunk.
1145 With a prefix argument, try to REVERSE the hunk."
1146   (interactive "P")
1147   (destructuring-bind (buf line-offset pos src dst &optional switched)
1148       (diff-find-source-location nil reverse)
1149     (set-window-point (display-buffer buf) (+ (car pos) (cdr src)))
1150     (diff-hunk-status-msg line-offset (diff-xor reverse switched) t)))
1151
1152
1153 (defun diff-goto-source (&optional other-file)
1154   "Jump to the corresponding source line.
1155 `diff-jump-to-old-file' (or its opposite if the OTHER-FILE prefix arg
1156 is given) determines whether to jump to the old or the new file.
1157 If the prefix arg is bigger than 8 (for example with \\[universal-argument] \\[universal-argument])
1158   then `diff-jump-to-old-file' is also set, for the next invocations."
1159   (interactive "P")
1160   ;; When pointing at a removal line, we probably want to jump to
1161   ;; the old location, and else to the new (i.e. as if reverting).
1162   ;; This is a convenient detail when using smerge-diff.
1163   (let ((rev (not (save-excursion (beginning-of-line) (looking-at "[-<]")))))
1164     (destructuring-bind (buf line-offset pos src dst &optional switched)
1165         (diff-find-source-location other-file rev)
1166       (pop-to-buffer buf)
1167       (goto-char (+ (car pos) (cdr src)))
1168       (diff-hunk-status-msg line-offset (diff-xor rev switched) t))))
1169
1170
1171 (defun diff-current-defun ()
1172   "Find the name of function at point.
1173 For use in `add-log-current-defun-function'."
1174   (destructuring-bind (buf line-offset pos src dst &optional switched)
1175       (diff-find-source-location)
1176     (save-excursion
1177       (beginning-of-line)
1178       (or (when (memq (char-after) '(?< ?-))
1179             ;; Cursor is pointing at removed text.  This could be a removed
1180             ;; function, in which case, going to the source buffer will
1181             ;; not help since the function is now removed.  Instead,
1182             ;; try to figure out the function name just from the code-fragment.
1183             (let ((old (if switched dst src)))
1184               (with-temp-buffer
1185                 (insert (car old))
1186                 (goto-char (cdr old))
1187                 (funcall (with-current-buffer buf major-mode))
1188                 (add-log-current-defun))))
1189           (with-current-buffer buf
1190             (goto-char (+ (car pos) (cdr src)))
1191             (add-log-current-defun))))))
1192
1193 ;; provide the package
1194 (provide 'diff-mode)
1195
1196 ;;; Old Change Log from when diff-mode wasn't part of Emacs:
1197 ;; Revision 1.11  1999/10/09 23:38:29  monnier
1198 ;; (diff-mode-load-hook): dropped.
1199 ;; (auto-mode-alist): also catch *.diffs.
1200 ;; (diff-find-file-name, diff-mode):  add smarts to find the right file
1201 ;;     for *.rej files (that lack any file name indication).
1202 ;;
1203 ;; Revision 1.10  1999/09/30 15:32:11  monnier
1204 ;; added support for "\ No newline at end of file".
1205 ;;
1206 ;; Revision 1.9  1999/09/15 00:01:13  monnier
1207 ;; - added basic `compile' support.
1208 ;; - have diff-kill-hunk call diff-kill-file if it's the only hunk.
1209 ;; - diff-kill-file now tries to kill the leading garbage as well.
1210 ;;
1211 ;; Revision 1.8  1999/09/13 21:10:09  monnier
1212 ;; - don't use CL in the autoloaded code
1213 ;; - accept diffs using -T
1214 ;;
1215 ;; Revision 1.7  1999/09/05 20:53:03  monnier
1216 ;; interface to ediff-patch
1217 ;;
1218 ;; Revision 1.6  1999/09/01 20:55:13  monnier
1219 ;; (ediff=patch-file):  add bindings to call ediff-patch.
1220 ;; (diff-find-file-name):  taken out of diff-goto-source.
1221 ;; (diff-unified->context, diff-context->unified, diff-reverse-direction,
1222 ;;  diff-fixup-modifs):  only use the region if a prefix arg is given.
1223 ;;
1224 ;; Revision 1.5  1999/08/31 19:18:52  monnier
1225 ;; (diff-beginning-of-file, diff-prev-file):  fixed wrong parenthesis.
1226 ;;
1227 ;; Revision 1.4  1999/08/31 13:01:44  monnier
1228 ;; use `combine-after-change-calls' to minimize the slowdown of font-lock.
1229 ;;
1230
1231 ;;; diff-mode.el ends here