lisp/gnus/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'gnus)
  34 (require 'gnus-ems)
  35 (require 'message)
  36 (require 'gnus-art)
  37 (require 'gnus-util)
  38
  39 (defcustom gnus-post-method 'current
  40   "*Preferred method for posting USENET news.
  41
  42 If this variable is `current' (which is the default), Gnus will use
  43 the \"current\" select method when posting.  If it is `native', Gnus
  44 will use the native select method when posting.
  45
  46 This method will not be used in mail groups and the like, only in
  47 \"real\" newsgroups.
  48
  49 If not `native' nor `current', the value must be a valid method as discussed
  50 in the documentation of `gnus-select-method'.  It can also be a list of
  51 methods.  If that is the case, the user will be queried for what select
  52 method to use when posting."
  53   :group 'gnus-group-foreign
  54   :link '(custom-manual "(gnus)Posting Server")
  55   :type `(choice (const native)
  56                  (const current)
  57                  (sexp :tag "Methods" ,gnus-select-method)))
  58
  59 (defcustom gnus-outgoing-message-group nil
  60   "*All outgoing messages will be put in this group.
  61 If you want to store all your outgoing mail and articles in the group
  62 \"nnml:archive\", you set this variable to that value.  This variable
  63 can also be a list of group names.
  64
  65 If you want to have greater control over what group to put each
  66 message in, you can set this variable to a function that checks the
  67 current newsgroup name and then returns a suitable group name (or list
  68 of names)."
  69   :group 'gnus-message
  70   :type '(choice (const nil)
  71                  (function)
  72                  (string :tag "Group")
  73                  (repeat :tag "List of groups" (string :tag "Group"))))
  74
  75 (defcustom gnus-mailing-list-groups nil
  76   "*If non-nil a regexp matching groups that are really mailing lists.
  77 This is useful when you're reading a mailing list that has been
  78 gatewayed to a newsgroup, and you want to followup to an article in
  79 the group."
  80   :group 'gnus-message
  81   :type '(choice (regexp)
  82                  (const nil)))
  83
  84 (defcustom gnus-add-to-list nil
  85   "*If non-nil, add a `to-list' parameter automatically."
  86   :group 'gnus-message
  87   :type 'boolean)
  88
  89 (defcustom gnus-crosspost-complaint
  90   "Hi,
  91
  92 You posted the article below with the following Newsgroups header:
  93
  94 Newsgroups: %s
  95
  96 The %s group, at least, was an inappropriate recipient
  97 of this message.  Please trim your Newsgroups header to exclude this
  98 group before posting in the future.
  99
 100 Thank you.
 101
 102 "
 103   "Format string to be inserted when complaining about crossposts.
 104 The first %s will be replaced by the Newsgroups header;
 105 the second with the current group name."
 106   :group 'gnus-message
 107   :type 'string)
 108
 109 (defcustom gnus-message-setup-hook nil
 110   "Hook run after setting up a message buffer."
 111   :group 'gnus-message
 112   :type 'hook)
 113
 114 (defcustom gnus-bug-create-help-buffer t
 115   "*Should we create the *Gnus Help Bug* buffer?"
 116   :group 'gnus-message
 117   :type 'boolean)
 118
 119 (defcustom gnus-posting-styles nil
 120   "*Alist of styles to use when posting.
 121 See Info node `(gnus)Posting Styles'."
 122   :group 'gnus-message
 123   :link '(custom-manual "(gnus)Posting Styles")
 124   :type '(repeat (cons (choice (regexp)
 125                                (variable)
 126                                (list (const header)
 127                                      (string :tag "Header")
 128                                      (regexp :tag "Regexp"))
 129                                (function)
 130                                (sexp))
 131                        (repeat (list
 132                                 (choice (const signature)
 133                                         (const signature-file)
 134                                         (const organization)
 135                                         (const address)
 136                                         (const x-face-file)
 137                                         (const name)
 138                                         (const body)
 139                                         (symbol)
 140                                         (string :tag "Header"))
 141                                 (choice (string)
 142                                         (function)
 143                                         (variable)
 144                                         (sexp)))))))
 145
 146 (defcustom gnus-gcc-mark-as-read nil
 147   "If non-nil, automatically mark Gcc articles as read."
 148   :version "22.1"
 149   :group 'gnus-message
 150   :type 'boolean)
 151
 152 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 153                         'gnus-gcc-mark-as-read)
 154
 155 (defcustom gnus-gcc-externalize-attachments nil
 156   "Should local-file attachments be included as external parts in Gcc copies?
 157 If it is `all', attach files as external parts;
 158 if a regexp and matches the Gcc group name, attach files as external parts;
 159 if nil, attach files as normal parts."
 160   :version "22.1"
 161   :group 'gnus-message
 162   :type '(choice (const nil :tag "None")
 163                  (const all :tag "Any")
 164                  (string :tag "Regexp")))
 165
 166 (gnus-define-group-parameter
 167  posting-charset-alist
 168  :type list
 169  :function-document
 170  "Return the permitted unencoded charsets for posting of GROUP."
 171  :variable gnus-group-posting-charset-alist
 172  :variable-default
 173   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 174     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 175     (message-this-is-mail nil nil)
 176     (message-this-is-news nil t))
 177  :variable-document
 178   "Alist of regexps and permitted unencoded charsets for posting.
 179 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 180 TEST is either a regular expression matching the newsgroup header or a
 181 variable to query,
 182 HEADER is the charset which may be left unencoded in the header (nil
 183 means encode all charsets),
 184 BODY-LIST is a list of charsets which may be encoded using 8bit
 185 content-transfer encoding in the body, or one of the special values
 186 nil (always encode using quoted-printable) or t (always use 8bit).
 187
 188 Note that any value other than nil for HEADER infringes some RFCs, so
 189 use this option with care."
 190  :variable-group gnus-charset
 191  :variable-type
 192  '(repeat (list :tag "Permitted unencoded charsets"
 193                 (choice :tag "Where"
 194                         (regexp :tag "Group")
 195                         (const :tag "Mail message" :value message-this-is-mail)
 196                         (const :tag "News article" :value message-this-is-news))
 197                 (choice :tag "Header"
 198                         (const :tag "None" nil)
 199                         (symbol :tag "Charset"))
 200                 (choice :tag "Body"
 201                         (const :tag "Any" :value t)
 202                         (const :tag "None" :value nil)
 203                         (repeat :tag "Charsets"
 204                                 (symbol :tag "Charset")))))
 205  :parameter-type '(choice :tag "Permitted unencoded charsets"
 206                           :value nil
 207                           (repeat (symbol)))
 208  :parameter-document       "\
 209 List of charsets that are permitted to be unencoded.")
 210
 211 (defcustom gnus-debug-files
 212   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 213     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 214     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 215     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 216     "mm-util.el" "mm-decode.el" "nnmail.el" "message.el")
 217   "Files whose variables will be reported in `gnus-bug'."
 218   :version "22.1"
 219   :group 'gnus-message
 220   :type '(repeat (string :tag "File")))
 221
 222 (defcustom gnus-debug-exclude-variables
 223   '(mm-mime-mule-charset-alist
 224     nnmail-split-fancy message-minibuffer-local-map)
 225   "Variables that should not be reported in `gnus-bug'."
 226   :version "22.1"
 227   :group 'gnus-message
 228   :type '(repeat (symbol :tag "Variable")))
 229
 230 (defcustom gnus-discouraged-post-methods
 231   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 232   "A list of back ends that are not used in \"real\" newsgroups.
 233 This variable is used only when `gnus-post-method' is `current'."
 234   :version "22.1"
 235   :group 'gnus-group-foreign
 236   :type '(repeat (symbol :tag "Back end")))
 237
 238 (defcustom gnus-message-replysign
 239   nil
 240   "Automatically sign replies to signed messages.
 241 See also the `mml-default-sign-method' variable."
 242   :group 'gnus-message
 243   :type 'boolean)
 244
 245 (defcustom gnus-message-replyencrypt
 246   nil
 247   "Automatically encrypt replies to encrypted messages.
 248 See also the `mml-default-encrypt-method' variable."
 249   :group 'gnus-message
 250   :type 'boolean)
 251
 252 (defcustom gnus-message-replysignencrypted
 253   t
 254   "Setting this causes automatically encrypted messages to also be signed."
 255   :group 'gnus-message
 256   :type 'boolean)
 257
 258 (defcustom gnus-confirm-mail-reply-to-news nil
 259   "If non-nil, Gnus requests confirmation when replying to news.
 260 This is done because new users often reply by mistake when reading
 261 news.
 262 This can also be a function receiving the group name as the only
 263 parameter which should return non-nil iff a confirmation is needed, or
 264 a regexp, in which case a confirmation is asked for iff the group name
 265 matches the regexp."
 266   :version "22.1"
 267   :group 'gnus-message
 268   :type '(choice (const :tag "No" nil)
 269                  (const :tag "Yes" t)
 270                  (regexp :tag "Iff group matches regexp")
 271                  (function :tag "Iff function evaluates to non-nil")))
 272
 273 (defcustom gnus-confirm-treat-mail-like-news
 274   nil
 275   "If non-nil, Gnus will treat mail like news with regard to confirmation
 276 when replying by mail.  See the `gnus-confirm-mail-reply-to-news' variable
 277 for fine-tuning this.
 278 If nil, Gnus will never ask for confirmation if replying to mail."
 279   :version "22.1"
 280   :group 'gnus-message
 281   :type 'boolean)
 282
 283 (defcustom gnus-summary-resend-default-address t
 284   "If non-nil, Gnus tries to suggest a default address to resend to.
 285 If nil, the address field will always be empty after invoking
 286 `gnus-summary-resend-message'."
 287   :version "22.1"
 288   :group 'gnus-message
 289   :type 'boolean)
 290
 291 ;;; Internal variables.
 292
 293 (defvar gnus-inhibit-posting-styles nil
 294   "Inhibit the use of posting styles.")
 295
 296 (defvar gnus-article-yanked-articles nil)
 297 (defvar gnus-message-buffer "*Mail Gnus*")
 298 (defvar gnus-article-copy nil)
 299 (defvar gnus-check-before-posting nil)
 300 (defvar gnus-last-posting-server nil)
 301 (defvar gnus-message-group-art nil)
 302
 303 (defvar gnus-msg-force-broken-reply-to nil)
 304
 305 (defconst gnus-bug-message
 306   "Sending a bug report to the Gnus Towers.
 307 ========================================
 308
 309 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 310 be sent to the Gnus Bug Exterminators.
 311
 312 The thing near the bottom of the buffer is how the environment
 313 settings will be included in the mail.  Please do not delete that.
 314 They will tell the Bug People what your environment is, so that it
 315 will be easier to locate the bugs.
 316
 317 If you have found a bug that makes Emacs go \"beep\", set
 318 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 319 and include the backtrace in your bug report.
 320
 321 Please describe the bug in annoying, painstaking detail.
 322
 323 Thank you for your help in stamping out bugs.
 324 ")
 325
 326 (eval-and-compile
 327   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 328   (autoload 'news-setup "rnewspost")
 329   (autoload 'news-reply-mode "rnewspost")
 330   (autoload 'rmail-dont-reply-to "mail-utils")
 331   (autoload 'rmail-output "rmailout"))
 332
 333 \f
 334 ;;;
 335 ;;; Gnus Posting Functions
 336 ;;;
 337
 338 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 339   "p" gnus-summary-post-news
 340   "i" gnus-summary-news-other-window
 341   "f" gnus-summary-followup
 342   "F" gnus-summary-followup-with-original
 343   "c" gnus-summary-cancel-article
 344   "s" gnus-summary-supersede-article
 345   "r" gnus-summary-reply
 346   "y" gnus-summary-yank-message
 347   "R" gnus-summary-reply-with-original
 348   "w" gnus-summary-wide-reply
 349   "W" gnus-summary-wide-reply-with-original
 350   "v" gnus-summary-very-wide-reply
 351   "V" gnus-summary-very-wide-reply-with-original
 352   "n" gnus-summary-followup-to-mail
 353   "N" gnus-summary-followup-to-mail-with-original
 354   "m" gnus-summary-mail-other-window
 355   "u" gnus-uu-post-news
 356   "\M-c" gnus-summary-mail-crosspost-complaint
 357   "Br" gnus-summary-reply-broken-reply-to
 358   "BR" gnus-summary-reply-broken-reply-to-with-original
 359   "om" gnus-summary-mail-forward
 360   "op" gnus-summary-post-forward
 361   "Om" gnus-uu-digest-mail-forward
 362   "Op" gnus-uu-digest-post-forward)
 363
 364 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 365   "b" gnus-summary-resend-bounced-mail
 366   ;; "c" gnus-summary-send-draft
 367   "r" gnus-summary-resend-message
 368   "e" gnus-summary-resend-message-edit)
 369
 370 ;;; Internal functions.
 371
 372 (defun gnus-inews-make-draft ()
 373   `(lambda ()
 374      (gnus-inews-make-draft-meta-information
 375       ,gnus-newsgroup-name ',gnus-article-reply)))
 376
 377 (defvar gnus-article-reply nil)
 378 (defmacro gnus-setup-message (config &rest forms)
 379   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 380         (buffer (make-symbol "gnus-setup-message-buffer"))
 381         (article (make-symbol "gnus-setup-message-article"))
 382         (yanked (make-symbol "gnus-setup-yanked-articles"))
 383         (group (make-symbol "gnus-setup-message-group")))
 384     `(let ((,winconf (current-window-configuration))
 385            (,buffer (buffer-name (current-buffer)))
 386            (,article gnus-article-reply)
 387            (,yanked gnus-article-yanked-articles)
 388            (,group gnus-newsgroup-name)
 389            (message-header-setup-hook
 390             (copy-sequence message-header-setup-hook))
 391            (mbl mml-buffer-list)
 392            (message-mode-hook (copy-sequence message-mode-hook)))
 393        (setq mml-buffer-list nil)
 394        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 395        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 396        ;; #### FIXME: for a reason that I did not manage to identify yet,
 397        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 398        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 399        ;; After evaluation of @forms below, it gets the value we actually want
 400        ;; to override, and the posting styles are used. For that reason, I've
 401        ;; added an optional argument to `gnus-configure-posting-styles' to
 402        ;; make sure that the correct value for the group name is used. -- drv
 403        (add-hook 'message-mode-hook
 404                  (if (memq ,config '(reply-yank reply))
 405                      (lambda ()
 406                        (gnus-configure-posting-styles ,group))
 407                    (lambda ()
 408                      ;; There may be an old " *gnus article copy*" buffer.
 409                      (let (gnus-article-copy)
 410                        (gnus-configure-posting-styles ,group)))))
 411        (gnus-pull ',(intern gnus-draft-meta-information-header)
 412                   message-required-headers)
 413        (when (and ,group
 414                   (not (string= ,group "")))
 415          (push (cons
 416                 (intern gnus-draft-meta-information-header)
 417                 (gnus-inews-make-draft))
 418                message-required-headers))
 419        (unwind-protect
 420            (progn
 421              ,@forms)
 422          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 423                                       ,yanked)
 424          (setq gnus-message-buffer (current-buffer))
 425          (set (make-local-variable 'gnus-message-group-art)
 426               (cons ,group ,article))
 427          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 428          (gnus-run-hooks 'gnus-message-setup-hook)
 429          (if (eq major-mode 'message-mode)
 430              (let ((mbl1 mml-buffer-list))
 431                (setq mml-buffer-list mbl)  ;; Global value
 432                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 433                (gnus-make-local-hook 'kill-buffer-hook)
 434                (gnus-make-local-hook 'change-major-mode-hook)
 435                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 436                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 437            (mml-destroy-buffers)
 438            (setq mml-buffer-list mbl)))
 439        (message-hide-headers)
 440        (gnus-add-buffer)
 441        (gnus-configure-windows ,config t)
 442        (run-hooks 'post-command-hook)
 443        (set-buffer-modified-p nil))))
 444
 445 (defun gnus-inews-make-draft-meta-information (group article)
 446   (concat "(\"" group "\" "
 447           (if article (number-to-string
 448                        (if (listp article)
 449                            (car article)
 450                          article)) "\"\"")
 451           ")"))
 452
 453 ;;;###autoload
 454 (defun gnus-msg-mail (&optional to subject other-headers continue
 455                                 switch-action yank-action send-actions)
 456   "Start editing a mail message to be sent.
 457 Like `message-mail', but with Gnus paraphernalia, particularly the
 458 Gcc: header for archiving purposes."
 459   (interactive)
 460   (let ((buf (current-buffer))
 461         mail-buf)
 462     (gnus-setup-message 'message
 463       (message-mail to subject other-headers continue
 464                     nil yank-action send-actions))
 465     (when switch-action
 466       (setq mail-buf (current-buffer))
 467       (switch-to-buffer buf)
 468       (apply switch-action mail-buf nil)))
 469   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 470   t)
 471
 472 ;;;###autoload
 473 (defun gnus-button-mailto (address)
 474   "Mail to ADDRESS."
 475   (set-buffer (gnus-copy-article-buffer))
 476   (gnus-setup-message 'message
 477     (message-reply address)))
 478
 479 ;;;###autoload
 480 (defun gnus-button-reply (&optional to-address wide)
 481   "Like `message-reply'."
 482   (interactive)
 483   (gnus-setup-message 'message
 484     (message-reply to-address wide)))
 485
 486 ;;;###autoload
 487 (define-mail-user-agent 'gnus-user-agent
 488   'gnus-msg-mail 'message-send-and-exit
 489   'message-kill-buffer 'message-send-hook)
 490
 491 (defun gnus-setup-posting-charset (group)
 492   (let ((alist gnus-group-posting-charset-alist)
 493         (group (or group ""))
 494         elem)
 495     (when group
 496       (catch 'found
 497         (while (setq elem (pop alist))
 498           (when (or (and (stringp (car elem))
 499                          (string-match (car elem) group))
 500                     (and (functionp (car elem))
 501                          (funcall (car elem) group))
 502                     (and (symbolp (car elem))
 503                          (symbol-value (car elem))))
 504             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 505
 506 (defun gnus-inews-add-send-actions (winconf buffer article
 507                                             &optional config yanked)
 508   (gnus-make-local-hook 'message-sent-hook)
 509   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 510                                  'gnus-inews-do-gcc) nil t)
 511   (when gnus-agent
 512     (gnus-make-local-hook 'message-header-hook)
 513     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 514   (setq message-post-method
 515         `(lambda (arg)
 516            (gnus-post-method arg ,gnus-newsgroup-name)))
 517   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 518   (message-add-action
 519    `(when (gnus-buffer-exists-p ,buffer)
 520       (set-window-configuration ,winconf))
 521    'exit 'postpone 'kill)
 522   (let ((to-be-marked (cond
 523                        (yanked
 524                         (mapcar
 525                          (lambda (x) (if (listp x) (car x) x)) yanked))
 526                        (article (if (listp article) article (list article)))
 527                        (t nil))))
 528     (message-add-action
 529      `(when (gnus-buffer-exists-p ,buffer)
 530         (save-excursion
 531           (set-buffer ,buffer)
 532           ,(when to-be-marked
 533              (if (eq config 'forward)
 534                  `(gnus-summary-mark-article-as-forwarded ',to-be-marked)
 535                `(gnus-summary-mark-article-as-replied ',to-be-marked)))))
 536      'send)))
 537
 538 (put 'gnus-setup-message 'lisp-indent-function 1)
 539 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 540
 541 ;;; Post news commands of Gnus group mode and summary mode
 542
 543 (defun gnus-group-mail (&optional arg)
 544   "Start composing a mail.
 545 If ARG, use the group under the point to find a posting style.
 546 If ARG is 1, prompt for a group name to find the posting style."
 547   (interactive "P")
 548   ;; We can't `let' gnus-newsgroup-name here, since that leads
 549   ;; to local variables leaking.
 550   (let ((group gnus-newsgroup-name)
 551         ;; make sure last viewed article doesn't affect posting styles:
 552         (gnus-article-copy)
 553         (buffer (current-buffer)))
 554     (unwind-protect
 555         (progn
 556           (setq gnus-newsgroup-name
 557                 (if arg
 558                     (if (= 1 (prefix-numeric-value arg))
 559                         (completing-read "Use posting style of group: "
 560                                          gnus-active-hashtb nil
 561                                          (gnus-read-active-file-p))
 562                       (gnus-group-group-name))
 563                   ""))
 564           ;; #### see comment in gnus-setup-message -- drv
 565           (gnus-setup-message 'message (message-mail)))
 566       (save-excursion
 567         (set-buffer buffer)
 568         (setq gnus-newsgroup-name group)))))
 569
 570 (defun gnus-group-news (&optional arg)
 571   "Start composing a news.
 572 If ARG, post to group under point.
 573 If ARG is 1, prompt for group name to post to.
 574
 575 This function prepares a news even when using mail groups.  This is useful
 576 for posting messages to mail groups without actually sending them over the
 577 network.  The corresponding back end must have a 'request-post method."
 578   (interactive "P")
 579   ;; We can't `let' gnus-newsgroup-name here, since that leads
 580   ;; to local variables leaking.
 581   (let ((group gnus-newsgroup-name)
 582         ;; make sure last viewed article doesn't affect posting styles:
 583         (gnus-article-copy)
 584         (buffer (current-buffer)))
 585     (unwind-protect
 586         (progn
 587           (setq gnus-newsgroup-name
 588                 (if arg
 589                     (if (= 1 (prefix-numeric-value arg))
 590                         (completing-read "Use group: "
 591                                          gnus-active-hashtb nil
 592                                          (gnus-read-active-file-p))
 593                       (gnus-group-group-name))
 594                   ""))
 595           ;; #### see comment in gnus-setup-message -- drv
 596           (gnus-setup-message 'message
 597             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 598       (save-excursion
 599         (set-buffer buffer)
 600         (setq gnus-newsgroup-name group)))))
 601
 602 (defun gnus-group-post-news (&optional arg)
 603   "Start composing a message (a news by default).
 604 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 605 Depending on the selected group, the message might be either a mail or
 606 a news."
 607   (interactive "P")
 608   ;; Bind this variable here to make message mode hooks work ok.
 609   (let ((gnus-newsgroup-name
 610          (if arg
 611              (if (= 1 (prefix-numeric-value arg))
 612                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 613                                   (gnus-read-active-file-p))
 614                (gnus-group-group-name))
 615            ""))
 616         ;; make sure last viewed article doesn't affect posting styles:
 617         (gnus-article-copy))
 618     (gnus-post-news 'post gnus-newsgroup-name nil nil nil nil
 619                     (string= gnus-newsgroup-name ""))))
 620
 621 (defun gnus-summary-mail-other-window (&optional arg)
 622   "Start composing a mail in another window.
 623 Use the posting of the current group by default.
 624 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 625 posting style."
 626   (interactive "P")
 627   ;; We can't `let' gnus-newsgroup-name here, since that leads
 628   ;; to local variables leaking.
 629   (let ((group gnus-newsgroup-name)
 630         ;; make sure last viewed article doesn't affect posting styles:
 631         (gnus-article-copy)
 632         (buffer (current-buffer)))
 633     (unwind-protect
 634         (progn
 635           (setq gnus-newsgroup-name
 636                 (if arg
 637                     (if (= 1 (prefix-numeric-value arg))
 638                         (completing-read "Use group: "
 639                                          gnus-active-hashtb nil
 640                                          (gnus-read-active-file-p))
 641                       "")
 642                   gnus-newsgroup-name))
 643           ;; #### see comment in gnus-setup-message -- drv
 644           (gnus-setup-message 'message (message-mail)))
 645       (save-excursion
 646         (set-buffer buffer)
 647         (setq gnus-newsgroup-name group)))))
 648
 649 (defun gnus-summary-news-other-window (&optional arg)
 650   "Start composing a news in another window.
 651 Post to the current group by default.
 652 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 653
 654 This function prepares a news even when using mail groups.  This is useful
 655 for posting messages to mail groups without actually sending them over the
 656 network.  The corresponding back end must have a 'request-post method."
 657   (interactive "P")
 658   ;; We can't `let' gnus-newsgroup-name here, since that leads
 659   ;; to local variables leaking.
 660   (let ((group gnus-newsgroup-name)
 661         ;; make sure last viewed article doesn't affect posting styles:
 662         (gnus-article-copy)
 663         (buffer (current-buffer)))
 664     (unwind-protect
 665         (progn
 666           (setq gnus-newsgroup-name
 667                 (if arg
 668                     (if (= 1 (prefix-numeric-value arg))
 669                         (completing-read "Use group: "
 670                                          gnus-active-hashtb nil
 671                                          (gnus-read-active-file-p))
 672                       "")
 673                   gnus-newsgroup-name))
 674           ;; #### see comment in gnus-setup-message -- drv
 675           (gnus-setup-message 'message
 676             (progn
 677               (message-news (gnus-group-real-name gnus-newsgroup-name))
 678               (set (make-local-variable 'gnus-discouraged-post-methods)
 679                    (delq
 680                     (car (gnus-find-method-for-group gnus-newsgroup-name))
 681                     (copy-sequence gnus-discouraged-post-methods))))))
 682       (save-excursion
 683         (set-buffer buffer)
 684         (setq gnus-newsgroup-name group)))))
 685
 686 (defun gnus-summary-post-news (&optional arg)
 687   "Start composing a message.  Post to the current group by default.
 688 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 689 Depending on the selected group, the message might be either a mail or
 690 a news."
 691   (interactive "P")
 692   ;; Bind this variable here to make message mode hooks work ok.
 693   (let ((gnus-newsgroup-name
 694          (if arg
 695              (if (= 1 (prefix-numeric-value arg))
 696                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 697                                   (gnus-read-active-file-p))
 698                "")
 699            gnus-newsgroup-name))
 700         ;; make sure last viewed article doesn't affect posting styles:
 701         (gnus-article-copy))
 702     (gnus-post-news 'post gnus-newsgroup-name)))
 703
 704
 705 (defun gnus-summary-followup (yank &optional force-news)
 706   "Compose a followup to an article.
 707 If prefix argument YANK is non-nil, the original article is yanked
 708 automatically.
 709 YANK is a list of elements, where the car of each element is the
 710 article number, and the cdr is the string to be yanked."
 711   (interactive
 712    (list (and current-prefix-arg
 713               (gnus-summary-work-articles 1))))
 714   (when yank
 715     (gnus-summary-goto-subject
 716      (if (listp (car yank))
 717          (caar yank)
 718        (car yank))))
 719   (save-window-excursion
 720     (gnus-summary-select-article))
 721   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 722         (gnus-newsgroup-name gnus-newsgroup-name))
 723     ;; Send a followup.
 724     (gnus-post-news nil gnus-newsgroup-name
 725                     headers gnus-article-buffer
 726                     yank nil force-news)
 727     (gnus-summary-handle-replysign)))
 728
 729 (defun gnus-summary-followup-with-original (n &optional force-news)
 730   "Compose a followup to an article and include the original article.
 731 The text in the region will be yanked.  If the region isn't
 732 active, the entire article will be yanked."
 733   (interactive "P")
 734   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 735
 736 (defun gnus-summary-followup-to-mail (&optional arg)
 737   "Followup to the current mail message via news."
 738   (interactive
 739    (list (and current-prefix-arg
 740               (gnus-summary-work-articles 1))))
 741   (gnus-summary-followup arg t))
 742
 743 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 744   "Followup to the current mail message via news."
 745   (interactive "P")
 746   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 747
 748 (defun gnus-inews-yank-articles (articles)
 749   (let (beg article yank-string)
 750     (message-goto-body)
 751     (while (setq article (pop articles))
 752       (when (listp article)
 753         (setq yank-string (nth 1 article)
 754               article (nth 0 article)))
 755       (save-window-excursion
 756         (set-buffer gnus-summary-buffer)
 757         (gnus-summary-select-article nil nil nil article)
 758         (gnus-summary-remove-process-mark article))
 759       (gnus-copy-article-buffer nil yank-string)
 760       (let ((message-reply-buffer gnus-article-copy)
 761             (message-reply-headers
 762              ;; The headers are decoded.
 763              (with-current-buffer gnus-article-copy
 764                (save-restriction
 765                  (nnheader-narrow-to-headers)
 766                  (nnheader-parse-naked-head)))))
 767         (message-yank-original)
 768         (setq beg (or beg (mark t))))
 769       (when articles
 770         (insert "\n")))
 771     (push-mark)
 772     (goto-char beg)))
 773
 774 (defun gnus-summary-cancel-article (&optional n symp)
 775   "Cancel an article you posted.
 776 Uses the process-prefix convention.  If given the symbolic
 777 prefix `a', cancel using the standard posting method; if not
 778 post using the current select method."
 779   (interactive (gnus-interactive "P\ny"))
 780   (let ((articles (gnus-summary-work-articles n))
 781         (message-post-method
 782          `(lambda (arg)
 783             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name)))
 784         article)
 785     (while (setq article (pop articles))
 786       (when (gnus-summary-select-article t nil nil article)
 787         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 788                 (message-cancel-news))
 789           (gnus-summary-mark-as-read article gnus-canceled-mark)
 790           (gnus-cache-remove-article 1))
 791         (gnus-article-hide-headers-if-wanted))
 792       (gnus-summary-remove-process-mark article))))
 793
 794 (defun gnus-summary-supersede-article ()
 795   "Compose an article that will supersede a previous article.
 796 This is done simply by taking the old article and adding a Supersedes
 797 header line with the old Message-ID."
 798   (interactive)
 799   (let ((article (gnus-summary-article-number)))
 800     (gnus-setup-message 'reply-yank
 801       (gnus-summary-select-article t)
 802       (set-buffer gnus-original-article-buffer)
 803       (message-supersede)
 804       (push
 805        `((lambda ()
 806            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 807              (save-excursion
 808                (set-buffer ,gnus-summary-buffer)
 809                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 810                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 811        message-send-actions))))
 812
 813 \f
 814
 815 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 816   ;; make a copy of the article buffer with all text properties removed
 817   ;; this copy is in the buffer gnus-article-copy.
 818   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 819   ;; this buffer should be passed to all mail/news reply/post routines.
 820   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 821   (save-excursion
 822     (set-buffer gnus-article-copy)
 823     (mm-enable-multibyte))
 824   (let ((article-buffer (or article-buffer gnus-article-buffer))
 825         end beg)
 826     (if (not (and (get-buffer article-buffer)
 827                   (gnus-buffer-exists-p article-buffer)))
 828         (error "Can't find any article buffer")
 829       (save-excursion
 830         (set-buffer article-buffer)
 831         (let ((gnus-newsgroup-charset (or gnus-article-charset
 832                                           gnus-newsgroup-charset))
 833               (gnus-newsgroup-ignored-charsets
 834                (or gnus-article-ignored-charsets
 835                    gnus-newsgroup-ignored-charsets)))
 836           (save-restriction
 837             ;; Copy over the (displayed) article buffer, delete
 838             ;; hidden text and remove text properties.
 839             (widen)
 840             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 841             (set-buffer gnus-article-copy)
 842             (when yank-string
 843               (message-goto-body)
 844               (delete-region (point) (point-max))
 845               (insert yank-string))
 846             (gnus-article-delete-text-of-type 'annotation)
 847             (gnus-remove-text-with-property 'gnus-prev)
 848             (gnus-remove-text-with-property 'gnus-next)
 849             (gnus-remove-text-with-property 'gnus-decoration)
 850             (insert
 851              (prog1
 852                  (buffer-substring-no-properties (point-min) (point-max))
 853                (erase-buffer)))
 854             ;; Find the original headers.
 855             (set-buffer gnus-original-article-buffer)
 856             (goto-char (point-min))
 857             (while (looking-at message-unix-mail-delimiter)
 858               (forward-line 1))
 859             (let ((mail-header-separator ""))
 860               (setq beg (point)
 861                     end (or (message-goto-body)
 862                             ;; There may be just a header.
 863                             (point-max))))
 864             ;; Delete the headers from the displayed articles.
 865             (set-buffer gnus-article-copy)
 866             (let ((mail-header-separator ""))
 867               (delete-region (goto-char (point-min))
 868                              (or (message-goto-body) (point-max))))
 869             ;; Insert the original article headers.
 870             (insert-buffer-substring gnus-original-article-buffer beg end)
 871             ;; Decode charsets.
 872             (let ((gnus-article-decode-hook
 873                    (delq 'article-decode-charset
 874                          (copy-sequence gnus-article-decode-hook)))
 875                   (rfc2047-quote-decoded-words-containing-tspecials t))
 876               (run-hooks 'gnus-article-decode-hook)))))
 877       gnus-article-copy)))
 878
 879 (defun gnus-post-news (post &optional group header article-buffer yank subject
 880                             force-news)
 881   (when article-buffer
 882     (gnus-copy-article-buffer))
 883   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 884         (gnus-article-yanked-articles yank)
 885         (add-to-list gnus-add-to-list))
 886     (gnus-setup-message (cond (yank 'reply-yank)
 887                               (article-buffer 'reply)
 888                               (t 'message))
 889       (let* ((group (or group gnus-newsgroup-name))
 890              (charset (gnus-group-name-charset nil group))
 891              (pgroup group)
 892              to-address to-group mailing-list to-list
 893              newsgroup-p)
 894         (when group
 895           (setq to-address (gnus-parameter-to-address group)
 896                 to-group (gnus-group-find-parameter group 'to-group)
 897                 to-list (gnus-parameter-to-list group)
 898                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 899                 mailing-list (when gnus-mailing-list-groups
 900                                (string-match gnus-mailing-list-groups group))
 901                 group (gnus-group-name-decode (gnus-group-real-name group)
 902                                               charset)))
 903         (if (or (and to-group
 904                      (gnus-news-group-p to-group))
 905                 newsgroup-p
 906                 force-news
 907                 (and (gnus-news-group-p
 908                       (or pgroup gnus-newsgroup-name)
 909                       (or header gnus-current-article))
 910                      (not mailing-list)
 911                      (not to-list)
 912                      (not to-address)))
 913             ;; This is news.
 914             (if post
 915                 (message-news
 916                  (or to-group
 917                      (and (not (gnus-virtual-group-p pgroup)) group)))
 918               (set-buffer gnus-article-copy)
 919               (gnus-msg-treat-broken-reply-to)
 920               (message-followup (if (or newsgroup-p force-news)
 921                                     (if (save-restriction
 922                                           (article-narrow-to-head)
 923                                           (message-fetch-field "newsgroups"))
 924                                         nil
 925                                       "")
 926                                   to-group)))
 927           ;; The is mail.
 928           (if post
 929               (progn
 930                 (message-mail (or to-address to-list))
 931                 ;; Arrange for mail groups that have no `to-address' to
 932                 ;; get that when the user sends off the mail.
 933                 (when (and (not to-list)
 934                            (not to-address)
 935                            add-to-list)
 936                   (push (list 'gnus-inews-add-to-address pgroup)
 937                         message-send-actions)))
 938             (set-buffer gnus-article-copy)
 939             (gnus-msg-treat-broken-reply-to)
 940             (message-wide-reply to-address)))
 941         (when yank
 942           (gnus-inews-yank-articles yank))))))
 943
 944 (defun gnus-msg-treat-broken-reply-to (&optional force)
 945   "Remove the Reply-to header if broken-reply-to."
 946   (when (or force
 947             (gnus-group-find-parameter
 948              gnus-newsgroup-name 'broken-reply-to))
 949     (save-restriction
 950       (message-narrow-to-head)
 951       (message-remove-header "reply-to"))))
 952
 953 (defun gnus-post-method (arg group &optional silent)
 954   "Return the posting method based on GROUP and ARG.
 955 If SILENT, don't prompt the user."
 956   (let ((gnus-post-method (or (gnus-parameter-post-method group)
 957                               gnus-post-method))
 958         (group-method (gnus-find-method-for-group group)))
 959     (cond
 960      ;; If the group-method is nil (which shouldn't happen) we use
 961      ;; the default method.
 962      ((null group-method)
 963       (or (and (listp gnus-post-method) ;If not current/native/nil
 964                (not (listp (car gnus-post-method))) ; and not a list of methods
 965                gnus-post-method)        ;then use it.
 966           gnus-select-method
 967           message-post-method))
 968      ;; We want the inverse of the default
 969      ((and arg (not (eq arg 0)))
 970       (if (eq gnus-post-method 'current)
 971           gnus-select-method
 972         group-method))
 973      ;; We query the user for a post method.
 974      ((or arg
 975           (and (listp gnus-post-method)
 976                (listp (car gnus-post-method))))
 977       (let* ((methods
 978               ;; Collect all methods we know about.
 979               (append
 980                (when (listp gnus-post-method)
 981                  (if (listp (car gnus-post-method))
 982                      gnus-post-method
 983                    (list gnus-post-method)))
 984                gnus-secondary-select-methods
 985                (mapcar 'cdr gnus-server-alist)
 986                (mapcar 'car gnus-opened-servers)
 987                (list gnus-select-method)
 988                (list group-method)))
 989              method-alist post-methods method)
 990         ;; Weed out all mail methods.
 991         (while methods
 992           (setq method (gnus-server-get-method "" (pop methods)))
 993           (when (and (or (gnus-method-option-p method 'post)
 994                          (gnus-method-option-p method 'post-mail))
 995                      (not (member method post-methods)))
 996             (push method post-methods)))
 997         ;; Create a name-method alist.
 998         (setq method-alist
 999               (mapcar
1000                (lambda (m)
1001                  (if (equal (cadr m) "")
1002                      (list (symbol-name (car m)) m)
1003                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
1004                post-methods))
1005         ;; Query the user.
1006         (cadr
1007          (assoc
1008           (setq gnus-last-posting-server
1009                 (if (and silent
1010                          gnus-last-posting-server)
1011                     ;; Just use the last value.
1012                     gnus-last-posting-server
1013                   (completing-read
1014                    "Posting method: " method-alist nil t
1015                    (cons (or gnus-last-posting-server "") 0))))
1016           method-alist))))
1017      ;; Override normal method.
1018      ((and (eq gnus-post-method 'current)
1019            (not (memq (car group-method) gnus-discouraged-post-methods))
1020            (gnus-get-function group-method 'request-post t))
1021       (assert (not arg))
1022       group-method)
1023      ;; Use gnus-post-method.
1024      ((listp gnus-post-method)          ;A method...
1025       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
1026       gnus-post-method)
1027      ;; Use the normal select method (nil or native).
1028      (t gnus-select-method))))
1029
1030 \f
1031
1032 (defun gnus-extended-version ()
1033   "Stringified Gnus version and Emacs version.
1034 See the variable `gnus-user-agent'."
1035   (interactive)
1036   (if (stringp gnus-user-agent)
1037       gnus-user-agent
1038     ;; `gnus-user-agent' is a list:
1039     (let* ((float-output-format nil)
1040            (gnus-v
1041             (when (memq 'gnus gnus-user-agent)
1042               (concat "Gnus/"
1043                       (prin1-to-string (gnus-continuum-version gnus-version) t)
1044                       " (" gnus-version ")")))
1045            (emacs-v (gnus-emacs-version)))
1046       (concat gnus-v (when (and gnus-v emacs-v) " ")
1047               emacs-v))))
1048
1049 \f
1050 ;;;
1051 ;;; Gnus Mail Functions
1052 ;;;
1053
1054 ;;; Mail reply commands of Gnus summary mode
1055
1056 (defun gnus-summary-reply (&optional yank wide very-wide)
1057   "Start composing a mail reply to the current message.
1058 If prefix argument YANK is non-nil, the original article is yanked
1059 automatically.
1060 If WIDE, make a wide reply.
1061 If VERY-WIDE, make a very wide reply."
1062   (interactive
1063    (list (and current-prefix-arg
1064               (gnus-summary-work-articles 1))))
1065   ;; Allow user to require confirmation before replying by mail to the
1066   ;; author of a news article (or mail message).
1067   (when (or
1068             (not (or (gnus-news-group-p gnus-newsgroup-name)
1069                      gnus-confirm-treat-mail-like-news))
1070             (not (cond ((stringp gnus-confirm-mail-reply-to-news)
1071                         (string-match gnus-confirm-mail-reply-to-news
1072                                       gnus-newsgroup-name))
1073                        ((functionp gnus-confirm-mail-reply-to-news)
1074                         (funcall gnus-confirm-mail-reply-to-news gnus-newsgroup-name))
1075                        (t gnus-confirm-mail-reply-to-news)))
1076             (y-or-n-p "Really reply by mail to article author? "))
1077     (let* ((article
1078             (if (listp (car yank))
1079                 (caar yank)
1080               (car yank)))
1081            (gnus-article-reply (or article (gnus-summary-article-number)))
1082            (gnus-article-yanked-articles yank)
1083            (headers ""))
1084       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1085       (when yank
1086         (gnus-summary-goto-subject article))
1087       (gnus-setup-message (if yank 'reply-yank 'reply)
1088         (if (not very-wide)
1089             (gnus-summary-select-article)
1090           (dolist (article very-wide)
1091             (gnus-summary-select-article nil nil nil article)
1092             (save-excursion
1093               (set-buffer (gnus-copy-article-buffer))
1094               (gnus-msg-treat-broken-reply-to)
1095               (save-restriction
1096                 (message-narrow-to-head)
1097                 (setq headers (concat headers (buffer-string)))))))
1098         (set-buffer (gnus-copy-article-buffer))
1099         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1100         (save-restriction
1101           (message-narrow-to-head)
1102           (when very-wide
1103             (erase-buffer)
1104             (insert headers))
1105           (goto-char (point-max)))
1106         (mml-quote-region (point) (point-max))
1107         (message-reply nil wide)
1108         (when yank
1109           (gnus-inews-yank-articles yank))
1110         (gnus-summary-handle-replysign)))))
1111
1112 (defun gnus-summary-handle-replysign ()
1113   "Check the various replysign variables and take action accordingly."
1114   (when (or gnus-message-replysign gnus-message-replyencrypt)
1115     (let (signed encrypted)
1116       (save-excursion
1117         (set-buffer gnus-article-buffer)
1118         (setq signed (memq 'signed gnus-article-wash-types))
1119         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1120       (cond ((and gnus-message-replyencrypt encrypted)
1121              (mml-secure-message mml-default-encrypt-method
1122                                  (if gnus-message-replysignencrypted
1123                                      'signencrypt
1124                                    'encrypt)))
1125             ((and gnus-message-replysign signed)
1126              (mml-secure-message mml-default-sign-method 'sign))))))
1127
1128 (defun gnus-summary-reply-with-original (n &optional wide)
1129   "Start composing a reply mail to the current message.
1130 The original article will be yanked."
1131   (interactive "P")
1132   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1133
1134 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1135   "Like `gnus-summary-reply' except removing reply-to field.
1136 If prefix argument YANK is non-nil, the original article is yanked
1137 automatically.
1138 If WIDE, make a wide reply.
1139 If VERY-WIDE, make a very wide reply."
1140   (interactive
1141    (list (and current-prefix-arg
1142               (gnus-summary-work-articles 1))))
1143   (let ((gnus-msg-force-broken-reply-to t))
1144     (gnus-summary-reply yank wide very-wide)))
1145
1146 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1147   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1148 The original article will be yanked."
1149   (interactive "P")
1150   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1151
1152 (defun gnus-summary-wide-reply (&optional yank)
1153   "Start composing a wide reply mail to the current message.
1154 If prefix argument YANK is non-nil, the original article is yanked
1155 automatically."
1156   (interactive
1157    (list (and current-prefix-arg
1158               (gnus-summary-work-articles 1))))
1159   (gnus-summary-reply yank t))
1160
1161 (defun gnus-summary-wide-reply-with-original (n)
1162   "Start composing a wide reply mail to the current message.
1163 The original article will be yanked.
1164 Uses the process/prefix convention."
1165   (interactive "P")
1166   (gnus-summary-reply-with-original n t))
1167
1168 (defun gnus-summary-very-wide-reply (&optional yank)
1169   "Start composing a very wide reply mail to the current message.
1170 If prefix argument YANK is non-nil, the original article is yanked
1171 automatically."
1172   (interactive
1173    (list (and current-prefix-arg
1174               (gnus-summary-work-articles 1))))
1175   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1176
1177 (defun gnus-summary-very-wide-reply-with-original (n)
1178   "Start composing a very wide reply mail to the current message.
1179 The original article will be yanked."
1180   (interactive "P")
1181   (gnus-summary-reply
1182    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1183
1184 (defun gnus-summary-mail-forward (&optional arg post)
1185   "Forward the current message(s) to another user.
1186 If process marks exist, forward all marked messages;
1187 if ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
1188 if ARG is 1, decode the message and forward directly inline;
1189 if ARG is 2, forward message as an rfc822 MIME section;
1190 if ARG is 3, decode message and forward as an rfc822 MIME section;
1191 if ARG is 4, forward message directly inline;
1192 otherwise, use flipped `message-forward-as-mime'.
1193 If POST, post instead of mail.
1194 For the `inline' alternatives, also see the variable
1195 `message-forward-ignored-headers'."
1196   (interactive "P")
1197   (if (cdr (gnus-summary-work-articles nil))
1198       ;; Process marks are given.
1199       (gnus-uu-digest-mail-forward arg post)
1200     ;; No process marks.
1201     (let ((message-forward-as-mime message-forward-as-mime)
1202           (message-forward-show-mml message-forward-show-mml))
1203       (cond
1204        ((null arg))
1205        ((eq arg 1)
1206         (setq message-forward-as-mime nil
1207               message-forward-show-mml t))
1208        ((eq arg 2)
1209         (setq message-forward-as-mime t
1210               message-forward-show-mml nil))
1211        ((eq arg 3)
1212         (setq message-forward-as-mime t
1213               message-forward-show-mml t))
1214        ((eq arg 4)
1215         (setq message-forward-as-mime nil
1216               message-forward-show-mml nil))
1217        (t
1218         (setq message-forward-as-mime (not message-forward-as-mime))))
1219       (let* ((gnus-article-reply (gnus-summary-article-number))
1220              (gnus-article-yanked-articles (list gnus-article-reply)))
1221         (gnus-setup-message 'forward
1222           (gnus-summary-select-article)
1223           (let ((mail-parse-charset
1224                  (or (and (gnus-buffer-live-p gnus-article-buffer)
1225                           (with-current-buffer gnus-article-buffer
1226                             gnus-article-charset))
1227                      gnus-newsgroup-charset))
1228                 (mail-parse-ignored-charsets
1229                  gnus-newsgroup-ignored-charsets))
1230             (set-buffer gnus-original-article-buffer)
1231             (message-forward post)))))))
1232
1233 (defun gnus-summary-resend-message (address n)
1234   "Resend the current article to ADDRESS."
1235   (interactive
1236    (list (message-read-from-minibuffer
1237           "Resend message(s) to: "
1238           (when (and gnus-summary-resend-default-address
1239                      (gnus-buffer-live-p gnus-original-article-buffer))
1240             ;; If some other article is currently selected, the
1241             ;; initial-contents is wrong. Whatever, it is just the
1242             ;; initial-contents.
1243             (with-current-buffer gnus-original-article-buffer
1244               (nnmail-fetch-field "to"))))
1245          current-prefix-arg))
1246   (let ((articles (gnus-summary-work-articles n))
1247         article)
1248     (while (setq article (pop articles))
1249       (gnus-summary-select-article nil nil nil article)
1250       (save-excursion
1251         (set-buffer gnus-original-article-buffer)
1252         (message-resend address))
1253       (gnus-summary-mark-article-as-forwarded article))))
1254
1255 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1256 (defun gnus-summary-resend-message-edit ()
1257   "Resend an article that has already been sent.
1258 A new buffer will be created to allow the user to modify body and
1259 contents of the message, and then, everything will happen as when
1260 composing a new message."
1261   (interactive)
1262   (let ((article (gnus-summary-article-number)))
1263     (gnus-setup-message 'reply-yank
1264       (gnus-summary-select-article t)
1265       (set-buffer gnus-original-article-buffer)
1266       (let ((cur (current-buffer))
1267             (to (message-fetch-field "to")))
1268         ;; Get a normal message buffer.
1269         (message-pop-to-buffer (message-buffer-name "Resend" to))
1270         (insert-buffer-substring cur)
1271         (mime-to-mml)
1272         (message-narrow-to-head-1)
1273         ;; Gnus will generate a new one when sending.
1274         (message-remove-header "Message-ID")
1275         (message-remove-header message-ignored-resent-headers t)
1276         ;; Remove unwanted headers.
1277         (goto-char (point-max))
1278         (insert mail-header-separator)
1279         (goto-char (point-min))
1280         (when (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1281           (forward-char 1))
1282         (widen)))))
1283
1284 (defun gnus-summary-post-forward (&optional arg)
1285   "Forward the current article to a newsgroup.
1286 See `gnus-summary-mail-forward' for ARG."
1287   (interactive "P")
1288   (gnus-summary-mail-forward arg t))
1289
1290 (defvar gnus-nastygram-message
1291   "The following article was inappropriately posted to %s.\n\n"
1292   "Format string to insert in nastygrams.
1293 The current group name will be inserted at \"%s\".")
1294
1295 (defun gnus-summary-mail-nastygram (n)
1296   "Send a nastygram to the author of the current article."
1297   (interactive "P")
1298   (when (or gnus-expert-user
1299             (gnus-y-or-n-p
1300              "Really send a nastygram to the author of the current article? "))
1301     (let ((group gnus-newsgroup-name))
1302       (gnus-summary-reply-with-original n)
1303       (set-buffer gnus-message-buffer)
1304       (message-goto-body)
1305       (insert (format gnus-nastygram-message group))
1306       (message-send-and-exit))))
1307
1308 (defun gnus-summary-mail-crosspost-complaint (n)
1309   "Send a complaint about crossposting to the current article(s)."
1310   (interactive "P")
1311   (let ((articles (gnus-summary-work-articles n))
1312         article)
1313     (while (setq article (pop articles))
1314       (set-buffer gnus-summary-buffer)
1315       (gnus-summary-goto-subject article)
1316       (let ((group (gnus-group-real-name gnus-newsgroup-name))
1317             newsgroups followup-to)
1318         (gnus-summary-select-article)
1319         (set-buffer gnus-original-article-buffer)
1320         (if (and (<= (length (message-tokenize-header
1321                               (setq newsgroups
1322                                     (mail-fetch-field "newsgroups"))
1323                               ", "))
1324                      1)
1325                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
1326                      (not (member group (message-tokenize-header
1327                                          followup-to ", ")))))
1328             (if followup-to
1329                 (gnus-message 1 "Followup-to restricted")
1330               (gnus-message 1 "Not a crossposted article"))
1331           (set-buffer gnus-summary-buffer)
1332           (gnus-summary-reply-with-original 1)
1333           (set-buffer gnus-message-buffer)
1334           (message-goto-body)
1335           (insert (format gnus-crosspost-complaint newsgroups group))
1336           (message-goto-subject)
1337           (re-search-forward " *$")
1338           (replace-match " (crosspost notification)" t t)
1339           (gnus-deactivate-mark)
1340           (when (gnus-y-or-n-p "Send this complaint? ")
1341             (message-send-and-exit)))))))
1342
1343 (defun gnus-mail-parse-comma-list ()
1344   (let (accumulated
1345         beg)
1346     (skip-chars-forward " ")
1347     (while (not (eobp))
1348       (setq beg (point))
1349       (skip-chars-forward "^,")
1350       (while (zerop
1351               (save-excursion
1352                 (save-restriction
1353                   (let ((i 0))
1354                     (narrow-to-region beg (point))
1355                     (goto-char beg)
1356                     (logand (progn
1357                               (while (search-forward "\"" nil t)
1358                                 (incf i))
1359                               (if (zerop i) 2 i))
1360                             2)))))
1361         (skip-chars-forward ",")
1362         (skip-chars-forward "^,"))
1363       (skip-chars-backward " ")
1364       (push (buffer-substring beg (point))
1365             accumulated)
1366       (skip-chars-forward "^,")
1367       (skip-chars-forward ", "))
1368     accumulated))
1369
1370 (defun gnus-inews-add-to-address (group)
1371   (let ((to-address (mail-fetch-field "to")))
1372     (when (and to-address
1373                (gnus-alive-p))
1374       ;; This mail group doesn't have a `to-list', so we add one
1375       ;; here.  Magic!
1376       (when (gnus-y-or-n-p
1377              (format "Do you want to add this as `to-list': %s? " to-address))
1378         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1379
1380 (defun gnus-put-message ()
1381   "Put the current message in some group and return to Gnus."
1382   (interactive)
1383   (let ((reply gnus-article-reply)
1384         (winconf gnus-prev-winconf)
1385         (group gnus-newsgroup-name))
1386     (unless (and group
1387                  (not (gnus-group-read-only-p group)))
1388       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1389
1390     (when (gnus-gethash group gnus-newsrc-hashtb)
1391       (error "No such group: %s" group))
1392     (save-excursion
1393       (save-restriction
1394         (widen)
1395         (message-narrow-to-headers)
1396         (let ((gnus-deletable-headers nil))
1397           (message-generate-headers
1398            (if (message-news-p)
1399                message-required-news-headers
1400              message-required-mail-headers)))
1401         (goto-char (point-max))
1402         (if (string-match " " group)
1403             (insert "Gcc: \"" group "\"\n")
1404           (insert "Gcc: " group "\n"))
1405         (widen)))
1406     (gnus-inews-do-gcc)
1407     (when (and (get-buffer gnus-group-buffer)
1408                (gnus-buffer-exists-p (car-safe reply))
1409                (cdr reply))
1410       (set-buffer (car reply))
1411       (gnus-summary-mark-article-as-replied (cdr reply)))
1412     (when winconf
1413       (set-window-configuration winconf))))
1414
1415 (defun gnus-article-mail (yank)
1416   "Send a reply to the address near point.
1417 If YANK is non-nil, include the original article."
1418   (interactive "P")
1419   (let ((address
1420          (buffer-substring
1421           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1422           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1423     (when address
1424       (gnus-msg-mail address)
1425       (when yank
1426         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1427
1428 (defvar nntp-server-type)
1429 (defun gnus-bug ()
1430   "Send a bug report to the Gnus maintainers."
1431   (interactive)
1432   (unless (gnus-alive-p)
1433     (error "Gnus has been shut down"))
1434   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1435     (unless (message-mail-user-agent)
1436       (delete-other-windows)
1437       (when gnus-bug-create-help-buffer
1438         (switch-to-buffer "*Gnus Help Bug*")
1439         (erase-buffer)
1440         (insert gnus-bug-message)
1441         (goto-char (point-min)))
1442       (message-pop-to-buffer "*Gnus Bug*"))
1443     (let ((message-this-is-mail t))
1444       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1445     (when gnus-bug-create-help-buffer
1446       (push `(gnus-bug-kill-buffer) message-send-actions))
1447     (goto-char (point-min))
1448     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1449     (forward-line 1)
1450     (insert (gnus-version) "\n"
1451             (emacs-version) "\n")
1452     (when (and (boundp 'nntp-server-type)
1453                (stringp nntp-server-type))
1454       (insert nntp-server-type))
1455     (insert "\n\n\n\n\n")
1456     (let (text)
1457       (save-excursion
1458         (set-buffer (gnus-get-buffer-create " *gnus environment info*"))
1459         (erase-buffer)
1460         (gnus-debug)
1461         (setq text (buffer-string)))
1462       (insert "<#part type=application/emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
1463     (goto-char (point-min))
1464     (search-forward "Subject: " nil t)
1465     (message "")))
1466
1467 (defun gnus-bug-kill-buffer ()
1468   (when (get-buffer "*Gnus Help Bug*")
1469     (kill-buffer "*Gnus Help Bug*")))
1470
1471 (defun gnus-summary-yank-message (buffer n)
1472   "Yank the current article into a composed message."
1473   (interactive
1474    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
1475          current-prefix-arg))
1476   (gnus-summary-iterate n
1477     (let ((gnus-inhibit-treatment t))
1478       (gnus-summary-select-article))
1479     (save-excursion
1480       (set-buffer buffer)
1481       (message-yank-buffer gnus-article-buffer))))
1482
1483 (defun gnus-debug ()
1484   "Attempts to go through the Gnus source file and report what variables have been changed.
1485 The source file has to be in the Emacs load path."
1486   (interactive)
1487   (let ((files gnus-debug-files)
1488         (point (point))
1489         file expr olist sym)
1490     (gnus-message 4 "Please wait while we snoop your variables...")
1491     (sit-for 0)
1492     ;; Go through all the files looking for non-default values for variables.
1493     (save-excursion
1494       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
1495       (while files
1496         (erase-buffer)
1497         (when (and (setq file (locate-library (pop files)))
1498                    (file-exists-p file))
1499           (insert-file-contents file)
1500           (goto-char (point-min))
1501           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1502               (gnus-message 4 "Malformed sources in file %s" file)
1503             (narrow-to-region (point-min) (point))
1504             (goto-char (point-min))
1505             (while (setq expr (ignore-errors (read (current-buffer))))
1506               (ignore-errors
1507                 (and (or (eq (car expr) 'defvar)
1508                          (eq (car expr) 'defcustom))
1509                      (stringp (nth 3 expr))
1510                      (not (memq (nth 1 expr) gnus-debug-exclude-variables))
1511                      (or (not (boundp (nth 1 expr)))
1512                          (not (equal (eval (nth 2 expr))
1513                                      (symbol-value (nth 1 expr)))))
1514                      (push (nth 1 expr) olist)))))))
1515       (kill-buffer (current-buffer)))
1516     (when (setq olist (nreverse olist))
1517       (insert "------------------ Environment follows ------------------\n\n"))
1518     (while olist
1519       (if (boundp (car olist))
1520           (ignore-errors
1521            (gnus-pp
1522             `(setq ,(car olist)
1523                    ,(if (or (consp (setq sym (symbol-value (car olist))))
1524                             (and (symbolp sym)
1525                                  (not (or (eq sym nil)
1526                                           (eq sym t)))))
1527                         (list 'quote (symbol-value (car olist)))
1528                       (symbol-value (car olist))))))
1529         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1530       (setq olist (cdr olist)))
1531     (insert "\n\n")
1532     ;; Remove any control chars - they seem to cause trouble for some
1533     ;; mailers.  (Byte-compiled output from the stuff above.)
1534     (goto-char point)
1535     (while (re-search-forward (mm-string-as-multibyte
1536                                "[\000-\010\013-\037\200-\237]") nil t)
1537       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1538                      t t))))
1539
1540 ;;; Treatment of rejected articles.
1541 ;;; Bounced mail.
1542
1543 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1544   "Re-mail the current message.
1545 This only makes sense if the current message is a bounce message that
1546 contains some mail you have written which has been bounced back to
1547 you.
1548 If FETCH, try to fetch the article that this is a reply to, if indeed
1549 this is a reply."
1550   (interactive "P")
1551   (gnus-summary-select-article t)
1552   (set-buffer gnus-original-article-buffer)
1553   (gnus-setup-message 'compose-bounce
1554     (let* ((references (mail-fetch-field "references"))
1555            (parent (and references (gnus-parent-id references))))
1556       (message-bounce)
1557       ;; If there are references, we fetch the article we answered to.
1558       (and fetch parent
1559            (gnus-summary-refer-article parent)
1560            (gnus-summary-show-all-headers)))))
1561
1562 ;;; Gcc handling.
1563
1564 (defun gnus-inews-group-method (group)
1565   (cond
1566    ;; If the group doesn't exist, we assume
1567    ;; it's an archive group...
1568    ((and (null (gnus-get-info group))
1569          (eq (car (gnus-server-to-method gnus-message-archive-method))
1570              (car (gnus-server-to-method (gnus-group-method group)))))
1571     gnus-message-archive-method)
1572    ;; Use the method.
1573    ((gnus-info-method (gnus-get-info group))
1574     (gnus-info-method (gnus-get-info group)))
1575    ;; Find the method.
1576    (t (gnus-server-to-method (gnus-group-method group)))))
1577
1578 ;; Do Gcc handling, which copied the message over to some group.
1579 (defun gnus-inews-do-gcc (&optional gcc)
1580   (interactive)
1581   (save-excursion
1582     (save-restriction
1583       (message-narrow-to-headers)
1584       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1585             (cur (current-buffer))
1586             groups group method group-art
1587             mml-externalize-attachments)
1588         (when gcc
1589           (message-remove-header "gcc")
1590           (widen)
1591           (setq groups (message-unquote-tokens
1592                         (message-tokenize-header gcc " ,")))
1593           ;; Copy the article over to some group(s).
1594           (while (setq group (pop groups))
1595             (unless (gnus-check-server
1596                      (setq method (gnus-inews-group-method group)))
1597               (error "Can't open server %s" (if (stringp method) method
1598                                               (car method))))
1599             (unless (gnus-request-group group nil method)
1600               (gnus-request-create-group group method))
1601             (setq mml-externalize-attachments
1602                   (if (stringp gnus-gcc-externalize-attachments)
1603                       (string-match gnus-gcc-externalize-attachments group)
1604                     gnus-gcc-externalize-attachments))
1605             (save-excursion
1606               (nnheader-set-temp-buffer " *acc*")
1607               (insert-buffer-substring cur)
1608               (message-encode-message-body)
1609               (save-restriction
1610                 (message-narrow-to-headers)
1611                 (let* ((mail-parse-charset message-default-charset)
1612                        (newsgroups-field (save-restriction
1613                                            (message-narrow-to-headers-or-head)
1614                                            (message-fetch-field "Newsgroups")))
1615                        (followup-field (save-restriction
1616                                          (message-narrow-to-headers-or-head)
1617                                          (message-fetch-field "Followup-To")))
1618                        ;; BUG: We really need to get the charset for
1619                        ;; each name in the Newsgroups and Followup-To
1620                        ;; lines to allow crossposting between group
1621                        ;; namess with incompatible character sets.
1622                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1623                        (group-field-charset
1624                         (gnus-group-name-charset
1625                          method (or newsgroups-field "")))
1626                        (followup-field-charset
1627                         (gnus-group-name-charset
1628                          method (or followup-field "")))
1629                        (rfc2047-header-encoding-alist
1630                         (append
1631                          (when group-field-charset
1632                            (list (cons "Newsgroups" group-field-charset)))
1633                          (when followup-field-charset
1634                            (list (cons "Followup-To" followup-field-charset)))
1635                          rfc2047-header-encoding-alist)))
1636                   (mail-encode-encoded-word-buffer)))
1637               (goto-char (point-min))
1638               (when (re-search-forward
1639                      (concat "^" (regexp-quote mail-header-separator) "$")
1640                      nil t)
1641                 (replace-match "" t t ))
1642               (unless (setq group-art
1643                             (gnus-request-accept-article group method t t))
1644                 (gnus-message 1 "Couldn't store article in group %s: %s"
1645                               group (gnus-status-message method))
1646                 (sit-for 2))
1647               (when (and group-art
1648                          ;; FIXME: Should gcc-mark-as-read work when
1649                          ;; Gnus is not running?
1650                          (gnus-alive-p)
1651                          (or gnus-gcc-mark-as-read
1652                              (and
1653                               (boundp 'gnus-inews-mark-gcc-as-read)
1654                               (symbol-value 'gnus-inews-mark-gcc-as-read))))
1655                 (gnus-group-mark-article-read group (cdr group-art)))
1656               (kill-buffer (current-buffer)))))))))
1657
1658 (defun gnus-inews-insert-gcc ()
1659   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1660   (save-excursion
1661     (save-restriction
1662       (message-narrow-to-headers)
1663       (let* ((group gnus-outgoing-message-group)
1664              (gcc (cond
1665                    ((functionp group)
1666                     (funcall group))
1667                    ((or (stringp group) (listp group))
1668                     group))))
1669         (when gcc
1670           (insert "Gcc: "
1671                   (if (stringp gcc)
1672                       (if (string-match " " gcc)
1673                           (concat "\"" gcc "\"")
1674                         gcc)
1675                     (mapconcat (lambda (group)
1676                                  (if (string-match " " group)
1677                                      (concat "\"" group "\"")
1678                                    group))
1679                                gcc " "))
1680                   "\n"))))))
1681
1682 (defun gnus-inews-insert-archive-gcc (&optional group)
1683   "Insert the Gcc to say where the article is to be archived."
1684   (let* ((var gnus-message-archive-group)
1685          (group (or group gnus-newsgroup-name ""))
1686          (gcc-self-val
1687           (and gnus-newsgroup-name
1688                (not (equal gnus-newsgroup-name ""))
1689                (gnus-group-find-parameter
1690                 gnus-newsgroup-name 'gcc-self)))
1691          result
1692          (groups
1693           (cond
1694            ((null gnus-message-archive-method)
1695             ;; Ignore.
1696             nil)
1697            ((stringp var)
1698             ;; Just a single group.
1699             (list var))
1700            ((null var)
1701             ;; We don't want this.
1702             nil)
1703            ((and (listp var) (stringp (car var)))
1704             ;; A list of groups.
1705             var)
1706            ((functionp var)
1707             ;; A function.
1708             (funcall var group))
1709            (t
1710             ;; An alist of regexps/functions/forms.
1711             (while (and var
1712                         (not
1713                          (setq result
1714                                (cond
1715                                 ((stringp (caar var))
1716                                  ;; Regexp.
1717                                  (when (string-match (caar var) group)
1718                                    (cdar var)))
1719                                 ((functionp (car var))
1720                                  ;; Function.
1721                                  (funcall (car var) group))
1722                                 (t
1723                                  (eval (car var)))))))
1724               (setq var (cdr var)))
1725             result)))
1726          name)
1727     (when (or groups gcc-self-val)
1728       (when (stringp groups)
1729         (setq groups (list groups)))
1730       (save-excursion
1731         (save-restriction
1732           (message-narrow-to-headers)
1733           (goto-char (point-max))
1734           (insert "Gcc: ")
1735           (if gcc-self-val
1736               ;; Use the `gcc-self' param value instead.
1737               (progn
1738                 (insert
1739                  (if (stringp gcc-self-val)
1740                      (if (string-match " " gcc-self-val)
1741                          (concat "\"" gcc-self-val "\"")
1742                        gcc-self-val)
1743                    ;; In nndoc groups, we use the parent group name
1744                    ;; instead of the current group.
1745                    (let ((group (or (gnus-group-find-parameter
1746                                      gnus-newsgroup-name 'parent-group)
1747                                     group)))
1748                      (if (string-match " " group)
1749                          (concat "\"" group "\"")
1750                        group))))
1751                 (if (not (eq gcc-self-val 'none))
1752                     (insert "\n")
1753                   (gnus-delete-line)))
1754             ;; Use the list of groups.
1755             (while (setq name (pop groups))
1756               (let ((str (if (string-match ":" name)
1757                              name
1758                            (gnus-group-prefixed-name
1759                             name gnus-message-archive-method))))
1760                 (insert (if (string-match " " str)
1761                             (concat "\"" str "\"")
1762                           str)))
1763               (when groups
1764                 (insert " ")))
1765             (insert "\n")))))))
1766
1767 (defun gnus-mailing-list-followup-to ()
1768   "Look at the headers in the current buffer and return a Mail-Followup-To address."
1769   (let ((x-been-there (gnus-fetch-original-field "x-beenthere"))
1770         (list-post (gnus-fetch-original-field "list-post")))
1771     (when (and list-post
1772                (string-match "mailto:\\([^>]+\\)" list-post))
1773       (setq list-post (match-string 1 list-post)))
1774     (or list-post
1775         x-been-there)))
1776
1777 ;;; Posting styles.
1778
1779 (defun gnus-configure-posting-styles (&optional group-name)
1780   "Configure posting styles according to `gnus-posting-styles'."
1781   (unless gnus-inhibit-posting-styles
1782     (let ((group (or group-name gnus-newsgroup-name ""))
1783           (styles gnus-posting-styles)
1784           style match attribute value v results
1785           filep name address element)
1786       ;; If the group has a posting-style parameter, add it at the end with a
1787       ;; regexp matching everything, to be sure it takes precedence over all
1788       ;; the others.
1789       (when gnus-newsgroup-name
1790         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1791           (when tmp-style
1792             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1793       ;; Go through all styles and look for matches.
1794       (dolist (style styles)
1795         (setq match (pop style))
1796         (goto-char (point-min))
1797         (when (cond
1798                ((stringp match)
1799                 ;; Regexp string match on the group name.
1800                 (string-match match group))
1801                ((eq match 'header)
1802                 ;; Obsolete format of header match.
1803                 (and (gnus-buffer-live-p gnus-article-copy)
1804                      (with-current-buffer gnus-article-copy
1805                        (save-restriction
1806                          (nnheader-narrow-to-headers)
1807                          (let ((header (message-fetch-field (pop style))))
1808                            (and header
1809                                 (string-match (pop style) header)))))))
1810                ((or (symbolp match)
1811                     (functionp match))
1812                 (cond
1813                  ((functionp match)
1814                   ;; Function to be called.
1815                   (funcall match))
1816                  ((boundp match)
1817                   ;; Variable to be checked.
1818                   (symbol-value match))))
1819                ((listp match)
1820                 (cond
1821                  ((eq (car match) 'header)
1822                   ;; New format of header match.
1823                   (and (gnus-buffer-live-p gnus-article-copy)
1824                        (with-current-buffer gnus-article-copy
1825                          (save-restriction
1826                            (nnheader-narrow-to-headers)
1827                            (let ((header (message-fetch-field (nth 1 match))))
1828                              (and header
1829                                   (string-match (nth 2 match) header)))))))
1830                  (t
1831                   ;; This is a form to be evaled.
1832                   (eval match)))))
1833           ;; We have a match, so we set the variables.
1834           (dolist (attribute style)
1835             (setq element (pop attribute)
1836                   filep nil)
1837             (setq value
1838                   (cond
1839                    ((eq (car attribute) :file)
1840                     (setq filep t)
1841                     (cadr attribute))
1842                    ((eq (car attribute) :value)
1843                     (cadr attribute))
1844                    (t
1845                     (car attribute))))
1846             ;; We get the value.
1847             (setq v
1848                   (cond
1849                    ((stringp value)
1850                     value)
1851                    ((or (symbolp value)
1852                         (functionp value))
1853                     (cond ((functionp value)
1854                            (funcall value))
1855                           ((boundp value)
1856                            (symbol-value value))))
1857                    ((listp value)
1858                     (eval value))))
1859             ;; Translate obsolescent value.
1860             (cond
1861              ((eq element 'signature-file)
1862               (setq element 'signature
1863                     filep t))
1864              ((eq element 'x-face-file)
1865               (setq element 'x-face
1866                     filep t)))
1867             ;; Get the contents of file elems.
1868             (when (and filep v)
1869               (setq v (with-temp-buffer
1870                         (insert-file-contents v)
1871                         (buffer-substring
1872                          (point-min)
1873                          (progn
1874                            (goto-char (point-max))
1875                            (if (zerop (skip-chars-backward "\n"))
1876                                (point)
1877                              (1+ (point))))))))
1878             (setq results (delq (assoc element results) results))
1879             (push (cons element v) results))))
1880       ;; Now we have all the styles, so we insert them.
1881       (setq name (assq 'name results)
1882             address (assq 'address results))
1883       (setq results (delq name (delq address results)))
1884       (gnus-make-local-hook 'message-setup-hook)
1885       (setq results (sort results (lambda (x y)
1886                                     (string-lessp (car x) (car y)))))
1887       (dolist (result results)
1888         (add-hook 'message-setup-hook
1889                   (cond
1890                    ((eq 'eval (car result))
1891                     'ignore)
1892                    ((eq 'body (car result))
1893                     `(lambda ()
1894                        (save-excursion
1895                          (message-goto-body)
1896                          (insert ,(cdr result)))))
1897                    ((eq 'signature (car result))
1898                     (set (make-local-variable 'message-signature) nil)
1899                     (set (make-local-variable 'message-signature-file) nil)
1900                     (if (not (cdr result))
1901                         'ignore
1902                       `(lambda ()
1903                          (save-excursion
1904                            (let ((message-signature ,(cdr result)))
1905                              (when message-signature
1906                                (message-insert-signature)))))))
1907                    (t
1908                     (let ((header
1909                            (if (symbolp (car result))
1910                                (capitalize (symbol-name (car result)))
1911                              (car result))))
1912                       `(lambda ()
1913                          (save-excursion
1914                            (message-remove-header ,header)
1915                            (let ((value ,(cdr result)))
1916                              (when value
1917                                (message-goto-eoh)
1918                                (insert ,header ": " value)
1919                                (unless (bolp)
1920                                  (insert "\n")))))))))
1921                   nil 'local))
1922       (when (or name address)
1923         (add-hook 'message-setup-hook
1924                   `(lambda ()
1925                      (set (make-local-variable 'user-mail-address)
1926                           ,(or (cdr address) user-mail-address))
1927                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1928                            (user-mail-address
1929                             ,(or (cdr address) user-mail-address)))
1930                        (save-excursion
1931                          (message-remove-header "From")
1932                          (message-goto-eoh)
1933                          (insert "From: " (message-make-from) "\n"))))
1934                   nil 'local)))))
1935
1936 ;;; Allow redefinition of functions.
1937
1938 (gnus-ems-redefine)
1939
1940 (provide 'gnus-msg)
1941
1942 ;;; arch-tag: 9f22b2f5-1c0a-49de-916e-4c88e984852b
1943 ;;; gnus-msg.el ends here