lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems
   2
   3 ;; Copyright (C) 1993, 1994, 1996, 1997, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar frame-creation-function-alist
  31   (list (cons nil
  32               (if (fboundp 'tty-create-frame-with-faces)
  33                   'tty-create-frame-with-faces
  34                 (function
  35                  (lambda (parameters)
  36                    (error "Can't create multiple frames without a window system"))))))
  37   "Alist of window-system dependent functions to call to create a new frame.
  38 The window system startup file should add its frame creation
  39 function to this list, which should take an alist of parameters
  40 as its argument.")
  41
  42 (defvar window-system-default-frame-alist nil
  43   "Alist of window-system dependent default frame parameters.
  44 These may be set in your init file, like this:
  45
  46     ;; Disable menubar and toolbar on the console, but enable them under X.
  47     (setq window-system-default-frame-alist
  48           '((x (menu-bar-lines . 1) (tool-bar-lines . 1))
  49             (nil (menu-bar-lines . 0) (tool-bar-lines . 0))))
  50
  51 Also see `default-frame-alist'.")
  52
  53 ;; The initial value given here used to ask for a minibuffer.
  54 ;; But that's not necessary, because the default is to have one.
  55 ;; By not specifying it here, we let an X resource specify it.
  56 (defcustom initial-frame-alist nil
  57   "*Alist of frame parameters for creating the initial X window frame.
  58 You can set this in your `.emacs' file; for example,
  59  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  60 Parameters specified here supersede the values given in `default-frame-alist'.
  61
  62 If the value calls for a frame without a minibuffer, and you have not created
  63 a minibuffer frame on your own, one is created according to
  64 `minibuffer-frame-alist'.
  65
  66 You can specify geometry-related options for just the initial frame
  67 by setting this variable in your `.emacs' file; however, they won't
  68 take effect until Emacs reads `.emacs', which happens after first creating
  69 the frame.  If you want the frame to have the proper geometry as soon
  70 as it appears, you need to use this three-step process:
  71 * Specify X resources to give the geometry you want.
  72 * Set `default-frame-alist' to override these options so that they
  73   don't affect subsequent frames.
  74 * Set `initial-frame-alist' in a way that matches the X resources,
  75   to override what you put in `default-frame-alist'."
  76   :type '(repeat (cons :format "%v"
  77                        (symbol :tag "Parameter")
  78                        (sexp :tag "Value")))
  79   :group 'frames)
  80
  81 (defcustom minibuffer-frame-alist '((width . 80) (height . 2))
  82   "*Alist of frame parameters for initially creating a minibuffer frame.
  83 You can set this in your `.emacs' file; for example,
  84  (setq minibuffer-frame-alist
  85    '((top . 1) (left . 1) (width . 80) (height . 2)))
  86 Parameters specified here supersede the values given in
  87 `default-frame-alist', for a minibuffer frame."
  88   :type '(repeat (cons :format "%v"
  89                        (symbol :tag "Parameter")
  90                        (sexp :tag "Value")))
  91   :group 'frames)
  92
  93 (defcustom pop-up-frame-alist nil
  94   "*Alist of frame parameters used when creating pop-up frames.
  95 Pop-up frames are used for completions, help, and the like.
  96 This variable can be set in your init file, like this:
  97   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  98 These supersede the values given in `default-frame-alist',
  99 for pop-up frames."
 100   :type '(repeat (cons :format "%v"
 101                        (symbol :tag "Parameter")
 102                        (sexp :tag "Value")))
 103   :group 'frames)
 104
 105 (setq pop-up-frame-function
 106       ;; Using `function' here caused some sort of problem.
 107       '(lambda ()
 108          (make-frame pop-up-frame-alist)))
 109
 110 (defcustom special-display-frame-alist
 111   '((height . 14) (width . 80) (unsplittable . t))
 112   "*Alist of frame parameters used when creating special frames.
 113 Special frames are used for buffers whose names are in
 114 `special-display-buffer-names' and for buffers whose names match
 115 one of the regular expressions in `special-display-regexps'.
 116 This variable can be set in your init file, like this:
 117   (setq special-display-frame-alist '((width . 80) (height . 20)))
 118 These supersede the values given in `default-frame-alist'."
 119   :type '(repeat (cons :format "%v"
 120                          (symbol :tag "Parameter")
 121                          (sexp :tag "Value")))
 122   :group 'frames)
 123
 124 (defun special-display-popup-frame (buffer &optional args)
 125   "Display BUFFER in its own frame, reusing an existing window if any.
 126 Return the window chosen.
 127 Currently we do not insist on selecting the window within its frame.
 128 If ARGS is an alist, use it as a list of frame parameter specs.
 129 If ARGS is a list whose car is a symbol,
 130 use (car ARGS) as a function to do the work.
 131 Pass it BUFFER as first arg, and (cdr ARGS) gives the rest of the args."
 132   (if (and args (symbolp (car args)))
 133       (apply (car args) buffer (cdr args))
 134     (let ((window (get-buffer-window buffer 0)))
 135       (or
 136        ;; If we have a window already, make it visible.
 137        (when window
 138          (let ((frame (window-frame window)))
 139            (make-frame-visible frame)
 140            (raise-frame frame)
 141            window))
 142        ;; Reuse the current window if the user requested it.
 143        (when (cdr (assq 'same-window args))
 144          (condition-case nil
 145              (progn (switch-to-buffer buffer) (selected-window))
 146            (error nil)))
 147        ;; Stay on the same frame if requested.
 148        (when (or (cdr (assq 'same-frame args)) (cdr (assq 'same-window args)))
 149          (let* ((pop-up-frames nil) (pop-up-windows t)
 150                 special-display-regexps special-display-buffer-names
 151                 (window (display-buffer buffer)))
 152            ;; Only do it if this is a new window:
 153            ;; (set-window-dedicated-p window t)
 154            window))
 155        ;; If no window yet, make one in a new frame.
 156        (let ((frame
 157               (with-current-buffer buffer
 158                 (make-frame (append args special-display-frame-alist)))))
 159          (set-window-buffer (frame-selected-window frame) buffer)
 160          (set-window-dedicated-p (frame-selected-window frame) t)
 161          (frame-selected-window frame))))))
 162
 163 (defun handle-delete-frame (event)
 164   "Handle delete-frame events from the X server."
 165   (interactive "e")
 166   (let ((frame (posn-window (event-start event)))
 167         (i 0)
 168         (tail (frame-list)))
 169     (while tail
 170       (and (frame-visible-p (car tail))
 171            (not (eq (car tail) frame))
 172           (setq i (1+ i)))
 173       (setq tail (cdr tail)))
 174     (if (> i 0)
 175         (delete-frame frame t)
 176       ;; Gildea@x.org says it is ok to ask questions before terminating.
 177       (save-buffers-kill-emacs))))
 178 \f
 179 ;;;; Arrangement of frames at startup
 180
 181 ;; 1) Load the window system startup file from the lisp library and read the
 182 ;; high-priority arguments (-q and the like).  The window system startup
 183 ;; file should create any frames specified in the window system defaults.
 184 ;;
 185 ;; 2) If no frames have been opened, we open an initial text frame.
 186 ;;
 187 ;; 3) Once the init file is done, we apply any newly set parameters
 188 ;; in initial-frame-alist to the frame.
 189
 190 ;; These are now called explicitly at the proper times,
 191 ;; since that is easier to understand.
 192 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
 193 ;; (add-hook 'before-init-hook 'frame-initialize)
 194 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
 195
 196 ;; If we create the initial frame, this is it.
 197 (defvar frame-initial-frame nil)
 198
 199 ;; Record the parameters used in frame-initialize to make the initial frame.
 200 (defvar frame-initial-frame-alist)
 201
 202 (defvar frame-initial-geometry-arguments nil)
 203
 204 ;; startup.el calls this function before loading the user's init
 205 ;; file - if there is no frame with a minibuffer open now, create
 206 ;; one to display messages while loading the init file.
 207 (defun frame-initialize ()
 208   "Create an initial frame if necessary."
 209   ;; Are we actually running under a window system at all?
 210   (if (and initial-window-system
 211            (not noninteractive)
 212            (not (eq initial-window-system 'pc)))
 213       (progn
 214         ;; Turn on special-display processing only if there's a window system.
 215         (setq special-display-function 'special-display-popup-frame)
 216
 217         ;; If there is no frame with a minibuffer besides the terminal
 218         ;; frame, then we need to create the opening frame.  Make sure
 219         ;; it has a minibuffer, but let initial-frame-alist omit the
 220         ;; minibuffer spec.
 221         (or (delq terminal-frame (minibuffer-frame-list))
 222             (progn
 223               (setq frame-initial-frame-alist
 224                     (append initial-frame-alist default-frame-alist nil))
 225               (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
 226                   (setq frame-initial-frame-alist
 227                         (cons '(horizontal-scroll-bars . t)
 228                               frame-initial-frame-alist)))
 229               (setq frame-initial-frame-alist
 230                     (cons (cons 'window-system initial-window-system)
 231                           frame-initial-frame-alist))
 232               (setq default-minibuffer-frame
 233                     (setq frame-initial-frame
 234                           (make-frame frame-initial-frame-alist)))
 235               ;; Delete any specifications for window geometry parameters
 236               ;; so that we won't reapply them in frame-notice-user-settings.
 237               ;; It would be wrong to reapply them then,
 238               ;; because that would override explicit user resizing.
 239               (setq initial-frame-alist
 240                     (frame-remove-geometry-params initial-frame-alist))))
 241         ;; At this point, we know that we have a frame open, so we
 242         ;; can delete the terminal frame.
 243         (delete-frame terminal-frame)
 244         (setq terminal-frame nil))))
 245
 246 (defvar frame-notice-user-settings t
 247   "Non-nil means function `frame-notice-user-settings' wasn't run yet.")
 248
 249 ;; startup.el calls this function after loading the user's init
 250 ;; file.  Now default-frame-alist and initial-frame-alist contain
 251 ;; information to which we must react; do what needs to be done.
 252 (defun frame-notice-user-settings ()
 253   "Act on user's init file settings of frame parameters.
 254 React to settings of `initial-frame-alist',
 255 `window-system-default-frame-alist' and `default-frame-alist'
 256 there (in decreasing order of priority)."
 257   ;; Make menu-bar-mode and default-frame-alist consistent.
 258   (when (boundp 'menu-bar-mode)
 259     (let ((default (assq 'menu-bar-lines default-frame-alist)))
 260       (if default
 261           (setq menu-bar-mode (not (eq (cdr default) 0)))
 262         (setq default-frame-alist
 263               (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
 264                     default-frame-alist)))))
 265
 266   ;; Make tool-bar-mode and default-frame-alist consistent.  Don't do
 267   ;; it in batch mode since that would leave a tool-bar-lines
 268   ;; parameter in default-frame-alist in a dumped Emacs, which is not
 269   ;; what we want.
 270   (when (and (boundp 'tool-bar-mode)
 271              (not noninteractive))
 272     (let ((default (assq 'tool-bar-lines default-frame-alist)))
 273       (if default
 274           (setq tool-bar-mode (not (eq (cdr default) 0)))
 275         (setq default-frame-alist
 276               (cons (cons 'tool-bar-lines (if tool-bar-mode 1 0))
 277                     default-frame-alist)))))
 278
 279   ;; Creating and deleting frames may shift the selected frame around,
 280   ;; and thus the current buffer.  Protect against that.  We don't
 281   ;; want to use save-excursion here, because that may also try to set
 282   ;; the buffer of the selected window, which fails when the selected
 283   ;; window is the minibuffer.
 284   (let ((old-buffer (current-buffer))
 285         (window-system-frame-alist (cdr (assq initial-window-system
 286                                               window-system-default-frame-alist))))
 287
 288     (when (and frame-notice-user-settings
 289                (null frame-initial-frame))
 290       ;; This case happens when we don't have a window system, and
 291       ;; also for MS-DOS frames.
 292       (let ((parms (frame-parameters frame-initial-frame)))
 293         ;; Don't change the frame names.
 294         (setq parms (delq (assq 'name parms) parms))
 295         ;; Can't modify the minibuffer parameter, so don't try.
 296         (setq parms (delq (assq 'minibuffer parms) parms))
 297         (modify-frame-parameters nil
 298                                  (if (null initial-window-system)
 299                                      (append initial-frame-alist
 300                                              window-system-frame-alist
 301                                              default-frame-alist
 302                                              parms
 303                                              nil)
 304                                    ;; initial-frame-alist and
 305                                    ;; default-frame-alist were already
 306                                    ;; applied in pc-win.el.
 307                                    parms))
 308         (if (null initial-window-system) ;; MS-DOS does this differently in pc-win.el
 309             (let ((newparms (frame-parameters))
 310                   (frame (selected-frame)))
 311               (tty-handle-reverse-video frame newparms)
 312               ;; If we changed the background color, we need to update
 313               ;; the background-mode parameter, and maybe some faces,
 314               ;; too.
 315               (when (assq 'background-color newparms)
 316                 (unless (or (assq 'background-mode initial-frame-alist)
 317                             (assq 'background-mode default-frame-alist))
 318                   (frame-set-background-mode frame))
 319                 (face-set-after-frame-default frame))))))
 320
 321     ;; If the initial frame is still around, apply initial-frame-alist
 322     ;; and default-frame-alist to it.
 323     (when (frame-live-p frame-initial-frame)
 324
 325       ;; When tool-bar has been switched off, correct the frame size
 326       ;; by the lines added in x-create-frame for the tool-bar and
 327       ;; switch `tool-bar-mode' off.
 328       (when (display-graphic-p)
 329         (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 330                                   (assq 'tool-bar-lines window-system-frame-alist)
 331                                   (assq 'tool-bar-lines default-frame-alist))))
 332           (when (and tool-bar-originally-present
 333                      (or (null tool-bar-lines)
 334                          (null (cdr tool-bar-lines))
 335                          (eq 0 (cdr tool-bar-lines))))
 336             (let* ((char-height (frame-char-height frame-initial-frame))
 337                    (image-height tool-bar-images-pixel-height)
 338                    (margin (cond ((and (consp tool-bar-button-margin)
 339                                        (integerp (cdr tool-bar-button-margin))
 340                                        (> tool-bar-button-margin 0))
 341                                   (cdr tool-bar-button-margin))
 342                                  ((and (integerp tool-bar-button-margin)
 343                                        (> tool-bar-button-margin 0))
 344                                   tool-bar-button-margin)
 345                                  (t 0)))
 346                    (relief (if (and (integerp tool-bar-button-relief)
 347                                     (> tool-bar-button-relief 0))
 348                                tool-bar-button-relief 3))
 349                    (lines (/ (+ image-height
 350                                 (* 2 margin)
 351                                 (* 2 relief)
 352                                 (1- char-height))
 353                              char-height))
 354                    (height (frame-parameter frame-initial-frame 'height))
 355                    (newparms (list (cons 'height (- height lines))))
 356                    (initial-top (cdr (assq 'top
 357                                            frame-initial-geometry-arguments)))
 358                    (top (frame-parameter frame-initial-frame 'top)))
 359               (when (and (consp initial-top) (eq '- (car initial-top)))
 360                 (let ((adjusted-top
 361                        (cond ((and (consp top)
 362                                    (eq '+ (car top)))
 363                               (list '+
 364                                     (+ (cadr top)
 365                                        (* lines char-height))))
 366                              ((and (consp top)
 367                                    (eq '- (car top)))
 368                               (list '-
 369                                     (- (cadr top)
 370                                        (* lines char-height))))
 371                              (t (+ top (* lines char-height))))))
 372                   (setq newparms
 373                         (append newparms
 374                                 `((top . ,adjusted-top))
 375                                 nil))))
 376               (modify-frame-parameters frame-initial-frame newparms)
 377               (tool-bar-mode -1)))))
 378
 379       ;; The initial frame we create above always has a minibuffer.
 380       ;; If the user wants to remove it, or make it a minibuffer-only
 381       ;; frame, then we'll have to delete the current frame and make a
 382       ;; new one; you can't remove or add a root window to/from an
 383       ;; existing frame.
 384       ;;
 385       ;; NOTE: default-frame-alist was nil when we created the
 386       ;; existing frame.  We need to explicitly include
 387       ;; default-frame-alist in the parameters of the screen we
 388       ;; create here, so that its new value, gleaned from the user's
 389       ;; .emacs file, will be applied to the existing screen.
 390       (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 391                             (assq 'minibuffer window-system-frame-alist)
 392                             (assq 'minibuffer default-frame-alist)
 393                             '(minibuffer . t)))
 394                    t))
 395           ;; Create the new frame.
 396           (let (parms new)
 397             ;; If the frame isn't visible yet, wait till it is.
 398             ;; If the user has to position the window,
 399             ;; Emacs doesn't know its real position until
 400             ;; the frame is seen to be visible.
 401             (while (not (cdr (assq 'visibility
 402                                    (frame-parameters frame-initial-frame))))
 403               (sleep-for 1))
 404             (setq parms (frame-parameters frame-initial-frame))
 405
 406             ;; Get rid of `name' unless it was specified explicitly before.
 407             (or (assq 'name frame-initial-frame-alist)
 408                 (setq parms (delq (assq 'name parms) parms)))
 409
 410             (setq parms (append initial-frame-alist
 411                                 window-system-frame-alist
 412                                 default-frame-alist
 413                                 parms
 414                                 nil))
 415
 416             ;; Get rid of `reverse', because that was handled
 417             ;; when we first made the frame.
 418             (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))
 419
 420             (if (assq 'height frame-initial-geometry-arguments)
 421                 (setq parms (assq-delete-all 'height parms)))
 422             (if (assq 'width frame-initial-geometry-arguments)
 423                 (setq parms (assq-delete-all 'width parms)))
 424             (if (assq 'left frame-initial-geometry-arguments)
 425                 (setq parms (assq-delete-all 'left parms)))
 426             (if (assq 'top frame-initial-geometry-arguments)
 427                 (setq parms (assq-delete-all 'top parms)))
 428             (setq new
 429                   (make-frame
 430                    ;; Use the geometry args that created the existing
 431                    ;; frame, rather than the parms we get for it.
 432                    (append frame-initial-geometry-arguments
 433                            '((user-size . t) (user-position . t))
 434                            parms)))
 435             ;; The initial frame, which we are about to delete, may be
 436             ;; the only frame with a minibuffer.  If it is, create a
 437             ;; new one.
 438             (or (delq frame-initial-frame (minibuffer-frame-list))
 439                 (make-initial-minibuffer-frame nil))
 440
 441             ;; If the initial frame is serving as a surrogate
 442             ;; minibuffer frame for any frames, we need to wean them
 443             ;; onto a new frame.  The default-minibuffer-frame
 444             ;; variable must be handled similarly.
 445             (let ((users-of-initial
 446                    (filtered-frame-list
 447                     (function (lambda (frame)
 448                                 (and (not (eq frame frame-initial-frame))
 449                                      (eq (window-frame
 450                                           (minibuffer-window frame))
 451                                          frame-initial-frame)))))))
 452               (if (or users-of-initial
 453                       (eq default-minibuffer-frame frame-initial-frame))
 454
 455                   ;; Choose an appropriate frame.  Prefer frames which
 456                   ;; are only minibuffers.
 457                   (let* ((new-surrogate
 458                           (car
 459                            (or (filtered-frame-list
 460                                 (function
 461                                  (lambda (frame)
 462                                    (eq (cdr (assq 'minibuffer
 463                                                   (frame-parameters frame)))
 464                                        'only))))
 465                                (minibuffer-frame-list))))
 466                          (new-minibuffer (minibuffer-window new-surrogate)))
 467
 468                     (if (eq default-minibuffer-frame frame-initial-frame)
 469                         (setq default-minibuffer-frame new-surrogate))
 470
 471                     ;; Wean the frames using frame-initial-frame as
 472                     ;; their minibuffer frame.
 473                     (mapcar
 474                      (function
 475                       (lambda (frame)
 476                         (modify-frame-parameters
 477                          frame (list (cons 'minibuffer new-minibuffer)))))
 478                      users-of-initial))))
 479
 480            ;; Redirect events enqueued at this frame to the new frame.
 481             ;; Is this a good idea?
 482             (redirect-frame-focus frame-initial-frame new)
 483
 484             ;; Finally, get rid of the old frame.
 485             (delete-frame frame-initial-frame t))
 486
 487         ;; Otherwise, we don't need all that rigamarole; just apply
 488         ;; the new parameters.
 489         (let (newparms allparms tail)
 490           (setq allparms (append initial-frame-alist
 491                                  window-system-frame-alist
 492                                  default-frame-alist nil))
 493           (if (assq 'height frame-initial-geometry-arguments)
 494               (setq allparms (assq-delete-all 'height allparms)))
 495           (if (assq 'width frame-initial-geometry-arguments)
 496               (setq allparms (assq-delete-all 'width allparms)))
 497           (if (assq 'left frame-initial-geometry-arguments)
 498               (setq allparms (assq-delete-all 'left allparms)))
 499           (if (assq 'top frame-initial-geometry-arguments)
 500               (setq allparms (assq-delete-all 'top allparms)))
 501           (setq tail allparms)
 502           ;; Find just the parms that have changed since we first
 503           ;; made this frame.  Those are the ones actually set by
 504           ;; the init file.  For those parms whose values we already knew
 505           ;; (such as those spec'd by command line options)
 506           ;; it is undesirable to specify the parm again
 507           ;; once the user has seen the frame and been able to alter it
 508           ;; manually.
 509           (while tail
 510             (let (newval oldval)
 511               (setq oldval (assq (car (car tail))
 512                                  frame-initial-frame-alist))
 513               (setq newval (cdr (assq (car (car tail)) allparms)))
 514               (or (and oldval (eq (cdr oldval) newval))
 515                   (setq newparms
 516                         (cons (cons (car (car tail)) newval) newparms))))
 517             (setq tail (cdr tail)))
 518           (setq newparms (nreverse newparms))
 519           (modify-frame-parameters frame-initial-frame
 520                                    newparms)
 521           ;; If we changed the background color,
 522           ;; we need to update the background-mode parameter
 523           ;; and maybe some faces too.
 524           (when (assq 'background-color newparms)
 525             (unless (assq 'background-mode newparms)
 526               (frame-set-background-mode frame-initial-frame))
 527             (face-set-after-frame-default frame-initial-frame)))))
 528
 529     ;; Restore the original buffer.
 530     (set-buffer old-buffer)
 531
 532     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 533     ;; Make sure frame-notice-user-settings does nothing if called twice.
 534     (setq frame-notice-user-settings nil)
 535     (setq frame-initial-frame nil)))
 536
 537 (defun make-initial-minibuffer-frame (display)
 538   (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
 539     (if display
 540         (make-frame-on-display display parms)
 541       (make-frame parms))))
 542
 543 ;;;; Creation of additional frames, and other frame miscellanea
 544
 545 (defun modify-all-frames-parameters (alist)
 546   "Modify all current and future frames' parameters according to ALIST.
 547 This changes `default-frame-alist' and possibly `initial-frame-alist'.
 548 See help of `modify-frame-parameters' for more information."
 549   (let (element)                        ;; temp
 550     (dolist (frame (frame-list))
 551       (modify-frame-parameters frame alist))
 552
 553     (dolist (pair alist)                ;; conses to add/replace
 554       ;; initial-frame-alist needs setting only when
 555       ;; frame-notice-user-settings is true
 556       (and frame-notice-user-settings
 557            (setq element (assoc (car pair) initial-frame-alist))
 558            (setq initial-frame-alist (delq element initial-frame-alist)))
 559       (and (setq element (assoc (car pair) default-frame-alist))
 560            (setq default-frame-alist (delq element default-frame-alist)))))
 561   (and frame-notice-user-settings
 562        (setq initial-frame-alist (append initial-frame-alist alist)))
 563   (setq default-frame-alist (append default-frame-alist alist)))
 564
 565 (defun get-other-frame ()
 566   "Return some frame other than the current frame.
 567 Create one if necessary.  Note that the minibuffer frame, if separate,
 568 is not considered (see `next-frame')."
 569   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 570                (make-frame)
 571              (next-frame (selected-frame)))))
 572     s))
 573
 574 (defun next-multiframe-window ()
 575   "Select the next window, regardless of which frame it is on."
 576   (interactive)
 577   (select-window (next-window (selected-window)
 578                               (> (minibuffer-depth) 0)
 579                               0))
 580   (select-frame-set-input-focus (selected-frame)))
 581
 582 (defun previous-multiframe-window ()
 583   "Select the previous window, regardless of which frame it is on."
 584   (interactive)
 585   (select-window (previous-window (selected-window)
 586                                   (> (minibuffer-depth) 0)
 587                                   0))
 588   (select-frame-set-input-focus (selected-frame)))
 589
 590 (defun make-frame-on-display (display &optional parameters)
 591   "Make a frame on X display DISPLAY.
 592 The optional second argument PARAMETERS specifies additional frame parameters."
 593   (interactive "sMake frame on display: ")
 594   (or (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
 595       (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
 596   (when (and (boundp 'x-initialized) (not x-initialized))
 597     (setq x-display-name display)
 598     (x-initialize-window-system))
 599   (make-frame `((window-system . x) (display . ,display) . ,parameters)))
 600
 601 (defun make-frame-on-tty (device type &optional parameters)
 602   "Make a frame on terminal DEVICE which is of type TYPE (e.g., \"xterm\").
 603 The optional third argument PARAMETERS specifies additional frame parameters."
 604   (interactive "fOpen frame on tty device: \nsTerminal type of %s: ")
 605   (unless device
 606     (error "Invalid terminal device"))
 607   (unless type
 608     (error "Invalid terminal type"))
 609   (make-frame `((window-system . nil) (tty . ,device) (tty-type . ,type) . ,parameters)))
 610
 611 (defun make-frame-command ()
 612   "Make a new frame, and select it if the terminal displays only one frame."
 613   (interactive)
 614   (if (and window-system (not (eq window-system 'pc)))
 615       (make-frame)
 616     (select-frame (make-frame))))
 617
 618 (defvar before-make-frame-hook nil
 619   "Functions to run before a frame is created.")
 620
 621 (defvar after-make-frame-functions nil
 622   "Functions to run after a frame is created.
 623 The functions are run with one arg, the newly created frame.")
 624
 625 (defvar after-setting-font-hook nil
 626   "Functions to run after a frame's font has been changed.")
 627
 628 ;; Alias, kept temporarily.
 629 (define-obsolete-function-alias 'new-frame 'make-frame "22.1")
 630
 631 (defun make-frame (&optional parameters)
 632   "Return a newly created frame displaying the current buffer.
 633 Optional argument PARAMETERS is an alist of parameters for the new frame.
 634 Each element of PARAMETERS should have the form (NAME . VALUE), for example:
 635
 636  (name . STRING)        The frame should be named STRING.
 637
 638  (width . NUMBER)       The frame should be NUMBER characters in width.
 639  (height . NUMBER)      The frame should be NUMBER text lines high.
 640
 641 You cannot specify either `width' or `height', you must use neither or both.
 642
 643  (minibuffer . t)       The frame should have a minibuffer.
 644  (minibuffer . nil)     The frame should have no minibuffer.
 645  (minibuffer . only)    The frame should contain only a minibuffer.
 646  (minibuffer . WINDOW)  The frame should use WINDOW as its minibuffer window.
 647
 648  (window-system . nil)  The frame should be displayed on a terminal device.
 649  (window-system . x)    The frame should be displayed in an X window.
 650
 651  (device . ID)          The frame should use the display device identified by ID.
 652
 653 Before the frame is created (via `frame-creation-function-alist'), functions on the
 654 hook `before-make-frame-hook' are run.  After the frame is created, functions
 655 on `after-make-frame-functions' are run with one arg, the newly created frame.
 656
 657 This function itself does not make the new frame the selected frame.
 658 The previously selected frame remains selected.  However, the
 659 window system may select the new frame for its own reasons, for
 660 instance if the frame appears under the mouse pointer and your
 661 setup is for focus to follow the pointer."
 662   (interactive)
 663   (let* ((w (cond
 664              ((assq 'device parameters)
 665               (let ((type (display-live-p (cdr (assq 'device parameters)))))
 666                 (cond
 667                  ((eq type t) nil)
 668                  ((eq type nil) (error "Display %s does not exist" (cdr (assq 'device parameters))))
 669                  (t type))))
 670              ((assq 'window-system parameters)
 671               (cdr (assq 'window-system parameters)))
 672              (t window-system)))
 673          (frame-creation-function (cdr (assq w frame-creation-function-alist)))
 674          frame)
 675     (unless frame-creation-function
 676       (error "Don't know how to create a frame on window system %s" w))
 677     (run-hooks 'before-make-frame-hook)
 678     (setq frame (funcall frame-creation-function (append parameters (cdr (assq w window-system-default-frame-alist)))))
 679     (normal-erase-is-backspace-setup-frame frame)
 680     (run-hook-with-args 'after-make-frame-functions frame)
 681     frame))
 682
 683 (defun filtered-frame-list (predicate)
 684   "Return a list of all live frames which satisfy PREDICATE."
 685   (let* ((frames (frame-list))
 686          (list frames))
 687     (while (consp frames)
 688       (unless (funcall predicate (car frames))
 689         (setcar frames nil))
 690       (setq frames (cdr frames)))
 691     (delq nil list)))
 692
 693 (defun minibuffer-frame-list ()
 694   "Return a list of all frames with their own minibuffers."
 695   (filtered-frame-list
 696    (function (lambda (frame)
 697                (eq frame (window-frame (minibuffer-window frame)))))))
 698
 699 (defun frames-on-display-list (&optional terminal)
 700   "Return a list of all frames on TERMINAL.
 701
 702 TERMINAL should be a terminal identifier (an integer), a frame,
 703 or a name of an X display (a string of the form
 704 HOST:SERVER.SCREEN).
 705
 706 If TERMINAL is omitted or nil, it defaults to the selected
 707 frame's terminal device."
 708   (let* ((terminal (terminal-id terminal))
 709          (func #'(lambda (frame)
 710                    (eq (frame-display frame) terminal))))
 711     (filtered-frame-list func)))
 712
 713 (defun framep-on-display (&optional display)
 714   "Return the type of frames on DISPLAY.
 715 DISPLAY may be a display id, a display name or a frame.  If it is
 716 a frame, its type is returned.
 717 If DISPLAY is omitted or nil, it defaults to the selected frame's display.
 718 All frames on a given display are of the same type."
 719   (or (display-live-p display)
 720       (framep display)
 721       (framep (car (frames-on-display-list display)))))
 722
 723 (defun frame-remove-geometry-params (param-list)
 724   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 725 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 726 `height', `user-size' and `user-position' parameters.
 727 Emacs uses this to avoid overriding explicit moves and resizings from
 728 the user during startup."
 729   (setq param-list (cons nil param-list))
 730   (let ((tail param-list))
 731     (while (consp (cdr tail))
 732       (if (and (consp (car (cdr tail)))
 733                (memq (car (car (cdr tail)))
 734                      '(height width top left user-position user-size)))
 735           (progn
 736             (setq frame-initial-geometry-arguments
 737                   (cons (car (cdr tail)) frame-initial-geometry-arguments))
 738             (setcdr tail (cdr (cdr tail))))
 739         (setq tail (cdr tail)))))
 740   (setq frame-initial-geometry-arguments
 741         (nreverse frame-initial-geometry-arguments))
 742   (cdr param-list))
 743
 744 (defcustom focus-follows-mouse t
 745   "*Non-nil if window system changes focus when you move the mouse.
 746 You should set this variable to tell Emacs how your window manager
 747 handles focus, since there is no way in general for Emacs to find out
 748 automatically."
 749   :type 'boolean
 750   :group 'frames
 751   :version "20.3")
 752
 753 (defun select-frame-set-input-focus (frame)
 754   "Select FRAME, raise it, and set input focus, if possible."
 755     (select-frame frame)
 756     (raise-frame frame)
 757     ;; Ensure, if possible, that frame gets input focus.
 758     (cond ((eq (window-system frame) 'x)
 759            (x-focus-frame frame))
 760           ((eq (window-system frame) 'w32)
 761            (w32-focus-frame frame)))
 762     (cond (focus-follows-mouse
 763            (set-mouse-position (selected-frame) (1- (frame-width)) 0))))
 764
 765 (defun other-frame (arg)
 766   "Select the ARG'th different visible frame on current display, and raise it.
 767 All frames are arranged in a cyclic order.
 768 This command selects the frame ARG steps away in that order.
 769 A negative ARG moves in the opposite order.
 770
 771 To make this command work properly, you must tell Emacs
 772 how the system (or the window manager) generally handles
 773 focus-switching between windows.  If moving the mouse onto a window
 774 selects it (gives it focus), set `focus-follows-mouse' to t.
 775 Otherwise, that variable should be nil."
 776   (interactive "p")
 777   (let ((frame (selected-frame)))
 778     (while (> arg 0)
 779       (setq frame (next-frame frame))
 780       (while (not (eq (frame-visible-p frame) t))
 781         (setq frame (next-frame frame)))
 782       (setq arg (1- arg)))
 783     (while (< arg 0)
 784       (setq frame (previous-frame frame))
 785       (while (not (eq (frame-visible-p frame) t))
 786         (setq frame (previous-frame frame)))
 787       (setq arg (1+ arg)))
 788     (select-frame-set-input-focus frame)))
 789
 790 (defun iconify-or-deiconify-frame ()
 791   "Iconify the selected frame, or deiconify if it's currently an icon."
 792   (interactive)
 793   (if (eq (cdr (assq 'visibility (frame-parameters))) t)
 794       (iconify-frame)
 795     (make-frame-visible)))
 796
 797 (defun suspend-frame ()
 798   "Do whatever is right to suspend the current frame.
 799 Calls `suspend-emacs' if invoked from the controlling terminal,
 800 `suspend-tty' from a secondary terminal, and
 801 `iconify-or-deiconify-frame' from an X frame."
 802   (interactive)
 803   (let ((type (framep (selected-frame))))
 804     (cond
 805      ((eq type 'x) (iconify-or-deiconify-frame))
 806      ((eq type t)
 807       (if (display-controlling-tty-p)
 808           (suspend-emacs)
 809         (suspend-tty)))
 810      (t (suspend-emacs)))))
 811
 812
 813 (defun make-frame-names-alist ()
 814   (let* ((current-frame (selected-frame))
 815          (falist
 816           (cons
 817            (cons (frame-parameter current-frame 'name) current-frame) nil))
 818          (frame (next-frame nil t)))
 819     (while (not (eq frame current-frame))
 820       (progn
 821         (setq falist (cons (cons (frame-parameter frame 'name) frame) falist))
 822         (setq frame (next-frame frame t))))
 823     falist))
 824
 825 (defvar frame-name-history nil)
 826 (defun select-frame-by-name (name)
 827   "Select the frame on the current terminal whose name is NAME and raise it.
 828 If there is no frame by that name, signal an error."
 829   (interactive
 830    (let* ((frame-names-alist (make-frame-names-alist))
 831            (default (car (car frame-names-alist)))
 832            (input (completing-read
 833                    (format "Select Frame (default %s): " default)
 834                    frame-names-alist nil t nil 'frame-name-history)))
 835      (if (= (length input) 0)
 836          (list default)
 837        (list input))))
 838   (let* ((frame-names-alist (make-frame-names-alist))
 839          (frame (cdr (assoc name frame-names-alist))))
 840     (or frame
 841         (error "There is no frame named `%s'" name))
 842     (make-frame-visible frame)
 843     (raise-frame frame)
 844     (select-frame frame)
 845     ;; Ensure, if possible, that frame gets input focus.
 846     (cond ((eq (window-system frame) 'x)
 847            (x-focus-frame frame))
 848           ((eq (window-system frame) 'w32)
 849            (w32-focus-frame frame)))
 850     (when focus-follows-mouse
 851       (set-mouse-position frame (1- (frame-width frame)) 0))))
 852 \f
 853 ;;;; Frame configurations
 854
 855 (defun current-frame-configuration ()
 856   "Return a list describing the positions and states of all frames.
 857 Its car is `frame-configuration'.
 858 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 859 where
 860   FRAME is a frame object,
 861   ALIST is an association list specifying some of FRAME's parameters, and
 862   WINDOW-CONFIG is a window configuration object for FRAME."
 863   (cons 'frame-configuration
 864         (mapcar (function
 865                  (lambda (frame)
 866                    (list frame
 867                          (frame-parameters frame)
 868                          (current-window-configuration frame))))
 869                 (frame-list))))
 870
 871 (defun set-frame-configuration (configuration &optional nodelete)
 872   "Restore the frames to the state described by CONFIGURATION.
 873 Each frame listed in CONFIGURATION has its position, size, window
 874 configuration, and other parameters set as specified in CONFIGURATION.
 875 However, this function does not restore deleted frames.
 876
 877 Ordinarily, this function deletes all existing frames not
 878 listed in CONFIGURATION.  But if optional second argument NODELETE
 879 is given and non-nil, the unwanted frames are iconified instead."
 880   (or (frame-configuration-p configuration)
 881       (signal 'wrong-type-argument
 882               (list 'frame-configuration-p configuration)))
 883   (let ((config-alist (cdr configuration))
 884         frames-to-delete)
 885     (mapcar (function
 886              (lambda (frame)
 887                (let ((parameters (assq frame config-alist)))
 888                  (if parameters
 889                      (progn
 890                        (modify-frame-parameters
 891                         frame
 892                         ;; Since we can't set a frame's minibuffer status,
 893                         ;; we might as well omit the parameter altogether.
 894                         (let* ((parms (nth 1 parameters))
 895                                (mini (assq 'minibuffer parms)))
 896                           (if mini (setq parms (delq mini parms)))
 897                           parms))
 898                        (set-window-configuration (nth 2 parameters)))
 899                    (setq frames-to-delete (cons frame frames-to-delete))))))
 900             (frame-list))
 901     (if nodelete
 902         ;; Note: making frames invisible here was tried
 903         ;; but led to some strange behavior--each time the frame
 904         ;; was made visible again, the window manager asked afresh
 905         ;; for where to put it.
 906         (mapcar 'iconify-frame frames-to-delete)
 907       (mapcar 'delete-frame frames-to-delete))))
 908 \f
 909 ;;;; Convenience functions for accessing and interactively changing
 910 ;;;; frame parameters.
 911
 912 (defun frame-height (&optional frame)
 913   "Return number of lines available for display on FRAME.
 914 If FRAME is omitted, describe the currently selected frame."
 915   (cdr (assq 'height (frame-parameters frame))))
 916
 917 (defun frame-width (&optional frame)
 918   "Return number of columns available for display on FRAME.
 919 If FRAME is omitted, describe the currently selected frame."
 920   (cdr (assq 'width (frame-parameters frame))))
 921
 922 (defalias 'set-default-font 'set-frame-font)
 923 (defun set-frame-font (font-name &optional keep-size)
 924   "Set the font of the selected frame to FONT-NAME.
 925 When called interactively, prompt for the name of the font to use.
 926 To get the frame's current default font, use `frame-parameters'.
 927
 928 The default behavior is to keep the numbers of lines and columns in
 929 the frame, thus may change its pixel size.  If optional KEEP-SIZE is
 930 non-nil (interactively, prefix argument) the current frame size (in
 931 pixels) is kept by adjusting the numbers of the lines and columns."
 932   (interactive
 933    (let* ((completion-ignore-case t)
 934           (font (completing-read "Font name: "
 935                          (mapcar #'list
 936                                  ;; x-list-fonts will fail with an error
 937                                  ;; if this frame doesn't support fonts.
 938                                  (x-list-fonts "*" nil (selected-frame)))
 939                          nil nil nil nil
 940                          (frame-parameter nil 'font))))
 941      (list font current-prefix-arg)))
 942   (let (fht fwd)
 943     (if keep-size
 944         (setq fht (* (frame-parameter nil 'height) (frame-char-height))
 945               fwd (* (frame-parameter nil 'width)  (frame-char-width))))
 946     (modify-frame-parameters (selected-frame)
 947                              (list (cons 'font font-name)))
 948     (if keep-size
 949         (modify-frame-parameters
 950          (selected-frame)
 951          (list (cons 'height (round fht (frame-char-height)))
 952                (cons 'width (round fwd (frame-char-width)))))))
 953   (run-hooks 'after-setting-font-hook 'after-setting-font-hooks))
 954
 955 (defun set-frame-parameter (frame parameter value)
 956   (modify-frame-parameters frame (list (cons parameter value))))
 957
 958 (defun set-background-color (color-name)
 959   "Set the background color of the selected frame to COLOR-NAME.
 960 When called interactively, prompt for the name of the color to use.
 961 To get the frame's current background color, use `frame-parameters'."
 962   (interactive (list (facemenu-read-color)))
 963   (modify-frame-parameters (selected-frame)
 964                            (list (cons 'background-color color-name)))
 965   (or window-system
 966       (face-set-after-frame-default (selected-frame))))
 967
 968 (defun set-foreground-color (color-name)
 969   "Set the foreground color of the selected frame to COLOR-NAME.
 970 When called interactively, prompt for the name of the color to use.
 971 To get the frame's current foreground color, use `frame-parameters'."
 972   (interactive (list (facemenu-read-color)))
 973   (modify-frame-parameters (selected-frame)
 974                            (list (cons 'foreground-color color-name)))
 975   (or window-system
 976       (face-set-after-frame-default (selected-frame))))
 977
 978 (defun set-cursor-color (color-name)
 979   "Set the text cursor color of the selected frame to COLOR-NAME.
 980 When called interactively, prompt for the name of the color to use.
 981 To get the frame's current cursor color, use `frame-parameters'."
 982   (interactive (list (facemenu-read-color)))
 983   (modify-frame-parameters (selected-frame)
 984                            (list (cons 'cursor-color color-name))))
 985
 986 (defun set-mouse-color (color-name)
 987   "Set the color of the mouse pointer of the selected frame to COLOR-NAME.
 988 When called interactively, prompt for the name of the color to use.
 989 To get the frame's current mouse color, use `frame-parameters'."
 990   (interactive (list (facemenu-read-color)))
 991   (modify-frame-parameters (selected-frame)
 992                            (list (cons 'mouse-color
 993                                        (or color-name
 994                                            (cdr (assq 'mouse-color
 995                                                       (frame-parameters))))))))
 996
 997 (defun set-border-color (color-name)
 998   "Set the color of the border of the selected frame to COLOR-NAME.
 999 When called interactively, prompt for the name of the color to use.
1000 To get the frame's current border color, use `frame-parameters'."
1001   (interactive (list (facemenu-read-color)))
1002   (modify-frame-parameters (selected-frame)
1003                            (list (cons 'border-color color-name))))
1004
1005 (defun auto-raise-mode (arg)
1006   "Toggle whether or not the selected frame should auto-raise.
1007 With arg, turn auto-raise mode on if and only if arg is positive.
1008 Note that this controls Emacs's own auto-raise feature.
1009 Some window managers allow you to enable auto-raise for certain windows.
1010 You can use that for Emacs windows if you wish, but if you do,
1011 that is beyond the control of Emacs and this command has no effect on it."
1012   (interactive "P")
1013   (if (null arg)
1014       (setq arg
1015             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
1016                 -1 1)))
1017   (if (> arg 0)
1018       (raise-frame (selected-frame)))
1019   (modify-frame-parameters (selected-frame)
1020                            (list (cons 'auto-raise (> arg 0)))))
1021
1022 (defun auto-lower-mode (arg)
1023   "Toggle whether or not the selected frame should auto-lower.
1024 With arg, turn auto-lower mode on if and only if arg is positive.
1025 Note that this controls Emacs's own auto-lower feature.
1026 Some window managers allow you to enable auto-lower for certain windows.
1027 You can use that for Emacs windows if you wish, but if you do,
1028 that is beyond the control of Emacs and this command has no effect on it."
1029   (interactive "P")
1030   (if (null arg)
1031       (setq arg
1032             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
1033                 -1 1)))
1034   (modify-frame-parameters (selected-frame)
1035                            (list (cons 'auto-lower (> arg 0)))))
1036 (defun set-frame-name (name)
1037   "Set the name of the selected frame to NAME.
1038 When called interactively, prompt for the name of the frame.
1039 The frame name is displayed on the modeline if the terminal displays only
1040 one frame, otherwise the name is displayed on the frame's caption bar."
1041   (interactive "sFrame name: ")
1042   (modify-frame-parameters (selected-frame)
1043                            (list (cons 'name name))))
1044
1045 (defun frame-current-scroll-bars (&optional frame)
1046   "Return the current scroll-bar settings in frame FRAME.
1047 Value is a cons (VERTICAL . HORIZ0NTAL) where VERTICAL specifies the
1048 current location of the vertical scroll-bars (left, right, or nil),
1049 and HORIZONTAL specifies the current location of the horizontal scroll
1050 bars (top, bottom, or nil)."
1051   (let ((vert (frame-parameter frame 'vertical-scroll-bars))
1052         (hor nil))
1053     (unless (memq vert '(left right nil))
1054       (setq vert default-frame-scroll-bars))
1055     (cons vert hor)))
1056 \f
1057 ;;;; Frame/display capabilities.
1058 (defun selected-display ()
1059   "Return the display that is now selected."
1060   (frame-display (selected-frame)))
1061
1062 (defun display-mouse-p (&optional display)
1063   "Return non-nil if DISPLAY has a mouse available.
1064 DISPLAY can be a display name, a frame, or nil (meaning the selected
1065 frame's display)."
1066   (let ((frame-type (framep-on-display display)))
1067     (cond
1068      ((eq frame-type 'pc)
1069       (msdos-mouse-p))
1070      ((eq system-type 'windows-nt)
1071       (with-no-warnings
1072        (> w32-num-mouse-buttons 0)))
1073      ((memq frame-type '(x mac))
1074       t)    ;; We assume X and Mac *always* have a pointing device
1075      (t
1076       (or (and (featurep 'xt-mouse)
1077                xterm-mouse-mode)
1078           ;; t-mouse is distributed with the GPM package.  It doesn't have
1079           ;; a toggle.
1080           (featurep 't-mouse))))))
1081
1082 (defun display-popup-menus-p (&optional display)
1083   "Return non-nil if popup menus are supported on DISPLAY.
1084 DISPLAY can be a display name, a frame, or nil (meaning the selected
1085 frame's display).
1086 Support for popup menus requires that the mouse be available."
1087   (and
1088    (let ((frame-type (framep-on-display display)))
1089      (memq frame-type '(x w32 pc mac)))
1090    (display-mouse-p display)))
1091
1092 (defun display-graphic-p (&optional display)
1093   "Return non-nil if DISPLAY is a graphic display.
1094 Graphical displays are those which are capable of displaying several
1095 frames and several different fonts at once.  This is true for displays
1096 that use a window system such as X, and false for text-only terminals.
1097 DISPLAY can be a display name, a frame, or nil (meaning the selected
1098 frame's display)."
1099   (not (null (memq (framep-on-display display) '(x w32 mac)))))
1100
1101 (defun display-images-p (&optional display)
1102   "Return non-nil if DISPLAY can display images.
1103
1104 DISPLAY can be a display name, a frame, or nil (meaning the selected
1105 frame's display)."
1106   (and (display-graphic-p display)
1107        (fboundp 'image-mask-p)
1108        (fboundp 'image-size)))
1109
1110 (defalias 'display-multi-frame-p 'display-graphic-p)
1111 (defalias 'display-multi-font-p 'display-graphic-p)
1112
1113 (defun display-selections-p (&optional display)
1114   "Return non-nil if DISPLAY supports selections.
1115 A selection is a way to transfer text or other data between programs
1116 via special system buffers called `selection' or `cut buffer' or
1117 `clipboard'.
1118 DISPLAY can be a display name, a frame, or nil (meaning the selected
1119 frame's display)."
1120   (let ((frame-type (framep-on-display display)))
1121     (cond
1122      ((eq frame-type 'pc)
1123       ;; MS-DOG frames support selections when Emacs runs inside
1124       ;; the Windows' DOS Box.
1125       (with-no-warnings
1126        (not (null dos-windows-version))))
1127      ((memq frame-type '(x w32 mac))
1128       t)    ;; FIXME?
1129      (t
1130       nil))))
1131
1132 (defun display-screens (&optional display)
1133   "Return the number of screens associated with DISPLAY."
1134   (let ((frame-type (framep-on-display display)))
1135     (cond
1136      ((memq frame-type '(x w32 mac))
1137       (x-display-screens display))
1138      (t
1139       1))))
1140
1141 (defun display-pixel-height (&optional display)
1142   "Return the height of DISPLAY's screen in pixels.
1143 For character terminals, each character counts as a single pixel."
1144   (let ((frame-type (framep-on-display display)))
1145     (cond
1146      ((memq frame-type '(x w32 mac))
1147       (x-display-pixel-height display))
1148      (t
1149       (frame-height (if (framep display) display (selected-frame)))))))
1150
1151 (defun display-pixel-width (&optional display)
1152   "Return the width of DISPLAY's screen in pixels.
1153 For character terminals, each character counts as a single pixel."
1154   (let ((frame-type (framep-on-display display)))
1155     (cond
1156      ((memq frame-type '(x w32 mac))
1157       (x-display-pixel-width display))
1158      (t
1159       (frame-width (if (framep display) display (selected-frame)))))))
1160
1161 (defun display-mm-height (&optional display)
1162   "Return the height of DISPLAY's screen in millimeters.
1163 If the information is unavailable, value is nil."
1164   (and (memq (framep-on-display display) '(x w32 mac))
1165        (x-display-mm-height display)))
1166
1167 (defun display-mm-width (&optional display)
1168   "Return the width of DISPLAY's screen in millimeters.
1169 If the information is unavailable, value is nil."
1170   (and (memq (framep-on-display display) '(x w32 mac))
1171        (x-display-mm-width display)))
1172
1173 (defun display-backing-store (&optional display)
1174   "Return the backing store capability of DISPLAY's screen.
1175 The value may be `always', `when-mapped', `not-useful', or nil if
1176 the question is inapplicable to a certain kind of display."
1177   (let ((frame-type (framep-on-display display)))
1178     (cond
1179      ((memq frame-type '(x w32 mac))
1180       (x-display-backing-store display))
1181      (t
1182       'not-useful))))
1183
1184 (defun display-save-under (&optional display)
1185   "Return non-nil if DISPLAY's screen supports the SaveUnder feature."
1186   (let ((frame-type (framep-on-display display)))
1187     (cond
1188      ((memq frame-type '(x w32 mac))
1189       (x-display-save-under display))
1190      (t
1191       'not-useful))))
1192
1193 (defun display-planes (&optional display)
1194   "Return the number of planes supported by DISPLAY."
1195   (let ((frame-type (framep-on-display display)))
1196     (cond
1197      ((memq frame-type '(x w32 mac))
1198       (x-display-planes display))
1199      ((eq frame-type 'pc)
1200       4)
1201      (t
1202       (truncate (log (length (tty-color-alist)) 2))))))
1203
1204 (defun display-color-cells (&optional display)
1205   "Return the number of color cells supported by DISPLAY."
1206   (let ((frame-type (framep-on-display display)))
1207     (cond
1208      ((memq frame-type '(x w32 mac))
1209       (x-display-color-cells display))
1210      ((eq frame-type 'pc)
1211       16)
1212      (t
1213       (tty-display-color-cells display)))))
1214
1215 (defun display-visual-class (&optional display)
1216   "Returns the visual class of DISPLAY.
1217 The value is one of the symbols `static-gray', `gray-scale',
1218 `static-color', `pseudo-color', `true-color', or `direct-color'."
1219   (let ((frame-type (framep-on-display display)))
1220     (cond
1221      ((memq frame-type '(x w32 mac))
1222       (x-display-visual-class display))
1223      ((and (memq frame-type '(pc t))
1224            (tty-display-color-p display))
1225       'static-color)
1226      (t
1227       'static-gray))))
1228
1229 \f
1230 ;;;; Aliases for backward compatibility with Emacs 18.
1231 (define-obsolete-function-alias 'screen-height 'frame-height) ;before 19.15
1232 (define-obsolete-function-alias 'screen-width 'frame-width) ;before 19.15
1233
1234 (defun set-screen-width (cols &optional pretend)
1235   "Change the size of the screen to COLS columns.
1236 Optional second arg non-nil means that redisplay should use COLS columns
1237 but that the idea of the actual width of the frame should not be changed.
1238 This function is provided only for compatibility with Emacs 18."
1239   (set-frame-width (selected-frame) cols pretend))
1240
1241 (defun set-screen-height (lines &optional pretend)
1242   "Change the height of the screen to LINES lines.
1243 Optional second arg non-nil means that redisplay should use LINES lines
1244 but that the idea of the actual height of the screen should not be changed.
1245 This function is provided only for compatibility with Emacs 18."
1246   (set-frame-height (selected-frame) lines pretend))
1247
1248 (defun delete-other-frames (&optional frame)
1249   "Delete all frames except FRAME.
1250 If FRAME uses another frame's minibuffer, the minibuffer frame is
1251 left untouched.  FRAME nil or omitted means use the selected frame."
1252   (interactive)
1253   (unless frame
1254     (setq frame (selected-frame)))
1255   (let* ((mini-frame (window-frame (minibuffer-window frame)))
1256          (frames (delq mini-frame (delq frame (frame-list)))))
1257     ;; Delete mon-minibuffer-only frames first, because `delete-frame'
1258     ;; signals an error when trying to delete a mini-frame that's
1259     ;; still in use by another frame.
1260     (dolist (frame frames)
1261       (unless (eq (frame-parameter frame 'minibuffer) 'only)
1262         (delete-frame frame)))
1263     ;; Delete minibuffer-only frames.
1264     (dolist (frame frames)
1265       (when (eq (frame-parameter frame 'minibuffer) 'only)
1266         (delete-frame frame)))))
1267
1268 (make-obsolete 'set-screen-width 'set-frame-width) ;before 19.15
1269 (make-obsolete 'set-screen-height 'set-frame-height) ;before 19.15
1270
1271 ;; miscellaneous obsolescence declarations
1272 (define-obsolete-variable-alias 'delete-frame-hook
1273     'delete-frame-functions "22.1")
1274
1275 \f
1276 ;; Highlighting trailing whitespace.
1277
1278 (make-variable-buffer-local 'show-trailing-whitespace)
1279
1280 (defcustom show-trailing-whitespace nil
1281   "*Non-nil means highlight trailing whitespace.
1282 This is done in the face `trailing-whitespace'."
1283   :tag "Highlight trailing whitespace."
1284   :type 'boolean
1285   :group 'whitespace-faces)
1286
1287
1288 \f
1289 ;; Scrolling
1290
1291 (defgroup scrolling nil
1292   "Scrolling windows."
1293   :version "21.1"
1294   :group 'frames)
1295
1296 (defcustom auto-hscroll-mode t
1297   "*Allow or disallow automatic scrolling windows horizontally.
1298 If non-nil, windows are automatically scrolled horizontally to make
1299 point visible."
1300   :version "21.1"
1301   :type 'boolean
1302   :group 'scrolling)
1303 (defvaralias 'automatic-hscrolling 'auto-hscroll-mode)
1304
1305 \f
1306 ;; Blinking cursor
1307
1308 (defgroup cursor nil
1309   "Displaying text cursors."
1310   :version "21.1"
1311   :group 'frames)
1312
1313 (defcustom blink-cursor-delay 0.5
1314   "*Seconds of idle time after which cursor starts to blink."
1315   :tag "Delay in seconds."
1316   :type 'number
1317   :group 'cursor)
1318
1319 (defcustom blink-cursor-interval 0.5
1320   "*Length of cursor blink interval in seconds."
1321   :tag "Blink interval in seconds."
1322   :type 'number
1323   :group 'cursor)
1324
1325 (defvar blink-cursor-idle-timer nil
1326   "Timer started after `blink-cursor-delay' seconds of Emacs idle time.
1327 The function `blink-cursor-start' is called when the timer fires.")
1328
1329 (defvar blink-cursor-timer nil
1330   "Timer started from `blink-cursor-start'.
1331 This timer calls `blink-cursor-timer-function' every
1332 `blink-cursor-interval' seconds.")
1333
1334 (define-minor-mode blink-cursor-mode
1335   "Toggle blinking cursor mode.
1336 With a numeric argument, turn blinking cursor mode on iff ARG is positive.
1337 When blinking cursor mode is enabled, the cursor of the selected
1338 window blinks.
1339
1340 Note that this command is effective only when Emacs
1341 displays through a window system, because then Emacs does its own
1342 cursor display.  On a text-only terminal, this is not implemented."
1343   :init-value (not (or noninteractive
1344                        no-blinking-cursor
1345                        (eq system-type 'ms-dos)
1346                        (not (memq initial-window-system '(x w32 mac)))))
1347   :initialize 'custom-initialize-safe-default
1348   :group 'cursor
1349   :global t
1350   (if blink-cursor-idle-timer (cancel-timer blink-cursor-idle-timer))
1351   (if blink-cursor-timer (cancel-timer blink-cursor-timer))
1352   (setq blink-cursor-idle-timer nil
1353         blink-cursor-timer nil)
1354   (if blink-cursor-mode
1355       (progn
1356         ;; Hide the cursor.
1357         ;;(internal-show-cursor nil nil)
1358         (setq blink-cursor-idle-timer
1359               (run-with-idle-timer blink-cursor-delay
1360                                    blink-cursor-delay
1361                                    'blink-cursor-start)))
1362     (internal-show-cursor nil t)))
1363
1364 (define-obsolete-variable-alias 'blink-cursor 'blink-cursor-mode "22.1")
1365
1366 (defun blink-cursor-start ()
1367   "Timer function called from the timer `blink-cursor-idle-timer'.
1368 This starts the timer `blink-cursor-timer', which makes the cursor blink
1369 if appropriate.  It also arranges to cancel that timer when the next
1370 command starts, by installing a pre-command hook."
1371   (when (null blink-cursor-timer)
1372     (add-hook 'pre-command-hook 'blink-cursor-end)
1373     (internal-show-cursor nil nil)
1374     (setq blink-cursor-timer
1375           (run-with-timer blink-cursor-interval blink-cursor-interval
1376                           'blink-cursor-timer-function))))
1377
1378 (defun blink-cursor-timer-function ()
1379   "Timer function of timer `blink-cursor-timer'."
1380   (internal-show-cursor nil (not (internal-show-cursor-p))))
1381
1382 (defun blink-cursor-end ()
1383   "Stop cursor blinking.
1384 This is installed as a pre-command hook by `blink-cursor-start'.
1385 When run, it cancels the timer `blink-cursor-timer' and removes
1386 itself as a pre-command hook."
1387   (remove-hook 'pre-command-hook 'blink-cursor-end)
1388   (internal-show-cursor nil t)
1389   (cancel-timer blink-cursor-timer)
1390   (setq blink-cursor-timer nil))
1391
1392
1393 \f
1394 ;; Hourglass pointer
1395
1396 (defcustom display-hourglass t
1397   "*Non-nil means show an hourglass pointer when running under a window system."
1398   :tag "Hourglass pointer"
1399   :type 'boolean
1400   :group 'cursor)
1401
1402 (defcustom hourglass-delay 1
1403   "*Seconds to wait before displaying an hourglass pointer."
1404   :tag "Hourglass delay"
1405   :type 'number
1406   :group 'cursor)
1407
1408 \f
1409 (defcustom cursor-in-non-selected-windows t
1410   "*Non-nil means show a hollow box cursor in non-selected windows.
1411 If nil, don't show a cursor except in the selected window.
1412 Use Custom to set this variable to get the display updated."
1413   :tag "Cursor in non-selected windows"
1414   :type 'boolean
1415   :group 'cursor
1416   :set #'(lambda (symbol value)
1417            (set-default symbol value)
1418            (force-mode-line-update t)))
1419
1420 \f
1421 ;;;; Key bindings
1422
1423 (define-key ctl-x-5-map "2" 'make-frame-command)
1424 (define-key ctl-x-5-map "1" 'delete-other-frames)
1425 (define-key ctl-x-5-map "0" 'delete-frame)
1426 (define-key ctl-x-5-map "o" 'other-frame)
1427
1428 (substitute-key-definition 'suspend-emacs 'suspend-frame global-map)
1429
1430
1431 (defun terminal-id (terminal)
1432   "Return the numerical id of terminal TERMINAL.
1433
1434 TERMINAL can be a terminal id (an integer), a frame, or
1435 nil (meaning the selected frame's terminal).  Alternatively,
1436 TERMINAL may be the name of an X display
1437 device (HOST.SERVER.SCREEN) or a tty device file."
1438   (cond
1439    ((integerp terminal)
1440     (if (display-live-p terminal)
1441         terminal
1442       (signal 'wrong-type-argument (list 'display-live-p terminal))))
1443    ((or (null terminal) (framep terminal))
1444     (frame-display terminal))
1445    ((stringp terminal)
1446     (let ((f (car (filtered-frame-list (lambda (frame)
1447                                          (or (equal (frame-parameter frame 'display) terminal)
1448                                              (equal (frame-parameter frame 'tty) terminal)))))))
1449       (or f (error "Display %s does not exist" terminal))
1450       (frame-display f)))
1451    (t
1452     (error "Invalid argument %s in `terminal-id'" terminal))))
1453
1454 (defvar terminal-parameter-alist nil
1455   "An alist of terminal parameter alists.")
1456
1457 (defun terminal-parameters (&optional terminal)
1458   "Return the paramater-alist of terminal TERMINAL.
1459 It is a list of elements of the form (PARM . VALUE), where PARM is a symbol.
1460
1461 TERMINAL can be a terminal id, a frame, or nil (meaning the
1462 selected frame's terminal)."
1463   (cdr (assq (terminal-id terminal) terminal-parameter-alist)))
1464
1465 (defun terminal-parameter-p (terminal parameter)
1466   "Return non-nil if PARAMETER is a terminal parameter on TERMINAL.
1467
1468 The actual value returned in that case is a cell (PARAMETER . VALUE),
1469 where VALUE is the current value of PARAMETER.
1470
1471 TERMINAL can be a terminal id, a frame, or nil (meaning the
1472 selected frame's terminal)."
1473   (assq parameter (cdr (assq (terminal-id terminal) terminal-parameter-alist))))
1474
1475 (defun terminal-parameter (terminal parameter)
1476   "Return TERMINAL's value for parameter PARAMETER.
1477
1478 TERMINAL can be a terminal id, a frame, or nil (meaning the
1479 selected frame's terminal)."
1480   (cdr (terminal-parameter-p terminal parameter)))
1481
1482 (defun set-terminal-parameter (terminal parameter value)
1483   "Set TERMINAL's value for parameter PARAMETER to VALUE.
1484 Returns the previous value of PARAMETER.
1485
1486 TERMINAL can be a terminal id, a frame, or nil (meaning the
1487 selected frame's terminal)."
1488   (setq terminal (terminal-id terminal))
1489   (let* ((alist (assq terminal terminal-parameter-alist))
1490          (pair (assq parameter (cdr alist)))
1491          (result (cdr pair)))
1492     (cond
1493      (pair (setcdr pair value))
1494      (alist (setcdr alist (cons (cons parameter value) (cdr alist))))
1495      (t (setq terminal-parameter-alist
1496               (cons (cons terminal
1497                           (cons (cons parameter value)
1498                                 nil))
1499                     terminal-parameter-alist))))
1500     result))
1501
1502 (defun terminal-handle-delete-frame (frame)
1503   "Clean up terminal parameters of FRAME, if it's the last frame on its terminal."
1504   ;; XXX We assume that the display is closed immediately after the
1505   ;; last frame is deleted on it.  It would be better to create a hook
1506   ;; called `delete-display-functions', and use it instead.
1507   (when (and (frame-live-p frame)
1508              (= 1 (length (frames-on-display-list (frame-display frame)))))
1509     (setq terminal-parameter-alist
1510           (assq-delete-all (frame-display frame) terminal-parameter-alist))))
1511
1512 (add-hook 'delete-frame-functions 'terminal-handle-delete-frame)
1513
1514 (defun terminal-getenv (variable &optional terminal)
1515   "Get the value of VARIABLE in the client environment of TERMINAL.
1516 VARIABLE should be a string.  Value is nil if VARIABLE is undefined in
1517 the environment.  Otherwise, value is a string.
1518
1519 If TERMINAL was created by an emacsclient invocation, then the
1520 variable is looked up in the environment of the emacsclient
1521 process; otherwise the function consults the environment of the
1522 Emacs process.
1523
1524 TERMINAL can be a terminal id, a frame, or nil (meaning the
1525 selected frame's terminal)."
1526   (setq terminal (terminal-id terminal))
1527   (if (not (terminal-parameter-p terminal 'environment))
1528       (getenv variable)
1529     (let ((env (terminal-parameter terminal 'environment))
1530           result entry)
1531       (while (and env (null result))
1532         (setq entry (car env)
1533               env (cdr env))
1534         (if (and (> (length entry) (length variable))
1535                  (eq ?= (aref entry (length variable)))
1536                  (equal variable (substring entry 0 (length variable))))
1537             (setq result (substring entry (+ (length variable) 1)))))
1538       (if (null result)
1539           (getenv variable)
1540         result))))
1541
1542 (defmacro with-terminal-environment (terminal vars &rest body)
1543   "Evaluate BODY with environment variables VARS set to those of TERMINAL.
1544 The environment variables are then restored to their previous values.
1545
1546 VARS should be a list of strings.
1547
1548 TERMINAL can be a terminal id, a frame, or nil (meaning the
1549 selected frame's terminal).
1550
1551 See also `terminal-getenv'."
1552   (declare (indent 2))
1553   (let ((oldvalues (make-symbol "oldvalues"))
1554         (var (make-symbol "var"))
1555         (value (make-symbol "value"))
1556         (pair (make-symbol "pair")))
1557     `(let (,oldvalues)
1558        (dolist (,var ,vars)
1559          (let ((,value (terminal-getenv ,var ,terminal)))
1560            (setq ,oldvalues (cons (cons ,var (getenv ,var)) ,oldvalues))
1561            (setenv ,var ,value)))
1562        (unwind-protect
1563            (progn ,@body)
1564          (dolist (,pair ,oldvalues)
1565            (setenv (car ,pair) (cdr ,pair)))))))
1566
1567
1568 (provide 'frame)
1569
1570 ;; arch-tag: 82979c70-b8f2-4306-b2ad-ddbd6b328b56
1571 ;;; frame.el ends here