lisp/skeleton.el

   1 ;;; skeleton.el --- Lisp language extension for writing statement skeletons
   2
   3 ;; Copyright (C) 1993, 1994, 1995, 1996 by Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel Pfeiffer <occitan@esperanto.org>
   6 ;; Maintainer: FSF
   7 ;; Keywords: extensions, abbrev, languages, tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; A very concise language extension for writing structured statement
  29 ;; skeleton insertion commands for programming language modes.  This
  30 ;; originated in shell-script mode and was applied to ada-mode's
  31 ;; commands which shrunk to one third.  And these commands are now
  32 ;; user configurable.
  33
  34 ;;; Code:
  35
  36 ;; page 1:      statement skeleton language definition & interpreter
  37 ;; page 2:      paired insertion
  38 ;; page 3:      mirror-mode, an example for setting up paired insertion
  39
  40
  41 (defvar skeleton-transformation nil
  42   "*If non-nil, function applied to literal strings before they are inserted.
  43 It should take strings and characters and return them transformed, or nil
  44 which means no transformation.
  45 Typical examples might be `upcase' or `capitalize'.")
  46
  47 ; this should be a fourth argument to defvar
  48 (put 'skeleton-transformation 'variable-interactive
  49      "aTransformation function: ")
  50
  51
  52 (defvar skeleton-autowrap t
  53   "Controls wrapping behaviour of functions created with `define-skeleton'.
  54 When the region is visible (due to `transient-mark-mode' or marking a region
  55 with the mouse) and this is non-`nil' and the function was called without an
  56 explicit ARG, then the ARG defaults to -1, i.e. wrapping around the visible
  57 region.
  58
  59 We will probably delete this variable in a future Emacs version
  60 unless we get a substantial number of complaints about the auto-wrap
  61 feature.")
  62
  63 (defvar skeleton-end-newline t
  64   "If non-nil, make sure that the skeleton inserted ends with a newline.
  65 This just influences the way the default `skeleton-end-hook' behaves.")
  66
  67 (defvar skeleton-end-hook
  68   (lambda ()
  69     (or (eolp) (not skeleton-end-newline) (newline-and-indent)))
  70   "Hook called at end of skeleton but before going to point of interest.
  71 By default this moves out anything following to next line,
  72   unless `skeleton-end-newline' is set to nil.
  73 The variables `v1' and `v2' are still set when calling this.")
  74
  75
  76 ;;;###autoload
  77 (defvar skeleton-filter 'identity
  78   "Function for transforming a skeleton proxy's aliases' variable value.")
  79
  80 (defvar skeleton-untabify t
  81   "When non-`nil' untabifies when deleting backwards with element -ARG.")
  82
  83 (defvar skeleton-newline-indent-rigidly nil
  84   "When non-`nil', indent rigidly under current line for element `\\n'.
  85 Else use mode's `indent-line-function'.")
  86
  87 (defvar skeleton-further-elements ()
  88   "A buffer-local varlist (see `let') of mode specific skeleton elements.
  89 These variables are bound while interpreting a skeleton.  Their value may
  90 in turn be any valid skeleton element if they are themselves to be used as
  91 skeleton elements.")
  92 (make-variable-buffer-local 'skeleton-further-elements)
  93
  94
  95 (defvar skeleton-subprompt
  96   (substitute-command-keys
  97    "RET, \\<minibuffer-local-map>\\[abort-recursive-edit] or \\[help-command]")
  98   "*Replacement for %s in prompts of recursive subskeletons.")
  99
 100
 101 (defvar skeleton-abbrev-cleanup nil
 102   "Variable used to delete the character that led to abbrev expansion.")
 103
 104
 105 (defvar skeleton-debug nil
 106   "*If non-nil `define-skeleton' will override previous definition.")
 107
 108 (defvar skeleton-positions nil
 109   "List of positions marked with @, after skeleton insertion.
 110 The list describes the most recent skeleton insertion, and its elements
 111 are integer buffer positions in the reverse order of the insertion order.")
 112
 113 ;; reduce the number of compiler warnings
 114 (defvar skeleton)
 115 (defvar skeleton-modified)
 116 (defvar skeleton-point)
 117 (defvar skeleton-regions)
 118
 119 ;;;###autoload
 120 (defmacro define-skeleton (command documentation &rest skeleton)
 121   "Define a user-configurable COMMAND that enters a statement skeleton.
 122 DOCUMENTATION is that of the command, while the variable of the same name,
 123 which contains the skeleton, has a documentation to that effect.
 124 INTERACTOR and ELEMENT ... are as defined under `skeleton-insert'."
 125   (if skeleton-debug
 126       (set command skeleton))
 127   `(progn
 128      (defun ,command (&optional str arg)
 129        ,(concat documentation
 130                 (if (string-match "\n\\>" documentation)
 131                     "" "\n")
 132                 "\n"
 133   "This is a skeleton command (see `skeleton-insert').
 134 Normally the skeleton text is inserted at point, with nothing \"inside\".
 135 If there is a highlighted region, the skeleton text is wrapped
 136 around the region text.
 137
 138 A prefix argument ARG says to wrap the skeleton around the next ARG words.
 139 A prefix argument of -1 says to wrap around region, even if not highlighted.
 140 A prefix argument of zero says to wrap around zero words---that is, nothing.
 141 This is a way of overriding the use of a highlighted region.")
 142        (interactive "*P\nP")
 143        (skeleton-proxy-new ',skeleton str arg))))
 144
 145 ;;;###autoload
 146 (defun skeleton-proxy-new (skeleton &optional str arg)
 147   "Insert skeleton defined by variable of same name (see `skeleton-insert').
 148 Prefix ARG allows wrapping around words or regions (see `skeleton-insert').
 149 If no ARG was given, but the region is visible, ARG defaults to -1 depending
 150 on `skeleton-autowrap'.  An ARG of  M-0  will prevent this just for once.
 151 This command can also be an abbrev expansion (3rd and 4th columns in
 152 \\[edit-abbrevs]  buffer: \"\"  command-name).
 153
 154 When called as a function, optional first argument STR may also be a string
 155 which will be the value of `str' whereas the skeleton's interactor is then
 156 ignored."
 157   (interactive "*P\nP")
 158   (setq skeleton (funcall skeleton-filter skeleton))
 159   (if (not skeleton)
 160       (if (memq this-command '(self-insert-command
 161                                skeleton-pair-insert-maybe
 162                                expand-abbrev))
 163           (setq buffer-undo-list (primitive-undo 1 buffer-undo-list)))
 164     (skeleton-insert skeleton
 165                      (if (setq skeleton-abbrev-cleanup
 166                                (or (eq this-command 'self-insert-command)
 167                                    (eq this-command
 168                                        'skeleton-pair-insert-maybe)))
 169                          ()
 170                        ;; Pretend  C-x a e  passed its prefix arg to us
 171                        (if (or arg current-prefix-arg)
 172                            (prefix-numeric-value (or arg
 173                                                      current-prefix-arg))
 174                          (and skeleton-autowrap
 175                               (or (eq last-command 'mouse-drag-region)
 176                                   (and transient-mark-mode mark-active))
 177                               -1)))
 178                      (if (stringp str)
 179                          str))
 180     (and skeleton-abbrev-cleanup
 181          (setq skeleton-abbrev-cleanup (point))
 182          (add-hook 'post-command-hook 'skeleton-abbrev-cleanup nil t))))
 183
 184 ;; This command isn't meant to be called, only its aliases with meaningful
 185 ;; names are.
 186 ;;;###autoload
 187 (defun skeleton-proxy (&optional str arg)
 188   "Insert skeleton defined by variable of same name (see `skeleton-insert').
 189 Prefix ARG allows wrapping around words or regions (see `skeleton-insert').
 190 If no ARG was given, but the region is visible, ARG defaults to -1 depending
 191 on `skeleton-autowrap'.  An ARG of  M-0  will prevent this just for once.
 192 This command can also be an abbrev expansion (3rd and 4th columns in
 193 \\[edit-abbrevs]  buffer: \"\"  command-name).
 194
 195 When called as a function, optional first argument STR may also be a string
 196 which will be the value of `str' whereas the skeleton's interactor is then
 197 ignored."
 198   (interactive "*P\nP")
 199   (let ((function (nth 1 (backtrace-frame 1))))
 200     (if (eq function 'nth)              ; uncompiled Lisp function
 201         (setq function (nth 1 (backtrace-frame 5)))
 202       (if (eq function 'byte-code)      ; tracing byte-compiled function
 203           (setq function (nth 1 (backtrace-frame 2)))))
 204     (if (not (setq function (funcall skeleton-filter (symbol-value function))))
 205         (if (memq this-command '(self-insert-command
 206                                  skeleton-pair-insert-maybe
 207                                  expand-abbrev))
 208             (setq buffer-undo-list (primitive-undo 1 buffer-undo-list)))
 209       (skeleton-insert function
 210                        (if (setq skeleton-abbrev-cleanup
 211                                  (or (eq this-command 'self-insert-command)
 212                                      (eq this-command
 213                                          'skeleton-pair-insert-maybe)))
 214                            ()
 215                          ;; Pretend  C-x a e  passed its prefix arg to us
 216                          (if (or arg current-prefix-arg)
 217                              (prefix-numeric-value (or arg
 218                                                        current-prefix-arg))
 219                            (and skeleton-autowrap
 220                                 (or (eq last-command 'mouse-drag-region)
 221                                     (and transient-mark-mode mark-active))
 222                                 -1)))
 223                        (if (stringp str)
 224                            str))
 225       (and skeleton-abbrev-cleanup
 226            (setq skeleton-abbrev-cleanup (point))
 227            (add-hook 'post-command-hook 'skeleton-abbrev-cleanup nil t)))))
 228
 229
 230 (defun skeleton-abbrev-cleanup (&rest list)
 231   "Value for `post-command-hook' to remove char that expanded abbrev."
 232   (if (integerp skeleton-abbrev-cleanup)
 233       (progn
 234         (delete-region skeleton-abbrev-cleanup (point))
 235         (setq skeleton-abbrev-cleanup)
 236         (remove-hook 'post-command-hook 'skeleton-abbrev-cleanup t))))
 237
 238
 239 ;;;###autoload
 240 (defun skeleton-insert (skeleton &optional regions str)
 241   "Insert the complex statement skeleton SKELETON describes very concisely.
 242
 243 With optional second argument REGIONS, wrap first interesting point
 244 \(`_') in skeleton around next REGIONS words, if REGIONS is positive.
 245 If REGIONS is negative, wrap REGIONS preceding interregions into first
 246 REGIONS interesting positions \(successive `_'s) in skeleton.
 247
 248 An interregion is the stretch of text between two contiguous marked
 249 points.  If you marked A B C [] (where [] is the cursor) in
 250 alphabetical order, the 3 interregions are simply the last 3 regions.
 251 But if you marked B A [] C, the interregions are B-A, A-[], []-C.
 252
 253 The optional third argument STR, if specified, is the value for the
 254 variable `str' within the skeleton.  When this is non-nil, the
 255 interactor gets ignored, and this should be a valid skeleton element.
 256
 257 SKELETON is made up as (INTERACTOR ELEMENT ...).  INTERACTOR may be nil if
 258 not needed, a prompt-string or an expression for complex read functions.
 259
 260 If ELEMENT is a string or a character it gets inserted (see also
 261 `skeleton-transformation').  Other possibilities are:
 262
 263         \\n     go to next line and indent according to mode
 264         _       interesting point, interregion here
 265         >       indent line (or interregion if > _) according to major mode
 266         @       add position to `skeleton-positions'
 267         &       do next ELEMENT iff previous moved point
 268         |       do next ELEMENT iff previous didn't move point
 269         -num    delete num preceding characters (see `skeleton-untabify')
 270         resume: skipped, continue here if quit is signaled
 271         nil     skipped
 272
 273 After termination, point will be positioned at the first occurrence
 274 of _ or @ or at the end of the inserted text.
 275
 276 Further elements can be defined via `skeleton-further-elements'.  ELEMENT may
 277 itself be a SKELETON with an INTERACTOR.  The user is prompted repeatedly for
 278 different inputs.  The SKELETON is processed as often as the user enters a
 279 non-empty string.  \\[keyboard-quit] terminates skeleton insertion, but
 280 continues after `resume:' and positions at `_' if any.  If INTERACTOR in such
 281 a subskeleton is a prompt-string which contains a \".. %s ..\" it is
 282 formatted with `skeleton-subprompt'.  Such an INTERACTOR may also be a list of
 283 strings with the subskeleton being repeated once for each string.
 284
 285 Quoted Lisp expressions are evaluated for their side-effects.
 286 Other Lisp expressions are evaluated and the value treated as above.
 287 Note that expressions may not return `t' since this implies an
 288 endless loop.  Modes can define other symbols by locally setting them
 289 to any valid skeleton element.  The following local variables are
 290 available:
 291
 292         str     first time: read a string according to INTERACTOR
 293                 then: insert previously read string once more
 294         help    help-form during interaction with the user or `nil'
 295         input   initial input (string or cons with index) while reading str
 296         v1, v2  local variables for memorizing anything you want
 297
 298 When done with skeleton, but before going back to `_'-point call
 299 `skeleton-end-hook' if that is non-`nil'."
 300   (let ((skeleton-regions regions))
 301     (and skeleton-regions
 302          (setq skeleton-regions
 303                (if (> skeleton-regions 0)
 304                    (list (point-marker)
 305                          (save-excursion (forward-word skeleton-regions)
 306                                          (point-marker)))
 307                  (setq skeleton-regions (- skeleton-regions))
 308                  ;; copy skeleton-regions - 1 elements from `mark-ring'
 309                  (let ((l1 (cons (mark-marker) mark-ring))
 310                        (l2 (list (point-marker))))
 311                    (while (and l1 (> skeleton-regions 0))
 312                      (setq l2 (cons (car l1) l2)
 313                            skeleton-regions (1- skeleton-regions)
 314                            l1 (cdr l1)))
 315                    (sort l2 '<))))
 316          (goto-char (car skeleton-regions))
 317          (setq skeleton-regions (cdr skeleton-regions)))
 318     (let ((beg (point))
 319           skeleton-modified skeleton-point resume: help input v1 v2)
 320       (setq skeleton-positions nil)
 321       (unwind-protect
 322           (eval `(let ,skeleton-further-elements
 323                    (skeleton-internal-list skeleton str)))
 324         (run-hooks 'skeleton-end-hook)
 325         (sit-for 0)
 326         (or (pos-visible-in-window-p beg)
 327             (progn
 328               (goto-char beg)
 329               (recenter 0)))
 330         (if skeleton-point
 331             (goto-char skeleton-point))))))
 332
 333 (defun skeleton-read (prompt &optional initial-input recursive)
 334   "Function for reading a string from the minibuffer within skeletons.
 335
 336 PROMPT must be a string or a form that evaluates to a string.
 337 It may contain a `%s' which will be replaced by `skeleton-subprompt'.
 338 If non-`nil' second arg INITIAL-INPUT or variable `input' is a string or
 339 cons with index to insert before reading.  If third arg RECURSIVE is non-`nil'
 340 i.e. we are handling the iterator of a subskeleton, returns empty string if
 341 user didn't modify input.
 342 While reading, the value of `minibuffer-help-form' is variable `help' if that
 343 is non-nil or a default string."
 344   (let ((minibuffer-help-form (or (if (boundp 'help) (symbol-value 'help))
 345                                   (if recursive "\
 346 As long as you provide input you will insert another subskeleton.
 347
 348 If you enter the empty string, the loop inserting subskeletons is
 349 left, and the current one is removed as far as it has been entered.
 350
 351 If you quit, the current subskeleton is removed as far as it has been
 352 entered.  No more of the skeleton will be inserted, except maybe for a
 353 syntactically necessary termination."
 354                                     "\
 355 You are inserting a skeleton.  Standard text gets inserted into the buffer
 356 automatically, and you are prompted to fill in the variable parts.")))
 357         (eolp (eolp)))
 358     ;; since Emacs doesn't show main window's cursor, do something noticeable
 359     (or eolp
 360         (open-line 1))
 361     (unwind-protect
 362         (setq prompt (if (stringp prompt)
 363                          (read-string (format prompt skeleton-subprompt)
 364                                       (setq initial-input
 365                                             (or initial-input
 366                                                 (symbol-value 'input))))
 367                        (eval prompt)))
 368       (or eolp
 369           (delete-char 1))))
 370   (if (and recursive
 371            (or (null prompt)
 372                (string= prompt "")
 373                (equal prompt initial-input)
 374                (equal prompt (car-safe initial-input))))
 375       (signal 'quit t)
 376     prompt))
 377
 378 (defun skeleton-internal-list (skeleton &optional str recursive)
 379   (let* ((start (save-excursion (beginning-of-line) (point)))
 380          (column (current-column))
 381          (line (buffer-substring start
 382                                  (save-excursion (end-of-line) (point))))
 383          opoint)
 384     (or str
 385         (setq str `(setq str (skeleton-read ',(car skeleton) nil ,recursive))))
 386     (when (and (eq (cadr skeleton) '\n)
 387                (<= (current-column) (current-indentation)))
 388       (setq skeleton (cons nil (cons '> (cddr skeleton)))))
 389     (while (setq skeleton-modified (eq opoint (point))
 390                  opoint (point)
 391                  skeleton (cdr skeleton))
 392       (condition-case quit
 393           (skeleton-internal-1 (car skeleton))
 394         (quit
 395          (if (eq (cdr quit) 'recursive)
 396              (setq recursive 'quit
 397                    skeleton (memq 'resume: skeleton))
 398            ;; remove the subskeleton as far as it has been shown
 399            ;; the subskeleton shouldn't have deleted outside current line
 400            (end-of-line)
 401            (delete-region start (point))
 402            (insert line)
 403            (move-to-column column)
 404            (if (cdr quit)
 405                (setq skeleton ()
 406                      recursive nil)
 407              (signal 'quit 'recursive)))))))
 408   ;; maybe continue loop or go on to next outer resume: section
 409   (if (eq recursive 'quit)
 410       (signal 'quit 'recursive)
 411     recursive))
 412
 413
 414 (defun skeleton-internal-1 (element &optional literal)
 415   (cond ((char-or-string-p element)
 416          (if (and (integerp element)    ; -num
 417                   (< element 0))
 418              (if skeleton-untabify
 419                  (backward-delete-char-untabify (- element))
 420                (delete-backward-char (- element)))
 421            (insert-before-markers (if (and skeleton-transformation
 422                                            (not literal))
 423                                       (funcall skeleton-transformation element)
 424                                     element))))
 425         ((eq element '\n)               ; actually (eq '\n 'n)
 426          (cond
 427           ((and skeleton-regions (eq (nth 1 skeleton) '_))
 428            (or (eolp) (newline))
 429            (indent-region (line-beginning-position)
 430                           (car skeleton-regions) nil))
 431           ;; \n as last element only inserts \n if not at eol.
 432           ((and (null (cdr skeleton)) (eolp)) nil)
 433           (skeleton-newline-indent-rigidly
 434            (indent-to (prog1 (current-indentation) (newline))))
 435           (t (newline) (indent-according-to-mode))))
 436         ((eq element '>)
 437          (if (and skeleton-regions (eq (nth 1 skeleton) '_))
 438              (indent-region (line-beginning-position)
 439                             (car skeleton-regions) nil)
 440            (indent-according-to-mode)))
 441         ((eq element '_)
 442          (if skeleton-regions
 443              (progn
 444                (goto-char (car skeleton-regions))
 445                (setq skeleton-regions (cdr skeleton-regions))
 446                (and (<= (current-column) (current-indentation))
 447                     (eq (nth 1 skeleton) '\n)
 448                     (end-of-line 0)))
 449            (or skeleton-point
 450                (setq skeleton-point (point)))))
 451         ((eq element '&)
 452          (when skeleton-modified (pop skeleton)))
 453         ((eq element '|)
 454          (unless skeleton-modified (pop skeleton)))
 455         ((eq element '@)
 456          (push (point) skeleton-positions)
 457          (unless skeleton-point (setq skeleton-point (point))))
 458         ((eq 'quote (car-safe element))
 459          (eval (nth 1 element)))
 460         ((or (stringp (car-safe element))
 461              (consp (car-safe element)))
 462          (if (symbolp (car-safe (car element)))
 463              (while (skeleton-internal-list element nil t))
 464            (setq literal (car element))
 465            (while literal
 466              (skeleton-internal-list element (car literal))
 467              (setq literal (cdr literal)))))
 468         ((null element))
 469         ((skeleton-internal-1 (eval element) t))))
 470
 471
 472 ;; Maybe belongs into simple.el or elsewhere
 473 ;; ;###autoload
 474 ;;; (define-skeleton local-variables-section
 475 ;;  "Insert a local variables section.  Use current comment syntax if any."
 476 ;;  (completing-read "Mode: " obarray
 477 ;;                 (lambda (symbol)
 478 ;;                   (if (commandp symbol)
 479 ;;                       (string-match "-mode$" (symbol-name symbol))))
 480 ;;                 t)
 481 ;;  '(save-excursion
 482 ;;     (if (re-search-forward page-delimiter nil t)
 483 ;;       (error "Not on last page")))
 484 ;;  comment-start "Local Variables:" comment-end \n
 485 ;;  comment-start "mode: " str
 486 ;;  & -5 | '(kill-line 0) & -1 | comment-end \n
 487 ;;  ( (completing-read (format "Variable, %s: " skeleton-subprompt)
 488 ;;                   obarray
 489 ;;                   (lambda (symbol)
 490 ;;                     (or (eq symbol 'eval)
 491 ;;                         (user-variable-p symbol)))
 492 ;;                   t)
 493 ;;    comment-start str ": "
 494 ;;    (read-from-minibuffer "Expression: " nil read-expression-map nil
 495 ;;                        'read-expression-history) | _
 496 ;;    comment-end \n)
 497 ;;  resume:
 498 ;;  comment-start "End:" comment-end \n)
 499 \f
 500 ;; Variables and command for automatically inserting pairs like () or "".
 501
 502 (defvar skeleton-pair nil
 503   "*If this is nil pairing is turned off, no matter what else is set.
 504 Otherwise modes with `skeleton-pair-insert-maybe' on some keys
 505 will attempt to insert pairs of matching characters.")
 506
 507
 508 (defvar skeleton-pair-on-word nil
 509   "*If this is nil, paired insertion is inhibited before or inside a word.")
 510
 511
 512 (defvar skeleton-pair-filter (lambda () nil)
 513   "Attempt paired insertion if this function returns nil, before inserting.
 514 This allows for context-sensitive checking whether pairing is appropriate.")
 515
 516
 517 (defvar skeleton-pair-alist ()
 518   "An override alist of pairing partners matched against `last-command-char'.
 519 Each alist element, which looks like (ELEMENT ...), is passed to
 520 `skeleton-insert' with no interactor.  Variable `str' does nothing.
 521
 522 Elements might be (?` ?` _ \"''\"), (?\\( ?  _ \" )\") or (?{ \\n > _ \\n ?} >).")
 523
 524
 525 ;;;###autoload
 526 (defun skeleton-pair-insert-maybe (arg)
 527   "Insert the character you type ARG times.
 528
 529 With no ARG, if `skeleton-pair' is non-nil, pairing can occur.  If the region
 530 is visible the pair is wrapped around it depending on `skeleton-autowrap'.
 531 Else, if `skeleton-pair-on-word' is non-nil or we are not before or inside a
 532 word, and if `skeleton-pair-filter' returns nil, pairing is performed.
 533 Pairing is also prohibited if we are right after a quoting character
 534 such as backslash.
 535
 536 If a match is found in `skeleton-pair-alist', that is inserted, else
 537 the defaults are used.  These are (), [], {}, <> and `' for the
 538 symmetrical ones, and the same character twice for the others."
 539   (interactive "*P")
 540   (let ((mark (and skeleton-autowrap
 541                    (or (eq last-command 'mouse-drag-region)
 542                        (and transient-mark-mode mark-active))))
 543         (skeleton-end-hook))
 544     (if (or arg
 545             (not skeleton-pair)
 546             (memq (char-syntax (preceding-char)) '(?\\ ?/))
 547             (and (not mark)
 548                  (or overwrite-mode
 549                      (if (not skeleton-pair-on-word) (looking-at "\\w"))
 550                      (funcall skeleton-pair-filter))))
 551         (self-insert-command (prefix-numeric-value arg))
 552       (setq last-command-char (logand last-command-char 255))
 553       (or skeleton-abbrev-cleanup
 554           (skeleton-insert
 555            (cons nil (or (assq last-command-char skeleton-pair-alist)
 556                          (assq last-command-char '((?( _ ?))
 557                                                    (?[ _ ?])
 558                                                    (?{ _ ?})
 559                                                    (?< _ ?>)
 560                                                    (?` _ ?')))
 561                          `(,last-command-char _ ,last-command-char)))
 562            (if mark -1))))))
 563
 564 \f
 565 ;; A more serious example can be found in sh-script.el
 566 ;;; (defun mirror-mode ()
 567 ;;  "This major mode is an amusing little example of paired insertion.
 568 ;;All printable characters do a paired self insert, while the other commands
 569 ;;work normally."
 570 ;;  (interactive)
 571 ;;  (kill-all-local-variables)
 572 ;;  (make-local-variable 'skeleton-pair)
 573 ;;  (make-local-variable 'skeleton-pair-on-word)
 574 ;;  (make-local-variable 'skeleton-pair-filter)
 575 ;;  (make-local-variable 'skeleton-pair-alist)
 576 ;;  (setq major-mode 'mirror-mode
 577 ;;      mode-name "Mirror"
 578 ;;      skeleton-pair-on-word t
 579 ;;      ;; in the middle column insert one or none if odd window-width
 580 ;;      skeleton-pair-filter (lambda ()
 581 ;;                             (if (>= (current-column)
 582 ;;                                     (/ (window-width) 2))
 583 ;;                                 ;; insert both on next line
 584 ;;                                 (next-line 1)
 585 ;;                               ;; insert one or both?
 586 ;;                               (= (* 2 (1+ (current-column)))
 587 ;;                                  (window-width))))
 588 ;;      ;; mirror these the other way round as well
 589 ;;      skeleton-pair-alist '((?) _ ?()
 590 ;;                            (?] _ ?[)
 591 ;;                            (?} _ ?{)
 592 ;;                            (?> _ ?<)
 593 ;;                            (?/ _ ?\\)
 594 ;;                            (?\\ _ ?/)
 595 ;;                            (?` ?` _ "''")
 596 ;;                            (?' ?' _ "``"))
 597 ;;      ;; in this mode we exceptionally ignore the user, else it's no fun
 598 ;;      skeleton-pair t)
 599 ;;  (let ((map (make-vector 256 'skeleton-pair-insert-maybe))
 600 ;;      (i 0))
 601 ;;    (use-local-map `(keymap ,map))
 602 ;;    (while (< i ? )
 603 ;;      (aset map i nil)
 604 ;;      (aset map (+ i 128) nil)
 605 ;;      (setq i (1+ i))))
 606 ;;  (run-hooks 'mirror-mode-hook))
 607
 608 (provide 'skeleton)
 609
 610 ;;; skeleton.el ends here