lisp/vc-rcs.el

   1 ;;; vc-rcs.el --- support for RCS version-control
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   4 ;;   2001, 2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author:     FSF (see vc.el for full credits)
   7 ;; Maintainer: Andre Spiegel <spiegel@gnu.org>
   8
   9 ;; $Id$
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; See vc.el
  31
  32 ;; TODO:
  33 ;; - remove call to vc-expand-dirs by implementing our own (which can just
  34 ;;   list the RCS subdir instead).
  35
  36 ;;; Code:
  37
  38 ;;;
  39 ;;; Customization options
  40 ;;;
  41
  42 (eval-when-compile
  43   (require 'cl)
  44   (require 'vc))
  45
  46 (defcustom vc-rcs-release nil
  47   "*The release number of your RCS installation, as a string.
  48 If nil, VC itself computes this value when it is first needed."
  49   :type '(choice (const :tag "Auto" nil)
  50                  (string :tag "Specified")
  51                  (const :tag "Unknown" unknown))
  52   :group 'vc)
  53
  54 (defcustom vc-rcs-register-switches nil
  55   "*Extra switches for registering a file in RCS.
  56 A string or list of strings.  These are passed to the checkin program
  57 by \\[vc-rcs-register]."
  58   :type '(choice (const :tag "None" nil)
  59                  (string :tag "Argument String")
  60                  (repeat :tag "Argument List"
  61                          :value ("")
  62                          string))
  63   :version "21.1"
  64   :group 'vc)
  65
  66 (defcustom vc-rcs-diff-switches nil
  67   "*A string or list of strings specifying extra switches for rcsdiff under VC."
  68   :type '(choice (const :tag "None" nil)
  69                  (string :tag "Argument String")
  70                  (repeat :tag "Argument List"
  71                          :value ("")
  72                          string))
  73   :version "21.1"
  74   :group 'vc)
  75
  76 (defcustom vc-rcs-header (or (cdr (assoc 'RCS vc-header-alist)) '("\$Id\$"))
  77   "*Header keywords to be inserted by `vc-insert-headers'."
  78   :type '(repeat string)
  79   :version "21.1"
  80   :group 'vc)
  81
  82 (defcustom vc-rcsdiff-knows-brief nil
  83   "*Indicates whether rcsdiff understands the --brief option.
  84 The value is either `yes', `no', or nil.  If it is nil, VC tries
  85 to use --brief and sets this variable to remember whether it worked."
  86   :type '(choice (const :tag "Work out" nil) (const yes) (const no))
  87   :group 'vc)
  88
  89 ;;;###autoload
  90 (defcustom vc-rcs-master-templates
  91   '("%sRCS/%s,v" "%s%s,v" "%sRCS/%s")
  92   "*Where to look for RCS master files.
  93 For a description of possible values, see `vc-check-master-templates'."
  94   :type '(choice (const :tag "Use standard RCS file names"
  95                         '("%sRCS/%s,v" "%s%s,v" "%sRCS/%s"))
  96                  (repeat :tag "User-specified"
  97                          (choice string
  98                                  function)))
  99   :version "21.1"
 100   :group 'vc)
 101
 102 \f
 103 ;;; Properties of the backend
 104
 105 (defun vc-rcs-revision-granularity ()
 106      'file)
 107
 108 ;;;
 109 ;;; State-querying functions
 110 ;;;
 111
 112 ;;; The autoload cookie below places vc-rcs-registered directly into
 113 ;;; loaddefs.el, so that vc-rcs.el does not need to be loaded for
 114 ;;; every file that is visited.  The definition is repeated below
 115 ;;; so that Help and etags can find it.
 116
 117 ;;;###autoload (defun vc-rcs-registered (f) (vc-default-registered 'RCS f))
 118 (defun vc-rcs-registered (f) (vc-default-registered 'RCS f))
 119
 120 (defun vc-rcs-state (file)
 121   "Implementation of `vc-state' for RCS."
 122   (or (boundp 'vc-rcs-headers-result)
 123       (and vc-consult-headers
 124            (vc-rcs-consult-headers file)))
 125   (let ((state
 126          ;; vc-workfile-version might not be known; in that case the
 127          ;; property is nil.  vc-rcs-fetch-master-state knows how to
 128          ;; handle that.
 129          (vc-rcs-fetch-master-state file
 130                                     (vc-file-getprop file
 131                                                      'vc-workfile-version))))
 132     (if (not (eq state 'up-to-date))
 133         state
 134       (if (vc-workfile-unchanged-p file)
 135           'up-to-date
 136         (if (eq (vc-checkout-model file) 'locking)
 137             'unlocked-changes
 138           'edited)))))
 139
 140 (defun vc-rcs-state-heuristic (file)
 141   "State heuristic for RCS."
 142   (let (vc-rcs-headers-result)
 143     (if (and vc-consult-headers
 144              (setq vc-rcs-headers-result
 145                    (vc-rcs-consult-headers file))
 146              (eq vc-rcs-headers-result 'rev-and-lock))
 147         (let ((state (vc-file-getprop file 'vc-state)))
 148           ;; If the headers say that the file is not locked, the
 149           ;; permissions can tell us whether locking is used for
 150           ;; the file or not.
 151           (if (and (eq state 'up-to-date)
 152                    (not (vc-mistrust-permissions file)))
 153               (cond
 154                ((string-match ".rw..-..-." (nth 8 (file-attributes file)))
 155                 (vc-file-setprop file 'vc-checkout-model 'implicit)
 156                 (setq state
 157                       (if (vc-rcs-workfile-is-newer file)
 158                           'edited
 159                         'up-to-date)))
 160                ((string-match ".r-..-..-." (nth 8 (file-attributes file)))
 161                 (vc-file-setprop file 'vc-checkout-model 'locking))))
 162           state)
 163       (if (not (vc-mistrust-permissions file))
 164           (let* ((attributes  (file-attributes file 'string))
 165                  (owner-name  (nth 2 attributes))
 166                  (permissions (nth 8 attributes)))
 167             (cond ((string-match ".r-..-..-." permissions)
 168                    (vc-file-setprop file 'vc-checkout-model 'locking)
 169                    'up-to-date)
 170                   ((string-match ".rw..-..-." permissions)
 171                    (if (eq (vc-checkout-model file) 'locking)
 172                        (if (file-ownership-preserved-p file)
 173                            'edited
 174                          owner-name)
 175                      (if (vc-rcs-workfile-is-newer file)
 176                          'edited
 177                        'up-to-date)))
 178                   (t
 179                    ;; Strange permissions.  Fall through to
 180                    ;; expensive state computation.
 181                    (vc-rcs-state file))))
 182         (vc-rcs-state file)))))
 183
 184 (defun vc-rcs-workfile-version (file)
 185   "RCS-specific version of `vc-workfile-version'."
 186   (or (and vc-consult-headers
 187            (vc-rcs-consult-headers file)
 188            (vc-file-getprop file 'vc-workfile-version))
 189       (progn
 190         (vc-rcs-fetch-master-state file)
 191         (vc-file-getprop file 'vc-workfile-version))))
 192
 193 (defun vc-rcs-latest-on-branch-p (file &optional version)
 194   "Return non-nil if workfile version of FILE is the latest on its branch.
 195 When VERSION is given, perform check for that version."
 196   (unless version (setq version (vc-workfile-version file)))
 197   (with-temp-buffer
 198     (string= version
 199              (if (vc-trunk-p version)
 200                  (progn
 201                    ;; Compare VERSION to the head version number.
 202                    (vc-insert-file (vc-name file) "^[0-9]")
 203                    (vc-parse-buffer "^head[ \t\n]+\\([^;]+\\);" 1))
 204                ;; If we are not on the trunk, we need to examine the
 205                ;; whole current branch.
 206                (vc-insert-file (vc-name file) "^desc")
 207                (vc-rcs-find-most-recent-rev (vc-branch-part version))))))
 208
 209 (defun vc-rcs-checkout-model (file)
 210   "RCS-specific version of `vc-checkout-model'."
 211   (let (result)
 212     (when vc-consult-headers
 213       (vc-file-setprop file 'vc-checkout-model nil)
 214       (vc-rcs-consult-headers file)
 215       (setq result (vc-file-getprop file 'vc-checkout-model)))
 216     (or result
 217         (progn (vc-rcs-fetch-master-state file)
 218                (vc-file-getprop file 'vc-checkout-model)))))
 219
 220 (defun vc-rcs-workfile-unchanged-p (file)
 221   "RCS-specific implementation of `vc-workfile-unchanged-p'."
 222   ;; Try to use rcsdiff --brief.  If rcsdiff does not understand that,
 223   ;; do a double take and remember the fact for the future
 224   (let* ((version (concat "-r" (vc-workfile-version file)))
 225          (status (if (eq vc-rcsdiff-knows-brief 'no)
 226                      (vc-do-command nil 1 "rcsdiff" file version)
 227                    (vc-do-command nil 2 "rcsdiff" file "--brief" version))))
 228     (if (eq status 2)
 229         (if (not vc-rcsdiff-knows-brief)
 230             (setq vc-rcsdiff-knows-brief 'no
 231                   status (vc-do-command nil 1 "rcsdiff" file version))
 232           (error "rcsdiff failed"))
 233       (if (not vc-rcsdiff-knows-brief) (setq vc-rcsdiff-knows-brief 'yes)))
 234     ;; The workfile is unchanged if rcsdiff found no differences.
 235     (zerop status)))
 236
 237 (defun vc-rcs-find-file-not-found-hook ()
 238   (if (yes-or-no-p
 239        (format "File %s was lost; check out from version control? "
 240                (file-name-nondirectory buffer-file-name)))
 241       (save-excursion
 242         (require 'vc)
 243         (let ((default-directory (file-name-directory buffer-file-name)))
 244           (not (vc-error-occurred (vc-checkout buffer-file-name)))))))
 245 \f
 246 ;;;
 247 ;;; State-changing functions
 248 ;;;
 249
 250 (defun vc-rcs-create-repo ()
 251   "Create a new RCS repository."
 252   ;; RCS is totally file-oriented, so all we have to do is make the directory
 253   (make-directory "RCS"))
 254
 255 (defun vc-rcs-register (files &optional rev comment)
 256   "Register FILES into the RCS version-control system.
 257 REV is the optional revision number for the files.  COMMENT can be used
 258 to provide an initial description for each FILES.
 259
 260 `vc-register-switches' and `vc-rcs-register-switches' are passed to
 261 the RCS command (in that order).
 262
 263 Automatically retrieve a read-only version of the file with keywords
 264 expanded if `vc-keep-workfiles' is non-nil, otherwise, delete the workfile."
 265   (let ((subdir (expand-file-name "RCS" (file-name-directory file))))
 266     (dolist (file files)
 267       (and (not (file-exists-p subdir))
 268            (not (directory-files (file-name-directory file)
 269                                  nil ".*,v$" t))
 270            (yes-or-no-p "Create RCS subdirectory? ")
 271            (make-directory subdir))
 272       (apply 'vc-do-command nil 0 "ci" file
 273              ;; if available, use the secure registering option
 274              (and (vc-rcs-release-p "5.6.4") "-i")
 275              (concat (if vc-keep-workfiles "-u" "-r") rev)
 276              (and comment (concat "-t-" comment))
 277              (vc-switches 'RCS 'register))
 278       ;; parse output to find master file name and workfile version
 279       (with-current-buffer "*vc*"
 280         (goto-char (point-min))
 281         (let ((name (if (looking-at (concat "^\\(.*\\)  <--  "
 282                                             (file-name-nondirectory file)))
 283                         (match-string 1))))
 284           (if (not name)
 285               ;; if we couldn't find the master name,
 286               ;; run vc-rcs-registered to get it
 287               ;; (will be stored into the vc-name property)
 288               (vc-rcs-registered file)
 289             (vc-file-setprop file 'vc-name
 290                              (if (file-name-absolute-p name)
 291                                  name
 292                                (expand-file-name
 293                                 name
 294                                 (file-name-directory file))))))
 295         (vc-file-setprop file 'vc-workfile-version
 296                          (if (re-search-forward
 297                               "^initial revision: \\([0-9.]+\\).*\n"
 298                               nil t)
 299                              (match-string 1)))))))
 300
 301 (defun vc-rcs-responsible-p (file)
 302   "Return non-nil if RCS thinks it would be responsible for registering FILE."
 303   ;; TODO: check for all the patterns in vc-rcs-master-templates
 304   (file-directory-p (expand-file-name "RCS" (file-name-directory file))))
 305
 306 (defun vc-rcs-receive-file (file rev)
 307   "Implementation of receive-file for RCS."
 308   (let ((checkout-model (vc-checkout-model file)))
 309     (vc-rcs-register file rev "")
 310     (when (eq checkout-model 'implicit)
 311       (vc-rcs-set-non-strict-locking file))
 312     (vc-rcs-set-default-branch file (concat rev ".1"))))
 313
 314 (defun vc-rcs-unregister (file)
 315   "Unregister FILE from RCS.
 316 If this leaves the RCS subdirectory empty, ask the user
 317 whether to remove it."
 318   (let* ((master (vc-name file))
 319          (dir (file-name-directory master))
 320          (backup-info (find-backup-file-name master)))
 321     (if (not backup-info)
 322         (delete-file master)
 323       (rename-file master (car backup-info) 'ok-if-already-exists)
 324       (dolist (f (cdr backup-info)) (ignore-errors (delete-file f))))
 325     (and (string= (file-name-nondirectory (directory-file-name dir)) "RCS")
 326          ;; check whether RCS dir is empty, i.e. it does not
 327          ;; contain any files except "." and ".."
 328          (not (directory-files dir nil
 329                                "^\\([^.]\\|\\.[^.]\\|\\.\\.[^.]\\).*"))
 330          (yes-or-no-p (format "Directory %s is empty; remove it? " dir))
 331          (delete-directory dir))))
 332
 333 (defun vc-rcs-checkin (files rev comment)
 334   "RCS-specific version of `vc-backend-checkin'."
 335   (let ((switches (vc-switches 'RCS 'checkin)))
 336     ;; Now operate on the files
 337     (dolist (file files)
 338       (let ((old-version (vc-workfile-version file)) new-version
 339             (default-branch (vc-file-getprop file 'vc-rcs-default-branch)))
 340         ;; Force branch creation if an appropriate
 341         ;; default branch has been set.
 342         (and (not rev)
 343              default-branch
 344              (string-match (concat "^" (regexp-quote old-version) "\\.")
 345                            default-branch)
 346              (setq rev default-branch)
 347              (setq switches (cons "-f" switches)))
 348         (if (and (not rev) old-version)
 349             (setq rev (vc-branch-part old-version)))
 350         (apply 'vc-do-command nil 0 "ci" (vc-name file)
 351                ;; if available, use the secure check-in option
 352                (and (vc-rcs-release-p "5.6.4") "-j")
 353                (concat (if vc-keep-workfiles "-u" "-r") rev)
 354                (concat "-m" comment)
 355                switches)
 356         (vc-file-setprop file 'vc-workfile-version nil)
 357
 358         ;; determine the new workfile version
 359         (set-buffer "*vc*")
 360         (goto-char (point-min))
 361         (when (or (re-search-forward
 362                    "new revision: \\([0-9.]+\\);" nil t)
 363                   (re-search-forward
 364                    "reverting to previous revision \\([0-9.]+\\)" nil t))
 365           (setq new-version (match-string 1))
 366           (vc-file-setprop file 'vc-workfile-version new-version))
 367
 368         ;; if we got to a different branch, adjust the default
 369         ;; branch accordingly
 370         (cond
 371          ((and old-version new-version
 372                (not (string= (vc-branch-part old-version)
 373                              (vc-branch-part new-version))))
 374           (vc-rcs-set-default-branch file
 375                                      (if (vc-trunk-p new-version) nil
 376                                        (vc-branch-part new-version)))
 377           ;; If this is an old RCS release, we might have
 378           ;; to remove a remaining lock.
 379           (if (not (vc-rcs-release-p "5.6.2"))
 380               ;; exit status of 1 is also accepted.
 381               ;; It means that the lock was removed before.
 382               (vc-do-command nil 1 "rcs" (vc-name file)
 383                              (concat "-u" old-version)))))))))
 384
 385 (defun vc-rcs-find-version (file rev buffer)
 386   (apply 'vc-do-command
 387          buffer 0 "co" (vc-name file)
 388          "-q" ;; suppress diagnostic output
 389          (concat "-p" rev)
 390          (vc-switches 'RCS 'checkout)))
 391
 392 (defun vc-rcs-checkout (file &optional editable rev)
 393   "Retrieve a copy of a saved version of FILE."
 394   (let ((file-buffer (get-file-buffer file))
 395         switches)
 396     (message "Checking out %s..." file)
 397     (save-excursion
 398       ;; Change buffers to get local value of vc-checkout-switches.
 399       (if file-buffer (set-buffer file-buffer))
 400       (setq switches (vc-switches 'RCS 'checkout))
 401       ;; Save this buffer's default-directory
 402       ;; and use save-excursion to make sure it is restored
 403       ;; in the same buffer it was saved in.
 404       (let ((default-directory default-directory))
 405         (save-excursion
 406           ;; Adjust the default-directory so that the check-out creates
 407           ;; the file in the right place.
 408           (setq default-directory (file-name-directory file))
 409           (let (new-version)
 410             ;; if we should go to the head of the trunk,
 411             ;; clear the default branch first
 412             (and rev (string= rev "")
 413                  (vc-rcs-set-default-branch file nil))
 414             ;; now do the checkout
 415             (apply 'vc-do-command
 416                    nil 0 "co" (vc-name file)
 417                    ;; If locking is not strict, force to overwrite
 418                    ;; the writable workfile.
 419                    (if (eq (vc-checkout-model file) 'implicit) "-f")
 420                    (if editable "-l")
 421                    (if (stringp rev)
 422                        ;; a literal revision was specified
 423                        (concat "-r" rev)
 424                      (let ((workrev (vc-workfile-version file)))
 425                        (if workrev
 426                            (concat "-r"
 427                                    (if (not rev)
 428                                        ;; no revision specified:
 429                                        ;; use current workfile version
 430                                        workrev
 431                                      ;; REV is t ...
 432                                      (if (not (vc-trunk-p workrev))
 433                                          ;; ... go to head of current branch
 434                                          (vc-branch-part workrev)
 435                                        ;; ... go to head of trunk
 436                                        (vc-rcs-set-default-branch file
 437                                                                   nil)
 438                                        ""))))))
 439                    switches)
 440             ;; determine the new workfile version
 441             (with-current-buffer "*vc*"
 442               (setq new-version
 443                     (vc-parse-buffer "^revision \\([0-9.]+\\).*\n" 1)))
 444             (vc-file-setprop file 'vc-workfile-version new-version)
 445             ;; if necessary, adjust the default branch
 446             (and rev (not (string= rev ""))
 447                  (vc-rcs-set-default-branch
 448                   file
 449                   (if (vc-rcs-latest-on-branch-p file new-version)
 450                       (if (vc-trunk-p new-version) nil
 451                         (vc-branch-part new-version))
 452                     new-version)))))
 453         (message "Checking out %s...done" file)))))
 454
 455 (defun vc-rcs-rollback (files)
 456   "Roll back, undoing the most recent checkins of FILES."
 457   (if (not files)
 458       (error "RCS backend doesn't support directory-level rollback."))
 459   (dolist (file files)
 460           (let* ((discard (vc-workfile-version file))
 461                  (previous (if (vc-trunk-p discard) "" (vc-branch-part discard)))
 462                  (config (current-window-configuration))
 463                  (done nil))
 464             (if (null (yes-or-no-p (format "Remove version %s from %s history? "
 465                                            discard file)))
 466                 (error "Aborted"))
 467             (message "Removing revision %s from %s." discard file)
 468             (vc-do-command nil 0 "rcs" (vc-name file) (concat "-o" discard))
 469             ;; Check out the most recent remaining version.  If it
 470             ;; fails, because the whole branch got deleted, do a
 471             ;; double-take and check out the version where the branch
 472             ;; started.
 473             (while (not done)
 474               (condition-case err
 475                   (progn
 476                     (vc-do-command nil 0 "co" (vc-name file) "-f"
 477                                    (concat "-u" previous))
 478                     (setq done t))
 479                 (error (set-buffer "*vc*")
 480                        (goto-char (point-min))
 481                        (if (search-forward "no side branches present for" nil t)
 482                            (progn (setq previous (vc-branch-part previous))
 483                                   (vc-rcs-set-default-branch file previous)
 484                                   ;; vc-do-command popped up a window with
 485                                   ;; the error message.  Get rid of it, by
 486                                   ;; restoring the old window configuration.
 487                                   (set-window-configuration config))
 488                          ;; No, it was some other error: re-signal it.
 489                          (signal (car err) (cdr err)))))))))
 490
 491 (defun vc-rcs-revert (file &optional contents-done)
 492   "Revert FILE to the version it was based on."
 493   (vc-do-command nil 0 "co" (vc-name file) "-f"
 494                  (concat (if (eq (vc-state file) 'edited) "-u" "-r")
 495                          (vc-workfile-version file))))
 496
 497 (defun vc-rcs-merge (file first-version &optional second-version)
 498   "Merge changes into current working copy of FILE.
 499 The changes are between FIRST-VERSION and SECOND-VERSION."
 500   (vc-do-command nil 1 "rcsmerge" (vc-name file)
 501                  "-kk"                  ; ignore keyword conflicts
 502                  (concat "-r" first-version)
 503                  (if second-version (concat "-r" second-version))))
 504
 505 (defun vc-rcs-steal-lock (file &optional rev)
 506   "Steal the lock on the current workfile for FILE and revision REV.
 507 Needs RCS 5.6.2 or later for -M."
 508   (vc-do-command nil 0 "rcs" (vc-name file) "-M" (concat "-u" rev))
 509   ;; Do a real checkout after stealing the lock, so that we see
 510   ;; expanded headers.
 511   (vc-do-command nil 0 "co" (vc-name file) "-f" (concat "-l" rev)))
 512
 513
 514 \f
 515 ;;;
 516 ;;; History functions
 517 ;;;
 518
 519 (defun vc-rcs-print-log (files &optional buffer)
 520   "Get change log associated with FILE."
 521   (vc-do-command buffer 0 "rlog" (mapcar 'vc-name files)))
 522
 523 (defun vc-rcs-diff (files &optional oldvers newvers buffer)
 524   "Get a difference report using RCS between two sets of files."
 525   (apply 'vc-do-command (or buffer "*vc-diff*")
 526          1              ;; Always go synchronous, the repo is local
 527          "rcsdiff" (vc-expand-dirs files)
 528          (append (list "-q"
 529                        (and oldvers (concat "-r" oldvers))
 530                        (and newvers (concat "-r" newvers)))
 531                  (vc-switches 'RCS 'diff))))
 532
 533 (defun vc-rcs-wash-log ()
 534   "Remove all non-comment information from log output."
 535   (let ((separator (concat "^-+\nrevision [0-9.]+\ndate: .*\n"
 536                            "\\(branches: .*;\n\\)?"
 537                            "\\(\\*\\*\\* empty log message \\*\\*\\*\n\\)?")))
 538     (goto-char (point-max)) (forward-line -1)
 539     (while (looking-at "=*\n")
 540       (delete-char (- (match-end 0) (match-beginning 0)))
 541       (forward-line -1))
 542     (goto-char (point-min))
 543     (if (looking-at "[\b\t\n\v\f\r ]+")
 544         (delete-char (- (match-end 0) (match-beginning 0))))
 545     (goto-char (point-min))
 546     (re-search-forward separator nil t)
 547     (delete-region (point-min) (point))
 548     (while (re-search-forward separator nil t)
 549       (delete-region (match-beginning 0) (match-end 0)))))
 550
 551 (defun vc-rcs-annotate-command (file buffer &optional revision)
 552   "Annotate FILE, inserting the results in BUFFER.
 553 Optional arg REVISION is a revision to annotate from."
 554   (vc-setup-buffer buffer)
 555   ;; Aside from the "head revision on the trunk", the instructions for
 556   ;; each revision on the trunk are an ordered list of kill and insert
 557   ;; commands necessary to go from the chronologically-following
 558   ;; revision to this one.  That is, associated with revision N are
 559   ;; edits that applied to revision N+1 would result in revision N.
 560   ;;
 561   ;; On a branch, however, (some) things are inverted: the commands
 562   ;; listed are those necessary to go from the chronologically-preceding
 563   ;; revision to this one.  That is, associated with revision N are
 564   ;; edits that applied to revision N-1 would result in revision N.
 565   ;;
 566   ;; So, to get per-line history info, we apply reverse-chronological
 567   ;; edits, starting with the head revision on the trunk, all the way
 568   ;; back through the initial revision (typically "1.1" or similar),
 569   ;; then apply forward-chronological edits -- keeping track of which
 570   ;; revision is associated with each inserted line -- until we reach
 571   ;; the desired revision for display (which may be either on the trunk
 572   ;; or on a branch).
 573   (let* ((tree (with-temp-buffer
 574                  (insert-file-contents (vc-rcs-registered file))
 575                  (vc-rcs-parse)))
 576          (revisions (cdr (assq 'revisions tree)))
 577          ;; The revision N whose instructions we currently are processing.
 578          (cur (cdr (assq 'head (cdr (assq 'headers tree)))))
 579          ;; Alist from the parse tree for N.
 580          (meta (cdr (assoc cur revisions)))
 581          ;; Point and temporary string, respectively.
 582          p s
 583          ;; "Next-branch list".  Nil means the desired revision to
 584          ;; display lives on the trunk.  Non-nil means it lives on a
 585          ;; branch, in which case the value is a list of revision pairs
 586          ;; (PARENT . CHILD), the first PARENT being on the trunk, that
 587          ;; links each series of revisions in the path from the initial
 588          ;; revision to the desired revision to display.
 589          nbls
 590          ;; "Path-accumulate-predicate plus revision/date/author".
 591          ;; Until set, forward-chronological edits are not accumulated.
 592          ;; Once set, its value (updated every revision) is used for
 593          ;; the text property `:vc-rcs-r/d/a' for inserts during
 594          ;; processing of forward-chronological instructions for N.
 595          ;; See internal func `r/d/a'.
 596          prda
 597          ;; List of forward-chronological instructions, each of the
 598          ;; form: (POS . ACTION), where POS is a buffer position.  If
 599          ;; ACTION is a string, it is inserted, otherwise it is taken as
 600          ;; the number of characters to be deleted.
 601          path
 602          ;; N+1.  When `cur' is "", this is the initial revision.
 603          pre)
 604     (unless revision
 605       (setq revision cur))
 606     (unless (assoc revision revisions)
 607       (error "No such revision: %s" revision))
 608     ;; Find which branches (if any) must be included in the edits.
 609     (let ((par revision)
 610           bpt kids)
 611       (while (setq bpt (vc-branch-part par)
 612                    par (vc-branch-part bpt))
 613         (setq kids (cdr (assq 'branches (cdr (assoc par revisions)))))
 614         ;; A branchpoint may have multiple children.  Find the right one.
 615         (while (not (string= bpt (vc-branch-part (car kids))))
 616           (setq kids (cdr kids)))
 617         (push (cons par (car kids)) nbls)))
 618     ;; Start with the full text.
 619     (set-buffer buffer)
 620     (insert (cdr (assq 'text meta)))
 621     ;; Apply reverse-chronological edits on the trunk, computing and
 622     ;; accumulating forward-chronological edits after some point, for
 623     ;; later.
 624     (flet ((r/d/a () (vector pre
 625                              (cdr (assq 'date meta))
 626                              (cdr (assq 'author meta)))))
 627       (while (when (setq pre cur cur (cdr (assq 'next meta)))
 628                (not (string= "" cur)))
 629         (setq
 630          ;; Start accumulating the forward-chronological edits when N+1
 631          ;; on the trunk is either the desired revision to display, or
 632          ;; the appropriate branchpoint for it.  Do this before
 633          ;; updating `meta' since `r/d/a' uses N+1's `meta' value.
 634          prda (when (or prda (string= (if nbls (caar nbls) revision) pre))
 635                 (r/d/a))
 636          meta (cdr (assoc cur revisions)))
 637         ;; Edits in the parse tree specify a line number (in the buffer
 638         ;; *BEFORE* editing occurs) to start from, but line numbers
 639         ;; change as a result of edits.  To DTRT, we apply edits in
 640         ;; order of descending buffer position so that edits further
 641         ;; down in the buffer occur first w/o corrupting specified
 642         ;; buffer positions of edits occurring towards the beginning of
 643         ;; the buffer.  In this way we avoid using markers.  A pleasant
 644         ;; property of this approach is ability to push instructions
 645         ;; onto `path' directly, w/o need to maintain rev boundaries.
 646         (dolist (insn (cdr (assq :insn meta)))
 647           (goto-line (pop insn))
 648           (setq p (point))
 649           (case (pop insn)
 650             (k (setq s (buffer-substring-no-properties
 651                         p (progn (forward-line (car insn))
 652                                  (point))))
 653                (when prda
 654                  (push `(,p . ,(propertize s :vc-rcs-r/d/a prda)) path))
 655                (delete-region p (point)))
 656             (i (setq s (car insn))
 657                (when prda
 658                  (push `(,p . ,(length s)) path))
 659                (insert s)))))
 660       ;; For the initial revision, setting `:vc-rcs-r/d/a' directly is
 661       ;; equivalent to pushing an insert instruction (of the entire buffer
 662       ;; contents) onto `path' then erasing the buffer, but less wasteful.
 663       (put-text-property (point-min) (point-max) :vc-rcs-r/d/a (r/d/a))
 664       ;; Now apply the forward-chronological edits for the trunk.
 665       (dolist (insn path)
 666         (goto-char (pop insn))
 667         (if (stringp insn)
 668             (insert insn)
 669           (delete-char insn)))
 670       ;; Now apply the forward-chronological edits (directly from the
 671       ;; parse-tree) for the branch(es), if necessary.  We re-use vars
 672       ;; `pre' and `meta' for the sake of internal func `r/d/a'.
 673       (while nbls
 674         (setq pre (cdr (pop nbls)))
 675         (while (progn
 676                  (setq meta (cdr (assoc pre revisions))
 677                        prda nil)
 678                  (dolist (insn (cdr (assq :insn meta)))
 679                    (goto-line (pop insn))
 680                    (case (pop insn)
 681                      (k (delete-region
 682                          (point) (progn (forward-line (car insn))
 683                                         (point))))
 684                      (i (insert (propertize
 685                                  (car insn)
 686                                  :vc-rcs-r/d/a
 687                                  (or prda (setq prda (r/d/a))))))))
 688                  (prog1 (not (string= (if nbls (caar nbls) revision) pre))
 689                    (setq pre (cdr (assq 'next meta)))))))))
 690   ;; Lastly, for each line, insert at bol nicely-formatted history info.
 691   ;; We do two passes to collect summary information used to minimize
 692   ;; the annotation's usage of screen real-estate: (1) Consider rendered
 693   ;; width of revision plus author together as a unit; and (2) Omit
 694   ;; author entirely if all authors are the same as the user.
 695   (let ((ht (make-hash-table :test 'eq))
 696         (me (user-login-name))
 697         (maxw 0)
 698         (all-me t)
 699         rda w a)
 700     (goto-char (point-max))
 701     (while (not (bobp))
 702       (forward-line -1)
 703       (setq rda (get-text-property (point) :vc-rcs-r/d/a))
 704       (unless (gethash rda ht)
 705         (setq a (aref rda 2)
 706               all-me (and all-me (string= a me)))
 707         (puthash rda (setq w (+ (length (aref rda 0))
 708                                 (length a)))
 709                  ht)
 710         (setq maxw (max w maxw))))
 711     (let ((padding (make-string maxw 32)))
 712       (flet ((pad (w) (substring-no-properties padding w))
 713              (render (rda &rest ls)
 714                      (propertize
 715                       (apply 'concat
 716                              (format-time-string "%Y-%m-%d" (aref rda 1))
 717                              "  "
 718                              (aref rda 0)
 719                              ls)
 720                       :vc-annotate-prefix t
 721                       :vc-rcs-r/d/a rda)))
 722         (maphash
 723          (if all-me
 724              (lambda (rda w)
 725                (puthash rda (render rda (pad w) ": ") ht))
 726            (lambda (rda w)
 727              (puthash rda (render rda " " (pad w) " " (aref rda 2) ": ") ht)))
 728          ht)))
 729     (while (not (eobp))
 730       (insert (gethash (get-text-property (point) :vc-rcs-r/d/a) ht))
 731       (forward-line 1))))
 732
 733 (defun vc-rcs-annotate-current-time ()
 734   "Return the current time, based at midnight of the current day, and
 735 encoded as fractional days."
 736   (vc-annotate-convert-time
 737    (apply 'encode-time 0 0 0 (nthcdr 3 (decode-time (current-time))))))
 738
 739 (defun vc-rcs-annotate-time ()
 740   "Return the time of the next annotation (as fraction of days)
 741 systime, or nil if there is none.  Also, reposition point."
 742   (unless (eobp)
 743     (prog1 (vc-annotate-convert-time
 744             (aref (get-text-property (point) :vc-rcs-r/d/a) 1))
 745       (goto-char (next-single-property-change (point) :vc-annotate-prefix)))))
 746
 747 (defun vc-rcs-annotate-extract-revision-at-line ()
 748   (aref (get-text-property (point) :vc-rcs-r/d/a) 0))
 749
 750 \f
 751 ;;;
 752 ;;; Snapshot system
 753 ;;;
 754
 755 (defun vc-rcs-assign-name (file name)
 756   "Assign to FILE's latest version a given NAME."
 757   (vc-do-command nil 0 "rcs" (vc-name file) (concat "-n" name ":")))
 758
 759 \f
 760 ;;;
 761 ;;; Miscellaneous
 762 ;;;
 763
 764 (defun vc-rcs-check-headers ()
 765   "Check if the current file has any headers in it."
 766   (save-excursion
 767     (goto-char (point-min))
 768          (re-search-forward "\\$[A-Za-z\300-\326\330-\366\370-\377]+\
 769 \\(: [\t -#%-\176\240-\377]*\\)?\\$" nil t)))
 770
 771 (defun vc-rcs-clear-headers ()
 772   "Implementation of vc-clear-headers for RCS."
 773   (let ((case-fold-search nil))
 774     (goto-char (point-min))
 775     (while (re-search-forward
 776             (concat "\\$\\(Author\\|Date\\|Header\\|Id\\|Locker\\|Name\\|"
 777                     "RCSfile\\|Revision\\|Source\\|State\\): [^$\n]+\\$")
 778             nil t)
 779       (replace-match "$\\1$"))))
 780
 781 (defun vc-rcs-rename-file (old new)
 782   ;; Just move the master file (using vc-rcs-master-templates).
 783   (vc-rename-master (vc-name old) new vc-rcs-master-templates))
 784
 785 \f
 786 ;;;
 787 ;;; Internal functions
 788 ;;;
 789
 790 (defun vc-rcs-workfile-is-newer (file)
 791   "Return non-nil if FILE is newer than its RCS master.
 792 This likely means that FILE has been changed with respect
 793 to its master version."
 794   (let ((file-time (nth 5 (file-attributes file)))
 795         (master-time (nth 5 (file-attributes (vc-name file)))))
 796     (or (> (nth 0 file-time) (nth 0 master-time))
 797         (and (= (nth 0 file-time) (nth 0 master-time))
 798              (> (nth 1 file-time) (nth 1 master-time))))))
 799
 800 (defun vc-rcs-find-most-recent-rev (branch)
 801   "Find most recent revision on BRANCH."
 802   (goto-char (point-min))
 803   (let ((latest-rev -1) value)
 804     (while (re-search-forward (concat "^\\(" (regexp-quote branch)
 805                                       "\\.\\([0-9]+\\)\\)\ndate[ \t]+[0-9.]+;")
 806                               nil t)
 807       (let ((rev (string-to-number (match-string 2))))
 808         (when (< latest-rev rev)
 809           (setq latest-rev rev)
 810           (setq value (match-string 1)))))
 811     (or value
 812         (vc-branch-part branch))))
 813
 814 (defun vc-rcs-fetch-master-state (file &optional workfile-version)
 815   "Compute the master file's idea of the state of FILE.
 816 If a WORKFILE-VERSION is given, compute the state of that version,
 817 otherwise determine the workfile version based on the master file.
 818 This function sets the properties `vc-workfile-version' and
 819 `vc-checkout-model' to their correct values, based on the master
 820 file."
 821   (with-temp-buffer
 822     (if (or (not (vc-insert-file (vc-name file) "^[0-9]"))
 823             (progn (goto-char (point-min))
 824                    (not (looking-at "^head[ \t\n]+[^;]+;$"))))
 825         (error "File %s is not an RCS master file" (vc-name file)))
 826     (let ((workfile-is-latest nil)
 827           (default-branch (vc-parse-buffer "^branch[ \t\n]+\\([^;]*\\);" 1)))
 828       (vc-file-setprop file 'vc-rcs-default-branch default-branch)
 829       (unless workfile-version
 830         ;; Workfile version not known yet.  Determine that first.  It
 831         ;; is either the head of the trunk, the head of the default
 832         ;; branch, or the "default branch" itself, if that is a full
 833         ;; revision number.
 834         (cond
 835          ;; no default branch
 836          ((or (not default-branch) (string= "" default-branch))
 837           (setq workfile-version
 838                 (vc-parse-buffer "^head[ \t\n]+\\([^;]+\\);" 1))
 839           (setq workfile-is-latest t))
 840          ;; default branch is actually a revision
 841          ((string-match "^[0-9]+\\.[0-9]+\\(\\.[0-9]+\\.[0-9]+\\)*$"
 842                         default-branch)
 843           (setq workfile-version default-branch))
 844          ;; else, search for the head of the default branch
 845          (t (vc-insert-file (vc-name file) "^desc")
 846             (setq workfile-version
 847                   (vc-rcs-find-most-recent-rev default-branch))
 848             (setq workfile-is-latest t)))
 849         (vc-file-setprop file 'vc-workfile-version workfile-version))
 850       ;; Check strict locking
 851       (goto-char (point-min))
 852       (vc-file-setprop file 'vc-checkout-model
 853                        (if (re-search-forward ";[ \t\n]*strict;" nil t)
 854                            'locking 'implicit))
 855       ;; Compute state of workfile version
 856       (goto-char (point-min))
 857       (let ((locking-user
 858              (vc-parse-buffer (concat "^locks[ \t\n]+[^;]*[ \t\n]+\\([^:]+\\):"
 859                                       (regexp-quote workfile-version)
 860                                       "[^0-9.]")
 861                               1)))
 862         (cond
 863          ;; not locked
 864          ((not locking-user)
 865           (if (or workfile-is-latest
 866                   (vc-rcs-latest-on-branch-p file workfile-version))
 867               ;; workfile version is latest on branch
 868               'up-to-date
 869             ;; workfile version is not latest on branch
 870             'needs-patch))
 871          ;; locked by the calling user
 872          ((and (stringp locking-user)
 873                (string= locking-user (vc-user-login-name file)))
 874           (if (or (eq (vc-checkout-model file) 'locking)
 875                   workfile-is-latest
 876                   (vc-rcs-latest-on-branch-p file workfile-version))
 877               'edited
 878             ;; Locking is not used for the file, but the owner does
 879             ;; have a lock, and there is a higher version on the current
 880             ;; branch.  Not sure if this can occur, and if it is right
 881             ;; to use `needs-merge' in this case.
 882             'needs-merge))
 883          ;; locked by somebody else
 884          ((stringp locking-user)
 885           locking-user)
 886          (t
 887           (error "Error getting state of RCS file")))))))
 888
 889 (defun vc-rcs-consult-headers (file)
 890   "Search for RCS headers in FILE, and set properties accordingly.
 891
 892 Returns: nil            if no headers were found
 893          'rev           if a workfile revision was found
 894          'rev-and-lock  if revision and lock info was found"
 895   (cond
 896    ((not (get-file-buffer file)) nil)
 897    ((let (status version locking-user)
 898      (save-excursion
 899       (set-buffer (get-file-buffer file))
 900       (goto-char (point-min))
 901       (cond
 902        ;; search for $Id or $Header
 903        ;; -------------------------
 904        ;; The `\ 's below avoid an RCS 5.7 bug when checking in this file.
 905        ((or (and (search-forward "$Id\ : " nil t)
 906                  (looking-at "[^ ]+ \\([0-9.]+\\) "))
 907             (and (progn (goto-char (point-min))
 908                         (search-forward "$Header\ : " nil t))
 909                  (looking-at "[^ ]+ \\([0-9.]+\\) ")))
 910         (goto-char (match-end 0))
 911         ;; if found, store the revision number ...
 912         (setq version (match-string-no-properties 1))
 913         ;; ... and check for the locking state
 914         (cond
 915          ((looking-at
 916            (concat "[0-9]+[/-][01][0-9][/-][0-3][0-9] "             ; date
 917             "[0-2][0-9]:[0-5][0-9]+:[0-6][0-9]+\\([+-][0-9:]+\\)? " ; time
 918                    "[^ ]+ [^ ]+ "))                       ; author & state
 919           (goto-char (match-end 0)) ; [0-6] in regexp handles leap seconds
 920           (cond
 921            ;; unlocked revision
 922            ((looking-at "\\$")
 923             (setq locking-user 'none)
 924             (setq status 'rev-and-lock))
 925            ;; revision is locked by some user
 926            ((looking-at "\\([^ ]+\\) \\$")
 927             (setq locking-user (match-string-no-properties 1))
 928             (setq status 'rev-and-lock))
 929            ;; everything else: false
 930            (nil)))
 931          ;; unexpected information in
 932          ;; keyword string --> quit
 933          (nil)))
 934        ;; search for $Revision
 935        ;; --------------------
 936        ((re-search-forward (concat "\\$"
 937                                    "Revision: \\([0-9.]+\\) \\$")
 938                            nil t)
 939         ;; if found, store the revision number ...
 940         (setq version (match-string-no-properties 1))
 941         ;; and see if there's any lock information
 942         (goto-char (point-min))
 943         (if (re-search-forward (concat "\\$" "Locker:") nil t)
 944             (cond ((looking-at " \\([^ ]+\\) \\$")
 945                    (setq locking-user (match-string-no-properties 1))
 946                    (setq status 'rev-and-lock))
 947                   ((looking-at " *\\$")
 948                    (setq locking-user 'none)
 949                    (setq status 'rev-and-lock))
 950                   (t
 951                    (setq locking-user 'none)
 952                    (setq status 'rev-and-lock)))
 953           (setq status 'rev)))
 954        ;; else: nothing found
 955        ;; -------------------
 956        (t nil)))
 957      (if status (vc-file-setprop file 'vc-workfile-version version))
 958      (and (eq status 'rev-and-lock)
 959           (vc-file-setprop file 'vc-state
 960                            (cond
 961                             ((eq locking-user 'none) 'up-to-date)
 962                             ((string= locking-user (vc-user-login-name file))
 963                              'edited)
 964                             (t locking-user)))
 965           ;; If the file has headers, we don't want to query the
 966           ;; master file, because that would eliminate all the
 967           ;; performance gain the headers brought us.  We therefore
 968           ;; use a heuristic now to find out whether locking is used
 969           ;; for this file.  If we trust the file permissions, and the
 970           ;; file is not locked, then if the file is read-only we
 971           ;; assume that locking is used for the file, otherwise
 972           ;; locking is not used.
 973           (not (vc-mistrust-permissions file))
 974           (vc-up-to-date-p file)
 975           (if (string-match ".r-..-..-." (nth 8 (file-attributes file)))
 976               (vc-file-setprop file 'vc-checkout-model 'locking)
 977             (vc-file-setprop file 'vc-checkout-model 'implicit)))
 978      status))))
 979
 980 (defun vc-release-greater-or-equal (r1 r2)
 981   "Compare release numbers, represented as strings.
 982 Release components are assumed cardinal numbers, not decimal fractions
 983 \(5.10 is a higher release than 5.9\).  Omitted fields are considered
 984 lower \(5.6.7 is earlier than 5.6.7.1\).  Comparison runs till the end
 985 of the string is found, or a non-numeric component shows up \(5.6.7 is
 986 earlier than \"5.6.7 beta\", which is probably not what you want in
 987 some cases\).  This code is suitable for existing RCS release numbers.
 988 CVS releases are handled reasonably, too \(1.3 < 1.4* < 1.5\)."
 989   (let (v1 v2 i1 i2)
 990     (catch 'done
 991       (or (and (string-match "^\\.?\\([0-9]+\\)" r1)
 992                (setq i1 (match-end 0))
 993                (setq v1 (string-to-number (match-string 1 r1)))
 994                (or (and (string-match "^\\.?\\([0-9]+\\)" r2)
 995                         (setq i2 (match-end 0))
 996                         (setq v2 (string-to-number (match-string 1 r2)))
 997                         (if (> v1 v2) (throw 'done t)
 998                           (if (< v1 v2) (throw 'done nil)
 999                             (throw 'done
1000                                    (vc-release-greater-or-equal
1001                                     (substring r1 i1)
1002                                     (substring r2 i2)))))))
1003                    (throw 'done t)))
1004           (or (and (string-match "^\\.?\\([0-9]+\\)" r2)
1005                    (throw 'done nil))
1006               (throw 'done t)))))
1007
1008 (defun vc-rcs-release-p (release)
1009   "Return t if we have RELEASE or better."
1010   (let ((installation (vc-rcs-system-release)))
1011     (if (and installation
1012              (not (eq installation 'unknown)))
1013         (vc-release-greater-or-equal installation release))))
1014
1015 (defun vc-rcs-system-release ()
1016   "Return the RCS release installed on this system, as a string.
1017 Return symbol UNKNOWN if the release cannot be deducted.  The user can
1018 override this using variable `vc-rcs-release'.
1019
1020 If the user has not set variable `vc-rcs-release' and it is nil,
1021 variable `vc-rcs-release' is set to the returned value."
1022   (or vc-rcs-release
1023       (setq vc-rcs-release
1024             (or (and (zerop (vc-do-command nil nil "rcs" nil "-V"))
1025                      (with-current-buffer (get-buffer "*vc*")
1026                        (vc-parse-buffer "^RCS version \\([0-9.]+ *.*\\)" 1)))
1027                 'unknown))))
1028
1029 (defun vc-rcs-set-non-strict-locking (file)
1030   (vc-do-command nil 0 "rcs" file "-U")
1031   (vc-file-setprop file 'vc-checkout-model 'implicit)
1032   (set-file-modes file (logior (file-modes file) 128)))
1033
1034 (defun vc-rcs-set-default-branch (file branch)
1035   (vc-do-command nil 0 "rcs" (vc-name file) (concat "-b" branch))
1036   (vc-file-setprop file 'vc-rcs-default-branch branch))
1037
1038 (defun vc-rcs-parse (&optional buffer)
1039   "Parse current buffer, presumed to be in RCS-style masterfile format.
1040 Optional arg BUFFER specifies another buffer to parse.  Return an alist
1041 of two elements, w/ keys `headers' and `revisions' and values in turn
1042 sub-alists.  For `headers', the values unless otherwise specified are
1043 strings and the keys are:
1044
1045   desc     -- description
1046   head     -- latest revision
1047   branch   -- the branch the \"head revision\" lies on;
1048               absent if the head revision lies on the trunk
1049   access   -- ???
1050   symbols  -- sub-alist of (SYMBOL . REVISION) elements
1051   locks    -- if file is checked out, something like \"ttn:1.7\"
1052   strict   -- t if \"strict locking\" is in effect, otherwise nil
1053   comment  -- may be absent; typically something like \"# \" or \"; \"
1054   expand   -- may be absent; ???
1055
1056 For `revisions', the car is REVISION (string), the cdr a sub-alist,
1057 with string values (unless otherwise specified) and keys:
1058
1059   date     -- a time value (like that returned by `encode-time'); as a
1060               special case, a year value less than 100 is augmented by 1900
1061   author   -- username
1062   state    -- typically \"Exp\" or \"Rel\"
1063   branches -- list of revisions that begin branches from this revision
1064   next     -- on the trunk: the chronologically-preceding revision, or \"\";
1065               on a branch: the chronologically-following revision, or \"\"
1066   log      -- change log entry
1067   text     -- for the head revision on the trunk, the body of the file;
1068               other revisions have `:insn' instead
1069   :insn    -- for non-head revisions, a list of parsed instructions
1070               in one of two forms, in both cases START meaning \"first
1071               go to line START\":
1072                - `(START k COUNT)' -- kill COUNT lines
1073                - `(START i TEXT)'  -- insert TEXT (a string)
1074               The list is in descending order by START.
1075
1076 The `:insn' key is a keyword to distinguish it as a vc-rcs.el extension."
1077   (setq buffer (get-buffer (or buffer (current-buffer))))
1078   (set-buffer buffer)
1079   ;; An RCS masterfile can be viewed as containing four regular (for the
1080   ;; most part) sections: (a) the "headers", (b) the "rev headers", (c)
1081   ;; the "description" and (d) the "rev bodies", in that order.  In the
1082   ;; returned alist (see docstring), elements from (b) and (d) are
1083   ;; combined pairwise to form the "revisions", while those from (a) and
1084   ;; (c) are simply combined to form the "headers".
1085   ;;
1086   ;; Loosely speaking, each section contains a series of alternating
1087   ;; "tags" and "printed representations".  In the (b) and (d), many
1088   ;; such series can appear, and a revision number on a line by itself
1089   ;; precedes the series of tags and printed representations associated
1090   ;; with it.
1091   ;;
1092   ;; In (a) and (b), the printed representations (with the exception of
1093   ;; the `comment' tag in the headers) terminate with a semicolon, which
1094   ;; is NOT part of the "value" finally associated with the tag.  All
1095   ;; other printed representations are in "@@-format"; there is an "@",
1096   ;; the middle part (to be translated into the value), another "@" and
1097   ;; a newline.  Each "@@" in the middle part indicates the position of
1098   ;; a single "@" (and consequently the requirement of an additional
1099   ;; initial step when translating to the value).
1100   ;;
1101   ;; Parser state includes vars that collect parts of the return value...
1102   (let ((desc nil) (headers nil) (revs nil)
1103         ;; ... as well as vars that support a single-pass, tag-assisted,
1104         ;; minimal-data-copying scan.  Basically -- skirting around the
1105         ;; grouping by revision required in (b) and (d) -- we repeatedly
1106         ;; and context-sensitively read a tag (that MUST be present),
1107         ;; determine the bounds of the printed representation, translate
1108         ;; it into a value, and push the tag plus value onto one of the
1109         ;; collection vars.  Finally, we return the parse tree
1110         ;; incorporating the values of the collection vars (see "rv").
1111         ;;
1112         ;; A symbol or string to keep track of context (for error messages).
1113         context
1114         ;; A symbol, the current tag.
1115         tok
1116         ;; Region (begin and end buffer positions) of the printed
1117         ;; representation for the current tag.
1118         b e
1119         ;; A list of buffer positions where "@@" can be found within the
1120         ;; printed representation region.  For each location, we push two
1121         ;; elements onto the list, 1+ and 2+ the location, respectively,
1122         ;; with the 2+ appearing at the head.  In this way, the expression
1123         ;;   `(,e ,@@-holes ,b)
1124         ;; describes regions that can be concatenated (in reverse order)
1125         ;; to "de-@@-format" the printed representation as the first step
1126         ;; to translating it into some value.  See internal func `gather'.
1127         @-holes)
1128     (flet ((sw () (skip-chars-forward " \t\n")) ; i.e., `[:space:]'
1129            (at (tag) (save-excursion (eq tag (read buffer))))
1130            (to-eol () (buffer-substring-no-properties
1131                        (point) (progn (forward-line 1)
1132                                       (1- (point)))))
1133            (to-semi () (setq b (point)
1134                              e (progn (search-forward ";")
1135                                       (1- (point)))))
1136            (to-one@ () (setq @-holes nil
1137                              b (progn (search-forward "@") (point))
1138                              e (progn (while (and (search-forward "@")
1139                                                   (= ?@ (char-after))
1140                                                   (progn
1141                                                     (push (point) @-holes)
1142                                                     (forward-char 1)
1143                                                     (push (point) @-holes))))
1144                                       (1- (point)))))
1145            (tok+val (set-b+e name &optional proc)
1146                     (unless (eq name (setq tok (read buffer)))
1147                       (error "Missing `%s' while parsing %s" name context))
1148                     (sw)
1149                     (funcall set-b+e)
1150                     (cons tok (if proc
1151                                   (funcall proc)
1152                                 (buffer-substring-no-properties b e))))
1153            (k-semi (name &optional proc) (tok+val 'to-semi name proc))
1154            (gather () (let ((pairs `(,e ,@@-holes ,b))
1155                             acc)
1156                         (while pairs
1157                           (push (buffer-substring-no-properties
1158                                  (cadr pairs) (car pairs))
1159                                 acc)
1160                           (setq pairs (cddr pairs)))
1161                         (apply 'concat acc)))
1162            (k-one@ (name &optional later) (tok+val 'to-one@ name
1163                                                    (if later
1164                                                        (lambda () t)
1165                                                      'gather))))
1166       (save-excursion
1167         (goto-char (point-min))
1168         ;; headers
1169         (setq context 'headers)
1170         (flet ((hpush (name &optional proc)
1171                       (push (k-semi name proc) headers)))
1172           (hpush 'head)
1173           (when (at 'branch)
1174             (hpush 'branch))
1175           (hpush 'access)
1176           (hpush 'symbols
1177                  (lambda ()
1178                    (mapcar (lambda (together)
1179                              (let ((two (split-string together ":")))
1180                                (setcar two (intern (car two)))
1181                                (setcdr two (cadr two))
1182                                two))
1183                            (split-string
1184                             (buffer-substring-no-properties b e)))))
1185           (hpush 'locks))
1186         (push `(strict . ,(when (at 'strict)
1187                             (search-forward ";")
1188                             t))
1189               headers)
1190         (when (at 'comment)
1191           (push (k-one@ 'comment) headers)
1192           (search-forward ";"))
1193         (when (at 'expand)
1194           (push (k-one@ 'expand) headers)
1195           (search-forward ";"))
1196         (setq headers (nreverse headers))
1197         ;; rev headers
1198         (sw) (setq context 'rev-headers)
1199         (while (looking-at "[0-9]")
1200           (push `(,(to-eol)
1201                   ,(k-semi 'date
1202                            (lambda ()
1203                              (let ((ls (mapcar 'string-to-number
1204                                                (split-string
1205                                                 (buffer-substring-no-properties
1206                                                  b e)
1207                                                 "\\."))))
1208                                ;; Hack the year -- verified to be the
1209                                ;; same algorithm used in RCS 5.7.
1210                                (when (< (car ls) 100)
1211                                  (setcar ls (+ 1900 (car ls))))
1212                                (apply 'encode-time (nreverse ls)))))
1213                   ,@(mapcar 'k-semi '(author state))
1214                   ,(k-semi 'branches
1215                            (lambda ()
1216                              (split-string
1217                               (buffer-substring-no-properties b e))))
1218                   ,(k-semi 'next))
1219                 revs)
1220           (sw))
1221         (setq revs (nreverse revs))
1222         ;; desc
1223         (sw) (setq context 'desc
1224                    desc (k-one@ 'desc))
1225         ;; rev bodies
1226         (let (acc
1227               ;; Element of `revs' that initially holds only header info.
1228               ;; "Pairwise combination" occurs when we add body info.
1229               rev
1230               ;; Components of the editing commands (aside from the actual
1231               ;; text) that comprise the `text' printed representations
1232               ;; (not including the "head" revision).
1233               cmd start act
1234               ;; Ascending (reversed) `@-holes' which the internal func
1235               ;; `incg' pops to effect incremental gathering.
1236               asc
1237               ;; Function to extract text (for the `a' command), either
1238               ;; `incg' or `buffer-substring-no-properties'.  (This is
1239               ;; for speed; strictly speaking, it is sufficient to use
1240               ;; only the former since it behaves identically to the
1241               ;; latter in the absense of "@@".)
1242               sub)
1243           (flet ((incg (beg end) (let ((b beg) (e end) @-holes)
1244                                    (while (and asc (< (car asc) e))
1245                                      (push (pop asc) @-holes))
1246                                    ;; Self-deprecate when work is done.
1247                                    ;; Folding many dimensions into one.
1248                                    ;; Thanks B.Mandelbrot, for complex sum.
1249                                    ;; O beauteous math! --the Unvexed Bum
1250                                    (unless asc
1251                                      (setq sub 'buffer-substring-no-properties))
1252                                    (gather))))
1253             (while (and (sw)
1254                         (not (eobp))
1255                         (setq context (to-eol)
1256                               rev (or (assoc context revs)
1257                                       (error "Rev `%s' has body but no head"
1258                                              context))))
1259               (push (k-one@ 'log) (cdr rev))
1260               ;; For rev body `text' tags, delay translation slightly...
1261               (push (k-one@ 'text t) (cdr rev))
1262               ;; ... until we decide which tag and value is appropriate to
1263               ;; collect.  For the "head" revision, compute the value of the
1264               ;; `text' printed representation by simple `gather'.  For all
1265               ;; other revisions, replace the `text' tag+value with `:insn'
1266               ;; plus value, always scanning in-place.
1267               (if (string= context (cdr (assq 'head headers)))
1268                   (setcdr (cadr rev) (gather))
1269                 (if @-holes
1270                     (setq asc (nreverse @-holes)
1271                           sub 'incg)
1272                   (setq sub 'buffer-substring-no-properties))
1273                 (goto-char b)
1274                 (setq acc nil)
1275                 (while (< (point) e)
1276                   (forward-char 1)
1277                   (setq cmd (char-before)
1278                         start (read (current-buffer))
1279                         act (read (current-buffer)))
1280                   (forward-char 1)
1281                   (push (case cmd
1282                           (?d
1283                            ;; `d' means "delete lines".
1284                            ;; For Emacs spirit, we use `k' for "kill".
1285                            `(,start k ,act))
1286                           (?a
1287                            ;; `a' means "append after this line" but
1288                            ;; internally we normalize it so that START
1289                            ;; specifies the actual line for insert, thus
1290                            ;; requiring less hair in the realization algs.
1291                            ;; For Emacs spirit, we use `i' for "insert".
1292                            `(,(1+ start) i
1293                              ,(funcall sub (point) (progn (forward-line act)
1294                                                           (point)))))
1295                           (t (error "Bad command `%c' in `text' for rev `%s'"
1296                                     cmd context)))
1297                         acc))
1298                 (goto-char (1+ e))
1299                 (setcar (cdr rev) (cons :insn acc)))))))
1300       ;; rv
1301       `((headers ,desc ,@headers)
1302         (revisions ,@revs)))))
1303
1304 (provide 'vc-rcs)
1305
1306 ;; arch-tag: 759b4916-5b0d-431d-b647-b185b8c652cf
1307 ;;; vc-rcs.el ends here