lisp/emacs-lisp/lisp.el

   1 ;;; lisp.el --- Lisp editing commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1994, 2000 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: lisp, languages
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Lisp editing commands to go with Lisp major mode.  More-or-less
  28 ;; applicable in other modes too.
  29
  30 ;;; Code:
  31
  32 ;; Note that this variable is used by non-lisp modes too.
  33 (defcustom defun-prompt-regexp nil
  34   "*If non-nil, a regexp to ignore before the character that starts a defun.
  35 This is only necessary if the opening paren or brace is not in column 0.
  36 See function `beginning-of-defun'.
  37
  38 Setting this variable automatically makes it local to the current buffer."
  39   :type '(choice (const nil)
  40                  regexp)
  41   :group 'lisp)
  42 (make-variable-buffer-local 'defun-prompt-regexp)
  43
  44 (defcustom parens-require-spaces t
  45   "Non-nil means `insert-parentheses' should insert whitespace as needed."
  46   :type 'boolean
  47   :group 'lisp)
  48
  49 (defvar forward-sexp-function nil
  50   "If non-nil, `forward-sexp' delegates to this function.
  51 Should take the same arguments and behave similarly to `forward-sexp'.")
  52
  53 (defun forward-sexp (&optional arg)
  54   "Move forward across one balanced expression (sexp).
  55 With ARG, do it that many times.  Negative arg -N means
  56 move backward across N balanced expressions."
  57   (interactive "p")
  58   (or arg (setq arg 1))
  59   (if forward-sexp-function
  60       (funcall forward-sexp-function arg)
  61     (goto-char (or (scan-sexps (point) arg) (buffer-end arg)))
  62     (if (< arg 0) (backward-prefix-chars))))
  63
  64 (defun backward-sexp (&optional arg)
  65   "Move backward across one balanced expression (sexp).
  66 With ARG, do it that many times.  Negative arg -N means
  67 move forward across N balanced expressions."
  68   (interactive "p")
  69   (or arg (setq arg 1))
  70   (forward-sexp (- arg)))
  71
  72 (defun mark-sexp (&optional arg)
  73   "Set mark ARG sexps from point.
  74 The place mark goes is the same place \\[forward-sexp] would
  75 move to with the same argument."
  76   (interactive "p")
  77   (push-mark
  78     (save-excursion
  79       (forward-sexp (or arg 1))
  80       (point))
  81     nil t))
  82
  83 (defun forward-list (&optional arg)
  84   "Move forward across one balanced group of parentheses.
  85 With ARG, do it that many times.
  86 Negative arg -N means move backward across N groups of parentheses."
  87   (interactive "p")
  88   (or arg (setq arg 1))
  89   (goto-char (or (scan-lists (point) arg 0) (buffer-end arg))))
  90
  91 (defun backward-list (&optional arg)
  92   "Move backward across one balanced group of parentheses.
  93 With ARG, do it that many times.
  94 Negative arg -N means move forward across N groups of parentheses."
  95   (interactive "p")
  96   (or arg (setq arg 1))
  97   (forward-list (- arg)))
  98
  99 (defun down-list (&optional arg)
 100   "Move forward down one level of parentheses.
 101 With ARG, do this that many times.
 102 A negative argument means move backward but still go down a level."
 103   (interactive "p")
 104   (or arg (setq arg 1))
 105   (let ((inc (if (> arg 0) 1 -1)))
 106     (while (/= arg 0)
 107       (goto-char (or (scan-lists (point) inc -1) (buffer-end arg)))
 108       (setq arg (- arg inc)))))
 109
 110 (defun backward-up-list (&optional arg)
 111   "Move backward out of one level of parentheses.
 112 With ARG, do this that many times.
 113 A negative argument means move forward but still to a less deep spot."
 114   (interactive "p")
 115   (up-list (- (or arg 1))))
 116
 117 (defun up-list (&optional arg)
 118   "Move forward out of one level of parentheses.
 119 With ARG, do this that many times.
 120 A negative argument means move backward but still to a less deep spot."
 121   (interactive "p")
 122   (or arg (setq arg 1))
 123   (let ((inc (if (> arg 0) 1 -1)))
 124     (while (/= arg 0)
 125       (goto-char (or (scan-lists (point) inc 1) (buffer-end arg)))
 126       (setq arg (- arg inc)))))
 127
 128 (defun kill-sexp (&optional arg)
 129   "Kill the sexp (balanced expression) following the cursor.
 130 With ARG, kill that many sexps after the cursor.
 131 Negative arg -N means kill N sexps before the cursor."
 132   (interactive "p")
 133   (let ((opoint (point)))
 134     (forward-sexp (or arg 1))
 135     (kill-region opoint (point))))
 136
 137 (defun backward-kill-sexp (&optional arg)
 138   "Kill the sexp (balanced expression) preceding the cursor.
 139 With ARG, kill that many sexps before the cursor.
 140 Negative arg -N means kill N sexps after the cursor."
 141   (interactive "p")
 142   (kill-sexp (- (or arg 1))))
 143 \f
 144 (defvar beginning-of-defun-function nil
 145   "If non-nil, function for `beginning-of-defun-raw' to call.
 146 This is used to find the beginning of the defun instead of using the
 147 normal recipe (see `beginning-of-defun').  Major modes can define this
 148 if defining `defun-prompt-regexp' is not sufficient to handle the mode's
 149 needs.
 150
 151 The function should go to the line on which the current defun starts,
 152 and return non-nil, or should return nil if it can't find the beginning.")
 153
 154 (defun beginning-of-defun (&optional arg)
 155   "Move backward to the beginning of a defun.
 156 With ARG, do it that many times.  Negative arg -N
 157 means move forward to Nth following beginning of defun.
 158 Returns t unless search stops due to beginning or end of buffer.
 159
 160 Normally a defun starts when there is an char with open-parenthesis
 161 syntax at the beginning of a line.  If `defun-prompt-regexp' is
 162 non-nil, then a string which matches that regexp may precede the
 163 open-parenthesis, and point ends up at the beginning of the line.
 164
 165 If variable `beginning-of-defun-function' is non-nil, its value
 166 is called as a function to find the defun's beginning."
 167   (interactive "p")
 168   (and (beginning-of-defun-raw arg)
 169        (progn (beginning-of-line) t)))
 170
 171 (defun beginning-of-defun-raw (&optional arg)
 172   "Move point to the character that starts a defun.
 173 This is identical to function `beginning-of-defun', except that point
 174 does not move to the beginning of the line when `defun-prompt-regexp'
 175 is non-nil.
 176
 177 If variable `beginning-of-defun-function' is non-nil, its value
 178 is called as a function to find the defun's beginning."
 179   (interactive "p")
 180   (if beginning-of-defun-function
 181       (funcall beginning-of-defun-function)
 182     (and arg (< arg 0) (not (eobp)) (forward-char 1))
 183     (and (re-search-backward (if defun-prompt-regexp
 184                                  (concat (if open-paren-in-column-0-is-defun-start
 185                                              "^\\s(\\|" "")
 186                                          "\\(" defun-prompt-regexp "\\)\\s(")
 187                                "^\\s(")
 188                              nil 'move (or arg 1))
 189          (progn (goto-char (1- (match-end 0)))) t)))
 190
 191 (defvar end-of-defun-function nil
 192   "If non-nil, function for function `end-of-defun' to call.
 193 This is used to find the end of the defun instead of using the normal
 194 recipe (see `end-of-defun').  Major modes can define this if the
 195 normal method is not appropriate.")
 196
 197 (defun buffer-end (arg)
 198   (if (> arg 0) (point-max) (point-min)))
 199
 200 (defun end-of-defun (&optional arg)
 201   "Move forward to next end of defun.  With argument, do it that many times.
 202 Negative argument -N means move back to Nth preceding end of defun.
 203
 204 An end of a defun occurs right after the close-parenthesis that
 205 matches the open-parenthesis that starts a defun; see function
 206 `beginning-of-defun'.
 207
 208 If variable `end-of-defun-function' is non-nil, its value
 209 is called as a function to find the defun's end."
 210   (interactive "p")
 211   (if end-of-defun-function
 212       (funcall end-of-defun-function)
 213     (if (or (null arg) (= arg 0)) (setq arg 1))
 214     (let ((first t))
 215       (while (and (> arg 0) (< (point) (point-max)))
 216         (let ((pos (point)) npos)
 217           (while (progn
 218                    (if (and first
 219                             (progn
 220                               (end-of-line 1)
 221                               (beginning-of-defun-raw 1)))
 222                        nil
 223                      (or (bobp) (forward-char -1))
 224                      (beginning-of-defun-raw -1))
 225                    (setq first nil)
 226                    (forward-list 1)
 227                    (skip-chars-forward " \t")
 228                    (if (looking-at "\\s<\\|\n")
 229                        (forward-line 1))
 230                    (<= (point) pos))))
 231         (setq arg (1- arg)))
 232       (while (< arg 0)
 233         (let ((pos (point)))
 234           (beginning-of-defun-raw 1)
 235           (forward-sexp 1)
 236           (forward-line 1)
 237           (if (>= (point) pos)
 238               (if (beginning-of-defun-raw 2)
 239                   (progn
 240                     (forward-list 1)
 241                     (skip-chars-forward " \t")
 242                     (if (looking-at "\\s<\\|\n")
 243                         (forward-line 1)))
 244                 (goto-char (point-min)))))
 245         (setq arg (1+ arg))))))
 246
 247 (defun mark-defun ()
 248   "Put mark at end of this defun, point at beginning.
 249 The defun marked is the one that contains point or follows point."
 250   (interactive)
 251   (push-mark (point))
 252   (end-of-defun)
 253   (push-mark (point) nil t)
 254   (beginning-of-defun)
 255   (re-search-backward "^\n" (- (point) 1) t))
 256
 257 (defun narrow-to-defun (&optional arg)
 258   "Make text outside current defun invisible.
 259 The defun visible is the one that contains point or follows point.
 260 Optional ARG is ignored."
 261   (interactive)
 262   (save-excursion
 263     (widen)
 264     (end-of-defun)
 265     (let ((end (point)))
 266       (beginning-of-defun)
 267       (narrow-to-region (point) end))))
 268
 269 (defun insert-parentheses (arg)
 270   "Enclose following ARG sexps in parentheses.  Leave point after open-paren.
 271 A negative ARG encloses the preceding ARG sexps instead.
 272 No argument is equivalent to zero: just insert `()' and leave point between.
 273 If `parens-require-spaces' is non-nil, this command also inserts a space
 274 before and after, depending on the surrounding characters."
 275   (interactive "P")
 276   (if arg (setq arg (prefix-numeric-value arg))
 277     (setq arg 0))
 278   (cond ((> arg 0) (skip-chars-forward " \t"))
 279         ((< arg 0) (forward-sexp arg) (setq arg (- arg))))
 280   (and parens-require-spaces
 281        (not (bobp))
 282        (memq (char-syntax (preceding-char)) '(?w ?_ ?\) ))
 283        (insert " "))
 284   (insert ?\()
 285   (save-excursion
 286     (or (eq arg 0) (forward-sexp arg))
 287     (insert ?\))
 288     (and parens-require-spaces
 289          (not (eobp))
 290          (memq (char-syntax (following-char)) '(?w ?_ ?\( ))
 291          (insert " "))))
 292
 293 (defun move-past-close-and-reindent ()
 294   "Move past next `)', delete indentation before it, then indent after it."
 295   (interactive)
 296   (up-list 1)
 297   (forward-char -1)
 298   (while (save-excursion                ; this is my contribution
 299            (let ((before-paren (point)))
 300              (back-to-indentation)
 301              (and (= (point) before-paren)
 302                   (progn
 303                     ;; Move to end of previous line.
 304                     (beginning-of-line)
 305                     (forward-char -1)
 306                     ;; Verify it doesn't end within a string or comment.
 307                     (let ((end (point))
 308                           state)
 309                       (beginning-of-line)
 310                       ;; Get state at start of line.
 311                       (setq state  (list 0 nil nil
 312                                          (null (calculate-lisp-indent))
 313                                          nil nil nil nil
 314                                          nil))
 315                       ;; Parse state across the line to get state at end.
 316                       (setq state (parse-partial-sexp (point) end nil nil
 317                                                       state))
 318                       ;; Check not in string or comment.
 319                       (and (not (elt state 3)) (not (elt state 4))))))))
 320     (delete-indentation))
 321   (forward-char 1)
 322   (newline-and-indent))
 323
 324 (defun check-parens ()                  ; lame name?
 325   "Check for unbalanced parentheses in the current buffer.
 326 More accurately, check the narrowed part of the buffer for unbalanced
 327 expressions (\"sexps\") in general.  This is done according to the
 328 current syntax table and will find unbalanced brackets or quotes as
 329 appropriate.  (See Info node `(emacs)Lists and Sexps'.)  If imbalance
 330 is found, an error is signalled and point is left at the first
 331 unbalanced character."
 332   (interactive)
 333   (condition-case data
 334       ;; Buffer can't have more than (point-max) sexps.
 335       (scan-sexps (point-min) (point-max))
 336     (scan-error (goto-char (nth 2 data))
 337                 ;; Could print (nth 1 data), which is either
 338                 ;; "Containing expression ends prematurely" or
 339                 ;; "Unbalanced parentheses", but those may not be so
 340                 ;; accurate/helpful, e.g. quotes may actually be
 341                 ;; mismatched.
 342                 (error "Unmatched bracket or quote"))
 343     (error (cond ((eq 'scan-error (car data))
 344                   (goto-char (nth 2 data))
 345                   (error "Unmatched bracket or quote"))
 346                  (t (signal (car data) (cdr data)))))))
 347 \f
 348 (defun lisp-complete-symbol (&optional predicate)
 349   "Perform completion on Lisp symbol preceding point.
 350 Compare that symbol against the known Lisp symbols.
 351
 352 When called from a program, optional arg PREDICATE is a predicate
 353 determining which symbols are considered, e.g. `commandp'.
 354 If PREDICATE is nil, the context determines which symbols are
 355 considered.  If the symbol starts just after an open-parenthesis, only
 356 symbols with function definitions are considered.  Otherwise, all
 357 symbols with function definitions, values or properties are
 358 considered."
 359   (interactive)
 360   (let* ((end (point))
 361          (beg (with-syntax-table emacs-lisp-mode-syntax-table
 362                 (save-excursion
 363                   (backward-sexp 1)
 364                   (while (= (char-syntax (following-char)) ?\')
 365                     (forward-char 1))
 366                   (point))))
 367          (pattern (buffer-substring-no-properties beg end))
 368          (predicate
 369           (or predicate
 370               (save-excursion
 371                 (goto-char beg)
 372                 (if (not (eq (char-before) ?\())
 373                     (lambda (sym)       ;why not just nil ?   -sm
 374                       (or (boundp sym) (fboundp sym)
 375                           (symbol-plist sym)))
 376                   ;; Looks like a funcall position.  Let's double check.
 377                   (if (condition-case nil
 378                           (progn (up-list -2) (forward-char 1)
 379                                  (eq (char-after) ?\())
 380                         (error nil))
 381                       ;; If the first element of the parent list is an open
 382                       ;; parenthesis we are probably not in a funcall position.
 383                       ;; Maybe a `let' varlist or something.
 384                       nil
 385                     ;; Else, we assume that a function name is expected.
 386                     'fboundp)))))
 387          (completion (try-completion pattern obarray predicate)))
 388     (cond ((eq completion t))
 389           ((null completion)
 390            (message "Can't find completion for \"%s\"" pattern)
 391            (ding))
 392           ((not (string= pattern completion))
 393            (delete-region beg end)
 394            (insert completion))
 395           (t
 396            (message "Making completion list...")
 397            (let ((list (all-completions pattern obarray predicate)))
 398              (setq list (sort list 'string<))
 399              (or (eq predicate 'fboundp)
 400                  (let (new)
 401                    (while list
 402                      (setq new (cons (if (fboundp (intern (car list)))
 403                                          (list (car list) " <f>")
 404                                        (car list))
 405                                      new))
 406                      (setq list (cdr list)))
 407                    (setq list (nreverse new))))
 408              (with-output-to-temp-buffer "*Completions*"
 409                (display-completion-list list)))
 410            (message "Making completion list...%s" "done")))))
 411
 412 ;;; lisp.el ends here