lisp/emacs-lisp/lisp-mode.el

   1 ;;; lisp-mode.el --- Lisp mode, and its idiosyncratic commands.
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: lisp, languages
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; The base major mode for editing Lisp code (used also for Emacs Lisp).
  27 ;; This mode is documented in the Emacs manual
  28
  29 ;;; Code:
  30
  31 (defvar lisp-mode-syntax-table nil "")
  32 (defvar emacs-lisp-mode-syntax-table nil "")
  33 (defvar lisp-mode-abbrev-table nil "")
  34
  35 (if (not emacs-lisp-mode-syntax-table)
  36     (let ((i 0))
  37       (setq emacs-lisp-mode-syntax-table (make-syntax-table))
  38       (while (< i ?0)
  39         (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
  40         (setq i (1+ i)))
  41       (setq i (1+ ?9))
  42       (while (< i ?A)
  43         (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
  44         (setq i (1+ i)))
  45       (setq i (1+ ?Z))
  46       (while (< i ?a)
  47         (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
  48         (setq i (1+ i)))
  49       (setq i (1+ ?z))
  50       (while (< i 128)
  51         (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
  52         (setq i (1+ i)))
  53       (modify-syntax-entry ?  "    " emacs-lisp-mode-syntax-table)
  54       (modify-syntax-entry ?\t "    " emacs-lisp-mode-syntax-table)
  55       (modify-syntax-entry ?\n ">   " emacs-lisp-mode-syntax-table)
  56       ;; Give CR the same syntax as newline, for selective-display.
  57       (modify-syntax-entry ?\^m ">   " emacs-lisp-mode-syntax-table)
  58       (modify-syntax-entry ?\; "<   " emacs-lisp-mode-syntax-table)
  59       (modify-syntax-entry ?` "'   " emacs-lisp-mode-syntax-table)
  60       (modify-syntax-entry ?' "'   " emacs-lisp-mode-syntax-table)
  61       (modify-syntax-entry ?, "'   " emacs-lisp-mode-syntax-table)
  62       ;; Used to be singlequote; changed for flonums.
  63       (modify-syntax-entry ?. "_   " emacs-lisp-mode-syntax-table)
  64       (modify-syntax-entry ?# "'   " emacs-lisp-mode-syntax-table)
  65       (modify-syntax-entry ?\" "\"    " emacs-lisp-mode-syntax-table)
  66       (modify-syntax-entry ?\\ "\\   " emacs-lisp-mode-syntax-table)
  67       (modify-syntax-entry ?\( "()  " emacs-lisp-mode-syntax-table)
  68       (modify-syntax-entry ?\) ")(  " emacs-lisp-mode-syntax-table)
  69       (modify-syntax-entry ?\[ "(]  " emacs-lisp-mode-syntax-table)
  70       (modify-syntax-entry ?\] ")[  " emacs-lisp-mode-syntax-table)))
  71
  72 (if (not lisp-mode-syntax-table)
  73     (progn (setq lisp-mode-syntax-table
  74                  (copy-syntax-table emacs-lisp-mode-syntax-table))
  75            (modify-syntax-entry ?\| "\"   " lisp-mode-syntax-table)
  76            (modify-syntax-entry ?\[ "_   " lisp-mode-syntax-table)
  77            (modify-syntax-entry ?\] "_   " lisp-mode-syntax-table)))
  78
  79 (define-abbrev-table 'lisp-mode-abbrev-table ())
  80
  81 (defvar lisp-imenu-generic-expression
  82       '(
  83         (nil
  84          "^\\s-*(def\\(un\\|subst\\|macro\\|advice\\)\\s-+\\([-A-Za-z0-9+]+\\)" 2)
  85         ("Variables"
  86          "^\\s-*(def\\(var\\|const\\)\\s-+\\([-A-Za-z0-9+]+\\)" 2)
  87         ("Types"
  88          "^\\s-*(def\\(type\\|struct\\|class\\|ine-condition\\)\\s-+\\([-A-Za-z0-9+]+\\)"
  89          2))
  90
  91   "Imenu generic expression for Lisp mode.  See `imenu-generic-expression'.")
  92
  93 (defun lisp-mode-variables (lisp-syntax)
  94   (cond (lisp-syntax
  95           (set-syntax-table lisp-mode-syntax-table)))
  96   (setq local-abbrev-table lisp-mode-abbrev-table)
  97   (make-local-variable 'paragraph-start)
  98   (setq paragraph-start (concat "^$\\|" page-delimiter))
  99   (make-local-variable 'paragraph-separate)
 100   (setq paragraph-separate paragraph-start)
 101   (make-local-variable 'paragraph-ignore-fill-prefix)
 102   (setq paragraph-ignore-fill-prefix t)
 103   (make-local-variable 'fill-paragraph-function)
 104   (setq fill-paragraph-function 'lisp-fill-paragraph)
 105   (make-local-variable 'indent-line-function)
 106   (setq indent-line-function 'lisp-indent-line)
 107   (make-local-variable 'indent-region-function)
 108   (setq indent-region-function 'lisp-indent-region)
 109   (make-local-variable 'parse-sexp-ignore-comments)
 110   (setq parse-sexp-ignore-comments t)
 111   (make-local-variable 'outline-regexp)
 112   (setq outline-regexp ";;; \\|(....")
 113   (make-local-variable 'comment-start)
 114   (setq comment-start ";")
 115   (make-local-variable 'comment-start-skip)
 116   (setq comment-start-skip ";+ *")
 117   (make-local-variable 'comment-column)
 118   (setq comment-column 40)
 119   (make-local-variable 'comment-indent-function)
 120   (setq comment-indent-function 'lisp-comment-indent)
 121   (make-local-variable 'imenu-generic-expression)
 122   (setq imenu-generic-expression lisp-imenu-generic-expression))
 123 \f
 124 (defvar shared-lisp-mode-map ()
 125   "Keymap for commands shared by all sorts of Lisp modes.")
 126
 127 (if shared-lisp-mode-map
 128     ()
 129    (setq shared-lisp-mode-map (make-sparse-keymap))
 130    (define-key shared-lisp-mode-map "\e\C-q" 'indent-sexp)
 131    (define-key shared-lisp-mode-map "\177" 'backward-delete-char-untabify))
 132
 133 (defvar emacs-lisp-mode-map ()
 134   "Keymap for Emacs Lisp mode.
 135 All commands in `shared-lisp-mode-map' are inherited by this map.")
 136
 137 (if emacs-lisp-mode-map
 138     ()
 139   (let ((map (make-sparse-keymap "Emacs-Lisp")))
 140     (setq emacs-lisp-mode-map
 141           (nconc (make-sparse-keymap) shared-lisp-mode-map))
 142     (define-key emacs-lisp-mode-map "\e\t" 'lisp-complete-symbol)
 143     (define-key emacs-lisp-mode-map "\e\C-x" 'eval-defun)
 144     (define-key emacs-lisp-mode-map [menu-bar] (make-sparse-keymap))
 145     (define-key emacs-lisp-mode-map [menu-bar emacs-lisp]
 146       (cons "Emacs-Lisp" map))
 147     (define-key map [edebug-defun]
 148       '("Instrument Function for Debugging" . edebug-defun))
 149     (define-key map [byte-recompile]
 150       '("Byte-recompile Directory..." . byte-recompile-directory))
 151     (define-key map [byte-compile]
 152       '("Byte-compile This File" . emacs-lisp-byte-compile))
 153     (define-key map [separator-eval] '("--"))
 154     (define-key map [eval-buffer] '("Evaluate Buffer" . eval-current-buffer))
 155     (define-key map [eval-region] '("Evaluate Region" . eval-region))
 156     (define-key map [eval-sexp] '("Evaluate Last S-expression" . eval-last-sexp))
 157     (define-key map [separator-format] '("--"))
 158     (define-key map [comment-region] '("Comment Out Region" . comment-region))
 159     (define-key map [indent-region] '("Indent Region" . indent-region))
 160     (define-key map [indent-line] '("Indent Line" . lisp-indent-line))
 161     (put 'eval-region 'menu-enable 'mark-active)
 162     (put 'comment-region 'menu-enable 'mark-active)
 163     (put 'indent-region 'menu-enable 'mark-active)))
 164
 165 (defun emacs-lisp-byte-compile ()
 166   "Byte compile the file containing the current buffer."
 167   (interactive)
 168   (if buffer-file-name
 169       (byte-compile-file buffer-file-name)
 170     (error "The buffer must be saved in a file first.")))
 171
 172 (defun emacs-lisp-mode ()
 173   "Major mode for editing Lisp code to run in Emacs.
 174 Commands:
 175 Delete converts tabs to spaces as it moves back.
 176 Blank lines separate paragraphs.  Semicolons start comments.
 177 \\{emacs-lisp-mode-map}
 178 Entry to this mode calls the value of `emacs-lisp-mode-hook'
 179 if that value is non-nil."
 180   (interactive)
 181   (kill-all-local-variables)
 182   (use-local-map emacs-lisp-mode-map)
 183   (set-syntax-table emacs-lisp-mode-syntax-table)
 184   (setq major-mode 'emacs-lisp-mode)
 185   (setq mode-name "Emacs-Lisp")
 186   (lisp-mode-variables nil)
 187   (run-hooks 'emacs-lisp-mode-hook))
 188
 189 (defvar lisp-mode-map ()
 190   "Keymap for ordinary Lisp mode.
 191 All commands in `shared-lisp-mode-map' are inherited by this map.")
 192
 193 (if lisp-mode-map
 194     ()
 195   (setq lisp-mode-map
 196         (nconc (make-sparse-keymap) shared-lisp-mode-map))
 197   (define-key lisp-mode-map "\e\C-x" 'lisp-eval-defun)
 198   (define-key lisp-mode-map "\C-c\C-z" 'run-lisp))
 199
 200 (defun lisp-mode ()
 201   "Major mode for editing Lisp code for Lisps other than GNU Emacs Lisp.
 202 Commands:
 203 Delete converts tabs to spaces as it moves back.
 204 Blank lines separate paragraphs.  Semicolons start comments.
 205 \\{lisp-mode-map}
 206 Note that `run-lisp' may be used either to start an inferior Lisp job
 207 or to switch back to an existing one.
 208
 209 Entry to this mode calls the value of `lisp-mode-hook'
 210 if that value is non-nil."
 211   (interactive)
 212   (kill-all-local-variables)
 213   (use-local-map lisp-mode-map)
 214   (setq major-mode 'lisp-mode)
 215   (setq mode-name "Lisp")
 216   (lisp-mode-variables t)
 217   (set-syntax-table lisp-mode-syntax-table)
 218   (run-hooks 'lisp-mode-hook))
 219
 220 ;; This will do unless shell.el is loaded.
 221 (defun lisp-eval-defun nil
 222   "Send the current defun to the Lisp process made by \\[run-lisp]."
 223   (interactive)
 224   (error "Process lisp does not exist"))
 225
 226 (defvar lisp-interaction-mode-map ()
 227   "Keymap for Lisp Interaction moe.
 228 All commands in `shared-lisp-mode-map' are inherited by this map.")
 229
 230 (if lisp-interaction-mode-map
 231     ()
 232   (setq lisp-interaction-mode-map
 233         (nconc (make-sparse-keymap) shared-lisp-mode-map))
 234   (define-key lisp-interaction-mode-map "\e\C-x" 'eval-defun)
 235   (define-key lisp-interaction-mode-map "\e\t" 'lisp-complete-symbol)
 236   (define-key lisp-interaction-mode-map "\n" 'eval-print-last-sexp))
 237
 238 (defun lisp-interaction-mode ()
 239   "Major mode for typing and evaluating Lisp forms.
 240 Like Lisp mode except that \\[eval-print-last-sexp] evals the Lisp expression
 241 before point, and prints its value into the buffer, advancing point.
 242
 243 Commands:
 244 Delete converts tabs to spaces as it moves back.
 245 Paragraphs are separated only by blank lines.
 246 Semicolons start comments.
 247 \\{lisp-interaction-mode-map}
 248 Entry to this mode calls the value of `lisp-interaction-mode-hook'
 249 if that value is non-nil."
 250   (interactive)
 251   (kill-all-local-variables)
 252   (use-local-map lisp-interaction-mode-map)
 253   (setq major-mode 'lisp-interaction-mode)
 254   (setq mode-name "Lisp Interaction")
 255   (set-syntax-table emacs-lisp-mode-syntax-table)
 256   (lisp-mode-variables nil)
 257   (run-hooks 'lisp-interaction-mode-hook))
 258
 259 (defun eval-print-last-sexp ()
 260   "Evaluate sexp before point; print value into current buffer."
 261   (interactive)
 262   (let ((standard-output (current-buffer)))
 263     (terpri)
 264     (eval-last-sexp t)
 265     (terpri)))
 266 \f
 267 (defun eval-last-sexp (eval-last-sexp-arg-internal)
 268   "Evaluate sexp before point; print value in minibuffer.
 269 With argument, print output into current buffer."
 270   (interactive "P")
 271   (let ((standard-output (if eval-last-sexp-arg-internal (current-buffer) t))
 272         (opoint (point)))
 273     (prin1 (let ((stab (syntax-table)))
 274              (eval (unwind-protect
 275                        (save-excursion
 276                          (set-syntax-table emacs-lisp-mode-syntax-table)
 277                          (forward-sexp -1)
 278                          (save-restriction
 279                            (narrow-to-region (point-min) opoint)
 280                            (read (current-buffer))))
 281                      (set-syntax-table stab)))))))
 282
 283 (defun eval-defun (eval-defun-arg-internal)
 284   "Evaluate defun that point is in or before.
 285 Print value in minibuffer.
 286 With argument, insert value in current buffer after the defun."
 287   (interactive "P")
 288   (let ((standard-output (if eval-defun-arg-internal (current-buffer) t))
 289         (form (save-excursion
 290                 (end-of-defun)
 291                 (beginning-of-defun)
 292                 (read (current-buffer)))))
 293     (if (and (eq (car form) 'defvar)
 294              (cdr-safe (cdr-safe form)))
 295         (setq form (cons 'defconst (cdr form))))
 296     (prin1 (eval form))))
 297 \f
 298 (defun lisp-comment-indent ()
 299   (if (looking-at "\\s<\\s<\\s<")
 300       (current-column)
 301     (if (looking-at "\\s<\\s<")
 302         (let ((tem (calculate-lisp-indent)))
 303           (if (listp tem) (car tem) tem))
 304       (skip-chars-backward " \t")
 305       (max (if (bolp) 0 (1+ (current-column)))
 306            comment-column))))
 307
 308 (defconst lisp-indent-offset nil "")
 309 (defconst lisp-indent-function 'lisp-indent-function "")
 310
 311 (defun lisp-indent-line (&optional whole-exp)
 312   "Indent current line as Lisp code.
 313 With argument, indent any additional lines of the same expression
 314 rigidly along with this one."
 315   (interactive "P")
 316   (let ((indent (calculate-lisp-indent)) shift-amt beg end
 317         (pos (- (point-max) (point))))
 318     (beginning-of-line)
 319     (setq beg (point))
 320     (skip-chars-forward " \t")
 321     (if (looking-at "\\s<\\s<\\s<")
 322         ;; Don't alter indentation of a ;;; comment line.
 323         (goto-char (- (point-max) pos))
 324       (if (and (looking-at "\\s<") (not (looking-at "\\s<\\s<")))
 325           ;; Single-semicolon comment lines should be indented
 326           ;; as comment lines, not as code.
 327           (progn (indent-for-comment) (forward-char -1))
 328         (if (listp indent) (setq indent (car indent)))
 329         (setq shift-amt (- indent (current-column)))
 330         (if (zerop shift-amt)
 331             nil
 332           (delete-region beg (point))
 333           (indent-to indent)))
 334       ;; If initial point was within line's indentation,
 335       ;; position after the indentation.  Else stay at same point in text.
 336       (if (> (- (point-max) pos) (point))
 337           (goto-char (- (point-max) pos)))
 338       ;; If desired, shift remaining lines of expression the same amount.
 339       (and whole-exp (not (zerop shift-amt))
 340            (save-excursion
 341              (goto-char beg)
 342              (forward-sexp 1)
 343              (setq end (point))
 344              (goto-char beg)
 345              (forward-line 1)
 346              (setq beg (point))
 347              (> end beg))
 348            (indent-code-rigidly beg end shift-amt)))))
 349
 350 (defvar calculate-lisp-indent-last-sexp)
 351
 352 (defun calculate-lisp-indent (&optional parse-start)
 353   "Return appropriate indentation for current line as Lisp code.
 354 In usual case returns an integer: the column to indent to.
 355 Can instead return a list, whose car is the column to indent to.
 356 This means that following lines at the same level of indentation
 357 should not necessarily be indented the same way.
 358 The second element of the list is the buffer position
 359 of the start of the containing expression."
 360   (save-excursion
 361     (beginning-of-line)
 362     (let ((indent-point (point))
 363           state paren-depth
 364           ;; setting this to a number inhibits calling hook
 365           (desired-indent nil)
 366           (retry t)
 367           calculate-lisp-indent-last-sexp containing-sexp)
 368       (if parse-start
 369           (goto-char parse-start)
 370           (beginning-of-defun))
 371       ;; Find outermost containing sexp
 372       (while (< (point) indent-point)
 373         (setq state (parse-partial-sexp (point) indent-point 0)))
 374       ;; Find innermost containing sexp
 375       (while (and retry
 376                   state
 377                   (> (setq paren-depth (elt state 0)) 0))
 378         (setq retry nil)
 379         (setq calculate-lisp-indent-last-sexp (elt state 2))
 380         (setq containing-sexp (elt state 1))
 381         ;; Position following last unclosed open.
 382         (goto-char (1+ containing-sexp))
 383         ;; Is there a complete sexp since then?
 384         (if (and calculate-lisp-indent-last-sexp
 385                  (> calculate-lisp-indent-last-sexp (point)))
 386             ;; Yes, but is there a containing sexp after that?
 387             (let ((peek (parse-partial-sexp calculate-lisp-indent-last-sexp
 388                                             indent-point 0)))
 389               (if (setq retry (car (cdr peek))) (setq state peek)))))
 390       (if retry
 391           nil
 392         ;; Innermost containing sexp found
 393         (goto-char (1+ containing-sexp))
 394         (if (not calculate-lisp-indent-last-sexp)
 395             ;; indent-point immediately follows open paren.
 396             ;; Don't call hook.
 397             (setq desired-indent (current-column))
 398           ;; Find the start of first element of containing sexp.
 399           (parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
 400           (cond ((looking-at "\\s(")
 401                  ;; First element of containing sexp is a list.
 402                  ;; Indent under that list.
 403                  )
 404                 ((> (save-excursion (forward-line 1) (point))
 405                     calculate-lisp-indent-last-sexp)
 406                  ;; This is the first line to start within the containing sexp.
 407                  ;; It's almost certainly a function call.
 408                  (if (= (point) calculate-lisp-indent-last-sexp)
 409                      ;; Containing sexp has nothing before this line
 410                      ;; except the first element.  Indent under that element.
 411                      nil
 412                    ;; Skip the first element, find start of second (the first
 413                    ;; argument of the function call) and indent under.
 414                    (progn (forward-sexp 1)
 415                           (parse-partial-sexp (point)
 416                                               calculate-lisp-indent-last-sexp
 417                                               0 t)))
 418                  (backward-prefix-chars))
 419                 (t
 420                  ;; Indent beneath first sexp on same line as
 421                  ;; calculate-lisp-indent-last-sexp.  Again, it's
 422                  ;; almost certainly a function call.
 423                  (goto-char calculate-lisp-indent-last-sexp)
 424                  (beginning-of-line)
 425                  (parse-partial-sexp (point) calculate-lisp-indent-last-sexp
 426                                      0 t)
 427                  (backward-prefix-chars)))))
 428       ;; Point is at the point to indent under unless we are inside a string.
 429       ;; Call indentation hook except when overridden by lisp-indent-offset
 430       ;; or if the desired indentation has already been computed.
 431       (let ((normal-indent (current-column)))
 432         (cond ((elt state 3)
 433                ;; Inside a string, don't change indentation.
 434                (goto-char indent-point)
 435                (skip-chars-forward " \t")
 436                (current-column))
 437               ((and (integerp lisp-indent-offset) containing-sexp)
 438                ;; Indent by constant offset
 439                (goto-char containing-sexp)
 440                (+ (current-column) lisp-indent-offset))
 441               (desired-indent)
 442               ((and (boundp 'lisp-indent-function)
 443                     lisp-indent-function
 444                     (not retry))
 445                (or (funcall lisp-indent-function indent-point state)
 446                    normal-indent))
 447               (t
 448                normal-indent))))))
 449
 450 (defun lisp-indent-function (indent-point state)
 451   (let ((normal-indent (current-column)))
 452     (goto-char (1+ (elt state 1)))
 453     (parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
 454     (if (and (elt state 2)
 455              (not (looking-at "\\sw\\|\\s_")))
 456         ;; car of form doesn't seem to be a a symbol
 457         (progn
 458           (if (not (> (save-excursion (forward-line 1) (point))
 459                       calculate-lisp-indent-last-sexp))
 460               (progn (goto-char calculate-lisp-indent-last-sexp)
 461                      (beginning-of-line)
 462                      (parse-partial-sexp (point)
 463                                          calculate-lisp-indent-last-sexp 0 t)))
 464           ;; Indent under the list or under the first sexp on the same
 465           ;; line as calculate-lisp-indent-last-sexp.  Note that first
 466           ;; thing on that line has to be complete sexp since we are
 467           ;; inside the innermost containing sexp.
 468           (backward-prefix-chars)
 469           (current-column))
 470       (let ((function (buffer-substring (point)
 471                                         (progn (forward-sexp 1) (point))))
 472             method)
 473         (setq method (or (get (intern-soft function) 'lisp-indent-function)
 474                          (get (intern-soft function) 'lisp-indent-hook)))
 475         (cond ((or (eq method 'defun)
 476                    (and (null method)
 477                         (> (length function) 3)
 478                         (string-match "\\`def" function)))
 479                (lisp-indent-defform state indent-point))
 480               ((integerp method)
 481                (lisp-indent-specform method state
 482                                      indent-point normal-indent))
 483               (method
 484                 (funcall method state indent-point)))))))
 485
 486 (defconst lisp-body-indent 2
 487   "Number of columns to indent the second line of a `(def...)' form.")
 488
 489 (defun lisp-indent-specform (count state indent-point normal-indent)
 490   (let ((containing-form-start (elt state 1))
 491         (i count)
 492         body-indent containing-form-column)
 493     ;; Move to the start of containing form, calculate indentation
 494     ;; to use for non-distinguished forms (> count), and move past the
 495     ;; function symbol.  lisp-indent-function guarantees that there is at
 496     ;; least one word or symbol character following open paren of containing
 497     ;; form.
 498     (goto-char containing-form-start)
 499     (setq containing-form-column (current-column))
 500     (setq body-indent (+ lisp-body-indent containing-form-column))
 501     (forward-char 1)
 502     (forward-sexp 1)
 503     ;; Now find the start of the last form.
 504     (parse-partial-sexp (point) indent-point 1 t)
 505     (while (and (< (point) indent-point)
 506                 (condition-case ()
 507                     (progn
 508                       (setq count (1- count))
 509                       (forward-sexp 1)
 510                       (parse-partial-sexp (point) indent-point 1 t))
 511                   (error nil))))
 512     ;; Point is sitting on first character of last (or count) sexp.
 513     (if (> count 0)
 514         ;; A distinguished form.  If it is the first or second form use double
 515         ;; lisp-body-indent, else normal indent.  With lisp-body-indent bound
 516         ;; to 2 (the default), this just happens to work the same with if as
 517         ;; the older code, but it makes unwind-protect, condition-case,
 518         ;; with-output-to-temp-buffer, et. al. much more tasteful.  The older,
 519         ;; less hacked, behavior can be obtained by replacing below with
 520         ;; (list normal-indent containing-form-start).
 521         (if (<= (- i count) 1)
 522             (list (+ containing-form-column (* 2 lisp-body-indent))
 523                   containing-form-start)
 524             (list normal-indent containing-form-start))
 525       ;; A non-distinguished form.  Use body-indent if there are no
 526       ;; distinguished forms and this is the first undistinguished form,
 527       ;; or if this is the first undistinguished form and the preceding
 528       ;; distinguished form has indentation at least as great as body-indent.
 529       (if (or (and (= i 0) (= count 0))
 530               (and (= count 0) (<= body-indent normal-indent)))
 531           body-indent
 532           normal-indent))))
 533
 534 (defun lisp-indent-defform (state indent-point)
 535   (goto-char (car (cdr state)))
 536   (forward-line 1)
 537   (if (> (point) (car (cdr (cdr state))))
 538       (progn
 539         (goto-char (car (cdr state)))
 540         (+ lisp-body-indent (current-column)))))
 541
 542 \f
 543 ;; (put 'progn 'lisp-indent-function 0), say, causes progn to be indented
 544 ;; like defun if the first form is placed on the next line, otherwise
 545 ;; it is indented like any other form (i.e. forms line up under first).
 546
 547 (put 'lambda 'lisp-indent-function 'defun)
 548 (put 'autoload 'lisp-indent-function 'defun)
 549 (put 'progn 'lisp-indent-function 0)
 550 (put 'prog1 'lisp-indent-function 1)
 551 (put 'prog2 'lisp-indent-function 2)
 552 (put 'save-excursion 'lisp-indent-function 0)
 553 (put 'save-window-excursion 'lisp-indent-function 0)
 554 (put 'save-selected-window 'lisp-indent-function 0)
 555 (put 'save-restriction 'lisp-indent-function 0)
 556 (put 'save-match-data 'lisp-indent-function 0)
 557 (put 'let 'lisp-indent-function 1)
 558 (put 'let* 'lisp-indent-function 1)
 559 (put 'while 'lisp-indent-function 1)
 560 (put 'if 'lisp-indent-function 2)
 561 (put 'catch 'lisp-indent-function 1)
 562 (put 'condition-case 'lisp-indent-function 2)
 563 (put 'unwind-protect 'lisp-indent-function 1)
 564 (put 'with-output-to-temp-buffer 'lisp-indent-function 1)
 565
 566 (defun indent-sexp (&optional endpos)
 567   "Indent each line of the list starting just after point.
 568 If optional arg ENDPOS is given, indent each line, stopping when
 569 ENDPOS is encountered."
 570   (interactive)
 571   (let ((indent-stack (list nil))
 572         (next-depth 0)
 573         ;; If ENDPOS is non-nil, use nil as STARTING-POINT
 574         ;; so that calculate-lisp-indent will find the beginning of
 575         ;; the defun we are in.
 576         ;; If ENDPOS is nil, it is safe not to scan before point
 577         ;; since every line we indent is more deeply nested than point is.
 578         (starting-point (if endpos nil (point)))
 579         (last-point (point))
 580         last-depth bol outer-loop-done inner-loop-done state this-indent)
 581     (or endpos
 582         ;; Get error now if we don't have a complete sexp after point.
 583         (save-excursion (forward-sexp 1)))
 584     (save-excursion
 585       (setq outer-loop-done nil)
 586       (while (if endpos (< (point) endpos)
 587                (not outer-loop-done))
 588         (setq last-depth next-depth
 589               inner-loop-done nil)
 590         ;; Parse this line so we can learn the state
 591         ;; to indent the next line.
 592         ;; This inner loop goes through only once
 593         ;; unless a line ends inside a string.
 594         (while (and (not inner-loop-done)
 595                     (not (setq outer-loop-done (eobp))))
 596           (setq state (parse-partial-sexp (point) (progn (end-of-line) (point))
 597                                           nil nil state))
 598           (setq next-depth (car state))
 599           ;; If the line contains a comment other than the sort
 600           ;; that is indented like code,
 601           ;; indent it now with indent-for-comment.
 602           ;; Comments indented like code are right already.
 603           ;; In any case clear the in-comment flag in the state
 604           ;; because parse-partial-sexp never sees the newlines.
 605           (if (car (nthcdr 4 state))
 606               (progn (indent-for-comment)
 607                      (end-of-line)
 608                      (setcar (nthcdr 4 state) nil)))
 609           ;; If this line ends inside a string,
 610           ;; go straight to next line, remaining within the inner loop,
 611           ;; and turn off the \-flag.
 612           (if (car (nthcdr 3 state))
 613               (progn
 614                 (forward-line 1)
 615                 (setcar (nthcdr 5 state) nil))
 616             (setq inner-loop-done t)))
 617         (and endpos
 618              (<= next-depth 0)
 619              (progn
 620                (setq indent-stack (append indent-stack
 621                                           (make-list (- next-depth) nil))
 622                      last-depth (- last-depth next-depth)
 623                      next-depth 0)))
 624         (or outer-loop-done endpos
 625             (setq outer-loop-done (<= next-depth 0)))
 626         (if outer-loop-done
 627             (forward-line 1)
 628           (while (> last-depth next-depth)
 629             (setq indent-stack (cdr indent-stack)
 630                   last-depth (1- last-depth)))
 631           (while (< last-depth next-depth)
 632             (setq indent-stack (cons nil indent-stack)
 633                   last-depth (1+ last-depth)))
 634           ;; Now go to the next line and indent it according
 635           ;; to what we learned from parsing the previous one.
 636           (forward-line 1)
 637           (setq bol (point))
 638           (skip-chars-forward " \t")
 639           ;; But not if the line is blank, or just a comment
 640           ;; (except for double-semi comments; indent them as usual).
 641           (if (or (eobp) (looking-at "\\s<\\|\n"))
 642               nil
 643             (if (and (car indent-stack)
 644                      (>= (car indent-stack) 0))
 645                 (setq this-indent (car indent-stack))
 646               (let ((val (calculate-lisp-indent
 647                           (if (car indent-stack) (- (car indent-stack))
 648                             starting-point))))
 649                 (if (integerp val)
 650                     (setcar indent-stack
 651                             (setq this-indent val))
 652                   (setcar indent-stack (- (car (cdr val))))
 653                   (setq this-indent (car val)))))
 654             (if (/= (current-column) this-indent)
 655                 (progn (delete-region bol (point))
 656                        (indent-to this-indent)))))
 657         (or outer-loop-done
 658             (setq outer-loop-done (= (point) last-point))
 659             (setq last-point (point)))))))
 660
 661 ;; Indent every line whose first char is between START and END inclusive.
 662 (defun lisp-indent-region (start end)
 663   (save-excursion
 664     (let ((endmark (copy-marker end)))
 665       (goto-char start)
 666       (and (bolp) (not (eolp))
 667            (lisp-indent-line))
 668       (indent-sexp endmark)
 669       (set-marker endmark nil))))
 670 \f
 671 ;;;; Lisp paragraph filling commands.
 672
 673 (defun lisp-fill-paragraph (&optional justify)
 674   "Like \\[fill-paragraph], but handle Emacs Lisp comments.
 675 If any of the current line is a comment, fill the comment or the
 676 paragraph of it that point is in, preserving the comment's indentation
 677 and initial semicolons."
 678   (interactive "P")
 679   (let (
 680         ;; Non-nil if the current line contains a comment.
 681         has-comment
 682
 683         ;; If has-comment, the appropriate fill-prefix for the comment.
 684         comment-fill-prefix
 685         )
 686
 687     ;; Figure out what kind of comment we are looking at.
 688     (save-excursion
 689       (beginning-of-line)
 690       (cond
 691
 692        ;; A line with nothing but a comment on it?
 693        ((looking-at "[ \t]*;[; \t]*")
 694         (setq has-comment t
 695               comment-fill-prefix (buffer-substring (match-beginning 0)
 696                                                     (match-end 0))))
 697
 698        ;; A line with some code, followed by a comment?  Remember that the
 699        ;; semi which starts the comment shouldn't be part of a string or
 700        ;; character.
 701        ((progn
 702           (while (not (looking-at ";\\|$"))
 703             (skip-chars-forward "^;\n\"\\\\?")
 704             (cond
 705              ((eq (char-after (point)) ?\\) (forward-char 2))
 706              ((memq (char-after (point)) '(?\" ??)) (forward-sexp 1))))
 707           (looking-at ";+[\t ]*"))
 708         (setq has-comment t)
 709         (setq comment-fill-prefix
 710               (concat (make-string (current-column) ? )
 711                       (buffer-substring (match-beginning 0) (match-end 0)))))))
 712
 713     (if (not has-comment)
 714         (fill-paragraph justify)
 715
 716       ;; Narrow to include only the comment, and then fill the region.
 717       (save-restriction
 718         (narrow-to-region
 719          ;; Find the first line we should include in the region to fill.
 720          (save-excursion
 721            (while (and (zerop (forward-line -1))
 722                        (looking-at "^[ \t]*;")))
 723            ;; We may have gone to far.  Go forward again.
 724            (or (looking-at "^[ \t]*;")
 725                (forward-line 1))
 726            (point))
 727          ;; Find the beginning of the first line past the region to fill.
 728          (save-excursion
 729            (while (progn (forward-line 1)
 730                          (looking-at "^[ \t]*;")))
 731            (point)))
 732
 733         ;; Lines with only semicolons on them can be paragraph boundaries.
 734         (let ((paragraph-start (concat paragraph-start "\\|^[ \t;]*$"))
 735               (paragraph-separate (concat paragraph-start "\\|^[ \t;]*$"))
 736               (fill-prefix comment-fill-prefix))
 737           (fill-paragraph justify))))
 738     t))
 739
 740 \f
 741 (defun indent-code-rigidly (start end arg &optional nochange-regexp)
 742   "Indent all lines of code, starting in the region, sideways by ARG columns.
 743 Does not affect lines starting inside comments or strings, assuming that
 744 the start of the region is not inside them.
 745
 746 Called from a program, takes args START, END, COLUMNS and NOCHANGE-REGEXP.
 747 The last is a regexp which, if matched at the beginning of a line,
 748 means don't indent that line."
 749   (interactive "r\np")
 750   (let (state)
 751     (save-excursion
 752       (goto-char end)
 753       (setq end (point-marker))
 754       (goto-char start)
 755       (or (bolp)
 756           (setq state (parse-partial-sexp (point)
 757                                           (progn
 758                                             (forward-line 1) (point))
 759                                           nil nil state)))
 760       (while (< (point) end)
 761         (or (car (nthcdr 3 state))
 762             (and nochange-regexp
 763                  (looking-at nochange-regexp))
 764             ;; If line does not start in string, indent it
 765             (let ((indent (current-indentation)))
 766               (delete-region (point) (progn (skip-chars-forward " \t") (point)))
 767               (or (eolp)
 768                   (indent-to (max 0 (+ indent arg)) 0))))
 769         (setq state (parse-partial-sexp (point)
 770                                         (progn
 771                                           (forward-line 1) (point))
 772                                         nil nil state))))))
 773
 774 (provide 'lisp-mode)
 775
 776 ;;; lisp-mode.el ends here