lisp/textmodes/spell.el

   1 ;;; spell.el --- spelling correction interface for Emacs.
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Code:
  24
  25 (defvar spell-command "spell"
  26   "*Command to run the spell program.")
  27
  28 (defvar spell-filter nil
  29   "*Filter function to process text before passing it to spell program.
  30 This function might remove text-processor commands.
  31 nil means don't alter the text before checking it.")
  32
  33 ;;;###autoload
  34 (defun spell-buffer ()
  35   "Check spelling of every word in the buffer.
  36 For each incorrect word, you are asked for the correct spelling
  37 and then put into a query-replace to fix some or all occurrences.
  38 If you do not want to change a word, just give the same word
  39 as its \"correct\" spelling; then the query replace is skipped."
  40   (interactive)
  41   (spell-region (point-min) (point-max) "buffer"))
  42
  43 ;;;###autoload
  44 (defun spell-word ()
  45   "Check spelling of word at or before point.
  46 If it is not correct, ask user for the correct spelling
  47 and query-replace the entire buffer to substitute it."
  48   (interactive)
  49   (let (beg end spell-filter)
  50     (save-excursion
  51      (if (not (looking-at "\\<"))
  52          (forward-word -1))
  53      (setq beg (point))
  54      (forward-word 1)
  55      (setq end (point)))
  56     (spell-region beg end (buffer-substring beg end))))
  57
  58 ;;;###autoload
  59 (defun spell-region (start end &optional description)
  60   "Like spell-buffer but applies only to region.
  61 Used in a program, applies from START to END.
  62 DESCRIPTION is an optional string naming the unit being checked:
  63 for example, \"word\"."
  64   (interactive "r")
  65   (let ((filter spell-filter)
  66         (buf (get-buffer-create " *temp*")))
  67     (save-excursion
  68      (set-buffer buf)
  69      (widen)
  70      (erase-buffer))
  71     (message "Checking spelling of %s..." (or description "region"))
  72     (if (and (null filter) (= ?\n (char-after (1- end))))
  73         (if (string= "spell" spell-command)
  74             (call-process-region start end "spell" nil buf)
  75           (call-process-region start end shell-file-name
  76                                nil buf nil "-c" spell-command))
  77       (let ((oldbuf (current-buffer)))
  78         (save-excursion
  79          (set-buffer buf)
  80          (insert-buffer-substring oldbuf start end)
  81          (or (bolp) (insert ?\n))
  82          (if filter (funcall filter))
  83          (if (string= "spell" spell-command)
  84              (call-process-region (point-min) (point-max) "spell" t buf)
  85            (call-process-region (point-min) (point-max) shell-file-name
  86                                 t buf nil "-c" spell-command)))))
  87     (message "Checking spelling of %s...%s"
  88              (or description "region")
  89              (if (save-excursion
  90                   (set-buffer buf)
  91                   (> (buffer-size) 0))
  92                  "not correct"
  93                "correct"))
  94     (let (word newword
  95           (case-fold-search t)
  96           (case-replace t))
  97       (while (save-excursion
  98               (set-buffer buf)
  99               (> (buffer-size) 0))
 100         (save-excursion
 101          (set-buffer buf)
 102          (goto-char (point-min))
 103          (setq word (downcase
 104                      (buffer-substring (point)
 105                                        (progn (end-of-line) (point)))))
 106          (forward-char 1)
 107          (delete-region (point-min) (point))
 108          (setq newword
 109                (read-input (concat "`" word
 110                                    "' not recognized; edit a replacement: ")
 111                            word))
 112          (flush-lines (concat "^" (regexp-quote word) "$")))
 113         (if (not (equal word newword))
 114             (progn
 115              (goto-char (point-min))
 116              (query-replace-regexp (concat "\\b" (regexp-quote word) "\\b")
 117                                    newword)))))))
 118
 119
 120 ;;;###autoload
 121 (defun spell-string (string)
 122   "Check spelling of string supplied as argument."
 123   (interactive "sSpell string: ")
 124   (let ((buf (get-buffer-create " *temp*")))
 125     (save-excursion
 126      (set-buffer buf)
 127      (widen)
 128      (erase-buffer)
 129      (insert string "\n")
 130      (if (string= "spell" spell-command)
 131          (call-process-region (point-min) (point-max) "spell"
 132                               t t)
 133        (call-process-region (point-min) (point-max) shell-file-name
 134                             t t nil "-c" spell-command))
 135      (if (= 0 (buffer-size))
 136          (message "%s is correct" string)
 137        (goto-char (point-min))
 138        (while (search-forward "\n" nil t)
 139          (replace-match " "))
 140        (message "%sincorrect" (buffer-substring 1 (point-max)))))))
 141
 142 ;;; spell.el ends here