lisp/emacs-lisp/backquote.el

   1 ;;; backquote.el --- implement the ` Lisp construct
   2
   3 ;;; Copyright (C) 1990, 1992, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Rick Sladkey <jrs@world.std.com>
   6 ;; Maintainer: FSF
   7 ;; Keywords: extensions, internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This backquote will generate calls to the backquote-list* form.
  29 ;; Both a function version and a macro version are included.
  30 ;; The macro version is used by default because it is faster
  31 ;; and needs no run-time support.  It should really be a subr.
  32
  33 ;;; Code:
  34
  35 (provide 'backquote)
  36
  37 ;; function and macro versions of backquote-list*
  38
  39 (defun backquote-list*-function (first &rest list)
  40   "Like `list' but the last argument is the tail of the new list.
  41
  42 For example (backquote-list* 'a 'b 'c) => (a b . c)"
  43   (if list
  44       (let* ((rest list) (newlist (cons first nil)) (last newlist))
  45         (while (cdr rest)
  46           (setcdr last (cons (car rest) nil))
  47           (setq last (cdr last)
  48                 rest (cdr rest)))
  49         (setcdr last (car rest))
  50         newlist)
  51     first))
  52
  53 (defmacro backquote-list*-macro (first &rest list)
  54   "Like `list' but the last argument is the tail of the new list.
  55
  56 For example (backquote-list* 'a 'b 'c) => (a b . c)"
  57   (setq list (reverse (cons first list))
  58         first (car list)
  59         list (cdr list))
  60   (if list
  61       (let* ((second (car list))
  62              (rest (cdr list))
  63              (newlist (list 'cons second first)))
  64         (while rest
  65           (setq newlist (list 'cons (car rest) newlist)
  66                 rest (cdr rest)))
  67         newlist)
  68     first))
  69
  70 (defalias 'backquote-list* (symbol-function 'backquote-list*-macro))
  71
  72 ;; A few advertised variables that control which symbols are used
  73 ;; to represent the backquote, unquote, and splice operations.
  74 (defconst backquote-backquote-symbol '\`
  75   "*Symbol used to represent a backquote or nested backquote.")
  76
  77 (defconst backquote-unquote-symbol ',
  78   "*Symbol used to represent an unquote inside a backquote.")
  79
  80 (defconst backquote-splice-symbol ',@
  81   "*Symbol used to represent a splice inside a backquote.")
  82
  83 ;;;###autoload
  84 (defmacro backquote (arg)
  85   "Argument STRUCTURE describes a template to build.
  86
  87 The whole structure acts as if it were quoted except for certain
  88 places where expressions are evaluated and inserted or spliced in.
  89
  90 For example:
  91
  92 b              => (ba bb bc)            ; assume b has this value
  93 `(a b c)       => (a b c)               ; backquote acts like quote
  94 `(a ,b c)      => (a (ba bb bc) c)      ; insert the value of b
  95 `(a ,@b c)     => (a ba bb bc c)        ; splice in the value of b
  96
  97 Vectors work just like lists.  Nested backquotes are permitted."
  98   (cdr (backquote-process arg)))
  99
 100 ;; GNU Emacs has no reader macros
 101
 102 ;;;###autoload
 103 (defalias '\` (symbol-function 'backquote))
 104
 105 ;; backquote-process returns a dotted-pair of a tag (0, 1, or 2) and
 106 ;; the backquote-processed structure.  0 => the structure is
 107 ;; constant, 1 => to be unquoted, 2 => to be spliced in.
 108 ;; The top-level backquote macro just discards the tag.
 109
 110 (defun backquote-process (s)
 111   (cond
 112    ((vectorp s)
 113     (let ((n (backquote-process (append s ()))))
 114       (if (= (car n) 0)
 115           (cons 0 s)
 116         (cons 1 (cond
 117                  ((not (listp (cdr n)))
 118                   (list 'vconcat (cdr n)))
 119                  ((eq (nth 1 n) 'list)
 120                   (cons 'vector (nthcdr 2 n)))
 121                  ((eq (nth 1 n) 'append)
 122                   (cons 'vconcat (nthcdr 2 n)))
 123                  (t
 124                   (list 'apply '(function vector) (cdr n))))))))
 125    ((atom s)
 126     (cons 0 (if (or (null s) (eq s t) (not (symbolp s)))
 127                 s
 128               (list 'quote s))))
 129    ((eq (car s) backquote-unquote-symbol)
 130     (cons 1 (nth 1 s)))
 131    ((eq (car s) backquote-splice-symbol)
 132     (cons 2 (nth 1 s)))
 133    ((eq (car s) backquote-backquote-symbol)
 134     (backquote-process (cdr (backquote-process (nth 1 s)))))
 135    (t
 136     (let ((rest s)
 137           item firstlist list lists expression)
 138       ;; Scan this list-level, setting LISTS to a list of forms,
 139       ;; each of which produces a list of elements
 140       ;; that should go in this level.
 141       ;; The order of LISTS is backwards.
 142       ;; If there are non-splicing elements (constant or variable)
 143       ;; at the beginning, put them in FIRSTLIST,
 144       ;; as a list of tagged values (TAG . FORM).
 145       ;; If there are any at the end, they go in LIST, likewise.
 146       (while (consp rest)
 147         ;; Turn . (, foo) into (,@ foo).
 148         (if (eq (car rest) backquote-unquote-symbol)
 149             (setq rest (list (list backquote-splice-symbol (nth 1 rest)))))
 150         (setq item (backquote-process (car rest)))
 151         (cond
 152          ((= (car item) 2)
 153           ;; Put the nonspliced items before the first spliced item
 154           ;; into FIRSTLIST.
 155           (if (null lists)
 156               (setq firstlist list
 157                     list nil))
 158           ;; Otherwise, put any preceding nonspliced items into LISTS.
 159           (if list
 160               (setq lists (cons (backquote-listify list '(0 . nil)) lists)))
 161           (setq lists (cons (cdr item) lists))
 162           (setq list nil))
 163          (t
 164           (setq list (cons item list))))
 165         (setq rest (cdr rest)))
 166       ;; Handle nonsplicing final elements, and the tail of the list
 167       ;; (which remains in REST).
 168       (if (or rest list)
 169           (setq lists (cons (backquote-listify list (backquote-process rest))
 170                             lists)))
 171       ;; Turn LISTS into a form that produces the combined list.
 172       (setq expression
 173             (if (or (cdr lists)
 174                     (eq (car-safe (car lists)) backquote-splice-symbol))
 175                 (cons 'append (nreverse lists))
 176               (car lists)))
 177       ;; Tack on any initial elements.
 178       (if firstlist
 179           (setq expression (backquote-listify firstlist (cons 1 expression))))
 180       (if (eq (car-safe expression) 'quote)
 181           (cons 0 (list 'quote s))
 182         (cons 1 expression))))))
 183
 184 ;; backquote-listify takes (tag . structure) pairs from backquote-process
 185 ;; and decides between append, list, backquote-list*, and cons depending
 186 ;; on which tags are in the list.
 187
 188 (defun backquote-listify (list old-tail)
 189   (let ((heads nil) (tail (cdr old-tail)) (list-tail list) (item nil))
 190     (if (= (car old-tail) 0)
 191         (setq tail (eval tail)
 192               old-tail nil))
 193     (while (consp list-tail)
 194       (setq item (car list-tail))
 195       (setq list-tail (cdr list-tail))
 196       (if (or heads old-tail (/= (car item) 0))
 197           (setq heads (cons (cdr item) heads))
 198         (setq tail (cons (eval (cdr item)) tail))))
 199     (cond
 200      (tail
 201       (if (null old-tail)
 202           (setq tail (list 'quote tail)))
 203       (if heads
 204           (let ((use-list* (or (cdr heads)
 205                                (and (consp (car heads))
 206                                     (eq (car (car heads))
 207                                         backquote-splice-symbol)))))
 208             (cons (if use-list* 'backquote-list* 'cons)
 209                   (append heads (list tail))))
 210         tail))
 211      (t (cons 'list heads)))))
 212
 213 ;;; backquote.el ends here