lisp/server.el

   1 ;;; server.el --- Lisp code for GNU Emacs running as server process
   2
   3 ;; Copyright (C) 1986, 1987, 1992, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   4 ;;   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: William Sommerfeld <wesommer@athena.mit.edu>
   7 ;; Maintainer: FSF
   8 ;; Keywords: processes
   9
  10 ;; Changes by peck@sun.com and by rms.
  11 ;; Overhaul by Karoly Lorentey <lorentey@elte.hu> for multi-tty support.
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;; This Lisp code is run in Emacs when it is to operate as
  31 ;; a server for other processes.
  32
  33 ;; Load this library and do M-x server-edit to enable Emacs as a server.
  34 ;; Emacs opens up a socket for communication with clients.  If there are no
  35 ;; client buffers to edit, server-edit acts like (switch-to-buffer
  36 ;; (other-buffer))
  37
  38 ;; When some other program runs "the editor" to edit a file,
  39 ;; "the editor" can be the Emacs client program ../lib-src/emacsclient.
  40 ;; This program transmits the file names to Emacs through
  41 ;; the server subprocess, and Emacs visits them and lets you edit them.
  42
  43 ;; Note that any number of clients may dispatch files to Emacs to be edited.
  44
  45 ;; When you finish editing a Server buffer, again call server-edit
  46 ;; to mark that buffer as done for the client and switch to the next
  47 ;; Server buffer.  When all the buffers for a client have been edited
  48 ;; and exited with server-edit, the client "editor" will return
  49 ;; to the program that invoked it.
  50
  51 ;; Your editing commands and Emacs's display output go to and from
  52 ;; the terminal in the usual way.  Thus, server operation is possible
  53 ;; only when Emacs can talk to the terminal at the time you invoke
  54 ;; the client.  This is possible in four cases:
  55
  56 ;; 1. On a window system, where Emacs runs in one window and the
  57 ;; program that wants to use "the editor" runs in another.
  58
  59 ;; 2. On a multi-terminal system, where Emacs runs on one terminal and the
  60 ;; program that wants to use "the editor" runs on another.
  61
  62 ;; 3. When the program that wants to use "the editor" is running
  63 ;; as a subprocess of Emacs.
  64
  65 ;; 4. On a system with job control, when Emacs is suspended, the program
  66 ;; that wants to use "the editor" will stop and display
  67 ;; "Waiting for Emacs...".  It can then be suspended, and Emacs can be
  68 ;; brought into the foreground for editing.  When done editing, Emacs is
  69 ;; suspended again, and the client program is brought into the foreground.
  70
  71 ;; The buffer local variable "server-buffer-clients" lists
  72 ;; the clients who are waiting for this buffer to be edited.
  73 ;; The global variable "server-clients" lists all the waiting clients,
  74 ;; and which files are yet to be edited for each.
  75
  76 ;; Todo:
  77
  78 ;; - handle command-line-args-left.
  79 ;; - move most of the args processing and decision making from emacsclient.c
  80 ;;   to here.
  81 ;; - fix up handling of the client's environment (place it in the terminal?).
  82
  83 ;;; Code:
  84
  85 (eval-when-compile (require 'cl))
  86
  87 (defgroup server nil
  88   "Emacs running as a server process."
  89   :group 'external)
  90
  91 (defcustom server-use-tcp nil
  92   "If non-nil, use TCP sockets instead of local sockets."
  93   :set #'(lambda (sym val)
  94            (unless (featurep 'make-network-process '(:family local))
  95              (setq val t)
  96              (unless load-in-progress
  97                (message "Local sockets unsupported, using TCP sockets")))
  98            (when val (random t))
  99            (set-default sym val))
 100   :group 'server
 101   :type 'boolean
 102   :version "22.1")
 103
 104 (defcustom server-host nil
 105   "The name or IP address to use as host address of the server process.
 106 If set, the server accepts remote connections; otherwise it is local."
 107   :group 'server
 108   :type '(choice
 109           (string :tag "Name or IP address")
 110           (const :tag "Local" nil))
 111   :version "22.1")
 112 (put 'server-host 'risky-local-variable t)
 113
 114 (defcustom server-auth-dir (locate-user-emacs-file "server/")
 115   "Directory for server authentication files."
 116   :group 'server
 117   :type 'directory
 118   :version "22.1")
 119 (put 'server-auth-dir 'risky-local-variable t)
 120
 121 (defcustom server-raise-frame t
 122   "If non-nil, raise frame when switching to a buffer."
 123   :group 'server
 124   :type 'boolean
 125   :version "22.1")
 126
 127 (defcustom server-visit-hook nil
 128   "Hook run when visiting a file for the Emacs server."
 129   :group 'server
 130   :type 'hook)
 131
 132 (defcustom server-switch-hook nil
 133   "Hook run when switching to a buffer for the Emacs server."
 134   :group 'server
 135   :type 'hook)
 136
 137 (defcustom server-done-hook nil
 138   "Hook run when done editing a buffer for the Emacs server."
 139   :group 'server
 140   :type 'hook)
 141
 142 (defvar server-process nil
 143   "The current server process.")
 144
 145 (defvar server-clients nil
 146   "List of current server clients.
 147 Each element is a process.")
 148
 149 (defvar server-buffer-clients nil
 150   "List of client processes requesting editing of current buffer.")
 151 (make-variable-buffer-local 'server-buffer-clients)
 152 ;; Changing major modes should not erase this local.
 153 (put 'server-buffer-clients 'permanent-local t)
 154
 155 (defcustom server-window nil
 156   "Specification of the window to use for selecting Emacs server buffers.
 157 If nil, use the selected window.
 158 If it is a function, it should take one argument (a buffer) and
 159 display and select it.  A common value is `pop-to-buffer'.
 160 If it is a window, use that.
 161 If it is a frame, use the frame's selected window.
 162
 163 It is not meaningful to set this to a specific frame or window with Custom.
 164 Only programs can do so."
 165   :group 'server
 166   :version "22.1"
 167   :type '(choice (const :tag "Use selected window"
 168                         :match (lambda (widget value)
 169                                  (not (functionp value)))
 170                         nil)
 171                  (function-item :tag "Display in new frame" switch-to-buffer-other-frame)
 172                  (function-item :tag "Use pop-to-buffer" pop-to-buffer)
 173                  (function :tag "Other function")))
 174
 175 (defcustom server-temp-file-regexp "^/tmp/Re\\|/draft$"
 176   "Regexp matching names of temporary files.
 177 These are deleted and reused after each edit by the programs that
 178 invoke the Emacs server."
 179   :group 'server
 180   :type 'regexp)
 181
 182 (defcustom server-kill-new-buffers t
 183   "Whether to kill buffers when done with them.
 184 If non-nil, kill a buffer unless it already existed before editing
 185 it with the Emacs server.  If nil, kill only buffers as specified by
 186 `server-temp-file-regexp'.
 187 Please note that only buffers that still have a client are killed,
 188 i.e. buffers visited with \"emacsclient --no-wait\" are never killed in
 189 this way."
 190   :group 'server
 191   :type 'boolean
 192   :version "21.1")
 193
 194 (or (assq 'server-buffer-clients minor-mode-alist)
 195     (push '(server-buffer-clients " Server") minor-mode-alist))
 196
 197 (defvar server-existing-buffer nil
 198   "Non-nil means the buffer existed before the server was asked to visit it.
 199 This means that the server should not kill the buffer when you say you
 200 are done with it in the server.")
 201 (make-variable-buffer-local 'server-existing-buffer)
 202
 203 (defvar server-name "server")
 204
 205 (defvar server-socket-dir
 206   (format "%s/emacs%d" (or (getenv "TMPDIR") "/tmp") (user-uid))
 207   "The directory in which to place the server socket.")
 208
 209 (defun server-clients-with (property value)
 210   "Return a list of clients with PROPERTY set to VALUE."
 211   (let (result)
 212     (dolist (proc server-clients result)
 213       (when (equal value (process-get proc property))
 214         (push proc result)))))
 215
 216 (defun server-add-client (proc)
 217   "Create a client for process PROC, if it doesn't already have one.
 218 New clients have no properties."
 219   (add-to-list 'server-clients proc))
 220
 221 (defmacro server-with-environment (env vars &rest body)
 222   "Evaluate BODY with environment variables VARS set to those in ENV.
 223 The environment variables are then restored to their previous values.
 224
 225 VARS should be a list of strings.
 226 ENV should be in the same format as `process-environment'."
 227   (declare (indent 2))
 228   (let ((var (make-symbol "var"))
 229         (value (make-symbol "value")))
 230     `(let ((process-environment process-environment))
 231        (dolist (,var ,vars)
 232          (let ((,value (getenv-internal ,var ,env)))
 233            (push (if (null ,value)
 234                      ,var
 235                    (concat ,var "=" ,value))
 236                  process-environment)))
 237        (progn ,@body))))
 238
 239 (defun server-delete-client (proc &optional noframe)
 240   "Delete PROC, including its buffers, terminals and frames.
 241 If NOFRAME is non-nil, let the frames live.  (To be used from
 242 `delete-frame-functions'.)"
 243   (server-log (concat "server-delete-client" (if noframe " noframe")) proc)
 244   ;; Force a new lookup of client (prevents infinite recursion).
 245   (when (memq proc server-clients)
 246     (let ((buffers (process-get proc 'buffers)))
 247
 248       ;; Kill the client's buffers.
 249       (dolist (buf buffers)
 250         (when (buffer-live-p buf)
 251           (with-current-buffer buf
 252             ;; Kill the buffer if necessary.
 253             (when (and (equal server-buffer-clients
 254                               (list proc))
 255                        (or (and server-kill-new-buffers
 256                                 (not server-existing-buffer))
 257                            (server-temp-file-p))
 258                        (not (buffer-modified-p)))
 259               (let (flag)
 260                 (unwind-protect
 261                     (progn (setq server-buffer-clients nil)
 262                            (kill-buffer (current-buffer))
 263                            (setq flag t))
 264                   (unless flag
 265                     ;; Restore clients if user pressed C-g in `kill-buffer'.
 266                     (setq server-buffer-clients (list proc)))))))))
 267
 268       ;; Delete the client's frames.
 269       (unless noframe
 270         (dolist (frame (frame-list))
 271           (when (and (frame-live-p frame)
 272                      (equal proc (frame-parameter frame 'client)))
 273             ;; Prevent `server-handle-delete-frame' from calling us
 274             ;; recursively.
 275             (set-frame-parameter frame 'client nil)
 276             (delete-frame frame))))
 277
 278       (setq server-clients (delq proc server-clients))
 279
 280       ;; Delete the client's tty.
 281       (let ((terminal (process-get proc 'terminal)))
 282         ;; Only delete the terminal if it is non-nil.
 283         (when (and terminal (eq (terminal-live-p terminal) t))
 284           (delete-terminal terminal)))
 285
 286       ;; Delete the client's process.
 287       (if (eq (process-status proc) 'open)
 288           (delete-process proc))
 289
 290       (server-log "Deleted" proc))))
 291
 292 (defvar server-log-time-function 'current-time-string
 293   "Function to generate timestamps for `server-buffer'.")
 294
 295 (defconst server-buffer " *server*"
 296   "Buffer used internally by Emacs's server.
 297 One use is to log the I/O for debugging purposes (see `server-log'),
 298 the other is to provide a current buffer in which the process filter can
 299 safely let-bind buffer-local variables like `default-directory'.")
 300
 301 (defvar server-log nil
 302   "If non-nil, log the server's inputs and outputs in the `server-buffer'.")
 303
 304 (defun server-log (string &optional client)
 305   "If `server-log' is non-nil, log STRING to `server-buffer'.
 306 If CLIENT is non-nil, add a description of it to the logged message."
 307   (when server-log
 308     (with-current-buffer (get-buffer-create server-buffer)
 309       (goto-char (point-max))
 310       (insert (funcall server-log-time-function)
 311               (cond
 312                 ((null client) " ")
 313                 ((listp client) (format " %s: " (car client)))
 314                 (t (format " %s: " client)))
 315               string)
 316       (or (bolp) (newline)))))
 317
 318 (defun server-sentinel (proc msg)
 319   "The process sentinel for Emacs server connections."
 320   ;; If this is a new client process, set the query-on-exit flag to nil
 321   ;; for this process (it isn't inherited from the server process).
 322   (when (and (eq (process-status proc) 'open)
 323              (process-query-on-exit-flag proc))
 324     (set-process-query-on-exit-flag proc nil))
 325   ;; Delete the associated connection file, if applicable.
 326   ;; This is actually problematic: the file may have been overwritten by
 327   ;; another Emacs server in the mean time, so it's not ours any more.
 328   ;; (and (process-contact proc :server)
 329   ;;      (eq (process-status proc) 'closed)
 330   ;;      (ignore-errors (delete-file (process-get proc :server-file))))
 331   (server-log (format "Status changed to %s: %s" (process-status proc) msg) proc)
 332   (server-delete-client proc))
 333
 334 (defun server-select-display (display)
 335   ;; If the current frame is on `display' we're all set.
 336   ;; Similarly if we are unable to open a frames on other displays, there's
 337   ;; nothing more we can do.
 338   (unless (or (not (fboundp 'make-frame-on-display))
 339               (equal (frame-parameter (selected-frame) 'display) display))
 340     ;; Otherwise, look for an existing frame there and select it.
 341     (dolist (frame (frame-list))
 342       (when (equal (frame-parameter frame 'display) display)
 343         (select-frame frame)))
 344     ;; If there's no frame on that display yet, create and select one.
 345     (unless (equal (frame-parameter (selected-frame) 'display) display)
 346       (let* ((buffer (generate-new-buffer " *server-dummy*"))
 347              (frame (make-frame-on-display
 348                      display
 349                      ;; Make it display (and remember) some dummy buffer, so
 350                      ;; we can detect later if the frame is in use or not.
 351                      `((server-dummy-buffer . ,buffer)
 352                        ;; This frame may be deleted later (see
 353                        ;; server-unselect-display) so we want it to be as
 354                        ;; unobtrusive as possible.
 355                        (visibility . nil)))))
 356         (select-frame frame)
 357         (set-window-buffer (selected-window) buffer)
 358         frame))))
 359
 360 (defun server-unselect-display (frame)
 361   (when (frame-live-p frame)
 362     ;; If the temporary frame is in use (displays something real), make it
 363     ;; visible.  If not (which can happen if the user's customizations call
 364     ;; pop-to-buffer etc.), delete it to avoid preserving the connection after
 365     ;; the last real frame is deleted.
 366     (if (and (eq (frame-first-window frame)
 367                  (next-window (frame-first-window frame) 'nomini))
 368              (eq (window-buffer (frame-first-window frame))
 369                  (frame-parameter frame 'server-dummy-buffer)))
 370         ;; The temp frame still only shows one buffer, and that is the
 371         ;; internal temp buffer.
 372         (delete-frame frame)
 373       (set-frame-parameter frame 'visibility t))
 374     (kill-buffer (frame-parameter frame 'server-dummy-buffer))
 375     (set-frame-parameter frame 'server-dummy-buffer nil)))
 376
 377 (defun server-handle-delete-frame (frame)
 378   "Delete the client connection when the emacsclient frame is deleted."
 379   (let ((proc (frame-parameter frame 'client)))
 380     (when (and (frame-live-p frame)
 381                proc
 382                ;; See if this is the last frame for this client.
 383                (>= 1 (let ((frame-num 0))
 384                       (dolist (f (frame-list))
 385                         (when (eq proc (frame-parameter f 'client))
 386                           (setq frame-num (1+ frame-num))))
 387                       frame-num)))
 388       (server-log (format "server-handle-delete-frame, frame %s" frame) proc)
 389       (server-delete-client proc 'noframe)))) ; Let delete-frame delete the frame later.
 390
 391 (defun server-handle-suspend-tty (terminal)
 392   "Notify the emacsclient process to suspend itself when its tty device is suspended."
 393   (dolist (proc (server-clients-with 'terminal terminal))
 394     (server-log (format "server-handle-suspend-tty, terminal %s" terminal) proc)
 395     (condition-case err
 396         (server-send-string proc "-suspend \n")
 397       (file-error                       ;The pipe/socket was closed.
 398        (ignore-errors (server-delete-client proc))))))
 399
 400 (defun server-unquote-arg (arg)
 401   "Remove &-quotation from ARG.
 402 See `server-quote-arg' and `server-process-filter'."
 403   (replace-regexp-in-string
 404    "&." (lambda (s)
 405           (case (aref s 1)
 406             (?& "&")
 407             (?- "-")
 408             (?n "\n")
 409             (t " ")))
 410    arg t t))
 411
 412 (defun server-quote-arg (arg)
 413   "In ARG, insert a & before each &, each space, each newline, and -.
 414 Change spaces to underscores, too, so that the return value never
 415 contains a space.
 416
 417 See `server-unquote-arg' and `server-process-filter'."
 418   (replace-regexp-in-string
 419    "[-&\n ]" (lambda (s)
 420                (case (aref s 0)
 421                  (?& "&&")
 422                  (?- "&-")
 423                  (?\n "&n")
 424                  (?\s "&_")))
 425    arg t t))
 426
 427 (defun server-send-string (proc string)
 428   "A wrapper around `proc-send-string' for logging."
 429   (server-log (concat "Sent " string) proc)
 430   (process-send-string proc string))
 431
 432 (defun server-ensure-safe-dir (dir)
 433   "Make sure DIR is a directory with no race-condition issues.
 434 Creates the directory if necessary and makes sure:
 435 - there's no symlink involved
 436 - it's owned by us
 437 - it's not readable/writable by anybody else."
 438   (setq dir (directory-file-name dir))
 439   (let ((attrs (file-attributes dir)))
 440     (unless attrs
 441       (letf (((default-file-modes) ?\700)) (make-directory dir t))
 442       (setq attrs (file-attributes dir)))
 443     ;; Check that it's safe for use.
 444     (unless (and (eq t (car attrs)) (eql (nth 2 attrs) (user-uid))
 445                  (or (eq system-type 'windows-nt)
 446                      (zerop (logand ?\077 (file-modes dir)))))
 447       (error "The directory %s is unsafe" dir))))
 448
 449 ;;;###autoload
 450 (defun server-start (&optional leave-dead)
 451   "Allow this Emacs process to be a server for client processes.
 452 This starts a server communications subprocess through which
 453 client \"editors\" can send your editing commands to this Emacs
 454 job.  To use the server, set up the program `emacsclient' in the
 455 Emacs distribution as your standard \"editor\".
 456
 457 Optional argument LEAVE-DEAD (interactively, a prefix arg) means just
 458 kill any existing server communications subprocess."
 459   (interactive "P")
 460   (when (or
 461          (not server-clients)
 462          (yes-or-no-p
 463           "The current server still has clients; delete them? "))
 464     (when server-process
 465       ;; kill it dead!
 466       (ignore-errors (delete-process server-process)))
 467     ;; Delete the socket files made by previous server invocations.
 468     (condition-case ()
 469         (delete-file (expand-file-name server-name server-socket-dir))
 470       (error nil))
 471     ;; If this Emacs already had a server, clear out associated status.
 472     (while server-clients
 473       (server-delete-client (car server-clients)))
 474     ;; Now any previous server is properly stopped.
 475     (if leave-dead
 476         (progn
 477           (server-log (message "Server stopped"))
 478           (setq server-process nil))
 479       (let* ((server-dir (if server-use-tcp server-auth-dir server-socket-dir))
 480              (server-file (expand-file-name server-name server-dir)))
 481         ;; Make sure there is a safe directory in which to place the socket.
 482         (server-ensure-safe-dir server-dir)
 483         ;; Remove any leftover socket or authentication file.
 484         (ignore-errors (delete-file server-file))
 485         (when server-process
 486           (server-log (message "Restarting server")))
 487         (letf (((default-file-modes) ?\700))
 488           (add-hook 'suspend-tty-functions 'server-handle-suspend-tty)
 489           (add-hook 'delete-frame-functions 'server-handle-delete-frame)
 490           (add-hook 'kill-buffer-query-functions 'server-kill-buffer-query-function)
 491           (add-hook 'kill-emacs-query-functions 'server-kill-emacs-query-function)
 492           (add-hook 'kill-emacs-hook (lambda () (server-mode -1))) ;Cleanup upon exit.
 493           (setq server-process
 494                 (apply #'make-network-process
 495                        :name server-name
 496                        :server t
 497                        :noquery t
 498                        :sentinel 'server-sentinel
 499                        :filter 'server-process-filter
 500                        ;; We must receive file names without being decoded.
 501                        ;; Those are decoded by server-process-filter according
 502                        ;; to file-name-coding-system.  Also don't get
 503                        ;; confused by CRs since we don't quote them.
 504                        :coding 'raw-text-unix
 505                        ;; The other args depend on the kind of socket used.
 506                        (if server-use-tcp
 507                            (list :family nil
 508                                  :service t
 509                                  :host (or server-host 'local)
 510                                  :plist '(:authenticated nil))
 511                          (list :family 'local
 512                                :service server-file
 513                                :plist '(:authenticated t)))))
 514           (unless server-process (error "Could not start server process"))
 515           (when server-use-tcp
 516             (let ((auth-key
 517                    (loop
 518                       ;; The auth key is a 64-byte string of random chars in the
 519                       ;; range `!'..`~'.
 520                       for i below 64
 521                       collect (+ 33 (random 94)) into auth
 522                       finally return (concat auth))))
 523               (process-put server-process :auth-key auth-key)
 524               (with-temp-file server-file
 525                 (set-buffer-multibyte nil)
 526                 (setq buffer-file-coding-system 'no-conversion)
 527                 (insert (format-network-address
 528                          (process-contact server-process :local))
 529                         " " (int-to-string (emacs-pid))
 530                         "\n" auth-key)))))))))
 531
 532 (defun server-running-p (&optional name)
 533   "Test whether server NAME is running."
 534   (interactive
 535    (list (if current-prefix-arg
 536              (read-string "Server name: " nil nil server-name))))
 537   (unless name (setq name server-name))
 538   (condition-case nil
 539       (progn
 540         (delete-process
 541          (make-network-process
 542           :name "server-client-test" :family 'local :server nil :noquery t
 543           :service (expand-file-name name server-socket-dir)))
 544         t)
 545     (file-error nil)))
 546
 547 ;;;###autoload
 548 (define-minor-mode server-mode
 549   "Toggle Server mode.
 550 With ARG, turn Server mode on if ARG is positive, off otherwise.
 551 Server mode runs a process that accepts commands from the
 552 `emacsclient' program.  See `server-start' and Info node `Emacs server'."
 553   :global t
 554   :group 'server
 555   :version "22.1"
 556   ;; Fixme: Should this check for an existing server socket and do
 557   ;; nothing if there is one (for multiple Emacs sessions)?
 558   (server-start (not server-mode)))
 559 \f
 560 (defun server-eval-and-print (expr proc)
 561   "Eval EXPR and send the result back to client PROC."
 562   (let ((v (eval (car (read-from-string expr)))))
 563     (when (and v proc)
 564       (with-temp-buffer
 565         (let ((standard-output (current-buffer)))
 566           (pp v)
 567           (let ((text (buffer-substring-no-properties
 568                        (point-min) (point-max))))
 569             (server-send-string
 570              proc (format "-print %s\n"
 571                           (server-quote-arg text)))))))))
 572
 573 (defun server-create-tty-frame (tty type proc)
 574   (add-to-list 'frame-inherited-parameters 'client)
 575   (let ((frame
 576          (server-with-environment (process-get proc 'env)
 577              '("LANG" "LC_CTYPE" "LC_ALL"
 578                ;; For tgetent(3); list according to ncurses(3).
 579                "BAUDRATE" "COLUMNS" "ESCDELAY" "HOME" "LINES"
 580                "NCURSES_ASSUMED_COLORS" "NCURSES_NO_PADDING"
 581                "NCURSES_NO_SETBUF" "TERM" "TERMCAP" "TERMINFO"
 582                "TERMINFO_DIRS" "TERMPATH"
 583                ;; rxvt wants these
 584                "COLORFGBG" "COLORTERM")
 585            (make-frame-on-tty tty type
 586                               ;; Ignore nowait here; we always need to
 587                               ;; clean up opened ttys when the client dies.
 588                               `((client . ,proc)
 589                                 ;; This is a leftover from an earlier
 590                                 ;; attempt at making it possible for process
 591                                 ;; run in the server process to use the
 592                                 ;; environment of the client process.
 593                                 ;; It has no effect now and to make it work
 594                                 ;; we'd need to decide how to make
 595                                 ;; process-environment interact with client
 596                                 ;; envvars, and then to change the
 597                                 ;; C functions `child_setup' and
 598                                 ;; `getenv_internal' accordingly.
 599                                 (environment . ,(process-get proc 'env)))))))
 600
 601     ;; ttys don't use the `display' parameter, but callproc.c does to set
 602     ;; the DISPLAY environment on subprocesses.
 603     (set-frame-parameter frame 'display
 604                          (getenv-internal "DISPLAY" (process-get proc 'env)))
 605     (select-frame frame)
 606     (process-put proc 'frame frame)
 607     (process-put proc 'terminal (frame-terminal frame))
 608
 609     ;; Display *scratch* by default.
 610     (switch-to-buffer (get-buffer-create "*scratch*") 'norecord)
 611
 612     ;; Reply with our pid.
 613     (server-send-string proc (concat "-emacs-pid "
 614                                      (number-to-string (emacs-pid)) "\n"))
 615     frame))
 616
 617 (defun server-create-window-system-frame (display nowait proc)
 618   (add-to-list 'frame-inherited-parameters 'client)
 619   (if (not (fboundp 'make-frame-on-display))
 620       (progn
 621         ;; This emacs does not support X.
 622         (server-log "Window system unsupported" proc)
 623         (server-send-string proc "-window-system-unsupported \n")
 624         nil)
 625     ;; Flag frame as client-created, but use a dummy client.
 626     ;; This will prevent the frame from being deleted when
 627     ;; emacsclient quits while also preventing
 628     ;; `server-save-buffers-kill-terminal' from unexpectedly
 629     ;; killing emacs on that frame.
 630     (let* ((params `((client . ,(if nowait 'nowait proc))
 631                      ;; This is a leftover, see above.
 632                      (environment . ,(process-get proc 'env))))
 633            (frame (make-frame-on-display
 634                    (or display
 635                        (frame-parameter nil 'display)
 636                        (getenv "DISPLAY")
 637                        (error "Please specify display"))
 638                    params)))
 639       (server-log (format "%s created" frame) proc)
 640       (select-frame frame)
 641       (process-put proc 'frame frame)
 642       (process-put proc 'terminal (frame-terminal frame))
 643
 644       ;; Display *scratch* by default.
 645       (switch-to-buffer (get-buffer-create "*scratch*") 'norecord)
 646       frame)))
 647
 648
 649 (defun server-goto-toplevel (proc)
 650   (condition-case nil
 651       ;; If we're running isearch, we must abort it to allow Emacs to
 652       ;; display the buffer and switch to it.
 653       (dolist (buffer (buffer-list))
 654         (with-current-buffer buffer
 655           (when (bound-and-true-p isearch-mode)
 656             (isearch-cancel))))
 657     ;; Signaled by isearch-cancel.
 658     (quit (message nil)))
 659   (when (> (recursion-depth) 0)
 660     ;; We're inside a minibuffer already, so if the emacs-client is trying
 661     ;; to open a frame on a new display, we might end up with an unusable
 662     ;; frame because input from that display will be blocked (until exiting
 663     ;; the minibuffer).  Better exit this minibuffer right away.
 664     ;; Similarly with recursive-edits such as the splash screen.
 665     (run-with-timer 0 nil (lexical-let ((proc proc))
 666                             (lambda () (server-execute-continuation proc))))
 667     (top-level)))
 668
 669 ;; We use various special properties on process objects:
 670 ;; - `env' stores the info about the environment of the emacsclient process.
 671 ;; - `continuation' is a no-arg function that we need to execute.  It contains
 672 ;;   commands we wanted to execute in some earlier invocation of the process
 673 ;;   filter but that we somehow were unable to process at that time
 674 ;;   (e.g. because we first need to throw to the toplevel).
 675
 676 (defun server-execute-continuation (proc)
 677   (let ((continuation (process-get proc 'continuation)))
 678     (process-put proc 'continuation nil)
 679     (if continuation (ignore-errors (funcall continuation)))))
 680
 681 (defun* server-process-filter (proc string)
 682   "Process a request from the server to edit some files.
 683 PROC is the server process.  STRING consists of a sequence of
 684 commands prefixed by a dash.  Some commands have arguments; these
 685 are &-quoted and need to be decoded by `server-unquote-arg'.  The
 686 filter parses and executes these commands.
 687
 688 To illustrate the protocol, here is an example command that
 689 emacsclient sends to create a new X frame (note that the whole
 690 sequence is sent on a single line):
 691
 692         -env HOME /home/lorentey
 693         -env DISPLAY :0.0
 694         ... lots of other -env commands
 695         -display :0.0
 696         -window-system
 697
 698 The following commands are accepted by the server:
 699
 700 `-auth AUTH-STRING'
 701   Authenticate the client using the secret authentication string
 702   AUTH-STRING.
 703
 704 `-env NAME=VALUE'
 705   An environment variable on the client side.
 706
 707 `-dir DIRNAME'
 708   The current working directory of the client process.
 709
 710 `-current-frame'
 711   Forbid the creation of new frames.
 712
 713 `-nowait'
 714   Request that the next frame created should not be
 715   associated with this client.
 716
 717 `-display DISPLAY'
 718   Set the display name to open X frames on.
 719
 720 `-position LINE[:COLUMN]'
 721   Go to the given line and column number
 722   in the next file opened.
 723
 724 `-file FILENAME'
 725   Load the given file in the current frame.
 726
 727 `-eval EXPR'
 728   Evaluate EXPR as a Lisp expression and return the
 729   result in -print commands.
 730
 731 `-window-system'
 732   Open a new X frame.
 733
 734 `-tty DEVICENAME TYPE'
 735   Open a new tty frame at the client.
 736
 737 `-suspend'
 738   Suspend this tty frame.  The client sends this string in
 739   response to SIGTSTP and SIGTTOU.  The server must cease all I/O
 740   on this tty until it gets a -resume command.
 741
 742 `-resume'
 743   Resume this tty frame.  The client sends this string when it
 744   gets the SIGCONT signal and it is the foreground process on its
 745   controlling tty.
 746
 747 `-ignore COMMENT'
 748   Do nothing, but put the comment in the server
 749   log.  Useful for debugging.
 750
 751
 752 The following commands are accepted by the client:
 753
 754 `-emacs-pid PID'
 755   Describes the process id of the Emacs process;
 756   used to forward window change signals to it.
 757
 758 `-window-system-unsupported'
 759   Signals that the server does not support creating X frames;
 760   the client must try again with a tty frame.
 761
 762 `-print STRING'
 763   Print STRING on stdout.  Used to send values
 764   returned by -eval.
 765
 766 `-error DESCRIPTION'
 767   Signal an error (but continue processing).
 768
 769 `-suspend'
 770   Suspend this terminal, i.e., stop the client process.
 771   Sent when the user presses C-z."
 772   (server-log (concat "Received " string) proc)
 773   ;; First things first: let's check the authentication
 774   (unless (process-get proc :authenticated)
 775     (if (and (string-match "-auth \\([!-~]+\\)\n?" string)
 776              (equal (match-string 1 string) (process-get proc :auth-key)))
 777         (progn
 778           (setq string (substring string (match-end 0)))
 779           (process-put proc :authenticated t)
 780           (server-log "Authentication successful" proc))
 781       (server-log "Authentication failed" proc)
 782       (server-send-string
 783        proc (concat "-error " (server-quote-arg "Authentication failed")))
 784       (delete-process proc)
 785       ;; We return immediately
 786       (return-from server-process-filter)))
 787   (let ((prev (process-get proc 'previous-string)))
 788     (when prev
 789       (setq string (concat prev string))
 790       (process-put proc 'previous-string nil)))
 791   (condition-case err
 792       (progn
 793         (server-add-client proc)
 794         (if (not (string-match "\n" string))
 795             ;; Save for later any partial line that remains.
 796             (when (> (length string) 0)
 797               (process-put proc 'previous-string string))
 798
 799           ;; In earlier versions of server.el (where we used an `emacsserver'
 800           ;; process), there could be multiple lines.  Nowadays this is not
 801           ;; supported any more.
 802           (assert (eq (match-end 0) (length string)))
 803           (let ((request (substring string 0 (match-beginning 0)))
 804                 (coding-system (and default-enable-multibyte-characters
 805                                     (or file-name-coding-system
 806                                         default-file-name-coding-system)))
 807                 nowait ; t if emacsclient does not want to wait for us.
 808                 frame ; The frame that was opened for the client (if any).
 809                 display              ; Open the frame on this display.
 810                 dontkill       ; t if the client should not be killed.
 811                 commands
 812                 dir
 813                 use-current-frame
 814                 tty-name       ;nil, `window-system', or the tty name.
 815                 tty-type             ;string.
 816                 files
 817                 filepos
 818                 command-line-args-left
 819                 arg)
 820             ;; Remove this line from STRING.
 821             (setq string (substring string (match-end 0)))
 822             (setq command-line-args-left
 823                   (mapcar 'server-unquote-arg (split-string request " " t)))
 824             (while (setq arg (pop command-line-args-left))
 825                 (cond
 826                  ;; -version CLIENT-VERSION: obsolete at birth.
 827                  ((and (equal "-version" arg) command-line-args-left)
 828                   (pop command-line-args-left))
 829
 830                  ;; -nowait:  Emacsclient won't wait for a result.
 831                  ((equal "-nowait" arg) (setq nowait t))
 832
 833                  ;; -current-frame:  Don't create frames.
 834                  ((equal "-current-frame" arg) (setq use-current-frame t))
 835
 836                  ;; -display DISPLAY:
 837                  ;; Open X frames on the given display instead of the default.
 838                  ((and (equal "-display" arg) command-line-args-left)
 839                   (setq display (pop command-line-args-left))
 840                   (if (zerop (length display)) (setq display nil)))
 841
 842                  ;; -window-system:  Open a new X frame.
 843                  ((equal "-window-system" arg)
 844                   (setq dontkill t)
 845                   (setq tty-name 'window-system))
 846
 847                  ;; -resume:  Resume a suspended tty frame.
 848                  ((equal "-resume" arg)
 849                   (lexical-let ((terminal (process-get proc 'terminal)))
 850                     (setq dontkill t)
 851                     (push (lambda ()
 852                             (when (eq (terminal-live-p terminal) t)
 853                               (resume-tty terminal)))
 854                           commands)))
 855
 856                  ;; -suspend:  Suspend the client's frame.  (In case we
 857                  ;; get out of sync, and a C-z sends a SIGTSTP to
 858                  ;; emacsclient.)
 859                  ((equal "-suspend" arg)
 860                   (lexical-let ((terminal (process-get proc 'terminal)))
 861                     (setq dontkill t)
 862                     (push (lambda ()
 863                             (when (eq (terminal-live-p terminal) t)
 864                               (suspend-tty terminal)))
 865                           commands)))
 866
 867                  ;; -ignore COMMENT:  Noop; useful for debugging emacsclient.
 868                  ;; (The given comment appears in the server log.)
 869                  ((and (equal "-ignore" arg) command-line-args-left
 870                   (setq dontkill t)
 871                   (pop command-line-args-left)))
 872
 873                  ;; -tty DEVICE-NAME TYPE:  Open a new tty frame at the client.
 874                  ((and (equal "-tty" arg)
 875                        (cdr command-line-args-left))
 876                   (setq tty-name (pop command-line-args-left)
 877                         tty-type (pop command-line-args-left)
 878                         dontkill (or dontkill
 879                                      (not use-current-frame))))
 880
 881                  ;; -position LINE[:COLUMN]:  Set point to the given
 882                  ;;  position in the next file.
 883                  ((and (equal "-position" arg)
 884                        command-line-args-left
 885                        (string-match "\\+\\([0-9]+\\)\\(?::\\([0-9]+\\)\\)?"
 886                                      (car command-line-args-left)))
 887                   (setq arg (pop command-line-args-left))
 888                   (setq filepos
 889                         (cons (string-to-number (match-string 1 arg))
 890                               (string-to-number (or (match-string 2 arg) "")))))
 891
 892                  ;; -file FILENAME:  Load the given file.
 893                  ((and (equal "-file" arg)
 894                        command-line-args-left)
 895                   (let ((file (pop command-line-args-left)))
 896                     (if coding-system
 897                         (setq file (decode-coding-string file coding-system)))
 898                     (setq file (command-line-normalize-file-name file))
 899                     (push (cons file filepos) files)
 900                     (server-log (format "New file: %s %s"
 901                                         file (or filepos "")) proc))
 902                   (setq filepos nil))
 903
 904                  ;; -eval EXPR:  Evaluate a Lisp expression.
 905                  ((and (equal "-eval" arg)
 906                        command-line-args-left)
 907                   (if use-current-frame
 908                       (setq use-current-frame 'always))
 909                   (lexical-let ((expr (pop command-line-args-left)))
 910                     (if coding-system
 911                         (setq expr (decode-coding-string expr coding-system)))
 912                     (push (lambda () (server-eval-and-print expr proc))
 913                           commands)
 914                     (setq filepos nil)))
 915
 916                  ;; -env NAME=VALUE:  An environment variable.
 917                  ((and (equal "-env" arg) command-line-args-left)
 918                   (let ((var (pop command-line-args-left)))
 919                     ;; XXX Variables should be encoded as in getenv/setenv.
 920                     (process-put proc 'env
 921                                  (cons var (process-get proc 'env)))))
 922
 923                  ;; -dir DIRNAME:  The cwd of the emacsclient process.
 924                  ((and (equal "-dir" arg) command-line-args-left)
 925                   (setq dir (pop command-line-args-left))
 926                   (if coding-system
 927                       (setq dir (decode-coding-string dir coding-system)))
 928                   (setq dir (command-line-normalize-file-name dir)))
 929
 930                  ;; Unknown command.
 931                  (t (error "Unknown command: %s" arg))))
 932
 933             (setq frame
 934                   (cond
 935                    ((and use-current-frame
 936                          (or (eq use-current-frame 'always)
 937                              ;; We can't use the Emacs daemon's
 938                              ;; terminal frame.
 939                              (not (and (= (length (frame-list)) 1)
 940                                        (eq (selected-frame)
 941                                            terminal-frame)))))
 942                     (setq tty-name nil)
 943                     (if display (server-select-display display)))
 944                    ((eq tty-name 'window-system)
 945                     (server-create-window-system-frame display nowait proc))
 946                    ;; When resuming on a tty, tty-name is nil.
 947                    (tty-name
 948                     (server-create-tty-frame tty-name tty-type proc))))
 949
 950             (process-put
 951              proc 'continuation
 952              (lexical-let ((proc proc)
 953                            (files files)
 954                            (nowait nowait)
 955                            (commands commands)
 956                            (dontkill dontkill)
 957                            (frame frame)
 958                            (dir dir)
 959                            (tty-name tty-name))
 960                (lambda ()
 961                  (with-current-buffer (get-buffer-create server-buffer)
 962                    ;; Use the same cwd as the emacsclient, if possible, so
 963                    ;; relative file names work correctly, even in `eval'.
 964                    (let ((default-directory
 965                           (if (and dir (file-directory-p dir))
 966                               dir default-directory)))
 967                      (server-execute proc files nowait commands
 968                                      dontkill frame tty-name))))))
 969
 970             (when (or frame files)
 971               (server-goto-toplevel proc))
 972
 973             (server-execute-continuation proc))))
 974     ;; condition-case
 975     (error (server-return-error proc err))))
 976
 977 (defun server-execute (proc files nowait commands dontkill frame tty-name)
 978   (condition-case err
 979       (let* ((buffers
 980               (when files
 981                 (run-hooks 'pre-command-hook)
 982                 (prog1 (server-visit-files files proc nowait)
 983                   (run-hooks 'post-command-hook)))))
 984
 985         (mapc 'funcall (nreverse commands))
 986
 987         ;; Delete the client if necessary.
 988         (cond
 989          (nowait
 990           ;; Client requested nowait; return immediately.
 991           (server-log "Close nowait client" proc)
 992           (server-delete-client proc))
 993          ((and (not dontkill) (null buffers))
 994           ;; This client is empty; get rid of it immediately.
 995           (server-log "Close empty client" proc)
 996           (server-delete-client proc)))
 997         (cond
 998          ((or isearch-mode (minibufferp))
 999           nil)
1000          ((and frame (null buffers))
1001           (message "%s" (substitute-command-keys
1002                          "When done with this frame, type \\[delete-frame]")))
1003          ((not (null buffers))
1004           (server-switch-buffer (car buffers) nil (cdr (car files)))
1005           (run-hooks 'server-switch-hook)
1006           (unless nowait
1007             (message "%s" (substitute-command-keys
1008                            "When done with a buffer, type \\[server-edit]")))))
1009         (when (and frame (null tty-name))
1010           (server-unselect-display frame)))
1011     (error (server-return-error proc err))))
1012
1013 (defun server-return-error (proc err)
1014   (ignore-errors
1015     (server-send-string
1016      proc (concat "-error " (server-quote-arg
1017                              (error-message-string err))))
1018     (server-log (error-message-string err) proc)
1019     (delete-process proc)))
1020
1021 (defun server-goto-line-column (line-col)
1022   "Move point to the position indicated in LINE-COL.
1023 LINE-COL should be a pair (LINE . COL)."
1024   (when line-col
1025     (goto-line (car line-col))
1026     (let ((column-number (cdr line-col)))
1027       (when (> column-number 0)
1028         (move-to-column (1- column-number))))))
1029
1030 (defun server-visit-files (files proc &optional nowait)
1031   "Find FILES and return a list of buffers created.
1032 FILES is an alist whose elements are (FILENAME . FILEPOS)
1033 where FILEPOS can be nil or a pair (LINENUMBER . COLUMNNUMBER).
1034 PROC is the client that requested this operation.
1035 NOWAIT non-nil means this client is not waiting for the results,
1036 so don't mark these buffers specially, just visit them normally."
1037   ;; Bind last-nonmenu-event to force use of keyboard, not mouse, for queries.
1038   (let ((last-nonmenu-event t) client-record)
1039     ;; Restore the current buffer afterward, but not using save-excursion,
1040     ;; because we don't want to save point in this buffer
1041     ;; if it happens to be one of those specified by the server.
1042     (save-current-buffer
1043       (dolist (file files)
1044         ;; If there is an existing buffer modified or the file is
1045         ;; modified, revert it.  If there is an existing buffer with
1046         ;; deleted file, offer to write it.
1047         (let* ((minibuffer-auto-raise (or server-raise-frame
1048                                           minibuffer-auto-raise))
1049                (filen (car file))
1050                (obuf (get-file-buffer filen)))
1051           (add-to-history 'file-name-history filen)
1052           (if (null obuf)
1053               (set-buffer (find-file-noselect filen))
1054             (set-buffer obuf)
1055             (cond ((file-exists-p filen)
1056                    (when (not (verify-visited-file-modtime obuf))
1057                      (revert-buffer t nil)))
1058                   (t
1059                    (when (y-or-n-p
1060                           (concat "File no longer exists: " filen
1061                                   ", write buffer to file? "))
1062                      (write-file filen))))
1063             (unless server-buffer-clients
1064               (setq server-existing-buffer t)))
1065           (server-goto-line-column (cdr file))
1066           (run-hooks 'server-visit-hook))
1067         (unless nowait
1068           ;; When the buffer is killed, inform the clients.
1069           (add-hook 'kill-buffer-hook 'server-kill-buffer nil t)
1070           (push proc server-buffer-clients))
1071         (push (current-buffer) client-record)))
1072     (unless nowait
1073       (process-put proc 'buffers
1074                    (nconc (process-get proc 'buffers) client-record)))
1075     client-record))
1076 \f
1077 (defun server-buffer-done (buffer &optional for-killing)
1078   "Mark BUFFER as \"done\" for its client(s).
1079 This buries the buffer, then returns a list of the form (NEXT-BUFFER KILLED).
1080 NEXT-BUFFER is another server buffer, as a suggestion for what to select next,
1081 or nil.  KILLED is t if we killed BUFFER (typically, because it was visiting
1082 a temp file).
1083 FOR-KILLING if non-nil indicates that we are called from `kill-buffer'."
1084   (let ((next-buffer nil)
1085         (killed nil))
1086     (dolist (proc server-clients)
1087       (let ((buffers (process-get proc 'buffers)))
1088         (or next-buffer
1089             (setq next-buffer (nth 1 (memq buffer buffers))))
1090         (when buffers                   ; Ignore bufferless clients.
1091           (setq buffers (delq buffer buffers))
1092           ;; Delete all dead buffers from PROC.
1093           (dolist (b buffers)
1094             (and (bufferp b)
1095                  (not (buffer-live-p b))
1096                  (setq buffers (delq b buffers))))
1097           (process-put proc 'buffers buffers)
1098           ;; If client now has no pending buffers,
1099           ;; tell it that it is done, and forget it entirely.
1100           (unless buffers
1101             (server-log "Close" proc)
1102             (if for-killing
1103                 ;; `server-delete-client' might delete the client's
1104                 ;; frames, which might change the current buffer.  We
1105                 ;; don't want that (bug#640).
1106                 (save-current-buffer
1107                   (server-delete-client proc))
1108               (server-delete-client proc))))))
1109     (when (and (bufferp buffer) (buffer-name buffer))
1110       ;; We may or may not kill this buffer;
1111       ;; if we do, do not call server-buffer-done recursively
1112       ;; from kill-buffer-hook.
1113       (let ((server-kill-buffer-running t))
1114         (with-current-buffer buffer
1115           (setq server-buffer-clients nil)
1116           (run-hooks 'server-done-hook))
1117         ;; Notice whether server-done-hook killed the buffer.
1118         (if (null (buffer-name buffer))
1119             (setq killed t)
1120           ;; Don't bother killing or burying the buffer
1121           ;; when we are called from kill-buffer.
1122           (unless for-killing
1123             (when (and (not killed)
1124                        server-kill-new-buffers
1125                        (with-current-buffer buffer
1126                          (not server-existing-buffer)))
1127               (setq killed t)
1128               (bury-buffer buffer)
1129               (kill-buffer buffer))
1130             (unless killed
1131               (if (server-temp-file-p buffer)
1132                   (progn
1133                     (kill-buffer buffer)
1134                     (setq killed t))
1135                 (bury-buffer buffer)))))))
1136     (list next-buffer killed)))
1137
1138 (defun server-temp-file-p (&optional buffer)
1139   "Return non-nil if BUFFER contains a file considered temporary.
1140 These are files whose names suggest they are repeatedly
1141 reused to pass information to another program.
1142
1143 The variable `server-temp-file-regexp' controls which filenames
1144 are considered temporary."
1145   (and (buffer-file-name buffer)
1146        (string-match server-temp-file-regexp (buffer-file-name buffer))))
1147
1148 (defun server-done ()
1149   "Offer to save current buffer, mark it as \"done\" for clients.
1150 This kills or buries the buffer, then returns a list
1151 of the form (NEXT-BUFFER KILLED).  NEXT-BUFFER is another server buffer,
1152 as a suggestion for what to select next, or nil.
1153 KILLED is t if we killed BUFFER, which happens if it was created
1154 specifically for the clients and did not exist before their request for it."
1155   (when server-buffer-clients
1156     (if (server-temp-file-p)
1157         ;; For a temp file, save, and do make a non-numeric backup
1158         ;; (unless make-backup-files is nil).
1159         (let ((version-control nil)
1160               (buffer-backed-up nil))
1161           (save-buffer))
1162       (when (and (buffer-modified-p)
1163                  buffer-file-name
1164                  (y-or-n-p (concat "Save file " buffer-file-name "? ")))
1165         (save-buffer)))
1166     (server-buffer-done (current-buffer))))
1167
1168 ;; Ask before killing a server buffer.
1169 ;; It was suggested to release its client instead,
1170 ;; but I think that is dangerous--the client would proceed
1171 ;; using whatever is on disk in that file. -- rms.
1172 (defun server-kill-buffer-query-function ()
1173   "Ask before killing a server buffer."
1174   (or (not server-buffer-clients)
1175       (let ((res t))
1176         (dolist (proc server-buffer-clients res)
1177           (when (and (memq proc server-clients)
1178                      (eq (process-status proc) 'open))
1179             (setq res nil))))
1180       (yes-or-no-p (format "Buffer `%s' still has clients; kill it? "
1181                            (buffer-name (current-buffer))))))
1182
1183 (defun server-kill-emacs-query-function ()
1184   "Ask before exiting Emacs if it has live clients."
1185   (or (not server-clients)
1186       (let (live-client)
1187         (dolist (proc server-clients live-client)
1188           (when (memq t (mapcar 'buffer-live-p (process-get
1189                                                 proc 'buffers)))
1190             (setq live-client t))))
1191       (yes-or-no-p "This Emacs session has clients; exit anyway? ")))
1192
1193 (defvar server-kill-buffer-running nil
1194   "Non-nil while `server-kill-buffer' or `server-buffer-done' is running.")
1195
1196 (defun server-kill-buffer ()
1197   "Remove the current buffer from its clients' buffer list.
1198 Designed to be added to `kill-buffer-hook'."
1199   ;; Prevent infinite recursion if user has made server-done-hook
1200   ;; call kill-buffer.
1201   (or server-kill-buffer-running
1202       (and server-buffer-clients
1203            (let ((server-kill-buffer-running t))
1204              (when server-process
1205                (server-buffer-done (current-buffer) t))))))
1206 \f
1207 (defun server-edit (&optional arg)
1208   "Switch to next server editing buffer; say \"Done\" for current buffer.
1209 If a server buffer is current, it is marked \"done\" and optionally saved.
1210 The buffer is also killed if it did not exist before the clients asked for it.
1211 When all of a client's buffers are marked as \"done\", the client is notified.
1212
1213 Temporary files such as MH <draft> files are always saved and backed up,
1214 no questions asked.  (The variable `make-backup-files', if nil, still
1215 inhibits a backup; you can set it locally in a particular buffer to
1216 prevent a backup for it.)  The variable `server-temp-file-regexp' controls
1217 which filenames are considered temporary.
1218
1219 If invoked with a prefix argument, or if there is no server process running,
1220 starts server process and that is all.  Invoked by \\[server-edit]."
1221   (interactive "P")
1222   (cond
1223     ((or arg
1224          (not server-process)
1225          (memq (process-status server-process) '(signal exit)))
1226      (server-mode 1))
1227     (server-clients (apply 'server-switch-buffer (server-done)))
1228     (t (message "No server editing buffers exist"))))
1229
1230 (defun server-switch-buffer (&optional next-buffer killed-one filepos)
1231   "Switch to another buffer, preferably one that has a client.
1232 Arg NEXT-BUFFER is a suggestion; if it is a live buffer, use it.
1233
1234 KILLED-ONE is t in a recursive call if we have already killed one
1235 temp-file server buffer.  This means we should avoid the final
1236 \"switch to some other buffer\" since we've already effectively
1237 done that.
1238
1239 FILEPOS specifies a new buffer position for NEXT-BUFFER, if we
1240 visit NEXT-BUFFER in an existing window.  If non-nil, it should
1241 be a cons cell (LINENUMBER . COLUMNNUMBER)."
1242   (if (null next-buffer)
1243       (progn
1244         (let ((rest server-clients))
1245           (while (and rest (not next-buffer))
1246             (let ((proc (car rest)))
1247               ;; Only look at frameless clients, or those in the selected
1248               ;; frame.
1249               (when (or (not (process-get proc 'frame))
1250                         (eq (process-get proc 'frame) (selected-frame)))
1251                 (setq next-buffer (car (process-get proc 'buffers))))
1252               (setq rest (cdr rest)))))
1253         (and next-buffer (server-switch-buffer next-buffer killed-one))
1254         (unless (or next-buffer killed-one (window-dedicated-p (selected-window)))
1255           ;; (switch-to-buffer (other-buffer))
1256           (message "No server buffers remain to edit")))
1257     (if (not (buffer-live-p next-buffer))
1258         ;; If NEXT-BUFFER is a dead buffer, remove the server records for it
1259         ;; and try the next surviving server buffer.
1260         (apply 'server-switch-buffer (server-buffer-done next-buffer))
1261       ;; OK, we know next-buffer is live, let's display and select it.
1262       (if (functionp server-window)
1263           (funcall server-window next-buffer)
1264         (let ((win (get-buffer-window next-buffer 0)))
1265           (if (and win (not server-window))
1266               ;; The buffer is already displayed: just reuse the
1267               ;; window.  If FILEPOS is non-nil, use it to replace the
1268               ;; window's own value of point.
1269               (progn
1270                 (select-window win)
1271                 (set-buffer next-buffer)
1272                 (when filepos
1273                   (server-goto-line-column filepos)))
1274             ;; Otherwise, let's find an appropriate window.
1275             (cond ((window-live-p server-window)
1276                    (select-window server-window))
1277                   ((framep server-window)
1278                    (unless (frame-live-p server-window)
1279                      (setq server-window (make-frame)))
1280                    (select-window (frame-selected-window server-window))))
1281             (when (window-minibuffer-p (selected-window))
1282               (select-window (next-window nil 'nomini 0)))
1283             ;; Move to a non-dedicated window, if we have one.
1284             (when (window-dedicated-p (selected-window))
1285               (select-window
1286                (get-window-with-predicate
1287                 (lambda (w)
1288                   (and (not (window-dedicated-p w))
1289                        (equal (frame-terminal (window-frame w))
1290                               (frame-terminal (selected-frame)))))
1291                 'nomini 'visible (selected-window))))
1292             (condition-case nil
1293                 (switch-to-buffer next-buffer)
1294               ;; After all the above, we might still have ended up with
1295               ;; a minibuffer/dedicated-window (if there's no other).
1296               (error (pop-to-buffer next-buffer)))))))
1297     (when server-raise-frame
1298       (select-frame-set-input-focus (window-frame (selected-window))))))
1299
1300 ;;;###autoload
1301 (defun server-save-buffers-kill-terminal (proc &optional arg)
1302   ;; Called from save-buffers-kill-terminal in files.el.
1303   "Offer to save each buffer, then kill PROC.
1304
1305 With prefix arg, silently save all file-visiting buffers, then kill.
1306
1307 If emacsclient was started with a list of filenames to edit, then
1308 only these files will be asked to be saved."
1309   ;; save-buffers-kill-terminal occasionally calls us with proc set
1310   ;; to `nowait' (comes from the value of the `client' frame parameter).
1311   (when (processp proc)
1312     (let ((buffers (process-get proc 'buffers)))
1313       ;; If client is bufferless, emulate a normal Emacs session
1314       ;; exit and offer to save all buffers.  Otherwise, offer to
1315       ;; save only the buffers belonging to the client.
1316       (save-some-buffers arg
1317                          (if buffers
1318                              (lambda () (memq (current-buffer) buffers))
1319                            t))
1320       (server-delete-client proc))))
1321
1322 (define-key ctl-x-map "#" 'server-edit)
1323
1324 (defun server-unload-function ()
1325   "Unload the server library."
1326   (server-mode -1)
1327   (substitute-key-definition 'server-edit nil ctl-x-map)
1328   (save-current-buffer
1329     (dolist (buffer (buffer-list))
1330       (set-buffer buffer)
1331       (remove-hook 'kill-buffer-hook 'server-kill-buffer t)))
1332   ;; continue standard unloading
1333   nil)
1334
1335 \f
1336 (provide 'server)
1337
1338 ;; arch-tag: 1f7ecb42-f00a-49f8-906d-61995d84c8d6
1339 ;;; server.el ends here