lisp/userlock.el

   1 ;;; userlock.el --- handle file access contention between multiple users
   2
   3 ;; Copyright (C) 1985, 1986 Free Software Foundation, inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This file is autoloaded to handle certain conditions
  27 ;; detected by the file-locking code within Emacs.
  28 ;; The two entry points are `ask-user-about-lock' and
  29 ;; `ask-user-about-supersession-threat'.
  30
  31 ;;; Code:
  32
  33 (put 'file-locked 'error-conditions '(file-locked file-error error))
  34
  35 ;;;###autoload
  36 (defun ask-user-about-lock (fn opponent)
  37   "Ask user what to do when he wants to edit FILE but it is locked by USER.
  38 This function has a choice of three things to do:
  39   do (signal 'buffer-file-locked (list FILE USER))
  40     to refrain from editing the file
  41   return t (grab the lock on the file)
  42   return nil (edit the file even though it is locked).
  43 You can rewrite it to use any criterion you like to choose which one to do."
  44   (discard-input)
  45   (save-window-excursion
  46     (let (answer)
  47       (while (null answer)
  48         (message "%s is locking %s: action (s, q, p, ?)? " opponent fn)
  49         (let ((tem (let ((inhibit-quit t)
  50                          (cursor-in-echo-area t))
  51                      (prog1 (downcase (read-char))
  52                             (setq quit-flag nil)))))
  53           (if (= tem help-char)
  54               (ask-user-about-lock-help)
  55             (setq answer (assoc tem '((?s . t)
  56                                       (?q . yield)
  57                                       (?\C-g . yield)
  58                                       (?p . nil)
  59                                       (?? . help))))
  60             (cond ((null answer)
  61                    (beep)
  62                    (message "Please type q, s, or p; or ? for help")
  63                    (sit-for 3))
  64                   ((eq (cdr answer) 'help)
  65                    (ask-user-about-lock-help)
  66                    (setq answer nil))
  67                   ((eq (cdr answer) 'yield)
  68                    (signal 'file-locked (list "File is locked" fn opponent)))))))
  69       (cdr answer))))
  70
  71 (defun ask-user-about-lock-help ()
  72   (with-output-to-temp-buffer "*Help*"
  73     (princ "It has been detected that you want to modify a file that someone else has
  74 already started modifying in EMACS.
  75
  76 You can <s>teal the file; The other user becomes the
  77   intruder if (s)he ever unmodifies the file and then changes it again.
  78 You can <p>roceed; you edit at your own (and the other user's) risk.
  79 You can <q>uit; don't modify this file.")
  80     (save-excursion
  81       (set-buffer standard-output)
  82       (help-mode))))
  83
  84 (put
  85  'file-supersession 'error-conditions '(file-supersession file-error error))
  86
  87 ;;;###autoload
  88 (defun ask-user-about-supersession-threat (fn)
  89   "Ask a user who is about to modify an obsolete buffer what to do.
  90 This function has two choices: it can return, in which case the modification
  91 of the buffer will proceed, or it can (signal 'file-supersession (file)),
  92 in which case the proposed buffer modification will not be made.
  93
  94 You can rewrite this to use any criterion you like to choose which one to do.
  95 The buffer in question is current when this function is called."
  96   (discard-input)
  97   (save-window-excursion
  98     (let (answer)
  99       (while (null answer)
 100         (message "%s changed on disk; really edit the buffer? (y, n or C-h) "
 101                  (file-name-nondirectory fn))
 102         (let ((tem (downcase (let ((cursor-in-echo-area t))
 103                                (read-char)))))
 104           (setq answer
 105                 (if (= tem help-char)
 106                     'help
 107                   (cdr (assoc tem '((?n . yield)
 108                                     (?\C-g . yield)
 109                                     (?y . proceed)
 110                                     (?? . help))))))
 111           (cond ((null answer)
 112                  (beep)
 113                  (message "Please type y or n; or ? for help")
 114                  (sit-for 3))
 115                 ((eq answer 'help)
 116                  (ask-user-about-supersession-help)
 117                  (setq answer nil))
 118                 ((eq answer 'yield)
 119                  (signal 'file-supersession
 120                          (list "File changed on disk" fn))))))
 121       (message
 122         "File on disk now will become a backup file if you save these changes.")
 123       (setq buffer-backed-up nil))))
 124
 125 (defun ask-user-about-supersession-help ()
 126   (with-output-to-temp-buffer "*Help*"
 127     (princ "You want to modify a buffer whose disk file has changed
 128 since you last read it in or saved it with this buffer.
 129
 130 If you say `y' to go ahead and modify this buffer,
 131 you risk ruining the work of whoever rewrote the file.
 132 If you say `n', the change you started to make will be aborted.
 133
 134 Usually, you should type `n' and then `M-x revert-buffer',
 135 to get the latest version of the file, then make the change again.")
 136     (save-excursion
 137       (set-buffer standard-output)
 138       (help-mode))))
 139
 140 ;;; userlock.el ends here