lisp/sort.el

   1 ;;; sort.el --- commands to sort text in an Emacs buffer.
   2
   3 ;; Copyright (C) 1986, 1987, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Howie Kaye
   6 ;; Maintainer: FSF
   7 ;; Keywords: unix
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; This package provides the sorting facilities documented in the Emacs
  28 ;;; user's manual.
  29
  30 ;;; Code:
  31
  32 (defvar sort-fold-case nil
  33   "*Non-nil if the buffer sort functions should ignore case.")
  34
  35 ;;;###autoload
  36 (defun sort-subr (reverse nextrecfun endrecfun &optional startkeyfun endkeyfun)
  37   "General text sorting routine to divide buffer into records and sort them.
  38 Arguments are REVERSE NEXTRECFUN ENDRECFUN &optional STARTKEYFUN ENDKEYFUN.
  39
  40 We divide the accessible portion of the buffer into disjoint pieces
  41 called sort records.  A portion of each sort record (perhaps all of
  42 it) is designated as the sort key.  The records are rearranged in the
  43 buffer in order by their sort keys.  The records may or may not be
  44 contiguous.
  45
  46 Usually the records are rearranged in order of ascending sort key.
  47 If REVERSE is non-nil, they are rearranged in order of descending sort key.
  48
  49 The next four arguments are functions to be called to move point
  50 across a sort record.  They will be called many times from within sort-subr.
  51
  52 NEXTRECFUN is called with point at the end of the previous record.
  53 It moves point to the start of the next record.
  54 It should move point to the end of the buffer if there are no more records.
  55 The first record is assumed to start at the position of point when sort-subr
  56 is called.
  57
  58 ENDRECFUN is called with point within the record.
  59 It should move point to the end of the record.
  60
  61 STARTKEYFUN moves from the start of the record to the start of the key.
  62 It may return either a non-nil value to be used as the key, or
  63 else the key is the substring between the values of point after
  64 STARTKEYFUN and ENDKEYFUN are called.  If STARTKEYFUN is nil, the key
  65 starts at the beginning of the record.
  66
  67 ENDKEYFUN moves from the start of the sort key to the end of the sort key.
  68 ENDKEYFUN may be nil if STARTKEYFUN returns a value or if it would be the
  69 same as ENDRECFUN."
  70   ;; Heuristically try to avoid messages if sorting a small amt of text.
  71   (let ((messages (> (- (point-max) (point-min)) 50000)))
  72     (save-excursion
  73       (if messages (message "Finding sort keys..."))
  74       (let* ((sort-lists (sort-build-lists nextrecfun endrecfun
  75                                            startkeyfun endkeyfun))
  76              (old (reverse sort-lists))
  77              (case-fold-search sort-fold-case))
  78         (if (null sort-lists)
  79             ()
  80           (or reverse (setq sort-lists (nreverse sort-lists)))
  81           (if messages (message "Sorting records..."))
  82           (setq sort-lists
  83                 (if (fboundp 'sortcar)
  84                     (sortcar sort-lists
  85                              (cond ((numberp (car (car sort-lists)))
  86                                     ;; This handles both ints and floats.
  87                                     '<)
  88                                    ((consp (car (car sort-lists)))
  89                                     (function
  90                                      (lambda (a b)
  91                                        (> 0 (compare-buffer-substrings
  92                                              nil (car a) (cdr a)
  93                                              nil (car b) (cdr b))))))
  94                                    (t
  95                                     'string<)))
  96                   (sort sort-lists
  97                         (cond ((numberp (car (car sort-lists)))
  98                                'car-less-than-car)
  99                               ((consp (car (car sort-lists)))
 100                                (function
 101                                 (lambda (a b)
 102                                   (> 0 (compare-buffer-substrings
 103                                         nil (car (car a)) (cdr (car a))
 104                                         nil (car (car b)) (cdr (car b)))))))
 105                               (t
 106                                (function
 107                                 (lambda (a b)
 108                                   (string< (car a) (car b)))))))))
 109           (if reverse (setq sort-lists (nreverse sort-lists)))
 110           (if messages (message "Reordering buffer..."))
 111           (sort-reorder-buffer sort-lists old)))
 112       (if messages (message "Reordering buffer... Done"))))
 113   nil)
 114
 115 ;; Parse buffer into records using the arguments as Lisp expressions;
 116 ;; return a list of records.  Each record looks like (KEY STARTPOS . ENDPOS)
 117 ;; where KEY is the sort key (a number or string),
 118 ;; and STARTPOS and ENDPOS are the bounds of this record in the buffer.
 119
 120 ;; The records appear in the list lastmost first!
 121
 122 (defun sort-build-lists (nextrecfun endrecfun startkeyfun endkeyfun)
 123   (let ((sort-lists ())
 124         (start-rec nil)
 125         done key)
 126     ;; Loop over sort records.
 127     ;(goto-char (point-min)) -- it is the caller's responsibility to
 128     ;arrange this if necessary
 129     (while (not (eobp))
 130       (setq start-rec (point))          ;save record start
 131       (setq done nil)
 132       ;; Get key value, or move to start of key.
 133       (setq key (catch 'key
 134                   (or (and startkeyfun (funcall startkeyfun))
 135                       ;; If key was not returned as value,
 136                       ;; move to end of key and get key from the buffer.
 137                       (let ((start (point)))
 138                         (funcall (or endkeyfun
 139                                      (prog1 endrecfun (setq done t))))
 140                         (cons start (point))))))
 141       ;; Move to end of this record (start of next one, or end of buffer).
 142       (cond ((prog1 done (setq done nil)))
 143             (endrecfun (funcall endrecfun))
 144             (nextrecfun (funcall nextrecfun) (setq done t)))
 145       (if key (setq sort-lists (cons
 146                                  ;; consing optimization in case in which key
 147                                  ;; is same as record.
 148                                  (if (and (consp key)
 149                                           (equal (car key) start-rec)
 150                                           (equal (cdr key) (point)))
 151                                      (cons key key)
 152                                    (cons key (cons start-rec (point))))
 153                                  sort-lists)))
 154       (and (not done) nextrecfun (funcall nextrecfun)))
 155     sort-lists))
 156
 157 (defun sort-reorder-buffer (sort-lists old)
 158   (let ((inhibit-quit t)
 159         (last (point-min))
 160         (min (point-min)) (max (point-max)))
 161     ;; Make sure insertions done for reordering
 162     ;; do not go after any markers at the end of the sorted region,
 163     ;; by inserting a space to separate them.
 164     (goto-char (point-max))
 165     (insert-before-markers " ")
 166     (narrow-to-region min (1- (point-max)))
 167     (while sort-lists
 168       (goto-char (point-max))
 169       (insert-buffer-substring (current-buffer)
 170                                last
 171                                (nth 1 (car old)))
 172       (goto-char (point-max))
 173       (insert-buffer-substring (current-buffer)
 174                                (nth 1 (car sort-lists))
 175                                (cdr (cdr (car sort-lists))))
 176       (setq last (cdr (cdr (car old)))
 177             sort-lists (cdr sort-lists)
 178             old (cdr old)))
 179     (goto-char (point-max))
 180     (insert-buffer-substring (current-buffer)
 181                              last
 182                              max)
 183     ;; Delete the original copy of the text.
 184     (delete-region min max)
 185     ;; Get rid of the separator " ".
 186     (goto-char (point-max))
 187     (narrow-to-region min (1+ (point)))
 188     (delete-region (point) (1+ (point)))))
 189
 190 ;;;###autoload
 191 (defun sort-lines (reverse beg end)
 192   "Sort lines in region alphabetically; argument means descending order.
 193 Called from a program, there are three arguments:
 194 REVERSE (non-nil means reverse order), BEG and END (region to sort)."
 195   (interactive "P\nr")
 196   (save-excursion
 197     (save-restriction
 198       (narrow-to-region beg end)
 199       (goto-char (point-min))
 200       (sort-subr reverse 'forward-line 'end-of-line))))
 201
 202 ;;;###autoload
 203 (defun sort-paragraphs (reverse beg end)
 204   "Sort paragraphs in region alphabetically; argument means descending order.
 205 Called from a program, there are three arguments:
 206 REVERSE (non-nil means reverse order), BEG and END (region to sort)."
 207   (interactive "P\nr")
 208   (save-excursion
 209     (save-restriction
 210       (narrow-to-region beg end)
 211       (goto-char (point-min))
 212       (sort-subr reverse
 213                  (function
 214                   (lambda ()
 215                     (while (and (not (eobp)) (looking-at paragraph-separate))
 216                       (forward-line 1))))
 217                  'forward-paragraph))))
 218
 219 ;;;###autoload
 220 (defun sort-pages (reverse beg end)
 221   "Sort pages in region alphabetically; argument means descending order.
 222 Called from a program, there are three arguments:
 223 REVERSE (non-nil means reverse order), BEG and END (region to sort)."
 224   (interactive "P\nr")
 225   (save-excursion
 226     (save-restriction
 227       (narrow-to-region beg end)
 228       (goto-char (point-min))
 229       (sort-subr reverse
 230                  (function (lambda () (skip-chars-forward "\n")))
 231                  'forward-page))))
 232 \f
 233 (defvar sort-fields-syntax-table nil)
 234 (if sort-fields-syntax-table nil
 235   (let ((table (make-syntax-table))
 236         (i 0))
 237     (while (< i 256)
 238       (modify-syntax-entry i "w" table)
 239       (setq i (1+ i)))
 240     (modify-syntax-entry ?\  " " table)
 241     (modify-syntax-entry ?\t " " table)
 242     (modify-syntax-entry ?\n " " table)
 243     (modify-syntax-entry ?\. "_" table) ; for floating pt. numbers. -wsr
 244     (setq sort-fields-syntax-table table)))
 245
 246 ;;;###autoload
 247 (defun sort-numeric-fields (field beg end)
 248   "Sort lines in region numerically by the ARGth field of each line.
 249 Fields are separated by whitespace and numbered from 1 up.
 250 Specified field must contain a number in each line of the region.
 251 With a negative arg, sorts by the ARGth field counted from the right.
 252 Called from a program, there are three arguments:
 253 FIELD, BEG and END.  BEG and END specify region to sort."
 254   (interactive "p\nr")
 255   (sort-fields-1 field beg end
 256                  (function (lambda ()
 257                              (sort-skip-fields field)
 258                              (string-to-number
 259                               (buffer-substring
 260                                 (point)
 261                                 (save-excursion
 262                                   ;; This is just wrong! Even without floats...
 263                                   ;; (skip-chars-forward "[0-9]")
 264                                   (forward-sexp 1)
 265                                   (point))))))
 266                  nil))
 267
 268 ;;;;;###autoload
 269 ;;(defun sort-float-fields (field beg end)
 270 ;;  "Sort lines in region numerically by the ARGth field of each line.
 271 ;;Fields are separated by whitespace and numbered from 1 up.  Specified field
 272 ;;must contain a floating point number in each line of the region.  With a
 273 ;;negative arg, sorts by the ARGth field counted from the right.  Called from a
 274 ;;program, there are three arguments: FIELD, BEG and END.  BEG and END specify
 275 ;;region to sort."
 276 ;;  (interactive "p\nr")
 277 ;;  (sort-fields-1 field beg end
 278 ;;               (function (lambda ()
 279 ;;                           (sort-skip-fields field)
 280 ;;                           (string-to-number
 281 ;;                            (buffer-substring
 282 ;;                             (point)
 283 ;;                             (save-excursion
 284 ;;                               (re-search-forward
 285 ;;                                "[+-]?[0-9]*\.?[0-9]*\\([eE][+-]?[0-9]+\\)?")
 286 ;;                               (point))))))
 287 ;;               nil))
 288
 289 ;;;###autoload
 290 (defun sort-fields (field beg end)
 291   "Sort lines in region lexicographically by the ARGth field of each line.
 292 Fields are separated by whitespace and numbered from 1 up.
 293 With a negative arg, sorts by the ARGth field counted from the right.
 294 Called from a program, there are three arguments:
 295 FIELD, BEG and END.  BEG and END specify region to sort."
 296   (interactive "p\nr")
 297   (sort-fields-1 field beg end
 298                  (function (lambda ()
 299                              (sort-skip-fields field)
 300                              nil))
 301                  (function (lambda () (skip-chars-forward "^ \t\n")))))
 302
 303 (defun sort-fields-1 (field beg end startkeyfun endkeyfun)
 304   (let ((tbl (syntax-table)))
 305     (if (zerop field) (setq field 1))
 306     (unwind-protect
 307         (save-excursion
 308           (save-restriction
 309             (narrow-to-region beg end)
 310             (goto-char (point-min))
 311             (set-syntax-table sort-fields-syntax-table)
 312             (sort-subr nil
 313                        'forward-line 'end-of-line
 314                        startkeyfun endkeyfun)))
 315       (set-syntax-table tbl))))
 316
 317 ;; Position at the beginning of field N on the current line,
 318 ;; assuming point is initially at the beginning of the line.
 319 (defun sort-skip-fields (n)
 320   (if (> n 0)
 321       ;; Skip across N - 1 fields.
 322       (let ((i (1- n)))
 323         (while (> i 0)
 324           (skip-chars-forward " \t")
 325           (skip-chars-forward "^ \t\n")
 326           (setq i (1- i)))
 327         (skip-chars-forward " \t")
 328         (if (eolp)
 329             (error "Line has too few fields: %s"
 330                    (buffer-substring
 331                     (save-excursion (beginning-of-line) (point))
 332                     (save-excursion (end-of-line) (point))))))
 333     (end-of-line)
 334     ;; Skip back across - N - 1 fields.
 335     (let ((i (1- (- n))))
 336       (while (> i 0)
 337         (skip-chars-backward " \t")
 338         (skip-chars-backward "^ \t\n")
 339         (setq i (1- i)))
 340       (skip-chars-backward " \t"))
 341     (if (bolp)
 342         (error "Line has too few fields: %s"
 343                (buffer-substring
 344                 (save-excursion (beginning-of-line) (point))
 345                 (save-excursion (end-of-line) (point)))))
 346     ;; Position at the front of the field
 347     ;; even if moving backwards.
 348     (skip-chars-backward "^ \t\n")))
 349 \f
 350 (defvar sort-regexp-fields-regexp)
 351 (defvar sort-regexp-record-end)
 352
 353 ;; Move to the beginning of the next match for record-regexp,
 354 ;; and set sort-regexp-record-end to the end of that match.
 355 ;; If the next match is empty and does not advance point,
 356 ;; skip one character and try again.
 357 (defun sort-regexp-fields-next-record ()
 358   (let ((oldpos (point)))
 359     (and (re-search-forward sort-regexp-fields-regexp nil 'move)
 360          (setq sort-regexp-record-end (match-end 0))
 361          (if (= sort-regexp-record-end oldpos)
 362              (progn
 363                (forward-char 1)
 364                (re-search-forward sort-regexp-fields-regexp nil 'move)
 365                (setq sort-regexp-record-end (match-end 0)))
 366            t)
 367          (goto-char (match-beginning 0)))))
 368
 369 ;;;###autoload
 370 (defun sort-regexp-fields (reverse record-regexp key-regexp beg end)
 371   "Sort the region lexicographically as specified by RECORD-REGEXP and KEY.
 372 RECORD-REGEXP specifies the textual units which should be sorted.
 373   For example, to sort lines RECORD-REGEXP would be \"^.*$\"
 374 KEY specifies the part of each record (ie each match for RECORD-REGEXP)
 375   is to be used for sorting.
 376   If it is \"\\digit\" then the digit'th \"\\(...\\)\" match field from
 377   RECORD-REGEXP is used.
 378   If it is \"\\&\" then the whole record is used.
 379   Otherwise, it is a regular-expression for which to search within the record.
 380 If a match for KEY is not found within a record then that record is ignored.
 381
 382 With a negative prefix arg sorts in reverse order.
 383
 384 For example: to sort lines in the region by the first word on each line
 385  starting with the letter \"f\",
 386  RECORD-REGEXP would be \"^.*$\" and KEY would be \"\\=\\<f\\w*\\>\""
 387   ;; using negative prefix arg to mean "reverse" is now inconsistent with
 388   ;; other sort-.*fields functions but then again this was before, since it
 389   ;; didn't use the magnitude of the arg to specify anything.
 390   (interactive "P\nsRegexp specifying records to sort:
 391 sRegexp specifying key within record: \nr")
 392   (cond ((or (equal key-regexp "") (equal key-regexp "\\&"))
 393          (setq key-regexp 0))
 394         ((string-match "\\`\\\\[1-9]\\'" key-regexp)
 395          (setq key-regexp (- (aref key-regexp 1) ?0))))
 396   (save-excursion
 397     (save-restriction
 398       (narrow-to-region beg end)
 399       (goto-char (point-min))
 400       (let (sort-regexp-record-end
 401             (sort-regexp-fields-regexp record-regexp))
 402         (re-search-forward sort-regexp-fields-regexp)
 403         (setq sort-regexp-record-end (point))
 404         (goto-char (match-beginning 0))
 405         (sort-subr reverse
 406                    'sort-regexp-fields-next-record
 407                    (function (lambda ()
 408                                (goto-char sort-regexp-record-end)))
 409                    (function (lambda ()
 410                                (let ((n 0))
 411                                  (cond ((numberp key-regexp)
 412                                         (setq n key-regexp))
 413                                        ((re-search-forward
 414                                           key-regexp sort-regexp-record-end t)
 415                                         (setq n 0))
 416                                        (t (throw 'key nil)))
 417                                  (condition-case ()
 418                                      (if (fboundp 'buffer-substring-lessp)
 419                                          (cons (match-beginning n)
 420                                                (match-end n))
 421                                          (buffer-substring (match-beginning n)
 422                                                            (match-end n)))
 423                                    ;; if there was no such register
 424                                    (error (throw 'key nil)))))))))))
 425
 426 \f
 427 (defvar sort-columns-subprocess t)
 428
 429 ;;;###autoload
 430 (defun sort-columns (reverse &optional beg end)
 431   "Sort lines in region alphabetically by a certain range of columns.
 432 For the purpose of this command, the region includes
 433 the entire line that point is in and the entire line the mark is in.
 434 The column positions of point and mark bound the range of columns to sort on.
 435 A prefix argument means sort into reverse order.
 436
 437 Note that `sort-columns' rejects text that contains tabs,
 438 because tabs could be split across the specified columns
 439 and it doesn't know how to handle that.  Also, when possible,
 440 it uses the `sort' utility program, which doesn't understand tabs.
 441 Use \\[untabify] to convert tabs to spaces before sorting."
 442   (interactive "P\nr")
 443   (save-excursion
 444     (let (beg1 end1 col-beg1 col-end1 col-start col-end)
 445       (goto-char (min beg end))
 446       (setq col-beg1 (current-column))
 447       (beginning-of-line)
 448       (setq beg1 (point))
 449       (goto-char (max beg end))
 450       (setq col-end1 (current-column))
 451       (forward-line)
 452       (setq end1 (point))
 453       (setq col-start (min col-beg1 col-end1))
 454       (setq col-end (max col-beg1 col-end1))
 455       (if (search-backward "\t" beg1 t)
 456           (error "sort-columns does not work with tabs.  Use M-x untabify."))
 457       (if (not (eq system-type 'vax-vms))
 458           ;; Use the sort utility if we can; it is 4 times as fast.
 459           (call-process-region beg1 end1 "sort" t t nil
 460                                (if reverse "-rt\n" "-t\n")
 461                                (concat "+0." col-start)
 462                                (concat "-0." col-end))
 463         ;; On VMS, use Emacs's own facilities.
 464         (save-excursion
 465           (save-restriction
 466             (narrow-to-region beg1 end1)
 467             (goto-char beg1)
 468             (sort-subr reverse 'forward-line 'end-of-line
 469                        (function (lambda () (move-to-column col-start) nil))
 470                        (function (lambda () (move-to-column col-end) nil)))))))))
 471
 472 ;;;###autoload
 473 (defun reverse-region (beg end)
 474   "Reverse the order of lines in a region.
 475 From a program takes two point or marker arguments, BEG and END."
 476   (interactive "r")
 477   (if (> beg end)
 478       (let (mid) (setq mid end end beg beg mid)))
 479   (save-excursion
 480     ;; put beg at the start of a line and end and the end of one --
 481     ;; the largest possible region which fits this criteria
 482     (goto-char beg)
 483     (or (bolp) (forward-line 1))
 484     (setq beg (point))
 485     (goto-char end)
 486     ;; the test for bolp is for those times when end is on an empty line;
 487     ;; it is probably not the case that the line should be included in the
 488     ;; reversal; it isn't difficult to add it afterward.
 489     (or (and (eolp) (not (bolp))) (progn (forward-line -1) (end-of-line)))
 490     (setq end (point-marker))
 491     ;; the real work.  this thing cranks through memory on large regions.
 492     (let (ll (do t))
 493       (while do
 494         (goto-char beg)
 495         (setq ll (cons (buffer-substring (point) (progn (end-of-line) (point)))
 496                        ll))
 497         (setq do (/= (point) end))
 498         (delete-region beg (if do (1+ (point)) (point))))
 499       (while (cdr ll)
 500         (insert (car ll) "\n")
 501         (setq ll (cdr ll)))
 502       (insert (car ll)))))
 503
 504 (provide 'sort)
 505
 506 ;;; sort.el ends here