configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2014 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 24.4.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl We get MINGW64 with MSYS2
  29 if test "x$MSYSTEM" = "xMINGW32" -o "x$MSYSTEM" = "xMINGW64"
  30 then
  31   . $srcdir/nt/mingw-cfg.site
  32
  33   case $srcdir in
  34     /* | ?:*)
  35       # srcdir is an absolute path.  In this case, force the format
  36       # "/c/foo/bar", to simplify later conversions to native Windows
  37       # format ("c:/foo/bar")
  38       srcdir=`cd "${srcdir}" && pwd -W`
  39       srcdir="/${srcdir:0:1}${srcdir:2}"
  40       ;;
  41   esac
  42 fi
  43
  44 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  45 dnl and then quoted again for a C string.  Separate options with spaces.
  46 dnl Add some environment variables, if they were passed via the environment
  47 dnl rather than on the command-line.
  48 emacs_config_options=
  49 optsep=
  50 dnl This is the documented way to record the args passed to configure,
  51 dnl rather than $ac_configure_args.
  52 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  53   case $opt in
  54     -n | --no-create | --no-recursion)
  55       continue ;;
  56     CFLAGS | CPPFLAGS | LDFLAGS)
  57       eval 'test "${'$opt'+set}" = set' || continue
  58       case " $*" in
  59         *" $opt="*) continue ;;
  60       esac
  61       eval opt=$opt=\$$opt ;;
  62   esac
  63
  64   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  65   case $opt in
  66     *[["$emacs_shell_specials"]]*)
  67       case $opt in
  68         *\'*)
  69           emacs_quote_apostrophes="s/'/'\\\\''/g"
  70           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  71       esac
  72       opt="'$opt'"
  73       case $opt in
  74         *[['"\\']]*)
  75           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  76           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  77       esac ;;
  78   esac
  79   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  80   optsep=' '
  81 done
  82
  83 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  84 AC_CONFIG_SRCDIR(src/lisp.h)
  85 AC_CONFIG_AUX_DIR(build-aux)
  86
  87 xcsdkdir=
  88 AC_CHECK_PROGS(XCRUN, [xcrun])
  89 if test -n "$XCRUN"; then
  90   if test -z "$MAKE"; then
  91     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  92     dnl SET_MAKE and with the usual MAKE variable that 'make' itself uses.
  93     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  94     if test -z "$MAKE_PROG"; then
  95       MAKE="$XCRUN MAKE"
  96       export MAKE
  97       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  98     fi
  99   fi
 100 fi
 101
 102 dnl Fairly arbitrary, older versions might work too.
 103 AM_INIT_AUTOMAKE(1.11)
 104
 105 dnl Support for --program-prefix, --program-suffix and
 106 dnl --program-transform-name options
 107 AC_ARG_PROGRAM
 108
 109 dnl It is important that variables on the RHS not be expanded here,
 110 dnl hence the single quotes.  This is per the GNU coding standards, see
 111 dnl (autoconf) Installation Directory Variables
 112 dnl See also epaths.h below.
 113 lispdir='${datadir}/emacs/${version}/lisp'
 114 standardlisppath='${lispdir}'
 115 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 116 '${datadir}/emacs/site-lisp'
 117 lisppath='${locallisppath}:${standardlisppath}'
 118 etcdir='${datadir}/emacs/${version}/etc'
 119 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 120 etcdocdir='${datadir}/emacs/${version}/etc'
 121 gamedir='${localstatedir}/games/emacs'
 122
 123 dnl Special option to disable the most of other options.
 124 AC_ARG_WITH(all,
 125 [AS_HELP_STRING([--without-all],
 126                 [omit almost all features and build
 127                 small executable with minimal dependencies])],
 128   [with_features=$withval],
 129   [with_features=yes])
 130
 131 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 132 dnl Create a new --with option that defaults to being disabled.
 133 dnl NAME is the base name of the option.  The shell variable with_NAME
 134 dnl   will be set to either the user's value (if the option is
 135 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 136 dnl   option is not specified).  Note that the shell variable name is
 137 dnl   constructed as autoconf does, by replacing non-alphanumeric
 138 dnl   characters with "_".
 139 dnl HELP-STRING is the help text for the option.
 140 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 141   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 142     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 143 ])dnl
 144
 145 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 146 dnl Create a new --with option that defaults to $with_features.
 147 dnl NAME is the base name of the option.  The shell variable with_NAME
 148 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 149 dnl   'yes' (if the option is not specified).  Note that the shell
 150 dnl   variable name is constructed as autoconf does, by replacing
 151 dnl   non-alphanumeric characters with "_".
 152 dnl HELP-STRING is the help text for the option.
 153 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 154   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 155    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 156 ])dnl
 157
 158 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 159 if test "$with_pop" = yes; then
 160    AC_DEFINE(MAIL_USE_POP)
 161 fi
 162 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 163
 164 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 165 if test "$with_kerberos" != no; then
 166    AC_DEFINE(KERBEROS)
 167 fi
 168 AH_TEMPLATE(KERBEROS,
 169             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 170
 171 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 172 if test "${with_kerberos5}" != no; then
 173   if test "${with_kerberos}" = no; then
 174     with_kerberos=yes
 175     AC_DEFINE(KERBEROS)
 176   fi
 177   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 178 fi
 179
 180 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 181 dnl FIXME hesiod support may not be present, so it seems like an error
 182 dnl to define, or at least use, this unconditionally.
 183 if test "$with_hesiod" != no; then
 184   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 185 fi
 186
 187 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 188 if test "$with_mmdf" != no; then
 189    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 190 fi
 191
 192 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 193 if test "$with_mail_unlink" != no; then
 194    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 195 fi
 196
 197 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 198     [string giving default POP mail host])],
 199     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 200
 201 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 202   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 203 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW.])],
 204   [ case "${withval}" in
 205       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 206       *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
 207 this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
 208       ;;
 209     esac
 210     with_sound=$val
 211   ],
 212   [with_sound=$with_features])
 213
 214 dnl FIXME currently it is not the last.
 215 dnl This should be the last --with option, because --with-x is
 216 dnl added later on when we find the file name of X, and it's best to
 217 dnl keep them together visually.
 218 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 219  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 220 [         case "${withval}" in
 221             y | ye | yes )      val=gtk ;;
 222             n | no )            val=no  ;;
 223             l | lu | luc | luci | lucid )       val=lucid ;;
 224             a | at | ath | athe | athen | athena )      val=athena ;;
 225             m | mo | mot | moti | motif )       val=motif ;;
 226             g | gt | gtk  )     val=gtk ;;
 227             gtk2  )     val=gtk2 ;;
 228             gtk3  )     val=gtk3 ;;
 229             * )
 230 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 231 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 232 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 233 `athena' and `lucid' are synonyms.])
 234             ;;
 235           esac
 236           with_x_toolkit=$val
 237 ])
 238
 239 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 240 if test "$with_wide_int" = yes; then
 241   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 242 fi
 243
 244 dnl _ON results in a '--without' option in the --help output, so
 245 dnl the help text should refer to "don't compile", etc.
 246 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 247 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 248 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 249 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 250 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 251 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 252 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 253 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 254
 255 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 256 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 257 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 258
 259 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 260 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 261 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 262 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 263 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 264
 265 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 266 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 267 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 268 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 269 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 270 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 271 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 272
 273 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 274  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 275  [ case "${withval}" in
 276     y | ye | yes )      val=yes ;;
 277     n | no )            val=no  ;;
 278     g | gf | gfi | gfil | gfile )       val=gfile ;;
 279     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 280     w | w3 | w32 )      val=w32 ;;
 281     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 282 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 283 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
 284 otherwise for the first of `gfile' or `inotify' that is usable.])
 285     ;;
 286    esac
 287    with_file_notification=$val
 288  ],
 289  [with_file_notification=$with_features])
 290
 291 ## For the times when you want to build Emacs but don't have
 292 ## a suitable makeinfo, and can live without the manuals.
 293 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 294 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 295
 296 ## Makefile.in needs the cache file name.
 297 AC_SUBST(cache_file)
 298
 299 ## This is an option because I do not know if all info/man support
 300 ## compressed files, nor how to test if they do so.
 301 OPTION_DEFAULT_ON([compress-install],
 302   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 303 make GZIP_PROG= install])
 304
 305 AC_ARG_WITH([pkg-config-prog],dnl
 306 [AS_HELP_STRING([--with-pkg-config-prog=FILENAME],
 307                   [file name of pkg-config for finding GTK and librsvg])])
 308 if test "X${with_pkg_config_prog}" != X; then
 309    if test "${with_pkg_config_prog}" != yes; then
 310       PKG_CONFIG="${with_pkg_config_prog}"
 311    fi
 312 fi
 313
 314 AC_ARG_WITH(gameuser,dnl
 315 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 316 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 317   && gameuser="${with_gameuser}"
 318 test "X$gameuser" = X && gameuser=games
 319
 320 AC_ARG_WITH([gnustep-conf],dnl
 321 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 322    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 323 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 324   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 325 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 326      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 327
 328 AC_ARG_ENABLE(ns-self-contained,
 329 [AS_HELP_STRING([--disable-ns-self-contained],
 330                 [disable self contained build under NeXTstep])],
 331    EN_NS_SELF_CONTAINED=$enableval,
 332    EN_NS_SELF_CONTAINED=yes)
 333
 334 AC_ARG_ENABLE(locallisppath,
 335 [AS_HELP_STRING([--enable-locallisppath=PATH],
 336                 [directories Emacs should search for lisp files specific
 337                  to this site])],
 338 if test "${enableval}" = "no"; then
 339   locallisppath=
 340 elif test "${enableval}" != "yes"; then
 341   locallisppath=${enableval}
 342 fi)
 343
 344 AC_ARG_ENABLE(checking,
 345 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 346                 [enable expensive run-time checks.  With LIST,
 347                  enable only specific categories of checks.
 348                  Categories are: all,yes,no.
 349                  Flags are: stringbytes, stringoverrun, stringfreelist,
 350                  xmallocoverrun, conslist, glyphs])],
 351 [ac_checking_flags="${enableval}"],[])
 352 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 353 for check in $ac_checking_flags
 354 do
 355         case $check in
 356         # these set all the flags to specific states
 357         yes)            ac_enable_checking=1 ;;
 358         no)             ac_enable_checking= ;
 359                         ac_gc_check_stringbytes= ;
 360                         ac_gc_check_string_overrun= ;
 361                         ac_gc_check_string_free_list= ;
 362                         ac_xmalloc_overrun= ;
 363                         ac_gc_check_cons_list= ;
 364                         ac_glyphs_debug= ;;
 365         all)            ac_enable_checking=1 ;
 366                         ac_gc_check_stringbytes=1 ;
 367                         ac_gc_check_string_overrun=1 ;
 368                         ac_gc_check_string_free_list=1 ;
 369                         ac_xmalloc_overrun=1 ;
 370                         ac_gc_check_cons_list=1 ;
 371                         ac_glyphs_debug=1 ;;
 372         # these enable particular checks
 373         stringbytes)    ac_gc_check_stringbytes=1 ;;
 374         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 375         stringfreelist) ac_gc_check_string_free_list=1 ;;
 376         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 377         conslist)       ac_gc_check_cons_list=1 ;;
 378         glyphs)         ac_glyphs_debug=1 ;;
 379         *)      AC_MSG_ERROR(unknown check category $check) ;;
 380         esac
 381 done
 382 IFS="$ac_save_IFS"
 383
 384 if test x$ac_enable_checking != x ; then
 385   AC_DEFINE(ENABLE_CHECKING, 1,
 386 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 387 fi
 388 if test x$ac_gc_check_stringbytes != x ; then
 389   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 390 [Define this temporarily to hunt a bug.  If defined, the size of
 391    strings is redundantly recorded in sdata structures so that it can
 392    be compared to the sizes recorded in Lisp strings.])
 393 fi
 394 if test x$ac_gc_check_string_overrun != x ; then
 395   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 396 [Define this to check for short string overrun.])
 397 fi
 398 if test x$ac_gc_check_string_free_list != x ; then
 399   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 400 [Define this to check the string free list.])
 401 fi
 402 if test x$ac_xmalloc_overrun != x ; then
 403   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 404 [Define this to check for malloc buffer overrun.])
 405 fi
 406 if test x$ac_gc_check_cons_list != x ; then
 407   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 408 [Define this to check for errors in cons list.])
 409 fi
 410 if test x$ac_glyphs_debug != x ; then
 411   AC_DEFINE(GLYPH_DEBUG, 1,
 412 [Define this to enable glyphs debugging code.])
 413 fi
 414
 415 AC_ARG_ENABLE(check-lisp-object-type,
 416 [AS_HELP_STRING([--enable-check-lisp-object-type],
 417                 [enable compile time checks for the Lisp_Object data type.
 418                 This is useful for development for catching certain types of bugs.])],
 419 if test "${enableval}" != "no"; then
 420    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 421    [Define this to enable compile time checks for the Lisp_Object data type.])
 422 fi)
 423
 424
 425 dnl The name of this option is unfortunate.  It predates, and has no
 426 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 427 dnl Actually, it stops it working.
 428 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 429 AC_ARG_ENABLE(profiling,
 430 [AS_HELP_STRING([--enable-profiling],
 431                 [build emacs with low-level, gprof profiling support.
 432                 Mainly useful for debugging Emacs itself.  May not work on
 433                 all platforms.  Stops profiler.el working.])],
 434 [ac_enable_profiling="${enableval}"],[])
 435 if test x$ac_enable_profiling != x ; then
 436    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 437 else
 438    PROFILING_CFLAGS=
 439 fi
 440 AC_SUBST(PROFILING_CFLAGS)
 441
 442 AC_ARG_ENABLE(autodepend,
 443 [AS_HELP_STRING([--enable-autodepend],
 444                 [automatically generate dependencies to .h-files.
 445                  Requires gcc, enabled if found.])],
 446 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 447
 448 AC_ARG_ENABLE(gtk-deprecation-warnings,
 449 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 450                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 451 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 452
 453 ### Canonicalize the configuration name.
 454
 455 AC_CANONICAL_HOST
 456 canonical=$host
 457 configuration=${host_alias-${build_alias-$host}}
 458
 459 dnl This used to use changequote, but, apart from `changequote is evil'
 460 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 461 dnl the great gob of text.  Thus it's not processed for possible expansion.
 462 dnl Just make sure the brackets remain balanced.
 463 dnl
 464 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 465 dnl indicated by comments.
 466 dnl quotation begins
 467 [
 468
 469 ### If you add support for a new configuration, add code to this
 470 ### switch statement to recognize your configuration name and select
 471 ### the appropriate opsys.
 472
 473 ### As far as handling version numbers on operating systems is
 474 ### concerned, make sure things will fail in a fixable way.  If
 475 ### /etc/MACHINES doesn't say anything about version numbers, be
 476 ### prepared to handle anything reasonably.  If version numbers
 477 ### matter, be sure /etc/MACHINES says something about it.
 478
 479 opsys='' unported=no
 480 case "${canonical}" in
 481
 482   ## GNU/Linux and similar ports
 483   *-*-linux* )
 484     opsys=gnu-linux
 485   ;;
 486
 487   ## FreeBSD ports
 488   *-*-freebsd* )
 489     opsys=freebsd
 490   ;;
 491
 492   ## DragonFly ports
 493   *-*-dragonfly* )
 494     opsys=dragonfly
 495   ;;
 496
 497   ## FreeBSD kernel + glibc based userland
 498   *-*-kfreebsd*gnu* )
 499     opsys=gnu-kfreebsd
 500   ;;
 501
 502   ## NetBSD ports
 503   *-*-netbsd* )
 504     opsys=netbsd
 505   ;;
 506
 507   ## OpenBSD ports
 508   *-*-openbsd* )
 509     opsys=openbsd
 510   ;;
 511
 512   ## Apple Darwin / Mac OS X
 513   *-apple-darwin* )
 514     case "${canonical}" in
 515       i[3456]86-* )  ;;
 516       powerpc-* )    ;;
 517       x86_64-* )     ;;
 518       * )            unported=yes ;;
 519     esac
 520     opsys=darwin
 521     ## Use fink packages if available.
 522     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 523 ##    if test -d /sw/include && test -d /sw/lib; then
 524 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 525 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 526 ##    fi
 527   ;;
 528
 529   ## Cygwin ports
 530   *-*-cygwin )
 531     opsys=cygwin
 532   ;;
 533
 534   ## HP 9000 series 700 and 800, running HP/UX
 535   hppa*-hp-hpux10.2* )
 536     opsys=hpux10-20
 537   ;;
 538   hppa*-hp-hpux1[1-9]* )
 539     opsys=hpux11
 540     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 541   ;;
 542
 543   ## IBM machines
 544   rs6000-ibm-aix4.[23]* )
 545     opsys=aix4-2
 546   ;;
 547   powerpc-ibm-aix4.[23]*  )
 548     opsys=aix4-2
 549   ;;
 550   rs6000-ibm-aix[56]* )
 551     opsys=aix4-2
 552   ;;
 553   powerpc-ibm-aix[56]*  )
 554     opsys=aix4-2
 555   ;;
 556
 557   ## Silicon Graphics machines
 558   ## Iris 4D
 559   mips-sgi-irix6.5 )
 560     opsys=irix6-5
 561     # Without defining _LANGUAGE_C, things get masked out in the headers
 562     # so that, for instance, grepping for `free' in stdlib.h fails and
 563     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 564     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 565   ;;
 566
 567   ## Suns
 568   *-sun-solaris* \
 569     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 570     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 571     case "${canonical}" in
 572       i[3456]86-*-* )   ;;
 573       amd64-*-*|x86_64-*-*) ;;
 574       sparc* )          ;;
 575       * )               unported=yes ;;
 576     esac
 577     case "${canonical}" in
 578       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 579                 opsys=sol2-10
 580                 emacs_check_sunpro_c=yes
 581                 ;;
 582       *-sunos5.6* | *-solaris2.6* )
 583                 opsys=sol2-6
 584                 RANLIB="ar -ts"
 585                 ;;
 586       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 587                 opsys=sol2-6
 588                 emacs_check_sunpro_c=yes
 589                 ;;
 590     esac
 591     ## Watch out for a compiler that we know will not work.
 592     case "${canonical}" in
 593      *-solaris* | *-sunos5* )
 594                 if [ "x$CC" = x/usr/ucb/cc ]; then
 595                   ## /usr/ucb/cc doesn't work;
 596                   ## we should find some other compiler that does work.
 597                   unset CC
 598                 fi
 599                 ;;
 600       *) ;;
 601     esac
 602   ;;
 603
 604   ## Intel 386 machines where we don't care about the manufacturer.
 605   i[3456]86-*-* )
 606     case "${canonical}" in
 607       *-darwin* )               opsys=darwin ;;
 608       *-mingw32 )
 609                 opsys=mingw32
 610                 # MinGW overrides and adds some system headers in nt/inc.
 611                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 612                 ;;
 613       *-sysv4.2uw* )            opsys=unixware ;;
 614       *-sysv5uw* )              opsys=unixware ;;
 615       *-sysv5OpenUNIX* )        opsys=unixware ;;
 616       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 617     esac
 618   ;;
 619
 620   # MinGW64
 621   x86_64-*-* )
 622     case "${canonical}" in
 623       *-mingw32 )
 624                 opsys=mingw32
 625                 # MinGW overrides and adds some system headers in nt/inc.
 626                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 627                 ;;
 628       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 629     esac
 630   ;;
 631
 632   * )
 633     unported=yes
 634   ;;
 635 esac
 636
 637 ### If the code above didn't choose an operating system, just choose
 638 ### an operating system based on the configuration name.  You really
 639 ### only want to use this when you have no idea what the right
 640 ### operating system is; if you know what operating systems a machine
 641 ### runs, it's cleaner to make it explicit in the case statement
 642 ### above.
 643 if test x"${opsys}" = x; then
 644   case "${canonical}" in
 645     *-gnu* )                            opsys=gnu ;;
 646     * )
 647       unported=yes
 648     ;;
 649   esac
 650 fi
 651
 652 ]
 653 dnl quotation ends
 654
 655 if test $unported = yes; then
 656   AC_MSG_ERROR([Emacs does not support `${canonical}' systems.
 657 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 658 Check `etc/MACHINES' for recognized configuration names.])
 659 fi
 660
 661
 662 AC_MSG_CHECKING([whether we are using GNU Make])
 663 testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
 664 if test "x$testval" != x; then
 665   AC_MSG_RESULT([yes])
 666 else
 667   AC_MSG_RESULT([no])
 668   AC_MSG_ERROR([Building Emacs requires GNU make.
 669 If you have it installed under another name, configure with 'MAKE=...'.
 670 For example, run './configure MAKE=gmake'.])
 671 fi
 672
 673
 674 #### Choose a compiler.
 675
 676 dnl Sets GCC=yes if using gcc.
 677 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 678 if test -n "$XCRUN"; then
 679   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 680   test -n "$AR" && export AR
 681 fi
 682
 683 AM_PROG_CC_C_O
 684
 685 if test x$GCC = xyes; then
 686   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 687 else
 688   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 689 fi
 690
 691 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 692 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 693 dnl that clash with MinGW.
 694 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 695
 696 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 697 AC_DEFUN([gl_CRYPTO_CHECK])
 698 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 699 # as we don't use them.
 700 AC_DEFUN([gl_FCNTL_O_FLAGS])
 701 # Avoid gnulib's threadlib module, as we do threads our own way.
 702 AC_DEFUN([gl_THREADLIB])
 703
 704 # Initialize gnulib right after choosing the compiler.
 705 dnl Amongst other things, this sets AR and ARFLAGS.
 706 gl_EARLY
 707
 708 if test "$ac_test_CFLAGS" != set; then
 709   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 710   # if -g3 works and the user does not specify CFLAGS.
 711   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 712   case $CFLAGS in
 713     '-g')
 714       emacs_g3_CFLAGS='-g3';;
 715     '-g -O2')
 716       emacs_g3_CFLAGS='-g3 -O2';;
 717     *)
 718       emacs_g3_CFLAGS='';;
 719   esac
 720   if test -n "$emacs_g3_CFLAGS"; then
 721     emacs_save_CFLAGS=$CFLAGS
 722     CFLAGS=$emacs_g3_CFLAGS
 723     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 724       [emacs_cv_prog_cc_g3],
 725       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 726          [emacs_cv_prog_cc_g3=yes],
 727          [emacs_cv_prog_cc_g3=no])])
 728     if test $emacs_cv_prog_cc_g3 != yes; then
 729       CFLAGS=$emacs_save_CFLAGS
 730     fi
 731     if test $opsys = mingw32; then
 732       CFLAGS="$CFLAGS -gdwarf-2"
 733     fi
 734   fi
 735
 736   case $CFLAGS in
 737     *-O*) ;;
 738     *)
 739       # No optimization flag was inferred for this non-GCC compiler.
 740       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 741       emacs_save_CFLAGS=$CFLAGS
 742       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 743       CFLAGS=${CFLAGS}-O
 744       AC_CACHE_CHECK([whether $CC accepts -O],
 745         [emacs_cv_prog_cc_o],
 746         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 747            [emacs_cv_prog_cc_o=yes],
 748            [emacs_cv_prog_cc_o=no])])
 749       if test $emacs_cv_prog_cc_o != yes; then
 750         CFLAGS=$emacs_save_CFLAGS
 751       fi ;;
 752   esac
 753 fi
 754
 755 AC_ARG_ENABLE([gcc-warnings],
 756   [AS_HELP_STRING([--enable-gcc-warnings],
 757                   [turn on lots of GCC warnings/errors. This is intended for
 758                    developers, and may generate false alarms when used
 759                    with older or non-GNU development tools.])],
 760   [case $enableval in
 761      yes|no) ;;
 762      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 763    esac
 764    gl_gcc_warnings=$enableval],
 765   [gl_gcc_warnings=no]
 766 )
 767
 768 AC_ARG_ENABLE(link-time-optimization,
 769 [AS_HELP_STRING([--enable-link-time-optimization],
 770                 [build emacs with link-time optimization.
 771                  This is supported only for GCC since 4.5.0.])],
 772 if test "${enableval}" != "no"; then
 773    AC_MSG_CHECKING([whether link-time optimization is supported])
 774    ac_lto_supported=no
 775    if test x$GCC = xyes; then
 776       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 777       if test x$CPUS != x; then
 778          LTO="-flto=$CPUS"
 779       else
 780          LTO="-flto"
 781       fi
 782       old_CFLAGS=$CFLAGS
 783       CFLAGS="$CFLAGS $LTO"
 784       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 785         [ac_lto_supported=yes], [ac_lto_supported=no])
 786       CFLAGS="$old_CFLAGS"
 787    fi
 788    AC_MSG_RESULT([$ac_lto_supported])
 789    if test "$ac_lto_supported" = "yes"; then
 790       CFLAGS="$CFLAGS $LTO"
 791    fi
 792 fi)
 793
 794 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 795 # ------------------------------------------------
 796 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 797 # Otherwise, run RUN-IF-NOT-FOUND.
 798 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 799   [AC_PREPROC_IFELSE(
 800     [AC_LANG_PROGRAM(
 801       [[
 802 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 803 /* ok */
 804 #else
 805 # error "your version of gcc is older than $1.$2"
 806 #endif
 807       ]]),
 808     ], [$3], [$4])
 809   ]
 810 )
 811
 812 # clang is unduly picky about some things.
 813 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 814   [AC_COMPILE_IFELSE(
 815      [AC_LANG_PROGRAM([[
 816           #ifndef __clang__
 817             #error "not clang"
 818           #endif
 819         ]])],
 820      [emacs_cv_clang=yes],
 821      [emacs_cv_clang=no])])
 822
 823 # When compiling with GCC, prefer -isystem to -I when including system
 824 # include files, to avoid generating useless diagnostics for the files.
 825 if test "$gl_gcc_warnings" != yes; then
 826   isystem='-I'
 827   if test "$emacs_cv_clang" = yes
 828   then
 829      # Turn off some warnings if supported.
 830      gl_WARN_ADD([-Wno-switch])
 831      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 832      gl_WARN_ADD([-Wno-pointer-sign])
 833   fi
 834 else
 835   isystem='-isystem '
 836
 837   # This, $nw, is the list of warnings we disable.
 838   nw=
 839
 840   case $with_x_toolkit in
 841     lucid | athena | motif)
 842        # Old toolkits mishandle 'const'.
 843        nw="$nw -Wwrite-strings"
 844        ;;
 845     *)
 846        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 847        ;;
 848   esac
 849   AC_SUBST([WERROR_CFLAGS])
 850
 851   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 852   nw="$nw -Woverlength-strings"     # Not a problem these days
 853   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 854   nw="$nw -Wformat-nonliteral"      # we do this a lot
 855   nw="$nw -Wvla"                    # warnings in gettext.h
 856   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 857   nw="$nw -Wswitch-default"         # Too many warnings for now
 858   nw="$nw -Winline"                 # OK to ignore 'inline'
 859   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 860   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 861                                     # signed overflow has undefined behavior
 862   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 863   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 864   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 865
 866   # Emacs doesn't care about shadowing; see
 867   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 868   nw="$nw -Wshadow"
 869
 870   # Emacs's use of alloca inhibits protecting the stack.
 871   nw="$nw -Wstack-protector"
 872
 873   # The following line should be removable at some point.
 874   nw="$nw -Wsuggest-attribute=pure"
 875
 876   # This part is merely for shortening the command line,
 877   # since -Wno-FOO needs to be added below regardless.
 878   nw="$nw -Wmissing-field-initializers"
 879   nw="$nw -Wswitch"
 880   nw="$nw -Wtype-limits"
 881   nw="$nw -Wunused-parameter"
 882
 883   if test $emacs_cv_clang = yes; then
 884     nw="$nw -Wcast-align"
 885   fi
 886
 887   gl_MANYWARN_ALL_GCC([ws])
 888   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 889   for w in $ws; do
 890     gl_WARN_ADD([$w])
 891   done
 892   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 893   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 894   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 895   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 896   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 897   gl_WARN_ADD([-Wno-format-nonliteral])
 898
 899   # In spite of excluding -Wlogical-op above, it is enabled, as of
 900   # gcc 4.5.0 20090517.
 901   gl_WARN_ADD([-Wno-logical-op])
 902
 903   # More things that clang is unduly picky about.
 904   if test $emacs_cv_clang = yes; then
 905     gl_WARN_ADD([-Wno-format-extra-args])
 906     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 907     gl_WARN_ADD([-Wno-unused-command-line-argument])
 908     gl_WARN_ADD([-Wno-unused-value])
 909   fi
 910
 911   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 912   AH_VERBATIM([FORTIFY_SOURCE],
 913   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 914       without upsetting glibc 2.15+. */
 915    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 916    # define _FORTIFY_SOURCE 2
 917    #endif
 918   ])
 919   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 920
 921   # We use a slightly smaller set of warning options for lib/.
 922   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 923   nw=
 924   nw="$nw -Wunused-macros"
 925
 926   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 927   AC_SUBST([GNULIB_WARN_CFLAGS])
 928 fi
 929
 930
 931
 932 dnl Some other nice autoconf tests.
 933 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 934 dnl AC_PROG_INSTALL
 935 dnl AC_PROG_MKDIR_P
 936 dnl if test "x$RANLIB" = x; then
 937 dnl   AC_PROG_RANLIB
 938 dnl fi
 939
 940
 941 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
 942 dnl can be made to directories.  This is not relevant for our usage, and
 943 dnl excludes some cases that work fine for us.  Eg MS Windows or files
 944 dnl hosted on AFS, both examples where simple links work, but links to
 945 dnl directories fail.  We use a cut-down version instead.
 946 dnl AC_PROG_LN_S
 947
 948 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
 949 rm -f conf$$ conf$$.file
 950
 951 LN_S_FILEONLY='cp -p'
 952
 953 if (echo >conf$$.file) 2>/dev/null; then
 954   if ln -s conf$$.file conf$$ 2>/dev/null; then
 955     LN_S_FILEONLY='ln -s'
 956   elif ln conf$$.file conf$$ 2>/dev/null; then
 957     LN_S_FILEONLY=ln
 958   fi
 959 fi
 960
 961 rm -f conf$$ conf$$.file
 962
 963 if test "$LN_S_FILEONLY" = "ln -s"; then
 964    AC_MSG_RESULT([yes])
 965 else
 966    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
 967 fi
 968
 969 AC_SUBST(LN_S_FILEONLY)
 970
 971
 972 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
 973 dnl doesn't support links to directories, as in "ln file dir".  But that
 974 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
 975 dnl executables at "make install" time.
 976 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
 977 dnl for more details.
 978 if test "$opsys" = "mingw32"; then
 979   LN_S="ln"
 980 fi
 981
 982 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 983   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 984 dnl Don't use GZIP, which is used by gzip for additional parameters.
 985 AC_PATH_PROG(GZIP_PROG, gzip)
 986
 987 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
 988    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
 989
 990 if test $opsys = gnu-linux; then
 991   AC_PATH_PROG(PAXCTL, paxctl,,
 992     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 993   if test "X$PAXCTL" != X; then
 994     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 995     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 996       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 997       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 998   fi
 999
1000   if test "${SETFATTR+set}" != set; then
1001     AC_CACHE_CHECK([for setfattr],
1002       [emacs_cv_prog_setfattr],
1003       [touch conftest.tmp
1004        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1005          emacs_cv_prog_setfattr=yes
1006        else
1007          emacs_cv_prog_setfattr=no
1008        fi])
1009     if test "$emacs_cv_prog_setfattr" = yes; then
1010       SETFATTR=setfattr
1011     else
1012       SETFATTR=
1013     fi
1014     rm -f conftest.tmp
1015     AC_SUBST([SETFATTR])
1016   fi
1017 fi
1018
1019 ## Need makeinfo >= 4.7 (?) to build the manuals.
1020 AC_PATH_PROG(MAKEINFO, makeinfo, no)
1021 dnl By this stage, configure has already checked for egrep and set EGREP,
1022 dnl or exited with an error if no egrep was found.
1023 if test "$MAKEINFO" != "no"; then
1024   case `
1025     $MAKEINFO --version 2> /dev/null |
1026     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
1027   ` in
1028     '') MAKEINFO=no;;
1029   esac
1030 fi
1031
1032 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1033 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1034 ## therefore in the category of "special tools" not normally required, which
1035 ## configure does not have to check for (eg autoconf itself).
1036 ## In a repository checkout on the other hand, the manuals are not included.
1037 ## So makeinfo is a requirement to build from the repository, and configure
1038 ## should test for it as it does for any other build requirement.
1039 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1040 ## with pre-built manuals, from a repository checkout.
1041 HAVE_MAKEINFO=yes
1042
1043 if test "$MAKEINFO" = "no"; then
1044   MAKEINFO=makeinfo
1045   if test "x${with_makeinfo}" = "xno"; then
1046     HAVE_MAKEINFO=no
1047   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1048     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1049 source tree does not seem to have pre-built manuals in the `info' directory.
1050 Either install a suitable version of makeinfo, or re-run configure
1051 with the `--without-makeinfo' option to build without the manuals.] )
1052   fi
1053 fi
1054 AC_SUBST(HAVE_MAKEINFO)
1055
1056 dnl Just so that there is only a single place we need to edit.
1057 INFO_EXT=.info
1058 INFO_OPTS=--no-split
1059 AC_SUBST(INFO_EXT)
1060 AC_SUBST(INFO_OPTS)
1061
1062 if test $opsys = mingw32; then
1063    DOCMISC_W32=efaq-w32
1064 else
1065    DOCMISC_W32=
1066 fi
1067 AC_SUBST(DOCMISC_W32)
1068
1069 dnl Add our options to ac_link now, after it is set up.
1070
1071 if test x$GCC = xyes; then
1072   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1073     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1074 else
1075   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1076     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1077 fi
1078
1079 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1080 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1081 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1082 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1083 dnl if not built to support GNU ld.
1084
1085 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1086 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1087 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1088 dnl   Eg "make LDFLAGS=... all" could run into problems,
1089 dnl   http://bugs.debian.org/684788
1090 dnl * unnecessary, since temacs is the only thing that actually needs it.
1091 dnl   Indeed this is where it was originally, prior to:
1092 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1093 late_LDFLAGS="$LDFLAGS"
1094 if test x$GCC = xyes; then
1095   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1096 else
1097   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1098 fi
1099
1100 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1101
1102 AC_MSG_CHECKING([for -znocombreloc])
1103 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1104   [AC_MSG_RESULT(yes)],
1105   LDFLAGS_NOCOMBRELOC=
1106   [AC_MSG_RESULT(no)])
1107
1108 LDFLAGS="$late_LDFLAGS"
1109
1110 AC_CACHE_CHECK([whether addresses are sanitized],
1111   [emacs_cv_sanitize_address],
1112   [AC_COMPILE_IFELSE(
1113      [AC_LANG_PROGRAM(
1114         [[#ifndef __has_feature
1115           #define __has_feature(f) 0
1116           #endif
1117           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1118           #else
1119            #error "Addresses are not sanitized."
1120           #endif
1121         ]])],
1122      [emacs_cv_sanitize_address=yes],
1123      [emacs_cv_sanitize_address=no])])
1124
1125 dnl The function dump-emacs will not be defined and temacs will do
1126 dnl (load "loadup") automatically unless told otherwise.
1127 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1128 case "$opsys" in
1129   your-opsys-here) CANNOT_DUMP=yes ;;
1130 esac
1131
1132 if test "$CANNOT_DUMP" = "yes"; then
1133   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1134 elif test "$emacs_cv_sanitize_address" = yes; then
1135   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1136 fi
1137
1138 AC_SUBST(CANNOT_DUMP)
1139
1140
1141 UNEXEC_OBJ=unexelf.o
1142 case "$opsys" in
1143   # MSDOS uses unexcoff.o
1144   aix4-2)
1145    UNEXEC_OBJ=unexaix.o
1146    ;;
1147   cygwin)
1148    UNEXEC_OBJ=unexcw.o
1149    ;;
1150   darwin)
1151    UNEXEC_OBJ=unexmacosx.o
1152    ;;
1153   hpux10-20 | hpux11)
1154    UNEXEC_OBJ=unexhp9k800.o
1155    ;;
1156   mingw32)
1157    UNEXEC_OBJ=unexw32.o
1158    ;;
1159   sol2-10)
1160    # Use the Solaris dldump() function, called from unexsol.c, to dump
1161    # emacs, instead of the generic ELF dump code found in unexelf.c.
1162    # The resulting binary has a complete symbol table, and is better
1163    # for debugging and other observability tools (debuggers, pstack, etc).
1164    #
1165    # If you encounter a problem using dldump(), please consider sending
1166    # a message to the OpenSolaris tools-linking mailing list:
1167    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1168    #
1169    # It is likely that dldump() works with older Solaris too, but this has
1170    # not been tested, so for now this change is for Solaris 10 or newer.
1171    UNEXEC_OBJ=unexsol.o
1172    ;;
1173 esac
1174
1175 LD_SWITCH_SYSTEM=
1176 case "$opsys" in
1177   freebsd|dragonfly)
1178    ## Let `ld' find image libs and similar things in /usr/local/lib.
1179    ## The system compiler, GCC, has apparently been modified to not
1180    ## look there, contrary to what a stock GCC would do.
1181 ### It's not our place to do this.  See bug#10313#17.
1182 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1183       :
1184    ;;
1185
1186   gnu-linux)
1187    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1188    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1189    ;;
1190
1191   netbsd)
1192 ### It's not our place to do this.  See bug#10313#17.
1193 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1194       :
1195    ;;
1196
1197   openbsd)
1198    ## Han Boetes <han@boetes.org> says this is necessary,
1199    ## otherwise Emacs dumps core on elf systems.
1200    LD_SWITCH_SYSTEM="-Z"
1201    ;;
1202 esac
1203 AC_SUBST(LD_SWITCH_SYSTEM)
1204
1205 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1206
1207 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1208 ## which has not been defined yet.  When this was handled with cpp,
1209 ## it was expanded to null when configure sourced the s/*.h file.
1210 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1211 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1212 ## (or somesuch), but because it is supposed to go at the _front_
1213 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1214 ## Compare with the gnu-linux case below, which added to the end
1215 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1216 ## LD_SWITCH_SYSTEM_TEMACS.
1217 case "$opsys" in
1218   netbsd|openbsd)
1219    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1220 esac
1221
1222
1223 C_SWITCH_MACHINE=
1224 case $canonical in
1225  alpha*)
1226   AC_CHECK_DECL([__ELF__])
1227   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1228     ## With ELF, make sure that all common symbols get allocated to in the
1229     ## data section.  Otherwise, the dump of temacs may miss variables in
1230     ## the shared library that have been initialized.  For example, with
1231     ## GNU libc, __malloc_initialized would normally be resolved to the
1232     ## shared library's .bss section, which is fatal.
1233     if test "x$GCC" = "xyes"; then
1234       C_SWITCH_MACHINE="-fno-common"
1235     else
1236       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1237     fi
1238   else
1239       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1240       dnl albeit under the mistaken assumption that said file
1241       dnl was no longer used.
1242       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1243   fi
1244   ;;
1245 esac
1246 AC_SUBST(C_SWITCH_MACHINE)
1247
1248 AC_SUBST(UNEXEC_OBJ)
1249
1250 C_SWITCH_SYSTEM=
1251 ## Some programs in src produce warnings saying certain subprograms
1252 ## are too complex and need a MAXMEM value greater than 2000 for
1253 ## additional optimization.  --nils@exp-math.uni-essen.de
1254 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1255   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1256 if test "$opsys" = "mingw32"; then
1257   case "$canonical" in
1258     x86_64-*-mingw32) C_SWITCH_SYSTEM="-mtune=generic" ;;
1259     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1260   esac
1261 fi
1262 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1263 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1264 AC_SUBST(C_SWITCH_SYSTEM)
1265
1266
1267 LIBS_SYSTEM=
1268 case "$opsys" in
1269   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1270   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1271
1272   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1273
1274   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1275
1276   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1277
1278   ## Motif needs -lgen.
1279   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1280 esac
1281
1282 AC_SUBST(LIBS_SYSTEM)
1283
1284 ### Make sure subsequent tests use flags consistent with the build flags.
1285
1286 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1287   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1288 else
1289   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1290 fi
1291
1292 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1293 AC_DEFUN([AC_TYPE_SIZE_T])
1294 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1295 AC_DEFUN([AC_TYPE_UID_T])
1296
1297
1298 LIB_MATH=-lm
1299 dnl Current possibilities handled by sed (aix4-2 -> aix,
1300 dnl gnu-linux -> gnu/linux, etc.):
1301 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1302 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1303 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1304
1305 case $opsys in
1306   cygwin )
1307     LIB_MATH=
1308     ;;
1309   darwin )
1310     ## Adding -lm confuses the dynamic linker, so omit it.
1311     LIB_MATH=
1312     ;;
1313   freebsd | dragonfly )
1314     SYSTEM_TYPE=berkeley-unix
1315     ;;
1316   gnu-linux | gnu-kfreebsd )
1317     ;;
1318   hpux10-20 | hpux11 )
1319     ;;
1320   mingw32 )
1321     LIB_MATH=
1322     SYSTEM_TYPE=windows-nt
1323     ;;
1324   dnl NB this may be adjusted below.
1325   netbsd | openbsd )
1326     SYSTEM_TYPE=berkeley-unix
1327     ;;
1328
1329   sol2* | unixware )
1330     SYSTEM_TYPE=usg-unix-v
1331     ;;
1332
1333 esac
1334
1335 AC_SUBST(LIB_MATH)
1336 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1337   [The type of system you are compiling for; sets `system-type'.])
1338
1339
1340 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1341 pre_PKG_CONFIG_LIBS=$LIBS
1342
1343 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1344
1345 dnl This function definition taken from Gnome 2.0
1346 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1347 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1348 dnl also defines GSTUFF_PKG_ERRORS on error
1349 AC_DEFUN([PKG_CHECK_MODULES], [
1350   succeeded=no
1351
1352   if test "$PKG_CONFIG" = "no" ; then
1353      ifelse([$4], , [AC_MSG_ERROR([
1354       *** The pkg-config script could not be found. Make sure it is in your path, or give the full name of pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1355   else
1356      PKG_CONFIG_MIN_VERSION=0.9.0
1357      if "$PKG_CONFIG" --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1358         AC_MSG_CHECKING(for $2)
1359
1360         if "$PKG_CONFIG" --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1361            $1_CFLAGS=`"$PKG_CONFIG" --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1362            $1_LIBS=`"$PKG_CONFIG" --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1363             edit_cflags="
1364               s,///*,/,g
1365               s/^/ /
1366               s/ -I/ $isystem/g
1367               s/^ //
1368             "
1369             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1370             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1371             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1372             succeeded=yes
1373         else
1374             AC_MSG_RESULT(no)
1375             $1_CFLAGS=""
1376             $1_LIBS=""
1377             ## If we have a custom action on failure, don't print errors, but
1378             ## do set a variable so people can do so.  Do it in a subshell
1379             ## to capture any diagnostics in invoking pkg-config.
1380             $1_PKG_ERRORS=`("$PKG_CONFIG" --print-errors "$2") 2>&1`
1381             ifelse([$4], ,echo "$$1_PKG_ERRORS",)
1382         fi
1383
1384         AC_SUBST($1_CFLAGS)
1385         AC_SUBST($1_LIBS)
1386      else
1387         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1388         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1389      fi
1390   fi
1391
1392   if test $succeeded = yes; then
1393      ifelse([$3], , :, [$3])
1394   else
1395      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1396   fi
1397 ])
1398
1399 HAVE_SOUND=no
1400 if test "${with_sound}" != "no"; then
1401   # Sound support for GNU/Linux, the free BSDs, and MinGW.
1402   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h],
1403     have_sound_header=yes, [], [
1404     #ifdef __MINGW32__
1405     #define WIN32_LEAN_AND_MEAN
1406     #include <windows.h>
1407     #endif
1408     ])
1409   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1410     AC_MSG_ERROR([OSS sound support requested but not found.])
1411
1412   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1413     # Emulation library used on NetBSD.
1414     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1415     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1416       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1417     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1418     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1419   fi
1420   AC_SUBST(LIBSOUND)
1421
1422   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1423     ALSA_REQUIRED=1.0.0
1424     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1425     PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1426     if test $HAVE_ALSA = yes; then
1427       SAVE_CFLAGS="$CFLAGS"
1428       SAVE_LIBS="$LIBS"
1429       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1430       LIBS="$ALSA_LIBS $LIBS"
1431       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1432                       emacs_alsa_normal=yes,
1433                     emacs_alsa_normal=no)
1434       if test "$emacs_alsa_normal" != yes; then
1435         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1436                        [[snd_lib_error_set_handler (0);]])],
1437                        emacs_alsa_subdir=yes,
1438                      emacs_alsa_subdir=no)
1439         if test "$emacs_alsa_subdir" != yes; then
1440           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1441         fi
1442         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1443       fi
1444
1445       CFLAGS="$SAVE_CFLAGS"
1446       LIBS="$SAVE_LIBS"
1447       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1448       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1449       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1450     elif test "${with_sound}" = "alsa"; then
1451       AC_MSG_ERROR([ALSA sound support requested but not found.])
1452     fi
1453   fi                            dnl with_sound = alsa|yes
1454
1455   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1456   dnl compiles only on the specified platforms.  For others, it
1457   dnl probably doesn't make sense to try.
1458   dnl FIXME So surely we should bypass this whole section if not using
1459   dnl one of these platforms?
1460   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1461      case "$opsys" in
1462        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1463        dnl Adjust the --with-sound help text if you change this.
1464        gnu-linux|freebsd|netbsd|mingw32)
1465          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1466          HAVE_SOUND=yes
1467          ;;
1468      esac
1469   fi
1470
1471   AC_SUBST(CFLAGS_SOUND)
1472 fi
1473
1474 dnl checks for header files
1475 AC_CHECK_HEADERS_ONCE(
1476   sys/systeminfo.h
1477   coff.h pty.h
1478   sys/resource.h
1479   sys/utsname.h pwd.h utmp.h util.h)
1480
1481 AC_MSG_CHECKING(if personality LINUX32 can be set)
1482 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1483                emacs_cv_personality_linux32=yes,
1484                emacs_cv_personality_linux32=no)
1485 AC_MSG_RESULT($emacs_cv_personality_linux32)
1486
1487 if test $emacs_cv_personality_linux32 = yes; then
1488   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1489             [Define to 1 if personality LINUX32 can be set.])
1490 fi
1491
1492 dnl On Solaris 8 there's a compilation warning for term.h because
1493 dnl it doesn't define `bool'.
1494 AC_CHECK_HEADERS(term.h, , , -)
1495 AC_HEADER_TIME
1496 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1497                                       ]])
1498 if test $ac_cv_have_decl_sys_siglist != yes; then
1499   # For Tru64, at least:
1500   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1501                                           ]])
1502 fi
1503 AC_HEADER_SYS_WAIT
1504
1505 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1506 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1507 #if HAVE_SYS_SOCKET_H
1508 #include <sys/socket.h>
1509 #endif])
1510 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1511 #if HAVE_SYS_SOCKET_H
1512 #include <sys/socket.h>
1513 #endif])
1514 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1515 #if HAVE_SYS_SOCKET_H
1516 #include <sys/socket.h>
1517 #endif])
1518
1519 dnl checks for structure members
1520 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1521                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1522                   struct ifreq.ifr_addr,
1523                   struct ifreq.ifr_addr.sa_len], , ,
1524                  [AC_INCLUDES_DEFAULT
1525 #if HAVE_SYS_SOCKET_H
1526 #include <sys/socket.h>
1527 #endif
1528 #if HAVE_NET_IF_H
1529 #include <net/if.h>
1530 #endif])
1531
1532 dnl Check for endianness.
1533 dnl AC_C_BIGENDIAN is done by gnulib.
1534
1535 dnl check for Make feature
1536 dnl AC_PROG_MAKE_SET is done by Automake.
1537
1538 DEPFLAGS=
1539 MKDEPDIR=":"
1540 deps_frag=deps.mk
1541 dnl check if we have GCC and autodepend is on.
1542 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1543    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1544    SAVE_CFLAGS="$CFLAGS"
1545    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1546    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1547    CFLAGS="$SAVE_CFLAGS"
1548    test -f deps.d || ac_enable_autodepend=no
1549    rm -rf deps.d
1550    AC_MSG_RESULT([$ac_enable_autodepend])
1551    if test $ac_enable_autodepend = yes; then
1552       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1553       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1554       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1555       deps_frag=autodeps.mk
1556    fi
1557 fi
1558 deps_frag=$srcdir/src/$deps_frag
1559 AC_SUBST(MKDEPDIR)
1560 AC_SUBST(DEPFLAGS)
1561 AC_SUBST_FILE(deps_frag)
1562
1563
1564 lisp_frag=$srcdir/src/lisp.mk
1565 AC_SUBST_FILE(lisp_frag)
1566
1567
1568 dnl checks for operating system services
1569 AC_SYS_LONG_FILE_NAMES
1570
1571 #### Choose a window system.
1572
1573 ## We leave window_system equal to none if
1574 ## we end up building without one.  Any new window system should
1575 ## set window_system to an appropriate value and add objects to
1576 ## window-system-specific substs.
1577
1578 window_system=none
1579 AC_PATH_X
1580 if test "$no_x" != yes; then
1581   window_system=x11
1582 fi
1583
1584 LD_SWITCH_X_SITE_RPATH=
1585 if test "${x_libraries}" != NONE; then
1586   if test -n "${x_libraries}"; then
1587     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1588     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1589   fi
1590   x_default_search_path=""
1591   x_search_path=${x_libraries}
1592   if test -z "${x_search_path}"; then
1593     x_search_path=/usr/lib
1594   fi
1595   for x_library in `echo ${x_search_path}: | \
1596                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1597     x_search_path="\
1598 ${x_library}/X11/%L/%T/%N%C%S:\
1599 ${x_library}/X11/%l/%T/%N%C%S:\
1600 ${x_library}/X11/%T/%N%C%S:\
1601 ${x_library}/X11/%L/%T/%N%S:\
1602 ${x_library}/X11/%l/%T/%N%S:\
1603 ${x_library}/X11/%T/%N%S"
1604     if test x"${x_default_search_path}" = x; then
1605       x_default_search_path=${x_search_path}
1606     else
1607       x_default_search_path="${x_search_path}:${x_default_search_path}"
1608     fi
1609   done
1610 fi
1611 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1612
1613 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1614   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1615 fi
1616
1617 if test x"${x_includes}" = x; then
1618   bitmapdir=/usr/include/X11/bitmaps
1619 else
1620   # accumulate include directories that have X11 bitmap subdirectories
1621   bmd_acc="dummyval"
1622   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1623     if test -d "${bmd}/X11/bitmaps"; then
1624       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1625     fi
1626     if test -d "${bmd}/bitmaps"; then
1627       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1628     fi
1629   done
1630   if test ${bmd_acc} != "dummyval"; then
1631     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1632   fi
1633 fi
1634
1635 HAVE_NS=no
1636 NS_IMPL_COCOA=no
1637 NS_IMPL_GNUSTEP=no
1638 tmp_CPPFLAGS="$CPPFLAGS"
1639 tmp_CFLAGS="$CFLAGS"
1640 CPPFLAGS="$CPPFLAGS -x objective-c"
1641 CFLAGS="$CFLAGS -x objective-c"
1642 GNU_OBJC_CFLAGS=
1643 LIBS_GNUSTEP=
1644 if test "${with_ns}" != no; then
1645   if test "${opsys}" = darwin; then
1646      NS_IMPL_COCOA=yes
1647      ns_appdir=`pwd`/nextstep/Emacs.app
1648      ns_appbindir=${ns_appdir}/Contents/MacOS
1649      ns_appresdir=${ns_appdir}/Contents/Resources
1650      ns_appsrc=Cocoa/Emacs.base
1651   elif test -f $GNUSTEP_CONFIG_FILE; then
1652      NS_IMPL_GNUSTEP=yes
1653      ns_appdir=`pwd`/nextstep/Emacs.app
1654      ns_appbindir=${ns_appdir}
1655      ns_appresdir=${ns_appdir}/Resources
1656      ns_appsrc=GNUstep/Emacs.base
1657      dnl FIXME sourcing this several times in subshells seems inefficient.
1658      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1659      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1660      dnl I seemed to need these as well with GNUstep-startup 0.25.
1661      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1662      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1663      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1664        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1665      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1666        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1667      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1668      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1669      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1670      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1671      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1672      dnl If they had chosen to either define it or not, we could have
1673      dnl just used AC_CHECK_DECL here.
1674      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1675        emacs_cv_objc_exceptions,
1676 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1677 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1678 1;
1679 #else
1680 fail;
1681 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1682      if test $emacs_cv_objc_exceptions = yes; then
1683        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1684        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1685          [Define if GNUstep uses ObjC exceptions.])
1686        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1687      fi
1688   fi
1689
1690   dnl This is only used while we test the NS headers, it gets reset below.
1691   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1692
1693   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1694                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1695   files are missing or cannot be compiled.])])
1696
1697   macfont_file=""
1698   if test "${NS_IMPL_COCOA}" = "yes"; then
1699     AC_MSG_CHECKING([for OSX 10.4 or newer])
1700     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1701                                      [
1702 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1703 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1704  ; /* OK */
1705 #else
1706 #error "OSX 10.4 or newer required"
1707 #endif
1708 #endif
1709                     ])],
1710                     ns_osx_have_104=yes,
1711                     ns_osx_have_104=no)
1712     AC_MSG_RESULT([$ns_osx_have_104])
1713
1714     if test $ns_osx_have_104 = no; then
1715        AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1716     fi
1717     AC_MSG_CHECKING([for OSX 10.5 or newer])
1718     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1719                                      [
1720 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1721 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1050
1722  ; /* OK */
1723 #else
1724 #error "OSX 10.5 not found"
1725 #endif
1726 #endif
1727                     ])],
1728                     ns_osx_have_105=yes,
1729                     ns_osx_have_105=no)
1730     AC_MSG_RESULT([$ns_osx_have_105])
1731     if test $ns_osx_have_105 = yes; then
1732       macfont_file="macfont.o"
1733     fi
1734   fi
1735   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1736                                      [NSInteger i;])],
1737                     ns_have_nsinteger=yes,
1738                     ns_have_nsinteger=no)
1739   if test $ns_have_nsinteger = yes; then
1740     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1741   fi
1742 fi
1743
1744 AC_SUBST(LIBS_GNUSTEP)
1745
1746 INSTALL_ARCH_INDEP_EXTRA=install-etc
1747 ns_self_contained=no
1748 NS_OBJ=
1749 NS_OBJC_OBJ=
1750 if test "${HAVE_NS}" = yes; then
1751   if test "$with_toolkit_scroll_bars" = "no"; then
1752     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1753   fi
1754
1755   window_system=nextstep
1756   # set up packaging dirs
1757   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1758      ns_self_contained=yes
1759      prefix=${ns_appresdir}
1760      exec_prefix=${ns_appbindir}
1761      dnl This one isn't really used, only archlibdir is.
1762      libexecdir="\${ns_appbindir}/libexec"
1763      archlibdir="\${ns_appbindir}/libexec"
1764      etcdocdir="\${ns_appresdir}/etc"
1765      etcdir="\${ns_appresdir}/etc"
1766      dnl FIXME maybe set datarootdir instead.
1767      dnl That would also get applications, icons, man.
1768      infodir="\${ns_appresdir}/info"
1769      mandir="\${ns_appresdir}/man"
1770      lispdir="\${ns_appresdir}/lisp"
1771      INSTALL_ARCH_INDEP_EXTRA=
1772   fi
1773
1774   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o $macfont_file"
1775 fi
1776 CFLAGS="$tmp_CFLAGS"
1777 CPPFLAGS="$tmp_CPPFLAGS"
1778 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1779 AC_SUBST(ns_self_contained)
1780 AC_SUBST(NS_OBJ)
1781 AC_SUBST(NS_OBJC_OBJ)
1782
1783 HAVE_W32=no
1784 W32_OBJ=
1785 W32_LIBS=
1786 EMACSRES=
1787 CLIENTRES=
1788 CLIENTW=
1789 W32_RES_LINK=
1790 EMACS_MANIFEST=
1791 UPDATE_MANIFEST=
1792 if test "${with_w32}" != no; then
1793   case "${opsys}" in
1794     cygwin)
1795       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1796              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1797                    cannot be found.])])
1798     ;;
1799     mingw32)
1800     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1801     ;;
1802     *)
1803       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1804     ;;
1805   esac
1806 fi
1807
1808 if test "${opsys}" = "mingw32"; then
1809   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1810   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1811      #include <windows.h>
1812      #include <usp10.h>]],
1813    [[PIMAGE_NT_HEADERS pHeader;
1814      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1815    [emacs_cv_w32api=yes
1816     HAVE_W32=yes],
1817    emacs_cv_w32api=no)
1818   AC_MSG_RESULT($emacs_cv_w32api)
1819   if test "${emacs_cv_w32api}" = "no"; then
1820     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1821   fi
1822 fi
1823
1824 FIRSTFILE_OBJ=
1825 NTDIR=
1826 LIBS_ECLIENT=
1827 LIB_WSOCK32=
1828 NTLIB=
1829 CM_OBJ="cm.o"
1830 XARGS_LIMIT=
1831 if test "${HAVE_W32}" = "yes"; then
1832   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1833   AC_CHECK_TOOL(WINDRES, [windres],
1834                 [AC_MSG_ERROR([No resource compiler found.])])
1835   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1836   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1837   EMACSRES="emacs.res"
1838   if test "${opsys}" = "cygwin"; then
1839     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1840     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1841     # Tell the linker that emacs.res is an object (which we compile from
1842     # the rc file), not a linker script.
1843     W32_RES_LINK="-Wl,emacs.res"
1844   else
1845     case "$canonical" in
1846       x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1847       *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1848     esac
1849     UPDATE_MANIFEST=update-game-score.exe.manifest
1850     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1851     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1852     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1853     W32_RES_LINK="\$(EMACSRES)"
1854     CLIENTRES="emacsclient.res"
1855     CLIENTW="emacsclientw\$(EXEEXT)"
1856     FIRSTFILE_OBJ=firstfile.o
1857     NTDIR=nt
1858     CM_OBJ=
1859     LIBS_ECLIENT="-lcomctl32"
1860     LIB_WSOCK32="-lwsock32"
1861     NTLIB="ntlib.$ac_objext"
1862     XARGS_LIMIT="-s 10000"
1863   fi
1864 fi
1865 AC_SUBST(W32_OBJ)
1866 AC_SUBST(W32_LIBS)
1867 AC_SUBST(EMACSRES)
1868 AC_SUBST(EMACS_MANIFEST)
1869 AC_SUBST(UPDATE_MANIFEST)
1870 AC_SUBST(CLIENTRES)
1871 AC_SUBST(CLIENTW)
1872 AC_SUBST(W32_RES_LINK)
1873 AC_SUBST(FIRSTFILE_OBJ)
1874 AC_SUBST(NTDIR)
1875 AC_SUBST(CM_OBJ)
1876 AC_SUBST(LIBS_ECLIENT)
1877 AC_SUBST(LIB_WSOCK32)
1878 AC_SUBST(NTLIB)
1879 AC_SUBST(XARGS_LIMIT)
1880
1881 if test "${HAVE_W32}" = "yes"; then
1882   window_system=w32
1883   with_xft=no
1884 fi
1885
1886 ## $window_system is now set to the window system we will
1887 ## ultimately use.
1888
1889 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
1890    # Too many warnings for now.
1891    nw=
1892    nw="$nw -Wsuggest-attribute=const"
1893    nw="$nw -Wsuggest-attribute=noreturn"
1894    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1895
1896    gl_WARN_ADD([-Wno-unused-variable])
1897    gl_WARN_ADD([-Wno-unused-but-set-variable])
1898    gl_WARN_ADD([-Wno-unused-but-set-parameter])
1899 fi
1900
1901 term_header=
1902 HAVE_X_WINDOWS=no
1903 HAVE_X11=no
1904 USE_X_TOOLKIT=none
1905
1906 case "${window_system}" in
1907   x11 )
1908     HAVE_X_WINDOWS=yes
1909     HAVE_X11=yes
1910     term_header=xterm.h
1911     case "${with_x_toolkit}" in
1912       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1913       motif ) USE_X_TOOLKIT=MOTIF ;;
1914       gtk ) with_gtk=yes
1915             term_header=gtkutil.h
1916 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1917 dnl USE_X_TOOLKIT is set.
1918             USE_X_TOOLKIT=none ;;
1919       gtk2 ) with_gtk2=yes
1920              term_header=gtkutil.h
1921              USE_X_TOOLKIT=none ;;
1922       gtk3 ) with_gtk3=yes
1923              term_header=gtkutil.h
1924              USE_X_TOOLKIT=none ;;
1925       no ) USE_X_TOOLKIT=none ;;
1926 dnl If user did not say whether to use a toolkit, make this decision later:
1927 dnl use the toolkit if we have gtk, or X11R5 or newer.
1928       * ) USE_X_TOOLKIT=maybe ;;
1929     esac
1930   ;;
1931   nextstep )
1932     term_header=nsterm.h
1933   ;;
1934   w32 )
1935     term_header=w32term.h
1936   ;;
1937 esac
1938
1939 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1940    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1941    if test "$HAVE_XSERVER" = true ||
1942       test -n "$DISPLAY" ||
1943       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1944         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1945 were found.  You should install the relevant development files for X
1946 and for the toolkit you want, such as Gtk+ or Motif.  Also make
1947 sure you have development files for image handling, i.e.
1948 tiff, gif, jpeg, png and xpm.
1949 If you are sure you want Emacs compiled without X window support, pass
1950   --without-x
1951 to configure.])
1952    fi
1953 fi
1954
1955 # Does the opsystem file prohibit the use of the GNU malloc?
1956 # Assume not, until told otherwise.
1957 GNU_MALLOC=yes
1958
1959 AC_CACHE_CHECK(
1960   [whether malloc is Doug Lea style],
1961   [emacs_cv_var_doug_lea_malloc],
1962   [emacs_cv_var_doug_lea_malloc=no
1963    dnl Hooks do not work with address sanitization.
1964    if test "$emacs_cv_sanitize_address" != yes; then
1965      AC_LINK_IFELSE(
1966        [AC_LANG_PROGRAM(
1967           [[#include <malloc.h>
1968             static void hook (void) {}]],
1969           [[malloc_set_state (malloc_get_state ());
1970             __after_morecore_hook = hook;
1971             __malloc_initialize_hook = hook;]])],
1972        [emacs_cv_var_doug_lea_malloc=yes])])
1973    fi
1974 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1975
1976 system_malloc=$emacs_cv_sanitize_address
1977 case "$opsys" in
1978   ## darwin ld insists on the use of malloc routines in the System framework.
1979   darwin|sol2-10) system_malloc=yes ;;
1980 esac
1981
1982 GMALLOC_OBJ=
1983 if test "${system_malloc}" = "yes"; then
1984   AC_DEFINE([SYSTEM_MALLOC], 1,
1985     [Define to 1 to use the system memory allocator, even if it is not
1986      Doug Lea style.])
1987   GNU_MALLOC=no
1988   GNU_MALLOC_reason="
1989     (The GNU allocators don't work with this system configuration.)"
1990   VMLIMIT_OBJ=
1991 else
1992   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1993   VMLIMIT_OBJ=vm-limit.o
1994
1995   AC_CHECK_HEADERS([sys/vlimit.h])
1996   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
1997     [AC_LINK_IFELSE(
1998        [AC_LANG_PROGRAM(
1999          [[extern char data_start[]; char ch;]],
2000          [[return data_start < &ch;]])],
2001        [emacs_cv_data_start=yes],
2002        [emacs_cv_data_start=no])])
2003   if test $emacs_cv_data_start = yes; then
2004     AC_DEFINE([HAVE_DATA_START], 1,
2005       [Define to 1 if data_start is the address of the start
2006        of the main data segment.])
2007   fi
2008 fi
2009 AC_SUBST(GMALLOC_OBJ)
2010 AC_SUBST(VMLIMIT_OBJ)
2011
2012 if test "$doug_lea_malloc" = "yes" ; then
2013   if test "$GNU_MALLOC" = yes ; then
2014     GNU_MALLOC_reason="
2015       (Using Doug Lea's new malloc from the GNU C Library.)"
2016   fi
2017   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2018     [Define to 1 if the system memory allocator is Doug Lea style,
2019      with malloc hooks and malloc_set_state.])
2020
2021   ## Use mmap directly for allocating larger buffers.
2022   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2023   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2024   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2025   case "$opsys" in
2026     gnu*) REL_ALLOC=no ;;
2027   esac
2028 fi
2029
2030 if test x"${REL_ALLOC}" = x; then
2031   REL_ALLOC=${GNU_MALLOC}
2032 fi
2033
2034 use_mmap_for_buffers=no
2035 case "$opsys" in
2036   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2037 esac
2038
2039 AC_FUNC_MMAP
2040 if test $use_mmap_for_buffers = yes; then
2041   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2042   REL_ALLOC=no
2043 fi
2044
2045 LIBS="$LIBS_SYSTEM $LIBS"
2046
2047 dnl If found, this adds -ldnet to LIBS, which Autoconf uses for checks.
2048 AC_CHECK_LIB(dnet, dnet_ntoa)
2049 dnl This causes -lresolv to get used in subsequent tests,
2050 dnl which causes failures on some systems such as HPUX 9.
2051 dnl AC_CHECK_LIB(resolv, gethostbyname)
2052
2053 dnl FIXME replace main with a function we actually want from this library.
2054 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2055
2056 dnl Check if pthreads is available.
2057 LIB_PTHREAD=
2058 AC_CHECK_HEADERS_ONCE(pthread.h)
2059 if test "$ac_cv_header_pthread_h"; then
2060   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
2061   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
2062   dnl testing for pthread_self if Emacs uses gmalloc.c.
2063   if test "$GMALLOC_OBJ" = gmalloc.o; then
2064     emacs_pthread_function=pthread_atfork
2065   else
2066     emacs_pthread_function=pthread_self
2067   fi
2068   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
2069 fi
2070 if test "$HAVE_PTHREAD" = yes; then
2071   case "${canonical}" in
2072     *-hpux*) ;;
2073     *) LIB_PTHREAD="-lpthread"
2074        LIBS="$LIB_PTHREAD $LIBS" ;;
2075   esac
2076   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
2077 fi
2078 AC_SUBST([LIB_PTHREAD])
2079
2080 AC_CHECK_LIB(pthreads, cma_open)
2081
2082 ## Note: when using cpp in s/aix4.2.h, this definition depended on
2083 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
2084 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
2085 ## added to LIBS in configure would never contain the pthreads part,
2086 ## but the value used in Makefiles might.  FIXME?
2087 ##
2088 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
2089 ## be harmless on older versions of X where it happens to exist.
2090 test "$opsys" = "aix4-2" && \
2091   test $ac_cv_lib_pthreads_cma_open = yes && \
2092   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
2093
2094 dnl Check for need for bigtoc support on IBM AIX
2095
2096 case ${host_os} in
2097 aix*)
2098   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2099     case $GCC in
2100     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2101     *) gdb_cv_bigtoc=-bbigtoc ;;
2102     esac
2103
2104     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2105     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2106   ])
2107   ;;
2108 esac
2109
2110 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
2111 # used for the tests that follow.  We set them back to REAL_CFLAGS and
2112 # REAL_CPPFLAGS later on.
2113
2114 REAL_CFLAGS="$CFLAGS"
2115 REAL_CPPFLAGS="$CPPFLAGS"
2116
2117 if test "${HAVE_X11}" = "yes"; then
2118   DEFS="$C_SWITCH_X_SITE $DEFS"
2119   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2120   LIBS="-lX11 $LIBS"
2121   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2122   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2123
2124   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2125   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2126   # but it's more convenient here to set LD_RUN_PATH since this
2127   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2128   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2129     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2130     export LD_RUN_PATH
2131   fi
2132
2133   if test "${opsys}" = "gnu-linux"; then
2134     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2135     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2136      [[XOpenDisplay ("foo");]])],
2137      [xgnu_linux_first_failure=no],
2138      [xgnu_linux_first_failure=yes])
2139     if test "${xgnu_linux_first_failure}" = "yes"; then
2140       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
2141       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
2142       OLD_CPPFLAGS="$CPPFLAGS"
2143       OLD_LIBS="$LIBS"
2144       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2145       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2146       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2147       LIBS="$LIBS -b i486-linuxaout"
2148       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2149        [[XOpenDisplay ("foo");]])],
2150        [xgnu_linux_second_failure=no],
2151        [xgnu_linux_second_failure=yes])
2152       if test "${xgnu_linux_second_failure}" = "yes"; then
2153         # If we get the same failure with -b, there is no use adding -b.
2154         # So take it out.  This plays safe.
2155         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
2156         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
2157         CPPFLAGS="$OLD_CPPFLAGS"
2158         LIBS="$OLD_LIBS"
2159         AC_MSG_RESULT(no)
2160       else
2161         AC_MSG_RESULT(yes)
2162       fi
2163     else
2164       AC_MSG_RESULT(no)
2165     fi
2166   fi
2167
2168   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2169   # header files included from there.
2170   AC_MSG_CHECKING(for Xkb)
2171   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2172 #include <X11/XKBlib.h>]],
2173         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2174         emacs_xkb=yes, emacs_xkb=no)
2175   AC_MSG_RESULT($emacs_xkb)
2176   if test $emacs_xkb = yes; then
2177     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2178   fi
2179
2180   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2181 XScreenNumberOfScreen)
2182 fi
2183
2184 if test "${window_system}" = "x11"; then
2185   AC_MSG_CHECKING(X11 version 6)
2186   AC_CACHE_VAL(emacs_cv_x11_version_6,
2187   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2188 [[#if XlibSpecificationRelease < 6
2189 fail;
2190 #endif
2191 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2192   if test $emacs_cv_x11_version_6 = yes; then
2193     AC_MSG_RESULT(6 or newer)
2194     AC_DEFINE(HAVE_X11R6, 1,
2195               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2196     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2197     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2198     ## XIM support.
2199     case "$opsys" in
2200       sol2-*) : ;;
2201       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2202            [Define if you have usable X11R6-style XIM support.])
2203          ;;
2204     esac
2205   else
2206     AC_MSG_RESULT(before 6)
2207   fi
2208 fi
2209
2210
2211 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2212 HAVE_RSVG=no
2213 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2214   if test "${with_rsvg}" != "no"; then
2215     RSVG_REQUIRED=2.11.0
2216     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2217
2218     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
2219     AC_SUBST(RSVG_CFLAGS)
2220     AC_SUBST(RSVG_LIBS)
2221
2222     if test $HAVE_RSVG = yes; then
2223       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2224       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2225       # Windows loads librsvg dynamically
2226       if test "${opsys}" = "mingw32"; then
2227         RSVG_LIBS=
2228       fi
2229       LIBS="$RSVG_LIBS $LIBS"
2230     fi
2231   fi
2232 fi
2233
2234 HAVE_IMAGEMAGICK=no
2235 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2236   if test "${with_imagemagick}" != "no"; then
2237     ## 6.2.8 is the earliest version known to work, but earlier versions
2238     ## might work - let us know if you find one.
2239     ## 6.0.7 does not work.  See bug#7955.
2240     ## 6.8.2 makes Emacs crash; see Bug#13867.
2241     IMAGEMAGICK_MODULE="Wand >= 6.2.8 Wand != 6.8.2"
2242     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
2243     AC_SUBST(IMAGEMAGICK_CFLAGS)
2244     AC_SUBST(IMAGEMAGICK_LIBS)
2245
2246     if test $HAVE_IMAGEMAGICK = yes; then
2247       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2248       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2249       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2250       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2251     fi
2252   fi
2253 fi
2254
2255
2256 HAVE_GTK=no
2257 GTK_OBJ=
2258 gtk_term_header=$term_header
2259 check_gtk2=no
2260 gtk3_pkg_errors=
2261 if test "${opsys}" != "mingw32"; then
2262   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2263     GLIB_REQUIRED=2.28
2264     GTK_REQUIRED=3.0
2265     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2266
2267     dnl Checks for libraries.
2268     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2269     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2270        AC_MSG_ERROR($GTK_PKG_ERRORS)
2271     fi
2272     if test "$pkg_check_gtk" = "yes"; then
2273        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2274        GTK_OBJ=emacsgtkfixed.o
2275        gtk_term_header=gtkutil.h
2276        USE_GTK_TOOLKIT="GTK3"
2277        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2278          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2279            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2280          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2281            [Define to 1 to disable Glib deprecation warnings.])
2282        fi
2283     else
2284        check_gtk2=yes
2285        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2286     fi
2287   fi
2288
2289   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2290     GLIB_REQUIRED=2.10
2291     GTK_REQUIRED=2.10
2292     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2293
2294     dnl Checks for libraries.
2295     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2296     if test "$pkg_check_gtk" = "no" &&
2297        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2298     then
2299       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2300     fi
2301     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2302   fi
2303 fi
2304
2305 if test x"$pkg_check_gtk" = xyes; then
2306
2307   AC_SUBST(GTK_LIBS)
2308   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2309   CFLAGS="$CFLAGS $GTK_CFLAGS"
2310   LIBS="$GTK_LIBS $LIBS"
2311   dnl Try to compile a simple GTK program.
2312   AC_MSG_CHECKING([whether GTK compiles])
2313   GTK_COMPILES=no
2314   AC_LINK_IFELSE(
2315     [AC_LANG_PROGRAM(
2316        [[/* Check the Gtk and Glib APIs.  */
2317          #include <gtk/gtk.h>
2318          #include <glib-object.h>
2319          static void
2320          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2321          {}
2322        ]],
2323        [[
2324          GtkSettings *gs = 0;
2325          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2326             strict C prohibits this.  Use gtk_main_iteration to test that the
2327             libraries are there.  */
2328          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2329                                     0, 0, 0, G_CALLBACK (callback), 0))
2330            gtk_main_iteration ();
2331        ]])],
2332     [GTK_COMPILES=yes])
2333   AC_MSG_RESULT([$GTK_COMPILES])
2334   if test "${GTK_COMPILES}" != "yes"; then
2335     GTK_OBJ=
2336     if test "$USE_X_TOOLKIT" != "maybe"; then
2337       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2338     fi
2339   else
2340     HAVE_GTK=yes
2341     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2342     GTK_OBJ="gtkutil.o $GTK_OBJ"
2343     term_header=$gtk_term_header
2344     USE_X_TOOLKIT=none
2345     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2346       :
2347     else
2348       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2349        closing open displays.  This is no problem if you just use
2350        one display, but if you use more than one and close one of them
2351        Emacs may crash.]])
2352       sleep 3
2353     fi
2354   fi
2355
2356 fi
2357 AC_SUBST(GTK_OBJ)
2358
2359
2360 if test "${HAVE_GTK}" = "yes"; then
2361
2362   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2363   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2364   if test "$with_toolkit_scroll_bars" != no; then
2365     with_toolkit_scroll_bars=yes
2366   fi
2367
2368   dnl  Check if we have the old file selection dialog declared and
2369   dnl  in the link library.  In 2.x it may be in the library,
2370   dnl  but not declared if deprecated featured has been selected out.
2371   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2372   HAVE_GTK_FILE_SELECTION=no
2373   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2374                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2375 #include <gtk/gtk.h>])
2376   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2377     AC_CHECK_FUNCS(gtk_file_selection_new)
2378   fi
2379
2380   dnl Same as above for gtk_handle_box.
2381   HAVE_GTK_HANDLE_BOX=no
2382   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2383                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2384 #include <gtk/gtk.h>])
2385   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2386     AC_CHECK_FUNCS(gtk_handle_box_new)
2387   fi
2388
2389   dnl Same as above for gtk_tearoff_menu_item.
2390   HAVE_GTK_TEAROFF_MENU_ITEM=no
2391   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2392                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2393 #include <gtk/gtk.h>])
2394   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2395     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2396   fi
2397
2398   dnl Check for functions introduced in 2.14 and later.
2399   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2400                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2401                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2402                  gtk_orientable_set_orientation \
2403                  gtk_window_set_has_resize_grip)
2404
2405  term_header=gtkutil.h
2406 fi
2407
2408 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2409 dnl other platforms.
2410 HAVE_DBUS=no
2411 DBUS_OBJ=
2412 if test "${with_dbus}" = "yes"; then
2413    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2414    if test "$HAVE_DBUS" = yes; then
2415      LIBS="$LIBS $DBUS_LIBS"
2416      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2417      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2418      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2419      dnl D-Bus 1.5.12.
2420      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2421                     dbus_type_is_valid \
2422                     dbus_validate_bus_name \
2423                     dbus_validate_path \
2424                     dbus_validate_interface \
2425                     dbus_validate_member)
2426      DBUS_OBJ=dbusbind.o
2427    fi
2428 fi
2429 AC_SUBST(DBUS_OBJ)
2430
2431 dnl GSettings has been tested under GNU/Linux only.
2432 HAVE_GSETTINGS=no
2433 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2434    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2435    if test "$HAVE_GSETTINGS" = "yes"; then
2436       old_CFLAGS=$CFLAGS
2437       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2438       old_LIBS=$LIBS
2439       LIBS="$LIBS $GSETTINGS_LIBS"
2440       AC_MSG_CHECKING([whether GSettings is in gio])
2441       AC_LINK_IFELSE(
2442          [AC_LANG_PROGRAM(
2443              [[/* Check that gsettings really is present.  */
2444              #include <glib-object.h>
2445              #include <gio/gio.h>
2446              ]],
2447              [[
2448                GSettings *settings;
2449                GVariant *val = g_settings_get_value (settings, "");
2450              ]])],
2451          [], HAVE_GSETTINGS=no)
2452       AC_MSG_RESULT([$HAVE_GSETTINGS])
2453
2454       if test "$HAVE_GSETTINGS" = "yes"; then
2455         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2456         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2457         SETTINGS_LIBS="$GSETTINGS_LIBS"
2458       fi
2459       CFLAGS=$old_CFLAGS
2460       LIBS=$old_LIBS
2461    fi
2462 fi
2463
2464 dnl GConf has been tested under GNU/Linux only.
2465 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2466 HAVE_GCONF=no
2467 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2468    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2469    if test "$HAVE_GCONF" = yes; then
2470       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2471       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2472       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2473       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2474    fi
2475 fi
2476
2477 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2478     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2479     if test "$HAVE_GOBJECT" = "yes"; then
2480        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2481        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2482     fi
2483     SAVE_CFLAGS="$CFLAGS"
2484     SAVE_LIBS="$LIBS"
2485     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2486     LIBS="$SETTINGS_LIBS $LIBS"
2487     CFLAGS="$SAVE_CFLAGS"
2488     LIBS="$SAVE_LIBS"
2489 fi
2490 AC_SUBST(SETTINGS_CFLAGS)
2491 AC_SUBST(SETTINGS_LIBS)
2492
2493
2494 dnl SELinux is available for GNU/Linux only.
2495 HAVE_LIBSELINUX=no
2496 LIBSELINUX_LIBS=
2497 if test "${with_selinux}" = "yes"; then
2498    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2499    if test "$HAVE_LIBSELINUX" = yes; then
2500       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2501       LIBSELINUX_LIBS=-lselinux
2502    fi
2503 fi
2504 AC_SUBST(LIBSELINUX_LIBS)
2505
2506 HAVE_GNUTLS=no
2507 HAVE_GNUTLS3=no
2508 if test "${with_gnutls}" = "yes" ; then
2509   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.0.0], HAVE_GNUTLS3=yes, HAVE_GNUTLS3=no)
2510   if test "${HAVE_GNUTLS3}" = "yes"; then
2511     AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])
2512     HAVE_GNUTLS="yes"
2513   else
2514     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2515   fi
2516   if test "${HAVE_GNUTLS}" = "yes"; then
2517     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2518   fi
2519
2520   # Windows loads GnuTLS dynamically
2521   if test "${opsys}" = "mingw32"; then
2522     LIBGNUTLS_LIBS=
2523   else
2524     CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2525     LIBS="$LIBGNUTLS_LIBS $LIBS"
2526   fi
2527 fi
2528
2529 AC_SUBST(LIBGNUTLS_LIBS)
2530 AC_SUBST(LIBGNUTLS_CFLAGS)
2531
2532 NOTIFY_OBJ=
2533 NOTIFY_SUMMARY=no
2534
2535 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2536 dnl a particular library.  This doesn't make much sense?
2537 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2538   with_file_notification=no
2539 fi
2540
2541 dnl MS Windows native file monitor is available for mingw32 only.
2542 case $with_file_notification,$opsys in
2543   w32,* | yes,mingw32)
2544     AC_CHECK_HEADER(windows.h)
2545     if test "$ac_cv_header_windows_h" = yes ; then
2546        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2547        NOTIFY_OBJ=w32notify.o
2548        NOTIFY_SUMMARY="yes (w32)"
2549     fi ;;
2550 esac
2551
2552 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2553 dnl has been added in glib 2.24.  It has been tested under
2554 dnl GNU/Linux only.  We take precedence over inotify, but this makes
2555 dnl only sense when glib has been compiled with inotify support.  How
2556 dnl to check?
2557 case $with_file_notification,$NOTIFY_OBJ in
2558   gfile, | yes,)
2559     PKG_CHECK_MODULES(GFILENOTIFY, gio-2.0 >= 2.24, HAVE_GFILENOTIFY=yes, HAVE_GFILENOTIFY=no)
2560     if test "$HAVE_GFILENOTIFY" = "yes"; then
2561        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2562        NOTIFY_OBJ=gfilenotify.o
2563        NOTIFY_SUMMARY="yes -lgio (gfile)"
2564     fi ;;
2565 esac
2566
2567 dnl inotify is only available on GNU/Linux.
2568 case $with_file_notification,$NOTIFY_OBJ in
2569   inotify, | yes,)
2570     AC_CHECK_HEADER(sys/inotify.h)
2571     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2572         AC_CHECK_FUNC(inotify_init1)
2573         if test "$ac_cv_func_inotify_init1" = yes; then
2574           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2575           NOTIFY_OBJ=inotify.o
2576           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2577        fi
2578     fi ;;
2579 esac
2580
2581 case $with_file_notification,$NOTIFY_OBJ in
2582   yes,* | no,* | *,?*) ;;
2583   *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;;
2584 esac
2585
2586 if test -n "$NOTIFY_OBJ"; then
2587    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2588 fi
2589 AC_SUBST(NOTIFY_OBJ)
2590 AC_SUBST(GFILENOTIFY_CFLAGS)
2591 AC_SUBST(GFILENOTIFY_LIBS)
2592
2593 dnl Do not put whitespace before the #include statements below.
2594 dnl Older compilers (eg sunos4 cc) choke on it.
2595 HAVE_XAW3D=no
2596 LUCID_LIBW=
2597 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2598   if test "$with_xaw3d" != no; then
2599     AC_CACHE_VAL(emacs_cv_xaw3d,
2600     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2601 #include <X11/Intrinsic.h>
2602 #include <X11/Xaw3d/Simple.h>]],
2603       [[]])],
2604       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2605                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2606       emacs_cv_xaw3d=no)])
2607   else
2608     emacs_cv_xaw3d=no
2609   fi
2610   if test $emacs_cv_xaw3d = yes; then
2611     AC_MSG_CHECKING(for xaw3d)
2612     AC_MSG_RESULT([yes; using Lucid toolkit])
2613     USE_X_TOOLKIT=LUCID
2614     HAVE_XAW3D=yes
2615     LUCID_LIBW=-lXaw3d
2616     AC_DEFINE(HAVE_XAW3D, 1,
2617               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2618   else
2619     AC_MSG_CHECKING(for xaw3d)
2620     AC_MSG_RESULT(no)
2621     AC_MSG_CHECKING(for libXaw)
2622     AC_CACHE_VAL(emacs_cv_xaw,
2623     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2624 #include <X11/Intrinsic.h>
2625 #include <X11/Xaw/Simple.h>]],
2626       [[]])],
2627       emacs_cv_xaw=yes,
2628       emacs_cv_xaw=no)])
2629     if test $emacs_cv_xaw = yes; then
2630       AC_MSG_RESULT([yes; using Lucid toolkit])
2631       USE_X_TOOLKIT=LUCID
2632       LUCID_LIBW=-lXaw
2633     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2634       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2635     else
2636       AC_MSG_ERROR([No X toolkit could be found.
2637 If you are sure you want Emacs compiled without an X toolkit, pass
2638   --with-x-toolkit=no
2639 to configure.  Otherwise, install the development libraries for the toolkit
2640 that you want to use (e.g. Gtk+) and re-run configure.])
2641     fi
2642   fi
2643 fi
2644
2645 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2646
2647 LIBXTR6=
2648 if test "${USE_X_TOOLKIT}" != "none"; then
2649   AC_MSG_CHECKING(X11 toolkit version)
2650   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2651   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2652 [[#if XtSpecificationRelease < 6
2653 fail;
2654 #endif
2655 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2656   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2657   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2658     AC_MSG_RESULT(6 or newer)
2659     AC_DEFINE(HAVE_X11XTR6, 1,
2660               [Define to 1 if you have the X11R6 or newer version of Xt.])
2661     LIBXTR6="-lSM -lICE"
2662     case "$opsys" in
2663       ## Use libw.a along with X11R6 Xt.
2664       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2665     esac
2666   else
2667     AC_MSG_RESULT(before 6)
2668   fi
2669
2670 dnl If using toolkit, check whether libXmu.a exists.
2671 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2672   OLDLIBS="$LIBS"
2673   if test x$HAVE_X11XTR6 = xyes; then
2674     LIBS="-lXt -lSM -lICE $LIBS"
2675   else
2676     LIBS="-lXt $LIBS"
2677   fi
2678   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2679   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2680   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2681 fi
2682 AC_SUBST(LIBXTR6)
2683
2684 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2685 dnl Why not just test for libxmu in the normal way?
2686 LIBXMU=-lXmu
2687 case $opsys in
2688   ## These systems don't supply Xmu.
2689   hpux* | aix4-2 )
2690     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2691     ;;
2692   mingw32 )
2693     LIBXMU=
2694     ;;
2695 esac
2696 AC_SUBST(LIBXMU)
2697
2698 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2699 if test "${HAVE_X11}" = "yes"; then
2700   if test "${USE_X_TOOLKIT}" != "none"; then
2701     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2702   fi
2703 fi
2704
2705 LIBXP=
2706 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2707   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2708   if test -d /usr/include/openmotif; then
2709     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2710     emacs_cv_openmotif=yes
2711     case "$canonical" in
2712       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2713       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2714       ;;
2715       *)
2716       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2717     esac
2718   else
2719     emacs_cv_openmotif=no
2720   fi
2721   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2722   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2723     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2724 int x = 5;
2725 #else
2726 Motif version prior to 2.1.
2727 #endif]])],
2728     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2729   if test $emacs_cv_motif_version_2_1 = yes; then
2730     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2731     if test x$emacs_cv_openmotif = xyes; then
2732       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2733     fi
2734   else
2735     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2736     # We put this in CFLAGS temporarily to precede other -I options
2737     # that might be in CFLAGS temporarily.
2738     # We put this in CPPFLAGS where it precedes the other -I options.
2739     OLD_CPPFLAGS=$CPPFLAGS
2740     OLD_CFLAGS=$CFLAGS
2741     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2742     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2743     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2744       [[int x = 5;]])],
2745       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2746     if test $emacs_cv_lesstif = yes; then
2747       # Make sure this -I option remains in CPPFLAGS after it is set
2748       # back to REAL_CPPFLAGS.
2749       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2750       # have those other -I options anyway.  Ultimately, having this
2751       # directory ultimately in CPPFLAGS will be enough.
2752       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2753       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2754     else
2755       CFLAGS=$OLD_CFLAGS
2756       CPPFLAGS=$OLD_CPPFLAGS
2757     fi
2758   fi
2759   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2760     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2761 fi
2762
2763 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2764 dnl using Motif or Xaw3d is available, and unless
2765 dnl --with-toolkit-scroll-bars=no was specified.
2766
2767 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2768             [Define to 1 if we should use toolkit scroll bars.])dnl
2769 USE_TOOLKIT_SCROLL_BARS=no
2770 if test "${with_toolkit_scroll_bars}" != "no"; then
2771   if test "${USE_X_TOOLKIT}" != "none"; then
2772     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2773       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2774       HAVE_XAW3D=no
2775       USE_TOOLKIT_SCROLL_BARS=yes
2776     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2777       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2778       USE_TOOLKIT_SCROLL_BARS=yes
2779     fi
2780   elif test "${HAVE_GTK}" = "yes"; then
2781     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2782     USE_TOOLKIT_SCROLL_BARS=yes
2783   elif test "${HAVE_NS}" = "yes"; then
2784     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2785     USE_TOOLKIT_SCROLL_BARS=yes
2786   elif test "${HAVE_W32}" = "yes"; then
2787     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2788     USE_TOOLKIT_SCROLL_BARS=yes
2789   fi
2790 fi
2791
2792 dnl See if XIM is available.
2793 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2794           #include <X11/Xlib.h>
2795           #include <X11/Xresource.h>]],
2796          [[XIMProc  callback;]])],
2797          [HAVE_XIM=yes
2798          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2799          HAVE_XIM=no)
2800
2801 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2802
2803 if test "${with_xim}" != "no"; then
2804   AC_DEFINE(USE_XIM, 1,
2805             [Define to 1 if we should use XIM, if it is available.])
2806 fi
2807
2808
2809 if test "${HAVE_XIM}" != "no"; then
2810   late_CFLAGS=$CFLAGS
2811   if test "$GCC" = yes; then
2812     CFLAGS="$CFLAGS --pedantic-errors"
2813   fi
2814   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2815 #include <X11/Xlib.h>
2816 #include <X11/Xresource.h>]],
2817 [[Display *display;
2818 XrmDatabase db;
2819 char *res_name;
2820 char *res_class;
2821 XIMProc  callback;
2822 XPointer *client_data;
2823 #ifndef __GNUC__
2824 /* If we're not using GCC, it's probably not XFree86, and this is
2825    probably right, but we can't use something like --pedantic-errors.  */
2826 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2827                                            char*, XIMProc, XPointer*);
2828 #endif
2829 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2830    client_data);]])],
2831     [emacs_cv_arg6_star=yes])
2832   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2833          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2834 either XPointer or XPointer*.])dnl
2835   if test "$emacs_cv_arg6_star" = yes; then
2836     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2837   else
2838     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2839   fi
2840   CFLAGS=$late_CFLAGS
2841 fi
2842
2843 ### Start of font-backend (under any platform) section.
2844 # (nothing here yet -- this is a placeholder)
2845 ### End of font-backend (under any platform) section.
2846
2847 ### Start of font-backend (under X11) section.
2848 if test "${HAVE_X11}" = "yes"; then
2849    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2850
2851    ## Use -lXft if available, unless `--with-xft=no'.
2852    HAVE_XFT=maybe
2853     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2854       with_xft="no";
2855     fi
2856     if test "x${with_xft}" != "xno"; then
2857
2858       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2859       ## Because xftfont.c uses XRenderQueryExtension, we also
2860       ## need to link to -lXrender.
2861       HAVE_XRENDER=no
2862       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2863       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2864         OLD_CPPFLAGS="$CPPFLAGS"
2865         OLD_CFLAGS="$CFLAGS"
2866         OLD_LIBS="$LIBS"
2867         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2868         CFLAGS="$CFLAGS $XFT_CFLAGS"
2869         XFT_LIBS="-lXrender $XFT_LIBS"
2870         LIBS="$XFT_LIBS $LIBS"
2871         AC_CHECK_HEADER(X11/Xft/Xft.h,
2872           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2873           [[#include <X11/X.h>]])
2874
2875         if test "${HAVE_XFT}" = "yes"; then
2876           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2877             AC_SUBST(XFT_LIBS)
2878           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2879         else
2880           CPPFLAGS="$OLD_CPPFLAGS"
2881           CFLAGS="$OLD_CFLAGS"
2882           LIBS="$OLD_LIBS"
2883         fi                        # "${HAVE_XFT}" = "yes"
2884       fi                          # "$HAVE_XFT" != no
2885     fi                            # "x${with_xft}" != "xno"
2886
2887     ## We used to allow building with FreeType and without Xft.
2888     ## However, the ftx font backend driver is not in good shape.
2889     if test "$HAVE_XFT" != "yes"; then
2890        dnl For the "Does Emacs use" message at the end.
2891        HAVE_XFT=no
2892        HAVE_FREETYPE=no
2893     else
2894        dnl Strict linkers fail with
2895        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2896        dnl if -lfreetype is not specified.
2897        dnl The following is needed to set FREETYPE_LIBS.
2898        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2899                          HAVE_FREETYPE=no)
2900
2901        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2902     fi
2903
2904     HAVE_LIBOTF=no
2905     if test "${HAVE_FREETYPE}" = "yes"; then
2906       AC_DEFINE(HAVE_FREETYPE, 1,
2907                 [Define to 1 if using the freetype and fontconfig libraries.])
2908       if test "${with_libotf}" != "no"; then
2909         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2910                           HAVE_LIBOTF=no)
2911         if test "$HAVE_LIBOTF" = "yes"; then
2912           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2913           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2914                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2915                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2916           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2917             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2918                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2919           fi
2920         fi
2921       fi
2922     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2923     dnl Does the new font backend require it, or can it work without it?
2924     fi
2925
2926     HAVE_M17N_FLT=no
2927     if test "${HAVE_LIBOTF}" = yes; then
2928       if test "${with_m17n_flt}" != "no"; then
2929         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2930         if test "$HAVE_M17N_FLT" = "yes"; then
2931           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2932         fi
2933       fi
2934     fi
2935 else
2936     HAVE_XFT=no
2937     HAVE_FREETYPE=no
2938     HAVE_LIBOTF=no
2939     HAVE_M17N_FLT=no
2940 fi
2941
2942 ### End of font-backend (under X11) section.
2943
2944 AC_SUBST(FREETYPE_CFLAGS)
2945 AC_SUBST(FREETYPE_LIBS)
2946 AC_SUBST(FONTCONFIG_CFLAGS)
2947 AC_SUBST(FONTCONFIG_LIBS)
2948 AC_SUBST(LIBOTF_CFLAGS)
2949 AC_SUBST(LIBOTF_LIBS)
2950 AC_SUBST(M17N_FLT_CFLAGS)
2951 AC_SUBST(M17N_FLT_LIBS)
2952
2953 ### Use -lXpm if available, unless `--with-xpm=no'.
2954 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
2955 HAVE_XPM=no
2956 LIBXPM=
2957 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
2958   if test "${with_xpm}" != "no"; then
2959     SAVE_CPPFLAGS="$CPPFLAGS"
2960     SAVE_LDFLAGS="$LDFLAGS"
2961     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2962     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2963     AC_CHECK_HEADER(X11/xpm.h,
2964       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2965     if test "${HAVE_XPM}" = "yes"; then
2966       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2967       AC_EGREP_CPP(no_return_alloc_pixels,
2968       [#include "X11/xpm.h"
2969 #ifndef XpmReturnAllocPixels
2970 no_return_alloc_pixels
2971 #endif
2972       ], HAVE_XPM=no, HAVE_XPM=yes)
2973
2974       if test "${HAVE_XPM}" = "yes"; then
2975         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2976         AC_MSG_RESULT(yes)
2977       else
2978         AC_MSG_RESULT(no)
2979         CPPFLAGS="$SAVE_CPPFLAGS"
2980         LDFLAGS="$SAVE_LDFLAGS"
2981       fi
2982     fi
2983   fi
2984
2985   if test "${HAVE_XPM}" = "yes"; then
2986     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2987     LIBXPM=-lXpm
2988   fi
2989 fi
2990
2991 if test "${HAVE_X11}" = "yes"; then
2992   if test "${with_xpm}" != "no"; then
2993     AC_CHECK_HEADER(X11/xpm.h,
2994       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2995     if test "${HAVE_XPM}" = "yes"; then
2996       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2997       AC_EGREP_CPP(no_return_alloc_pixels,
2998       [#include "X11/xpm.h"
2999 #ifndef XpmReturnAllocPixels
3000 no_return_alloc_pixels
3001 #endif
3002       ], HAVE_XPM=no, HAVE_XPM=yes)
3003
3004       if test "${HAVE_XPM}" = "yes"; then
3005         AC_MSG_RESULT(yes)
3006       else
3007         AC_MSG_RESULT(no)
3008       fi
3009     fi
3010   fi
3011
3012   if test "${HAVE_XPM}" = "yes"; then
3013     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3014     LIBXPM=-lXpm
3015   fi
3016 fi
3017
3018 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3019 ### slightly different requirements wrt image libraries (it doesn't
3020 ### use -lXpm because it loads the xpm shared library dynamically at
3021 ### run time).
3022 if test "${opsys}" = "mingw32"; then
3023   if test "${with_xpm}" != "no"; then
3024     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3025 #define FOR_MSW 1])
3026   fi
3027
3028   if test "${HAVE_XPM}" = "yes"; then
3029     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3030   fi
3031 fi
3032
3033 AC_SUBST(LIBXPM)
3034
3035 ### Use -ljpeg if available, unless `--with-jpeg=no'.
3036 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
3037 HAVE_JPEG=no
3038 LIBJPEG=
3039 if test "${opsys}" = "mingw32"; then
3040   if test "${with_jpeg}" != "no"; then
3041     dnl Checking for jpeglib.h can lose because of a redefinition of
3042     dnl HAVE_STDLIB_H.
3043     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
3044   fi
3045   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3046   if test "${HAVE_JPEG}" = "yes"; then
3047     AC_DEFINE(HAVE_JPEG)
3048     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3049         [#include <jpeglib.h>
3050          version=JPEG_LIB_VERSION
3051 ],
3052         [AC_DEFINE(HAVE_JPEG)],
3053         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3054         HAVE_JPEG=no])
3055   fi
3056 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3057   if test "${with_jpeg}" != "no"; then
3058     dnl Checking for jpeglib.h can lose because of a redefinition of
3059     dnl  HAVE_STDLIB_H.
3060     AC_CHECK_HEADER(jerror.h,
3061       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
3062   fi
3063
3064   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3065   if test "${HAVE_JPEG}" = "yes"; then
3066     AC_DEFINE(HAVE_JPEG)
3067     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3068         [#include <jpeglib.h>
3069          version=JPEG_LIB_VERSION
3070 ],
3071         [AC_DEFINE(HAVE_JPEG)],
3072         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3073         HAVE_JPEG=no])
3074   fi
3075   if test "${HAVE_JPEG}" = "yes"; then
3076     LIBJPEG=-ljpeg
3077   fi
3078 fi
3079 AC_SUBST(LIBJPEG)
3080
3081 ### Use -lpng if available, unless `--with-png=no'.
3082 ### mingw32 doesn't use -lpng, since it loads the library dynamically.
3083 HAVE_PNG=no
3084 LIBPNG=
3085 if test "${opsys}" = "mingw32"; then
3086   if test "${with_png}" != "no"; then
3087     AC_CHECK_HEADER(png.h, HAVE_PNG=yes, HAVE_PNG=no)
3088   fi
3089   if test "${HAVE_PNG}" = "yes"; then
3090     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
3091
3092     AC_CHECK_DECL(png_longjmp,
3093       [],
3094       [AC_DEFINE(PNG_DEPSTRUCT, [],
3095          [Define to empty to suppress deprecation warnings when building
3096           with --enable-gcc-warnings and with libpng versions before 1.5,
3097           which lack png_longjmp.])],
3098       [[#ifdef HAVE_LIBPNG_PNG_H
3099         # include <libpng/png.h>
3100         #else
3101         # include <png.h>
3102         #endif
3103       ]])
3104   fi
3105 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3106   if test "${with_png}" != "no"; then
3107     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3108     # in /usr/include/libpng.
3109     AC_CHECK_HEADERS(png.h libpng/png.h, break)
3110     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
3111       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
3112     fi
3113   fi
3114
3115   if test "${HAVE_PNG}" = "yes"; then
3116     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
3117     LIBPNG="-lpng -lz -lm"
3118
3119     AC_CHECK_DECL(png_longjmp,
3120       [],
3121       [AC_DEFINE(PNG_DEPSTRUCT, [],
3122          [Define to empty to suppress deprecation warnings when building
3123           with --enable-gcc-warnings and with libpng versions before 1.5,
3124           which lack png_longjmp.])],
3125       [[#ifdef HAVE_LIBPNG_PNG_H
3126         # include <libpng/png.h>
3127         #else
3128         # include <png.h>
3129         #endif
3130       ]])
3131   fi
3132 fi
3133 AC_SUBST(LIBPNG)
3134
3135 HAVE_ZLIB=no
3136 LIBZ=
3137 if test "${with_zlib}" != "no"; then
3138   OLIBS=$LIBS
3139   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3140   LIBS=$OLIBS
3141   case $ac_cv_search_inflateEnd in
3142     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3143   esac
3144 fi
3145 if test "${HAVE_ZLIB}" = "yes"; then
3146   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3147   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3148   if test "${opsys}" = "mingw32"; then
3149      LIBZ=
3150   fi
3151 fi
3152 AC_SUBST(LIBZ)
3153
3154
3155 ### Use -ltiff if available, unless `--with-tiff=no'.
3156 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3157 HAVE_TIFF=no
3158 LIBTIFF=
3159 if test "${opsys}" = "mingw32"; then
3160   if test "${with_tiff}" != "no"; then
3161     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3162   fi
3163   if test "${HAVE_TIFF}" = "yes"; then
3164     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3165   fi
3166 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3167   if test "${with_tiff}" != "no"; then
3168     AC_CHECK_HEADER(tiffio.h,
3169       [tifflibs="-lz -lm"
3170       # At least one tiff package requires the jpeg library.
3171       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3172       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3173   fi
3174
3175   if test "${HAVE_TIFF}" = "yes"; then
3176     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3177     dnl FIXME -lz -lm, as per libpng?
3178     LIBTIFF=-ltiff
3179   fi
3180 fi
3181 AC_SUBST(LIBTIFF)
3182
3183 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
3184 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3185 HAVE_GIF=no
3186 LIBGIF=
3187 if test "${opsys}" = "mingw32"; then
3188   if test "${with_gif}" != "no"; then
3189     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3190   fi
3191   if test "${HAVE_GIF}" = "yes"; then
3192     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3193   fi
3194 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3195         || test "${HAVE_W32}" = "yes"; then
3196   AC_CHECK_HEADER(gif_lib.h,
3197 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3198 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3199     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3200         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3201
3202   if test "$HAVE_GIF" = yes; then
3203     LIBGIF=-lgif
3204   elif test "$HAVE_GIF" = maybe; then
3205 # If gif_lib.h but no libgif, try libungif.
3206     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3207     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3208   fi
3209
3210   if test "${HAVE_GIF}" = "yes"; then
3211     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3212   fi
3213 fi
3214 AC_SUBST(LIBGIF)
3215
3216 dnl Check for required libraries.
3217 if test "${HAVE_X11}" = "yes"; then
3218   MISSING=""
3219   WITH_NO=""
3220   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3221     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3222   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3223     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3224   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3225     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3226   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3227     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3228   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3229     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3230
3231   if test "X${MISSING}" != X; then
3232     AC_MSG_ERROR([The following required libraries were not found:
3233     $MISSING
3234 Maybe some development libraries/packages are missing?
3235 If you don't want to link with them give
3236     $WITH_NO
3237 as options to configure])
3238   fi
3239 fi
3240
3241 ### Use -lgpm if available, unless `--with-gpm=no'.
3242 HAVE_GPM=no
3243 LIBGPM=
3244 if test "${with_gpm}" != "no"; then
3245   AC_CHECK_HEADER(gpm.h,
3246     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3247
3248   if test "${HAVE_GPM}" = "yes"; then
3249     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3250     LIBGPM=-lgpm
3251   fi
3252 fi
3253 AC_SUBST(LIBGPM)
3254
3255 dnl Check for malloc/malloc.h on darwin
3256 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3257
3258 GNUSTEP_CFLAGS=
3259 ### Use NeXTstep API to implement GUI.
3260 if test "${HAVE_NS}" = "yes"; then
3261   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3262   if test "${NS_IMPL_COCOA}" = "yes"; then
3263     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3264   fi
3265   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3266     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3267     # See also .m.o rule in Makefile.in */
3268     # FIXME: are all these flags really needed?  Document here why.  */
3269     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3270     ## Extra CFLAGS applied to src/*.m files.
3271     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3272   fi
3273   OTHER_FILES=ns-app
3274 fi
3275
3276 ### Use session management (-lSM -lICE) if available
3277 HAVE_X_SM=no
3278 LIBXSM=
3279 if test "${HAVE_X11}" = "yes"; then
3280   AC_CHECK_HEADER(X11/SM/SMlib.h,
3281     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3282
3283   if test "${HAVE_X_SM}" = "yes"; then
3284     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3285     LIBXSM="-lSM -lICE"
3286     case "$LIBS" in
3287       *-lSM*) ;;
3288       *)      LIBS="$LIBXSM $LIBS" ;;
3289     esac
3290   fi
3291 fi
3292 AC_SUBST(LIBXSM)
3293
3294 ### Use XRandr (-lXrandr) if available
3295 HAVE_XRANDR=no
3296 if test "${HAVE_X11}" = "yes"; then
3297   XRANDR_REQUIRED=1.2.2
3298   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3299   PKG_CHECK_MODULES(XRANDR, $XRANDR_MODULES, HAVE_XRANDR=yes, HAVE_XRANDR=no)
3300   if test $HAVE_XRANDR = no; then
3301     # Test old way in case pkg-config doesn't have it (older machines).
3302     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3303       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)])
3304     if test $HAVE_XRANDR = yes; then
3305       XRANDR_LIBS=-lXrandr
3306       AC_SUBST(XRANDR_LIBS)
3307     fi
3308   fi
3309   if test $HAVE_XRANDR = yes; then
3310     SAVE_CFLAGS="$CFLAGS"
3311     SAVE_LIBS="$LIBS"
3312     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3313     LIBS="$XRANDR_LIBS $LIBS"
3314     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3315     CFLAGS="$SAVE_CFLAGS"
3316     LIBS="$SAVE_LIBS"
3317
3318     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3319   fi
3320 fi
3321
3322 ### Use Xinerama (-lXinerama) if available
3323 HAVE_XINERAMA=no
3324 if test "${HAVE_X11}" = "yes"; then
3325   XINERAMA_REQUIRED=1.0.2
3326   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3327   PKG_CHECK_MODULES(XINERAMA, $XINERAMA_MODULES, HAVE_XINERAMA=yes,
3328                     HAVE_XINERAMA=no)
3329   if test $HAVE_XINERAMA = no; then
3330     # Test old way in case pkg-config doesn't have it (older machines).
3331     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3332       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3333     if test $HAVE_XINERAMA = yes; then
3334       XINERAMA_LIBS=-lXinerama
3335       AC_SUBST(XINERAMA_LIBS)
3336     fi
3337   fi
3338   if test $HAVE_XINERAMA = yes; then
3339     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3340   fi
3341 fi
3342
3343
3344 ### Use libxml (-lxml2) if available
3345 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3346 HAVE_LIBXML2=no
3347 if test "${with_xml2}" != "no"; then
3348   ### I'm not sure what the version number should be, so I just guessed.
3349   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3350   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3351   if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3352     SAVE_CPPFLAGS="$CPPFLAGS"
3353     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3354     AC_CHECK_HEADER(libxml/HTMLparser.h,
3355       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3356                      [#include <libxml/HTMLparser.h>])])
3357     CPPFLAGS="$SAVE_CPPFLAGS"
3358     if test "${HAVE_LIBXML2}" = "yes"; then
3359       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3360       LIBXML2_LIBS="-lxml2"
3361     fi
3362   fi
3363   if test "${HAVE_LIBXML2}" = "yes"; then
3364     if test "${opsys}" != "mingw32"; then
3365       LIBS="$LIBXML2_LIBS $LIBS"
3366       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3367     else
3368       LIBXML2_LIBS=""
3369     fi
3370     if test "${HAVE_LIBXML2}" = "yes"; then
3371       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3372     else
3373       LIBXML2_LIBS=""
3374       LIBXML2_CFLAGS=""
3375     fi
3376   fi
3377 fi
3378 AC_SUBST(LIBXML2_LIBS)
3379 AC_SUBST(LIBXML2_CFLAGS)
3380
3381 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3382 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3383 if test "${opsys}" = "mingw32"; then
3384   emacs_cv_netdb_declares_h_errno=yes
3385 fi
3386 AC_CACHE_CHECK(whether netdb declares h_errno,
3387                emacs_cv_netdb_declares_h_errno,
3388 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3389   [[return h_errno;]])],
3390   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3391 if test $emacs_cv_netdb_declares_h_errno = yes; then
3392   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3393 fi
3394
3395 # sqrt and other floating-point functions such as fmod and frexp
3396 # are found in -lm on most systems, but mingw32 doesn't use -lm.
3397 if test "${opsys}" != "mingw32"; then
3398   AC_CHECK_LIB(m, sqrt)
3399 fi
3400
3401 # Check for mail-locking functions in a "mail" library.  Probably this should
3402 # have the same check as for liblockfile below.
3403 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3404 if test $have_mail = yes; then
3405   LIBS_MAIL=-lmail
3406   LIBS="$LIBS_MAIL $LIBS"
3407   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3408 else
3409   LIBS_MAIL=
3410 fi
3411 dnl Debian, at least:
3412 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3413 if test $have_lockfile = yes; then
3414    LIBS_MAIL=-llockfile
3415    LIBS="$LIBS_MAIL $LIBS"
3416    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3417 else
3418 # If we have the shared liblockfile, assume we must use it for mail
3419 # locking (e.g. Debian).  If we couldn't link against liblockfile
3420 # (no liblockfile.a installed), ensure that we don't need to.
3421   dnl This works for files generally, not just executables.
3422   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3423   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3424                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3425   if test $ac_cv_prog_liblockfile = yes; then
3426     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3427 This probably means that movemail could lose mail.
3428 There may be a `development' package to install containing liblockfile.])
3429   fi
3430 fi
3431 AC_CHECK_HEADERS_ONCE(maillock.h)
3432 AC_SUBST(LIBS_MAIL)
3433
3434 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3435 ## interlock access to the mail spool.  The alternative is a lock file named
3436 ## /usr/spool/mail/$USER.lock.
3437 mail_lock=no
3438 case "$opsys" in
3439   aix4-2) mail_lock="lockf" ;;
3440
3441   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3442
3443   ## On GNU/Linux systems, both methods are used by various mail programs.
3444   ## I assume most people are using newer mailers that have heard of flock.
3445   ## Change this if you need to.
3446   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3447   ## configure gets the right answers, and that means *NOT* using flock.
3448   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3449   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3450   ## Debian maintainer hasn't provided a clean fix for Emacs.
3451   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3452   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3453   ## correct logic.  -- fx
3454   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3455   ## liblockfile is a Free Software replacement for libmail, used on
3456   ## Debian systems and elsewhere. -rfr.
3457   gnu-*)
3458     mail_lock="flock"
3459     if test $have_mail = yes || test $have_lockfile = yes; then
3460       test $ac_cv_header_maillock_h = yes && mail_lock=no
3461     fi
3462     ;;
3463
3464   mingw32)
3465     mail_lock="none-needed" ;;
3466 esac
3467
3468 BLESSMAIL_TARGET=
3469 case "$mail_lock" in
3470   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3471
3472   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3473
3474   none-needed) ;;
3475
3476   *) BLESSMAIL_TARGET="need-blessmail" ;;
3477 esac
3478 AC_SUBST(BLESSMAIL_TARGET)
3479
3480
3481 AC_CHECK_FUNCS(accept4 gethostname \
3482 getrusage get_current_dir_name \
3483 lrand48 \
3484 select getpagesize setlocale \
3485 getrlimit setrlimit shutdown getaddrinfo \
3486 strsignal setitimer \
3487 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3488 gai_strerror getline getdelim sync \
3489 getpwent endpwent getgrent endgrent \
3490 touchlock \
3491 cfmakeraw cfsetspeed copysign __executable_start log2)
3492
3493 dnl No need to check for aligned_alloc and posix_memalign if using
3494 dnl gmalloc.o, as it supplies them.  Don't use these functions on
3495 dnl Darwin as they are incompatible with unexmacosx.c.
3496 if test -z "$GMALLOC_OBJ" && test "$opsys" != darwin; then
3497   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3498 fi
3499
3500 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
3501 ## has a broken `rint' in some library versions including math library
3502 ## version number A.09.05.
3503 ## You can fix the math library by installing patch number PHSS_4630.
3504 ## But we can fix it more reliably for Emacs by just not using rint.
3505 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
3506 case $opsys in
3507    hpux*) : ;;
3508    *) AC_CHECK_FUNCS(random rint) ;;
3509 esac
3510
3511 dnl Cannot use AC_CHECK_FUNCS
3512 AC_CACHE_CHECK([for __builtin_unwind_init],
3513                emacs_cv_func___builtin_unwind_init,
3514 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3515                 emacs_cv_func___builtin_unwind_init=yes,
3516                 emacs_cv_func___builtin_unwind_init=no)])
3517 if test $emacs_cv_func___builtin_unwind_init = yes; then
3518   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3519             [Define to 1 if you have the `__builtin_unwind_init' function.])
3520 fi
3521
3522 AC_CHECK_HEADERS_ONCE(sys/un.h)
3523
3524 AC_FUNC_FSEEKO
3525
3526 # UNIX98 PTYs.
3527 AC_CHECK_FUNCS(grantpt)
3528
3529 # PTY-related GNU extensions.
3530 AC_CHECK_FUNCS(getpt posix_openpt)
3531
3532 # Check this now, so that we will NOT find the above functions in ncurses.
3533 # That is because we have not set up to link ncurses in lib-src.
3534 # It's better to believe a function is not available
3535 # than to expect to find it in ncurses.
3536 # Also we need tputs and friends to be able to build at all.
3537 AC_MSG_CHECKING([for library containing tputs])
3538 # Run a test program that contains a call to tputs, a call that is
3539 # never executed.  This tests whether a pre-'main' dynamic linker
3540 # works with the library.  It's too much trouble to actually call
3541 # tputs in the test program, due to portability hassles.  When
3542 # cross-compiling, assume the test program will run if it links.
3543 AC_DEFUN([tputs_link_source], [
3544   AC_LANG_SOURCE(
3545      [[extern void tputs (const char *, int, int (*)(int));
3546        int main (int argc, char **argv)
3547        {
3548           if (argc == 10000)
3549             tputs (argv[0], 0, 0);
3550           return 0;
3551        }]])
3552 ])
3553 if test "${opsys}" = "mingw32"; then
3554   msg='none required'
3555 else
3556   # Maybe curses should be tried earlier?
3557   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3558   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3559     OLIBS=$LIBS
3560     if test -z "$tputs_library"; then
3561       LIBS_TERMCAP=
3562       msg='none required'
3563     else
3564       LIBS_TERMCAP=-l$tputs_library
3565       msg=$LIBS_TERMCAP
3566       LIBS="$LIBS_TERMCAP $LIBS"
3567     fi
3568     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3569       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3570     LIBS=$OLIBS
3571     if test "X$msg" != Xno; then
3572       break
3573     fi
3574   done
3575 fi
3576 AC_MSG_RESULT([$msg])
3577 if test "X$msg" = Xno; then
3578   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3579 The following libraries were tried (in order):
3580   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3581 Please try installing whichever of these libraries is most appropriate
3582 for your system, together with its header files.
3583 For example, a libncurses-dev(el) or similar package.])
3584 fi
3585
3586 ## Use termcap instead of terminfo?
3587 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3588 TERMINFO=yes
3589 ## FIXME?  In the cases below where we unconditionally set
3590 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3591 ## if that was found above to have tputs.
3592 ## Should we use the gnu* logic everywhere?
3593 case "$opsys" in
3594   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3595   ##  The ncurses library has been moved out of the System framework in
3596   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3597   ##  option to use it.
3598   darwin) LIBS_TERMCAP="-lncurses" ;;
3599
3600   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3601
3602   freebsd)
3603     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3604     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3605     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3606 [[#if __FreeBSD_version < 400000
3607 fail;
3608 #endif
3609 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3610
3611     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3612
3613     if test $emacs_cv_freebsd_terminfo = yes; then
3614       LIBS_TERMCAP="-lncurses"
3615     else
3616       TERMINFO=no
3617       LIBS_TERMCAP="-ltermcap"
3618     fi
3619     ;;
3620
3621   mingw32)
3622     TERMINFO=no
3623     LIBS_TERMCAP=
3624     ;;
3625
3626   netbsd)
3627     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3628       TERMINFO=no
3629       LIBS_TERMCAP="-ltermcap"
3630     fi
3631     ;;
3632
3633   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3634
3635   ## hpux: Make sure we get select from libc rather than from libcurses
3636   ##  because libcurses on HPUX 10.10 has a broken version of select.
3637   ##  We used to use -lc -lcurses, but this may be cleaner.
3638   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3639   # set that way, now it uses the default).  Isn't this a contradiction?
3640   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3641
3642 esac
3643
3644 TERMCAP_OBJ=tparam.o
3645 if test $TERMINFO = yes; then
3646   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3647   TERMCAP_OBJ=terminfo.o
3648 fi
3649 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3650   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3651 fi
3652 AC_SUBST(LIBS_TERMCAP)
3653 AC_SUBST(TERMCAP_OBJ)
3654
3655
3656 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3657 # On Darwin, res_init appears not to be useful: see bug#562 and
3658 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3659 resolv=no
3660
3661 if test $opsys != darwin; then
3662
3663   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3664 #include <arpa/nameser.h>
3665 #include <resolv.h>]],
3666     [[return res_init();]])],
3667     have_res_init=yes, have_res_init=no)
3668   if test "$have_res_init" = no; then
3669     OLIBS="$LIBS"
3670     LIBS="$LIBS -lresolv"
3671     AC_MSG_CHECKING(for res_init with -lresolv)
3672     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3673 #include <arpa/nameser.h>
3674 #include <resolv.h>]],
3675       [[return res_init();]])],
3676       have_res_init=yes, have_res_init=no)
3677     AC_MSG_RESULT($have_res_init)
3678     if test "$have_res_init" = yes ; then
3679       resolv=yes
3680     fi
3681     LIBS="$OLIBS"
3682   fi
3683
3684   if test "$have_res_init" = yes; then
3685     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3686   fi
3687 fi                              dnl !darwin
3688
3689 # Do we need the Hesiod library to provide the support routines?
3690 dnl FIXME?  Should we be skipping this on Darwin too?
3691 LIBHESIOD=
3692 if test "$with_hesiod" != no ; then
3693   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3694   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3695      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3696                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3697   if test "$resolv" = yes ; then
3698     RESOLVLIB=-lresolv
3699   else
3700     RESOLVLIB=
3701   fi
3702   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3703         hesiod=yes, :, $RESOLVLIB)])
3704
3705   if test x"$hesiod" = xyes; then
3706     LIBHESIOD=-lhesiod
3707   fi
3708 fi
3709 AC_SUBST(LIBHESIOD)
3710
3711 # Do we need libresolv (due to res_init or Hesiod)?
3712 if test "$resolv" = yes && test $opsys != darwin; then
3713   LIBRESOLV=-lresolv
3714 else
3715   LIBRESOLV=
3716 fi
3717 AC_SUBST(LIBRESOLV)
3718
3719 # These tell us which Kerberos-related libraries to use.
3720 COM_ERRLIB=
3721 CRYPTOLIB=
3722 KRB5LIB=
3723 DESLIB=
3724 KRB4LIB=
3725
3726 if test "${with_kerberos}" != no; then
3727   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3728   if test $have_com_err = yes; then
3729     COM_ERRLIB=-lcom_err
3730     LIBS="$COM_ERRLIB $LIBS"
3731   fi
3732   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3733   if test $have_crypto = yes; then
3734     CRYPTOLIB=-lcrypto
3735     LIBS="$CRYPTOLIB $LIBS"
3736   fi
3737   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3738   if test $have_k5crypto = yes; then
3739     CRYPTOLIB=-lk5crypto
3740     LIBS="$CRYPTOLIB $LIBS"
3741   fi
3742   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3743   if test $have_krb5=yes; then
3744     KRB5LIB=-lkrb5
3745     LIBS="$KRB5LIB $LIBS"
3746   fi
3747   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3748   if test "${with_kerberos5}" = no; then
3749     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3750     if test $have_des425 = yes; then
3751       DESLIB=-ldes425
3752       LIBS="$DESLIB $LIBS"
3753     else
3754       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3755       if test $have_des = yes; then
3756         DESLIB=-ldes
3757         LIBS="$DESLIB $LIBS"
3758       fi
3759     fi
3760     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3761     if test $have_krb4 = yes; then
3762       KRB4LIB=-lkrb4
3763       LIBS="$KRB4LIB $LIBS"
3764     else
3765       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3766       if test $have_krb = yes; then
3767         KRB4LIB=-lkrb
3768         LIBS="$KRB4LIB $LIBS"
3769       fi
3770     fi
3771   fi
3772
3773   if test "${with_kerberos5}" != no; then
3774     AC_CHECK_HEADERS(krb5.h,
3775       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3776                         [#include <krb5.h>])])
3777   else
3778     AC_CHECK_HEADERS(krb.h,,
3779                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3780                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3781   fi
3782   AC_CHECK_HEADERS(com_err.h)
3783 fi
3784
3785 AC_SUBST(COM_ERRLIB)
3786 AC_SUBST(CRYPTOLIB)
3787 AC_SUBST(KRB5LIB)
3788 AC_SUBST(DESLIB)
3789 AC_SUBST(KRB4LIB)
3790
3791 AC_CHECK_HEADERS(valgrind/valgrind.h)
3792
3793 AC_CHECK_FUNCS_ONCE(tzset)
3794 AC_MSG_CHECKING(whether localtime caches TZ)
3795 AC_CACHE_VAL(emacs_cv_localtime_cache,
3796 [if test x$ac_cv_func_tzset = xyes; then
3797 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3798 char TZ_GMT0[] = "TZ=GMT0";
3799 char TZ_PST8[] = "TZ=PST8";
3800 main()
3801 {
3802   time_t now = time ((time_t *) 0);
3803   int hour_GMT0, hour_unset;
3804   if (putenv (TZ_GMT0) != 0)
3805     exit (1);
3806   hour_GMT0 = localtime (&now)->tm_hour;
3807   unsetenv("TZ");
3808   hour_unset = localtime (&now)->tm_hour;
3809   if (putenv (TZ_PST8) != 0)
3810     exit (1);
3811   if (localtime (&now)->tm_hour == hour_GMT0)
3812     exit (1);
3813   unsetenv("TZ");
3814   if (localtime (&now)->tm_hour != hour_unset)
3815     exit (1);
3816   exit (0);
3817 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3818 [# If we have tzset, assume the worst when cross-compiling.
3819 emacs_cv_localtime_cache=yes])
3820 else
3821         # If we lack tzset, report that localtime does not cache TZ,
3822         # since we can't invalidate the cache if we don't have tzset.
3823         emacs_cv_localtime_cache=no
3824 fi])dnl
3825 AC_MSG_RESULT($emacs_cv_localtime_cache)
3826 if test $emacs_cv_localtime_cache = yes; then
3827   AC_DEFINE(LOCALTIME_CACHE, 1,
3828             [Define to 1 if localtime caches TZ.])
3829 fi
3830
3831 ok_so_far=yes
3832 AC_CHECK_FUNC(socket, , ok_so_far=no)
3833 if test $ok_so_far = yes; then
3834   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3835 fi
3836 if test $ok_so_far = yes; then
3837   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3838 fi
3839 if test $ok_so_far = yes; then
3840 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3841   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3842             [Define to 1 if you have inet sockets.])
3843 fi
3844
3845 dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69).
3846 dnl This can be removed once we assume Autoconf 2.70.
3847 case $canonical in
3848   *-solaris2.4 | *-solaris2.4.*)
3849     dnl Disable the Autoconf-generated vfork test.
3850     : ${ac_cv_func_vfork_works=no};;
3851 esac
3852
3853 AC_FUNC_FORK
3854
3855 AC_CHECK_FUNCS(snprintf)
3856
3857 dnl Check this late.  It depends on what other libraries (lrsvg, Gtk+ etc)
3858 dnl Emacs uses.
3859 XGSELOBJ=
3860 OLDCFLAGS="$CFLAGS"
3861 OLDLIBS="$LIBS"
3862 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS"
3863 LIBS="$LIBS $GFILENOTIFY_LIBS"
3864 AC_MSG_CHECKING([whether GLib is linked in])
3865 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3866         [[#include <glib.h>
3867         ]],
3868         [[g_print ("Hello world");]])],
3869      [links_glib=yes],
3870      [links_glib=no])
3871 AC_MSG_RESULT([$links_glib])
3872 if test "${links_glib}" = "yes"; then
3873   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
3874   if test "$HAVE_NS" = no;then
3875     XGSELOBJ=xgselect.o
3876   fi
3877 fi
3878 CFLAGS="$OLDCFLAGS"
3879 LIBS="$OLDLIBS"
3880 AC_SUBST(XGSELOBJ)
3881
3882 dnl Adapted from Haible's version.
3883 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3884   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3885     [[char* cs = nl_langinfo(CODESET);]])],
3886     emacs_cv_langinfo_codeset=yes,
3887     emacs_cv_langinfo_codeset=no)
3888   ])
3889 if test $emacs_cv_langinfo_codeset = yes; then
3890   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3891     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3892 fi
3893
3894 AC_TYPE_MBSTATE_T
3895
3896 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3897   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3898                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3899 if test "$emacs_cv_c_restrict_arr" = yes; then
3900   AC_DEFINE(__restrict_arr, __restrict,
3901     [Define to compiler's equivalent of C99 restrict keyword in array
3902      declarations.  Define as empty for no equivalent.])
3903 fi
3904
3905 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3906 dnl how the tty code is related to POSIX and/or other versions of termios.
3907 dnl The following looks like a useful start.
3908 dnl
3909 dnl AC_SYS_POSIX_TERMIOS
3910 dnl if test $ac_cv_sys_posix_termios = yes; then
3911 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3912 dnl                                and macros for terminal control.])
3913 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3914 dnl fi
3915
3916 dnl Turned on June 1996 supposing nobody will mind it.
3917 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
3918 if test "${opsys}" != "mingw32"; then
3919    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3920      in the full name stands for the login id.])
3921 fi
3922
3923 dnl Everybody supports this, except MS.
3924 dnl Seems like the kind of thing we should be testing for, though.
3925 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3926 if test "${opsys}" != "mingw32"; then
3927   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3928 fi
3929
3930 dnl Everybody supports this, except MS-DOS.
3931 dnl Seems like the kind of thing we should be testing for, though.
3932 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3933 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3934   4.2-compatible sockets.])
3935
3936 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3937
3938 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
3939   a null file, or a data sink.])
3940 if test "${opsys}" = "mingw32"; then
3941   AC_DEFINE(NULL_DEVICE, ["NUL:"])
3942 else
3943   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
3944 fi
3945
3946 if test "${opsys}" = "mingw32"; then
3947   SEPCHAR=';'
3948 else
3949   SEPCHAR=':'
3950 fi
3951 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
3952 dnl This is for MinGW, and is used in test/automated/Makefile.in.
3953 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
3954 dnl decides that a command-line argument to be passed to a MinGW program
3955 dnl is a PATH-style list of directories.  But that heuristics plays it
3956 dnl safe, and only does the replacement when it is _absolutely_ sure it
3957 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
3958 dnl which breaks in-tree builds.  So we do this manually instead.
3959 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
3960 dnl be computed as ':' in MSYS Bash.
3961 AC_SUBST(SEPCHAR)
3962
3963 dnl Everybody supports this, except MS-DOS.
3964 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3965
3966 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3967
3968
3969 AC_DEFINE(DIRECTORY_SEP, ['/'],
3970   [Character that separates directories in a file name.])
3971
3972 if test "${opsys}" = "mingw32"; then
3973   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
3974     [Returns true if character is a device separator.])
3975
3976   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
3977     [Returns true if character is a directory separator.])
3978
3979   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
3980     [Returns true if character is any form of separator.])
3981 else
3982   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3983     [Returns true if character is a device separator.])
3984
3985   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3986     [Returns true if character is a directory separator.])
3987
3988   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3989     [Returns true if character is any form of separator.])
3990 fi
3991
3992 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3993
3994 case $opsys in
3995   aix4-2)
3996     dnl Unfortunately without libXmu we cannot support EditRes.
3997     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3998       AC_DEFINE(NO_EDITRES, 1)
3999     fi
4000     ;;
4001
4002   hpux*)
4003     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4004     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4005     AC_DEFINE(NO_EDITRES, 1)
4006     ;;
4007 esac
4008
4009
4010 case $opsys in
4011   irix6-5 | sol2* | unixware )
4012     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4013     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4014     dnl need the constant to dimension an array.  So wire in the appropriate
4015     dnl value here.
4016     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4017     ;;
4018 esac
4019
4020 emacs_broken_SIGIO=no
4021
4022 case $opsys in
4023   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4024   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4025   hpux* | irix6-5 | openbsd | sol2* | unixware )
4026     emacs_broken_SIGIO=yes
4027     ;;
4028
4029   aix4-2)
4030     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4031     dnl the way this system works, libc functions that return malloced
4032     dnl memory use the libc malloc implementation. Calling xfree or
4033     dnl xrealloc on the results of such functions results in a crash.
4034     dnl
4035     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4036     dnl but that does not currently work on this system.
4037     dnl
4038     dnl It is possible to completely override the malloc implementation on
4039     dnl AIX, but that involves putting the malloc functions in a shared
4040     dnl library and setting the MALLOCTYPE environment variable to point to
4041     dnl that shared library.
4042     dnl
4043     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4044     dnl to avoid a crash just use the Emacs implementation for that function.
4045     dnl
4046     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4047     dnl of this file, so that we do not check for get_current_dir_name
4048     dnl on AIX.  But that might be fragile if something else ends
4049     dnl up testing for get_current_dir_name as a dependency.
4050     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4051       get_current_dir_name should not be used.])
4052     ;;
4053
4054   freebsd)
4055     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4056     dnl writes/reads on a PTY, read(2) returns bogus data:
4057     dnl
4058     dnl write(2)  1022 bytes
4059     dnl write(2)   954 bytes, get EAGAIN
4060     dnl read(2)   1024 bytes in process_read_output
4061     dnl read(2)     11 bytes in process_read_output
4062     dnl
4063     dnl That is, read(2) returns more bytes than have ever been written
4064     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4065     dnl successfully after processing (for example with CRs added if the
4066     dnl terminal is set up that way which it is here).  The same bytes will
4067     dnl be seen again in a later read(2), without the CRs.
4068     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4069       work around an issue when reading from a PTY.])
4070     ;;
4071 esac
4072
4073 case $opsys in
4074   gnu-* | sol2-10 )
4075     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4076     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4077   ;;
4078 esac
4079
4080 case $opsys in
4081   darwin | dragonfly | freebsd | netbsd | openbsd )
4082     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4083       close a pty to make it a controlling terminal (it is already a
4084       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4085   ;;
4086 esac
4087
4088 dnl FIXME Surely we can test for this rather than hard-code it.
4089 case $opsys in
4090   netbsd | openbsd) sound_device="/dev/audio" ;;
4091   *) sound_device="/dev/dsp" ;;
4092 esac
4093
4094 dnl Used in sound.c
4095 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4096   [Name of the default sound device.])
4097
4098
4099 dnl Emacs can read input using SIGIO and buffering characters itself,
4100 dnl or using CBREAK mode and making C-g cause SIGINT.
4101 dnl The choice is controlled by the variable interrupt_input.
4102 dnl
4103 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4104 dnl
4105 dnl Emacs uses the presence of the USABLE_SIGIO macro
4106 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4107 dnl INTERRUPT_INPUT to decide whether to use it by default.
4108 dnl
4109 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4110 dnl CBREAK mode has two disadvantages
4111 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4112 dnl I hear that in system V this problem does not exist.
4113 dnl 2) Control-G causes output to be discarded.
4114 dnl I do not know whether this can be fixed in system V.
4115 dnl
4116 dnl Another method of doing input is planned but not implemented.
4117 dnl It would have Emacs fork off a separate process
4118 dnl to read the input and send it to the true Emacs process
4119 dnl through a pipe.
4120 case $opsys in
4121   darwin | gnu-linux | gnu-kfreebsd )
4122     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4123   ;;
4124 esac
4125
4126
4127 dnl If the system's imake configuration file defines `NeedWidePrototypes'
4128 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
4129 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
4130 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4131 dnl taking float or double parameters.
4132 case $opsys in
4133   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4134     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4135       file defines `NeedWidePrototypes' as `NO'.])
4136   ;;
4137 esac
4138
4139
4140 dnl Used in process.c, this must be a loop, even if it only runs once.
4141 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4142 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4143 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4144 dnl trying suffixes 0-16.
4145 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4146   first PTY, if PTYs are supported.])
4147 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4148 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4149   end of a PTY, if non-standard.])
4150 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4151   end of a PTY, if non-standard.])
4152
4153 case $opsys in
4154   aix4-2 )
4155     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4156     dnl You allocate a pty by opening /dev/ptc to get the master side.
4157     dnl To get the name of the slave side, you just ttyname() the master side.
4158     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4159     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4160     ;;
4161
4162   cygwin )
4163     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4164     dnl multi-line AC_DEFINEs are hard. :(
4165     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4166     AC_DEFINE(PTY_NAME_SPRINTF, [])
4167     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4168     ;;
4169
4170   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4171   darwin )
4172     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4173     dnl Not used, because PTY_ITERATION is defined.
4174     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4175     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4176     dnl But we don't have to block SIGCHLD because it is blocked in the
4177     dnl implementation of grantpt.
4178     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4179     AC_DEFINE(PTY_NAME_SPRINTF, [])
4180     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4181     ;;
4182
4183   gnu | openbsd )
4184     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4185     ;;
4186
4187   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
4188     dnl if HAVE_GRANTPT
4189     if test "x$ac_cv_func_grantpt" = xyes; then
4190       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4191       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4192       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4193       dnl to prevent sigchld_handler from intercepting the child's death.
4194       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4195       dnl if HAVE_POSIX_OPENPT
4196       if test "x$ac_cv_func_posix_openpt" = xyes; then
4197         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4198         AC_DEFINE(PTY_NAME_SPRINTF, [])
4199       dnl if HAVE_GETPT
4200       elif test "x$ac_cv_func_getpt" = xyes; then
4201         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4202         AC_DEFINE(PTY_NAME_SPRINTF, [])
4203       else
4204         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4205       fi
4206     else
4207       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4208     fi
4209     ;;
4210
4211   hpux*)
4212     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4213     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4214     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4215     ;;
4216
4217   irix6-5 )
4218     dnl It looks like this cannot be right, because it is not a loop.
4219     dnl However, process.c actually does this:
4220     dnl # ifndef __sgi
4221     dnl   continue;
4222     dnl # else
4223     dnl   return -1;
4224     dnl # endif
4225     dnl which presumably makes it OK, since irix == sgi (?).
4226     dnl FIXME it seems like this special treatment is unnecessary?
4227     dnl Why can't irix use a single-trip loop like eg cygwin?
4228     AC_DEFINE(PTY_ITERATION, [])
4229     dnl Not used, because PTY_ITERATION is defined.
4230     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4231     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4232     dnl No need to get the pty name at all.
4233     AC_DEFINE(PTY_NAME_SPRINTF, [])
4234     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4235     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4236     ;;
4237
4238   sol2* )
4239     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4240     dnl from intercepting that death.  If any child but grantpt's should die
4241     dnl within, it should be caught after sigrelse(2).
4242     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4243     ;;
4244
4245   unixware )
4246     dnl Comments are as per sol2*.
4247     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4248     ;;
4249 esac
4250
4251
4252 case $opsys in
4253   sol2* | unixware )
4254     dnl This change means that we don't loop through allocate_pty too
4255     dnl many times in the (rare) event of a failure.
4256     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4257     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4258     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4259     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4260     ;;
4261 esac
4262
4263
4264 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4265 "typing" a signal character on the pty.])
4266
4267 case $opsys in
4268   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4269   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4270   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4271     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4272     ;;
4273
4274   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4275   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4276   gnu-linux | gnu-kfreebsd )
4277
4278     AC_MSG_CHECKING([for signals via characters])
4279     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4280 #include <linux/version.h>
4281 #if LINUX_VERSION_CODE < 0x20400
4282 # error "Linux version too old"
4283 #endif
4284       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4285
4286     AC_MSG_RESULT([$emacs_signals_via_chars])
4287     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4288     ;;
4289 esac
4290
4291
4292 dnl Used in lisp.h, emacs.c, vm-limit.c
4293 dnl NEWS.18 describes this as "a number which contains
4294 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
4295 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
4296 stored in a Lisp_Object.])
4297 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
4298
4299 case $opsys in
4300   aix*)
4301     dnl This works with 32-bit executables; Emacs doesn't support 64-bit.
4302     AC_DEFINE(DATA_SEG_BITS, [0x20000000])
4303     ;;
4304   hpux*)
4305     dnl The data segment on this machine always starts at address 0x40000000.
4306     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
4307     ;;
4308   irix6-5)
4309     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
4310     ;;
4311 esac
4312
4313
4314 AH_TEMPLATE(TAB3, [Undocumented.])
4315
4316 case $opsys in
4317   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4318
4319   gnu | dragonfly | freebsd | netbsd | openbsd )
4320     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4321     AC_DEFINE(TAB3, OXTABS)
4322     ;;
4323
4324   gnu-linux | gnu-kfreebsd )
4325     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4326 #ifndef __ia64__
4327 # error "not ia64"
4328 #endif
4329       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4330         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4331         [Mark a secondary stack, like the register stack on the ia64.]), [])
4332     ;;
4333
4334   hpux*)
4335     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4336       run_time_remap; for HPUX.])
4337     ;;
4338 esac
4339
4340
4341 dnl This won't be used automatically yet.  We also need to know, at least,
4342 dnl that the stack is continuous.
4343 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4344   registers relevant for conservative garbage collection in the jmp_buf.])
4345
4346
4347 case $opsys in
4348   dnl Not all the architectures are tested, but there are Debian packages
4349   dnl for SCM and/or Guile on them, so the technique must work.  See also
4350   dnl comments in alloc.c concerning setjmp and gcc.
4351   dnl Fixme: it's probably safe to just use the GCC conditional below.
4352   gnu-linux | gnu-kfreebsd )
4353     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4354 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4355   || defined __alpha__ || defined __mips__ || defined __s390__ \
4356   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4357   || defined __ia64__ || defined __sh__
4358 /* ok */
4359 #else
4360 # error "setjmp not known to work on this arch"
4361 #endif
4362     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4363     ;;
4364 esac
4365
4366
4367 if test x$GCC = xyes; then
4368    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4369    AC_DEFINE(GC_SETJMP_WORKS, 1)
4370 else
4371   case $opsys in
4372     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4373     dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4374       AC_DEFINE(GC_SETJMP_WORKS, 1)
4375       ;;
4376   esac
4377 fi                              dnl GCC?
4378
4379 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4380 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4381   [AC_LINK_IFELSE(
4382      [AC_LANG_PROGRAM(
4383        [[#include <setjmp.h>
4384          #ifdef __MINGW32__
4385          # define _longjmp longjmp
4386          #endif
4387        ]],
4388        [[jmp_buf j;
4389          if (! _setjmp (j))
4390            _longjmp (j, 1);]])],
4391      [emacs_cv_func__setjmp=yes],
4392      [emacs_cv_func__setjmp=no])])
4393 if test $emacs_cv_func__setjmp = yes; then
4394   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4395 else
4396   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4397     [AC_LINK_IFELSE(
4398        [AC_LANG_PROGRAM(
4399          [[#include <setjmp.h>
4400          ]],
4401          [[sigjmp_buf j;
4402            if (! sigsetjmp (j, 1))
4403              siglongjmp (j, 1);]])],
4404        [emacs_cv_func_sigsetjmp=yes],
4405        [emacs_cv_func_sigsetjmp=no])])
4406   if test $emacs_cv_func_sigsetjmp = yes; then
4407     AC_DEFINE([HAVE_SIGSETJMP], 1,
4408       [Define to 1 if sigsetjmp and siglongjmp work.
4409        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
4410   fi
4411 fi
4412
4413 case $opsys in
4414   sol2* | unixware )
4415     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4416     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4417     dnl and this is all we need.
4418     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4419     ;;
4420 esac
4421
4422
4423 case $opsys in
4424   hpux* | sol2* )
4425     dnl Used in xfaces.c.
4426     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4427       some systems, where it requires time.h.])
4428     ;;
4429 esac
4430
4431
4432 dnl Define symbols to identify the version of Unix this is.
4433 dnl Define all the symbols that apply correctly.
4434 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4435 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4436 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4437 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4438
4439 case $opsys in
4440   aix4-2)
4441     AC_DEFINE(USG, [])
4442     dnl This symbol should be defined on AIX Version 3  ???????
4443     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4444 #ifndef _AIX
4445 # error "_AIX not defined"
4446 #endif
4447     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4448     ;;
4449
4450   cygwin)
4451     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4452     ;;
4453
4454   darwin)
4455     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4456     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4457     dnl distinguish OS X from pure Darwin.
4458     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4459     ;;
4460
4461   gnu-linux | gnu-kfreebsd )
4462     AC_DEFINE(USG, [])
4463     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4464     ;;
4465
4466   hpux*)
4467     AC_DEFINE(USG, [])
4468     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4469     ;;
4470
4471   irix6-5)
4472     AC_DEFINE(USG, [])
4473     AC_DEFINE(USG5_4, [])
4474     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4475     ;;
4476
4477   mingw32)
4478     AC_DEFINE(DOS_NT, [])
4479     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4480     if test "x$ac_enable_checking" != "x" ; then
4481       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4482     fi
4483     ;;
4484
4485   sol2*)
4486     AC_DEFINE(USG, [])
4487     AC_DEFINE(USG5_4, [])
4488     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4489     ;;
4490
4491   unixware)
4492     AC_DEFINE(USG, [])
4493     AC_DEFINE(USG5_4, [])
4494     ;;
4495 esac
4496
4497 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4498   [case $opsys in
4499      aix4-2)
4500        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4501        emacs_cv_usable_FIONREAD=no
4502        ;;
4503
4504      mingw32)
4505        emacs_cv_usable_FIONREAD=yes
4506        ;;
4507
4508      *)
4509        AC_COMPILE_IFELSE(
4510          [AC_LANG_PROGRAM([[#include <sys/types.h>
4511                             #include <sys/ioctl.h>
4512                             #ifdef USG5_4
4513                             # include <sys/filio.h>
4514                             #endif
4515                           ]],
4516                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4517          [emacs_cv_usable_FIONREAD=yes],
4518          [emacs_cv_usable_FIONREAD=no])
4519        ;;
4520    esac])
4521 if test $emacs_cv_usable_FIONREAD = yes; then
4522   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4523
4524   if test $emacs_broken_SIGIO = no; then
4525     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4526       [AC_COMPILE_IFELSE(
4527          [AC_LANG_PROGRAM([[#include <fcntl.h>
4528                             #include <signal.h>
4529                           ]],
4530                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4531          [emacs_cv_usable_SIGIO=yes],
4532          [emacs_cv_usable_SIGIO=no])],
4533       [emacs_cv_usable_SIGIO=yes],
4534       [emacs_cv_usable_SIGIO=no])
4535     if test $emacs_cv_usable_SIGIO = yes; then
4536       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4537     fi
4538   fi
4539 fi
4540
4541
4542 case $opsys in
4543   dnl Emacs supplies its own malloc, but glib calls posix_memalign,
4544   dnl and on Cygwin prior to version 1.7.24 that becomes the
4545   dnl Cygwin-supplied posix_memalign.  As malloc is not the Cygwin
4546   dnl malloc, the Cygwin posix_memalign always returns ENOSYS.  A
4547   dnl workaround is to set G_SLICE=always-malloc.  This is no longer
4548   dnl needed starting with cygwin-1.7.24, and it is no longer
4549   dnl effective starting with glib-2.36. */
4550   cygwin)
4551     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
4552       G_SLICE environment variable to "always-malloc" at startup.])
4553     ;;
4554
4555   hpux11)
4556     dnl It works to open the pty's tty in the parent (Emacs), then
4557     dnl close and reopen it in the child.
4558     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4559       works to open a pty's tty in the parent process, then close and
4560       reopen it in the child.])
4561     ;;
4562
4563   irix6-5)
4564     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4565       use VSUSP instead of VSWTCH.])
4566     ;;
4567
4568   sol2-10)
4569     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4570       on Solaris.])
4571     ;;
4572 esac
4573
4574 # Set up the CFLAGS for real compilation, so we can substitute it.
4575 CFLAGS="$REAL_CFLAGS"
4576 CPPFLAGS="$REAL_CPPFLAGS"
4577
4578 ## Hack to detect a buggy GCC version.
4579 if test "x$GCC" = xyes \
4580    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4581    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4582    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4583    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4584 fi
4585
4586 version=$PACKAGE_VERSION
4587
4588 copyright="Copyright (C) 2014 Free Software Foundation, Inc."
4589 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4590   [Short copyright string for this version of Emacs.])
4591 AC_SUBST(copyright)
4592
4593 ### Specify what sort of things we'll be editing into Makefile and config.h.
4594 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4595 AC_SUBST(version)
4596 AC_SUBST(configuration)
4597 ## Unused?
4598 AC_SUBST(canonical)
4599 AC_SUBST(srcdir)
4600 AC_SUBST(prefix)
4601 AC_SUBST(exec_prefix)
4602 AC_SUBST(bindir)
4603 AC_SUBST(datadir)
4604 AC_SUBST(sharedstatedir)
4605 AC_SUBST(libexecdir)
4606 AC_SUBST(mandir)
4607 AC_SUBST(infodir)
4608 AC_SUBST(lispdir)
4609 AC_SUBST(standardlisppath)
4610 AC_SUBST(locallisppath)
4611 AC_SUBST(lisppath)
4612 AC_SUBST(x_default_search_path)
4613 AC_SUBST(etcdir)
4614 AC_SUBST(archlibdir)
4615 AC_SUBST(etcdocdir)
4616 AC_SUBST(bitmapdir)
4617 AC_SUBST(gamedir)
4618 AC_SUBST(gameuser)
4619 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4620 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4621 ## end of LIBX_BASE, but nothing ever set it.
4622 AC_SUBST(LD_SWITCH_X_SITE)
4623 AC_SUBST(C_SWITCH_X_SITE)
4624 AC_SUBST(GNUSTEP_CFLAGS)
4625 AC_SUBST(CFLAGS)
4626 ## Used in lwlib/Makefile.in.
4627 AC_SUBST(X_TOOLKIT_TYPE)
4628 AC_SUBST(ns_appdir)
4629 AC_SUBST(ns_appbindir)
4630 AC_SUBST(ns_appresdir)
4631 AC_SUBST(ns_appsrc)
4632 AC_SUBST(GNU_OBJC_CFLAGS)
4633 AC_SUBST(OTHER_FILES)
4634
4635 if test -n "${term_header}"; then
4636     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4637         [Define to the header for the built-in window system.])
4638 fi
4639
4640 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4641                    [Define to the canonical Emacs configuration name.])
4642 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4643                    [Define to the options passed to configure.])
4644 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4645   define this to include extra configuration information.])
4646
4647 case $opsys in
4648   mingw32)
4649     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4650     ;;
4651 esac
4652
4653 XMENU_OBJ=
4654 XOBJ=
4655 FONT_OBJ=
4656 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4657   AC_DEFINE(HAVE_X_WINDOWS, 1,
4658             [Define to 1 if you want to use the X window system.])
4659   XMENU_OBJ=xmenu.o
4660   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4661   FONT_OBJ=xfont.o
4662   if test "$HAVE_XFT" = "yes"; then
4663     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4664   elif test "$HAVE_FREETYPE" = "yes"; then
4665     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4666   fi
4667   AC_SUBST(FONT_OBJ)
4668 fi
4669 AC_SUBST(XMENU_OBJ)
4670 AC_SUBST(XOBJ)
4671 AC_SUBST(FONT_OBJ)
4672
4673 WIDGET_OBJ=
4674 MOTIF_LIBW=
4675 if test "${USE_X_TOOLKIT}" != "none" ; then
4676   WIDGET_OBJ=widget.o
4677   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4678   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4679     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4680   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4681     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4682     MOTIF_LIBW=-lXm
4683     case "$opsys" in
4684       gnu-linux)
4685         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4686         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4687         ;;
4688
4689       unixware)
4690         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4691         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4692         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4693         ;;
4694
4695       aix4-2)
4696         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4697         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4698         ;;
4699     esac
4700     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4701   fi
4702 fi
4703 AC_SUBST(WIDGET_OBJ)
4704
4705 TOOLKIT_LIBW=
4706 case "$USE_X_TOOLKIT" in
4707   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4708   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4709   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4710 esac
4711 AC_SUBST(TOOLKIT_LIBW)
4712
4713 if test "${opsys}" != "mingw32"; then
4714   if test "$USE_X_TOOLKIT" = "none"; then
4715     LIBXT_OTHER="\$(LIBXSM)"
4716   else
4717     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4718   fi
4719 fi
4720 AC_SUBST(LIBXT_OTHER)
4721
4722 if test "${HAVE_X11}" = "yes" ; then
4723   AC_DEFINE(HAVE_X11, 1,
4724             [Define to 1 if you want to use version 11 of X windows.])
4725   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4726 else
4727   LIBX_OTHER=
4728 fi
4729 AC_SUBST(LIBX_OTHER)
4730
4731 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4732   LIBXMENU=
4733 elif test "$USE_X_TOOLKIT" = none; then
4734   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4735 else
4736   LIBXMENU='$(lwlibdir)/liblw.a'
4737 fi
4738 AC_SUBST(LIBXMENU)
4739
4740 if test "${GNU_MALLOC}" = "yes" ; then
4741   AC_DEFINE(GNU_MALLOC, 1,
4742             [Define to 1 if you want to use the GNU memory allocator.])
4743 fi
4744
4745 RALLOC_OBJ=
4746 if test "${REL_ALLOC}" = "yes" ; then
4747   AC_DEFINE(REL_ALLOC, 1,
4748             [Define REL_ALLOC if you want to use the relocating allocator for
4749              buffer space.])
4750
4751   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4752 fi
4753 AC_SUBST(RALLOC_OBJ)
4754
4755 if test "$opsys" = "cygwin"; then
4756   CYGWIN_OBJ="sheap.o cygw32.o"
4757   ## Cygwin differs because of its unexec().
4758   PRE_ALLOC_OBJ=
4759   POST_ALLOC_OBJ=lastfile.o
4760 elif test "$opsys" = "mingw32"; then
4761   CYGWIN_OBJ=
4762   PRE_ALLOC_OBJ=
4763   POST_ALLOC_OBJ=lastfile.o
4764 else
4765   CYGWIN_OBJ=
4766   PRE_ALLOC_OBJ=lastfile.o
4767   POST_ALLOC_OBJ=
4768 fi
4769 AC_SUBST(CYGWIN_OBJ)
4770 AC_SUBST(PRE_ALLOC_OBJ)
4771 AC_SUBST(POST_ALLOC_OBJ)
4772
4773 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4774 dnl verbatim defined above.  The tricky name is apropos, as this hack
4775 dnl makes Fortify go sour!
4776 AH_VERBATIM([FORTIFY_SOUR],
4777 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4778    The workaround disables some useful run-time checking, so it
4779    should be conditional to the platforms with the performance bug.
4780    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4781 #if defined __APPLE__ && defined __GNUC__
4782 # ifndef _DONT_USE_CTYPE_INLINE_
4783 #  define _DONT_USE_CTYPE_INLINE_
4784 # endif
4785 # ifndef _FORTIFY_SOURCE
4786 #  define _FORTIFY_SOURCE 0
4787 # endif
4788 #endif
4789 ])
4790
4791 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4792 # it temporarily reverts them to their pre-pkg-config values,
4793 # because gnulib needs to work with both src (which uses the
4794 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4795 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4796 # and it therefore needs to run in an environment where LIBS does not
4797 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4798 # for some package unrelated to lib-src.
4799 SAVE_CFLAGS=$CFLAGS
4800 SAVE_LIBS=$LIBS
4801 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4802 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4803 gl_ASSERT_NO_GNULIB_POSIXCHECK
4804 gl_ASSERT_NO_GNULIB_TESTS
4805 gl_INIT
4806 CFLAGS=$SAVE_CFLAGS
4807 LIBS=$SAVE_LIBS
4808
4809 if test "${opsys}" = "mingw32"; then
4810   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4811   # Remove unneeded switches from the value of CC that goes to Makefiles
4812   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4813 fi
4814
4815 case "$opsys" in
4816   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4817
4818   darwin)
4819    ## The -headerpad option tells ld (see man page) to leave room at the
4820    ## end of the header for adding load commands.  Needed for dumping.
4821    ## 0x690 is the total size of 30 segment load commands (at 56
4822    ## each); under Cocoa 31 commands are required.
4823    if test "$HAVE_NS" = "yes"; then
4824      libs_nsgui="-framework AppKit"
4825      if test "$NS_IMPL_COCOA" = "yes"; then
4826         libs_nsgui="$libs_nsgui -framework IOKit"
4827      fi
4828      headerpad_extra=6C8
4829    else
4830      libs_nsgui=
4831      headerpad_extra=690
4832    fi
4833    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4834
4835    ## This is here because src/Makefile.in did some extra fiddling around
4836    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
4837    ## LD_SWITCH_SYSTEM_TEMACS instead,
4838    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4839      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4840    ;;
4841
4842   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4843   ## find X at run-time.
4844   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4845   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4846   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4847   ## had different values in configure (in ac_link) and src/Makefile.in.
4848   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4849   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4850
4851   mingw32)
4852    ## MinGW64 does not prepend an underscore to symbols, so we must
4853    ## pass a different -entry switch to linker.  FIXME: It is better
4854    ## to make the entry points the same by changing unexw32.c.
4855    case "$canonical" in
4856      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4857      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4858    esac
4859    ;;
4860
4861   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4862
4863   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4864 esac
4865
4866 if test x$ac_enable_profiling != x ; then
4867   case $opsys in
4868     *freebsd | gnu-linux) ;;
4869     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4870   esac
4871 fi
4872
4873 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
4874
4875 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4876
4877 ## MinGW-specific post-link processing of temacs.
4878 TEMACS_POST_LINK=":"
4879 ADDSECTION=
4880 EMACS_HEAPSIZE=
4881 if test "${opsys}" = "mingw32"; then
4882   TEMACS_POST_LINK="\$(MINGW_TEMACS_POST_LINK)"
4883   ADDSECTION="../nt/addsection\$(EXEEXT)"
4884   ## Preload heap size of temacs.exe in MB.
4885   case "$canonical" in
4886     x86_64-*-*) EMACS_HEAPSIZE=42 ;;
4887     *) EMACS_HEAPSIZE=27 ;;
4888   esac
4889 fi
4890
4891 AC_SUBST(ADDSECTION)
4892 AC_SUBST(TEMACS_POST_LINK)
4893 AC_SUBST(EMACS_HEAPSIZE)
4894
4895 ## Common for all window systems
4896 if test "$window_system" != "none"; then
4897   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4898   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4899 fi
4900
4901 AC_SUBST(WINDOW_SYSTEM_OBJ)
4902
4903 AH_TOP([/* GNU Emacs site configuration template file.
4904
4905 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2014
4906   Free Software Foundation, Inc.
4907
4908 This file is part of GNU Emacs.
4909
4910 GNU Emacs is free software: you can redistribute it and/or modify
4911 it under the terms of the GNU General Public License as published by
4912 the Free Software Foundation, either version 3 of the License, or
4913 (at your option) any later version.
4914
4915 GNU Emacs is distributed in the hope that it will be useful,
4916 but WITHOUT ANY WARRANTY; without even the implied warranty of
4917 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4918 GNU General Public License for more details.
4919
4920 You should have received a copy of the GNU General Public License
4921 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4922
4923
4924 /* No code in Emacs #includes config.h twice, but some bits of code
4925    intended to work with other packages as well (like gmalloc.c)
4926    think they can include it as many times as they like.  */
4927 #ifndef EMACS_CONFIG_H
4928 #define EMACS_CONFIG_H
4929 ])dnl
4930
4931 AH_BOTTOM([#include <conf_post.h>
4932
4933 #endif /* EMACS_CONFIG_H */
4934
4935 /*
4936 Local Variables:
4937 mode: c
4938 End:
4939 */
4940 ])dnl
4941
4942 #### Report on what we decided to do.
4943 #### Report GTK as a toolkit, even if it doesn't use Xt.
4944 #### It makes printing result more understandable as using GTK sets
4945 #### toolkit_scroll_bars to yes by default.
4946 if test "${HAVE_GTK}" = "yes"; then
4947   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4948 fi
4949
4950 if test $USE_ACL -ne 0; then
4951   ACL_SUMMARY="yes $LIB_ACL"
4952 else
4953   ACL_SUMMARY=no
4954 fi
4955
4956 echo "
4957 Configured for \`${canonical}'.
4958
4959   Where should the build process find the source code?    ${srcdir}
4960   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4961   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4962   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4963   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4964   What window system should Emacs use?                    ${window_system}
4965   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4966
4967 if test -n "${x_includes}"; then
4968 echo "  Where do we find X Windows header files?                ${x_includes}"
4969 else
4970 echo "  Where do we find X Windows header files?                Standard dirs"
4971 fi
4972 if test -n "${x_libraries}"; then
4973 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4974 else
4975 echo "  Where do we find X Windows libraries?                   Standard dirs"
4976 fi
4977
4978 optsep=
4979 emacs_config_features=
4980 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG IMAGEMAGICK SOUND GPM DBUS \
4981   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
4982   LIBOTF XFT ZLIB; do
4983
4984     case $opt in
4985       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
4986       *) eval val=\${HAVE_$opt} ;;
4987     esac
4988     test x"$val" = xno && continue
4989     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
4990     optsep=' '
4991 done
4992 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
4993   [Summary of some of the main features enabled by configure.])
4994
4995 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4996 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4997 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4998 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4999 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
5000 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
5001 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
5002 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
5003
5004 echo "  Does Emacs support sound?                               ${HAVE_SOUND}"
5005
5006 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
5007 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
5008 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
5009 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
5010 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
5011 echo "  Does Emacs use access control lists?                    ${ACL_SUMMARY}"
5012 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
5013 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
5014 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
5015
5016 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
5017 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
5018 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
5019 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
5020 echo "  Does Emacs directly use zlib?                           ${HAVE_ZLIB}"
5021
5022 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
5023 echo
5024
5025 if test -n "${EMACSDATA}"; then
5026    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
5027 fi
5028 if test -n "${EMACSDOC}"; then
5029    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
5030 fi
5031
5032 echo
5033
5034 if test "$HAVE_NS" = "yes"; then
5035    echo
5036    echo "You must run \"${MAKE-make} install\" in order to test the built application.
5037 The installed application will go to nextstep/Emacs.app and can be
5038 run or moved from there."
5039    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5040       echo "The application will be fully self-contained."
5041     else
5042       echo "The lisp resources for the application will be installed under ${prefix}.
5043 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5044 to run if these resources are not installed."
5045    fi
5046    echo
5047 fi
5048
5049 if test "${opsys}" = "cygwin"; then
5050   case `uname -r` in
5051     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5052            echo
5053            ;;
5054   esac
5055 fi
5056
5057 # Remove any trailing slashes in these variables.
5058 [test "${prefix}" != NONE &&
5059   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
5060 test "${exec_prefix}" != NONE &&
5061   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
5062
5063 if test "$HAVE_NS" = "yes"; then
5064   if test "$NS_IMPL_GNUSTEP" = yes; then
5065     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5066       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5067     ns_check_file=Resources/Info-gnustep.plist
5068   else
5069     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5070       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5071     ns_check_file=Contents/Info.plist
5072   fi
5073   AC_SUBST(ns_check_file)
5074 fi
5075
5076 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5077 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5078 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5079 dnl (else you get "no `Makefile.am' found for any configure output").
5080 dnl This will work, but you get a config.status that is not quite right
5081 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5082 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5083 dnl it seems better to just live with the duplication.
5084 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5085
5086 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5087        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5088        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5089        leim/Makefile nextstep/Makefile nt/Makefile])
5090
5091 dnl test/ is not present in release tarfiles.
5092 opt_makefile=test/automated/Makefile
5093
5094 if test -f "$srcdir/$opt_makefile.in"; then
5095   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5096   dnl Again, it's best not to use a variable.  Though you can add
5097   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5098   AC_CONFIG_FILES([test/automated/Makefile])
5099 fi
5100
5101
5102 dnl The admin/ directory used to be excluded from tarfiles.
5103 if test -d $srcdir/admin; then
5104   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/unidata/Makefile admin/grammars/Makefile"
5105   AC_CONFIG_FILES([admin/unidata/Makefile])
5106   AC_CONFIG_FILES([admin/grammars/Makefile])
5107 fi                              dnl -d admin
5108
5109
5110 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5111
5112 AC_SUBST(SUBDIR_MAKEFILES_IN)
5113
5114 dnl You might wonder (I did) why epaths.h is generated by running make,
5115 dnl rather than just letting configure generate it from epaths.in.
5116 dnl One reason is that the various paths are not fully expanded (see above);
5117 dnl eg gamedir=${prefix}/var/games/emacs.
5118 dnl Secondly, the GNU Coding standards require that one should be able
5119 dnl to run `make prefix=/some/where/else' and override the values set
5120 dnl by configure.  This also explains the `move-if-change' test and
5121 dnl the use of force in the `epaths-force' rule in Makefile.in.
5122 AC_CONFIG_COMMANDS([src/epaths.h], [
5123 if test "${opsys}" = "mingw32"; then
5124   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5125 else
5126   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5127 fi
5128 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5129
5130 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5131 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5132 dnl or a symlink?
5133 AC_CONFIG_COMMANDS([src/.gdbinit], [
5134 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5135   echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit
5136 fi
5137 ])
5138
5139 AC_OUTPUT