configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation; either version 3, or (at your option)
  14 dnl  any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  23 dnl  Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 dnl  Boston, MA 02110-1301, USA.
  25
  26 AC_PREREQ(2.61)dnl
  27 AC_INIT(emacs, 23.0.60)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 lispdir='${datadir}/emacs/${version}/lisp'
  36 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  37 '${datadir}/emacs/site-lisp'
  38 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  39 etcdir='${datadir}/emacs/${version}/etc'
  40 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  41 docdir='${datadir}/emacs/${version}/etc'
  42 gamedir='${localstatedir}/games/emacs'
  43
  44 gameuser=games
  45
  46 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  47 dnl Create a new --with option that defaults to being disabled.
  48 dnl NAME is the base name of the option.  The shell variable with_NAME
  49 dnl   will be set to either the user's value (if the option is
  50 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  51 dnl   option is not specified).  Note that the shell variable name is
  52 dnl   constructed as autoconf does, by replacing non-alphanumeric
  53 dnl   characters with "_".
  54 dnl HELP-STRING is the help text for the option.
  55 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  56   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  57     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  58 ])dnl
  59
  60 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  61 dnl Create a new --with option that defaults to being enabled.  NAME
  62 dnl   is the base name of the option.  The shell variable with_NAME
  63 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  64 dnl   'yes' (if the option is not specified).  Note that the shell
  65 dnl   variable name is constructed as autoconf does, by replacing
  66 dnl   non-alphanumeric characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  70    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  71 ])dnl
  72
  73 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  74 if test "$with_pop" = yes; then
  75    AC_DEFINE(MAIL_USE_POP)
  76 fi
  77 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  78
  79 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  80 if test "$with_kerberos" = yes; then
  81    AC_DEFINE(KERBEROS)
  82 fi
  83 AH_TEMPLATE(KERBEROS,
  84             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  85
  86 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  87 if test "${with_kerberos5}" = yes; then
  88   if test "${with_kerberos}" != yes; then
  89     with_kerberos=yes
  90     AC_DEFINE(KERBEROS)
  91   fi
  92   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  93 fi
  94
  95 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  96 if test "$with_hesiod" = yes; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 101
 102 dnl FIXME currently it is not the last.
 103 dnl This should be the last --with option, because --with-x is
 104 dnl added later on when we find the path of X, and it's best to
 105 dnl keep them together visually.
 106 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 107  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 108 [         case "${withval}" in
 109             y | ye | yes )      val=gtk ;;
 110             n | no )            val=no  ;;
 111             l | lu | luc | luci | lucid )       val=lucid ;;
 112             a | at | ath | athe | athen | athena )      val=athena ;;
 113             m | mo | mot | moti | motif )       val=motif ;;
 114             g | gt | gtk  )     val=gtk ;;
 115             * )
 116 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 117 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 118 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 119             ;;
 120           esac
 121           with_x_toolkit=$val
 122 ])
 123
 124 dnl _ON results in a '--without' option in the --help output, so
 125 dnl the help text should refer to "don't compile", etc.
 126 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 127 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 128 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 129 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 130 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 131 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 132
 133 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 134 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 135 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 136 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 137
 138 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 139 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 140 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 141 OPTION_DEFAULT_OFF([carbon],[use Carbon GUI on Mac OS X.  This is unsupported!])
 142
 143 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 144 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 145
 146 dnl Can remove these in Emacs 24.
 147 AC_ARG_WITH([gtk],,
 148   AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 149 specify a toolkit.]),,)
 150
 151 AC_ARG_WITH([gcc],,
 152   AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 153   variable to specify a compiler.]),,)
 154
 155 AC_ARG_WITH([pkg-config-prog],dnl
 156 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 157                   [Path to pkg-config for finding GTK and librsvg])])
 158 if test "X${with_pkg_config_prog}" != X; then
 159    if test "${with_pkg_config_prog}" != yes; then
 160       PKG_CONFIG="${with_pkg_config_prog}"
 161    fi
 162 fi
 163
 164 AC_ARG_ENABLE(carbon-app,
 165 [AS_HELP_STRING([--enable-carbon-app@<:@=DIR@:>@],
 166                 [specify install directory for Emacs.app on Mac OS X
 167                  [DIR=/Application]])],
 168 [ carbon_appdir_x=${enableval}])
 169
 170 ## Enabled by default.
 171 AC_ARG_ENABLE(font-backend,
 172 [AS_HELP_STRING([--disable-font-backend],[don't compile font-backend support])],
 173       USE_FONT_BACKEND=$enableval,
 174       USE_FONT_BACKEND=yes)
 175
 176 ## Enabled by default.
 177 AC_ARG_ENABLE(sync-input,
 178 [AS_HELP_STRING([--disable-sync-input], [don't compile code with sync-input])],
 179       USE_SYNC_INPUT=$enableval,
 180       USE_SYNC_INPUT=yes)
 181
 182 AC_ARG_ENABLE(asserts,
 183 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 184       USE_XASSERTS=$enableval,
 185       USE_XASSERTS=no)
 186
 187 AC_ARG_ENABLE(maintainer-mode,
 188 [AS_HELP_STRING([--enable-maintainer-mode],
 189                 [enable make rules and dependencies not useful (and sometimes
 190                  confusing) to the casual installer])],
 191       USE_MAINTAINER_MODE=$enableval,
 192       USE_MAINTAINER_MODE=no)
 193 if test $USE_MAINTAINER_MODE = yes; then
 194   MAINT=
 195 else
 196   MAINT=#
 197 fi
 198 AC_SUBST(MAINT)
 199
 200 AC_ARG_ENABLE(locallisppath,
 201 [AS_HELP_STRING([--enable-locallisppath=PATH],
 202                 [directories Emacs should search for lisp files specific
 203                  to this site])],
 204 if test "${enableval}" = "no"; then
 205   locallisppath=
 206 elif test "${enableval}" != "yes"; then
 207   locallisppath=${enableval}
 208 fi)
 209
 210 #### Make srcdir absolute, if it isn't already.  It's important to
 211 #### avoid running the path through pwd unnecessarily, since pwd can
 212 #### give you automounter prefixes, which can go away.  We do all this
 213 #### so Emacs can find its files when run uninstalled.
 214 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 215 unset CDPATH
 216 case "${srcdir}" in
 217   /* ) ;;
 218   . )
 219     ## We may be able to use the $PWD environment variable to make this
 220     ## absolute.  But sometimes PWD is inaccurate.
 221     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 222     ## but that tested only for a well-formed and valid PWD,
 223     ## it did not object when PWD was well-formed and valid but just wrong.
 224     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 225     then
 226       srcdir="$PWD"
 227     else
 228       srcdir="`(cd ${srcdir}; pwd)`"
 229     fi
 230   ;;
 231   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 232 esac
 233
 234 #### Check if the source directory already has a configured system in it.
 235 if test `pwd` != `(cd ${srcdir} && pwd)` \
 236    && test -f "${srcdir}/src/config.h" ; then
 237   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 238    as a build directory right now; it has been configured in its own
 239    right.  To configure in another directory as well, you MUST
 240    use GNU make.  If you do not have GNU make, then you must
 241    now do `make distclean' in ${srcdir},
 242    and then run $0 again.]])
 243 fi
 244
 245 #### Given the configuration name, set machfile and opsysfile to the
 246 #### names of the m/*.h and s/*.h files we should use.
 247
 248 ### Canonicalize the configuration name.
 249
 250 AC_CANONICAL_HOST
 251 canonical=$host
 252 configuration=${host_alias-${build_alias-$host}}
 253
 254 dnl This used to use changequote, but, apart from `changequote is evil'
 255 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 256 dnl the great gob of text.  Thus it's not processed for possible expansion.
 257 dnl Just make sure the brackets remain balanced.
 258 dnl
 259 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 260 dnl indicated by comments.
 261 dnl quotation begins
 262 [
 263
 264 ### If you add support for a new configuration, add code to this
 265 ### switch statement to recognize your configuration name and select
 266 ### the appropriate operating system and machine description files.
 267
 268 ### You would hope that you could choose an m/*.h file pretty much
 269 ### based on the machine portion of the configuration name, and an s-
 270 ### file based on the operating system portion.  However, it turns out
 271 ### that each m/*.h file is pretty manufacturer-specific - for
 272 ### example hp9000s300.h is a 68000 machine;
 273 ### mips.h, pmax.h are all MIPS
 274 ### machines.  So we basically have to have a special case for each
 275 ### configuration name.
 276 ###
 277 ### As far as handling version numbers on operating systems is
 278 ### concerned, make sure things will fail in a fixable way.  If
 279 ### /etc/MACHINES doesn't say anything about version numbers, be
 280 ### prepared to handle anything reasonably.  If version numbers
 281 ### matter, be sure /etc/MACHINES says something about it.
 282 ###
 283 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 284 ### "System V Release 4"; he writes, "The old convention encouraged
 285 ### confusion between `system' and `release' levels'."
 286
 287 machine='' opsys='' unported=no
 288 case "${canonical}" in
 289
 290   ## FreeBSD ports
 291   *-*-freebsd* )
 292     opsys=freebsd
 293     case "${canonical}" in
 294       alpha*-*-freebsd*)        machine=alpha ;;
 295       arm*-*-freebsd*)          machine=arm ;;
 296       ia64-*-freebsd*)          machine=ia64 ;;
 297       sparc64-*-freebsd*)       machine=sparc ;;
 298       powerpc-*-freebsd*)       machine=macppc ;;
 299       i[3456]86-*-freebsd*)     machine=intel386 ;;
 300       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 301     esac
 302   ;;
 303
 304   ## FreeBSD kernel + glibc based userland
 305   *-*-kfreebsd*gnu* )
 306     opsys=gnu-kfreebsd
 307     case "${canonical}" in
 308       alpha*-*-kfreebsd*)       machine=alpha ;;
 309       ia64-*-kfreebsd*)         machine=ia64 ;;
 310       sparc64-*-kfreebsd*)      machine=sparc ;;
 311       powerpc-*-kfreebsd*)      machine=macppc ;;
 312       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 313       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 314     esac
 315   ;;
 316
 317   ## NetBSD ports
 318   *-*-netbsd* )
 319     opsys=netbsd
 320     if test -f /usr/lib/crti.o; then]
 321 dnl The close and open brackets here are because this section is quoted --
 322 dnl see the `changequote' comment above.
 323       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 324 [   fi
 325
 326     case "${canonical}" in
 327       alpha*-*-netbsd*) machine=alpha ;;
 328       i[3456]86-*-netbsd*) machine=intel386 ;;
 329       m68k-*-netbsd*)
 330                         # This is somewhat bogus.
 331                         machine=hp9000s300 ;;
 332       mips-*-netbsd*)   machine=pmax ;;
 333       mipsel-*-netbsd*) machine=pmax ;;
 334       mipseb-*-netbsd*) machine=pmax ;;
 335       powerpc-*-netbsd*) machine=macppc ;;
 336       sparc*-*-netbsd*) machine=sparc ;;
 337       vax-*-netbsd*)    machine=vax ;;
 338       arm-*-netbsd*)    machine=arm ;;
 339       x86_64-*-netbsd*) machine=amdx86-64 ;;
 340       hppa-*-netbsd*)   machine=hp800 ;;
 341     esac
 342   ;;
 343
 344   ## OpenBSD ports
 345   *-*-openbsd* )
 346     opsys=openbsd
 347     case "${canonical}" in
 348       alpha*-*-openbsd*)        machine=alpha ;;
 349       arm-*-openbsd*)          machine=arm ;;
 350       hppa-*-openbsd*)         machine=hp9000s300 ;;
 351       i386-*-openbsd*)         machine=intel386 ;;
 352       m68k-*-openbsd*)         machine=hp9000s300 ;;
 353       powerpc-*-openbsd*)      machine=macppc ;;
 354       sparc*-*-openbsd*)       machine=sparc ;;
 355       vax-*-openbsd*)          machine=vax ;;
 356       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 357     esac
 358   ;;
 359
 360   ## LynxOS ports
 361   *-*-lynxos* )
 362     opsys=lynxos
 363     case "${canonical}" in
 364       i[3456]86-*-lynxos*) machine=intel386 ;;
 365       powerpc-*-lynxos*) machine=powerpc ;;
 366     esac
 367   ;;
 368
 369   ## BSDI ports
 370   *-*-bsdi* )
 371     opsys=bsdi
 372     case "${canonical}" in
 373       i[345]86-*-bsdi*) machine=intel386 ;;
 374       sparc-*-bsdi*)  machine=sparc ;;
 375       powerpc-*-bsdi*)  machine=macppc ;;
 376     esac
 377     case "${canonical}" in
 378       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 379       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 380       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 381       *-*-bsdi3* )              opsys=bsdos3 ;;
 382       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 383     esac
 384   ;;
 385
 386   alpha*-*-linux-gnu* )
 387     machine=alpha opsys=gnu-linux
 388   ;;
 389
 390   arm*-*-linux-gnu* )
 391     machine=arm opsys=gnu-linux
 392   ;;
 393
 394   ## Apple Darwin / Mac OS X
 395   *-apple-darwin* )
 396     case "${canonical}" in
 397       i[3456]86-* )  machine=intel386 ;;
 398       powerpc-* )    machine=powermac ;;
 399       * )            unported=yes ;;
 400     esac
 401     opsys=darwin
 402     # Define CPP as follows to make autoconf work correctly.
 403     CPP="${CC-cc} -E -no-cpp-precomp"
 404     # Use fink packages if available.
 405     if test -d /sw/include && test -d /sw/lib; then
 406       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 407       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 408       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 409     fi
 410   ;;
 411
 412   ## Cubix QBx/386
 413   i[3456]86-cubix-sysv* )
 414     machine=intel386 opsys=usg5-3
 415   ;;
 416
 417   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 418     machine=pmax opsys=bsd4-2
 419   ;;
 420   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 421     machine=pmax opsys=bsd4-3
 422   ;;
 423   mips-dec-ultrix* )
 424     machine=pmax opsys=ultrix4-3
 425   ;;
 426   ## HP 9000 series 200 or 300
 427   m68*-hp-bsd* )
 428     machine=hp9000s300 opsys=bsd4-3
 429   ;;
 430   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 431   m68*-hp-hpux* )
 432     case "`uname -r`" in
 433       ## Someone's system reports A.B8.05 for this.
 434       ## I wonder what other possibilities there are.
 435       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 436       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 437       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 438       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 439       *) machine=hp9000s300 opsys=hpux ;;
 440     esac
 441   ;;
 442
 443   ## HP 9000 series 700 and 800, running HP/UX
 444   hppa*-hp-hpux7* )
 445     machine=hp800 opsys=hpux
 446   ;;
 447   hppa*-hp-hpux8* )
 448     machine=hp800 opsys=hpux8
 449   ;;
 450   hppa*-hp-hpux9shr* )
 451     machine=hp800 opsys=hpux9shr
 452   ;;
 453   hppa*-hp-hpux9* )
 454     machine=hp800 opsys=hpux9
 455   ;;
 456   hppa*-hp-hpux10.2* )
 457     machine=hp800 opsys=hpux10-20
 458   ;;
 459   hppa*-hp-hpux10* )
 460     machine=hp800 opsys=hpux10
 461   ;;
 462   hppa*-hp-hpux1[1-9]* )
 463     machine=hp800 opsys=hpux11
 464     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 465   ;;
 466
 467   hppa*-*-linux-gnu* )
 468     machine=hp800 opsys=gnu-linux
 469   ;;
 470
 471   ## HP 9000 series 700 and 800, running HP/UX
 472   hppa*-hp-hpux* )
 473     ## Cross-compilation?  Nah!
 474     case "`uname -r`" in
 475       ## Someone's system reports A.B8.05 for this.
 476       ## I wonder what other possibilities there are.
 477       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 478       *.08.* ) machine=hp800 opsys=hpux8 ;;
 479       *.09.* ) machine=hp800 opsys=hpux9 ;;
 480       *) machine=hp800 opsys=hpux10 ;;
 481     esac
 482   ;;
 483   hppa*-*-nextstep* )
 484     machine=hp800 opsys=nextstep
 485   ;;
 486
 487   ## IBM machines
 488   i370-ibm-aix*)
 489     machine=ibm370aix opsys=usg5-3
 490   ;;
 491   s390-*-linux-gnu* )
 492     machine=ibms390 opsys=gnu-linux
 493   ;;
 494   s390x-*-linux-gnu* )
 495     machine=ibms390x opsys=gnu-linux
 496   ;;
 497   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 498     machine=ibmrs6000 opsys=aix3-1
 499   ;;
 500   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 501     machine=ibmrs6000 opsys=aix3-2-5
 502   ;;
 503   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 504     machine=ibmrs6000 opsys=aix4-1
 505   ;;
 506   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 507     machine=ibmrs6000 opsys=aix4-2
 508   ;;
 509   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 510     machine=ibmrs6000 opsys=aix4-2
 511   ;;
 512   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 513     machine=ibmrs6000 opsys=aix4-2
 514   ;;
 515   rs6000-ibm-aix5* | powerpc-ibm-aix6*  )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 519     machine=ibmrs6000 opsys=aix4
 520   ;;
 521   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 522     machine=ibmrs6000 opsys=aix4-1
 523   ;;
 524   rs6000-ibm-aix* | powerpc-ibm-aix* )
 525     machine=ibmrs6000 opsys=aix3-2
 526   ;;
 527
 528   ## Prime EXL
 529   i[3456]86-prime-sysv* )
 530     machine=i386 opsys=usg5-3
 531   ;;
 532
 533   ## ncr machine running svr4.3.
 534   i[3456]86-ncr-sysv4.3 )
 535     machine=ncr386 opsys=usg5-4-3
 536   ;;
 537
 538   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 539   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 540   i[3456]86-ncr-sysv* )
 541     machine=ncr386 opsys=usg5-4-2
 542   ;;
 543
 544   ## Macintosh PowerPC
 545   powerpc*-*-linux-gnu* )
 546     machine=macppc opsys=gnu-linux
 547   ;;
 548
 549   ## Workstations sold by MIPS
 550   ## This is not necessarily all workstations using the MIPS processor -
 551   ## Irises are produced by SGI, and DECstations by DEC.
 552
 553   mips-mips-bsd* )
 554     machine=mips opsys=bsd4-3
 555   ;;
 556   mips-mips-* )
 557     machine=mips opsys=usg5-2-2
 558   ;;
 559
 560   ## NeXT
 561   m68*-next-* | m68k-*-nextstep* )
 562     machine=m68k opsys=nextstep
 563   ;;
 564
 565   ## NEC EWS4800
 566   mips-nec-sysv4*)
 567   machine=ews4800 opsys=ux4800
 568   ;;
 569
 570   ## Siemens Nixdorf
 571   mips-siemens-sysv* | mips-sni-sysv*)
 572     machine=mips-siemens opsys=usg5-4
 573     NON_GNU_CC=/usr/ccs/bin/cc
 574     NON_GNU_CPP=/usr/ccs/lib/cpp
 575   ;;
 576
 577   ## Silicon Graphics machines
 578   ## Iris 4D
 579   mips-sgi-irix6.5 )
 580     machine=iris4d opsys=irix6-5
 581     # Without defining _LANGUAGE_C, things get masked out in the headers
 582     # so that, for instance, grepping for `free' in stdlib.h fails and
 583     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 584     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 585     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 586   ;;
 587
 588   ## Suns
 589   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 590     machine=sparc opsys=gnu-linux
 591   ;;
 592
 593   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 594     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 595     | rs6000-*-solaris2*)
 596     case "${canonical}" in
 597       i[3456]86-*-* )     machine=intel386 ;;
 598       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 599       powerpcle* )      machine=powerpcle ;;
 600       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 601       sparc* )          machine=sparc ;;
 602       * )               unported=yes ;;
 603     esac
 604     case "${canonical}" in
 605       *-sunos5.3* | *-solaris2.3* )
 606                 opsys=sol2-3
 607                 NON_GNU_CPP=/usr/ccs/lib/cpp
 608                 ;;
 609       *-sunos5.4* | *-solaris2.4* )
 610                 opsys=sol2-4
 611                 NON_GNU_CPP=/usr/ccs/lib/cpp
 612                 RANLIB="ar -ts"
 613                 ;;
 614       *-sunos5.5* | *-solaris2.5* )
 615                 opsys=sol2-5
 616                 NON_GNU_CPP=/usr/ccs/lib/cpp
 617                 RANLIB="ar -ts"
 618                 ;;
 619       *-sunos5.6* | *-solaris2.6* )
 620                 opsys=sol2-6
 621                 NON_GNU_CPP=/usr/ccs/lib/cpp
 622                 RANLIB="ar -ts"
 623                 ;;
 624       *-sunos5* | *-solaris* )
 625                 opsys=sol2-6
 626                 emacs_check_sunpro_c=yes
 627                 NON_GNU_CPP=/usr/ccs/lib/cpp
 628                 ;;
 629       *                   ) opsys=bsd4-2   ;;
 630     esac
 631     ## Watch out for a compiler that we know will not work.
 632     case "${canonical}" in
 633      *-solaris* | *-sunos5* )
 634                 if [ "x$CC" = x/usr/ucb/cc ]; then
 635                   ## /usr/ucb/cc doesn't work;
 636                   ## we should find some other compiler that does work.
 637                   unset CC
 638                 fi
 639                 ;;
 640       *) ;;
 641     esac
 642   ;;
 643   sparc-*-nextstep* )
 644     machine=sparc opsys=nextstep
 645   ;;
 646
 647   ## Tandem Integrity S2
 648   mips-tandem-sysv* )
 649     machine=tandem-s2 opsys=usg5-3
 650   ;;
 651
 652   ## Vaxen.
 653   vax-dec-* )
 654     machine=vax
 655     case "${canonical}" in
 656       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 657       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 658       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 659       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 660       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 661       *-vms* )                                          opsys=vms ;;
 662       * )                                               unported=yes
 663     esac
 664   ;;
 665
 666   ## IA-64
 667   ia64*-*-linux* )
 668     machine=ia64 opsys=gnu-linux
 669   ;;
 670
 671   ## Intel 386 machines where we don't care about the manufacturer
 672   i[3456]86-*-* )
 673     machine=intel386
 674     case "${canonical}" in
 675       *-cygwin )                opsys=cygwin ;;
 676       *-darwin* )               opsys=darwin
 677                                 CPP="${CC-cc} -E -no-cpp-precomp"
 678                                 ;;
 679       *-linux-gnu* )            opsys=gnu-linux ;;
 680       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 681       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 682       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 683       *-386bsd* )               opsys=386bsd ;;
 684       *-nextstep* )             opsys=nextstep ;;
 685       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 686     esac
 687   ;;
 688
 689   ## m68k Linux-based GNU system
 690   m68k-*-linux-gnu* )
 691     machine=m68k opsys=gnu-linux
 692   ;;
 693
 694   ## Mips Linux-based GNU system
 695   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 696     machine=mips opsys=gnu-linux
 697   ;;
 698
 699   ## UXP/DS
 700   sparc-fujitsu-sysv4* )
 701     machine=sparc opsys=uxpds
 702     NON_GNU_CPP=/usr/ccs/lib/cpp
 703     RANLIB="ar -ts"
 704   ;;
 705
 706   ## AMD x86-64 Linux-based GNU system
 707   x86_64-*-linux-gnu* )
 708     machine=amdx86-64 opsys=gnu-linux
 709   ;;
 710
 711   ## Tensilica Xtensa Linux-based GNU system
 712   xtensa*-*-linux-gnu* )
 713     machine=xtensa opsys=gnu-linux
 714     ;;
 715
 716   * )
 717     unported=yes
 718   ;;
 719 esac
 720
 721 ### If the code above didn't choose an operating system, just choose
 722 ### an operating system based on the configuration name.  You really
 723 ### only want to use this when you have no idea what the right
 724 ### operating system is; if you know what operating systems a machine
 725 ### runs, it's cleaner to make it explicit in the case statement
 726 ### above.
 727 if test x"${opsys}" = x; then
 728   case "${canonical}" in
 729     *-gnu* )                            opsys=gnu ;;
 730     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 731     *-bsd4.2 )                          opsys=bsd4-2 ;;
 732     *-bsd4.3 )                          opsys=bsd4-3 ;;
 733     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 734     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 735     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 736     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 737     *-sysv4.2uw* )                      opsys=unixware ;;
 738     *-sysv5uw* )                        opsys=unixware ;;
 739     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 740     *-sysv4.1* | *-sysvr4.1* )
 741         NON_GNU_CPP=/usr/lib/cpp
 742         opsys=usg5-4 ;;
 743     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 744         if [ x$NON_GNU_CPP = x ]; then
 745           if [ -f /usr/ccs/lib/cpp ]; then
 746             NON_GNU_CPP=/usr/ccs/lib/cpp
 747           else
 748             NON_GNU_CPP=/lib/cpp
 749           fi
 750         fi
 751         opsys=usg5-4-2 ;;
 752     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 753     * )
 754       unported=yes
 755     ;;
 756   esac
 757 fi
 758
 759 ### Tests for sytems that we beleive are obsolete and should be desupported.
 760
 761 case "${machine}" in
 762      pmax | hp9000s300 | ibm370aix | ncr386 | ews4800 | mips-siemens | powerpcle | tandem-s2 )
 763           echo "The system that you are configuring on: ${canonical} is considered to be obsolete"
 764           echo "and it is planned to be desupported in the next version of Emacs"
 765           echo "Please email emacs-devel@gnu.org as soon as possible if this system is still in use."
 766           echo "The code is still functional, but you need to edit the 'configure' script and remove the"
 767           echo "exit 33 line.  After that you can run configure again and 'complete' the build."
 768           exit 33
 769           ;;
 770 esac
 771
 772 case "${opsys}" in
 773      bsd386 | bsdos2-1 |  bsdos2 | bsdos3 | bsdos4 | bsd4-1 | bsd4-2 | bsd4-3 | usg5-0 | usg5-2-2 | usg5-2 | usg5-3 | ultrix4-3 | 386bsd | hpux | hpux8 | hpux9 | hpux9shr | hpux10 | hpux10-20 | aix3-1 | aix3-2-5 | aix3-2 | aix4-1 | nextstep | ux4800 | uxpds | uxpv )
 774           echo "The system that you are configuring on: ${canonical} is considered to be obsolete"
 775           echo "and it is planned to be desupported in the next version of Emacs"
 776           echo "Please email emacs-devel@gnu.org as soon as possible if this system is still in use."
 777           echo "The code is still functional, but you need to edit the 'configure' script and remove the"
 778           echo "'exit 44' line.  After that you can run 'configure' again and complete the build."
 779           exit 44
 780           ;;
 781 esac
 782
 783 ]
 784 dnl quotation ends
 785
 786 if test $unported = yes; then
 787   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 788 Check `etc/MACHINES' for recognized configuration names.])
 789 fi
 790
 791 machfile="m/${machine}.h"
 792 opsysfile="s/${opsys}.h"
 793
 794
 795 #### Choose a compiler.
 796 test -n "$CC" && cc_specified=yes
 797
 798 # Save the value of CFLAGS that the user specified.
 799 SPECIFIED_CFLAGS="$CFLAGS"
 800
 801 dnl Sets GCC=yes if using gcc.
 802 AC_PROG_CC
 803
 804 # On Suns, sometimes $CPP names a directory.
 805 if test -n "$CPP" && test -d "$CPP"; then
 806   CPP=
 807 fi
 808
 809 ## If not using gcc, and on Solaris, and no CPP specified, see if
 810 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 811 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 812  test x"$CPP" = x; then
 813   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 814   AC_CACHE_VAL(emacs_cv_sunpro_c,
 815   [AC_TRY_LINK([],
 816 [#ifndef __SUNPRO_C
 817 fail;
 818 #endif
 819 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 820   AC_MSG_RESULT($emacs_cv_sunpro_c)
 821
 822   if test x"$emacs_cv_sunpro_c" = xyes; then
 823     NON_GNU_CPP="$CC -E -Xs"
 824   fi
 825 fi
 826
 827 #### Some systems specify a CPP to use unless we are using GCC.
 828 #### Now that we know whether we are using GCC, we can decide whether
 829 #### to use that one.
 830 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 831 then
 832   CPP="$NON_GNU_CPP"
 833 fi
 834
 835 #### Some systems specify a CC to use unless we are using GCC.
 836 #### Now that we know whether we are using GCC, we can decide whether
 837 #### to use that one.
 838 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 839   test x$cc_specified != xyes
 840 then
 841   CC="$NON_GNU_CC"
 842 fi
 843
 844 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 845 then
 846   CC="$CC $GCC_TEST_OPTIONS"
 847 fi
 848
 849 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 850 then
 851   CC="$CC $NON_GCC_TEST_OPTIONS"
 852 fi
 853
 854 dnl checks for Unix variants
 855 AC_AIX
 856 AC_GNU_SOURCE
 857
 858 ### Use -Wno-pointer-sign if the compiler supports it
 859 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 860 SAVE_CFLAGS="$CFLAGS"
 861 CFLAGS="$CFLAGS -Wno-pointer-sign"
 862 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 863 if test $has_option = yes; then
 864    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 865 fi
 866 AC_MSG_RESULT($has_option)
 867 CFLAGS="$SAVE_CFLAGS"
 868 unset has_option
 869 unset SAVE_CFLAGS
 870
 871 #### Some other nice autoconf tests.
 872
 873 dnl checks for programs
 874 AC_PROG_LN_S
 875 AC_PROG_CPP
 876 AC_PROG_INSTALL
 877 if test "x$RANLIB" = x; then
 878   AC_PROG_RANLIB
 879 fi
 880 AC_PATH_PROG(INSTALL_INFO, install-info)
 881 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 882 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 883 dnl Don't use GZIP, which is used by gzip for additional parameters.
 884 AC_PATH_PROG(GZIP_PROG, gzip)
 885
 886
 887 ## Need makeinfo >= 4.6 (?) to build the manuals.
 888 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 889 dnl By this stage, configure has already checked for egrep and set EGREP,
 890 dnl or exited with an error if no egrep was found.
 891 if test "$MAKEINFO" != "no" && \
 892   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 893    MAKEINFO=no
 894 fi
 895
 896 if test "$MAKEINFO" = "no"; then
 897   AC_MSG_ERROR( [makeinfo >= 4.6 is required] )
 898 fi
 899
 900
 901 dnl Add our options to ac_link now, after it is set up.
 902
 903 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 904 then
 905   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 906 fi
 907
 908 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 909 then
 910   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 911 fi
 912
 913 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 914 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 915 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 916 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 917 dnl if not built to support GNU ld.
 918
 919 late_LDFLAGS=$LDFLAGS
 920 if test "$GCC" = yes; then
 921   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 922 else
 923   LDFLAGS="$LDFLAGS -znocombreloc"
 924 fi
 925
 926 AC_MSG_CHECKING([for -znocombreloc])
 927 AC_LINK_IFELSE([main(){return 0;}],
 928   [AC_MSG_RESULT(yes)],
 929   LDFLAGS=$late_LDFLAGS
 930   [AC_MSG_RESULT(no)])
 931
 932 #### Extract some information from the operating system and machine files.
 933
 934 AC_CHECKING([the machine- and system-dependent files to find out
 935  - which libraries the lib-src programs will want, and
 936  - whether the GNU malloc routines are usable])
 937
 938 ### First figure out CFLAGS (which we use for running the compiler here)
 939 ### and REAL_CFLAGS (which we use for real compilation).
 940 ### The two are the same except on a few systems, where they are made
 941 ### different to work around various lossages.  For example,
 942 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 943 ### as implying static linking.
 944
 945 ### If the CFLAGS env var is specified, we use that value
 946 ### instead of the default.
 947
 948 ### It's not important that this name contain the PID; you can't run
 949 ### two configures in the same directory and have anything work
 950 ### anyway.
 951 tempcname="conftest.c"
 952
 953 echo '
 954 #include "'${srcdir}'/src/'${opsysfile}'"
 955 #include "'${srcdir}'/src/'${machfile}'"
 956 #ifndef LIBS_MACHINE
 957 #define LIBS_MACHINE
 958 #endif
 959 #ifndef LIBS_SYSTEM
 960 #define LIBS_SYSTEM
 961 #endif
 962 #ifndef C_SWITCH_SYSTEM
 963 #define C_SWITCH_SYSTEM
 964 #endif
 965 #ifndef C_SWITCH_MACHINE
 966 #define C_SWITCH_MACHINE
 967 #endif
 968 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 969 configure___ c_switch_system=C_SWITCH_SYSTEM
 970 configure___ c_switch_machine=C_SWITCH_MACHINE
 971
 972 #ifndef LIB_X11_LIB
 973 #define LIB_X11_LIB -lX11
 974 #endif
 975
 976 #ifndef LIBX11_SYSTEM
 977 #define LIBX11_SYSTEM
 978 #endif
 979 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 980
 981 #ifdef UNEXEC
 982 configure___ unexec=UNEXEC
 983 #else
 984 configure___ unexec=unexec.o
 985 #endif
 986
 987 #ifdef SYSTEM_MALLOC
 988 configure___ system_malloc=yes
 989 #else
 990 configure___ system_malloc=no
 991 #endif
 992
 993 #ifdef USE_MMAP_FOR_BUFFERS
 994 configure___ use_mmap_for_buffers=yes
 995 #else
 996 configure___ use_mmap_for_buffers=no
 997 #endif
 998
 999 #ifndef C_DEBUG_SWITCH
1000 #define C_DEBUG_SWITCH -g
1001 #endif
1002
1003 #ifndef C_OPTIMIZE_SWITCH
1004 #ifdef __GNUC__
1005 #define C_OPTIMIZE_SWITCH -O2
1006 #else
1007 #define C_OPTIMIZE_SWITCH -O
1008 #endif
1009 #endif
1010
1011 #ifndef C_WARNINGS_SWITCH
1012 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
1013 #endif
1014
1015 #ifndef LD_SWITCH_MACHINE
1016 #define LD_SWITCH_MACHINE
1017 #endif
1018
1019 #ifndef LD_SWITCH_SYSTEM
1020 #define LD_SWITCH_SYSTEM
1021 #endif
1022
1023 #ifndef LD_SWITCH_X_SITE_AUX
1024 #define LD_SWITCH_X_SITE_AUX
1025 #endif
1026
1027 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1028 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1029
1030 #ifdef THIS_IS_CONFIGURE
1031
1032 /* Get the CFLAGS for tests in configure.  */
1033 #ifdef __GNUC__
1034 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1035 #else
1036 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1037 #endif
1038
1039 #else /* not THIS_IS_CONFIGURE */
1040
1041 /* Get the CFLAGS for real compilation.  */
1042 #ifdef __GNUC__
1043 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
1044 #else
1045 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1046 #endif
1047
1048 #endif /* not THIS_IS_CONFIGURE */
1049 ' > ${tempcname}
1050
1051 # The value of CPP is a quoted variable reference, so we need to do this
1052 # to get its actual value...
1053 CPP=`eval "echo $CPP"`
1054 [eval `${CPP} -Isrc ${tempcname} \
1055        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1056 if test "x$SPECIFIED_CFLAGS" = x; then
1057   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1058          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1059 else
1060   REAL_CFLAGS="$CFLAGS"
1061 fi]
1062 rm ${tempcname}
1063
1064 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1065
1066 ### Make sure subsequent tests use flags consistent with the build flags.
1067
1068 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1069   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1070 else
1071   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1072 fi
1073
1074 dnl For AC_FUNC_GETLOADAVG, at least:
1075 AC_CONFIG_LIBOBJ_DIR(src)
1076
1077 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1078 AC_SYS_LARGEFILE
1079
1080
1081 ### The standard library on x86-64 and s390x GNU/Linux distributions can
1082 ### be located in either /usr/lib64 or /usr/lib.
1083 case "${canonical}" in
1084   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1085     if test -d /usr/lib64; then
1086       AC_DEFINE(HAVE_LIB64_DIR, 1,
1087         [Define to 1 if the directory /usr/lib64 exists.])
1088 fi
1089 esac
1090
1091 dnl This function defintion taken from Gnome 2.0
1092 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1093 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1094 dnl also defines GSTUFF_PKG_ERRORS on error
1095 AC_DEFUN([PKG_CHECK_MODULES], [
1096   succeeded=no
1097
1098   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1099
1100   if test "$PKG_CONFIG" = "no" ; then
1101      ifelse([$4], , [AC_MSG_ERROR([
1102       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1103   else
1104      PKG_CONFIG_MIN_VERSION=0.9.0
1105      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1106         AC_MSG_CHECKING(for $2)
1107
1108         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1109             AC_MSG_RESULT(yes)
1110             succeeded=yes
1111
1112             AC_MSG_CHECKING($1_CFLAGS)
1113             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1114             AC_MSG_RESULT($$1_CFLAGS)
1115
1116             AC_MSG_CHECKING($1_LIBS)
1117             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1118             AC_MSG_RESULT($$1_LIBS)
1119         else
1120             AC_MSG_RESULT(no)
1121             $1_CFLAGS=""
1122             $1_LIBS=""
1123             ## If we have a custom action on failure, don't print errors, but
1124             ## do set a variable so people can do so.
1125             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1126             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1127         fi
1128
1129         AC_SUBST($1_CFLAGS)
1130         AC_SUBST($1_LIBS)
1131      else
1132         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1133         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1134      fi
1135   fi
1136
1137   if test $succeeded = yes; then
1138      ifelse([$3], , :, [$3])
1139   else
1140      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1141   fi
1142 ])
1143
1144
1145 if test "${with_sound}" != "no"; then
1146   # Sound support for GNU/Linux and the free BSDs.
1147   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1148   # Emulation library used on NetBSD.
1149   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1150   AC_SUBST(LIBSOUND)
1151
1152   ALSA_REQUIRED=1.0.0
1153   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1154   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1155   if test $HAVE_ALSA = yes; then
1156     SAVE_CFLAGS="$CFLAGS"
1157     SAVE_LDFLAGS="$LDFLAGS"
1158     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1159     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1160     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1161                     emacs_alsa_normal=yes,
1162                     emacs_alsa_normal=no)
1163     if test "$emacs_alsa_normal" != yes; then
1164       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1165                      [snd_lib_error_set_handler (0);],
1166                      emacs_alsa_subdir=yes,
1167                      emacs_alsa_subdir=no)
1168       if test "$emacs_alsa_subdir" != yes; then
1169         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1170       fi
1171       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1172     fi
1173
1174     CFLAGS="$SAVE_CFLAGS"
1175     LDFLAGS="$SAVE_LDFLAGS"
1176     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1177     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1178     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1179   fi
1180   AC_SUBST(CFLAGS_SOUND)
1181 fi
1182
1183 dnl checks for header files
1184 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1185   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1186   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1187   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1188   sys/utsname.h pwd.h)
1189
1190 AC_MSG_CHECKING(if personality LINUX32 can be set)
1191 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1192                emacs_cv_personality_linux32=yes,
1193                emacs_cv_personality_linux32=no)
1194 AC_MSG_RESULT($emacs_cv_personality_linux32)
1195
1196 if test $emacs_cv_personality_linux32 = yes; then
1197   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1198             [Define to 1 if personality LINUX32 can be set.])
1199 fi
1200
1201 dnl On Solaris 8 there's a compilation warning for term.h because
1202 dnl it doesn't define `bool'.
1203 AC_CHECK_HEADERS(term.h, , , -)
1204 AC_HEADER_STDC
1205 AC_HEADER_TIME
1206 AC_CHECK_DECLS([sys_siglist])
1207 if test $ac_cv_have_decl_sys_siglist != yes; then
1208   # For Tru64, at least:
1209   AC_CHECK_DECLS([__sys_siglist])
1210   if test $ac_cv_have_decl___sys_siglist = yes; then
1211     AC_DEFINE(sys_siglist, __sys_siglist,
1212               [Define to any substitute for sys_siglist.])
1213   fi
1214 fi
1215 AC_HEADER_SYS_WAIT
1216
1217 dnl Some systems have utime.h but don't declare the struct anyplace.
1218 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1219 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1220 #include <sys/time.h>
1221 #include <time.h>
1222 #else
1223 #ifdef HAVE_SYS_TIME_H
1224 #include <sys/time.h>
1225 #else
1226 #include <time.h>
1227 #endif
1228 #endif
1229 #ifdef HAVE_UTIME_H
1230 #include <utime.h>
1231 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1232   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1233 if test $emacs_cv_struct_utimbuf = yes; then
1234   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1235 fi
1236
1237 dnl checks for typedefs
1238 AC_TYPE_SIGNAL
1239
1240 dnl Check for speed_t typedef.
1241 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1242   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1243     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1244 if test $emacs_cv_speed_t = yes; then
1245   AC_DEFINE(HAVE_SPEED_T, 1,
1246            [Define to 1 if `speed_t' is declared by <termios.h>.])
1247 fi
1248
1249 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1250 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1251 #include <sys/time.h>
1252 #include <time.h>
1253 #else
1254 #ifdef HAVE_SYS_TIME_H
1255 #include <sys/time.h>
1256 #else
1257 #include <time.h>
1258 #endif
1259 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1260   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1261 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1262 if test $emacs_cv_struct_timeval = yes; then
1263   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1264 fi
1265
1266 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1267 AC_TRY_COMPILE([#include <math.h>],
1268 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1269   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1270 HAVE_EXCEPTION=$emacs_cv_struct_exception
1271 if test $emacs_cv_struct_exception != yes; then
1272   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1273 fi
1274
1275 AC_CHECK_HEADERS(sys/socket.h)
1276 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1277 #if HAVE_SYS_SOCKET_H
1278 #include <sys/socket.h>
1279 #endif])
1280
1281 dnl checks for structure members
1282 AC_STRUCT_TM
1283 AC_STRUCT_TIMEZONE
1284 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1285                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1286                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1287                 [#include <time.h>])
1288 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1289                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1290                   struct ifreq.ifr_addr], , ,
1291                  [AC_INCLUDES_DEFAULT
1292 #if HAVE_SYS_SOCKET_H
1293 #include <sys/socket.h>
1294 #endif
1295 #if HAVE_NET_IF_H
1296 #include <net/if.h>
1297 #endif])
1298
1299 dnl checks for compiler characteristics
1300
1301 dnl Testing __STDC__ to determine prototype support isn't good enough.
1302 dnl DEC C, for instance, doesn't define it with default options, and
1303 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1304 dnl and void *.
1305 AC_C_PROTOTYPES
1306 AC_C_VOLATILE
1307 AC_C_CONST
1308 dnl This isn't useful because we can't turn on use of `inline' unless
1309 dnl the compiler groks `extern inline'.
1310 dnl AC_C_INLINE
1311 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1312   [AC_TRY_COMPILE(, [void * foo;],
1313                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1314 if test $emacs_cv_void_star = yes; then
1315   AC_DEFINE(POINTER_TYPE, void)
1316 else
1317   AC_DEFINE(POINTER_TYPE, char)
1318 fi
1319 AH_TEMPLATE(POINTER_TYPE,
1320             [Define as `void' if your compiler accepts `void *'; otherwise
1321              define as `char'.])dnl
1322
1323
1324
1325 dnl This could be used for targets which can have both byte sexes.
1326 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1327 dnl AC_C_BIGENDIAN
1328
1329 dnl check for Make feature
1330 AC_PROG_MAKE_SET
1331
1332 dnl checks for operating system services
1333 AC_SYS_LONG_FILE_NAMES
1334
1335 #### Choose a window system.
1336
1337 AC_PATH_X
1338 if test "$no_x" = yes; then
1339   window_system=none
1340 else
1341   window_system=x11
1342 fi
1343
1344 if test "${x_libraries}" != NONE; then
1345   if test -n "${x_libraries}"; then
1346     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1347     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1348   fi
1349   x_default_search_path=""
1350   x_search_path=${x_libraries}
1351   if test -z "${x_search_path}"; then
1352     x_search_path=/usr/lib
1353   fi
1354   for x_library in `echo ${x_search_path}: | \
1355                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1356     x_search_path="\
1357 ${x_library}/X11/%L/%T/%N%C%S:\
1358 ${x_library}/X11/%l/%T/%N%C%S:\
1359 ${x_library}/X11/%T/%N%C%S:\
1360 ${x_library}/X11/%L/%T/%N%S:\
1361 ${x_library}/X11/%l/%T/%N%S:\
1362 ${x_library}/X11/%T/%N%S"
1363     if test x"${x_default_search_path}" = x; then
1364       x_default_search_path=${x_search_path}
1365     else
1366       x_default_search_path="${x_search_path}:${x_default_search_path}"
1367     fi
1368   done
1369 fi
1370 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1371   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1372 fi
1373
1374 if test x"${x_includes}" = x; then
1375   bitmapdir=/usr/include/X11/bitmaps
1376 else
1377   # accumulate include directories that have X11 bitmap subdirectories
1378   bmd_acc="dummyval"
1379   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1380     if test -d "${bmd}/X11/bitmaps"; then
1381       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1382     fi
1383     if test -d "${bmd}/bitmaps"; then
1384       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1385     fi
1386   done
1387   if test ${bmd_acc} != "dummyval"; then
1388     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1389   fi
1390 fi
1391
1392 HAVE_CARBON=no
1393 if test "${with_carbon}" != no; then
1394   AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1395 fi
1396 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1397   if test "${with_carbon+set}" != set \
1398      && test "${carbon_appdir_x+set}" != set; then
1399     for var in with_x with_x_toolkit with_xim \
1400                with_xpm with_jpeg with_tiff with_gif with_png; do
1401       if eval test \"\${$var+set}\" = set; then
1402         HAVE_CARBON=no
1403         break
1404       fi
1405     done
1406   fi
1407 fi
1408 if test "${HAVE_CARBON}" = yes; then
1409   window_system=mac
1410 fi
1411
1412 case "${window_system}" in
1413   x11 )
1414     HAVE_X_WINDOWS=yes
1415     HAVE_X11=yes
1416     case "${with_x_toolkit}" in
1417       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1418       motif ) USE_X_TOOLKIT=MOTIF ;;
1419       gtk ) with_gtk=yes
1420 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1421 dnl USE_X_TOOLKIT is set.
1422             USE_X_TOOLKIT=none ;;
1423       no ) USE_X_TOOLKIT=none ;;
1424 dnl If user did not say whether to use a toolkit, make this decision later:
1425 dnl use the toolkit if we have gtk, or X11R5 or newer.
1426       * ) USE_X_TOOLKIT=maybe ;;
1427     esac
1428   ;;
1429   mac | none )
1430     HAVE_X_WINDOWS=no
1431     HAVE_X11=no
1432     USE_X_TOOLKIT=none
1433   ;;
1434 esac
1435
1436 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1437    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1438    if test "$HAVE_XSERVER" = true ||
1439       test -n "$DISPLAY" ||
1440       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1441         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1442 were found.  You should install the relevant development files for X
1443 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1444 sure you have development files for image handling, i.e.
1445 tiff, gif, jpeg, png and xpm.
1446 If you are sure you want Emacs compiled without X window support, pass
1447   --without-x
1448 to configure.])
1449    fi
1450 fi
1451
1452 ### If we're using X11, we should use the X menu package.
1453 HAVE_MENUS=no
1454 case ${HAVE_X11} in
1455   yes ) HAVE_MENUS=yes ;;
1456 esac
1457
1458 ### Compute the unexec source name from the object name.
1459 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1460
1461 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1462 # Assume not, until told otherwise.
1463 GNU_MALLOC=yes
1464 doug_lea_malloc=yes
1465 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1466 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1467 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1468                emacs_cv_var___after_morecore_hook,
1469 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1470   emacs_cv_var___after_morecore_hook=yes,
1471   emacs_cv_var___after_morecore_hook=no)])
1472 if test $emacs_cv_var___after_morecore_hook = no; then
1473   doug_lea_malloc=no
1474 fi
1475 if test "${system_malloc}" = "yes"; then
1476   GNU_MALLOC=no
1477   GNU_MALLOC_reason="
1478     (The GNU allocators don't work with this system configuration.)"
1479 fi
1480 if test "$doug_lea_malloc" = "yes" ; then
1481   if test "$GNU_MALLOC" = yes ; then
1482     GNU_MALLOC_reason="
1483       (Using Doug Lea's new malloc from the GNU C Library.)"
1484   fi
1485   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1486             [Define to 1 if you are using the GNU C Library.])
1487 fi
1488
1489 if test x"${REL_ALLOC}" = x; then
1490   REL_ALLOC=${GNU_MALLOC}
1491 fi
1492
1493 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1494 dnl the system configuration file (s/*.h) to turn the use of mmap
1495 dnl in the relocating allocator on.
1496
1497 AC_FUNC_MMAP
1498 if test $use_mmap_for_buffers = yes; then
1499   REL_ALLOC=no
1500 fi
1501
1502 LIBS="$libsrc_libs $LIBS"
1503
1504 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1505 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1506 AC_CHECK_LIB(dnet, dnet_ntoa)
1507 dnl This causes -lresolv to get used in subsequent tests,
1508 dnl which causes failures on some systems such as HPUX 9.
1509 dnl AC_CHECK_LIB(resolv, gethostbyname)
1510
1511 dnl FIXME replace main with a function we actually want from this library.
1512 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1513
1514 AC_CHECK_LIB(pthreads, cma_open)
1515
1516 dnl Check for need for bigtoc support on IBM AIX
1517
1518 case ${host_os} in
1519 aix*)
1520   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1521     case $GCC in
1522     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1523     *) gdb_cv_bigtoc=-bbigtoc ;;
1524     esac
1525
1526     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1527     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1528   ])
1529   ;;
1530 esac
1531
1532 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1533 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1534 # REAL_CPPFLAGS later on.
1535
1536 REAL_CPPFLAGS="$CPPFLAGS"
1537
1538 if test "${HAVE_X11}" = "yes"; then
1539   DEFS="$C_SWITCH_X_SITE $DEFS"
1540   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1541   LIBS="$LIBX $LIBS"
1542   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1543   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1544
1545   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1546   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1547   # but it's more convenient here to set LD_RUN_PATH
1548   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1549   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1550     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1551     export LD_RUN_PATH
1552   fi
1553
1554   if test "${opsys}" = "gnu-linux"; then
1555     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1556     AC_TRY_LINK([],
1557      [XOpenDisplay ("foo");],
1558      [xlinux_first_failure=no],
1559      [xlinux_first_failure=yes])
1560     if test "${xlinux_first_failure}" = "yes"; then
1561       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1562       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1563       OLD_CPPFLAGS="$CPPFLAGS"
1564       OLD_LIBS="$LIBS"
1565       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1566       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1567       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1568       LIBS="$LIBS -b i486-linuxaout"
1569       AC_TRY_LINK([],
1570        [XOpenDisplay ("foo");],
1571        [xlinux_second_failure=no],
1572        [xlinux_second_failure=yes])
1573       if test "${xlinux_second_failure}" = "yes"; then
1574         # If we get the same failure with -b, there is no use adding -b.
1575         # So take it out.  This plays safe.
1576         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1577         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1578         CPPFLAGS="$OLD_CPPFLAGS"
1579         LIBS="$OLD_LIBS"
1580         AC_MSG_RESULT(no)
1581       else
1582         AC_MSG_RESULT(yes)
1583       fi
1584     else
1585       AC_MSG_RESULT(no)
1586     fi
1587   fi
1588
1589   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1590   # header files included from there.
1591   AC_MSG_CHECKING(for Xkb)
1592   AC_TRY_LINK([#include <X11/Xlib.h>
1593 #include <X11/XKBlib.h>],
1594         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1595         emacs_xkb=yes, emacs_xkb=no)
1596   AC_MSG_RESULT($emacs_xkb)
1597   if test $emacs_xkb = yes; then
1598     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1599   fi
1600
1601   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1602 XScreenNumberOfScreen XSetWMProtocols)
1603 fi
1604
1605 if test "${window_system}" = "x11"; then
1606   AC_MSG_CHECKING(X11 version 6)
1607   AC_CACHE_VAL(emacs_cv_x11_version_6,
1608   [AC_TRY_LINK([#include <X11/Xlib.h>],
1609 [#if XlibSpecificationRelease < 6
1610 fail;
1611 #endif
1612 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1613   if test $emacs_cv_x11_version_6 = yes; then
1614     AC_MSG_RESULT(6 or newer)
1615     AC_DEFINE(HAVE_X11R6, 1,
1616               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1617   else
1618     AC_MSG_RESULT(before 6)
1619   fi
1620 fi
1621
1622
1623 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1624 HAVE_RSVG=no
1625 if test "${HAVE_X11}" = "yes" || test "${HAVE_CARBON}" = "yes"; then
1626   if test "${with_rsvg}" != "no"; then
1627     RSVG_REQUIRED=2.0.0
1628     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1629
1630     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1631     AC_SUBST(RSVG_CFLAGS)
1632     AC_SUBST(RSVG_LIBS)
1633
1634     if test ".${RSVG_CFLAGS}" != "."; then
1635       HAVE_RSVG=yes
1636       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1637       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1638       LIBS="$RSVG_LIBS $LIBS"
1639     fi
1640   fi
1641 fi
1642
1643
1644 HAVE_GTK=no
1645 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1646   GLIB_REQUIRED=2.6
1647   GTK_REQUIRED=2.6
1648   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1649
1650   dnl Checks for libraries.
1651   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1652   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1653      AC_MSG_ERROR($GTK_PKG_ERRORS)
1654   fi
1655 fi
1656
1657
1658 if test x"$pkg_check_gtk" = xyes; then
1659
1660   AC_SUBST(GTK_CFLAGS)
1661   AC_SUBST(GTK_LIBS)
1662   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1663   CFLAGS="$CFLAGS $GTK_CFLAGS"
1664   LIBS="$GTK_LIBS $LIBS"
1665   dnl Try to compile a simple GTK program.
1666   GTK_COMPILES=no
1667   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1668   if test "${GTK_COMPILES}" != "yes"; then
1669     if test "$USE_X_TOOLKIT" != "maybe"; then
1670       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1671     fi
1672   else
1673     HAVE_GTK=yes
1674     AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
1675     USE_X_TOOLKIT=none
1676     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1677       :
1678     else
1679       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1680        closing open displays.  This is no problem if you just use
1681        one display, but if you use more than one and close one of them
1682        Emacs may crash.]])
1683       sleep 3
1684     fi
1685   fi
1686
1687 fi
1688
1689
1690 if test "${HAVE_GTK}" = "yes"; then
1691
1692   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1693   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1694   if test "$with_toolkit_scroll_bars" != no; then
1695     with_toolkit_scroll_bars=yes
1696   fi
1697
1698   dnl  Check if we can use multiple displays with this GTK version.
1699   dnl  If gdk_display_open exists, assume all others are there also.
1700   HAVE_GTK_MULTIDISPLAY=no
1701   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1702   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1703     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1704               [Define to 1 if GTK can handle more than one display.])
1705   fi
1706
1707   dnl  Check if we have the old file selection dialog.
1708   dnl  If gdk_display_open exists, assume all others are there also.
1709   HAVE_GTK_FILE_SELECTION=no
1710   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1711
1712   dnl  Check if we have the new file chooser dialog
1713   dnl  If gdk_display_open exists, assume all others are there also.
1714   HAVE_GTK_FILE_CHOOSER=no
1715   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1716
1717   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1718      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1719     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1720               [Define to 1 if GTK has both file selection and chooser dialog.])
1721   fi
1722
1723   dnl Check if pthreads are available.  Emacs only needs this when using
1724   dnl gtk_file_chooser under Gnome.
1725   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1726     HAVE_GTK_AND_PTHREAD=no
1727     AC_CHECK_HEADERS(pthread.h)
1728     if test "$ac_cv_header_pthread_h"; then
1729       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1730     fi
1731     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1732       case "${canonical}" in
1733         *-hpux*) ;;
1734         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1735       esac
1736       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1737                [Define to 1 if you have GTK and pthread (-lpthread).])
1738     fi
1739   fi
1740 fi
1741
1742 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1743 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1744 dnl also not configured.
1745 HAVE_DBUS=no
1746 if test "${with_dbus}" = "yes"; then
1747    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1748    if test "$HAVE_DBUS" = yes; then
1749       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1750    fi
1751 fi
1752
1753 dnl Do not put whitespace before the #include statements below.
1754 dnl Older compilers (eg sunos4 cc) choke on it.
1755 HAVE_XAW3D=no
1756 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1757   if test "$with_xaw3d" != no; then
1758     AC_MSG_CHECKING(for xaw3d)
1759     AC_CACHE_VAL(emacs_cv_xaw3d,
1760     [AC_TRY_LINK([
1761 #include <X11/Intrinsic.h>
1762 #include <X11/Xaw3d/Simple.h>],
1763       [],
1764       emacs_cv_xaw3d=yes,
1765       emacs_cv_xaw3d=no)])
1766   else
1767     emacs_cv_xaw3d=no
1768   fi
1769   if test $emacs_cv_xaw3d = yes; then
1770     AC_MSG_RESULT([yes; using Lucid toolkit])
1771     USE_X_TOOLKIT=LUCID
1772     HAVE_XAW3D=yes
1773     AC_DEFINE(HAVE_XAW3D, 1,
1774               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1775   else
1776     AC_MSG_RESULT(no)
1777     AC_MSG_CHECKING(for libXaw)
1778     AC_CACHE_VAL(emacs_cv_xaw,
1779     [AC_TRY_LINK([
1780 #include <X11/Intrinsic.h>
1781 #include <X11/Xaw/Simple.h>],
1782       [],
1783       emacs_cv_xaw=yes,
1784       emacs_cv_xaw=no)])
1785     if test $emacs_cv_xaw = yes; then
1786       AC_MSG_RESULT([yes; using Lucid toolkit])
1787       USE_X_TOOLKIT=LUCID
1788     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1789       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1790     else
1791       AC_MSG_RESULT([no; do not use toolkit by default])
1792       USE_X_TOOLKIT=none
1793     fi
1794   fi
1795 fi
1796
1797 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1798
1799 if test "${USE_X_TOOLKIT}" != "none"; then
1800   AC_MSG_CHECKING(X11 toolkit version)
1801   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1802   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1803 [#if XtSpecificationRelease < 6
1804 fail;
1805 #endif
1806 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1807   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1808   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1809     AC_MSG_RESULT(6 or newer)
1810     AC_DEFINE(HAVE_X11XTR6, 1,
1811               [Define to 1 if you have the X11R6 or newer version of Xt.])
1812   else
1813     AC_MSG_RESULT(before 6)
1814   fi
1815
1816 dnl If using toolkit, check whether libXmu.a exists.
1817 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1818   OLDLIBS="$LIBS"
1819   if test x$HAVE_X11XTR6 = xyes; then
1820     LIBS="-lXt -lSM -lICE $LIBS"
1821   else
1822     LIBS="-lXt $LIBS"
1823   fi
1824   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1825   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1826 fi
1827
1828 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1829 if test "${HAVE_X11}" = "yes"; then
1830   if test "${USE_X_TOOLKIT}" != "none"; then
1831     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1832   fi
1833 fi
1834
1835 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1836   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1837   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1838     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1839 int x = 5;
1840 #else
1841 Motif version prior to 2.1.
1842 #endif],
1843     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1844   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1845   if test $emacs_cv_motif_version_2_1 = yes; then
1846     HAVE_LIBXP=no
1847     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1848               [Define to 1 if you have Motif 2.1 or newer.])
1849     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1850     if test ${HAVE_LIBXP} = yes; then
1851       AC_DEFINE(HAVE_LIBXP, 1,
1852                 [Define to 1 if you have the Xp library (-lXp).])
1853     fi
1854   else
1855     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1856     # We put this in CFLAGS temporarily to precede other -I options
1857     # that might be in CFLAGS temporarily.
1858     # We put this in CPPFLAGS where it precedes the other -I options.
1859     OLD_CPPFLAGS=$CPPFLAGS
1860     OLD_CFLAGS=$CFLAGS
1861     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1862     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1863     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1864       [int x = 5;],
1865       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1866     if test $emacs_cv_lesstif = yes; then
1867       # Make sure this -I option remains in CPPFLAGS after it is set
1868       # back to REAL_CPPFLAGS.
1869       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1870       # have those other -I options anyway.  Ultimately, having this
1871       # directory ultimately in CPPFLAGS will be enough.
1872       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1873       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1874     else
1875       CFLAGS=$OLD_CFLAGS
1876       CPPFLAGS=$OLD_CPPFLAGS
1877     fi
1878   fi
1879 fi
1880
1881 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1882 dnl using Motif or Xaw3d is available, and unless
1883 dnl --with-toolkit-scroll-bars=no was specified.
1884
1885 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1886             [Define to 1 if we should use toolkit scroll bars.])dnl
1887 USE_TOOLKIT_SCROLL_BARS=no
1888 if test "${with_toolkit_scroll_bars}" != "no"; then
1889   if test "${USE_X_TOOLKIT}" != "none"; then
1890     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1891       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1892       HAVE_XAW3D=no
1893       USE_TOOLKIT_SCROLL_BARS=yes
1894     elif test "${HAVE_XAW3D}" = "yes"; then
1895       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1896       USE_TOOLKIT_SCROLL_BARS=yes
1897     fi
1898   elif test "${HAVE_GTK}" = "yes"; then
1899     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1900     USE_TOOLKIT_SCROLL_BARS=yes
1901   elif test "${HAVE_CARBON}" = "yes"; then
1902     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1903     USE_TOOLKIT_SCROLL_BARS=yes
1904   fi
1905 fi
1906
1907 dnl See if XIM is available.
1908 AC_TRY_COMPILE([
1909           #include <X11/Xlib.h>
1910           #include <X11/Xresource.h>],
1911          [XIMProc  callback;],
1912          [HAVE_XIM=yes
1913          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1914          HAVE_XIM=no)
1915
1916 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1917
1918 if test "${with_xim}" != "no"; then
1919   AC_DEFINE(USE_XIM, 1,
1920             [Define to 1 if we should use XIM, if it is available.])
1921 fi
1922
1923
1924 if test "${HAVE_XIM}" != "no"; then
1925   late_CFLAGS=$CFLAGS
1926   if test "$GCC" = yes; then
1927     CFLAGS="$CFLAGS --pedantic-errors"
1928   fi
1929   AC_TRY_COMPILE([
1930 #include <X11/Xlib.h>
1931 #include <X11/Xresource.h>],
1932 [Display *display;
1933 XrmDatabase db;
1934 char *res_name;
1935 char *res_class;
1936 XIMProc  callback;
1937 XPointer *client_data;
1938 #ifndef __GNUC__
1939 /* If we're not using GCC, it's probably not XFree86, and this is
1940    probably right, but we can't use something like --pedantic-errors.  */
1941 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1942                                            char*, XIMProc, XPointer*);
1943 #endif
1944 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1945    client_data);],
1946     [emacs_cv_arg6_star=yes])
1947   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1948          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1949 either XPointer or XPointer*.])dnl
1950   if test "$emacs_cv_arg6_star" = yes; then
1951     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1952   else
1953     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1954   fi
1955   CFLAGS=$late_CFLAGS
1956 fi
1957
1958 ### Start of font-backend section.
1959 if test "${HAVE_X11}" != "yes"; then
1960   USE_FONT_BACKEND=no
1961 fi
1962
1963 if test "${USE_FONT_BACKEND}" = "yes"; then
1964   AC_DEFINE(USE_FONT_BACKEND, 1, [Define to 1 if we should use font-backend.])
1965
1966   ## Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1967   HAVE_XFT=maybe
1968   if test "x${with_freetype}" = "xno"; then
1969     with_xft="no";
1970   fi
1971   if test "x${with_xft}" != "xno"; then
1972
1973     PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1974     if test "$HAVE_XFT" != no; then
1975       OLD_CPPFLAGS="$CPPFLAGS"
1976       OLD_CFLAGS="$CFLAGS"
1977       OLD_LIBS="$LIBS"
1978       CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1979       CFLAGS="$CFLAGS $XFT_CFLAGS"
1980       LIBS="$XFT_LIBS $LIBS"
1981       AC_CHECK_HEADER(X11/Xft/Xft.h,
1982         AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1983
1984       if test "${HAVE_XFT}" = "yes"; then
1985         AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1986         AC_SUBST(XFT_LIBS)
1987         C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1988       else
1989         CPPFLAGS="$OLD_CPPFLAGS"
1990         CFLAGS="$OLD_CFLAGS"
1991         LIBS="$OLD_LIBS"
1992       fi                        # "${HAVE_XFT}" = "yes"
1993     fi                          # "$HAVE_XFT" != no
1994   fi                            # "x${with_xft}" != "xno"
1995
1996   dnl For the "Does Emacs use" message at the end.
1997   if test "$HAVE_XFT" != "yes"; then
1998      HAVE_XFT=no
1999   fi
2000
2001
2002   HAVE_FREETYPE=no
2003   ### Use -lfreetype if available, unless `--with-freetype=no'.
2004   if test "${HAVE_XFT}" = "yes"; then
2005     dnl As we use Xft, we anyway use freetype.
2006     dnl In this case, there's no need of additional CFLAGS and LIBS.
2007     HAVE_FREETYPE=yes
2008   elif test "x${with_freetype}" != "xno"; then
2009
2010     PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
2011     if test "${HAVE_FREETYPE}" = "yes"; then
2012       PKG_CHECK_MODULES(FONTCONFIG, fontconfig, HAVE_FC=yes, HAVE_FC=no)
2013       if test "${HAVE_FC}" = "no"; then
2014         dnl Without fontconfig, we can't use freetype at the moment.
2015         HAVE_FREETYPE=no
2016       fi
2017     fi
2018   fi
2019
2020   HAVE_LIBOTF=no
2021   if test "${HAVE_FREETYPE}" = "yes"; then
2022     AC_DEFINE(HAVE_FREETYPE, 1,
2023               [Define to 1 if using the freetype and fontconfig libraries.])
2024     if test "${with_libotf}" != "no"; then
2025       PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2026                         HAVE_LIBOTF=no)
2027       if test "$HAVE_LIBOTF" = "yes"; then
2028         AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2029       fi
2030     fi
2031 dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2032 dnl Does the new font backend require it, or can it work without it?
2033   fi
2034
2035   HAVE_M17N_FLT=no
2036   if test "${with_m17n_flt}" != "no"; then
2037     PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2038     if test "$HAVE_M17N_FLT" = "yes"; then
2039       AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2040     fi
2041   fi
2042
2043   AC_SUBST(FREETYPE_CFLAGS)
2044   AC_SUBST(FREETYPE_LIBS)
2045   AC_SUBST(FONTCONFIG_CFLAGS)
2046   AC_SUBST(FONTCONFIG_LIBS)
2047   AC_SUBST(LIBOTF_CFLAGS)
2048   AC_SUBST(LIBOTF_LIBS)
2049   AC_SUBST(M17N_FLT_CFLAGS)
2050   AC_SUBST(M17N_FLT_LIBS)
2051
2052 fi                              # "${USE_FONT_BACKEND}" = "yes"
2053 ### End of font-backend section.
2054
2055 ### Use -lXpm if available, unless `--with-xpm=no'.
2056 HAVE_XPM=no
2057 if test "${HAVE_X11}" = "yes"; then
2058   if test "${with_xpm}" != "no"; then
2059     AC_CHECK_HEADER(X11/xpm.h,
2060       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2061     if test "${HAVE_XPM}" = "yes"; then
2062       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2063       AC_EGREP_CPP(no_return_alloc_pixels,
2064       [#include "X11/xpm.h"
2065 #ifndef XpmReturnAllocPixels
2066 no_return_alloc_pixels
2067 #endif
2068       ], HAVE_XPM=no, HAVE_XPM=yes)
2069
2070       if test "${HAVE_XPM}" = "yes"; then
2071         AC_MSG_RESULT(yes)
2072       else
2073         AC_MSG_RESULT(no)
2074       fi
2075     fi
2076   fi
2077
2078   if test "${HAVE_XPM}" = "yes"; then
2079     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2080   fi
2081 fi
2082
2083 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2084 HAVE_JPEG=no
2085 if test "${HAVE_X11}" = "yes"; then
2086   if test "${with_jpeg}" != "no"; then
2087     dnl Checking for jpeglib.h can lose because of a redefinition of
2088     dnl  HAVE_STDLIB_H.
2089     AC_CHECK_HEADER(jerror.h,
2090       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2091   fi
2092
2093   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2094   if test "${HAVE_JPEG}" = "yes"; then
2095     AC_DEFINE(HAVE_JPEG)
2096     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2097         [#include <jpeglib.h>
2098          version=JPEG_LIB_VERSION
2099 ],
2100         [AC_DEFINE(HAVE_JPEG)],
2101         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2102         HAVE_JPEG=no])
2103   fi
2104 fi
2105
2106 ### Use -lpng if available, unless `--with-png=no'.
2107 HAVE_PNG=no
2108 if test "${HAVE_X11}" = "yes"; then
2109   if test "${with_png}" != "no"; then
2110     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2111     # in /usr/include/libpng.
2112     AC_CHECK_HEADERS(png.h libpng/png.h)
2113     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2114       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2115     fi
2116   fi
2117
2118   if test "${HAVE_PNG}" = "yes"; then
2119     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2120   fi
2121 fi
2122
2123 ### Use -ltiff if available, unless `--with-tiff=no'.
2124 HAVE_TIFF=no
2125 if test "${HAVE_X11}" = "yes"; then
2126   if test "${with_tiff}" != "no"; then
2127     AC_CHECK_HEADER(tiffio.h,
2128       [tifflibs="-lz -lm"
2129       # At least one tiff package requires the jpeg library.
2130       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2131       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2132   fi
2133
2134   if test "${HAVE_TIFF}" = "yes"; then
2135     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2136   fi
2137 fi
2138
2139 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2140 HAVE_GIF=no
2141 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2142   AC_CHECK_HEADER(gif_lib.h,
2143 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2144 # Earlier versions can crash Emacs.
2145     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2146
2147   if test "$HAVE_GIF" = yes; then
2148       ac_gif_lib_name="-lgif"
2149   fi
2150
2151 # If gif_lib.h but no libgif, try libungif.
2152   if test x"$try_libungif" = xyes; then
2153     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2154
2155     if test "$HAVE_GIF" = yes; then
2156       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2157       ac_gif_lib_name="-lungif"
2158     fi
2159   fi
2160
2161   if test "${HAVE_GIF}" = "yes"; then
2162     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2163   fi
2164 fi
2165
2166 dnl Check for required libraries.
2167 if test "${HAVE_X11}" = "yes"; then
2168   MISSING=""
2169   WITH_NO=""
2170   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2171     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2172   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2173     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2174   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2175     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2176   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2177     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2178   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2179     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2180
2181   if test "X${MISSING}" != X; then
2182     AC_MSG_ERROR([The following required libraries were not found:
2183     $MISSING
2184 Maybe some development libraries/packages are missing?
2185 If you don't want to link with them give
2186     $WITH_NO
2187 as options to configure])
2188   fi
2189 fi
2190
2191 ### Use -lgpm if available, unless `--with-gpm=no'.
2192 HAVE_GPM=no
2193 if test "${with_gpm}" != "no"; then
2194   AC_CHECK_HEADER(gpm.h,
2195     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2196 fi
2197
2198 if test "${HAVE_GPM}" = "yes"; then
2199   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2200 fi
2201
2202 dnl Check for malloc/malloc.h on darwin
2203 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2204
2205 ### Use Mac OS X Carbon API to implement GUI.
2206 if test "${HAVE_CARBON}" = "yes"; then
2207   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2208   ## Specify the install directory
2209   carbon_appdir=
2210   if test "${carbon_appdir_x}" != ""; then
2211     case ${carbon_appdir_x} in
2212       y | ye | yes)  carbon_appdir=/Applications ;;
2213       * ) carbon_appdir=${carbon_appdir_x} ;;
2214     esac
2215   fi
2216   # We also have mouse menus.
2217   HAVE_MENUS=yes
2218 fi
2219
2220 ### Use session management (-lSM -lICE) if available
2221 HAVE_X_SM=no
2222 if test "${HAVE_X11}" = "yes"; then
2223   AC_CHECK_HEADER(X11/SM/SMlib.h,
2224     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2225
2226   if test "${HAVE_X_SM}" = "yes"; then
2227     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2228     case "$LIBS" in
2229       *-lSM*) ;;
2230       *)      LIBS="-lSM -lICE $LIBS" ;;
2231     esac
2232   fi
2233 fi
2234
2235 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2236 AC_CACHE_CHECK(whether netdb declares h_errno,
2237                emacs_cv_netdb_declares_h_errno,
2238 [AC_TRY_LINK([#include <netdb.h>],
2239   [return h_errno;],
2240   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2241 if test $emacs_cv_netdb_declares_h_errno = yes; then
2242   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2243 fi
2244
2245 AC_FUNC_ALLOCA
2246
2247 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2248 dnl FIXME is there an autoconf test that does the right thing, without
2249 dnl needing to call A_M_E afterwards?
2250 if test x"$ac_cv_func_alloca_works" != xyes; then
2251    AC_MSG_ERROR( [a system implementation of alloca is required] )
2252 fi
2253
2254 # fmod, logb, and frexp are found in -lm on most systems.
2255 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2256 AC_CHECK_LIB(m, sqrt)
2257
2258 # Check for mail-locking functions in a "mail" library.  Probably this should
2259 # have the same check as for liblockfile below.
2260 AC_CHECK_LIB(mail, maillock)
2261 dnl Debian, at least:
2262 AC_CHECK_LIB(lockfile, maillock)
2263 # If we have the shared liblockfile, assume we must use it for mail
2264 # locking (e.g. Debian).  If we couldn't link against liblockfile
2265 # (no liblockfile.a installed), ensure that we don't need to.
2266 if test "$ac_cv_lib_lockfile_maillock" = no; then
2267   dnl This works for files generally, not just executables.
2268   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2269   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2270                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2271   if test $ac_cv_prog_liblockfile = yes; then
2272     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2273 This probably means that movemail could lose mail.
2274 There may be a `development' package to install containing liblockfile.])
2275   else :
2276   fi
2277 fi
2278 AC_CHECK_FUNCS(touchlock)
2279 AC_CHECK_HEADERS(maillock.h)
2280
2281 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2282 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2283 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2284 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2285 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2286 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2287 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2288 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2289 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2290
2291 AC_CHECK_HEADERS(sys/un.h)
2292
2293 AC_FUNC_MKTIME
2294 if test "$ac_cv_func_working_mktime" = no; then
2295   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2296 fi
2297
2298 AC_FUNC_GETLOADAVG
2299
2300 AC_FUNC_FSEEKO
2301
2302 # Configure getopt.
2303 m4_include([m4/getopt.m4])
2304 gl_GETOPT_IFELSE([
2305   gl_GETOPT_SUBSTITUTE_HEADER
2306   gl_PREREQ_GETOPT
2307   GETOPTOBJS='getopt.o getopt1.o'
2308 ])
2309 AC_SUBST(GETOPTOBJS)
2310
2311 AC_FUNC_GETPGRP
2312
2313 AC_FUNC_STRFTIME
2314
2315 # UNIX98 PTYs.
2316 AC_CHECK_FUNCS(grantpt)
2317
2318 # PTY-related GNU extensions.
2319 AC_CHECK_FUNCS(getpt)
2320
2321 # Check this now, so that we will NOT find the above functions in ncurses.
2322 # That is because we have not set up to link ncurses in lib-src.
2323 # It's better to believe a function is not available
2324 # than to expect to find it in ncurses.
2325 AC_CHECK_LIB(ncurses, tparm)
2326
2327 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2328
2329 resolv=no
2330 AC_TRY_LINK([#include <netinet/in.h>
2331 #include <arpa/nameser.h>
2332 #include <resolv.h>],
2333     [return res_init();],
2334     have_res_init=yes, have_res_init=no)
2335 if test "$have_res_init" = no; then
2336   OLIBS="$LIBS"
2337   LIBS="$LIBS -lresolv"
2338   AC_MSG_CHECKING(for res_init with -lresolv)
2339   AC_TRY_LINK([#include <netinet/in.h>
2340 #include <arpa/nameser.h>
2341 #include <resolv.h>],
2342     [return res_init();],
2343     have_res_init=yes, have_res_init=no)
2344   AC_MSG_RESULT($have_res_init)
2345   if test "$have_res_init" = yes ; then
2346     resolv=yes
2347   fi
2348   LIBS="$OLIBS"
2349 fi
2350
2351 if test "$have_res_init" = yes; then
2352   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2353 fi
2354
2355 # Do we need the Hesiod library to provide the support routines?
2356 if test "$with_hesiod" = yes ; then
2357   # Don't set $LIBS here -- see comments above.
2358   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2359      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2360                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2361   if test "$resolv" = yes ; then
2362     RESOLVLIB=-lresolv
2363   else
2364     RESOLVLIB=
2365   fi
2366   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2367         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2368                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2369         :, $RESOLVLIB)])
2370 fi
2371
2372 # Do we need libresolv (due to res_init or Hesiod)?
2373 if test "$resolv" = yes ; then
2374   AC_DEFINE(HAVE_LIBRESOLV, 1,
2375             [Define to 1 if you have the resolv library (-lresolv).])
2376 fi
2377
2378 # These tell us which Kerberos-related libraries to use.
2379 if test "${with_kerberos+set}" = set; then
2380   AC_CHECK_LIB(com_err, com_err)
2381   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2382   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2383   AC_CHECK_LIB(krb5, krb5_init_context)
2384   if test "${with_kerberos5+set}" != set; then
2385     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2386                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2387     AC_CHECK_LIB(krb4, krb_get_cred,,
2388                  [AC_CHECK_LIB(krb, krb_get_cred)])
2389   fi
2390
2391   if test "${with_kerberos5+set}" = set; then
2392     AC_CHECK_HEADERS(krb5.h)
2393   else
2394     AC_CHECK_HEADERS(des.h,,
2395                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2396                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2397     AC_CHECK_HEADERS(krb.h,,
2398                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2399                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2400   fi
2401   AC_CHECK_HEADERS(com_err.h)
2402 fi
2403
2404 # Solaris requires -lintl if you want strerror (which calls dgettext)
2405 # to return localized messages.
2406 AC_CHECK_LIB(intl, dgettext)
2407
2408 AC_MSG_CHECKING(whether localtime caches TZ)
2409 AC_CACHE_VAL(emacs_cv_localtime_cache,
2410 [if test x$ac_cv_func_tzset = xyes; then
2411 AC_TRY_RUN([#include <time.h>
2412 extern char **environ;
2413 unset_TZ ()
2414 {
2415   char **from, **to;
2416   for (to = from = environ; (*to = *from); from++)
2417     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2418       to++;
2419 }
2420 char TZ_GMT0[] = "TZ=GMT0";
2421 char TZ_PST8[] = "TZ=PST8";
2422 main()
2423 {
2424   time_t now = time ((time_t *) 0);
2425   int hour_GMT0, hour_unset;
2426   if (putenv (TZ_GMT0) != 0)
2427     exit (1);
2428   hour_GMT0 = localtime (&now)->tm_hour;
2429   unset_TZ ();
2430   hour_unset = localtime (&now)->tm_hour;
2431   if (putenv (TZ_PST8) != 0)
2432     exit (1);
2433   if (localtime (&now)->tm_hour == hour_GMT0)
2434     exit (1);
2435   unset_TZ ();
2436   if (localtime (&now)->tm_hour != hour_unset)
2437     exit (1);
2438   exit (0);
2439 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2440 [# If we have tzset, assume the worst when cross-compiling.
2441 emacs_cv_localtime_cache=yes])
2442 else
2443         # If we lack tzset, report that localtime does not cache TZ,
2444         # since we can't invalidate the cache if we don't have tzset.
2445         emacs_cv_localtime_cache=no
2446 fi])dnl
2447 AC_MSG_RESULT($emacs_cv_localtime_cache)
2448 if test $emacs_cv_localtime_cache = yes; then
2449   AC_DEFINE(LOCALTIME_CACHE, 1,
2450             [Define to 1 if localtime caches TZ.])
2451 fi
2452
2453 if test "x$HAVE_TIMEVAL" = xyes; then
2454   AC_CHECK_FUNCS(gettimeofday)
2455   if test $ac_cv_func_gettimeofday = yes; then
2456     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2457                    emacs_cv_gettimeofday_two_arguments,
2458     [AC_TRY_COMPILE([
2459 #ifdef TIME_WITH_SYS_TIME
2460 #include <sys/time.h>
2461 #include <time.h>
2462 #else
2463 #ifdef HAVE_SYS_TIME_H
2464 #include <sys/time.h>
2465 #else
2466 #include <time.h>
2467 #endif
2468 #endif],
2469       [struct timeval time;
2470        gettimeofday (&time, 0);],
2471       emacs_cv_gettimeofday_two_arguments=yes,
2472       emacs_cv_gettimeofday_two_arguments=no)])
2473     if test $emacs_cv_gettimeofday_two_arguments = no; then
2474       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2475                 [Define to 1 if gettimeofday accepts only one argument.])
2476     fi
2477   fi
2478 fi
2479
2480 ok_so_far=yes
2481 AC_CHECK_FUNC(socket, , ok_so_far=no)
2482 if test $ok_so_far = yes; then
2483   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2484 fi
2485 if test $ok_so_far = yes; then
2486   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2487 fi
2488 if test $ok_so_far = yes; then
2489 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2490   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2491             [Define to 1 if you have inet sockets.])
2492 fi
2493
2494 AC_CHECK_HEADERS(sys/ioctl.h)
2495
2496 if test -f /usr/lpp/X11/bin/smt.exp; then
2497   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2498             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2499 fi
2500
2501 AC_MSG_CHECKING(whether system supports dynamic ptys)
2502 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2503   AC_MSG_RESULT(yes)
2504   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2505 else
2506   AC_MSG_RESULT(no)
2507 fi
2508
2509 AC_FUNC_FORK
2510
2511 dnl Adapted from Haible's version.
2512 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2513   [AC_TRY_LINK([#include <langinfo.h>],
2514     [char* cs = nl_langinfo(CODESET);],
2515     emacs_cv_langinfo_codeset=yes,
2516     emacs_cv_langinfo_codeset=no)
2517   ])
2518 if test $emacs_cv_langinfo_codeset = yes; then
2519   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2520     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2521 fi
2522
2523 AC_CHECK_TYPES(size_t)
2524
2525 AC_TYPE_MBSTATE_T
2526
2527 dnl Restrict could probably be used effectively other than in regex.c.
2528 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2529   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2530                   emacs_cv_c_restrict=yes,
2531                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2532                                   emacs_cv_c_restrict=__restrict,
2533                                   emacs_cv_c_restrict=no)])])
2534 case "$emacs_cv_c_restrict" in
2535   yes) emacs_restrict=restrict;;
2536   no) emacs_restrict="";;
2537   *) emacs_restrict="$emacs_cv_c_restrict";;
2538 esac
2539 if test "$emacs_restrict" != __restrict; then
2540   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2541     [Define to compiler's equivalent of C99 restrict keyword.
2542      Don't define if equivalent is `__restrict'.])
2543 fi
2544
2545 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2546   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2547                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2548 if test "$emacs_cv_c_restrict_arr" = yes; then
2549   AC_DEFINE(__restrict_arr, __restrict,
2550     [Define to compiler's equivalent of C99 restrict keyword in array
2551      declarations.  Define as empty for no equivalent.])
2552 fi
2553
2554 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2555 dnl how the tty code is related to POSIX and/or other versions of termios.
2556 dnl The following looks like a useful start.
2557 dnl
2558 dnl AC_SYS_POSIX_TERMIOS
2559 dnl if test $ac_cv_sys_posix_termios = yes; then
2560 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2561 dnl                                and macros for terminal control.])
2562 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2563 dnl fi
2564
2565 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2566
2567 # Set up the CFLAGS for real compilation, so we can substitute it.
2568 CFLAGS="$REAL_CFLAGS"
2569 CPPFLAGS="$REAL_CPPFLAGS"
2570
2571 #### Find out which version of Emacs this is.
2572 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2573          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2574 if test x"${version}" = x; then
2575   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2576 fi
2577
2578 ### Specify what sort of things we'll be editing into Makefile and config.h.
2579 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2580 AC_SUBST(version)
2581 AC_SUBST(configuration)
2582 AC_SUBST(canonical)
2583 AC_SUBST(srcdir)
2584 AC_SUBST(prefix)
2585 AC_SUBST(exec_prefix)
2586 AC_SUBST(bindir)
2587 AC_SUBST(datadir)
2588 AC_SUBST(sharedstatedir)
2589 AC_SUBST(libexecdir)
2590 AC_SUBST(mandir)
2591 AC_SUBST(infodir)
2592 AC_SUBST(lispdir)
2593 AC_SUBST(locallisppath)
2594 AC_SUBST(lisppath)
2595 AC_SUBST(x_default_search_path)
2596 AC_SUBST(etcdir)
2597 AC_SUBST(archlibdir)
2598 AC_SUBST(docdir)
2599 AC_SUBST(bitmapdir)
2600 AC_SUBST(gamedir)
2601 AC_SUBST(gameuser)
2602 AC_SUBST(c_switch_system)
2603 AC_SUBST(c_switch_machine)
2604 AC_SUBST(LD_SWITCH_X_SITE)
2605 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2606 AC_SUBST(C_SWITCH_X_SITE)
2607 AC_SUBST(CFLAGS)
2608 AC_SUBST(X_TOOLKIT_TYPE)
2609 AC_SUBST(machfile)
2610 AC_SUBST(opsysfile)
2611 AC_SUBST(GETLOADAVG_LIBS)
2612 AC_SUBST(carbon_appdir)
2613
2614 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2615                    [Define to the canonical Emacs configuration name.])
2616 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2617                    [Define to the options passed to configure.])
2618 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2619                    [Define to the used machine dependent file.])
2620 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2621                    [Define to the used os dependent file.])
2622 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2623 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2624  may need to deal with X Windows.  For instance, if you've defined
2625  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2626  your loader can find on its own, you might want to add "-L/..." or
2627  something similar.])
2628 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2629                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2630                     in case it's needed (for Solaris, for example).])
2631 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2632 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2633  may need to deal with X Windows.  For instance, if you've defined
2634  HAVE_X_WINDOWS above and your X include files aren't in a place
2635  that your compiler can find on its own, you might want to add
2636  "-I/..." or something similar.])
2637 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2638                    [Define to the unexec source file name.])
2639
2640 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2641   AC_DEFINE(HAVE_X_WINDOWS, 1,
2642             [Define to 1 if you want to use the X window system.])
2643 fi
2644 if test "${USE_X_TOOLKIT}" != "none" ; then
2645   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2646 fi
2647 if test "${HAVE_X11}" = "yes" ; then
2648   AC_DEFINE(HAVE_X11, 1,
2649             [Define to 1 if you want to use version 11 of X windows.
2650              Otherwise, Emacs expects to use version 10.])
2651 fi
2652 if test "${HAVE_MENUS}" = "yes" ; then
2653   AC_DEFINE(HAVE_MENUS, 1,
2654             [Define to 1 if you have mouse menus.
2655              (This is automatic if you use X, but the option to specify it remains.)
2656              It is also defined with other window systems that support xmenu.c.])
2657 fi
2658 if test "${GNU_MALLOC}" = "yes" ; then
2659   AC_DEFINE(GNU_MALLOC, 1,
2660             [Define to 1 if you want to use the GNU memory allocator.])
2661 fi
2662 if test "${REL_ALLOC}" = "yes" ; then
2663   AC_DEFINE(REL_ALLOC, 1,
2664             [Define REL_ALLOC if you want to use the relocating allocator for
2665              buffer space.])
2666 fi
2667
2668
2669 AH_TOP([/* GNU Emacs site configuration template file.
2670    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2671      2006, 2007, 2008  Free Software Foundation, Inc.
2672
2673 This file is part of GNU Emacs.
2674
2675 GNU Emacs is free software; you can redistribute it and/or modify
2676 it under the terms of the GNU General Public License as published by
2677 the Free Software Foundation; either version 3, or (at your option)
2678 any later version.
2679
2680 GNU Emacs is distributed in the hope that it will be useful,
2681 but WITHOUT ANY WARRANTY; without even the implied warranty of
2682 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2683 GNU General Public License for more details.
2684
2685 You should have received a copy of the GNU General Public License
2686 along with GNU Emacs; see the file COPYING.  If not, write to the
2687 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
2688 Boston, MA 02110-1301, USA.  */
2689
2690
2691 /* No code in Emacs #includes config.h twice, but some bits of code
2692    intended to work with other packages as well (like gmalloc.c)
2693    think they can include it as many times as they like.  */
2694 #ifndef EMACS_CONFIG_H
2695 #define EMACS_CONFIG_H
2696 ])dnl
2697
2698 AH_BOTTOM([
2699 /* If we're using any sort of window system, define some consequences.  */
2700 #ifdef HAVE_X_WINDOWS
2701 #define HAVE_WINDOW_SYSTEM
2702 #define MULTI_KBOARD
2703 #define HAVE_MOUSE
2704 #endif
2705
2706 /* Multi-tty support relies on MULTI_KBOARD.  It seems safe to turn it
2707    on unconditionally. */
2708 #ifndef MULTI_KBOARD
2709 #define MULTI_KBOARD
2710 #endif
2711
2712 /* If we're using the Carbon API on Mac OS X, define a few more
2713    variables as well.  */
2714 #ifdef HAVE_CARBON
2715 #define HAVE_WINDOW_SYSTEM
2716 #define HAVE_MOUSE
2717 #endif
2718
2719 /* Define USER_FULL_NAME to return a string
2720    that is the user's full name.
2721    It can assume that the variable `pw'
2722    points to the password file entry for this user.
2723
2724    At some sites, the pw_gecos field contains
2725    the user's full name.  If neither this nor any other
2726    field contains the right thing, use pw_name,
2727    giving the user's login name, since that is better than nothing.  */
2728 #define USER_FULL_NAME pw->pw_gecos
2729
2730 /* Define AMPERSAND_FULL_NAME if you use the convention
2731    that & in the full name stands for the login id.  */
2732 /* Turned on June 1996 supposing nobody will mind it.  */
2733 #define AMPERSAND_FULL_NAME
2734
2735 /* We have blockinput.h.  */
2736 #define DO_BLOCK_INPUT
2737
2738 /* Define HAVE_SOUND if we have sound support.  We know it works
2739    and compiles only on the specified platforms.   For others,
2740    it probably doesn't make sense to try.  */
2741
2742 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2743 #ifdef HAVE_MACHINE_SOUNDCARD_H
2744 #define HAVE_SOUND 1
2745 #endif
2746 #ifdef HAVE_SYS_SOUNDCARD_H
2747 #define HAVE_SOUND 1
2748 #endif
2749 #ifdef HAVE_SOUNDCARD_H
2750 #define HAVE_SOUND 1
2751 #endif
2752 #ifdef HAVE_ALSA
2753 #define HAVE_SOUND 1
2754 #endif
2755 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2756
2757 /* If using GNU, then support inline function declarations. */
2758 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2759    generally, because even if non-gcc compilers accept `inline', they
2760    may reject `extern inline'.  */
2761 #if defined (__GNUC__) && defined (OPTIMIZE)
2762 #define INLINE __inline__
2763 #else
2764 #define INLINE
2765 #endif
2766
2767 /* Include the os and machine dependent files.  */
2768 #include config_opsysfile
2769 #include config_machfile
2770
2771 /* If no remapping takes place, static variables cannot be dumped as
2772    pure, so don't worry about the `static' keyword. */
2773 #ifdef NO_REMAP
2774 #undef static
2775 #endif
2776
2777 /* Define `subprocesses' should be defined if you want to
2778    have code for asynchronous subprocesses
2779    (as used in M-x compile and M-x shell).
2780    These do not work for some USG systems yet;
2781    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
2782
2783 #ifndef VMS
2784 #ifndef USG
2785 /* #define subprocesses */
2786 #endif
2787 #endif
2788
2789 /* SIGTYPE is the macro we actually use.  */
2790 #ifndef SIGTYPE
2791 #define SIGTYPE RETSIGTYPE
2792 #endif
2793
2794 #ifdef emacs /* Don't do this for lib-src.  */
2795 /* Tell regex.c to use a type compatible with Emacs.  */
2796 #define RE_TRANSLATE_TYPE Lisp_Object
2797 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2798 #ifdef make_number
2799 /* If make_number is a macro, use it.  */
2800 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2801 #else
2802 /* If make_number is a function, avoid it.  */
2803 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2804 #endif
2805 #endif
2806
2807 /* Avoid link-time collision with system mktime if we will use our own.  */
2808 #if ! HAVE_MKTIME || BROKEN_MKTIME
2809 #define mktime emacs_mktime
2810 #endif
2811
2812 #define my_strftime nstrftime   /* for strftime.c */
2813
2814 /* The rest of the code currently tests the CPP symbol BSTRING.
2815    Override any claims made by the system-description files.
2816    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2817 #undef BSTRING
2818 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2819 #define BSTRING
2820 #endif
2821
2822 /* Some of the files of Emacs which are intended for use with other
2823    programs assume that if you have a config.h file, you must declare
2824    the type of getenv.
2825
2826    This declaration shouldn't appear when alloca.s or Makefile.in
2827    includes config.h.  */
2828 #ifndef NOT_C_CODE
2829 extern char *getenv ();
2830 #endif
2831
2832 /* These default definitions are good for almost all machines.
2833    The exceptions override them in m/MACHINE.h.  */
2834
2835 #ifndef BITS_PER_CHAR
2836 #define BITS_PER_CHAR 8
2837 #endif
2838
2839 #ifndef BITS_PER_SHORT
2840 #define BITS_PER_SHORT 16
2841 #endif
2842
2843 /* Note that lisp.h uses this in a preprocessor conditional, so it
2844    would not work to use sizeof.  That being so, we do all of them
2845    without sizeof, for uniformity's sake.  */
2846 #ifndef BITS_PER_INT
2847 #define BITS_PER_INT 32
2848 #endif
2849
2850 #ifndef BITS_PER_LONG
2851 #ifdef _LP64
2852 #define BITS_PER_LONG 64
2853 #else
2854 #define BITS_PER_LONG 32
2855 #endif
2856 #endif
2857
2858 /* Define if the compiler supports function prototypes.  It may do so
2859    but not define __STDC__ (e.g. DEC C by default) or may define it as
2860    zero.  */
2861 #undef PROTOTYPES
2862 /* For mktime.c:  */
2863 #ifndef __P
2864 # if defined PROTOTYPES
2865 #  define __P(args) args
2866 # else
2867 #  define __P(args) ()
2868 # endif  /* GCC.  */
2869 #endif /* __P */
2870
2871 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2872 #ifndef NOT_C_CODE
2873 #ifdef HAVE_STRING_H
2874 #include "string.h"
2875 #endif
2876 #ifdef HAVE_STRINGS_H
2877 #include "strings.h"  /* May be needed for bcopy & al. */
2878 #endif
2879 #ifdef HAVE_STDLIB_H
2880 #include <stdlib.h>
2881 #endif
2882 #ifndef __GNUC__
2883 # ifdef HAVE_ALLOCA_H
2884 #  include <alloca.h>
2885 # else /* AIX files deal with #pragma.  */
2886 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2887 char *alloca ();
2888 #  endif
2889 # endif /* HAVE_ALLOCA_H */
2890 #endif /* __GNUC__ */
2891 #ifndef HAVE_SIZE_T
2892 typedef unsigned size_t;
2893 #endif
2894 #endif /* NOT_C_CODE */
2895
2896 /* Define HAVE_X_I18N if we have usable i18n support.  */
2897
2898 #ifdef HAVE_X11R6
2899 #define HAVE_X_I18N
2900 #elif !defined X11R5_INHIBIT_I18N
2901 #define HAVE_X_I18N
2902 #endif
2903
2904 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2905
2906 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2907 #define HAVE_X11R6_XIM
2908 #endif
2909
2910 /* Should we enable expensive run-time checking of data types?  */
2911 #undef ENABLE_CHECKING
2912
2913 #if defined __GNUC__ && (__GNUC__ > 2 \
2914                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2915 #define NO_RETURN       __attribute__ ((__noreturn__))
2916 #else
2917 #define NO_RETURN       /* nothing */
2918 #endif
2919
2920 /* These won't be used automatically yet.  We also need to know, at least,
2921    that the stack is continuous.  */
2922 #ifdef __GNUC__
2923 #  ifndef GC_SETJMP_WORKS
2924   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2925      see NON_SAVING_SETJMP in the target descriptions.  */
2926   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2927      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2928      Fixme: Deal with SVR3.  */
2929 #    define GC_SETJMP_WORKS 1
2930 #  endif
2931 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2932 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2933 #  endif
2934 #endif
2935
2936 #ifndef HAVE_BCOPY
2937 #define bcopy(a,b,s) memcpy (b,a,s)
2938 #endif
2939 #ifndef HAVE_BZERO
2940 #define bzero(a,s) memset (a,0,s)
2941 #endif
2942 #ifndef HAVE_BCMP
2943 #define BCMP memcmp
2944 #endif
2945
2946 #endif /* EMACS_CONFIG_H */
2947
2948 /*
2949 Local Variables:
2950 mode: c
2951 End:
2952 */
2953 ])dnl
2954
2955 #### Report on what we decided to do.
2956 #### Report GTK as a toolkit, even if it doesn't use Xt.
2957 #### It makes printing result more understandable as using GTK sets
2958 #### toolkit_scroll_bars to yes by default.
2959 if test "${HAVE_GTK}" = "yes"; then
2960   USE_X_TOOLKIT=GTK
2961 fi
2962
2963 echo "
2964 Configured for \`${canonical}'.
2965
2966   Where should the build process find the source code?    ${srcdir}
2967   What operating system and machine description files should Emacs use?
2968         \`${opsysfile}' and \`${machfile}'
2969   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2970   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2971   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2972   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2973   What window system should Emacs use?                    ${window_system}
2974   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2975
2976 if test -n "${x_includes}"; then
2977 echo "  Where do we find X Windows header files?                ${x_includes}"
2978 else
2979 echo "  Where do we find X Windows header files?                Standard dirs"
2980 fi
2981 if test -n "${x_libraries}"; then
2982 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2983 else
2984 echo "  Where do we find X Windows libraries?                   Standard dirs"
2985 fi
2986
2987 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2988 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2989 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2990 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2991 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2992 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2993 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2994 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2995 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2996 echo "  Does Emacs use a font backend?                          ${USE_FONT_BACKEND}"
2997
2998 if test "${USE_FONT_BACKEND}" = "yes"; then
2999   echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3000   echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3001   echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3002   echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3003 fi
3004 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
3005 echo
3006
3007 if test $USE_XASSERTS = yes; then
3008    echo "  Compiling with asserts turned on."
3009    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3010 fi
3011
3012 if test $USE_SYNC_INPUT = yes; then
3013    echo "  Compiling with sync input."
3014    CPPFLAGS="$CPPFLAGS -DSYNC_INPUT=1"
3015 fi
3016
3017 echo
3018
3019 if test "$USE_X_TOOLKIT" = GTK; then
3020   case "$canonical" in
3021   *cygwin*)
3022     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
3023   will probably get a crash on startup.  If this happens, please use another
3024   toolkit for Emacs.  See etc/PROBLEMS for more information."
3025   ;;
3026   esac
3027 fi
3028
3029
3030 if test "$HAVE_CARBON" = "yes"; then
3031    echo
3032    echo "Warning: The Mac Carbon port is currently unsupported and has
3033 known problems.  It is not recommended for use by non-developers.
3034 Read the emacs-devel archives for more information."
3035    echo
3036 fi
3037
3038 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3039   echo "D-Bus integration has been tested for GNU/Linux only."
3040   echo
3041 fi
3042
3043
3044 # Remove any trailing slashes in these variables.
3045 [test "${prefix}" != NONE &&
3046   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3047 test "${exec_prefix}" != NONE &&
3048   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3049
3050 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3051 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3052 ## from Makefile.c can correctly provide the arg `-traditional' to the
3053 ## C preprocessor.
3054
3055 AC_EGREP_CPP(yes..yes,
3056         [yes..yes],
3057         CPP_NEED_TRADITIONAL=no,
3058         CPP_NEED_TRADITIONAL=yes)
3059
3060 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3061         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3062         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3063         lwlib/Makefile lisp/Makefile leim/Makefile, [
3064
3065 ### Make the necessary directories, if they don't exist.
3066 for dir in etc lisp ; do
3067   test -d ${dir} || mkdir ${dir}
3068 done
3069
3070 # Build src/Makefile from ${srcdir}/src/Makefile.c
3071 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3072 # This must be done after src/config.h is built, since we rely on that file.
3073
3074 # Now get this: Some word that is part of the ${srcdir} directory name
3075 # or the ${configuration} value might, just might, happen to be an
3076 # identifier like `sun4' or `i386' or something, and be predefined by
3077 # the C preprocessor to some helpful value like 1, or maybe the empty
3078 # string.  Needless to say consequent macro substitutions are less
3079 # than conducive to the makefile finding the correct directory.
3080 [undefs="`echo $top_srcdir $configuration $canonical |
3081 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3082     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3083 `"]
3084
3085 echo creating src/epaths.h
3086 ${MAKE-make} epaths-force
3087
3088 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3089 # `..' to `. .'  unless invoked with -traditional
3090
3091 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3092   CPPFLAGS="$CPPFLAGS -traditional"
3093 fi
3094
3095 echo creating lib-src/Makefile
3096 ( cd lib-src
3097   rm -f junk.c junk1.c junk2.c
3098   sed -e '/start of cpp stuff/q' \
3099       < Makefile.c > junk1.c
3100   sed -e '1,/start of cpp stuff/d'\
3101       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3102       < Makefile.c > junk.c
3103   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3104       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3105   cat junk1.c junk2.c > Makefile.new
3106   rm -f junk.c junk1.c junk2.c
3107   chmod 444 Makefile.new
3108   mv -f Makefile.new Makefile
3109 )
3110
3111 echo creating src/Makefile
3112 ( cd src
3113   rm -f junk.c junk1.c junk2.c
3114   sed -e '/start of cpp stuff/q' \
3115       < Makefile.c > junk1.c
3116   sed -e '1,/start of cpp stuff/d'\
3117       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3118       < Makefile.c > junk.c
3119   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3120       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3121   cat junk1.c junk2.c > Makefile.new
3122   rm -f junk.c junk1.c junk2.c
3123   chmod 444 Makefile.new
3124   mv -f Makefile.new Makefile
3125 )
3126
3127 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3128   echo creating src/.gdbinit
3129   echo source $srcdir/src/.gdbinit > src/.gdbinit
3130 fi
3131
3132 # This is how we know whether to re-run configure in certain cases.
3133 touch src/config.stamp
3134
3135 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3136
3137 m4_if(dnl       Do not change this comment
3138    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3139 )dnl