configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 standardlisppath='${lispdir}:${leimdir}'
  42 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  43 '${datadir}/emacs/site-lisp'
  44 lisppath='${locallisppath}:${standardlisppath}'
  45 etcdir='${datadir}/emacs/${version}/etc'
  46 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  47 docdir='${datadir}/emacs/${version}/etc'
  48 gamedir='${localstatedir}/games/emacs'
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 151 if test "$with_wide_int" = yes; then
 152   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 153 fi
 154
 155 dnl _ON results in a '--without' option in the --help output, so
 156 dnl the help text should refer to "don't compile", etc.
 157 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 158 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 159 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 160 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 161 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 162 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 163 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 164 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 165
 166 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 167 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 168 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 169
 170 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 171 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 172 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 173 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 174
 175 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 176 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 177 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 178 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 179 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 180 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 181
 182 ## For the times when you want to build Emacs but don't have
 183 ## a suitable makeinfo, and can live without the manuals.
 184 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 185 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 186
 187 ## Makefile.in needs the cache file name.
 188 AC_SUBST(cache_file)
 189
 190 ## This is an option because I do not know if all info/man support
 191 ## compressed files, nor how to test if they do so.
 192 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 193 if test $with_compress_info = yes; then
 194    GZIP_INFO=yes
 195 else
 196    GZIP_INFO=
 197 fi
 198 AC_SUBST(GZIP_INFO)
 199
 200 AC_ARG_WITH([pkg-config-prog],dnl
 201 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 202                   [path to pkg-config for finding GTK and librsvg])])
 203 if test "X${with_pkg_config_prog}" != X; then
 204    if test "${with_pkg_config_prog}" != yes; then
 205       PKG_CONFIG="${with_pkg_config_prog}"
 206    fi
 207 fi
 208
 209 CRT_DIR=
 210 AC_ARG_WITH([crt-dir],dnl
 211 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 212 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 213 CRT_DIR="${with_crt_dir}"
 214
 215 AC_ARG_WITH(gameuser,dnl
 216 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 217 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 218   && gameuser="${with_gameuser}"
 219 test "X$gameuser" = X && gameuser=games
 220
 221 AC_ARG_WITH([gnustep-conf],dnl
 222 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 223 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 224   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 225 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 226      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 227
 228 AC_ARG_ENABLE(ns-self-contained,
 229 [AS_HELP_STRING([--disable-ns-self-contained],
 230                 [disable self contained build under NeXTstep])],
 231    EN_NS_SELF_CONTAINED=$enableval,
 232    EN_NS_SELF_CONTAINED=yes)
 233
 234 AC_ARG_ENABLE(locallisppath,
 235 [AS_HELP_STRING([--enable-locallisppath=PATH],
 236                 [directories Emacs should search for lisp files specific
 237                  to this site])],
 238 if test "${enableval}" = "no"; then
 239   locallisppath=
 240 elif test "${enableval}" != "yes"; then
 241   locallisppath=${enableval}
 242 fi)
 243
 244 AC_ARG_ENABLE(checking,
 245 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 246                 [enable expensive run-time checks.  With LIST,
 247                  enable only specific categories of checks.
 248                  Categories are: all,yes,no.
 249                  Flags are: stringbytes, stringoverrun, stringfreelist,
 250                  xmallocoverrun, conslist, glyphs])],
 251 [ac_checking_flags="${enableval}"],[])
 252 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 253 for check in $ac_checking_flags
 254 do
 255         case $check in
 256         # these set all the flags to specific states
 257         yes)            ac_enable_checking=1 ;;
 258         no)             ac_enable_checking= ;
 259                         ac_gc_check_stringbytes= ;
 260                         ac_gc_check_string_overrun= ;
 261                         ac_gc_check_string_free_list= ;
 262                         ac_xmalloc_overrun= ;
 263                         ac_gc_check_cons_list= ;
 264                         ac_glyphs_debug= ;;
 265         all)            ac_enable_checking=1 ;
 266                         ac_gc_check_stringbytes=1 ;
 267                         ac_gc_check_string_overrun=1 ;
 268                         ac_gc_check_string_free_list=1 ;
 269                         ac_xmalloc_overrun=1 ;
 270                         ac_gc_check_cons_list=1 ;
 271                         ac_glyphs_debug=1 ;;
 272         # these enable particular checks
 273         stringbytes)    ac_gc_check_stringbytes=1 ;;
 274         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 275         stringfreelist) ac_gc_check_string_free_list=1 ;;
 276         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 277         conslist)       ac_gc_check_cons_list=1 ;;
 278         glyphs)         ac_glyphs_debug=1 ;;
 279         *)      AC_MSG_ERROR(unknown check category $check) ;;
 280         esac
 281 done
 282 IFS="$ac_save_IFS"
 283
 284 if test x$ac_enable_checking != x ; then
 285   AC_DEFINE(ENABLE_CHECKING, 1,
 286 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 287 fi
 288 if test x$ac_gc_check_stringbytes != x ; then
 289   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 290 [Define this temporarily to hunt a bug.  If defined, the size of
 291    strings is redundantly recorded in sdata structures so that it can
 292    be compared to the sizes recorded in Lisp strings.])
 293 fi
 294 if test x$ac_gc_check_string_overrun != x ; then
 295   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 296 [Define this to check for short string overrun.])
 297 fi
 298 if test x$ac_gc_check_string_free_list != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 300 [Define this to check the string free list.])
 301 fi
 302 if test x$ac_xmalloc_overrun != x ; then
 303   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 304 [Define this to check for malloc buffer overrun.])
 305 fi
 306 if test x$ac_gc_check_cons_list != x ; then
 307   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 308 [Define this to check for errors in cons list.])
 309 fi
 310 if test x$ac_glyphs_debug != x ; then
 311   AC_DEFINE(GLYPH_DEBUG, 1,
 312 [Define this to enable glyphs debugging code.])
 313 fi
 314
 315 AC_ARG_ENABLE(check-lisp-object-type,
 316 [AS_HELP_STRING([--enable-check-lisp-object-type],
 317                 [enable compile time checks for the Lisp_Object data type.
 318                 This is useful for development for catching certain types of bugs.])],
 319 if test "${enableval}" != "no"; then
 320    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 321    [Define this to enable compile time checks for the Lisp_Object data type.])
 322 fi)
 323
 324
 325 AC_ARG_ENABLE(profiling,
 326 [AS_HELP_STRING([--enable-profiling],
 327                 [build emacs with profiling support.
 328                  This might not work on all platforms])],
 329 [ac_enable_profiling="${enableval}"],[])
 330 if test x$ac_enable_profiling != x ; then
 331    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 332 else
 333    PROFILING_CFLAGS=
 334 fi
 335 AC_SUBST(PROFILING_CFLAGS)
 336
 337 AC_ARG_ENABLE(autodepend,
 338 [AS_HELP_STRING([--enable-autodepend],
 339                 [automatically generate dependencies to .h-files.
 340                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 341                  found])],
 342 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 343
 344 #### Make srcdir absolute, if it isn't already.  It's important to
 345 #### avoid running the path through pwd unnecessarily, since pwd can
 346 #### give you automounter prefixes, which can go away.  We do all this
 347 #### so Emacs can find its files when run uninstalled.
 348 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 349 unset CDPATH
 350 case "${srcdir}" in
 351   /* ) ;;
 352   . )
 353     ## We may be able to use the $PWD environment variable to make this
 354     ## absolute.  But sometimes PWD is inaccurate.
 355     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 356     ## but that tested only for a well-formed and valid PWD,
 357     ## it did not object when PWD was well-formed and valid but just wrong.
 358     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 359     then
 360       srcdir="$PWD"
 361     else
 362       srcdir="`(cd ${srcdir}; pwd)`"
 363     fi
 364   ;;
 365   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 366 esac
 367
 368 #### Given the configuration name, set opsysfile to the
 369 #### name of s/*.h file we should use.
 370
 371 ### Canonicalize the configuration name.
 372
 373 AC_CANONICAL_HOST
 374 canonical=$host
 375 configuration=${host_alias-${build_alias-$host}}
 376
 377 dnl This used to use changequote, but, apart from `changequote is evil'
 378 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 379 dnl the great gob of text.  Thus it's not processed for possible expansion.
 380 dnl Just make sure the brackets remain balanced.
 381 dnl
 382 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 383 dnl indicated by comments.
 384 dnl quotation begins
 385 [
 386
 387 ### If you add support for a new configuration, add code to this
 388 ### switch statement to recognize your configuration name and select
 389 ### the appropriate operating system file.
 390
 391 ### You would hope that you could choose an s/*.h
 392 ### file based on the operating system portion.  However, it turns out
 393 ### that each s/*.h file is pretty manufacturer-specific.
 394 ### So we basically have to have a special case for each
 395 ### configuration name.
 396 ###
 397 ### As far as handling version numbers on operating systems is
 398 ### concerned, make sure things will fail in a fixable way.  If
 399 ### /etc/MACHINES doesn't say anything about version numbers, be
 400 ### prepared to handle anything reasonably.  If version numbers
 401 ### matter, be sure /etc/MACHINES says something about it.
 402
 403 opsys='' unported=no
 404 case "${canonical}" in
 405
 406   ## GNU/Linux and similar ports
 407   *-*-linux* )
 408     opsys=gnu-linux
 409   ;;
 410
 411   ## FreeBSD ports
 412   *-*-freebsd* )
 413     opsys=freebsd
 414   ;;
 415
 416   ## FreeBSD kernel + glibc based userland
 417   *-*-kfreebsd*gnu* )
 418     opsys=gnu-kfreebsd
 419   ;;
 420
 421   ## NetBSD ports
 422   *-*-netbsd* )
 423     opsys=netbsd
 424   ;;
 425
 426   ## OpenBSD ports
 427   *-*-openbsd* )
 428     opsys=openbsd
 429   ;;
 430
 431   ## Apple Darwin / Mac OS X
 432   *-apple-darwin* )
 433     case "${canonical}" in
 434       i[3456]86-* )  ;;
 435       powerpc-* )    ;;
 436       x86_64-* )     ;;
 437       * )            unported=yes ;;
 438     esac
 439     opsys=darwin
 440     ## Use fink packages if available.
 441     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 442 ##    if test -d /sw/include && test -d /sw/lib; then
 443 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 444 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 445 ##    fi
 446   ;;
 447
 448   ## HP 9000 series 700 and 800, running HP/UX
 449   hppa*-hp-hpux10.2* )
 450     opsys=hpux10-20
 451   ;;
 452   hppa*-hp-hpux1[1-9]* )
 453     opsys=hpux11
 454     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 455   ;;
 456
 457   ## IBM machines
 458   rs6000-ibm-aix4.[23]* )
 459     opsys=aix4-2
 460   ;;
 461   powerpc-ibm-aix4.[23]*  )
 462     opsys=aix4-2
 463   ;;
 464   rs6000-ibm-aix[56]* )
 465     opsys=aix4-2
 466   ;;
 467   powerpc-ibm-aix[56]*  )
 468     opsys=aix4-2
 469   ;;
 470
 471   ## Silicon Graphics machines
 472   ## Iris 4D
 473   mips-sgi-irix6.5 )
 474     opsys=irix6-5
 475     # Without defining _LANGUAGE_C, things get masked out in the headers
 476     # so that, for instance, grepping for `free' in stdlib.h fails and
 477     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 478     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 479   ;;
 480
 481   ## Suns
 482   *-sun-solaris* \
 483     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 484     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 485     case "${canonical}" in
 486       i[3456]86-*-* )   ;;
 487       amd64-*-*|x86_64-*-*) ;;
 488       sparc* )          ;;
 489       * )               unported=yes ;;
 490     esac
 491     case "${canonical}" in
 492       *-sunos5.6* | *-solaris2.6* )
 493                 opsys=sol2-6
 494                 RANLIB="ar -ts"
 495                 ;;
 496       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 497                 opsys=sol2-6
 498                 emacs_check_sunpro_c=yes
 499                 ;;
 500       *-sunos5* | *-solaris* )
 501                 opsys=sol2-10
 502                 emacs_check_sunpro_c=yes
 503                 ;;
 504     esac
 505     ## Watch out for a compiler that we know will not work.
 506     case "${canonical}" in
 507      *-solaris* | *-sunos5* )
 508                 if [ "x$CC" = x/usr/ucb/cc ]; then
 509                   ## /usr/ucb/cc doesn't work;
 510                   ## we should find some other compiler that does work.
 511                   unset CC
 512                 fi
 513                 ;;
 514       *) ;;
 515     esac
 516   ;;
 517
 518   ## Intel 386 machines where we don't care about the manufacturer.
 519   i[3456]86-*-* )
 520     case "${canonical}" in
 521       *-cygwin )                opsys=cygwin ;;
 522       *-darwin* )               opsys=darwin ;;
 523       *-sysv4.2uw* )            opsys=unixware ;;
 524       *-sysv5uw* )              opsys=unixware ;;
 525       *-sysv5OpenUNIX* )        opsys=unixware ;;
 526       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 527     esac
 528   ;;
 529
 530   * )
 531     unported=yes
 532   ;;
 533 esac
 534
 535 ### If the code above didn't choose an operating system, just choose
 536 ### an operating system based on the configuration name.  You really
 537 ### only want to use this when you have no idea what the right
 538 ### operating system is; if you know what operating systems a machine
 539 ### runs, it's cleaner to make it explicit in the case statement
 540 ### above.
 541 if test x"${opsys}" = x; then
 542   case "${canonical}" in
 543     *-gnu* )                            opsys=gnu ;;
 544     * )
 545       unported=yes
 546     ;;
 547   esac
 548 fi
 549
 550 ]
 551 dnl quotation ends
 552
 553 if test $unported = yes; then
 554   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 555 Check `etc/MACHINES' for recognized configuration names.])
 556 fi
 557
 558 opsysfile="s/${opsys}.h"
 559
 560
 561 #### Choose a compiler.
 562
 563 dnl Sets GCC=yes if using gcc.
 564 AC_PROG_CC
 565 AM_PROG_CC_C_O
 566
 567 if test x$GCC = xyes; then
 568   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 569 else
 570   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 571 fi
 572
 573 # Initialize gnulib right after choosing the compiler.
 574 gl_EARLY
 575
 576 AC_ARG_ENABLE([gcc-warnings],
 577   [AS_HELP_STRING([--enable-gcc-warnings],
 578                   [turn on lots of GCC warnings. This is intended for
 579                    developers, and may generate false alarms when used
 580                    with older or non-GNU development tools.])],
 581   [case $enableval in
 582      yes|no) ;;
 583      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 584    esac
 585    gl_gcc_warnings=$enableval],
 586   [gl_gcc_warnings=no]
 587 )
 588
 589 AC_ARG_ENABLE(link-time-optimization,
 590 [AS_HELP_STRING([--enable-link-time-optimization],
 591                 [build emacs with link-time optimization.
 592                  This is supported only for GCC since 4.5.0.])],
 593 if test "${enableval}" != "no"; then
 594    AC_MSG_CHECKING([whether link-time optimization is supported])
 595    ac_lto_supported=no
 596    if test x$GCC = xyes; then
 597       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 598       if test x$CPUS != x; then
 599          LTO="-flto=$CPUS"
 600       else
 601          LTO="-flto"
 602       fi
 603       old_CFLAGS=$CFLAGS
 604       CFLAGS="$CFLAGS $LTO"
 605       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 606         [ac_lto_supported=yes], [ac_lto_supported=no])
 607       CFLAGS="$old_CFLAGS"
 608    fi
 609    AC_MSG_RESULT([$ac_lto_supported])
 610    if test "$ac_lto_supported" = "yes"; then
 611       CFLAGS="$CFLAGS $LTO"
 612    fi
 613 fi)
 614
 615 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 616 # ------------------------------------------------
 617 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 618 # Otherwise, run RUN-IF-NOT-FOUND.
 619 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 620   [AC_PREPROC_IFELSE(
 621     [AC_LANG_PROGRAM(
 622       [[
 623 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 624 /* ok */
 625 #else
 626 # error "your version of gcc is older than $1.$2"
 627 #endif
 628       ]]),
 629     ], [$3], [$4])
 630   ]
 631 )
 632
 633 # When compiling with GCC, prefer -isystem to -I when including system
 634 # include files, to avoid generating useless diagnostics for the files.
 635 if test "$gl_gcc_warnings" != yes; then
 636   isystem='-I'
 637 else
 638   isystem='-isystem '
 639
 640   # This, $nw, is the list of warnings we disable.
 641   nw=
 642
 643   case $with_x_toolkit in
 644     lucid | athena | motif)
 645        # Old toolkits mishandle 'const'.
 646        nw="$nw -Wwrite-strings"
 647        ;;
 648     *)
 649        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 650        ;;
 651   esac
 652   AC_SUBST([WERROR_CFLAGS])
 653
 654   nw="$nw -Waggregate-return"       # anachronistic
 655   nw="$nw -Wlong-long"              # C90 is anachronistic
 656   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 657   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 658   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 659   nw="$nw -Wcast-qual"              # Too many warnings for now
 660   nw="$nw -Wconversion"             # Too many warnings for now
 661   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 662   nw="$nw -Wsign-conversion"        # Too many warnings for now
 663   nw="$nw -Woverlength-strings"     # Not a problem these days
 664   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 665   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 666   nw="$nw -Wpadded"                 # Our structs are not padded
 667   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 668   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 669   nw="$nw -Wformat-nonliteral"      # we do this a lot
 670   nw="$nw -Wvla"                    # warnings in gettext.h
 671   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 672   nw="$nw -Wswitch-enum"            # Too many warnings for now
 673   nw="$nw -Wswitch-default"         # Too many warnings for now
 674   nw="$nw -Wfloat-equal"            # warns about high-quality code
 675   nw="$nw -Winline"                 # OK to ignore 'inline'
 676   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 677   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 678
 679   # Emacs doesn't care about shadowing; see
 680   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 681   nw="$nw -Wshadow"
 682
 683   # The following lines should be removable at some point.
 684   nw="$nw -Wstack-protector"
 685   nw="$nw -Wstrict-overflow"
 686   nw="$nw -Wsuggest-attribute=pure"
 687
 688   gl_MANYWARN_ALL_GCC([ws])
 689   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 690   for w in $ws; do
 691     gl_WARN_ADD([$w])
 692   done
 693   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 694   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 695   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 696   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 697   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 698   gl_WARN_ADD([-Wno-format-nonliteral])
 699
 700   # In spite of excluding -Wlogical-op above, it is enabled, as of
 701   # gcc 4.5.0 20090517.
 702   gl_WARN_ADD([-Wno-logical-op])
 703
 704   gl_WARN_ADD([-fdiagnostics-show-option])
 705   gl_WARN_ADD([-funit-at-a-time])
 706
 707   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 708   AC_DEFINE([_FORTIFY_SOURCE], [2],
 709     [enable compile-time and run-time bounds-checking, and some warnings])
 710   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 711
 712   # We use a slightly smaller set of warning options for lib/.
 713   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 714   nw=
 715   nw="$nw -Wunused-macros"
 716
 717   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 718   AC_SUBST([GNULIB_WARN_CFLAGS])
 719 fi
 720
 721
 722
 723 dnl Some other nice autoconf tests.
 724 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 725 dnl AC_PROG_INSTALL
 726 dnl AC_PROG_MKDIR_P
 727 dnl if test "x$RANLIB" = x; then
 728 dnl   AC_PROG_RANLIB
 729 dnl fi
 730
 731 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 732   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 733 dnl Don't use GZIP, which is used by gzip for additional parameters.
 734 AC_PATH_PROG(GZIP_PROG, gzip)
 735
 736 if test $opsys = gnu-linux; then
 737   AC_PATH_PROG(PAXCTL, paxctl,,
 738     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 739 fi
 740
 741 ## Need makeinfo >= 4.7 (?) to build the manuals.
 742 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 743 dnl By this stage, configure has already checked for egrep and set EGREP,
 744 dnl or exited with an error if no egrep was found.
 745 if test "$MAKEINFO" != "no" && \
 746   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 747    MAKEINFO=no
 748 fi
 749
 750 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 751 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 752 ## therefore in the category of "special tools" not normally required, which
 753 ## configure does not have to check for (eg autoconf itself).
 754 ## In a Bazaar checkout on the other hand, the manuals are not included.
 755 ## So makeinfo is a requirement to build from Bazaar, and configure
 756 ## should test for it as it does for any other build requirement.
 757 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 758 ## with pre-built manuals, from a Bazaar checkout.
 759 HAVE_MAKEINFO=yes
 760
 761 if test "$MAKEINFO" = "no"; then
 762   MAKEINFO=makeinfo
 763   if test "x${with_makeinfo}" = "xno"; then
 764     HAVE_MAKEINFO=no
 765   elif test ! -e $srcdir/info/emacs; then
 766     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 767 source tree does not seem to have pre-built manuals in the `info' directory.
 768 Either install a suitable version of makeinfo, or re-run configure
 769 with the `--without-makeinfo' option to build without the manuals.] )
 770   fi
 771 fi
 772 AC_SUBST(HAVE_MAKEINFO)
 773
 774 dnl Just so that there is only a single place we need to edit.
 775 INFO_EXT=.info
 776 INFO_OPTS=--no-split
 777 AC_SUBST(INFO_EXT)
 778 AC_SUBST(INFO_OPTS)
 779
 780 dnl Add our options to ac_link now, after it is set up.
 781
 782 if test x$GCC = xyes; then
 783   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 784     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 785 else
 786   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 787     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 788 fi
 789
 790 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 791 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 792 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 793 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 794 dnl if not built to support GNU ld.
 795
 796 late_LDFLAGS=$LDFLAGS
 797 if test x$GCC = xyes; then
 798   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 799 else
 800   LDFLAGS="$LDFLAGS -znocombreloc"
 801 fi
 802
 803 AC_MSG_CHECKING([for -znocombreloc])
 804 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 805   [AC_MSG_RESULT(yes)],
 806   LDFLAGS=$late_LDFLAGS
 807   [AC_MSG_RESULT(no)])
 808
 809
 810 dnl The function dump-emacs will not be defined and temacs will do
 811 dnl (load "loadup") automatically unless told otherwise.
 812 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 813 case "$opsys" in
 814   your-opsys-here) CANNOT_DUMP=yes ;;
 815 esac
 816
 817 test "$CANNOT_DUMP" = "yes" && \
 818   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 819
 820 AC_SUBST(CANNOT_DUMP)
 821
 822
 823 UNEXEC_OBJ=unexelf.o
 824 case "$opsys" in
 825   # MSDOS uses unexcoff.o
 826   # MSWindows uses unexw32.o
 827   aix4-2)
 828    UNEXEC_OBJ=unexaix.o
 829    ;;
 830   cygwin)
 831    UNEXEC_OBJ=unexcw.o
 832    ;;
 833   darwin)
 834    UNEXEC_OBJ=unexmacosx.o
 835    ;;
 836   hpux10-20 | hpux11)
 837    UNEXEC_OBJ=unexhp9k800.o
 838    ;;
 839   sol2-10)
 840    # Use the Solaris dldump() function, called from unexsol.c, to dump
 841    # emacs, instead of the generic ELF dump code found in unexelf.c.
 842    # The resulting binary has a complete symbol table, and is better
 843    # for debugging and other observability tools (debuggers, pstack, etc).
 844    #
 845    # If you encounter a problem using dldump(), please consider sending
 846    # a message to the OpenSolaris tools-linking mailing list:
 847    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 848    #
 849    # It is likely that dldump() works with older Solaris too, but this has
 850    # not been tested, so for now this change is for Solaris 10 or newer.
 851    UNEXEC_OBJ=unexsol.o
 852    ;;
 853 esac
 854
 855 LD_SWITCH_SYSTEM=
 856 case "$opsys" in
 857   freebsd)
 858    ## Let `ld' find image libs and similar things in /usr/local/lib.
 859    ## The system compiler, GCC, has apparently been modified to not
 860    ## look there, contrary to what a stock GCC would do.
 861 ### It's not our place to do this.  See bug#10313#17.
 862 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 863       :
 864    ;;
 865
 866   gnu-linux)
 867    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 868    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 869    ;;
 870
 871   netbsd)
 872 ### It's not our place to do this.  See bug#10313#17.
 873 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 874       :
 875    ;;
 876
 877   openbsd)
 878    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 879    ## otherwise Emacs dumps core on elf systems.
 880    LD_SWITCH_SYSTEM="-Z"
 881    ;;
 882 esac
 883 AC_SUBST(LD_SWITCH_SYSTEM)
 884
 885 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 886
 887 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 888 ## which has not been defined yet.  When this was handled with cpp,
 889 ## it was expanded to null when configure sourced the s/*.h file.
 890 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 891 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 892 ## (or somesuch), but because it is supposed to go at the _front_
 893 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 894 ## Compare with the gnu-linux case below, which added to the end
 895 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 896 ## LD_SWITCH_SYSTEM_TEMACS.
 897 case "$opsys" in
 898   netbsd|openbsd)
 899    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 900 esac
 901
 902
 903 C_SWITCH_MACHINE=
 904 case $canonical in
 905  alpha*)
 906   AC_CHECK_DECL([__ELF__])
 907   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 908     ## With ELF, make sure that all common symbols get allocated to in the
 909     ## data section.  Otherwise, the dump of temacs may miss variables in
 910     ## the shared library that have been initialized.  For example, with
 911     ## GNU libc, __malloc_initialized would normally be resolved to the
 912     ## shared library's .bss section, which is fatal.
 913     if test "x$GCC" = "xyes"; then
 914       C_SWITCH_MACHINE="-fno-common"
 915     else
 916       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 917     fi
 918   else
 919     UNEXEC_OBJ=unexalpha.o
 920   fi
 921   ;;
 922 esac
 923 AC_SUBST(C_SWITCH_MACHINE)
 924
 925 AC_SUBST(UNEXEC_OBJ)
 926
 927 C_SWITCH_SYSTEM=
 928 ## Some programs in src produce warnings saying certain subprograms
 929 ## are too complex and need a MAXMEM value greater than 2000 for
 930 ## additional optimization.  --nils@exp-math.uni-essen.de
 931 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 932   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 933 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 934 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 935 AC_SUBST(C_SWITCH_SYSTEM)
 936
 937
 938 LIBS_SYSTEM=
 939 case "$opsys" in
 940   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 941   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 942
 943   freebsd) LIBS_SYSTEM="-lutil" ;;
 944
 945   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 946
 947   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 948
 949   ## Motif needs -lgen.
 950   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 951 esac
 952 AC_SUBST(LIBS_SYSTEM)
 953
 954
 955 ### Make sure subsequent tests use flags consistent with the build flags.
 956
 957 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 958   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 959 else
 960   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 961 fi
 962
 963 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 964 AC_DEFUN([AC_TYPE_SIZE_T])
 965 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 966 AC_DEFUN([AC_TYPE_UID_T])
 967
 968
 969 LIB_MATH=-lm
 970 LIB_STANDARD=
 971 START_FILES=
 972 dnl Current possibilities handled by sed (aix4-2 -> aix,
 973 dnl gnu-linux -> gnu/linux, etc.):
 974 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
 975 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
 976 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
 977
 978 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 979 case $opsys in
 980   cygwin )
 981     LIB_MATH=
 982     START_FILES='pre-crt0.o'
 983     ;;
 984   darwin )
 985     ## Adding -lm confuses the dynamic linker, so omit it.
 986     LIB_MATH=
 987     START_FILES='pre-crt0.o'
 988     ;;
 989   freebsd )
 990     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
 991     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
 992     SYSTEM_TYPE=berkeley-unix
 993     ;;
 994   gnu-linux | gnu-kfreebsd )
 995     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 996     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 997     ;;
 998   hpux10-20 | hpux11 )
 999     LIB_STANDARD=-lc
1000     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1001     ;;
1002   dnl NB this may be adjusted below.
1003   netbsd | openbsd )
1004     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1005     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1006     SYSTEM_TYPE=berkeley-unix
1007     ;;
1008
1009   sol2* | unixware )
1010     SYSTEM_TYPE=usg-unix-v
1011     ;;
1012
1013 esac
1014
1015 AC_SUBST(LIB_MATH)
1016 AC_SUBST(START_FILES)
1017 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1018   [The type of system you are compiling for; sets `system-type'.])
1019
1020 dnl Not all platforms use crtn.o files.  Check if the current one does.
1021 crt_files=
1022
1023 for file in x $LIB_STANDARD $START_FILES; do
1024   case "$file" in
1025     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1026   esac
1027 done
1028
1029 if test "x$crt_files" != x; then
1030
1031   ## If user specified a crt-dir, use that unconditionally.
1032   crt_gcc=no
1033
1034   if test "X$CRT_DIR" = "X"; then
1035
1036     CRT_DIR=/usr/lib            # default
1037
1038     case "$canonical" in
1039       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1040       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1041       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1042       ## For anything else (eg /usr/lib32), it is up the user to specify
1043       ## the location (bug#5655).
1044       ## Test for crtn.o, not just the directory, because sometimes the
1045       ## directory exists but does not have the relevant files (bug#1287).
1046       ## FIXME better to test for binary compatibility somehow.
1047       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1048       ;;
1049
1050       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1051     esac
1052
1053     case "$opsys" in
1054       hpux10-20) CRT_DIR=/lib ;;
1055     esac
1056
1057     test "x${GCC}" = xyes && crt_gcc=yes
1058
1059   fi                            # CRT_DIR = ""
1060
1061   crt_missing=
1062
1063   for file in $crt_files; do
1064
1065     ## If we're using gcc, try to determine it automatically by asking
1066     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1067     ## system-dependent default from above.]
1068     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1069
1070        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1071        case "$crt_file" in
1072          */*)
1073            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1074            ;;
1075        esac
1076     fi
1077
1078     dnl We expect all the files to be in a single directory, so after the
1079     dnl first there is no point asking gcc.
1080     crt_gcc=no
1081
1082     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1083   done                          # $crt_files
1084
1085   test "x$crt_missing" = x || \
1086     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1087 Try using the --with-crt-dir option.])
1088
1089 fi                              # crt_files != ""
1090
1091 AC_SUBST(CRT_DIR)
1092
1093 case $opsys in
1094   netbsd | openbsd )
1095     if test -f $CRT_DIR/crti.o; then
1096
1097         test -f $CRT_DIR/crtn.o || \
1098           AC_MSG_ERROR([Required file not found: crtn.o])
1099
1100         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1101         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1102     fi
1103     ;;
1104 esac
1105
1106
1107 # Configure gnulib before invoking PKG_CHECK_MODULES, as the latter might
1108 # for example add -lrt to RSVG_LIBS, which would then cause gnulib to
1109 # incorrectly conclude that -lrt is not needed to link clock_gettime.
1110 gl_ASSERT_NO_GNULIB_POSIXCHECK
1111 gl_ASSERT_NO_GNULIB_TESTS
1112 gl_INIT
1113
1114 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1115
1116 dnl This function definition taken from Gnome 2.0
1117 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1118 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1119 dnl also defines GSTUFF_PKG_ERRORS on error
1120 AC_DEFUN([PKG_CHECK_MODULES], [
1121   succeeded=no
1122
1123   if test "$PKG_CONFIG" = "no" ; then
1124      ifelse([$4], , [AC_MSG_ERROR([
1125       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1126   else
1127      PKG_CONFIG_MIN_VERSION=0.9.0
1128      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1129         AC_MSG_CHECKING(for $2)
1130
1131         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1132            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1133            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1134             edit_cflags="
1135               s,///*,/,g
1136               s/^/ /
1137               s/ -I/ $isystem/g
1138               s/^ //
1139             "
1140             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1141             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1142             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1143             succeeded=yes
1144         else
1145             AC_MSG_RESULT(no)
1146             $1_CFLAGS=""
1147             $1_LIBS=""
1148             ## If we have a custom action on failure, don't print errors, but
1149             ## do set a variable so people can do so.
1150             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1151             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1152         fi
1153
1154         AC_SUBST($1_CFLAGS)
1155         AC_SUBST($1_LIBS)
1156      else
1157         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1158         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1159      fi
1160   fi
1161
1162   if test $succeeded = yes; then
1163      ifelse([$3], , :, [$3])
1164   else
1165      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1166   fi
1167 ])
1168
1169
1170 if test "${with_sound}" != "no"; then
1171   # Sound support for GNU/Linux and the free BSDs.
1172   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1173     have_sound_header=yes)
1174   # Emulation library used on NetBSD.
1175   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1176   AC_SUBST(LIBSOUND)
1177
1178   ALSA_REQUIRED=1.0.0
1179   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1180   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1181   if test $HAVE_ALSA = yes; then
1182     SAVE_CFLAGS="$CFLAGS"
1183     SAVE_LIBS="$LIBS"
1184     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1185     LIBS="$ALSA_LIBS $LIBS"
1186     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1187                     emacs_alsa_normal=yes,
1188                     emacs_alsa_normal=no)
1189     if test "$emacs_alsa_normal" != yes; then
1190       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1191                      [[snd_lib_error_set_handler (0);]])],
1192                      emacs_alsa_subdir=yes,
1193                      emacs_alsa_subdir=no)
1194       if test "$emacs_alsa_subdir" != yes; then
1195         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1196       fi
1197       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1198     fi
1199
1200     CFLAGS="$SAVE_CFLAGS"
1201     LIBS="$SAVE_LIBS"
1202     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1203     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1204     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1205   fi
1206
1207   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1208   dnl compiles only on the specified platforms.  For others, it
1209   dnl probably doesn't make sense to try.
1210   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1211      case "$opsys" in
1212        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1213        gnu-linux|freebsd|netbsd)
1214          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1215          ;;
1216      esac
1217   fi
1218
1219   AC_SUBST(CFLAGS_SOUND)
1220 fi
1221
1222 dnl checks for header files
1223 AC_CHECK_HEADERS_ONCE(
1224   linux/version.h sys/systeminfo.h
1225   stdio_ext.h fcntl.h coff.h pty.h
1226   sys/vlimit.h sys/resource.h
1227   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1228
1229 AC_MSG_CHECKING(if personality LINUX32 can be set)
1230 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1231                emacs_cv_personality_linux32=yes,
1232                emacs_cv_personality_linux32=no)
1233 AC_MSG_RESULT($emacs_cv_personality_linux32)
1234
1235 if test $emacs_cv_personality_linux32 = yes; then
1236   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1237             [Define to 1 if personality LINUX32 can be set.])
1238 fi
1239
1240 dnl On Solaris 8 there's a compilation warning for term.h because
1241 dnl it doesn't define `bool'.
1242 AC_CHECK_HEADERS(term.h, , , -)
1243 AC_HEADER_TIME
1244 AC_CHECK_DECLS([sys_siglist])
1245 if test $ac_cv_have_decl_sys_siglist != yes; then
1246   # For Tru64, at least:
1247   AC_CHECK_DECLS([__sys_siglist])
1248   if test $ac_cv_have_decl___sys_siglist = yes; then
1249     AC_DEFINE(sys_siglist, __sys_siglist,
1250               [Define to any substitute for sys_siglist.])
1251   fi
1252 fi
1253 AC_HEADER_SYS_WAIT
1254
1255 dnl Check for speed_t typedef.
1256 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1257   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1258     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1259 if test $emacs_cv_speed_t = yes; then
1260   AC_DEFINE(HAVE_SPEED_T, 1,
1261            [Define to 1 if `speed_t' is declared by <termios.h>.])
1262 fi
1263
1264 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1265 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1266 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1267   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1268 HAVE_EXCEPTION=$emacs_cv_struct_exception
1269 if test $emacs_cv_struct_exception != yes; then
1270   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1271 fi
1272
1273 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1274 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1275 #if HAVE_SYS_SOCKET_H
1276 #include <sys/socket.h>
1277 #endif])
1278 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1279 #if HAVE_SYS_SOCKET_H
1280 #include <sys/socket.h>
1281 #endif])
1282 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1283 #if HAVE_SYS_SOCKET_H
1284 #include <sys/socket.h>
1285 #endif])
1286
1287 dnl checks for structure members
1288 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1289                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1290                   struct ifreq.ifr_addr,
1291                   struct ifreq.ifr_addr.sa_len], , ,
1292                  [AC_INCLUDES_DEFAULT
1293 #if HAVE_SYS_SOCKET_H
1294 #include <sys/socket.h>
1295 #endif
1296 #if HAVE_NET_IF_H
1297 #include <net/if.h>
1298 #endif])
1299
1300 dnl Check for endianness.
1301 dnl AC_C_BIGENDIAN is done by gnulib.
1302
1303 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1304   [emacs_cv_attribute_aligned],
1305   [AC_COMPILE_IFELSE(
1306      [AC_LANG_PROGRAM(
1307         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1308         [[]])],
1309      [emacs_cv_attribute_aligned=yes],
1310      [emacs_cv_attribute_aligned=no])])
1311 if test $emacs_cv_attribute_aligned = yes; then
1312   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1313     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1314 fi
1315
1316 dnl check for Make feature
1317 dnl AC_PROG_MAKE_SET is done by Automake.
1318
1319 DEPFLAGS=
1320 MKDEPDIR=":"
1321 deps_frag=deps.mk
1322 dnl check for GNU Make if we have GCC and autodepend is on.
1323 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1324    AC_MSG_CHECKING([whether we are using GNU Make])
1325    HAVE_GNU_MAKE=no
1326    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1327    if test "x$testval" != x; then
1328       HAVE_GNU_MAKE=yes
1329    else
1330       ac_enable_autodepend=no
1331    fi
1332    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1333    if test $HAVE_GNU_MAKE = yes; then
1334       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1335       SAVE_CFLAGS="$CFLAGS"
1336       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1337       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1338       CFLAGS="$SAVE_CFLAGS"
1339       test -f deps.d || ac_enable_autodepend=no
1340       rm -rf deps.d
1341       AC_MSG_RESULT([$ac_enable_autodepend])
1342    fi
1343    if test $ac_enable_autodepend = yes; then
1344       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1345       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1346       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1347       deps_frag=autodeps.mk
1348    fi
1349 fi
1350 deps_frag=$srcdir/src/$deps_frag
1351 AC_SUBST(MKDEPDIR)
1352 AC_SUBST(DEPFLAGS)
1353 AC_SUBST_FILE(deps_frag)
1354
1355
1356 lisp_frag=$srcdir/src/lisp.mk
1357 AC_SUBST_FILE(lisp_frag)
1358
1359
1360 dnl checks for operating system services
1361 AC_SYS_LONG_FILE_NAMES
1362
1363 #### Choose a window system.
1364
1365 AC_PATH_X
1366 if test "$no_x" = yes; then
1367   window_system=none
1368 else
1369   window_system=x11
1370 fi
1371
1372 LD_SWITCH_X_SITE_RPATH=
1373 if test "${x_libraries}" != NONE; then
1374   if test -n "${x_libraries}"; then
1375     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1376     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1377   fi
1378   x_default_search_path=""
1379   x_search_path=${x_libraries}
1380   if test -z "${x_search_path}"; then
1381     x_search_path=/usr/lib
1382   fi
1383   for x_library in `echo ${x_search_path}: | \
1384                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1385     x_search_path="\
1386 ${x_library}/X11/%L/%T/%N%C%S:\
1387 ${x_library}/X11/%l/%T/%N%C%S:\
1388 ${x_library}/X11/%T/%N%C%S:\
1389 ${x_library}/X11/%L/%T/%N%S:\
1390 ${x_library}/X11/%l/%T/%N%S:\
1391 ${x_library}/X11/%T/%N%S"
1392     if test x"${x_default_search_path}" = x; then
1393       x_default_search_path=${x_search_path}
1394     else
1395       x_default_search_path="${x_search_path}:${x_default_search_path}"
1396     fi
1397   done
1398 fi
1399 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1400
1401 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1402   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1403 fi
1404
1405 if test x"${x_includes}" = x; then
1406   bitmapdir=/usr/include/X11/bitmaps
1407 else
1408   # accumulate include directories that have X11 bitmap subdirectories
1409   bmd_acc="dummyval"
1410   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1411     if test -d "${bmd}/X11/bitmaps"; then
1412       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1413     fi
1414     if test -d "${bmd}/bitmaps"; then
1415       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1416     fi
1417   done
1418   if test ${bmd_acc} != "dummyval"; then
1419     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1420   fi
1421 fi
1422
1423 HAVE_NS=no
1424 NS_IMPL_COCOA=no
1425 NS_IMPL_GNUSTEP=no
1426 tmp_CPPFLAGS="$CPPFLAGS"
1427 tmp_CFLAGS="$CFLAGS"
1428 CPPFLAGS="$CPPFLAGS -x objective-c"
1429 CFLAGS="$CFLAGS -x objective-c"
1430 TEMACS_LDFLAGS2="\${LDFLAGS}"
1431 GNU_OBJC_CFLAGS=
1432 if test "${with_ns}" != no; then
1433   if test "${opsys}" = darwin; then
1434      NS_IMPL_COCOA=yes
1435      ns_appdir=`pwd`/nextstep/Emacs.app
1436      ns_appbindir=${ns_appdir}/Contents/MacOS
1437      ns_appresdir=${ns_appdir}/Contents/Resources
1438      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1439   elif test -f $GNUSTEP_CONFIG_FILE; then
1440      NS_IMPL_GNUSTEP=yes
1441      ns_appdir=`pwd`/nextstep/Emacs.app
1442      ns_appbindir=${ns_appdir}
1443      ns_appresdir=${ns_appdir}/Resources
1444      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1445      dnl FIXME sourcing this several times in subshells seems inefficient.
1446      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1447      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1448      dnl I seemed to need these as well with GNUstep-startup 0.25.
1449      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1450      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1451      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1452        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1453      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1454        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1455      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1456      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1457      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1458      LIB_STANDARD=
1459      START_FILES=
1460      TEMACS_LDFLAGS2=
1461      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1462      dnl If they had chosen to either define it or not, we could have
1463      dnl just used AC_CHECK_DECL here.
1464      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1465        emacs_cv_objc_exceptions,
1466 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1467 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1468 1;
1469 #else
1470 fail;
1471 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1472      if test $emacs_cv_objc_exceptions = yes; then
1473        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1474        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1475          [Define if GNUstep uses ObjC exceptions.])
1476        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1477      fi
1478   fi
1479
1480   dnl This is only used while we test the NS headers, it gets reset below.
1481   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1482
1483   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1484                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1485   files are missing or cannot be compiled.])])
1486   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1487                                      [NSInteger i;])],
1488                     ns_have_nsinteger=yes,
1489                     ns_have_nsinteger=no)
1490   if test $ns_have_nsinteger = yes; then
1491     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1492   fi
1493 fi
1494 AC_SUBST(TEMACS_LDFLAGS2)
1495
1496 INSTALL_ARCH_INDEP_EXTRA=install-etc
1497 ns_self_contained=no
1498 ns_frag=/dev/null
1499 NS_OBJ=
1500 NS_OBJC_OBJ=
1501 if test "${HAVE_NS}" = yes; then
1502   if test "$with_toolkit_scroll_bars" = "no"; then
1503     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1504   fi
1505
1506   window_system=nextstep
1507   with_xft=no
1508   # set up packaging dirs
1509   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1510      ns_self_contained=yes
1511      prefix=${ns_appresdir}
1512      exec_prefix=${ns_appbindir}
1513      dnl This one isn't really used, only archlibdir is.
1514      libexecdir="\${ns_appbindir}/libexec"
1515      archlibdir="\${ns_appbindir}/libexec"
1516      docdir="\${ns_appresdir}/etc"
1517      etcdir="\${ns_appresdir}/etc"
1518      dnl FIXME maybe set datarootdir instead.
1519      dnl That would also get applications, icons, man.
1520      infodir="\${ns_appresdir}/info"
1521      mandir="\${ns_appresdir}/man"
1522      lispdir="\${ns_appresdir}/lisp"
1523      leimdir="\${ns_appresdir}/leim"
1524      INSTALL_ARCH_INDEP_EXTRA=
1525   fi
1526   ns_frag=$srcdir/src/ns.mk
1527   NS_OBJ="fontset.o fringe.o image.o"
1528   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1529 fi
1530 CFLAGS="$tmp_CFLAGS"
1531 CPPFLAGS="$tmp_CPPFLAGS"
1532 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1533 AC_SUBST(ns_self_contained)
1534 AC_SUBST(NS_OBJ)
1535 AC_SUBST(NS_OBJC_OBJ)
1536 AC_SUBST(LIB_STANDARD)
1537 AC_SUBST_FILE(ns_frag)
1538
1539 case "${window_system}" in
1540   x11 )
1541     HAVE_X_WINDOWS=yes
1542     HAVE_X11=yes
1543     case "${with_x_toolkit}" in
1544       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1545       motif ) USE_X_TOOLKIT=MOTIF ;;
1546       gtk ) with_gtk=yes
1547 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1548 dnl USE_X_TOOLKIT is set.
1549             USE_X_TOOLKIT=none ;;
1550       gtk3 ) with_gtk3=yes
1551              USE_X_TOOLKIT=none ;;
1552       no ) USE_X_TOOLKIT=none ;;
1553 dnl If user did not say whether to use a toolkit, make this decision later:
1554 dnl use the toolkit if we have gtk, or X11R5 or newer.
1555       * ) USE_X_TOOLKIT=maybe ;;
1556     esac
1557   ;;
1558   nextstep | none )
1559     HAVE_X_WINDOWS=no
1560     HAVE_X11=no
1561     USE_X_TOOLKIT=none
1562   ;;
1563 esac
1564
1565 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1566    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1567    if test "$HAVE_XSERVER" = true ||
1568       test -n "$DISPLAY" ||
1569       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1570         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1571 were found.  You should install the relevant development files for X
1572 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1573 sure you have development files for image handling, i.e.
1574 tiff, gif, jpeg, png and xpm.
1575 If you are sure you want Emacs compiled without X window support, pass
1576   --without-x
1577 to configure.])
1578    fi
1579 fi
1580
1581 ### If we're using X11, we should use the X menu package.
1582 HAVE_MENUS=no
1583 case ${HAVE_X11} in
1584   yes ) HAVE_MENUS=yes ;;
1585 esac
1586
1587 # Does the opsystem file prohibit the use of the GNU malloc?
1588 # Assume not, until told otherwise.
1589 GNU_MALLOC=yes
1590
1591 AC_CACHE_CHECK(
1592   [whether malloc is Doug Lea style],
1593   [emacs_cv_var_doug_lea_malloc],
1594   [AC_LINK_IFELSE(
1595      [AC_LANG_PROGRAM(
1596         [[#include <malloc.h>
1597           static void hook (void) {}]],
1598         [[malloc_set_state (malloc_get_state ());
1599           __after_morecore_hook = hook;
1600           __malloc_initialize_hook = hook;]])],
1601      [emacs_cv_var_doug_lea_malloc=yes],
1602      [emacs_cv_var_doug_lea_malloc=no])])
1603 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1604
1605
1606 dnl See comments in aix4-2.h about maybe using system malloc there.
1607 system_malloc=no
1608 case "$opsys" in
1609   ## darwin ld insists on the use of malloc routines in the System framework.
1610   darwin|sol2-10) system_malloc=yes ;;
1611 esac
1612
1613 if test "${system_malloc}" = "yes"; then
1614   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1615   GNU_MALLOC=no
1616   GNU_MALLOC_reason="
1617     (The GNU allocators don't work with this system configuration.)"
1618   GMALLOC_OBJ=
1619   VMLIMIT_OBJ=
1620 else
1621   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1622   VMLIMIT_OBJ=vm-limit.o
1623 fi
1624 AC_SUBST(GMALLOC_OBJ)
1625 AC_SUBST(VMLIMIT_OBJ)
1626
1627 if test "$doug_lea_malloc" = "yes" ; then
1628   if test "$GNU_MALLOC" = yes ; then
1629     GNU_MALLOC_reason="
1630       (Using Doug Lea's new malloc from the GNU C Library.)"
1631   fi
1632   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1633             [Define to 1 if you are using the GNU C Library.])
1634
1635   ## Use mmap directly for allocating larger buffers.
1636   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1637   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1638   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1639   case "$opsys" in
1640     gnu*) REL_ALLOC=no ;;
1641   esac
1642 fi
1643
1644 if test x"${REL_ALLOC}" = x; then
1645   REL_ALLOC=${GNU_MALLOC}
1646 fi
1647
1648 use_mmap_for_buffers=no
1649 case "$opsys" in
1650   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1651 esac
1652
1653 AC_FUNC_MMAP
1654 if test $use_mmap_for_buffers = yes; then
1655   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1656   REL_ALLOC=no
1657 fi
1658
1659 LIBS="$LIBS_SYSTEM $LIBS"
1660
1661 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1662 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1663 AC_CHECK_LIB(dnet, dnet_ntoa)
1664 dnl This causes -lresolv to get used in subsequent tests,
1665 dnl which causes failures on some systems such as HPUX 9.
1666 dnl AC_CHECK_LIB(resolv, gethostbyname)
1667
1668 dnl FIXME replace main with a function we actually want from this library.
1669 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1670
1671 dnl Check if pthreads is available.
1672 LIB_PTHREAD=
1673 AC_CHECK_HEADERS_ONCE(pthread.h)
1674 if test "$ac_cv_header_pthread_h"; then
1675   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1676   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1677   dnl testing for pthread_self if Emacs uses gmalloc.c.
1678   if test "$GMALLOC_OBJ" = gmalloc.o; then
1679     emacs_pthread_function=pthread_atfork
1680   else
1681     emacs_pthread_function=pthread_self
1682   fi
1683   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1684 fi
1685 if test "$HAVE_PTHREAD" = yes; then
1686   case "${canonical}" in
1687     *-hpux*) ;;
1688     *) LIB_PTHREAD="-lpthread"
1689        LIBS="$LIB_PTHREAD $LIBS" ;;
1690   esac
1691   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1692 fi
1693 AC_SUBST([LIB_PTHREAD])
1694
1695 AC_CHECK_LIB(pthreads, cma_open)
1696
1697 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1698 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1699 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1700 ## added to LIBS in configure would never contain the pthreads part,
1701 ## but the value used in Makefiles might.  FIXME?
1702 ##
1703 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1704 ## be harmless on older versions of X where it happens to exist.
1705 test "$opsys" = "aix4-2" && \
1706   test $ac_cv_lib_pthreads_cma_open = yes && \
1707   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1708
1709 dnl Check for need for bigtoc support on IBM AIX
1710
1711 case ${host_os} in
1712 aix*)
1713   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1714     case $GCC in
1715     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1716     *) gdb_cv_bigtoc=-bbigtoc ;;
1717     esac
1718
1719     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1720     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1721   ])
1722   ;;
1723 esac
1724
1725 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1726 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1727 # REAL_CPPFLAGS later on.
1728
1729 REAL_CFLAGS="$CFLAGS"
1730 REAL_CPPFLAGS="$CPPFLAGS"
1731
1732 if test "${HAVE_X11}" = "yes"; then
1733   DEFS="$C_SWITCH_X_SITE $DEFS"
1734   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1735   LIBS="-lX11 $LIBS"
1736   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1737   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1738
1739   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1740   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1741   # but it's more convenient here to set LD_RUN_PATH since this
1742   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1743   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1744     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1745     export LD_RUN_PATH
1746   fi
1747
1748   if test "${opsys}" = "gnu-linux"; then
1749     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1750     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1751      [[XOpenDisplay ("foo");]])],
1752      [xgnu_linux_first_failure=no],
1753      [xgnu_linux_first_failure=yes])
1754     if test "${xgnu_linux_first_failure}" = "yes"; then
1755       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1756       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1757       OLD_CPPFLAGS="$CPPFLAGS"
1758       OLD_LIBS="$LIBS"
1759       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1760       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1761       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1762       LIBS="$LIBS -b i486-linuxaout"
1763       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1764        [[XOpenDisplay ("foo");]])],
1765        [xgnu_linux_second_failure=no],
1766        [xgnu_linux_second_failure=yes])
1767       if test "${xgnu_linux_second_failure}" = "yes"; then
1768         # If we get the same failure with -b, there is no use adding -b.
1769         # So take it out.  This plays safe.
1770         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1771         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1772         CPPFLAGS="$OLD_CPPFLAGS"
1773         LIBS="$OLD_LIBS"
1774         AC_MSG_RESULT(no)
1775       else
1776         AC_MSG_RESULT(yes)
1777       fi
1778     else
1779       AC_MSG_RESULT(no)
1780     fi
1781   fi
1782
1783   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1784   # header files included from there.
1785   AC_MSG_CHECKING(for Xkb)
1786   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1787 #include <X11/XKBlib.h>]],
1788         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1789         emacs_xkb=yes, emacs_xkb=no)
1790   AC_MSG_RESULT($emacs_xkb)
1791   if test $emacs_xkb = yes; then
1792     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1793   fi
1794
1795   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1796 XScreenNumberOfScreen)
1797 fi
1798
1799 if test "${window_system}" = "x11"; then
1800   AC_MSG_CHECKING(X11 version 6)
1801   AC_CACHE_VAL(emacs_cv_x11_version_6,
1802   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1803 [[#if XlibSpecificationRelease < 6
1804 fail;
1805 #endif
1806 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1807   if test $emacs_cv_x11_version_6 = yes; then
1808     AC_MSG_RESULT(6 or newer)
1809     AC_DEFINE(HAVE_X11R6, 1,
1810               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1811     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1812     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1813     ## XIM support.
1814     case "$opsys" in
1815       sol2-*) : ;;
1816       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1817            [Define if you have usable X11R6-style XIM support.])
1818          ;;
1819     esac
1820   else
1821     AC_MSG_RESULT(before 6)
1822   fi
1823 fi
1824
1825
1826 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1827 HAVE_RSVG=no
1828 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1829   if test "${with_rsvg}" != "no"; then
1830     RSVG_REQUIRED=2.11.0
1831     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1832
1833     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1834     AC_SUBST(RSVG_CFLAGS)
1835     AC_SUBST(RSVG_LIBS)
1836
1837     if test $HAVE_RSVG = yes; then
1838       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1839       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1840       LIBS="$RSVG_LIBS $LIBS"
1841     fi
1842   fi
1843 fi
1844
1845 HAVE_IMAGEMAGICK=no
1846 if test "${HAVE_X11}" = "yes"; then
1847   if test "${with_imagemagick}" != "no"; then
1848     ## 6.2.8 is the earliest version known to work, but earlier versions
1849     ## might work - let us know if you find one.
1850     ## 6.0.7 does not work.  See bug#7955.
1851     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1852     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1853     AC_SUBST(IMAGEMAGICK_CFLAGS)
1854     AC_SUBST(IMAGEMAGICK_LIBS)
1855
1856     if test $HAVE_IMAGEMAGICK = yes; then
1857       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1858       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1859       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1860       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1861     fi
1862   fi
1863 fi
1864
1865
1866 HAVE_GTK=no
1867 GTK_OBJ=
1868 if test "${with_gtk3}" = "yes"; then
1869   GLIB_REQUIRED=2.28
1870   GTK_REQUIRED=3.0
1871   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1872
1873   dnl Checks for libraries.
1874   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1875   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1876      AC_MSG_ERROR($GTK_PKG_ERRORS)
1877   fi
1878   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1879   GTK_OBJ=emacsgtkfixed.o
1880 fi
1881
1882 if test "$pkg_check_gtk" != "yes"; then
1883   HAVE_GTK=no
1884 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1885   GLIB_REQUIRED=2.10
1886   GTK_REQUIRED=2.10
1887   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1888
1889   dnl Checks for libraries.
1890   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1891   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1892      AC_MSG_ERROR($GTK_PKG_ERRORS)
1893   fi
1894 fi
1895 fi
1896
1897 if test x"$pkg_check_gtk" = xyes; then
1898
1899   AC_SUBST(GTK_CFLAGS)
1900   AC_SUBST(GTK_LIBS)
1901   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1902   CFLAGS="$CFLAGS $GTK_CFLAGS"
1903   LIBS="$GTK_LIBS $LIBS"
1904   dnl Try to compile a simple GTK program.
1905   GTK_COMPILES=no
1906   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1907   if test "${GTK_COMPILES}" != "yes"; then
1908     if test "$USE_X_TOOLKIT" != "maybe"; then
1909       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1910     fi
1911   else
1912     HAVE_GTK=yes
1913     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1914     GTK_OBJ="gtkutil.o $GTK_OBJ"
1915     USE_X_TOOLKIT=none
1916     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1917       :
1918     else
1919       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1920        closing open displays.  This is no problem if you just use
1921        one display, but if you use more than one and close one of them
1922        Emacs may crash.]])
1923       sleep 3
1924     fi
1925   fi
1926
1927 fi
1928 AC_SUBST(GTK_OBJ)
1929
1930
1931 if test "${HAVE_GTK}" = "yes"; then
1932
1933   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1934   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1935   if test "$with_toolkit_scroll_bars" != no; then
1936     with_toolkit_scroll_bars=yes
1937   fi
1938
1939   dnl  Check if we have the old file selection dialog declared and
1940   dnl  in the link library.  In 2.x it may be in the library,
1941   dnl  but not declared if deprecated featured has been selected out.
1942   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1943   HAVE_GTK_FILE_SELECTION=no
1944   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1945                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1946 #include <gtk/gtk.h>])
1947   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1948     AC_CHECK_FUNCS(gtk_file_selection_new)
1949   fi
1950
1951
1952   dnl Check for functions introduced in 2.14 and later.
1953   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1954                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1955                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1956                  gtk_orientable_set_orientation \
1957                  gtk_window_set_has_resize_grip)
1958 fi
1959
1960 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1961 dnl other platforms.
1962 HAVE_DBUS=no
1963 DBUS_OBJ=
1964 if test "${with_dbus}" = "yes"; then
1965    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1966    if test "$HAVE_DBUS" = yes; then
1967      LIBS="$LIBS $DBUS_LIBS"
1968      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1969      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1970      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
1971      dnl D-Bus 1.5.12.
1972      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1973                     dbus_type_is_valid \
1974                     dbus_validate_bus_name \
1975                     dbus_validate_path \
1976                     dbus_validate_interface \
1977                     dbus_validate_member)
1978      DBUS_OBJ=dbusbind.o
1979    fi
1980 fi
1981 AC_SUBST(DBUS_OBJ)
1982
1983 dnl GSettings has been tested under GNU/Linux only.
1984 HAVE_GSETTINGS=no
1985 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1986    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1987    if test "$HAVE_GSETTINGS" = "yes"; then
1988       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1989       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1990       SETTINGS_LIBS="$GSETTINGS_LIBS"
1991    fi
1992 fi
1993
1994 dnl GConf has been tested under GNU/Linux only.
1995 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1996 HAVE_GCONF=no
1997 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1998    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1999    if test "$HAVE_GCONF" = yes; then
2000       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2001       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2002       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2003       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2004    fi
2005 fi
2006
2007 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2008     SAVE_CFLAGS="$CFLAGS"
2009     SAVE_LIBS="$LIBS"
2010     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2011     LIBS="$SETTINGS_LIBS $LIBS"
2012     AC_CHECK_FUNCS([g_type_init])
2013     CFLAGS="$SAVE_CFLAGS"
2014     LIBS="$SAVE_LIBS"
2015 fi
2016 AC_SUBST(SETTINGS_CFLAGS)
2017 AC_SUBST(SETTINGS_LIBS)
2018
2019
2020 dnl SELinux is available for GNU/Linux only.
2021 HAVE_LIBSELINUX=no
2022 LIBSELINUX_LIBS=
2023 if test "${with_selinux}" = "yes"; then
2024    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2025    if test "$HAVE_LIBSELINUX" = yes; then
2026       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2027       LIBSELINUX_LIBS=-lselinux
2028    fi
2029 fi
2030 AC_SUBST(LIBSELINUX_LIBS)
2031
2032 HAVE_GNUTLS=no
2033 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2034 if test "${with_gnutls}" = "yes" ; then
2035   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2036   if test "${HAVE_GNUTLS}" = "yes"; then
2037     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2038   fi
2039
2040   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2041   LIBS="$LIBGNUTLS_LIBS $LIBS"
2042   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2043
2044   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2045     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2046   fi
2047 fi
2048
2049 AC_SUBST(LIBGNUTLS_LIBS)
2050 AC_SUBST(LIBGNUTLS_CFLAGS)
2051
2052 dnl Do not put whitespace before the #include statements below.
2053 dnl Older compilers (eg sunos4 cc) choke on it.
2054 HAVE_XAW3D=no
2055 LUCID_LIBW=
2056 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2057   if test "$with_xaw3d" != no; then
2058     AC_MSG_CHECKING(for xaw3d)
2059     AC_CACHE_VAL(emacs_cv_xaw3d,
2060     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2061 #include <X11/Intrinsic.h>
2062 #include <X11/Xaw3d/Simple.h>]],
2063       [[]])],
2064       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2065                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2066       emacs_cv_xaw3d=no)])
2067   else
2068     emacs_cv_xaw3d=no
2069   fi
2070   if test $emacs_cv_xaw3d = yes; then
2071     AC_MSG_RESULT([yes; using Lucid toolkit])
2072     USE_X_TOOLKIT=LUCID
2073     HAVE_XAW3D=yes
2074     LUCID_LIBW=-lXaw3d
2075     AC_DEFINE(HAVE_XAW3D, 1,
2076               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2077   else
2078     AC_MSG_RESULT(no)
2079     AC_MSG_CHECKING(for libXaw)
2080     AC_CACHE_VAL(emacs_cv_xaw,
2081     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2082 #include <X11/Intrinsic.h>
2083 #include <X11/Xaw/Simple.h>]],
2084       [[]])],
2085       emacs_cv_xaw=yes,
2086       emacs_cv_xaw=no)])
2087     if test $emacs_cv_xaw = yes; then
2088       AC_MSG_RESULT([yes; using Lucid toolkit])
2089       USE_X_TOOLKIT=LUCID
2090       LUCID_LIBW=-lXaw
2091     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2092       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2093     else
2094       AC_MSG_ERROR([No X toolkit could be found.
2095 If you are sure you want Emacs compiled without an X toolkit, pass
2096   --with-x-toolkit=no
2097 to configure.  Otherwise, install the development libraries for the toolkit
2098 that you want to use (e.g. Gtk+) and re-run configure.])
2099     fi
2100   fi
2101 fi
2102
2103 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2104
2105 LIBXTR6=
2106 if test "${USE_X_TOOLKIT}" != "none"; then
2107   AC_MSG_CHECKING(X11 toolkit version)
2108   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2109   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2110 [[#if XtSpecificationRelease < 6
2111 fail;
2112 #endif
2113 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2114   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2115   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2116     AC_MSG_RESULT(6 or newer)
2117     AC_DEFINE(HAVE_X11XTR6, 1,
2118               [Define to 1 if you have the X11R6 or newer version of Xt.])
2119     LIBXTR6="-lSM -lICE"
2120     case "$opsys" in
2121       ## Use libw.a along with X11R6 Xt.
2122       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2123     esac
2124   else
2125     AC_MSG_RESULT(before 6)
2126   fi
2127
2128 dnl If using toolkit, check whether libXmu.a exists.
2129 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2130   OLDLIBS="$LIBS"
2131   if test x$HAVE_X11XTR6 = xyes; then
2132     LIBS="-lXt -lSM -lICE $LIBS"
2133   else
2134     LIBS="-lXt $LIBS"
2135   fi
2136   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2137   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2138 fi
2139 AC_SUBST(LIBXTR6)
2140
2141 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2142 dnl Why not just test for libxmu in the normal way?
2143 LIBXMU=-lXmu
2144 case $opsys in
2145   ## These systems don't supply Xmu.
2146   hpux* | aix4-2 )
2147     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2148     ;;
2149 esac
2150 AC_SUBST(LIBXMU)
2151
2152 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2153 if test "${HAVE_X11}" = "yes"; then
2154   if test "${USE_X_TOOLKIT}" != "none"; then
2155     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2156   fi
2157 fi
2158
2159 LIBXP=
2160 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2161   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2162   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2163     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2164 int x = 5;
2165 #else
2166 Motif version prior to 2.1.
2167 #endif]])],
2168     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2169   if test $emacs_cv_motif_version_2_1 = yes; then
2170     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2171   else
2172     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2173     # We put this in CFLAGS temporarily to precede other -I options
2174     # that might be in CFLAGS temporarily.
2175     # We put this in CPPFLAGS where it precedes the other -I options.
2176     OLD_CPPFLAGS=$CPPFLAGS
2177     OLD_CFLAGS=$CFLAGS
2178     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2179     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2180     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2181       [[int x = 5;]])],
2182       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2183     if test $emacs_cv_lesstif = yes; then
2184       # Make sure this -I option remains in CPPFLAGS after it is set
2185       # back to REAL_CPPFLAGS.
2186       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2187       # have those other -I options anyway.  Ultimately, having this
2188       # directory ultimately in CPPFLAGS will be enough.
2189       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2190       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2191     else
2192       CFLAGS=$OLD_CFLAGS
2193       CPPFLAGS=$OLD_CPPFLAGS
2194     fi
2195   fi
2196   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2197     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2198 fi
2199
2200 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2201 dnl using Motif or Xaw3d is available, and unless
2202 dnl --with-toolkit-scroll-bars=no was specified.
2203
2204 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2205             [Define to 1 if we should use toolkit scroll bars.])dnl
2206 USE_TOOLKIT_SCROLL_BARS=no
2207 if test "${with_toolkit_scroll_bars}" != "no"; then
2208   if test "${USE_X_TOOLKIT}" != "none"; then
2209     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2210       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2211       HAVE_XAW3D=no
2212       USE_TOOLKIT_SCROLL_BARS=yes
2213     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2214       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2215       USE_TOOLKIT_SCROLL_BARS=yes
2216     fi
2217   elif test "${HAVE_GTK}" = "yes"; then
2218     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2219     USE_TOOLKIT_SCROLL_BARS=yes
2220   elif test "${HAVE_NS}" = "yes"; then
2221     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2222     USE_TOOLKIT_SCROLL_BARS=yes
2223   fi
2224 fi
2225
2226 dnl See if XIM is available.
2227 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2228           #include <X11/Xlib.h>
2229           #include <X11/Xresource.h>]],
2230          [[XIMProc  callback;]])],
2231          [HAVE_XIM=yes
2232          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2233          HAVE_XIM=no)
2234
2235 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2236
2237 if test "${with_xim}" != "no"; then
2238   AC_DEFINE(USE_XIM, 1,
2239             [Define to 1 if we should use XIM, if it is available.])
2240 fi
2241
2242
2243 if test "${HAVE_XIM}" != "no"; then
2244   late_CFLAGS=$CFLAGS
2245   if test "$GCC" = yes; then
2246     CFLAGS="$CFLAGS --pedantic-errors"
2247   fi
2248   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2249 #include <X11/Xlib.h>
2250 #include <X11/Xresource.h>]],
2251 [[Display *display;
2252 XrmDatabase db;
2253 char *res_name;
2254 char *res_class;
2255 XIMProc  callback;
2256 XPointer *client_data;
2257 #ifndef __GNUC__
2258 /* If we're not using GCC, it's probably not XFree86, and this is
2259    probably right, but we can't use something like --pedantic-errors.  */
2260 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2261                                            char*, XIMProc, XPointer*);
2262 #endif
2263 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2264    client_data);]])],
2265     [emacs_cv_arg6_star=yes])
2266   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2267          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2268 either XPointer or XPointer*.])dnl
2269   if test "$emacs_cv_arg6_star" = yes; then
2270     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2271   else
2272     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2273   fi
2274   CFLAGS=$late_CFLAGS
2275 fi
2276
2277 ### Start of font-backend (under any platform) section.
2278 # (nothing here yet -- this is a placeholder)
2279 ### End of font-backend (under any platform) section.
2280
2281 ### Start of font-backend (under X11) section.
2282 if test "${HAVE_X11}" = "yes"; then
2283    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2284
2285    ## Use -lXft if available, unless `--with-xft=no'.
2286    HAVE_XFT=maybe
2287     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2288       with_xft="no";
2289     fi
2290     if test "x${with_xft}" != "xno"; then
2291
2292       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2293       ## Because xftfont.c uses XRenderQueryExtension, we also
2294       ## need to link to -lXrender.
2295       HAVE_XRENDER=no
2296       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2297       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2298         OLD_CPPFLAGS="$CPPFLAGS"
2299         OLD_CFLAGS="$CFLAGS"
2300         OLD_LIBS="$LIBS"
2301         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2302         CFLAGS="$CFLAGS $XFT_CFLAGS"
2303         XFT_LIBS="-lXrender $XFT_LIBS"
2304         LIBS="$XFT_LIBS $LIBS"
2305         AC_CHECK_HEADER(X11/Xft/Xft.h,
2306           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2307
2308         if test "${HAVE_XFT}" = "yes"; then
2309           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2310             AC_SUBST(XFT_LIBS)
2311           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2312         else
2313           CPPFLAGS="$OLD_CPPFLAGS"
2314           CFLAGS="$OLD_CFLAGS"
2315           LIBS="$OLD_LIBS"
2316         fi                        # "${HAVE_XFT}" = "yes"
2317       fi                          # "$HAVE_XFT" != no
2318     fi                            # "x${with_xft}" != "xno"
2319
2320     ## We used to allow building with FreeType and without Xft.
2321     ## However, the ftx font backend driver is not in good shape.
2322     if test "$HAVE_XFT" != "yes"; then
2323        dnl For the "Does Emacs use" message at the end.
2324        HAVE_XFT=no
2325        HAVE_FREETYPE=no
2326     else
2327        dnl Strict linkers fail with
2328        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2329        dnl if -lfreetype is not specified.
2330        dnl The following is needed to set FREETYPE_LIBS.
2331        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2332                          HAVE_FREETYPE=no)
2333
2334        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2335     fi
2336
2337     HAVE_LIBOTF=no
2338     if test "${HAVE_FREETYPE}" = "yes"; then
2339       AC_DEFINE(HAVE_FREETYPE, 1,
2340                 [Define to 1 if using the freetype and fontconfig libraries.])
2341       if test "${with_libotf}" != "no"; then
2342         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2343                           HAVE_LIBOTF=no)
2344         if test "$HAVE_LIBOTF" = "yes"; then
2345           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2346           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2347                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2348                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2349           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2350             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2351                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2352           fi
2353         fi
2354       fi
2355     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2356     dnl Does the new font backend require it, or can it work without it?
2357     fi
2358
2359     HAVE_M17N_FLT=no
2360     if test "${HAVE_LIBOTF}" = yes; then
2361       if test "${with_m17n_flt}" != "no"; then
2362         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2363         if test "$HAVE_M17N_FLT" = "yes"; then
2364           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2365         fi
2366       fi
2367     fi
2368 else
2369     HAVE_XFT=no
2370     HAVE_FREETYPE=no
2371     HAVE_LIBOTF=no
2372     HAVE_M17N_FLT=no
2373 fi
2374
2375 ### End of font-backend (under X11) section.
2376
2377 AC_SUBST(FREETYPE_CFLAGS)
2378 AC_SUBST(FREETYPE_LIBS)
2379 AC_SUBST(FONTCONFIG_CFLAGS)
2380 AC_SUBST(FONTCONFIG_LIBS)
2381 AC_SUBST(LIBOTF_CFLAGS)
2382 AC_SUBST(LIBOTF_LIBS)
2383 AC_SUBST(M17N_FLT_CFLAGS)
2384 AC_SUBST(M17N_FLT_LIBS)
2385
2386 ### Use -lXpm if available, unless `--with-xpm=no'.
2387 HAVE_XPM=no
2388 LIBXPM=
2389 if test "${HAVE_X11}" = "yes"; then
2390   if test "${with_xpm}" != "no"; then
2391     AC_CHECK_HEADER(X11/xpm.h,
2392       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2393     if test "${HAVE_XPM}" = "yes"; then
2394       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2395       AC_EGREP_CPP(no_return_alloc_pixels,
2396       [#include "X11/xpm.h"
2397 #ifndef XpmReturnAllocPixels
2398 no_return_alloc_pixels
2399 #endif
2400       ], HAVE_XPM=no, HAVE_XPM=yes)
2401
2402       if test "${HAVE_XPM}" = "yes"; then
2403         AC_MSG_RESULT(yes)
2404       else
2405         AC_MSG_RESULT(no)
2406       fi
2407     fi
2408   fi
2409
2410   if test "${HAVE_XPM}" = "yes"; then
2411     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2412     LIBXPM=-lXpm
2413   fi
2414 fi
2415 AC_SUBST(LIBXPM)
2416
2417 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2418 HAVE_JPEG=no
2419 LIBJPEG=
2420 if test "${HAVE_X11}" = "yes"; then
2421   if test "${with_jpeg}" != "no"; then
2422     dnl Checking for jpeglib.h can lose because of a redefinition of
2423     dnl  HAVE_STDLIB_H.
2424     AC_CHECK_HEADER(jerror.h,
2425       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2426   fi
2427
2428   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2429   if test "${HAVE_JPEG}" = "yes"; then
2430     AC_DEFINE(HAVE_JPEG)
2431     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2432         [#include <jpeglib.h>
2433          version=JPEG_LIB_VERSION
2434 ],
2435         [AC_DEFINE(HAVE_JPEG)],
2436         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2437         HAVE_JPEG=no])
2438   fi
2439   if test "${HAVE_JPEG}" = "yes"; then
2440     LIBJPEG=-ljpeg
2441   fi
2442 fi
2443 AC_SUBST(LIBJPEG)
2444
2445 ### Use -lpng if available, unless `--with-png=no'.
2446 HAVE_PNG=no
2447 LIBPNG=
2448 if test "${HAVE_X11}" = "yes"; then
2449   if test "${with_png}" != "no"; then
2450     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2451     # in /usr/include/libpng.
2452     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2453     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2454       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2455     fi
2456   fi
2457
2458   if test "${HAVE_PNG}" = "yes"; then
2459     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2460     LIBPNG="-lpng -lz -lm"
2461
2462     AC_CHECK_DECL(png_longjmp,
2463       [],
2464       [AC_DEFINE(PNG_DEPSTRUCT, [],
2465          [Define to empty to suppress deprecation warnings when building
2466           with --enable-gcc-warnings and with libpng versions before 1.5,
2467           which lack png_longjmp.])],
2468       [[#ifdef HAVE_LIBPNG_PNG_H
2469         # include <libpng/png.h>
2470         #else
2471         # include <png.h>
2472         #endif
2473       ]])
2474   fi
2475 fi
2476 AC_SUBST(LIBPNG)
2477
2478 ### Use -ltiff if available, unless `--with-tiff=no'.
2479 HAVE_TIFF=no
2480 LIBTIFF=
2481 if test "${HAVE_X11}" = "yes"; then
2482   if test "${with_tiff}" != "no"; then
2483     AC_CHECK_HEADER(tiffio.h,
2484       [tifflibs="-lz -lm"
2485       # At least one tiff package requires the jpeg library.
2486       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2487       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2488   fi
2489
2490   if test "${HAVE_TIFF}" = "yes"; then
2491     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2492     dnl FIXME -lz -lm, as per libpng?
2493     LIBTIFF=-ltiff
2494   fi
2495 fi
2496 AC_SUBST(LIBTIFF)
2497
2498 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2499 HAVE_GIF=no
2500 LIBGIF=
2501 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2502   AC_CHECK_HEADER(gif_lib.h,
2503 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2504 # Earlier versions can crash Emacs.
2505     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2506
2507   if test "$HAVE_GIF" = yes; then
2508     LIBGIF=-lgif
2509   elif test "$HAVE_GIF" = maybe; then
2510 # If gif_lib.h but no libgif, try libungif.
2511     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2512     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2513   fi
2514
2515   if test "${HAVE_GIF}" = "yes"; then
2516     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2517   fi
2518 fi
2519 AC_SUBST(LIBGIF)
2520
2521 dnl Check for required libraries.
2522 if test "${HAVE_X11}" = "yes"; then
2523   MISSING=""
2524   WITH_NO=""
2525   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2526     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2527   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2528     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2529   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2530     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2531   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2532     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2533   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2534     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2535
2536   if test "X${MISSING}" != X; then
2537     AC_MSG_ERROR([The following required libraries were not found:
2538     $MISSING
2539 Maybe some development libraries/packages are missing?
2540 If you don't want to link with them give
2541     $WITH_NO
2542 as options to configure])
2543   fi
2544 fi
2545
2546 ### Use -lgpm if available, unless `--with-gpm=no'.
2547 HAVE_GPM=no
2548 LIBGPM=
2549 if test "${with_gpm}" != "no"; then
2550   AC_CHECK_HEADER(gpm.h,
2551     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2552
2553   if test "${HAVE_GPM}" = "yes"; then
2554     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2555     LIBGPM=-lgpm
2556   fi
2557 fi
2558 AC_SUBST(LIBGPM)
2559
2560 dnl Check for malloc/malloc.h on darwin
2561 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2562
2563 GNUSTEP_CFLAGS=
2564 ### Use NeXTstep API to implement GUI.
2565 if test "${HAVE_NS}" = "yes"; then
2566   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2567   if test "${NS_IMPL_COCOA}" = "yes"; then
2568     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2569   fi
2570   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2571     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2572     # See also .m.o rule in Makefile.in */
2573     # FIXME: are all these flags really needed?  Document here why.  */
2574     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2575     ## Extra CFLAGS applied to src/*.m files.
2576     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2577   fi
2578   # We also have mouse menus.
2579   HAVE_MENUS=yes
2580   OTHER_FILES=ns-app
2581 fi
2582
2583
2584 ### Use session management (-lSM -lICE) if available
2585 HAVE_X_SM=no
2586 LIBXSM=
2587 if test "${HAVE_X11}" = "yes"; then
2588   AC_CHECK_HEADER(X11/SM/SMlib.h,
2589     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2590
2591   if test "${HAVE_X_SM}" = "yes"; then
2592     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2593     LIBXSM="-lSM -lICE"
2594     case "$LIBS" in
2595       *-lSM*) ;;
2596       *)      LIBS="$LIBXSM $LIBS" ;;
2597     esac
2598   fi
2599 fi
2600 AC_SUBST(LIBXSM)
2601
2602 ### Use libxml (-lxml2) if available
2603 HAVE_LIBXML2=no
2604 if test "${with_xml2}" != "no"; then
2605   ### I'm not sure what the version number should be, so I just guessed.
2606   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2607   if test "${HAVE_LIBXML2}" = "yes"; then
2608     LIBS="$LIBXML2_LIBS $LIBS"
2609     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2610     if test "${HAVE_LIBXML2}" = "yes"; then
2611       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2612     else
2613       LIBXML2_LIBS=""
2614       LIBXML2_CFLAGS=""
2615     fi
2616   fi
2617 fi
2618 AC_SUBST(LIBXML2_LIBS)
2619 AC_SUBST(LIBXML2_CFLAGS)
2620
2621 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2622 AC_CACHE_CHECK(whether netdb declares h_errno,
2623                emacs_cv_netdb_declares_h_errno,
2624 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2625   [[return h_errno;]])],
2626   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2627 if test $emacs_cv_netdb_declares_h_errno = yes; then
2628   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2629 fi
2630
2631 # fmod, logb, and frexp are found in -lm on most systems.
2632 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2633 AC_CHECK_LIB(m, sqrt)
2634
2635 # Check for mail-locking functions in a "mail" library.  Probably this should
2636 # have the same check as for liblockfile below.
2637 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2638 if test $have_mail = yes; then
2639   LIBS_MAIL=-lmail
2640   LIBS="$LIBS_MAIL $LIBS"
2641   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2642 else
2643   LIBS_MAIL=
2644 fi
2645 dnl Debian, at least:
2646 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2647 if test $have_lockfile = yes; then
2648    LIBS_MAIL=-llockfile
2649    LIBS="$LIBS_MAIL $LIBS"
2650    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2651 else
2652 # If we have the shared liblockfile, assume we must use it for mail
2653 # locking (e.g. Debian).  If we couldn't link against liblockfile
2654 # (no liblockfile.a installed), ensure that we don't need to.
2655   dnl This works for files generally, not just executables.
2656   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2657   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2658                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2659   if test $ac_cv_prog_liblockfile = yes; then
2660     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2661 This probably means that movemail could lose mail.
2662 There may be a `development' package to install containing liblockfile.])
2663   fi
2664 fi
2665 AC_CHECK_HEADERS_ONCE(maillock.h)
2666 AC_SUBST(LIBS_MAIL)
2667
2668 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2669 ## interlock access to the mail spool.  The alternative is a lock file named
2670 ## /usr/spool/mail/$USER.lock.
2671 mail_lock=no
2672 case "$opsys" in
2673   aix4-2) mail_lock="lockf" ;;
2674
2675   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2676
2677   ## On GNU/Linux systems, both methods are used by various mail programs.
2678   ## I assume most people are using newer mailers that have heard of flock.
2679   ## Change this if you need to.
2680   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2681   ## configure gets the right answers, and that means *NOT* using flock.
2682   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2683   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2684   ## Debian maintainer hasn't provided a clean fix for Emacs.
2685   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2686   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2687   ## correct logic.  -- fx
2688   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2689   ## liblockfile is a Free Software replacement for libmail, used on
2690   ## Debian systems and elsewhere. -rfr.
2691   gnu-*)
2692     mail_lock="flock"
2693     if test $have_mail = yes || test $have_lockfile = yes; then
2694       test $ac_cv_header_maillock_h = yes && mail_lock=no
2695     fi
2696     ;;
2697 esac
2698
2699 BLESSMAIL_TARGET=
2700 case "$mail_lock" in
2701   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2702
2703   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2704
2705   *) BLESSMAIL_TARGET="need-blessmail" ;;
2706 esac
2707 AC_SUBST(BLESSMAIL_TARGET)
2708
2709
2710 AC_CHECK_FUNCS(gethostname \
2711 closedir getrusage get_current_dir_name \
2712 lrand48 logb frexp fmod cbrt setsid \
2713 fpathconf select euidaccess getpagesize setlocale \
2714 utimes getrlimit setrlimit setpgid getcwd shutdown getaddrinfo \
2715 __fpending strsignal setitimer \
2716 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2717 gai_strerror mkstemp getline getdelim fsync sync \
2718 difftime posix_memalign \
2719 getpwent endpwent getgrent endgrent \
2720 touchlock \
2721 cfmakeraw cfsetspeed copysign __executable_start)
2722
2723 dnl getwd appears to be buggy on SVR4.2, so we don't use it.
2724 if test $opsys != unixware; then
2725   AC_CHECK_FUNCS(getwd)
2726 fi
2727
2728 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
2729 ## has a broken `rint' in some library versions including math library
2730 ## version number A.09.05.
2731 ## You can fix the math library by installing patch number PHSS_4630.
2732 ## But we can fix it more reliably for Emacs by just not using rint.
2733 ## We also skip HAVE_RANDOM - see comments in src/s/hpux10-20.h.
2734 case $opsys in
2735    hpux*) : ;;
2736    *) AC_CHECK_FUNCS(random rint) ;;
2737 esac
2738
2739 dnl Cannot use AC_CHECK_FUNCS
2740 AC_CACHE_CHECK([for __builtin_unwind_init],
2741                emacs_cv_func___builtin_unwind_init,
2742 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2743                 emacs_cv_func___builtin_unwind_init=yes,
2744                 emacs_cv_func___builtin_unwind_init=no)])
2745 if test $emacs_cv_func___builtin_unwind_init = yes; then
2746   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2747             [Define to 1 if you have the `__builtin_unwind_init' function.])
2748 fi
2749
2750 AC_CHECK_HEADERS_ONCE(sys/un.h)
2751
2752 AC_FUNC_FSEEKO
2753
2754 AC_FUNC_GETPGRP
2755
2756 # UNIX98 PTYs.
2757 AC_CHECK_FUNCS(grantpt)
2758
2759 # PTY-related GNU extensions.
2760 AC_CHECK_FUNCS(getpt)
2761
2762 # Check this now, so that we will NOT find the above functions in ncurses.
2763 # That is because we have not set up to link ncurses in lib-src.
2764 # It's better to believe a function is not available
2765 # than to expect to find it in ncurses.
2766 # Also we need tputs and friends to be able to build at all.
2767 AC_MSG_CHECKING([for library containing tputs])
2768 # Run a test program that contains a call to tputs, a call that is
2769 # never executed.  This tests whether a pre-'main' dynamic linker
2770 # works with the library.  It's too much trouble to actually call
2771 # tputs in the test program, due to portability hassles.  When
2772 # cross-compiling, assume the test program will run if it links.
2773 AC_DEFUN([tputs_link_source], [
2774   AC_LANG_SOURCE(
2775      [[extern void tputs (const char *, int, int (*)(int));
2776        int main (int argc, char **argv)
2777        {
2778           if (argc == 10000)
2779             tputs (argv[0], 0, 0);
2780           return 0;
2781        }]])
2782 ])
2783 # Maybe curses should be tried earlier?
2784 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2785 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2786   OLIBS=$LIBS
2787   if test -z "$tputs_library"; then
2788     LIBS_TERMCAP=
2789     msg='none required'
2790   else
2791     LIBS_TERMCAP=-l$tputs_library
2792     msg=$LIBS_TERMCAP
2793     LIBS="$LIBS_TERMCAP $LIBS"
2794   fi
2795   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2796     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2797   LIBS=$OLIBS
2798   if test "X$msg" != Xno; then
2799     break
2800   fi
2801 done
2802 AC_MSG_RESULT([$msg])
2803 if test "X$msg" = Xno; then
2804   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2805 The following libraries were tried (in order):
2806   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2807 Please try installing whichever of these libraries is most appropriate
2808 for your system, together with its header files.
2809 For example, a libncurses-dev(el) or similar package.])
2810 fi
2811
2812 ## Use termcap instead of terminfo?
2813 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2814 TERMINFO=yes
2815 ## FIXME?  In the cases below where we unconditionally set
2816 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2817 ## if that was found above to have tputs.
2818 ## Should we use the gnu* logic everywhere?
2819 case "$opsys" in
2820   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2821   ##  The ncurses library has been moved out of the System framework in
2822   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2823   ##  option to use it.
2824   darwin) LIBS_TERMCAP="-lncurses" ;;
2825
2826   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2827
2828   freebsd)
2829     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2830     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2831     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2832 [[#if __FreeBSD_version < 400000
2833 fail;
2834 #endif
2835 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2836
2837     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2838
2839     if test $emacs_cv_freebsd_terminfo = yes; then
2840       LIBS_TERMCAP="-lncurses"
2841     else
2842       TERMINFO=no
2843       LIBS_TERMCAP="-ltermcap"
2844     fi
2845     ;;
2846
2847   netbsd)
2848     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2849       TERMINFO=no
2850       LIBS_TERMCAP="-ltermcap"
2851     fi
2852     ;;
2853
2854   openbsd) LIBS_TERMCAP="-lncurses" ;;
2855
2856   ## hpux: Make sure we get select from libc rather than from libcurses
2857   ##  because libcurses on HPUX 10.10 has a broken version of select.
2858   ##  We used to use -lc -lcurses, but this may be cleaner.
2859   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2860   # set that way, now it uses the default).  Isn't this a contradiction?
2861   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2862
2863 esac
2864
2865 TERMCAP_OBJ=tparam.o
2866 if test $TERMINFO = yes; then
2867   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2868   TERMCAP_OBJ=terminfo.o
2869 fi
2870 AC_SUBST(LIBS_TERMCAP)
2871 AC_SUBST(TERMCAP_OBJ)
2872
2873
2874 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2875 # On Darwin, res_init appears not to be useful: see bug#562 and
2876 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
2877 resolv=no
2878
2879 if test $opsys != darwin; then
2880
2881   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2882 #include <arpa/nameser.h>
2883 #include <resolv.h>]],
2884     [[return res_init();]])],
2885     have_res_init=yes, have_res_init=no)
2886   if test "$have_res_init" = no; then
2887     OLIBS="$LIBS"
2888     LIBS="$LIBS -lresolv"
2889     AC_MSG_CHECKING(for res_init with -lresolv)
2890     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2891 #include <arpa/nameser.h>
2892 #include <resolv.h>]],
2893       [[return res_init();]])],
2894       have_res_init=yes, have_res_init=no)
2895     AC_MSG_RESULT($have_res_init)
2896     if test "$have_res_init" = yes ; then
2897       resolv=yes
2898     fi
2899     LIBS="$OLIBS"
2900   fi
2901
2902   if test "$have_res_init" = yes; then
2903     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2904   fi
2905 fi                              dnl !darwin
2906
2907 # Do we need the Hesiod library to provide the support routines?
2908 dnl FIXME?  Should we be skipping this on Darwin too?
2909 LIBHESIOD=
2910 if test "$with_hesiod" != no ; then
2911   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2912   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2913      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2914                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2915   if test "$resolv" = yes ; then
2916     RESOLVLIB=-lresolv
2917   else
2918     RESOLVLIB=
2919   fi
2920   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2921         hesiod=yes, :, $RESOLVLIB)])
2922
2923   if test x"$hesiod" = xyes; then
2924     AC_DEFINE(HAVE_LIBHESIOD, 1,
2925               [Define to 1 if you have the hesiod library (-lhesiod).])
2926     LIBHESIOD=-lhesiod
2927   fi
2928 fi
2929 AC_SUBST(LIBHESIOD)
2930
2931 # Do we need libresolv (due to res_init or Hesiod)?
2932 if test "$resolv" = yes && test $opsys != darwin; then
2933   AC_DEFINE(HAVE_LIBRESOLV, 1,
2934             [Define to 1 if you have the resolv library (-lresolv).])
2935   LIBRESOLV=-lresolv
2936 else
2937   LIBRESOLV=
2938 fi
2939 AC_SUBST(LIBRESOLV)
2940
2941 # These tell us which Kerberos-related libraries to use.
2942 COM_ERRLIB=
2943 CRYPTOLIB=
2944 KRB5LIB=
2945 DESLIB=
2946 KRB4LIB=
2947
2948 if test "${with_kerberos}" != no; then
2949   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2950   if test $have_com_err = yes; then
2951     COM_ERRLIB=-lcom_err
2952     LIBS="$COM_ERRLIB $LIBS"
2953     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2954   fi
2955   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2956   if test $have_crypto = yes; then
2957     CRYPTOLIB=-lcrypto
2958     LIBS="$CRYPTOLIB $LIBS"
2959     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2960   fi
2961   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2962   if test $have_k5crypto = yes; then
2963     CRYPTOLIB=-lk5crypto
2964     LIBS="$CRYPTOLIB $LIBS"
2965     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2966   fi
2967   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2968   if test $have_krb5=yes; then
2969     KRB5LIB=-lkrb5
2970     LIBS="$KRB5LIB $LIBS"
2971     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2972   fi
2973   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2974   if test "${with_kerberos5}" = no; then
2975     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2976     if test $have_des425 = yes; then
2977       DESLIB=-ldes425
2978       LIBS="$DESLIB $LIBS"
2979       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2980     else
2981       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2982       if test $have_des = yes; then
2983         DESLIB=-ldes
2984         LIBS="$DESLIB $LIBS"
2985         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2986       fi
2987     fi
2988     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2989     if test $have_krb4 = yes; then
2990       KRB4LIB=-lkrb4
2991       LIBS="$KRB4LIB $LIBS"
2992       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2993     else
2994       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2995       if test $have_krb = yes; then
2996         KRB4LIB=-lkrb
2997         LIBS="$KRB4LIB $LIBS"
2998         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2999       fi
3000     fi
3001   fi
3002
3003   if test "${with_kerberos5}" != no; then
3004     AC_CHECK_HEADERS(krb5.h,
3005       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3006                         [#include <krb5.h>])])
3007   else
3008     AC_CHECK_HEADERS(des.h,,
3009                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3010                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3011     AC_CHECK_HEADERS(krb.h,,
3012                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3013                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3014   fi
3015   AC_CHECK_HEADERS(com_err.h)
3016 fi
3017
3018 AC_SUBST(COM_ERRLIB)
3019 AC_SUBST(CRYPTOLIB)
3020 AC_SUBST(KRB5LIB)
3021 AC_SUBST(DESLIB)
3022 AC_SUBST(KRB4LIB)
3023
3024 AC_CHECK_FUNCS_ONCE(tzset)
3025 AC_MSG_CHECKING(whether localtime caches TZ)
3026 AC_CACHE_VAL(emacs_cv_localtime_cache,
3027 [if test x$ac_cv_func_tzset = xyes; then
3028 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3029 char TZ_GMT0[] = "TZ=GMT0";
3030 char TZ_PST8[] = "TZ=PST8";
3031 main()
3032 {
3033   time_t now = time ((time_t *) 0);
3034   int hour_GMT0, hour_unset;
3035   if (putenv (TZ_GMT0) != 0)
3036     exit (1);
3037   hour_GMT0 = localtime (&now)->tm_hour;
3038   unsetenv("TZ");
3039   hour_unset = localtime (&now)->tm_hour;
3040   if (putenv (TZ_PST8) != 0)
3041     exit (1);
3042   if (localtime (&now)->tm_hour == hour_GMT0)
3043     exit (1);
3044   unsetenv("TZ");
3045   if (localtime (&now)->tm_hour != hour_unset)
3046     exit (1);
3047   exit (0);
3048 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3049 [# If we have tzset, assume the worst when cross-compiling.
3050 emacs_cv_localtime_cache=yes])
3051 else
3052         # If we lack tzset, report that localtime does not cache TZ,
3053         # since we can't invalidate the cache if we don't have tzset.
3054         emacs_cv_localtime_cache=no
3055 fi])dnl
3056 AC_MSG_RESULT($emacs_cv_localtime_cache)
3057 if test $emacs_cv_localtime_cache = yes; then
3058   AC_DEFINE(LOCALTIME_CACHE, 1,
3059             [Define to 1 if localtime caches TZ.])
3060 fi
3061
3062 ok_so_far=yes
3063 AC_CHECK_FUNC(socket, , ok_so_far=no)
3064 if test $ok_so_far = yes; then
3065   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3066 fi
3067 if test $ok_so_far = yes; then
3068   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3069 fi
3070 if test $ok_so_far = yes; then
3071 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3072   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3073             [Define to 1 if you have inet sockets.])
3074 fi
3075
3076 if test -f /usr/lpp/X11/bin/smt.exp; then
3077   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3078             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3079 fi
3080
3081 AC_MSG_CHECKING(whether system supports dynamic ptys)
3082 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3083   AC_MSG_RESULT(yes)
3084   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3085 else
3086   AC_MSG_RESULT(no)
3087 fi
3088
3089 AC_FUNC_FORK
3090
3091 AC_CHECK_FUNCS(snprintf)
3092
3093 dnl Adapted from Haible's version.
3094 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3095   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3096     [[char* cs = nl_langinfo(CODESET);]])],
3097     emacs_cv_langinfo_codeset=yes,
3098     emacs_cv_langinfo_codeset=no)
3099   ])
3100 if test $emacs_cv_langinfo_codeset = yes; then
3101   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3102     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3103 fi
3104
3105 AC_TYPE_MBSTATE_T
3106
3107 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3108   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3109                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3110 if test "$emacs_cv_c_restrict_arr" = yes; then
3111   AC_DEFINE(__restrict_arr, __restrict,
3112     [Define to compiler's equivalent of C99 restrict keyword in array
3113      declarations.  Define as empty for no equivalent.])
3114 fi
3115
3116 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3117 dnl how the tty code is related to POSIX and/or other versions of termios.
3118 dnl The following looks like a useful start.
3119 dnl
3120 dnl AC_SYS_POSIX_TERMIOS
3121 dnl if test $ac_cv_sys_posix_termios = yes; then
3122 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3123 dnl                                and macros for terminal control.])
3124 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3125 dnl fi
3126
3127 dnl Every platform that uses configure (ie every non-MS platform)
3128 dnl supports this.  There is a create-lockfiles option you can
3129 dnl customize if you do not want the lock files to be written.
3130 dnl So it is not clear that this #define still needs to exist.
3131 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3132   so that Emacs can tell instantly when you try to modify a file that
3133   someone else has modified in his/her Emacs.])
3134
3135 case $opsys in
3136   darwin | gnu | hpux* | *bsd )
3137     AC_DEFINE(NO_TERMIO, 1, [Define if termio.h should not be included.])
3138   ;;
3139 esac
3140
3141 dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3142 dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3143 case $opsys in
3144   hpux* | irix6-5 | openbsd | sol2* | unixware )
3145     AC_DEFINE(BROKEN_SIGIO, 1, [Define if SIGIO should not be used.])
3146   ;;
3147 esac
3148
3149 case $opsys in
3150   gnu-* | sol2-10 )
3151     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3152     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3153   ;;
3154 esac
3155
3156 case $opsys in
3157   darwin | freebsd | netbsd | openbsd )
3158     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3159       close a pty to make it a controlling terminal (it is already a
3160       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3161   ;;
3162 esac
3163
3164 dnl FIXME Surely we can test for this rather than hard-code it.
3165 case $opsys in
3166   netbsd | openbsd) sound_device="/dev/audio" ;;
3167   *) sound_device="/dev/dsp" ;;
3168 esac
3169
3170 dnl Used in sound.c
3171 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3172   [Name of the default sound device.])
3173
3174 dnl Used in dispnew.c
3175 AH_TEMPLATE(PENDING_OUTPUT_COUNT, [Number of chars of output in the
3176 buffer of a stdio stream.])
3177
3178 dnl FIXME just PENDING_OUTPUT_COUNT should suffice.
3179 AH_TEMPLATE(GNU_LIBRARY_PENDING_OUTPUT_COUNT, [Value of
3180 PENDING_OUTPUT_COUNT if using the GNU C library.])
3181
3182 case $opsys in
3183   cygwin | darwin | freebsd | netbsd | openbsd )
3184     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_p - (FILE)->_bf._base)])
3185     ;;
3186
3187   unixware)
3188     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__ptr - (FILE)->__base)])
3189     ;;
3190
3191   gnu | gnu-linux | gnu-kfreebsd )
3192     AC_MSG_CHECKING([for style of pending output formalism])
3193     dnl In autoconf 2.67 (?) and later, we could use a single test
3194     dnl since the preprocessed output is accessible in "conftest.i".
3195     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3196 #include <stdio.h>
3197 #if !defined (_IO_STDIO_H) && !defined (_STDIO_USES_IOSTREAM)
3198 # error "stdio definitions not found"
3199 #endif
3200       ]], [[]])], emacs_pending_output=new, emacs_pending_output=unknown)
3201
3202       if test $emacs_pending_output = unknown; then
3203         case $opsys in
3204           gnu-linux | gnu-kfreebsd)
3205             AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3206 #include <stdio.h>
3207 #ifndef __UCLIBC__
3208 # error "not using uclibc"
3209 #endif
3210             ]], [[]])], emacs_pending_output=uclibc, emacs_pending_output=old)
3211             ;;
3212         esac
3213       fi
3214
3215       AC_MSG_RESULT([$emacs_pending_output])
3216
3217       case $emacs_pending_output in
3218         new)
3219           dnl New C libio names.
3220           AC_DEFINE(GNU_LIBRARY_PENDING_OUTPUT_COUNT(FILE),
3221             [((FILE)->_IO_write_ptr - (FILE)->_IO_write_base)])
3222           ;;
3223         uclibc)
3224           dnl Using the uClibc library.
3225           AC_DEFINE(GNU_LIBRARY_PENDING_OUTPUT_COUNT(FILE),
3226             [((FILE)->__bufpos - (FILE)->__bufstart)])
3227           ;;
3228         old)
3229           dnl Old C++ iostream names.
3230           AC_DEFINE(GNU_LIBRARY_PENDING_OUTPUT_COUNT(FILE),
3231             [((FILE)->_pptr - (FILE)->_pbase)])
3232           ;;
3233       esac
3234     ;;
3235 esac
3236
3237
3238 dnl Used in vm-limit.c
3239 AH_TEMPLATE(DATA_START, [Address of the start of the data segment.])
3240 dnl Used in lisp.h, emacs.c, mem-limits.h
3241 dnl NEWS.18 describes this as "a number which contains
3242 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
3243 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
3244 stored in a Lisp_Object.])
3245 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
3246
3247 case $opsys in
3248   gnu)
3249     dnl libc defines data_start.
3250     AC_DEFINE(DATA_START, [({ extern int data_start; (char *) &data_start; })])
3251     ;;
3252
3253   hpux*)
3254     dnl The data segment on this machine always starts at address 0x40000000.
3255     AC_DEFINE(DATA_START, [0x40000000])
3256     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
3257     ;;
3258   irix6-5)
3259     AC_DEFINE(DATA_START, [0x10000000])
3260     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
3261     ;;
3262 esac
3263
3264 case $opsys in
3265    gnu) opsysfile="s/bsd-common.h" ;;
3266
3267    gnu-kfreebsd) opsysfile="s/gnu-linux.h" ;;
3268
3269    hpux11)
3270      dnl See comments in sysdep.c:sys_signal.
3271      dnl SA_RESTART resets the timeout of `select' on hpux11.
3272      dnl Defining BROKEN_SA_RESTART is not the same as undef'ing SA_RESTART.
3273      AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should only
3274        be used in batch mode.])
3275      dnl It works to open the pty's tty in the parent (Emacs), then
3276      dnl close and reopen it in the child.
3277      AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3278        works to open a pty's tty in the parent process, then close and
3279        reopen it in the child.])
3280
3281      opsysfile="s/hpux10-20.h"
3282    ;;
3283
3284    openbsd) opsysfile="s/netbsd.h" ;;
3285
3286    sol2-10)
3287      AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
3288        on Solaris.])
3289      opsysfile="s/sol2-6.h"
3290    ;;
3291 esac
3292
3293 # Set up the CFLAGS for real compilation, so we can substitute it.
3294 CFLAGS="$REAL_CFLAGS"
3295 CPPFLAGS="$REAL_CPPFLAGS"
3296
3297 ## Hack to detect a buggy GCC version.
3298 if test "x$GCC" = xyes \
3299    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3300    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3301    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3302    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3303 fi
3304
3305 version=$PACKAGE_VERSION
3306
3307 ### Specify what sort of things we'll be editing into Makefile and config.h.
3308 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3309 AC_SUBST(version)
3310 AC_SUBST(configuration)
3311 ## Unused?
3312 AC_SUBST(canonical)
3313 AC_SUBST(srcdir)
3314 AC_SUBST(prefix)
3315 AC_SUBST(exec_prefix)
3316 AC_SUBST(bindir)
3317 AC_SUBST(datadir)
3318 AC_SUBST(sharedstatedir)
3319 AC_SUBST(libexecdir)
3320 AC_SUBST(mandir)
3321 AC_SUBST(infodir)
3322 AC_SUBST(lispdir)
3323 AC_SUBST(leimdir)
3324 AC_SUBST(standardlisppath)
3325 AC_SUBST(locallisppath)
3326 AC_SUBST(lisppath)
3327 AC_SUBST(x_default_search_path)
3328 AC_SUBST(etcdir)
3329 AC_SUBST(archlibdir)
3330 AC_SUBST(docdir)
3331 AC_SUBST(bitmapdir)
3332 AC_SUBST(gamedir)
3333 AC_SUBST(gameuser)
3334 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3335 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3336 ## end of LIBX_BASE, but nothing ever set it.
3337 AC_SUBST(LD_SWITCH_X_SITE)
3338 AC_SUBST(C_SWITCH_X_SITE)
3339 AC_SUBST(GNUSTEP_CFLAGS)
3340 AC_SUBST(CFLAGS)
3341 ## Used in lwlib/Makefile.in.
3342 AC_SUBST(X_TOOLKIT_TYPE)
3343 if test -n "${opsysfile}"; then
3344   S_FILE="\$(srcdir)/${opsysfile}"
3345 else
3346   S_FILE=
3347 fi
3348 AC_SUBST(S_FILE)
3349 AC_SUBST(ns_appdir)
3350 AC_SUBST(ns_appbindir)
3351 AC_SUBST(ns_appresdir)
3352 AC_SUBST(ns_appsrc)
3353 AC_SUBST(GNU_OBJC_CFLAGS)
3354 AC_SUBST(OTHER_FILES)
3355
3356 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3357                    [Define to the canonical Emacs configuration name.])
3358 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3359                    [Define to the options passed to configure.])
3360 if test -n "$opsysfile"; then
3361   AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3362                      [Define to the used os dependent file.])
3363 fi
3364
3365 XMENU_OBJ=
3366 XOBJ=
3367 FONT_OBJ=
3368 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3369   AC_DEFINE(HAVE_X_WINDOWS, 1,
3370             [Define to 1 if you want to use the X window system.])
3371   XMENU_OBJ=xmenu.o
3372   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3373   FONT_OBJ=xfont.o
3374   if test "$HAVE_XFT" = "yes"; then
3375     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3376   elif test "$HAVE_FREETYPE" = "yes"; then
3377     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3378   fi
3379   AC_SUBST(FONT_OBJ)
3380 fi
3381 AC_SUBST(XMENU_OBJ)
3382 AC_SUBST(XOBJ)
3383 AC_SUBST(FONT_OBJ)
3384
3385 WIDGET_OBJ=
3386 MOTIF_LIBW=
3387 if test "${USE_X_TOOLKIT}" != "none" ; then
3388   WIDGET_OBJ=widget.o
3389   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3390   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3391     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3392   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3393     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3394     MOTIF_LIBW=-lXm
3395     case "$opsys" in
3396       gnu-linux)
3397         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3398         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3399         ;;
3400
3401       unixware)
3402         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3403         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3404         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3405         ;;
3406
3407       aix4-2)
3408         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3409         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3410         ;;
3411     esac
3412     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3413   fi
3414 fi
3415 AC_SUBST(WIDGET_OBJ)
3416
3417 TOOLKIT_LIBW=
3418 case "$USE_X_TOOLKIT" in
3419   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3420   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3421   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3422 esac
3423 AC_SUBST(TOOLKIT_LIBW)
3424
3425 if test "$USE_X_TOOLKIT" = "none"; then
3426   LIBXT_OTHER="\$(LIBXSM)"
3427   OLDXMENU_TARGET="really-oldXMenu"
3428 else
3429   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3430   OLDXMENU_TARGET="really-lwlib"
3431 fi
3432 AC_SUBST(LIBXT_OTHER)
3433
3434 ## The X Menu stuff is present in the X10 distribution, but missing
3435 ## from X11.  If we have X10, just use the installed library;
3436 ## otherwise, use our own copy.
3437 if test "${HAVE_X11}" = "yes" ; then
3438   AC_DEFINE(HAVE_X11, 1,
3439             [Define to 1 if you want to use version 11 of X windows.
3440              Otherwise, Emacs expects to use version 10.])
3441
3442   if test "$USE_X_TOOLKIT" = "none"; then
3443     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3444   else
3445     OLDXMENU="\${lwlibdir}/liblw.a"
3446   fi
3447   LIBXMENU="\$(OLDXMENU)"
3448   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3449   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3450 else
3451   ## For a syntactically valid Makefile; not actually used for anything.
3452   ## See comments in src/Makefile.in.
3453   OLDXMENU=nothing
3454   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3455   if test "${HAVE_X_WINDOWS}" = "yes"; then
3456     LIBXMENU="-lXMenu"
3457   else
3458     LIBXMENU=
3459   fi
3460   LIBX_OTHER=
3461   OLDXMENU_DEPS=
3462 fi
3463
3464 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3465   OLDXMENU_TARGET=
3466   OLDXMENU=nothing
3467   LIBXMENU=
3468   OLDXMENU_DEPS=
3469 fi
3470
3471 AC_SUBST(OLDXMENU_TARGET)
3472 AC_SUBST(OLDXMENU)
3473 AC_SUBST(LIBXMENU)
3474 AC_SUBST(LIBX_OTHER)
3475 AC_SUBST(OLDXMENU_DEPS)
3476
3477 if test "${HAVE_MENUS}" = "yes" ; then
3478   AC_DEFINE(HAVE_MENUS, 1,
3479             [Define to 1 if you have mouse menus.
3480              (This is automatic if you use X, but the option to specify it remains.)
3481              It is also defined with other window systems that support xmenu.c.])
3482 fi
3483
3484 if test "${GNU_MALLOC}" = "yes" ; then
3485   AC_DEFINE(GNU_MALLOC, 1,
3486             [Define to 1 if you want to use the GNU memory allocator.])
3487 fi
3488
3489 RALLOC_OBJ=
3490 if test "${REL_ALLOC}" = "yes" ; then
3491   AC_DEFINE(REL_ALLOC, 1,
3492             [Define REL_ALLOC if you want to use the relocating allocator for
3493              buffer space.])
3494
3495   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3496 fi
3497 AC_SUBST(RALLOC_OBJ)
3498
3499 if test "$opsys" = "cygwin"; then
3500   CYGWIN_OBJ="sheap.o"
3501   ## Cygwin differs because of its unexec().
3502   PRE_ALLOC_OBJ=
3503   POST_ALLOC_OBJ=lastfile.o
3504 else
3505   CYGWIN_OBJ=
3506   PRE_ALLOC_OBJ=lastfile.o
3507   POST_ALLOC_OBJ=
3508 fi
3509 AC_SUBST(CYGWIN_OBJ)
3510 AC_SUBST(PRE_ALLOC_OBJ)
3511 AC_SUBST(POST_ALLOC_OBJ)
3512
3513 case "$opsys" in
3514   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3515
3516   darwin)
3517    ## The -headerpad option tells ld (see man page) to leave room at the
3518    ## end of the header for adding load commands.  Needed for dumping.
3519    ## 0x690 is the total size of 30 segment load commands (at 56
3520    ## each); under Cocoa 31 commands are required.
3521    if test "$HAVE_NS" = "yes"; then
3522      libs_nsgui="-framework AppKit"
3523      headerpad_extra=6C8
3524    else
3525      libs_nsgui=
3526      headerpad_extra=690
3527    fi
3528    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3529
3530    ## This is here because src/Makefile.in did some extra fiddling around
3531    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3532    ##   #ifndef LD_SWITCH_SYSTEM
3533    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3534    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3535    ## not using gcc, darwin.
3536    ## Because this was done in src/Makefile.in, the resulting part of
3537    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3538    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3539    ## rather than LD_SWITCH_SYSTEM.
3540    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3541      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3542    ;;
3543
3544   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3545   ## find X at run-time.
3546   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3547   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3548   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3549   ## had different values in configure (in ac_link) and src/Makefile.in.
3550   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3551   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3552
3553   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3554 esac
3555
3556 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3557   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3558 fi
3559
3560 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3561
3562
3563 LD_FIRSTFLAG=
3564 ORDINARY_LINK=
3565 case "$opsys" in
3566   ## gnu: GNU needs its own crt0.
3567   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3568
3569   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3570   ## library search parth, i.e. it won't search /usr/lib for libc and
3571   ## friends.  Using -nostartfiles instead avoids this problem, and
3572   ## will also work on earlier NetBSD releases.
3573   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3574
3575   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3576   ##   MkLinux/LinuxPPC needs this.
3577   ## s390x-* only supports opsys = gnu-linux so it can be added here.
3578   gnu-*)
3579     case "$canonical" in
3580       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
3581     esac
3582     ;;
3583 esac
3584
3585
3586 if test "x$ORDINARY_LINK" = "xyes"; then
3587
3588   LD_FIRSTFLAG=""
3589   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3590
3591 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3592 ## freebsd, gnu-* not on powerpc*|s390x*.
3593 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3594
3595   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3596   ## places that are difficult to figure out at make time.  Fortunately,
3597   ## these same versions allow you to pass arbitrary flags on to the
3598   ## linker, so there is no reason not to use it as a linker.
3599   ##
3600   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3601   ## searching for libraries in its internal directories, so we have to
3602   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3603   LD_FIRSTFLAG="-nostdlib"
3604 fi
3605
3606 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3607 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3608
3609 AC_SUBST(LD_FIRSTFLAG)
3610
3611
3612 ## FIXME? The logic here is not precisely the same as that above.
3613 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3614 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3615 LIB_GCC=
3616 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3617
3618   case "$opsys" in
3619     freebsd|netbsd|openbsd) LIB_GCC= ;;
3620
3621     gnu-*)
3622       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3623       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3624       case $host_cpu in
3625       arm*)
3626         LIB_GCC="-lgcc_s"
3627         ;;
3628       *)
3629         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3630         ## immediately undefine it again and redefine it to empty.
3631         ## Was the C_SWITCH_X_SITE part really necessary?
3632 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3633         LIB_GCC=
3634         ;;
3635       esac
3636       ;;
3637
3638     ## Ask GCC where to find libgcc.a.
3639     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3640   esac
3641 fi                              dnl if $GCC
3642 AC_SUBST(LIB_GCC)
3643
3644
3645 ## If we're using X11/GNUstep, define some consequences.
3646 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3647   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3648   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3649 fi
3650
3651
3652 AH_TOP([/* GNU Emacs site configuration template file.
3653
3654 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3655   Free Software Foundation, Inc.
3656
3657 This file is part of GNU Emacs.
3658
3659 GNU Emacs is free software: you can redistribute it and/or modify
3660 it under the terms of the GNU General Public License as published by
3661 the Free Software Foundation, either version 3 of the License, or
3662 (at your option) any later version.
3663
3664 GNU Emacs is distributed in the hope that it will be useful,
3665 but WITHOUT ANY WARRANTY; without even the implied warranty of
3666 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3667 GNU General Public License for more details.
3668
3669 You should have received a copy of the GNU General Public License
3670 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3671
3672
3673 /* No code in Emacs #includes config.h twice, but some bits of code
3674    intended to work with other packages as well (like gmalloc.c)
3675    think they can include it as many times as they like.  */
3676 #ifndef EMACS_CONFIG_H
3677 #define EMACS_CONFIG_H
3678 ])dnl
3679
3680 AH_BOTTOM([
3681 /* On AIX 3 this must be included before any other include file.  */
3682 #include <alloca.h>
3683 #if ! HAVE_ALLOCA
3684 # error "alloca not available on this machine"
3685 #endif
3686
3687 /* Define AMPERSAND_FULL_NAME if you use the convention
3688    that & in the full name stands for the login id.  */
3689 /* Turned on June 1996 supposing nobody will mind it.  */
3690 #define AMPERSAND_FULL_NAME
3691
3692 /* `subprocesses' should be defined if you want to
3693    have code for asynchronous subprocesses
3694    (as used in M-x compile and M-x shell).
3695    Only MSDOS does not support this (it overrides
3696    this in its config_opsysfile below).  */
3697
3698 #define subprocesses
3699
3700 /* Include the os dependent file.  */
3701 #ifdef config_opsysfile
3702 # include config_opsysfile
3703 #endif
3704
3705 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3706    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3707   (There is probably a better place to do this, but right now the
3708    Cocoa side does this in s/darwin.h and we cannot parallel this
3709    exactly since GNUstep is multi-OS.  */
3710 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3711 #  define SYSTEM_PURESIZE_EXTRA 30000
3712 #endif
3713
3714 #ifdef emacs /* Don't do this for lib-src.  */
3715 /* Tell regex.c to use a type compatible with Emacs.  */
3716 #define RE_TRANSLATE_TYPE Lisp_Object
3717 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3718 #ifdef make_number
3719 /* If make_number is a macro, use it.  */
3720 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3721 #else
3722 /* If make_number is a function, avoid it.  */
3723 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3724 #endif
3725 #endif
3726
3727 #include <string.h>
3728 #include <stdlib.h>
3729
3730 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3731 #define NO_INLINE __attribute__((noinline))
3732 #else
3733 #define NO_INLINE
3734 #endif
3735
3736 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3737 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3738 #else
3739 #define EXTERNALLY_VISIBLE
3740 #endif
3741
3742 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3743 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3744 #else
3745 # define ATTRIBUTE_FORMAT(spec) /* empty */
3746 #endif
3747
3748 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3749 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3750    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3751 #else
3752 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3753    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3754 #endif
3755
3756 #define ATTRIBUTE_CONST _GL_ATTRIBUTE_CONST
3757
3758 /* Some versions of GNU/Linux define noinline in their headers.  */
3759 #ifdef noinline
3760 #undef noinline
3761 #endif
3762
3763 /* These won't be used automatically yet.  We also need to know, at least,
3764    that the stack is continuous.  */
3765 #ifdef __GNUC__
3766 #  ifndef GC_SETJMP_WORKS
3767   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3768 #    define GC_SETJMP_WORKS 1
3769 #  endif
3770 #endif
3771
3772 #endif /* EMACS_CONFIG_H */
3773
3774 /*
3775 Local Variables:
3776 mode: c
3777 End:
3778 */
3779 ])dnl
3780
3781 #### Report on what we decided to do.
3782 #### Report GTK as a toolkit, even if it doesn't use Xt.
3783 #### It makes printing result more understandable as using GTK sets
3784 #### toolkit_scroll_bars to yes by default.
3785 if test "${HAVE_GTK}" = "yes"; then
3786   USE_X_TOOLKIT=GTK
3787 fi
3788
3789 echo "
3790 Configured for \`${canonical}'.
3791
3792   Where should the build process find the source code?    ${srcdir}
3793   What operating system file should Emacs use?            ${opsysfile-none}
3794   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3795   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3796   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3797   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3798   What window system should Emacs use?                    ${window_system}
3799   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3800
3801 if test -n "${x_includes}"; then
3802 echo "  Where do we find X Windows header files?                ${x_includes}"
3803 else
3804 echo "  Where do we find X Windows header files?                Standard dirs"
3805 fi
3806 if test -n "${x_libraries}"; then
3807 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3808 else
3809 echo "  Where do we find X Windows libraries?                   Standard dirs"
3810 fi
3811
3812 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3813 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3814 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3815 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3816 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3817 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3818 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3819 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3820
3821 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3822 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3823 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3824 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3825 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3826 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3827 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3828
3829 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3830 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3831 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3832 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3833
3834 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3835 echo
3836
3837 if test -n "${EMACSDATA}"; then
3838    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3839 fi
3840 if test -n "${EMACSDOC}"; then
3841    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3842 fi
3843
3844 echo
3845
3846 if test "$HAVE_NS" = "yes"; then
3847    echo
3848    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3849 The installed application will go to nextstep/Emacs.app and can be
3850 run or moved from there."
3851    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3852       echo "The application will be fully self-contained."
3853     else
3854       echo "The lisp resources for the application will be installed under ${prefix}.
3855 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3856 to run if these resources are not installed."
3857    fi
3858    echo
3859 fi
3860
3861 if test "${opsys}" = "cygwin"; then
3862   case `uname -r` in
3863     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3864            echo
3865            ;;
3866   esac
3867 fi
3868
3869 # Remove any trailing slashes in these variables.
3870 [test "${prefix}" != NONE &&
3871   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3872 test "${exec_prefix}" != NONE &&
3873   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3874
3875 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3876 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3877 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3878 dnl (else you get "no `Makefile.am' found for any configure output").
3879 dnl This will work, but you get a config.status that is not quite right
3880 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3881 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3882 dnl it seems better to just live with the duplication.
3883 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3884
3885 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3886        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3887        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3888        leim/Makefile])
3889
3890 dnl test/ is not present in release tarfiles.
3891 opt_makefile=test/automated/Makefile
3892
3893 if test -f $srcdir/${opt_makefile}.in; then
3894   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3895   dnl Again, it's best not to use a variable.  Though you can add
3896   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3897   AC_CONFIG_FILES([test/automated/Makefile])
3898 fi
3899
3900
3901 dnl admin/ may or may not be present.
3902 opt_makefile=admin/unidata/Makefile
3903
3904 if test -f $srcdir/${opt_makefile}.in; then
3905   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3906   AC_CONFIG_FILES([admin/unidata/Makefile])
3907 fi
3908
3909
3910 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3911
3912 AC_SUBST(SUBDIR_MAKEFILES_IN)
3913
3914 dnl Make the necessary directories, if they don't exist.
3915 AC_CONFIG_COMMANDS([mkdirs], [
3916 for dir in etc lisp ; do
3917   test -d ${dir} || mkdir ${dir}
3918 done
3919 ])
3920
3921 dnl You might wonder (I did) why epaths.h is generated by running make,
3922 dnl rather than just letting configure generate it from epaths.in.
3923 dnl One reason is that the various paths are not fully expanded (see above);
3924 dnl eg gamedir=${prefix}/var/games/emacs.
3925 dnl Secondly, the GNU Coding standards require that one should be able
3926 dnl to run `make prefix=/some/where/else' and override the values set
3927 dnl by configure.  This also explains the `move-if-change' test and
3928 dnl the use of force in the `epaths-force' rule in Makefile.in.
3929 AC_CONFIG_COMMANDS([epaths], [
3930 echo creating src/epaths.h
3931 ${MAKE-make} epaths-force
3932 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
3933
3934 AC_CONFIG_COMMANDS([gdbinit], [
3935 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3936   echo creating src/.gdbinit
3937   echo source $srcdir/src/.gdbinit > src/.gdbinit
3938 fi
3939 ])
3940
3941 AC_OUTPUT