lisp/ps-bdf.el

   1 ;;; ps-bdf.el --- BDF font file handler for ps-print
   2
   3 ;; Copyright (C) 1998, 1999, 2001 Electrotechnical Laboratory, JAPAN.
   4 ;;   Licensed to the Free Software Foundation.
   5 ;; Copyright (C) 2001, 2002, 2003 Free Software Foundation, Inc.
   6 ;; Copyright (C) 2003
   7 ;;   National Institute of Advanced Industrial Science and Technology (AIST)
   8 ;;   Registration Number H13PRO009
   9
  10 ;; Keywords: wp, BDF, font, PostScript
  11 ;; Maintainer: Kenichi Handa <handa@m17n.org>
  12 ;; Time-stamp: <2003/07/11 21:13:44 vinicius>
  13
  14 ;; This file is part of GNU Emacs.
  15
  16 ;; GNU Emacs is free software; you can redistribute it and/or modify
  17 ;; it under the terms of the GNU General Public License as published by
  18 ;; the Free Software Foundation; either version 2, or (at your option)
  19 ;; any later version.
  20
  21 ;; GNU Emacs is distributed in the hope that it will be useful,
  22 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;; GNU General Public License for more details.
  25
  26 ;; You should have received a copy of the GNU General Public License
  27 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  28 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  29 ;; Boston, MA 02110-1301, USA.
  30
  31 ;;; Commentary:
  32
  33 ;; Functions for getting bitmap information from X's BDF font file are
  34 ;; provided.
  35
  36 ;;; Code:
  37
  38 (eval-and-compile
  39   (require 'ps-mule)
  40
  41   ;; to avoid XEmacs compilation gripes
  42   (defvar installation-directory nil)
  43   (defvar coding-system-for-read nil))
  44
  45 ;;;###autoload
  46 (defvar bdf-directory-list
  47   (if (memq system-type '(ms-dos windows-nt))
  48       (list (expand-file-name "fonts/bdf" installation-directory))
  49     '("/usr/local/share/emacs/fonts/bdf"))
  50   "*List of directories to search for `BDF' font files.
  51 The default value is '(\"/usr/local/share/emacs/fonts/bdf\").")
  52
  53 ;; MS-DOS and MS-Windows users like to move the binary around after
  54 ;; it's built, but the value above is computed at load-up time.
  55 (and (memq system-type '(ms-dos windows-nt))
  56      (setq bdf-directory-list
  57            (list (expand-file-name "fonts/bdf" installation-directory))))
  58
  59 (defun bdf-expand-file-name (bdfname)
  60   "Return an absolute path name of a `BDF' font file BDFNAME.
  61 It searches directories listed in the variable `bdf-directory-list'
  62 for BDFNAME."
  63   (if (file-name-absolute-p bdfname)
  64       (and (file-readable-p bdfname)
  65            bdfname)
  66     (catch 'tag
  67       (dolist (dir bdf-directory-list)
  68         (let ((absolute-path (expand-file-name bdfname dir)))
  69           (if (file-readable-p absolute-path)
  70             (throw 'tag absolute-path)))))))
  71
  72 (defsubst bdf-file-mod-time (filename)
  73   "Return modification time of FILENAME.
  74 The value is a list of two integers, the first integer has high-order
  75 16 bits, the second has low 16 bits."
  76   (nth 5 (file-attributes filename)))
  77
  78 (defun bdf-file-newer-than-time (filename mod-time)
  79   "Return non-nil if and only if FILENAME is newer than MOD-TIME.
  80 MOD-TIME is a modification time as a list of two integers, the first
  81 integer has high-order 16 bits, the second has low 16 bits."
  82   (let* ((new-mod-time (bdf-file-mod-time filename))
  83          (new-time (car new-mod-time))
  84          (time (car mod-time)))
  85     (or (> new-time time)
  86         (and (= new-time time)
  87              (> (nth 1 new-mod-time) (nth 1 mod-time))))))
  88
  89 (defun bdf-find-file (bdfname)
  90   "Return a buffer visiting a bdf file BDFNAME.
  91 BDFNAME must be an absolute file name.
  92 If BDFNAME doesn't exist, return nil."
  93   (and (file-readable-p bdfname)
  94        (let ((buf (generate-new-buffer " *bdf-work*"))
  95              (coding-system-for-read 'no-conversion))
  96          (save-excursion
  97            (set-buffer buf)
  98            (insert-file-contents bdfname)
  99            buf))))
 100
 101 (defvar bdf-cache-file (if (eq system-type 'ms-dos)
 102                            ;; convert-standard-filename doesn't
 103                            ;; guarantee that the .el extension will be
 104                            ;; preserved.
 105                            "~/_bdfcache.el"
 106                          (convert-standard-filename "~/.bdfcache.el"))
 107   "Name of cache file which contains information of `BDF' font files.")
 108
 109 (defvar bdf-cache nil
 110   "Cached information of `BDF' font files.  It is a list of FONT-INFO.
 111 FONT-INFO is a list of the following format:
 112     (ABSOLUTE-FILE-NAME MOD-TIME SIZE FONT-BOUNDING-BOX
 113      RELATIVE-COMPOSE BASELINE-OFFSET CODE-RANGE MAXLEN OFFSET-VECTOR)
 114 See the documentation of the function `bdf-read-font-info' for more detail.")
 115
 116 (defun bdf-read-cache ()
 117   "Return a cached information about `BDF' font files from a cache file.
 118 The variable `bdf-cache-file' holds the cache file name.
 119 If the cache file is not readable, this return nil."
 120   (setq bdf-cache nil)
 121   (condition-case nil
 122       (and (file-readable-p bdf-cache-file)
 123            (progn
 124              (load-file bdf-cache-file)
 125              (if (listp bdf-cache)
 126                  bdf-cache
 127                (setq bdf-cache nil))))
 128     (error nil)))
 129
 130 (defun bdf-write-cache ()
 131   "Write out cached information of `BDF' font file to a file.
 132 The variable `bdf-cache-file' holds the cache file name.
 133 The file is written if and only if the file already exists and writable."
 134   (and bdf-cache
 135        (file-exists-p bdf-cache-file)
 136        (file-writable-p bdf-cache-file)
 137        (write-region (format "(setq bdf-cache '%S)\n" bdf-cache)
 138                      nil bdf-cache-file)))
 139
 140 (defun bdf-set-cache (font-info)
 141   "Cache FONT-INFO as information about one `BDF' font file.
 142 FONT-INFO is a list of the following format:
 143     (ABSOLUTE-FILE-NAME MOD-TIME SIZE FONT-BOUNDING-BOX
 144      RELATIVE-COMPOSE BASELINE-OFFSET CODE-RANGE MAXLEN OFFSET-VECTOR)
 145 See the documentation of the function `bdf-read-font-info' for more detail."
 146   (let ((slot (assoc (car font-info) bdf-cache)))
 147     (if slot
 148         (setcdr slot (cdr font-info))
 149       (setq bdf-cache (cons font-info bdf-cache)))))
 150
 151 (defun bdf-initialize ()
 152   "Initialize `bdf' library."
 153   (and (bdf-read-cache)
 154        (add-hook 'kill-emacs-hook 'bdf-write-cache)))
 155
 156 (defun bdf-compact-code (code code-range)
 157   (if (or (< code (aref code-range 4))
 158           (> code (aref code-range 5)))
 159       (setq code (aref code-range 6)))
 160   (+ (* (- (lsh code -8) (aref code-range 0))
 161         (1+ (- (aref code-range 3) (aref code-range 2))))
 162      (- (logand code 255) (aref code-range 2))))
 163
 164 (defun bdf-expand-code (code code-range)
 165   (let ((code0-range (1+ (- (aref code-range 3) (aref code-range 2)))))
 166     (+ (* (+ (/ code code0-range) (aref code-range 0)) 256)
 167        (+ (% code code0-range) (aref code-range 2)))))
 168
 169 (defun bdf-search-and-read (match limit)
 170   (goto-char (point-min))
 171   (and (search-forward match limit t)
 172        (progn
 173          (goto-char (match-end 0))
 174          (read (current-buffer)))))
 175
 176 (defun bdf-read-font-info (bdfname)
 177   "Read `BDF' font file BDFNAME and return information (FONT-INFO) of the file.
 178 BDFNAME must be an absolute file name.
 179 FONT-INFO is a list of the following format:
 180     (BDFFILE MOD-TIME FONT-BOUNDING-BOX
 181      RELATIVE-COMPOSE BASELINE-OFFSET CODE-RANGE MAXLEN OFFSET-VECTOR)
 182
 183 MOD-TIME is last modification time as a list of two integers, the
 184 first integer has high-order 16 bits, the second has low 16 bits.
 185
 186 SIZE is a size of the font on 72 dpi device.  This value is got
 187 from SIZE record of the font.
 188
 189 FONT-BOUNDING-BOX is the font bounding box as a list of four integers,
 190 BBX-WIDTH, BBX-HEIGHT, BBX-XOFF, and BBX-YOFF.
 191
 192 RELATIVE-COMPOSE is an integer value of the font's property
 193 `_MULE_RELATIVE_COMPOSE'.  If the font doesn't have this property, the
 194 value is 0.
 195
 196 BASELINE-OFFSET is an integer value of the font's property
 197 `_MULE_BASELINE_OFFSET'.  If the font doesn't have this property, the
 198 value is 0.
 199
 200 CODE-RANGE is a vector of minimum 1st byte, maximum 1st byte, minimum
 201 2nd byte, maximum 2nd byte, minimum code, maximum code, and default
 202 code.  For 1-byte fonts, the first two elements are 0.
 203
 204 MAXLEN is a maximum bytes of one glyph information in the font file.
 205
 206 OFFSET-VECTOR is a vector of a file position which starts bitmap data
 207 of the glyph in the font file.
 208
 209 Nth element of OFFSET-VECTOR is a file position for the glyph of code
 210 CODE, where N and CODE are in the following relation:
 211     (bdf-compact-code CODE) => N, (bdf-expand-code N) => CODE"
 212   (let* ((buf (bdf-find-file bdfname))
 213          (maxlen 0)
 214          (relative-compose 'false)
 215          (baseline-offset 0)
 216          size
 217          dpi
 218          font-bounding-box
 219          default-char
 220          code-range
 221          offset-vector)
 222     (if buf
 223         (message "Reading %s..." bdfname)
 224       (error "BDF file %s doesn't exist" bdfname))
 225     (unwind-protect
 226         (save-excursion
 227           (set-buffer buf)
 228           (goto-char (point-min))
 229           (search-forward "\nFONTBOUNDINGBOX")
 230           (setq font-bounding-box
 231                 (vector (read (current-buffer)) (read (current-buffer))
 232                         (read (current-buffer)) (read (current-buffer))))
 233           ;; The following kludgy code is to avoid bugs of fonts
 234           ;; jiskan16.bdf and jiskan24.bdf distributed with X.
 235           ;; They contain wrong FONTBOUNDINGBOX.
 236           (and (> (aref font-bounding-box 3) 0)
 237                (string-match "jiskan\\(16\\|24\\)" bdfname)
 238                (aset font-bounding-box 3
 239                      (- (aref font-bounding-box 3))))
 240
 241           (goto-char (point-min))
 242           (search-forward "\nFONT ")
 243           (if (looking-at "-[^-]*-[^-]*-[^-]*-[^-]*-[^-]*-[^-]*-\\([0-9]+\\)")
 244               (setq size (string-to-int (match-string 1)))
 245             (search-forward "\nSIZE ")
 246             (setq size (read (current-buffer)))
 247             ;; The following kludgy code is t avoid bugs of several
 248             ;; fonts which have wrong SIZE record.
 249             (and (string-match "jiskan" bdfname)
 250                  (<= size (/ (aref font-bounding-box 1) 3))
 251                  (setq size (aref font-bounding-box 1)))
 252             (setq dpi (read (current-buffer)))
 253             (if (and (> dpi 0) (/= dpi 72))
 254                 (setq size (/ (* size dpi) 72))))
 255
 256           (setq default-char (bdf-search-and-read "\nDEFAULT_CHAR" nil))
 257
 258           (search-forward "\nSTARTCHAR")
 259           (forward-line -1)
 260           (let ((limit (point)))
 261             (setq relative-compose
 262                   (or (bdf-search-and-read "\n_MULE_RELATIVE_COMPOSE" limit)
 263                       'false)
 264                   baseline-offset
 265                   (or (bdf-search-and-read "\n_MULE_BASELINE_OFFSET" limit)
 266                       0)))
 267
 268           (let ((min-code0 256) (min-code1 256) (min-code 65536)
 269                 (max-code0 0) (max-code1 0) (max-code 0)
 270                 glyph glyph-list code0 code1 code offset)
 271
 272             (while (search-forward "\nSTARTCHAR" nil t)
 273               (setq offset (line-beginning-position))
 274               (search-forward "\nENCODING")
 275               (setq code (read (current-buffer)))
 276               (if (< code 0)
 277                   (search-forward "ENDCHAR")
 278                 (setq code0 (lsh code -8)
 279                       code1 (logand code 255)
 280                       min-code (min min-code code)
 281                       max-code (max max-code code)
 282                       min-code0 (min min-code0 code0)
 283                       max-code0 (max max-code0 code0)
 284                       min-code1 (min min-code1 code1)
 285                       max-code1 (max max-code1 code1))
 286                 (search-forward "ENDCHAR")
 287                 (setq maxlen (max maxlen (- (point) offset))
 288                       glyph-list (cons (cons code offset) glyph-list))))
 289
 290             (setq code-range
 291                   (vector min-code0 max-code0 min-code1 max-code1
 292                           min-code max-code (or default-char min-code))
 293                   offset-vector
 294                   (make-vector (1+ (bdf-compact-code max-code code-range))
 295                                nil))
 296
 297             (while glyph-list
 298               (setq glyph (car glyph-list)
 299                     glyph-list (cdr glyph-list))
 300               (aset offset-vector
 301                     (bdf-compact-code (car glyph) code-range)
 302                     (cdr glyph)))))
 303
 304     (kill-buffer buf))
 305   (message "Reading %s...done" bdfname)
 306   (list bdfname (bdf-file-mod-time bdfname)
 307         size font-bounding-box relative-compose baseline-offset
 308         code-range maxlen offset-vector)))
 309
 310 (defsubst bdf-info-absolute-path (font-info)     (nth 0 font-info))
 311 (defsubst bdf-info-mod-time (font-info)          (nth 1 font-info))
 312 (defsubst bdf-info-size (font-info)              (nth 2 font-info))
 313 (defsubst bdf-info-font-bounding-box (font-info) (nth 3 font-info))
 314 (defsubst bdf-info-relative-compose (font-info)  (nth 4 font-info))
 315 (defsubst bdf-info-baseline-offset (font-info)   (nth 5 font-info))
 316 (defsubst bdf-info-code-range (font-info)        (nth 6 font-info))
 317 (defsubst bdf-info-maxlen (font-info)            (nth 7 font-info))
 318 (defsubst bdf-info-offset-vector (font-info)     (nth 8 font-info))
 319
 320 (defun bdf-get-font-info (bdfname)
 321   "Return information about `BDF' font file BDFNAME.
 322 BDFNAME must be an absolute file name.
 323 The value FONT-INFO is a list of the following format:
 324     (BDFNAME MOD-TIME SIZE FONT-BOUNDING-BOX
 325      RELATIVE-COMPOSE BASELINE-OFFSET CODE-RANGE MAXLEN OFFSET-VECTOR)
 326 See the documentation of the function `bdf-read-font-info' for more detail."
 327   (or bdf-cache
 328       (bdf-read-cache))
 329   (let ((font-info (assoc bdfname bdf-cache)))
 330     (if (or (not font-info)
 331             (not (file-readable-p bdfname))
 332             (bdf-file-newer-than-time bdfname (bdf-info-mod-time font-info)))
 333         (progn
 334           (setq font-info (bdf-read-font-info bdfname))
 335           (bdf-set-cache font-info)))
 336     font-info))
 337
 338 (defun bdf-read-bitmap (bdfname offset maxlen relative-compose)
 339   "Read `BDF' font file BDFNAME to get bitmap data at file position OFFSET.
 340 BDFNAME is an absolute path name of the font file.
 341 MAXLEN specifies how many bytes we should read at least.
 342 The value is a list of DWIDTH, BBX, and BITMAP-STRING.
 343 DWIDTH is a pixel width of a glyph.
 344 BBX is a bounding box of the glyph.
 345 BITMAP-STRING is a string representing bits by hexadecimal digits."
 346   (let* ((coding-system-for-read 'no-conversion)
 347          (bbx (bdf-info-font-bounding-box (bdf-get-font-info bdfname)))
 348          (dwidth (elt bbx 0))
 349          (bitmap-string "")
 350          height yoff)
 351     (condition-case nil
 352         (with-temp-buffer
 353           (insert-file-contents bdfname nil offset (+ offset maxlen))
 354           (goto-char (point-min))
 355           (search-forward "\nDWIDTH")
 356           (setq dwidth (read (current-buffer)))
 357           (if (= dwidth 0)
 358               (setq dwidth 0.1))
 359           (goto-char (point-min))
 360           (search-forward "\nBBX")
 361           (setq bbx (vector (read (current-buffer)) (read (current-buffer))
 362                             (read (current-buffer)) (read (current-buffer)))
 363                 height (aref bbx 1)
 364                 yoff (aref bbx 3))
 365           (search-forward "\nBITMAP")
 366           (forward-line 1)
 367           (delete-region (point-min) (point))
 368           (and (looking-at "\\(0+\n\\)+")
 369                (progn
 370                  (setq height (- height (count-lines (point) (match-end 0))))
 371                  (delete-region (point) (match-end 0))))
 372           (or (looking-at "ENDCHAR")
 373               (progn
 374                 (search-forward "ENDCHAR" nil 'move)
 375                 (forward-line -1)
 376                 (while (looking-at "0+$")
 377                   (setq yoff (1+ yoff)
 378                         height (1- height))
 379                   (forward-line -1))
 380                 (forward-line 1)))
 381           (aset bbx 1 height)
 382           (aset bbx 3 yoff)
 383           (delete-region (point) (point-max))
 384           (goto-char (point-min))
 385           (while (not (eobp))
 386             (end-of-line)
 387             (delete-char 1))
 388           (setq bitmap-string (buffer-string)))
 389       (error nil))
 390     (vector dwidth (aref bbx 0) (aref bbx 1) (aref bbx 2) (aref bbx 3)
 391             (concat "<" bitmap-string ">")
 392             (or relative-compose 'false))))
 393
 394 (defun bdf-get-bitmap (bdfname code)
 395   "Return bitmap information of glyph of CODE in `BDF' font file BDFNAME.
 396 CODE is an encoding number of glyph in the file.
 397 The value is a list (DWIDTH BBX BITMAP-STRING).
 398 DWIDTH is a pixel width of a glyph.
 399 BBX is a bounding box of the glyph.
 400 BITMAP-STRING is a string representing bits by hexadecimal digits."
 401   (let* ((info (bdf-get-font-info bdfname))
 402          (maxlen (bdf-info-maxlen info))
 403          (code-range (bdf-info-code-range info))
 404          (offset-vector (bdf-info-offset-vector info)))
 405     (bdf-read-bitmap bdfname
 406                      (aref offset-vector (bdf-compact-code code code-range))
 407                      maxlen (bdf-info-relative-compose info))))
 408
 409 ;;; Interface to ps-mule.el
 410
 411 ;; Called from ps-mule-init-external-library.
 412 (defun bdf-generate-prologue ()
 413   (or bdf-cache
 414       (bdf-initialize))
 415   (ps-mule-generate-bitmap-prologue))
 416
 417 ;; Called from ps-mule-check-font.
 418 (defun bdf-check-font (font-spec)
 419   (let ((font-name-list (ps-mule-font-spec-name font-spec)))
 420     (ps-mule-font-spec-set-name
 421      font-spec
 422      (if (stringp font-name-list)
 423          (bdf-expand-file-name font-name-list)
 424        (catch 'tag
 425          (dolist (font-name font-name-list)
 426            (setq font-name (bdf-expand-file-name font-name))
 427            (if font-name
 428                (throw 'tag font-name))))))))
 429
 430 ;; Called from ps-mule-generate-font.
 431 (defun bdf-generate-font (font-spec)
 432   (let ((info (bdf-get-font-info (ps-mule-font-spec-name font-spec))))
 433     (ps-mule-font-spec-set-extra
 434      font-spec (bdf-info-absolute-path info))
 435     (ps-mule-generate-bitmap-font font-spec
 436                                   (bdf-info-size info)
 437                                   (bdf-info-relative-compose info)
 438                                   (bdf-info-baseline-offset info)
 439                                   (bdf-info-font-bounding-box info))))
 440
 441 ;; Called from ps-mule-generate-glyph.
 442 (defun bdf-generate-glyph (font-spec char)
 443   (let ((font-name (ps-mule-font-spec-extra font-spec))
 444         (code (ps-mule-encode-char char font-spec)))
 445     (ps-mule-generate-bitmap-glyph font-spec char code
 446                                    (bdf-get-bitmap font-name code))))
 447
 448 (provide 'ps-bdf)
 449
 450 ;;; arch-tag: 9b875ba8-565a-4ecf-acaa-30cee732c898
 451 ;;; ps-bdf.el ends here