lisp/progmodes/hideif.el

   1 ;;; hideif.el --- hides selected code within ifdef
   2
   3 ;; Copyright (C) 1988, 1994, 2001-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Brian Marick
   6 ;;      Daniel LaLiberte <liberte@holonexus.org>
   7 ;; Maintainer: FSF
   8 ;; Keywords: c, outlines
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; To initialize, toggle the hide-ifdef minor mode with
  28 ;;
  29 ;; M-x hide-ifdef-mode
  30 ;;
  31 ;; This will set up key bindings and call hide-ifdef-mode-hook if it
  32 ;; has a value.  To explicitly hide ifdefs using a buffer-local
  33 ;; define list (default empty), type
  34 ;;
  35 ;; M-x hide-ifdefs  or C-c @ h
  36 ;;
  37 ;; Hide-ifdef suppresses the display of code that the preprocessor wouldn't
  38 ;; pass through.  The support of constant expressions in #if lines is
  39 ;; limited to identifiers, parens, and the operators: &&, ||, !, and
  40 ;; "defined".  Please extend this.
  41 ;;
  42 ;; The hidden code is marked by ellipses (...).  Be
  43 ;; cautious when editing near ellipses, since the hidden text is
  44 ;; still in the buffer, and you can move the point into it and modify
  45 ;; text unawares.
  46 ;; You can make your buffer read-only while hide-ifdef-hiding by setting
  47 ;; hide-ifdef-read-only to a non-nil value.  You can toggle this
  48 ;; variable with hide-ifdef-toggle-read-only (C-c @ C-q).
  49 ;;
  50 ;; You can undo the effect of hide-ifdefs by typing
  51 ;;
  52 ;; M-x show-ifdefs  or C-c @ s
  53 ;;
  54 ;; Use M-x hide-ifdef-define (C-c @ d) to define a symbol.
  55 ;; Use M-x hide-ifdef-undef (C-c @ u) to undefine a symbol.
  56 ;;
  57 ;; If you define or undefine a symbol while hide-ifdef-mode is in effect,
  58 ;; the display will be updated.  Only the define list for the current
  59 ;; buffer will be affected.  You can save changes to the local define
  60 ;; list with hide-ifdef-set-define-alist.  This adds entries
  61 ;; to hide-ifdef-define-alist.
  62 ;;
  63 ;; If you have defined a hide-ifdef-mode-hook, you can set
  64 ;; up a list of symbols that may be used by hide-ifdefs as in the
  65 ;; following example:
  66 ;;
  67 ;; (add-hook 'hide-ifdef-mode-hook
  68 ;;      (lambda ()
  69 ;;       (unless hide-ifdef-define-alist
  70 ;;         (setq hide-ifdef-define-alist
  71 ;;              '((list1 ONE TWO)
  72 ;;                (list2 TWO THREE))))
  73 ;;       (hide-ifdef-use-define-alist 'list2))) ; use list2 by default
  74 ;;
  75 ;; You can call hide-ifdef-use-define-alist (C-c @ U) at any time to specify
  76 ;; another list to use.
  77 ;;
  78 ;; To cause ifdefs to be hidden as soon as hide-ifdef-mode is called,
  79 ;; set hide-ifdef-initially to non-nil.
  80 ;;
  81 ;; If you set hide-ifdef-lines to t, hide-ifdefs hides all the #ifdef lines.
  82 ;; In the absence of highlighting, that might be a bad idea.  If you set
  83 ;; hide-ifdef-lines to nil (the default), the surrounding preprocessor
  84 ;; lines will be displayed.  That can be confusing in its own
  85 ;; right.  Other variations on display are possible, but not much
  86 ;; better.
  87 ;;
  88 ;; You can explicitly hide or show individual ifdef blocks irrespective
  89 ;; of the define list by using hide-ifdef-block and show-ifdef-block.
  90 ;;
  91 ;; You can move the point between ifdefs with forward-ifdef, backward-ifdef,
  92 ;; up-ifdef, down-ifdef, next-ifdef, and previous-ifdef.
  93 ;;
  94 ;; If you have minor-mode-alist in your mode line (the default) two labels
  95 ;; may appear.  "Ifdef" will appear when hide-ifdef-mode is active.  "Hiding"
  96 ;; will appear when text may be hidden ("hide-ifdef-hiding" is non-nil).
  97 ;;
  98 ;; Written by Brian Marick, at Gould, Computer Systems Division, Urbana IL.
  99 ;; Extensively modified by Daniel LaLiberte (while at Gould).
 100
 101 ;;; Code:
 102
 103 (require 'cc-mode)
 104
 105 (defgroup hide-ifdef nil
 106   "Hide selected code within `ifdef'."
 107   :group 'c)
 108
 109 (defcustom hide-ifdef-initially nil
 110   "Non-nil means call `hide-ifdefs' when Hide-Ifdef mode is first activated."
 111   :type 'boolean
 112   :group 'hide-ifdef)
 113
 114 (defcustom hide-ifdef-read-only nil
 115   "Set to non-nil if you want buffer to be read-only while hiding text."
 116   :type 'boolean
 117   :group 'hide-ifdef)
 118
 119 (defcustom hide-ifdef-lines nil
 120   "Non-nil means hide the #ifX, #else, and #endif lines."
 121   :type 'boolean
 122   :group 'hide-ifdef)
 123
 124 (defcustom hide-ifdef-shadow nil
 125   "Non-nil means shadow text instead of hiding it."
 126   :type 'boolean
 127   :group 'hide-ifdef
 128   :version "23.1")
 129
 130 (defface hide-ifdef-shadow '((t (:inherit shadow)))
 131   "Face for shadowing ifdef blocks."
 132   :group 'hide-ifdef
 133   :version "23.1")
 134
 135
 136 (defvar hide-ifdef-mode-submap
 137   ;; Set up the submap that goes after the prefix key.
 138   (let ((map (make-sparse-keymap)))
 139     (define-key map "d" 'hide-ifdef-define)
 140     (define-key map "u" 'hide-ifdef-undef)
 141     (define-key map "D" 'hide-ifdef-set-define-alist)
 142     (define-key map "U" 'hide-ifdef-use-define-alist)
 143
 144     (define-key map "h" 'hide-ifdefs)
 145     (define-key map "s" 'show-ifdefs)
 146     (define-key map "\C-d" 'hide-ifdef-block)
 147     (define-key map "\C-s" 'show-ifdef-block)
 148
 149     (define-key map "\C-q" 'hide-ifdef-toggle-read-only)
 150     (define-key map "\C-w" 'hide-ifdef-toggle-shadowing)
 151     (substitute-key-definition
 152      'toggle-read-only 'hide-ifdef-toggle-outside-read-only map)
 153     map)
 154   "Keymap used by `hide-ifdef-mode' under `hide-ifdef-mode-prefix-key'.")
 155
 156 (defconst hide-ifdef-mode-prefix-key "\C-c@"
 157   "Prefix key for all Hide-Ifdef mode commands.")
 158
 159 (defvar hide-ifdef-mode-map
 160   ;; Set up the mode's main map, which leads via the prefix key to the submap.
 161   (let ((map (make-sparse-keymap)))
 162     (define-key map hide-ifdef-mode-prefix-key hide-ifdef-mode-submap)
 163     map)
 164   "Keymap used with `hide-ifdef-mode'.")
 165
 166 (easy-menu-define hide-ifdef-mode-menu hide-ifdef-mode-map
 167   "Menu for `hide-ifdef-mode'."
 168   '("Hide-Ifdef"
 169     ["Hide some ifdefs" hide-ifdefs
 170      :help "Hide the contents of some #ifdefs"]
 171     ["Show all ifdefs" show-ifdefs
 172      :help "Cancel the effects of `hide-ifdef': show the contents of all #ifdefs"]
 173     ["Hide ifdef block" hide-ifdef-block
 174      :help "Hide the ifdef block (true or false part) enclosing or before the cursor"]
 175     ["Show ifdef block" show-ifdef-block
 176      :help "Show the ifdef block (true or false part) enclosing or before the cursor"]
 177     ["Define a variable..." hide-ifdef-define
 178      :help "Define a VAR so that #ifdef VAR would be included"]
 179     ["Undefine a variable..." hide-ifdef-undef
 180      :help "Undefine a VAR so that #ifdef VAR would not be included"]
 181     ["Define an alist..." hide-ifdef-set-define-alist
 182      :help "Set the association for NAME to `hide-ifdef-env'"]
 183     ["Use an alist..." hide-ifdef-use-define-alist
 184      :help "Set `hide-ifdef-env' to the define list specified by NAME"]
 185     ["Toggle read only" hide-ifdef-toggle-read-only
 186      :style toggle :selected hide-ifdef-read-only
 187      :help "Buffer should be read-only while hiding text"]
 188     ["Toggle shadowing" hide-ifdef-toggle-shadowing
 189      :style toggle :selected hide-ifdef-shadow
 190      :help "Text should be shadowed instead of hidden"]))
 191
 192 (defvar hide-ifdef-hiding nil
 193   "Non-nil when text may be hidden.")
 194
 195 (or (assq 'hide-ifdef-hiding minor-mode-alist)
 196     (setq minor-mode-alist
 197           (cons '(hide-ifdef-hiding " Hiding")
 198                 minor-mode-alist)))
 199
 200 ;; fix c-mode syntax table so we can recognize whole symbols.
 201 (defvar hide-ifdef-syntax-table
 202   (let ((st (copy-syntax-table c-mode-syntax-table)))
 203     (modify-syntax-entry ?_ "w" st)
 204     (modify-syntax-entry ?& "." st)
 205     (modify-syntax-entry ?\| "." st)
 206     st)
 207   "Syntax table used for tokenizing #if expressions.")
 208
 209 (defvar hide-ifdef-env nil
 210   "An alist of defined symbols and their values.")
 211
 212 (defvar hif-outside-read-only nil
 213   "Internal variable.  Saves the value of `buffer-read-only' while hiding.")
 214
 215 ;;;###autoload
 216 (define-minor-mode hide-ifdef-mode
 217   "Toggle Hide-Ifdef mode.  This is a minor mode, albeit a large one.
 218 With ARG, turn Hide-Ifdef mode on if arg is positive, off otherwise.
 219 In Hide-Ifdef mode, code within #ifdef constructs that the C preprocessor
 220 would eliminate may be hidden from view.  Several variables affect
 221 how the hiding is done:
 222
 223 `hide-ifdef-env'
 224         An association list of defined and undefined symbols for the
 225         current buffer.  Initially, the global value of `hide-ifdef-env'
 226         is used.
 227
 228 `hide-ifdef-define-alist'
 229         An association list of defined symbol lists.
 230         Use `hide-ifdef-set-define-alist' to save the current `hide-ifdef-env'
 231         and `hide-ifdef-use-define-alist' to set the current `hide-ifdef-env'
 232         from one of the lists in `hide-ifdef-define-alist'.
 233
 234 `hide-ifdef-lines'
 235         Set to non-nil to not show #if, #ifdef, #ifndef, #else, and
 236         #endif lines when hiding.
 237
 238 `hide-ifdef-initially'
 239         Indicates whether `hide-ifdefs' should be called when Hide-Ifdef mode
 240         is activated.
 241
 242 `hide-ifdef-read-only'
 243         Set to non-nil if you want to make buffers read only while hiding.
 244         After `show-ifdefs', read-only status is restored to previous value.
 245
 246 \\{hide-ifdef-mode-map}"
 247   :group 'hide-ifdef :lighter " Ifdef"
 248   (if hide-ifdef-mode
 249       (progn
 250         ;; inherit global values
 251         (set (make-local-variable 'hide-ifdef-env)
 252              (default-value 'hide-ifdef-env))
 253         (set (make-local-variable 'hide-ifdef-hiding)
 254              (default-value 'hide-ifdef-hiding))
 255         (set (make-local-variable 'hif-outside-read-only) buffer-read-only)
 256         (set (make-local-variable 'line-move-ignore-invisible) t)
 257         (add-hook 'change-major-mode-hook
 258                   (lambda () (hide-ifdef-mode -1)) nil t)
 259
 260         (add-to-invisibility-spec '(hide-ifdef . t))
 261
 262         (if hide-ifdef-initially
 263             (hide-ifdefs)
 264           (show-ifdefs)))
 265     ;; else end hide-ifdef-mode
 266     (kill-local-variable 'line-move-ignore-invisible)
 267     (remove-from-invisibility-spec '(hide-ifdef . t))
 268     (when hide-ifdef-hiding
 269       (show-ifdefs))))
 270
 271
 272 (defun hif-show-all ()
 273   "Show all of the text in the current buffer."
 274   (interactive)
 275   (hif-show-ifdef-region (point-min) (point-max)))
 276
 277 ;; By putting this on after-revert-hook, we arrange that it only
 278 ;; does anything when revert-buffer avoids turning off the mode.
 279 ;; (That can happen in VC.)
 280 (defun hif-after-revert-function ()
 281   (and hide-ifdef-mode hide-ifdef-hiding
 282        (hide-ifdefs t)))
 283 (add-hook 'after-revert-hook 'hif-after-revert-function)
 284
 285 (defun hif-end-of-line ()
 286   (end-of-line)
 287   (while (= (logand 1 (skip-chars-backward "\\\\")) 1)
 288     (end-of-line 2)))
 289
 290 (defun hide-ifdef-region-internal (start end)
 291   (remove-overlays start end 'hide-ifdef t)
 292   (let ((o (make-overlay start end)))
 293     (overlay-put o 'hide-ifdef t)
 294     (if hide-ifdef-shadow
 295         (overlay-put o 'face 'hide-ifdef-shadow)
 296       (overlay-put o 'invisible 'hide-ifdef))))
 297
 298 (defun hide-ifdef-region (start end)
 299   "START is the start of a #if or #else form.  END is the ending part.
 300 Everything including these lines is made invisible."
 301   (save-excursion
 302     (goto-char start) (hif-end-of-line) (setq start (point))
 303     (goto-char end) (hif-end-of-line) (setq end (point))
 304     (hide-ifdef-region-internal start end)))
 305
 306 (defun hif-show-ifdef-region (start end)
 307   "Everything between START and END is made visible."
 308   (remove-overlays start end 'hide-ifdef t))
 309
 310
 311 ;;===%%SF%% evaluation (Start)  ===
 312
 313 ;; It is not useful to set this to anything but `eval'.
 314 ;; In fact, the variable might as well be eliminated.
 315 (defvar hide-ifdef-evaluator 'eval
 316   "The function to use to evaluate a form.
 317 The evaluator is given a canonical form and returns t if text under
 318 that form should be displayed.")
 319
 320 (defvar hif-undefined-symbol nil
 321   "...is by default considered to be false.")
 322
 323
 324 (defun hif-set-var (var value)
 325   "Prepend (var value) pair to hide-ifdef-env."
 326   (setq hide-ifdef-env (cons (cons var value) hide-ifdef-env)))
 327
 328
 329 (defun hif-lookup (var)
 330   ;; (message "hif-lookup %s" var)
 331   (let ((val (assoc var hide-ifdef-env)))
 332     (if val
 333         (cdr val)
 334       hif-undefined-symbol)))
 335
 336 (defun hif-defined (var)
 337    (if (assoc var hide-ifdef-env) 1 0))
 338
 339 ;;===%%SF%% evaluation (End)  ===
 340
 341
 342
 343 ;;===%%SF%% parsing (Start)  ===
 344 ;;;  The code that understands what ifs and ifdef in files look like.
 345
 346 (defconst hif-cpp-prefix "\\(^\\|\r\\)[ \t]*#[ \t]*")
 347 (defconst hif-ifndef-regexp (concat hif-cpp-prefix "ifndef"))
 348 (defconst hif-ifx-regexp (concat hif-cpp-prefix "if\\(n?def\\)?[ \t]+"))
 349 (defconst hif-else-regexp (concat hif-cpp-prefix "else"))
 350 (defconst hif-endif-regexp (concat hif-cpp-prefix "endif"))
 351 (defconst hif-ifx-else-endif-regexp
 352   (concat hif-ifx-regexp "\\|" hif-else-regexp "\\|" hif-endif-regexp))
 353
 354 ;; Used to store the current token and the whole token list during parsing.
 355 ;; Only bound dynamically.
 356 (defvar hif-token)
 357 (defvar hif-token-list)
 358
 359 (defconst hif-token-alist
 360   '(("||" . or)
 361     ("&&" . and)
 362     ("|"  . hif-logior)
 363     ("&"  . hif-logand)
 364     ("==" . equal)
 365     ("!=" . hif-notequal)
 366     ("!"  . not)
 367     ("("  . lparen)
 368     (")"  . rparen)
 369     (">"  . hif-greater)
 370     ("<"  . hif-less)
 371     (">=" . hif-greater-equal)
 372     ("<=" . hif-less-equal)
 373     ("+"  . hif-plus)
 374     ("-"  . hif-minus)
 375     ("?"  . hif-conditional)
 376     (":"  . hif-colon)))
 377
 378 (defconst hif-token-regexp
 379   (concat (regexp-opt (mapcar 'car hif-token-alist)) "\\|\\w+"))
 380
 381 (defun hif-tokenize (start end)
 382   "Separate string between START and END into a list of tokens."
 383   (let ((token-list nil))
 384     (with-syntax-table hide-ifdef-syntax-table
 385       (save-excursion
 386         (goto-char start)
 387         (while (progn (forward-comment (point-max)) (< (point) end))
 388           ;; (message "expr-start = %d" expr-start) (sit-for 1)
 389           (cond
 390            ((looking-at "\\\\\n")
 391             (forward-char 2))
 392
 393            ((looking-at hif-token-regexp)
 394             (let ((token (buffer-substring (point) (match-end 0))))
 395               (goto-char (match-end 0))
 396               ;; (message "token: %s" token) (sit-for 1)
 397               (push (or (cdr (assoc token hif-token-alist))
 398                         (if (string-equal token "defined") 'hif-defined)
 399                         (if (string-match "\\`[0-9]*\\'" token)
 400                             (string-to-number token))
 401                         (intern token))
 402                     token-list)))
 403            (t (error "Bad #if expression: %s" (buffer-string)))))))
 404     (nreverse token-list)))
 405
 406 ;;;-----------------------------------------------------------------
 407 ;;; Translate C preprocessor #if expressions using recursive descent.
 408 ;;; This parser is limited to the operators &&, ||, !, and "defined".
 409 ;;; Added ==, !=, +, and -.  Gary Oberbrunner, garyo@avs.com, 8/9/94
 410
 411 (defsubst hif-nexttoken ()
 412   "Pop the next token from token-list into the let variable \"hif-token\"."
 413   (setq hif-token (pop hif-token-list)))
 414
 415 (defun hif-parse-if-exp (hif-token-list)
 416   "Parse the TOKEN-LIST.  Return translated list in prefix form."
 417   (hif-nexttoken)
 418   (prog1
 419       (hif-expr)
 420     (if hif-token ; is there still a token?
 421         (error "Error: unexpected token: %s" hif-token))))
 422
 423 (defun hif-expr ()
 424   "Parse an expression as found in #if.
 425        expr : or-expr | or-expr '?' expr ':' expr."
 426   (let ((result (hif-or-expr))
 427         middle)
 428     (while (eq hif-token 'hif-conditional)
 429       (hif-nexttoken)
 430       (setq middle (hif-expr))
 431       (if (eq hif-token 'hif-colon)
 432           (progn
 433             (hif-nexttoken)
 434             (setq result (list 'hif-conditional result middle (hif-expr))))
 435         (error "Error: unexpected token: %s" hif-token)))
 436     result))
 437
 438 (defun hif-or-expr ()
 439   "Parse n or-expr : and-expr | or-expr '||' and-expr."
 440   (let ((result (hif-and-expr)))
 441     (while (eq hif-token 'or)
 442       (hif-nexttoken)
 443       (setq result (list 'hif-or result (hif-and-expr))))
 444   result))
 445
 446 (defun hif-and-expr ()
 447   "Parse an and-expr : eq-expr | and-expr '&&' eq-expr."
 448   (let ((result (hif-eq-expr)))
 449     (while (eq hif-token 'and)
 450       (hif-nexttoken)
 451       (setq result (list 'hif-and result (hif-eq-expr))))
 452     result))
 453
 454 (defun hif-eq-expr ()
 455   "Parse an eq-expr : math | eq-expr `=='|`!='|`<'|`>'|`>='|`<=' math."
 456   (let ((result (hif-math))
 457         (eq-token nil))
 458     (while (memq hif-token '(equal hif-notequal hif-greater hif-less
 459                              hif-greater-equal hif-less-equal))
 460       (setq eq-token hif-token)
 461       (hif-nexttoken)
 462       (setq result (list eq-token result (hif-math))))
 463     result))
 464
 465 (defun hif-math ()
 466   "Parse an expression with + or - and simpler things.
 467        math : factor | math '+|-' factor."
 468   (let ((result (hif-factor))
 469         (math-op nil))
 470     (while (memq hif-token '(hif-plus hif-minus hif-logior hif-logand))
 471       (setq math-op hif-token)
 472       (hif-nexttoken)
 473       (setq result (list math-op result (hif-factor))))
 474   result))
 475
 476 (defun hif-factor ()
 477   "Parse a factor: '!' factor | '(' expr ')' | 'defined(' id ')' | id."
 478   (cond
 479    ((eq hif-token 'not)
 480     (hif-nexttoken)
 481     (list 'hif-not (hif-factor)))
 482
 483    ((eq hif-token 'lparen)
 484     (hif-nexttoken)
 485     (let ((result (hif-expr)))
 486       (if (not (eq hif-token 'rparen))
 487           (error "Bad token in parenthesized expression: %s" hif-token)
 488         (hif-nexttoken)
 489         result)))
 490
 491    ((eq hif-token 'hif-defined)
 492     (hif-nexttoken)
 493     (let ((paren (when (eq hif-token 'lparen) (hif-nexttoken) t))
 494           (ident hif-token))
 495       (if (memq hif-token '(or and not hif-defined lparen rparen))
 496           (error "Error: unexpected token: %s" hif-token))
 497       (when paren
 498         (hif-nexttoken)
 499         (unless (eq hif-token 'rparen)
 500           (error "Error: expected \")\" after identifier")))
 501       (hif-nexttoken)
 502       `(hif-defined (quote ,ident))))
 503
 504    ((numberp hif-token)
 505     (prog1 hif-token (hif-nexttoken)))
 506
 507    ;; Unary plus/minus.
 508    ((memq hif-token '(hif-minus hif-plus))
 509     (list (prog1 hif-token (hif-nexttoken)) 0 (hif-factor)))
 510
 511    (t                                   ; identifier
 512     (let ((ident hif-token))
 513       (if (memq ident '(or and))
 514           (error "Error: missing identifier"))
 515       (hif-nexttoken)
 516       `(hif-lookup (quote ,ident))))))
 517
 518 (defun hif-mathify (val)
 519   "Treat VAL as a number: if it's t or nil, use 1 or 0."
 520   (cond ((eq val t) 1)
 521         ((null val) 0)
 522         (t val)))
 523
 524 (defun hif-conditional (a b c)
 525   (if (not (zerop (hif-mathify a))) (hif-mathify b) (hif-mathify c)))
 526 (defun hif-and (a b)
 527   (and (not (zerop (hif-mathify a))) (not (zerop (hif-mathify b)))))
 528 (defun hif-or (a b)
 529   (or (not (zerop (hif-mathify a))) (not (zerop (hif-mathify b)))))
 530 (defun hif-not (a)
 531   (zerop (hif-mathify a)))
 532
 533 (defmacro hif-mathify-binop (fun)
 534   `(lambda (a b)
 535      ,(format "Like `%s' but treat t and nil as 1 and 0." fun)
 536      (,fun (hif-mathify a) (hif-mathify b))))
 537
 538 (defalias 'hif-plus          (hif-mathify-binop +))
 539 (defalias 'hif-minus         (hif-mathify-binop -))
 540 (defalias 'hif-notequal      (hif-mathify-binop /=))
 541 (defalias 'hif-greater       (hif-mathify-binop >))
 542 (defalias 'hif-less          (hif-mathify-binop <))
 543 (defalias 'hif-greater-equal (hif-mathify-binop >=))
 544 (defalias 'hif-less-equal    (hif-mathify-binop <=))
 545 (defalias 'hif-logior        (hif-mathify-binop logior))
 546 (defalias 'hif-logand        (hif-mathify-binop logand))
 547
 548 ;;;----------- end of parser -----------------------
 549
 550
 551 (defun hif-canonicalize ()
 552   "When at beginning of #ifX, return a Lisp expression for its condition."
 553   (save-excursion
 554     (let ((negate (looking-at hif-ifndef-regexp)))
 555       (re-search-forward hif-ifx-regexp)
 556       (let* ((tokens (hif-tokenize (point)
 557                                    (progn (hif-end-of-line) (point))))
 558              (expr (hif-parse-if-exp tokens)))
 559         ;; (message "hif-canonicalized: %s" expr)
 560         (if negate
 561             (list 'hif-not expr)
 562           expr)))))
 563
 564
 565 (defun hif-find-any-ifX ()
 566   "Move to next #if..., or #ifndef, at point or after."
 567   ;; (message "find ifX at %d" (point))
 568   (prog1
 569       (re-search-forward hif-ifx-regexp (point-max) t)
 570     (beginning-of-line)))
 571
 572
 573 (defun hif-find-next-relevant ()
 574   "Move to next #if..., #else, or #endif, after the current line."
 575   ;; (message "hif-find-next-relevant at %d" (point))
 576   (end-of-line)
 577   ;; avoid infinite recursion by only going to beginning of line if match found
 578   (if (re-search-forward hif-ifx-else-endif-regexp (point-max) t)
 579       (beginning-of-line)))
 580
 581 (defun hif-find-previous-relevant ()
 582   "Move to previous #if..., #else, or #endif, before the current line."
 583   ;; (message "hif-find-previous-relevant at %d" (point))
 584   (beginning-of-line)
 585   ;; avoid infinite recursion by only going to beginning of line if match found
 586   (if (re-search-backward hif-ifx-else-endif-regexp (point-min) t)
 587      (beginning-of-line)))
 588
 589
 590 (defun hif-looking-at-ifX ()            ;; Should eventually see #if
 591   (looking-at hif-ifx-regexp))
 592 (defun hif-looking-at-endif ()
 593   (looking-at hif-endif-regexp))
 594 (defun hif-looking-at-else ()
 595   (looking-at hif-else-regexp))
 596
 597
 598
 599 (defun hif-ifdef-to-endif ()
 600   "If positioned at #ifX or #else form, skip to corresponding #endif."
 601   ;; (message "hif-ifdef-to-endif at %d" (point)) (sit-for 1)
 602   (hif-find-next-relevant)
 603   (cond ((hif-looking-at-ifX)
 604          (hif-ifdef-to-endif) ; find endif of nested if
 605          (hif-ifdef-to-endif)) ; find outer endif or else
 606         ((hif-looking-at-else)
 607          (hif-ifdef-to-endif)) ; find endif following else
 608         ((hif-looking-at-endif)
 609          'done)
 610         (t
 611          (error "Mismatched #ifdef #endif pair"))))
 612
 613
 614 (defun hif-endif-to-ifdef ()
 615   "If positioned at #endif form, skip backward to corresponding #ifX."
 616   ;; (message "hif-endif-to-ifdef at %d" (point))
 617   (let ((start (point)))
 618     (hif-find-previous-relevant)
 619     (if (= start (point))
 620         (error "Mismatched #ifdef #endif pair")))
 621   (cond ((hif-looking-at-endif)
 622          (hif-endif-to-ifdef) ; find beginning of nested if
 623          (hif-endif-to-ifdef)) ; find beginning of outer if or else
 624         ((hif-looking-at-else)
 625          (hif-endif-to-ifdef))
 626         ((hif-looking-at-ifX)
 627          'done)
 628         (t)))                   ; never gets here
 629
 630
 631 (defun forward-ifdef (&optional arg)
 632   "Move point to beginning of line of the next ifdef-endif.
 633 With argument, do this that many times."
 634   (interactive "p")
 635   (or arg (setq arg 1))
 636   (if (< arg 0) (backward-ifdef (- arg))
 637     (while (< 0 arg)
 638       (setq arg (- arg))
 639       (let ((start (point)))
 640         (unless (hif-looking-at-ifX)
 641           (hif-find-next-relevant))
 642         (if (hif-looking-at-ifX)
 643             (hif-ifdef-to-endif)
 644           (goto-char start)
 645           (error "No following #ifdef"))))))
 646
 647
 648 (defun backward-ifdef (&optional arg)
 649   "Move point to beginning of the previous ifdef-endif.
 650 With argument, do this that many times."
 651   (interactive "p")
 652   (or arg (setq arg 1))
 653   (if (< arg 0) (forward-ifdef (- arg))
 654     (while (< 0 arg)
 655       (setq arg (1- arg))
 656       (beginning-of-line)
 657       (let ((start (point)))
 658         (unless (hif-looking-at-endif)
 659           (hif-find-previous-relevant))
 660         (if (hif-looking-at-endif)
 661             (hif-endif-to-ifdef)
 662           (goto-char start)
 663           (error "No previous #ifdef"))))))
 664
 665
 666 (defun down-ifdef ()
 667   "Move point to beginning of nested ifdef or else-part."
 668     (interactive)
 669     (let ((start (point)))
 670       (hif-find-next-relevant)
 671       (if (or (hif-looking-at-ifX) (hif-looking-at-else))
 672           ()
 673         (goto-char start)
 674         (error "No following #ifdef"))))
 675
 676
 677 (defun up-ifdef ()
 678   "Move point to beginning of enclosing ifdef or else-part."
 679   (interactive)
 680   (beginning-of-line)
 681   (let ((start (point)))
 682     (unless (hif-looking-at-endif)
 683       (hif-find-previous-relevant))
 684     (if (hif-looking-at-endif)
 685         (hif-endif-to-ifdef))
 686       (if (= start (point))
 687           (error "No previous #ifdef"))))
 688
 689 (defun next-ifdef (&optional arg)
 690   "Move to the beginning of the next #ifX, #else, or #endif.
 691 With argument, do this that many times."
 692   (interactive "p")
 693   (or arg (setq arg 1))
 694   (if (< arg 0) (previous-ifdef (- arg))
 695     (while (< 0 arg)
 696       (setq arg (1- arg))
 697       (hif-find-next-relevant)
 698       (when (eolp)
 699         (beginning-of-line)
 700         (error "No following #ifdefs, #elses, or #endifs")))))
 701
 702 (defun previous-ifdef (&optional arg)
 703   "Move to the beginning of the previous #ifX, #else, or #endif.
 704 With argument, do this that many times."
 705   (interactive "p")
 706   (or arg (setq arg 1))
 707   (if (< arg 0) (next-ifdef (- arg))
 708     (while (< 0 arg)
 709       (setq arg (1- arg))
 710       (let ((start (point)))
 711         (hif-find-previous-relevant)
 712         (if (= start (point))
 713             (error "No previous #ifdefs, #elses, or #endifs"))))))
 714
 715
 716 ;;===%%SF%% parsing (End)  ===
 717
 718
 719 ;;===%%SF%% hide-ifdef-hiding (Start)  ===
 720
 721
 722 ;;; A range is a structure with four components:
 723 ;;; ELSE-P      True if there was an else clause for the ifdef.
 724 ;;; START       The start of the range. (beginning of line)
 725 ;;; ELSE        The else marker (beginning of line)
 726 ;;;                     Only valid if ELSE-P is true.
 727 ;;; END         The end of the range.  (beginning of line)
 728
 729 (defsubst hif-make-range (start end &optional else)
 730   (list start else end))
 731
 732 (defsubst hif-range-start (range) (elt range 0))
 733 (defsubst hif-range-else (range) (elt range 1))
 734 (defsubst hif-range-end (range) (elt range 2))
 735
 736
 737
 738 ;;; Find-Range
 739 ;;; The workhorse, it delimits the #if region.  Reasonably simple:
 740 ;;; Skip until an #else or #endif is found, remembering positions.  If
 741 ;;; an #else was found, skip some more, looking for the true #endif.
 742
 743 (defun hif-find-range ()
 744   "Return a Range structure describing the current #if region.
 745 Point is left unchanged."
 746   ;; (message "hif-find-range at %d" (point))
 747   (save-excursion
 748     (beginning-of-line)
 749     (let ((start (point))
 750           (else nil)
 751           (end nil))
 752       ;; Part one.  Look for either #endif or #else.
 753       ;; This loop-and-a-half dedicated to E. Dijkstra.
 754       (while (progn
 755                (hif-find-next-relevant)
 756                (hif-looking-at-ifX))            ; Skip nested ifdef
 757         (hif-ifdef-to-endif))
 758       ;; Found either a #else or an #endif.
 759       (cond ((hif-looking-at-else)
 760              (setq else (point)))
 761             (t
 762              (setq end (point)))) ; (line-end-position)
 763       ;; If found #else, look for #endif.
 764       (when else
 765         (while (progn
 766                  (hif-find-next-relevant)
 767                  (hif-looking-at-ifX))  ; Skip nested ifdef
 768           (hif-ifdef-to-endif))
 769         (if (hif-looking-at-else)
 770             (error "Found two elses in a row?  Broken!"))
 771         (setq end (point)))            ; (line-end-position)
 772       (hif-make-range start end else))))
 773
 774
 775 ;;; A bit slimy.
 776
 777 (defun hif-hide-line (point)
 778   "Hide the line containing point.  Does nothing if `hide-ifdef-lines' is nil."
 779   (when hide-ifdef-lines
 780     (save-excursion
 781       (goto-char point)
 782       (hide-ifdef-region-internal
 783        (line-beginning-position) (progn (hif-end-of-line) (point))))))
 784
 785
 786 ;;;  Hif-Possibly-Hide
 787 ;;;  There are four cases.  The #ifX expression is "taken" if it
 788 ;;;  the hide-ifdef-evaluator returns T.  Presumably, this means the code
 789 ;;;  inside the #ifdef would be included when the program was
 790 ;;;  compiled.
 791 ;;;
 792 ;;;  Case 1:  #ifX taken, and there's an #else.
 793 ;;;     The #else part must be hidden.  The #if (then) part must be
 794 ;;;     processed for nested #ifX's.
 795 ;;;  Case 2:  #ifX taken, and there's no #else.
 796 ;;;     The #if part must be processed for nested #ifX's.
 797 ;;;  Case 3:  #ifX not taken, and there's an #else.
 798 ;;;     The #if part must be hidden.  The #else part must be processed
 799 ;;;     for nested #ifs.
 800 ;;;  Case 4:  #ifX not taken, and there's no #else.
 801 ;;;     The #ifX part must be hidden.
 802 ;;;
 803 ;;;  Further processing is done by narrowing to the relevant region
 804 ;;;  and just recursively calling hide-ifdef-guts.
 805 ;;;
 806 ;;;  When hif-possibly-hide returns, point is at the end of the
 807 ;;;  possibly-hidden range.
 808
 809 (defun hif-recurse-on (start end)
 810   "Call `hide-ifdef-guts' after narrowing to end of START line and END line."
 811   (save-excursion
 812     (save-restriction
 813       (goto-char start)
 814       (end-of-line)
 815       (narrow-to-region (point) end)
 816       (hide-ifdef-guts))))
 817
 818 (defun hif-possibly-hide ()
 819   "Called at #ifX expression, this hides those parts that should be hidden.
 820 It uses the judgement of `hide-ifdef-evaluator'."
 821   ;; (message "hif-possibly-hide") (sit-for 1)
 822   (let ((test (hif-canonicalize))
 823         (range (hif-find-range)))
 824     ;; (message "test = %s" test) (sit-for 1)
 825
 826     (hif-hide-line (hif-range-end range))
 827     (if (not (hif-not (funcall hide-ifdef-evaluator test)))
 828         (cond ((hif-range-else range)   ; case 1
 829                (hif-hide-line (hif-range-else range))
 830                (hide-ifdef-region (hif-range-else range)
 831                                   (1- (hif-range-end range)))
 832                (hif-recurse-on (hif-range-start range)
 833                                (hif-range-else range)))
 834               (t                        ; case 2
 835                (hif-recurse-on (hif-range-start range)
 836                                (hif-range-end range))))
 837       (cond ((hif-range-else range)     ; case 3
 838              (hif-hide-line (hif-range-else range))
 839              (hide-ifdef-region (hif-range-start range)
 840                                 (1- (hif-range-else range)))
 841              (hif-recurse-on (hif-range-else range)
 842                              (hif-range-end range)))
 843             (t                          ; case 4
 844              (hide-ifdef-region (point)
 845                                 (1- (hif-range-end range))))))
 846     (hif-hide-line (hif-range-start range)) ; Always hide start.
 847     (goto-char (hif-range-end range))
 848     (end-of-line)))
 849
 850
 851
 852 (defun hide-ifdef-guts ()
 853   "Does most of the work of `hide-ifdefs'.
 854 It does not do the work that's pointless to redo on a recursive entry."
 855   ;; (message "hide-ifdef-guts")
 856   (save-excursion
 857     (goto-char (point-min))
 858     (while (hif-find-any-ifX)
 859       (hif-possibly-hide))))
 860
 861 ;;===%%SF%% hide-ifdef-hiding (End)  ===
 862
 863
 864 ;;===%%SF%% exports (Start)  ===
 865
 866 (defun hide-ifdef-toggle-read-only ()
 867   "Toggle `hide-ifdef-read-only'."
 868   (interactive)
 869   (setq hide-ifdef-read-only (not hide-ifdef-read-only))
 870   (message "Hide-Read-Only %s"
 871            (if hide-ifdef-read-only "ON" "OFF"))
 872   (if hide-ifdef-hiding
 873       (setq buffer-read-only (or hide-ifdef-read-only hif-outside-read-only)))
 874   (force-mode-line-update))
 875
 876 (defun hide-ifdef-toggle-outside-read-only ()
 877   "Replacement for `toggle-read-only' within Hide-Ifdef mode."
 878   (interactive)
 879   (setq hif-outside-read-only (not hif-outside-read-only))
 880   (message "Read only %s"
 881            (if hif-outside-read-only "ON" "OFF"))
 882   (setq buffer-read-only
 883         (or (and hide-ifdef-hiding hide-ifdef-read-only)
 884             hif-outside-read-only))
 885   (force-mode-line-update))
 886
 887 (defun hide-ifdef-toggle-shadowing ()
 888   "Toggle shadowing."
 889   (interactive)
 890   (set (make-local-variable 'hide-ifdef-shadow) (not hide-ifdef-shadow))
 891   (message "Shadowing %s" (if hide-ifdef-shadow "ON" "OFF"))
 892   (save-restriction
 893     (widen)
 894     (dolist (overlay (overlays-in (point-min) (point-max)))
 895       (when (overlay-get overlay 'hide-ifdef)
 896         (if hide-ifdef-shadow
 897             (progn
 898               (overlay-put overlay 'invisible nil)
 899               (overlay-put overlay 'face 'hide-ifdef-shadow))
 900           (overlay-put overlay 'face nil)
 901           (overlay-put overlay 'invisible 'hide-ifdef))))))
 902
 903 (defun hide-ifdef-define (var)
 904   "Define a VAR so that #ifdef VAR would be included."
 905   (interactive "SDefine what? ")
 906   (hif-set-var var 1)
 907   (if hide-ifdef-hiding (hide-ifdefs)))
 908
 909 (defun hide-ifdef-undef (var)
 910   "Undefine a VAR so that #ifdef VAR would not be included."
 911   (interactive "SUndefine what? ")
 912   (hif-set-var var nil)
 913   (if hide-ifdef-hiding (hide-ifdefs)))
 914
 915
 916 (defun hide-ifdefs (&optional nomsg)
 917   "Hide the contents of some #ifdefs.
 918 Assume that defined symbols have been added to `hide-ifdef-env'.
 919 The text hidden is the text that would not be included by the C
 920 preprocessor if it were given the file with those symbols defined.
 921
 922 Turn off hiding by calling `show-ifdefs'."
 923
 924   (interactive)
 925   (message "Hiding...")
 926   (setq hif-outside-read-only buffer-read-only)
 927   (unless hide-ifdef-mode (hide-ifdef-mode 1)) ; turn on hide-ifdef-mode
 928   (if hide-ifdef-hiding
 929       (show-ifdefs))                    ; Otherwise, deep confusion.
 930   (setq hide-ifdef-hiding t)
 931   (hide-ifdef-guts)
 932   (setq buffer-read-only (or hide-ifdef-read-only hif-outside-read-only))
 933   (or nomsg
 934       (message "Hiding done")))
 935
 936
 937 (defun show-ifdefs ()
 938   "Cancel the effects of `hide-ifdef': show the contents of all #ifdefs."
 939   (interactive)
 940   (setq buffer-read-only hif-outside-read-only)
 941   (hif-show-all)
 942   (setq hide-ifdef-hiding nil))
 943
 944
 945 (defun hif-find-ifdef-block ()
 946   "Utility for hide and show `ifdef-block'.
 947 Return as (TOP . BOTTOM) the extent of ifdef block."
 948   (let (max-bottom)
 949     (cons (save-excursion
 950             (beginning-of-line)
 951             (unless (or (hif-looking-at-else) (hif-looking-at-ifX))
 952               (up-ifdef))
 953             (prog1 (point)
 954               (hif-ifdef-to-endif)
 955               (setq max-bottom (1- (point)))))
 956           (save-excursion
 957             (beginning-of-line)
 958             (unless (hif-looking-at-endif)
 959               (hif-find-next-relevant))
 960             (while (hif-looking-at-ifX)
 961               (hif-ifdef-to-endif)
 962               (hif-find-next-relevant))
 963             (min max-bottom (1- (point)))))))
 964
 965
 966 (defun hide-ifdef-block ()
 967   "Hide the ifdef block (true or false part) enclosing or before the cursor."
 968   (interactive)
 969   (unless hide-ifdef-mode (hide-ifdef-mode 1))
 970   (let ((top-bottom (hif-find-ifdef-block)))
 971     (hide-ifdef-region (car top-bottom) (cdr top-bottom))
 972     (when hide-ifdef-lines
 973       (hif-hide-line (car top-bottom))
 974       (hif-hide-line (1+ (cdr top-bottom))))
 975     (setq hide-ifdef-hiding t))
 976   (setq buffer-read-only (or hide-ifdef-read-only hif-outside-read-only)))
 977
 978 (defun show-ifdef-block ()
 979   "Show the ifdef block (true or false part) enclosing or before the cursor."
 980   (interactive)
 981   (let ((top-bottom (hif-find-ifdef-block)))
 982     (if hide-ifdef-lines
 983         (hif-show-ifdef-region
 984          (save-excursion
 985            (goto-char (car top-bottom)) (line-beginning-position))
 986          (save-excursion
 987            (goto-char (1+ (cdr top-bottom)))
 988            (hif-end-of-line) (point)))
 989       (hif-show-ifdef-region (1- (car top-bottom)) (cdr top-bottom)))))
 990
 991
 992 ;;;  definition alist support
 993
 994 (defvar hide-ifdef-define-alist nil
 995   "A global assoc list of pre-defined symbol lists.")
 996
 997 (defun hif-compress-define-list (env)
 998   "Compress the define list ENV into a list of defined symbols only."
 999   (let ((new-defs nil))
1000     (dolist (def env new-defs)
1001       (if (hif-lookup (car def)) (push (car env) new-defs)))))
1002
1003 (defun hide-ifdef-set-define-alist (name)
1004   "Set the association for NAME to `hide-ifdef-env'."
1005   (interactive "SSet define list: ")
1006   (push (cons name (hif-compress-define-list hide-ifdef-env))
1007         hide-ifdef-define-alist))
1008
1009 (defun hide-ifdef-use-define-alist (name)
1010   "Set `hide-ifdef-env' to the define list specified by NAME."
1011   (interactive
1012    (list (completing-read "Use define list: "
1013                           (mapcar (lambda (x) (symbol-name (car x)))
1014                                   hide-ifdef-define-alist)
1015                           nil t)))
1016   (if (stringp name) (setq name (intern name)))
1017   (let ((define-list (assoc name hide-ifdef-define-alist)))
1018     (if define-list
1019         (setq hide-ifdef-env
1020               (mapcar (lambda (arg) (cons arg t))
1021                       (cdr define-list)))
1022       (error "No define list for %s" name))
1023     (if hide-ifdef-hiding (hide-ifdefs))))
1024
1025 (provide 'hideif)
1026
1027 ;;; hideif.el ends here