lisp/progmodes/which-func.el

   1 ;;; which-func.el --- print current function in mode line
   2
   3 ;; Copyright (C) 1994, 1997-1998, 2001-2012 Free Software Foundation, Inc.
   4
   5 ;; Author:   Alex Rezinsky <alexr@msil.sps.mot.com>
   6 ;;           (doesn't seem to be responsive any more)
   7 ;; Keywords: mode-line, imenu, tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This package prints name of function where your current point is
  27 ;; located in mode line. It assumes that you work with imenu package
  28 ;; and imenu--index-alist is up to date.
  29
  30 ;; KNOWN BUGS
  31 ;; ----------
  32 ;; Really this package shows not "function where the current point is
  33 ;; located now", but "nearest function which defined above the current
  34 ;; point". So if your current point is located after end of function
  35 ;; FOO but before begin of function BAR, FOO will be displayed in mode
  36 ;; line.
  37 ;; - if two windows display the same buffer, both windows
  38 ;;   show the same `which-func' information.
  39
  40 ;; TODO LIST
  41 ;; ---------
  42 ;;     1. Dependence on imenu package should be removed.  Separate
  43 ;; function determination mechanism should be used to determine the end
  44 ;; of a function as well as the beginning of a function.
  45 ;;     2. This package should be realized with the help of overlay
  46 ;; properties instead of imenu--index-alist variable.
  47
  48 ;;; History:
  49
  50 ;; THANKS TO
  51 ;; ---------
  52 ;; Per Abrahamsen   <abraham@iesd.auc.dk>
  53 ;;     Some ideas (inserting  in mode-line,  using of post-command  hook
  54 ;;     and toggling this  mode) have  been   borrowed from  his  package
  55 ;;     column.el
  56 ;; Peter Eisenhauer <pipe@fzi.de>
  57 ;;     Bug fixing in case nested indexes.
  58 ;; Terry Tateyama   <ttt@ursa0.cs.utah.edu>
  59 ;;     Suggestion to use find-file-hook for first imenu
  60 ;;     index building.
  61
  62 ;;; Code:
  63
  64 ;; Variables for customization
  65 ;; ---------------------------
  66 ;;
  67 (defvar which-func-unknown "???"
  68   "String to display in the mode line when current function is unknown.")
  69
  70 (defgroup which-func nil
  71   "Display the current function name in the modeline."
  72   :group 'tools
  73   :version "20.3")
  74
  75 (defcustom which-func-modes t
  76   ;; '(emacs-lisp-mode c-mode c++-mode objc-mode perl-mode cperl-mode python-mode
  77   ;;                makefile-mode sh-mode fortran-mode f90-mode ada-mode
  78   ;;                diff-mode)
  79   "List of major modes for which Which Function mode should be used.
  80 For other modes it is disabled.  If this is equal to t,
  81 then Which Function mode is enabled in any major mode that supports it."
  82   :group 'which-func
  83   :version "24.2"                       ; explicit list -> t
  84   :type '(choice (const :tag "All modes" t)
  85                  (repeat (symbol :tag "Major mode"))))
  86
  87 (defcustom which-func-non-auto-modes nil
  88   "List of major modes where Which Function mode is inactive till Imenu is used.
  89 This means that Which Function mode won't really do anything
  90 until you use Imenu, in these modes.  Note that files
  91 larger than `which-func-maxout' behave in this way too;
  92 Which Function mode doesn't do anything until you use Imenu."
  93   :group 'which-func
  94   :type '(repeat (symbol :tag "Major mode")))
  95
  96 (defcustom which-func-maxout 500000
  97   "Don't automatically compute the Imenu menu if buffer is this big or bigger.
  98 Zero means compute the Imenu menu regardless of size."
  99   :group 'which-func
 100   :type 'integer)
 101
 102 (defvar which-func-keymap
 103   (let ((map (make-sparse-keymap)))
 104     (define-key map [mode-line mouse-1] 'beginning-of-defun)
 105     (define-key map [mode-line mouse-2]
 106       (lambda ()
 107         (interactive)
 108         (if (eq (point-min) 1)
 109             (narrow-to-defun)
 110           (widen))))
 111     (define-key map [mode-line mouse-3] 'end-of-defun)
 112     map)
 113   "Keymap to display on mode line which-func.")
 114
 115 (defface which-func
 116   ;; Whether `font-lock-function-name-face' is an appropriate face to
 117   ;; inherit depends on the mode-line face; define several variants based
 118   ;; on the default mode-line face.
 119   '(;; The default mode-line face on a high-color display is a relatively
 120     ;; light color ("grey75"), and only the light-background variant of
 121     ;; `font-lock-function-name-face' is visible against it.
 122     (((class color) (min-colors 88) (background light))
 123      :inherit font-lock-function-name-face)
 124     ;; The default mode-line face on other display types is inverse-video;
 125     ;; it seems that only in the dark-background case is
 126     ;; `font-lock-function-name-face' visible against it.
 127     (((class grayscale mono) (background dark))
 128      :inherit font-lock-function-name-face)
 129     (((class color) (background light))
 130      :inherit font-lock-function-name-face)
 131     ;; If none of the above cases, use an explicit color chosen to contrast
 132     ;; well with the default mode-line face.
 133     (((class color) (min-colors 88) (background dark))
 134      :foreground "Blue1")
 135     (((background dark))
 136      :foreground "Blue1")
 137     (t
 138      :foreground "LightSkyBlue"))
 139   "Face used to highlight mode line function names."
 140   :group 'which-func)
 141
 142 (defcustom which-func-format
 143   `("["
 144     (:propertize which-func-current
 145                  local-map ,which-func-keymap
 146                  face which-func
 147                  ;;mouse-face highlight ; currently not evaluated :-(
 148                  help-echo "mouse-1: go to beginning\n\
 149 mouse-2: toggle rest visibility\n\
 150 mouse-3: go to end")
 151     "]")
 152   "Format for displaying the function in the mode line."
 153   :group 'which-func
 154   :type 'sexp)
 155 ;;;###autoload (put 'which-func-format 'risky-local-variable t)
 156
 157 (defvar which-func-imenu-joiner-function (lambda (x) (car (last x)))
 158   "Function to join together multiple levels of imenu nomenclature.
 159 Called with a single argument, a list of strings giving the names
 160 of the menus we had to traverse to get to the item.  Returns a
 161 single string, the new name of the item.")
 162
 163 (defvar which-func-cleanup-function nil
 164   "Function to transform a string before displaying it in the mode line.
 165 The function is called with one argument, the string to display.
 166 Its return value is displayed in the modeline.
 167 If nil, no function is called.  The default value is nil.
 168
 169 This feature can be useful if Imenu is set up to make more
 170 detailed entries (e.g., containing the argument list of a function),
 171 and you want to simplify them for the mode line
 172 \(e.g., removing the parameter list to just have the function name.)")
 173
 174 ;;; Code, nothing to customize below here
 175 ;;; -------------------------------------
 176 ;;;
 177 (require 'imenu)
 178
 179 (defvar which-func-table (make-hash-table :test 'eq :weakness 'key))
 180
 181 (defconst which-func-current
 182   '(:eval (replace-regexp-in-string
 183            "%" "%%"
 184            (gethash (selected-window) which-func-table which-func-unknown))))
 185 ;;;###autoload (put 'which-func-current 'risky-local-variable t)
 186
 187 (defvar which-func-mode nil
 188   "Non-nil means display current function name in mode line.
 189 This makes a difference only if `which-function-mode' is non-nil.")
 190 (make-variable-buffer-local 'which-func-mode)
 191 ;;(put 'which-func-mode 'permanent-local t)
 192
 193 (add-hook 'find-file-hook 'which-func-ff-hook t)
 194
 195 (defun which-func-ff-hook ()
 196   "File find hook for Which Function mode.
 197 It creates the Imenu index for the buffer, if necessary."
 198   (setq which-func-mode
 199         (and which-function-mode
 200              (or (eq which-func-modes t)
 201                  (member major-mode which-func-modes))))
 202
 203   (condition-case err
 204       (if (and which-func-mode
 205                (not (member major-mode which-func-non-auto-modes))
 206                (or (null which-func-maxout)
 207                    (< buffer-saved-size which-func-maxout)
 208                    (= which-func-maxout 0)))
 209           (setq imenu--index-alist
 210                 (save-excursion (funcall imenu-create-index-function))))
 211     (error
 212      (unless (equal err '(error "This buffer cannot use `imenu-default-create-index-function'"))
 213        (message "which-func-ff-hook error: %S" err))
 214      (setq which-func-mode nil))))
 215
 216 (defun which-func-update ()
 217   ;; "Update the Which-Function mode display for all windows."
 218   ;; (walk-windows 'which-func-update-1 nil 'visible))
 219   (which-func-update-1 (selected-window)))
 220
 221 (defun which-func-update-1 (window)
 222   "Update the Which Function mode display for window WINDOW."
 223   (with-selected-window window
 224     (when which-func-mode
 225       (condition-case info
 226           (let ((current (which-function)))
 227             (unless (equal current (gethash window which-func-table))
 228               (puthash window current which-func-table)
 229               (force-mode-line-update)))
 230         (error
 231          (setq which-func-mode nil)
 232          (error "Error in which-func-update: %S" info))))))
 233
 234 ;;;###autoload
 235 (defun which-func-mode (&optional arg)
 236   (which-function-mode arg))
 237 (make-obsolete 'which-func-mode 'which-function-mode "24.1")
 238
 239 (defvar which-func-update-timer nil)
 240
 241 ;; This is the name people would normally expect.
 242 ;;;###autoload
 243 (define-minor-mode which-function-mode
 244   "Toggle mode line display of current function (Which Function mode).
 245 With a prefix argument ARG, enable Which Function mode if ARG is
 246 positive, and disable it otherwise.  If called from Lisp, enable
 247 the mode if ARG is omitted or nil.
 248
 249 Which Function mode is a global minor mode.  When enabled, the
 250 current function name is continuously displayed in the mode line,
 251 in certain major modes."
 252   :global t :group 'which-func
 253   (when (timerp which-func-update-timer)
 254     (cancel-timer which-func-update-timer))
 255   (setq which-func-update-timer nil)
 256   (if which-function-mode
 257       ;;Turn it on
 258       (progn
 259         (setq which-func-update-timer
 260               (run-with-idle-timer idle-update-delay t 'which-func-update))
 261         (dolist (buf (buffer-list))
 262           (with-current-buffer buf
 263             (setq which-func-mode
 264                   (or (eq which-func-modes t)
 265                       (member major-mode which-func-modes))))))
 266     ;; Turn it off
 267     (dolist (buf (buffer-list))
 268       (with-current-buffer buf (setq which-func-mode nil)))))
 269
 270 (defvar which-function-imenu-failed nil
 271   "Locally t in a buffer if `imenu--make-index-alist' found nothing there.")
 272
 273 (defvar which-func-functions nil
 274   "List of functions for `which-function' to call with no arguments.
 275 It calls them sequentially, and if any returns non-nil,
 276 `which-function' uses that name and stops looking for the name.")
 277
 278 (defun which-function ()
 279   "Return current function name based on point.
 280 Uses `which-func-functions', `imenu--index-alist'
 281 or `add-log-current-defun'.
 282 If no function name is found, return nil."
 283   (let ((name
 284          ;; Try the `which-func-functions' functions first.
 285          (run-hook-with-args-until-success 'which-func-functions)))
 286
 287     ;; If Imenu is loaded, try to make an index alist with it.
 288     (when (and (null name)
 289                (boundp 'imenu--index-alist) (null imenu--index-alist)
 290                (null which-function-imenu-failed))
 291       (imenu--make-index-alist t)
 292       (unless imenu--index-alist
 293         (set (make-local-variable 'which-function-imenu-failed) t)))
 294     ;; If we have an index alist, use it.
 295     (when (and (null name)
 296                (boundp 'imenu--index-alist) imenu--index-alist)
 297       (let ((alist imenu--index-alist)
 298             (minoffset (point-max))
 299             offset pair mark imstack namestack)
 300         ;; Elements of alist are either ("name" . marker), or
 301         ;; ("submenu" ("name" . marker) ... ). The list can be
 302         ;; arbitrarily nested.
 303         (while (or alist imstack)
 304           (if (null alist)
 305               (setq alist     (car imstack)
 306                     namestack (cdr namestack)
 307                     imstack   (cdr imstack))
 308
 309             (setq pair (car-safe alist)
 310                   alist (cdr-safe alist))
 311
 312             (cond
 313              ((atom pair))              ; Skip anything not a cons.
 314
 315              ((imenu--subalist-p pair)
 316               (setq imstack   (cons alist imstack)
 317                     namestack (cons (car pair) namestack)
 318                     alist     (cdr pair)))
 319
 320              ((number-or-marker-p (setq mark (cdr pair)))
 321               (when (and (>= (setq offset (- (point) mark)) 0)
 322                          (< offset minoffset)) ; Find the closest item.
 323                 (setq minoffset offset
 324                       name (if (null which-func-imenu-joiner-function)
 325                                (car pair)
 326                              (funcall
 327                               which-func-imenu-joiner-function
 328                               (reverse (cons (car pair) namestack))))))))))))
 329
 330     ;; Try using add-log support.
 331     (when (null name)
 332       (setq name (add-log-current-defun)))
 333     ;; Filter the name if requested.
 334     (when name
 335       (if which-func-cleanup-function
 336           (funcall which-func-cleanup-function name)
 337         name))))
 338
 339 (provide 'which-func)
 340
 341 ;;; which-func.el ends here