lisp/emacs-lisp/macroexp.el

   1 ;;; macroexp.el --- Additional macro-expansion support -*- lexical-binding: t -*-
   2 ;;
   3 ;; Copyright (C) 2004-2012 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Miles Bader <miles@gnu.org>
   6 ;; Keywords: lisp, compiler, macros
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24 ;;
  25 ;; This file contains macro-expansions functions that are not defined in
  26 ;; the Lisp core, namely `macroexpand-all', which expands all macros in
  27 ;; a form, not just a top-level one.
  28 ;;
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl))
  33
  34 ;; Bound by the top-level `macroexpand-all', and modified to include any
  35 ;; macros defined by `defmacro'.
  36 (defvar macroexpand-all-environment nil)
  37
  38 (defun maybe-cons (car cdr original-cons)
  39   "Return (CAR . CDR), using ORIGINAL-CONS if possible."
  40   (if (and (eq car (car original-cons)) (eq cdr (cdr original-cons)))
  41       original-cons
  42     (cons car cdr)))
  43
  44 ;; We use this special macro to iteratively process forms and share list
  45 ;; structure of the result with the input.  Doing so recursively using
  46 ;; `maybe-cons' results in excessively deep recursion for very long
  47 ;; input forms.
  48 (defmacro macroexp-accumulate (var+list &rest body)
  49   "Return a list of the results of evaluating BODY for each element of LIST.
  50 Evaluate BODY with VAR bound to each `car' from LIST, in turn.
  51 Return a list of the values of the final form in BODY.
  52 The list structure of the result will share as much with LIST as
  53 possible (for instance, when BODY just returns VAR unchanged, the
  54 result will be eq to LIST).
  55
  56 \(fn (VAR LIST) BODY...)"
  57   (declare (indent 1))
  58   (let ((var (car var+list))
  59         (list (cadr var+list))
  60         (shared (make-symbol "shared"))
  61         (unshared (make-symbol "unshared"))
  62         (tail (make-symbol "tail"))
  63         (new-el (make-symbol "new-el")))
  64     `(let* ((,shared ,list)
  65             (,unshared nil)
  66             (,tail ,shared)
  67             ,var ,new-el)
  68        (while (consp ,tail)
  69          (setq ,var (car ,tail)
  70                ,new-el (progn ,@body))
  71          (unless (eq ,var ,new-el)
  72            (while (not (eq ,shared ,tail))
  73              (push (pop ,shared) ,unshared))
  74            (setq ,shared (cdr ,shared))
  75            (push ,new-el ,unshared))
  76          (setq ,tail (cdr ,tail)))
  77        (nconc (nreverse ,unshared) ,shared))))
  78
  79 (defun macroexpand-all-forms (forms &optional skip)
  80   "Return FORMS with macros expanded.  FORMS is a list of forms.
  81 If SKIP is non-nil, then don't expand that many elements at the start of
  82 FORMS."
  83   (macroexp-accumulate (form forms)
  84     (if (or (null skip) (zerop skip))
  85         (macroexpand-all-1 form)
  86       (setq skip (1- skip))
  87       form)))
  88
  89 (defun macroexpand-all-clauses (clauses &optional skip)
  90   "Return CLAUSES with macros expanded.
  91 CLAUSES is a list of lists of forms; any clause that's not a list is ignored.
  92 If SKIP is non-nil, then don't expand that many elements at the start of
  93 each clause."
  94   (macroexp-accumulate (clause clauses)
  95     (if (listp clause)
  96         (macroexpand-all-forms clause skip)
  97       clause)))
  98
  99 (defun macroexpand-all-1 (form)
 100   "Expand all macros in FORM.
 101 This is an internal version of `macroexpand-all'.
 102 Assumes the caller has bound `macroexpand-all-environment'."
 103   (if (and (listp form) (eq (car form) 'backquote-list*))
 104       ;; Special-case `backquote-list*', as it is normally a macro that
 105       ;; generates exceedingly deep expansions from relatively shallow input
 106       ;; forms.  We just process it `in reverse' -- first we expand all the
 107       ;; arguments, _then_ we expand the top-level definition.
 108       (macroexpand (macroexpand-all-forms form 1)
 109                    macroexpand-all-environment)
 110     ;; Normal form; get its expansion, and then expand arguments.
 111     (let ((new-form (macroexpand form macroexpand-all-environment)))
 112       (when (and (not (eq form new-form)) ;It was a macro call.
 113                  (car-safe form)
 114                  (symbolp (car form))
 115                  (get (car form) 'byte-obsolete-info)
 116                  (fboundp 'byte-compile-warn-obsolete))
 117         (byte-compile-warn-obsolete (car form)))
 118       (setq form new-form))
 119     (pcase form
 120       (`(cond . ,clauses)
 121        (maybe-cons 'cond (macroexpand-all-clauses clauses) form))
 122       (`(condition-case . ,(or `(,err ,body . ,handlers) dontcare))
 123        (maybe-cons
 124         'condition-case
 125         (maybe-cons err
 126                     (maybe-cons (macroexpand-all-1 body)
 127                                 (macroexpand-all-clauses handlers 1)
 128                                 (cddr form))
 129                     (cdr form))
 130         form))
 131       (`(,(or `defvar `defconst) . ,_) (macroexpand-all-forms form 2))
 132       (`(function ,(and f `(lambda . ,_)))
 133        (maybe-cons 'function
 134                    (maybe-cons (macroexpand-all-forms f 2)
 135                                nil
 136                                (cdr form))
 137                    form))
 138       (`(,(or `function `quote) . ,_) form)
 139       (`(,(and fun (or `let `let*)) . ,(or `(,bindings . ,body) dontcare))
 140        (maybe-cons fun
 141                    (maybe-cons (macroexpand-all-clauses bindings 1)
 142                                (macroexpand-all-forms body)
 143                                (cdr form))
 144                    form))
 145       (`(,(and fun `(lambda . ,_)) . ,args)
 146        ;; Embedded lambda in function position.
 147        (maybe-cons (macroexpand-all-forms fun 2)
 148                    (macroexpand-all-forms args)
 149                    form))
 150       ;; The following few cases are for normal function calls that
 151       ;; are known to funcall one of their arguments.  The byte
 152       ;; compiler has traditionally handled these functions specially
 153       ;; by treating a lambda expression quoted by `quote' as if it
 154       ;; were quoted by `function'.  We make the same transformation
 155       ;; here, so that any code that cares about the difference will
 156       ;; see the same transformation.
 157       ;; First arg is a function:
 158       (`(,(and fun (or `funcall `apply `mapcar `mapatoms `mapconcat `mapc))
 159          ',(and f `(lambda . ,_)) . ,args)
 160        (byte-compile-log-warning
 161         (format "%s quoted with ' rather than with #'"
 162                 (list 'lambda (nth 1 f) '...))
 163         t)
 164        ;; We don't use `maybe-cons' since there's clearly a change.
 165        (cons fun
 166              (cons (macroexpand-all-1 (list 'function f))
 167                    (macroexpand-all-forms args))))
 168       ;; Second arg is a function:
 169       (`(,(and fun (or `sort)) ,arg1 ',(and f `(lambda . ,_)) . ,args)
 170        (byte-compile-log-warning
 171         (format "%s quoted with ' rather than with #'"
 172                 (list 'lambda (nth 1 f) '...))
 173         t)
 174        ;; We don't use `maybe-cons' since there's clearly a change.
 175        (cons fun
 176              (cons (macroexpand-all-1 arg1)
 177                    (cons (macroexpand-all-1
 178                           (list 'function f))
 179                          (macroexpand-all-forms args)))))
 180       ;; Macro expand compiler macros.  This cannot be delayed to
 181       ;; byte-optimize-form because the output of the compiler-macro can
 182       ;; use macros.
 183       ;; FIXME: Don't depend on CL.
 184       (`(,(pred (lambda (fun)
 185                   (and (symbolp fun)
 186                        (eq (get fun 'byte-compile)
 187                            'cl-byte-compile-compiler-macro)
 188                        (functionp 'compiler-macroexpand))))
 189          . ,_)
 190        (let ((newform (with-no-warnings (compiler-macroexpand form))))
 191          (if (eq form newform)
 192              (macroexpand-all-forms form 1)
 193            (macroexpand-all-1 newform))))
 194       (`(,_ . ,_)
 195        ;; For every other list, we just expand each argument (for
 196        ;; setq/setq-default this works alright because the variable names
 197        ;; are symbols).
 198        (macroexpand-all-forms form 1))
 199       (t form))))
 200
 201 ;;;###autoload
 202 (defun macroexpand-all (form &optional environment)
 203   "Return result of expanding macros at all levels in FORM.
 204 If no macros are expanded, FORM is returned unchanged.
 205 The second optional arg ENVIRONMENT specifies an environment of macro
 206 definitions to shadow the loaded ones for use in file byte-compilation."
 207   (let ((macroexpand-all-environment environment))
 208     (macroexpand-all-1 form)))
 209
 210 (provide 'macroexp)
 211
 212 ;;; macroexp.el ends here